gcc/ada/gnatlink.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             G N A T L I N K                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1996-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Gnatlink usage: please consult the gnat documentation
  27
  28 with ALI;      use ALI;
  29 with Csets;
  30 with Gnatvsn;  use Gnatvsn;
  31 with Hostparm;
  32 with Indepsw;  use Indepsw;
  33 with Namet;    use Namet;
  34 with Opt;
  35 with Osint;    use Osint;
  36 with Output;   use Output;
  37 with Snames;
  38 with Switch;   use Switch;
  39 with System;   use System;
  40 with Table;
  41 with Targparm; use Targparm;
  42 with Types;
  43
  44 with Ada.Command_Line; use Ada.Command_Line;
  45 with Ada.Exceptions;   use Ada.Exceptions;
  46
  47 with System.OS_Lib; use System.OS_Lib;
  48 with System.CRTL;
  49
  50 with Interfaces.C_Streams; use Interfaces.C_Streams;
  51 with Interfaces.C.Strings; use Interfaces.C.Strings;
  52
  53 procedure Gnatlink is
  54    pragma Ident (Gnatvsn.Gnat_Static_Version_String);
  55
  56    Shared_Libgcc_String : constant String := "-shared-libgcc";
  57    Shared_Libgcc        : constant String_Access :=
  58                             new String'(Shared_Libgcc_String);
  59    --  Used to invoke gcc when the binder is invoked with -shared
  60
  61    Static_Libgcc_String : constant String := "-static-libgcc";
  62    Static_Libgcc        : constant String_Access :=
  63                             new String'(Static_Libgcc_String);
  64    --  Used to invoke gcc when shared libs are not used
  65
  66    package Gcc_Linker_Options is new Table.Table (
  67      Table_Component_Type => String_Access,
  68      Table_Index_Type     => Integer,
  69      Table_Low_Bound      => 1,
  70      Table_Initial        => 20,
  71      Table_Increment      => 100,
  72      Table_Name           => "Gnatlink.Gcc_Linker_Options");
  73    --  Comments needed ???
  74
  75    package Libpath is new Table.Table (
  76      Table_Component_Type => Character,
  77      Table_Index_Type     => Integer,
  78      Table_Low_Bound      => 1,
  79      Table_Initial        => 4096,
  80      Table_Increment      => 100,
  81      Table_Name           => "Gnatlink.Libpath");
  82    --  Comments needed ???
  83
  84    package Linker_Options is new Table.Table (
  85      Table_Component_Type => String_Access,
  86      Table_Index_Type     => Integer,
  87      Table_Low_Bound      => 1,
  88      Table_Initial        => 20,
  89      Table_Increment      => 100,
  90      Table_Name           => "Gnatlink.Linker_Options");
  91    --  Comments needed ???
  92
  93    package Linker_Objects is new Table.Table (
  94      Table_Component_Type => String_Access,
  95      Table_Index_Type     => Integer,
  96      Table_Low_Bound      => 1,
  97      Table_Initial        => 20,
  98      Table_Increment      => 100,
  99      Table_Name           => "Gnatlink.Linker_Objects");
 100    --  This table collects the objects file to be passed to the linker. In the
 101    --  case where the linker command line is too long then programs objects
 102    --  are put on the Response_File_Objects table. Note that the binder object
 103    --  file and the user's objects remain in this table. This is very
 104    --  important because on the GNU linker command line the -L switch is not
 105    --  used to look for objects files but -L switch is used to look for
 106    --  objects listed in the response file. This is not a problem with the
 107    --  applications objects as they are specified with a full name.
 108
 109    package Response_File_Objects is new Table.Table (
 110      Table_Component_Type => String_Access,
 111      Table_Index_Type     => Integer,
 112      Table_Low_Bound      => 1,
 113      Table_Initial        => 20,
 114      Table_Increment      => 100,
 115      Table_Name           => "Gnatlink.Response_File_Objects");
 116    --  This table collects the objects file that are to be put in the response
 117    --  file. Only application objects are collected there (see details in
 118    --  Linker_Objects table comments)
 119
 120    package Binder_Options_From_ALI is new Table.Table (
 121      Table_Component_Type => String_Access,
 122      Table_Index_Type     => Integer,
 123      Table_Low_Bound      => 1, -- equals low bound of Argument_List for Spawn
 124      Table_Initial        => 20,
 125      Table_Increment      => 100,
 126      Table_Name           => "Gnatlink.Binder_Options_From_ALI");
 127    --  This table collects the switches from the ALI file of the main
 128    --  subprogram.
 129
 130    package Binder_Options is new Table.Table (
 131      Table_Component_Type => String_Access,
 132      Table_Index_Type     => Integer,
 133      Table_Low_Bound      => 1, -- equals low bound of Argument_List for Spawn
 134      Table_Initial        => 20,
 135      Table_Increment      => 100,
 136      Table_Name           => "Gnatlink.Binder_Options");
 137    --  This table collects the arguments to be passed to compile the binder
 138    --  generated file.
 139
 140    Gcc : String_Access := Program_Name ("gcc", "gnatlink");
 141
 142    Read_Mode : constant String := "r" & ASCII.NUL;
 143
 144    Begin_Info : constant String := "--  BEGIN Object file/option list";
 145    End_Info   : constant String := "--  END Object file/option list   ";
 146
 147    Gcc_Path             : String_Access;
 148    Linker_Path          : String_Access;
 149    Output_File_Name     : String_Access;
 150    Ali_File_Name        : String_Access;
 151    Binder_Spec_Src_File : String_Access;
 152    Binder_Body_Src_File : String_Access;
 153    Binder_Ali_File      : String_Access;
 154    Binder_Obj_File      : String_Access;
 155
 156    Tname    : Temp_File_Name;
 157    Tname_FD : File_Descriptor := Invalid_FD;
 158    --  Temporary file used by linker to pass list of object files on
 159    --  certain systems with limitations on size of arguments.
 160
 161    Debug_Flag_Present : Boolean := False;
 162    Verbose_Mode       : Boolean := False;
 163    Very_Verbose_Mode  : Boolean := False;
 164
 165    Standard_Gcc : Boolean := True;
 166
 167    Compile_Bind_File : Boolean := True;
 168    --  Set to False if bind file is not to be compiled
 169
 170    Create_Map_File : Boolean := False;
 171    --  Set to True by switch -M. The map file name is derived from
 172    --  the ALI file name (mainprog.ali => mainprog.map).
 173
 174    Object_List_File_Supported : Boolean;
 175    for Object_List_File_Supported'Size use Character'Size;
 176    pragma Import
 177      (C, Object_List_File_Supported, "__gnat_objlist_file_supported");
 178    --  Predicate indicating whether the linker has an option whereby the
 179    --  names of object files can be passed to the linker in a file.
 180
 181    Object_File_Option_Ptr : Interfaces.C.Strings.chars_ptr;
 182    pragma Import (C, Object_File_Option_Ptr, "__gnat_object_file_option");
 183    --  Pointer to a string representing the linker option which specifies
 184    --  the response file.
 185
 186    Object_File_Option : constant String := Value (Object_File_Option_Ptr);
 187    --  The linker option which specifies the response file as a string
 188
 189    Using_GNU_response_file : constant Boolean :=
 190      Object_File_Option'Length > 0
 191        and then Object_File_Option (Object_File_Option'Last) = '@';
 192    --  Whether a GNU response file is used
 193
 194    Object_List_File_Required : Boolean := False;
 195    --  Set to True to force generation of a response file
 196
 197    Shared_Libgcc_Default : Character;
 198    for Shared_Libgcc_Default'Size use Character'Size;
 199    pragma Import
 200      (C, Shared_Libgcc_Default, "__gnat_shared_libgcc_default");
 201    --  Indicates wether libgcc should be statically linked (use 'T') or
 202    --  dynamically linked (use 'H') by default.
 203
 204    function Base_Name (File_Name : String) return String;
 205    --  Return just the file name part without the extension (if present)
 206
 207    procedure Check_Existing_Executable (File_Name : String);
 208    --  Delete any existing executable to avoid accidentally updating the target
 209    --  of a symbolic link, but produce a Fatail_Error if File_Name matches any
 210    --  of the source file names. This avoids overwriting of extensionless
 211    --  source files by accident on systems where executables do not have
 212    --  extensions.
 213
 214    procedure Delete (Name : String);
 215    --  Wrapper to unlink as status is ignored by this application
 216
 217    procedure Error_Msg (Message : String);
 218    --  Output the error or warning Message
 219
 220    procedure Exit_With_Error (Error : String);
 221    --  Output Error and exit program with a fatal condition
 222
 223    procedure Process_Args;
 224    --  Go through all the arguments and build option tables
 225
 226    procedure Process_Binder_File (Name : String);
 227    --  Reads the binder file and extracts linker arguments
 228
 229    procedure Usage;
 230    --  Display usage
 231
 232    procedure Write_Header;
 233    --  Show user the program name, version and copyright
 234
 235    procedure Write_Usage;
 236    --  Show user the program options
 237
 238    ---------------
 239    -- Base_Name --
 240    ---------------
 241
 242    function Base_Name (File_Name : String) return String is
 243       Findex1 : Natural;
 244       Findex2 : Natural;
 245
 246    begin
 247       Findex1 := File_Name'First;
 248
 249       --  The file might be specified by a full path name. However,
 250       --  we want the path to be stripped away.
 251
 252       for J in reverse File_Name'Range loop
 253          if Is_Directory_Separator (File_Name (J)) then
 254             Findex1 := J + 1;
 255             exit;
 256          end if;
 257       end loop;
 258
 259       Findex2 := File_Name'Last;
 260       while Findex2 > Findex1
 261         and then File_Name (Findex2) /=  '.'
 262       loop
 263          Findex2 := Findex2 - 1;
 264       end loop;
 265
 266       if Findex2 = Findex1 then
 267          Findex2 := File_Name'Last + 1;
 268       end if;
 269
 270       return File_Name (Findex1 .. Findex2 - 1);
 271    end Base_Name;
 272
 273    -------------------------------
 274    -- Check_Existing_Executable --
 275    -------------------------------
 276
 277    procedure Check_Existing_Executable (File_Name : String) is
 278       Ename : String := File_Name;
 279       Efile : File_Name_Type;
 280       Sfile : File_Name_Type;
 281
 282    begin
 283       Canonical_Case_File_Name (Ename);
 284       Name_Len := 0;
 285       Add_Str_To_Name_Buffer (Ename);
 286       Efile := Name_Find;
 287
 288       for J in Units.Table'First .. Units.Last loop
 289          Sfile := Units.Table (J).Sfile;
 290          if Sfile = Efile then
 291             Exit_With_Error ("executable name """ & File_Name & """ matches "
 292               & "source file name """ & Get_Name_String (Sfile) & """");
 293          end if;
 294       end loop;
 295
 296       Delete (File_Name);
 297    end Check_Existing_Executable;
 298
 299    ------------
 300    -- Delete --
 301    ------------
 302
 303    procedure Delete (Name : String) is
 304       Status : int;
 305       pragma Unreferenced (Status);
 306    begin
 307       Status := unlink (Name'Address);
 308       --  Is it really right to ignore an error here ???
 309    end Delete;
 310
 311    ---------------
 312    -- Error_Msg --
 313    ---------------
 314
 315    procedure Error_Msg (Message : String) is
 316    begin
 317       Write_Str (Base_Name (Command_Name));
 318       Write_Str (": ");
 319       Write_Str (Message);
 320       Write_Eol;
 321    end Error_Msg;
 322
 323    ---------------------
 324    -- Exit_With_Error --
 325    ---------------------
 326
 327    procedure Exit_With_Error (Error : String) is
 328    begin
 329       Error_Msg (Error);
 330       Exit_Program (E_Fatal);
 331    end Exit_With_Error;
 332
 333    ------------------
 334    -- Process_Args --
 335    ------------------
 336
 337    procedure Process_Args is
 338       Next_Arg  : Integer;
 339       Skip_Next : Boolean := False;
 340       --  Set to true if the next argument is to be added into the list of
 341       --  linker's argument without parsing it.
 342
 343       procedure Check_Version_And_Help is new Check_Version_And_Help_G (Usage);
 344
 345       --  Start of processing for Process_Args
 346
 347    begin
 348       --  First, check for --version and --help
 349
 350       Check_Version_And_Help ("GNATLINK", "1995");
 351
 352       --  Loop through arguments of gnatlink command
 353
 354       Next_Arg := 1;
 355       loop
 356          exit when Next_Arg > Argument_Count;
 357
 358          Process_One_Arg : declare
 359             Arg : constant String := Argument (Next_Arg);
 360
 361          begin
 362             --  Case of argument which is a switch
 363
 364             --  We definitely need section by section comments here ???
 365
 366             if Skip_Next then
 367
 368                --  This argument must not be parsed, just add it to the
 369                --  list of linker's options.
 370
 371                Skip_Next := False;
 372
 373                Linker_Options.Increment_Last;
 374                Linker_Options.Table (Linker_Options.Last) :=
 375                  new String'(Arg);
 376
 377             elsif Arg'Length /= 0 and then Arg (1) = '-' then
 378                if Arg'Length > 4 and then Arg (2 .. 5) =  "gnat" then
 379                   Exit_With_Error
 380                     ("invalid switch: """ & Arg & """ (gnat not needed here)");
 381                end if;
 382
 383                if Arg = "-Xlinker" then
 384
 385                   --  Next argument should be sent directly to the linker.
 386                   --  We do not want to parse it here.
 387
 388                   Skip_Next := True;
 389
 390                   Linker_Options.Increment_Last;
 391                   Linker_Options.Table (Linker_Options.Last) :=
 392                     new String'(Arg);
 393
 394                elsif Arg (2) = 'g'
 395                  and then (Arg'Length < 5 or else Arg (2 .. 5) /= "gnat")
 396                then
 397                   Debug_Flag_Present := True;
 398
 399                   Linker_Options.Increment_Last;
 400                   Linker_Options.Table (Linker_Options.Last) :=
 401                    new String'(Arg);
 402
 403                   Binder_Options.Increment_Last;
 404                   Binder_Options.Table (Binder_Options.Last) :=
 405                     Linker_Options.Table (Linker_Options.Last);
 406
 407                elsif Arg'Length >= 3 and then Arg (2) = 'M' then
 408                   declare
 409                      Switches : String_List_Access;
 410
 411                   begin
 412                      Convert (Map_File, Arg (3 .. Arg'Last), Switches);
 413
 414                      if Switches /= null then
 415                         for J in Switches'Range loop
 416                            Linker_Options.Increment_Last;
 417                            Linker_Options.Table (Linker_Options.Last) :=
 418                              Switches (J);
 419                         end loop;
 420                      end if;
 421                   end;
 422
 423                elsif Arg'Length = 2 then
 424                   case Arg (2) is
 425                      when 'b' =>
 426                         Linker_Options.Increment_Last;
 427                         Linker_Options.Table (Linker_Options.Last) :=
 428                           new String'(Arg);
 429
 430                         Binder_Options.Increment_Last;
 431                         Binder_Options.Table (Binder_Options.Last) :=
 432                           Linker_Options.Table (Linker_Options.Last);
 433
 434                         Next_Arg := Next_Arg + 1;
 435
 436                         if Next_Arg > Argument_Count then
 437                            Exit_With_Error ("Missing argument for -b");
 438                         end if;
 439
 440                         Get_Machine_Name : declare
 441                            Name_Arg : constant String_Access :=
 442                                         new String'(Argument (Next_Arg));
 443
 444                         begin
 445                            Linker_Options.Increment_Last;
 446                            Linker_Options.Table (Linker_Options.Last) :=
 447                              Name_Arg;
 448
 449                            Binder_Options.Increment_Last;
 450                            Binder_Options.Table (Binder_Options.Last) :=
 451                              Name_Arg;
 452
 453                         end Get_Machine_Name;
 454
 455                      when 'f' =>
 456                         if Object_List_File_Supported then
 457                            Object_List_File_Required := True;
 458                         else
 459                            Exit_With_Error
 460                              ("Object list file not supported on this target");
 461                         end if;
 462
 463                      when 'M' =>
 464                         Create_Map_File := True;
 465
 466                      when 'n' =>
 467                         Compile_Bind_File := False;
 468
 469                      when 'o' =>
 470                         Next_Arg := Next_Arg + 1;
 471
 472                         if Next_Arg > Argument_Count then
 473                            Exit_With_Error ("Missing argument for -o");
 474                         end if;
 475
 476                         Output_File_Name :=
 477                           new String'(Executable_Name
 478                                         (Argument (Next_Arg),
 479                                          Only_If_No_Suffix => True));
 480
 481                      when 'P' =>
 482                         Opt.CodePeer_Mode := True;
 483
 484                      when 'R' =>
 485                         Opt.Run_Path_Option := False;
 486
 487                      when 'v' =>
 488
 489                         --  Support "double" verbose mode.  Second -v
 490                         --  gets sent to the linker and binder phases.
 491
 492                         if Verbose_Mode then
 493                            Very_Verbose_Mode := True;
 494
 495                            Linker_Options.Increment_Last;
 496                            Linker_Options.Table (Linker_Options.Last) :=
 497                             new String'(Arg);
 498
 499                            Binder_Options.Increment_Last;
 500                            Binder_Options.Table (Binder_Options.Last) :=
 501                              Linker_Options.Table (Linker_Options.Last);
 502
 503                         else
 504                            Verbose_Mode := True;
 505
 506                         end if;
 507
 508                      when others =>
 509                         Linker_Options.Increment_Last;
 510                         Linker_Options.Table (Linker_Options.Last) :=
 511                          new String'(Arg);
 512
 513                   end case;
 514
 515                elsif Arg (2) = 'B' then
 516                   Linker_Options.Increment_Last;
 517                   Linker_Options.Table (Linker_Options.Last) :=
 518                     new String'(Arg);
 519
 520                   Binder_Options.Increment_Last;
 521                   Binder_Options.Table (Binder_Options.Last) :=
 522                     Linker_Options.Table (Linker_Options.Last);
 523
 524                elsif Arg'Length >= 7 and then Arg (1 .. 7) = "--LINK=" then
 525                   if Arg'Length = 7 then
 526                      Exit_With_Error ("Missing argument for --LINK=");
 527                   end if;
 528
 529                   Linker_Path :=
 530                     System.OS_Lib.Locate_Exec_On_Path (Arg (8 .. Arg'Last));
 531
 532                   if Linker_Path = null then
 533                      Exit_With_Error
 534                        ("Could not locate linker: " & Arg (8 .. Arg'Last));
 535                   end if;
 536
 537                elsif Arg'Length > 6 and then Arg (1 .. 6) = "--GCC=" then
 538                   declare
 539                      Program_Args : constant Argument_List_Access :=
 540                                       Argument_String_To_List
 541                                                  (Arg (7 .. Arg'Last));
 542
 543                   begin
 544                      if Program_Args.all (1).all /= Gcc.all then
 545                         Gcc := new String'(Program_Args.all (1).all);
 546                         Standard_Gcc := False;
 547                      end if;
 548
 549                      --  Set appropriate flags for switches passed
 550
 551                      for J in 2 .. Program_Args.all'Last loop
 552                         declare
 553                            Arg : constant String := Program_Args.all (J).all;
 554                            AF  : constant Integer := Arg'First;
 555
 556                         begin
 557                            if Arg'Length /= 0 and then Arg (AF) = '-' then
 558                               if Arg (AF + 1) = 'g'
 559                                 and then (Arg'Length = 2
 560                                   or else Arg (AF + 2) in '0' .. '3'
 561                                   or else Arg (AF + 2 .. Arg'Last) = "coff")
 562                               then
 563                                  Debug_Flag_Present := True;
 564                               end if;
 565                            end if;
 566
 567                            --  Add directory to source search dirs so that
 568                            --  Get_Target_Parameters can find system.ads
 569
 570                            if Arg (AF .. AF + 1) = "-I"
 571                              and then Arg'Length > 2
 572                            then
 573                               Add_Src_Search_Dir (Arg (AF + 2 .. Arg'Last));
 574                            end if;
 575
 576                            --  Pass to gcc for compiling binder generated file
 577                            --  No use passing libraries, it will just generate
 578                            --  a warning
 579
 580                            if not (Arg (AF .. AF + 1) = "-l"
 581                              or else Arg (AF .. AF + 1) = "-L")
 582                            then
 583                               Binder_Options.Increment_Last;
 584                               Binder_Options.Table (Binder_Options.Last) :=
 585                                 new String'(Arg);
 586                            end if;
 587
 588                            --  Pass to gcc for linking program
 589
 590                            Gcc_Linker_Options.Increment_Last;
 591                            Gcc_Linker_Options.Table
 592                              (Gcc_Linker_Options.Last) := new String'(Arg);
 593                         end;
 594                      end loop;
 595                   end;
 596
 597                --  Send all multi-character switches not recognized as
 598                --  a special case by gnatlink to the linker/loader stage.
 599
 600                else
 601                   Linker_Options.Increment_Last;
 602                   Linker_Options.Table (Linker_Options.Last) :=
 603                     new String'(Arg);
 604                end if;
 605
 606             --  Here if argument is a file name rather than a switch
 607
 608             else
 609                --  If explicit ali file, capture it
 610
 611                if Arg'Length > 4
 612                  and then Arg (Arg'Last - 3 .. Arg'Last) = ".ali"
 613                then
 614                   if Ali_File_Name = null then
 615                      Ali_File_Name := new String'(Arg);
 616                   else
 617                      Exit_With_Error ("cannot handle more than one ALI file");
 618                   end if;
 619
 620                --  If target object file, record object file
 621
 622                elsif Arg'Length > Get_Target_Object_Suffix.all'Length
 623                  and then Arg
 624                    (Arg'Last -
 625                     Get_Target_Object_Suffix.all'Length + 1 .. Arg'Last)
 626                    = Get_Target_Object_Suffix.all
 627                then
 628                   Linker_Objects.Increment_Last;
 629                   Linker_Objects.Table (Linker_Objects.Last) :=
 630                     new String'(Arg);
 631
 632                --  If host object file, record object file
 633                --  e.g. accept foo.o as well as foo.obj on VMS target
 634
 635                elsif Arg'Length > Get_Object_Suffix.all'Length
 636                  and then Arg
 637                    (Arg'Last - Get_Object_Suffix.all'Length + 1 .. Arg'Last)
 638                                                 = Get_Object_Suffix.all
 639                then
 640                   Linker_Objects.Increment_Last;
 641                   Linker_Objects.Table (Linker_Objects.Last) :=
 642                     new String'(Arg);
 643
 644                --  If corresponding ali file exists, capture it
 645
 646                elsif Ali_File_Name = null
 647                  and then Is_Regular_File (Arg & ".ali")
 648                then
 649                   Ali_File_Name := new String'(Arg & ".ali");
 650
 651                --  Otherwise assume this is a linker options entry, but
 652                --  see below for interesting adjustment to this assumption.
 653
 654                else
 655                   Linker_Options.Increment_Last;
 656                   Linker_Options.Table (Linker_Options.Last) :=
 657                     new String'(Arg);
 658                end if;
 659             end if;
 660          end Process_One_Arg;
 661
 662          Next_Arg := Next_Arg + 1;
 663       end loop;
 664
 665       --  Compile the bind file with warnings suppressed, because
 666       --  otherwise the with of the main program may cause junk warnings.
 667
 668       Binder_Options.Increment_Last;
 669       Binder_Options.Table (Binder_Options.Last) := new String'("-gnatws");
 670
 671       --  If we did not get an ali file at all, and we had at least one
 672       --  linker option, then assume that was the intended ali file after
 673       --  all, so that we get a nicer message later on.
 674
 675       if Ali_File_Name = null
 676         and then Linker_Options.Last >= Linker_Options.First
 677       then
 678          Ali_File_Name :=
 679            new String'(Linker_Options.Table (Linker_Options.First).all &
 680                                                                    ".ali");
 681       end if;
 682    end Process_Args;
 683
 684    -------------------------
 685    -- Process_Binder_File --
 686    -------------------------
 687
 688    procedure Process_Binder_File (Name : String) is
 689       Fd : FILEs;
 690       --  Binder file's descriptor
 691
 692       Link_Bytes : Integer := 0;
 693       --  Projected number of bytes for the linker command line
 694
 695       Link_Max : Integer;
 696       pragma Import (C, Link_Max, "__gnat_link_max");
 697       --  Maximum number of bytes on the command line supported by the OS
 698       --  linker. Passed this limit the response file mechanism must be used
 699       --  if supported.
 700
 701       Next_Line : String (1 .. 1000);
 702       --  Current line value
 703
 704       Nlast  : Integer;
 705       Nfirst : Integer;
 706       --  Current line slice (the slice does not contain line terminator)
 707
 708       Last : Integer;
 709       --  Current line last character for shared libraries (without version)
 710
 711       Objs_Begin : Integer := 0;
 712       --  First object file index in Linker_Objects table
 713
 714       Objs_End : Integer := 0;
 715       --  Last object file index in Linker_Objects table
 716
 717       Status : int;
 718       pragma Warnings (Off, Status);
 719       --  Used for various Interfaces.C_Streams calls
 720
 721       Closing_Status : Boolean;
 722       pragma Warnings (Off, Closing_Status);
 723       --  For call to Close
 724
 725       GNAT_Static : Boolean := False;
 726       --  Save state of -static option
 727
 728       GNAT_Shared : Boolean := False;
 729       --  Save state of -shared option
 730
 731       Xlinker_Was_Previous : Boolean := False;
 732       --  Indicate that "-Xlinker" was the option preceding the current
 733       --  option. If True, then the current option is never suppressed.
 734
 735       --  Rollback data
 736
 737       --  These data items are used to store current binder file context.
 738       --  The context is composed of the file descriptor position and the
 739       --  current line together with the slice indexes (first and last
 740       --  position) for this line. The rollback data are used by the
 741       --  Store_File_Context and Rollback_File_Context routines below.
 742       --  The file context mechanism interact only with the Get_Next_Line
 743       --  call. For example:
 744
 745       --     Store_File_Context;
 746       --     Get_Next_Line;
 747       --     Rollback_File_Context;
 748       --     Get_Next_Line;
 749
 750       --  Both Get_Next_Line calls above will read the exact same data from
 751       --  the file. In other words, Next_Line, Nfirst and Nlast variables
 752       --  will be set with the exact same values.
 753
 754       RB_File_Pos  : long;                -- File position
 755       RB_Next_Line : String (1 .. 1000);  -- Current line content
 756       RB_Nlast     : Integer;             -- Slice last index
 757       RB_Nfirst    : Integer;             -- Slice first index
 758
 759       Run_Path_Option_Ptr : Interfaces.C.Strings.chars_ptr;
 760       pragma Import (C, Run_Path_Option_Ptr, "__gnat_run_path_option");
 761       --  Pointer to string representing the native linker option which
 762       --  specifies the path where the dynamic loader should find shared
 763       --  libraries. Equal to null string if this system doesn't support it.
 764
 765       Libgcc_Subdir_Ptr : Interfaces.C.Strings.chars_ptr;
 766       pragma Import (C, Libgcc_Subdir_Ptr, "__gnat_default_libgcc_subdir");
 767       --  Pointer to string indicating the installation subdirectory where
 768       --  a default shared libgcc might be found.
 769
 770       Object_Library_Ext_Ptr : Interfaces.C.Strings.chars_ptr;
 771       pragma Import
 772         (C, Object_Library_Ext_Ptr, "__gnat_object_library_extension");
 773       --  Pointer to string specifying the default extension for
 774       --  object libraries, e.g. Unix uses ".a", VMS uses ".olb".
 775
 776       Separate_Run_Path_Options : Boolean;
 777       for Separate_Run_Path_Options'Size use Character'Size;
 778       pragma Import
 779         (C, Separate_Run_Path_Options, "__gnat_separate_run_path_options");
 780       --  Whether separate rpath options should be emitted for each directory
 781
 782       procedure Get_Next_Line;
 783       --  Read the next line from the binder file without the line
 784       --  terminator.
 785
 786       function Index (S, Pattern : String) return Natural;
 787       --  Return the last occurrence of Pattern in S, or 0 if none
 788
 789       function Is_Option_Present (Opt : String) return Boolean;
 790       --  Return true if the option Opt is already present in
 791       --  Linker_Options table.
 792
 793       procedure Store_File_Context;
 794       --  Store current file context, Fd position and current line data.
 795       --  The file context is stored into the rollback data above (RB_*).
 796       --  Store_File_Context can be called at any time, only the last call
 797       --  will be used (i.e. this routine overwrites the file context).
 798
 799       procedure Rollback_File_Context;
 800       --  Restore file context from rollback data. This routine must be called
 801       --  after Store_File_Context. The binder file context will be restored
 802       --  with the data stored by the last Store_File_Context call.
 803
 804       procedure Write_RF (S : String);
 805       --  Write a string to the response file and check if it was successful.
 806       --  Fail the program if it was not successful (disk full).
 807
 808       -------------------
 809       -- Get_Next_Line --
 810       -------------------
 811
 812       procedure Get_Next_Line is
 813          Fchars : chars;
 814
 815       begin
 816          Fchars := fgets (Next_Line'Address, Next_Line'Length, Fd);
 817
 818          if Fchars = System.Null_Address then
 819             Exit_With_Error ("Error reading binder output");
 820          end if;
 821
 822          Nfirst := Next_Line'First;
 823          Nlast := Nfirst;
 824          while Nlast <= Next_Line'Last
 825            and then Next_Line (Nlast) /= ASCII.LF
 826            and then Next_Line (Nlast) /= ASCII.CR
 827          loop
 828             Nlast := Nlast + 1;
 829          end loop;
 830
 831          Nlast := Nlast - 1;
 832       end Get_Next_Line;
 833
 834       -----------
 835       -- Index --
 836       -----------
 837
 838       function Index (S, Pattern : String) return Natural is
 839          Len : constant Natural := Pattern'Length;
 840
 841       begin
 842          for J in reverse S'First .. S'Last - Len + 1 loop
 843             if Pattern = S (J .. J + Len - 1) then
 844                return J;
 845             end if;
 846          end loop;
 847
 848          return 0;
 849       end Index;
 850
 851       -----------------------
 852       -- Is_Option_Present --
 853       -----------------------
 854
 855       function Is_Option_Present (Opt : String) return Boolean is
 856       begin
 857          for I in 1 .. Linker_Options.Last loop
 858
 859             if Linker_Options.Table (I).all = Opt then
 860                return True;
 861             end if;
 862
 863          end loop;
 864
 865          return False;
 866       end Is_Option_Present;
 867
 868       ---------------------------
 869       -- Rollback_File_Context --
 870       ---------------------------
 871
 872       procedure Rollback_File_Context is
 873       begin
 874          Next_Line := RB_Next_Line;
 875          Nfirst    := RB_Nfirst;
 876          Nlast     := RB_Nlast;
 877          Status    := fseek (Fd, RB_File_Pos, Interfaces.C_Streams.SEEK_SET);
 878
 879          if Status = -1 then
 880             Exit_With_Error ("Error setting file position");
 881          end if;
 882       end Rollback_File_Context;
 883
 884       ------------------------
 885       -- Store_File_Context --
 886       ------------------------
 887
 888       procedure Store_File_Context is
 889          use type System.CRTL.long;
 890       begin
 891          RB_Next_Line := Next_Line;
 892          RB_Nfirst    := Nfirst;
 893          RB_Nlast     := Nlast;
 894          RB_File_Pos  := ftell (Fd);
 895
 896          if RB_File_Pos = -1 then
 897             Exit_With_Error ("Error getting file position");
 898          end if;
 899       end Store_File_Context;
 900
 901       --------------
 902       -- Write_RF --
 903       --------------
 904
 905       procedure Write_RF (S : String) is
 906          Success : Boolean := True;
 907       begin
 908          --  If a GNU response file is used, space and backslash need to be
 909          --  escaped because they are interpreted as a string separator and
 910          --  an escape character respectively by the underlying mechanism.
 911          --  On the other hand, quote and double-quote are not escaped since
 912          --  they are interpreted as string delimiters on both sides.
 913
 914          if Using_GNU_response_file then
 915             for I in S'Range loop
 916                if S (I) = ' ' or else S (I) = '\' then
 917                   if Write (Tname_FD, ASCII.BACK_SLASH'Address, 1) /= 1 then
 918                      Success := False;
 919                   end if;
 920                end if;
 921
 922                if Write (Tname_FD, S (I)'Address, 1) /= 1 then
 923                   Success := False;
 924                end if;
 925             end loop;
 926          else
 927             if Write (Tname_FD, S'Address, S'Length) /= S'Length then
 928                Success := False;
 929             end if;
 930          end if;
 931
 932          if Write (Tname_FD, ASCII.LF'Address, 1) /= 1 then
 933             Success := False;
 934          end if;
 935
 936          if not Success then
 937             Exit_With_Error ("Error generating response file: disk full");
 938          end if;
 939       end Write_RF;
 940
 941    --  Start of processing for Process_Binder_File
 942
 943    begin
 944       Fd := fopen (Name'Address, Read_Mode'Address);
 945
 946       if Fd = NULL_Stream then
 947          Exit_With_Error ("Failed to open binder output");
 948       end if;
 949
 950       --  Skip up to the Begin Info line
 951
 952       loop
 953          Get_Next_Line;
 954          exit when Next_Line (Nfirst .. Nlast) = Begin_Info;
 955       end loop;
 956
 957       loop
 958          Get_Next_Line;
 959
 960          --  Go to end when end line is reached (this will happen in
 961          --  High_Integrity_Mode where no -L switches are generated)
 962
 963          exit when Next_Line (Nfirst .. Nlast) = End_Info;
 964
 965          Next_Line (Nfirst .. Nlast - 8) := Next_Line (Nfirst + 8 .. Nlast);
 966          Nlast := Nlast - 8;
 967
 968          --  Go to next section when switches are reached
 969
 970          exit when Next_Line (1) = '-';
 971
 972          --  Otherwise we have another object file to collect
 973
 974          Linker_Objects.Increment_Last;
 975
 976          --  Mark the positions of first and last object files in case
 977          --  they need to be placed with a named file on systems having
 978          --  linker line limitations.
 979
 980          if Objs_Begin = 0 then
 981             Objs_Begin := Linker_Objects.Last;
 982          end if;
 983
 984          Linker_Objects.Table (Linker_Objects.Last) :=
 985            new String'(Next_Line (Nfirst .. Nlast));
 986
 987          Link_Bytes := Link_Bytes + Nlast - Nfirst + 2;
 988          --  Nlast - Nfirst + 1, for the size, plus one for the space between
 989          --  each arguments.
 990       end loop;
 991
 992       Objs_End := Linker_Objects.Last;
 993
 994       --  Continue to compute the Link_Bytes, the linker options are part of
 995       --  command line length.
 996
 997       Store_File_Context;
 998
 999       while Next_Line (Nfirst .. Nlast) /= End_Info loop
1000          Link_Bytes := Link_Bytes + Nlast - Nfirst + 2;
1001          Get_Next_Line;
1002       end loop;
1003
1004       Rollback_File_Context;
1005
1006       --  On systems that have limitations on handling very long linker lines
1007       --  we make use of the system linker option which takes a list of object
1008       --  file names from a file instead of the command line itself. What we do
1009       --  is to replace the list of object files by the special linker option
1010       --  which then reads the object file list from a file instead. The option
1011       --  to read from a file instead of the command line is only triggered if
1012       --  a conservative threshold is passed.
1013
1014       if Object_List_File_Required
1015         or else (Object_List_File_Supported
1016                    and then Link_Bytes > Link_Max)
1017       then
1018          --  Create a temporary file containing the Ada user object files
1019          --  needed by the link. This list is taken from the bind file
1020          --  and is output one object per line for maximal compatibility with
1021          --  linkers supporting this option.
1022
1023          Create_Temp_File (Tname_FD, Tname);
1024
1025          --  ??? File descriptor should be checked to not be Invalid_FD.
1026          --  ??? Status of Write and Close operations should be checked, and
1027          --  failure should occur if a status is wrong.
1028
1029          for J in Objs_Begin .. Objs_End loop
1030             Write_RF (Linker_Objects.Table (J).all);
1031
1032             Response_File_Objects.Increment_Last;
1033             Response_File_Objects.Table (Response_File_Objects.Last) :=
1034               Linker_Objects.Table (J);
1035          end loop;
1036
1037          Close (Tname_FD, Closing_Status);
1038
1039          --  Add the special objects list file option together with the name
1040          --  of the temporary file (removing the null character) to the objects
1041          --  file table.
1042
1043          Linker_Objects.Table (Objs_Begin) :=
1044            new String'(Object_File_Option &
1045                        Tname (Tname'First .. Tname'Last - 1));
1046
1047          --  The slots containing these object file names are then removed
1048          --  from the objects table so they do not appear in the link. They
1049          --  are removed by moving up the linker options and non-Ada object
1050          --  files appearing after the Ada object list in the table.
1051
1052          declare
1053             N : Integer;
1054
1055          begin
1056             N := Objs_End - Objs_Begin + 1;
1057
1058             for J in Objs_End + 1 .. Linker_Objects.Last loop
1059                Linker_Objects.Table (J - N + 1) := Linker_Objects.Table (J);
1060             end loop;
1061
1062             Linker_Objects.Set_Last (Linker_Objects.Last - N + 1);
1063          end;
1064       end if;
1065
1066       --  Process switches and options
1067
1068       if Next_Line (Nfirst .. Nlast) /= End_Info then
1069          Xlinker_Was_Previous := False;
1070
1071          loop
1072             if Xlinker_Was_Previous
1073               or else Next_Line (Nfirst .. Nlast) = "-Xlinker"
1074             then
1075                Linker_Options.Increment_Last;
1076                Linker_Options.Table (Linker_Options.Last) :=
1077                  new String'(Next_Line (Nfirst .. Nlast));
1078
1079             elsif Next_Line (Nfirst .. Nlast) = "-static" then
1080                GNAT_Static := True;
1081
1082             elsif Next_Line (Nfirst .. Nlast) = "-shared" then
1083                GNAT_Shared := True;
1084
1085             --  Add binder options only if not already set on the command
1086             --  line. This rule is a way to control the linker options order.
1087
1088             --  The following test needs comments, why is it VMS specific.
1089             --  The above comment looks out of date ???
1090
1091             elsif not (OpenVMS_On_Target
1092                          and then
1093                        Is_Option_Present (Next_Line (Nfirst .. Nlast)))
1094             then
1095                if Nlast > Nfirst + 2 and then
1096                  Next_Line (Nfirst .. Nfirst + 1) = "-L"
1097                then
1098                   --  Construct a library search path for use later
1099                   --  to locate static gnatlib libraries.
1100
1101                   if Libpath.Last > 1 then
1102                      Libpath.Increment_Last;
1103                      Libpath.Table (Libpath.Last) := Path_Separator;
1104                   end if;
1105
1106                   for I in Nfirst + 2 .. Nlast loop
1107                      Libpath.Increment_Last;
1108                      Libpath.Table (Libpath.Last) := Next_Line (I);
1109                   end loop;
1110
1111                   Linker_Options.Increment_Last;
1112
1113                   Linker_Options.Table (Linker_Options.Last) :=
1114                     new String'(Next_Line (Nfirst .. Nlast));
1115
1116                elsif Next_Line (Nfirst .. Nlast) = "-ldecgnat"
1117                  or else Next_Line (Nfirst .. Nlast) = "-lgnarl"
1118                  or else Next_Line (Nfirst .. Nlast) = "-lgnat"
1119                  or else Next_Line
1120                      (1 .. Natural'Min (Nlast, 8 + Library_Version'Length)) =
1121                        Shared_Lib ("gnarl")
1122                  or else Next_Line
1123                      (1 .. Natural'Min (Nlast, 7 + Library_Version'Length)) =
1124                        Shared_Lib ("gnat")
1125                then
1126                   --  If it is a shared library, remove the library version.
1127                   --  We will be looking for the static version of the library
1128                   --  as it is in the same directory as the shared version.
1129
1130                   if Next_Line (Nlast - Library_Version'Length + 1 .. Nlast)
1131                        = Library_Version
1132                   then
1133                      --  Set Last to point to last character before the
1134                      --  library version.
1135
1136                      Last := Nlast - Library_Version'Length - 1;
1137                   else
1138                      Last := Nlast;
1139                   end if;
1140
1141                   --  Given a Gnat standard library, search the library path to
1142                   --  find the library location.
1143
1144                   --  Shouldn't we abstract a proc here, we are getting awfully
1145                   --  heavily nested ???
1146
1147                   declare
1148                      File_Path : String_Access;
1149
1150                      Object_Lib_Extension : constant String :=
1151                                               Value (Object_Library_Ext_Ptr);
1152
1153                      File_Name : constant String := "lib" &
1154                                    Next_Line (Nfirst + 2 .. Last) &
1155                                    Object_Lib_Extension;
1156
1157                      Run_Path_Opt : constant String :=
1158                        Value (Run_Path_Option_Ptr);
1159
1160                      GCC_Index          : Natural;
1161                      Run_Path_Opt_Index : Natural := 0;
1162
1163                   begin
1164                      File_Path :=
1165                        Locate_Regular_File (File_Name,
1166                          String (Libpath.Table (1 .. Libpath.Last)));
1167
1168                      if File_Path /= null then
1169                         if GNAT_Static then
1170
1171                            --  If static gnatlib found, explicitly
1172                            --  specify to overcome possible linker
1173                            --  default usage of shared version.
1174
1175                            Linker_Options.Increment_Last;
1176
1177                            Linker_Options.Table (Linker_Options.Last) :=
1178                              new String'(File_Path.all);
1179
1180                         elsif GNAT_Shared then
1181                            if Opt.Run_Path_Option then
1182
1183                               --  If shared gnatlib desired, add the
1184                               --  appropriate system specific switch
1185                               --  so that it can be located at runtime.
1186
1187                               if Run_Path_Opt'Length /= 0 then
1188
1189                                  --  Output the system specific linker command
1190                                  --  that allows the image activator to find
1191                                  --  the shared library at runtime. Also add
1192                                  --  path to find libgcc_s.so, if relevant.
1193
1194                                  declare
1195                                     Path : String (1 .. File_Path'Length + 15);
1196                                     Path_Last : constant Natural :=
1197                                                   File_Path'Length;
1198
1199                                  begin
1200                                     Path (1 .. File_Path'Length) :=
1201                                       File_Path.all;
1202
1203                                  --  To find the location of the shared version
1204                                  --  of libgcc, we look for "gcc-lib" in the
1205                                  --  path of the library. However, this
1206                                  --  subdirectory is no longer present in
1207                                  --  recent versions of GCC. So, we look for
1208                                  --  the last subdirectory "lib" in the path.
1209
1210                                     GCC_Index :=
1211                                       Index (Path (1 .. Path_Last), "gcc-lib");
1212
1213                                     if GCC_Index /= 0 then
1214
1215                                        --  The shared version of libgcc is
1216                                        --  located in the parent directory.
1217
1218                                        GCC_Index := GCC_Index - 1;
1219
1220                                     else
1221                                        GCC_Index :=
1222                                          Index
1223                                            (Path (1 .. Path_Last),
1224                                             "/lib/");
1225
1226                                        if GCC_Index = 0 then
1227                                           GCC_Index :=
1228                                             Index (Path (1 .. Path_Last),
1229                                                    Directory_Separator &
1230                                                    "lib" &
1231                                                    Directory_Separator);
1232                                        end if;
1233
1234                                        --  If we have found a "lib" subdir in
1235                                        --  the path to libgnat, the possible
1236                                        --  shared libgcc of interest by default
1237                                        --  is in libgcc_subdir at the same
1238                                        --  level.
1239
1240                                        if GCC_Index /= 0 then
1241                                           declare
1242                                              Subdir : constant String :=
1243                                                Value (Libgcc_Subdir_Ptr);
1244                                           begin
1245                                              Path
1246                                                (GCC_Index + 1 ..
1247                                                 GCC_Index + Subdir'Length) :=
1248                                                Subdir;
1249                                              GCC_Index :=
1250                                                GCC_Index + Subdir'Length;
1251                                           end;
1252                                        end if;
1253                                     end if;
1254
1255                                  --  Look for an eventual run_path_option in
1256                                  --  the linker switches.
1257
1258                                     if Separate_Run_Path_Options then
1259                                        Linker_Options.Increment_Last;
1260                                        Linker_Options.Table
1261                                          (Linker_Options.Last) :=
1262                                            new String'
1263                                              (Run_Path_Opt
1264                                               & File_Path
1265                                                 (1 .. File_Path'Length
1266                                                  - File_Name'Length));
1267
1268                                        if GCC_Index /= 0 then
1269                                           Linker_Options.Increment_Last;
1270                                           Linker_Options.Table
1271                                             (Linker_Options.Last) :=
1272                                             new String'
1273                                               (Run_Path_Opt
1274                                                & Path (1 .. GCC_Index));
1275                                        end if;
1276
1277                                     else
1278                                        for J in reverse
1279                                          1 .. Linker_Options.Last
1280                                        loop
1281                                           if Linker_Options.Table (J) /= null
1282                                             and then
1283                                               Linker_Options.Table (J)'Length
1284                                                         > Run_Path_Opt'Length
1285                                             and then
1286                                               Linker_Options.Table (J)
1287                                                 (1 .. Run_Path_Opt'Length) =
1288                                                                  Run_Path_Opt
1289                                           then
1290                                              --  We have found an already
1291                                              --  specified run_path_option: we
1292                                              --  will add to this switch,
1293                                              --  because only one
1294                                              --  run_path_option should be
1295                                              --  specified.
1296
1297                                              Run_Path_Opt_Index := J;
1298                                              exit;
1299                                           end if;
1300                                        end loop;
1301
1302                                        --  If there is no run_path_option, we
1303                                        --  need to add one.
1304
1305                                        if Run_Path_Opt_Index = 0 then
1306                                           Linker_Options.Increment_Last;
1307                                        end if;
1308
1309                                        if GCC_Index = 0 then
1310                                           if Run_Path_Opt_Index = 0 then
1311                                              Linker_Options.Table
1312                                                (Linker_Options.Last) :=
1313                                                  new String'
1314                                                    (Run_Path_Opt
1315                                                     & File_Path
1316                                                       (1 .. File_Path'Length
1317                                                        - File_Name'Length));
1318
1319                                           else
1320                                              Linker_Options.Table
1321                                                (Run_Path_Opt_Index) :=
1322                                                  new String'
1323                                                    (Linker_Options.Table
1324                                                      (Run_Path_Opt_Index).all
1325                                                     & Path_Separator
1326                                                     & File_Path
1327                                                       (1 .. File_Path'Length
1328                                                        - File_Name'Length));
1329                                           end if;
1330
1331                                        else
1332                                           if Run_Path_Opt_Index = 0 then
1333                                              Linker_Options.Table
1334                                                (Linker_Options.Last) :=
1335                                                  new String'
1336                                                    (Run_Path_Opt
1337                                                     & File_Path
1338                                                       (1 .. File_Path'Length
1339                                                        - File_Name'Length)
1340                                                     & Path_Separator
1341                                                     & Path (1 .. GCC_Index));
1342
1343                                           else
1344                                              Linker_Options.Table
1345                                                (Run_Path_Opt_Index) :=
1346                                                  new String'
1347                                                    (Linker_Options.Table
1348                                                      (Run_Path_Opt_Index).all
1349                                                     & Path_Separator
1350                                                     & File_Path
1351                                                       (1 .. File_Path'Length
1352                                                        - File_Name'Length)
1353                                                     & Path_Separator
1354                                                     & Path (1 .. GCC_Index));
1355                                           end if;
1356                                        end if;
1357                                     end if;
1358                                  end;
1359                               end if;
1360                            end if;
1361
1362                            --  Then we add the appropriate -l switch
1363
1364                            Linker_Options.Increment_Last;
1365                            Linker_Options.Table (Linker_Options.Last) :=
1366                              new String'(Next_Line (Nfirst .. Nlast));
1367                         end if;
1368
1369                      else
1370                         --  If gnatlib library not found, then
1371                         --  add it anyway in case some other
1372                         --  mechanism may find it.
1373
1374                         Linker_Options.Increment_Last;
1375                         Linker_Options.Table (Linker_Options.Last) :=
1376                           new String'(Next_Line (Nfirst .. Nlast));
1377                      end if;
1378                   end;
1379                else
1380                   Linker_Options.Increment_Last;
1381                   Linker_Options.Table (Linker_Options.Last) :=
1382                     new String'(Next_Line (Nfirst .. Nlast));
1383                end if;
1384             end if;
1385
1386             Xlinker_Was_Previous := Next_Line (Nfirst .. Nlast) = "-Xlinker";
1387
1388             Get_Next_Line;
1389             exit when Next_Line (Nfirst .. Nlast) = End_Info;
1390
1391             Next_Line (Nfirst .. Nlast - 8) := Next_Line (Nfirst + 8 .. Nlast);
1392             Nlast := Nlast - 8;
1393          end loop;
1394       end if;
1395
1396       --  If -shared was specified, invoke gcc with -shared-libgcc
1397
1398       if GNAT_Shared then
1399          Linker_Options.Increment_Last;
1400          Linker_Options.Table (Linker_Options.Last) := Shared_Libgcc;
1401       end if;
1402
1403       Status := fclose (Fd);
1404    end Process_Binder_File;
1405
1406    -----------
1407    -- Usage --
1408    -----------
1409
1410    procedure Usage is
1411    begin
1412       Write_Str ("Usage: ");
1413       Write_Str (Base_Name (Command_Name));
1414       Write_Str (" switches mainprog.ali [non-Ada-objects] [linker-options]");
1415       Write_Eol;
1416       Write_Eol;
1417       Write_Line ("  mainprog.ali   the ALI file of the main program");
1418       Write_Eol;
1419       Write_Eol;
1420       Display_Usage_Version_And_Help;
1421       Write_Line ("  -f    Force object file list to be generated");
1422       Write_Line ("  -g    Compile binder source file with debug information");
1423       Write_Line ("  -n    Do not compile the binder source file");
1424       Write_Line ("  -P    Process files for use by CodePeer");
1425       Write_Line ("  -R    Do not use a run_path_option");
1426       Write_Line ("  -v    Verbose mode");
1427       Write_Line ("  -v -v Very verbose mode");
1428       Write_Eol;
1429       Write_Line ("  -o nam     Use 'nam' as the name of the executable");
1430       Write_Line ("  -b target  Compile the binder source to run on target");
1431       Write_Line ("  -Bdir      Load compiler executables from dir");
1432
1433       if Is_Supported (Map_File) then
1434          Write_Line ("  -Mmap      Create map file map");
1435          Write_Line ("  -M         Create map file mainprog.map");
1436       end if;
1437
1438       Write_Line ("  --GCC=comp Use comp as the compiler");
1439       Write_Line ("  --LINK=nam Use 'nam' for the linking rather than 'gcc'");
1440       Write_Eol;
1441       Write_Line ("  [non-Ada-objects]  list of non Ada object files");
1442       Write_Line ("  [linker-options]   other options for the linker");
1443    end Usage;
1444
1445    ------------------
1446    -- Write_Header --
1447    ------------------
1448
1449    procedure Write_Header is
1450    begin
1451       if Verbose_Mode then
1452          Write_Eol;
1453          Display_Version ("GNATLINK", "1995");
1454       end if;
1455    end Write_Header;
1456
1457    -----------------
1458    -- Write_Usage --
1459    -----------------
1460
1461    procedure Write_Usage is
1462    begin
1463       Write_Header;
1464       Usage;
1465    end Write_Usage;
1466
1467 --  Start of processing for Gnatlink
1468
1469 begin
1470    --  Add the directory where gnatlink is invoked in front of the path, if
1471    --  gnatlink is invoked with directory information. Only do this if the
1472    --  platform is not VMS, where the notion of path does not really exist.
1473
1474    if not Hostparm.OpenVMS then
1475       declare
1476          Command : constant String := Command_Name;
1477
1478       begin
1479          for Index in reverse Command'Range loop
1480             if Command (Index) = Directory_Separator then
1481                declare
1482                   Absolute_Dir : constant String :=
1483                                    Normalize_Pathname
1484                                      (Command (Command'First .. Index));
1485
1486                   PATH : constant String :=
1487                            Absolute_Dir &
1488                            Path_Separator &
1489                            Getenv ("PATH").all;
1490
1491                begin
1492                   Setenv ("PATH", PATH);
1493                end;
1494
1495                exit;
1496             end if;
1497          end loop;
1498       end;
1499    end if;
1500
1501    Process_Args;
1502
1503    if Argument_Count = 0
1504      or else (Verbose_Mode and then Argument_Count = 1)
1505    then
1506       Write_Usage;
1507       Exit_Program (E_Fatal);
1508    end if;
1509
1510    --  Initialize packages to be used
1511
1512    Csets.Initialize;
1513    Snames.Initialize;
1514
1515    --  We always compile with -c
1516
1517    Binder_Options_From_ALI.Increment_Last;
1518    Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1519      new String'("-c");
1520
1521    if Ali_File_Name = null then
1522       Exit_With_Error ("no ali file given for link");
1523    end if;
1524
1525    if not Is_Regular_File (Ali_File_Name.all) then
1526       Exit_With_Error (Ali_File_Name.all & " not found");
1527    end if;
1528
1529    --  Read the ALI file of the main subprogram if the binder generated file
1530    --  needs to be compiled and no --GCC= switch has been specified. Fetch the
1531    --  back end switches from this ALI file and use these switches to compile
1532    --  the binder generated file
1533
1534    if Compile_Bind_File and then Standard_Gcc then
1535       Initialize_ALI;
1536       Name_Len := Ali_File_Name'Length;
1537       Name_Buffer (1 .. Name_Len) := Ali_File_Name.all;
1538
1539       declare
1540          use Types;
1541          F : constant File_Name_Type := Name_Find;
1542          T : Text_Buffer_Ptr;
1543          A : ALI_Id;
1544
1545       begin
1546          --  Load the ALI file
1547
1548          T := Read_Library_Info (F, True);
1549
1550          --  Read it. Note that we ignore errors, since we only want very
1551          --  limited information from the ali file, and likely a slightly
1552          --  wrong version will be just fine, though in normal operation
1553          --  we don't expect this to happen!
1554
1555          A := Scan_ALI
1556                (F,
1557                 T,
1558                 Ignore_ED     => False,
1559                 Err           => False,
1560                 Ignore_Errors => True);
1561
1562          if A /= No_ALI_Id then
1563             for
1564               Index in Units.Table (ALIs.Table (A).First_Unit).First_Arg ..
1565                        Units.Table (ALIs.Table (A).First_Unit).Last_Arg
1566             loop
1567                --  Do not compile with the front end switches. However, --RTS
1568                --  is to be dealt with specially because it needs to be passed
1569                --  if the binder-generated file is in Ada and may also be used
1570                --  to drive the linker.
1571
1572                declare
1573                   Arg : String_Ptr renames Args.Table (Index);
1574                begin
1575                   if not Is_Front_End_Switch (Arg.all) then
1576                      Binder_Options_From_ALI.Increment_Last;
1577                      Binder_Options_From_ALI.Table
1578                        (Binder_Options_From_ALI.Last) := String_Access (Arg);
1579
1580                   elsif Arg'Length > 5
1581                     and then Arg (Arg'First + 2 .. Arg'First + 5) = "RTS="
1582                   then
1583                      Binder_Options_From_ALI.Increment_Last;
1584                      Binder_Options_From_ALI.Table
1585                        (Binder_Options_From_ALI.Last) := String_Access (Arg);
1586
1587                      --  Set the RTS_*_Path_Name variables, so that
1588                      --  the correct directories will be set when
1589                      --  Osint.Add_Default_Search_Dirs will be called later.
1590
1591                      Opt.RTS_Src_Path_Name :=
1592                        Get_RTS_Search_Dir
1593                          (Arg (Arg'First + 6 .. Arg'Last), Include);
1594
1595                      Opt.RTS_Lib_Path_Name :=
1596                        Get_RTS_Search_Dir
1597                          (Arg (Arg'First + 6 .. Arg'Last), Objects);
1598
1599                      --  GNAT doesn't support the GCC multilib mechanism.
1600                      --  This means that, when a multilib switch is used
1601                      --  to request a particular compilation mode, the
1602                      --  corresponding runtime switch (--RTS) must also be
1603                      --  specified. The long-term goal is to fully support the
1604                      --  multilib mechanism; however, in the meantime, it is
1605                      --  convenient to eliminate the redundancy by keying the
1606                      --  compilation mode on a single switch, namely --RTS.
1607
1608                      --  Pass -mrtp to the linker if --RTS=rtp was passed
1609
1610                      if Arg'Length > 8
1611                        and then
1612                          (Arg (Arg'First + 6 .. Arg'First + 8) = "rtp"
1613                            or else Arg (Arg'Last - 2 .. Arg'Last) = "rtp")
1614                      then
1615                         Linker_Options.Increment_Last;
1616                         Linker_Options.Table (Linker_Options.Last) :=
1617                           new String'("-mrtp");
1618                      end if;
1619                   end if;
1620                end;
1621             end loop;
1622          end if;
1623       end;
1624    end if;
1625
1626    --  Get target parameters
1627
1628    Osint.Add_Default_Search_Dirs;
1629    Targparm.Get_Target_Parameters;
1630
1631    if VM_Target /= No_VM then
1632       case VM_Target is
1633          when JVM_Target => Gcc := new String'("jvm-gnatcompile");
1634          when CLI_Target => Gcc := new String'("dotnet-gnatcompile");
1635          when No_VM      => raise Program_Error;
1636       end case;
1637    end if;
1638
1639    --  Compile the bind file with the following switches:
1640
1641    --    -gnatA   stops reading gnat.adc, since we don't know what
1642    --             pragmas would work, and we do not need it anyway.
1643
1644    --    -gnatWb  allows brackets coding for wide characters
1645
1646    --    -gnatiw  allows wide characters in identifiers. This is needed
1647    --             because bindgen uses brackets encoding for all upper
1648    --             half and wide characters in identifier names.
1649
1650    --  In addition, in CodePeer mode compile with -gnatcC
1651
1652    Binder_Options_From_ALI.Increment_Last;
1653    Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1654         new String'("-gnatA");
1655    Binder_Options_From_ALI.Increment_Last;
1656    Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1657         new String'("-gnatWb");
1658    Binder_Options_From_ALI.Increment_Last;
1659    Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1660         new String'("-gnatiw");
1661
1662    if Opt.CodePeer_Mode then
1663       Binder_Options_From_ALI.Increment_Last;
1664       Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1665            new String'("-gnatcC");
1666    end if;
1667
1668    --  Locate all the necessary programs and verify required files are present
1669
1670    Gcc_Path := System.OS_Lib.Locate_Exec_On_Path (Gcc.all);
1671
1672    if Gcc_Path = null then
1673       Exit_With_Error ("Couldn't locate " & Gcc.all);
1674    end if;
1675
1676    if Linker_Path = null then
1677       if VM_Target = CLI_Target then
1678          Linker_Path := System.OS_Lib.Locate_Exec_On_Path ("dotnet-ld");
1679
1680          if Linker_Path = null then
1681             Exit_With_Error ("Couldn't locate dotnet-ld");
1682          end if;
1683
1684       elsif RTX_RTSS_Kernel_Module_On_Target then
1685
1686          --  Use Microsoft linker for RTSS modules
1687
1688          Linker_Path := System.OS_Lib.Locate_Exec_On_Path ("link");
1689
1690          if Linker_Path = null then
1691             Exit_With_Error ("Couldn't locate link");
1692          end if;
1693
1694       else
1695          Linker_Path := Gcc_Path;
1696       end if;
1697    end if;
1698
1699    Write_Header;
1700
1701    --  If no output name specified, then use the base name of .ali file name
1702
1703    if Output_File_Name = null then
1704       Output_File_Name :=
1705         new String'(Base_Name (Ali_File_Name.all)
1706                       & Get_Target_Debuggable_Suffix.all);
1707    end if;
1708
1709    if RTX_RTSS_Kernel_Module_On_Target then
1710       Linker_Options.Increment_Last;
1711       Linker_Options.Table (Linker_Options.Last) :=
1712         new String'("/OUT:" & Output_File_Name.all);
1713
1714    else
1715       Linker_Options.Increment_Last;
1716       Linker_Options.Table (Linker_Options.Last) := new String'("-o");
1717
1718       Linker_Options.Increment_Last;
1719       Linker_Options.Table (Linker_Options.Last) :=
1720         new String'(Output_File_Name.all);
1721    end if;
1722
1723    Check_Existing_Executable (Output_File_Name.all);
1724
1725    --  Warn if main program is called "test", as that may be a built-in command
1726    --  on Unix. On non-Unix systems executables have a suffix, so the warning
1727    --  will not appear. However, do not warn in the case of a cross compiler.
1728
1729    --  Assume this is a cross tool if the executable name is not gnatlink
1730
1731    if Base_Name (Command_Name) = "gnatlink"
1732      and then Output_File_Name.all = "test"
1733    then
1734       Error_Msg ("warning: executable name """ & Output_File_Name.all
1735                    & """ may conflict with shell command");
1736    end if;
1737
1738    --  If -M switch was specified, add the switches to create the map file
1739
1740    if Create_Map_File then
1741       declare
1742          Map_Name : constant String := Base_Name (Ali_File_Name.all) & ".map";
1743          Switches : String_List_Access;
1744
1745       begin
1746          Convert (Map_File, Map_Name, Switches);
1747
1748          if Switches /= null then
1749             for J in Switches'Range loop
1750                Linker_Options.Increment_Last;
1751                Linker_Options.Table (Linker_Options.Last) := Switches (J);
1752             end loop;
1753          end if;
1754       end;
1755    end if;
1756
1757    --  Perform consistency checks
1758
1759    --  Transform the .ali file name into the binder output file name
1760
1761    Make_Binder_File_Names : declare
1762       Fname     : constant String  := Base_Name (Ali_File_Name.all);
1763       Fname_Len : Integer := Fname'Length;
1764
1765       function Get_Maximum_File_Name_Length return Integer;
1766       pragma Import (C, Get_Maximum_File_Name_Length,
1767                         "__gnat_get_maximum_file_name_length");
1768
1769       Maximum_File_Name_Length : constant Integer :=
1770                                    Get_Maximum_File_Name_Length;
1771
1772       Bind_File_Prefix : Types.String_Ptr;
1773       --  Contains prefix used for bind files
1774
1775    begin
1776       --  Set prefix
1777
1778       if OpenVMS_On_Target then
1779          Bind_File_Prefix := new String'("b__");
1780       else
1781          Bind_File_Prefix := new String'("b~");
1782       end if;
1783
1784       --  If the length of the binder file becomes too long due to
1785       --  the addition of the "b?" prefix, then truncate it.
1786
1787       if Maximum_File_Name_Length > 0 then
1788          while Fname_Len >
1789                  Maximum_File_Name_Length - Bind_File_Prefix.all'Length
1790          loop
1791             Fname_Len := Fname_Len - 1;
1792          end loop;
1793       end if;
1794
1795       declare
1796          Fnam : constant String :=
1797                   Bind_File_Prefix.all &
1798                     Fname (Fname'First .. Fname'First + Fname_Len - 1);
1799
1800       begin
1801          Binder_Spec_Src_File := new String'(Fnam & ".ads");
1802          Binder_Body_Src_File := new String'(Fnam & ".adb");
1803          Binder_Ali_File      := new String'(Fnam & ".ali");
1804
1805          Binder_Obj_File := new String'(Fnam & Get_Target_Object_Suffix.all);
1806       end;
1807
1808       if Fname_Len /= Fname'Length then
1809          Binder_Options.Increment_Last;
1810          Binder_Options.Table (Binder_Options.Last) := new String'("-o");
1811          Binder_Options.Increment_Last;
1812          Binder_Options.Table (Binder_Options.Last) := Binder_Obj_File;
1813       end if;
1814    end Make_Binder_File_Names;
1815
1816    Process_Binder_File (Binder_Body_Src_File.all & ASCII.NUL);
1817
1818    --  Compile the binder file. This is fast, so we always do it, unless
1819    --  specifically told not to by the -n switch
1820
1821    if Compile_Bind_File then
1822       Bind_Step : declare
1823          Success : Boolean;
1824          Args    : Argument_List
1825            (1 .. Binder_Options_From_ALI.Last + Binder_Options.Last + 1);
1826
1827       begin
1828          for J in 1 .. Binder_Options_From_ALI.Last loop
1829             Args (J) := Binder_Options_From_ALI.Table (J);
1830          end loop;
1831
1832          for J in 1 .. Binder_Options.Last loop
1833             Args (Binder_Options_From_ALI.Last + J) :=
1834               Binder_Options.Table (J);
1835          end loop;
1836
1837          --  Use the full path of the binder generated source, so that it is
1838          --  guaranteed that the debugger will find this source, even with
1839          --  STABS.
1840
1841          Args (Args'Last) :=
1842            new String'(Normalize_Pathname (Binder_Body_Src_File.all));
1843
1844          if Verbose_Mode then
1845             Write_Str (Base_Name (Gcc_Path.all));
1846
1847             for J in Args'Range loop
1848                Write_Str (" ");
1849                Write_Str (Args (J).all);
1850             end loop;
1851
1852             Write_Eol;
1853          end if;
1854
1855          System.OS_Lib.Spawn (Gcc_Path.all, Args, Success);
1856
1857          if not Success then
1858             Exit_Program (E_Fatal);
1859          end if;
1860       end Bind_Step;
1861    end if;
1862
1863    --  In CodePeer mode, there's nothing left to do after the binder file has
1864    --  been compiled.
1865
1866    if Opt.CodePeer_Mode then
1867       return;
1868    end if;
1869
1870    --  Now, actually link the program
1871
1872    --  Skip this step for now on JVM since the Java interpreter will do
1873    --  the actual link at run time. We might consider packing all class files
1874    --  in a .zip file during this step.
1875
1876    if VM_Target /= JVM_Target then
1877       Link_Step : declare
1878          Num_Args : Natural :=
1879                      (Linker_Options.Last - Linker_Options.First + 1) +
1880                      (Gcc_Linker_Options.Last - Gcc_Linker_Options.First + 1) +
1881                      (Linker_Objects.Last - Linker_Objects.First + 1);
1882          Stack_Op : Boolean := False;
1883          IDENT_Op : Boolean := False;
1884
1885       begin
1886          if AAMP_On_Target then
1887
1888             --  Remove extraneous flags not relevant for AAMP
1889
1890             for J in reverse Linker_Options.First .. Linker_Options.Last loop
1891                if Linker_Options.Table (J)'Length = 0
1892                  or else Linker_Options.Table (J) (1 .. 3) = "-Wl"
1893                  or else Linker_Options.Table (J) (1 .. 3) = "-sh"
1894                  or else Linker_Options.Table (J) (1 .. 2) = "-O"
1895                  or else Linker_Options.Table (J) (1 .. 2) = "-g"
1896                then
1897                   Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1898                     Linker_Options.Table (J + 1 .. Linker_Options.Last);
1899                   Linker_Options.Decrement_Last;
1900                   Num_Args := Num_Args - 1;
1901                end if;
1902             end loop;
1903
1904          elsif RTX_RTSS_Kernel_Module_On_Target then
1905
1906             --  Remove flags not relevant for Microsoft linker and adapt some
1907             --  others.
1908
1909             for J in reverse Linker_Options.First .. Linker_Options.Last loop
1910
1911                --  Remove flags that are not accepted
1912
1913                if Linker_Options.Table (J)'Length = 0
1914                  or else Linker_Options.Table (J) (1 .. 2) = "-l"
1915                  or else Linker_Options.Table (J) (1 .. 3) = "-Wl"
1916                  or else Linker_Options.Table (J) (1 .. 3) = "-sh"
1917                  or else Linker_Options.Table (J) (1 .. 2) = "-O"
1918                  or else Linker_Options.Table (J) (1 .. 8) = "-Xlinker"
1919                  or else Linker_Options.Table (J) (1 .. 9) = "-mthreads"
1920                then
1921                   Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1922                     Linker_Options.Table (J + 1 .. Linker_Options.Last);
1923                   Linker_Options.Decrement_Last;
1924                   Num_Args := Num_Args - 1;
1925
1926                --  Replace "-L" by its counterpart "/LIBPATH:" and UNIX "/" by
1927                --  Windows "\".
1928                elsif Linker_Options.Table (J) (1 .. 2) = "-L" then
1929                   declare
1930                      Libpath_Option : constant String_Access := new String'
1931                        ("/LIBPATH:" &
1932                         Linker_Options.Table (J)
1933                           (3 .. Linker_Options.Table (J).all'Last));
1934                   begin
1935                      for Index in 10 .. Libpath_Option'Last loop
1936                         if Libpath_Option (Index) = '/' then
1937                            Libpath_Option (Index) := '\';
1938                         end if;
1939                      end loop;
1940
1941                      Linker_Options.Table (J) := Libpath_Option;
1942                   end;
1943
1944                --  Replace "-g" by "/DEBUG"
1945                elsif Linker_Options.Table (J) (1 .. 2) = "-g" then
1946                   Linker_Options.Table (J) := new String'("/DEBUG");
1947
1948                --  Replace "-o" by "/OUT:"
1949                elsif Linker_Options.Table (J) (1 .. 2) = "-o" then
1950                   Linker_Options.Table (J + 1) := new String'
1951                     ("/OUT:" & Linker_Options.Table (J + 1).all);
1952
1953                   Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1954                     Linker_Options.Table (J + 1 .. Linker_Options.Last);
1955                   Linker_Options.Decrement_Last;
1956                   Num_Args := Num_Args - 1;
1957
1958                --  Replace "--stack=" by "/STACK:"
1959                elsif Linker_Options.Table (J) (1 .. 8) = "--stack=" then
1960                   Linker_Options.Table (J) := new String'
1961                     ("/STACK:" &
1962                      Linker_Options.Table (J)
1963                        (9 .. Linker_Options.Table (J).all'Last));
1964
1965                --  Replace "-v" by its counterpart "/VERBOSE"
1966                elsif Linker_Options.Table (J) (1 .. 2) = "-v" then
1967                   Linker_Options.Table (J) := new String'("/VERBOSE");
1968                end if;
1969             end loop;
1970
1971             --  Add some required flags to create RTSS modules
1972
1973             declare
1974                Flags_For_Linker : constant array (1 .. 17) of String_Access :=
1975                  (new String'("/NODEFAULTLIB"),
1976                   new String'("/INCREMENTAL:NO"),
1977                   new String'("/NOLOGO"),
1978                   new String'("/DRIVER"),
1979                   new String'("/ALIGN:0x20"),
1980                   new String'("/SUBSYSTEM:NATIVE"),
1981                   new String'("/ENTRY:_RtapiProcessEntryCRT@8"),
1982                   new String'("/RELEASE"),
1983                   new String'("startupCRT.obj"),
1984                   new String'("rtxlibcmt.lib"),
1985                   new String'("oldnames.lib"),
1986                   new String'("rtapi_rtss.lib"),
1987                   new String'("Rtx_Rtss.lib"),
1988                   new String'("libkernel32.a"),
1989                   new String'("libws2_32.a"),
1990                   new String'("libmswsock.a"),
1991                   new String'("libadvapi32.a"));
1992                --  These flags need to be passed to Microsoft linker. They
1993                --  come from the RTX documentation.
1994
1995                Gcc_Lib_Path : constant String_Access := new String'
1996                  ("/LIBPATH:" & Include_Dir_Default_Prefix & "\..\");
1997                --  Place to look for gcc related libraries, such as libgcc
1998
1999             begin
2000                --  Replace UNIX "/" by Windows "\" in the path
2001
2002                for Index in 10 .. Gcc_Lib_Path.all'Last loop
2003                   if Gcc_Lib_Path (Index) = '/' then
2004                      Gcc_Lib_Path (Index) := '\';
2005                   end if;
2006                end loop;
2007
2008                Linker_Options.Increment_Last;
2009                Linker_Options.Table (Linker_Options.Last) := Gcc_Lib_Path;
2010                Num_Args := Num_Args + 1;
2011
2012                for Index in Flags_For_Linker'Range loop
2013                   Linker_Options.Increment_Last;
2014                   Linker_Options.Table (Linker_Options.Last) :=
2015                     Flags_For_Linker (Index);
2016                   Num_Args := Num_Args + 1;
2017                end loop;
2018             end;
2019          end if;
2020
2021          --  Remove duplicate stack size setting from the Linker_Options
2022          --  table. The stack setting option "-Xlinker --stack=R,C" can be
2023          --  found in one line when set by a pragma Linker_Options or in two
2024          --  lines ("-Xlinker" then "--stack=R,C") when set on the command
2025          --  line. We also check for the "-Wl,--stack=R" style option.
2026
2027          --  We must remove the second stack setting option instance
2028          --  because the one on the command line will always be the first
2029          --  one. And any subsequent stack setting option will overwrite the
2030          --  previous one. This is done especially for GNAT/NT where we set
2031          --  the stack size for tasking programs by a pragma in the NT
2032          --  specific tasking package System.Task_Primitives.Operations.
2033
2034          --  Note: This is not a FOR loop that runs from Linker_Options.First
2035          --  to Linker_Options.Last, since operations within the loop can
2036          --  modify the length of the table.
2037
2038          Clean_Link_Option_Set : declare
2039             J : Natural := Linker_Options.First;
2040             Shared_Libgcc_Seen : Boolean := False;
2041
2042          begin
2043             while J <= Linker_Options.Last loop
2044
2045                if Linker_Options.Table (J).all = "-Xlinker"
2046                  and then J < Linker_Options.Last
2047                  and then Linker_Options.Table (J + 1)'Length > 8
2048                  and then Linker_Options.Table (J + 1) (1 .. 8) = "--stack="
2049                then
2050                   if Stack_Op then
2051                      Linker_Options.Table (J .. Linker_Options.Last - 2) :=
2052                        Linker_Options.Table (J + 2 .. Linker_Options.Last);
2053                      Linker_Options.Decrement_Last;
2054                      Linker_Options.Decrement_Last;
2055                      Num_Args := Num_Args - 2;
2056
2057                   else
2058                      Stack_Op := True;
2059                   end if;
2060                end if;
2061
2062                --  Remove duplicate -shared-libgcc switch
2063
2064                if Linker_Options.Table (J).all = Shared_Libgcc_String then
2065                   if Shared_Libgcc_Seen then
2066                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
2067                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
2068                      Linker_Options.Decrement_Last;
2069                      Num_Args := Num_Args - 1;
2070
2071                   else
2072                      Shared_Libgcc_Seen := True;
2073                   end if;
2074                end if;
2075
2076                --  Here we just check for a canonical form that matches the
2077                --  pragma Linker_Options set in the NT runtime.
2078
2079                if (Linker_Options.Table (J)'Length > 17
2080                    and then Linker_Options.Table (J) (1 .. 17)
2081                            = "-Xlinker --stack=")
2082                  or else
2083                   (Linker_Options.Table (J)'Length > 12
2084                    and then Linker_Options.Table (J) (1 .. 12)
2085                             = "-Wl,--stack=")
2086                then
2087                   if Stack_Op then
2088                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
2089                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
2090                      Linker_Options.Decrement_Last;
2091                      Num_Args := Num_Args - 1;
2092
2093                   else
2094                      Stack_Op := True;
2095                   end if;
2096                end if;
2097
2098                --  Remove duplicate IDENTIFICATION directives (VMS)
2099
2100                if Linker_Options.Table (J)'Length > 29
2101                  and then Linker_Options.Table (J) (1 .. 30) =
2102                             "--for-linker=--identification="
2103                then
2104                   if IDENT_Op then
2105                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
2106                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
2107                      Linker_Options.Decrement_Last;
2108                      Num_Args := Num_Args - 1;
2109
2110                   else
2111                      IDENT_Op := True;
2112                   end if;
2113                end if;
2114
2115                J := J + 1;
2116             end loop;
2117
2118             if Linker_Path = Gcc_Path and then VM_Target = No_VM then
2119
2120                --  For systems where the default is to link statically with
2121                --  libgcc, if gcc is not called with -shared-libgcc, call it
2122                --  with -static-libgcc, as there are some platforms where one
2123                --  of these two switches is compulsory to link.
2124
2125                if Shared_Libgcc_Default = 'T'
2126                  and then not Shared_Libgcc_Seen
2127                then
2128                   Linker_Options.Increment_Last;
2129                   Linker_Options.Table (Linker_Options.Last) := Static_Libgcc;
2130                   Num_Args := Num_Args + 1;
2131                end if;
2132
2133             elsif RTX_RTSS_Kernel_Module_On_Target then
2134
2135                --  Force the use of the static libgcc for RTSS modules
2136
2137                Linker_Options.Increment_Last;
2138                Linker_Options.Table (Linker_Options.Last) :=
2139                  new String'("libgcc.a");
2140                Num_Args := Num_Args + 1;
2141             end if;
2142
2143          end Clean_Link_Option_Set;
2144
2145          --  Prepare arguments for call to linker
2146
2147          Call_Linker : declare
2148             Success  : Boolean;
2149             Args     : Argument_List (1 .. Num_Args + 1);
2150             Index    : Integer := Args'First;
2151
2152          begin
2153             Args (Index) := Binder_Obj_File;
2154
2155             --  Add the object files and any -largs libraries
2156
2157             for J in Linker_Objects.First .. Linker_Objects.Last loop
2158                Index := Index + 1;
2159                Args (Index) := Linker_Objects.Table (J);
2160             end loop;
2161
2162             --  Add the linker options from the binder file
2163
2164             for J in Linker_Options.First .. Linker_Options.Last loop
2165                Index := Index + 1;
2166                Args (Index) := Linker_Options.Table (J);
2167             end loop;
2168
2169             --  Finally add the libraries from the --GCC= switch
2170
2171             for J in Gcc_Linker_Options.First .. Gcc_Linker_Options.Last loop
2172                Index := Index + 1;
2173                Args (Index) := Gcc_Linker_Options.Table (J);
2174             end loop;
2175
2176             if Verbose_Mode then
2177                Write_Str (Linker_Path.all);
2178
2179                for J in Args'Range loop
2180                   Write_Str (" ");
2181                   Write_Str (Args (J).all);
2182                end loop;
2183
2184                Write_Eol;
2185
2186                --  If we are on very verbose mode (-v -v) and a response file
2187                --  is used we display its content.
2188
2189                if Very_Verbose_Mode and then Tname_FD /= Invalid_FD then
2190                   Write_Eol;
2191                   Write_Str ("Response file (" &
2192                              Tname (Tname'First .. Tname'Last - 1) &
2193                              ") content : ");
2194                   Write_Eol;
2195
2196                   for J in
2197                     Response_File_Objects.First ..
2198                     Response_File_Objects.Last
2199                   loop
2200                      Write_Str (Response_File_Objects.Table (J).all);
2201                      Write_Eol;
2202                   end loop;
2203
2204                   Write_Eol;
2205                end if;
2206             end if;
2207
2208             System.OS_Lib.Spawn (Linker_Path.all, Args, Success);
2209
2210             if Success then
2211                --  Delete the temporary file used in conjunction with linking
2212                --  if one was created. See Process_Bind_File for details.
2213
2214                if Tname_FD /= Invalid_FD then
2215                   Delete (Tname);
2216                end if;
2217
2218             else
2219                Error_Msg ("error when calling " & Linker_Path.all);
2220                Exit_Program (E_Fatal);
2221             end if;
2222          end Call_Linker;
2223       end Link_Step;
2224    end if;
2225
2226    --  Only keep the binder output file and it's associated object
2227    --  file if compiling with the -g option.  These files are only
2228    --  useful if debugging.
2229
2230    if not Debug_Flag_Present then
2231       Delete (Binder_Ali_File.all & ASCII.NUL);
2232       Delete (Binder_Spec_Src_File.all & ASCII.NUL);
2233       Delete (Binder_Body_Src_File.all & ASCII.NUL);
2234
2235       if VM_Target = No_VM then
2236          Delete (Binder_Obj_File.all & ASCII.NUL);
2237       end if;
2238    end if;
2239
2240    Exit_Program (E_Success);
2241
2242 exception
2243    when X : others =>
2244       Write_Line (Exception_Information (X));
2245       Exit_With_Error ("INTERNAL ERROR. Please report");
2246 end Gnatlink;