gcc/ada/g-thread.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                         G N A T . T H R E A D S                          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --            Copyright (C) 1998-2000 Ada Core Technologies, Inc.           --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 with Ada.Task_Identification; use Ada.Task_Identification;
  34 with System.Task_Primitives.Operations;
  35 with System.Tasking;
  36 with System.OS_Interface;
  37 with Unchecked_Conversion;
  38
  39 package body GNAT.Threads is
  40
  41    use System;
  42
  43    function To_Addr is new Unchecked_Conversion (Task_Id, Address);
  44    function To_Id   is new Unchecked_Conversion (Address, Task_Id);
  45    function To_Id   is new Unchecked_Conversion (Address, Tasking.Task_ID);
  46
  47    type Code_Proc is access procedure (Id : Address; Parm : Void_Ptr);
  48
  49    task type Thread
  50      (Stsz : Natural;
  51       Prio : Any_Priority;
  52       Parm : Void_Ptr;
  53       Code : Code_Proc)
  54    is
  55       pragma Priority (Prio);
  56       pragma Storage_Size (Stsz);
  57    end Thread;
  58
  59    task body Thread is
  60    begin
  61       Code.all (To_Addr (Current_Task), Parm);
  62    end Thread;
  63
  64    type Tptr is access Thread;
  65
  66    -------------------
  67    -- Create_Thread --
  68    -------------------
  69
  70    function Create_Thread
  71      (Code : Address;
  72       Parm : Void_Ptr;
  73       Size : Natural;
  74       Prio : Integer) return System.Address
  75    is
  76       TP : Tptr;
  77
  78       function To_CP is new Unchecked_Conversion (Address, Code_Proc);
  79
  80    begin
  81       TP := new Thread (Size, Prio, Parm, To_CP (Code));
  82       return To_Addr (TP'Identity);
  83    end Create_Thread;
  84
  85    --------------------
  86    -- Destroy_Thread --
  87    --------------------
  88
  89    procedure Destroy_Thread (Id : Address) is
  90       Tid : Task_Id := To_Id (Id);
  91
  92    begin
  93       Abort_Task (Tid);
  94    end Destroy_Thread;
  95
  96    ----------------
  97    -- Get_Thread --
  98    ----------------
  99
 100    procedure Get_Thread (Id : Address; Thread : Address) is
 101       use System.OS_Interface;
 102
 103       Thr : Thread_Id;
 104       for Thr use at Thread;
 105    begin
 106       Thr := Task_Primitives.Operations.Get_Thread_Id (To_Id (Id));
 107    end Get_Thread;
 108
 109 end GNAT.Threads;