gcc/ada/inline.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               I N L I N E                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This module handles two kinds of inlining activity:
  28
  29 --  a) Instantiation of generic bodies. This is done unconditionally, after
  30 --  analysis and expansion of the main unit.
  31
  32 --  b) Compilation of unit bodies that contain the bodies of inlined sub-
  33 --  programs. This is done only if inlining is enabled (-gnatn). Full inlining
  34 --  requires that a) an b) be mutually recursive, because each step may
  35 --  generate another generic expansion and further inlined calls. For now each
  36 --  of them uses a workpile algorithm, but they are called independently from
  37 --  Frontend, and thus are not mutually recursive.
  38
  39 with Alloc;
  40 with Sem;   use Sem;
  41 with Table;
  42 with Types; use Types;
  43
  44 package Inline is
  45
  46    --------------------------------
  47    -- Generic Body Instantiation --
  48    --------------------------------
  49
  50    --  The bodies of generic instantiations are built after semantic analysis
  51    --  of the main unit is complete. Generic instantiations are saved in a
  52    --  global data structure, and the bodies constructed by means of a separate
  53    --  analysis and expansion step.
  54
  55    --  See full description in body of Sem_Ch12 for more details
  56
  57    type Pending_Body_Info is record
  58       Inst_Node : Node_Id;
  59       --  Node for instantiation that requires the body
  60
  61       Act_Decl : Node_Id;
  62       --  Declaration for package or subprogram spec for instantiation
  63
  64       Expander_Status : Boolean;
  65       --  If the body is instantiated only for semantic checking, expansion
  66       --  must be inhibited.
  67
  68       Current_Sem_Unit : Unit_Number_Type;
  69       --  The semantic unit within which the instantiation is found. Must
  70       --  be restored when compiling the body, to insure that internal enti-
  71       --  ties use the same counter and are unique over spec and body.
  72
  73       Scope_Suppress           : Suppress_Array;
  74       Local_Suppress_Stack_Top : Suppress_Stack_Entry_Ptr;
  75       --  Save suppress information at the point of instantiation. Used to
  76       --  properly inherit check status active at this point (see RM 11.5
  77       --  (7.2/2), AI95-00224-01):
  78       --
  79       --    "If a checking pragma applies to a generic instantiation, then the
  80       --    checking pragma also applies to the instance. If a checking pragma
  81       --    applies to a call to a subprogram that has a pragma Inline applied
  82       --    to it, then the checking pragma also applies to the inlined
  83       --    subprogram body".
  84       --
  85       --  This means we have to capture this information from the current scope
  86       --  at the point of instantiation.
  87
  88    end record;
  89
  90    package Pending_Instantiations is new Table.Table (
  91      Table_Component_Type => Pending_Body_Info,
  92      Table_Index_Type     => Int,
  93      Table_Low_Bound      => 0,
  94      Table_Initial        => Alloc.Pending_Instantiations_Initial,
  95      Table_Increment      => Alloc.Pending_Instantiations_Increment,
  96      Table_Name           => "Pending_Instantiations");
  97
  98    --  The following table records subprograms and packages for which
  99    --  generation of subprogram descriptors must be delayed.
 100
 101    package Pending_Descriptor is new Table.Table (
 102      Table_Component_Type => Entity_Id,
 103      Table_Index_Type     => Int,
 104      Table_Low_Bound      => 0,
 105      Table_Initial        => Alloc.Pending_Instantiations_Initial,
 106      Table_Increment      => Alloc.Pending_Instantiations_Increment,
 107      Table_Name           => "Pending_Descriptor");
 108
 109    Analyzing_Inlined_Bodies : Boolean;
 110    --  This flag is set False by the call to Initialize, and then is set
 111    --  True by the call to Analyze_Inlined_Bodies. It is used to suppress
 112    --  generation of subprogram descriptors for inlined bodies.
 113
 114    -----------------
 115    -- Subprograms --
 116    -----------------
 117
 118    procedure Initialize;
 119    --  Initialize internal tables
 120
 121    procedure Lock;
 122    --  Lock internal tables before calling backend
 123
 124    procedure Instantiate_Bodies;
 125    --  This procedure is called after semantic analysis is complete, to
 126    --  instantiate the bodies of generic instantiations that appear in the
 127    --  compilation unit.
 128
 129    procedure Add_Inlined_Body (E : Entity_Id);
 130    --  E is an inlined subprogram appearing in a call, either explicitly, or
 131    --  a discriminant check for which gigi builds a call.  Add E's enclosing
 132    --  unit to Inlined_Bodies so that body of E can be subsequently retrieved
 133    --  and analyzed.
 134
 135    procedure Analyze_Inlined_Bodies;
 136    --  At end of compilation, analyze the bodies of all units that contain
 137    --  inlined subprograms that are actually called.
 138
 139    procedure Check_Body_For_Inlining (N : Node_Id; P : Entity_Id);
 140    --  If front-end inlining is enabled and a package declaration contains
 141    --  inlined subprograms, load and compile the package body to collect the
 142    --  bodies of these subprograms, so they are available to inline calls.
 143    --  N is the compilation unit for the package.
 144
 145    procedure Remove_Dead_Instance (N : Node_Id);
 146    --  If an instantiation appears in unreachable code, delete the pending
 147    --  body instance.
 148
 149 end Inline;