gcc/ada/gnat1drv.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             G N A T 1 D R V                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Back_End; use Back_End;
  28 with Comperr;
  29 with Csets;    use Csets;
  30 with Debug;    use Debug;
  31 with Elists;
  32 with Errout;   use Errout;
  33 with Fmap;
  34 with Fname;    use Fname;
  35 with Fname.UF; use Fname.UF;
  36 with Frontend;
  37 with Gnatvsn;  use Gnatvsn;
  38 with Hostparm;
  39 with Inline;
  40 with Lib;      use Lib;
  41 with Lib.Writ; use Lib.Writ;
  42 with Lib.Xref;
  43 with Namet;    use Namet;
  44 with Nlists;
  45 with Opt;      use Opt;
  46 with Osint;    use Osint;
  47 with Output;   use Output;
  48 with Par_SCO;
  49 with Prepcomp;
  50 with Repinfo;  use Repinfo;
  51 with Restrict;
  52 with Rtsfind;
  53 with SCOs;
  54 with Sem;
  55 with Sem_Ch8;
  56 with Sem_Ch12;
  57 with Sem_Ch13;
  58 with Sem_Elim;
  59 with Sem_Eval;
  60 with Sem_Type;
  61 with Sinfo;    use Sinfo;
  62 with Sinput.L; use Sinput.L;
  63 with Snames;
  64 with Sprint;   use Sprint;
  65 with Stringt;
  66 with Stylesw;  use Stylesw;
  67 with Targparm; use Targparm;
  68 with Tree_Gen;
  69 with Treepr;   use Treepr;
  70 with Ttypes;
  71 with Types;    use Types;
  72 with Uintp;    use Uintp;
  73 with Uname;    use Uname;
  74 with Urealp;
  75 with Usage;
  76 with Validsw;  use Validsw;
  77
  78 with System.Assertions;
  79
  80 procedure Gnat1drv is
  81    Main_Unit_Node : Node_Id;
  82    --  Compilation unit node for main unit
  83
  84    Main_Kind : Node_Kind;
  85    --  Kind of main compilation unit node
  86
  87    Back_End_Mode : Back_End.Back_End_Mode_Type;
  88    --  Record back end mode
  89
  90    procedure Adjust_Global_Switches;
  91    --  There are various interactions between front end switch settings,
  92    --  including debug switch settings and target dependent parameters.
  93    --  This procedure takes care of properly handling these interactions.
  94    --  We do it after scanning out all the switches, so that we are not
  95    --  depending on the order in which switches appear.
  96
  97    procedure Check_Bad_Body;
  98    --  Called to check if the unit we are compiling has a bad body
  99
 100    procedure Check_Rep_Info;
 101    --  Called when we are not generating code, to check if -gnatR was requested
 102    --  and if so, explain that we will not be honoring the request.
 103
 104    procedure Check_Library_Items;
 105    --  For debugging -- checks the behavior of Walk_Library_Items
 106    pragma Warnings (Off, Check_Library_Items);
 107    --  In case the call below is commented out
 108
 109    ----------------------------
 110    -- Adjust_Global_Switches --
 111    ----------------------------
 112
 113    procedure Adjust_Global_Switches is
 114    begin
 115       --  Debug flag -gnatd.I is a synonym of Generate_SCIL
 116
 117       if Debug_Flag_Dot_II then
 118          Generate_SCIL := True;
 119       end if;
 120
 121       --  Set ASIS mode if -gnatt and -gnatc are set
 122
 123       if Operating_Mode = Check_Semantics and then Tree_Output then
 124          ASIS_Mode := True;
 125
 126          --  Turn off inlining in ASIS mode, since ASIS cannot handle the extra
 127          --  information in the trees caused by inlining being active.
 128
 129          --  More specifically, the tree seems to be malformed from the ASIS
 130          --  point of view if -gnatc and -gnatn appear together???
 131
 132          Inline_Active := False;
 133
 134          --  Turn off SCIL generation in ASIS mode, since SCIL requires front-
 135          --  end expansion.
 136
 137          Generate_SCIL := False;
 138       end if;
 139
 140       --  SCIL mode needs to disable front-end inlining since the generated
 141       --  trees (in particular order and consistency between specs compiled
 142       --  as part of a main unit or as part of a with-clause) are causing
 143       --  troubles.
 144
 145       if Generate_SCIL then
 146          Front_End_Inlining := False;
 147       end if;
 148
 149       --  Tune settings for optimal SCIL generation in CodePeer_Mode
 150
 151       if CodePeer_Mode then
 152
 153          --  Turn off inlining, confuses CodePeer output and gains nothing
 154
 155          Front_End_Inlining := False;
 156          Inline_Active      := False;
 157
 158          --  Turn off ASIS mode: incompatible with front-end expansion.
 159
 160          ASIS_Mode := False;
 161
 162          --  Suppress overflow, division by zero and access checks since they
 163          --  are handled implicitly by CodePeer.
 164
 165          --  Turn off dynamic elaboration checks: generates inconsistencies in
 166          --  trees between specs compiled as part of a main unit or as part of
 167          --  a with-clause.
 168
 169          --  Turn off alignment checks: these cannot be proved statically by
 170          --  CodePeer and generate false positives.
 171
 172          --  Enable all other language checks
 173
 174          Suppress_Options :=
 175            (Access_Check      => True,
 176             Alignment_Check   => True,
 177             Division_Check    => True,
 178             Elaboration_Check => True,
 179             Overflow_Check    => True,
 180             others            => False);
 181          Enable_Overflow_Checks := False;
 182          Dynamic_Elaboration_Checks := False;
 183
 184          --  Kill debug of generated code, since it messes up sloc values
 185
 186          Debug_Generated_Code := False;
 187
 188          --  Turn cross-referencing on in case it was disabled (by e.g. -gnatD)
 189          --  Do we really need to spend time generating xref in CodePeer
 190          --  mode??? Consider setting Xref_Active to False.
 191
 192          Xref_Active := True;
 193
 194          --  Polling mode forced off, since it generates confusing junk
 195
 196          Polling_Required := False;
 197
 198          --  Set operating mode to Generate_Code to benefit from full
 199          --  front-end expansion (e.g. generics).
 200
 201          Operating_Mode := Generate_Code;
 202
 203          --  We need SCIL generation of course
 204
 205          Generate_SCIL := True;
 206
 207          --  Enable assertions and debug pragmas, since they give CodePeer
 208          --  valuable extra information.
 209
 210          Assertions_Enabled     := True;
 211          Debug_Pragmas_Enabled  := True;
 212
 213          --  Suppress compiler warnings, since what we are interested in here
 214          --  is what CodePeer can find out. Also disable all simple value
 215          --  propagation. This is an optimization which is valuable for code
 216          --  optimization, and also for generation of compiler warnings, but
 217          --  these are being turned off anyway, and CodePeer understands
 218          --  things more clearly if references are not optimized in this way.
 219
 220          Warning_Mode  := Suppress;
 221          Debug_Flag_MM := True;
 222
 223          --  Set normal RM validity checking, and checking of IN OUT parameters
 224          --  (this might give CodePeer more useful checks to analyze, to be
 225          --  confirmed???). All other validity checking is turned off, since
 226          --  this can generate very complex trees that only confuse CodePeer
 227          --  and do not bring enough useful info.
 228
 229          Reset_Validity_Check_Options;
 230          Validity_Check_Default       := True;
 231          Validity_Check_In_Out_Params := True;
 232          Validity_Check_In_Params     := True;
 233
 234          --  Turn off style check options since we are not interested in any
 235          --  front-end warnings when we are getting CodePeer output.
 236
 237          Reset_Style_Check_Options;
 238       end if;
 239
 240       --  Set Configurable_Run_Time mode if system.ads flag set
 241
 242       if Targparm.Configurable_Run_Time_On_Target or Debug_Flag_YY then
 243          Configurable_Run_Time_Mode := True;
 244       end if;
 245
 246       --  Set -gnatR3m mode if debug flag A set
 247
 248       if Debug_Flag_AA then
 249          Back_Annotate_Rep_Info := True;
 250          List_Representation_Info := 1;
 251          List_Representation_Info_Mechanisms := True;
 252       end if;
 253
 254       --  Force Target_Strict_Alignment true if debug flag -gnatd.a is set
 255
 256       if Debug_Flag_Dot_A then
 257          Ttypes.Target_Strict_Alignment := True;
 258       end if;
 259
 260       --  Disable static allocation of dispatch tables if -gnatd.t or if layout
 261       --  is enabled. The front end's layout phase currently treats types that
 262       --  have discriminant-dependent arrays as not being static even when a
 263       --  discriminant constraint on the type is static, and this leads to
 264       --  problems with subtypes of type Ada.Tags.Dispatch_Table_Wrapper. ???
 265
 266       if Debug_Flag_Dot_T or else Frontend_Layout_On_Target then
 267          Static_Dispatch_Tables := False;
 268       end if;
 269
 270       --  Flip endian mode if -gnatd8 set
 271
 272       if Debug_Flag_8 then
 273          Ttypes.Bytes_Big_Endian := not Ttypes.Bytes_Big_Endian;
 274       end if;
 275
 276       --  Deal with forcing OpenVMS switches True if debug flag M is set, but
 277       --  record the setting of Targparm.Open_VMS_On_Target in True_VMS_Target
 278       --  before doing this, so we know if we are in real OpenVMS or not!
 279
 280       Opt.True_VMS_Target := Targparm.OpenVMS_On_Target;
 281
 282       if Debug_Flag_M then
 283          Targparm.OpenVMS_On_Target := True;
 284          Hostparm.OpenVMS := True;
 285       end if;
 286
 287       --  Activate front end layout if debug flag -gnatdF is set
 288
 289       if Debug_Flag_FF then
 290          Targparm.Frontend_Layout_On_Target := True;
 291       end if;
 292
 293       --  Set and check exception mechnism
 294
 295       if Targparm.ZCX_By_Default_On_Target then
 296          if Targparm.GCC_ZCX_Support_On_Target then
 297             Exception_Mechanism := Back_End_Exceptions;
 298          else
 299             Osint.Fail ("Zero Cost Exceptions not supported on this target");
 300          end if;
 301       end if;
 302
 303       --  Set proper status for overflow checks. We turn on overflow checks
 304       --  if -gnatp was not specified, and either -gnato is set or the back
 305       --  end takes care of overflow checks. Otherwise we suppress overflow
 306       --  checks by default (since front end checks are expensive).
 307
 308       if not Opt.Suppress_Checks
 309         and then (Opt.Enable_Overflow_Checks
 310                     or else
 311                       (Targparm.Backend_Divide_Checks_On_Target
 312                         and
 313                        Targparm.Backend_Overflow_Checks_On_Target))
 314       then
 315          Suppress_Options (Overflow_Check) := False;
 316       else
 317          Suppress_Options (Overflow_Check) := True;
 318       end if;
 319    end Adjust_Global_Switches;
 320
 321    --------------------
 322    -- Check_Bad_Body --
 323    --------------------
 324
 325    procedure Check_Bad_Body is
 326       Sname   : Unit_Name_Type;
 327       Src_Ind : Source_File_Index;
 328       Fname   : File_Name_Type;
 329
 330       procedure Bad_Body_Error (Msg : String);
 331       --  Issue message for bad body found
 332
 333       --------------------
 334       -- Bad_Body_Error --
 335       --------------------
 336
 337       procedure Bad_Body_Error (Msg : String) is
 338       begin
 339          Error_Msg_N (Msg, Main_Unit_Node);
 340          Error_Msg_File_1 := Fname;
 341          Error_Msg_N ("remove incorrect body in file{!", Main_Unit_Node);
 342       end Bad_Body_Error;
 343
 344       --  Start of processing for Check_Bad_Body
 345
 346    begin
 347       --  Nothing to do if we are only checking syntax, because we don't know
 348       --  enough to know if we require or forbid a body in this case.
 349
 350       if Operating_Mode = Check_Syntax then
 351          return;
 352       end if;
 353
 354       --  Check for body not allowed
 355
 356       if (Main_Kind = N_Package_Declaration
 357            and then not Body_Required (Main_Unit_Node))
 358         or else (Main_Kind = N_Generic_Package_Declaration
 359                   and then not Body_Required (Main_Unit_Node))
 360         or else Main_Kind = N_Package_Renaming_Declaration
 361         or else Main_Kind = N_Subprogram_Renaming_Declaration
 362         or else Nkind (Original_Node (Unit (Main_Unit_Node)))
 363                          in N_Generic_Instantiation
 364       then
 365          Sname := Unit_Name (Main_Unit);
 366
 367          --  If we do not already have a body name, then get the body name
 368          --  (but how can we have a body name here ???)
 369
 370          if not Is_Body_Name (Sname) then
 371             Sname := Get_Body_Name (Sname);
 372          end if;
 373
 374          Fname := Get_File_Name (Sname, Subunit => False);
 375          Src_Ind := Load_Source_File (Fname);
 376
 377          --  Case where body is present and it is not a subunit. Exclude
 378          --  the subunit case, because it has nothing to do with the
 379          --  package we are compiling. It is illegal for a child unit and a
 380          --  subunit with the same expanded name (RM 10.2(9)) to appear
 381          --  together in a partition, but there is nothing to stop a
 382          --  compilation environment from having both, and the test here
 383          --  simply allows that. If there is an attempt to include both in
 384          --  a partition, this is diagnosed at bind time. In Ada 83 mode
 385          --  this is not a warning case.
 386
 387          --  Note: if weird file names are being used, we can have
 388          --  situation where the file name that supposedly contains body,
 389          --  in fact contains a spec, or we can't tell what it contains.
 390          --  Skip the error message in these cases.
 391
 392          --  Also ignore body that is nothing but pragma No_Body; (that's the
 393          --  whole point of this pragma, to be used this way and to cause the
 394          --  body file to be ignored in this context).
 395
 396          if Src_Ind /= No_Source_File
 397            and then Get_Expected_Unit_Type (Fname) = Expect_Body
 398            and then not Source_File_Is_Subunit (Src_Ind)
 399            and then not Source_File_Is_No_Body (Src_Ind)
 400          then
 401             Errout.Finalize (Last_Call => False);
 402
 403             Error_Msg_Unit_1 := Sname;
 404
 405             --  Ada 83 case of a package body being ignored. This is not an
 406             --  error as far as the Ada 83 RM is concerned, but it is almost
 407             --  certainly not what is wanted so output a warning. Give this
 408             --  message only if there were no errors, since otherwise it may
 409             --  be incorrect (we may have misinterpreted a junk spec as not
 410             --  needing a body when it really does).
 411
 412             if Main_Kind = N_Package_Declaration
 413               and then Ada_Version = Ada_83
 414               and then Operating_Mode = Generate_Code
 415               and then Distribution_Stub_Mode /= Generate_Caller_Stub_Body
 416               and then not Compilation_Errors
 417             then
 418                Error_Msg_N
 419                  ("package $$ does not require a body?", Main_Unit_Node);
 420                Error_Msg_File_1 := Fname;
 421                Error_Msg_N ("body in file{? will be ignored", Main_Unit_Node);
 422
 423                --  Ada 95 cases of a body file present when no body is
 424                --  permitted. This we consider to be an error.
 425
 426             else
 427                --  For generic instantiations, we never allow a body
 428
 429                if Nkind (Original_Node (Unit (Main_Unit_Node)))
 430                in N_Generic_Instantiation
 431                then
 432                   Bad_Body_Error
 433                     ("generic instantiation for $$ does not allow a body");
 434
 435                   --  A library unit that is a renaming never allows a body
 436
 437                elsif Main_Kind in N_Renaming_Declaration then
 438                   Bad_Body_Error
 439                     ("renaming declaration for $$ does not allow a body!");
 440
 441                   --  Remaining cases are packages and generic packages. Here
 442                   --  we only do the test if there are no previous errors,
 443                   --  because if there are errors, they may lead us to
 444                   --  incorrectly believe that a package does not allow a body
 445                   --  when in fact it does.
 446
 447                elsif not Compilation_Errors then
 448                   if Main_Kind = N_Package_Declaration then
 449                      Bad_Body_Error
 450                        ("package $$ does not allow a body!");
 451
 452                   elsif Main_Kind = N_Generic_Package_Declaration then
 453                      Bad_Body_Error
 454                        ("generic package $$ does not allow a body!");
 455                   end if;
 456                end if;
 457
 458             end if;
 459          end if;
 460       end if;
 461    end Check_Bad_Body;
 462
 463    --------------------
 464    -- Check_Rep_Info --
 465    --------------------
 466
 467    procedure Check_Rep_Info is
 468    begin
 469       if List_Representation_Info /= 0
 470         or else List_Representation_Info_Mechanisms
 471       then
 472          Set_Standard_Error;
 473          Write_Eol;
 474          Write_Str
 475            ("cannot generate representation information, no code generated");
 476          Write_Eol;
 477          Write_Eol;
 478          Set_Standard_Output;
 479       end if;
 480    end Check_Rep_Info;
 481
 482    -------------------------
 483    -- Check_Library_Items --
 484    -------------------------
 485
 486    --  Walk_Library_Items has plenty of assertions, so all we need to do is
 487    --  call it, just for these assertions, not actually doing anything else.
 488
 489    procedure Check_Library_Items is
 490
 491       procedure Action (Item : Node_Id);
 492       --  Action passed to Walk_Library_Items to do nothing
 493
 494       ------------
 495       -- Action --
 496       ------------
 497
 498       procedure Action (Item : Node_Id) is
 499       begin
 500          null;
 501       end Action;
 502
 503       procedure Walk is new Sem.Walk_Library_Items (Action);
 504
 505    --  Start of processing for Check_Library_Items
 506
 507    begin
 508       Walk;
 509    end Check_Library_Items;
 510
 511 --  Start of processing for Gnat1drv
 512
 513 begin
 514    --  This inner block is set up to catch assertion errors and constraint
 515    --  errors. Since the code for handling these errors can cause another
 516    --  exception to be raised (namely Unrecoverable_Error), we need two
 517    --  nested blocks, so that the outer one handles unrecoverable error.
 518
 519    begin
 520       --  Initialize all packages. For the most part, these initialization
 521       --  calls can be made in any order. Exceptions are as follows:
 522
 523       --  Lib.Initialize need to be called before Scan_Compiler_Arguments,
 524       --  because it initializes a table filled by Scan_Compiler_Arguments.
 525
 526       Osint.Initialize;
 527       Fmap.Reset_Tables;
 528       Lib.Initialize;
 529       Lib.Xref.Initialize;
 530       Scan_Compiler_Arguments;
 531       Osint.Add_Default_Search_Dirs;
 532
 533       Nlists.Initialize;
 534       Sinput.Initialize;
 535       Sem.Initialize;
 536       Csets.Initialize;
 537       Uintp.Initialize;
 538       Urealp.Initialize;
 539       Errout.Initialize;
 540       Namet.Initialize;
 541       SCOs.Initialize;
 542       Snames.Initialize;
 543       Stringt.Initialize;
 544       Inline.Initialize;
 545       Par_SCO.Initialize;
 546       Sem_Ch8.Initialize;
 547       Sem_Ch12.Initialize;
 548       Sem_Ch13.Initialize;
 549       Sem_Elim.Initialize;
 550       Sem_Eval.Initialize;
 551       Sem_Type.Init_Interp_Tables;
 552
 553       --  Acquire target parameters from system.ads (source of package System)
 554
 555       declare
 556          use Sinput;
 557
 558          S : Source_File_Index;
 559          N : File_Name_Type;
 560
 561       begin
 562          Name_Buffer (1 .. 10) := "system.ads";
 563          Name_Len := 10;
 564          N := Name_Find;
 565          S := Load_Source_File (N);
 566
 567          if S = No_Source_File then
 568             Write_Line
 569               ("fatal error, run-time library not installed correctly");
 570             Write_Line
 571               ("cannot locate file system.ads");
 572             raise Unrecoverable_Error;
 573
 574          --  Remember source index of system.ads (which was read successfully)
 575
 576          else
 577             System_Source_File_Index := S;
 578          end if;
 579
 580          Targparm.Get_Target_Parameters
 581            (System_Text  => Source_Text  (S),
 582             Source_First => Source_First (S),
 583             Source_Last  => Source_Last  (S));
 584
 585          --  Acquire configuration pragma information from Targparm
 586
 587          Restrict.Restrictions := Targparm.Restrictions_On_Target;
 588       end;
 589
 590       Adjust_Global_Switches;
 591
 592       --  Output copyright notice if full list mode unless we have a list
 593       --  file, in which case we defer this so that it is output in the file
 594
 595       if (Verbose_Mode or else (Full_List and then Full_List_File_Name = null))
 596         and then not Debug_Flag_7
 597       then
 598          Write_Eol;
 599          Write_Str ("GNAT ");
 600          Write_Str (Gnat_Version_String);
 601          Write_Eol;
 602          Write_Str ("Copyright 1992-" &
 603                     Current_Year &
 604                     ", Free Software Foundation, Inc.");
 605          Write_Eol;
 606       end if;
 607
 608       --  Check we do not have more than one source file, this happens only in
 609       --  the case where the driver is called directly, it cannot happen when
 610       --  gnat1 is invoked from gcc in the normal case.
 611
 612       if Osint.Number_Of_Files /= 1 then
 613          Usage;
 614          Write_Eol;
 615          Osint.Fail ("you must provide one source file");
 616
 617       elsif Usage_Requested then
 618          Usage;
 619       end if;
 620
 621       Original_Operating_Mode := Operating_Mode;
 622       Frontend;
 623
 624       --  Exit with errors if the main source could not be parsed
 625
 626       if Sinput.Main_Source_File = No_Source_File then
 627          Errout.Finalize (Last_Call => True);
 628          Errout.Output_Messages;
 629          Exit_Program (E_Errors);
 630       end if;
 631
 632       Main_Unit_Node := Cunit (Main_Unit);
 633       Main_Kind := Nkind (Unit (Main_Unit_Node));
 634       Check_Bad_Body;
 635
 636       --  Exit if compilation errors detected
 637
 638       Errout.Finalize (Last_Call => False);
 639
 640       if Compilation_Errors then
 641          Treepr.Tree_Dump;
 642          Sem_Ch13.Validate_Unchecked_Conversions;
 643          Sem_Ch13.Validate_Address_Clauses;
 644          Errout.Output_Messages;
 645          Namet.Finalize;
 646
 647          --  Generate ALI file if specially requested
 648
 649          if Opt.Force_ALI_Tree_File then
 650             Write_ALI (Object => False);
 651             Tree_Gen;
 652          end if;
 653
 654          Errout.Finalize (Last_Call => True);
 655          Exit_Program (E_Errors);
 656       end if;
 657
 658       --  Set Generate_Code on main unit and its spec. We do this even if are
 659       --  not generating code, since Lib-Writ uses this to determine which
 660       --  units get written in the ali file.
 661
 662       Set_Generate_Code (Main_Unit);
 663
 664       --  If we have a corresponding spec, and it comes from source
 665       --  or it is not a generated spec for a child subprogram body,
 666       --  then we need object code for the spec unit as well.
 667
 668       if Nkind (Unit (Main_Unit_Node)) in N_Unit_Body
 669         and then not Acts_As_Spec (Main_Unit_Node)
 670       then
 671          if Nkind (Unit (Main_Unit_Node)) = N_Subprogram_Body
 672            and then not Comes_From_Source (Library_Unit (Main_Unit_Node))
 673          then
 674             null;
 675          else
 676             Set_Generate_Code
 677               (Get_Cunit_Unit_Number (Library_Unit (Main_Unit_Node)));
 678          end if;
 679       end if;
 680
 681       --  Case of no code required to be generated, exit indicating no error
 682
 683       if Original_Operating_Mode = Check_Syntax then
 684          Treepr.Tree_Dump;
 685          Errout.Finalize (Last_Call => True);
 686          Errout.Output_Messages;
 687          Tree_Gen;
 688          Namet.Finalize;
 689          Check_Rep_Info;
 690
 691          --  Use a goto instead of calling Exit_Program so that finalization
 692          --  occurs normally.
 693
 694          goto End_Of_Program;
 695
 696       elsif Original_Operating_Mode = Check_Semantics then
 697          Back_End_Mode := Declarations_Only;
 698
 699       --  All remaining cases are cases in which the user requested that code
 700       --  be generated (i.e. no -gnatc or -gnats switch was used). Check if
 701       --  we can in fact satisfy this request.
 702
 703       --  Cannot generate code if someone has turned off code generation for
 704       --  any reason at all. We will try to figure out a reason below.
 705
 706       elsif Operating_Mode /= Generate_Code then
 707          Back_End_Mode := Skip;
 708
 709       --  We can generate code for a subprogram body unless there were missing
 710       --  subunits. Note that we always generate code for all generic units (a
 711       --  change from some previous versions of GNAT).
 712
 713       elsif Main_Kind = N_Subprogram_Body
 714         and then not Subunits_Missing
 715       then
 716          Back_End_Mode := Generate_Object;
 717
 718       --  We can generate code for a package body unless there are subunits
 719       --  missing (note that we always generate code for generic units, which
 720       --  is a change from some earlier versions of GNAT).
 721
 722       elsif Main_Kind = N_Package_Body
 723         and then not Subunits_Missing
 724       then
 725          Back_End_Mode := Generate_Object;
 726
 727       --  We can generate code for a package declaration or a subprogram
 728       --  declaration only if it does not required a body.
 729
 730       elsif (Main_Kind = N_Package_Declaration
 731                or else
 732              Main_Kind = N_Subprogram_Declaration)
 733         and then
 734           (not Body_Required (Main_Unit_Node)
 735              or else
 736            Distribution_Stub_Mode = Generate_Caller_Stub_Body)
 737       then
 738          Back_End_Mode := Generate_Object;
 739
 740       --  We can generate code for a generic package declaration of a generic
 741       --  subprogram declaration only if does not require a body.
 742
 743       elsif (Main_Kind = N_Generic_Package_Declaration
 744                or else
 745              Main_Kind = N_Generic_Subprogram_Declaration)
 746         and then not Body_Required (Main_Unit_Node)
 747       then
 748          Back_End_Mode := Generate_Object;
 749
 750       --  Compilation units that are renamings do not require bodies,
 751       --  so we can generate code for them.
 752
 753       elsif Main_Kind = N_Package_Renaming_Declaration
 754         or else Main_Kind = N_Subprogram_Renaming_Declaration
 755       then
 756          Back_End_Mode := Generate_Object;
 757
 758       --  Compilation units that are generic renamings do not require bodies
 759       --  so we can generate code for them.
 760
 761       elsif Main_Kind in N_Generic_Renaming_Declaration then
 762          Back_End_Mode := Generate_Object;
 763
 764       --  It's not an error to generate SCIL for e.g. a spec which has a body
 765
 766       elsif CodePeer_Mode then
 767          Back_End_Mode := Generate_Object;
 768
 769       --  In all other cases (specs which have bodies, generics, and bodies
 770       --  where subunits are missing), we cannot generate code and we generate
 771       --  a warning message. Note that generic instantiations are gone at this
 772       --  stage since they have been replaced by their instances.
 773
 774       else
 775          Back_End_Mode := Skip;
 776       end if;
 777
 778       --  At this stage Back_End_Mode is set to indicate if the backend should
 779       --  be called to generate code. If it is Skip, then code generation has
 780       --  been turned off, even though code was requested by the original
 781       --  command. This is not an error from the user point of view, but it is
 782       --  an error from the point of view of the gcc driver, so we must exit
 783       --  with an error status.
 784
 785       --  We generate an informative message (from the gcc point of view, it
 786       --  is an error message, but from the users point of view this is not an
 787       --  error, just a consequence of compiling something that cannot
 788       --  generate code).
 789
 790       if Back_End_Mode = Skip then
 791          Set_Standard_Error;
 792          Write_Str ("cannot generate code for ");
 793          Write_Str ("file ");
 794          Write_Name (Unit_File_Name (Main_Unit));
 795
 796          if Subunits_Missing then
 797             Write_Str (" (missing subunits)");
 798             Write_Eol;
 799             Write_Str ("to check parent unit");
 800
 801          elsif Main_Kind = N_Subunit then
 802             Write_Str (" (subunit)");
 803             Write_Eol;
 804             Write_Str ("to check subunit");
 805
 806          elsif Main_Kind = N_Subprogram_Declaration then
 807             Write_Str (" (subprogram spec)");
 808             Write_Eol;
 809             Write_Str ("to check subprogram spec");
 810
 811          --  Generic package body in GNAT implementation mode
 812
 813          elsif Main_Kind = N_Package_Body and then GNAT_Mode then
 814             Write_Str (" (predefined generic)");
 815             Write_Eol;
 816             Write_Str ("to check predefined generic");
 817
 818          --  Only other case is a package spec
 819
 820          else
 821             Write_Str (" (package spec)");
 822             Write_Eol;
 823             Write_Str ("to check package spec");
 824          end if;
 825
 826          Write_Str (" for errors, use ");
 827
 828          if Hostparm.OpenVMS then
 829             Write_Str ("/NOLOAD");
 830          else
 831             Write_Str ("-gnatc");
 832          end if;
 833
 834          Write_Eol;
 835          Set_Standard_Output;
 836
 837          Sem_Ch13.Validate_Unchecked_Conversions;
 838          Sem_Ch13.Validate_Address_Clauses;
 839          Errout.Finalize (Last_Call => True);
 840          Errout.Output_Messages;
 841          Treepr.Tree_Dump;
 842          Tree_Gen;
 843          Write_ALI (Object => False);
 844          Namet.Finalize;
 845          Check_Rep_Info;
 846
 847          --  Exit program with error indication, to kill object file
 848
 849          Exit_Program (E_No_Code);
 850       end if;
 851
 852       --  In -gnatc mode, we only do annotation if -gnatt or -gnatR is also
 853       --  set as indicated by Back_Annotate_Rep_Info being set to True.
 854
 855       --  We don't call for annotations on a subunit, because to process those
 856       --  the back-end requires that the parent(s) be properly compiled.
 857
 858       --  Annotation is suppressed for targets where front-end layout is
 859       --  enabled, because the front end determines representations.
 860
 861       --  Annotation is also suppressed in the case of compiling for
 862       --  a VM, since representations are largely symbolic there.
 863
 864       if Back_End_Mode = Declarations_Only
 865         and then (not (Back_Annotate_Rep_Info or Generate_SCIL)
 866                    or else Main_Kind = N_Subunit
 867                    or else Targparm.Frontend_Layout_On_Target
 868                    or else Targparm.VM_Target /= No_VM)
 869       then
 870          Sem_Ch13.Validate_Unchecked_Conversions;
 871          Sem_Ch13.Validate_Address_Clauses;
 872          Errout.Finalize (Last_Call => True);
 873          Errout.Output_Messages;
 874          Write_ALI (Object => False);
 875          Tree_Dump;
 876          Tree_Gen;
 877          Namet.Finalize;
 878          Check_Rep_Info;
 879          return;
 880       end if;
 881
 882       --  Ensure that we properly register a dependency on system.ads, since
 883       --  even if we do not semantically depend on this, Targparm has read
 884       --  system parameters from the system.ads file.
 885
 886       Lib.Writ.Ensure_System_Dependency;
 887
 888       --  Add dependencies, if any, on preprocessing data file and on
 889       --  preprocessing definition file(s).
 890
 891       Prepcomp.Add_Dependencies;
 892
 893       --  Back end needs to explicitly unlock tables it needs to touch
 894
 895       Atree.Lock;
 896       Elists.Lock;
 897       Fname.UF.Lock;
 898       Inline.Lock;
 899       Lib.Lock;
 900       Nlists.Lock;
 901       Sem.Lock;
 902       Sinput.Lock;
 903       Namet.Lock;
 904       Stringt.Lock;
 905
 906       --  ???Check_Library_Items under control of a debug flag, because it
 907       --  currently does not work if the -gnatn switch (back end inlining) is
 908       --  used.
 909
 910       if Debug_Flag_Dot_WW then
 911          Check_Library_Items;
 912       end if;
 913
 914       --  Here we call the back end to generate the output code
 915
 916       Generating_Code := True;
 917       Back_End.Call_Back_End (Back_End_Mode);
 918
 919       --  Once the backend is complete, we unlock the names table. This call
 920       --  allows a few extra entries, needed for example for the file name for
 921       --  the library file output.
 922
 923       Namet.Unlock;
 924
 925       --  Validate unchecked conversions (using the values for size and
 926       --  alignment annotated by the backend where possible).
 927
 928       Sem_Ch13.Validate_Unchecked_Conversions;
 929
 930       --  Validate address clauses (again using alignment values annotated
 931       --  by the backend where possible).
 932
 933       Sem_Ch13.Validate_Address_Clauses;
 934
 935       --  Now we complete output of errors, rep info and the tree info. These
 936       --  are delayed till now, since it is perfectly possible for gigi to
 937       --  generate errors, modify the tree (in particular by setting flags
 938       --  indicating that elaboration is required, and also to back annotate
 939       --  representation information for List_Rep_Info.
 940
 941       Errout.Finalize (Last_Call => True);
 942       Errout.Output_Messages;
 943       List_Rep_Info;
 944
 945       --  Only write the library if the backend did not generate any error
 946       --  messages. Otherwise signal errors to the driver program so that
 947       --  there will be no attempt to generate an object file.
 948
 949       if Compilation_Errors then
 950          Treepr.Tree_Dump;
 951          Exit_Program (E_Errors);
 952       end if;
 953
 954       Write_ALI (Object => (Back_End_Mode = Generate_Object));
 955
 956       --  Generate the ASIS tree after writing the ALI file, since in ASIS
 957       --  mode, Write_ALI may in fact result in further tree decoration from
 958       --  the original tree file. Note that we dump the tree just before
 959       --  generating it, so that the dump will exactly reflect what is written
 960       --  out.
 961
 962       Treepr.Tree_Dump;
 963       Tree_Gen;
 964
 965       --  Finalize name table and we are all done
 966
 967       Namet.Finalize;
 968
 969    exception
 970       --  Handle fatal internal compiler errors
 971
 972       when Rtsfind.RE_Not_Available =>
 973          Comperr.Compiler_Abort ("RE_Not_Available");
 974
 975       when System.Assertions.Assert_Failure =>
 976          Comperr.Compiler_Abort ("Assert_Failure");
 977
 978       when Constraint_Error =>
 979          Comperr.Compiler_Abort ("Constraint_Error");
 980
 981       when Program_Error =>
 982          Comperr.Compiler_Abort ("Program_Error");
 983
 984       when Storage_Error =>
 985
 986          --  Assume this is a bug. If it is real, the message will in any case
 987          --  say Storage_Error, giving a strong hint!
 988
 989          Comperr.Compiler_Abort ("Storage_Error");
 990    end;
 991
 992    <<End_Of_Program>>
 993    null;
 994
 995    --  The outer exception handles an unrecoverable error
 996
 997 exception
 998    when Unrecoverable_Error =>
 999       Errout.Finalize (Last_Call => True);
1000       Errout.Output_Messages;
1001
1002       Set_Standard_Error;
1003       Write_Str ("compilation abandoned");
1004       Write_Eol;
1005
1006       Set_Standard_Output;
1007       Source_Dump;
1008       Tree_Dump;
1009       Exit_Program (E_Errors);
1010
1011 end Gnat1drv;