gcc/ada/makeutl.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              M A K E U T L                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Debug;
  27 with Osint;    use Osint;
  28 with Output;   use Output;
  29 with Prj.Ext;
  30 with Prj.Util;
  31 with Snames;   use Snames;
  32 with Table;
  33
  34 with Ada.Command_Line;  use Ada.Command_Line;
  35
  36 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  37
  38 with System.Case_Util; use System.Case_Util;
  39 with System.HTable;
  40
  41 package body Makeutl is
  42
  43    type Mark_Key is record
  44       File  : File_Name_Type;
  45       Index : Int;
  46    end record;
  47    --  Identify either a mono-unit source (when Index = 0) or a specific unit
  48    --  (index = 1's origin index of unit) in a multi-unit source.
  49
  50    --  There follow many global undocumented declarations, comments needed ???
  51
  52    Max_Mask_Num : constant := 2048;
  53
  54    subtype Mark_Num is Union_Id range 0 .. Max_Mask_Num - 1;
  55
  56    function Hash (Key : Mark_Key) return Mark_Num;
  57
  58    package Marks is new System.HTable.Simple_HTable
  59      (Header_Num => Mark_Num,
  60       Element    => Boolean,
  61       No_Element => False,
  62       Key        => Mark_Key,
  63       Hash       => Hash,
  64       Equal      => "=");
  65    --  A hash table to keep tracks of the marked units
  66
  67    type Linker_Options_Data is record
  68       Project : Project_Id;
  69       Options : String_List_Id;
  70    end record;
  71
  72    Linker_Option_Initial_Count : constant := 20;
  73
  74    Linker_Options_Buffer : String_List_Access :=
  75      new String_List (1 .. Linker_Option_Initial_Count);
  76
  77    Last_Linker_Option : Natural := 0;
  78
  79    package Linker_Opts is new Table.Table (
  80      Table_Component_Type => Linker_Options_Data,
  81      Table_Index_Type     => Integer,
  82      Table_Low_Bound      => 1,
  83      Table_Initial        => 10,
  84      Table_Increment      => 100,
  85      Table_Name           => "Make.Linker_Opts");
  86
  87    procedure Add_Linker_Option (Option : String);
  88
  89    ---------
  90    -- Add --
  91    ---------
  92
  93    procedure Add
  94      (Option : String_Access;
  95       To     : in out String_List_Access;
  96       Last   : in out Natural)
  97    is
  98    begin
  99       if Last = To'Last then
 100          declare
 101             New_Options : constant String_List_Access :=
 102                             new String_List (1 .. To'Last * 2);
 103          begin
 104             New_Options (To'Range) := To.all;
 105
 106             --  Set all elements of the original options to null to avoid
 107             --  deallocation of copies.
 108
 109             To.all := (others => null);
 110
 111             Free (To);
 112             To := New_Options;
 113          end;
 114       end if;
 115
 116       Last := Last + 1;
 117       To (Last) := Option;
 118    end Add;
 119
 120    procedure Add
 121      (Option : String;
 122       To     : in out String_List_Access;
 123       Last   : in out Natural)
 124    is
 125    begin
 126       Add (Option => new String'(Option), To => To, Last => Last);
 127    end Add;
 128
 129    -----------------------
 130    -- Add_Linker_Option --
 131    -----------------------
 132
 133    procedure Add_Linker_Option (Option : String) is
 134    begin
 135       if Option'Length > 0 then
 136          if Last_Linker_Option = Linker_Options_Buffer'Last then
 137             declare
 138                New_Buffer : constant String_List_Access :=
 139                               new String_List
 140                                 (1 .. Linker_Options_Buffer'Last +
 141                                         Linker_Option_Initial_Count);
 142             begin
 143                New_Buffer (Linker_Options_Buffer'Range) :=
 144                  Linker_Options_Buffer.all;
 145                Linker_Options_Buffer.all := (others => null);
 146                Free (Linker_Options_Buffer);
 147                Linker_Options_Buffer := New_Buffer;
 148             end;
 149          end if;
 150
 151          Last_Linker_Option := Last_Linker_Option + 1;
 152          Linker_Options_Buffer (Last_Linker_Option) := new String'(Option);
 153       end if;
 154    end Add_Linker_Option;
 155
 156    -----------------
 157    -- Create_Name --
 158    -----------------
 159
 160    function Create_Name (Name : String) return File_Name_Type is
 161    begin
 162       Name_Len := 0;
 163       Add_Str_To_Name_Buffer (Name);
 164       return Name_Find;
 165    end Create_Name;
 166
 167    function Create_Name (Name : String) return Name_Id is
 168    begin
 169       Name_Len := 0;
 170       Add_Str_To_Name_Buffer (Name);
 171       return Name_Find;
 172    end Create_Name;
 173
 174    function Create_Name (Name : String) return Path_Name_Type is
 175    begin
 176       Name_Len := 0;
 177       Add_Str_To_Name_Buffer (Name);
 178       return Name_Find;
 179    end Create_Name;
 180
 181    ----------------------
 182    -- Delete_All_Marks --
 183    ----------------------
 184
 185    procedure Delete_All_Marks is
 186    begin
 187       Marks.Reset;
 188    end Delete_All_Marks;
 189
 190    ----------------------------
 191    -- Executable_Prefix_Path --
 192    ----------------------------
 193
 194    function Executable_Prefix_Path return String is
 195       Exec_Name : constant String := Command_Name;
 196
 197       function Get_Install_Dir (S : String) return String;
 198       --  S is the executable name preceded by the absolute or relative
 199       --  path, e.g. "c:\usr\bin\gcc.exe". Returns the absolute directory
 200       --  where "bin" lies (in the example "C:\usr").
 201       --  If the executable is not in a "bin" directory, return "".
 202
 203       ---------------------
 204       -- Get_Install_Dir --
 205       ---------------------
 206
 207       function Get_Install_Dir (S : String) return String is
 208          Exec      : String  := S;
 209          Path_Last : Integer := 0;
 210
 211       begin
 212          for J in reverse Exec'Range loop
 213             if Exec (J) = Directory_Separator then
 214                Path_Last := J - 1;
 215                exit;
 216             end if;
 217          end loop;
 218
 219          if Path_Last >= Exec'First + 2 then
 220             To_Lower (Exec (Path_Last - 2 .. Path_Last));
 221          end if;
 222
 223          if Path_Last < Exec'First + 2
 224            or else Exec (Path_Last - 2 .. Path_Last) /= "bin"
 225            or else (Path_Last - 3 >= Exec'First
 226                      and then Exec (Path_Last - 3) /= Directory_Separator)
 227          then
 228             return "";
 229          end if;
 230
 231          return Normalize_Pathname (Exec (Exec'First .. Path_Last - 4));
 232       end Get_Install_Dir;
 233
 234    --  Beginning of Executable_Prefix_Path
 235
 236    begin
 237       --  First determine if a path prefix was placed in front of the
 238       --  executable name.
 239
 240       for J in reverse Exec_Name'Range loop
 241          if Exec_Name (J) = Directory_Separator then
 242             return Get_Install_Dir (Exec_Name);
 243          end if;
 244       end loop;
 245
 246       --  If we get here, the user has typed the executable name with no
 247       --  directory prefix.
 248
 249       return Get_Install_Dir (Locate_Exec_On_Path (Exec_Name).all);
 250    end Executable_Prefix_Path;
 251
 252    ----------
 253    -- Hash --
 254    ----------
 255
 256    function Hash (Key : Mark_Key) return Mark_Num is
 257    begin
 258       return Union_Id (Key.File) mod Max_Mask_Num;
 259    end Hash;
 260
 261    ------------
 262    -- Inform --
 263    ------------
 264
 265    procedure Inform (N : File_Name_Type; Msg : String) is
 266    begin
 267       Inform (Name_Id (N), Msg);
 268    end Inform;
 269
 270    procedure Inform (N : Name_Id := No_Name; Msg : String) is
 271    begin
 272       Osint.Write_Program_Name;
 273
 274       Write_Str (": ");
 275
 276       if N /= No_Name then
 277          Write_Str ("""");
 278
 279          declare
 280             Name : constant String := Get_Name_String (N);
 281          begin
 282             if Debug.Debug_Flag_F and then Is_Absolute_Path (Name) then
 283                Write_Str (File_Name (Name));
 284             else
 285                Write_Str (Name);
 286             end if;
 287          end;
 288
 289          Write_Str (""" ");
 290       end if;
 291
 292       Write_Str (Msg);
 293       Write_Eol;
 294    end Inform;
 295
 296    ----------------------------
 297    -- Is_External_Assignment --
 298    ----------------------------
 299
 300    function Is_External_Assignment (Argv : String) return Boolean is
 301       Start     : Positive := 3;
 302       Finish    : Natural := Argv'Last;
 303       Equal_Pos : Natural;
 304
 305       pragma Assert (Argv'First = 1);
 306       pragma Assert (Argv (1 .. 2) = "-X");
 307
 308    begin
 309       if Argv'Last < 5 then
 310          return False;
 311
 312       elsif Argv (3) = '"' then
 313          if Argv (Argv'Last) /= '"' or else Argv'Last < 7 then
 314             return False;
 315          else
 316             Start := 4;
 317             Finish := Argv'Last - 1;
 318          end if;
 319       end if;
 320
 321       Equal_Pos := Start;
 322
 323       while Equal_Pos <= Finish and then Argv (Equal_Pos) /= '=' loop
 324          Equal_Pos := Equal_Pos + 1;
 325       end loop;
 326
 327       if Equal_Pos = Start
 328         or else Equal_Pos > Finish
 329       then
 330          return False;
 331       else
 332          Prj.Ext.Add
 333            (External_Name => Argv (Start .. Equal_Pos - 1),
 334             Value         => Argv (Equal_Pos + 1 .. Finish));
 335          return True;
 336       end if;
 337    end Is_External_Assignment;
 338
 339    ---------------
 340    -- Is_Marked --
 341    ---------------
 342
 343    function Is_Marked
 344      (Source_File : File_Name_Type;
 345       Index       : Int := 0) return Boolean
 346    is
 347    begin
 348       return Marks.Get (K => (File => Source_File, Index => Index));
 349    end Is_Marked;
 350
 351    -----------------------------
 352    -- Linker_Options_Switches --
 353    -----------------------------
 354
 355    function Linker_Options_Switches
 356      (Project  : Project_Id;
 357       In_Tree  : Project_Tree_Ref) return String_List
 358    is
 359       procedure Recursive_Add_Linker_Options (Proj : Project_Id);
 360       --  The recursive routine used to add linker options
 361
 362       ----------------------------------
 363       -- Recursive_Add_Linker_Options --
 364       ----------------------------------
 365
 366       procedure Recursive_Add_Linker_Options (Proj : Project_Id) is
 367          Data           : Project_Data;
 368          Linker_Package : Package_Id;
 369          Options        : Variable_Value;
 370          Imported       : Project_List;
 371
 372       begin
 373          if Proj /= No_Project then
 374             Data := In_Tree.Projects.Table (Proj);
 375
 376             if not Data.Seen then
 377                In_Tree.Projects.Table (Proj).Seen := True;
 378                Imported := Data.Imported_Projects;
 379
 380                while Imported /= Empty_Project_List loop
 381                   Recursive_Add_Linker_Options
 382                     (In_Tree.Project_Lists.Table
 383                        (Imported).Project);
 384                   Imported := In_Tree.Project_Lists.Table
 385                                 (Imported).Next;
 386                end loop;
 387
 388                if Proj /= Project then
 389                   Linker_Package :=
 390                     Prj.Util.Value_Of
 391                       (Name        => Name_Linker,
 392                        In_Packages => Data.Decl.Packages,
 393                        In_Tree     => In_Tree);
 394                   Options :=
 395                     Prj.Util.Value_Of
 396                       (Name                    => Name_Ada,
 397                        Index                   => 0,
 398                        Attribute_Or_Array_Name => Name_Linker_Options,
 399                        In_Package              => Linker_Package,
 400                        In_Tree                 => In_Tree);
 401
 402                   --  If attribute is present, add the project with
 403                   --  the attribute to table Linker_Opts.
 404
 405                   if Options /= Nil_Variable_Value then
 406                      Linker_Opts.Increment_Last;
 407                      Linker_Opts.Table (Linker_Opts.Last) :=
 408                        (Project => Proj, Options => Options.Values);
 409                   end if;
 410                end if;
 411             end if;
 412          end if;
 413       end Recursive_Add_Linker_Options;
 414
 415    --  Start of processing for Linker_Options_Switches
 416
 417    begin
 418       Linker_Opts.Init;
 419
 420       for Index in Project_Table.First ..
 421                    Project_Table.Last (In_Tree.Projects)
 422       loop
 423          In_Tree.Projects.Table (Index).Seen := False;
 424       end loop;
 425
 426       Recursive_Add_Linker_Options (Project);
 427
 428       Last_Linker_Option := 0;
 429
 430       for Index in reverse 1 .. Linker_Opts.Last loop
 431          declare
 432             Options : String_List_Id := Linker_Opts.Table (Index).Options;
 433             Proj    : constant Project_Id :=
 434               Linker_Opts.Table (Index).Project;
 435             Option  : Name_Id;
 436
 437          begin
 438             --  If Dir_Path has not been computed for this project, do it now
 439
 440             if In_Tree.Projects.Table (Proj).Dir_Path = null then
 441                In_Tree.Projects.Table (Proj).Dir_Path :=
 442                  new String'
 443                    (Get_Name_String
 444                         (In_Tree.Projects.Table
 445                              (Proj). Directory));
 446             end if;
 447
 448             while Options /= Nil_String loop
 449                Option :=
 450                  In_Tree.String_Elements.Table (Options).Value;
 451                Get_Name_String (Option);
 452
 453                --  Do not consider empty linker options
 454
 455                if Name_Len /= 0 then
 456                   Add_Linker_Option (Name_Buffer (1 .. Name_Len));
 457
 458                   --  Object files and -L switches specified with relative
 459                   --  paths must be converted to absolute paths.
 460
 461                   Test_If_Relative_Path
 462                     (Switch =>
 463                        Linker_Options_Buffer (Last_Linker_Option),
 464                      Parent =>
 465                        In_Tree.Projects.Table (Proj).Dir_Path,
 466                      Including_L_Switch => True);
 467                end if;
 468
 469                Options :=
 470                  In_Tree.String_Elements.Table (Options).Next;
 471             end loop;
 472          end;
 473       end loop;
 474
 475       return Linker_Options_Buffer (1 .. Last_Linker_Option);
 476    end Linker_Options_Switches;
 477
 478    -----------
 479    -- Mains --
 480    -----------
 481
 482    package body Mains is
 483
 484       package Names is new Table.Table
 485         (Table_Component_Type => File_Name_Type,
 486          Table_Index_Type     => Integer,
 487          Table_Low_Bound      => 1,
 488          Table_Initial        => 10,
 489          Table_Increment      => 100,
 490          Table_Name           => "Makeutl.Mains.Names");
 491       --  The table that stores the mains
 492
 493       Current : Natural := 0;
 494       --  The index of the last main retrieved from the table
 495
 496       --------------
 497       -- Add_Main --
 498       --------------
 499
 500       procedure Add_Main (Name : String) is
 501       begin
 502          Name_Len := 0;
 503          Add_Str_To_Name_Buffer (Name);
 504          Names.Increment_Last;
 505          Names.Table (Names.Last) := Name_Find;
 506       end Add_Main;
 507
 508       ------------
 509       -- Delete --
 510       ------------
 511
 512       procedure Delete is
 513       begin
 514          Names.Set_Last (0);
 515          Mains.Reset;
 516       end Delete;
 517
 518       ---------------
 519       -- Next_Main --
 520       ---------------
 521
 522       function Next_Main return String is
 523       begin
 524          if Current >= Names.Last then
 525             return "";
 526
 527          else
 528             Current := Current + 1;
 529             return Get_Name_String (Names.Table (Current));
 530          end if;
 531       end Next_Main;
 532
 533       ---------------------
 534       -- Number_Of_Mains --
 535       ---------------------
 536
 537       function Number_Of_Mains return Natural is
 538       begin
 539          return Names.Last;
 540       end Number_Of_Mains;
 541
 542       -----------
 543       -- Reset --
 544       -----------
 545
 546       procedure Reset is
 547       begin
 548          Current := 0;
 549       end Reset;
 550
 551    end Mains;
 552
 553    ----------
 554    -- Mark --
 555    ----------
 556
 557    procedure Mark (Source_File : File_Name_Type; Index : Int := 0) is
 558    begin
 559       Marks.Set (K => (File => Source_File, Index => Index), E => True);
 560    end Mark;
 561
 562    -----------------------
 563    -- Path_Or_File_Name --
 564    -----------------------
 565
 566    function Path_Or_File_Name (Path : Path_Name_Type) return String is
 567       Path_Name : constant String := Get_Name_String (Path);
 568    begin
 569       if Debug.Debug_Flag_F then
 570          return File_Name (Path_Name);
 571       else
 572          return Path_Name;
 573       end if;
 574    end Path_Or_File_Name;
 575
 576    ---------------------------
 577    -- Test_If_Relative_Path --
 578    ---------------------------
 579
 580    procedure Test_If_Relative_Path
 581      (Switch               : in out String_Access;
 582       Parent               : String_Access;
 583       Including_L_Switch   : Boolean := True;
 584       Including_Non_Switch : Boolean := True)
 585    is
 586    begin
 587       if Switch /= null then
 588          declare
 589             Sw : String (1 .. Switch'Length);
 590             Start : Positive;
 591
 592          begin
 593             Sw := Switch.all;
 594
 595             if Sw (1) = '-' then
 596                if Sw'Length >= 3
 597                  and then (Sw (2) = 'A'
 598                            or else Sw (2) = 'I'
 599                            or else (Including_L_Switch and then Sw (2) = 'L'))
 600                then
 601                   Start := 3;
 602
 603                   if Sw = "-I-" then
 604                      return;
 605                   end if;
 606
 607                elsif Sw'Length >= 4
 608                  and then (Sw (2 .. 3) = "aL"
 609                            or else Sw (2 .. 3) = "aO"
 610                            or else Sw (2 .. 3) = "aI")
 611                then
 612                   Start := 4;
 613
 614                else
 615                   return;
 616                end if;
 617
 618                --  Because relative path arguments to --RTS= may be relative
 619                --  to the search directory prefix, those relative path
 620                --  arguments are not converted.
 621
 622                if not Is_Absolute_Path (Sw (Start .. Sw'Last)) then
 623                   if Parent = null or else Parent'Length = 0 then
 624                      Do_Fail
 625                        ("relative search path switches (""",
 626                         Sw,
 627                         """) are not allowed");
 628
 629                   else
 630                      Switch :=
 631                        new String'
 632                          (Sw (1 .. Start - 1) &
 633                           Parent.all &
 634                           Directory_Separator &
 635                           Sw (Start .. Sw'Last));
 636                   end if;
 637                end if;
 638
 639             elsif Including_Non_Switch then
 640                if not Is_Absolute_Path (Sw) then
 641                   if Parent = null or else Parent'Length = 0 then
 642                      Do_Fail
 643                        ("relative paths (""", Sw, """) are not allowed");
 644
 645                   else
 646                      Switch :=
 647                        new String'(Parent.all & Directory_Separator & Sw);
 648                   end if;
 649                end if;
 650             end if;
 651          end;
 652       end if;
 653    end Test_If_Relative_Path;
 654
 655    -------------------
 656    -- Unit_Index_Of --
 657    -------------------
 658
 659    function Unit_Index_Of (ALI_File : File_Name_Type) return Int is
 660       Start  : Natural;
 661       Finish : Natural;
 662       Result : Int := 0;
 663
 664    begin
 665       Get_Name_String (ALI_File);
 666
 667       --  First, find the last dot
 668
 669       Finish := Name_Len;
 670
 671       while Finish >= 1 and then Name_Buffer (Finish) /= '.' loop
 672          Finish := Finish - 1;
 673       end loop;
 674
 675       if Finish = 1 then
 676          return 0;
 677       end if;
 678
 679       --  Now check that the dot is preceded by digits
 680
 681       Start := Finish;
 682       Finish := Finish - 1;
 683
 684       while Start >= 1 and then Name_Buffer (Start - 1) in '0' .. '9' loop
 685          Start := Start - 1;
 686       end loop;
 687
 688       --  If there are no digits, or if the digits are not preceded by
 689       --  the character that precedes a unit index, this is not the ALI file
 690       --  of a unit in a multi-unit source.
 691
 692       if Start > Finish
 693         or else Start = 1
 694         or else Name_Buffer (Start - 1) /= Multi_Unit_Index_Character
 695       then
 696          return 0;
 697       end if;
 698
 699       --  Build the index from the digit(s)
 700
 701       while Start <= Finish loop
 702          Result := Result * 10 +
 703                      Character'Pos (Name_Buffer (Start)) - Character'Pos ('0');
 704          Start := Start + 1;
 705       end loop;
 706
 707       return Result;
 708    end Unit_Index_Of;
 709
 710 end Makeutl;