gcc/ada/osint.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                O S I N T                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Unchecked_Conversion;
  28
  29 with System.Case_Util; use System.Case_Util;
  30
  31 with GNAT.HTable;
  32
  33 with Fmap;             use Fmap;
  34 with Gnatvsn;          use Gnatvsn;
  35 with Hostparm;
  36 with Opt;              use Opt;
  37 with Output;           use Output;
  38 with Sdefault;         use Sdefault;
  39 with Table;
  40 with Targparm;         use Targparm;
  41
  42 package body Osint is
  43
  44    Running_Program : Program_Type := Unspecified;
  45    --  comment required here ???
  46
  47    Program_Set : Boolean := False;
  48    --  comment required here ???
  49
  50    Std_Prefix : String_Ptr;
  51    --  Standard prefix, computed dynamically the first time Relocate_Path
  52    --  is called, and cached for subsequent calls.
  53
  54    Empty  : aliased String := "";
  55    No_Dir : constant String_Ptr := Empty'Access;
  56    --  Used in Locate_File as a fake directory when Name is already an
  57    --  absolute path.
  58
  59    -------------------------------------
  60    -- Use of Name_Find and Name_Enter --
  61    -------------------------------------
  62
  63    --  This package creates a number of source, ALI and object file names
  64    --  that are used to locate the actual file and for the purpose of message
  65    --  construction. These names need not be accessible by Name_Find, and can
  66    --  be therefore created by using routine Name_Enter. The files in question
  67    --  are file names with a prefix directory (ie the files not in the current
  68    --  directory). File names without a prefix directory are entered with
  69    --  Name_Find because special values might be attached to the various Info
  70    --  fields of the corresponding name table entry.
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    function Append_Suffix_To_File_Name
  77      (Name   : File_Name_Type;
  78       Suffix : String) return File_Name_Type;
  79    --  Appends Suffix to Name and returns the new name
  80
  81    function OS_Time_To_GNAT_Time (T : OS_Time) return Time_Stamp_Type;
  82    --  Convert OS format time to GNAT format time stamp
  83
  84    function Executable_Prefix return String_Ptr;
  85    --  Returns the name of the root directory where the executable is stored.
  86    --  The executable must be located in a directory called "bin", or under
  87    --  root/lib/gcc-lib/..., or under root/libexec/gcc/... For example, if
  88    --  executable is stored in directory "/foo/bar/bin", this routine returns
  89    --  "/foo/bar/". Return "" if location is not recognized as described above.
  90
  91    function Update_Path (Path : String_Ptr) return String_Ptr;
  92    --  Update the specified path to replace the prefix with the location
  93    --  where GNAT is installed. See the file prefix.c in GCC for details.
  94
  95    function Locate_File
  96      (N    : File_Name_Type;
  97       T    : File_Type;
  98       Dir  : Natural;
  99       Name : String) return File_Name_Type;
 100    --  See if the file N whose name is Name exists in directory Dir. Dir is an
 101    --  index into the Lib_Search_Directories table if T = Library. Otherwise
 102    --  if T = Source, Dir is an index into the Src_Search_Directories table.
 103    --  Returns the File_Name_Type of the full file name if file found, or
 104    --  No_File if not found.
 105
 106    function C_String_Length (S : Address) return Integer;
 107    --  Returns length of a C string (zero for a null address)
 108
 109    function To_Path_String_Access
 110      (Path_Addr : Address;
 111       Path_Len  : Integer) return String_Access;
 112    --  Converts a C String to an Ada String. Are we doing this to avoid withing
 113    --  Interfaces.C.Strings ???
 114
 115    ------------------------------
 116    -- Other Local Declarations --
 117    ------------------------------
 118
 119    EOL : constant Character := ASCII.LF;
 120    --  End of line character
 121
 122    Number_File_Names : Int := 0;
 123    --  Number of file names founde on command line and placed in File_Names
 124
 125    Look_In_Primary_Directory_For_Current_Main : Boolean := False;
 126    --  When this variable is True, Find_File only looks in Primary_Directory
 127    --  for the Current_Main file. This variable is always set to True for the
 128    --  compiler. It is also True for gnatmake, when the soucr name given on
 129    --  the command line has directory information.
 130
 131    Current_Full_Source_Name  : File_Name_Type  := No_File;
 132    Current_Full_Source_Stamp : Time_Stamp_Type := Empty_Time_Stamp;
 133    Current_Full_Lib_Name     : File_Name_Type  := No_File;
 134    Current_Full_Lib_Stamp    : Time_Stamp_Type := Empty_Time_Stamp;
 135    Current_Full_Obj_Name     : File_Name_Type  := No_File;
 136    Current_Full_Obj_Stamp    : Time_Stamp_Type := Empty_Time_Stamp;
 137    --  Respectively full name (with directory info) and time stamp of the
 138    --  latest source, library and object files opened by Read_Source_File and
 139    --  Read_Library_Info.
 140
 141    ------------------
 142    -- Search Paths --
 143    ------------------
 144
 145    Primary_Directory : constant := 0;
 146    --  This is index in the tables created below for the first directory to
 147    --  search in for source or library information files. This is the directory
 148    --  containing the latest main input file (a source file for the compiler or
 149    --  a library file for the binder).
 150
 151    package Src_Search_Directories is new Table.Table (
 152      Table_Component_Type => String_Ptr,
 153      Table_Index_Type     => Integer,
 154      Table_Low_Bound      => Primary_Directory,
 155      Table_Initial        => 10,
 156      Table_Increment      => 100,
 157      Table_Name           => "Osint.Src_Search_Directories");
 158    --  Table of names of directories in which to search for source (Compiler)
 159    --  files. This table is filled in the order in which the directories are
 160    --  to be searched, and then used in that order.
 161
 162    package Lib_Search_Directories is new Table.Table (
 163      Table_Component_Type => String_Ptr,
 164      Table_Index_Type     => Integer,
 165      Table_Low_Bound      => Primary_Directory,
 166      Table_Initial        => 10,
 167      Table_Increment      => 100,
 168      Table_Name           => "Osint.Lib_Search_Directories");
 169    --  Table of names of directories in which to search for library (Binder)
 170    --  files. This table is filled in the order in which the directories are
 171    --  to be searched and then used in that order. The reason for having two
 172    --  distinct tables is that we need them both in gnatmake.
 173
 174    ---------------------
 175    -- File Hash Table --
 176    ---------------------
 177
 178    --  The file hash table is provided to free the programmer from any
 179    --  efficiency concern when retrieving full file names or time stamps of
 180    --  source files. If the programmer calls Source_File_Data (Cache => True)
 181    --  he is guaranteed that the price to retrieve the full name (ie with
 182    --  directory info) or time stamp of the file will be payed only once, the
 183    --  first time the full name is actually searched (or the first time the
 184    --  time stamp is actually retrieved). This is achieved by employing a hash
 185    --  table that stores as a key the File_Name_Type of the file and associates
 186    --  to that File_Name_Type the full file name and time stamp of the file.
 187
 188    File_Cache_Enabled : Boolean := False;
 189    --  Set to true if you want the enable the file data caching mechanism
 190
 191    type File_Hash_Num is range 0 .. 1020;
 192
 193    function File_Hash (F : File_Name_Type) return File_Hash_Num;
 194    --  Compute hash index for use by Simple_HTable
 195
 196    package File_Name_Hash_Table is new GNAT.HTable.Simple_HTable (
 197      Header_Num => File_Hash_Num,
 198      Element    => File_Name_Type,
 199      No_Element => No_File,
 200      Key        => File_Name_Type,
 201      Hash       => File_Hash,
 202      Equal      => "=");
 203
 204    package File_Stamp_Hash_Table is new GNAT.HTable.Simple_HTable (
 205      Header_Num => File_Hash_Num,
 206      Element    => Time_Stamp_Type,
 207      No_Element => Empty_Time_Stamp,
 208      Key        => File_Name_Type,
 209      Hash       => File_Hash,
 210      Equal      => "=");
 211
 212    function Smart_Find_File
 213      (N : File_Name_Type;
 214       T : File_Type) return File_Name_Type;
 215    --  Exactly like Find_File except that if File_Cache_Enabled is True this
 216    --  routine looks first in the hash table to see if the full name of the
 217    --  file is already available.
 218
 219    function Smart_File_Stamp
 220      (N : File_Name_Type;
 221       T : File_Type) return Time_Stamp_Type;
 222    --  Takes the same parameter as the routine above (N is a file name without
 223    --  any prefix directory information) and behaves like File_Stamp except
 224    --  that if File_Cache_Enabled is True this routine looks first in the hash
 225    --  table to see if the file stamp of the file is already available.
 226
 227    -----------------------------
 228    -- Add_Default_Search_Dirs --
 229    -----------------------------
 230
 231    procedure Add_Default_Search_Dirs is
 232       Search_Dir     : String_Access;
 233       Search_Path    : String_Access;
 234       Path_File_Name : String_Access;
 235
 236       procedure Add_Search_Dir
 237         (Search_Dir            : String;
 238          Additional_Source_Dir : Boolean);
 239       procedure Add_Search_Dir
 240         (Search_Dir            : String_Access;
 241          Additional_Source_Dir : Boolean);
 242       --  Add a source search dir or a library search dir, depending on the
 243       --  value of Additional_Source_Dir.
 244
 245       procedure Get_Dirs_From_File (Additional_Source_Dir : Boolean);
 246       --  Open a path file and read the directory to search, one per line
 247
 248       function Get_Libraries_From_Registry return String_Ptr;
 249       --  On Windows systems, get the list of installed standard libraries
 250       --  from the registry key:
 251       --
 252       --  HKEY_LOCAL_MACHINE\SOFTWARE\Ada Core Technologies\
 253       --                             GNAT\Standard Libraries
 254       --  Return an empty string on other systems
 255
 256       --------------------
 257       -- Add_Search_Dir --
 258       --------------------
 259
 260       procedure Add_Search_Dir
 261         (Search_Dir            : String;
 262          Additional_Source_Dir : Boolean)
 263       is
 264       begin
 265          if Additional_Source_Dir then
 266             Add_Src_Search_Dir (Search_Dir);
 267          else
 268             Add_Lib_Search_Dir (Search_Dir);
 269          end if;
 270       end Add_Search_Dir;
 271
 272       procedure Add_Search_Dir
 273         (Search_Dir            : String_Access;
 274          Additional_Source_Dir : Boolean)
 275       is
 276       begin
 277          if Additional_Source_Dir then
 278             Add_Src_Search_Dir (Search_Dir.all);
 279          else
 280             Add_Lib_Search_Dir (Search_Dir.all);
 281          end if;
 282       end Add_Search_Dir;
 283
 284       ------------------------
 285       -- Get_Dirs_From_File --
 286       ------------------------
 287
 288       procedure Get_Dirs_From_File (Additional_Source_Dir : Boolean) is
 289          File_FD    : File_Descriptor;
 290          Buffer     : constant String := Path_File_Name.all & ASCII.NUL;
 291          Len        : Natural;
 292          Actual_Len : Natural;
 293          S          : String_Access;
 294          Curr       : Natural;
 295          First      : Natural;
 296          Ch         : Character;
 297
 298          Status : Boolean;
 299          --  For the call to Close
 300
 301       begin
 302          File_FD := Open_Read (Buffer'Address, Binary);
 303
 304          --  If we cannot open the file, we ignore it, we don't fail
 305
 306          if File_FD = Invalid_FD then
 307             return;
 308          end if;
 309
 310          Len := Integer (File_Length (File_FD));
 311
 312          S := new String (1 .. Len);
 313
 314          --  Read the file. Note that the loop is not necessary since the
 315          --  whole file is read at once except on VMS.
 316
 317          Curr := 1;
 318          Actual_Len := Len;
 319          while Curr <= Len and then Actual_Len /= 0 loop
 320             Actual_Len := Read (File_FD, S (Curr)'Address, Len);
 321             Curr := Curr + Actual_Len;
 322          end loop;
 323
 324          --  We are done with the file, so we close it (ignore any error on
 325          --  the close, since we have successfully read the file).
 326
 327          Close (File_FD, Status);
 328
 329          --  Now, we read line by line
 330
 331          First := 1;
 332          Curr := 0;
 333          while Curr < Len loop
 334             Ch := S (Curr + 1);
 335
 336             if Ch = ASCII.CR or else Ch = ASCII.LF
 337               or else Ch = ASCII.FF or else Ch = ASCII.VT
 338             then
 339                if First <= Curr then
 340                   Add_Search_Dir (S (First .. Curr), Additional_Source_Dir);
 341                end if;
 342
 343                First := Curr + 2;
 344             end if;
 345
 346             Curr := Curr + 1;
 347          end loop;
 348
 349          --  Last line is a special case, if the file does not end with
 350          --  an end of line mark.
 351
 352          if First <= S'Last then
 353             Add_Search_Dir (S (First .. S'Last), Additional_Source_Dir);
 354          end if;
 355       end Get_Dirs_From_File;
 356
 357       ---------------------------------
 358       -- Get_Libraries_From_Registry --
 359       ---------------------------------
 360
 361       function Get_Libraries_From_Registry return String_Ptr is
 362          function C_Get_Libraries_From_Registry return Address;
 363          pragma Import (C, C_Get_Libraries_From_Registry,
 364                         "__gnat_get_libraries_from_registry");
 365
 366          function Strlen (Str : Address) return Integer;
 367          pragma Import (C, Strlen, "strlen");
 368
 369          procedure Strncpy (X : Address; Y : Address; Length : Integer);
 370          pragma Import (C, Strncpy, "strncpy");
 371
 372          Result_Ptr    : Address;
 373          Result_Length : Integer;
 374          Out_String    : String_Ptr;
 375
 376       begin
 377          Result_Ptr := C_Get_Libraries_From_Registry;
 378          Result_Length := Strlen (Result_Ptr);
 379
 380          Out_String := new String (1 .. Result_Length);
 381          Strncpy (Out_String.all'Address, Result_Ptr, Result_Length);
 382          return Out_String;
 383       end Get_Libraries_From_Registry;
 384
 385    --  Start of processing for Add_Default_Search_Dirs
 386
 387    begin
 388       --  After the locations specified on the command line, the next places
 389       --  to look for files are the directories specified by the appropriate
 390       --  environment variable. Get this value, extract the directory names
 391       --  and store in the tables.
 392
 393       --  Check for eventual project path file env vars
 394
 395       Path_File_Name := Getenv (Project_Include_Path_File);
 396
 397       if Path_File_Name'Length > 0 then
 398          Get_Dirs_From_File (Additional_Source_Dir => True);
 399       end if;
 400
 401       Path_File_Name := Getenv (Project_Objects_Path_File);
 402
 403       if Path_File_Name'Length > 0 then
 404          Get_Dirs_From_File (Additional_Source_Dir => False);
 405       end if;
 406
 407       --  On VMS, don't expand the logical name (e.g. environment variable),
 408       --  just put it into Unix (e.g. canonical) format. System services
 409       --  will handle the expansion as part of the file processing.
 410
 411       for Additional_Source_Dir in False .. True loop
 412          if Additional_Source_Dir then
 413             Search_Path := Getenv (Ada_Include_Path);
 414
 415             if Search_Path'Length > 0 then
 416                if Hostparm.OpenVMS then
 417                   Search_Path := To_Canonical_Path_Spec ("ADA_INCLUDE_PATH:");
 418                else
 419                   Search_Path := To_Canonical_Path_Spec (Search_Path.all);
 420                end if;
 421             end if;
 422
 423          else
 424             Search_Path := Getenv (Ada_Objects_Path);
 425
 426             if Search_Path'Length > 0 then
 427                if Hostparm.OpenVMS then
 428                   Search_Path := To_Canonical_Path_Spec ("ADA_OBJECTS_PATH:");
 429                else
 430                   Search_Path := To_Canonical_Path_Spec (Search_Path.all);
 431                end if;
 432             end if;
 433          end if;
 434
 435          Get_Next_Dir_In_Path_Init (Search_Path);
 436          loop
 437             Search_Dir := Get_Next_Dir_In_Path (Search_Path);
 438             exit when Search_Dir = null;
 439             Add_Search_Dir (Search_Dir, Additional_Source_Dir);
 440          end loop;
 441       end loop;
 442
 443       --  For the compiler, if --RTS= was specified, add the runtime
 444       --  directories.
 445
 446       if RTS_Src_Path_Name /= null
 447         and then RTS_Lib_Path_Name /= null
 448       then
 449          Add_Search_Dirs (RTS_Src_Path_Name, Include);
 450          Add_Search_Dirs (RTS_Lib_Path_Name, Objects);
 451
 452       else
 453          if not Opt.No_Stdinc then
 454
 455             --  For WIN32 systems, look for any system libraries defined in
 456             --  the registry. These are added to both source and object
 457             --  directories.
 458
 459             Search_Path := String_Access (Get_Libraries_From_Registry);
 460
 461             Get_Next_Dir_In_Path_Init (Search_Path);
 462             loop
 463                Search_Dir := Get_Next_Dir_In_Path (Search_Path);
 464                exit when Search_Dir = null;
 465                Add_Search_Dir (Search_Dir, False);
 466                Add_Search_Dir (Search_Dir, True);
 467             end loop;
 468
 469             --  The last place to look are the defaults
 470
 471             Search_Path :=
 472               Read_Default_Search_Dirs
 473                 (String_Access (Update_Path (Search_Dir_Prefix)),
 474                  Include_Search_File,
 475                  String_Access (Update_Path (Include_Dir_Default_Name)));
 476
 477             Get_Next_Dir_In_Path_Init (Search_Path);
 478             loop
 479                Search_Dir := Get_Next_Dir_In_Path (Search_Path);
 480                exit when Search_Dir = null;
 481                Add_Search_Dir (Search_Dir, True);
 482             end loop;
 483          end if;
 484
 485          if not Opt.No_Stdlib and not Opt.RTS_Switch then
 486             Search_Path :=
 487               Read_Default_Search_Dirs
 488                 (String_Access (Update_Path (Search_Dir_Prefix)),
 489                  Objects_Search_File,
 490                  String_Access (Update_Path (Object_Dir_Default_Name)));
 491
 492             Get_Next_Dir_In_Path_Init (Search_Path);
 493             loop
 494                Search_Dir := Get_Next_Dir_In_Path (Search_Path);
 495                exit when Search_Dir = null;
 496                Add_Search_Dir (Search_Dir, False);
 497             end loop;
 498          end if;
 499       end if;
 500    end Add_Default_Search_Dirs;
 501
 502    --------------
 503    -- Add_File --
 504    --------------
 505
 506    procedure Add_File (File_Name : String; Index : Int := No_Index) is
 507    begin
 508       Number_File_Names := Number_File_Names + 1;
 509
 510       --  As Add_File may be called for mains specified inside a project file,
 511       --  File_Names may be too short and needs to be extended.
 512
 513       if Number_File_Names > File_Names'Last then
 514          File_Names := new File_Name_Array'(File_Names.all & File_Names.all);
 515          File_Indexes :=
 516            new File_Index_Array'(File_Indexes.all & File_Indexes.all);
 517       end if;
 518
 519       File_Names   (Number_File_Names) := new String'(File_Name);
 520       File_Indexes (Number_File_Names) := Index;
 521    end Add_File;
 522
 523    ------------------------
 524    -- Add_Lib_Search_Dir --
 525    ------------------------
 526
 527    procedure Add_Lib_Search_Dir (Dir : String) is
 528    begin
 529       if Dir'Length = 0 then
 530          Fail ("missing library directory name");
 531       end if;
 532
 533       Lib_Search_Directories.Increment_Last;
 534       Lib_Search_Directories.Table (Lib_Search_Directories.Last) :=
 535         Normalize_Directory_Name (Dir);
 536    end Add_Lib_Search_Dir;
 537
 538    ---------------------
 539    -- Add_Search_Dirs --
 540    ---------------------
 541
 542    procedure Add_Search_Dirs
 543      (Search_Path : String_Ptr;
 544       Path_Type   : Search_File_Type)
 545    is
 546       Current_Search_Path : String_Access;
 547
 548    begin
 549       Get_Next_Dir_In_Path_Init (String_Access (Search_Path));
 550       loop
 551          Current_Search_Path :=
 552            Get_Next_Dir_In_Path (String_Access (Search_Path));
 553          exit when Current_Search_Path = null;
 554
 555          if Path_Type = Include then
 556             Add_Src_Search_Dir (Current_Search_Path.all);
 557          else
 558             Add_Lib_Search_Dir (Current_Search_Path.all);
 559          end if;
 560       end loop;
 561    end Add_Search_Dirs;
 562
 563    ------------------------
 564    -- Add_Src_Search_Dir --
 565    ------------------------
 566
 567    procedure Add_Src_Search_Dir (Dir : String) is
 568    begin
 569       if Dir'Length = 0 then
 570          Fail ("missing source directory name");
 571       end if;
 572
 573       Src_Search_Directories.Increment_Last;
 574       Src_Search_Directories.Table (Src_Search_Directories.Last) :=
 575         Normalize_Directory_Name (Dir);
 576    end Add_Src_Search_Dir;
 577
 578    --------------------------------
 579    -- Append_Suffix_To_File_Name --
 580    --------------------------------
 581
 582    function Append_Suffix_To_File_Name
 583      (Name   : File_Name_Type;
 584       Suffix : String) return File_Name_Type
 585    is
 586    begin
 587       Get_Name_String (Name);
 588       Name_Buffer (Name_Len + 1 .. Name_Len + Suffix'Length) := Suffix;
 589       Name_Len := Name_Len + Suffix'Length;
 590       return Name_Find;
 591    end Append_Suffix_To_File_Name;
 592
 593    ---------------------
 594    -- C_String_Length --
 595    ---------------------
 596
 597    function C_String_Length (S : Address) return Integer is
 598       function Strlen (S : Address) return Integer;
 599       pragma Import (C, Strlen, "strlen");
 600    begin
 601       if S = Null_Address then
 602          return 0;
 603       else
 604          return Strlen (S);
 605       end if;
 606    end C_String_Length;
 607
 608    ------------------------------
 609    -- Canonical_Case_File_Name --
 610    ------------------------------
 611
 612    --  For now, we only deal with the case of a-z. Eventually we should
 613    --  worry about other Latin-1 letters on systems that support this ???
 614
 615    procedure Canonical_Case_File_Name (S : in out String) is
 616    begin
 617       if not File_Names_Case_Sensitive then
 618          for J in S'Range loop
 619             if S (J) in 'A' .. 'Z' then
 620                S (J) := Character'Val (
 621                           Character'Pos (S (J)) +
 622                           Character'Pos ('a')   -
 623                           Character'Pos ('A'));
 624             end if;
 625          end loop;
 626       end if;
 627    end Canonical_Case_File_Name;
 628
 629    ---------------------------
 630    -- Create_File_And_Check --
 631    ---------------------------
 632
 633    procedure Create_File_And_Check
 634      (Fdesc : out File_Descriptor;
 635       Fmode : Mode)
 636    is
 637    begin
 638       Output_File_Name := Name_Enter;
 639       Fdesc := Create_File (Name_Buffer'Address, Fmode);
 640
 641       if Fdesc = Invalid_FD then
 642          Fail ("Cannot create: ", Name_Buffer (1 .. Name_Len));
 643       end if;
 644    end Create_File_And_Check;
 645
 646    ------------------------
 647    -- Current_File_Index --
 648    ------------------------
 649
 650    function Current_File_Index return Int is
 651    begin
 652       return File_Indexes (Current_File_Name_Index);
 653    end Current_File_Index;
 654
 655    --------------------------------
 656    -- Current_Library_File_Stamp --
 657    --------------------------------
 658
 659    function Current_Library_File_Stamp return Time_Stamp_Type is
 660    begin
 661       return Current_Full_Lib_Stamp;
 662    end Current_Library_File_Stamp;
 663
 664    -------------------------------
 665    -- Current_Object_File_Stamp --
 666    -------------------------------
 667
 668    function Current_Object_File_Stamp return Time_Stamp_Type is
 669    begin
 670       return Current_Full_Obj_Stamp;
 671    end Current_Object_File_Stamp;
 672
 673    -------------------------------
 674    -- Current_Source_File_Stamp --
 675    -------------------------------
 676
 677    function Current_Source_File_Stamp return Time_Stamp_Type is
 678    begin
 679       return Current_Full_Source_Stamp;
 680    end Current_Source_File_Stamp;
 681
 682    ----------------------------
 683    -- Dir_In_Obj_Search_Path --
 684    ----------------------------
 685
 686    function Dir_In_Obj_Search_Path (Position : Natural) return String_Ptr is
 687    begin
 688       if Opt.Look_In_Primary_Dir then
 689          return
 690            Lib_Search_Directories.Table (Primary_Directory + Position - 1);
 691       else
 692          return Lib_Search_Directories.Table (Primary_Directory + Position);
 693       end if;
 694    end Dir_In_Obj_Search_Path;
 695
 696    ----------------------------
 697    -- Dir_In_Src_Search_Path --
 698    ----------------------------
 699
 700    function Dir_In_Src_Search_Path (Position : Natural) return String_Ptr is
 701    begin
 702       if Opt.Look_In_Primary_Dir then
 703          return
 704            Src_Search_Directories.Table (Primary_Directory + Position - 1);
 705       else
 706          return Src_Search_Directories.Table (Primary_Directory + Position);
 707       end if;
 708    end Dir_In_Src_Search_Path;
 709
 710    ---------------------
 711    -- Executable_Name --
 712    ---------------------
 713
 714    function Executable_Name (Name : File_Name_Type) return File_Name_Type is
 715       Exec_Suffix : String_Access;
 716
 717    begin
 718       if Name = No_File then
 719          return No_File;
 720       end if;
 721
 722       if Executable_Extension_On_Target = No_Name then
 723          Exec_Suffix := Get_Target_Executable_Suffix;
 724       else
 725          Get_Name_String (Executable_Extension_On_Target);
 726          Exec_Suffix := new String'(Name_Buffer (1 .. Name_Len));
 727       end if;
 728
 729       Get_Name_String (Name);
 730
 731       if Exec_Suffix'Length /= 0 then
 732          declare
 733             Buffer : String := Name_Buffer (1 .. Name_Len);
 734
 735          begin
 736             --  Get the file name in canonical case to accept as is names
 737             --  ending with ".EXE" on VMS and Windows.
 738
 739             Canonical_Case_File_Name (Buffer);
 740
 741             --  If Executable does not end with the executable suffix, add it
 742
 743             if Buffer'Length <= Exec_Suffix'Length
 744               or else
 745                 Buffer (Buffer'Last - Exec_Suffix'Length + 1 .. Buffer'Last)
 746                   /= Exec_Suffix.all
 747             then
 748                Name_Buffer (Name_Len + 1 .. Name_Len + Exec_Suffix'Length) :=
 749                  Exec_Suffix.all;
 750                Name_Len := Name_Len + Exec_Suffix'Length;
 751                Free (Exec_Suffix);
 752                return Name_Find;
 753             end if;
 754          end;
 755       end if;
 756
 757       Free (Exec_Suffix);
 758       return Name;
 759    end Executable_Name;
 760
 761    function Executable_Name (Name : String) return String is
 762       Exec_Suffix    : String_Access;
 763       Canonical_Name : String := Name;
 764
 765    begin
 766       if Executable_Extension_On_Target = No_Name then
 767          Exec_Suffix := Get_Target_Executable_Suffix;
 768       else
 769          Get_Name_String (Executable_Extension_On_Target);
 770          Exec_Suffix := new String'(Name_Buffer (1 .. Name_Len));
 771       end if;
 772
 773       declare
 774          Suffix : constant String := Exec_Suffix.all;
 775
 776       begin
 777          Free (Exec_Suffix);
 778          Canonical_Case_File_Name (Canonical_Name);
 779
 780          if Suffix'Length /= 0
 781            and then
 782              (Canonical_Name'Length <= Suffix'Length
 783                or else Canonical_Name (Canonical_Name'Last - Suffix'Length + 1
 784                                          .. Canonical_Name'Last) /= Suffix)
 785          then
 786             declare
 787                Result : String (1 .. Name'Length + Suffix'Length);
 788             begin
 789                Result (1 .. Name'Length) := Name;
 790                Result (Name'Length + 1 .. Result'Last) := Suffix;
 791                return Result;
 792             end;
 793          else
 794             return Name;
 795          end if;
 796       end;
 797    end Executable_Name;
 798
 799    -----------------------
 800    -- Executable_Prefix --
 801    -----------------------
 802
 803    function Executable_Prefix return String_Ptr is
 804
 805       function Get_Install_Dir (Exec : String) return String_Ptr;
 806       --  S is the executable name preceeded by the absolute or relative
 807       --  path, e.g. "c:\usr\bin\gcc.exe" or "..\bin\gcc".
 808
 809       ---------------------
 810       -- Get_Install_Dir --
 811       ---------------------
 812
 813       function Get_Install_Dir (Exec : String) return String_Ptr is
 814          Full_Path : constant String := Normalize_Pathname (Exec);
 815          --  Use the full path, so that we find "lib" or "bin", even when
 816          --  the tool has been invoked with a relative path, as in
 817          --  "./gnatls -v" invoked in the GNAT bin directory.
 818
 819       begin
 820          for J in reverse Full_Path'Range loop
 821             if Is_Directory_Separator (Full_Path (J)) then
 822                if J < Full_Path'Last - 5 then
 823                   if (To_Lower (Full_Path (J + 1)) = 'l'
 824                       and then To_Lower (Full_Path (J + 2)) = 'i'
 825                       and then To_Lower (Full_Path (J + 3)) = 'b')
 826                     or else
 827                       (To_Lower (Full_Path (J + 1)) = 'b'
 828                        and then To_Lower (Full_Path (J + 2)) = 'i'
 829                        and then To_Lower (Full_Path (J + 3)) = 'n')
 830                   then
 831                      return new String'(Full_Path (Full_Path'First .. J));
 832                   end if;
 833                end if;
 834             end if;
 835          end loop;
 836
 837          return new String'("");
 838       end Get_Install_Dir;
 839
 840    --  Start of processing for Executable_Prefix
 841
 842    begin
 843       if Exec_Name = null then
 844          Exec_Name := new String (1 .. Len_Arg (0));
 845          Osint.Fill_Arg (Exec_Name (1)'Address, 0);
 846       end if;
 847
 848       --  First determine if a path prefix was placed in front of the
 849       --  executable name.
 850
 851       for J in reverse Exec_Name'Range loop
 852          if Is_Directory_Separator (Exec_Name (J)) then
 853             return Get_Install_Dir (Exec_Name.all);
 854          end if;
 855       end loop;
 856
 857       --  If we come here, the user has typed the executable name with no
 858       --  directory prefix.
 859
 860       return Get_Install_Dir (Locate_Exec_On_Path (Exec_Name.all).all);
 861    end Executable_Prefix;
 862
 863    ------------------
 864    -- Exit_Program --
 865    ------------------
 866
 867    procedure Exit_Program (Exit_Code : Exit_Code_Type) is
 868    begin
 869       --  The program will exit with the following status:
 870
 871       --    0 if the object file has been generated (with or without warnings)
 872       --    1 if recompilation was not needed (smart recompilation)
 873       --    2 if gnat1 has been killed by a signal (detected by GCC)
 874       --    4 for a fatal error
 875       --    5 if there were errors
 876       --    6 if no code has been generated (spec)
 877
 878       --  Note that exit code 3 is not used and must not be used as this is
 879       --  the code returned by a program aborted via C abort() routine on
 880       --  Windows. GCC checks for that case and thinks that the child process
 881       --  has been aborted. This code (exit code 3) used to be the code used
 882       --  for E_No_Code, but E_No_Code was changed to 6 for this reason.
 883
 884       case Exit_Code is
 885          when E_Success    => OS_Exit (0);
 886          when E_Warnings   => OS_Exit (0);
 887          when E_No_Compile => OS_Exit (1);
 888          when E_Fatal      => OS_Exit (4);
 889          when E_Errors     => OS_Exit (5);
 890          when E_No_Code    => OS_Exit (6);
 891          when E_Abort      => OS_Abort;
 892       end case;
 893    end Exit_Program;
 894
 895    ----------
 896    -- Fail --
 897    ----------
 898
 899    procedure Fail (S1 : String; S2 : String := ""; S3 : String := "") is
 900    begin
 901       --  We use Output in case there is a special output set up.
 902       --  In this case Set_Standard_Error will have no immediate effect.
 903
 904       Set_Standard_Error;
 905       Osint.Write_Program_Name;
 906       Write_Str (": ");
 907       Write_Str (S1);
 908       Write_Str (S2);
 909       Write_Str (S3);
 910       Write_Eol;
 911
 912       Exit_Program (E_Fatal);
 913    end Fail;
 914
 915    ---------------
 916    -- File_Hash --
 917    ---------------
 918
 919    function File_Hash (F : File_Name_Type) return File_Hash_Num is
 920    begin
 921       return File_Hash_Num (Int (F) rem File_Hash_Num'Range_Length);
 922    end File_Hash;
 923
 924    ----------------
 925    -- File_Stamp --
 926    ----------------
 927
 928    function File_Stamp (Name : File_Name_Type) return Time_Stamp_Type is
 929    begin
 930       if Name = No_File then
 931          return Empty_Time_Stamp;
 932       end if;
 933
 934       Get_Name_String (Name);
 935
 936       if not Is_Regular_File (Name_Buffer (1 .. Name_Len)) then
 937          return Empty_Time_Stamp;
 938       else
 939          Name_Buffer (Name_Len + 1) := ASCII.NUL;
 940          return OS_Time_To_GNAT_Time (File_Time_Stamp (Name_Buffer));
 941       end if;
 942    end File_Stamp;
 943
 944    function File_Stamp (Name : Path_Name_Type) return Time_Stamp_Type is
 945    begin
 946       return File_Stamp (File_Name_Type (Name));
 947    end File_Stamp;
 948
 949    ---------------
 950    -- Find_File --
 951    ---------------
 952
 953    function Find_File
 954      (N : File_Name_Type;
 955       T : File_Type) return File_Name_Type
 956    is
 957    begin
 958       Get_Name_String (N);
 959
 960       declare
 961          File_Name : String renames Name_Buffer (1 .. Name_Len);
 962          File      : File_Name_Type := No_File;
 963          Last_Dir  : Natural;
 964
 965       begin
 966          --  If we are looking for a config file, look only in the current
 967          --  directory, i.e. return input argument unchanged. Also look
 968          --  only in the current directory if we are looking for a .dg
 969          --  file (happens in -gnatD mode).
 970
 971          if T = Config
 972            or else (Debug_Generated_Code
 973                       and then Name_Len > 3
 974                       and then
 975                       (Name_Buffer (Name_Len - 2 .. Name_Len) = ".dg"
 976                        or else
 977                        (Hostparm.OpenVMS and then
 978                         Name_Buffer (Name_Len - 2 .. Name_Len) = "_dg")))
 979          then
 980             return N;
 981
 982          --  If we are trying to find the current main file just look in the
 983          --  directory where the user said it was.
 984
 985          elsif Look_In_Primary_Directory_For_Current_Main
 986            and then Current_Main = N
 987          then
 988             return Locate_File (N, T, Primary_Directory, File_Name);
 989
 990          --  Otherwise do standard search for source file
 991
 992          else
 993             --  Check the mapping of this file name
 994
 995             File := Mapped_Path_Name (N);
 996
 997             --  If the file name is mapped to a path name, return the
 998             --  corresponding path name
 999
1000             if File /= No_File then
1001
1002                --  For locally removed file, Error_Name is returned; then
1003                --  return No_File, indicating the file is not a source.
1004
1005                if File = Error_File_Name then
1006                   return No_File;
1007
1008                else
1009                   return File;
1010                end if;
1011             end if;
1012
1013             --  First place to look is in the primary directory (i.e. the same
1014             --  directory as the source) unless this has been disabled with -I-
1015
1016             if Opt.Look_In_Primary_Dir then
1017                File := Locate_File (N, T, Primary_Directory, File_Name);
1018
1019                if File /= No_File then
1020                   return File;
1021                end if;
1022             end if;
1023
1024             --  Finally look in directories specified with switches -I/-aI/-aO
1025
1026             if T = Library then
1027                Last_Dir := Lib_Search_Directories.Last;
1028             else
1029                Last_Dir := Src_Search_Directories.Last;
1030             end if;
1031
1032             for D in Primary_Directory + 1 .. Last_Dir loop
1033                File := Locate_File (N, T, D, File_Name);
1034
1035                if File /= No_File then
1036                   return File;
1037                end if;
1038             end loop;
1039
1040             return No_File;
1041          end if;
1042       end;
1043    end Find_File;
1044
1045    -----------------------
1046    -- Find_Program_Name --
1047    -----------------------
1048
1049    procedure Find_Program_Name is
1050       Command_Name : String (1 .. Len_Arg (0));
1051       Cindex1      : Integer := Command_Name'First;
1052       Cindex2      : Integer := Command_Name'Last;
1053
1054    begin
1055       Fill_Arg (Command_Name'Address, 0);
1056
1057       if Command_Name = "" then
1058          Name_Len := 0;
1059          return;
1060       end if;
1061
1062       --  The program name might be specified by a full path name. However,
1063       --  we don't want to print that all out in an error message, so the
1064       --  path might need to be stripped away.
1065
1066       for J in reverse Cindex1 .. Cindex2 loop
1067          if Is_Directory_Separator (Command_Name (J)) then
1068             Cindex1 := J + 1;
1069             exit;
1070          end if;
1071       end loop;
1072
1073       --  Command_Name(Cindex1 .. Cindex2) is now the equivalent of the
1074       --  POSIX command "basename argv[0]"
1075
1076       --  Strip off any versioning information such as found on VMS.
1077       --  This would take the form of TOOL.exe followed by a ";" or "."
1078       --  and a sequence of one or more numbers.
1079
1080       if Command_Name (Cindex2) in '0' .. '9' then
1081          for J in reverse Cindex1 .. Cindex2 loop
1082             if Command_Name (J) = '.' or Command_Name (J) = ';' then
1083                Cindex2 := J - 1;
1084                exit;
1085             end if;
1086
1087             exit when Command_Name (J) not in '0' .. '9';
1088          end loop;
1089       end if;
1090
1091       --  Strip off any executable extension (usually nothing or .exe)
1092       --  but formally reported by autoconf in the variable EXEEXT
1093
1094       if Cindex2 - Cindex1 >= 4 then
1095          if To_Lower (Command_Name (Cindex2 - 3)) = '.'
1096             and then To_Lower (Command_Name (Cindex2 - 2)) = 'e'
1097             and then To_Lower (Command_Name (Cindex2 - 1)) = 'x'
1098             and then To_Lower (Command_Name (Cindex2)) = 'e'
1099          then
1100             Cindex2 := Cindex2 - 4;
1101          end if;
1102       end if;
1103
1104       Name_Len := Cindex2 - Cindex1 + 1;
1105       Name_Buffer (1 .. Name_Len) := Command_Name (Cindex1 .. Cindex2);
1106    end Find_Program_Name;
1107
1108    ------------------------
1109    -- Full_Lib_File_Name --
1110    ------------------------
1111
1112    function Full_Lib_File_Name (N : File_Name_Type) return File_Name_Type is
1113    begin
1114       return Find_File (N, Library);
1115    end Full_Lib_File_Name;
1116
1117    ----------------------------
1118    -- Full_Library_Info_Name --
1119    ----------------------------
1120
1121    function Full_Library_Info_Name return File_Name_Type is
1122    begin
1123       return Current_Full_Lib_Name;
1124    end Full_Library_Info_Name;
1125
1126    ---------------------------
1127    -- Full_Object_File_Name --
1128    ---------------------------
1129
1130    function Full_Object_File_Name return File_Name_Type is
1131    begin
1132       return Current_Full_Obj_Name;
1133    end Full_Object_File_Name;
1134
1135    ----------------------
1136    -- Full_Source_Name --
1137    ----------------------
1138
1139    function Full_Source_Name return File_Name_Type is
1140    begin
1141       return Current_Full_Source_Name;
1142    end Full_Source_Name;
1143
1144    ----------------------
1145    -- Full_Source_Name --
1146    ----------------------
1147
1148    function Full_Source_Name (N : File_Name_Type) return File_Name_Type is
1149    begin
1150       return Smart_Find_File (N, Source);
1151    end Full_Source_Name;
1152
1153    -------------------
1154    -- Get_Directory --
1155    -------------------
1156
1157    function Get_Directory (Name : File_Name_Type) return File_Name_Type is
1158    begin
1159       Get_Name_String (Name);
1160
1161       for J in reverse 1 .. Name_Len loop
1162          if Is_Directory_Separator (Name_Buffer (J)) then
1163             Name_Len := J;
1164             return Name_Find;
1165          end if;
1166       end loop;
1167
1168       Name_Len := Hostparm.Normalized_CWD'Length;
1169       Name_Buffer (1 .. Name_Len) := Hostparm.Normalized_CWD;
1170       return Name_Find;
1171    end Get_Directory;
1172
1173    --------------------------
1174    -- Get_Next_Dir_In_Path --
1175    --------------------------
1176
1177    Search_Path_Pos : Integer;
1178    --  Keeps track of current position in search path. Initialized by the
1179    --  call to Get_Next_Dir_In_Path_Init, updated by Get_Next_Dir_In_Path.
1180
1181    function Get_Next_Dir_In_Path
1182      (Search_Path : String_Access) return String_Access
1183    is
1184       Lower_Bound : Positive := Search_Path_Pos;
1185       Upper_Bound : Positive;
1186
1187    begin
1188       loop
1189          while Lower_Bound <= Search_Path'Last
1190            and then Search_Path.all (Lower_Bound) = Path_Separator
1191          loop
1192             Lower_Bound := Lower_Bound + 1;
1193          end loop;
1194
1195          exit when Lower_Bound > Search_Path'Last;
1196
1197          Upper_Bound := Lower_Bound;
1198          while Upper_Bound <= Search_Path'Last
1199            and then Search_Path.all (Upper_Bound) /= Path_Separator
1200          loop
1201             Upper_Bound := Upper_Bound + 1;
1202          end loop;
1203
1204          Search_Path_Pos := Upper_Bound;
1205          return new String'(Search_Path.all (Lower_Bound .. Upper_Bound - 1));
1206       end loop;
1207
1208       return null;
1209    end Get_Next_Dir_In_Path;
1210
1211    -------------------------------
1212    -- Get_Next_Dir_In_Path_Init --
1213    -------------------------------
1214
1215    procedure Get_Next_Dir_In_Path_Init (Search_Path : String_Access) is
1216    begin
1217       Search_Path_Pos := Search_Path'First;
1218    end Get_Next_Dir_In_Path_Init;
1219
1220    --------------------------------------
1221    -- Get_Primary_Src_Search_Directory --
1222    --------------------------------------
1223
1224    function Get_Primary_Src_Search_Directory return String_Ptr is
1225    begin
1226       return Src_Search_Directories.Table (Primary_Directory);
1227    end Get_Primary_Src_Search_Directory;
1228
1229    ------------------------
1230    -- Get_RTS_Search_Dir --
1231    ------------------------
1232
1233    function Get_RTS_Search_Dir
1234      (Search_Dir : String;
1235       File_Type  : Search_File_Type) return String_Ptr
1236    is
1237       procedure Get_Current_Dir
1238         (Dir    : System.Address;
1239          Length : System.Address);
1240       pragma Import (C, Get_Current_Dir, "__gnat_get_current_dir");
1241
1242       Max_Path : Integer;
1243       pragma Import (C, Max_Path, "__gnat_max_path_len");
1244       --  Maximum length of a path name
1245
1246       Current_Dir        : String_Ptr;
1247       Default_Search_Dir : String_Access;
1248       Default_Suffix_Dir : String_Access;
1249       Local_Search_Dir   : String_Access;
1250       Norm_Search_Dir    : String_Access;
1251       Result_Search_Dir  : String_Access;
1252       Search_File        : String_Access;
1253       Temp_String        : String_Ptr;
1254
1255    begin
1256       --  Add a directory separator at the end of the directory if necessary
1257       --  so that we can directly append a file to the directory
1258
1259       if Search_Dir (Search_Dir'Last) /= Directory_Separator then
1260          Local_Search_Dir :=
1261            new String'(Search_Dir & String'(1 => Directory_Separator));
1262       else
1263          Local_Search_Dir := new String'(Search_Dir);
1264       end if;
1265
1266       if File_Type = Include then
1267          Search_File := Include_Search_File;
1268          Default_Suffix_Dir := new String'("adainclude");
1269       else
1270          Search_File := Objects_Search_File;
1271          Default_Suffix_Dir := new String'("adalib");
1272       end if;
1273
1274       Norm_Search_Dir := To_Canonical_Path_Spec (Local_Search_Dir.all);
1275
1276       if Is_Absolute_Path (Norm_Search_Dir.all) then
1277
1278          --  We first verify if there is a directory Include_Search_Dir
1279          --  containing default search directories
1280
1281          Result_Search_Dir :=
1282            Read_Default_Search_Dirs (Norm_Search_Dir, Search_File, null);
1283          Default_Search_Dir :=
1284            new String'(Norm_Search_Dir.all & Default_Suffix_Dir.all);
1285          Free (Norm_Search_Dir);
1286
1287          if Result_Search_Dir /= null then
1288             return String_Ptr (Result_Search_Dir);
1289          elsif Is_Directory (Default_Search_Dir.all) then
1290             return String_Ptr (Default_Search_Dir);
1291          else
1292             return null;
1293          end if;
1294
1295       --  Search in the current directory
1296
1297       else
1298          --  Get the current directory
1299
1300          declare
1301             Buffer   : String (1 .. Max_Path + 2);
1302             Path_Len : Natural := Max_Path;
1303
1304          begin
1305             Get_Current_Dir (Buffer'Address, Path_Len'Address);
1306
1307             if Buffer (Path_Len) /= Directory_Separator then
1308                Path_Len := Path_Len + 1;
1309                Buffer (Path_Len) := Directory_Separator;
1310             end if;
1311
1312             Current_Dir := new String'(Buffer (1 .. Path_Len));
1313          end;
1314
1315          Norm_Search_Dir :=
1316            new String'(Current_Dir.all & Local_Search_Dir.all);
1317
1318          Result_Search_Dir :=
1319            Read_Default_Search_Dirs (Norm_Search_Dir, Search_File, null);
1320
1321          Default_Search_Dir :=
1322            new String'(Norm_Search_Dir.all & Default_Suffix_Dir.all);
1323
1324          Free (Norm_Search_Dir);
1325
1326          if Result_Search_Dir /= null then
1327             return String_Ptr (Result_Search_Dir);
1328
1329          elsif Is_Directory (Default_Search_Dir.all) then
1330             return String_Ptr (Default_Search_Dir);
1331
1332          else
1333             --  Search in Search_Dir_Prefix/Search_Dir
1334
1335             Norm_Search_Dir :=
1336               new String'
1337                (Update_Path (Search_Dir_Prefix).all & Local_Search_Dir.all);
1338
1339             Result_Search_Dir :=
1340               Read_Default_Search_Dirs (Norm_Search_Dir, Search_File, null);
1341
1342             Default_Search_Dir :=
1343               new String'(Norm_Search_Dir.all & Default_Suffix_Dir.all);
1344
1345             Free (Norm_Search_Dir);
1346
1347             if Result_Search_Dir /= null then
1348                return String_Ptr (Result_Search_Dir);
1349
1350             elsif Is_Directory (Default_Search_Dir.all) then
1351                return String_Ptr (Default_Search_Dir);
1352
1353             else
1354                --  We finally search in Search_Dir_Prefix/rts-Search_Dir
1355
1356                Temp_String :=
1357                  new String'(Update_Path (Search_Dir_Prefix).all & "rts-");
1358
1359                Norm_Search_Dir :=
1360                  new String'(Temp_String.all & Local_Search_Dir.all);
1361
1362                Result_Search_Dir :=
1363                  Read_Default_Search_Dirs (Norm_Search_Dir, Search_File, null);
1364
1365                Default_Search_Dir :=
1366                  new String'(Norm_Search_Dir.all & Default_Suffix_Dir.all);
1367                Free (Norm_Search_Dir);
1368
1369                if Result_Search_Dir /= null then
1370                   return String_Ptr (Result_Search_Dir);
1371
1372                elsif Is_Directory (Default_Search_Dir.all) then
1373                   return String_Ptr (Default_Search_Dir);
1374
1375                else
1376                   return null;
1377                end if;
1378             end if;
1379          end if;
1380       end if;
1381    end Get_RTS_Search_Dir;
1382
1383    --------------------------------
1384    -- Include_Dir_Default_Prefix --
1385    --------------------------------
1386
1387    function Include_Dir_Default_Prefix return String is
1388       Include_Dir : String_Access :=
1389                       String_Access (Update_Path (Include_Dir_Default_Name));
1390
1391    begin
1392       if Include_Dir = null then
1393          return "";
1394
1395       else
1396          declare
1397             Result : constant String := Include_Dir.all;
1398          begin
1399             Free (Include_Dir);
1400             return Result;
1401          end;
1402       end if;
1403    end Include_Dir_Default_Prefix;
1404
1405    ----------------
1406    -- Initialize --
1407    ----------------
1408
1409    procedure Initialize is
1410    begin
1411       Number_File_Names       := 0;
1412       Current_File_Name_Index := 0;
1413
1414       Src_Search_Directories.Init;
1415       Lib_Search_Directories.Init;
1416
1417       --  Start off by setting all suppress options to False, these will
1418       --  be reset later (turning some on if -gnato is not specified, and
1419       --  turning all of them on if -gnatp is specified).
1420
1421       Suppress_Options := (others => False);
1422
1423       --  Reserve the first slot in the search paths table. This is the
1424       --  directory of the main source file or main library file and is filled
1425       --  in by each call to Next_Main_Source/Next_Main_Lib_File with the
1426       --  directory specified for this main source or library file. This is the
1427       --  directory which is searched first by default. This default search is
1428       --  inhibited by the option -I- for both source and library files.
1429
1430       Src_Search_Directories.Set_Last (Primary_Directory);
1431       Src_Search_Directories.Table (Primary_Directory) := new String'("");
1432
1433       Lib_Search_Directories.Set_Last (Primary_Directory);
1434       Lib_Search_Directories.Table (Primary_Directory) := new String'("");
1435    end Initialize;
1436
1437    ----------------------------
1438    -- Is_Directory_Separator --
1439    ----------------------------
1440
1441    function Is_Directory_Separator (C : Character) return Boolean is
1442    begin
1443       --  In addition to the default directory_separator allow the '/' to
1444       --  act as separator since this is allowed in MS-DOS, Windows 95/NT,
1445       --  and OS2 ports. On VMS, the situation is more complicated because
1446       --  there are two characters to check for.
1447
1448       return
1449         C = Directory_Separator
1450           or else C = '/'
1451           or else (Hostparm.OpenVMS
1452                     and then (C = ']' or else C = ':'));
1453    end Is_Directory_Separator;
1454
1455    -------------------------
1456    -- Is_Readonly_Library --
1457    -------------------------
1458
1459    function Is_Readonly_Library (File : File_Name_Type) return Boolean is
1460    begin
1461       Get_Name_String (File);
1462
1463       pragma Assert (Name_Buffer (Name_Len - 3 .. Name_Len) = ".ali");
1464
1465       return not Is_Writable_File (Name_Buffer (1 .. Name_Len));
1466    end Is_Readonly_Library;
1467
1468    -------------------
1469    -- Lib_File_Name --
1470    -------------------
1471
1472    function Lib_File_Name
1473      (Source_File : File_Name_Type;
1474       Munit_Index : Nat := 0) return File_Name_Type
1475    is
1476    begin
1477       Get_Name_String (Source_File);
1478
1479       for J in reverse 2 .. Name_Len loop
1480          if Name_Buffer (J) = '.' then
1481             Name_Len := J - 1;
1482             exit;
1483          end if;
1484       end loop;
1485
1486       if Munit_Index /= 0 then
1487          Add_Char_To_Name_Buffer (Multi_Unit_Index_Character);
1488          Add_Nat_To_Name_Buffer (Munit_Index);
1489       end if;
1490
1491       Add_Char_To_Name_Buffer ('.');
1492       Add_Str_To_Name_Buffer (ALI_Suffix.all);
1493       return Name_Find;
1494    end Lib_File_Name;
1495
1496    ------------------------
1497    -- Library_File_Stamp --
1498    ------------------------
1499
1500    function Library_File_Stamp (N : File_Name_Type) return Time_Stamp_Type is
1501    begin
1502       return File_Stamp (Find_File (N, Library));
1503    end Library_File_Stamp;
1504
1505    -----------------
1506    -- Locate_File --
1507    -----------------
1508
1509    function Locate_File
1510      (N    : File_Name_Type;
1511       T    : File_Type;
1512       Dir  : Natural;
1513       Name : String) return File_Name_Type
1514    is
1515       Dir_Name : String_Ptr;
1516
1517    begin
1518       --  If Name is already an absolute path, do not look for a directory
1519
1520       if Is_Absolute_Path (Name) then
1521          Dir_Name := No_Dir;
1522
1523       elsif T = Library then
1524          Dir_Name := Lib_Search_Directories.Table (Dir);
1525
1526       else pragma Assert (T /= Config);
1527          Dir_Name := Src_Search_Directories.Table (Dir);
1528       end if;
1529
1530       declare
1531          Full_Name : String (1 .. Dir_Name'Length + Name'Length);
1532
1533       begin
1534          Full_Name (1 .. Dir_Name'Length) := Dir_Name.all;
1535          Full_Name (Dir_Name'Length + 1 .. Full_Name'Length) := Name;
1536
1537          if not Is_Regular_File (Full_Name) then
1538             return No_File;
1539
1540          else
1541             --  If the file is in the current directory then return N itself
1542
1543             if Dir_Name'Length = 0 then
1544                return N;
1545             else
1546                Name_Len := Full_Name'Length;
1547                Name_Buffer (1 .. Name_Len) := Full_Name;
1548                return Name_Enter;
1549             end if;
1550          end if;
1551       end;
1552    end Locate_File;
1553
1554    -------------------------------
1555    -- Matching_Full_Source_Name --
1556    -------------------------------
1557
1558    function Matching_Full_Source_Name
1559      (N : File_Name_Type;
1560       T : Time_Stamp_Type) return File_Name_Type
1561    is
1562    begin
1563       Get_Name_String (N);
1564
1565       declare
1566          File_Name : constant String := Name_Buffer (1 .. Name_Len);
1567          File      : File_Name_Type := No_File;
1568          Last_Dir  : Natural;
1569
1570       begin
1571          if Opt.Look_In_Primary_Dir then
1572             File := Locate_File (N, Source, Primary_Directory, File_Name);
1573
1574             if File /= No_File and then T = File_Stamp (N) then
1575                return File;
1576             end if;
1577          end if;
1578
1579          Last_Dir := Src_Search_Directories.Last;
1580
1581          for D in Primary_Directory + 1 .. Last_Dir loop
1582             File := Locate_File (N, Source, D, File_Name);
1583
1584             if File /= No_File and then T = File_Stamp (File) then
1585                return File;
1586             end if;
1587          end loop;
1588
1589          return No_File;
1590       end;
1591    end Matching_Full_Source_Name;
1592
1593    ----------------
1594    -- More_Files --
1595    ----------------
1596
1597    function More_Files return Boolean is
1598    begin
1599       return (Current_File_Name_Index < Number_File_Names);
1600    end More_Files;
1601
1602    -------------------------------
1603    -- Nb_Dir_In_Obj_Search_Path --
1604    -------------------------------
1605
1606    function Nb_Dir_In_Obj_Search_Path return Natural is
1607    begin
1608       if Opt.Look_In_Primary_Dir then
1609          return Lib_Search_Directories.Last -  Primary_Directory + 1;
1610       else
1611          return Lib_Search_Directories.Last -  Primary_Directory;
1612       end if;
1613    end Nb_Dir_In_Obj_Search_Path;
1614
1615    -------------------------------
1616    -- Nb_Dir_In_Src_Search_Path --
1617    -------------------------------
1618
1619    function Nb_Dir_In_Src_Search_Path return Natural is
1620    begin
1621       if Opt.Look_In_Primary_Dir then
1622          return Src_Search_Directories.Last -  Primary_Directory + 1;
1623       else
1624          return Src_Search_Directories.Last -  Primary_Directory;
1625       end if;
1626    end Nb_Dir_In_Src_Search_Path;
1627
1628    --------------------
1629    -- Next_Main_File --
1630    --------------------
1631
1632    function Next_Main_File return File_Name_Type is
1633       File_Name : String_Ptr;
1634       Dir_Name  : String_Ptr;
1635       Fptr      : Natural;
1636
1637    begin
1638       pragma Assert (More_Files);
1639
1640       Current_File_Name_Index := Current_File_Name_Index + 1;
1641
1642       --  Get the file and directory name
1643
1644       File_Name := File_Names (Current_File_Name_Index);
1645       Fptr := File_Name'First;
1646
1647       for J in reverse File_Name'Range loop
1648          if File_Name (J) = Directory_Separator
1649            or else File_Name (J) = '/'
1650          then
1651             if J = File_Name'Last then
1652                Fail ("File name missing");
1653             end if;
1654
1655             Fptr := J + 1;
1656             exit;
1657          end if;
1658       end loop;
1659
1660       --  Save name of directory in which main unit resides for use in
1661       --  locating other units
1662
1663       Dir_Name := new String'(File_Name (File_Name'First .. Fptr - 1));
1664
1665       case Running_Program is
1666
1667          when Compiler =>
1668             Src_Search_Directories.Table (Primary_Directory) := Dir_Name;
1669             Look_In_Primary_Directory_For_Current_Main := True;
1670
1671          when Make =>
1672             Src_Search_Directories.Table (Primary_Directory) := Dir_Name;
1673
1674             if Fptr > File_Name'First then
1675                Look_In_Primary_Directory_For_Current_Main := True;
1676             end if;
1677
1678          when Binder | Gnatls =>
1679             Dir_Name := Normalize_Directory_Name (Dir_Name.all);
1680             Lib_Search_Directories.Table (Primary_Directory) := Dir_Name;
1681
1682          when Unspecified =>
1683             null;
1684       end case;
1685
1686       Name_Len := File_Name'Last - Fptr + 1;
1687       Name_Buffer (1 .. Name_Len) := File_Name (Fptr .. File_Name'Last);
1688       Canonical_Case_File_Name (Name_Buffer (1 .. Name_Len));
1689       Current_Main := Name_Find;
1690
1691       --  In the gnatmake case, the main file may have not have the
1692       --  extension. Try ".adb" first then ".ads"
1693
1694       if Running_Program = Make then
1695          declare
1696             Orig_Main : constant File_Name_Type := Current_Main;
1697
1698          begin
1699             if Strip_Suffix (Orig_Main) = Orig_Main then
1700                Current_Main :=
1701                  Append_Suffix_To_File_Name (Orig_Main, ".adb");
1702
1703                if Full_Source_Name (Current_Main) = No_File then
1704                   Current_Main :=
1705                     Append_Suffix_To_File_Name (Orig_Main, ".ads");
1706
1707                   if Full_Source_Name (Current_Main) = No_File then
1708                      Current_Main := Orig_Main;
1709                   end if;
1710                end if;
1711             end if;
1712          end;
1713       end if;
1714
1715       return Current_Main;
1716    end Next_Main_File;
1717
1718    ------------------------------
1719    -- Normalize_Directory_Name --
1720    ------------------------------
1721
1722    function Normalize_Directory_Name (Directory : String) return String_Ptr is
1723
1724       function Is_Quoted (Path : String) return Boolean;
1725       pragma Inline (Is_Quoted);
1726       --  Returns true if Path is quoted (either double or single quotes)
1727
1728       ---------------
1729       -- Is_Quoted --
1730       ---------------
1731
1732       function Is_Quoted (Path : String) return Boolean is
1733          First : constant Character := Path (Path'First);
1734          Last  : constant Character := Path (Path'Last);
1735
1736       begin
1737          if (First = ''' and then Last = ''')
1738                or else
1739             (First = '"' and then Last = '"')
1740          then
1741             return True;
1742          else
1743             return False;
1744          end if;
1745       end Is_Quoted;
1746
1747       Result : String_Ptr;
1748
1749    --  Start of processing for Normalize_Directory_Name
1750
1751    begin
1752       if Directory'Length = 0 then
1753          Result := new String'(Hostparm.Normalized_CWD);
1754
1755       elsif Is_Directory_Separator (Directory (Directory'Last)) then
1756          Result := new String'(Directory);
1757
1758       elsif Is_Quoted (Directory) then
1759
1760          --  This is a quoted string, it certainly means that the directory
1761          --  contains some spaces for example. We can safely remove the quotes
1762          --  here as the OS_Lib.Normalize_Arguments will be called before any
1763          --  spawn routines. This ensure that quotes will be added when needed.
1764
1765          Result := new String (1 .. Directory'Length - 1);
1766          Result (1 .. Directory'Length - 2) :=
1767            Directory (Directory'First + 1 .. Directory'Last - 1);
1768          Result (Result'Last) := Directory_Separator;
1769
1770       else
1771          Result := new String (1 .. Directory'Length + 1);
1772          Result (1 .. Directory'Length) := Directory;
1773          Result (Directory'Length + 1) := Directory_Separator;
1774       end if;
1775
1776       return Result;
1777    end Normalize_Directory_Name;
1778
1779    ---------------------
1780    -- Number_Of_Files --
1781    ---------------------
1782
1783    function Number_Of_Files return Int is
1784    begin
1785       return Number_File_Names;
1786    end Number_Of_Files;
1787
1788    -------------------------------
1789    -- Object_Dir_Default_Prefix --
1790    -------------------------------
1791
1792    function Object_Dir_Default_Prefix return String is
1793       Object_Dir : String_Access :=
1794                      String_Access (Update_Path (Object_Dir_Default_Name));
1795
1796    begin
1797       if Object_Dir = null then
1798          return "";
1799
1800       else
1801          declare
1802             Result : constant String := Object_Dir.all;
1803          begin
1804             Free (Object_Dir);
1805             return Result;
1806          end;
1807       end if;
1808    end Object_Dir_Default_Prefix;
1809
1810    ----------------------
1811    -- Object_File_Name --
1812    ----------------------
1813
1814    function Object_File_Name (N : File_Name_Type) return File_Name_Type is
1815    begin
1816       if N = No_File then
1817          return No_File;
1818       end if;
1819
1820       Get_Name_String (N);
1821       Name_Len := Name_Len - ALI_Suffix'Length - 1;
1822
1823       for J in Target_Object_Suffix'Range loop
1824          Name_Len := Name_Len + 1;
1825          Name_Buffer (Name_Len) := Target_Object_Suffix (J);
1826       end loop;
1827
1828       return Name_Enter;
1829    end Object_File_Name;
1830
1831    -------------------------------
1832    -- OS_Exit_Through_Exception --
1833    -------------------------------
1834
1835    procedure OS_Exit_Through_Exception (Status : Integer) is
1836    begin
1837       Current_Exit_Status := Status;
1838       raise Types.Terminate_Program;
1839    end OS_Exit_Through_Exception;
1840
1841    --------------------------
1842    -- OS_Time_To_GNAT_Time --
1843    --------------------------
1844
1845    function OS_Time_To_GNAT_Time (T : OS_Time) return Time_Stamp_Type is
1846       GNAT_Time : Time_Stamp_Type;
1847
1848       Y  : Year_Type;
1849       Mo : Month_Type;
1850       D  : Day_Type;
1851       H  : Hour_Type;
1852       Mn : Minute_Type;
1853       S  : Second_Type;
1854
1855    begin
1856       GM_Split (T, Y, Mo, D, H, Mn, S);
1857       Make_Time_Stamp
1858         (Year    => Nat (Y),
1859          Month   => Nat (Mo),
1860          Day     => Nat (D),
1861          Hour    => Nat (H),
1862          Minutes => Nat (Mn),
1863          Seconds => Nat (S),
1864          TS      => GNAT_Time);
1865
1866       return GNAT_Time;
1867    end OS_Time_To_GNAT_Time;
1868
1869    ------------------
1870    -- Program_Name --
1871    ------------------
1872
1873    function Program_Name (Nam : String) return String_Access is
1874       Res : String_Access;
1875
1876    begin
1877       --  Get the name of the current program being executed
1878
1879       Find_Program_Name;
1880
1881       --  Find the target prefix if any, for the cross compilation case.
1882       --  For instance in "alpha-dec-vxworks-gcc" the target prefix is
1883       --  "alpha-dec-vxworks-"
1884
1885       while Name_Len > 0  loop
1886
1887          --  All done if we find the last hyphen
1888
1889          if Name_Buffer (Name_Len) = '-' then
1890             exit;
1891
1892          --  If directory separator found, we don't want to look further
1893          --  since in this case, no prefix has been found.
1894
1895          elsif Is_Directory_Separator (Name_Buffer (Name_Len)) then
1896             Name_Len := 0;
1897             exit;
1898          end if;
1899
1900          Name_Len := Name_Len - 1;
1901       end loop;
1902
1903       --  Create the new program name
1904
1905       Res := new String (1 .. Name_Len + Nam'Length);
1906       Res.all (1 .. Name_Len) := Name_Buffer (1 .. Name_Len);
1907       Res.all (Name_Len + 1 .. Name_Len + Nam'Length) := Nam;
1908       return Res;
1909    end Program_Name;
1910
1911    ------------------------------
1912    -- Read_Default_Search_Dirs --
1913    ------------------------------
1914
1915    function Read_Default_Search_Dirs
1916      (Search_Dir_Prefix       : String_Access;
1917       Search_File             : String_Access;
1918       Search_Dir_Default_Name : String_Access) return String_Access
1919    is
1920       Prefix_Len : constant Integer := Search_Dir_Prefix.all'Length;
1921       Buffer     : String (1 .. Prefix_Len + Search_File.all'Length + 1);
1922       File_FD    : File_Descriptor;
1923       S, S1      : String_Access;
1924       Len        : Integer;
1925       Curr       : Integer;
1926       Actual_Len : Integer;
1927       J1         : Integer;
1928
1929       Prev_Was_Separator : Boolean;
1930       Nb_Relative_Dir    : Integer;
1931
1932       function Is_Relative (S : String; K : Positive) return Boolean;
1933       pragma Inline (Is_Relative);
1934       --  Returns True if a relative directory specification is found
1935       --  in S at position K, False otherwise.
1936
1937       -----------------
1938       -- Is_Relative --
1939       -----------------
1940
1941       function Is_Relative (S : String; K : Positive) return Boolean is
1942       begin
1943          return not Is_Absolute_Path (S (K .. S'Last));
1944       end Is_Relative;
1945
1946    --  Start of processing for Read_Default_Search_Dirs
1947
1948    begin
1949       --  Construct a C compatible character string buffer
1950
1951       Buffer (1 .. Search_Dir_Prefix.all'Length)
1952         := Search_Dir_Prefix.all;
1953       Buffer (Search_Dir_Prefix.all'Length + 1 .. Buffer'Last - 1)
1954         := Search_File.all;
1955       Buffer (Buffer'Last) := ASCII.NUL;
1956
1957       File_FD := Open_Read (Buffer'Address, Binary);
1958       if File_FD = Invalid_FD then
1959          return Search_Dir_Default_Name;
1960       end if;
1961
1962       Len := Integer (File_Length (File_FD));
1963
1964       --  An extra character for a trailing Path_Separator is allocated
1965
1966       S := new String (1 .. Len + 1);
1967       S (Len + 1) := Path_Separator;
1968
1969       --  Read the file. Note that the loop is not necessary since the
1970       --  whole file is read at once except on VMS.
1971
1972       Curr := 1;
1973       Actual_Len := Len;
1974       while Actual_Len /= 0 loop
1975          Actual_Len := Read (File_FD, S (Curr)'Address, Len);
1976          Curr := Curr + Actual_Len;
1977       end loop;
1978
1979       --  Process the file, translating line and file ending
1980       --  control characters to a path separator character.
1981
1982       Prev_Was_Separator := True;
1983       Nb_Relative_Dir := 0;
1984       for J in 1 .. Len loop
1985          if S (J) in ASCII.NUL .. ASCII.US or else S (J) = ' ' then
1986             S (J) := Path_Separator;
1987          end if;
1988
1989          if S (J) = Path_Separator then
1990             Prev_Was_Separator := True;
1991
1992          else
1993             if Prev_Was_Separator and then Is_Relative (S.all, J) then
1994                Nb_Relative_Dir := Nb_Relative_Dir + 1;
1995             end if;
1996
1997             Prev_Was_Separator := False;
1998          end if;
1999       end loop;
2000
2001       if Nb_Relative_Dir = 0 then
2002          return S;
2003       end if;
2004
2005       --  Add the Search_Dir_Prefix to all relative paths
2006
2007       S1 := new String (1 .. S'Length + Nb_Relative_Dir * Prefix_Len);
2008       J1 := 1;
2009       Prev_Was_Separator := True;
2010       for J in 1 .. Len + 1 loop
2011          if S (J) = Path_Separator then
2012             Prev_Was_Separator := True;
2013
2014          else
2015             if Prev_Was_Separator and then Is_Relative (S.all, J) then
2016                S1 (J1 .. J1 + Prefix_Len - 1) := Search_Dir_Prefix.all;
2017                J1 := J1 + Prefix_Len;
2018             end if;
2019
2020             Prev_Was_Separator := False;
2021          end if;
2022          S1 (J1) := S (J);
2023          J1 := J1 + 1;
2024       end loop;
2025
2026       Free (S);
2027       return S1;
2028    end Read_Default_Search_Dirs;
2029
2030    -----------------------
2031    -- Read_Library_Info --
2032    -----------------------
2033
2034    function Read_Library_Info
2035      (Lib_File  : File_Name_Type;
2036       Fatal_Err : Boolean := False) return Text_Buffer_Ptr
2037    is
2038       Lib_FD : File_Descriptor;
2039       --  The file descriptor for the current library file. A negative value
2040       --  indicates failure to open the specified source file.
2041
2042       Text : Text_Buffer_Ptr;
2043       --  Allocated text buffer
2044
2045       Status : Boolean;
2046       --  For the calls to Close
2047
2048    begin
2049       Current_Full_Lib_Name := Find_File (Lib_File, Library);
2050       Current_Full_Obj_Name := Object_File_Name (Current_Full_Lib_Name);
2051
2052       if Current_Full_Lib_Name = No_File then
2053          if Fatal_Err then
2054             Fail ("Cannot find: ", Name_Buffer (1 .. Name_Len));
2055          else
2056             Current_Full_Obj_Stamp := Empty_Time_Stamp;
2057             return null;
2058          end if;
2059       end if;
2060
2061       Get_Name_String (Current_Full_Lib_Name);
2062       Name_Buffer (Name_Len + 1) := ASCII.NUL;
2063
2064       --  Open the library FD, note that we open in binary mode, because as
2065       --  documented in the spec, the caller is expected to handle either
2066       --  DOS or Unix mode files, and there is no point in wasting time on
2067       --  text translation when it is not required.
2068
2069       Lib_FD := Open_Read (Name_Buffer'Address, Binary);
2070
2071       if Lib_FD = Invalid_FD then
2072          if Fatal_Err then
2073             Fail ("Cannot open: ",  Name_Buffer (1 .. Name_Len));
2074          else
2075             Current_Full_Obj_Stamp := Empty_Time_Stamp;
2076             return null;
2077          end if;
2078       end if;
2079
2080       --  Check for object file consistency if requested
2081
2082       if Opt.Check_Object_Consistency then
2083          Current_Full_Lib_Stamp := File_Stamp (Current_Full_Lib_Name);
2084          Current_Full_Obj_Stamp := File_Stamp (Current_Full_Obj_Name);
2085
2086          if Current_Full_Obj_Stamp (1) = ' ' then
2087
2088             --  When the library is readonly always assume object is consistent
2089
2090             if Is_Readonly_Library (Current_Full_Lib_Name) then
2091                Current_Full_Obj_Stamp := Current_Full_Lib_Stamp;
2092
2093             elsif Fatal_Err then
2094                Get_Name_String (Current_Full_Obj_Name);
2095                Close (Lib_FD, Status);
2096
2097                --  No need to check the status, we fail anyway
2098
2099                Fail ("Cannot find: ", Name_Buffer (1 .. Name_Len));
2100
2101             else
2102                Current_Full_Obj_Stamp := Empty_Time_Stamp;
2103                Close (Lib_FD, Status);
2104
2105                --  No need to check the status, we return null anyway
2106
2107                return null;
2108             end if;
2109          end if;
2110       end if;
2111
2112       --  Read data from the file
2113
2114       declare
2115          Len : constant Integer := Integer (File_Length (Lib_FD));
2116          --  Length of source file text. If it doesn't fit in an integer
2117          --  we're probably stuck anyway (>2 gigs of source seems a lot!)
2118
2119          Actual_Len : Integer := 0;
2120
2121          Lo : constant Text_Ptr := 0;
2122          --  Low bound for allocated text buffer
2123
2124          Hi : Text_Ptr := Text_Ptr (Len);
2125          --  High bound for allocated text buffer. Note length is Len + 1
2126          --  which allows for extra EOF character at the end of the buffer.
2127
2128       begin
2129          --  Allocate text buffer. Note extra character at end for EOF
2130
2131          Text := new Text_Buffer (Lo .. Hi);
2132
2133          --  Some systems (e.g. VMS) have file types that require one
2134          --  read per line, so read until we get the Len bytes or until
2135          --  there are no more characters.
2136
2137          Hi := Lo;
2138          loop
2139             Actual_Len := Read (Lib_FD, Text (Hi)'Address, Len);
2140             Hi := Hi + Text_Ptr (Actual_Len);
2141             exit when Actual_Len = Len or Actual_Len <= 0;
2142          end loop;
2143
2144          Text (Hi) := EOF;
2145       end;
2146
2147       --  Read is complete, close file and we are done
2148
2149       Close (Lib_FD, Status);
2150       --  The status should never be False. But, if it is, what can we do?
2151       --  So, we don't test it.
2152
2153       return Text;
2154
2155    end Read_Library_Info;
2156
2157    ----------------------
2158    -- Read_Source_File --
2159    ----------------------
2160
2161    procedure Read_Source_File
2162      (N   : File_Name_Type;
2163       Lo  : Source_Ptr;
2164       Hi  : out Source_Ptr;
2165       Src : out Source_Buffer_Ptr;
2166       T   : File_Type := Source)
2167    is
2168       Source_File_FD : File_Descriptor;
2169       --  The file descriptor for the current source file. A negative value
2170       --  indicates failure to open the specified source file.
2171
2172       Len : Integer;
2173       --  Length of file. Assume no more than 2 gigabytes of source!
2174
2175       Actual_Len : Integer;
2176
2177       Status : Boolean;
2178       --  For the call to Close
2179
2180    begin
2181       Current_Full_Source_Name  := Find_File (N, T);
2182       Current_Full_Source_Stamp := File_Stamp (Current_Full_Source_Name);
2183
2184       if Current_Full_Source_Name = No_File then
2185
2186          --  If we were trying to access the main file and we could not find
2187          --  it, we have an error.
2188
2189          if N = Current_Main then
2190             Get_Name_String (N);
2191             Fail ("Cannot find: ", Name_Buffer (1 .. Name_Len));
2192          end if;
2193
2194          Src := null;
2195          Hi  := No_Location;
2196          return;
2197       end if;
2198
2199       Get_Name_String (Current_Full_Source_Name);
2200       Name_Buffer (Name_Len + 1) := ASCII.NUL;
2201
2202       --  Open the source FD, note that we open in binary mode, because as
2203       --  documented in the spec, the caller is expected to handle either
2204       --  DOS or Unix mode files, and there is no point in wasting time on
2205       --  text translation when it is not required.
2206
2207       Source_File_FD := Open_Read (Name_Buffer'Address, Binary);
2208
2209       if Source_File_FD = Invalid_FD then
2210          Src := null;
2211          Hi  := No_Location;
2212          return;
2213       end if;
2214
2215       --  Prepare to read data from the file
2216
2217       Len := Integer (File_Length (Source_File_FD));
2218
2219       --  Set Hi so that length is one more than the physical length,
2220       --  allowing for the extra EOF character at the end of the buffer
2221
2222       Hi := Lo + Source_Ptr (Len);
2223
2224       --  Do the actual read operation
2225
2226       declare
2227          subtype Actual_Source_Buffer is Source_Buffer (Lo .. Hi);
2228          --  Physical buffer allocated
2229
2230          type Actual_Source_Ptr is access Actual_Source_Buffer;
2231          --  This is the pointer type for the physical buffer allocated
2232
2233          Actual_Ptr : constant Actual_Source_Ptr := new Actual_Source_Buffer;
2234          --  And this is the actual physical buffer
2235
2236       begin
2237          --  Allocate source buffer, allowing extra character at end for EOF
2238
2239          --  Some systems (e.g. VMS) have file types that require one
2240          --  read per line, so read until we get the Len bytes or until
2241          --  there are no more characters.
2242
2243          Hi := Lo;
2244          loop
2245             Actual_Len := Read (Source_File_FD, Actual_Ptr (Hi)'Address, Len);
2246             Hi := Hi + Source_Ptr (Actual_Len);
2247             exit when Actual_Len = Len or Actual_Len <= 0;
2248          end loop;
2249
2250          Actual_Ptr (Hi) := EOF;
2251
2252          --  Now we need to work out the proper virtual origin pointer to
2253          --  return. This is exactly Actual_Ptr (0)'Address, but we have
2254          --  to be careful to suppress checks to compute this address.
2255
2256          declare
2257             pragma Suppress (All_Checks);
2258
2259             pragma Warnings (Off);
2260             --  This use of unchecked conversion is aliasing safe
2261
2262             function To_Source_Buffer_Ptr is new
2263               Unchecked_Conversion (Address, Source_Buffer_Ptr);
2264
2265             pragma Warnings (On);
2266
2267          begin
2268             Src := To_Source_Buffer_Ptr (Actual_Ptr (0)'Address);
2269          end;
2270       end;
2271
2272       --  Read is complete, get time stamp and close file and we are done
2273
2274       Close (Source_File_FD, Status);
2275
2276       --  The status should never be False. But, if it is, what can we do?
2277       --  So, we don't test it.
2278
2279    end Read_Source_File;
2280
2281    -------------------
2282    -- Relocate_Path --
2283    -------------------
2284
2285    function Relocate_Path
2286      (Prefix : String;
2287       Path   : String) return String_Ptr
2288    is
2289       S : String_Ptr;
2290
2291       procedure set_std_prefix (S : String; Len : Integer);
2292       pragma Import (C, set_std_prefix);
2293
2294    begin
2295       if Std_Prefix = null then
2296          Std_Prefix := Executable_Prefix;
2297
2298          if Std_Prefix.all /= "" then
2299
2300             --  Remove trailing directory separator when calling set_std_prefix
2301
2302             set_std_prefix (Std_Prefix.all, Std_Prefix'Length - 1);
2303          end if;
2304       end if;
2305
2306       if Path (Prefix'Range) = Prefix then
2307          if Std_Prefix.all /= "" then
2308             S := new String
2309               (1 .. Std_Prefix'Length + Path'Last - Prefix'Last);
2310             S (1 .. Std_Prefix'Length) := Std_Prefix.all;
2311             S (Std_Prefix'Length + 1 .. S'Last) :=
2312               Path (Prefix'Last + 1 .. Path'Last);
2313             return S;
2314          end if;
2315       end if;
2316
2317       return new String'(Path);
2318    end Relocate_Path;
2319
2320    -----------------
2321    -- Set_Program --
2322    -----------------
2323
2324    procedure Set_Program (P : Program_Type) is
2325    begin
2326       if Program_Set then
2327          Fail ("Set_Program called twice");
2328       end if;
2329
2330       Program_Set := True;
2331       Running_Program := P;
2332    end Set_Program;
2333
2334    ----------------
2335    -- Shared_Lib --
2336    ----------------
2337
2338    function Shared_Lib (Name : String) return String is
2339       Library : String (1 .. Name'Length + Library_Version'Length + 3);
2340       --  3 = 2 for "-l" + 1 for "-" before lib version
2341
2342    begin
2343       Library (1 .. 2)                          := "-l";
2344       Library (3 .. 2 + Name'Length)            := Name;
2345       Library (3 + Name'Length)                 := '-';
2346       Library (4 + Name'Length .. Library'Last) := Library_Version;
2347
2348       if OpenVMS_On_Target then
2349          for K in Library'First + 2 .. Library'Last loop
2350             if Library (K) = '.' or else Library (K) = '-' then
2351                Library (K) := '_';
2352             end if;
2353          end loop;
2354       end if;
2355
2356       return Library;
2357    end Shared_Lib;
2358
2359    ----------------------
2360    -- Smart_File_Stamp --
2361    ----------------------
2362
2363    function Smart_File_Stamp
2364      (N : File_Name_Type;
2365       T : File_Type) return Time_Stamp_Type
2366    is
2367       Time_Stamp : Time_Stamp_Type;
2368
2369    begin
2370       if not File_Cache_Enabled then
2371          return File_Stamp (Find_File (N, T));
2372       end if;
2373
2374       Time_Stamp := File_Stamp_Hash_Table.Get (N);
2375
2376       if Time_Stamp (1) = ' ' then
2377          Time_Stamp := File_Stamp (Smart_Find_File (N, T));
2378          File_Stamp_Hash_Table.Set (N, Time_Stamp);
2379       end if;
2380
2381       return Time_Stamp;
2382    end Smart_File_Stamp;
2383
2384    ---------------------
2385    -- Smart_Find_File --
2386    ---------------------
2387
2388    function Smart_Find_File
2389      (N : File_Name_Type;
2390       T : File_Type) return File_Name_Type
2391    is
2392       Full_File_Name : File_Name_Type;
2393
2394    begin
2395       if not File_Cache_Enabled then
2396          return Find_File (N, T);
2397       end if;
2398
2399       Full_File_Name := File_Name_Hash_Table.Get (N);
2400
2401       if Full_File_Name = No_File then
2402          Full_File_Name := Find_File (N, T);
2403          File_Name_Hash_Table.Set (N, Full_File_Name);
2404       end if;
2405
2406       return Full_File_Name;
2407    end Smart_Find_File;
2408
2409    ----------------------
2410    -- Source_File_Data --
2411    ----------------------
2412
2413    procedure Source_File_Data (Cache : Boolean) is
2414    begin
2415       File_Cache_Enabled := Cache;
2416    end Source_File_Data;
2417
2418    -----------------------
2419    -- Source_File_Stamp --
2420    -----------------------
2421
2422    function Source_File_Stamp (N : File_Name_Type) return Time_Stamp_Type is
2423    begin
2424       return Smart_File_Stamp (N, Source);
2425    end Source_File_Stamp;
2426
2427    ---------------------
2428    -- Strip_Directory --
2429    ---------------------
2430
2431    function Strip_Directory (Name : File_Name_Type) return File_Name_Type is
2432    begin
2433       Get_Name_String (Name);
2434
2435       for J in reverse 1 .. Name_Len - 1 loop
2436
2437          --  If we find the last directory separator
2438
2439          if Is_Directory_Separator (Name_Buffer (J)) then
2440
2441             --  Return the part of Name that follows this last directory
2442             --  separator.
2443
2444             Name_Buffer (1 .. Name_Len - J) := Name_Buffer (J + 1 .. Name_Len);
2445             Name_Len := Name_Len - J;
2446             return Name_Find;
2447          end if;
2448       end loop;
2449
2450       --  There were no directory separator, just return Name
2451
2452       return Name;
2453    end Strip_Directory;
2454
2455    ------------------
2456    -- Strip_Suffix --
2457    ------------------
2458
2459    function Strip_Suffix (Name : File_Name_Type) return File_Name_Type is
2460    begin
2461       Get_Name_String (Name);
2462
2463       for J in reverse 2 .. Name_Len loop
2464
2465          --  If we found the last '.', return part of Name that precedes it
2466
2467          if Name_Buffer (J) = '.' then
2468             Name_Len := J - 1;
2469             return Name_Enter;
2470          end if;
2471       end loop;
2472
2473       return Name;
2474    end Strip_Suffix;
2475
2476    ---------------------------
2477    -- To_Canonical_Dir_Spec --
2478    ---------------------------
2479
2480    function To_Canonical_Dir_Spec
2481      (Host_Dir     : String;
2482       Prefix_Style : Boolean) return String_Access
2483    is
2484       function To_Canonical_Dir_Spec
2485         (Host_Dir    : Address;
2486          Prefix_Flag : Integer) return Address;
2487       pragma Import (C, To_Canonical_Dir_Spec, "__gnat_to_canonical_dir_spec");
2488
2489       C_Host_Dir      : String (1 .. Host_Dir'Length + 1);
2490       Canonical_Dir_Addr : Address;
2491       Canonical_Dir_Len  : Integer;
2492
2493    begin
2494       C_Host_Dir (1 .. Host_Dir'Length) := Host_Dir;
2495       C_Host_Dir (C_Host_Dir'Last)      := ASCII.NUL;
2496
2497       if Prefix_Style then
2498          Canonical_Dir_Addr := To_Canonical_Dir_Spec (C_Host_Dir'Address, 1);
2499       else
2500          Canonical_Dir_Addr := To_Canonical_Dir_Spec (C_Host_Dir'Address, 0);
2501       end if;
2502       Canonical_Dir_Len := C_String_Length (Canonical_Dir_Addr);
2503
2504       if Canonical_Dir_Len = 0 then
2505          return null;
2506       else
2507          return To_Path_String_Access (Canonical_Dir_Addr, Canonical_Dir_Len);
2508       end if;
2509
2510    exception
2511       when others =>
2512          Fail ("erroneous directory spec: ", Host_Dir);
2513          return null;
2514    end To_Canonical_Dir_Spec;
2515
2516    ---------------------------
2517    -- To_Canonical_File_List --
2518    ---------------------------
2519
2520    function To_Canonical_File_List
2521      (Wildcard_Host_File : String;
2522       Only_Dirs          : Boolean) return String_Access_List_Access
2523    is
2524       function To_Canonical_File_List_Init
2525         (Host_File : Address;
2526          Only_Dirs : Integer) return Integer;
2527       pragma Import (C, To_Canonical_File_List_Init,
2528                      "__gnat_to_canonical_file_list_init");
2529
2530       function To_Canonical_File_List_Next return Address;
2531       pragma Import (C, To_Canonical_File_List_Next,
2532                      "__gnat_to_canonical_file_list_next");
2533
2534       procedure To_Canonical_File_List_Free;
2535       pragma Import (C, To_Canonical_File_List_Free,
2536                      "__gnat_to_canonical_file_list_free");
2537
2538       Num_Files            : Integer;
2539       C_Wildcard_Host_File : String (1 .. Wildcard_Host_File'Length + 1);
2540
2541    begin
2542       C_Wildcard_Host_File (1 .. Wildcard_Host_File'Length) :=
2543         Wildcard_Host_File;
2544       C_Wildcard_Host_File (C_Wildcard_Host_File'Last) := ASCII.NUL;
2545
2546       --  Do the expansion and say how many there are
2547
2548       Num_Files := To_Canonical_File_List_Init
2549          (C_Wildcard_Host_File'Address, Boolean'Pos (Only_Dirs));
2550
2551       declare
2552          Canonical_File_List : String_Access_List (1 .. Num_Files);
2553          Canonical_File_Addr : Address;
2554          Canonical_File_Len  : Integer;
2555
2556       begin
2557          --  Retrieve the expanded directoy names and build the list
2558
2559          for J in 1 .. Num_Files loop
2560             Canonical_File_Addr := To_Canonical_File_List_Next;
2561             Canonical_File_Len  := C_String_Length (Canonical_File_Addr);
2562             Canonical_File_List (J) := To_Path_String_Access
2563                   (Canonical_File_Addr, Canonical_File_Len);
2564          end loop;
2565
2566          --  Free up the storage
2567
2568          To_Canonical_File_List_Free;
2569
2570          return new String_Access_List'(Canonical_File_List);
2571       end;
2572    end To_Canonical_File_List;
2573
2574    ----------------------------
2575    -- To_Canonical_File_Spec --
2576    ----------------------------
2577
2578    function To_Canonical_File_Spec
2579      (Host_File : String) return String_Access
2580    is
2581       function To_Canonical_File_Spec (Host_File : Address) return Address;
2582       pragma Import
2583         (C, To_Canonical_File_Spec, "__gnat_to_canonical_file_spec");
2584
2585       C_Host_File         : String (1 .. Host_File'Length + 1);
2586       Canonical_File_Addr : Address;
2587       Canonical_File_Len  : Integer;
2588
2589    begin
2590       C_Host_File (1 .. Host_File'Length) := Host_File;
2591       C_Host_File (C_Host_File'Last)      := ASCII.NUL;
2592
2593       Canonical_File_Addr := To_Canonical_File_Spec (C_Host_File'Address);
2594       Canonical_File_Len  := C_String_Length (Canonical_File_Addr);
2595
2596       if Canonical_File_Len = 0 then
2597          return null;
2598       else
2599          return To_Path_String_Access
2600                   (Canonical_File_Addr, Canonical_File_Len);
2601       end if;
2602
2603    exception
2604       when others =>
2605          Fail ("erroneous file spec: ", Host_File);
2606          return null;
2607    end To_Canonical_File_Spec;
2608
2609    ----------------------------
2610    -- To_Canonical_Path_Spec --
2611    ----------------------------
2612
2613    function To_Canonical_Path_Spec
2614      (Host_Path : String) return String_Access
2615    is
2616       function To_Canonical_Path_Spec (Host_Path : Address) return Address;
2617       pragma Import
2618         (C, To_Canonical_Path_Spec, "__gnat_to_canonical_path_spec");
2619
2620       C_Host_Path         : String (1 .. Host_Path'Length + 1);
2621       Canonical_Path_Addr : Address;
2622       Canonical_Path_Len  : Integer;
2623
2624    begin
2625       C_Host_Path (1 .. Host_Path'Length) := Host_Path;
2626       C_Host_Path (C_Host_Path'Last)      := ASCII.NUL;
2627
2628       Canonical_Path_Addr := To_Canonical_Path_Spec (C_Host_Path'Address);
2629       Canonical_Path_Len  := C_String_Length (Canonical_Path_Addr);
2630
2631       --  Return a null string (vice a null) for zero length paths, for
2632       --  compatibility with getenv().
2633
2634       return To_Path_String_Access (Canonical_Path_Addr, Canonical_Path_Len);
2635
2636    exception
2637       when others =>
2638          Fail ("erroneous path spec: ", Host_Path);
2639          return null;
2640    end To_Canonical_Path_Spec;
2641
2642    ---------------------------
2643    -- To_Host_Dir_Spec --
2644    ---------------------------
2645
2646    function To_Host_Dir_Spec
2647      (Canonical_Dir : String;
2648       Prefix_Style  : Boolean) return String_Access
2649    is
2650       function To_Host_Dir_Spec
2651         (Canonical_Dir : Address;
2652          Prefix_Flag   : Integer) return Address;
2653       pragma Import (C, To_Host_Dir_Spec, "__gnat_to_host_dir_spec");
2654
2655       C_Canonical_Dir : String (1 .. Canonical_Dir'Length + 1);
2656       Host_Dir_Addr   : Address;
2657       Host_Dir_Len    : Integer;
2658
2659    begin
2660       C_Canonical_Dir (1 .. Canonical_Dir'Length) := Canonical_Dir;
2661       C_Canonical_Dir (C_Canonical_Dir'Last)      := ASCII.NUL;
2662
2663       if Prefix_Style then
2664          Host_Dir_Addr := To_Host_Dir_Spec (C_Canonical_Dir'Address, 1);
2665       else
2666          Host_Dir_Addr := To_Host_Dir_Spec (C_Canonical_Dir'Address, 0);
2667       end if;
2668       Host_Dir_Len := C_String_Length (Host_Dir_Addr);
2669
2670       if Host_Dir_Len = 0 then
2671          return null;
2672       else
2673          return To_Path_String_Access (Host_Dir_Addr, Host_Dir_Len);
2674       end if;
2675    end To_Host_Dir_Spec;
2676
2677    ----------------------------
2678    -- To_Host_File_Spec --
2679    ----------------------------
2680
2681    function To_Host_File_Spec
2682      (Canonical_File : String) return String_Access
2683    is
2684       function To_Host_File_Spec (Canonical_File : Address) return Address;
2685       pragma Import (C, To_Host_File_Spec, "__gnat_to_host_file_spec");
2686
2687       C_Canonical_File      : String (1 .. Canonical_File'Length + 1);
2688       Host_File_Addr : Address;
2689       Host_File_Len  : Integer;
2690
2691    begin
2692       C_Canonical_File (1 .. Canonical_File'Length) := Canonical_File;
2693       C_Canonical_File (C_Canonical_File'Last)      := ASCII.NUL;
2694
2695       Host_File_Addr := To_Host_File_Spec (C_Canonical_File'Address);
2696       Host_File_Len  := C_String_Length (Host_File_Addr);
2697
2698       if Host_File_Len = 0 then
2699          return null;
2700       else
2701          return To_Path_String_Access
2702                   (Host_File_Addr, Host_File_Len);
2703       end if;
2704    end To_Host_File_Spec;
2705
2706    ---------------------------
2707    -- To_Path_String_Access --
2708    ---------------------------
2709
2710    function To_Path_String_Access
2711      (Path_Addr : Address;
2712       Path_Len  : Integer) return String_Access
2713    is
2714       subtype Path_String is String (1 .. Path_Len);
2715       type Path_String_Access is access Path_String;
2716
2717       function Address_To_Access is new
2718         Unchecked_Conversion (Source => Address,
2719                               Target => Path_String_Access);
2720
2721       Path_Access : constant Path_String_Access :=
2722                       Address_To_Access (Path_Addr);
2723
2724       Return_Val : String_Access;
2725
2726    begin
2727       Return_Val := new String (1 .. Path_Len);
2728
2729       for J in 1 .. Path_Len loop
2730          Return_Val (J) := Path_Access (J);
2731       end loop;
2732
2733       return Return_Val;
2734    end To_Path_String_Access;
2735
2736    -----------------
2737    -- Update_Path --
2738    -----------------
2739
2740    function Update_Path (Path : String_Ptr) return String_Ptr is
2741
2742       function C_Update_Path (Path, Component : Address) return Address;
2743       pragma Import (C, C_Update_Path, "update_path");
2744
2745       function Strlen (Str : Address) return Integer;
2746       pragma Import (C, Strlen, "strlen");
2747
2748       procedure Strncpy (X : Address; Y : Address; Length : Integer);
2749       pragma Import (C, Strncpy, "strncpy");
2750
2751       In_Length      : constant Integer := Path'Length;
2752       In_String      : String (1 .. In_Length + 1);
2753       Component_Name : aliased String := "GCC" & ASCII.NUL;
2754       Result_Ptr     : Address;
2755       Result_Length  : Integer;
2756       Out_String     : String_Ptr;
2757
2758    begin
2759       In_String (1 .. In_Length) := Path.all;
2760       In_String (In_Length + 1) := ASCII.NUL;
2761       Result_Ptr := C_Update_Path (In_String'Address, Component_Name'Address);
2762       Result_Length := Strlen (Result_Ptr);
2763
2764       Out_String := new String (1 .. Result_Length);
2765       Strncpy (Out_String.all'Address, Result_Ptr, Result_Length);
2766       return Out_String;
2767    end Update_Path;
2768
2769    ----------------
2770    -- Write_Info --
2771    ----------------
2772
2773    procedure Write_Info (Info : String) is
2774    begin
2775       Write_With_Check (Info'Address, Info'Length);
2776       Write_With_Check (EOL'Address, 1);
2777    end Write_Info;
2778
2779    ------------------------
2780    -- Write_Program_Name --
2781    ------------------------
2782
2783    procedure Write_Program_Name is
2784       Save_Buffer : constant String (1 .. Name_Len) :=
2785                       Name_Buffer (1 .. Name_Len);
2786
2787    begin
2788       Find_Program_Name;
2789
2790       --  Convert the name to lower case so error messages are the same on
2791       --  all systems.
2792
2793       for J in 1 .. Name_Len loop
2794          if Name_Buffer (J) in 'A' .. 'Z' then
2795             Name_Buffer (J) :=
2796               Character'Val (Character'Pos (Name_Buffer (J)) + 32);
2797          end if;
2798       end loop;
2799
2800       Write_Str (Name_Buffer (1 .. Name_Len));
2801
2802       --  Restore Name_Buffer which was clobbered by the call to
2803       --  Find_Program_Name
2804
2805       Name_Len := Save_Buffer'Last;
2806       Name_Buffer (1 .. Name_Len) := Save_Buffer;
2807    end Write_Program_Name;
2808
2809    ----------------------
2810    -- Write_With_Check --
2811    ----------------------
2812
2813    procedure Write_With_Check (A  : Address; N  : Integer) is
2814       Ignore : Boolean;
2815
2816    begin
2817       if N = Write (Output_FD, A, N) then
2818          return;
2819
2820       else
2821          Write_Str ("error: disk full writing ");
2822          Write_Name_Decoded (Output_File_Name);
2823          Write_Eol;
2824          Name_Len := Name_Len + 1;
2825          Name_Buffer (Name_Len) := ASCII.NUL;
2826          Delete_File (Name_Buffer'Address, Ignore);
2827          Exit_Program (E_Fatal);
2828       end if;
2829    end Write_With_Check;
2830
2831 ----------------------------
2832 -- Package Initialization --
2833 ----------------------------
2834
2835 begin
2836    Initialization : declare
2837
2838       function Get_Default_Identifier_Character_Set return Character;
2839       pragma Import (C, Get_Default_Identifier_Character_Set,
2840                        "__gnat_get_default_identifier_character_set");
2841       --  Function to determine the default identifier character set,
2842       --  which is system dependent. See Opt package spec for a list of
2843       --  the possible character codes and their interpretations.
2844
2845       function Get_Maximum_File_Name_Length return Int;
2846       pragma Import (C, Get_Maximum_File_Name_Length,
2847                     "__gnat_get_maximum_file_name_length");
2848       --  Function to get maximum file name length for system
2849
2850    begin
2851       Identifier_Character_Set := Get_Default_Identifier_Character_Set;
2852       Maximum_File_Name_Length := Get_Maximum_File_Name_Length;
2853
2854       --  Following should be removed by having above function return
2855       --  Integer'Last as indication of no maximum instead of -1 ???
2856
2857       if Maximum_File_Name_Length = -1 then
2858          Maximum_File_Name_Length := Int'Last;
2859       end if;
2860
2861       Src_Search_Directories.Set_Last (Primary_Directory);
2862       Src_Search_Directories.Table (Primary_Directory) := new String'("");
2863
2864       Lib_Search_Directories.Set_Last (Primary_Directory);
2865       Lib_Search_Directories.Table (Primary_Directory) := new String'("");
2866
2867       Osint.Initialize;
2868    end Initialization;
2869
2870 end Osint;