gcc/ada/g-debuti.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                 G N A T . D E B U G _ U T I L I T I E S                  --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --           Copyright (C) 1997-1998 Ada Core Technologies, Inc.            --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System;                  use System;
  35 with System.Storage_Elements; use System.Storage_Elements;
  36
  37 package body GNAT.Debug_Utilities is
  38
  39    --------------------------
  40    -- Image (address case) --
  41    --------------------------
  42
  43    function Image (A : Address) return String is
  44       S : String (1 .. Address_Image_Length);
  45       P : Natural := S'Last - 1;
  46       N : Integer_Address := To_Integer (A);
  47       U : Natural := 0;
  48
  49       H : array (Integer range 0 .. 15) of Character := "0123456789ABCDEF";
  50
  51    begin
  52       S (S'Last) := '#';
  53
  54       while P > 3 loop
  55          if U = 4 then
  56             S (P) := '_';
  57             P := P - 1;
  58             U := 1;
  59
  60          else
  61             U := U + 1;
  62          end if;
  63
  64          S (P) := H (Integer (N mod 16));
  65          P := P - 1;
  66          N := N / 16;
  67       end loop;
  68
  69       S (1 .. 3) := "16#";
  70       return S;
  71    end Image;
  72
  73    -------------------------
  74    -- Image (string case) --
  75    -------------------------
  76
  77    function Image (S : String) return String is
  78       W : String (1 .. 2 * S'Length + 2);
  79       P : Positive := 1;
  80
  81    begin
  82       W (1) := '"';
  83
  84       for J in S'Range loop
  85          if S (J) = '"' then
  86             P := P + 1;
  87             W (P) := '"';
  88          end if;
  89
  90          P := P + 1;
  91          W (P) := S (J);
  92       end loop;
  93
  94       P := P + 1;
  95       W (P) := '"';
  96       return W (1 .. P);
  97    end Image;
  98
  99    -----------
 100    -- Value --
 101    -----------
 102
 103    function Value (S : String) return System.Address is
 104       N : constant Integer_Address := Integer_Address'Value (S);
 105
 106    begin
 107       return To_Address (N);
 108    end Value;
 109
 110 end GNAT.Debug_Utilities;