gcc/ada/osint-c.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              O S I N T - C                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Hostparm;
  27 with Opt;      use Opt;
  28 with Tree_IO;  use Tree_IO;
  29
  30 package body Osint.C is
  31
  32    Output_Object_File_Name : String_Ptr;
  33    --  Argument of -o compiler option, if given. This is needed to verify
  34    --  consistency with the ALI file name.
  35
  36    procedure Adjust_OS_Resource_Limits;
  37    pragma Import (C, Adjust_OS_Resource_Limits,
  38                   "__gnat_adjust_os_resource_limits");
  39    --  Procedure to make system specific adjustments to make GNAT run better
  40
  41    function Create_Auxiliary_File
  42      (Src    : File_Name_Type;
  43       Suffix : String) return File_Name_Type;
  44    --  Common processing for Create_List_File, Create_Repinfo_File and
  45    --  Create_Debug_File. Src is the file name used to create the required
  46    --  output file and Suffix is the desired suffix (dg/rep/xxx for debug/
  47    --  repinfo/list file where xxx is specified extension.
  48
  49    procedure Set_Library_Info_Name;
  50    --  Sets a default ALI file name from the main compiler source name.
  51    --  This is used by Create_Output_Library_Info, and by the version of
  52    --  Read_Library_Info that takes a default file name. The name is in
  53    --  Name_Buffer (with length in Name_Len) on return from the call.
  54
  55    ----------------------
  56    -- Close_Debug_File --
  57    ----------------------
  58
  59    procedure Close_Debug_File is
  60       Status : Boolean;
  61
  62    begin
  63       Close (Output_FD, Status);
  64
  65       if not Status then
  66          Fail
  67            ("error while closing expanded source file "
  68             & Get_Name_String (Output_File_Name));
  69       end if;
  70    end Close_Debug_File;
  71
  72    ---------------------
  73    -- Close_List_File --
  74    ---------------------
  75
  76    procedure Close_List_File is
  77       Status : Boolean;
  78
  79    begin
  80       Close (Output_FD, Status);
  81
  82       if not Status then
  83          Fail
  84            ("error while closing list file "
  85             & Get_Name_String (Output_File_Name));
  86       end if;
  87    end Close_List_File;
  88
  89    -------------------------------
  90    -- Close_Output_Library_Info --
  91    -------------------------------
  92
  93    procedure Close_Output_Library_Info is
  94       Status : Boolean;
  95
  96    begin
  97       Close (Output_FD, Status);
  98
  99       if not Status then
 100          Fail
 101            ("error while closing ALI file "
 102             & Get_Name_String (Output_File_Name));
 103       end if;
 104    end Close_Output_Library_Info;
 105
 106    ------------------------
 107    -- Close_Repinfo_File --
 108    ------------------------
 109
 110    procedure Close_Repinfo_File is
 111       Status : Boolean;
 112
 113    begin
 114       Close (Output_FD, Status);
 115
 116       if not Status then
 117          Fail
 118            ("error while closing representation info file "
 119             & Get_Name_String (Output_File_Name));
 120       end if;
 121    end Close_Repinfo_File;
 122
 123    ---------------------------
 124    -- Create_Auxiliary_File --
 125    ---------------------------
 126
 127    function Create_Auxiliary_File
 128      (Src    : File_Name_Type;
 129       Suffix : String) return File_Name_Type
 130    is
 131       Result : File_Name_Type;
 132
 133    begin
 134       Get_Name_String (Src);
 135
 136       if Hostparm.OpenVMS then
 137          Name_Buffer (Name_Len + 1) := '_';
 138       else
 139          Name_Buffer (Name_Len + 1) := '.';
 140       end if;
 141
 142       Name_Len := Name_Len + 1;
 143       Name_Buffer (Name_Len + 1 .. Name_Len + Suffix'Length) := Suffix;
 144       Name_Len := Name_Len + Suffix'Length;
 145
 146       if Output_Object_File_Name /= null then
 147          for Index in reverse Output_Object_File_Name'Range loop
 148             if Output_Object_File_Name (Index) = Directory_Separator then
 149                declare
 150                   File_Name : constant String := Name_Buffer (1 .. Name_Len);
 151                begin
 152                   Name_Len := Index - Output_Object_File_Name'First + 1;
 153                   Name_Buffer (1 .. Name_Len) :=
 154                     Output_Object_File_Name
 155                       (Output_Object_File_Name'First .. Index);
 156                   Name_Buffer (Name_Len + 1 .. Name_Len + File_Name'Length) :=
 157                     File_Name;
 158                   Name_Len := Name_Len + File_Name'Length;
 159                end;
 160
 161                exit;
 162             end if;
 163          end loop;
 164       end if;
 165
 166       Result := Name_Find;
 167       Name_Buffer (Name_Len + 1) := ASCII.NUL;
 168       Create_File_And_Check (Output_FD, Text);
 169       return Result;
 170    end Create_Auxiliary_File;
 171
 172    -----------------------
 173    -- Create_Debug_File --
 174    -----------------------
 175
 176    function Create_Debug_File (Src : File_Name_Type) return File_Name_Type is
 177    begin
 178       return Create_Auxiliary_File (Src, "dg");
 179    end Create_Debug_File;
 180
 181    ----------------------
 182    -- Create_List_File --
 183    ----------------------
 184
 185    procedure Create_List_File (S : String) is
 186       F : File_Name_Type;
 187       pragma Warnings (Off, F);
 188    begin
 189       if S (S'First) = '.' then
 190          F := Create_Auxiliary_File (Current_Main, S (S'First + 1 .. S'Last));
 191
 192       else
 193          Name_Buffer (1 .. S'Length) := S;
 194          Name_Len := S'Length + 1;
 195          Name_Buffer (Name_Len) := ASCII.NUL;
 196          Create_File_And_Check (Output_FD, Text);
 197       end if;
 198    end Create_List_File;
 199
 200    --------------------------------
 201    -- Create_Output_Library_Info --
 202    --------------------------------
 203
 204    procedure Create_Output_Library_Info is
 205    begin
 206       Set_Library_Info_Name;
 207       Create_File_And_Check (Output_FD, Text);
 208    end Create_Output_Library_Info;
 209
 210    -------------------------
 211    -- Create_Repinfo_File --
 212    -------------------------
 213
 214    procedure Create_Repinfo_File (Src : String) is
 215       Discard : File_Name_Type;
 216       pragma Warnings (Off, Discard);
 217    begin
 218       Name_Buffer (1 .. Src'Length) := Src;
 219       Name_Len := Src'Length;
 220       Discard := Create_Auxiliary_File (Name_Find, "rep");
 221       return;
 222    end Create_Repinfo_File;
 223
 224    ---------------------------
 225    -- Debug_File_Eol_Length --
 226    ---------------------------
 227
 228    function Debug_File_Eol_Length return Nat is
 229    begin
 230       --  There has to be a cleaner way to do this! ???
 231
 232       if Directory_Separator = '/' then
 233          return 1;
 234       else
 235          return 2;
 236       end if;
 237    end Debug_File_Eol_Length;
 238
 239    ---------------------------------
 240    -- Get_Output_Object_File_Name --
 241    ---------------------------------
 242
 243    function Get_Output_Object_File_Name return String is
 244    begin
 245       pragma Assert (Output_Object_File_Name /= null);
 246
 247       return Output_Object_File_Name.all;
 248    end Get_Output_Object_File_Name;
 249
 250    -----------------------
 251    -- More_Source_Files --
 252    -----------------------
 253
 254    function More_Source_Files return Boolean renames More_Files;
 255
 256    ----------------------
 257    -- Next_Main_Source --
 258    ----------------------
 259
 260    function Next_Main_Source return File_Name_Type renames Next_Main_File;
 261
 262    -----------------------
 263    -- Read_Library_Info --
 264    -----------------------
 265
 266    --  Version with default file name
 267
 268    procedure Read_Library_Info
 269      (Name : out File_Name_Type;
 270       Text : out Text_Buffer_Ptr)
 271    is
 272    begin
 273       Set_Library_Info_Name;
 274       Name := Name_Find;
 275       Text := Read_Library_Info (Name, Fatal_Err => False);
 276    end Read_Library_Info;
 277
 278    ---------------------------
 279    -- Set_Library_Info_Name --
 280    ---------------------------
 281
 282    procedure Set_Library_Info_Name is
 283       Dot_Index : Natural;
 284
 285    begin
 286       Get_Name_String (Current_Main);
 287
 288       --  Find last dot since we replace the existing extension by .ali. The
 289       --  initialization to Name_Len + 1 provides for simply adding the .ali
 290       --  extension if the source file name has no extension.
 291
 292       Dot_Index := Name_Len + 1;
 293
 294       for J in reverse 1 .. Name_Len loop
 295          if Name_Buffer (J) = '.' then
 296             Dot_Index := J;
 297             exit;
 298          end if;
 299       end loop;
 300
 301       --  Make sure that the output file name matches the source file name.
 302       --  To compare them, remove file name directories and extensions.
 303
 304       if Output_Object_File_Name /= null then
 305
 306          --  Make sure there is a dot at Dot_Index. This may not be the case
 307          --  if the source file name has no extension.
 308
 309          Name_Buffer (Dot_Index) := '.';
 310
 311          --  If we are in multiple unit per file mode, then add ~nnn
 312          --  extension to the name before doing the comparison.
 313
 314          if Multiple_Unit_Index /= 0 then
 315             declare
 316                Exten : constant String := Name_Buffer (Dot_Index .. Name_Len);
 317             begin
 318                Name_Len := Dot_Index - 1;
 319                Add_Char_To_Name_Buffer (Multi_Unit_Index_Character);
 320                Add_Nat_To_Name_Buffer (Multiple_Unit_Index);
 321                Dot_Index := Name_Len + 1;
 322                Add_Str_To_Name_Buffer (Exten);
 323             end;
 324          end if;
 325
 326          --  Remove extension preparing to replace it
 327
 328          declare
 329             Name  : String  := Name_Buffer (1 .. Dot_Index);
 330             First : Positive;
 331
 332          begin
 333             Name_Buffer (1 .. Output_Object_File_Name'Length) :=
 334               Output_Object_File_Name.all;
 335
 336             --  Put two names in canonical case, to allow object file names
 337             --  with upper-case letters on Windows.
 338
 339             Canonical_Case_File_Name (Name);
 340             Canonical_Case_File_Name
 341               (Name_Buffer (1 .. Output_Object_File_Name'Length));
 342
 343             Dot_Index := 0;
 344             for J in reverse Output_Object_File_Name'Range loop
 345                if Name_Buffer (J) = '.' then
 346                   Dot_Index := J;
 347                   exit;
 348                end if;
 349             end loop;
 350
 351             --  Dot_Index should not be zero now (we check for extension
 352             --  elsewhere).
 353
 354             pragma Assert (Dot_Index /= 0);
 355
 356             --  Look for first character of file name
 357
 358             First := Dot_Index;
 359             while First > 1
 360               and then Name_Buffer (First - 1) /= Directory_Separator
 361               and then Name_Buffer (First - 1) /= '/'
 362             loop
 363                First := First - 1;
 364             end loop;
 365
 366             --  Check name of object file is what we expect
 367
 368             if Name /= Name_Buffer (First .. Dot_Index) then
 369                Fail ("incorrect object file name");
 370             end if;
 371          end;
 372       end if;
 373
 374       Name_Buffer (Dot_Index) := '.';
 375       Name_Buffer (Dot_Index + 1 .. Dot_Index + 3) := ALI_Suffix.all;
 376       Name_Buffer (Dot_Index + 4) := ASCII.NUL;
 377       Name_Len := Dot_Index + 3;
 378    end Set_Library_Info_Name;
 379
 380    ---------------------------------
 381    -- Set_Output_Object_File_Name --
 382    ---------------------------------
 383
 384    procedure Set_Output_Object_File_Name (Name : String) is
 385       Ext : constant String  := Target_Object_Suffix;
 386       NL  : constant Natural := Name'Length;
 387       EL  : constant Natural := Ext'Length;
 388
 389    begin
 390       --  Make sure that the object file has the expected extension
 391
 392       if NL <= EL
 393          or else
 394           (Name (NL - EL + Name'First .. Name'Last) /= Ext
 395              and then Name (NL - 2 + Name'First .. Name'Last) /= ".o")
 396       then
 397          Fail ("incorrect object file extension");
 398       end if;
 399
 400       Output_Object_File_Name := new String'(Name);
 401    end Set_Output_Object_File_Name;
 402
 403    ----------------
 404    -- Tree_Close --
 405    ----------------
 406
 407    procedure Tree_Close is
 408       Status : Boolean;
 409    begin
 410       Tree_Write_Terminate;
 411       Close (Output_FD, Status);
 412
 413       if not Status then
 414          Fail
 415            ("error while closing tree file "
 416             & Get_Name_String (Output_File_Name));
 417       end if;
 418    end Tree_Close;
 419
 420    -----------------
 421    -- Tree_Create --
 422    -----------------
 423
 424    procedure Tree_Create is
 425       Dot_Index : Natural;
 426
 427    begin
 428       Get_Name_String (Current_Main);
 429
 430       --  If an object file has been specified, then the ALI file
 431       --  will be in the same directory as the object file;
 432       --  so, we put the tree file in this same directory,
 433       --  even though no object file needs to be generated.
 434
 435       if Output_Object_File_Name /= null then
 436          Name_Len := Output_Object_File_Name'Length;
 437          Name_Buffer (1 .. Name_Len) := Output_Object_File_Name.all;
 438       end if;
 439
 440       Dot_Index := Name_Len + 1;
 441
 442       for J in reverse 1 .. Name_Len loop
 443          if Name_Buffer (J) = '.' then
 444             Dot_Index := J;
 445             exit;
 446          end if;
 447       end loop;
 448
 449       --  Should be impossible to not have an extension
 450
 451       pragma Assert (Dot_Index /= 0);
 452
 453       --  Change extension to adt
 454
 455       Name_Buffer (Dot_Index) := '.';
 456       Name_Buffer (Dot_Index + 1) := 'a';
 457       Name_Buffer (Dot_Index + 2) := 'd';
 458       Name_Buffer (Dot_Index + 3) := 't';
 459       Name_Buffer (Dot_Index + 4) := ASCII.NUL;
 460       Name_Len := Dot_Index + 3;
 461       Create_File_And_Check (Output_FD, Binary);
 462
 463       Tree_Write_Initialize (Output_FD);
 464    end Tree_Create;
 465
 466    -----------------------
 467    -- Write_Debug_Info --
 468    -----------------------
 469
 470    procedure Write_Debug_Info (Info : String) renames Write_Info;
 471
 472    ------------------------
 473    -- Write_Library_Info --
 474    ------------------------
 475
 476    procedure Write_Library_Info (Info : String) renames Write_Info;
 477
 478    ---------------------
 479    -- Write_List_Info --
 480    ---------------------
 481
 482    procedure Write_List_Info (S : String) is
 483    begin
 484       Write_With_Check (S'Address, S'Length);
 485    end Write_List_Info;
 486
 487    ------------------------
 488    -- Write_Repinfo_Line --
 489    ------------------------
 490
 491    procedure Write_Repinfo_Line (Info : String) renames Write_Info;
 492
 493 begin
 494    Adjust_OS_Resource_Limits;
 495
 496    Opt.Create_Repinfo_File_Access := Create_Repinfo_File'Access;
 497    Opt.Write_Repinfo_Line_Access  := Write_Repinfo_Line'Access;
 498    Opt.Close_Repinfo_File_Access  := Close_Repinfo_File'Access;
 499
 500    Opt.Create_List_File_Access := Create_List_File'Access;
 501    Opt.Write_List_Info_Access  := Write_List_Info'Access;
 502    Opt.Close_List_File_Access  := Close_List_File'Access;
 503
 504    Set_Program (Compiler);
 505 end Osint.C;