gcc/ada/lib-load.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . L O A D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Fname;    use Fname;
  31 with Fname.UF; use Fname.UF;
  32 with Nlists;   use Nlists;
  33 with Nmake;    use Nmake;
  34 with Opt;      use Opt;
  35 with Osint;    use Osint;
  36 with Osint.C;  use Osint.C;
  37 with Output;   use Output;
  38 with Par;
  39 with Restrict; use Restrict;
  40 with Scn;      use Scn;
  41 with Sinfo;    use Sinfo;
  42 with Sinput;   use Sinput;
  43 with Sinput.L; use Sinput.L;
  44 with Stand;    use Stand;
  45 with Tbuild;   use Tbuild;
  46 with Uname;    use Uname;
  47
  48 package body Lib.Load is
  49
  50    -----------------------
  51    -- Local Subprograms --
  52    -----------------------
  53
  54    function From_Limited_With_Chain return Boolean;
  55    --  Check whether a possible circular dependence includes units that
  56    --  have been loaded through limited_with clauses, in which case there
  57    --  is no real circularity.
  58
  59    function Spec_Is_Irrelevant
  60      (Spec_Unit : Unit_Number_Type;
  61       Body_Unit : Unit_Number_Type) return Boolean;
  62    --  The Spec_Unit and Body_Unit parameters are the unit numbers of the
  63    --  spec file that corresponds to the main unit which is a body. This
  64    --  function determines if the spec file is irrelevant and will be
  65    --  overridden by the body as described in RM 10.1.4(4). See description
  66    --  in "Special Handling of Subprogram Bodies" for further details.
  67
  68    procedure Write_Dependency_Chain;
  69    --  This procedure is used to generate error message info lines that
  70    --  trace the current dependency chain when a load error occurs.
  71
  72    ------------------------------
  73    -- Change_Main_Unit_To_Spec --
  74    ------------------------------
  75
  76    procedure Change_Main_Unit_To_Spec is
  77       U : Unit_Record renames Units.Table (Main_Unit);
  78       N : File_Name_Type;
  79       X : Source_File_Index;
  80
  81    begin
  82       --  Get name of unit body
  83
  84       Get_Name_String (U.Unit_File_Name);
  85
  86       --  Note: for the following we should really generalize and consult the
  87       --  file name pattern data, but for now we just deal with the common
  88       --  naming cases, which is probably good enough in practice ???
  89
  90       --  Change .adb to .ads
  91
  92       if Name_Len >= 5
  93         and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".adb"
  94       then
  95          Name_Buffer (Name_Len) := 's';
  96
  97       --  Change .2.ada to .1.ada (Rational convention)
  98
  99       elsif Name_Len >= 7
 100         and then Name_Buffer (Name_Len - 5 .. Name_Len) = ".2.ada"
 101       then
 102          Name_Buffer (Name_Len - 4) := '1';
 103
 104       --  Change .ada to _.ada (DEC convention)
 105
 106       elsif Name_Len >= 5
 107         and then Name_Buffer (Name_Len - 3 .. Name_Len) = ".ada"
 108       then
 109          Name_Buffer (Name_Len - 3 .. Name_Len + 1) := "_.ada";
 110          Name_Len := Name_Len + 1;
 111
 112       --  No match, don't make the change
 113
 114       else
 115          return;
 116       end if;
 117
 118       --  Try loading the spec
 119
 120       N := Name_Find;
 121       X := Load_Source_File (N);
 122
 123       --  No change if we did not find the spec
 124
 125       if X = No_Source_File then
 126          return;
 127       end if;
 128
 129       --  Otherwise modify Main_Unit entry to point to spec
 130
 131       U.Unit_File_Name := N;
 132       U.Source_Index := X;
 133    end Change_Main_Unit_To_Spec;
 134
 135    -------------------------------
 136    -- Create_Dummy_Package_Unit --
 137    -------------------------------
 138
 139    function Create_Dummy_Package_Unit
 140      (With_Node : Node_Id;
 141       Spec_Name : Unit_Name_Type) return Unit_Number_Type
 142    is
 143       Unum         : Unit_Number_Type;
 144       Cunit_Entity : Entity_Id;
 145       Cunit        : Node_Id;
 146       Du_Name      : Node_Or_Entity_Id;
 147       End_Lab      : Node_Id;
 148       Save_CS      : constant Boolean := Get_Comes_From_Source_Default;
 149
 150    begin
 151       --  The created dummy package unit does not come from source
 152
 153       Set_Comes_From_Source_Default (False);
 154
 155       --  Normal package
 156
 157       if Nkind (Name (With_Node)) = N_Identifier then
 158          Cunit_Entity :=
 159            Make_Defining_Identifier (No_Location,
 160              Chars => Chars (Name (With_Node)));
 161          Du_Name := Cunit_Entity;
 162          End_Lab := New_Occurrence_Of (Cunit_Entity, No_Location);
 163
 164       --  Child package
 165
 166       else
 167          Cunit_Entity :=
 168            Make_Defining_Identifier (No_Location,
 169              Chars => Chars (Selector_Name (Name (With_Node))));
 170          Du_Name :=
 171            Make_Defining_Program_Unit_Name (No_Location,
 172              Name => New_Copy_Tree (Prefix (Name (With_Node))),
 173              Defining_Identifier => Cunit_Entity);
 174
 175          Set_Is_Child_Unit (Cunit_Entity);
 176
 177          End_Lab :=
 178            Make_Designator (No_Location,
 179              Name => New_Copy_Tree (Prefix (Name (With_Node))),
 180              Identifier => New_Occurrence_Of (Cunit_Entity, No_Location));
 181       end if;
 182
 183       Set_Scope (Cunit_Entity, Standard_Standard);
 184
 185       Cunit :=
 186         Make_Compilation_Unit (No_Location,
 187           Context_Items => Empty_List,
 188           Unit =>
 189             Make_Package_Declaration (No_Location,
 190               Specification =>
 191                 Make_Package_Specification (No_Location,
 192                   Defining_Unit_Name   => Du_Name,
 193                   Visible_Declarations => Empty_List,
 194                   End_Label            => End_Lab)),
 195           Aux_Decls_Node =>
 196             Make_Compilation_Unit_Aux (No_Location));
 197
 198       --  Mark the dummy package as analyzed to prevent analysis of this
 199       --  (non-existent) unit in -gnatQ mode because at the moment the
 200       --  structure and attributes of this dummy package does not allow
 201       --  a normal analysis of this unit
 202
 203       Set_Analyzed (Cunit);
 204
 205       Units.Increment_Last;
 206       Unum := Units.Last;
 207
 208       Units.Table (Unum) := (
 209         Cunit            => Cunit,
 210         Cunit_Entity     => Cunit_Entity,
 211         Dependency_Num   => 0,
 212         Dynamic_Elab     => False,
 213         Error_Location   => Sloc (With_Node),
 214         Expected_Unit    => Spec_Name,
 215         Fatal_Error      => True,
 216         Generate_Code    => False,
 217         Has_RACW         => False,
 218         Is_Compiler_Unit => False,
 219         Ident_String     => Empty,
 220         Loading          => False,
 221         Main_Priority    => Default_Main_Priority,
 222         Munit_Index      => 0,
 223         Serial_Number    => 0,
 224         Source_Index     => No_Source_File,
 225         Unit_File_Name   => Get_File_Name (Spec_Name, Subunit => False),
 226         Unit_Name        => Spec_Name,
 227         Version          => 0,
 228         OA_Setting       => 'O');
 229
 230       Set_Comes_From_Source_Default (Save_CS);
 231       Set_Error_Posted (Cunit_Entity);
 232       Set_Error_Posted (Cunit);
 233       return Unum;
 234    end Create_Dummy_Package_Unit;
 235
 236    -----------------------------
 237    -- From_Limited_With_Chain --
 238    -----------------------------
 239
 240    function From_Limited_With_Chain return Boolean is
 241       Curr_Num : constant Unit_Number_Type :=
 242                    Load_Stack.Table (Load_Stack.Last).Unit_Number;
 243
 244    begin
 245       --  True if the current load operation is through a limited_with clause
 246       --  and we are not within a loop of regular with_clauses.
 247
 248       for U in reverse Load_Stack.First .. Load_Stack.Last - 1 loop
 249          if Load_Stack.Table (U).Unit_Number = Curr_Num then
 250             return False;
 251
 252          elsif Present (Load_Stack.Table (U).With_Node)
 253            and then Limited_Present (Load_Stack.Table (U).With_Node)
 254          then
 255             return True;
 256          end if;
 257       end loop;
 258
 259       return False;
 260    end From_Limited_With_Chain;
 261
 262    ----------------
 263    -- Initialize --
 264    ----------------
 265
 266    procedure Initialize is
 267    begin
 268       Units.Init;
 269       Load_Stack.Init;
 270    end Initialize;
 271
 272    ------------------------
 273    -- Initialize_Version --
 274    ------------------------
 275
 276    procedure Initialize_Version (U : Unit_Number_Type) is
 277    begin
 278       Units.Table (U).Version := Source_Checksum (Source_Index (U));
 279    end Initialize_Version;
 280
 281    ----------------------
 282    -- Load_Main_Source --
 283    ----------------------
 284
 285    procedure Load_Main_Source is
 286       Fname   : File_Name_Type;
 287       Version : Word := 0;
 288
 289    begin
 290       Load_Stack.Increment_Last;
 291       Load_Stack.Table (Load_Stack.Last) := (Main_Unit, Empty);
 292
 293       --  Initialize unit table entry for Main_Unit. Note that we don't know
 294       --  the unit name yet, that gets filled in when the parser parses the
 295       --  main unit, at which time a check is made that it matches the main
 296       --  file name, and then the Unit_Name field is set. The Cunit and
 297       --  Cunit_Entity fields also get filled in later by the parser.
 298
 299       Units.Increment_Last;
 300       Fname := Next_Main_Source;
 301
 302       Units.Table (Main_Unit).Unit_File_Name := Fname;
 303
 304       if Fname /= No_File then
 305          Main_Source_File := Load_Source_File (Fname);
 306          Current_Error_Source_File := Main_Source_File;
 307
 308          if Main_Source_File /= No_Source_File then
 309             Version := Source_Checksum (Main_Source_File);
 310          end if;
 311
 312          Units.Table (Main_Unit) := (
 313            Cunit            => Empty,
 314            Cunit_Entity     => Empty,
 315            Dependency_Num   => 0,
 316            Dynamic_Elab     => False,
 317            Error_Location   => No_Location,
 318            Expected_Unit    => No_Unit_Name,
 319            Fatal_Error      => False,
 320            Generate_Code    => False,
 321            Has_RACW         => False,
 322            Is_Compiler_Unit => False,
 323            Ident_String     => Empty,
 324            Loading          => True,
 325            Main_Priority    => Default_Main_Priority,
 326            Munit_Index      => 0,
 327            Serial_Number    => 0,
 328            Source_Index     => Main_Source_File,
 329            Unit_File_Name   => Fname,
 330            Unit_Name        => No_Unit_Name,
 331            Version          => Version,
 332            OA_Setting       => 'O');
 333       end if;
 334    end Load_Main_Source;
 335
 336    ---------------
 337    -- Load_Unit --
 338    ---------------
 339
 340    function Load_Unit
 341      (Load_Name         : Unit_Name_Type;
 342       Required          : Boolean;
 343       Error_Node        : Node_Id;
 344       Subunit           : Boolean;
 345       Corr_Body         : Unit_Number_Type := No_Unit;
 346       Renamings         : Boolean          := False;
 347       With_Node         : Node_Id          := Empty) return Unit_Number_Type
 348    is
 349       Calling_Unit : Unit_Number_Type;
 350       Uname_Actual : Unit_Name_Type;
 351       Unum         : Unit_Number_Type;
 352       Unump        : Unit_Number_Type;
 353       Fname        : File_Name_Type;
 354       Src_Ind      : Source_File_Index;
 355
 356    --  Start of processing for Load_Unit
 357
 358    begin
 359       --  If renamings are allowed and we have a child unit name, then we
 360       --  must first load the parent to deal with finding the real name.
 361
 362       if Renamings and then Is_Child_Name (Load_Name) then
 363          Unump :=
 364            Load_Unit
 365              (Load_Name  => Get_Parent_Spec_Name (Load_Name),
 366               Required   => Required,
 367               Subunit    => False,
 368               Renamings  => True,
 369               Error_Node => Error_Node);
 370
 371          if Unump = No_Unit then
 372             return No_Unit;
 373          end if;
 374
 375          --  If parent is a renaming, then we use the renamed package as
 376          --  the actual parent for the subsequent load operation.
 377
 378          if Nkind (Unit (Cunit (Unump))) = N_Package_Renaming_Declaration then
 379             Uname_Actual :=
 380               New_Child
 381                 (Load_Name, Get_Unit_Name (Name (Unit (Cunit (Unump)))));
 382
 383             --  Save the renaming entity, to establish its visibility when
 384             --  installing the context. The implicit with is on this entity,
 385             --  not on the package it renames.
 386
 387             if Nkind (Error_Node) = N_With_Clause
 388               and then Nkind (Name (Error_Node)) = N_Selected_Component
 389             then
 390                declare
 391                   Par : Node_Id := Name (Error_Node);
 392
 393                begin
 394                   while Nkind (Par) = N_Selected_Component
 395                     and then Chars (Selector_Name (Par)) /=
 396                       Chars (Cunit_Entity (Unump))
 397                   loop
 398                      Par := Prefix (Par);
 399                   end loop;
 400
 401                   --  Case of some intermediate parent is a renaming
 402
 403                   if Nkind (Par) = N_Selected_Component then
 404                      Set_Entity (Selector_Name (Par), Cunit_Entity (Unump));
 405
 406                   --  Case where the ultimate parent is a renaming
 407
 408                   else
 409                      Set_Entity (Par, Cunit_Entity (Unump));
 410                   end if;
 411                end;
 412             end if;
 413
 414          --  If the parent is not a renaming, then get its name (this may
 415          --  be different from the parent spec name obtained above because
 416          --  of renamings higher up in the hierarchy).
 417
 418          else
 419             Uname_Actual := New_Child (Load_Name, Unit_Name (Unump));
 420          end if;
 421
 422       --  Here if unit to be loaded is not a child unit
 423
 424       else
 425          Uname_Actual := Load_Name;
 426       end if;
 427
 428       Fname := Get_File_Name (Uname_Actual, Subunit);
 429
 430       if Debug_Flag_L then
 431          Write_Eol;
 432          Write_Str ("*** Load request for unit: ");
 433          Write_Unit_Name (Load_Name);
 434
 435          if Required then
 436             Write_Str (" (Required = True)");
 437          else
 438             Write_Str (" (Required = False)");
 439          end if;
 440
 441          Write_Eol;
 442
 443          if Uname_Actual /= Load_Name then
 444             Write_Str ("*** Actual unit loaded: ");
 445             Write_Unit_Name (Uname_Actual);
 446          end if;
 447       end if;
 448
 449       --  Capture error location if it is for the main unit. The idea is to
 450       --  post errors on the main unit location, not the most recent unit.
 451       --  Note: Unit_Name (Main_Unit) is not set if we are parsing gnat.adc.
 452
 453       if Present (Error_Node)
 454         and then Unit_Name (Main_Unit) /= No_Unit_Name
 455       then
 456          --  It seems like In_Extended_Main_Source_Unit (Error_Node) would
 457          --  do the trick here, but that's wrong, it is much too early to
 458          --  call this routine. We are still in the parser, and the required
 459          --  semantic information is not established yet. So we base the
 460          --  judgment on unit names.
 461
 462          Get_External_Unit_Name_String (Unit_Name (Main_Unit));
 463
 464          declare
 465             Main_Unit_Name : constant String := Name_Buffer (1 .. Name_Len);
 466
 467          begin
 468             Get_External_Unit_Name_String
 469               (Unit_Name (Get_Source_Unit (Error_Node)));
 470
 471             --  If the two names are identical, then for sure we are part
 472             --  of the extended main unit
 473
 474             if Main_Unit_Name = Name_Buffer (1 .. Name_Len) then
 475                Load_Msg_Sloc := Sloc (Error_Node);
 476
 477             --  If the load is called from a with_type clause, the error
 478             --  node is correct.
 479
 480             --  Otherwise, check for the subunit case, and if so, consider
 481             --  we have a match if one name is a prefix of the other name.
 482
 483             else
 484                if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit
 485                     or else
 486                   Nkind (Unit (Cunit (Get_Source_Unit (Error_Node)))) =
 487                                                                 N_Subunit
 488                then
 489                   Name_Len := Integer'Min (Name_Len, Main_Unit_Name'Length);
 490
 491                   if Name_Buffer (1 .. Name_Len)
 492                         =
 493                      Main_Unit_Name (1 .. Name_Len)
 494                   then
 495                      Load_Msg_Sloc := Sloc (Error_Node);
 496                   end if;
 497                end if;
 498             end if;
 499          end;
 500       end if;
 501
 502       --  If we are generating error messages, then capture calling unit
 503
 504       if Present (Error_Node) then
 505          Calling_Unit := Get_Source_Unit (Error_Node);
 506       else
 507          Calling_Unit := No_Unit;
 508       end if;
 509
 510       --  See if we already have an entry for this unit
 511
 512       Unum := Main_Unit;
 513
 514       while Unum <= Units.Last loop
 515          exit when Uname_Actual = Units.Table (Unum).Unit_Name;
 516          Unum := Unum + 1;
 517       end loop;
 518
 519       --  Whether or not the entry was found, Unum is now the right value,
 520       --  since it is one more than Units.Last (i.e. the index of the new
 521       --  entry we will create) in the not found case.
 522
 523       --  A special check is necessary in the unit not found case. If the unit
 524       --  is not found, but the file in which it lives has already been loaded,
 525       --  then we have the problem that the file does not contain the unit that
 526       --  is needed. We simply treat this as a file not found condition.
 527
 528       --  We skip this test in multiple unit per file mode since in this
 529       --  case we can have multiple units from the same source file.
 530
 531       if Unum > Units.Last and then Get_Unit_Index (Uname_Actual) = 0 then
 532          for J in Units.First .. Units.Last loop
 533             if Fname = Units.Table (J).Unit_File_Name then
 534                if Debug_Flag_L then
 535                   Write_Str ("  file does not contain unit, Unit_Number = ");
 536                   Write_Int (Int (Unum));
 537                   Write_Eol;
 538                   Write_Eol;
 539                end if;
 540
 541                if Present (Error_Node) then
 542                   if Is_Predefined_File_Name (Fname) then
 543                      Error_Msg_Unit_1 := Uname_Actual;
 544                      Error_Msg
 545                        ("$$ is not a language defined unit", Load_Msg_Sloc);
 546                   else
 547                      Error_Msg_File_1 := Fname;
 548                      Error_Msg_Unit_1 := Uname_Actual;
 549                      Error_Msg ("File{ does not contain unit$", Load_Msg_Sloc);
 550                   end if;
 551
 552                   Write_Dependency_Chain;
 553                   return No_Unit;
 554
 555                else
 556                   return No_Unit;
 557                end if;
 558             end if;
 559          end loop;
 560       end if;
 561
 562       --  If we are proceeding with load, then make load stack entry,
 563       --  and indicate the kind of with_clause responsible for the load.
 564
 565       Load_Stack.Increment_Last;
 566       Load_Stack.Table (Load_Stack.Last) := (Unum, With_Node);
 567
 568       --  Case of entry already in table
 569
 570       if Unum <= Units.Last then
 571
 572          --  Here is where we check for a circular dependency, which is
 573          --  an attempt to load a unit which is currently in the process
 574          --  of being loaded. We do *not* care about a circular chain that
 575          --  leads back to a body, because this kind of circular dependence
 576          --  legitimately occurs (e.g. two package bodies that contain
 577          --  inlined subprogram referenced by the other).
 578
 579          --  Ada 2005 (AI-50217): We also ignore limited_with clauses, because
 580          --  their purpose is precisely to create legal circular structures.
 581
 582          if Loading (Unum)
 583            and then (Is_Spec_Name (Units.Table (Unum).Unit_Name)
 584                        or else Acts_As_Spec (Units.Table (Unum).Cunit))
 585            and then (Nkind (Error_Node) /= N_With_Clause
 586                        or else not Limited_Present (Error_Node))
 587            and then not From_Limited_With_Chain
 588          then
 589             if Debug_Flag_L then
 590                Write_Str ("  circular dependency encountered");
 591                Write_Eol;
 592             end if;
 593
 594             if Present (Error_Node) then
 595                Error_Msg ("circular unit dependency", Load_Msg_Sloc);
 596                Write_Dependency_Chain;
 597             else
 598                Load_Stack.Decrement_Last;
 599             end if;
 600
 601             return No_Unit;
 602          end if;
 603
 604          if Debug_Flag_L then
 605             Write_Str ("  unit already in file table, Unit_Number = ");
 606             Write_Int (Int (Unum));
 607             Write_Eol;
 608          end if;
 609
 610          Load_Stack.Decrement_Last;
 611          return Unum;
 612
 613       --  Unit is not already in table, so try to open the file
 614
 615       else
 616          if Debug_Flag_L then
 617             Write_Str ("  attempt unit load, Unit_Number = ");
 618             Write_Int (Int (Unum));
 619             Write_Eol;
 620          end if;
 621
 622          Src_Ind := Load_Source_File (Fname);
 623
 624          --  Make a partial entry in the file table, used even in the file not
 625          --  found case to print the dependency chain including the last entry
 626
 627          Units.Increment_Last;
 628          Units.Table (Unum).Unit_Name := Uname_Actual;
 629
 630          --  File was found
 631
 632          if Src_Ind /= No_Source_File then
 633             Units.Table (Unum) := (
 634               Cunit            => Empty,
 635               Cunit_Entity     => Empty,
 636               Dependency_Num   => 0,
 637               Dynamic_Elab     => False,
 638               Error_Location   => Sloc (Error_Node),
 639               Expected_Unit    => Uname_Actual,
 640               Fatal_Error      => False,
 641               Generate_Code    => False,
 642               Has_RACW         => False,
 643               Is_Compiler_Unit => False,
 644               Ident_String     => Empty,
 645               Loading          => True,
 646               Main_Priority    => Default_Main_Priority,
 647               Munit_Index      => 0,
 648               Serial_Number    => 0,
 649               Source_Index     => Src_Ind,
 650               Unit_File_Name   => Fname,
 651               Unit_Name        => Uname_Actual,
 652               Version          => Source_Checksum (Src_Ind),
 653               OA_Setting       => 'O');
 654
 655             --  Parse the new unit
 656
 657             declare
 658                Save_Index : constant Nat := Multiple_Unit_Index;
 659             begin
 660                Multiple_Unit_Index := Get_Unit_Index (Uname_Actual);
 661                Units.Table (Unum).Munit_Index := Multiple_Unit_Index;
 662                Initialize_Scanner (Unum, Source_Index (Unum));
 663                Discard_List (Par (Configuration_Pragmas => False));
 664                Multiple_Unit_Index := Save_Index;
 665                Set_Loading (Unum, False);
 666             end;
 667
 668             --  If spec is irrelevant, then post errors and quit
 669
 670             if Corr_Body /= No_Unit
 671               and then Spec_Is_Irrelevant (Unum, Corr_Body)
 672             then
 673                Error_Msg_File_1 := Unit_File_Name (Corr_Body);
 674                Error_Msg
 675                  ("cannot compile subprogram in file {!", Load_Msg_Sloc);
 676                Error_Msg_File_1 := Unit_File_Name (Unum);
 677                Error_Msg
 678                  ("\incorrect spec in file { must be removed first!",
 679                   Load_Msg_Sloc);
 680                return No_Unit;
 681             end if;
 682
 683             --  If loaded unit had a fatal error, then caller inherits it!
 684
 685             if Units.Table (Unum).Fatal_Error
 686               and then Present (Error_Node)
 687             then
 688                Units.Table (Calling_Unit).Fatal_Error := True;
 689             end if;
 690
 691             --  Remove load stack entry and return the entry in the file table
 692
 693             Load_Stack.Decrement_Last;
 694             return Unum;
 695
 696          --  Case of file not found
 697
 698          else
 699             if Debug_Flag_L then
 700                Write_Str ("  file was not found, load failed");
 701                Write_Eol;
 702             end if;
 703
 704             --  Generate message if unit required
 705
 706             if Required and then Present (Error_Node) then
 707                if Is_Predefined_File_Name (Fname) then
 708
 709                   --  This is a predefined library unit which is not present
 710                   --  in the run time. If a predefined unit is not available
 711                   --  it may very likely be the case that there is also pragma
 712                   --  Restriction forbidding its usage. This is typically the
 713                   --  case when building a configurable run time, where the
 714                   --  usage of certain run-time units units is restricted by
 715                   --  means of both the corresponding pragma Restriction (such
 716                   --  as No_Calendar), and by not including the unit. Hence,
 717                   --  we check whether this predefined unit is forbidden, so
 718                   --  that the message about the restriction violation is
 719                   --  generated, if needed.
 720
 721                   Check_Restricted_Unit (Load_Name, Error_Node);
 722
 723                   Error_Msg_Unit_1 := Uname_Actual;
 724                   Error_Msg
 725                     ("$$ is not a predefined library unit", Load_Msg_Sloc);
 726
 727                else
 728                   Error_Msg_File_1 := Fname;
 729                   Error_Msg ("file{ not found", Load_Msg_Sloc);
 730                end if;
 731
 732                Write_Dependency_Chain;
 733
 734                --  Remove unit from stack, to avoid cascaded errors on
 735                --  subsequent missing files.
 736
 737                Load_Stack.Decrement_Last;
 738                Units.Decrement_Last;
 739
 740             --  If unit not required, remove load stack entry and the junk
 741             --  file table entry, and return No_Unit to indicate not found,
 742
 743             else
 744                Load_Stack.Decrement_Last;
 745                Units.Decrement_Last;
 746             end if;
 747
 748             return No_Unit;
 749          end if;
 750       end if;
 751    end Load_Unit;
 752
 753    ------------------------
 754    -- Make_Instance_Unit --
 755    ------------------------
 756
 757    --  If the unit is an instance, it appears as a package declaration, but
 758    --  contains both declaration and body of the instance. The body becomes
 759    --  the main unit of the compilation, and the declaration is inserted
 760    --  at the end of the unit table. The main unit now has the name of a
 761    --  body, which is constructed from the name of the original spec,
 762    --  and is attached to the compilation node of the original unit. The
 763    --  declaration has been attached to a new compilation unit node, and
 764    --  code will have to be generated for it.
 765
 766    procedure Make_Instance_Unit (N : Node_Id) is
 767       Sind : constant Source_File_Index := Source_Index (Main_Unit);
 768    begin
 769       Units.Increment_Last;
 770       Units.Table (Units.Last)               := Units.Table (Main_Unit);
 771       Units.Table (Units.Last).Cunit         := Library_Unit (N);
 772       Units.Table (Units.Last).Generate_Code := True;
 773       Units.Table (Main_Unit).Cunit          := N;
 774       Units.Table (Main_Unit).Unit_Name      :=
 775         Get_Body_Name (Unit_Name (Get_Cunit_Unit_Number (Library_Unit (N))));
 776       Units.Table (Main_Unit).Version        := Source_Checksum (Sind);
 777    end Make_Instance_Unit;
 778
 779    ------------------------
 780    -- Spec_Is_Irrelevant --
 781    ------------------------
 782
 783    function Spec_Is_Irrelevant
 784      (Spec_Unit : Unit_Number_Type;
 785       Body_Unit : Unit_Number_Type) return Boolean
 786    is
 787       Sunit : constant Node_Id := Cunit (Spec_Unit);
 788       Bunit : constant Node_Id := Cunit (Body_Unit);
 789
 790    begin
 791       --  The spec is irrelevant if the body is a subprogram body, and the
 792       --  spec is other than a subprogram spec or generic subprogram spec.
 793       --  Note that the names must be the same, we don't need to check that,
 794       --  because we already know that from the fact that the file names are
 795       --  the same.
 796
 797       return
 798          Nkind (Unit (Bunit)) = N_Subprogram_Body
 799            and then Nkind (Unit (Sunit)) /= N_Subprogram_Declaration
 800            and then Nkind (Unit (Sunit)) /= N_Generic_Subprogram_Declaration;
 801    end Spec_Is_Irrelevant;
 802
 803    --------------------
 804    -- Version_Update --
 805    --------------------
 806
 807    procedure Version_Update (U : Node_Id; From : Node_Id) is
 808       Unum  : constant Unit_Number_Type := Get_Cunit_Unit_Number (U);
 809       Fnum  : constant Unit_Number_Type := Get_Cunit_Unit_Number (From);
 810    begin
 811       if Source_Index (Fnum) /= No_Source_File then
 812          Units.Table (Unum).Version :=
 813            Units.Table (Unum).Version
 814              xor
 815               Source_Checksum (Source_Index (Fnum));
 816       end if;
 817    end Version_Update;
 818
 819    ----------------------------
 820    -- Write_Dependency_Chain --
 821    ----------------------------
 822
 823    procedure Write_Dependency_Chain is
 824    begin
 825       --  The dependency chain is only written if it is at least two entries
 826       --  deep, otherwise it is trivial (the main unit depending on a unit
 827       --  that it obviously directly depends on).
 828
 829       if Load_Stack.Last - 1 > Load_Stack.First then
 830          for U in Load_Stack.First .. Load_Stack.Last - 1 loop
 831             Error_Msg_Unit_1 :=
 832               Unit_Name (Load_Stack.Table (U).Unit_Number);
 833             Error_Msg_Unit_2 :=
 834               Unit_Name (Load_Stack.Table (U + 1).Unit_Number);
 835             Error_Msg ("$ depends on $!", Load_Msg_Sloc);
 836          end loop;
 837       end if;
 838    end Write_Dependency_Chain;
 839
 840 end Lib.Load;