gcc/ada/inline.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               I N L I N E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Einfo;    use Einfo;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Exp_Ch7;  use Exp_Ch7;
  31 with Exp_Tss;  use Exp_Tss;
  32 with Fname;    use Fname;
  33 with Fname.UF; use Fname.UF;
  34 with Lib;      use Lib;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Sem_Aux;  use Sem_Aux;
  38 with Sem_Ch8;  use Sem_Ch8;
  39 with Sem_Ch10; use Sem_Ch10;
  40 with Sem_Ch12; use Sem_Ch12;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Snames;   use Snames;
  44 with Stand;    use Stand;
  45 with Uname;    use Uname;
  46
  47 package body Inline is
  48
  49    --------------------
  50    -- Inlined Bodies --
  51    --------------------
  52
  53    --  Inlined functions are actually placed in line by the backend if the
  54    --  corresponding bodies are available (i.e. compiled). Whenever we find
  55    --  a call to an inlined subprogram, we add the name of the enclosing
  56    --  compilation unit to a worklist. After all compilation, and after
  57    --  expansion of generic bodies, we traverse the list of pending bodies
  58    --  and compile them as well.
  59
  60    package Inlined_Bodies is new Table.Table (
  61      Table_Component_Type => Entity_Id,
  62      Table_Index_Type     => Int,
  63      Table_Low_Bound      => 0,
  64      Table_Initial        => Alloc.Inlined_Bodies_Initial,
  65      Table_Increment      => Alloc.Inlined_Bodies_Increment,
  66      Table_Name           => "Inlined_Bodies");
  67
  68    -----------------------
  69    -- Inline Processing --
  70    -----------------------
  71
  72    --  For each call to an inlined subprogram, we make entries in a table
  73    --  that stores caller and callee, and indicates a prerequisite from
  74    --  one to the other. We also record the compilation unit that contains
  75    --  the callee. After analyzing the bodies of all such compilation units,
  76    --  we produce a list of subprograms in  topological order, for use by the
  77    --  back-end. If P2 is a prerequisite of P1, then P1 calls P2, and for
  78    --  proper inlining the back-end must analyze the body of P2 before that of
  79    --  P1. The code below guarantees that the transitive closure of inlined
  80    --  subprograms called from the main compilation unit is made available to
  81    --  the code generator.
  82
  83    Last_Inlined : Entity_Id := Empty;
  84
  85    --  For each entry in the table we keep a list of successors in topological
  86    --  order, i.e. callers of the current subprogram.
  87
  88    type Subp_Index is new Nat;
  89    No_Subp : constant Subp_Index := 0;
  90
  91    --  The subprogram entities are hashed into the Inlined table
  92
  93    Num_Hash_Headers : constant := 512;
  94
  95    Hash_Headers : array (Subp_Index range 0 .. Num_Hash_Headers - 1)
  96                                                           of Subp_Index;
  97
  98    type Succ_Index is new Nat;
  99    No_Succ : constant Succ_Index := 0;
 100
 101    type Succ_Info is record
 102       Subp : Subp_Index;
 103       Next : Succ_Index;
 104    end record;
 105
 106    --  The following table stores list elements for the successor lists.
 107    --  These lists cannot be chained directly through entries in the Inlined
 108    --  table, because a given subprogram can appear in several such lists.
 109
 110    package Successors is new Table.Table (
 111       Table_Component_Type => Succ_Info,
 112       Table_Index_Type     => Succ_Index,
 113       Table_Low_Bound      => 1,
 114       Table_Initial        => Alloc.Successors_Initial,
 115       Table_Increment      => Alloc.Successors_Increment,
 116       Table_Name           => "Successors");
 117
 118    type Subp_Info is record
 119       Name        : Entity_Id  := Empty;
 120       First_Succ  : Succ_Index := No_Succ;
 121       Count       : Integer    := 0;
 122       Listed      : Boolean    := False;
 123       Main_Call   : Boolean    := False;
 124       Next        : Subp_Index := No_Subp;
 125       Next_Nopred : Subp_Index := No_Subp;
 126    end record;
 127
 128    package Inlined is new Table.Table (
 129       Table_Component_Type => Subp_Info,
 130       Table_Index_Type     => Subp_Index,
 131       Table_Low_Bound      => 1,
 132       Table_Initial        => Alloc.Inlined_Initial,
 133       Table_Increment      => Alloc.Inlined_Increment,
 134       Table_Name           => "Inlined");
 135
 136    -----------------------
 137    -- Local Subprograms --
 138    -----------------------
 139
 140    function Get_Code_Unit_Entity (E : Entity_Id) return Entity_Id;
 141    pragma Inline (Get_Code_Unit_Entity);
 142    --  Return the entity node for the unit containing E
 143
 144    function Scope_In_Main_Unit (Scop : Entity_Id) return Boolean;
 145    --  Return True if Scop is in the main unit or its spec
 146
 147    procedure Add_Call (Called : Entity_Id; Caller : Entity_Id := Empty);
 148    --  Make two entries in Inlined table, for an inlined subprogram being
 149    --  called, and for the inlined subprogram that contains the call. If
 150    --  the call is in the main compilation unit, Caller is Empty.
 151
 152    function Add_Subp (E : Entity_Id) return Subp_Index;
 153    --  Make entry in Inlined table for subprogram E, or return table index
 154    --  that already holds E.
 155
 156    function Has_Initialized_Type (E : Entity_Id) return Boolean;
 157    --  If a candidate for inlining contains type declarations for types with
 158    --  non-trivial initialization procedures, they are not worth inlining.
 159
 160    function Is_Nested (E : Entity_Id) return Boolean;
 161    --  If the function is nested inside some other function, it will
 162    --  always be compiled if that function is, so don't add it to the
 163    --  inline list. We cannot compile a nested function outside the
 164    --  scope of the containing function anyway. This is also the case if
 165    --  the function is defined in a task body or within an entry (for
 166    --  example, an initialization procedure).
 167
 168    procedure Add_Inlined_Subprogram (Index : Subp_Index);
 169    --  Add subprogram to Inlined List once all of its predecessors have been
 170    --  placed on the list. Decrement the count of all its successors, and
 171    --  add them to list (recursively) if count drops to zero.
 172
 173    ------------------------------
 174    -- Deferred Cleanup Actions --
 175    ------------------------------
 176
 177    --  The cleanup actions for scopes that contain instantiations is delayed
 178    --  until after expansion of those instantiations, because they may
 179    --  contain finalizable objects or tasks that affect the cleanup code.
 180    --  A scope that contains instantiations only needs to be finalized once,
 181    --  even if it contains more than one instance. We keep a list of scopes
 182    --  that must still be finalized, and call cleanup_actions after all the
 183    --  instantiations have been completed.
 184
 185    To_Clean : Elist_Id;
 186
 187    procedure Add_Scope_To_Clean (Inst : Entity_Id);
 188    --  Build set of scopes on which cleanup actions must be performed
 189
 190    procedure Cleanup_Scopes;
 191    --  Complete cleanup actions on scopes that need it
 192
 193    --------------
 194    -- Add_Call --
 195    --------------
 196
 197    procedure Add_Call (Called : Entity_Id; Caller : Entity_Id := Empty) is
 198       P1 : constant Subp_Index := Add_Subp (Called);
 199       P2 : Subp_Index;
 200       J  : Succ_Index;
 201
 202    begin
 203       if Present (Caller) then
 204          P2 := Add_Subp (Caller);
 205
 206          --  Add P2 to the list of successors of P1, if not already there.
 207          --  Note that P2 may contain more than one call to P1, and only
 208          --  one needs to be recorded.
 209
 210          J := Inlined.Table (P1).First_Succ;
 211          while J /= No_Succ loop
 212             if Successors.Table (J).Subp = P2 then
 213                return;
 214             end if;
 215
 216             J := Successors.Table (J).Next;
 217          end loop;
 218
 219          --  On exit, make a successor entry for P2
 220
 221          Successors.Increment_Last;
 222          Successors.Table (Successors.Last).Subp := P2;
 223          Successors.Table (Successors.Last).Next :=
 224                              Inlined.Table (P1).First_Succ;
 225          Inlined.Table (P1).First_Succ := Successors.Last;
 226
 227          Inlined.Table (P2).Count := Inlined.Table (P2).Count + 1;
 228
 229       else
 230          Inlined.Table (P1).Main_Call := True;
 231       end if;
 232    end Add_Call;
 233
 234    ----------------------
 235    -- Add_Inlined_Body --
 236    ----------------------
 237
 238    procedure Add_Inlined_Body (E : Entity_Id) is
 239
 240       function Must_Inline return Boolean;
 241       --  Inlining is only done if the call statement N is in the main unit,
 242       --  or within the body of another inlined subprogram.
 243
 244       -----------------
 245       -- Must_Inline --
 246       -----------------
 247
 248       function Must_Inline return Boolean is
 249          Scop : Entity_Id;
 250          Comp : Node_Id;
 251
 252       begin
 253          --  Check if call is in main unit
 254
 255          Scop := Current_Scope;
 256
 257          --  Do not try to inline if scope is standard. This could happen, for
 258          --  example, for a call to Add_Global_Declaration, and it causes
 259          --  trouble to try to inline at this level.
 260
 261          if Scop = Standard_Standard then
 262             return False;
 263          end if;
 264
 265          --  Otherwise lookup scope stack to outer scope
 266
 267          while Scope (Scop) /= Standard_Standard
 268            and then not Is_Child_Unit (Scop)
 269          loop
 270             Scop := Scope (Scop);
 271          end loop;
 272
 273          Comp := Parent (Scop);
 274          while Nkind (Comp) /= N_Compilation_Unit loop
 275             Comp := Parent (Comp);
 276          end loop;
 277
 278          if Comp = Cunit (Main_Unit)
 279            or else Comp = Library_Unit (Cunit (Main_Unit))
 280          then
 281             Add_Call (E);
 282             return True;
 283          end if;
 284
 285          --  Call is not in main unit. See if it's in some inlined subprogram
 286
 287          Scop := Current_Scope;
 288          while Scope (Scop) /= Standard_Standard
 289            and then not Is_Child_Unit (Scop)
 290          loop
 291             if Is_Overloadable (Scop)
 292               and then Is_Inlined (Scop)
 293             then
 294                Add_Call (E, Scop);
 295                return True;
 296             end if;
 297
 298             Scop := Scope (Scop);
 299          end loop;
 300
 301          return False;
 302       end Must_Inline;
 303
 304    --  Start of processing for Add_Inlined_Body
 305
 306    begin
 307       --  Find unit containing E, and add to list of inlined bodies if needed.
 308       --  If the body is already present, no need to load any other unit. This
 309       --  is the case for an initialization procedure, which appears in the
 310       --  package declaration that contains the type. It is also the case if
 311       --  the body has already been analyzed. Finally, if the unit enclosing
 312       --  E is an instance, the instance body will be analyzed in any case,
 313       --  and there is no need to add the enclosing unit (whose body might not
 314       --  be available).
 315
 316       --  Library-level functions must be handled specially, because there is
 317       --  no enclosing package to retrieve. In this case, it is the body of
 318       --  the function that will have to be loaded.
 319
 320       if not Is_Abstract_Subprogram (E)
 321         and then not Is_Nested (E)
 322         and then Convention (E) /= Convention_Protected
 323         and then Must_Inline
 324       then
 325          declare
 326             Pack : constant Entity_Id := Get_Code_Unit_Entity (E);
 327
 328          begin
 329             if Pack = E then
 330
 331                --  Library-level inlined function. Add function itself to
 332                --  list of needed units.
 333
 334                Set_Is_Called (E);
 335                Inlined_Bodies.Increment_Last;
 336                Inlined_Bodies.Table (Inlined_Bodies.Last) := E;
 337
 338             elsif Ekind (Pack) = E_Package then
 339                Set_Is_Called (E);
 340
 341                if Is_Generic_Instance (Pack) then
 342                   null;
 343
 344                --  Do not inline the package if the subprogram is an init proc
 345                --  or other internally generated subprogram, because in that
 346                --  case the subprogram body appears in the same unit that
 347                --  declares the type, and that body is visible to the back end.
 348
 349                elsif not Is_Inlined (Pack)
 350                  and then Comes_From_Source (E)
 351                then
 352                   Set_Is_Inlined (Pack);
 353                   Inlined_Bodies.Increment_Last;
 354                   Inlined_Bodies.Table (Inlined_Bodies.Last) := Pack;
 355                end if;
 356             end if;
 357          end;
 358       end if;
 359    end Add_Inlined_Body;
 360
 361    ----------------------------
 362    -- Add_Inlined_Subprogram --
 363    ----------------------------
 364
 365    procedure Add_Inlined_Subprogram (Index : Subp_Index) is
 366       E    : constant Entity_Id := Inlined.Table (Index).Name;
 367       Pack : constant Entity_Id := Get_Code_Unit_Entity (E);
 368       Succ : Succ_Index;
 369       Subp : Subp_Index;
 370
 371       function Back_End_Cannot_Inline (Subp : Entity_Id) return Boolean;
 372       --  There are various conditions under which back-end inlining cannot
 373       --  be done reliably:
 374       --
 375       --    a) If a body has handlers, it must not be inlined, because this
 376       --    may violate program semantics, and because in zero-cost exception
 377       --    mode it will lead to undefined symbols at link time.
 378       --
 379       --    b) If a body contains inlined function instances, it cannot be
 380       --    inlined under ZCX because the numeric suffix generated by gigi
 381       --    will be different in the body and the place of the inlined call.
 382       --
 383       --  This procedure must be carefully coordinated with the back end.
 384
 385       ----------------------------
 386       -- Back_End_Cannot_Inline --
 387       ----------------------------
 388
 389       function Back_End_Cannot_Inline (Subp : Entity_Id) return Boolean is
 390          Decl     : constant Node_Id := Unit_Declaration_Node (Subp);
 391          Body_Ent : Entity_Id;
 392          Ent      : Entity_Id;
 393
 394       begin
 395          if Nkind (Decl) = N_Subprogram_Declaration
 396            and then Present (Corresponding_Body (Decl))
 397          then
 398             Body_Ent := Corresponding_Body (Decl);
 399          else
 400             return False;
 401          end if;
 402
 403          --  If subprogram is marked Inline_Always, inlining is mandatory
 404
 405          if Has_Pragma_Inline_Always (Subp) then
 406             return False;
 407          end if;
 408
 409          if Present
 410           (Exception_Handlers
 411             (Handled_Statement_Sequence
 412               (Unit_Declaration_Node (Corresponding_Body (Decl)))))
 413          then
 414             return True;
 415          end if;
 416
 417          Ent := First_Entity (Body_Ent);
 418          while Present (Ent) loop
 419             if Is_Subprogram (Ent)
 420               and then Is_Generic_Instance (Ent)
 421             then
 422                return True;
 423             end if;
 424
 425             Next_Entity (Ent);
 426          end loop;
 427
 428          return False;
 429       end Back_End_Cannot_Inline;
 430
 431    --  Start of processing for Add_Inlined_Subprogram
 432
 433    begin
 434       --  If the subprogram is to be inlined, and if its unit is known to be
 435       --  inlined or is an instance whose body will be analyzed anyway or the
 436       --  subprogram has been generated by the compiler, and if it is declared
 437       --  at the library level not in the main unit, and if it can be inlined
 438       --  by the back-end, then insert it in the list of inlined subprograms.
 439
 440       if Is_Inlined (E)
 441         and then (Is_Inlined (Pack)
 442                     or else Is_Generic_Instance (Pack)
 443                     or else Is_Internal (E))
 444         and then not Scope_In_Main_Unit (E)
 445         and then not Is_Nested (E)
 446         and then not Has_Initialized_Type (E)
 447       then
 448          if Back_End_Cannot_Inline (E) then
 449             Set_Is_Inlined (E, False);
 450
 451          else
 452             if No (Last_Inlined) then
 453                Set_First_Inlined_Subprogram (Cunit (Main_Unit), E);
 454             else
 455                Set_Next_Inlined_Subprogram (Last_Inlined, E);
 456             end if;
 457
 458             Last_Inlined := E;
 459          end if;
 460       end if;
 461
 462       Inlined.Table (Index).Listed := True;
 463
 464       --  Now add to the list those callers of the current subprogram that
 465       --  are themselves called. They may appear on the graph as callers
 466       --  of the current one, even if they are themselves not called, and
 467       --  there is no point in including them in the list for the backend.
 468       --  Furthermore, they might not even be public, in which case the
 469       --  back-end cannot handle them at all.
 470
 471       Succ := Inlined.Table (Index).First_Succ;
 472       while Succ /= No_Succ loop
 473          Subp := Successors.Table (Succ).Subp;
 474          Inlined.Table (Subp).Count := Inlined.Table (Subp).Count - 1;
 475
 476          if Inlined.Table (Subp).Count = 0
 477            and then Is_Called (Inlined.Table (Subp).Name)
 478          then
 479             Add_Inlined_Subprogram (Subp);
 480          end if;
 481
 482          Succ := Successors.Table (Succ).Next;
 483       end loop;
 484    end Add_Inlined_Subprogram;
 485
 486    ------------------------
 487    -- Add_Scope_To_Clean --
 488    ------------------------
 489
 490    procedure Add_Scope_To_Clean (Inst : Entity_Id) is
 491       Scop : constant Entity_Id := Enclosing_Dynamic_Scope (Inst);
 492       Elmt : Elmt_Id;
 493
 494    begin
 495       --  If the instance appears in a library-level package declaration,
 496       --  all finalization is global, and nothing needs doing here.
 497
 498       if Scop = Standard_Standard then
 499          return;
 500       end if;
 501
 502       --  If the instance is within a generic unit, no finalization code
 503       --  can be generated. Note that at this point all bodies have been
 504       --  analyzed, and the scope stack itself is not present, and the flag
 505       --  Inside_A_Generic is not set.
 506
 507       declare
 508          S : Entity_Id;
 509
 510       begin
 511          S := Scope (Inst);
 512          while Present (S) and then S /= Standard_Standard loop
 513             if Is_Generic_Unit (S) then
 514                return;
 515             end if;
 516
 517             S := Scope (S);
 518          end loop;
 519       end;
 520
 521       Elmt := First_Elmt (To_Clean);
 522       while Present (Elmt) loop
 523          if Node (Elmt) = Scop then
 524             return;
 525          end if;
 526
 527          Elmt := Next_Elmt (Elmt);
 528       end loop;
 529
 530       Append_Elmt (Scop, To_Clean);
 531    end Add_Scope_To_Clean;
 532
 533    --------------
 534    -- Add_Subp --
 535    --------------
 536
 537    function Add_Subp (E : Entity_Id) return Subp_Index is
 538       Index : Subp_Index := Subp_Index (E) mod Num_Hash_Headers;
 539       J     : Subp_Index;
 540
 541       procedure New_Entry;
 542       --  Initialize entry in Inlined table
 543
 544       procedure New_Entry is
 545       begin
 546          Inlined.Increment_Last;
 547          Inlined.Table (Inlined.Last).Name        := E;
 548          Inlined.Table (Inlined.Last).First_Succ  := No_Succ;
 549          Inlined.Table (Inlined.Last).Count       := 0;
 550          Inlined.Table (Inlined.Last).Listed      := False;
 551          Inlined.Table (Inlined.Last).Main_Call   := False;
 552          Inlined.Table (Inlined.Last).Next        := No_Subp;
 553          Inlined.Table (Inlined.Last).Next_Nopred := No_Subp;
 554       end New_Entry;
 555
 556    --  Start of processing for Add_Subp
 557
 558    begin
 559       if Hash_Headers (Index) = No_Subp then
 560          New_Entry;
 561          Hash_Headers (Index) := Inlined.Last;
 562          return Inlined.Last;
 563
 564       else
 565          J := Hash_Headers (Index);
 566          while J /= No_Subp loop
 567             if Inlined.Table (J).Name = E then
 568                return J;
 569             else
 570                Index := J;
 571                J := Inlined.Table (J).Next;
 572             end if;
 573          end loop;
 574
 575          --  On exit, subprogram was not found. Enter in table. Index is
 576          --  the current last entry on the hash chain.
 577
 578          New_Entry;
 579          Inlined.Table (Index).Next := Inlined.Last;
 580          return Inlined.Last;
 581       end if;
 582    end Add_Subp;
 583
 584    ----------------------------
 585    -- Analyze_Inlined_Bodies --
 586    ----------------------------
 587
 588    procedure Analyze_Inlined_Bodies is
 589       Comp_Unit : Node_Id;
 590       J         : Int;
 591       Pack      : Entity_Id;
 592       S         : Succ_Index;
 593
 594       function Is_Ancestor_Of_Main
 595         (U_Name : Entity_Id;
 596          Nam    : Node_Id) return Boolean;
 597       --  Determine whether the unit whose body is loaded is an ancestor of
 598       --  the main unit, and has a with_clause on it. The body is not
 599       --  analyzed yet, so the check is purely lexical: the name of the with
 600       --  clause is a selected component, and names of ancestors must match.
 601
 602       -------------------------
 603       -- Is_Ancestor_Of_Main --
 604       -------------------------
 605
 606       function Is_Ancestor_Of_Main
 607         (U_Name : Entity_Id;
 608          Nam    : Node_Id) return Boolean
 609       is
 610          Pref : Node_Id;
 611
 612       begin
 613          if Nkind (Nam) /= N_Selected_Component then
 614             return False;
 615
 616          else
 617             if Chars (Selector_Name (Nam)) /=
 618                Chars (Cunit_Entity (Main_Unit))
 619             then
 620                return False;
 621             end if;
 622
 623             Pref := Prefix (Nam);
 624             if Nkind (Pref) = N_Identifier then
 625
 626                --  Par is an ancestor of Par.Child.
 627
 628                return Chars (Pref) = Chars (U_Name);
 629
 630             elsif Nkind (Pref) = N_Selected_Component
 631               and then Chars (Selector_Name (Pref)) = Chars (U_Name)
 632             then
 633                --  Par.Child is an ancestor of Par.Child.Grand.
 634
 635                return True;   --  should check that ancestor match
 636
 637             else
 638                --  A is an ancestor of A.B.C if it is an ancestor of A.B
 639
 640                return Is_Ancestor_Of_Main (U_Name, Pref);
 641             end if;
 642          end if;
 643       end Is_Ancestor_Of_Main;
 644
 645    --  Start of processing for  Analyze_Inlined_Bodies
 646
 647    begin
 648       Analyzing_Inlined_Bodies := False;
 649
 650       if Serious_Errors_Detected = 0 then
 651          Push_Scope (Standard_Standard);
 652
 653          J := 0;
 654          while J <= Inlined_Bodies.Last
 655            and then Serious_Errors_Detected = 0
 656          loop
 657             Pack := Inlined_Bodies.Table (J);
 658             while Present (Pack)
 659               and then Scope (Pack) /= Standard_Standard
 660               and then not Is_Child_Unit (Pack)
 661             loop
 662                Pack := Scope (Pack);
 663             end loop;
 664
 665             Comp_Unit := Parent (Pack);
 666             while Present (Comp_Unit)
 667               and then Nkind (Comp_Unit) /= N_Compilation_Unit
 668             loop
 669                Comp_Unit := Parent (Comp_Unit);
 670             end loop;
 671
 672             --  Load the body, unless it the main unit, or is an instance whose
 673             --  body has already been analyzed.
 674
 675             if Present (Comp_Unit)
 676               and then Comp_Unit /= Cunit (Main_Unit)
 677               and then Body_Required (Comp_Unit)
 678               and then (Nkind (Unit (Comp_Unit)) /= N_Package_Declaration
 679                          or else No (Corresponding_Body (Unit (Comp_Unit))))
 680             then
 681                declare
 682                   Bname : constant Unit_Name_Type :=
 683                             Get_Body_Name (Get_Unit_Name (Unit (Comp_Unit)));
 684
 685                   OK : Boolean;
 686
 687                begin
 688                   if not Is_Loaded (Bname) then
 689                      Style_Check := False;
 690                      Load_Needed_Body (Comp_Unit, OK, Do_Analyze => False);
 691
 692                      if not OK then
 693
 694                         --  Warn that a body was not available for inlining
 695                         --  by the back-end.
 696
 697                         Error_Msg_Unit_1 := Bname;
 698                         Error_Msg_N
 699                           ("one or more inlined subprograms accessed in $!?",
 700                            Comp_Unit);
 701                         Error_Msg_File_1 :=
 702                           Get_File_Name (Bname, Subunit => False);
 703                         Error_Msg_N ("\but file{ was not found!?", Comp_Unit);
 704
 705                      else
 706                         --  If the package to be inlined is an ancestor unit of
 707                         --  the main unit, and it has a semantic dependence on
 708                         --  it, the inlining cannot take place to prevent an
 709                         --  elaboration circularity. The desired body is not
 710                         --  analyzed yet, to prevent the completion of Taft
 711                         --  amendment types that would lead to elaboration
 712                         --  circularities in gigi.
 713
 714                         declare
 715                            U_Id      : constant Entity_Id :=
 716                                          Defining_Entity (Unit (Comp_Unit));
 717                            Body_Unit : constant Node_Id :=
 718                                          Library_Unit (Comp_Unit);
 719                            Item      : Node_Id;
 720
 721                         begin
 722                            Item := First (Context_Items (Body_Unit));
 723                            while Present (Item) loop
 724                               if Nkind (Item) = N_With_Clause
 725                                 and then
 726                                   Is_Ancestor_Of_Main (U_Id, Name (Item))
 727                               then
 728                                  Set_Is_Inlined (U_Id, False);
 729                                  exit;
 730                               end if;
 731
 732                               Next (Item);
 733                            end loop;
 734
 735                            --  If no suspicious with_clauses, analyze the body.
 736
 737                            if Is_Inlined (U_Id) then
 738                               Semantics (Body_Unit);
 739                            end if;
 740                         end;
 741                      end if;
 742                   end if;
 743                end;
 744             end if;
 745
 746             J := J + 1;
 747          end loop;
 748
 749          --  The analysis of required bodies may have produced additional
 750          --  generic instantiations. To obtain further inlining, we perform
 751          --  another round of generic body instantiations. Establishing a
 752          --  fully recursive loop between inlining and generic instantiations
 753          --  is unlikely to yield more than this one additional pass.
 754
 755          Instantiate_Bodies;
 756
 757          --  The list of inlined subprograms is an overestimate, because it
 758          --  includes inlined functions called from functions that are compiled
 759          --  as part of an inlined package, but are not themselves called. An
 760          --  accurate computation of just those subprograms that are needed
 761          --  requires that we perform a transitive closure over the call graph,
 762          --  starting from calls in the main program. Here we do one step of
 763          --  the inverse transitive closure, and reset the Is_Called flag on
 764          --  subprograms all of whose callers are not.
 765
 766          for Index in Inlined.First .. Inlined.Last loop
 767             S := Inlined.Table (Index).First_Succ;
 768
 769             if S /= No_Succ
 770               and then not Inlined.Table (Index).Main_Call
 771             then
 772                Set_Is_Called (Inlined.Table (Index).Name, False);
 773
 774                while S /= No_Succ loop
 775                   if Is_Called
 776                     (Inlined.Table (Successors.Table (S).Subp).Name)
 777                    or else Inlined.Table (Successors.Table (S).Subp).Main_Call
 778                   then
 779                      Set_Is_Called (Inlined.Table (Index).Name);
 780                      exit;
 781                   end if;
 782
 783                   S := Successors.Table (S).Next;
 784                end loop;
 785             end if;
 786          end loop;
 787
 788          --  Now that the units are compiled, chain the subprograms within
 789          --  that are called and inlined. Produce list of inlined subprograms
 790          --  sorted in  topological order. Start with all subprograms that
 791          --  have no prerequisites, i.e. inlined subprograms that do not call
 792          --  other inlined subprograms.
 793
 794          for Index in Inlined.First .. Inlined.Last loop
 795
 796             if Is_Called (Inlined.Table (Index).Name)
 797               and then Inlined.Table (Index).Count = 0
 798               and then not Inlined.Table (Index).Listed
 799             then
 800                Add_Inlined_Subprogram (Index);
 801             end if;
 802          end loop;
 803
 804          --  Because Add_Inlined_Subprogram treats recursively nodes that have
 805          --  no prerequisites left, at the end of the loop all subprograms
 806          --  must have been listed. If there are any unlisted subprograms
 807          --  left, there must be some recursive chains that cannot be inlined.
 808
 809          for Index in Inlined.First .. Inlined.Last loop
 810             if Is_Called (Inlined.Table (Index).Name)
 811               and then Inlined.Table (Index).Count /= 0
 812               and then not Is_Predefined_File_Name
 813                 (Unit_File_Name
 814                   (Get_Source_Unit (Inlined.Table (Index).Name)))
 815             then
 816                Error_Msg_N
 817                  ("& cannot be inlined?", Inlined.Table (Index).Name);
 818
 819                --  A warning on the first one might be sufficient ???
 820             end if;
 821          end loop;
 822
 823          Pop_Scope;
 824       end if;
 825    end Analyze_Inlined_Bodies;
 826
 827    -----------------------------
 828    -- Check_Body_For_Inlining --
 829    -----------------------------
 830
 831    procedure Check_Body_For_Inlining (N : Node_Id; P : Entity_Id) is
 832       Bname : Unit_Name_Type;
 833       E     : Entity_Id;
 834       OK    : Boolean;
 835
 836    begin
 837       if Is_Compilation_Unit (P)
 838         and then not Is_Generic_Instance (P)
 839       then
 840          Bname := Get_Body_Name (Get_Unit_Name (Unit (N)));
 841
 842          E := First_Entity (P);
 843          while Present (E) loop
 844             if Has_Pragma_Inline_Always (E)
 845               or else (Front_End_Inlining and then Has_Pragma_Inline (E))
 846             then
 847                if not Is_Loaded (Bname) then
 848                   Load_Needed_Body (N, OK);
 849
 850                   if OK then
 851
 852                      --  Check we are not trying to inline a parent whose body
 853                      --  depends on a child, when we are compiling the body of
 854                      --  the child. Otherwise we have a potential elaboration
 855                      --  circularity with inlined subprograms and with
 856                      --  Taft-Amendment types.
 857
 858                      declare
 859                         Comp        : Node_Id;      --  Body just compiled
 860                         Child_Spec  : Entity_Id;    --  Spec of main unit
 861                         Ent         : Entity_Id;    --  For iteration
 862                         With_Clause : Node_Id;      --  Context of body.
 863
 864                      begin
 865                         if Nkind (Unit (Cunit (Main_Unit))) = N_Package_Body
 866                           and then Present (Body_Entity (P))
 867                         then
 868                            Child_Spec :=
 869                              Defining_Entity
 870                                ((Unit (Library_Unit (Cunit (Main_Unit)))));
 871
 872                            Comp :=
 873                              Parent (Unit_Declaration_Node (Body_Entity (P)));
 874
 875                            --  Check whether the context of the body just
 876                            --  compiled includes a child of itself, and that
 877                            --  child is the spec of the main compilation.
 878
 879                            With_Clause := First (Context_Items (Comp));
 880                            while Present (With_Clause) loop
 881                               if Nkind (With_Clause) = N_With_Clause
 882                                 and then
 883                                   Scope (Entity (Name (With_Clause))) = P
 884                                 and then
 885                                   Entity (Name (With_Clause)) = Child_Spec
 886                               then
 887                                  Error_Msg_Node_2 := Child_Spec;
 888                                  Error_Msg_NE
 889                                    ("body of & depends on child unit&?",
 890                                       With_Clause, P);
 891                                  Error_Msg_N
 892                                    ("\subprograms in body cannot be inlined?",
 893                                       With_Clause);
 894
 895                                  --  Disable further inlining from this unit,
 896                                  --  and keep Taft-amendment types incomplete.
 897
 898                                  Ent := First_Entity (P);
 899                                  while Present (Ent) loop
 900                                     if Is_Type (Ent)
 901                                        and then Has_Completion_In_Body (Ent)
 902                                     then
 903                                        Set_Full_View (Ent, Empty);
 904
 905                                     elsif Is_Subprogram (Ent) then
 906                                        Set_Is_Inlined (Ent, False);
 907                                     end if;
 908
 909                                     Next_Entity (Ent);
 910                                  end loop;
 911
 912                                  return;
 913                               end if;
 914
 915                               Next (With_Clause);
 916                            end loop;
 917                         end if;
 918                      end;
 919
 920                   elsif Ineffective_Inline_Warnings then
 921                      Error_Msg_Unit_1 := Bname;
 922                      Error_Msg_N
 923                        ("unable to inline subprograms defined in $?", P);
 924                      Error_Msg_N ("\body not found?", P);
 925                      return;
 926                   end if;
 927                end if;
 928
 929                return;
 930             end if;
 931
 932             Next_Entity (E);
 933          end loop;
 934       end if;
 935    end Check_Body_For_Inlining;
 936
 937    --------------------
 938    -- Cleanup_Scopes --
 939    --------------------
 940
 941    procedure Cleanup_Scopes is
 942       Elmt : Elmt_Id;
 943       Decl : Node_Id;
 944       Scop : Entity_Id;
 945
 946    begin
 947       Elmt := First_Elmt (To_Clean);
 948       while Present (Elmt) loop
 949          Scop := Node (Elmt);
 950
 951          if Ekind (Scop) = E_Entry then
 952             Scop := Protected_Body_Subprogram (Scop);
 953
 954          elsif Is_Subprogram (Scop)
 955            and then Is_Protected_Type (Scope (Scop))
 956            and then Present (Protected_Body_Subprogram (Scop))
 957          then
 958             --  If a protected operation contains an instance, its
 959             --  cleanup operations have been delayed, and the subprogram
 960             --  has been rewritten in the expansion of the enclosing
 961             --  protected body. It is the corresponding subprogram that
 962             --  may require the cleanup operations, so propagate the
 963             --  information that triggers cleanup activity.
 964
 965             Set_Uses_Sec_Stack
 966               (Protected_Body_Subprogram (Scop),
 967                 Uses_Sec_Stack (Scop));
 968
 969             Scop := Protected_Body_Subprogram (Scop);
 970          end if;
 971
 972          if Ekind (Scop) = E_Block then
 973             Decl := Parent (Block_Node (Scop));
 974
 975          else
 976             Decl := Unit_Declaration_Node (Scop);
 977
 978             if Nkind (Decl) = N_Subprogram_Declaration
 979               or else Nkind (Decl) = N_Task_Type_Declaration
 980               or else Nkind (Decl) = N_Subprogram_Body_Stub
 981             then
 982                Decl := Unit_Declaration_Node (Corresponding_Body (Decl));
 983             end if;
 984          end if;
 985
 986          Push_Scope (Scop);
 987          Expand_Cleanup_Actions (Decl);
 988          End_Scope;
 989
 990          Elmt := Next_Elmt (Elmt);
 991       end loop;
 992    end Cleanup_Scopes;
 993
 994    --------------------------
 995    -- Get_Code_Unit_Entity --
 996    --------------------------
 997
 998    function Get_Code_Unit_Entity (E : Entity_Id) return Entity_Id is
 999    begin
1000       return Cunit_Entity (Get_Code_Unit (E));
1001    end Get_Code_Unit_Entity;
1002
1003    --------------------------
1004    -- Has_Initialized_Type --
1005    --------------------------
1006
1007    function Has_Initialized_Type (E : Entity_Id) return Boolean is
1008       E_Body : constant Node_Id := Get_Subprogram_Body (E);
1009       Decl   : Node_Id;
1010
1011    begin
1012       if No (E_Body) then        --  imported subprogram
1013          return False;
1014
1015       else
1016          Decl := First (Declarations (E_Body));
1017          while Present (Decl) loop
1018
1019             if Nkind (Decl) = N_Full_Type_Declaration
1020               and then Present (Init_Proc (Defining_Identifier (Decl)))
1021             then
1022                return True;
1023             end if;
1024
1025             Next (Decl);
1026          end loop;
1027       end if;
1028
1029       return False;
1030    end Has_Initialized_Type;
1031
1032    ----------------
1033    -- Initialize --
1034    ----------------
1035
1036    procedure Initialize is
1037    begin
1038       Analyzing_Inlined_Bodies := False;
1039       Pending_Descriptor.Init;
1040       Pending_Instantiations.Init;
1041       Inlined_Bodies.Init;
1042       Successors.Init;
1043       Inlined.Init;
1044
1045       for J in Hash_Headers'Range loop
1046          Hash_Headers (J) := No_Subp;
1047       end loop;
1048    end Initialize;
1049
1050    ------------------------
1051    -- Instantiate_Bodies --
1052    ------------------------
1053
1054    --  Generic bodies contain all the non-local references, so an
1055    --  instantiation does not need any more context than Standard
1056    --  itself, even if the instantiation appears in an inner scope.
1057    --  Generic associations have verified that the contract model is
1058    --  satisfied, so that any error that may occur in the analysis of
1059    --  the body is an internal error.
1060
1061    procedure Instantiate_Bodies is
1062       J    : Int;
1063       Info : Pending_Body_Info;
1064
1065    begin
1066       if Serious_Errors_Detected = 0 then
1067
1068          Expander_Active := (Operating_Mode = Opt.Generate_Code);
1069          Push_Scope (Standard_Standard);
1070          To_Clean := New_Elmt_List;
1071
1072          if Is_Generic_Unit (Cunit_Entity (Main_Unit)) then
1073             Start_Generic;
1074          end if;
1075
1076          --  A body instantiation may generate additional instantiations, so
1077          --  the following loop must scan to the end of a possibly expanding
1078          --  set (that's why we can't simply use a FOR loop here).
1079
1080          J := 0;
1081          while J <= Pending_Instantiations.Last
1082            and then Serious_Errors_Detected = 0
1083          loop
1084             Info := Pending_Instantiations.Table (J);
1085
1086             --  If the instantiation node is absent, it has been removed
1087             --  as part of unreachable code.
1088
1089             if No (Info.Inst_Node) then
1090                null;
1091
1092             elsif Nkind (Info.Act_Decl) = N_Package_Declaration then
1093                Instantiate_Package_Body (Info);
1094                Add_Scope_To_Clean (Defining_Entity (Info.Act_Decl));
1095
1096             else
1097                Instantiate_Subprogram_Body (Info);
1098             end if;
1099
1100             J := J + 1;
1101          end loop;
1102
1103          --  Reset the table of instantiations. Additional instantiations
1104          --  may be added through inlining, when additional bodies are
1105          --  analyzed.
1106
1107          Pending_Instantiations.Init;
1108
1109          --  We can now complete the cleanup actions of scopes that contain
1110          --  pending instantiations (skipped for generic units, since we
1111          --  never need any cleanups in generic units).
1112          --  pending instantiations.
1113
1114          if Expander_Active
1115            and then not Is_Generic_Unit (Main_Unit_Entity)
1116          then
1117             Cleanup_Scopes;
1118          elsif Is_Generic_Unit (Cunit_Entity (Main_Unit)) then
1119             End_Generic;
1120          end if;
1121
1122          Pop_Scope;
1123       end if;
1124    end Instantiate_Bodies;
1125
1126    ---------------
1127    -- Is_Nested --
1128    ---------------
1129
1130    function Is_Nested (E : Entity_Id) return Boolean is
1131       Scop : Entity_Id;
1132
1133    begin
1134       Scop := Scope (E);
1135       while Scop /= Standard_Standard loop
1136          if Ekind (Scop) in Subprogram_Kind then
1137             return True;
1138
1139          elsif Ekind (Scop) = E_Task_Type
1140            or else Ekind (Scop) = E_Entry
1141            or else Ekind (Scop) = E_Entry_Family then
1142             return True;
1143          end if;
1144
1145          Scop := Scope (Scop);
1146       end loop;
1147
1148       return False;
1149    end Is_Nested;
1150
1151    ----------
1152    -- Lock --
1153    ----------
1154
1155    procedure Lock is
1156    begin
1157       Pending_Instantiations.Locked := True;
1158       Inlined_Bodies.Locked := True;
1159       Successors.Locked := True;
1160       Inlined.Locked := True;
1161       Pending_Instantiations.Release;
1162       Inlined_Bodies.Release;
1163       Successors.Release;
1164       Inlined.Release;
1165    end Lock;
1166
1167    --------------------------
1168    -- Remove_Dead_Instance --
1169    --------------------------
1170
1171    procedure Remove_Dead_Instance (N : Node_Id) is
1172       J : Int;
1173
1174    begin
1175       J := 0;
1176       while J <= Pending_Instantiations.Last loop
1177          if Pending_Instantiations.Table (J).Inst_Node = N then
1178             Pending_Instantiations.Table (J).Inst_Node := Empty;
1179             return;
1180          end if;
1181
1182          J := J + 1;
1183       end loop;
1184    end Remove_Dead_Instance;
1185
1186    ------------------------
1187    -- Scope_In_Main_Unit --
1188    ------------------------
1189
1190    function Scope_In_Main_Unit (Scop : Entity_Id) return Boolean is
1191       Comp : constant Node_Id := Cunit (Get_Code_Unit (Scop));
1192
1193    begin
1194       --  Check whether the scope of the subprogram to inline is within the
1195       --  main unit or within its spec. In either case there are no additional
1196       --  bodies to process. If the subprogram appears in a parent of the
1197       --  current unit, the check on whether inlining is possible is done in
1198       --  Analyze_Inlined_Bodies.
1199
1200       return
1201         Comp = Cunit (Main_Unit)
1202           or else Comp = Library_Unit (Cunit (Main_Unit));
1203    end Scope_In_Main_Unit;
1204
1205 end Inline;