gcc/ada/gnat1drv.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             G N A T 1 D R V                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Back_End; use Back_End;
  29 with Comperr;
  30 with Csets;    use Csets;
  31 with Debug;    use Debug;
  32 with Elists;
  33 with Errout;   use Errout;
  34 with Fmap;
  35 with Fname;    use Fname;
  36 with Fname.UF; use Fname.UF;
  37 with Frontend;
  38 with Gnatvsn;  use Gnatvsn;
  39 with Hostparm;
  40 with Inline;
  41 with Lib;      use Lib;
  42 with Lib.Writ; use Lib.Writ;
  43 with Lib.Xref;
  44 with Namet;    use Namet;
  45 with Nlists;
  46 with Opt;      use Opt;
  47 with Osint;    use Osint;
  48 with Output;   use Output;
  49 with Prepcomp;
  50 with Repinfo;  use Repinfo;
  51 with Restrict;
  52 with Sem;
  53 with Sem_Ch8;
  54 with Sem_Ch12;
  55 with Sem_Ch13;
  56 with Sem_Elim;
  57 with Sem_Eval;
  58 with Sem_Type;
  59 with Sinfo;    use Sinfo;
  60 with Sinput.L; use Sinput.L;
  61 with Snames;
  62 with Sprint;   use Sprint;
  63 with Stringt;
  64 with Targparm;
  65 with Tree_Gen;
  66 with Treepr;   use Treepr;
  67 with Ttypes;
  68 with Types;    use Types;
  69 with Uintp;    use Uintp;
  70 with Uname;    use Uname;
  71 with Urealp;
  72 with Usage;
  73
  74 with System.Assertions;
  75
  76 procedure Gnat1drv is
  77    Main_Unit_Node : Node_Id;
  78    --  Compilation unit node for main unit
  79
  80    Main_Kind : Node_Kind;
  81    --  Kind of main compilation unit node
  82
  83    Back_End_Mode : Back_End.Back_End_Mode_Type;
  84    --  Record back end mode
  85
  86 begin
  87    --  This inner block is set up to catch assertion errors and constraint
  88    --  errors. Since the code for handling these errors can cause another
  89    --  exception to be raised (namely Unrecoverable_Error), we need two
  90    --  nested blocks, so that the outer one handles unrecoverable error.
  91
  92    begin
  93       --  Lib.Initialize need to be called before Scan_Compiler_Arguments,
  94       --  because it initialize a table that is filled by
  95       --  Scan_Compiler_Arguments.
  96
  97       Osint.Initialize;
  98       Fmap.Reset_Tables;
  99       Lib.Initialize;
 100       Lib.Xref.Initialize;
 101       Scan_Compiler_Arguments;
 102       Osint.Add_Default_Search_Dirs;
 103
 104       Nlists.Initialize;
 105       Sinput.Initialize;
 106       Sem.Initialize;
 107       Csets.Initialize;
 108       Uintp.Initialize;
 109       Urealp.Initialize;
 110       Errout.Initialize;
 111       Namet.Initialize;
 112       Snames.Initialize;
 113       Stringt.Initialize;
 114       Inline.Initialize;
 115       Sem_Ch8.Initialize;
 116       Sem_Ch12.Initialize;
 117       Sem_Ch13.Initialize;
 118       Sem_Elim.Initialize;
 119       Sem_Eval.Initialize;
 120       Sem_Type.Init_Interp_Tables;
 121
 122       --  Acquire target parameters from system.ads (source of package System)
 123
 124       declare
 125          use Sinput;
 126
 127          S : Source_File_Index;
 128          N : Name_Id;
 129
 130       begin
 131          Name_Buffer (1 .. 10) := "system.ads";
 132          Name_Len := 10;
 133          N := Name_Find;
 134          S := Load_Source_File (N);
 135
 136          if S = No_Source_File then
 137             Write_Line
 138               ("fatal error, run-time library not installed correctly");
 139             Write_Line
 140               ("cannot locate file system.ads");
 141             raise Unrecoverable_Error;
 142
 143          --  Remember source index of system.ads (which was read successfully)
 144
 145          else
 146             System_Source_File_Index := S;
 147          end if;
 148
 149          Targparm.Get_Target_Parameters
 150            (System_Text  => Source_Text (S),
 151             Source_First => Source_First (S),
 152             Source_Last  => Source_Last (S));
 153
 154          --  Acquire configuration pragma information from Targparm
 155
 156          Restrict.Restrictions := Targparm.Restrictions_On_Target;
 157       end;
 158
 159       --  Set Configurable_Run_Time mode if system.ads flag set
 160
 161       if Targparm.Configurable_Run_Time_On_Target or Debug_Flag_YY then
 162          Configurable_Run_Time_Mode := True;
 163       end if;
 164
 165       --  Set -gnatR3m mode if debug flag A set
 166
 167       if Debug_Flag_AA then
 168          Back_Annotate_Rep_Info := True;
 169          List_Representation_Info := 1;
 170          List_Representation_Info_Mechanisms := True;
 171       end if;
 172
 173       --  Output copyright notice if full list mode
 174
 175       if (Verbose_Mode or Full_List)
 176         and then (not Debug_Flag_7)
 177       then
 178          Write_Eol;
 179          Write_Str ("GNAT ");
 180          Write_Str (Gnat_Version_String);
 181          Write_Eol;
 182          Write_Str ("Copyright 1992-" &
 183                     Current_Year &
 184                     ", Free Software Foundation, Inc.");
 185          Write_Eol;
 186       end if;
 187
 188       --  Before we do anything else, adjust certain global values for
 189       --  debug switches which modify their normal natural settings.
 190
 191       if Debug_Flag_8 then
 192          Ttypes.Bytes_Big_Endian := not Ttypes.Bytes_Big_Endian;
 193       end if;
 194
 195       if Debug_Flag_M then
 196          Targparm.OpenVMS_On_Target := True;
 197          Hostparm.OpenVMS := True;
 198       end if;
 199
 200       if Debug_Flag_FF then
 201          Targparm.Frontend_Layout_On_Target := True;
 202       end if;
 203
 204       --  We take the default exception mechanism into account
 205
 206       if Targparm.ZCX_By_Default_On_Target then
 207          if Targparm.GCC_ZCX_Support_On_Target then
 208             Exception_Mechanism := Back_End_Exceptions;
 209          else
 210             Osint.Fail
 211               ("Zero Cost Exceptions not supported on this target");
 212          end if;
 213       end if;
 214
 215       --  Set proper status for overflow checks. We turn on overflow checks
 216       --  if -gnatp was not specified, and either -gnato is set or the back
 217       --  end takes care of overflow checks. Otherwise we suppress overflow
 218       --  checks by default (since front end checks are expensive).
 219
 220       if not Opt.Suppress_Checks
 221         and then (Opt.Enable_Overflow_Checks
 222                     or else
 223                       (Targparm.Backend_Divide_Checks_On_Target
 224                         and
 225                        Targparm.Backend_Overflow_Checks_On_Target))
 226       then
 227          Suppress_Options (Overflow_Check) := False;
 228       else
 229          Suppress_Options (Overflow_Check) := True;
 230       end if;
 231
 232       --  Check we have exactly one source file, this happens only in the case
 233       --  where the driver is called directly, it cannot happen when gnat1 is
 234       --  invoked from gcc in the normal case.
 235
 236       if Osint.Number_Of_Files /= 1 then
 237          Usage;
 238          Write_Eol;
 239          Osint.Fail ("you must provide one source file");
 240
 241       elsif Usage_Requested then
 242          Usage;
 243       end if;
 244
 245       Original_Operating_Mode := Operating_Mode;
 246       Frontend;
 247       Main_Unit_Node := Cunit (Main_Unit);
 248       Main_Kind := Nkind (Unit (Main_Unit_Node));
 249
 250       --  Check for suspicious or incorrect body present if we are doing
 251       --  semantic checking. We omit this check in syntax only mode, because
 252       --  in that case we do not know if we need a body or not.
 253
 254       if Operating_Mode /= Check_Syntax
 255         and then
 256           ((Main_Kind = N_Package_Declaration
 257              and then not Body_Required (Main_Unit_Node))
 258            or else (Main_Kind = N_Generic_Package_Declaration
 259                      and then not Body_Required (Main_Unit_Node))
 260            or else Main_Kind = N_Package_Renaming_Declaration
 261            or else Main_Kind = N_Subprogram_Renaming_Declaration
 262            or else Nkind (Original_Node (Unit (Main_Unit_Node)))
 263                            in N_Generic_Instantiation)
 264       then
 265          Bad_Body : declare
 266             Sname   : Unit_Name_Type := Unit_Name (Main_Unit);
 267             Src_Ind : Source_File_Index;
 268             Fname   : File_Name_Type;
 269
 270             procedure Bad_Body_Error (Msg : String);
 271             --  Issue message for bad body found
 272
 273             --------------------
 274             -- Bad_Body_Error --
 275             --------------------
 276
 277             procedure Bad_Body_Error (Msg : String) is
 278             begin
 279                Error_Msg_N (Msg, Main_Unit_Node);
 280                Error_Msg_Name_1 := Fname;
 281                Error_Msg_N
 282                  ("remove incorrect body in file{!", Main_Unit_Node);
 283             end Bad_Body_Error;
 284
 285          --  Start of processing for Bad_Body
 286
 287          begin
 288             Sname := Unit_Name (Main_Unit);
 289
 290             --  If we do not already have a body name, then get the body name
 291             --  (but how can we have a body name here ???)
 292
 293             if not Is_Body_Name (Sname) then
 294                Sname := Get_Body_Name (Sname);
 295             end if;
 296
 297             Fname := Get_File_Name (Sname, Subunit => False);
 298             Src_Ind := Load_Source_File (Fname);
 299
 300             --  Case where body is present and it is not a subunit. Exclude
 301             --  the subunit case, because it has nothing to do with the
 302             --  package we are compiling. It is illegal for a child unit and a
 303             --  subunit with the same expanded name (RM 10.2(9)) to appear
 304             --  together in a partition, but there is nothing to stop a
 305             --  compilation environment from having both, and the test here
 306             --  simply allows that. If there is an attempt to include both in
 307             --  a partition, this is diagnosed at bind time. In Ada 83 mode
 308             --  this is not a warning case.
 309
 310             --  Note: if weird file names are being used, we can have
 311             --  situation where the file name that supposedly contains body,
 312             --  in fact contains a spec, or we can't tell what it contains.
 313             --  Skip the error message in these cases.
 314
 315             if Src_Ind /= No_Source_File
 316               and then Get_Expected_Unit_Type (Fname) = Expect_Body
 317               and then not Source_File_Is_Subunit (Src_Ind)
 318             then
 319                Error_Msg_Name_1 := Sname;
 320
 321                --  Ada 83 case of a package body being ignored. This is not an
 322                --  error as far as the Ada 83 RM is concerned, but it is
 323                --  almost certainly not what is wanted so output a warning.
 324                --  Give this message only if there were no errors, since
 325                --  otherwise it may be incorrect (we may have misinterpreted a
 326                --  junk spec as not needing a body when it really does).
 327
 328                if Main_Kind = N_Package_Declaration
 329                  and then Ada_Version = Ada_83
 330                  and then Operating_Mode = Generate_Code
 331                  and then Distribution_Stub_Mode /= Generate_Caller_Stub_Body
 332                  and then not Compilation_Errors
 333                then
 334                   Error_Msg_N
 335                     ("package % does not require a body?", Main_Unit_Node);
 336                   Error_Msg_Name_1 := Fname;
 337                   Error_Msg_N
 338                     ("body in file{? will be ignored", Main_Unit_Node);
 339
 340                --  Ada 95 cases of a body file present when no body is
 341                --  permitted. This we consider to be an error.
 342
 343                else
 344                   --  For generic instantiations, we never allow a body
 345
 346                   if Nkind (Original_Node (Unit (Main_Unit_Node)))
 347                       in N_Generic_Instantiation
 348                   then
 349                      Bad_Body_Error
 350                        ("generic instantiation for % does not allow a body");
 351
 352                   --  A library unit that is a renaming never allows a body
 353
 354                   elsif Main_Kind in N_Renaming_Declaration then
 355                      Bad_Body_Error
 356                        ("renaming declaration for % does not allow a body!");
 357
 358                   --  Remaining cases are packages and generic packages. Here
 359                   --  we only do the test if there are no previous errors,
 360                   --  because if there are errors, they may lead us to
 361                   --  incorrectly believe that a package does not allow a body
 362                   --  when in fact it does.
 363
 364                   elsif not Compilation_Errors then
 365                      if Main_Kind = N_Package_Declaration then
 366                         Bad_Body_Error
 367                           ("package % does not allow a body!");
 368
 369                      elsif Main_Kind = N_Generic_Package_Declaration then
 370                         Bad_Body_Error
 371                           ("generic package % does not allow a body!");
 372                      end if;
 373                   end if;
 374
 375                end if;
 376             end if;
 377          end Bad_Body;
 378       end if;
 379
 380       --  Exit if compilation errors detected
 381
 382       if Compilation_Errors then
 383          Treepr.Tree_Dump;
 384          Sem_Ch13.Validate_Unchecked_Conversions;
 385          Errout.Finalize;
 386          Namet.Finalize;
 387
 388          --  Generate ALI file if specially requested
 389
 390          if Opt.Force_ALI_Tree_File then
 391             Write_ALI (Object => False);
 392             Tree_Gen;
 393          end if;
 394
 395          Exit_Program (E_Errors);
 396       end if;
 397
 398       --  Set Generate_Code on main unit and its spec. We do this even if are
 399       --  not generating code, since Lib-Writ uses this to determine which
 400       --  units get written in the ali file.
 401
 402       Set_Generate_Code (Main_Unit);
 403
 404       --  If we have a corresponding spec, then we need object
 405       --  code for the spec unit as well
 406
 407       if Nkind (Unit (Main_Unit_Node)) in N_Unit_Body
 408         and then not Acts_As_Spec (Main_Unit_Node)
 409       then
 410          Set_Generate_Code
 411            (Get_Cunit_Unit_Number (Library_Unit (Main_Unit_Node)));
 412       end if;
 413
 414       --  Case of no code required to be generated, exit indicating no error
 415
 416       if Original_Operating_Mode = Check_Syntax then
 417          Treepr.Tree_Dump;
 418          Errout.Finalize;
 419          Tree_Gen;
 420          Namet.Finalize;
 421
 422          --  Use a goto instead of calling Exit_Program so that finalization
 423          --  occurs normally.
 424
 425          goto End_Of_Program;
 426
 427       elsif Original_Operating_Mode = Check_Semantics then
 428          Back_End_Mode := Declarations_Only;
 429
 430       --  All remaining cases are cases in which the user requested that code
 431       --  be generated (i.e. no -gnatc or -gnats switch was used). Check if
 432       --  we can in fact satisfy this request.
 433
 434       --  Cannot generate code if someone has turned off code generation for
 435       --  any reason at all. We will try to figure out a reason below.
 436
 437       elsif Operating_Mode /= Generate_Code then
 438          Back_End_Mode := Skip;
 439
 440       --  We can generate code for a subprogram body unless there were missing
 441       --  subunits. Note that we always generate code for all generic units (a
 442       --  change from some previous versions of GNAT).
 443
 444       elsif Main_Kind = N_Subprogram_Body
 445         and then not Subunits_Missing
 446       then
 447          Back_End_Mode := Generate_Object;
 448
 449       --  We can generate code for a package body unless there are subunits
 450       --  missing (note that we always generate code for generic units, which
 451       --  is a change from some earlier versions of GNAT).
 452
 453       elsif Main_Kind = N_Package_Body
 454         and then not Subunits_Missing
 455       then
 456          Back_End_Mode := Generate_Object;
 457
 458       --  We can generate code for a package declaration or a subprogram
 459       --  declaration only if it does not required a body.
 460
 461       elsif (Main_Kind = N_Package_Declaration
 462                or else
 463              Main_Kind = N_Subprogram_Declaration)
 464         and then
 465           (not Body_Required (Main_Unit_Node)
 466              or else
 467            Distribution_Stub_Mode = Generate_Caller_Stub_Body)
 468       then
 469          Back_End_Mode := Generate_Object;
 470
 471       --  We can generate code for a generic package declaration of a generic
 472       --  subprogram declaration only if does not require a body.
 473
 474       elsif (Main_Kind = N_Generic_Package_Declaration
 475                or else
 476              Main_Kind = N_Generic_Subprogram_Declaration)
 477         and then not Body_Required (Main_Unit_Node)
 478       then
 479          Back_End_Mode := Generate_Object;
 480
 481       --  Compilation units that are renamings do not require bodies,
 482       --  so we can generate code for them.
 483
 484       elsif Main_Kind = N_Package_Renaming_Declaration
 485         or else Main_Kind = N_Subprogram_Renaming_Declaration
 486       then
 487          Back_End_Mode := Generate_Object;
 488
 489       --  Compilation units that are generic renamings do not require bodies
 490       --  so we can generate code for them.
 491
 492       elsif Main_Kind in N_Generic_Renaming_Declaration then
 493          Back_End_Mode := Generate_Object;
 494
 495       --  In all other cases (specs which have bodies, generics, and bodies
 496       --  where subunits are missing), we cannot generate code and we generate
 497       --  a warning message. Note that generic instantiations are gone at this
 498       --  stage since they have been replaced by their instances.
 499
 500       else
 501          Back_End_Mode := Skip;
 502       end if;
 503
 504       --  At this stage Call_Back_End is set to indicate if the backend should
 505       --  be called to generate code. If it is not set, then code generation
 506       --  has been turned off, even though code was requested by the original
 507       --  command. This is not an error from the user point of view, but it is
 508       --  an error from the point of view of the gcc driver, so we must exit
 509       --  with an error status.
 510
 511       --  We generate an informative message (from the gcc point of view, it
 512       --  is an error message, but from the users point of view this is not an
 513       --  error, just a consequence of compiling something that cannot
 514       --  generate code).
 515
 516       if Back_End_Mode = Skip then
 517          Write_Str ("cannot generate code for ");
 518          Write_Str ("file ");
 519          Write_Name (Unit_File_Name (Main_Unit));
 520
 521          if Subunits_Missing then
 522             Write_Str (" (missing subunits)");
 523             Write_Eol;
 524             Write_Str ("to check parent unit");
 525
 526          elsif Main_Kind = N_Subunit then
 527             Write_Str (" (subunit)");
 528             Write_Eol;
 529             Write_Str ("to check subunit");
 530
 531          elsif Main_Kind = N_Subprogram_Declaration then
 532             Write_Str (" (subprogram spec)");
 533             Write_Eol;
 534             Write_Str ("to check subprogram spec");
 535
 536          --  Generic package body in GNAT implementation mode
 537
 538          elsif Main_Kind = N_Package_Body and then GNAT_Mode then
 539             Write_Str (" (predefined generic)");
 540             Write_Eol;
 541             Write_Str ("to check predefined generic");
 542
 543          --  Only other case is a package spec
 544
 545          else
 546             Write_Str (" (package spec)");
 547             Write_Eol;
 548             Write_Str ("to check package spec");
 549          end if;
 550
 551          Write_Str (" for errors, use ");
 552
 553          if Hostparm.OpenVMS then
 554             Write_Str ("/NOLOAD");
 555          else
 556             Write_Str ("-gnatc");
 557          end if;
 558
 559          Write_Eol;
 560
 561          Sem_Ch13.Validate_Unchecked_Conversions;
 562          Errout.Finalize;
 563          Treepr.Tree_Dump;
 564          Tree_Gen;
 565          Write_ALI (Object => False);
 566          Namet.Finalize;
 567
 568          --  Exit program with error indication, to kill object file
 569
 570          Exit_Program (E_No_Code);
 571       end if;
 572
 573       --  In -gnatc mode, we only do annotation if -gnatt or -gnatR is also
 574       --  set as indicated by Back_Annotate_Rep_Info being set to True.
 575
 576       --  We don't call for annotations on a subunit, because to process those
 577       --  the back-end requires that the parent(s) be properly compiled.
 578
 579       --  Annotation is suppressed for targets where front-end layout is
 580       --  enabled, because the front end determines representations.
 581
 582       --  Annotation is also suppressed in the case of compiling for
 583       --  the Java VM, since representations are largely symbolic there.
 584
 585       if Back_End_Mode = Declarations_Only
 586         and then (not Back_Annotate_Rep_Info
 587                     or else Main_Kind = N_Subunit
 588                     or else Targparm.Frontend_Layout_On_Target
 589                     or else Hostparm.Java_VM)
 590       then
 591          Sem_Ch13.Validate_Unchecked_Conversions;
 592          Errout.Finalize;
 593          Write_ALI (Object => False);
 594          Tree_Dump;
 595          Tree_Gen;
 596          Namet.Finalize;
 597          return;
 598       end if;
 599
 600       --  Ensure that we properly register a dependency on system.ads, since
 601       --  even if we do not semantically depend on this, Targparm has read
 602       --  system parameters from the system.ads file.
 603
 604       Lib.Writ.Ensure_System_Dependency;
 605
 606       --  Add dependencies, if any, on preprocessing data file and on
 607       --  preprocessing definition file(s).
 608
 609       Prepcomp.Add_Dependencies;
 610
 611       --  Back end needs to explicitly unlock tables it needs to touch
 612
 613       Atree.Lock;
 614       Elists.Lock;
 615       Fname.UF.Lock;
 616       Inline.Lock;
 617       Lib.Lock;
 618       Nlists.Lock;
 619       Sem.Lock;
 620       Sinput.Lock;
 621       Namet.Lock;
 622       Stringt.Lock;
 623
 624       --  Here we call the back end to generate the output code
 625
 626       Back_End.Call_Back_End (Back_End_Mode);
 627
 628       --  Once the backend is complete, we unlock the names table. This call
 629       --  allows a few extra entries, needed for example for the file name for
 630       --  the library file output.
 631
 632       Namet.Unlock;
 633
 634       --  Validate unchecked conversions (using the values for size and
 635       --  alignment annotated by the backend where possible).
 636
 637       Sem_Ch13.Validate_Unchecked_Conversions;
 638
 639       --  Now we complete output of errors, rep info and the tree info. These
 640       --  are delayed till now, since it is perfectly possible for gigi to
 641       --  generate errors, modify the tree (in particular by setting flags
 642       --  indicating that elaboration is required, and also to back annotate
 643       --  representation information for List_Rep_Info.
 644
 645       Errout.Finalize;
 646       List_Rep_Info;
 647
 648       --  Only write the library if the backend did not generate any error
 649       --  messages. Otherwise signal errors to the driver program so that
 650       --  there will be no attempt to generate an object file.
 651
 652       if Compilation_Errors then
 653          Treepr.Tree_Dump;
 654          Exit_Program (E_Errors);
 655       end if;
 656
 657       Write_ALI (Object => (Back_End_Mode = Generate_Object));
 658
 659       --  Generate the ASIS tree after writing the ALI file, since in ASIS
 660       --  mode, Write_ALI may in fact result in further tree decoration from
 661       --  the original tree file. Note that we dump the tree just before
 662       --  generating it, so that the dump will exactly reflect what is written
 663       --  out.
 664
 665       Treepr.Tree_Dump;
 666       Tree_Gen;
 667
 668       --  Finalize name table and we are all done
 669
 670       Namet.Finalize;
 671
 672    exception
 673       --  Handle fatal internal compiler errors
 674
 675       when System.Assertions.Assert_Failure =>
 676          Comperr.Compiler_Abort ("Assert_Failure");
 677
 678       when Constraint_Error =>
 679          Comperr.Compiler_Abort ("Constraint_Error");
 680
 681       when Program_Error =>
 682          Comperr.Compiler_Abort ("Program_Error");
 683
 684       when Storage_Error =>
 685
 686          --  Assume this is a bug. If it is real, the message will in any case
 687          --  say Storage_Error, giving a strong hint!
 688
 689          Comperr.Compiler_Abort ("Storage_Error");
 690    end;
 691
 692    <<End_Of_Program>>
 693    null;
 694
 695    --  The outer exception handles an unrecoverable error
 696
 697 exception
 698    when Unrecoverable_Error =>
 699       Errout.Finalize;
 700
 701       Set_Standard_Error;
 702       Write_Str ("compilation abandoned");
 703       Write_Eol;
 704
 705       Set_Standard_Output;
 706       Source_Dump;
 707       Tree_Dump;
 708       Exit_Program (E_Errors);
 709
 710 end Gnat1drv;