gcc/ada/gnat1drv.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             G N A T 1 D R V                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Back_End; use Back_End;
  28 with Comperr;
  29 with Csets;    use Csets;
  30 with Debug;    use Debug;
  31 with Elists;
  32 with Errout;   use Errout;
  33 with Fmap;
  34 with Fname;    use Fname;
  35 with Fname.UF; use Fname.UF;
  36 with Frontend;
  37 with Gnatvsn;  use Gnatvsn;
  38 with Hostparm;
  39 with Inline;
  40 with Lib;      use Lib;
  41 with Lib.Writ; use Lib.Writ;
  42 with Lib.Xref;
  43 with Namet;    use Namet;
  44 with Nlists;
  45 with Opt;      use Opt;
  46 with Osint;    use Osint;
  47 with Output;   use Output;
  48 with Par_SCO;
  49 with Prepcomp;
  50 with Repinfo;  use Repinfo;
  51 with Restrict;
  52 with Rtsfind;
  53 with Sem;
  54 with Sem_Ch8;
  55 with Sem_Ch12;
  56 with Sem_Ch13;
  57 with Sem_Elim;
  58 with Sem_Eval;
  59 with Sem_Type;
  60 with Sinfo;    use Sinfo;
  61 with Sinput.L; use Sinput.L;
  62 with Snames;
  63 with Sprint;   use Sprint;
  64 with Stringt;
  65 with Stylesw;  use Stylesw;
  66 with Targparm; use Targparm;
  67 with Tree_Gen;
  68 with Treepr;   use Treepr;
  69 with Ttypes;
  70 with Types;    use Types;
  71 with Uintp;    use Uintp;
  72 with Uname;    use Uname;
  73 with Urealp;
  74 with Usage;
  75 with Validsw;  use Validsw;
  76
  77 with System.Assertions;
  78
  79 procedure Gnat1drv is
  80    Main_Unit_Node : Node_Id;
  81    --  Compilation unit node for main unit
  82
  83    Main_Kind : Node_Kind;
  84    --  Kind of main compilation unit node
  85
  86    Back_End_Mode : Back_End.Back_End_Mode_Type;
  87    --  Record back end mode
  88
  89    procedure Adjust_Global_Switches;
  90    --  There are various interactions between front end switch settings,
  91    --  including debug switch settings and target dependent parameters.
  92    --  This procedure takes care of properly handling these interactions.
  93    --  We do it after scanning out all the switches, so that we are not
  94    --  depending on the order in which switches appear.
  95
  96    procedure Check_Bad_Body;
  97    --  Called to check if the unit we are compiling has a bad body
  98
  99    procedure Check_Rep_Info;
 100    --  Called when we are not generating code, to check if -gnatR was requested
 101    --  and if so, explain that we will not be honoring the request.
 102
 103    procedure Check_Library_Items;
 104    --  For debugging -- checks the behavior of Walk_Library_Items
 105    pragma Warnings (Off, Check_Library_Items);
 106    --  In case the call below is commented out
 107
 108    ----------------------------
 109    -- Adjust_Global_Switches --
 110    ----------------------------
 111
 112    procedure Adjust_Global_Switches is
 113    begin
 114       --  Debug flag -gnatd.I is a synonym of Generate_SCIL
 115
 116       if Debug_Flag_Dot_II then
 117          Generate_SCIL := True;
 118       end if;
 119
 120       --  Set ASIS mode if -gnatt and -gnatc are set
 121
 122       if Operating_Mode = Check_Semantics and then Tree_Output then
 123          ASIS_Mode := True;
 124
 125          --  Turn off inlining in ASIS mode, since ASIS cannot handle the extra
 126          --  information in the trees caused by inlining being active.
 127
 128          --  More specifically, the tree seems to be malformed from the ASIS
 129          --  point of view if -gnatc and -gnatn appear together???
 130
 131          Inline_Active := False;
 132
 133          --  Turn off SCIL generation in ASIS mode, since SCIL requires front-
 134          --  end expansion.
 135
 136          Generate_SCIL := False;
 137       end if;
 138
 139       --  SCIL mode needs to disable front-end inlining since the generated
 140       --  trees (in particular order and consistency between specs compiled
 141       --  as part of a main unit or as part of a with-clause) are causing
 142       --  troubles.
 143
 144       if Generate_SCIL then
 145          Front_End_Inlining := False;
 146       end if;
 147
 148       --  Tune settings for optimal SCIL generation in CodePeer_Mode
 149
 150       if CodePeer_Mode then
 151
 152          --  Turn off inlining, confuses CodePeer output and gains nothing
 153
 154          Front_End_Inlining := False;
 155          Inline_Active      := False;
 156
 157          --  Turn off ASIS mode: incompatible with front-end expansion.
 158
 159          ASIS_Mode := False;
 160
 161          --  Turn off dynamic elaboration checks: generates inconsitencies in
 162          --  trees between specs compiled as part of a main unit or as part of
 163          --  a with-clause.
 164
 165          Dynamic_Elaboration_Checks := False;
 166
 167          --  Suppress overflow checks since this is handled implicitely by
 168          --  CodePeer. Enable all other language checks.
 169
 170          Suppress_Options       := (Overflow_Check => True, others => False);
 171          Enable_Overflow_Checks := False;
 172
 173          --  Kill debug of generated code, since it messes up sloc values
 174
 175          Debug_Generated_Code := False;
 176
 177          --  Turn cross-referencing on in case it was disabled (by e.g. -gnatD)
 178          --  Do we really need to spend time generating xref in CodePeer
 179          --  mode??? Consider setting Xref_Active to False.
 180
 181          Xref_Active := True;
 182
 183          --  Polling mode forced off, since it generates confusing junk
 184
 185          Polling_Required := False;
 186
 187          --  Set operating mode to Generate_Code to benefit from full
 188          --  front-end expansion (e.g. generics).
 189
 190          Operating_Mode := Generate_Code;
 191
 192          --  We need SCIL generation of course
 193
 194          Generate_SCIL := True;
 195
 196          --  Enable assertions and debug pragmas, since they give CodePeer
 197          --  valuable extra information.
 198
 199          Assertions_Enabled     := True;
 200          Debug_Pragmas_Enabled  := True;
 201
 202          --  Suppress compiler warnings, since what we are interested in here
 203          --  is what CodePeer can find out. Also disable all simple value
 204          --  propagation. This is an optimization which is valuable for code
 205          --  optimization, and also for generation of compiler warnings, but
 206          --  these are being turned off anyway, and CodePeer understands
 207          --  things more clearly if references are not optimized in this way.
 208
 209          Warning_Mode  := Suppress;
 210          Debug_Flag_MM := True;
 211
 212          --  Set normal RM validity checking, and checking of IN OUT parameters
 213          --  (this might give CodePeer more useful checks to analyze, to be
 214          --  confirmed???). All other validity checking is turned off, since
 215          --  this can generate very complex trees that only confuse CodePeer
 216          --  and do not bring enough useful info.
 217
 218          Reset_Validity_Check_Options;
 219          Validity_Check_Default       := True;
 220          Validity_Check_In_Out_Params := True;
 221          Validity_Check_In_Params     := True;
 222
 223          --  Turn off style check options since we are not interested in any
 224          --  front-end warnings when we are getting CodePeer output.
 225
 226          Reset_Style_Check_Options;
 227       end if;
 228
 229       --  Set Configurable_Run_Time mode if system.ads flag set
 230
 231       if Targparm.Configurable_Run_Time_On_Target or Debug_Flag_YY then
 232          Configurable_Run_Time_Mode := True;
 233       end if;
 234
 235       --  Set -gnatR3m mode if debug flag A set
 236
 237       if Debug_Flag_AA then
 238          Back_Annotate_Rep_Info := True;
 239          List_Representation_Info := 1;
 240          List_Representation_Info_Mechanisms := True;
 241       end if;
 242
 243       --  Force Target_Strict_Alignment true if debug flag -gnatd.a is set
 244
 245       if Debug_Flag_Dot_A then
 246          Ttypes.Target_Strict_Alignment := True;
 247       end if;
 248
 249       --  Disable static allocation of dispatch tables if -gnatd.t or if layout
 250       --  is enabled. The front end's layout phase currently treats types that
 251       --  have discriminant-dependent arrays as not being static even when a
 252       --  discriminant constraint on the type is static, and this leads to
 253       --  problems with subtypes of type Ada.Tags.Dispatch_Table_Wrapper. ???
 254
 255       if Debug_Flag_Dot_T or else Frontend_Layout_On_Target then
 256          Static_Dispatch_Tables := False;
 257       end if;
 258
 259       --  Flip endian mode if -gnatd8 set
 260
 261       if Debug_Flag_8 then
 262          Ttypes.Bytes_Big_Endian := not Ttypes.Bytes_Big_Endian;
 263       end if;
 264
 265       --  Deal with forcing OpenVMS switches True if debug flag M is set, but
 266       --  record the setting of Targparm.Open_VMS_On_Target in True_VMS_Target
 267       --  before doing this, so we know if we are in real OpenVMS or not!
 268
 269       Opt.True_VMS_Target := Targparm.OpenVMS_On_Target;
 270
 271       if Debug_Flag_M then
 272          Targparm.OpenVMS_On_Target := True;
 273          Hostparm.OpenVMS := True;
 274       end if;
 275
 276       --  Activate front end layout if debug flag -gnatdF is set
 277
 278       if Debug_Flag_FF then
 279          Targparm.Frontend_Layout_On_Target := True;
 280       end if;
 281
 282       --  Set and check exception mechnism
 283
 284       if Targparm.ZCX_By_Default_On_Target then
 285          if Targparm.GCC_ZCX_Support_On_Target then
 286             Exception_Mechanism := Back_End_Exceptions;
 287          else
 288             Osint.Fail ("Zero Cost Exceptions not supported on this target");
 289          end if;
 290       end if;
 291
 292       --  Set proper status for overflow checks. We turn on overflow checks
 293       --  if -gnatp was not specified, and either -gnato is set or the back
 294       --  end takes care of overflow checks. Otherwise we suppress overflow
 295       --  checks by default (since front end checks are expensive).
 296
 297       if not Opt.Suppress_Checks
 298         and then (Opt.Enable_Overflow_Checks
 299                     or else
 300                       (Targparm.Backend_Divide_Checks_On_Target
 301                         and
 302                        Targparm.Backend_Overflow_Checks_On_Target))
 303       then
 304          Suppress_Options (Overflow_Check) := False;
 305       else
 306          Suppress_Options (Overflow_Check) := True;
 307       end if;
 308    end Adjust_Global_Switches;
 309
 310    --------------------
 311    -- Check_Bad_Body --
 312    --------------------
 313
 314    procedure Check_Bad_Body is
 315       Sname   : Unit_Name_Type;
 316       Src_Ind : Source_File_Index;
 317       Fname   : File_Name_Type;
 318
 319       procedure Bad_Body_Error (Msg : String);
 320       --  Issue message for bad body found
 321
 322       --------------------
 323       -- Bad_Body_Error --
 324       --------------------
 325
 326       procedure Bad_Body_Error (Msg : String) is
 327       begin
 328          Error_Msg_N (Msg, Main_Unit_Node);
 329          Error_Msg_File_1 := Fname;
 330          Error_Msg_N ("remove incorrect body in file{!", Main_Unit_Node);
 331       end Bad_Body_Error;
 332
 333       --  Start of processing for Check_Bad_Body
 334
 335    begin
 336       --  Nothing to do if we are only checking syntax, because we don't know
 337       --  enough to know if we require or forbid a body in this case.
 338
 339       if Operating_Mode = Check_Syntax then
 340          return;
 341       end if;
 342
 343       --  Check for body not allowed
 344
 345       if (Main_Kind = N_Package_Declaration
 346            and then not Body_Required (Main_Unit_Node))
 347         or else (Main_Kind = N_Generic_Package_Declaration
 348                   and then not Body_Required (Main_Unit_Node))
 349         or else Main_Kind = N_Package_Renaming_Declaration
 350         or else Main_Kind = N_Subprogram_Renaming_Declaration
 351         or else Nkind (Original_Node (Unit (Main_Unit_Node)))
 352                          in N_Generic_Instantiation
 353       then
 354          Sname := Unit_Name (Main_Unit);
 355
 356          --  If we do not already have a body name, then get the body name
 357          --  (but how can we have a body name here ???)
 358
 359          if not Is_Body_Name (Sname) then
 360             Sname := Get_Body_Name (Sname);
 361          end if;
 362
 363          Fname := Get_File_Name (Sname, Subunit => False);
 364          Src_Ind := Load_Source_File (Fname);
 365
 366          --  Case where body is present and it is not a subunit. Exclude
 367          --  the subunit case, because it has nothing to do with the
 368          --  package we are compiling. It is illegal for a child unit and a
 369          --  subunit with the same expanded name (RM 10.2(9)) to appear
 370          --  together in a partition, but there is nothing to stop a
 371          --  compilation environment from having both, and the test here
 372          --  simply allows that. If there is an attempt to include both in
 373          --  a partition, this is diagnosed at bind time. In Ada 83 mode
 374          --  this is not a warning case.
 375
 376          --  Note: if weird file names are being used, we can have
 377          --  situation where the file name that supposedly contains body,
 378          --  in fact contains a spec, or we can't tell what it contains.
 379          --  Skip the error message in these cases.
 380
 381          --  Also ignore body that is nothing but pragma No_Body; (that's the
 382          --  whole point of this pragma, to be used this way and to cause the
 383          --  body file to be ignored in this context).
 384
 385          if Src_Ind /= No_Source_File
 386            and then Get_Expected_Unit_Type (Fname) = Expect_Body
 387            and then not Source_File_Is_Subunit (Src_Ind)
 388            and then not Source_File_Is_No_Body (Src_Ind)
 389          then
 390             Errout.Finalize (Last_Call => False);
 391
 392             Error_Msg_Unit_1 := Sname;
 393
 394             --  Ada 83 case of a package body being ignored. This is not an
 395             --  error as far as the Ada 83 RM is concerned, but it is almost
 396             --  certainly not what is wanted so output a warning. Give this
 397             --  message only if there were no errors, since otherwise it may
 398             --  be incorrect (we may have misinterpreted a junk spec as not
 399             --  needing a body when it really does).
 400
 401             if Main_Kind = N_Package_Declaration
 402               and then Ada_Version = Ada_83
 403               and then Operating_Mode = Generate_Code
 404               and then Distribution_Stub_Mode /= Generate_Caller_Stub_Body
 405               and then not Compilation_Errors
 406             then
 407                Error_Msg_N
 408                  ("package $$ does not require a body?", Main_Unit_Node);
 409                Error_Msg_File_1 := Fname;
 410                Error_Msg_N ("body in file{? will be ignored", Main_Unit_Node);
 411
 412                --  Ada 95 cases of a body file present when no body is
 413                --  permitted. This we consider to be an error.
 414
 415             else
 416                --  For generic instantiations, we never allow a body
 417
 418                if Nkind (Original_Node (Unit (Main_Unit_Node)))
 419                in N_Generic_Instantiation
 420                then
 421                   Bad_Body_Error
 422                     ("generic instantiation for $$ does not allow a body");
 423
 424                   --  A library unit that is a renaming never allows a body
 425
 426                elsif Main_Kind in N_Renaming_Declaration then
 427                   Bad_Body_Error
 428                     ("renaming declaration for $$ does not allow a body!");
 429
 430                   --  Remaining cases are packages and generic packages. Here
 431                   --  we only do the test if there are no previous errors,
 432                   --  because if there are errors, they may lead us to
 433                   --  incorrectly believe that a package does not allow a body
 434                   --  when in fact it does.
 435
 436                elsif not Compilation_Errors then
 437                   if Main_Kind = N_Package_Declaration then
 438                      Bad_Body_Error
 439                        ("package $$ does not allow a body!");
 440
 441                   elsif Main_Kind = N_Generic_Package_Declaration then
 442                      Bad_Body_Error
 443                        ("generic package $$ does not allow a body!");
 444                   end if;
 445                end if;
 446
 447             end if;
 448          end if;
 449       end if;
 450    end Check_Bad_Body;
 451
 452    --------------------
 453    -- Check_Rep_Info --
 454    --------------------
 455
 456    procedure Check_Rep_Info is
 457    begin
 458       if List_Representation_Info /= 0
 459         or else List_Representation_Info_Mechanisms
 460       then
 461          Set_Standard_Error;
 462          Write_Eol;
 463          Write_Str
 464            ("cannot generate representation information, no code generated");
 465          Write_Eol;
 466          Write_Eol;
 467          Set_Standard_Output;
 468       end if;
 469    end Check_Rep_Info;
 470
 471    -------------------------
 472    -- Check_Library_Items --
 473    -------------------------
 474
 475    --  Walk_Library_Items has plenty of assertions, so all we need to do is
 476    --  call it, just for these assertions, not actually doing anything else.
 477
 478    procedure Check_Library_Items is
 479
 480       procedure Action (Item : Node_Id);
 481       --  Action passed to Walk_Library_Items to do nothing
 482
 483       ------------
 484       -- Action --
 485       ------------
 486
 487       procedure Action (Item : Node_Id) is
 488       begin
 489          null;
 490       end Action;
 491
 492       procedure Walk is new Sem.Walk_Library_Items (Action);
 493
 494    --  Start of processing for Check_Library_Items
 495
 496    begin
 497       Walk;
 498    end Check_Library_Items;
 499
 500 --  Start of processing for Gnat1drv
 501
 502 begin
 503    --  This inner block is set up to catch assertion errors and constraint
 504    --  errors. Since the code for handling these errors can cause another
 505    --  exception to be raised (namely Unrecoverable_Error), we need two
 506    --  nested blocks, so that the outer one handles unrecoverable error.
 507
 508    begin
 509       --  Initialize all packages. For the most part, these initialization
 510       --  calls can be made in any order. Exceptions are as follows:
 511
 512       --  Lib.Initialize need to be called before Scan_Compiler_Arguments,
 513       --  because it initializes a table filled by Scan_Compiler_Arguments.
 514
 515       Osint.Initialize;
 516       Fmap.Reset_Tables;
 517       Lib.Initialize;
 518       Lib.Xref.Initialize;
 519       Scan_Compiler_Arguments;
 520       Osint.Add_Default_Search_Dirs;
 521
 522       Nlists.Initialize;
 523       Sinput.Initialize;
 524       Sem.Initialize;
 525       Csets.Initialize;
 526       Uintp.Initialize;
 527       Urealp.Initialize;
 528       Errout.Initialize;
 529       Namet.Initialize;
 530       Snames.Initialize;
 531       Stringt.Initialize;
 532       Inline.Initialize;
 533       Par_SCO.Initialize;
 534       Sem_Ch8.Initialize;
 535       Sem_Ch12.Initialize;
 536       Sem_Ch13.Initialize;
 537       Sem_Elim.Initialize;
 538       Sem_Eval.Initialize;
 539       Sem_Type.Init_Interp_Tables;
 540
 541       --  Acquire target parameters from system.ads (source of package System)
 542
 543       declare
 544          use Sinput;
 545
 546          S : Source_File_Index;
 547          N : File_Name_Type;
 548
 549       begin
 550          Name_Buffer (1 .. 10) := "system.ads";
 551          Name_Len := 10;
 552          N := Name_Find;
 553          S := Load_Source_File (N);
 554
 555          if S = No_Source_File then
 556             Write_Line
 557               ("fatal error, run-time library not installed correctly");
 558             Write_Line
 559               ("cannot locate file system.ads");
 560             raise Unrecoverable_Error;
 561
 562          --  Remember source index of system.ads (which was read successfully)
 563
 564          else
 565             System_Source_File_Index := S;
 566          end if;
 567
 568          Targparm.Get_Target_Parameters
 569            (System_Text  => Source_Text  (S),
 570             Source_First => Source_First (S),
 571             Source_Last  => Source_Last  (S));
 572
 573          --  Acquire configuration pragma information from Targparm
 574
 575          Restrict.Restrictions := Targparm.Restrictions_On_Target;
 576       end;
 577
 578       Adjust_Global_Switches;
 579
 580       --  Output copyright notice if full list mode unless we have a list
 581       --  file, in which case we defer this so that it is output in the file
 582
 583       if (Verbose_Mode or else (Full_List and then Full_List_File_Name = null))
 584         and then not Debug_Flag_7
 585       then
 586          Write_Eol;
 587          Write_Str ("GNAT ");
 588          Write_Str (Gnat_Version_String);
 589          Write_Eol;
 590          Write_Str ("Copyright 1992-" &
 591                     Current_Year &
 592                     ", Free Software Foundation, Inc.");
 593          Write_Eol;
 594       end if;
 595
 596       --  Check we do not have more than one source file, this happens only in
 597       --  the case where the driver is called directly, it cannot happen when
 598       --  gnat1 is invoked from gcc in the normal case.
 599
 600       if Osint.Number_Of_Files /= 1 then
 601          Usage;
 602          Write_Eol;
 603          Osint.Fail ("you must provide one source file");
 604
 605       elsif Usage_Requested then
 606          Usage;
 607       end if;
 608
 609       Original_Operating_Mode := Operating_Mode;
 610       Frontend;
 611
 612       --  Exit with errors if the main source could not be parsed
 613
 614       if Sinput.Main_Source_File = No_Source_File then
 615          Errout.Finalize (Last_Call => True);
 616          Errout.Output_Messages;
 617          Exit_Program (E_Errors);
 618       end if;
 619
 620       Main_Unit_Node := Cunit (Main_Unit);
 621       Main_Kind := Nkind (Unit (Main_Unit_Node));
 622       Check_Bad_Body;
 623
 624       --  Exit if compilation errors detected
 625
 626       Errout.Finalize (Last_Call => False);
 627
 628       if Compilation_Errors then
 629          Treepr.Tree_Dump;
 630          Sem_Ch13.Validate_Unchecked_Conversions;
 631          Sem_Ch13.Validate_Address_Clauses;
 632          Errout.Output_Messages;
 633          Namet.Finalize;
 634
 635          --  Generate ALI file if specially requested
 636
 637          if Opt.Force_ALI_Tree_File then
 638             Write_ALI (Object => False);
 639             Tree_Gen;
 640          end if;
 641
 642          Errout.Finalize (Last_Call => True);
 643          Exit_Program (E_Errors);
 644       end if;
 645
 646       --  Set Generate_Code on main unit and its spec. We do this even if are
 647       --  not generating code, since Lib-Writ uses this to determine which
 648       --  units get written in the ali file.
 649
 650       Set_Generate_Code (Main_Unit);
 651
 652       --  If we have a corresponding spec, and it comes from source
 653       --  or it is not a generated spec for a child subprogram body,
 654       --  then we need object code for the spec unit as well.
 655
 656       if Nkind (Unit (Main_Unit_Node)) in N_Unit_Body
 657         and then not Acts_As_Spec (Main_Unit_Node)
 658       then
 659          if Nkind (Unit (Main_Unit_Node)) = N_Subprogram_Body
 660            and then not Comes_From_Source (Library_Unit (Main_Unit_Node))
 661          then
 662             null;
 663          else
 664             Set_Generate_Code
 665               (Get_Cunit_Unit_Number (Library_Unit (Main_Unit_Node)));
 666          end if;
 667       end if;
 668
 669       --  Case of no code required to be generated, exit indicating no error
 670
 671       if Original_Operating_Mode = Check_Syntax then
 672          Treepr.Tree_Dump;
 673          Errout.Finalize (Last_Call => True);
 674          Errout.Output_Messages;
 675          Tree_Gen;
 676          Namet.Finalize;
 677          Check_Rep_Info;
 678
 679          --  Use a goto instead of calling Exit_Program so that finalization
 680          --  occurs normally.
 681
 682          goto End_Of_Program;
 683
 684       elsif Original_Operating_Mode = Check_Semantics then
 685          Back_End_Mode := Declarations_Only;
 686
 687       --  All remaining cases are cases in which the user requested that code
 688       --  be generated (i.e. no -gnatc or -gnats switch was used). Check if
 689       --  we can in fact satisfy this request.
 690
 691       --  Cannot generate code if someone has turned off code generation for
 692       --  any reason at all. We will try to figure out a reason below.
 693
 694       elsif Operating_Mode /= Generate_Code then
 695          Back_End_Mode := Skip;
 696
 697       --  We can generate code for a subprogram body unless there were missing
 698       --  subunits. Note that we always generate code for all generic units (a
 699       --  change from some previous versions of GNAT).
 700
 701       elsif Main_Kind = N_Subprogram_Body
 702         and then not Subunits_Missing
 703       then
 704          Back_End_Mode := Generate_Object;
 705
 706       --  We can generate code for a package body unless there are subunits
 707       --  missing (note that we always generate code for generic units, which
 708       --  is a change from some earlier versions of GNAT).
 709
 710       elsif Main_Kind = N_Package_Body
 711         and then not Subunits_Missing
 712       then
 713          Back_End_Mode := Generate_Object;
 714
 715       --  We can generate code for a package declaration or a subprogram
 716       --  declaration only if it does not required a body.
 717
 718       elsif (Main_Kind = N_Package_Declaration
 719                or else
 720              Main_Kind = N_Subprogram_Declaration)
 721         and then
 722           (not Body_Required (Main_Unit_Node)
 723              or else
 724            Distribution_Stub_Mode = Generate_Caller_Stub_Body)
 725       then
 726          Back_End_Mode := Generate_Object;
 727
 728       --  We can generate code for a generic package declaration of a generic
 729       --  subprogram declaration only if does not require a body.
 730
 731       elsif (Main_Kind = N_Generic_Package_Declaration
 732                or else
 733              Main_Kind = N_Generic_Subprogram_Declaration)
 734         and then not Body_Required (Main_Unit_Node)
 735       then
 736          Back_End_Mode := Generate_Object;
 737
 738       --  Compilation units that are renamings do not require bodies,
 739       --  so we can generate code for them.
 740
 741       elsif Main_Kind = N_Package_Renaming_Declaration
 742         or else Main_Kind = N_Subprogram_Renaming_Declaration
 743       then
 744          Back_End_Mode := Generate_Object;
 745
 746       --  Compilation units that are generic renamings do not require bodies
 747       --  so we can generate code for them.
 748
 749       elsif Main_Kind in N_Generic_Renaming_Declaration then
 750          Back_End_Mode := Generate_Object;
 751
 752       --  In all other cases (specs which have bodies, generics, and bodies
 753       --  where subunits are missing), we cannot generate code and we generate
 754       --  a warning message. Note that generic instantiations are gone at this
 755       --  stage since they have been replaced by their instances.
 756
 757       else
 758          Back_End_Mode := Skip;
 759       end if;
 760
 761       --  At this stage Back_End_Mode is set to indicate if the backend should
 762       --  be called to generate code. If it is Skip, then code generation has
 763       --  been turned off, even though code was requested by the original
 764       --  command. This is not an error from the user point of view, but it is
 765       --  an error from the point of view of the gcc driver, so we must exit
 766       --  with an error status.
 767
 768       --  We generate an informative message (from the gcc point of view, it
 769       --  is an error message, but from the users point of view this is not an
 770       --  error, just a consequence of compiling something that cannot
 771       --  generate code).
 772
 773       if Back_End_Mode = Skip then
 774          Set_Standard_Error;
 775          Write_Str ("cannot generate code for ");
 776          Write_Str ("file ");
 777          Write_Name (Unit_File_Name (Main_Unit));
 778
 779          if Subunits_Missing then
 780             Write_Str (" (missing subunits)");
 781             Write_Eol;
 782             Write_Str ("to check parent unit");
 783
 784          elsif Main_Kind = N_Subunit then
 785             Write_Str (" (subunit)");
 786             Write_Eol;
 787             Write_Str ("to check subunit");
 788
 789          elsif Main_Kind = N_Subprogram_Declaration then
 790             Write_Str (" (subprogram spec)");
 791             Write_Eol;
 792             Write_Str ("to check subprogram spec");
 793
 794          --  Generic package body in GNAT implementation mode
 795
 796          elsif Main_Kind = N_Package_Body and then GNAT_Mode then
 797             Write_Str (" (predefined generic)");
 798             Write_Eol;
 799             Write_Str ("to check predefined generic");
 800
 801          --  Only other case is a package spec
 802
 803          else
 804             Write_Str (" (package spec)");
 805             Write_Eol;
 806             Write_Str ("to check package spec");
 807          end if;
 808
 809          Write_Str (" for errors, use ");
 810
 811          if Hostparm.OpenVMS then
 812             Write_Str ("/NOLOAD");
 813          else
 814             Write_Str ("-gnatc");
 815          end if;
 816
 817          Write_Eol;
 818          Set_Standard_Output;
 819
 820          Sem_Ch13.Validate_Unchecked_Conversions;
 821          Sem_Ch13.Validate_Address_Clauses;
 822          Errout.Finalize (Last_Call => True);
 823          Errout.Output_Messages;
 824          Treepr.Tree_Dump;
 825          Tree_Gen;
 826          Write_ALI (Object => False);
 827          Namet.Finalize;
 828          Check_Rep_Info;
 829
 830          --  Exit program with error indication, to kill object file
 831
 832          Exit_Program (E_No_Code);
 833       end if;
 834
 835       --  In -gnatc mode, we only do annotation if -gnatt or -gnatR is also
 836       --  set as indicated by Back_Annotate_Rep_Info being set to True.
 837
 838       --  We don't call for annotations on a subunit, because to process those
 839       --  the back-end requires that the parent(s) be properly compiled.
 840
 841       --  Annotation is suppressed for targets where front-end layout is
 842       --  enabled, because the front end determines representations.
 843
 844       --  Annotation is also suppressed in the case of compiling for
 845       --  a VM, since representations are largely symbolic there.
 846
 847       if Back_End_Mode = Declarations_Only
 848         and then (not (Back_Annotate_Rep_Info or Generate_SCIL)
 849                    or else Main_Kind = N_Subunit
 850                    or else Targparm.Frontend_Layout_On_Target
 851                    or else Targparm.VM_Target /= No_VM)
 852       then
 853          Sem_Ch13.Validate_Unchecked_Conversions;
 854          Sem_Ch13.Validate_Address_Clauses;
 855          Errout.Finalize (Last_Call => True);
 856          Errout.Output_Messages;
 857          Write_ALI (Object => False);
 858          Tree_Dump;
 859          Tree_Gen;
 860          Namet.Finalize;
 861          Check_Rep_Info;
 862          return;
 863       end if;
 864
 865       --  Ensure that we properly register a dependency on system.ads, since
 866       --  even if we do not semantically depend on this, Targparm has read
 867       --  system parameters from the system.ads file.
 868
 869       Lib.Writ.Ensure_System_Dependency;
 870
 871       --  Add dependencies, if any, on preprocessing data file and on
 872       --  preprocessing definition file(s).
 873
 874       Prepcomp.Add_Dependencies;
 875
 876       --  Back end needs to explicitly unlock tables it needs to touch
 877
 878       Atree.Lock;
 879       Elists.Lock;
 880       Fname.UF.Lock;
 881       Inline.Lock;
 882       Lib.Lock;
 883       Nlists.Lock;
 884       Sem.Lock;
 885       Sinput.Lock;
 886       Namet.Lock;
 887       Stringt.Lock;
 888
 889       --  ???Check_Library_Items under control of a debug flag, because it
 890       --  currently does not work if the -gnatn switch (back end inlining) is
 891       --  used.
 892
 893       if Debug_Flag_Dot_WW then
 894          Check_Library_Items;
 895       end if;
 896
 897       --  Here we call the back end to generate the output code
 898
 899       Generating_Code := True;
 900       Back_End.Call_Back_End (Back_End_Mode);
 901
 902       --  Once the backend is complete, we unlock the names table. This call
 903       --  allows a few extra entries, needed for example for the file name for
 904       --  the library file output.
 905
 906       Namet.Unlock;
 907
 908       --  Validate unchecked conversions (using the values for size and
 909       --  alignment annotated by the backend where possible).
 910
 911       Sem_Ch13.Validate_Unchecked_Conversions;
 912
 913       --  Validate address clauses (again using alignment values annotated
 914       --  by the backend where possible).
 915
 916       Sem_Ch13.Validate_Address_Clauses;
 917
 918       --  Now we complete output of errors, rep info and the tree info. These
 919       --  are delayed till now, since it is perfectly possible for gigi to
 920       --  generate errors, modify the tree (in particular by setting flags
 921       --  indicating that elaboration is required, and also to back annotate
 922       --  representation information for List_Rep_Info.
 923
 924       Errout.Finalize (Last_Call => True);
 925       Errout.Output_Messages;
 926       List_Rep_Info;
 927
 928       --  Only write the library if the backend did not generate any error
 929       --  messages. Otherwise signal errors to the driver program so that
 930       --  there will be no attempt to generate an object file.
 931
 932       if Compilation_Errors then
 933          Treepr.Tree_Dump;
 934          Exit_Program (E_Errors);
 935       end if;
 936
 937       Write_ALI (Object => (Back_End_Mode = Generate_Object));
 938
 939       --  Generate the ASIS tree after writing the ALI file, since in ASIS
 940       --  mode, Write_ALI may in fact result in further tree decoration from
 941       --  the original tree file. Note that we dump the tree just before
 942       --  generating it, so that the dump will exactly reflect what is written
 943       --  out.
 944
 945       Treepr.Tree_Dump;
 946       Tree_Gen;
 947
 948       --  Finalize name table and we are all done
 949
 950       Namet.Finalize;
 951
 952    exception
 953       --  Handle fatal internal compiler errors
 954
 955       when Rtsfind.RE_Not_Available =>
 956          Comperr.Compiler_Abort ("RE_Not_Available");
 957
 958       when System.Assertions.Assert_Failure =>
 959          Comperr.Compiler_Abort ("Assert_Failure");
 960
 961       when Constraint_Error =>
 962          Comperr.Compiler_Abort ("Constraint_Error");
 963
 964       when Program_Error =>
 965          Comperr.Compiler_Abort ("Program_Error");
 966
 967       when Storage_Error =>
 968
 969          --  Assume this is a bug. If it is real, the message will in any case
 970          --  say Storage_Error, giving a strong hint!
 971
 972          Comperr.Compiler_Abort ("Storage_Error");
 973    end;
 974
 975    <<End_Of_Program>>
 976    null;
 977
 978    --  The outer exception handles an unrecoverable error
 979
 980 exception
 981    when Unrecoverable_Error =>
 982       Errout.Finalize (Last_Call => True);
 983       Errout.Output_Messages;
 984
 985       Set_Standard_Error;
 986       Write_Str ("compilation abandoned");
 987       Write_Eol;
 988
 989       Set_Standard_Output;
 990       Source_Dump;
 991       Tree_Dump;
 992       Exit_Program (E_Errors);
 993
 994 end Gnat1drv;