gcc/ada/gnatdll.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              G N A T D L L                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1997-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  GNATDLL is a Windows specific tool for building a DLL.
  28 --  Both relocatable and non-relocatable DLL's are supported
  29
  30 with Ada.Text_IO;           use Ada.Text_IO;
  31 with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
  32 with Ada.Exceptions;        use Ada.Exceptions;
  33 with Ada.Command_Line;      use Ada.Command_Line;
  34 with GNAT.OS_Lib;           use GNAT.OS_Lib;
  35 with GNAT.Command_Line;     use GNAT.Command_Line;
  36 with Gnatvsn;
  37
  38 with MDLL.Fil;              use MDLL.Fil;
  39 with MDLL.Utl;              use MDLL.Utl;
  40
  41 procedure Gnatdll is
  42
  43    use type GNAT.OS_Lib.Argument_List;
  44
  45    procedure Syntax;
  46    --  Print out usage
  47
  48    procedure Check (Filename : String);
  49    --  Check that the file whose name is Filename exists
  50
  51    procedure Parse_Command_Line;
  52    --  Parse the command line arguments passed to gnatdll
  53
  54    procedure Check_Context;
  55    --  Check the context before runing any commands to build the library
  56
  57    Syntax_Error : exception;
  58    --  Raised when a syntax error is detected, in this case a usage info will
  59    --  be displayed.
  60
  61    Context_Error : exception;
  62    --  Raised when some files (specifed on the command line) are missing to
  63    --  build the DLL.
  64
  65    Help : Boolean := False;
  66    --  Help will be set to True the usage information is to be displayed
  67
  68    Version : constant String := Gnatvsn.Gnat_Version_String;
  69    --  Why should it be necessary to make a copy of this
  70
  71    Default_DLL_Address : constant String := "0x11000000";
  72    --  Default address for non relocatable DLL (Win32)
  73
  74    Lib_Filename : Unbounded_String := Null_Unbounded_String;
  75    --  The DLL filename that will be created (.dll)
  76
  77    Def_Filename : Unbounded_String := Null_Unbounded_String;
  78    --  The definition filename (.def)
  79
  80    List_Filename : Unbounded_String := Null_Unbounded_String;
  81    --  The name of the file containing the objects file to put into the DLL
  82
  83    DLL_Address : Unbounded_String := To_Unbounded_String (Default_DLL_Address);
  84    --  The DLL's base address
  85
  86    Gen_Map_File : Boolean := False;
  87    --  Set to True if a map file is to be generated
  88
  89    Objects_Files : Argument_List_Access := MDLL.Null_Argument_List_Access;
  90    --  List of objects to put inside the library
  91
  92    Ali_Files : Argument_List_Access := MDLL.Null_Argument_List_Access;
  93    --  For each Ada file specified, we keep arecord of the corresponding
  94    --  ALI file. This list of SLI files is used to build the binder program.
  95
  96    Options : Argument_List_Access := MDLL.Null_Argument_List_Access;
  97    --  A list of options set in the command line
  98
  99    Largs_Options : Argument_List_Access := MDLL.Null_Argument_List_Access;
 100    Bargs_Options : Argument_List_Access := MDLL.Null_Argument_List_Access;
 101    --  GNAT linker and binder args options
 102
 103    type Build_Mode_State is (Import_Lib, Dynamic_Lib, Dynamic_Lib_Only, Nil);
 104    --  Import_Lib means only the .a file will be created, Dynamic_Lib means
 105    --  that both the DLL and the import library will be created.
 106    --  Dynamic_Lib_Only means that only the DLL will be created (no import
 107    --  library).
 108
 109    Build_Mode : Build_Mode_State := Nil;
 110    --  Will be set when parsing the command line
 111
 112    Must_Build_Relocatable : Boolean := True;
 113    --  True means build a relocatable DLL, will be set to False if a
 114    --  non-relocatable DLL must be built.
 115
 116    ------------
 117    -- Syntax --
 118    ------------
 119
 120    procedure Syntax is
 121       procedure P (Str : String) renames Put_Line;
 122    begin
 123       P ("Usage : gnatdll [options] [list-of-files]");
 124       New_Line;
 125       P ("[list-of-files] a list of Ada libraries (.ali) and/or " &
 126          "foreign object files");
 127       New_Line;
 128       P ("[options] can be");
 129       P ("   -h            Help - display this message");
 130       P ("   -v            Verbose");
 131       P ("   -q            Quiet");
 132       P ("   -k            Remove @nn suffix from exported names");
 133       P ("   -g            Generate debugging information");
 134       P ("   -Idir         Specify source and object files search path");
 135       P ("   -l file       File contains a list-of-files to be added to "
 136          & "the library");
 137       P ("   -e file       Definition file containing exports");
 138       P ("   -d file       Put objects in the relocatable dynamic "
 139          & "library <file>");
 140       P ("   -b addr       Set base address for the relocatable DLL");
 141       P ("                 default address is " & Default_DLL_Address);
 142       P ("   -a[addr]      Build non-relocatable DLL at address <addr>");
 143       P ("                 if <addr> is not specified use "
 144          & Default_DLL_Address);
 145       P ("   -m            Generate map file");
 146       P ("   -n            No-import - do not create the import library");
 147       P ("   -bargs opts   opts are passed to the binder");
 148       P ("   -largs opts   opts are passed to the linker");
 149    end Syntax;
 150
 151    -----------
 152    -- Check --
 153    -----------
 154
 155    procedure Check (Filename : String) is
 156    begin
 157       if not Is_Regular_File (Filename) then
 158          Raise_Exception
 159            (Context_Error'Identity, "Error: " & Filename & " not found.");
 160       end if;
 161    end Check;
 162
 163    ------------------------
 164    -- Parse_Command_Line --
 165    ------------------------
 166
 167    procedure Parse_Command_Line is
 168
 169       procedure Add_File (Filename : String);
 170       --  Add one file to the list of file to handle
 171
 172       procedure Add_Files_From_List (List_Filename : String);
 173       --  Add the files listed in List_Filename (one by line) to the list
 174       --  of file to handle
 175
 176       Max_Files   : constant := 5_000;
 177       Max_Options : constant :=   100;
 178       --  These are arbitrary limits, a better way will be to use linked list.
 179       --  No, a better choice would be to use tables ???
 180       --  Limits on what???
 181
 182       Ofiles : Argument_List (1 .. Max_Files);
 183       O      : Positive := Ofiles'First;
 184       --  List of object files to put in the library. O is the next entry
 185       --  to be used.
 186
 187       Afiles : Argument_List (1 .. Max_Files);
 188       A      : Positive := Afiles'First;
 189       --  List of ALI files. A is the next entry to be used
 190
 191       Gopts  : Argument_List (1 .. Max_Options);
 192       G      : Positive := Gopts'First;
 193       --  List of gcc options. G is the next entry to be used
 194
 195       Lopts  : Argument_List (1 .. Max_Options);
 196       L      : Positive := Lopts'First;
 197       --  A list of -largs options (L is next entry to be used)
 198
 199       Bopts  : Argument_List (1 .. Max_Options);
 200       B      : Positive := Bopts'First;
 201       --  A list of -bargs options (B is next entry to be used)
 202
 203       Build_Import : Boolean := True;
 204       --  Set to Fals if option -n if specified (no-import)
 205
 206       --------------
 207       -- Add_File --
 208       --------------
 209
 210       procedure Add_File (Filename : String) is
 211       begin
 212          if Is_Ali (Filename) then
 213             Check (Filename);
 214
 215             --  Record it to generate the binder program when
 216             --  building dynamic library
 217
 218             Afiles (A) := new String'(Filename);
 219             A := A + 1;
 220
 221          elsif Is_Obj (Filename) then
 222             Check (Filename);
 223
 224             --  Just record this object file
 225
 226             Ofiles (O) := new String'(Filename);
 227             O := O + 1;
 228
 229          else
 230             --  Unknown file type
 231
 232             Raise_Exception
 233               (Syntax_Error'Identity,
 234                "don't know what to do with " & Filename & " !");
 235          end if;
 236       end Add_File;
 237
 238       -------------------------
 239       -- Add_Files_From_List --
 240       -------------------------
 241
 242       procedure Add_Files_From_List (List_Filename : String) is
 243          File   : File_Type;
 244          Buffer : String (1 .. 500);
 245          Last   : Natural;
 246
 247       begin
 248          Open (File, In_File, List_Filename);
 249
 250          while not End_Of_File (File) loop
 251             Get_Line (File, Buffer, Last);
 252             Add_File (Buffer (1 .. Last));
 253          end loop;
 254
 255          Close (File);
 256       end Add_Files_From_List;
 257
 258    --  Start of processing for Parse_Command_Line
 259
 260    begin
 261       Initialize_Option_Scan ('-', False, "bargs largs");
 262
 263       --  scan gnatdll switches
 264
 265       loop
 266          case Getopt ("g h v q k a? b: d: e: l: n m I:") is
 267
 268             when ASCII.Nul =>
 269                exit;
 270
 271             when 'h' =>
 272                Help := True;
 273
 274             when 'g' =>
 275                Gopts (G) := new String'("-g");
 276                G := G + 1;
 277
 278             when 'v' =>
 279
 280                --  Turn verbose mode on
 281
 282                MDLL.Verbose := True;
 283                if MDLL.Quiet then
 284                   Raise_Exception
 285                     (Syntax_Error'Identity,
 286                      "impossible to use -q and -v together.");
 287                end if;
 288
 289             when 'q' =>
 290
 291                --  Turn quiet mode on
 292
 293                MDLL.Quiet := True;
 294                if MDLL.Verbose then
 295                   Raise_Exception
 296                     (Syntax_Error'Identity,
 297                      "impossible to use -v and -q together.");
 298                end if;
 299
 300             when 'k' =>
 301
 302                MDLL.Kill_Suffix := True;
 303
 304             when 'a' =>
 305
 306                if Parameter = "" then
 307
 308                   --  Default address for a relocatable dynamic library.
 309                   --  address for a non relocatable dynamic library.
 310
 311                   DLL_Address := To_Unbounded_String (Default_DLL_Address);
 312
 313                else
 314                   DLL_Address := To_Unbounded_String (Parameter);
 315                end if;
 316
 317                Must_Build_Relocatable := False;
 318
 319             when 'b' =>
 320
 321                DLL_Address := To_Unbounded_String (Parameter);
 322
 323                Must_Build_Relocatable := True;
 324
 325             when 'e' =>
 326
 327                Def_Filename := To_Unbounded_String (Parameter);
 328
 329             when 'd' =>
 330
 331                --  Build a non relocatable DLL
 332
 333                Lib_Filename := To_Unbounded_String (Parameter);
 334
 335                if Def_Filename = Null_Unbounded_String then
 336                   Def_Filename := To_Unbounded_String
 337                     (Ext_To (Parameter, "def"));
 338                end if;
 339
 340                Build_Mode := Dynamic_Lib;
 341
 342             when 'm' =>
 343
 344                Gen_Map_File := True;
 345
 346             when 'n' =>
 347
 348                Build_Import := False;
 349
 350             when 'l' =>
 351                List_Filename := To_Unbounded_String (Parameter);
 352
 353             when 'I' =>
 354                Gopts (G) := new String'("-I" & Parameter);
 355                G := G + 1;
 356
 357             when others =>
 358                raise Invalid_Switch;
 359          end case;
 360       end loop;
 361
 362       --  Get parameters
 363
 364       loop
 365          declare
 366             File : constant String := Get_Argument (Do_Expansion => True);
 367          begin
 368             exit when File'Length = 0;
 369             Add_File (File);
 370          end;
 371       end loop;
 372
 373       --  Get largs parameters
 374
 375       Goto_Section ("largs");
 376
 377       loop
 378          case Getopt ("*") is
 379             when ASCII.Nul =>
 380                exit;
 381
 382             when others =>
 383                Lopts (L) := new String'(Full_Switch);
 384                L := L + 1;
 385          end case;
 386       end loop;
 387
 388       --  Get bargs parameters
 389
 390       Goto_Section ("bargs");
 391
 392       loop
 393          case Getopt ("*") is
 394
 395             when ASCII.Nul =>
 396                exit;
 397
 398             when others =>
 399                Bopts (B) := new String'(Full_Switch);
 400                B := B + 1;
 401
 402          end case;
 403       end loop;
 404
 405       --  if list filename has been specified, parse it
 406
 407       if List_Filename /= Null_Unbounded_String then
 408          Add_Files_From_List (To_String (List_Filename));
 409       end if;
 410
 411       --  Check if the set of parameters are compatible
 412
 413       if Build_Mode = Nil and then not Help and then not MDLL.Verbose then
 414          Raise_Exception (Syntax_Error'Identity, "nothing to do.");
 415       end if;
 416
 417       --  -n option but no file specified
 418
 419       if not Build_Import
 420         and then A = Afiles'First
 421         and then O = Ofiles'First
 422       then
 423          Raise_Exception
 424            (Syntax_Error'Identity,
 425             "-n specified but there are no objects to build the library.");
 426       end if;
 427
 428       --  Check if we want to build an import library (option -e and
 429       --  no file specified)
 430
 431       if Build_Mode = Dynamic_Lib
 432         and then A = Afiles'First
 433         and then O = Ofiles'First
 434       then
 435          Build_Mode := Import_Lib;
 436       end if;
 437
 438       --  If map file is to be generated, add linker option here
 439
 440       if Gen_Map_File and then Build_Mode = Import_Lib then
 441          Raise_Exception
 442            (Syntax_Error'Identity,
 443             "Can't generate a map file for an import library.");
 444       end if;
 445
 446       --  Check if only a dynamic library must be built
 447
 448       if Build_Mode = Dynamic_Lib and then not Build_Import then
 449          Build_Mode := Dynamic_Lib_Only;
 450       end if;
 451
 452       if O /= Ofiles'First then
 453          Objects_Files := new Argument_List'(Ofiles (1 .. O - 1));
 454       end if;
 455
 456       if A /= Afiles'First then
 457          Ali_Files     := new Argument_List'(Afiles (1 .. A - 1));
 458       end if;
 459
 460       if G /= Gopts'First then
 461          Options       := new Argument_List'(Gopts (1 .. G - 1));
 462       end if;
 463
 464       if L /= Lopts'First then
 465          Largs_Options := new Argument_List'(Lopts (1 .. L - 1));
 466       end if;
 467
 468       if B /= Bopts'First then
 469          Bargs_Options := new Argument_List'(Bopts (1 .. B - 1));
 470       end if;
 471
 472    exception
 473       when Invalid_Switch    =>
 474          Raise_Exception
 475            (Syntax_Error'Identity,
 476             Message => "Invalid Switch " & Full_Switch);
 477
 478       when Invalid_Parameter =>
 479          Raise_Exception
 480            (Syntax_Error'Identity,
 481             Message => "No parameter for " & Full_Switch);
 482    end Parse_Command_Line;
 483
 484    -------------------
 485    -- Check_Context --
 486    -------------------
 487
 488    procedure Check_Context is
 489    begin
 490       Check (To_String (Def_Filename));
 491
 492       --  Check that each object file specified exists and raise exception
 493       --  Context_Error if it does not.
 494
 495       for F in Objects_Files'Range loop
 496          Check (Objects_Files (F).all);
 497       end loop;
 498    end Check_Context;
 499
 500 --  Start of processing for Gnatdll
 501
 502 begin
 503    if Ada.Command_Line.Argument_Count = 0 then
 504       Help := True;
 505    else
 506       Parse_Command_Line;
 507    end if;
 508
 509    if MDLL.Verbose or else Help then
 510       New_Line;
 511       Put_Line ("GNATDLL " & Version & " - Dynamic Libraries Builder");
 512       New_Line;
 513    end if;
 514
 515    MDLL.Utl.Locate;
 516
 517    if Help
 518      or else (MDLL.Verbose and then Ada.Command_Line.Argument_Count = 1)
 519    then
 520       Syntax;
 521    else
 522       Check_Context;
 523
 524       case Build_Mode is
 525          when Import_Lib =>
 526             MDLL.Build_Import_Library
 527               (To_String (Lib_Filename),
 528                To_String (Def_Filename));
 529
 530          when Dynamic_Lib =>
 531             MDLL.Build_Dynamic_Library
 532               (Objects_Files.all,
 533                Ali_Files.all,
 534                Options.all,
 535                Bargs_Options.all,
 536                Largs_Options.all,
 537                To_String (Lib_Filename),
 538                To_String (Def_Filename),
 539                To_String (DLL_Address),
 540                Build_Import => True,
 541                Relocatable  => Must_Build_Relocatable,
 542                Map_File     => Gen_Map_File);
 543
 544          when Dynamic_Lib_Only =>
 545             MDLL.Build_Dynamic_Library
 546               (Objects_Files.all,
 547                Ali_Files.all,
 548                Options.all,
 549                Bargs_Options.all,
 550                Largs_Options.all,
 551                To_String (Lib_Filename),
 552                To_String (Def_Filename),
 553                To_String (DLL_Address),
 554                Build_Import => False,
 555                Relocatable  => Must_Build_Relocatable,
 556                Map_File     => Gen_Map_File);
 557
 558          when Nil =>
 559             null;
 560       end case;
 561    end if;
 562
 563    Set_Exit_Status (Success);
 564
 565 exception
 566    when SE : Syntax_Error =>
 567       Put_Line ("Syntax error : " & Exception_Message (SE));
 568       New_Line;
 569       Syntax;
 570       Set_Exit_Status (Failure);
 571
 572    when E : MDLL.Tools_Error | Context_Error =>
 573       Put_Line (Exception_Message (E));
 574       Set_Exit_Status (Failure);
 575
 576    when others =>
 577       Put_Line ("gnatdll: INTERNAL ERROR. Please report");
 578       Set_Exit_Status (Failure);
 579 end Gnatdll;