gcc/ada/gnatlink.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             G N A T L I N K                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1996-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Gnatlink usage: please consult the gnat documentation
  27
  28 with ALI;      use ALI;
  29 with Csets;
  30 with Gnatvsn;  use Gnatvsn;
  31 with Hostparm;
  32 with Indepsw;  use Indepsw;
  33 with Namet;    use Namet;
  34 with Opt;
  35 with Osint;    use Osint;
  36 with Output;   use Output;
  37 with Snames;
  38 with Switch;   use Switch;
  39 with System;   use System;
  40 with Table;
  41 with Targparm; use Targparm;
  42 with Types;
  43
  44 with Ada.Command_Line;     use Ada.Command_Line;
  45 with Ada.Exceptions;       use Ada.Exceptions;
  46
  47 with System.OS_Lib;        use System.OS_Lib;
  48 with System.CRTL;
  49
  50 with Interfaces.C_Streams; use Interfaces.C_Streams;
  51 with Interfaces.C.Strings; use Interfaces.C.Strings;
  52
  53 procedure Gnatlink is
  54    pragma Ident (Gnatvsn.Gnat_Static_Version_String);
  55
  56    Shared_Libgcc_String : constant String := "-shared-libgcc";
  57    Shared_Libgcc        : constant String_Access :=
  58                             new String'(Shared_Libgcc_String);
  59    --  Used to invoke gcc when the binder is invoked with -shared
  60
  61    Static_Libgcc_String : constant String := "-static-libgcc";
  62    Static_Libgcc        : constant String_Access :=
  63                             new String'(Static_Libgcc_String);
  64    --  Used to invoke gcc when shared libs are not used
  65
  66    package Gcc_Linker_Options is new Table.Table (
  67      Table_Component_Type => String_Access,
  68      Table_Index_Type     => Integer,
  69      Table_Low_Bound      => 1,
  70      Table_Initial        => 20,
  71      Table_Increment      => 100,
  72      Table_Name           => "Gnatlink.Gcc_Linker_Options");
  73    --  Comments needed ???
  74
  75    package Libpath is new Table.Table (
  76      Table_Component_Type => Character,
  77      Table_Index_Type     => Integer,
  78      Table_Low_Bound      => 1,
  79      Table_Initial        => 4096,
  80      Table_Increment      => 100,
  81      Table_Name           => "Gnatlink.Libpath");
  82    --  Comments needed ???
  83
  84    package Linker_Options is new Table.Table (
  85      Table_Component_Type => String_Access,
  86      Table_Index_Type     => Integer,
  87      Table_Low_Bound      => 1,
  88      Table_Initial        => 20,
  89      Table_Increment      => 100,
  90      Table_Name           => "Gnatlink.Linker_Options");
  91    --  Comments needed ???
  92
  93    package Linker_Objects is new Table.Table (
  94      Table_Component_Type => String_Access,
  95      Table_Index_Type     => Integer,
  96      Table_Low_Bound      => 1,
  97      Table_Initial        => 20,
  98      Table_Increment      => 100,
  99      Table_Name           => "Gnatlink.Linker_Objects");
 100    --  This table collects the objects file to be passed to the linker. In the
 101    --  case where the linker command line is too long then programs objects
 102    --  are put on the Response_File_Objects table. Note that the binder object
 103    --  file and the user's objects remain in this table. This is very
 104    --  important because on the GNU linker command line the -L switch is not
 105    --  used to look for objects files but -L switch is used to look for
 106    --  objects listed in the response file. This is not a problem with the
 107    --  applications objects as they are specified with a fullname.
 108
 109    package Response_File_Objects is new Table.Table (
 110      Table_Component_Type => String_Access,
 111      Table_Index_Type     => Integer,
 112      Table_Low_Bound      => 1,
 113      Table_Initial        => 20,
 114      Table_Increment      => 100,
 115      Table_Name           => "Gnatlink.Response_File_Objects");
 116    --  This table collects the objects file that are to be put in the response
 117    --  file. Only application objects are collected there (see details in
 118    --  Linker_Objects table comments)
 119
 120    package Binder_Options_From_ALI is new Table.Table (
 121      Table_Component_Type => String_Access,
 122      Table_Index_Type     => Integer,
 123      Table_Low_Bound      => 1, -- equals low bound of Argument_List for Spawn
 124      Table_Initial        => 20,
 125      Table_Increment      => 100,
 126      Table_Name           => "Gnatlink.Binder_Options_From_ALI");
 127    --  This table collects the switches from the ALI file of the main
 128    --  subprogram.
 129
 130    package Binder_Options is new Table.Table (
 131      Table_Component_Type => String_Access,
 132      Table_Index_Type     => Integer,
 133      Table_Low_Bound      => 1, -- equals low bound of Argument_List for Spawn
 134      Table_Initial        => 20,
 135      Table_Increment      => 100,
 136      Table_Name           => "Gnatlink.Binder_Options");
 137    --  This table collects the arguments to be passed to compile the binder
 138    --  generated file.
 139
 140    Gcc : String_Access := Program_Name ("gcc");
 141
 142    Read_Mode  : constant String := "r" & ASCII.Nul;
 143
 144    Begin_Info : String := "--  BEGIN Object file/option list";
 145    End_Info   : String := "--  END Object file/option list   ";
 146    --  Note: above lines are modified in C mode, see option processing
 147
 148    Gcc_Path             : String_Access;
 149    Linker_Path          : String_Access;
 150
 151    Output_File_Name     : String_Access;
 152    Ali_File_Name        : String_Access;
 153    Binder_Spec_Src_File : String_Access;
 154    Binder_Body_Src_File : String_Access;
 155    Binder_Ali_File      : String_Access;
 156    Binder_Obj_File      : String_Access;
 157
 158    Tname    : Temp_File_Name;
 159    Tname_FD : File_Descriptor := Invalid_FD;
 160    --  Temporary file used by linker to pass list of object files on
 161    --  certain systems with limitations on size of arguments.
 162
 163    Debug_Flag_Present : Boolean := False;
 164    Verbose_Mode       : Boolean := False;
 165    Very_Verbose_Mode  : Boolean := False;
 166
 167    Ada_Bind_File : Boolean := True;
 168    --  Set to True if bind file is generated in Ada
 169
 170    Standard_Gcc  : Boolean := True;
 171
 172    Compile_Bind_File : Boolean := True;
 173    --  Set to False if bind file is not to be compiled
 174
 175    Create_Map_File : Boolean := False;
 176    --  Set to True by switch -M. The map file name is derived from
 177    --  the ALI file name (mainprog.ali => mainprog.map).
 178
 179    Object_List_File_Supported : Boolean;
 180    for Object_List_File_Supported'Size use Character'Size;
 181    pragma Import
 182      (C, Object_List_File_Supported, "__gnat_objlist_file_supported");
 183    --  Predicate indicating whether the linker has an option whereby the
 184    --  names of object files can be passed to the linker in a file.
 185
 186    Object_List_File_Required : Boolean := False;
 187    --  Set to True to force generation of a response file
 188
 189    function Base_Name (File_Name : String) return String;
 190    --  Return just the file name part without the extension (if present)
 191
 192    procedure Delete (Name : String);
 193    --  Wrapper to unlink as status is ignored by this application
 194
 195    procedure Error_Msg (Message : String);
 196    --  Output the error or warning Message
 197
 198    procedure Exit_With_Error (Error : String);
 199    --  Output Error and exit program with a fatal condition
 200
 201    procedure Process_Args;
 202    --  Go through all the arguments and build option tables
 203
 204    procedure Process_Binder_File (Name : String);
 205    --  Reads the binder file and extracts linker arguments
 206
 207    procedure Usage;
 208    --  Display usage
 209
 210    procedure Write_Header;
 211    --  Show user the program name, version and copyright
 212
 213    procedure Write_Usage;
 214    --  Show user the program options
 215
 216    ---------------
 217    -- Base_Name --
 218    ---------------
 219
 220    function Base_Name (File_Name : String) return String is
 221       Findex1 : Natural;
 222       Findex2 : Natural;
 223
 224    begin
 225       Findex1 := File_Name'First;
 226
 227       --  The file might be specified by a full path name. However,
 228       --  we want the path to be stripped away.
 229
 230       for J in reverse File_Name'Range loop
 231          if Is_Directory_Separator (File_Name (J)) then
 232             Findex1 := J + 1;
 233             exit;
 234          end if;
 235       end loop;
 236
 237       Findex2 := File_Name'Last;
 238       while Findex2 > Findex1
 239         and then File_Name (Findex2) /=  '.'
 240       loop
 241          Findex2 := Findex2 - 1;
 242       end loop;
 243
 244       if Findex2 = Findex1 then
 245          Findex2 := File_Name'Last + 1;
 246       end if;
 247
 248       return File_Name (Findex1 .. Findex2 - 1);
 249    end Base_Name;
 250
 251    ------------
 252    -- Delete --
 253    ------------
 254
 255    procedure Delete (Name : String) is
 256       Status : int;
 257       pragma Unreferenced (Status);
 258    begin
 259       Status := unlink (Name'Address);
 260       --  Is it really right to ignore an error here ???
 261    end Delete;
 262
 263    ---------------
 264    -- Error_Msg --
 265    ---------------
 266
 267    procedure Error_Msg (Message : String) is
 268    begin
 269       Write_Str (Base_Name (Command_Name));
 270       Write_Str (": ");
 271       Write_Str (Message);
 272       Write_Eol;
 273    end Error_Msg;
 274
 275    ---------------------
 276    -- Exit_With_Error --
 277    ---------------------
 278
 279    procedure Exit_With_Error (Error : String) is
 280    begin
 281       Error_Msg (Error);
 282       Exit_Program (E_Fatal);
 283    end Exit_With_Error;
 284
 285    ------------------
 286    -- Process_Args --
 287    ------------------
 288
 289    procedure Process_Args is
 290       Next_Arg  : Integer;
 291       Skip_Next : Boolean := False;
 292       --  Set to true if the next argument is to be added into the list of
 293       --  linker's argument without parsing it.
 294
 295    begin
 296       --  First, check for --version and --help
 297
 298       Check_Version_And_Help ("GNATLINK", "1995", Usage'Unrestricted_Access);
 299
 300       --  Loop through arguments of gnatlink command
 301
 302       Next_Arg := 1;
 303       loop
 304          exit when Next_Arg > Argument_Count;
 305
 306          Process_One_Arg : declare
 307             Arg : constant String := Argument (Next_Arg);
 308
 309          begin
 310             --  Case of argument which is a switch
 311
 312             --  We definitely need section by section comments here ???
 313
 314             if Skip_Next then
 315
 316                --  This argument must not be parsed, just add it to the
 317                --  list of linker's options.
 318
 319                Skip_Next := False;
 320
 321                Linker_Options.Increment_Last;
 322                Linker_Options.Table (Linker_Options.Last) :=
 323                  new String'(Arg);
 324
 325             elsif Arg'Length /= 0 and then Arg (1) = '-' then
 326                if Arg'Length > 4 and then Arg (2 .. 5) =  "gnat" then
 327                   Exit_With_Error
 328                     ("invalid switch: """ & Arg & """ (gnat not needed here)");
 329                end if;
 330
 331                if Arg = "-Xlinker" then
 332
 333                   --  Next argument should be sent directly to the linker.
 334                   --  We do not want to parse it here.
 335
 336                   Skip_Next := True;
 337
 338                   Linker_Options.Increment_Last;
 339                   Linker_Options.Table (Linker_Options.Last) :=
 340                     new String'(Arg);
 341
 342                elsif Arg (2) = 'g'
 343                  and then (Arg'Length < 5 or else Arg (2 .. 5) /= "gnat")
 344                then
 345                   Debug_Flag_Present := True;
 346
 347                   Linker_Options.Increment_Last;
 348                   Linker_Options.Table (Linker_Options.Last) :=
 349                    new String'(Arg);
 350
 351                   Binder_Options.Increment_Last;
 352                   Binder_Options.Table (Binder_Options.Last) :=
 353                     Linker_Options.Table (Linker_Options.Last);
 354
 355                elsif Arg'Length >= 3 and then Arg (2) = 'M' then
 356                   declare
 357                      Switches : String_List_Access;
 358
 359                   begin
 360                      Convert (Map_File, Arg (3 .. Arg'Last), Switches);
 361
 362                      if Switches /= null then
 363                         for J in Switches'Range loop
 364                            Linker_Options.Increment_Last;
 365                            Linker_Options.Table (Linker_Options.Last) :=
 366                              Switches (J);
 367                         end loop;
 368                      end if;
 369                   end;
 370
 371                elsif Arg'Length = 2 then
 372                   case Arg (2) is
 373                      when 'A' =>
 374                         Ada_Bind_File := True;
 375                         Begin_Info := "--  BEGIN Object file/option list";
 376                         End_Info   := "--  END Object file/option list   ";
 377
 378                      when 'b' =>
 379                         Linker_Options.Increment_Last;
 380                         Linker_Options.Table (Linker_Options.Last) :=
 381                           new String'(Arg);
 382
 383                         Binder_Options.Increment_Last;
 384                         Binder_Options.Table (Binder_Options.Last) :=
 385                           Linker_Options.Table (Linker_Options.Last);
 386
 387                         Next_Arg := Next_Arg + 1;
 388
 389                         if Next_Arg > Argument_Count then
 390                            Exit_With_Error ("Missing argument for -b");
 391                         end if;
 392
 393                         Get_Machine_Name : declare
 394                            Name_Arg : constant String_Access :=
 395                                         new String'(Argument (Next_Arg));
 396
 397                         begin
 398                            Linker_Options.Increment_Last;
 399                            Linker_Options.Table (Linker_Options.Last) :=
 400                              Name_Arg;
 401
 402                            Binder_Options.Increment_Last;
 403                            Binder_Options.Table (Binder_Options.Last) :=
 404                              Name_Arg;
 405
 406                         end Get_Machine_Name;
 407
 408                      when 'C' =>
 409                         Ada_Bind_File := False;
 410                         Begin_Info := "/*  BEGIN Object file/option list";
 411                         End_Info   := "    END Object file/option list */";
 412
 413                      when 'f' =>
 414                         if Object_List_File_Supported then
 415                            Object_List_File_Required := True;
 416                         else
 417                            Exit_With_Error
 418                              ("Object list file not supported on this target");
 419                         end if;
 420
 421                      when 'M' =>
 422                         Create_Map_File := True;
 423
 424                      when 'n' =>
 425                         Compile_Bind_File := False;
 426
 427                      when 'o' =>
 428                         if VM_Target = CLI_Target then
 429                            Linker_Options.Increment_Last;
 430                            Linker_Options.Table (Linker_Options.Last) :=
 431                               new String'("/QUIET");
 432
 433                         else
 434                            Linker_Options.Increment_Last;
 435                            Linker_Options.Table (Linker_Options.Last) :=
 436                              new String'(Arg);
 437                         end if;
 438
 439                         Next_Arg := Next_Arg + 1;
 440
 441                         if Next_Arg > Argument_Count then
 442                            Exit_With_Error ("Missing argument for -o");
 443                         end if;
 444
 445                         if VM_Target = CLI_Target then
 446                            Output_File_Name :=
 447                              new String'("/OUTPUT=" & Argument (Next_Arg));
 448                         else
 449                            Output_File_Name :=
 450                              new String'(Argument (Next_Arg));
 451                         end if;
 452
 453                         Linker_Options.Increment_Last;
 454                         Linker_Options.Table (Linker_Options.Last) :=
 455                           Output_File_Name;
 456
 457                      when 'R' =>
 458                         Opt.Run_Path_Option := False;
 459
 460                      when 'v' =>
 461
 462                         --  Support "double" verbose mode.  Second -v
 463                         --  gets sent to the linker and binder phases.
 464
 465                         if Verbose_Mode then
 466                            Very_Verbose_Mode := True;
 467
 468                            Linker_Options.Increment_Last;
 469                            Linker_Options.Table (Linker_Options.Last) :=
 470                             new String'(Arg);
 471
 472                            Binder_Options.Increment_Last;
 473                            Binder_Options.Table (Binder_Options.Last) :=
 474                              Linker_Options.Table (Linker_Options.Last);
 475
 476                         else
 477                            Verbose_Mode := True;
 478
 479                         end if;
 480
 481                      when others =>
 482                         Linker_Options.Increment_Last;
 483                         Linker_Options.Table (Linker_Options.Last) :=
 484                          new String'(Arg);
 485
 486                   end case;
 487
 488                elsif Arg (2) = 'B' then
 489                   Linker_Options.Increment_Last;
 490                   Linker_Options.Table (Linker_Options.Last) :=
 491                     new String'(Arg);
 492
 493                   Binder_Options.Increment_Last;
 494                   Binder_Options.Table (Binder_Options.Last) :=
 495                     Linker_Options.Table (Linker_Options.Last);
 496
 497                elsif Arg'Length >= 7 and then Arg (1 .. 7) = "--LINK=" then
 498                   if Arg'Length = 7 then
 499                      Exit_With_Error ("Missing argument for --LINK=");
 500                   end if;
 501
 502                   Linker_Path :=
 503                     System.OS_Lib.Locate_Exec_On_Path (Arg (8 .. Arg'Last));
 504
 505                   if Linker_Path = null then
 506                      Exit_With_Error
 507                        ("Could not locate linker: " & Arg (8 .. Arg'Last));
 508                   end if;
 509
 510                elsif Arg'Length > 6 and then Arg (1 .. 6) = "--GCC=" then
 511                   declare
 512                      Program_Args : constant Argument_List_Access :=
 513                                       Argument_String_To_List
 514                                                  (Arg (7 .. Arg'Last));
 515
 516                   begin
 517                      Gcc := new String'(Program_Args.all (1).all);
 518                      Standard_Gcc := False;
 519
 520                      --  Set appropriate flags for switches passed
 521
 522                      for J in 2 .. Program_Args.all'Last loop
 523                         declare
 524                            Arg : constant String := Program_Args.all (J).all;
 525                            AF  : constant Integer := Arg'First;
 526
 527                         begin
 528                            if Arg'Length /= 0 and then Arg (AF) = '-' then
 529                               if Arg (AF + 1) = 'g'
 530                                 and then (Arg'Length = 2
 531                                   or else Arg (AF + 2) in '0' .. '3'
 532                                   or else Arg (AF + 2 .. Arg'Last) = "coff")
 533                               then
 534                                  Debug_Flag_Present := True;
 535                               end if;
 536                            end if;
 537
 538                            --  Add directory to source search dirs so that
 539                            --  Get_Target_Parameters can find system.ads
 540
 541                            if Arg (AF .. AF + 1) = "-I"
 542                              and then Arg'Length > 2
 543                            then
 544                               Add_Src_Search_Dir (Arg (AF + 2 .. Arg'Last));
 545                            end if;
 546
 547                            --  Pass to gcc for compiling binder generated file
 548                            --  No use passing libraries, it will just generate
 549                            --  a warning
 550
 551                            if not (Arg (AF .. AF + 1) = "-l"
 552                              or else Arg (AF .. AF + 1) = "-L")
 553                            then
 554                               Binder_Options.Increment_Last;
 555                               Binder_Options.Table (Binder_Options.Last) :=
 556                                 new String'(Arg);
 557                            end if;
 558
 559                            --  Pass to gcc for linking program
 560
 561                            Gcc_Linker_Options.Increment_Last;
 562                            Gcc_Linker_Options.Table
 563                              (Gcc_Linker_Options.Last) := new String'(Arg);
 564                         end;
 565                      end loop;
 566                   end;
 567
 568                --  Send all multi-character switches not recognized as
 569                --  a special case by gnatlink to the linker/loader stage.
 570
 571                else
 572                   Linker_Options.Increment_Last;
 573                   Linker_Options.Table (Linker_Options.Last) :=
 574                     new String'(Arg);
 575                end if;
 576
 577             --  Here if argument is a file name rather than a switch
 578
 579             else
 580                --  If explicit ali file, capture it
 581
 582                if Arg'Length > 4
 583                  and then Arg (Arg'Last - 3 .. Arg'Last) = ".ali"
 584                then
 585                   if Ali_File_Name = null then
 586                      Ali_File_Name := new String'(Arg);
 587                   else
 588                      Exit_With_Error ("cannot handle more than one ALI file");
 589                   end if;
 590
 591                --  If target object file, record object file
 592
 593                elsif Arg'Length > Get_Target_Object_Suffix.all'Length
 594                  and then Arg
 595                    (Arg'Last -
 596                     Get_Target_Object_Suffix.all'Length + 1 .. Arg'Last)
 597                    = Get_Target_Object_Suffix.all
 598                then
 599                   Linker_Objects.Increment_Last;
 600                   Linker_Objects.Table (Linker_Objects.Last) :=
 601                     new String'(Arg);
 602
 603                --  If host object file, record object file
 604                --  e.g. accept foo.o as well as foo.obj on VMS target
 605
 606                elsif Arg'Length > Get_Object_Suffix.all'Length
 607                  and then Arg
 608                    (Arg'Last - Get_Object_Suffix.all'Length + 1 .. Arg'Last)
 609                                                 = Get_Object_Suffix.all
 610                then
 611                   Linker_Objects.Increment_Last;
 612                   Linker_Objects.Table (Linker_Objects.Last) :=
 613                     new String'(Arg);
 614
 615                --  If corresponding ali file exists, capture it
 616
 617                elsif Ali_File_Name = null
 618                  and then Is_Regular_File (Arg & ".ali")
 619                then
 620                   Ali_File_Name := new String'(Arg & ".ali");
 621
 622                --  Otherwise assume this is a linker options entry, but
 623                --  see below for interesting adjustment to this assumption.
 624
 625                else
 626                   Linker_Options.Increment_Last;
 627                   Linker_Options.Table (Linker_Options.Last) :=
 628                     new String'(Arg);
 629                end if;
 630             end if;
 631          end Process_One_Arg;
 632
 633          Next_Arg := Next_Arg + 1;
 634       end loop;
 635
 636       --  If Ada bind file, then compile it with warnings suppressed, because
 637       --  otherwise the with of the main program may cause junk warnings.
 638
 639       if Ada_Bind_File then
 640          Binder_Options.Increment_Last;
 641          Binder_Options.Table (Binder_Options.Last) := new String'("-gnatws");
 642       end if;
 643
 644       --  If we did not get an ali file at all, and we had at least one
 645       --  linker option, then assume that was the intended ali file after
 646       --  all, so that we get a nicer message later on.
 647
 648       if Ali_File_Name = null
 649         and then Linker_Options.Last >= Linker_Options.First
 650       then
 651          Ali_File_Name :=
 652            new String'(Linker_Options.Table (Linker_Options.First).all &
 653                                                                    ".ali");
 654       end if;
 655    end Process_Args;
 656
 657    -------------------------
 658    -- Process_Binder_File --
 659    -------------------------
 660
 661    procedure Process_Binder_File (Name : String) is
 662       Fd : FILEs;
 663       --  Binder file's descriptor
 664
 665       Link_Bytes : Integer := 0;
 666       --  Projected number of bytes for the linker command line
 667
 668       Link_Max : Integer;
 669       pragma Import (C, Link_Max, "__gnat_link_max");
 670       --  Maximum number of bytes on the command line supported by the OS
 671       --  linker. Passed this limit the response file mechanism must be used
 672       --  if supported.
 673
 674       Next_Line : String (1 .. 1000);
 675       --  Current line value
 676
 677       Nlast  : Integer;
 678       Nfirst : Integer;
 679       --  Current line slice (the slice does not contain line terminator)
 680
 681       Last : Integer;
 682       --  Current line last character for shared libraries (without version)
 683
 684       Objs_Begin : Integer := 0;
 685       --  First object file index in Linker_Objects table
 686
 687       Objs_End : Integer := 0;
 688       --  Last object file index in Linker_Objects table
 689
 690       Status : int;
 691       pragma Warnings (Off, Status);
 692       --  Used for various Interfaces.C_Streams calls
 693
 694       Closing_Status : Boolean;
 695       --  For call to Close
 696
 697       GNAT_Static : Boolean := False;
 698       --  Save state of -static option
 699
 700       GNAT_Shared : Boolean := False;
 701       --  Save state of -shared option
 702
 703       Xlinker_Was_Previous : Boolean := False;
 704       --  Indicate that "-Xlinker" was the option preceding the current
 705       --  option. If True, then the current option is never suppressed.
 706
 707       --  Rollback data
 708
 709       --  These data items are used to store current binder file context.
 710       --  The context is composed of the file descriptor position and the
 711       --  current line together with the slice indexes (first and last
 712       --  position) for this line. The rollback data are used by the
 713       --  Store_File_Context and Rollback_File_Context routines below.
 714       --  The file context mechanism interact only with the Get_Next_Line
 715       --  call. For example:
 716
 717       --     Store_File_Context;
 718       --     Get_Next_Line;
 719       --     Rollback_File_Context;
 720       --     Get_Next_Line;
 721
 722       --  Both Get_Next_Line calls above will read the exact same data from
 723       --  the file. In other words, Next_Line, Nfirst and Nlast variables
 724       --  will be set with the exact same values.
 725
 726       RB_File_Pos  : long;                -- File position
 727       RB_Next_Line : String (1 .. 1000);  -- Current line content
 728       RB_Nlast     : Integer;             -- Slice last index
 729       RB_Nfirst    : Integer;             -- Slice first index
 730
 731       Run_Path_Option_Ptr : Interfaces.C.Strings.chars_ptr;
 732       pragma Import (C, Run_Path_Option_Ptr, "__gnat_run_path_option");
 733       --  Pointer to string representing the native linker option which
 734       --  specifies the path where the dynamic loader should find shared
 735       --  libraries. Equal to null string if this system doesn't support it.
 736
 737       Object_Library_Ext_Ptr : Interfaces.C.Strings.chars_ptr;
 738       pragma Import
 739         (C, Object_Library_Ext_Ptr, "__gnat_object_library_extension");
 740       --  Pointer to string specifying the default extension for
 741       --  object libraries, e.g. Unix uses ".a", VMS uses ".olb".
 742
 743       Object_File_Option_Ptr : Interfaces.C.Strings.chars_ptr;
 744       pragma Import (C, Object_File_Option_Ptr, "__gnat_object_file_option");
 745       --  Pointer to a string representing the linker option which specifies
 746       --  the response file.
 747
 748       Using_GNU_Linker : Boolean;
 749       for Using_GNU_Linker'Size use Character'Size;
 750       pragma Import (C, Using_GNU_Linker, "__gnat_using_gnu_linker");
 751       --  Predicate indicating whether this target uses the GNU linker. In
 752       --  this case we must output a GNU linker compatible response file.
 753
 754       Opening : aliased constant String := """";
 755       Closing : aliased constant String := '"' & ASCII.LF;
 756       --  Needed to quote object paths in object list files when GNU linker
 757       --  is used.
 758
 759       procedure Get_Next_Line;
 760       --  Read the next line from the binder file without the line
 761       --  terminator.
 762
 763       function Index (S, Pattern : String) return Natural;
 764       --  Return the last occurrence of Pattern in S, or 0 if none
 765
 766       function Is_Option_Present (Opt : String) return Boolean;
 767       --  Return true if the option Opt is already present in
 768       --  Linker_Options table.
 769
 770       procedure Store_File_Context;
 771       --  Store current file context, Fd position and current line data.
 772       --  The file context is stored into the rollback data above (RB_*).
 773       --  Store_File_Context can be called at any time, only the last call
 774       --  will be used (i.e. this routine overwrites the file context).
 775
 776       procedure Rollback_File_Context;
 777       --  Restore file context from rollback data. This routine must be called
 778       --  after Store_File_Context. The binder file context will be restored
 779       --  with the data stored by the last Store_File_Context call.
 780
 781       -------------------
 782       -- Get_Next_Line --
 783       -------------------
 784
 785       procedure Get_Next_Line is
 786          Fchars : chars;
 787
 788       begin
 789          Fchars := fgets (Next_Line'Address, Next_Line'Length, Fd);
 790
 791          if Fchars = System.Null_Address then
 792             Exit_With_Error ("Error reading binder output");
 793          end if;
 794
 795          Nfirst := Next_Line'First;
 796          Nlast := Nfirst;
 797          while Nlast <= Next_Line'Last
 798            and then Next_Line (Nlast) /= ASCII.LF
 799            and then Next_Line (Nlast) /= ASCII.CR
 800          loop
 801             Nlast := Nlast + 1;
 802          end loop;
 803
 804          Nlast := Nlast - 1;
 805       end Get_Next_Line;
 806
 807       -----------
 808       -- Index --
 809       -----------
 810
 811       function Index (S, Pattern : String) return Natural is
 812          Len : constant Natural := Pattern'Length;
 813
 814       begin
 815          for J in reverse S'First .. S'Last - Len + 1 loop
 816             if Pattern = S (J .. J + Len - 1) then
 817                return J;
 818             end if;
 819          end loop;
 820
 821          return 0;
 822       end Index;
 823
 824       -----------------------
 825       -- Is_Option_Present --
 826       -----------------------
 827
 828       function Is_Option_Present (Opt : String) return Boolean is
 829       begin
 830          for I in 1 .. Linker_Options.Last loop
 831
 832             if Linker_Options.Table (I).all = Opt then
 833                return True;
 834             end if;
 835
 836          end loop;
 837
 838          return False;
 839       end Is_Option_Present;
 840
 841       ---------------------------
 842       -- Rollback_File_Context --
 843       ---------------------------
 844
 845       procedure Rollback_File_Context is
 846       begin
 847          Next_Line := RB_Next_Line;
 848          Nfirst    := RB_Nfirst;
 849          Nlast     := RB_Nlast;
 850          Status    := fseek (Fd, RB_File_Pos, Interfaces.C_Streams.SEEK_SET);
 851
 852          if Status = -1 then
 853             Exit_With_Error ("Error setting file position");
 854          end if;
 855       end Rollback_File_Context;
 856
 857       ------------------------
 858       -- Store_File_Context --
 859       ------------------------
 860
 861       procedure Store_File_Context is
 862          use type System.CRTL.long;
 863       begin
 864          RB_Next_Line := Next_Line;
 865          RB_Nfirst    := Nfirst;
 866          RB_Nlast     := Nlast;
 867          RB_File_Pos  := ftell (Fd);
 868
 869          if RB_File_Pos = -1 then
 870             Exit_With_Error ("Error getting file position");
 871          end if;
 872       end Store_File_Context;
 873
 874    --  Start of processing for Process_Binder_File
 875
 876    begin
 877       Fd := fopen (Name'Address, Read_Mode'Address);
 878
 879       if Fd = NULL_Stream then
 880          Exit_With_Error ("Failed to open binder output");
 881       end if;
 882
 883       --  Skip up to the Begin Info line
 884
 885       loop
 886          Get_Next_Line;
 887          exit when Next_Line (Nfirst .. Nlast) = Begin_Info;
 888       end loop;
 889
 890       loop
 891          Get_Next_Line;
 892
 893          --  Go to end when end line is reached (this will happen in
 894          --  High_Integrity_Mode where no -L switches are generated)
 895
 896          exit when Next_Line (Nfirst .. Nlast) = End_Info;
 897
 898          if Ada_Bind_File then
 899             Next_Line (Nfirst .. Nlast - 8) :=
 900               Next_Line (Nfirst + 8 .. Nlast);
 901             Nlast := Nlast - 8;
 902          end if;
 903
 904          --  Go to next section when switches are reached
 905
 906          exit when Next_Line (1) = '-';
 907
 908          --  Otherwise we have another object file to collect
 909
 910          Linker_Objects.Increment_Last;
 911
 912          --  Mark the positions of first and last object files in case
 913          --  they need to be placed with a named file on systems having
 914          --  linker line limitations.
 915
 916          if Objs_Begin = 0 then
 917             Objs_Begin := Linker_Objects.Last;
 918          end if;
 919
 920          Linker_Objects.Table (Linker_Objects.Last) :=
 921            new String'(Next_Line (Nfirst .. Nlast));
 922
 923          Link_Bytes := Link_Bytes + Nlast - Nfirst + 2;
 924          --  Nlast - Nfirst + 1, for the size, plus one for the space between
 925          --  each arguments.
 926       end loop;
 927
 928       Objs_End := Linker_Objects.Last;
 929
 930       --  Let's continue to compute the Link_Bytes, the linker options are
 931       --  part of command line length.
 932
 933       Store_File_Context;
 934
 935       while Next_Line (Nfirst .. Nlast) /= End_Info loop
 936          Link_Bytes := Link_Bytes + Nlast - Nfirst + 2;
 937          --  See comment above
 938          Get_Next_Line;
 939       end loop;
 940
 941       Rollback_File_Context;
 942
 943       --  On systems that have limitations on handling very long linker lines
 944       --  we make use of the system linker option which takes a list of object
 945       --  file names from a file instead of the command line itself. What we do
 946       --  is to replace the list of object files by the special linker option
 947       --  which then reads the object file list from a file instead. The option
 948       --  to read from a file instead of the command line is only triggered if
 949       --  a conservative threshold is passed.
 950
 951       if Object_List_File_Required
 952         or else (Object_List_File_Supported
 953                    and then Link_Bytes > Link_Max)
 954       then
 955          --  Create a temporary file containing the Ada user object files
 956          --  needed by the link. This list is taken from the bind file
 957          --  and is output one object per line for maximal compatibility with
 958          --  linkers supporting this option.
 959
 960          Create_Temp_File (Tname_FD, Tname);
 961
 962          --  ??? File descriptor should be checked to not be Invalid_FD.
 963          --  ??? Status of Write and Close operations should be checked, and
 964          --  failure should occur if a status is wrong.
 965
 966          --  If target is using the GNU linker we must add a special header
 967          --  and footer in the response file.
 968
 969          --  The syntax is : INPUT (object1.o object2.o ... )
 970
 971          --  Because the GNU linker does not like name with characters such
 972          --  as '!', we must put the object paths between double quotes.
 973
 974          if Using_GNU_Linker then
 975             declare
 976                GNU_Header : aliased constant String := "INPUT (";
 977
 978             begin
 979                Status := Write (Tname_FD, GNU_Header'Address,
 980                  GNU_Header'Length);
 981             end;
 982          end if;
 983
 984          for J in Objs_Begin .. Objs_End loop
 985
 986             --  Opening quote for GNU linker
 987
 988             if Using_GNU_Linker then
 989                Status := Write (Tname_FD, Opening'Address, 1);
 990             end if;
 991
 992             Status := Write (Tname_FD, Linker_Objects.Table (J).all'Address,
 993                              Linker_Objects.Table (J).all'Length);
 994
 995             --  Closing quote for GNU linker
 996
 997             if Using_GNU_Linker then
 998                Status := Write (Tname_FD, Closing'Address, 2);
 999
1000             else
1001                Status := Write (Tname_FD, ASCII.LF'Address, 1);
1002             end if;
1003
1004             Response_File_Objects.Increment_Last;
1005             Response_File_Objects.Table (Response_File_Objects.Last) :=
1006               Linker_Objects.Table (J);
1007          end loop;
1008
1009          --  Handle GNU linker response file footer
1010
1011          if Using_GNU_Linker then
1012             declare
1013                GNU_Footer : aliased constant String := ")";
1014
1015             begin
1016                Status := Write (Tname_FD, GNU_Footer'Address,
1017                  GNU_Footer'Length);
1018             end;
1019          end if;
1020
1021          Close (Tname_FD, Closing_Status);
1022
1023          --  Add the special objects list file option together with the name
1024          --  of the temporary file (removing the null character) to the objects
1025          --  file table.
1026
1027          Linker_Objects.Table (Objs_Begin) :=
1028            new String'(Value (Object_File_Option_Ptr) &
1029                        Tname (Tname'First .. Tname'Last - 1));
1030
1031          --  The slots containing these object file names are then removed
1032          --  from the objects table so they do not appear in the link. They
1033          --  are removed by moving up the linker options and non-Ada object
1034          --  files appearing after the Ada object list in the table.
1035
1036          declare
1037             N : Integer;
1038
1039          begin
1040             N := Objs_End - Objs_Begin + 1;
1041
1042             for J in Objs_End + 1 .. Linker_Objects.Last loop
1043                Linker_Objects.Table (J - N + 1) := Linker_Objects.Table (J);
1044             end loop;
1045
1046             Linker_Objects.Set_Last (Linker_Objects.Last - N + 1);
1047          end;
1048       end if;
1049
1050       --  Process switches and options
1051
1052       if Next_Line (Nfirst .. Nlast) /= End_Info then
1053          Xlinker_Was_Previous := False;
1054
1055          loop
1056             if Xlinker_Was_Previous
1057               or else Next_Line (Nfirst .. Nlast) = "-Xlinker"
1058             then
1059                Linker_Options.Increment_Last;
1060                Linker_Options.Table (Linker_Options.Last) :=
1061                  new String'(Next_Line (Nfirst .. Nlast));
1062
1063             elsif Next_Line (Nfirst .. Nlast) = "-static" then
1064                GNAT_Static := True;
1065
1066             elsif Next_Line (Nfirst .. Nlast) = "-shared" then
1067                GNAT_Shared := True;
1068
1069             --  Add binder options only if not already set on the command
1070             --  line. This rule is a way to control the linker options order.
1071
1072             --  The following test needs comments, why is it VMS specific.
1073             --  The above comment looks out of date ???
1074
1075             elsif not (OpenVMS_On_Target
1076                          and then
1077                        Is_Option_Present (Next_Line (Nfirst .. Nlast)))
1078             then
1079                if Nlast > Nfirst + 2 and then
1080                  Next_Line (Nfirst .. Nfirst + 1) = "-L"
1081                then
1082                   --  Construct a library search path for use later
1083                   --  to locate static gnatlib libraries.
1084
1085                   if Libpath.Last > 1 then
1086                      Libpath.Increment_Last;
1087                      Libpath.Table (Libpath.Last) := Path_Separator;
1088                   end if;
1089
1090                   for I in Nfirst + 2 .. Nlast loop
1091                      Libpath.Increment_Last;
1092                      Libpath.Table (Libpath.Last) := Next_Line (I);
1093                   end loop;
1094
1095                   Linker_Options.Increment_Last;
1096
1097                   Linker_Options.Table (Linker_Options.Last) :=
1098                     new String'(Next_Line (Nfirst .. Nlast));
1099
1100                elsif Next_Line (Nfirst .. Nlast) = "-ldecgnat"
1101                  or else Next_Line (Nfirst .. Nlast) = "-lgnarl"
1102                  or else Next_Line (Nfirst .. Nlast) = "-lgnat"
1103                  or else Next_Line
1104                      (1 .. Natural'Min (Nlast, 8 + Library_Version'Length)) =
1105                        Shared_Lib ("gnarl")
1106                  or else Next_Line
1107                      (1 .. Natural'Min (Nlast, 7 + Library_Version'Length)) =
1108                        Shared_Lib ("gnat")
1109                then
1110                   --  If it is a shared library, remove the library version.
1111                   --  We will be looking for the static version of the library
1112                   --  as it is in the same directory as the shared version.
1113
1114                   if Next_Line (Nlast - Library_Version'Length + 1 .. Nlast)
1115                        = Library_Version
1116                   then
1117                      --  Set Last to point to last character before the
1118                      --  library version.
1119
1120                      Last := Nlast - Library_Version'Length - 1;
1121                   else
1122                      Last := Nlast;
1123                   end if;
1124
1125                   --  Given a Gnat standard library, search the
1126                   --  library path to find the library location
1127
1128                   declare
1129                      File_Path : String_Access;
1130
1131                      Object_Lib_Extension : constant String :=
1132                                               Value (Object_Library_Ext_Ptr);
1133
1134                      File_Name : constant String := "lib" &
1135                                    Next_Line (Nfirst + 2 .. Last) &
1136                                    Object_Lib_Extension;
1137
1138                      Run_Path_Opt : constant String :=
1139                        Value (Run_Path_Option_Ptr);
1140
1141                      GCC_Index          : Natural;
1142                      Run_Path_Opt_Index : Natural := 0;
1143
1144                   begin
1145                      File_Path :=
1146                        Locate_Regular_File (File_Name,
1147                          String (Libpath.Table (1 .. Libpath.Last)));
1148
1149                      if File_Path /= null then
1150                         if GNAT_Static then
1151
1152                            --  If static gnatlib found, explicitly
1153                            --  specify to overcome possible linker
1154                            --  default usage of shared version.
1155
1156                            Linker_Options.Increment_Last;
1157
1158                            Linker_Options.Table (Linker_Options.Last) :=
1159                              new String'(File_Path.all);
1160
1161                         elsif GNAT_Shared then
1162                            if Opt.Run_Path_Option then
1163                               --  If shared gnatlib desired, add the
1164                               --  appropriate system specific switch
1165                               --  so that it can be located at runtime.
1166
1167                               if Run_Path_Opt'Length /= 0 then
1168                                  --  Output the system specific linker command
1169                                  --  that allows the image activator to find
1170                                  --  the shared library at runtime.
1171                                  --  Also add path to find libgcc_s.so, if
1172                                  --  relevant.
1173
1174                                  --  To find the location of the shared version
1175                                  --  of libgcc, we look for "gcc-lib" in the
1176                                  --  path of the library. However, this
1177                                  --  subdirectory is no longer present in
1178                                  --  in recent version of GCC. So, we look for
1179                                  --  the last subdirectory "lib" in the path.
1180
1181                                  GCC_Index :=
1182                                    Index (File_Path.all, "gcc-lib");
1183
1184                                  if GCC_Index /= 0 then
1185                                     --  The shared version of libgcc is
1186                                     --  located in the parent directory.
1187
1188                                     GCC_Index := GCC_Index - 1;
1189
1190                                  else
1191                                     GCC_Index :=
1192                                       Index (File_Path.all, "/lib/");
1193
1194                                     if GCC_Index = 0 then
1195                                        GCC_Index :=
1196                                          Index (File_Path.all,
1197                                                 Directory_Separator &
1198                                                 "lib" &
1199                                                 Directory_Separator);
1200                                     end if;
1201
1202                                     --  We have found a subdirectory "lib",
1203                                     --  this is where the shared version of
1204                                     --  libgcc should be located.
1205
1206                                     if GCC_Index /= 0 then
1207                                        GCC_Index := GCC_Index + 3;
1208                                     end if;
1209                                  end if;
1210
1211                                  --  Look for an eventual run_path_option in
1212                                  --  the linker switches.
1213
1214                                  for J in reverse 1 .. Linker_Options.Last loop
1215                                     if Linker_Options.Table (J) /= null
1216                                       and then
1217                                         Linker_Options.Table (J)'Length
1218                                                   > Run_Path_Opt'Length
1219                                       and then
1220                                         Linker_Options.Table (J)
1221                                           (1 .. Run_Path_Opt'Length) =
1222                                                                 Run_Path_Opt
1223                                     then
1224                                        --  We have found a already specified
1225                                        --  run_path_option: we will add to this
1226                                        --  switch, because only one
1227                                        --  run_path_option should be specified.
1228
1229                                        Run_Path_Opt_Index := J;
1230                                        exit;
1231                                     end if;
1232                                  end loop;
1233
1234                                  --  If there is no run_path_option, we need
1235                                  --  to add one.
1236
1237                                  if Run_Path_Opt_Index = 0 then
1238                                     Linker_Options.Increment_Last;
1239                                  end if;
1240
1241                                  if GCC_Index = 0 then
1242                                     if Run_Path_Opt_Index = 0 then
1243                                        Linker_Options.Table
1244                                          (Linker_Options.Last) :=
1245                                            new String'
1246                                               (Run_Path_Opt
1247                                                 & File_Path
1248                                                   (1 .. File_Path'Length
1249                                                          - File_Name'Length));
1250
1251                                     else
1252                                        Linker_Options.Table
1253                                          (Run_Path_Opt_Index) :=
1254                                            new String'
1255                                              (Linker_Options.Table
1256                                                  (Run_Path_Opt_Index).all
1257                                               & Path_Separator
1258                                               & File_Path
1259                                                  (1 .. File_Path'Length
1260                                                        - File_Name'Length));
1261                                     end if;
1262
1263                                  else
1264                                     if Run_Path_Opt_Index = 0 then
1265                                        Linker_Options.Table
1266                                          (Linker_Options.Last) :=
1267                                            new String'(Run_Path_Opt
1268                                              & File_Path
1269                                                  (1 .. File_Path'Length
1270                                                        - File_Name'Length)
1271                                              & Path_Separator
1272                                              & File_Path (1 .. GCC_Index));
1273
1274                                     else
1275                                        Linker_Options.Table
1276                                          (Run_Path_Opt_Index) :=
1277                                            new String'
1278                                             (Linker_Options.Table
1279                                                 (Run_Path_Opt_Index).all
1280                                              & Path_Separator
1281                                              & File_Path
1282                                                  (1 .. File_Path'Length
1283                                                        - File_Name'Length)
1284                                              & Path_Separator
1285                                              & File_Path (1 .. GCC_Index));
1286                                     end if;
1287                                  end if;
1288                               end if;
1289                            end if;
1290
1291                            --  Then we add the appropriate -l switch
1292
1293                            Linker_Options.Increment_Last;
1294                            Linker_Options.Table (Linker_Options.Last) :=
1295                              new String'(Next_Line (Nfirst .. Nlast));
1296                         end if;
1297
1298                      else
1299                         --  If gnatlib library not found, then
1300                         --  add it anyway in case some other
1301                         --  mechanimsm may find it.
1302
1303                         Linker_Options.Increment_Last;
1304                         Linker_Options.Table (Linker_Options.Last) :=
1305                           new String'(Next_Line (Nfirst .. Nlast));
1306                      end if;
1307                   end;
1308                else
1309                   Linker_Options.Increment_Last;
1310                   Linker_Options.Table (Linker_Options.Last) :=
1311                     new String'(Next_Line (Nfirst .. Nlast));
1312                end if;
1313             end if;
1314
1315             Xlinker_Was_Previous := Next_Line (Nfirst .. Nlast) = "-Xlinker";
1316
1317             Get_Next_Line;
1318             exit when Next_Line (Nfirst .. Nlast) = End_Info;
1319
1320             if Ada_Bind_File then
1321                Next_Line (Nfirst .. Nlast - 8) :=
1322                  Next_Line (Nfirst + 8 .. Nlast);
1323                Nlast := Nlast - 8;
1324             end if;
1325          end loop;
1326       end if;
1327
1328       --  If -shared was specified, invoke gcc with -shared-libgcc
1329
1330       if GNAT_Shared then
1331          Linker_Options.Increment_Last;
1332          Linker_Options.Table (Linker_Options.Last) := Shared_Libgcc;
1333       end if;
1334
1335       Status := fclose (Fd);
1336    end Process_Binder_File;
1337
1338    -----------
1339    -- Usage --
1340    -----------
1341
1342    procedure Usage is
1343    begin
1344       Write_Str ("Usage: ");
1345       Write_Str (Base_Name (Command_Name));
1346       Write_Str (" switches mainprog.ali [non-Ada-objects] [linker-options]");
1347       Write_Eol;
1348       Write_Eol;
1349       Write_Line ("  mainprog.ali   the ALI file of the main program");
1350       Write_Eol;
1351       Write_Line ("  -A    Binder generated source file is in Ada (default)");
1352       Write_Line ("  -C    Binder generated source file is in C");
1353       Write_Line ("  -f    force object file list to be generated");
1354       Write_Line ("  -g    Compile binder source file with debug information");
1355       Write_Line ("  -n    Do not compile the binder source file");
1356       Write_Line ("  -R    Do not use a run_path_option");
1357       Write_Line ("  -v    verbose mode");
1358       Write_Line ("  -v -v very verbose mode");
1359       Write_Eol;
1360       Write_Line ("  -o nam     Use 'nam' as the name of the executable");
1361       Write_Line ("  -b target  Compile the binder source to run on target");
1362       Write_Line ("  -Bdir      Load compiler executables from dir");
1363
1364       if Is_Supported (Map_File) then
1365          Write_Line ("  -Mmap      Create map file map");
1366          Write_Line ("  -M         Create map file mainprog.map");
1367       end if;
1368
1369       Write_Line ("  --GCC=comp Use comp as the compiler");
1370       Write_Line ("  --LINK=nam Use 'nam' for the linking rather than 'gcc'");
1371       Write_Eol;
1372       Write_Line ("  [non-Ada-objects]  list of non Ada object files");
1373       Write_Line ("  [linker-options]   other options for the linker");
1374    end Usage;
1375
1376    ------------------
1377    -- Write_Header --
1378    ------------------
1379
1380    procedure Write_Header is
1381    begin
1382       if Verbose_Mode then
1383          Write_Eol;
1384          Display_Version ("GNATLINK", "1995");
1385       end if;
1386    end Write_Header;
1387
1388    -----------------
1389    -- Write_Usage --
1390    -----------------
1391
1392    procedure Write_Usage is
1393    begin
1394       Write_Header;
1395       Usage;
1396    end Write_Usage;
1397
1398 --  Start of processing for Gnatlink
1399
1400 begin
1401    --  Add the directory where gnatlink is invoked in front of the
1402    --  path, if gnatlink is invoked with directory information.
1403    --  Only do this if the platform is not VMS, where the notion of path
1404    --  does not really exist.
1405
1406    if not Hostparm.OpenVMS then
1407       declare
1408          Command : constant String := Command_Name;
1409
1410       begin
1411          for Index in reverse Command'Range loop
1412             if Command (Index) = Directory_Separator then
1413                declare
1414                   Absolute_Dir : constant String :=
1415                                    Normalize_Pathname
1416                                      (Command (Command'First .. Index));
1417
1418                   PATH         : constant String :=
1419                                    Absolute_Dir &
1420                   Path_Separator &
1421                   Getenv ("PATH").all;
1422
1423                begin
1424                   Setenv ("PATH", PATH);
1425                end;
1426
1427                exit;
1428             end if;
1429          end loop;
1430       end;
1431    end if;
1432
1433    Process_Args;
1434
1435    if Argument_Count = 0
1436      or else
1437      (Verbose_Mode and then Argument_Count = 1)
1438    then
1439       Write_Usage;
1440       Exit_Program (E_Fatal);
1441    end if;
1442
1443    --  Get target parameters
1444
1445    Namet.Initialize;
1446    Csets.Initialize;
1447    Snames.Initialize;
1448    Osint.Add_Default_Search_Dirs;
1449    Targparm.Get_Target_Parameters;
1450
1451    if VM_Target /= No_VM then
1452       case VM_Target is
1453          when JVM_Target => Gcc := new String'("jgnat");
1454          when CLI_Target => Gcc := new String'("dotnet-gnatcompile");
1455          when No_VM      => raise Program_Error;
1456       end case;
1457
1458       Ada_Bind_File := True;
1459       Begin_Info := "--  BEGIN Object file/option list";
1460       End_Info   := "--  END Object file/option list   ";
1461    end if;
1462
1463    --  We always compile with -c
1464
1465    Binder_Options_From_ALI.Increment_Last;
1466    Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1467      new String'("-c");
1468
1469    --  If the main program is in Ada it is compiled with the following
1470    --  switches:
1471
1472    --    -gnatA   stops reading gnat.adc, since we don't know what
1473    --             pagmas would work, and we do not need it anyway.
1474
1475    --    -gnatWb  allows brackets coding for wide characters
1476
1477    --    -gnatiw  allows wide characters in identifiers. This is needed
1478    --             because bindgen uses brackets encoding for all upper
1479    --             half and wide characters in identifier names.
1480
1481    if Ada_Bind_File then
1482       Binder_Options_From_ALI.Increment_Last;
1483       Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1484         new String'("-gnatA");
1485       Binder_Options_From_ALI.Increment_Last;
1486       Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1487         new String'("-gnatWb");
1488       Binder_Options_From_ALI.Increment_Last;
1489       Binder_Options_From_ALI.Table (Binder_Options_From_ALI.Last) :=
1490         new String'("-gnatiw");
1491    end if;
1492
1493    --  Locate all the necessary programs and verify required files are present
1494
1495    Gcc_Path := System.OS_Lib.Locate_Exec_On_Path (Gcc.all);
1496
1497    if Gcc_Path = null then
1498       Exit_With_Error ("Couldn't locate " & Gcc.all);
1499    end if;
1500
1501    if Linker_Path = null then
1502       if VM_Target = CLI_Target then
1503          Linker_Path := System.OS_Lib.Locate_Exec_On_Path ("ilasm");
1504
1505          if Linker_Path = null then
1506             Exit_With_Error ("Couldn't locate ilasm");
1507          end if;
1508       else
1509          Linker_Path := Gcc_Path;
1510       end if;
1511    end if;
1512
1513    if Ali_File_Name = null then
1514       Exit_With_Error ("no ali file given for link");
1515    end if;
1516
1517    if not Is_Regular_File (Ali_File_Name.all) then
1518       Exit_With_Error (Ali_File_Name.all & " not found");
1519    end if;
1520
1521    --  Read the ALI file of the main subprogram if the binder generated
1522    --  file needs to be compiled and no --GCC= switch has been specified.
1523    --  Fetch the back end switches from this ALI file and use these switches
1524    --  to compile the binder generated file
1525
1526    if Compile_Bind_File and then Standard_Gcc then
1527
1528       Initialize_ALI;
1529       Name_Len := Ali_File_Name'Length;
1530       Name_Buffer (1 .. Name_Len) := Ali_File_Name.all;
1531
1532       declare
1533          use Types;
1534          F : constant File_Name_Type := Name_Find;
1535          T : Text_Buffer_Ptr;
1536          A : ALI_Id;
1537
1538       begin
1539          --  Load the ALI file
1540
1541          T := Read_Library_Info (F, True);
1542
1543          --  Read it. Note that we ignore errors, since we only want very
1544          --  limited information from the ali file, and likely a slightly
1545          --  wrong version will be just fine, though in normal operation
1546          --  we don't expect this to happen!
1547
1548          A := Scan_ALI
1549                (F,
1550                 T,
1551                 Ignore_ED     => False,
1552                 Err           => False,
1553                 Ignore_Errors => True);
1554
1555          if A /= No_ALI_Id then
1556             for
1557               Index in Units.Table (ALIs.Table (A).First_Unit).First_Arg ..
1558                        Units.Table (ALIs.Table (A).First_Unit).Last_Arg
1559             loop
1560                --  Do not compile with the front end switches. However, --RTS
1561                --  is to be dealt with specially because it needs to be passed
1562                --  if the binder-generated file is in Ada and may also be used
1563                --  to drive the linker.
1564
1565                declare
1566                   Arg : String_Ptr renames Args.Table (Index);
1567                begin
1568                   if not Is_Front_End_Switch (Arg.all) then
1569                      Binder_Options_From_ALI.Increment_Last;
1570                      Binder_Options_From_ALI.Table
1571                        (Binder_Options_From_ALI.Last) := String_Access (Arg);
1572
1573                   elsif Arg'Length > 5
1574                     and then Arg (Arg'First + 2 .. Arg'First + 5) = "RTS="
1575                   then
1576                      if Ada_Bind_File then
1577                         Binder_Options_From_ALI.Increment_Last;
1578                         Binder_Options_From_ALI.Table
1579                           (Binder_Options_From_ALI.Last)
1580                             := String_Access (Arg);
1581                      end if;
1582
1583                      --  GNAT doesn't support the GCC multilib mechanism.
1584                      --  This means that, when a multilib switch is used
1585                      --  to request a particular compilation mode, the
1586                      --  corresponding runtime switch (--RTS) must also be
1587                      --  specified. The long-term goal is to fully support the
1588                      --  multilib mechanism; however, in the meantime, it is
1589                      --  convenient to eliminate the redundancy by keying the
1590                      --  compilation mode on a single switch, namely --RTS.
1591
1592                      --  Pass -mrtp to the linker if --RTS=rtp was passed.
1593
1594                      if Linker_Path = Gcc_Path
1595                        and then Arg'Length > 8
1596                        and then Arg (Arg'First + 6 .. Arg'First + 8) = "rtp"
1597                      then
1598                         Linker_Options.Increment_Last;
1599                         Linker_Options.Table (Linker_Options.Last) :=
1600                           new String'("-mrtp");
1601
1602                      --  Pass -fsjlj to the linker if --RTS=sjlj was passed.
1603
1604                      elsif Linker_Path = Gcc_Path
1605                        and then Arg'Length > 9
1606                        and then Arg (Arg'First + 6 .. Arg'First + 9) = "sjlj"
1607                      then
1608                         Linker_Options.Increment_Last;
1609                         Linker_Options.Table (Linker_Options.Last) :=
1610                           new String'("-fsjlj");
1611                      end if;
1612                   end if;
1613                end;
1614             end loop;
1615          end if;
1616       end;
1617    end if;
1618
1619    Write_Header;
1620
1621    --  If no output name specified, then use the base name of .ali file name
1622
1623    if Output_File_Name = null then
1624       Output_File_Name :=
1625         new String'(Base_Name (Ali_File_Name.all)
1626                       & Get_Target_Debuggable_Suffix.all);
1627
1628       if VM_Target = CLI_Target then
1629          Linker_Options.Increment_Last;
1630          Linker_Options.Table (Linker_Options.Last) := new String'("/QUIET");
1631
1632          Linker_Options.Increment_Last;
1633          Linker_Options.Table (Linker_Options.Last) := new String'("/DEBUG");
1634
1635          Linker_Options.Increment_Last;
1636          Linker_Options.Table (Linker_Options.Last) :=
1637            new String'("/OUTPUT=" & Output_File_Name.all);
1638
1639       else
1640          Linker_Options.Increment_Last;
1641          Linker_Options.Table (Linker_Options.Last) := new String'("-o");
1642
1643          Linker_Options.Increment_Last;
1644          Linker_Options.Table (Linker_Options.Last) :=
1645            new String'(Output_File_Name.all);
1646       end if;
1647    end if;
1648
1649    --  Warn if main program is called "test", as that may be a built-in command
1650    --  on Unix. On non-Unix systems executables have a suffix, so the warning
1651    --  will not appear. However, do not warn in the case of a cross compiler.
1652
1653    --  Assume this is a cross tool if the executable name is not gnatlink
1654
1655    if Base_Name (Command_Name) = "gnatlink"
1656      and then Output_File_Name.all = "test"
1657    then
1658       Error_Msg ("warning: executable name """ & Output_File_Name.all
1659                    & """ may conflict with shell command");
1660    end if;
1661
1662    --  If -M switch was specified, add the switches to create the map file
1663
1664    if Create_Map_File then
1665       declare
1666          Map_Name : constant String := Base_Name (Ali_File_Name.all) & ".map";
1667          Switches : String_List_Access;
1668
1669       begin
1670          Convert (Map_File, Map_Name, Switches);
1671
1672          if Switches /= null then
1673             for J in Switches'Range loop
1674                Linker_Options.Increment_Last;
1675                Linker_Options.Table (Linker_Options.Last) := Switches (J);
1676             end loop;
1677          end if;
1678       end;
1679    end if;
1680
1681    --  Perform consistency checks
1682
1683    --  Transform the .ali file name into the binder output file name
1684
1685    Make_Binder_File_Names : declare
1686       Fname     : constant String  := Base_Name (Ali_File_Name.all);
1687       Fname_Len : Integer := Fname'Length;
1688
1689       function Get_Maximum_File_Name_Length return Integer;
1690       pragma Import (C, Get_Maximum_File_Name_Length,
1691                         "__gnat_get_maximum_file_name_length");
1692
1693       Maximum_File_Name_Length : constant Integer :=
1694                                    Get_Maximum_File_Name_Length;
1695
1696       Bind_File_Prefix : Types.String_Ptr;
1697       --  Contains prefix used for bind files
1698
1699    begin
1700       --  Set prefix
1701
1702       if not Ada_Bind_File then
1703          Bind_File_Prefix := new String'("b_");
1704       elsif OpenVMS_On_Target then
1705          Bind_File_Prefix := new String'("b__");
1706       else
1707          Bind_File_Prefix := new String'("b~");
1708       end if;
1709
1710       --  If the length of the binder file becomes too long due to
1711       --  the addition of the "b?" prefix, then truncate it.
1712
1713       if Maximum_File_Name_Length > 0 then
1714          while Fname_Len >
1715                  Maximum_File_Name_Length - Bind_File_Prefix.all'Length
1716          loop
1717             Fname_Len := Fname_Len - 1;
1718          end loop;
1719       end if;
1720
1721       declare
1722          Fnam : constant String :=
1723                   Bind_File_Prefix.all &
1724                     Fname (Fname'First .. Fname'First + Fname_Len - 1);
1725
1726       begin
1727          if Ada_Bind_File then
1728             Binder_Spec_Src_File := new String'(Fnam & ".ads");
1729             Binder_Body_Src_File := new String'(Fnam & ".adb");
1730             Binder_Ali_File      := new String'(Fnam & ".ali");
1731          else
1732             Binder_Body_Src_File := new String'(Fnam & ".c");
1733          end if;
1734
1735          Binder_Obj_File := new String'(Fnam & Get_Target_Object_Suffix.all);
1736       end;
1737
1738       if Fname_Len /= Fname'Length then
1739          Binder_Options.Increment_Last;
1740          Binder_Options.Table (Binder_Options.Last) := new String'("-o");
1741          Binder_Options.Increment_Last;
1742          Binder_Options.Table (Binder_Options.Last) := Binder_Obj_File;
1743       end if;
1744    end Make_Binder_File_Names;
1745
1746    Process_Binder_File (Binder_Body_Src_File.all & ASCII.NUL);
1747
1748    --  Compile the binder file. This is fast, so we always do it, unless
1749    --  specifically told not to by the -n switch
1750
1751    if Compile_Bind_File then
1752       Bind_Step : declare
1753          Success : Boolean;
1754          Args    : Argument_List
1755            (1 .. Binder_Options_From_ALI.Last + Binder_Options.Last + 1);
1756
1757       begin
1758          for J in 1 .. Binder_Options_From_ALI.Last loop
1759             Args (J) := Binder_Options_From_ALI.Table (J);
1760          end loop;
1761
1762          for J in 1 .. Binder_Options.Last loop
1763             Args (Binder_Options_From_ALI.Last + J) :=
1764               Binder_Options.Table (J);
1765          end loop;
1766
1767          Args (Args'Last) := Binder_Body_Src_File;
1768
1769          if Verbose_Mode then
1770             Write_Str (Base_Name (Gcc_Path.all));
1771
1772             for J in Args'Range loop
1773                Write_Str (" ");
1774                Write_Str (Args (J).all);
1775             end loop;
1776
1777             Write_Eol;
1778          end if;
1779
1780          System.OS_Lib.Spawn (Gcc_Path.all, Args, Success);
1781
1782          if not Success then
1783             Exit_Program (E_Fatal);
1784          end if;
1785       end Bind_Step;
1786    end if;
1787
1788    --  Now, actually link the program
1789
1790    --  Skip this step for now on JVM since the Java interpreter will do
1791    --  the actual link at run time. We might consider packing all class files
1792    --  in a .zip file during this step.
1793
1794    if VM_Target /= JVM_Target then
1795       Link_Step : declare
1796          Num_Args : Natural :=
1797                      (Linker_Options.Last - Linker_Options.First + 1) +
1798                      (Gcc_Linker_Options.Last - Gcc_Linker_Options.First + 1) +
1799                      (Linker_Objects.Last - Linker_Objects.First + 1);
1800          Stack_Op : Boolean := False;
1801          IDENT_Op : Boolean := False;
1802
1803       begin
1804          if VM_Target = CLI_Target then
1805
1806             --  Remove extraneous flags not relevant for CIL. Also remove empty
1807             --  arguments, since ilasm chokes on them.
1808
1809             for J in reverse Linker_Options.First .. Linker_Options.Last loop
1810                if Linker_Options.Table (J)'Length = 0
1811                  or else Linker_Options.Table (J) (1 .. 2) = "-L"
1812                  or else Linker_Options.Table (J) (1 .. 2) = "-l"
1813                  or else Linker_Options.Table (J) (1 .. 3) = "-Wl"
1814                  or else Linker_Options.Table (J) (1 .. 3) = "-sh"
1815                  or else Linker_Options.Table (J) (1 .. 2) = "-g"
1816                then
1817                   Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1818                     Linker_Options.Table (J + 1 .. Linker_Options.Last);
1819                   Linker_Options.Decrement_Last;
1820                   Num_Args := Num_Args - 1;
1821                end if;
1822             end loop;
1823          end if;
1824
1825          --  Remove duplicate stack size setting from the Linker_Options
1826          --  table. The stack setting option "-Xlinker --stack=R,C" can be
1827          --  found in one line when set by a pragma Linker_Options or in two
1828          --  lines ("-Xlinker" then "--stack=R,C") when set on the command
1829          --  line. We also check for the "-Wl,--stack=R" style option.
1830
1831          --  We must remove the second stack setting option instance
1832          --  because the one on the command line will always be the first
1833          --  one. And any subsequent stack setting option will overwrite the
1834          --  previous one. This is done especially for GNAT/NT where we set
1835          --  the stack size for tasking programs by a pragma in the NT
1836          --  specific tasking package System.Task_Primitives.Oparations.
1837
1838          --  Note: This is not a FOR loop that runs from Linker_Options.First
1839          --  to Linker_Options.Last, since operations within the loop can
1840          --  modify the length of the table.
1841
1842          Clean_Link_Option_Set : declare
1843             J : Natural := Linker_Options.First;
1844             Shared_Libgcc_Seen : Boolean := False;
1845
1846          begin
1847             while J <= Linker_Options.Last loop
1848
1849                if Linker_Options.Table (J).all = "-Xlinker"
1850                  and then J < Linker_Options.Last
1851                  and then Linker_Options.Table (J + 1)'Length > 8
1852                  and then Linker_Options.Table (J + 1) (1 .. 8) = "--stack="
1853                then
1854                   if Stack_Op then
1855                      Linker_Options.Table (J .. Linker_Options.Last - 2) :=
1856                        Linker_Options.Table (J + 2 .. Linker_Options.Last);
1857                      Linker_Options.Decrement_Last;
1858                      Linker_Options.Decrement_Last;
1859                      Num_Args := Num_Args - 2;
1860
1861                   else
1862                      Stack_Op := True;
1863                   end if;
1864                end if;
1865
1866                --  Remove duplicate -shared-libgcc switch
1867
1868                if Linker_Options.Table (J).all = Shared_Libgcc_String then
1869                   if Shared_Libgcc_Seen then
1870                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1871                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
1872                      Linker_Options.Decrement_Last;
1873                      Num_Args := Num_Args - 1;
1874
1875                   else
1876                      Shared_Libgcc_Seen := True;
1877                   end if;
1878                end if;
1879
1880                --  Here we just check for a canonical form that matches the
1881                --  pragma Linker_Options set in the NT runtime.
1882
1883                if (Linker_Options.Table (J)'Length > 17
1884                    and then Linker_Options.Table (J) (1 .. 17)
1885                            = "-Xlinker --stack=")
1886                  or else
1887                   (Linker_Options.Table (J)'Length > 12
1888                    and then Linker_Options.Table (J) (1 .. 12)
1889                             = "-Wl,--stack=")
1890                then
1891                   if Stack_Op then
1892                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1893                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
1894                      Linker_Options.Decrement_Last;
1895                      Num_Args := Num_Args - 1;
1896
1897                   else
1898                      Stack_Op := True;
1899                   end if;
1900                end if;
1901
1902                --  Remove duplicate IDENTIFICATION directives (VMS)
1903
1904                if Linker_Options.Table (J)'Length > 27
1905                  and then Linker_Options.Table (J) (1 .. 28)
1906                           = "--for-linker=IDENTIFICATION="
1907                then
1908                   if IDENT_Op then
1909                      Linker_Options.Table (J .. Linker_Options.Last - 1) :=
1910                        Linker_Options.Table (J + 1 .. Linker_Options.Last);
1911                      Linker_Options.Decrement_Last;
1912                      Num_Args := Num_Args - 1;
1913                   else
1914                      IDENT_Op := True;
1915                   end if;
1916                end if;
1917
1918                J := J + 1;
1919             end loop;
1920
1921             if Linker_Path = Gcc_Path and then VM_Target = No_VM then
1922
1923                --  If gcc is not called with -shared-libgcc, call it with
1924                --  -static-libgcc, as there are some platforms where one of
1925                --  these two switches is compulsory to link.
1926
1927                if not Shared_Libgcc_Seen then
1928                   Linker_Options.Increment_Last;
1929                   Linker_Options.Table (Linker_Options.Last) := Static_Libgcc;
1930                   Num_Args := Num_Args + 1;
1931                end if;
1932             end if;
1933
1934          end Clean_Link_Option_Set;
1935
1936          --  Prepare arguments for call to linker
1937
1938          Call_Linker : declare
1939             Success  : Boolean;
1940             Args     : Argument_List (1 .. Num_Args + 1);
1941             Index    : Integer := Args'First;
1942
1943          begin
1944             Args (Index) := Binder_Obj_File;
1945
1946             --  Add the object files and any -largs libraries
1947
1948             for J in Linker_Objects.First .. Linker_Objects.Last loop
1949                Index := Index + 1;
1950                Args (Index) := Linker_Objects.Table (J);
1951             end loop;
1952
1953             --  Add the linker options from the binder file
1954
1955             for J in Linker_Options.First .. Linker_Options.Last loop
1956                Index := Index + 1;
1957                Args (Index) := Linker_Options.Table (J);
1958             end loop;
1959
1960             --  Finally add the libraries from the --GCC= switch
1961
1962             for J in Gcc_Linker_Options.First .. Gcc_Linker_Options.Last loop
1963                Index := Index + 1;
1964                Args (Index) := Gcc_Linker_Options.Table (J);
1965             end loop;
1966
1967             if Verbose_Mode then
1968                Write_Str (Linker_Path.all);
1969
1970                for J in Args'Range loop
1971                   Write_Str (" ");
1972                   Write_Str (Args (J).all);
1973                end loop;
1974
1975                Write_Eol;
1976
1977                --  If we are on very verbose mode (-v -v) and a response file
1978                --  is used we display its content.
1979
1980                if Very_Verbose_Mode and then Tname_FD /= Invalid_FD then
1981                   Write_Eol;
1982                   Write_Str ("Response file (" &
1983                              Tname (Tname'First .. Tname'Last - 1) &
1984                              ") content : ");
1985                   Write_Eol;
1986
1987                   for J in
1988                     Response_File_Objects.First ..
1989                     Response_File_Objects.Last
1990                   loop
1991                      Write_Str (Response_File_Objects.Table (J).all);
1992                      Write_Eol;
1993                   end loop;
1994
1995                   Write_Eol;
1996                end if;
1997             end if;
1998
1999             System.OS_Lib.Spawn (Linker_Path.all, Args, Success);
2000
2001             --  Delete the temporary file used in conjuction with linking if
2002             --  one was created. See Process_Bind_File for details.
2003
2004             if Tname_FD /= Invalid_FD then
2005                Delete (Tname);
2006             end if;
2007
2008             if not Success then
2009                Error_Msg ("error when calling " & Linker_Path.all);
2010                Exit_Program (E_Fatal);
2011             end if;
2012          end Call_Linker;
2013       end Link_Step;
2014    end if;
2015
2016    --  Only keep the binder output file and it's associated object
2017    --  file if compiling with the -g option.  These files are only
2018    --  useful if debugging.
2019
2020    if not Debug_Flag_Present then
2021       if Binder_Ali_File /= null then
2022          Delete (Binder_Ali_File.all & ASCII.NUL);
2023       end if;
2024
2025       if Binder_Spec_Src_File /= null then
2026          Delete (Binder_Spec_Src_File.all & ASCII.NUL);
2027       end if;
2028
2029       Delete (Binder_Body_Src_File.all & ASCII.NUL);
2030
2031       if VM_Target = No_VM then
2032          Delete (Binder_Obj_File.all & ASCII.NUL);
2033       end if;
2034    end if;
2035
2036    Exit_Program (E_Success);
2037
2038 exception
2039    when X : others =>
2040       Write_Line (Exception_Information (X));
2041       Exit_With_Error ("INTERNAL ERROR. Please report");
2042 end Gnatlink;