gcc/ada/lib.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  L I B                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Style_Checks (All_Checks);
  35 --  Subprogram ordering not enforced in this unit
  36 --  (because of some logical groupings).
  37
  38 with Atree;   use Atree;
  39 with Einfo;   use Einfo;
  40 with Fname;   use Fname;
  41 with Output;  use Output;
  42 with Sinfo;   use Sinfo;
  43 with Sinput;  use Sinput;
  44 with Stand;   use Stand;
  45 with Stringt; use Stringt;
  46 with Tree_IO; use Tree_IO;
  47 with Uname;   use Uname;
  48
  49 package body Lib is
  50
  51    Switch_Storing_Enabled : Boolean := True;
  52    --  Set to False by Disable_Switch_Storing
  53
  54    -----------------------
  55    -- Local Subprograms --
  56    -----------------------
  57
  58    type SEU_Result is (
  59       Yes_Before, -- S1 is in same extended unit as S2 and appears before it
  60       Yes_Same,   -- S1 is in same extended unit as S2, Slocs are the same
  61       Yes_After,  -- S1 is in same extended unit as S2, and appears after it
  62       No);        -- S2 is not in same extended unit as S2
  63
  64    function Check_Same_Extended_Unit (S1, S2 : Source_Ptr) return SEU_Result;
  65    --  Used by In_Same_Extended_Unit and Earlier_In_Extended_Unit. Returns
  66    --  value as described above.
  67
  68    function Get_Code_Or_Source_Unit
  69      (S                : Source_Ptr;
  70       Unwind_Instances : Boolean) return Unit_Number_Type;
  71    --  Common code for Get_Code_Unit (get unit of instantiation for location)
  72    --  and Get_Source_Unit (get unit of template for location).
  73
  74    --------------------------------------------
  75    -- Access Functions for Unit Table Fields --
  76    --------------------------------------------
  77
  78    function Cunit (U : Unit_Number_Type) return Node_Id is
  79    begin
  80       return Units.Table (U).Cunit;
  81    end Cunit;
  82
  83    function Cunit_Entity (U : Unit_Number_Type) return Entity_Id is
  84    begin
  85       return Units.Table (U).Cunit_Entity;
  86    end Cunit_Entity;
  87
  88    function Dependency_Num (U : Unit_Number_Type) return Nat is
  89    begin
  90       return Units.Table (U).Dependency_Num;
  91    end Dependency_Num;
  92
  93    function Dynamic_Elab (U : Unit_Number_Type) return Boolean is
  94    begin
  95       return Units.Table (U).Dynamic_Elab;
  96    end Dynamic_Elab;
  97
  98    function Error_Location (U : Unit_Number_Type) return Source_Ptr is
  99    begin
 100       return Units.Table (U).Error_Location;
 101    end Error_Location;
 102
 103    function Expected_Unit (U : Unit_Number_Type) return Unit_Name_Type is
 104    begin
 105       return Units.Table (U).Expected_Unit;
 106    end Expected_Unit;
 107
 108    function Fatal_Error (U : Unit_Number_Type) return Boolean is
 109    begin
 110       return Units.Table (U).Fatal_Error;
 111    end Fatal_Error;
 112
 113    function Generate_Code (U : Unit_Number_Type) return Boolean is
 114    begin
 115       return Units.Table (U).Generate_Code;
 116    end Generate_Code;
 117
 118    function Has_RACW (U : Unit_Number_Type) return Boolean is
 119    begin
 120       return Units.Table (U).Has_RACW;
 121    end Has_RACW;
 122
 123    function Ident_String (U : Unit_Number_Type) return Node_Id is
 124    begin
 125       return Units.Table (U).Ident_String;
 126    end Ident_String;
 127
 128    function Loading (U : Unit_Number_Type) return Boolean is
 129    begin
 130       return Units.Table (U).Loading;
 131    end Loading;
 132
 133    function Main_Priority (U : Unit_Number_Type) return Int is
 134    begin
 135       return Units.Table (U).Main_Priority;
 136    end Main_Priority;
 137
 138    function Munit_Index (U : Unit_Number_Type) return Nat is
 139    begin
 140       return Units.Table (U).Munit_Index;
 141    end Munit_Index;
 142
 143    function Source_Index (U : Unit_Number_Type) return Source_File_Index is
 144    begin
 145       return Units.Table (U).Source_Index;
 146    end Source_Index;
 147
 148    function Unit_File_Name (U : Unit_Number_Type) return File_Name_Type is
 149    begin
 150       return Units.Table (U).Unit_File_Name;
 151    end Unit_File_Name;
 152
 153    function Unit_Name (U : Unit_Number_Type) return Unit_Name_Type is
 154    begin
 155       return Units.Table (U).Unit_Name;
 156    end Unit_Name;
 157
 158    ------------------------------------------
 159    -- Subprograms to Set Unit Table Fields --
 160    ------------------------------------------
 161
 162    procedure Set_Cunit (U : Unit_Number_Type; N : Node_Id) is
 163    begin
 164       Units.Table (U).Cunit := N;
 165    end Set_Cunit;
 166
 167    procedure Set_Cunit_Entity (U : Unit_Number_Type; E : Entity_Id) is
 168    begin
 169       Units.Table (U).Cunit_Entity := E;
 170       Set_Is_Compilation_Unit (E);
 171    end Set_Cunit_Entity;
 172
 173    procedure Set_Dynamic_Elab (U : Unit_Number_Type; B : Boolean := True) is
 174    begin
 175       Units.Table (U).Dynamic_Elab := B;
 176    end Set_Dynamic_Elab;
 177
 178    procedure Set_Error_Location (U : Unit_Number_Type; W : Source_Ptr) is
 179    begin
 180       Units.Table (U).Error_Location := W;
 181    end Set_Error_Location;
 182
 183    procedure Set_Fatal_Error (U : Unit_Number_Type; B : Boolean := True) is
 184    begin
 185       Units.Table (U).Fatal_Error := B;
 186    end Set_Fatal_Error;
 187
 188    procedure Set_Generate_Code (U : Unit_Number_Type; B : Boolean := True) is
 189    begin
 190       Units.Table (U).Generate_Code := B;
 191    end Set_Generate_Code;
 192
 193    procedure Set_Has_RACW (U : Unit_Number_Type; B : Boolean := True) is
 194    begin
 195       Units.Table (U).Has_RACW := B;
 196    end Set_Has_RACW;
 197
 198    procedure Set_Ident_String (U : Unit_Number_Type; N : Node_Id) is
 199    begin
 200       Units.Table (U).Ident_String := N;
 201    end Set_Ident_String;
 202
 203    procedure Set_Loading (U : Unit_Number_Type; B : Boolean := True) is
 204    begin
 205       Units.Table (U).Loading := B;
 206    end Set_Loading;
 207
 208    procedure Set_Main_Priority (U : Unit_Number_Type; P : Int) is
 209    begin
 210       Units.Table (U).Main_Priority := P;
 211    end Set_Main_Priority;
 212
 213    procedure Set_Unit_Name (U : Unit_Number_Type; N : Unit_Name_Type) is
 214    begin
 215       Units.Table (U).Unit_Name := N;
 216    end Set_Unit_Name;
 217
 218    ------------------------------
 219    -- Check_Same_Extended_Unit --
 220    ------------------------------
 221
 222    function Check_Same_Extended_Unit (S1, S2 : Source_Ptr) return SEU_Result is
 223       Sloc1  : Source_Ptr;
 224       Sloc2  : Source_Ptr;
 225       Sind1  : Source_File_Index;
 226       Sind2  : Source_File_Index;
 227       Inst1  : Source_Ptr;
 228       Inst2  : Source_Ptr;
 229       Unum1  : Unit_Number_Type;
 230       Unum2  : Unit_Number_Type;
 231       Unit1  : Node_Id;
 232       Unit2  : Node_Id;
 233       Depth1 : Nat;
 234       Depth2 : Nat;
 235
 236    begin
 237       if S1 = No_Location or else S2 = No_Location then
 238          return No;
 239
 240       elsif S1 = Standard_Location then
 241          if S2 = Standard_Location then
 242             return Yes_Same;
 243          else
 244             return No;
 245          end if;
 246
 247       elsif S2 = Standard_Location then
 248          return No;
 249       end if;
 250
 251       Sloc1 := S1;
 252       Sloc2 := S2;
 253       Unum1 := Get_Code_Unit (Sloc1);
 254       Unum2 := Get_Code_Unit (Sloc2);
 255
 256       loop
 257          Sind1 := Get_Source_File_Index (Sloc1);
 258          Sind2 := Get_Source_File_Index (Sloc2);
 259
 260          if Sind1 = Sind2 then
 261             if Sloc1 < Sloc2 then
 262                return Yes_Before;
 263             elsif Sloc1 > Sloc2 then
 264                return Yes_After;
 265             else
 266                return Yes_Same;
 267             end if;
 268          end if;
 269
 270          --  OK, the two nodes are in separate source elements, but this is not
 271          --  decisive, because of the issue of subunits and instantiations.
 272
 273          --  First we deal with subunits, since if the subunit is in an
 274          --  instantiation, we know that the parent is in the corresponding
 275          --  instantiation, since that is the only way we can have a subunit
 276          --  that is part of an instantiation.
 277
 278          Unit1 := Unit (Cunit (Unum1));
 279          Unit2 := Unit (Cunit (Unum2));
 280
 281          if Nkind (Unit1) = N_Subunit
 282            and then Present (Corresponding_Stub (Unit1))
 283          then
 284             --  Both in subunits. They could have a common ancestor. If they
 285             --  do, then the deeper one must have a longer unit name. Replace
 286             --  the deeper one with its corresponding stub, in order to find
 287             --  nearest common ancestor, if any.
 288
 289             if Nkind (Unit2) = N_Subunit
 290               and then Present (Corresponding_Stub (Unit2))
 291             then
 292                if Length_Of_Name (Unit_Name (Unum1)) <
 293                   Length_Of_Name (Unit_Name (Unum2))
 294                then
 295                   Sloc2 := Sloc (Corresponding_Stub (Unit2));
 296                   Unum2 := Get_Source_Unit (Sloc2);
 297                   goto Continue;
 298
 299                else
 300                   Sloc1 := Sloc (Corresponding_Stub (Unit1));
 301                   Unum1 := Get_Source_Unit (Sloc1);
 302                   goto Continue;
 303                end if;
 304
 305             --  Nod1 in subunit, Nod2 not
 306
 307             else
 308                Sloc1 := Sloc (Corresponding_Stub (Unit1));
 309                Unum1 := Get_Source_Unit (Sloc1);
 310                goto Continue;
 311             end if;
 312
 313          --  Nod2 in subunit, Nod1 not
 314
 315          elsif Nkind (Unit2) = N_Subunit
 316            and then Present (Corresponding_Stub (Unit2))
 317          then
 318             Sloc2 := Sloc (Corresponding_Stub (Unit2));
 319             Unum2 := Get_Source_Unit (Sloc2);
 320             goto Continue;
 321          end if;
 322
 323          --  At this stage we know that neither is a subunit, so we deal
 324          --  with instantiations, since we culd have a common ancestor
 325
 326          Inst1 := Instantiation (Sind1);
 327          Inst2 := Instantiation (Sind2);
 328
 329          if Inst1 /= No_Location then
 330
 331             --  Both are instantiations
 332
 333             if Inst2 /= No_Location then
 334
 335                Depth1 := Instantiation_Depth (Sloc1);
 336                Depth2 := Instantiation_Depth (Sloc2);
 337
 338                if Depth1 < Depth2 then
 339                   Sloc2 := Inst2;
 340                   Unum2 := Get_Source_Unit (Sloc2);
 341                   goto Continue;
 342
 343                elsif Depth1 > Depth2 then
 344                   Sloc1 := Inst1;
 345                   Unum1 := Get_Source_Unit (Sloc1);
 346                   goto Continue;
 347
 348                else
 349                   Sloc1 := Inst1;
 350                   Sloc2 := Inst2;
 351                   Unum1 := Get_Source_Unit (Sloc1);
 352                   Unum2 := Get_Source_Unit (Sloc2);
 353                   goto Continue;
 354                end if;
 355
 356             --  Only first node is in instantiation
 357
 358             else
 359                Sloc1 := Inst1;
 360                Unum1 := Get_Source_Unit (Sloc1);
 361                goto Continue;
 362             end if;
 363
 364          --  Only second node is instantiation
 365
 366          elsif Inst2 /= No_Location then
 367             Sloc2 := Inst2;
 368             Unum2 := Get_Source_Unit (Sloc2);
 369             goto Continue;
 370          end if;
 371
 372          --  No instantiations involved, so we are not in the same unit
 373          --  However, there is one case still to check, namely the case
 374          --  where one location is in the spec, and the other in the
 375          --  corresponding body (the spec location is earlier).
 376
 377          if Nkind (Unit1) = N_Subprogram_Body
 378               or else
 379             Nkind (Unit1) = N_Package_Body
 380          then
 381             if Library_Unit (Cunit (Unum1)) = Cunit (Unum2) then
 382                return Yes_After;
 383             end if;
 384
 385          elsif Nkind (Unit2) = N_Subprogram_Body
 386                  or else
 387                Nkind (Unit2) = N_Package_Body
 388          then
 389             if Library_Unit (Cunit (Unum2)) = Cunit (Unum1) then
 390                return Yes_Before;
 391             end if;
 392          end if;
 393
 394          --  If that special case does not occur, then we are certain that
 395          --  the two locations are really in separate units.
 396
 397          return No;
 398
 399          <<Continue>>
 400             null;
 401       end loop;
 402    end Check_Same_Extended_Unit;
 403
 404    -------------------------------
 405    -- Compilation_Switches_Last --
 406    -------------------------------
 407
 408    function Compilation_Switches_Last return Nat is
 409    begin
 410       return Compilation_Switches.Last;
 411    end Compilation_Switches_Last;
 412
 413    procedure Disable_Switch_Storing is
 414    begin
 415       Switch_Storing_Enabled := False;
 416    end Disable_Switch_Storing;
 417
 418    ------------------------------
 419    -- Earlier_In_Extended_Unit --
 420    ------------------------------
 421
 422    function Earlier_In_Extended_Unit (S1, S2 : Source_Ptr) return Boolean is
 423    begin
 424       return Check_Same_Extended_Unit (S1, S2) = Yes_Before;
 425    end Earlier_In_Extended_Unit;
 426
 427    ----------------------------
 428    -- Entity_Is_In_Main_Unit --
 429    ----------------------------
 430
 431    function Entity_Is_In_Main_Unit (E : Entity_Id) return Boolean is
 432       S : Entity_Id;
 433
 434    begin
 435       S := Scope (E);
 436
 437       while S /= Standard_Standard loop
 438          if S = Main_Unit_Entity then
 439             return True;
 440          elsif Ekind (S) = E_Package and then Is_Child_Unit (S) then
 441             return False;
 442          else
 443             S := Scope (S);
 444          end if;
 445       end loop;
 446
 447       return False;
 448    end Entity_Is_In_Main_Unit;
 449
 450    --------------------------
 451    -- Generic_May_Lack_ALI --
 452    --------------------------
 453
 454    function Generic_May_Lack_ALI (Sfile : File_Name_Type) return Boolean is
 455    begin
 456       --  We allow internal generic units to be used without having a
 457       --  corresponding ALI files to help bootstrapping with older compilers
 458       --  that did not support generating ALIs for such generics. It is safe
 459       --  to do so because the only thing the generated code would contain
 460       --  is the elaboration boolean, and we are careful to elaborate all
 461       --  predefined units first anyway.
 462
 463       return Is_Internal_File_Name
 464                (Fname              => Sfile,
 465                 Renamings_Included => True);
 466    end Generic_May_Lack_ALI;
 467
 468    -----------------------------
 469    -- Get_Code_Or_Source_Unit --
 470    -----------------------------
 471
 472    function Get_Code_Or_Source_Unit
 473      (S                : Source_Ptr;
 474       Unwind_Instances : Boolean) return Unit_Number_Type
 475    is
 476    begin
 477       --  Search table unless we have No_Location, which can happen if the
 478       --  relevant location has not been set yet. Happens for example when
 479       --  we obtain Sloc (Cunit (Main_Unit)) before it is set.
 480
 481       if S /= No_Location then
 482          declare
 483             Source_File : Source_File_Index;
 484             Source_Unit : Unit_Number_Type;
 485
 486          begin
 487             Source_File := Get_Source_File_Index (S);
 488
 489             if Unwind_Instances then
 490                while Template (Source_File) /= No_Source_File loop
 491                   Source_File := Template (Source_File);
 492                end loop;
 493             end if;
 494
 495             Source_Unit := Unit (Source_File);
 496
 497             if Source_Unit /= No_Unit then
 498                return Source_Unit;
 499             end if;
 500          end;
 501       end if;
 502
 503       --  If S was No_Location, or was not in the table, we must be in the main
 504       --  source unit (and the value has not been placed in the table yet),
 505       --  or in one of the configuration pragma files.
 506
 507       return Main_Unit;
 508    end Get_Code_Or_Source_Unit;
 509
 510    -------------------
 511    -- Get_Code_Unit --
 512    -------------------
 513
 514    function Get_Code_Unit (S : Source_Ptr) return Unit_Number_Type is
 515    begin
 516       return Get_Code_Or_Source_Unit (Top_Level_Location (S),
 517         Unwind_Instances => False);
 518    end Get_Code_Unit;
 519
 520    function Get_Code_Unit (N : Node_Or_Entity_Id) return Unit_Number_Type is
 521    begin
 522       return Get_Code_Unit (Sloc (N));
 523    end Get_Code_Unit;
 524
 525    ----------------------------
 526    -- Get_Compilation_Switch --
 527    ----------------------------
 528
 529    function Get_Compilation_Switch (N : Pos) return String_Ptr is
 530    begin
 531       if N <= Compilation_Switches.Last then
 532          return Compilation_Switches.Table (N);
 533
 534       else
 535          return null;
 536       end if;
 537    end Get_Compilation_Switch;
 538
 539    ----------------------------------
 540    -- Get_Cunit_Entity_Unit_Number --
 541    ----------------------------------
 542
 543    function Get_Cunit_Entity_Unit_Number
 544      (E : Entity_Id) return Unit_Number_Type
 545    is
 546    begin
 547       for U in Units.First .. Units.Last loop
 548          if Cunit_Entity (U) = E then
 549             return U;
 550          end if;
 551       end loop;
 552
 553       --  If not in the table, must be the main source unit, and we just
 554       --  have not got it put into the table yet.
 555
 556       return Main_Unit;
 557    end Get_Cunit_Entity_Unit_Number;
 558
 559    ---------------------------
 560    -- Get_Cunit_Unit_Number --
 561    ---------------------------
 562
 563    function Get_Cunit_Unit_Number (N : Node_Id) return Unit_Number_Type is
 564    begin
 565       for U in Units.First .. Units.Last loop
 566          if Cunit (U) = N then
 567             return U;
 568          end if;
 569       end loop;
 570
 571       --  If not in the table, must be the main source unit, and we just
 572       --  have not got it put into the table yet.
 573
 574       return Main_Unit;
 575    end Get_Cunit_Unit_Number;
 576
 577    ---------------------
 578    -- Get_Source_Unit --
 579    ---------------------
 580
 581    function Get_Source_Unit (S : Source_Ptr) return Unit_Number_Type is
 582    begin
 583       return Get_Code_Or_Source_Unit (S, Unwind_Instances => True);
 584    end Get_Source_Unit;
 585
 586    function Get_Source_Unit (N : Node_Or_Entity_Id) return Unit_Number_Type is
 587    begin
 588       return Get_Source_Unit (Sloc (N));
 589    end Get_Source_Unit;
 590
 591    --------------------------------
 592    -- In_Extended_Main_Code_Unit --
 593    --------------------------------
 594
 595    function In_Extended_Main_Code_Unit
 596      (N : Node_Or_Entity_Id) return Boolean
 597    is
 598    begin
 599       if Sloc (N) = Standard_Location then
 600          return True;
 601
 602       elsif Sloc (N) = No_Location then
 603          return False;
 604
 605       --  Special case Itypes to test the Sloc of the associated node. The
 606       --  reason we do this is for possible calls from gigi after -gnatD
 607       --  processing is complete in sprint. This processing updates the
 608       --  sloc fields of all nodes in the tree, but itypes are not in the
 609       --  tree so their slocs do not get updated.
 610
 611       elsif Nkind (N) = N_Defining_Identifier
 612         and then Is_Itype (N)
 613       then
 614          return In_Extended_Main_Code_Unit (Associated_Node_For_Itype (N));
 615
 616       --  Otherwise see if we are in the main unit
 617
 618       elsif Get_Code_Unit (Sloc (N)) = Get_Code_Unit (Cunit (Main_Unit)) then
 619          return True;
 620
 621       --  Node may be in spec (or subunit etc) of main unit
 622
 623       else
 624          return
 625            In_Same_Extended_Unit (N, Cunit (Main_Unit));
 626       end if;
 627    end In_Extended_Main_Code_Unit;
 628
 629    function In_Extended_Main_Code_Unit (Loc : Source_Ptr) return Boolean is
 630    begin
 631       if Loc = Standard_Location then
 632          return True;
 633
 634       elsif Loc = No_Location then
 635          return False;
 636
 637       --  Otherwise see if we are in the main unit
 638
 639       elsif Get_Code_Unit (Loc) = Get_Code_Unit (Cunit (Main_Unit)) then
 640          return True;
 641
 642       --  Location may be in spec (or subunit etc) of main unit
 643
 644       else
 645          return
 646            In_Same_Extended_Unit (Loc, Sloc (Cunit (Main_Unit)));
 647       end if;
 648    end In_Extended_Main_Code_Unit;
 649
 650    ----------------------------------
 651    -- In_Extended_Main_Source_Unit --
 652    ----------------------------------
 653
 654    function In_Extended_Main_Source_Unit
 655      (N : Node_Or_Entity_Id) return Boolean
 656    is
 657       Nloc : constant Source_Ptr := Sloc (N);
 658       Mloc : constant Source_Ptr := Sloc (Cunit (Main_Unit));
 659
 660    begin
 661       --  If Mloc is not set, it means we are still parsing the main unit,
 662       --  so everything so far is in the extended main source unit.
 663
 664       if Mloc = No_Location then
 665          return True;
 666
 667       --  Special value cases
 668
 669       elsif Nloc = Standard_Location then
 670          return True;
 671
 672       elsif Nloc = No_Location then
 673          return False;
 674
 675       --  Special case Itypes to test the Sloc of the associated node. The
 676       --  reason we do this is for possible calls from gigi after -gnatD
 677       --  processing is complete in sprint. This processing updates the
 678       --  sloc fields of all nodes in the tree, but itypes are not in the
 679       --  tree so their slocs do not get updated.
 680
 681       elsif Nkind (N) = N_Defining_Identifier
 682         and then Is_Itype (N)
 683       then
 684          return In_Extended_Main_Source_Unit (Associated_Node_For_Itype (N));
 685
 686       --  Otherwise compare original locations to see if in same unit
 687
 688       else
 689          return
 690            In_Same_Extended_Unit
 691              (Original_Location (Nloc), Original_Location (Mloc));
 692       end if;
 693    end In_Extended_Main_Source_Unit;
 694
 695    function In_Extended_Main_Source_Unit
 696      (Loc : Source_Ptr) return Boolean
 697    is
 698       Mloc : constant Source_Ptr := Sloc (Cunit (Main_Unit));
 699
 700    begin
 701       --  If Mloc is not set, it means we are still parsing the main unit,
 702       --  so everything so far is in the extended main source unit.
 703
 704       if Mloc = No_Location then
 705          return True;
 706
 707       --  Special value cases
 708
 709       elsif Loc = Standard_Location then
 710          return True;
 711
 712       elsif Loc = No_Location then
 713          return False;
 714
 715       --  Otherwise compare original locations to see if in same unit
 716
 717       else
 718          return
 719            In_Same_Extended_Unit
 720              (Original_Location (Loc), Original_Location (Mloc));
 721       end if;
 722    end In_Extended_Main_Source_Unit;
 723
 724    ------------------------
 725    -- In_Predefined_Unit --
 726    ------------------------
 727
 728    function In_Predefined_Unit (N : Node_Or_Entity_Id) return Boolean is
 729    begin
 730       return In_Predefined_Unit (Sloc (N));
 731    end In_Predefined_Unit;
 732
 733    function In_Predefined_Unit (S : Source_Ptr) return Boolean is
 734       Unit : constant Unit_Number_Type := Get_Source_Unit (S);
 735       File : constant File_Name_Type   := Unit_File_Name (Unit);
 736    begin
 737       return Is_Predefined_File_Name (File);
 738    end In_Predefined_Unit;
 739
 740    -----------------------
 741    -- In_Same_Code_Unit --
 742    -----------------------
 743
 744    function In_Same_Code_Unit (N1, N2 : Node_Or_Entity_Id) return Boolean is
 745       S1 : constant Source_Ptr := Sloc (N1);
 746       S2 : constant Source_Ptr := Sloc (N2);
 747
 748    begin
 749       if S1 = No_Location or else S2 = No_Location then
 750          return False;
 751
 752       elsif S1 = Standard_Location then
 753          return S2 = Standard_Location;
 754
 755       elsif S2 = Standard_Location then
 756          return False;
 757       end if;
 758
 759       return Get_Code_Unit (N1) = Get_Code_Unit (N2);
 760    end In_Same_Code_Unit;
 761
 762    ---------------------------
 763    -- In_Same_Extended_Unit --
 764    ---------------------------
 765
 766    function In_Same_Extended_Unit
 767      (N1, N2 : Node_Or_Entity_Id) return Boolean
 768    is
 769    begin
 770       return Check_Same_Extended_Unit (Sloc (N1), Sloc (N2)) /= No;
 771    end In_Same_Extended_Unit;
 772
 773    function In_Same_Extended_Unit (S1, S2 : Source_Ptr) return Boolean is
 774    begin
 775       return Check_Same_Extended_Unit (S1, S2) /= No;
 776    end In_Same_Extended_Unit;
 777
 778    -------------------------
 779    -- In_Same_Source_Unit --
 780    -------------------------
 781
 782    function In_Same_Source_Unit (N1, N2 : Node_Or_Entity_Id) return Boolean is
 783       S1 : constant Source_Ptr := Sloc (N1);
 784       S2 : constant Source_Ptr := Sloc (N2);
 785
 786    begin
 787       if S1 = No_Location or else S2 = No_Location then
 788          return False;
 789
 790       elsif S1 = Standard_Location then
 791          return S2 = Standard_Location;
 792
 793       elsif S2 = Standard_Location then
 794          return False;
 795       end if;
 796
 797       return Get_Source_Unit (N1) = Get_Source_Unit (N2);
 798    end In_Same_Source_Unit;
 799
 800    -----------------------------
 801    -- Increment_Serial_Number --
 802    -----------------------------
 803
 804    function Increment_Serial_Number return Nat is
 805       TSN : Int renames Units.Table (Current_Sem_Unit).Serial_Number;
 806    begin
 807       TSN := TSN + 1;
 808       return TSN;
 809    end Increment_Serial_Number;
 810
 811    ----------------
 812    -- Initialize --
 813    ----------------
 814
 815    procedure Initialize is
 816    begin
 817       Linker_Option_Lines.Init;
 818       Load_Stack.Init;
 819       Units.Init;
 820       Compilation_Switches.Init;
 821    end Initialize;
 822
 823    ---------------
 824    -- Is_Loaded --
 825    ---------------
 826
 827    function Is_Loaded (Uname : Unit_Name_Type) return Boolean is
 828    begin
 829       for Unum in Units.First .. Units.Last loop
 830          if Uname = Unit_Name (Unum) then
 831             return True;
 832          end if;
 833       end loop;
 834
 835       return False;
 836    end Is_Loaded;
 837
 838    ---------------
 839    -- Last_Unit --
 840    ---------------
 841
 842    function Last_Unit return Unit_Number_Type is
 843    begin
 844       return Units.Last;
 845    end Last_Unit;
 846
 847    ----------
 848    -- List --
 849    ----------
 850
 851    procedure List (File_Names_Only : Boolean := False) is separate;
 852
 853    ----------
 854    -- Lock --
 855    ----------
 856
 857    procedure Lock is
 858    begin
 859       Linker_Option_Lines.Locked := True;
 860       Load_Stack.Locked := True;
 861       Units.Locked := True;
 862       Linker_Option_Lines.Release;
 863       Load_Stack.Release;
 864       Units.Release;
 865    end Lock;
 866
 867    ---------------
 868    -- Num_Units --
 869    ---------------
 870
 871    function Num_Units return Nat is
 872    begin
 873       return Int (Units.Last) - Int (Main_Unit) + 1;
 874    end Num_Units;
 875
 876    -----------------
 877    -- Remove_Unit --
 878    -----------------
 879
 880    procedure Remove_Unit (U : Unit_Number_Type) is
 881    begin
 882       if U = Units.Last then
 883          Units.Decrement_Last;
 884       end if;
 885    end Remove_Unit;
 886
 887    ----------------------------------
 888    -- Replace_Linker_Option_String --
 889    ----------------------------------
 890
 891    procedure Replace_Linker_Option_String
 892      (S : String_Id; Match_String : String)
 893    is
 894    begin
 895       if Match_String'Length > 0 then
 896          for J in 1 .. Linker_Option_Lines.Last loop
 897             String_To_Name_Buffer (Linker_Option_Lines.Table (J).Option);
 898
 899             if Match_String = Name_Buffer (1 .. Match_String'Length) then
 900                Linker_Option_Lines.Table (J).Option := S;
 901                return;
 902             end if;
 903          end loop;
 904       end if;
 905
 906       Store_Linker_Option_String (S);
 907    end Replace_Linker_Option_String;
 908
 909    ----------
 910    -- Sort --
 911    ----------
 912
 913    procedure Sort (Tbl : in out Unit_Ref_Table) is separate;
 914
 915    ------------------------------
 916    -- Store_Compilation_Switch --
 917    ------------------------------
 918
 919    procedure Store_Compilation_Switch (Switch : String) is
 920    begin
 921       if Switch_Storing_Enabled then
 922          Compilation_Switches.Increment_Last;
 923          Compilation_Switches.Table (Compilation_Switches.Last) :=
 924            new String'(Switch);
 925
 926          --  Fix up --RTS flag which has been transformed by the gcc driver
 927          --  into -fRTS
 928
 929          if Switch'Last >= Switch'First + 4
 930            and then Switch (Switch'First .. Switch'First + 4) = "-fRTS"
 931          then
 932             Compilation_Switches.Table
 933               (Compilation_Switches.Last) (Switch'First + 1) := '-';
 934          end if;
 935       end if;
 936    end Store_Compilation_Switch;
 937
 938    --------------------------------
 939    -- Store_Linker_Option_String --
 940    --------------------------------
 941
 942    procedure Store_Linker_Option_String (S : String_Id) is
 943    begin
 944       Linker_Option_Lines.Increment_Last;
 945       Linker_Option_Lines.Table (Linker_Option_Lines.Last) :=
 946         (Option => S, Unit => Current_Sem_Unit);
 947    end Store_Linker_Option_String;
 948
 949    -------------------------------
 950    -- Synchronize_Serial_Number --
 951    -------------------------------
 952
 953    procedure Synchronize_Serial_Number is
 954       TSN : Int renames Units.Table (Current_Sem_Unit).Serial_Number;
 955    begin
 956       TSN := TSN + 1;
 957    end Synchronize_Serial_Number;
 958
 959    ---------------
 960    -- Tree_Read --
 961    ---------------
 962
 963    procedure Tree_Read is
 964       N : Nat;
 965       S : String_Ptr;
 966
 967    begin
 968       Units.Tree_Read;
 969
 970       --  Read Compilation_Switches table. First release the memory occupied
 971       --  by the previously loaded switches.
 972
 973       for J in Compilation_Switches.First .. Compilation_Switches.Last loop
 974          Free (Compilation_Switches.Table (J));
 975       end loop;
 976
 977       Tree_Read_Int (N);
 978       Compilation_Switches.Set_Last (N);
 979
 980       for J in 1 .. N loop
 981          Tree_Read_Str (S);
 982          Compilation_Switches.Table (J) := S;
 983       end loop;
 984    end Tree_Read;
 985
 986    ----------------
 987    -- Tree_Write --
 988    ----------------
 989
 990    procedure Tree_Write is
 991    begin
 992       Units.Tree_Write;
 993
 994       --  Write Compilation_Switches table
 995
 996       Tree_Write_Int (Compilation_Switches.Last);
 997
 998       for J in 1 .. Compilation_Switches.Last loop
 999          Tree_Write_Str (Compilation_Switches.Table (J));
1000       end loop;
1001    end Tree_Write;
1002
1003    ------------
1004    -- Unlock --
1005    ------------
1006
1007    procedure Unlock is
1008    begin
1009       Linker_Option_Lines.Locked := False;
1010       Load_Stack.Locked := False;
1011       Units.Locked := False;
1012    end Unlock;
1013
1014    -----------------
1015    -- Version_Get --
1016    -----------------
1017
1018    function Version_Get (U : Unit_Number_Type) return Word_Hex_String is
1019    begin
1020       return Get_Hex_String (Units.Table (U).Version);
1021    end Version_Get;
1022
1023    ------------------------
1024    -- Version_Referenced --
1025    ------------------------
1026
1027    procedure Version_Referenced (S : String_Id) is
1028    begin
1029       Version_Ref.Append (S);
1030    end Version_Referenced;
1031
1032 end Lib;