gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere.
 365
 366       if Ekind_In (Old_S, E_Function, E_Procedure)
 367         and then Nkind (Decl) = N_Subprogram_Declaration
 368       then
 369          Set_Body_To_Inline (Decl, Old_S);
 370       end if;
 371
 372       --  The body generated for this renaming is an internal artifact, and
 373       --  does not  constitute a freeze point for the called entity.
 374
 375       Set_Must_Not_Freeze (Call_Name);
 376
 377       Formal := First_Formal (Defining_Entity (Decl));
 378
 379       if Present (Pref) then
 380          declare
 381             Pref_Type : constant Entity_Id := Etype (Pref);
 382             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 383
 384          begin
 385             --  The controlling formal may be an access parameter, or the
 386             --  actual may be an access value, so adjust accordingly.
 387
 388             if Is_Access_Type (Pref_Type)
 389               and then not Is_Access_Type (Form_Type)
 390             then
 391                Actuals := New_List
 392                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 393
 394             elsif Is_Access_Type (Form_Type)
 395               and then not Is_Access_Type (Pref)
 396             then
 397                Actuals := New_List
 398                  (Make_Attribute_Reference (Loc,
 399                    Attribute_Name => Name_Access,
 400                    Prefix => Relocate_Node (Pref)));
 401             else
 402                Actuals := New_List (Pref);
 403             end if;
 404          end;
 405
 406       elsif Present (Formal) then
 407          Actuals := New_List;
 408
 409       else
 410          Actuals := No_List;
 411       end if;
 412
 413       if Present (Formal) then
 414          while Present (Formal) loop
 415             Append (New_Reference_To (Formal, Loc), Actuals);
 416             Next_Formal (Formal);
 417          end loop;
 418       end if;
 419
 420       --  If the renamed entity is an entry, inherit its profile. For other
 421       --  renamings as bodies, both profiles must be subtype conformant, so it
 422       --  is not necessary to replace the profile given in the declaration.
 423       --  However, default values that are aggregates are rewritten when
 424       --  partially analyzed, so we recover the original aggregate to insure
 425       --  that subsequent conformity checking works. Similarly, if the default
 426       --  expression was constant-folded, recover the original expression.
 427
 428       Formal := First_Formal (Defining_Entity (Decl));
 429
 430       if Present (Formal) then
 431          O_Formal := First_Formal (Old_S);
 432          Param_Spec := First (Parameter_Specifications (Spec));
 433          while Present (Formal) loop
 434             if Is_Entry (Old_S) then
 435                if Nkind (Parameter_Type (Param_Spec)) /=
 436                                                     N_Access_Definition
 437                then
 438                   Set_Etype (Formal, Etype (O_Formal));
 439                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 440                end if;
 441
 442             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 443               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 444                                            Nkind (Default_Value (O_Formal))
 445             then
 446                Set_Expression (Param_Spec,
 447                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 448             end if;
 449
 450             Next_Formal (Formal);
 451             Next_Formal (O_Formal);
 452             Next (Param_Spec);
 453          end loop;
 454       end if;
 455
 456       --  If the renamed entity is a function, the generated body contains a
 457       --  return statement. Otherwise, build a procedure call. If the entity is
 458       --  an entry, subsequent analysis of the call will transform it into the
 459       --  proper entry or protected operation call. If the renamed entity is
 460       --  a character literal, return it directly.
 461
 462       if Ekind (Old_S) = E_Function
 463         or else Ekind (Old_S) = E_Operator
 464         or else (Ekind (Old_S) = E_Subprogram_Type
 465                   and then Etype (Old_S) /= Standard_Void_Type)
 466       then
 467          Call_Node :=
 468            Make_Simple_Return_Statement (Loc,
 469               Expression =>
 470                 Make_Function_Call (Loc,
 471                   Name => Call_Name,
 472                   Parameter_Associations => Actuals));
 473
 474       elsif Ekind (Old_S) = E_Enumeration_Literal then
 475          Call_Node :=
 476            Make_Simple_Return_Statement (Loc,
 477               Expression => New_Occurrence_Of (Old_S, Loc));
 478
 479       elsif Nkind (Nam) = N_Character_Literal then
 480          Call_Node :=
 481            Make_Simple_Return_Statement (Loc,
 482              Expression => Call_Name);
 483
 484       else
 485          Call_Node :=
 486            Make_Procedure_Call_Statement (Loc,
 487              Name => Call_Name,
 488              Parameter_Associations => Actuals);
 489       end if;
 490
 491       --  Create entities for subprogram body and formals
 492
 493       Set_Defining_Unit_Name (Spec,
 494         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 495
 496       Param_Spec := First (Parameter_Specifications (Spec));
 497       while Present (Param_Spec) loop
 498          Set_Defining_Identifier (Param_Spec,
 499            Make_Defining_Identifier (Loc,
 500              Chars => Chars (Defining_Identifier (Param_Spec))));
 501          Next (Param_Spec);
 502       end loop;
 503
 504       Body_Node :=
 505         Make_Subprogram_Body (Loc,
 506           Specification => Spec,
 507           Declarations => New_List,
 508           Handled_Statement_Sequence =>
 509             Make_Handled_Sequence_Of_Statements (Loc,
 510               Statements => New_List (Call_Node)));
 511
 512       if Nkind (Decl) /= N_Subprogram_Declaration then
 513          Rewrite (N,
 514            Make_Subprogram_Declaration (Loc,
 515              Specification => Specification (N)));
 516       end if;
 517
 518       --  Link the body to the entity whose declaration it completes. If
 519       --  the body is analyzed when the renamed entity is frozen, it may
 520       --  be necessary to restore the proper scope (see package Exp_Ch13).
 521
 522       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 523         and then Present (Corresponding_Spec (N))
 524       then
 525          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 526       else
 527          Set_Corresponding_Spec (Body_Node, New_S);
 528       end if;
 529
 530       return Body_Node;
 531    end Build_Renamed_Body;
 532
 533    --------------------------
 534    -- Check_Address_Clause --
 535    --------------------------
 536
 537    procedure Check_Address_Clause (E : Entity_Id) is
 538       Addr : constant Node_Id   := Address_Clause (E);
 539       Expr : Node_Id;
 540       Decl : constant Node_Id   := Declaration_Node (E);
 541       Typ  : constant Entity_Id := Etype (E);
 542
 543    begin
 544       if Present (Addr) then
 545          Expr := Expression (Addr);
 546
 547          if Needs_Constant_Address (Decl, Typ) then
 548             Check_Constant_Address_Clause (Expr, E);
 549
 550             --  Has_Delayed_Freeze was set on E when the address clause was
 551             --  analyzed. Reset the flag now unless freeze actions were
 552             --  attached to it in the mean time.
 553
 554             if No (Freeze_Node (E)) then
 555                Set_Has_Delayed_Freeze (E, False);
 556             end if;
 557          end if;
 558
 559          --  If Rep_Clauses are to be ignored, remove address clause from
 560          --  list attached to entity, because it may be illegal for gigi,
 561          --  for example by breaking order of elaboration..
 562
 563          if Ignore_Rep_Clauses then
 564             declare
 565                Rep : Node_Id;
 566
 567             begin
 568                Rep := First_Rep_Item (E);
 569
 570                if Rep = Addr then
 571                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 572
 573                else
 574                   while Present (Rep)
 575                     and then Next_Rep_Item (Rep) /= Addr
 576                   loop
 577                      Rep := Next_Rep_Item (Rep);
 578                   end loop;
 579                end if;
 580
 581                if Present (Rep) then
 582                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 583                end if;
 584             end;
 585
 586             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 587
 588          elsif not Error_Posted (Expr)
 589            and then not Needs_Finalization (Typ)
 590          then
 591             Warn_Overlay (Expr, Typ, Name (Addr));
 592          end if;
 593       end if;
 594    end Check_Address_Clause;
 595
 596    -----------------------------
 597    -- Check_Compile_Time_Size --
 598    -----------------------------
 599
 600    procedure Check_Compile_Time_Size (T : Entity_Id) is
 601
 602       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 603       --  Sets the compile time known size (32 bits or less) in the Esize
 604       --  field, of T checking for a size clause that was given which attempts
 605       --  to give a smaller size, and also checking for an alignment clause.
 606
 607       function Size_Known (T : Entity_Id) return Boolean;
 608       --  Recursive function that does all the work
 609
 610       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 611       --  If T is a constrained subtype, its size is not known if any of its
 612       --  discriminant constraints is not static and it is not a null record.
 613       --  The test is conservative and doesn't check that the components are
 614       --  in fact constrained by non-static discriminant values. Could be made
 615       --  more precise ???
 616
 617       --------------------
 618       -- Set_Small_Size --
 619       --------------------
 620
 621       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 622       begin
 623          if S > 32 then
 624             return;
 625
 626          --  Don't bother if alignment clause with a value other than 1 is
 627          --  present, because size may be padded up to meet back end alignment
 628          --  requirements, and only the back end knows the rules!
 629
 630          elsif Known_Alignment (T) and then Alignment (T) /= 1 then
 631             return;
 632
 633          --  Check for bad size clause given
 634
 635          elsif Has_Size_Clause (T) then
 636             if RM_Size (T) < S then
 637                Error_Msg_Uint_1 := S;
 638                Error_Msg_NE
 639                  ("size for& too small, minimum allowed is ^",
 640                   Size_Clause (T), T);
 641
 642             elsif Unknown_Esize (T) then
 643                Set_Esize (T, S);
 644             end if;
 645
 646          --  Set sizes if not set already
 647
 648          else
 649             if Unknown_Esize (T) then
 650                Set_Esize (T, S);
 651             end if;
 652
 653             if Unknown_RM_Size (T) then
 654                Set_RM_Size (T, S);
 655             end if;
 656          end if;
 657       end Set_Small_Size;
 658
 659       ----------------
 660       -- Size_Known --
 661       ----------------
 662
 663       function Size_Known (T : Entity_Id) return Boolean is
 664          Index : Entity_Id;
 665          Comp  : Entity_Id;
 666          Ctyp  : Entity_Id;
 667          Low   : Node_Id;
 668          High  : Node_Id;
 669
 670       begin
 671          if Size_Known_At_Compile_Time (T) then
 672             return True;
 673
 674          --  Always True for scalar types. This is true even for generic formal
 675          --  scalar types. We used to return False in the latter case, but the
 676          --  size is known at compile time, even in the template, we just do
 677          --  not know the exact size but that's not the point of this routine.
 678
 679          elsif Is_Scalar_Type (T)
 680            or else Is_Task_Type (T)
 681          then
 682             return True;
 683
 684          --  Array types
 685
 686          elsif Is_Array_Type (T) then
 687
 688             --  String literals always have known size, and we can set it
 689
 690             if Ekind (T) = E_String_Literal_Subtype then
 691                Set_Small_Size (T, Component_Size (T)
 692                                * String_Literal_Length (T));
 693                return True;
 694
 695             --  Unconstrained types never have known at compile time size
 696
 697             elsif not Is_Constrained (T) then
 698                return False;
 699
 700             --  Don't do any recursion on type with error posted, since we may
 701             --  have a malformed type that leads us into a loop.
 702
 703             elsif Error_Posted (T) then
 704                return False;
 705
 706             --  Otherwise if component size unknown, then array size unknown
 707
 708             elsif not Size_Known (Component_Type (T)) then
 709                return False;
 710             end if;
 711
 712             --  Check for all indexes static, and also compute possible size
 713             --  (in case it is less than 32 and may be packable).
 714
 715             declare
 716                Esiz : Uint := Component_Size (T);
 717                Dim  : Uint;
 718
 719             begin
 720                Index := First_Index (T);
 721                while Present (Index) loop
 722                   if Nkind (Index) = N_Range then
 723                      Get_Index_Bounds (Index, Low, High);
 724
 725                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 726                      return False;
 727
 728                   else
 729                      Low  := Type_Low_Bound (Etype (Index));
 730                      High := Type_High_Bound (Etype (Index));
 731                   end if;
 732
 733                   if not Compile_Time_Known_Value (Low)
 734                     or else not Compile_Time_Known_Value (High)
 735                     or else Etype (Index) = Any_Type
 736                   then
 737                      return False;
 738
 739                   else
 740                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 741
 742                      if Dim >= 0 then
 743                         Esiz := Esiz * Dim;
 744                      else
 745                         Esiz := Uint_0;
 746                      end if;
 747                   end if;
 748
 749                   Next_Index (Index);
 750                end loop;
 751
 752                Set_Small_Size (T, Esiz);
 753                return True;
 754             end;
 755
 756          --  Access types always have known at compile time sizes
 757
 758          elsif Is_Access_Type (T) then
 759             return True;
 760
 761          --  For non-generic private types, go to underlying type if present
 762
 763          elsif Is_Private_Type (T)
 764            and then not Is_Generic_Type (T)
 765            and then Present (Underlying_Type (T))
 766          then
 767             --  Don't do any recursion on type with error posted, since we may
 768             --  have a malformed type that leads us into a loop.
 769
 770             if Error_Posted (T) then
 771                return False;
 772             else
 773                return Size_Known (Underlying_Type (T));
 774             end if;
 775
 776          --  Record types
 777
 778          elsif Is_Record_Type (T) then
 779
 780             --  A class-wide type is never considered to have a known size
 781
 782             if Is_Class_Wide_Type (T) then
 783                return False;
 784
 785             --  A subtype of a variant record must not have non-static
 786             --  discriminated components.
 787
 788             elsif T /= Base_Type (T)
 789               and then not Static_Discriminated_Components (T)
 790             then
 791                return False;
 792
 793             --  Don't do any recursion on type with error posted, since we may
 794             --  have a malformed type that leads us into a loop.
 795
 796             elsif Error_Posted (T) then
 797                return False;
 798             end if;
 799
 800             --  Now look at the components of the record
 801
 802             declare
 803                --  The following two variables are used to keep track of the
 804                --  size of packed records if we can tell the size of the packed
 805                --  record in the front end. Packed_Size_Known is True if so far
 806                --  we can figure out the size. It is initialized to True for a
 807                --  packed record, unless the record has discriminants. The
 808                --  reason we eliminate the discriminated case is that we don't
 809                --  know the way the back end lays out discriminated packed
 810                --  records. If Packed_Size_Known is True, then Packed_Size is
 811                --  the size in bits so far.
 812
 813                Packed_Size_Known : Boolean :=
 814                                      Is_Packed (T)
 815                                        and then not Has_Discriminants (T);
 816
 817                Packed_Size : Uint := Uint_0;
 818
 819             begin
 820                --  Test for variant part present
 821
 822                if Has_Discriminants (T)
 823                  and then Present (Parent (T))
 824                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 825                  and then Nkind (Type_Definition (Parent (T))) =
 826                                                N_Record_Definition
 827                  and then not Null_Present (Type_Definition (Parent (T)))
 828                  and then Present (Variant_Part
 829                             (Component_List (Type_Definition (Parent (T)))))
 830                then
 831                   --  If variant part is present, and type is unconstrained,
 832                   --  then we must have defaulted discriminants, or a size
 833                   --  clause must be present for the type, or else the size
 834                   --  is definitely not known at compile time.
 835
 836                   if not Is_Constrained (T)
 837                     and then
 838                       No (Discriminant_Default_Value (First_Discriminant (T)))
 839                     and then Unknown_Esize (T)
 840                   then
 841                      return False;
 842                   end if;
 843                end if;
 844
 845                --  Loop through components
 846
 847                Comp := First_Component_Or_Discriminant (T);
 848                while Present (Comp) loop
 849                   Ctyp := Etype (Comp);
 850
 851                   --  We do not know the packed size if there is a component
 852                   --  clause present (we possibly could, but this would only
 853                   --  help in the case of a record with partial rep clauses.
 854                   --  That's because in the case of full rep clauses, the
 855                   --  size gets figured out anyway by a different circuit).
 856
 857                   if Present (Component_Clause (Comp)) then
 858                      Packed_Size_Known := False;
 859                   end if;
 860
 861                   --  We need to identify a component that is an array where
 862                   --  the index type is an enumeration type with non-standard
 863                   --  representation, and some bound of the type depends on a
 864                   --  discriminant.
 865
 866                   --  This is because gigi computes the size by doing a
 867                   --  substitution of the appropriate discriminant value in
 868                   --  the size expression for the base type, and gigi is not
 869                   --  clever enough to evaluate the resulting expression (which
 870                   --  involves a call to rep_to_pos) at compile time.
 871
 872                   --  It would be nice if gigi would either recognize that
 873                   --  this expression can be computed at compile time, or
 874                   --  alternatively figured out the size from the subtype
 875                   --  directly, where all the information is at hand ???
 876
 877                   if Is_Array_Type (Etype (Comp))
 878                     and then Present (Packed_Array_Type (Etype (Comp)))
 879                   then
 880                      declare
 881                         Ocomp  : constant Entity_Id :=
 882                                    Original_Record_Component (Comp);
 883                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 884                         Ind    : Node_Id;
 885                         Indtyp : Entity_Id;
 886                         Lo, Hi : Node_Id;
 887
 888                      begin
 889                         Ind := First_Index (OCtyp);
 890                         while Present (Ind) loop
 891                            Indtyp := Etype (Ind);
 892
 893                            if Is_Enumeration_Type (Indtyp)
 894                              and then Has_Non_Standard_Rep (Indtyp)
 895                            then
 896                               Lo := Type_Low_Bound  (Indtyp);
 897                               Hi := Type_High_Bound (Indtyp);
 898
 899                               if Is_Entity_Name (Lo)
 900                                 and then Ekind (Entity (Lo)) = E_Discriminant
 901                               then
 902                                  return False;
 903
 904                               elsif Is_Entity_Name (Hi)
 905                                 and then Ekind (Entity (Hi)) = E_Discriminant
 906                               then
 907                                  return False;
 908                               end if;
 909                            end if;
 910
 911                            Next_Index (Ind);
 912                         end loop;
 913                      end;
 914                   end if;
 915
 916                   --  Clearly size of record is not known if the size of one of
 917                   --  the components is not known.
 918
 919                   if not Size_Known (Ctyp) then
 920                      return False;
 921                   end if;
 922
 923                   --  Accumulate packed size if possible
 924
 925                   if Packed_Size_Known then
 926
 927                      --  We can only deal with elementary types, since for
 928                      --  non-elementary components, alignment enters into the
 929                      --  picture, and we don't know enough to handle proper
 930                      --  alignment in this context. Packed arrays count as
 931                      --  elementary if the representation is a modular type.
 932
 933                      if Is_Elementary_Type (Ctyp)
 934                        or else (Is_Array_Type (Ctyp)
 935                                  and then Present (Packed_Array_Type (Ctyp))
 936                                  and then Is_Modular_Integer_Type
 937                                             (Packed_Array_Type (Ctyp)))
 938                      then
 939                         --  If RM_Size is known and static, then we can keep
 940                         --  accumulating the packed size.
 941
 942                         if Known_Static_RM_Size (Ctyp) then
 943
 944                            --  A little glitch, to be removed sometime ???
 945                            --  gigi does not understand zero sizes yet.
 946
 947                            if RM_Size (Ctyp) = Uint_0 then
 948                               Packed_Size_Known := False;
 949
 950                            --  Normal case where we can keep accumulating the
 951                            --  packed array size.
 952
 953                            else
 954                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 955                            end if;
 956
 957                         --  If we have a field whose RM_Size is not known then
 958                         --  we can't figure out the packed size here.
 959
 960                         else
 961                            Packed_Size_Known := False;
 962                         end if;
 963
 964                      --  If we have a non-elementary type we can't figure out
 965                      --  the packed array size (alignment issues).
 966
 967                      else
 968                         Packed_Size_Known := False;
 969                      end if;
 970                   end if;
 971
 972                   Next_Component_Or_Discriminant (Comp);
 973                end loop;
 974
 975                if Packed_Size_Known then
 976                   Set_Small_Size (T, Packed_Size);
 977                end if;
 978
 979                return True;
 980             end;
 981
 982          --  All other cases, size not known at compile time
 983
 984          else
 985             return False;
 986          end if;
 987       end Size_Known;
 988
 989       -------------------------------------
 990       -- Static_Discriminated_Components --
 991       -------------------------------------
 992
 993       function Static_Discriminated_Components
 994         (T : Entity_Id) return Boolean
 995       is
 996          Constraint : Elmt_Id;
 997
 998       begin
 999          if Has_Discriminants (T)
1000            and then Present (Discriminant_Constraint (T))
1001            and then Present (First_Component (T))
1002          then
1003             Constraint := First_Elmt (Discriminant_Constraint (T));
1004             while Present (Constraint) loop
1005                if not Compile_Time_Known_Value (Node (Constraint)) then
1006                   return False;
1007                end if;
1008
1009                Next_Elmt (Constraint);
1010             end loop;
1011          end if;
1012
1013          return True;
1014       end Static_Discriminated_Components;
1015
1016    --  Start of processing for Check_Compile_Time_Size
1017
1018    begin
1019       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1020    end Check_Compile_Time_Size;
1021
1022    -----------------------------
1023    -- Check_Debug_Info_Needed --
1024    -----------------------------
1025
1026    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1027    begin
1028       if Debug_Info_Off (T) then
1029          return;
1030
1031       elsif Comes_From_Source (T)
1032         or else Debug_Generated_Code
1033         or else Debug_Flag_VV
1034         or else Needs_Debug_Info (T)
1035       then
1036          Set_Debug_Info_Needed (T);
1037       end if;
1038    end Check_Debug_Info_Needed;
1039
1040    ----------------------------
1041    -- Check_Strict_Alignment --
1042    ----------------------------
1043
1044    procedure Check_Strict_Alignment (E : Entity_Id) is
1045       Comp  : Entity_Id;
1046
1047    begin
1048       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1049          Set_Strict_Alignment (E);
1050
1051       elsif Is_Array_Type (E) then
1052          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1053
1054       elsif Is_Record_Type (E) then
1055          if Is_Limited_Record (E) then
1056             Set_Strict_Alignment (E);
1057             return;
1058          end if;
1059
1060          Comp := First_Component (E);
1061          while Present (Comp) loop
1062             if not Is_Type (Comp)
1063               and then (Strict_Alignment (Etype (Comp))
1064                          or else Is_Aliased (Comp))
1065             then
1066                Set_Strict_Alignment (E);
1067                return;
1068             end if;
1069
1070             Next_Component (Comp);
1071          end loop;
1072       end if;
1073    end Check_Strict_Alignment;
1074
1075    -------------------------
1076    -- Check_Unsigned_Type --
1077    -------------------------
1078
1079    procedure Check_Unsigned_Type (E : Entity_Id) is
1080       Ancestor : Entity_Id;
1081       Lo_Bound : Node_Id;
1082       Btyp     : Entity_Id;
1083
1084    begin
1085       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1086          return;
1087       end if;
1088
1089       --  Do not attempt to analyze case where range was in error
1090
1091       if No (Scalar_Range (E))
1092         or else Error_Posted (Scalar_Range (E))
1093       then
1094          return;
1095       end if;
1096
1097       --  The situation that is non trivial is something like
1098
1099       --     subtype x1 is integer range -10 .. +10;
1100       --     subtype x2 is x1 range 0 .. V1;
1101       --     subtype x3 is x2 range V2 .. V3;
1102       --     subtype x4 is x3 range V4 .. V5;
1103
1104       --  where Vn are variables. Here the base type is signed, but we still
1105       --  know that x4 is unsigned because of the lower bound of x2.
1106
1107       --  The only way to deal with this is to look up the ancestor chain
1108
1109       Ancestor := E;
1110       loop
1111          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1112             return;
1113          end if;
1114
1115          Lo_Bound := Type_Low_Bound (Ancestor);
1116
1117          if Compile_Time_Known_Value (Lo_Bound) then
1118
1119             if Expr_Rep_Value (Lo_Bound) >= 0 then
1120                Set_Is_Unsigned_Type (E, True);
1121             end if;
1122
1123             return;
1124
1125          else
1126             Ancestor := Ancestor_Subtype (Ancestor);
1127
1128             --  If no ancestor had a static lower bound, go to base type
1129
1130             if No (Ancestor) then
1131
1132                --  Note: the reason we still check for a compile time known
1133                --  value for the base type is that at least in the case of
1134                --  generic formals, we can have bounds that fail this test,
1135                --  and there may be other cases in error situations.
1136
1137                Btyp := Base_Type (E);
1138
1139                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1140                   return;
1141                end if;
1142
1143                Lo_Bound := Type_Low_Bound (Base_Type (E));
1144
1145                if Compile_Time_Known_Value (Lo_Bound)
1146                  and then Expr_Rep_Value (Lo_Bound) >= 0
1147                then
1148                   Set_Is_Unsigned_Type (E, True);
1149                end if;
1150
1151                return;
1152             end if;
1153          end if;
1154       end loop;
1155    end Check_Unsigned_Type;
1156
1157    -------------------------
1158    -- Is_Atomic_Aggregate --
1159    -------------------------
1160
1161    function  Is_Atomic_Aggregate
1162      (E   : Entity_Id;
1163       Typ : Entity_Id) return Boolean
1164    is
1165       Loc   : constant Source_Ptr := Sloc (E);
1166       New_N : Node_Id;
1167       Par   : Node_Id;
1168       Temp  : Entity_Id;
1169
1170    begin
1171       Par := Parent (E);
1172
1173       --  Array may be qualified, so find outer context
1174
1175       if Nkind (Par) = N_Qualified_Expression then
1176          Par := Parent (Par);
1177       end if;
1178
1179       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1180         and then Comes_From_Source (Par)
1181       then
1182          Temp := Make_Temporary (Loc, 'T', E);
1183          New_N :=
1184            Make_Object_Declaration (Loc,
1185              Defining_Identifier => Temp,
1186              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1187              Expression          => Relocate_Node (E));
1188          Insert_Before (Par, New_N);
1189          Analyze (New_N);
1190
1191          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1192          return True;
1193
1194       else
1195          return False;
1196       end if;
1197    end Is_Atomic_Aggregate;
1198
1199    ----------------
1200    -- Freeze_All --
1201    ----------------
1202
1203    --  Note: the easy coding for this procedure would be to just build a
1204    --  single list of freeze nodes and then insert them and analyze them
1205    --  all at once. This won't work, because the analysis of earlier freeze
1206    --  nodes may recursively freeze types which would otherwise appear later
1207    --  on in the freeze list. So we must analyze and expand the freeze nodes
1208    --  as they are generated.
1209
1210    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1211       E     : Entity_Id;
1212       Decl  : Node_Id;
1213
1214       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1215       --  This is the internal recursive routine that does freezing of entities
1216       --  (but NOT the analysis of default expressions, which should not be
1217       --  recursive, we don't want to analyze those till we are sure that ALL
1218       --  the types are frozen).
1219
1220       --------------------
1221       -- Freeze_All_Ent --
1222       --------------------
1223
1224       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1225          E     : Entity_Id;
1226          Flist : List_Id;
1227          Lastn : Node_Id;
1228
1229          procedure Process_Flist;
1230          --  If freeze nodes are present, insert and analyze, and reset cursor
1231          --  for next insertion.
1232
1233          -------------------
1234          -- Process_Flist --
1235          -------------------
1236
1237          procedure Process_Flist is
1238          begin
1239             if Is_Non_Empty_List (Flist) then
1240                Lastn := Next (After);
1241                Insert_List_After_And_Analyze (After, Flist);
1242
1243                if Present (Lastn) then
1244                   After := Prev (Lastn);
1245                else
1246                   After := Last (List_Containing (After));
1247                end if;
1248             end if;
1249          end Process_Flist;
1250
1251       --  Start or processing for Freeze_All_Ent
1252
1253       begin
1254          E := From;
1255          while Present (E) loop
1256
1257             --  If the entity is an inner package which is not a package
1258             --  renaming, then its entities must be frozen at this point. Note
1259             --  that such entities do NOT get frozen at the end of the nested
1260             --  package itself (only library packages freeze).
1261
1262             --  Same is true for task declarations, where anonymous records
1263             --  created for entry parameters must be frozen.
1264
1265             if Ekind (E) = E_Package
1266               and then No (Renamed_Object (E))
1267               and then not Is_Child_Unit (E)
1268               and then not Is_Frozen (E)
1269             then
1270                Push_Scope (E);
1271                Install_Visible_Declarations (E);
1272                Install_Private_Declarations (E);
1273
1274                Freeze_All (First_Entity (E), After);
1275
1276                End_Package_Scope (E);
1277
1278             elsif Ekind (E) in Task_Kind
1279               and then
1280                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1281                    or else
1282                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1283             then
1284                Push_Scope (E);
1285                Freeze_All (First_Entity (E), After);
1286                End_Scope;
1287
1288             --  For a derived tagged type, we must ensure that all the
1289             --  primitive operations of the parent have been frozen, so that
1290             --  their addresses will be in the parent's dispatch table at the
1291             --  point it is inherited.
1292
1293             elsif Ekind (E) = E_Record_Type
1294               and then Is_Tagged_Type (E)
1295               and then Is_Tagged_Type (Etype (E))
1296               and then Is_Derived_Type (E)
1297             then
1298                declare
1299                   Prim_List : constant Elist_Id :=
1300                                Primitive_Operations (Etype (E));
1301
1302                   Prim : Elmt_Id;
1303                   Subp : Entity_Id;
1304
1305                begin
1306                   Prim  := First_Elmt (Prim_List);
1307                   while Present (Prim) loop
1308                      Subp := Node (Prim);
1309
1310                      if Comes_From_Source (Subp)
1311                        and then not Is_Frozen (Subp)
1312                      then
1313                         Flist := Freeze_Entity (Subp, After);
1314                         Process_Flist;
1315                      end if;
1316
1317                      Next_Elmt (Prim);
1318                   end loop;
1319                end;
1320             end if;
1321
1322             if not Is_Frozen (E) then
1323                Flist := Freeze_Entity (E, After);
1324                Process_Flist;
1325
1326             --  If already frozen, and there are delayed aspects, this is where
1327             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1328             --  for a description of how we handle aspect visibility).
1329
1330             elsif Has_Delayed_Aspects (E) then
1331                declare
1332                   Ritem : Node_Id;
1333
1334                begin
1335                   Ritem := First_Rep_Item (E);
1336                   while Present (Ritem) loop
1337                      if Nkind (Ritem) = N_Aspect_Specification
1338                        and then Entity (Ritem) = E
1339                        and then Is_Delayed_Aspect (Ritem)
1340                      then
1341                         Check_Aspect_At_End_Of_Declarations (Ritem);
1342                      end if;
1343
1344                      Ritem := Next_Rep_Item (Ritem);
1345                   end loop;
1346                end;
1347             end if;
1348
1349             --  If an incomplete type is still not frozen, this may be a
1350             --  premature freezing because of a body declaration that follows.
1351             --  Indicate where the freezing took place.
1352
1353             --  If the freezing is caused by the end of the current declarative
1354             --  part, it is a Taft Amendment type, and there is no error.
1355
1356             if not Is_Frozen (E)
1357               and then Ekind (E) = E_Incomplete_Type
1358             then
1359                declare
1360                   Bod : constant Node_Id := Next (After);
1361
1362                begin
1363                   if (Nkind_In (Bod, N_Subprogram_Body,
1364                                      N_Entry_Body,
1365                                      N_Package_Body,
1366                                      N_Protected_Body,
1367                                      N_Task_Body)
1368                         or else Nkind (Bod) in N_Body_Stub)
1369                      and then
1370                        List_Containing (After) = List_Containing (Parent (E))
1371                   then
1372                      Error_Msg_Sloc := Sloc (Next (After));
1373                      Error_Msg_NE
1374                        ("type& is frozen# before its full declaration",
1375                          Parent (E), E);
1376                   end if;
1377                end;
1378             end if;
1379
1380             Next_Entity (E);
1381          end loop;
1382       end Freeze_All_Ent;
1383
1384    --  Start of processing for Freeze_All
1385
1386    begin
1387       Freeze_All_Ent (From, After);
1388
1389       --  Now that all types are frozen, we can deal with default expressions
1390       --  that require us to build a default expression functions. This is the
1391       --  point at which such functions are constructed (after all types that
1392       --  might be used in such expressions have been frozen).
1393
1394       --  For subprograms that are renaming_as_body, we create the wrapper
1395       --  bodies as needed.
1396
1397       --  We also add finalization chains to access types whose designated
1398       --  types are controlled. This is normally done when freezing the type,
1399       --  but this misses recursive type definitions where the later members
1400       --  of the recursion introduce controlled components.
1401
1402       --  Loop through entities
1403
1404       E := From;
1405       while Present (E) loop
1406          if Is_Subprogram (E) then
1407
1408             if not Default_Expressions_Processed (E) then
1409                Process_Default_Expressions (E, After);
1410             end if;
1411
1412             if not Has_Completion (E) then
1413                Decl := Unit_Declaration_Node (E);
1414
1415                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1416                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1417
1418                elsif Nkind (Decl) = N_Subprogram_Declaration
1419                  and then Present (Corresponding_Body (Decl))
1420                  and then
1421                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1422                                           = N_Subprogram_Renaming_Declaration
1423                then
1424                   Build_And_Analyze_Renamed_Body
1425                     (Decl, Corresponding_Body (Decl), After);
1426                end if;
1427             end if;
1428
1429          elsif Ekind (E) in Task_Kind
1430            and then
1431              (Nkind (Parent (E)) = N_Task_Type_Declaration
1432                 or else
1433               Nkind (Parent (E)) = N_Single_Task_Declaration)
1434          then
1435             declare
1436                Ent : Entity_Id;
1437
1438             begin
1439                Ent := First_Entity (E);
1440                while Present (Ent) loop
1441                   if Is_Entry (Ent)
1442                     and then not Default_Expressions_Processed (Ent)
1443                   then
1444                      Process_Default_Expressions (Ent, After);
1445                   end if;
1446
1447                   Next_Entity (Ent);
1448                end loop;
1449             end;
1450
1451          elsif Is_Access_Type (E)
1452            and then Comes_From_Source (E)
1453            and then Ekind (Directly_Designated_Type (E)) = E_Incomplete_Type
1454            and then Needs_Finalization (Designated_Type (E))
1455            and then No (Associated_Final_Chain (E))
1456          then
1457             Build_Final_List (Parent (E), E);
1458          end if;
1459
1460          Next_Entity (E);
1461       end loop;
1462    end Freeze_All;
1463
1464    -----------------------
1465    -- Freeze_And_Append --
1466    -----------------------
1467
1468    procedure Freeze_And_Append
1469      (Ent    : Entity_Id;
1470       N      : Node_Id;
1471       Result : in out List_Id)
1472    is
1473       L : constant List_Id := Freeze_Entity (Ent, N);
1474    begin
1475       if Is_Non_Empty_List (L) then
1476          if Result = No_List then
1477             Result := L;
1478          else
1479             Append_List (L, Result);
1480          end if;
1481       end if;
1482    end Freeze_And_Append;
1483
1484    -------------------
1485    -- Freeze_Before --
1486    -------------------
1487
1488    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1489       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1490    begin
1491       if Is_Non_Empty_List (Freeze_Nodes) then
1492          Insert_Actions (N, Freeze_Nodes);
1493       end if;
1494    end Freeze_Before;
1495
1496    -------------------
1497    -- Freeze_Entity --
1498    -------------------
1499
1500    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1501       Loc    : constant Source_Ptr := Sloc (N);
1502       Test_E : Entity_Id := E;
1503       Comp   : Entity_Id;
1504       F_Node : Node_Id;
1505       Result : List_Id;
1506       Indx   : Node_Id;
1507       Formal : Entity_Id;
1508       Atype  : Entity_Id;
1509
1510       Has_Default_Initialization : Boolean := False;
1511       --  This flag gets set to true for a variable with default initialization
1512
1513       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1514       --  Check that an Access or Unchecked_Access attribute with a prefix
1515       --  which is the current instance type can only be applied when the type
1516       --  is limited.
1517
1518       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1519       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1520       --  integer literal without an explicit corresponding size clause. The
1521       --  caller has checked that Utype is a modular integer type.
1522
1523       function After_Last_Declaration return Boolean;
1524       --  If Loc is a freeze_entity that appears after the last declaration
1525       --  in the scope, inhibit error messages on late completion.
1526
1527       procedure Freeze_Record_Type (Rec : Entity_Id);
1528       --  Freeze each component, handle some representation clauses, and freeze
1529       --  primitive operations if this is a tagged type.
1530
1531       ----------------------------
1532       -- After_Last_Declaration --
1533       ----------------------------
1534
1535       function After_Last_Declaration return Boolean is
1536          Spec : constant Node_Id := Parent (Current_Scope);
1537       begin
1538          if Nkind (Spec) = N_Package_Specification then
1539             if Present (Private_Declarations (Spec)) then
1540                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1541             elsif Present (Visible_Declarations (Spec)) then
1542                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1543             else
1544                return False;
1545             end if;
1546          else
1547             return False;
1548          end if;
1549       end After_Last_Declaration;
1550
1551       ----------------------------
1552       -- Check_Current_Instance --
1553       ----------------------------
1554
1555       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1556
1557          Rec_Type : constant Entity_Id :=
1558                       Scope (Defining_Identifier (Comp_Decl));
1559
1560          Decl : constant Node_Id := Parent (Rec_Type);
1561
1562          function Process (N : Node_Id) return Traverse_Result;
1563          --  Process routine to apply check to given node
1564
1565          -------------
1566          -- Process --
1567          -------------
1568
1569          function Process (N : Node_Id) return Traverse_Result is
1570          begin
1571             case Nkind (N) is
1572                when N_Attribute_Reference =>
1573                   if (Attribute_Name (N) = Name_Access
1574                         or else
1575                       Attribute_Name (N) = Name_Unchecked_Access)
1576                     and then Is_Entity_Name (Prefix (N))
1577                     and then Is_Type (Entity (Prefix (N)))
1578                     and then Entity (Prefix (N)) = E
1579                   then
1580                      Error_Msg_N
1581                        ("current instance must be a limited type", Prefix (N));
1582                      return Abandon;
1583                   else
1584                      return OK;
1585                   end if;
1586
1587                when others => return OK;
1588             end case;
1589          end Process;
1590
1591          procedure Traverse is new Traverse_Proc (Process);
1592
1593       --  Start of processing for Check_Current_Instance
1594
1595       begin
1596          --  In Ada95, the (imprecise) rule is that the current instance of a
1597          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1598          --  either a tagged type, or a limited record.
1599
1600          if Is_Limited_Type (Rec_Type)
1601            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1602          then
1603             return;
1604
1605          elsif Nkind (Decl) = N_Full_Type_Declaration
1606            and then Limited_Present (Type_Definition (Decl))
1607          then
1608             return;
1609
1610          else
1611             Traverse (Comp_Decl);
1612          end if;
1613       end Check_Current_Instance;
1614
1615       ------------------------------
1616       -- Check_Suspicious_Modulus --
1617       ------------------------------
1618
1619       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1620          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1621
1622       begin
1623          if Nkind (Decl) = N_Full_Type_Declaration then
1624             declare
1625                Tdef : constant Node_Id := Type_Definition (Decl);
1626             begin
1627                if Nkind (Tdef) = N_Modular_Type_Definition then
1628                   declare
1629                      Modulus : constant Node_Id :=
1630                                  Original_Node (Expression (Tdef));
1631                   begin
1632                      if Nkind (Modulus) = N_Integer_Literal then
1633                         declare
1634                            Modv : constant Uint := Intval (Modulus);
1635                            Sizv : constant Uint := RM_Size (Utype);
1636
1637                         begin
1638                            --  First case, modulus and size are the same. This
1639                            --  happens if you have something like mod 32, with
1640                            --  an explicit size of 32, this is for sure a case
1641                            --  where the warning is given, since it is seems
1642                            --  very unlikely that someone would want e.g. a
1643                            --  five bit type stored in 32 bits. It is much
1644                            --  more likely they wanted a 32-bit type.
1645
1646                            if Modv = Sizv then
1647                               null;
1648
1649                            --  Second case, the modulus is 32 or 64 and no
1650                            --  size clause is present. This is a less clear
1651                            --  case for giving the warning, but in the case
1652                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1653                            --  enough that it is a likely error (and in any
1654                            --  case using 2**5 or 2**6 in these cases seems
1655                            --  clearer. We don't include 8 or 16 here, simply
1656                            --  because in practice 3-bit and 4-bit types are
1657                            --  more common and too many false positives if
1658                            --  we warn in these cases.
1659
1660                            elsif not Has_Size_Clause (Utype)
1661                              and then (Modv = Uint_32 or else Modv = Uint_64)
1662                            then
1663                               null;
1664
1665                            --  No warning needed
1666
1667                            else
1668                               return;
1669                            end if;
1670
1671                            --  If we fall through, give warning
1672
1673                            Error_Msg_Uint_1 := Modv;
1674                            Error_Msg_N
1675                              ("?2 '*'*^' may have been intended here",
1676                               Modulus);
1677                         end;
1678                      end if;
1679                   end;
1680                end if;
1681             end;
1682          end if;
1683       end Check_Suspicious_Modulus;
1684
1685       ------------------------
1686       -- Freeze_Record_Type --
1687       ------------------------
1688
1689       procedure Freeze_Record_Type (Rec : Entity_Id) is
1690          Comp : Entity_Id;
1691          IR   : Node_Id;
1692          ADC  : Node_Id;
1693          Prev : Entity_Id;
1694
1695          Junk : Boolean;
1696          pragma Warnings (Off, Junk);
1697
1698          Unplaced_Component : Boolean := False;
1699          --  Set True if we find at least one component with no component
1700          --  clause (used to warn about useless Pack pragmas).
1701
1702          Placed_Component : Boolean := False;
1703          --  Set True if we find at least one component with a component
1704          --  clause (used to warn about useless Bit_Order pragmas, and also
1705          --  to detect cases where Implicit_Packing may have an effect).
1706
1707          All_Scalar_Components : Boolean := True;
1708          --  Set False if we encounter a component of a non-scalar type
1709
1710          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1711          Scalar_Component_Total_Esize   : Uint := Uint_0;
1712          --  Accumulates total RM_Size values and total Esize values of all
1713          --  scalar components. Used for processing of Implicit_Packing.
1714
1715          function Check_Allocator (N : Node_Id) return Node_Id;
1716          --  If N is an allocator, possibly wrapped in one or more level of
1717          --  qualified expression(s), return the inner allocator node, else
1718          --  return Empty.
1719
1720          procedure Check_Itype (Typ : Entity_Id);
1721          --  If the component subtype is an access to a constrained subtype of
1722          --  an already frozen type, make the subtype frozen as well. It might
1723          --  otherwise be frozen in the wrong scope, and a freeze node on
1724          --  subtype has no effect. Similarly, if the component subtype is a
1725          --  regular (not protected) access to subprogram, set the anonymous
1726          --  subprogram type to frozen as well, to prevent an out-of-scope
1727          --  freeze node at some eventual point of call. Protected operations
1728          --  are handled elsewhere.
1729
1730          ---------------------
1731          -- Check_Allocator --
1732          ---------------------
1733
1734          function Check_Allocator (N : Node_Id) return Node_Id is
1735             Inner : Node_Id;
1736          begin
1737             Inner := N;
1738             loop
1739                if Nkind (Inner) = N_Allocator then
1740                   return Inner;
1741                elsif Nkind (Inner) = N_Qualified_Expression then
1742                   Inner := Expression (Inner);
1743                else
1744                   return Empty;
1745                end if;
1746             end loop;
1747          end Check_Allocator;
1748
1749          -----------------
1750          -- Check_Itype --
1751          -----------------
1752
1753          procedure Check_Itype (Typ : Entity_Id) is
1754             Desig : constant Entity_Id := Designated_Type (Typ);
1755
1756          begin
1757             if not Is_Frozen (Desig)
1758               and then Is_Frozen (Base_Type (Desig))
1759             then
1760                Set_Is_Frozen (Desig);
1761
1762                --  In addition, add an Itype_Reference to ensure that the
1763                --  access subtype is elaborated early enough. This cannot be
1764                --  done if the subtype may depend on discriminants.
1765
1766                if Ekind (Comp) = E_Component
1767                  and then Is_Itype (Etype (Comp))
1768                  and then not Has_Discriminants (Rec)
1769                then
1770                   IR := Make_Itype_Reference (Sloc (Comp));
1771                   Set_Itype (IR, Desig);
1772
1773                   if No (Result) then
1774                      Result := New_List (IR);
1775                   else
1776                      Append (IR, Result);
1777                   end if;
1778                end if;
1779
1780             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1781               and then Convention (Desig) /= Convention_Protected
1782             then
1783                Set_Is_Frozen (Desig);
1784             end if;
1785          end Check_Itype;
1786
1787       --  Start of processing for Freeze_Record_Type
1788
1789       begin
1790          --  If this is a subtype of a controlled type, declared without a
1791          --  constraint, the _controller may not appear in the component list
1792          --  if the parent was not frozen at the point of subtype declaration.
1793          --  Inherit the _controller component now.
1794
1795          if Rec /= Base_Type (Rec)
1796            and then Has_Controlled_Component (Rec)
1797          then
1798             if Nkind (Parent (Rec)) = N_Subtype_Declaration
1799               and then Is_Entity_Name (Subtype_Indication (Parent (Rec)))
1800             then
1801                Set_First_Entity (Rec, First_Entity (Base_Type (Rec)));
1802
1803             --  If this is an internal type without a declaration, as for
1804             --  record component, the base type may not yet be frozen, and its
1805             --  controller has not been created. Add an explicit freeze node
1806             --  for the itype, so it will be frozen after the base type. This
1807             --  freeze node is used to communicate with the expander, in order
1808             --  to create the controller for the enclosing record, and it is
1809             --  deleted afterwards (see exp_ch3). It must not be created when
1810             --  expansion is off, because it might appear in the wrong context
1811             --  for the back end.
1812
1813             elsif Is_Itype (Rec)
1814               and then Has_Delayed_Freeze (Base_Type (Rec))
1815               and then
1816                 Nkind (Associated_Node_For_Itype (Rec)) =
1817                                                      N_Component_Declaration
1818               and then Expander_Active
1819             then
1820                Ensure_Freeze_Node (Rec);
1821             end if;
1822          end if;
1823
1824          --  Freeze components and embedded subtypes
1825
1826          Comp := First_Entity (Rec);
1827          Prev := Empty;
1828          while Present (Comp) loop
1829
1830             --  First handle the component case
1831
1832             if Ekind (Comp) = E_Component
1833               or else Ekind (Comp) = E_Discriminant
1834             then
1835                declare
1836                   CC : constant Node_Id := Component_Clause (Comp);
1837
1838                begin
1839                   --  Freezing a record type freezes the type of each of its
1840                   --  components. However, if the type of the component is
1841                   --  part of this record, we do not want or need a separate
1842                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1843                   --  also set in private type cases. We also can't check for
1844                   --  the Scope being exactly Rec because of private types and
1845                   --  record extensions.
1846
1847                   if Is_Itype (Etype (Comp))
1848                     and then Is_Record_Type (Underlying_Type
1849                                              (Scope (Etype (Comp))))
1850                   then
1851                      Undelay_Type (Etype (Comp));
1852                   end if;
1853
1854                   Freeze_And_Append (Etype (Comp), N, Result);
1855
1856                   --  Check for error of component clause given for variable
1857                   --  sized type. We have to delay this test till this point,
1858                   --  since the component type has to be frozen for us to know
1859                   --  if it is variable length. We omit this test in a generic
1860                   --  context, it will be applied at instantiation time.
1861
1862                   if Present (CC) then
1863                      Placed_Component := True;
1864
1865                      if Inside_A_Generic then
1866                         null;
1867
1868                      elsif not
1869                        Size_Known_At_Compile_Time
1870                          (Underlying_Type (Etype (Comp)))
1871                      then
1872                         Error_Msg_N
1873                           ("component clause not allowed for variable " &
1874                            "length component", CC);
1875                      end if;
1876
1877                   else
1878                      Unplaced_Component := True;
1879                   end if;
1880
1881                   --  Case of component requires byte alignment
1882
1883                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1884
1885                      --  Set the enclosing record to also require byte align
1886
1887                      Set_Must_Be_On_Byte_Boundary (Rec);
1888
1889                      --  Check for component clause that is inconsistent with
1890                      --  the required byte boundary alignment.
1891
1892                      if Present (CC)
1893                        and then Normalized_First_Bit (Comp) mod
1894                                   System_Storage_Unit /= 0
1895                      then
1896                         Error_Msg_N
1897                           ("component & must be byte aligned",
1898                            Component_Name (Component_Clause (Comp)));
1899                      end if;
1900                   end if;
1901                end;
1902             end if;
1903
1904             --  Gather data for possible Implicit_Packing later. Note that at
1905             --  this stage we might be dealing with a real component, or with
1906             --  an implicit subtype declaration.
1907
1908             if not Is_Scalar_Type (Etype (Comp)) then
1909                All_Scalar_Components := False;
1910             else
1911                Scalar_Component_Total_RM_Size :=
1912                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1913                Scalar_Component_Total_Esize :=
1914                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1915             end if;
1916
1917             --  If the component is an Itype with Delayed_Freeze and is either
1918             --  a record or array subtype and its base type has not yet been
1919             --  frozen, we must remove this from the entity list of this record
1920             --  and put it on the entity list of the scope of its base type.
1921             --  Note that we know that this is not the type of a component
1922             --  since we cleared Has_Delayed_Freeze for it in the previous
1923             --  loop. Thus this must be the Designated_Type of an access type,
1924             --  which is the type of a component.
1925
1926             if Is_Itype (Comp)
1927               and then Is_Type (Scope (Comp))
1928               and then Is_Composite_Type (Comp)
1929               and then Base_Type (Comp) /= Comp
1930               and then Has_Delayed_Freeze (Comp)
1931               and then not Is_Frozen (Base_Type (Comp))
1932             then
1933                declare
1934                   Will_Be_Frozen : Boolean := False;
1935                   S              : Entity_Id;
1936
1937                begin
1938                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1939                   --  being defined in a subprogram that's created as part of
1940                   --  the freezing of Rec'Base. In that case, we know that
1941                   --  Comp'Base must have already been frozen by the time we
1942                   --  get to elaborate this because Gigi doesn't elaborate any
1943                   --  bodies until it has elaborated all of the declarative
1944                   --  part. But Is_Frozen will not be set at this point because
1945                   --  we are processing code in lexical order.
1946
1947                   --  We detect this case by going up the Scope chain of Rec
1948                   --  and seeing if we have a subprogram scope before reaching
1949                   --  the top of the scope chain or that of Comp'Base. If we
1950                   --  do, then mark that Comp'Base will actually be frozen. If
1951                   --  so, we merely undelay it.
1952
1953                   S := Scope (Rec);
1954                   while Present (S) loop
1955                      if Is_Subprogram (S) then
1956                         Will_Be_Frozen := True;
1957                         exit;
1958                      elsif S = Scope (Base_Type (Comp)) then
1959                         exit;
1960                      end if;
1961
1962                      S := Scope (S);
1963                   end loop;
1964
1965                   if Will_Be_Frozen then
1966                      Undelay_Type (Comp);
1967                   else
1968                      if Present (Prev) then
1969                         Set_Next_Entity (Prev, Next_Entity (Comp));
1970                      else
1971                         Set_First_Entity (Rec, Next_Entity (Comp));
1972                      end if;
1973
1974                      --  Insert in entity list of scope of base type (which
1975                      --  must be an enclosing scope, because still unfrozen).
1976
1977                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1978                   end if;
1979                end;
1980
1981             --  If the component is an access type with an allocator as default
1982             --  value, the designated type will be frozen by the corresponding
1983             --  expression in init_proc. In order to place the freeze node for
1984             --  the designated type before that for the current record type,
1985             --  freeze it now.
1986
1987             --  Same process if the component is an array of access types,
1988             --  initialized with an aggregate. If the designated type is
1989             --  private, it cannot contain allocators, and it is premature
1990             --  to freeze the type, so we check for this as well.
1991
1992             elsif Is_Access_Type (Etype (Comp))
1993               and then Present (Parent (Comp))
1994               and then Present (Expression (Parent (Comp)))
1995             then
1996                declare
1997                   Alloc : constant Node_Id :=
1998                             Check_Allocator (Expression (Parent (Comp)));
1999
2000                begin
2001                   if Present (Alloc) then
2002
2003                      --  If component is pointer to a classwide type, freeze
2004                      --  the specific type in the expression being allocated.
2005                      --  The expression may be a subtype indication, in which
2006                      --  case freeze the subtype mark.
2007
2008                      if Is_Class_Wide_Type
2009                           (Designated_Type (Etype (Comp)))
2010                      then
2011                         if Is_Entity_Name (Expression (Alloc)) then
2012                            Freeze_And_Append
2013                              (Entity (Expression (Alloc)), N, Result);
2014                         elsif
2015                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2016                         then
2017                            Freeze_And_Append
2018                             (Entity (Subtype_Mark (Expression (Alloc))),
2019                              N, Result);
2020                         end if;
2021
2022                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2023                         Check_Itype (Etype (Comp));
2024
2025                      else
2026                         Freeze_And_Append
2027                           (Designated_Type (Etype (Comp)), N, Result);
2028                      end if;
2029                   end if;
2030                end;
2031
2032             elsif Is_Access_Type (Etype (Comp))
2033               and then Is_Itype (Designated_Type (Etype (Comp)))
2034             then
2035                Check_Itype (Etype (Comp));
2036
2037             elsif Is_Array_Type (Etype (Comp))
2038               and then Is_Access_Type (Component_Type (Etype (Comp)))
2039               and then Present (Parent (Comp))
2040               and then Nkind (Parent (Comp)) = N_Component_Declaration
2041               and then Present (Expression (Parent (Comp)))
2042               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2043               and then Is_Fully_Defined
2044                  (Designated_Type (Component_Type (Etype (Comp))))
2045             then
2046                Freeze_And_Append
2047                  (Designated_Type
2048                    (Component_Type (Etype (Comp))), N, Result);
2049             end if;
2050
2051             Prev := Comp;
2052             Next_Entity (Comp);
2053          end loop;
2054
2055          --  Deal with pragma Bit_Order setting non-standard bit order
2056
2057          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2058             if not Placed_Component then
2059                ADC :=
2060                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2061                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2062                Error_Msg_N
2063                  ("\?since no component clauses were specified", ADC);
2064
2065             --  Here is where we do the processing for reversed bit order
2066
2067             else
2068                Adjust_Record_For_Reverse_Bit_Order (Rec);
2069             end if;
2070          end if;
2071
2072          --  Complete error checking on record representation clause (e.g.
2073          --  overlap of components). This is called after adjusting the
2074          --  record for reverse bit order.
2075
2076          declare
2077             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2078          begin
2079             if Present (RRC) then
2080                Check_Record_Representation_Clause (RRC);
2081             end if;
2082          end;
2083
2084          --  Set OK_To_Reorder_Components depending on debug flags
2085
2086          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2087             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2088                   or else
2089                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2090             then
2091                Set_OK_To_Reorder_Components (Rec);
2092             end if;
2093          end if;
2094
2095          --  Check for useless pragma Pack when all components placed. We only
2096          --  do this check for record types, not subtypes, since a subtype may
2097          --  have all its components placed, and it still makes perfectly good
2098          --  sense to pack other subtypes or the parent type. We do not give
2099          --  this warning if Optimize_Alignment is set to Space, since the
2100          --  pragma Pack does have an effect in this case (it always resets
2101          --  the alignment to one).
2102
2103          if Ekind (Rec) = E_Record_Type
2104            and then Is_Packed (Rec)
2105            and then not Unplaced_Component
2106            and then Optimize_Alignment /= 'S'
2107          then
2108             --  Reset packed status. Probably not necessary, but we do it so
2109             --  that there is no chance of the back end doing something strange
2110             --  with this redundant indication of packing.
2111
2112             Set_Is_Packed (Rec, False);
2113
2114             --  Give warning if redundant constructs warnings on
2115
2116             if Warn_On_Redundant_Constructs then
2117                Error_Msg_N -- CODEFIX
2118                  ("?pragma Pack has no effect, no unplaced components",
2119                   Get_Rep_Pragma (Rec, Name_Pack));
2120             end if;
2121          end if;
2122
2123          --  If this is the record corresponding to a remote type, freeze the
2124          --  remote type here since that is what we are semantically freezing.
2125          --  This prevents the freeze node for that type in an inner scope.
2126
2127          --  Also, Check for controlled components and unchecked unions.
2128          --  Finally, enforce the restriction that access attributes with a
2129          --  current instance prefix can only apply to limited types.
2130
2131          if Ekind (Rec) = E_Record_Type then
2132             if Present (Corresponding_Remote_Type (Rec)) then
2133                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2134             end if;
2135
2136             Comp := First_Component (Rec);
2137             while Present (Comp) loop
2138
2139                --  Do not set Has_Controlled_Component on a class-wide
2140                --  equivalent type. See Make_CW_Equivalent_Type.
2141
2142                if not Is_Class_Wide_Equivalent_Type (Rec)
2143                  and then (Has_Controlled_Component (Etype (Comp))
2144                             or else (Chars (Comp) /= Name_uParent
2145                                       and then Is_Controlled (Etype (Comp)))
2146                             or else (Is_Protected_Type (Etype (Comp))
2147                                       and then Present
2148                                         (Corresponding_Record_Type
2149                                           (Etype (Comp)))
2150                                       and then Has_Controlled_Component
2151                                         (Corresponding_Record_Type
2152                                           (Etype (Comp)))))
2153                then
2154                   Set_Has_Controlled_Component (Rec);
2155                   exit;
2156                end if;
2157
2158                if Has_Unchecked_Union (Etype (Comp)) then
2159                   Set_Has_Unchecked_Union (Rec);
2160                end if;
2161
2162                if Has_Per_Object_Constraint (Comp) then
2163
2164                   --  Scan component declaration for likely misuses of current
2165                   --  instance, either in a constraint or a default expression.
2166
2167                   Check_Current_Instance (Parent (Comp));
2168                end if;
2169
2170                Next_Component (Comp);
2171             end loop;
2172          end if;
2173
2174          Set_Component_Alignment_If_Not_Set (Rec);
2175
2176          --  For first subtypes, check if there are any fixed-point fields with
2177          --  component clauses, where we must check the size. This is not done
2178          --  till the freeze point, since for fixed-point types, we do not know
2179          --  the size until the type is frozen. Similar processing applies to
2180          --  bit packed arrays.
2181
2182          if Is_First_Subtype (Rec) then
2183             Comp := First_Component (Rec);
2184             while Present (Comp) loop
2185                if Present (Component_Clause (Comp))
2186                  and then (Is_Fixed_Point_Type (Etype (Comp))
2187                              or else
2188                            Is_Bit_Packed_Array (Etype (Comp)))
2189                then
2190                   Check_Size
2191                     (Component_Name (Component_Clause (Comp)),
2192                      Etype (Comp),
2193                      Esize (Comp),
2194                      Junk);
2195                end if;
2196
2197                Next_Component (Comp);
2198             end loop;
2199          end if;
2200
2201          --  Generate warning for applying C or C++ convention to a record
2202          --  with discriminants. This is suppressed for the unchecked union
2203          --  case, since the whole point in this case is interface C. We also
2204          --  do not generate this within instantiations, since we will have
2205          --  generated a message on the template.
2206
2207          if Has_Discriminants (E)
2208            and then not Is_Unchecked_Union (E)
2209            and then (Convention (E) = Convention_C
2210                        or else
2211                      Convention (E) = Convention_CPP)
2212            and then Comes_From_Source (E)
2213            and then not In_Instance
2214            and then not Has_Warnings_Off (E)
2215            and then not Has_Warnings_Off (Base_Type (E))
2216          then
2217             declare
2218                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2219                A2    : Node_Id;
2220
2221             begin
2222                if Present (Cprag) then
2223                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2224
2225                   if Convention (E) = Convention_C then
2226                      Error_Msg_N
2227                        ("?variant record has no direct equivalent in C", A2);
2228                   else
2229                      Error_Msg_N
2230                        ("?variant record has no direct equivalent in C++", A2);
2231                   end if;
2232
2233                   Error_Msg_NE
2234                     ("\?use of convention for type& is dubious", A2, E);
2235                end if;
2236             end;
2237          end if;
2238
2239          --  See if Size is too small as is (and implicit packing might help)
2240
2241          if not Is_Packed (Rec)
2242
2243            --  No implicit packing if even one component is explicitly placed
2244
2245            and then not Placed_Component
2246
2247            --  Must have size clause and all scalar components
2248
2249            and then Has_Size_Clause (Rec)
2250            and then All_Scalar_Components
2251
2252            --  Do not try implicit packing on records with discriminants, too
2253            --  complicated, especially in the variant record case.
2254
2255            and then not Has_Discriminants (Rec)
2256
2257            --  We can implicitly pack if the specified size of the record is
2258            --  less than the sum of the object sizes (no point in packing if
2259            --  this is not the case).
2260
2261            and then Esize (Rec) < Scalar_Component_Total_Esize
2262
2263            --  And the total RM size cannot be greater than the specified size
2264            --  since otherwise packing will not get us where we have to be!
2265
2266            and then Esize (Rec) >= Scalar_Component_Total_RM_Size
2267
2268            --  Never do implicit packing in CodePeer mode since we don't do
2269            --  any packing in this mode, since this generates over-complex
2270            --  code that confuses CodePeer, and in general, CodePeer does not
2271            --  care about the internal representation of objects.
2272
2273            and then not CodePeer_Mode
2274          then
2275             --  If implicit packing enabled, do it
2276
2277             if Implicit_Packing then
2278                Set_Is_Packed (Rec);
2279
2280                --  Otherwise flag the size clause
2281
2282             else
2283                declare
2284                   Sz : constant Node_Id := Size_Clause (Rec);
2285                begin
2286                   Error_Msg_NE -- CODEFIX
2287                     ("size given for& too small", Sz, Rec);
2288                   Error_Msg_N -- CODEFIX
2289                     ("\use explicit pragma Pack "
2290                      & "or use pragma Implicit_Packing", Sz);
2291                end;
2292             end if;
2293          end if;
2294       end Freeze_Record_Type;
2295
2296    --  Start of processing for Freeze_Entity
2297
2298    begin
2299       --  We are going to test for various reasons why this entity need not be
2300       --  frozen here, but in the case of an Itype that's defined within a
2301       --  record, that test actually applies to the record.
2302
2303       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2304          Test_E := Scope (E);
2305       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2306         and then Is_Record_Type (Underlying_Type (Scope (E)))
2307       then
2308          Test_E := Underlying_Type (Scope (E));
2309       end if;
2310
2311       --  Do not freeze if already frozen since we only need one freeze node
2312
2313       if Is_Frozen (E) then
2314          return No_List;
2315
2316       --  It is improper to freeze an external entity within a generic because
2317       --  its freeze node will appear in a non-valid context. The entity will
2318       --  be frozen in the proper scope after the current generic is analyzed.
2319
2320       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2321          return No_List;
2322
2323       --  Do not freeze a global entity within an inner scope created during
2324       --  expansion. A call to subprogram E within some internal procedure
2325       --  (a stream attribute for example) might require freezing E, but the
2326       --  freeze node must appear in the same declarative part as E itself.
2327       --  The two-pass elaboration mechanism in gigi guarantees that E will
2328       --  be frozen before the inner call is elaborated. We exclude constants
2329       --  from this test, because deferred constants may be frozen early, and
2330       --  must be diagnosed (e.g. in the case of a deferred constant being used
2331       --  in a default expression). If the enclosing subprogram comes from
2332       --  source, or is a generic instance, then the freeze point is the one
2333       --  mandated by the language, and we freeze the entity. A subprogram that
2334       --  is a child unit body that acts as a spec does not have a spec that
2335       --  comes from source, but can only come from source.
2336
2337       elsif In_Open_Scopes (Scope (Test_E))
2338         and then Scope (Test_E) /= Current_Scope
2339         and then Ekind (Test_E) /= E_Constant
2340       then
2341          declare
2342             S : Entity_Id;
2343
2344          begin
2345             S := Current_Scope;
2346             while Present (S) loop
2347                if Is_Overloadable (S) then
2348                   if Comes_From_Source (S)
2349                     or else Is_Generic_Instance (S)
2350                     or else Is_Child_Unit (S)
2351                   then
2352                      exit;
2353                   else
2354                      return No_List;
2355                   end if;
2356                end if;
2357
2358                S := Scope (S);
2359             end loop;
2360          end;
2361
2362       --  Similarly, an inlined instance body may make reference to global
2363       --  entities, but these references cannot be the proper freezing point
2364       --  for them, and in the absence of inlining freezing will take place in
2365       --  their own scope. Normally instance bodies are analyzed after the
2366       --  enclosing compilation, and everything has been frozen at the proper
2367       --  place, but with front-end inlining an instance body is compiled
2368       --  before the end of the enclosing scope, and as a result out-of-order
2369       --  freezing must be prevented.
2370
2371       elsif Front_End_Inlining
2372         and then In_Instance_Body
2373         and then Present (Scope (Test_E))
2374       then
2375          declare
2376             S : Entity_Id;
2377
2378          begin
2379             S := Scope (Test_E);
2380             while Present (S) loop
2381                if Is_Generic_Instance (S) then
2382                   exit;
2383                else
2384                   S := Scope (S);
2385                end if;
2386             end loop;
2387
2388             if No (S) then
2389                return No_List;
2390             end if;
2391          end;
2392       end if;
2393
2394       --  Deal with delayed aspect specifications. The analysis of the aspect
2395       --  is required to be delayed to the freeze point, so we evaluate the
2396       --  pragma or attribute definition clause in the tree at this point.
2397
2398       --  We also have to deal with the case of Boolean aspects, where the
2399       --  value of the Boolean expression is represented by the setting of
2400       --  the Aspect_Cancel flag on the pragma.
2401
2402       if Has_Delayed_Aspects (E) then
2403          declare
2404             Ritem : Node_Id;
2405             Aitem : Node_Id;
2406
2407          begin
2408             --  Look for aspect specification entries for this entity
2409
2410             Ritem := First_Rep_Item (E);
2411             while Present (Ritem) loop
2412                if Nkind (Ritem) = N_Aspect_Specification
2413                  and then Entity (Ritem) = E
2414                  and then Is_Delayed_Aspect (Ritem)
2415                then
2416                   Aitem := Aspect_Rep_Item (Ritem);
2417                   Set_Parent (Aitem, Ritem);
2418
2419                   --  Deal with Boolean case, if no expression, True, otherwise
2420                   --  analyze the expression, check it is static, and if its
2421                   --  value is False, set Aspect_Cancel for the related pragma.
2422
2423                   if Is_Boolean_Aspect (Ritem) then
2424                      declare
2425                         Expr : constant Node_Id := Expression (Ritem);
2426
2427                      begin
2428                         if Present (Expr) then
2429                            Analyze_And_Resolve (Expr, Standard_Boolean);
2430
2431                            if not Is_OK_Static_Expression (Expr) then
2432                               Error_Msg_Name_1 := Chars (Identifier (Ritem));
2433                               Error_Msg_N
2434                                 ("expression for % aspect must be static",
2435                                  Expr);
2436
2437                            elsif Is_False (Expr_Value (Expr)) then
2438                               Set_Aspect_Cancel (Aitem);
2439                            end if;
2440                         end if;
2441                      end;
2442                   end if;
2443
2444                   --  Analyze the pragma after possibly setting Aspect_Cancel
2445
2446                   Analyze (Aitem);
2447                end if;
2448
2449                Next_Rep_Item (Ritem);
2450             end loop;
2451          end;
2452       end if;
2453
2454       --  Here to freeze the entity
2455
2456       Result := No_List;
2457       Set_Is_Frozen (E);
2458
2459       --  Case of entity being frozen is other than a type
2460
2461       if not Is_Type (E) then
2462
2463          --  If entity is exported or imported and does not have an external
2464          --  name, now is the time to provide the appropriate default name.
2465          --  Skip this if the entity is stubbed, since we don't need a name
2466          --  for any stubbed routine. For the case on intrinsics, if no
2467          --  external name is specified, then calls will be handled in
2468          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2469          --  external name is provided, then Expand_Intrinsic_Call leaves
2470          --  calls in place for expansion by GIGI.
2471
2472          if (Is_Imported (E) or else Is_Exported (E))
2473            and then No (Interface_Name (E))
2474            and then Convention (E) /= Convention_Stubbed
2475            and then Convention (E) /= Convention_Intrinsic
2476          then
2477             Set_Encoded_Interface_Name
2478               (E, Get_Default_External_Name (E));
2479
2480          --  If entity is an atomic object appearing in a declaration and
2481          --  the expression is an aggregate, assign it to a temporary to
2482          --  ensure that the actual assignment is done atomically rather
2483          --  than component-wise (the assignment to the temp may be done
2484          --  component-wise, but that is harmless).
2485
2486          elsif Is_Atomic (E)
2487            and then Nkind (Parent (E)) = N_Object_Declaration
2488            and then Present (Expression (Parent (E)))
2489            and then Nkind (Expression (Parent (E))) = N_Aggregate
2490            and then
2491              Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2492          then
2493             null;
2494          end if;
2495
2496          --  For a subprogram, freeze all parameter types and also the return
2497          --  type (RM 13.14(14)). However skip this for internal subprograms.
2498          --  This is also the point where any extra formal parameters are
2499          --  created since we now know whether the subprogram will use a
2500          --  foreign convention.
2501
2502          if Is_Subprogram (E) then
2503             if not Is_Internal (E) then
2504                declare
2505                   F_Type    : Entity_Id;
2506                   R_Type    : Entity_Id;
2507                   Warn_Node : Node_Id;
2508
2509                begin
2510                   --  Loop through formals
2511
2512                   Formal := First_Formal (E);
2513                   while Present (Formal) loop
2514                      F_Type := Etype (Formal);
2515                      Freeze_And_Append (F_Type, N, Result);
2516
2517                      if Is_Private_Type (F_Type)
2518                        and then Is_Private_Type (Base_Type (F_Type))
2519                        and then No (Full_View (Base_Type (F_Type)))
2520                        and then not Is_Generic_Type (F_Type)
2521                        and then not Is_Derived_Type (F_Type)
2522                      then
2523                         --  If the type of a formal is incomplete, subprogram
2524                         --  is being frozen prematurely. Within an instance
2525                         --  (but not within a wrapper package) this is an
2526                         --  artifact of our need to regard the end of an
2527                         --  instantiation as a freeze point. Otherwise it is
2528                         --  a definite error.
2529
2530                         if In_Instance then
2531                            Set_Is_Frozen (E, False);
2532                            return No_List;
2533
2534                         elsif not After_Last_Declaration
2535                           and then not Freezing_Library_Level_Tagged_Type
2536                         then
2537                            Error_Msg_Node_1 := F_Type;
2538                            Error_Msg
2539                              ("type& must be fully defined before this point",
2540                                Loc);
2541                         end if;
2542                      end if;
2543
2544                      --  Check suspicious parameter for C function. These tests
2545                      --  apply only to exported/imported subprograms.
2546
2547                      if Warn_On_Export_Import
2548                        and then Comes_From_Source (E)
2549                        and then (Convention (E) = Convention_C
2550                                    or else
2551                                  Convention (E) = Convention_CPP)
2552                        and then (Is_Imported (E) or else Is_Exported (E))
2553                        and then Convention (E) /= Convention (Formal)
2554                        and then not Has_Warnings_Off (E)
2555                        and then not Has_Warnings_Off (F_Type)
2556                        and then not Has_Warnings_Off (Formal)
2557                      then
2558                         --  Qualify mention of formals with subprogram name
2559
2560                         Error_Msg_Qual_Level := 1;
2561
2562                         --  Check suspicious use of fat C pointer
2563
2564                         if Is_Access_Type (F_Type)
2565                           and then Esize (F_Type) > Ttypes.System_Address_Size
2566                         then
2567                            Error_Msg_N
2568                              ("?type of & does not correspond to C pointer!",
2569                               Formal);
2570
2571                         --  Check suspicious return of boolean
2572
2573                         elsif Root_Type (F_Type) = Standard_Boolean
2574                           and then Convention (F_Type) = Convention_Ada
2575                           and then not Has_Warnings_Off (F_Type)
2576                           and then not Has_Size_Clause (F_Type)
2577                           and then VM_Target = No_VM
2578                         then
2579                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2580                            Error_Msg_N
2581                              ("\use appropriate corresponding type in C "
2582                               & "(e.g. char)?", Formal);
2583
2584                         --  Check suspicious tagged type
2585
2586                         elsif (Is_Tagged_Type (F_Type)
2587                                 or else (Is_Access_Type (F_Type)
2588                                            and then
2589                                              Is_Tagged_Type
2590                                                (Designated_Type (F_Type))))
2591                           and then Convention (E) = Convention_C
2592                         then
2593                            Error_Msg_N
2594                              ("?& involves a tagged type which does not "
2595                               & "correspond to any C type!", Formal);
2596
2597                         --  Check wrong convention subprogram pointer
2598
2599                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2600                           and then not Has_Foreign_Convention (F_Type)
2601                         then
2602                            Error_Msg_N
2603                              ("?subprogram pointer & should "
2604                               & "have foreign convention!", Formal);
2605                            Error_Msg_Sloc := Sloc (F_Type);
2606                            Error_Msg_NE
2607                              ("\?add Convention pragma to declaration of &#",
2608                               Formal, F_Type);
2609                         end if;
2610
2611                         --  Turn off name qualification after message output
2612
2613                         Error_Msg_Qual_Level := 0;
2614                      end if;
2615
2616                      --  Check for unconstrained array in exported foreign
2617                      --  convention case.
2618
2619                      if Has_Foreign_Convention (E)
2620                        and then not Is_Imported (E)
2621                        and then Is_Array_Type (F_Type)
2622                        and then not Is_Constrained (F_Type)
2623                        and then Warn_On_Export_Import
2624
2625                        --  Exclude VM case, since both .NET and JVM can handle
2626                        --  unconstrained arrays without a problem.
2627
2628                        and then VM_Target = No_VM
2629                      then
2630                         Error_Msg_Qual_Level := 1;
2631
2632                         --  If this is an inherited operation, place the
2633                         --  warning on the derived type declaration, rather
2634                         --  than on the original subprogram.
2635
2636                         if Nkind (Original_Node (Parent (E))) =
2637                           N_Full_Type_Declaration
2638                         then
2639                            Warn_Node := Parent (E);
2640
2641                            if Formal = First_Formal (E) then
2642                               Error_Msg_NE
2643                                 ("?in inherited operation&", Warn_Node, E);
2644                            end if;
2645                         else
2646                            Warn_Node := Formal;
2647                         end if;
2648
2649                         Error_Msg_NE
2650                           ("?type of argument& is unconstrained array",
2651                            Warn_Node, Formal);
2652                         Error_Msg_NE
2653                           ("?foreign caller must pass bounds explicitly",
2654                            Warn_Node, Formal);
2655                         Error_Msg_Qual_Level := 0;
2656                      end if;
2657
2658                      if not From_With_Type (F_Type) then
2659                         if Is_Access_Type (F_Type) then
2660                            F_Type := Designated_Type (F_Type);
2661                         end if;
2662
2663                         --  If the formal is an anonymous_access_to_subprogram
2664                         --  freeze the  subprogram type as well, to prevent
2665                         --  scope anomalies in gigi, because there is no other
2666                         --  clear point at which it could be frozen.
2667
2668                         if Is_Itype (Etype (Formal))
2669                           and then Ekind (F_Type) = E_Subprogram_Type
2670                         then
2671                            Freeze_And_Append (F_Type, N, Result);
2672                         end if;
2673                      end if;
2674
2675                      Next_Formal (Formal);
2676                   end loop;
2677
2678                   --  Case of function: similar checks on return type
2679
2680                   if Ekind (E) = E_Function then
2681
2682                      --  Freeze return type
2683
2684                      R_Type := Etype (E);
2685                      Freeze_And_Append (R_Type, N, Result);
2686
2687                      --  Check suspicious return type for C function
2688
2689                      if Warn_On_Export_Import
2690                        and then (Convention (E) = Convention_C
2691                                    or else
2692                                  Convention (E) = Convention_CPP)
2693                        and then (Is_Imported (E) or else Is_Exported (E))
2694                      then
2695                         --  Check suspicious return of fat C pointer
2696
2697                         if Is_Access_Type (R_Type)
2698                           and then Esize (R_Type) > Ttypes.System_Address_Size
2699                           and then not Has_Warnings_Off (E)
2700                           and then not Has_Warnings_Off (R_Type)
2701                         then
2702                            Error_Msg_N
2703                              ("?return type of& does not "
2704                               & "correspond to C pointer!", E);
2705
2706                         --  Check suspicious return of boolean
2707
2708                         elsif Root_Type (R_Type) = Standard_Boolean
2709                           and then Convention (R_Type) = Convention_Ada
2710                           and then VM_Target = No_VM
2711                           and then not Has_Warnings_Off (E)
2712                           and then not Has_Warnings_Off (R_Type)
2713                           and then not Has_Size_Clause (R_Type)
2714                         then
2715                            declare
2716                               N : constant Node_Id :=
2717                                     Result_Definition (Declaration_Node (E));
2718                            begin
2719                               Error_Msg_NE
2720                                 ("return type of & is an 8-bit Ada Boolean?",
2721                                  N, E);
2722                               Error_Msg_NE
2723                                 ("\use appropriate corresponding type in C "
2724                                  & "(e.g. char)?", N, E);
2725                            end;
2726
2727                         --  Check suspicious return tagged type
2728
2729                         elsif (Is_Tagged_Type (R_Type)
2730                                 or else (Is_Access_Type (R_Type)
2731                                            and then
2732                                              Is_Tagged_Type
2733                                                (Designated_Type (R_Type))))
2734                           and then Convention (E) = Convention_C
2735                           and then not Has_Warnings_Off (E)
2736                           and then not Has_Warnings_Off (R_Type)
2737                         then
2738                            Error_Msg_N
2739                              ("?return type of & does not "
2740                               & "correspond to C type!", E);
2741
2742                         --  Check return of wrong convention subprogram pointer
2743
2744                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2745                           and then not Has_Foreign_Convention (R_Type)
2746                           and then not Has_Warnings_Off (E)
2747                           and then not Has_Warnings_Off (R_Type)
2748                         then
2749                            Error_Msg_N
2750                              ("?& should return a foreign "
2751                               & "convention subprogram pointer", E);
2752                            Error_Msg_Sloc := Sloc (R_Type);
2753                            Error_Msg_NE
2754                              ("\?add Convention pragma to declaration of& #",
2755                               E, R_Type);
2756                         end if;
2757                      end if;
2758
2759                      --  Give warning for suspicious return of a result of an
2760                      --  unconstrained array type in a foreign convention
2761                      --  function.
2762
2763                      if Has_Foreign_Convention (E)
2764
2765                        --  We are looking for a return of unconstrained array
2766
2767                        and then Is_Array_Type (R_Type)
2768                        and then not Is_Constrained (R_Type)
2769
2770                        --  Exclude imported routines, the warning does not
2771                        --  belong on the import, but on the routine definition.
2772
2773                        and then not Is_Imported (E)
2774
2775                        --  Exclude VM case, since both .NET and JVM can handle
2776                        --  return of unconstrained arrays without a problem.
2777
2778                        and then VM_Target = No_VM
2779
2780                        --  Check that general warning is enabled, and that it
2781                        --  is not suppressed for this particular case.
2782
2783                        and then Warn_On_Export_Import
2784                        and then not Has_Warnings_Off (E)
2785                        and then not Has_Warnings_Off (R_Type)
2786                      then
2787                         Error_Msg_N
2788                           ("?foreign convention function& should not " &
2789                            "return unconstrained array!", E);
2790                      end if;
2791                   end if;
2792                end;
2793             end if;
2794
2795             --  Must freeze its parent first if it is a derived subprogram
2796
2797             if Present (Alias (E)) then
2798                Freeze_And_Append (Alias (E), N, Result);
2799             end if;
2800
2801             --  We don't freeze internal subprograms, because we don't normally
2802             --  want addition of extra formals or mechanism setting to happen
2803             --  for those. However we do pass through predefined dispatching
2804             --  cases, since extra formals may be needed in some cases, such as
2805             --  for the stream 'Input function (build-in-place formals).
2806
2807             if not Is_Internal (E)
2808               or else Is_Predefined_Dispatching_Operation (E)
2809             then
2810                Freeze_Subprogram (E);
2811             end if;
2812
2813          --  Here for other than a subprogram or type
2814
2815          else
2816             --  If entity has a type, and it is not a generic unit, then
2817             --  freeze it first (RM 13.14(10)).
2818
2819             if Present (Etype (E))
2820               and then Ekind (E) /= E_Generic_Function
2821             then
2822                Freeze_And_Append (Etype (E), N, Result);
2823             end if;
2824
2825             --  Special processing for objects created by object declaration
2826
2827             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2828
2829                --  Abstract type allowed only for C++ imported variables or
2830                --  constants.
2831
2832                --  Note: we inhibit this check for objects that do not come
2833                --  from source because there is at least one case (the
2834                --  expansion of x'class'input where x is abstract) where we
2835                --  legitimately generate an abstract object.
2836
2837                if Is_Abstract_Type (Etype (E))
2838                  and then Comes_From_Source (Parent (E))
2839                  and then not (Is_Imported (E)
2840                                  and then Is_CPP_Class (Etype (E)))
2841                then
2842                   Error_Msg_N ("type of object cannot be abstract",
2843                                Object_Definition (Parent (E)));
2844
2845                   if Is_CPP_Class (Etype (E)) then
2846                      Error_Msg_NE
2847                        ("\} may need a cpp_constructor",
2848                        Object_Definition (Parent (E)), Etype (E));
2849                   end if;
2850                end if;
2851
2852                --  For object created by object declaration, perform required
2853                --  categorization (preelaborate and pure) checks. Defer these
2854                --  checks to freeze time since pragma Import inhibits default
2855                --  initialization and thus pragma Import affects these checks.
2856
2857                Validate_Object_Declaration (Declaration_Node (E));
2858
2859                --  If there is an address clause, check that it is valid
2860
2861                Check_Address_Clause (E);
2862
2863                --  If the object needs any kind of default initialization, an
2864                --  error must be issued if No_Default_Initialization applies.
2865                --  The check doesn't apply to imported objects, which are not
2866                --  ever default initialized, and is why the check is deferred
2867                --  until freezing, at which point we know if Import applies.
2868                --  Deferred constants are also exempted from this test because
2869                --  their completion is explicit, or through an import pragma.
2870
2871                if Ekind (E) = E_Constant
2872                  and then Present (Full_View (E))
2873                then
2874                   null;
2875
2876                elsif Comes_From_Source (E)
2877                  and then not Is_Imported (E)
2878                  and then not Has_Init_Expression (Declaration_Node (E))
2879                  and then
2880                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2881                       and then not No_Initialization (Declaration_Node (E))
2882                       and then not Is_Value_Type (Etype (E))
2883                       and then not Suppress_Init_Proc (Etype (E)))
2884                     or else
2885                       (Needs_Simple_Initialization (Etype (E))
2886                         and then not Is_Internal (E)))
2887                then
2888                   Has_Default_Initialization := True;
2889                   Check_Restriction
2890                     (No_Default_Initialization, Declaration_Node (E));
2891                end if;
2892
2893                --  Check that a Thread_Local_Storage variable does not have
2894                --  default initialization, and any explicit initialization must
2895                --  either be the null constant or a static constant.
2896
2897                if Has_Pragma_Thread_Local_Storage (E) then
2898                   declare
2899                      Decl : constant Node_Id := Declaration_Node (E);
2900                   begin
2901                      if Has_Default_Initialization
2902                        or else
2903                          (Has_Init_Expression (Decl)
2904                             and then
2905                              (No (Expression (Decl))
2906                                 or else not
2907                                   (Is_Static_Expression (Expression (Decl))
2908                                      or else
2909                                    Nkind (Expression (Decl)) = N_Null)))
2910                      then
2911                         Error_Msg_NE
2912                           ("Thread_Local_Storage variable& is "
2913                            & "improperly initialized", Decl, E);
2914                         Error_Msg_NE
2915                           ("\only allowed initialization is explicit "
2916                            & "NULL or static expression", Decl, E);
2917                      end if;
2918                   end;
2919                end if;
2920
2921                --  For imported objects, set Is_Public unless there is also an
2922                --  address clause, which means that there is no external symbol
2923                --  needed for the Import (Is_Public may still be set for other
2924                --  unrelated reasons). Note that we delayed this processing
2925                --  till freeze time so that we can be sure not to set the flag
2926                --  if there is an address clause. If there is such a clause,
2927                --  then the only purpose of the Import pragma is to suppress
2928                --  implicit initialization.
2929
2930                if Is_Imported (E)
2931                  and then No (Address_Clause (E))
2932                then
2933                   Set_Is_Public (E);
2934                end if;
2935
2936                --  For convention C objects of an enumeration type, warn if
2937                --  the size is not integer size and no explicit size given.
2938                --  Skip warning for Boolean, and Character, assume programmer
2939                --  expects 8-bit sizes for these cases.
2940
2941                if (Convention (E) = Convention_C
2942                     or else
2943                    Convention (E) = Convention_CPP)
2944                  and then Is_Enumeration_Type (Etype (E))
2945                  and then not Is_Character_Type (Etype (E))
2946                  and then not Is_Boolean_Type (Etype (E))
2947                  and then Esize (Etype (E)) < Standard_Integer_Size
2948                  and then not Has_Size_Clause (E)
2949                then
2950                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2951                   Error_Msg_N
2952                     ("?convention C enumeration object has size less than ^",
2953                      E);
2954                   Error_Msg_N ("\?use explicit size clause to set size", E);
2955                end if;
2956             end if;
2957
2958             --  Check that a constant which has a pragma Volatile[_Components]
2959             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2960
2961             --  Note: Atomic[_Components] also sets Volatile[_Components]
2962
2963             if Ekind (E) = E_Constant
2964               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2965               and then not Is_Imported (E)
2966             then
2967                --  Make sure we actually have a pragma, and have not merely
2968                --  inherited the indication from elsewhere (e.g. an address
2969                --  clause, which is not good enough in RM terms!)
2970
2971                if Has_Rep_Pragma (E, Name_Atomic)
2972                     or else
2973                   Has_Rep_Pragma (E, Name_Atomic_Components)
2974                then
2975                   Error_Msg_N
2976                     ("stand alone atomic constant must be " &
2977                      "imported (RM C.6(13))", E);
2978
2979                elsif Has_Rep_Pragma (E, Name_Volatile)
2980                        or else
2981                      Has_Rep_Pragma (E, Name_Volatile_Components)
2982                then
2983                   Error_Msg_N
2984                     ("stand alone volatile constant must be " &
2985                      "imported (RM C.6(13))", E);
2986                end if;
2987             end if;
2988
2989             --  Static objects require special handling
2990
2991             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2992               and then Is_Statically_Allocated (E)
2993             then
2994                Freeze_Static_Object (E);
2995             end if;
2996
2997             --  Remaining step is to layout objects
2998
2999             if Ekind (E) = E_Variable
3000                  or else
3001                Ekind (E) = E_Constant
3002                  or else
3003                Ekind (E) = E_Loop_Parameter
3004                  or else
3005                Is_Formal (E)
3006             then
3007                Layout_Object (E);
3008             end if;
3009          end if;
3010
3011       --  Case of a type or subtype being frozen
3012
3013       else
3014          --  We used to check here that a full type must have preelaborable
3015          --  initialization if it completes a private type specified with
3016          --  pragma Preelaborable_Initialization, but that missed cases where
3017          --  the types occur within a generic package, since the freezing
3018          --  that occurs within a containing scope generally skips traversal
3019          --  of a generic unit's declarations (those will be frozen within
3020          --  instances). This check was moved to Analyze_Package_Specification.
3021
3022          --  The type may be defined in a generic unit. This can occur when
3023          --  freezing a generic function that returns the type (which is
3024          --  defined in a parent unit). It is clearly meaningless to freeze
3025          --  this type. However, if it is a subtype, its size may be determi-
3026          --  nable and used in subsequent checks, so might as well try to
3027          --  compute it.
3028
3029          if Present (Scope (E))
3030            and then Is_Generic_Unit (Scope (E))
3031          then
3032             Check_Compile_Time_Size (E);
3033             return No_List;
3034          end if;
3035
3036          --  Deal with special cases of freezing for subtype
3037
3038          if E /= Base_Type (E) then
3039
3040             --  Before we do anything else, a specialized test for the case of
3041             --  a size given for an array where the array needs to be packed,
3042             --  but was not so the size cannot be honored. This would of course
3043             --  be caught by the backend, and indeed we don't catch all cases.
3044             --  The point is that we can give a better error message in those
3045             --  cases that we do catch with the circuitry here. Also if pragma
3046             --  Implicit_Packing is set, this is where the packing occurs.
3047
3048             --  The reason we do this so early is that the processing in the
3049             --  automatic packing case affects the layout of the base type, so
3050             --  it must be done before we freeze the base type.
3051
3052             if Is_Array_Type (E) then
3053                declare
3054                   Lo, Hi : Node_Id;
3055                   Ctyp   : constant Entity_Id := Component_Type (E);
3056
3057                begin
3058                   --  Check enabling conditions. These are straightforward
3059                   --  except for the test for a limited composite type. This
3060                   --  eliminates the rare case of a array of limited components
3061                   --  where there are issues of whether or not we can go ahead
3062                   --  and pack the array (since we can't freely pack and unpack
3063                   --  arrays if they are limited).
3064
3065                   --  Note that we check the root type explicitly because the
3066                   --  whole point is we are doing this test before we have had
3067                   --  a chance to freeze the base type (and it is that freeze
3068                   --  action that causes stuff to be inherited).
3069
3070                   if Present (Size_Clause (E))
3071                     and then Known_Static_Esize (E)
3072                     and then not Is_Packed (E)
3073                     and then not Has_Pragma_Pack (E)
3074                     and then Number_Dimensions (E) = 1
3075                     and then not Has_Component_Size_Clause (E)
3076                     and then Known_Static_Esize (Ctyp)
3077                     and then not Is_Limited_Composite (E)
3078                     and then not Is_Packed (Root_Type (E))
3079                     and then not Has_Component_Size_Clause (Root_Type (E))
3080                     and then not CodePeer_Mode
3081                   then
3082                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3083
3084                      if Compile_Time_Known_Value (Lo)
3085                        and then Compile_Time_Known_Value (Hi)
3086                        and then Known_Static_RM_Size (Ctyp)
3087                        and then RM_Size (Ctyp) < 64
3088                      then
3089                         declare
3090                            Lov  : constant Uint      := Expr_Value (Lo);
3091                            Hiv  : constant Uint      := Expr_Value (Hi);
3092                            Len  : constant Uint      := UI_Max
3093                                                          (Uint_0,
3094                                                           Hiv - Lov + 1);
3095                            Rsiz : constant Uint      := RM_Size (Ctyp);
3096                            SZ   : constant Node_Id   := Size_Clause (E);
3097                            Btyp : constant Entity_Id := Base_Type (E);
3098
3099                         --  What we are looking for here is the situation where
3100                         --  the RM_Size given would be exactly right if there
3101                         --  was a pragma Pack (resulting in the component size
3102                         --  being the same as the RM_Size). Furthermore, the
3103                         --  component type size must be an odd size (not a
3104                         --  multiple of storage unit). If the component RM size
3105                         --  is an exact number of storage units that is a power
3106                         --  of two, the array is not packed and has a standard
3107                         --  representation.
3108
3109                         begin
3110                            if RM_Size (E) = Len * Rsiz
3111                              and then Rsiz mod System_Storage_Unit /= 0
3112                            then
3113                               --  For implicit packing mode, just set the
3114                               --  component size silently.
3115
3116                               if Implicit_Packing then
3117                                  Set_Component_Size       (Btyp, Rsiz);
3118                                  Set_Is_Bit_Packed_Array  (Btyp);
3119                                  Set_Is_Packed            (Btyp);
3120                                  Set_Has_Non_Standard_Rep (Btyp);
3121
3122                                  --  Otherwise give an error message
3123
3124                               else
3125                                  Error_Msg_NE
3126                                    ("size given for& too small", SZ, E);
3127                                  Error_Msg_N -- CODEFIX
3128                                    ("\use explicit pragma Pack "
3129                                     & "or use pragma Implicit_Packing", SZ);
3130                               end if;
3131
3132                            elsif RM_Size (E) = Len * Rsiz
3133                              and then Implicit_Packing
3134                              and then
3135                                (Rsiz / System_Storage_Unit = 1
3136                                  or else Rsiz / System_Storage_Unit = 2
3137                                  or else Rsiz / System_Storage_Unit = 4)
3138                            then
3139
3140                               --  Not a packed array, but indicate the desired
3141                               --  component size, for the back-end.
3142
3143                               Set_Component_Size (Btyp, Rsiz);
3144                            end if;
3145                         end;
3146                      end if;
3147                   end if;
3148                end;
3149             end if;
3150
3151             --  If ancestor subtype present, freeze that first. Note that this
3152             --  will also get the base type frozen. Need RM reference ???
3153
3154             Atype := Ancestor_Subtype (E);
3155
3156             if Present (Atype) then
3157                Freeze_And_Append (Atype, N, Result);
3158
3159             --  No ancestor subtype present
3160
3161             else
3162                --  See if we have a nearest ancestor that has a predicate.
3163                --  That catches the case of derived type with a predicate.
3164                --  Need RM reference here ???
3165
3166                Atype := Nearest_Ancestor (E);
3167
3168                if Present (Atype) and then Has_Predicates (Atype) then
3169                   Freeze_And_Append (Atype, N, Result);
3170                end if;
3171
3172                --  Freeze base type before freezing the entity (RM 13.14(15))
3173
3174                if E /= Base_Type (E) then
3175                   Freeze_And_Append (Base_Type (E), N, Result);
3176                end if;
3177             end if;
3178
3179          --  For a derived type, freeze its parent type first (RM 13.14(15))
3180
3181          elsif Is_Derived_Type (E) then
3182             Freeze_And_Append (Etype (E), N, Result);
3183             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3184          end if;
3185
3186          --  For array type, freeze index types and component type first
3187          --  before freezing the array (RM 13.14(15)).
3188
3189          if Is_Array_Type (E) then
3190             declare
3191                FS     : constant Entity_Id := First_Subtype (E);
3192                Ctyp   : constant Entity_Id := Component_Type (E);
3193                Clause : Entity_Id;
3194
3195                Non_Standard_Enum : Boolean := False;
3196                --  Set true if any of the index types is an enumeration type
3197                --  with a non-standard representation.
3198
3199             begin
3200                Freeze_And_Append (Ctyp, N, Result);
3201
3202                Indx := First_Index (E);
3203                while Present (Indx) loop
3204                   Freeze_And_Append (Etype (Indx), N, Result);
3205
3206                   if Is_Enumeration_Type (Etype (Indx))
3207                     and then Has_Non_Standard_Rep (Etype (Indx))
3208                   then
3209                      Non_Standard_Enum := True;
3210                   end if;
3211
3212                   Next_Index (Indx);
3213                end loop;
3214
3215                --  Processing that is done only for base types
3216
3217                if Ekind (E) = E_Array_Type then
3218
3219                   --  Propagate flags for component type
3220
3221                   if Is_Controlled (Component_Type (E))
3222                     or else Has_Controlled_Component (Ctyp)
3223                   then
3224                      Set_Has_Controlled_Component (E);
3225                   end if;
3226
3227                   if Has_Unchecked_Union (Component_Type (E)) then
3228                      Set_Has_Unchecked_Union (E);
3229                   end if;
3230
3231                   --  If packing was requested or if the component size was set
3232                   --  explicitly, then see if bit packing is required. This
3233                   --  processing is only done for base types, since all the
3234                   --  representation aspects involved are type-related. This
3235                   --  is not just an optimization, if we start processing the
3236                   --  subtypes, they interfere with the settings on the base
3237                   --  type (this is because Is_Packed has a slightly different
3238                   --  meaning before and after freezing).
3239
3240                   declare
3241                      Csiz : Uint;
3242                      Esiz : Uint;
3243
3244                   begin
3245                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3246                        and then Known_Static_RM_Size (Ctyp)
3247                        and then not Has_Component_Size_Clause (E)
3248                      then
3249                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3250
3251                      elsif Known_Component_Size (E) then
3252                         Csiz := Component_Size (E);
3253
3254                      elsif not Known_Static_Esize (Ctyp) then
3255                         Csiz := Uint_0;
3256
3257                      else
3258                         Esiz := Esize (Ctyp);
3259
3260                         --  We can set the component size if it is less than
3261                         --  16, rounding it up to the next storage unit size.
3262
3263                         if Esiz <= 8 then
3264                            Csiz := Uint_8;
3265                         elsif Esiz <= 16 then
3266                            Csiz := Uint_16;
3267                         else
3268                            Csiz := Uint_0;
3269                         end if;
3270
3271                         --  Set component size up to match alignment if it
3272                         --  would otherwise be less than the alignment. This
3273                         --  deals with cases of types whose alignment exceeds
3274                         --  their size (padded types).
3275
3276                         if Csiz /= 0 then
3277                            declare
3278                               A : constant Uint := Alignment_In_Bits (Ctyp);
3279                            begin
3280                               if Csiz < A then
3281                                  Csiz := A;
3282                               end if;
3283                            end;
3284                         end if;
3285                      end if;
3286
3287                      --  Case of component size that may result in packing
3288
3289                      if 1 <= Csiz and then Csiz <= 64 then
3290                         declare
3291                            Ent         : constant Entity_Id :=
3292                                            First_Subtype (E);
3293                            Pack_Pragma : constant Node_Id :=
3294                                            Get_Rep_Pragma (Ent, Name_Pack);
3295                            Comp_Size_C : constant Node_Id :=
3296                                            Get_Attribute_Definition_Clause
3297                                              (Ent, Attribute_Component_Size);
3298                         begin
3299                            --  Warn if we have pack and component size so that
3300                            --  the pack is ignored.
3301
3302                            --  Note: here we must check for the presence of a
3303                            --  component size before checking for a Pack pragma
3304                            --  to deal with the case where the array type is a
3305                            --  derived type whose parent is currently private.
3306
3307                            if Present (Comp_Size_C)
3308                              and then Has_Pragma_Pack (Ent)
3309                              and then Warn_On_Redundant_Constructs
3310                            then
3311                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3312                               Error_Msg_NE
3313                                 ("?pragma Pack for& ignored!",
3314                                  Pack_Pragma, Ent);
3315                               Error_Msg_N
3316                                 ("\?explicit component size given#!",
3317                                  Pack_Pragma);
3318                               Set_Is_Packed (Base_Type (Ent), False);
3319                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3320                            end if;
3321
3322                            --  Set component size if not already set by a
3323                            --  component size clause.
3324
3325                            if not Present (Comp_Size_C) then
3326                               Set_Component_Size (E, Csiz);
3327                            end if;
3328
3329                            --  Check for base type of 8, 16, 32 bits, where an
3330                            --  unsigned subtype has a length one less than the
3331                            --  base type (e.g. Natural subtype of Integer).
3332
3333                            --  In such cases, if a component size was not set
3334                            --  explicitly, then generate a warning.
3335
3336                            if Has_Pragma_Pack (E)
3337                              and then not Present (Comp_Size_C)
3338                              and then
3339                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3340                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3341                            then
3342                               Error_Msg_Uint_1 := Csiz;
3343
3344                               if Present (Pack_Pragma) then
3345                                  Error_Msg_N
3346                                    ("?pragma Pack causes component size "
3347                                     & "to be ^!", Pack_Pragma);
3348                                  Error_Msg_N
3349                                    ("\?use Component_Size to set "
3350                                     & "desired value!", Pack_Pragma);
3351                               end if;
3352                            end if;
3353
3354                            --  Actual packing is not needed for 8, 16, 32, 64.
3355                            --  Also not needed for 24 if alignment is 1.
3356
3357                            if        Csiz = 8
3358                              or else Csiz = 16
3359                              or else Csiz = 32
3360                              or else Csiz = 64
3361                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3362                            then
3363                               --  Here the array was requested to be packed,
3364                               --  but the packing request had no effect, so
3365                               --  Is_Packed is reset.
3366
3367                               --  Note: semantically this means that we lose
3368                               --  track of the fact that a derived type
3369                               --  inherited a pragma Pack that was non-
3370                               --  effective, but that seems fine.
3371
3372                               --  We regard a Pack pragma as a request to set
3373                               --  a representation characteristic, and this
3374                               --  request may be ignored.
3375
3376                               Set_Is_Packed           (Base_Type (E), False);
3377                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3378
3379                               if Known_Static_Esize (Component_Type (E))
3380                                 and then Esize (Component_Type (E)) = Csiz
3381                               then
3382                                  Set_Has_Non_Standard_Rep
3383                                    (Base_Type (E), False);
3384                               end if;
3385
3386                            --  In all other cases, packing is indeed needed
3387
3388                            else
3389                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3390                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3391                               Set_Is_Packed            (Base_Type (E), True);
3392                            end if;
3393                         end;
3394                      end if;
3395                   end;
3396
3397                   --  Check for Atomic_Components or Aliased with unsuitable
3398                   --  packing or explicit component size clause given.
3399
3400                   if (Has_Atomic_Components (E)
3401                        or else Has_Aliased_Components (E))
3402                     and then (Has_Component_Size_Clause (E)
3403                                or else Is_Packed (E))
3404                   then
3405                      Alias_Atomic_Check : declare
3406
3407                         procedure Complain_CS (T : String);
3408                         --  Outputs error messages for incorrect CS clause or
3409                         --  pragma Pack for aliased or atomic components (T is
3410                         --  "aliased" or "atomic");
3411
3412                         -----------------
3413                         -- Complain_CS --
3414                         -----------------
3415
3416                         procedure Complain_CS (T : String) is
3417                         begin
3418                            if Has_Component_Size_Clause (E) then
3419                               Clause :=
3420                                 Get_Attribute_Definition_Clause
3421                                   (FS, Attribute_Component_Size);
3422
3423                               if Known_Static_Esize (Ctyp) then
3424                                  Error_Msg_N
3425                                    ("incorrect component size for "
3426                                     & T & " components", Clause);
3427                                  Error_Msg_Uint_1 := Esize (Ctyp);
3428                                  Error_Msg_N
3429                                    ("\only allowed value is^", Clause);
3430
3431                               else
3432                                  Error_Msg_N
3433                                    ("component size cannot be given for "
3434                                     & T & " components", Clause);
3435                               end if;
3436
3437                            else
3438                               Error_Msg_N
3439                                 ("cannot pack " & T & " components",
3440                                  Get_Rep_Pragma (FS, Name_Pack));
3441                            end if;
3442
3443                            return;
3444                         end Complain_CS;
3445
3446                      --  Start of processing for Alias_Atomic_Check
3447
3448                      begin
3449                         --  Case where component size has no effect. First
3450                         --  check for object size of component type known
3451                         --  and a multiple of the storage unit size.
3452
3453                         if Known_Static_Esize (Ctyp)
3454                           and then Esize (Ctyp) mod System_Storage_Unit = 0
3455
3456                           --  OK in both packing case and component size case
3457                           --  if RM size is known and static and the same as
3458                           --  the object size.
3459
3460                           and then
3461                             ((Known_Static_RM_Size (Ctyp)
3462                                and then Esize (Ctyp) = RM_Size (Ctyp))
3463
3464                              --  Or if we have an explicit component size
3465                              --  clause and the component size and object size
3466                              --  are equal.
3467
3468                              or else
3469                                  (Has_Component_Size_Clause (E)
3470                                  and then Component_Size (E) = Esize (Ctyp)))
3471                         then
3472                            null;
3473
3474                         elsif Has_Aliased_Components (E)
3475                           or else Is_Aliased (Ctyp)
3476                         then
3477                            Complain_CS ("aliased");
3478
3479                         elsif Has_Atomic_Components (E)
3480                           or else Is_Atomic (Ctyp)
3481                         then
3482                            Complain_CS ("atomic");
3483                         end if;
3484                      end Alias_Atomic_Check;
3485                   end if;
3486
3487                   --  Warn for case of atomic type
3488
3489                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3490
3491                   if Present (Clause)
3492                     and then not Addressable (Component_Size (FS))
3493                   then
3494                      Error_Msg_NE
3495                        ("non-atomic components of type& may not be "
3496                         & "accessible by separate tasks?", Clause, E);
3497
3498                      if Has_Component_Size_Clause (E) then
3499                         Error_Msg_Sloc :=
3500                           Sloc
3501                             (Get_Attribute_Definition_Clause
3502                                  (FS, Attribute_Component_Size));
3503                         Error_Msg_N
3504                           ("\because of component size clause#?",
3505                            Clause);
3506
3507                      elsif Has_Pragma_Pack (E) then
3508                         Error_Msg_Sloc :=
3509                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3510                         Error_Msg_N
3511                           ("\because of pragma Pack#?", Clause);
3512                      end if;
3513                   end if;
3514
3515                --  Processing that is done only for subtypes
3516
3517                else
3518                   --  Acquire alignment from base type
3519
3520                   if Unknown_Alignment (E) then
3521                      Set_Alignment (E, Alignment (Base_Type (E)));
3522                      Adjust_Esize_Alignment (E);
3523                   end if;
3524                end if;
3525
3526                --  For bit-packed arrays, check the size
3527
3528                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3529                   declare
3530                      SizC : constant Node_Id := Size_Clause (E);
3531
3532                      Discard : Boolean;
3533                      pragma Warnings (Off, Discard);
3534
3535                   begin
3536                      --  It is not clear if it is possible to have no size
3537                      --  clause at this stage, but it is not worth worrying
3538                      --  about. Post error on the entity name in the size
3539                      --  clause if present, else on the type entity itself.
3540
3541                      if Present (SizC) then
3542                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3543                      else
3544                         Check_Size (E, E, RM_Size (E), Discard);
3545                      end if;
3546                   end;
3547                end if;
3548
3549                --  If any of the index types was an enumeration type with a
3550                --  non-standard rep clause, then we indicate that the array
3551                --  type is always packed (even if it is not bit packed).
3552
3553                if Non_Standard_Enum then
3554                   Set_Has_Non_Standard_Rep (Base_Type (E));
3555                   Set_Is_Packed            (Base_Type (E));
3556                end if;
3557
3558                Set_Component_Alignment_If_Not_Set (E);
3559
3560                --  If the array is packed, we must create the packed array
3561                --  type to be used to actually implement the type. This is
3562                --  only needed for real array types (not for string literal
3563                --  types, since they are present only for the front end).
3564
3565                if Is_Packed (E)
3566                  and then Ekind (E) /= E_String_Literal_Subtype
3567                then
3568                   Create_Packed_Array_Type (E);
3569                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3570
3571                   --  Size information of packed array type is copied to the
3572                   --  array type, since this is really the representation. But
3573                   --  do not override explicit existing size values. If the
3574                   --  ancestor subtype is constrained the packed_array_type
3575                   --  will be inherited from it, but the size may have been
3576                   --  provided already, and must not be overridden either.
3577
3578                   if not Has_Size_Clause (E)
3579                     and then
3580                       (No (Ancestor_Subtype (E))
3581                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3582                   then
3583                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3584                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3585                   end if;
3586
3587                   if not Has_Alignment_Clause (E) then
3588                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3589                   end if;
3590                end if;
3591
3592                --  For non-packed arrays set the alignment of the array to the
3593                --  alignment of the component type if it is unknown. Skip this
3594                --  in atomic case (atomic arrays may need larger alignments).
3595
3596                if not Is_Packed (E)
3597                  and then Unknown_Alignment (E)
3598                  and then Known_Alignment (Ctyp)
3599                  and then Known_Static_Component_Size (E)
3600                  and then Known_Static_Esize (Ctyp)
3601                  and then Esize (Ctyp) = Component_Size (E)
3602                  and then not Is_Atomic (E)
3603                then
3604                   Set_Alignment (E, Alignment (Component_Type (E)));
3605                end if;
3606             end;
3607
3608          --  For a class-wide type, the corresponding specific type is
3609          --  frozen as well (RM 13.14(15))
3610
3611          elsif Is_Class_Wide_Type (E) then
3612             Freeze_And_Append (Root_Type (E), N, Result);
3613
3614             --  If the base type of the class-wide type is still incomplete,
3615             --  the class-wide remains unfrozen as well. This is legal when
3616             --  E is the formal of a primitive operation of some other type
3617             --  which is being frozen.
3618
3619             if not Is_Frozen (Root_Type (E)) then
3620                Set_Is_Frozen (E, False);
3621                return Result;
3622             end if;
3623
3624             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3625             --  parent of a derived type) and it is a library-level entity,
3626             --  generate an itype reference for it. Otherwise, its first
3627             --  explicit reference may be in an inner scope, which will be
3628             --  rejected by the back-end.
3629
3630             if Is_Itype (E)
3631               and then Is_Compilation_Unit (Scope (E))
3632             then
3633                declare
3634                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3635
3636                begin
3637                   Set_Itype (Ref, E);
3638                   if No (Result) then
3639                      Result := New_List (Ref);
3640                   else
3641                      Append (Ref, Result);
3642                   end if;
3643                end;
3644             end if;
3645
3646             --  The equivalent type associated with a class-wide subtype needs
3647             --  to be frozen to ensure that its layout is done.
3648
3649             if Ekind (E) = E_Class_Wide_Subtype
3650               and then Present (Equivalent_Type (E))
3651             then
3652                Freeze_And_Append (Equivalent_Type (E), N, Result);
3653             end if;
3654
3655          --  For a record (sub)type, freeze all the component types (RM
3656          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3657          --  Is_Record_Type, because we don't want to attempt the freeze for
3658          --  the case of a private type with record extension (we will do that
3659          --  later when the full type is frozen).
3660
3661          elsif Ekind (E) = E_Record_Type
3662            or else Ekind (E) = E_Record_Subtype
3663          then
3664             Freeze_Record_Type (E);
3665
3666          --  For a concurrent type, freeze corresponding record type. This
3667          --  does not correspond to any specific rule in the RM, but the
3668          --  record type is essentially part of the concurrent type.
3669          --  Freeze as well all local entities. This includes record types
3670          --  created for entry parameter blocks, and whatever local entities
3671          --  may appear in the private part.
3672
3673          elsif Is_Concurrent_Type (E) then
3674             if Present (Corresponding_Record_Type (E)) then
3675                Freeze_And_Append
3676                  (Corresponding_Record_Type (E), N, Result);
3677             end if;
3678
3679             Comp := First_Entity (E);
3680             while Present (Comp) loop
3681                if Is_Type (Comp) then
3682                   Freeze_And_Append (Comp, N, Result);
3683
3684                elsif (Ekind (Comp)) /= E_Function then
3685                   if Is_Itype (Etype (Comp))
3686                     and then Underlying_Type (Scope (Etype (Comp))) = E
3687                   then
3688                      Undelay_Type (Etype (Comp));
3689                   end if;
3690
3691                   Freeze_And_Append (Etype (Comp), N, Result);
3692                end if;
3693
3694                Next_Entity (Comp);
3695             end loop;
3696
3697          --  Private types are required to point to the same freeze node as
3698          --  their corresponding full views. The freeze node itself has to
3699          --  point to the partial view of the entity (because from the partial
3700          --  view, we can retrieve the full view, but not the reverse).
3701          --  However, in order to freeze correctly, we need to freeze the full
3702          --  view. If we are freezing at the end of a scope (or within the
3703          --  scope of the private type), the partial and full views will have
3704          --  been swapped, the full view appears first in the entity chain and
3705          --  the swapping mechanism ensures that the pointers are properly set
3706          --  (on scope exit).
3707
3708          --  If we encounter the partial view before the full view (e.g. when
3709          --  freezing from another scope), we freeze the full view, and then
3710          --  set the pointers appropriately since we cannot rely on swapping to
3711          --  fix things up (subtypes in an outer scope might not get swapped).
3712
3713          elsif Is_Incomplete_Or_Private_Type (E)
3714            and then not Is_Generic_Type (E)
3715          then
3716             --  The construction of the dispatch table associated with library
3717             --  level tagged types forces freezing of all the primitives of the
3718             --  type, which may cause premature freezing of the partial view.
3719             --  For example:
3720
3721             --     package Pkg is
3722             --        type T is tagged private;
3723             --        type DT is new T with private;
3724             --        procedure Prim (X : in out T; Y : in out DT'class);
3725             --     private
3726             --        type T is tagged null record;
3727             --        Obj : T;
3728             --        type DT is new T with null record;
3729             --     end;
3730
3731             --  In this case the type will be frozen later by the usual
3732             --  mechanism: an object declaration, an instantiation, or the
3733             --  end of a declarative part.
3734
3735             if Is_Library_Level_Tagged_Type (E)
3736               and then not Present (Full_View (E))
3737             then
3738                Set_Is_Frozen (E, False);
3739                return Result;
3740
3741             --  Case of full view present
3742
3743             elsif Present (Full_View (E)) then
3744
3745                --  If full view has already been frozen, then no further
3746                --  processing is required
3747
3748                if Is_Frozen (Full_View (E)) then
3749                   Set_Has_Delayed_Freeze (E, False);
3750                   Set_Freeze_Node (E, Empty);
3751                   Check_Debug_Info_Needed (E);
3752
3753                --  Otherwise freeze full view and patch the pointers so that
3754                --  the freeze node will elaborate both views in the back-end.
3755
3756                else
3757                   declare
3758                      Full : constant Entity_Id := Full_View (E);
3759
3760                   begin
3761                      if Is_Private_Type (Full)
3762                        and then Present (Underlying_Full_View (Full))
3763                      then
3764                         Freeze_And_Append
3765                           (Underlying_Full_View (Full), N, Result);
3766                      end if;
3767
3768                      Freeze_And_Append (Full, N, Result);
3769
3770                      if Has_Delayed_Freeze (E) then
3771                         F_Node := Freeze_Node (Full);
3772
3773                         if Present (F_Node) then
3774                            Set_Freeze_Node (E, F_Node);
3775                            Set_Entity (F_Node, E);
3776
3777                         else
3778                            --  {Incomplete,Private}_Subtypes with Full_Views
3779                            --  constrained by discriminants.
3780
3781                            Set_Has_Delayed_Freeze (E, False);
3782                            Set_Freeze_Node (E, Empty);
3783                         end if;
3784                      end if;
3785                   end;
3786
3787                   Check_Debug_Info_Needed (E);
3788                end if;
3789
3790                --  AI-117 requires that the convention of a partial view be the
3791                --  same as the convention of the full view. Note that this is a
3792                --  recognized breach of privacy, but it's essential for logical
3793                --  consistency of representation, and the lack of a rule in
3794                --  RM95 was an oversight.
3795
3796                Set_Convention (E, Convention (Full_View (E)));
3797
3798                Set_Size_Known_At_Compile_Time (E,
3799                  Size_Known_At_Compile_Time (Full_View (E)));
3800
3801                --  Size information is copied from the full view to the
3802                --  incomplete or private view for consistency.
3803
3804                --  We skip this is the full view is not a type. This is very
3805                --  strange of course, and can only happen as a result of
3806                --  certain illegalities, such as a premature attempt to derive
3807                --  from an incomplete type.
3808
3809                if Is_Type (Full_View (E)) then
3810                   Set_Size_Info (E, Full_View (E));
3811                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3812                end if;
3813
3814                return Result;
3815
3816             --  Case of no full view present. If entity is derived or subtype,
3817             --  it is safe to freeze, correctness depends on the frozen status
3818             --  of parent. Otherwise it is either premature usage, or a Taft
3819             --  amendment type, so diagnosis is at the point of use and the
3820             --  type might be frozen later.
3821
3822             elsif E /= Base_Type (E)
3823               or else Is_Derived_Type (E)
3824             then
3825                null;
3826
3827             else
3828                Set_Is_Frozen (E, False);
3829                return No_List;
3830             end if;
3831
3832          --  For access subprogram, freeze types of all formals, the return
3833          --  type was already frozen, since it is the Etype of the function.
3834          --  Formal types can be tagged Taft amendment types, but otherwise
3835          --  they cannot be incomplete.
3836
3837          elsif Ekind (E) = E_Subprogram_Type then
3838             Formal := First_Formal (E);
3839             while Present (Formal) loop
3840                if Ekind (Etype (Formal)) = E_Incomplete_Type
3841                  and then No (Full_View (Etype (Formal)))
3842                  and then not Is_Value_Type (Etype (Formal))
3843                then
3844                   if Is_Tagged_Type (Etype (Formal)) then
3845                      null;
3846
3847                   --  AI05-151: Incomplete types are allowed in access to
3848                   --  subprogram specifications.
3849
3850                   elsif Ada_Version < Ada_2012 then
3851                      Error_Msg_NE
3852                        ("invalid use of incomplete type&", E, Etype (Formal));
3853                   end if;
3854                end if;
3855
3856                Freeze_And_Append (Etype (Formal), N, Result);
3857                Next_Formal (Formal);
3858             end loop;
3859
3860             Freeze_Subprogram (E);
3861
3862          --  For access to a protected subprogram, freeze the equivalent type
3863          --  (however this is not set if we are not generating code or if this
3864          --  is an anonymous type used just for resolution).
3865
3866          elsif Is_Access_Protected_Subprogram_Type (E) then
3867             if Present (Equivalent_Type (E)) then
3868                Freeze_And_Append (Equivalent_Type (E), N, Result);
3869             end if;
3870          end if;
3871
3872          --  Generic types are never seen by the back-end, and are also not
3873          --  processed by the expander (since the expander is turned off for
3874          --  generic processing), so we never need freeze nodes for them.
3875
3876          if Is_Generic_Type (E) then
3877             return Result;
3878          end if;
3879
3880          --  Some special processing for non-generic types to complete
3881          --  representation details not known till the freeze point.
3882
3883          if Is_Fixed_Point_Type (E) then
3884             Freeze_Fixed_Point_Type (E);
3885
3886             --  Some error checks required for ordinary fixed-point type. Defer
3887             --  these till the freeze-point since we need the small and range
3888             --  values. We only do these checks for base types
3889
3890             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3891                if Small_Value (E) < Ureal_2_M_80 then
3892                   Error_Msg_Name_1 := Name_Small;
3893                   Error_Msg_N
3894                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3895
3896                elsif Small_Value (E) > Ureal_2_80 then
3897                   Error_Msg_Name_1 := Name_Small;
3898                   Error_Msg_N
3899                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3900                end if;
3901
3902                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3903                   Error_Msg_Name_1 := Name_First;
3904                   Error_Msg_N
3905                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3906                end if;
3907
3908                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3909                   Error_Msg_Name_1 := Name_Last;
3910                   Error_Msg_N
3911                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3912                end if;
3913             end if;
3914
3915          elsif Is_Enumeration_Type (E) then
3916             Freeze_Enumeration_Type (E);
3917
3918          elsif Is_Integer_Type (E) then
3919             Adjust_Esize_For_Alignment (E);
3920
3921             if Is_Modular_Integer_Type (E)
3922               and then Warn_On_Suspicious_Modulus_Value
3923             then
3924                Check_Suspicious_Modulus (E);
3925             end if;
3926
3927          elsif Is_Access_Type (E) then
3928
3929             --  If a pragma Default_Storage_Pool applies, and this type has no
3930             --  Storage_Pool or Storage_Size clause (which must have occurred
3931             --  before the freezing point), then use the default. This applies
3932             --  only to base types.
3933
3934             if Present (Default_Pool)
3935               and then Is_Base_Type (E)
3936               and then not Has_Storage_Size_Clause (E)
3937               and then No (Associated_Storage_Pool (E))
3938             then
3939                --  Case of pragma Default_Storage_Pool (null)
3940
3941                if Nkind (Default_Pool) = N_Null then
3942                   Set_No_Pool_Assigned (E);
3943
3944                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3945
3946                else
3947                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3948                end if;
3949             end if;
3950
3951             --  Check restriction for standard storage pool
3952
3953             if No (Associated_Storage_Pool (E)) then
3954                Check_Restriction (No_Standard_Storage_Pools, E);
3955             end if;
3956
3957             --  Deal with error message for pure access type. This is not an
3958             --  error in Ada 2005 if there is no pool (see AI-366).
3959
3960             if Is_Pure_Unit_Access_Type (E)
3961               and then (Ada_Version < Ada_2005
3962                          or else not No_Pool_Assigned (E))
3963             then
3964                Error_Msg_N ("named access type not allowed in pure unit", E);
3965
3966                if Ada_Version >= Ada_2005 then
3967                   Error_Msg_N
3968                     ("\would be legal if Storage_Size of 0 given?", E);
3969
3970                elsif No_Pool_Assigned (E) then
3971                   Error_Msg_N
3972                     ("\would be legal in Ada 2005?", E);
3973
3974                else
3975                   Error_Msg_N
3976                     ("\would be legal in Ada 2005 if "
3977                      & "Storage_Size of 0 given?", E);
3978                end if;
3979             end if;
3980          end if;
3981
3982          --  Case of composite types
3983
3984          if Is_Composite_Type (E) then
3985
3986             --  AI-117 requires that all new primitives of a tagged type must
3987             --  inherit the convention of the full view of the type. Inherited
3988             --  and overriding operations are defined to inherit the convention
3989             --  of their parent or overridden subprogram (also specified in
3990             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3991             --  and New_Overloaded_Entity). Here we set the convention of
3992             --  primitives that are still convention Ada, which will ensure
3993             --  that any new primitives inherit the type's convention. Class-
3994             --  wide types can have a foreign convention inherited from their
3995             --  specific type, but are excluded from this since they don't have
3996             --  any associated primitives.
3997
3998             if Is_Tagged_Type (E)
3999               and then not Is_Class_Wide_Type (E)
4000               and then Convention (E) /= Convention_Ada
4001             then
4002                declare
4003                   Prim_List : constant Elist_Id := Primitive_Operations (E);
4004                   Prim      : Elmt_Id;
4005
4006                begin
4007                   Prim := First_Elmt (Prim_List);
4008                   while Present (Prim) loop
4009                      if Convention (Node (Prim)) = Convention_Ada then
4010                         Set_Convention (Node (Prim), Convention (E));
4011                      end if;
4012
4013                      Next_Elmt (Prim);
4014                   end loop;
4015                end;
4016             end if;
4017          end if;
4018
4019          --  Now that all types from which E may depend are frozen, see if the
4020          --  size is known at compile time, if it must be unsigned, or if
4021          --  strict alignment is required
4022
4023          Check_Compile_Time_Size (E);
4024          Check_Unsigned_Type (E);
4025
4026          if Base_Type (E) = E then
4027             Check_Strict_Alignment (E);
4028          end if;
4029
4030          --  Do not allow a size clause for a type which does not have a size
4031          --  that is known at compile time
4032
4033          if Has_Size_Clause (E)
4034            and then not Size_Known_At_Compile_Time (E)
4035          then
4036             --  Suppress this message if errors posted on E, even if we are
4037             --  in all errors mode, since this is often a junk message
4038
4039             if not Error_Posted (E) then
4040                Error_Msg_N
4041                  ("size clause not allowed for variable length type",
4042                   Size_Clause (E));
4043             end if;
4044          end if;
4045
4046          --  Remaining process is to set/verify the representation information,
4047          --  in particular the size and alignment values. This processing is
4048          --  not required for generic types, since generic types do not play
4049          --  any part in code generation, and so the size and alignment values
4050          --  for such types are irrelevant.
4051
4052          if Is_Generic_Type (E) then
4053             return Result;
4054
4055          --  Otherwise we call the layout procedure
4056
4057          else
4058             Layout_Type (E);
4059          end if;
4060
4061          --  End of freeze processing for type entities
4062       end if;
4063
4064       --  Here is where we logically freeze the current entity. If it has a
4065       --  freeze node, then this is the point at which the freeze node is
4066       --  linked into the result list.
4067
4068       if Has_Delayed_Freeze (E) then
4069
4070          --  If a freeze node is already allocated, use it, otherwise allocate
4071          --  a new one. The preallocation happens in the case of anonymous base
4072          --  types, where we preallocate so that we can set First_Subtype_Link.
4073          --  Note that we reset the Sloc to the current freeze location.
4074
4075          if Present (Freeze_Node (E)) then
4076             F_Node := Freeze_Node (E);
4077             Set_Sloc (F_Node, Loc);
4078
4079          else
4080             F_Node := New_Node (N_Freeze_Entity, Loc);
4081             Set_Freeze_Node (E, F_Node);
4082             Set_Access_Types_To_Process (F_Node, No_Elist);
4083             Set_TSS_Elist (F_Node, No_Elist);
4084             Set_Actions (F_Node, No_List);
4085          end if;
4086
4087          Set_Entity (F_Node, E);
4088
4089          if Result = No_List then
4090             Result := New_List (F_Node);
4091          else
4092             Append (F_Node, Result);
4093          end if;
4094
4095          --  A final pass over record types with discriminants. If the type
4096          --  has an incomplete declaration, there may be constrained access
4097          --  subtypes declared elsewhere, which do not depend on the discrimi-
4098          --  nants of the type, and which are used as component types (i.e.
4099          --  the full view is a recursive type). The designated types of these
4100          --  subtypes can only be elaborated after the type itself, and they
4101          --  need an itype reference.
4102
4103          if Ekind (E) = E_Record_Type
4104            and then Has_Discriminants (E)
4105          then
4106             declare
4107                Comp : Entity_Id;
4108                IR   : Node_Id;
4109                Typ  : Entity_Id;
4110
4111             begin
4112                Comp := First_Component (E);
4113                while Present (Comp) loop
4114                   Typ  := Etype (Comp);
4115
4116                   if Ekind (Comp) = E_Component
4117                     and then Is_Access_Type (Typ)
4118                     and then Scope (Typ) /= E
4119                     and then Base_Type (Designated_Type (Typ)) = E
4120                     and then Is_Itype (Designated_Type (Typ))
4121                   then
4122                      IR := Make_Itype_Reference (Sloc (Comp));
4123                      Set_Itype (IR, Designated_Type (Typ));
4124                      Append (IR, Result);
4125                   end if;
4126
4127                   Next_Component (Comp);
4128                end loop;
4129             end;
4130          end if;
4131       end if;
4132
4133       --  When a type is frozen, the first subtype of the type is frozen as
4134       --  well (RM 13.14(15)). This has to be done after freezing the type,
4135       --  since obviously the first subtype depends on its own base type.
4136
4137       if Is_Type (E) then
4138          Freeze_And_Append (First_Subtype (E), N, Result);
4139
4140          --  If we just froze a tagged non-class wide record, then freeze the
4141          --  corresponding class-wide type. This must be done after the tagged
4142          --  type itself is frozen, because the class-wide type refers to the
4143          --  tagged type which generates the class.
4144
4145          if Is_Tagged_Type (E)
4146            and then not Is_Class_Wide_Type (E)
4147            and then Present (Class_Wide_Type (E))
4148          then
4149             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4150          end if;
4151       end if;
4152
4153       Check_Debug_Info_Needed (E);
4154
4155       --  Special handling for subprograms
4156
4157       if Is_Subprogram (E) then
4158
4159          --  If subprogram has address clause then reset Is_Public flag, since
4160          --  we do not want the backend to generate external references.
4161
4162          if Present (Address_Clause (E))
4163            and then not Is_Library_Level_Entity (E)
4164          then
4165             Set_Is_Public (E, False);
4166
4167          --  If no address clause and not intrinsic, then for imported
4168          --  subprogram in main unit, generate descriptor if we are in
4169          --  Propagate_Exceptions mode.
4170
4171          elsif Propagate_Exceptions
4172            and then Is_Imported (E)
4173            and then not Is_Intrinsic_Subprogram (E)
4174            and then Convention (E) /= Convention_Stubbed
4175          then
4176             if Result = No_List then
4177                Result := Empty_List;
4178             end if;
4179          end if;
4180       end if;
4181
4182       return Result;
4183    end Freeze_Entity;
4184
4185    -----------------------------
4186    -- Freeze_Enumeration_Type --
4187    -----------------------------
4188
4189    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4190    begin
4191       --  By default, if no size clause is present, an enumeration type with
4192       --  Convention C is assumed to interface to a C enum, and has integer
4193       --  size. This applies to types. For subtypes, verify that its base
4194       --  type has no size clause either.
4195
4196       if Has_Foreign_Convention (Typ)
4197         and then not Has_Size_Clause (Typ)
4198         and then not Has_Size_Clause (Base_Type (Typ))
4199         and then Esize (Typ) < Standard_Integer_Size
4200       then
4201          Init_Esize (Typ, Standard_Integer_Size);
4202
4203       else
4204          --  If the enumeration type interfaces to C, and it has a size clause
4205          --  that specifies less than int size, it warrants a warning. The
4206          --  user may intend the C type to be an enum or a char, so this is
4207          --  not by itself an error that the Ada compiler can detect, but it
4208          --  it is a worth a heads-up. For Boolean and Character types we
4209          --  assume that the programmer has the proper C type in mind.
4210
4211          if Convention (Typ) = Convention_C
4212            and then Has_Size_Clause (Typ)
4213            and then Esize (Typ) /= Esize (Standard_Integer)
4214            and then not Is_Boolean_Type (Typ)
4215            and then not Is_Character_Type (Typ)
4216          then
4217             Error_Msg_N
4218               ("C enum types have the size of a C int?", Size_Clause (Typ));
4219          end if;
4220
4221          Adjust_Esize_For_Alignment (Typ);
4222       end if;
4223    end Freeze_Enumeration_Type;
4224
4225    -----------------------
4226    -- Freeze_Expression --
4227    -----------------------
4228
4229    procedure Freeze_Expression (N : Node_Id) is
4230       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4231       Typ         : Entity_Id;
4232       Nam         : Entity_Id;
4233       Desig_Typ   : Entity_Id;
4234       P           : Node_Id;
4235       Parent_P    : Node_Id;
4236
4237       Freeze_Outside : Boolean := False;
4238       --  This flag is set true if the entity must be frozen outside the
4239       --  current subprogram. This happens in the case of expander generated
4240       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4241       --  not freeze all entities like other bodies, but which nevertheless
4242       --  may reference entities that have to be frozen before the body and
4243       --  obviously cannot be frozen inside the body.
4244
4245       function In_Exp_Body (N : Node_Id) return Boolean;
4246       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4247       --  it is the handled statement sequence of an expander-generated
4248       --  subprogram (init proc, stream subprogram, or renaming as body).
4249       --  If so, this is not a freezing context.
4250
4251       -----------------
4252       -- In_Exp_Body --
4253       -----------------
4254
4255       function In_Exp_Body (N : Node_Id) return Boolean is
4256          P  : Node_Id;
4257          Id : Entity_Id;
4258
4259       begin
4260          if Nkind (N) = N_Subprogram_Body then
4261             P := N;
4262          else
4263             P := Parent (N);
4264          end if;
4265
4266          if Nkind (P) /= N_Subprogram_Body then
4267             return False;
4268
4269          else
4270             Id := Defining_Unit_Name (Specification (P));
4271
4272             if Nkind (Id) = N_Defining_Identifier
4273               and then (Is_Init_Proc (Id)              or else
4274                         Is_TSS (Id, TSS_Stream_Input)  or else
4275                         Is_TSS (Id, TSS_Stream_Output) or else
4276                         Is_TSS (Id, TSS_Stream_Read)   or else
4277                         Is_TSS (Id, TSS_Stream_Write)  or else
4278                         Nkind (Original_Node (P)) =
4279                           N_Subprogram_Renaming_Declaration)
4280             then
4281                return True;
4282             else
4283                return False;
4284             end if;
4285          end if;
4286       end In_Exp_Body;
4287
4288    --  Start of processing for Freeze_Expression
4289
4290    begin
4291       --  Immediate return if freezing is inhibited. This flag is set by the
4292       --  analyzer to stop freezing on generated expressions that would cause
4293       --  freezing if they were in the source program, but which are not
4294       --  supposed to freeze, since they are created.
4295
4296       if Must_Not_Freeze (N) then
4297          return;
4298       end if;
4299
4300       --  If expression is non-static, then it does not freeze in a default
4301       --  expression, see section "Handling of Default Expressions" in the
4302       --  spec of package Sem for further details. Note that we have to
4303       --  make sure that we actually have a real expression (if we have
4304       --  a subtype indication, we can't test Is_Static_Expression!)
4305
4306       if In_Spec_Exp
4307         and then Nkind (N) in N_Subexpr
4308         and then not Is_Static_Expression (N)
4309       then
4310          return;
4311       end if;
4312
4313       --  Freeze type of expression if not frozen already
4314
4315       Typ := Empty;
4316
4317       if Nkind (N) in N_Has_Etype then
4318          if not Is_Frozen (Etype (N)) then
4319             Typ := Etype (N);
4320
4321          --  Base type may be an derived numeric type that is frozen at
4322          --  the point of declaration, but first_subtype is still unfrozen.
4323
4324          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4325             Typ := First_Subtype (Etype (N));
4326          end if;
4327       end if;
4328
4329       --  For entity name, freeze entity if not frozen already. A special
4330       --  exception occurs for an identifier that did not come from source.
4331       --  We don't let such identifiers freeze a non-internal entity, i.e.
4332       --  an entity that did come from source, since such an identifier was
4333       --  generated by the expander, and cannot have any semantic effect on
4334       --  the freezing semantics. For example, this stops the parameter of
4335       --  an initialization procedure from freezing the variable.
4336
4337       if Is_Entity_Name (N)
4338         and then not Is_Frozen (Entity (N))
4339         and then (Nkind (N) /= N_Identifier
4340                    or else Comes_From_Source (N)
4341                    or else not Comes_From_Source (Entity (N)))
4342       then
4343          Nam := Entity (N);
4344       else
4345          Nam := Empty;
4346       end if;
4347
4348       --  For an allocator freeze designated type if not frozen already
4349
4350       --  For an aggregate whose component type is an access type, freeze the
4351       --  designated type now, so that its freeze does not appear within the
4352       --  loop that might be created in the expansion of the aggregate. If the
4353       --  designated type is a private type without full view, the expression
4354       --  cannot contain an allocator, so the type is not frozen.
4355
4356       --  For a function, we freeze the entity when the subprogram declaration
4357       --  is frozen, but a function call may appear in an initialization proc.
4358       --  before the declaration is frozen. We need to generate the extra
4359       --  formals, if any, to ensure that the expansion of the call includes
4360       --  the proper actuals. This only applies to Ada subprograms, not to
4361       --  imported ones.
4362
4363       Desig_Typ := Empty;
4364
4365       case Nkind (N) is
4366          when N_Allocator =>
4367             Desig_Typ := Designated_Type (Etype (N));
4368
4369          when N_Aggregate =>
4370             if Is_Array_Type (Etype (N))
4371               and then Is_Access_Type (Component_Type (Etype (N)))
4372             then
4373                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4374             end if;
4375
4376          when N_Selected_Component |
4377             N_Indexed_Component    |
4378             N_Slice                =>
4379
4380             if Is_Access_Type (Etype (Prefix (N))) then
4381                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4382             end if;
4383
4384          when N_Identifier =>
4385             if Present (Nam)
4386               and then Ekind (Nam) = E_Function
4387               and then Nkind (Parent (N)) = N_Function_Call
4388               and then Convention (Nam) = Convention_Ada
4389             then
4390                Create_Extra_Formals (Nam);
4391             end if;
4392
4393          when others =>
4394             null;
4395       end case;
4396
4397       if Desig_Typ /= Empty
4398         and then (Is_Frozen (Desig_Typ)
4399                    or else (not Is_Fully_Defined (Desig_Typ)))
4400       then
4401          Desig_Typ := Empty;
4402       end if;
4403
4404       --  All done if nothing needs freezing
4405
4406       if No (Typ)
4407         and then No (Nam)
4408         and then No (Desig_Typ)
4409       then
4410          return;
4411       end if;
4412
4413       --  Loop for looking at the right place to insert the freeze nodes,
4414       --  exiting from the loop when it is appropriate to insert the freeze
4415       --  node before the current node P.
4416
4417       --  Also checks some special exceptions to the freezing rules. These
4418       --  cases result in a direct return, bypassing the freeze action.
4419
4420       P := N;
4421       loop
4422          Parent_P := Parent (P);
4423
4424          --  If we don't have a parent, then we are not in a well-formed tree.
4425          --  This is an unusual case, but there are some legitimate situations
4426          --  in which this occurs, notably when the expressions in the range of
4427          --  a type declaration are resolved. We simply ignore the freeze
4428          --  request in this case. Is this right ???
4429
4430          if No (Parent_P) then
4431             return;
4432          end if;
4433
4434          --  See if we have got to an appropriate point in the tree
4435
4436          case Nkind (Parent_P) is
4437
4438             --  A special test for the exception of (RM 13.14(8)) for the case
4439             --  of per-object expressions (RM 3.8(18)) occurring in component
4440             --  definition or a discrete subtype definition. Note that we test
4441             --  for a component declaration which includes both cases we are
4442             --  interested in, and furthermore the tree does not have explicit
4443             --  nodes for either of these two constructs.
4444
4445             when N_Component_Declaration =>
4446
4447                --  The case we want to test for here is an identifier that is
4448                --  a per-object expression, this is either a discriminant that
4449                --  appears in a context other than the component declaration
4450                --  or it is a reference to the type of the enclosing construct.
4451
4452                --  For either of these cases, we skip the freezing
4453
4454                if not In_Spec_Expression
4455                  and then Nkind (N) = N_Identifier
4456                  and then (Present (Entity (N)))
4457                then
4458                   --  We recognize the discriminant case by just looking for
4459                   --  a reference to a discriminant. It can only be one for
4460                   --  the enclosing construct. Skip freezing in this case.
4461
4462                   if Ekind (Entity (N)) = E_Discriminant then
4463                      return;
4464
4465                   --  For the case of a reference to the enclosing record,
4466                   --  (or task or protected type), we look for a type that
4467                   --  matches the current scope.
4468
4469                   elsif Entity (N) = Current_Scope then
4470                      return;
4471                   end if;
4472                end if;
4473
4474             --  If we have an enumeration literal that appears as the choice in
4475             --  the aggregate of an enumeration representation clause, then
4476             --  freezing does not occur (RM 13.14(10)).
4477
4478             when N_Enumeration_Representation_Clause =>
4479
4480                --  The case we are looking for is an enumeration literal
4481
4482                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4483                  and then Is_Enumeration_Type (Etype (N))
4484                then
4485                   --  If enumeration literal appears directly as the choice,
4486                   --  do not freeze (this is the normal non-overloaded case)
4487
4488                   if Nkind (Parent (N)) = N_Component_Association
4489                     and then First (Choices (Parent (N))) = N
4490                   then
4491                      return;
4492
4493                   --  If enumeration literal appears as the name of function
4494                   --  which is the choice, then also do not freeze. This
4495                   --  happens in the overloaded literal case, where the
4496                   --  enumeration literal is temporarily changed to a function
4497                   --  call for overloading analysis purposes.
4498
4499                   elsif Nkind (Parent (N)) = N_Function_Call
4500                      and then
4501                        Nkind (Parent (Parent (N))) = N_Component_Association
4502                      and then
4503                        First (Choices (Parent (Parent (N)))) = Parent (N)
4504                   then
4505                      return;
4506                   end if;
4507                end if;
4508
4509             --  Normally if the parent is a handled sequence of statements,
4510             --  then the current node must be a statement, and that is an
4511             --  appropriate place to insert a freeze node.
4512
4513             when N_Handled_Sequence_Of_Statements =>
4514
4515                --  An exception occurs when the sequence of statements is for
4516                --  an expander generated body that did not do the usual freeze
4517                --  all operation. In this case we usually want to freeze
4518                --  outside this body, not inside it, and we skip past the
4519                --  subprogram body that we are inside.
4520
4521                if In_Exp_Body (Parent_P) then
4522
4523                   --  However, we *do* want to freeze at this point if we have
4524                   --  an entity to freeze, and that entity is declared *inside*
4525                   --  the body of the expander generated procedure. This case
4526                   --  is recognized by the scope of the type, which is either
4527                   --  the spec for some enclosing body, or (in the case of
4528                   --  init_procs, for which there are no separate specs) the
4529                   --  current scope.
4530
4531                   declare
4532                      Subp : constant Node_Id := Parent (Parent_P);
4533                      Cspc : Entity_Id;
4534
4535                   begin
4536                      if Nkind (Subp) = N_Subprogram_Body then
4537                         Cspc := Corresponding_Spec (Subp);
4538
4539                         if (Present (Typ) and then Scope (Typ) = Cspc)
4540                              or else
4541                            (Present (Nam) and then Scope (Nam) = Cspc)
4542                         then
4543                            exit;
4544
4545                         elsif Present (Typ)
4546                           and then Scope (Typ) = Current_Scope
4547                           and then Current_Scope = Defining_Entity (Subp)
4548                         then
4549                            exit;
4550                         end if;
4551                      end if;
4552                   end;
4553
4554                   --  If not that exception to the exception, then this is
4555                   --  where we delay the freeze till outside the body.
4556
4557                   Parent_P := Parent (Parent_P);
4558                   Freeze_Outside := True;
4559
4560                --  Here if normal case where we are in handled statement
4561                --  sequence and want to do the insertion right there.
4562
4563                else
4564                   exit;
4565                end if;
4566
4567             --  If parent is a body or a spec or a block, then the current node
4568             --  is a statement or declaration and we can insert the freeze node
4569             --  before it.
4570
4571             when N_Package_Specification |
4572                  N_Package_Body          |
4573                  N_Subprogram_Body       |
4574                  N_Task_Body             |
4575                  N_Protected_Body        |
4576                  N_Entry_Body            |
4577                  N_Block_Statement       => exit;
4578
4579             --  The expander is allowed to define types in any statements list,
4580             --  so any of the following parent nodes also mark a freezing point
4581             --  if the actual node is in a list of statements or declarations.
4582
4583             when N_Exception_Handler          |
4584                  N_If_Statement               |
4585                  N_Elsif_Part                 |
4586                  N_Case_Statement_Alternative |
4587                  N_Compilation_Unit_Aux       |
4588                  N_Selective_Accept           |
4589                  N_Accept_Alternative         |
4590                  N_Delay_Alternative          |
4591                  N_Conditional_Entry_Call     |
4592                  N_Entry_Call_Alternative     |
4593                  N_Triggering_Alternative     |
4594                  N_Abortable_Part             |
4595                  N_And_Then                   |
4596                  N_Or_Else                    |
4597                  N_Freeze_Entity              =>
4598
4599                exit when Is_List_Member (P);
4600
4601             --  Note: The N_Loop_Statement is a special case. A type that
4602             --  appears in the source can never be frozen in a loop (this
4603             --  occurs only because of a loop expanded by the expander), so we
4604             --  keep on going. Otherwise we terminate the search. Same is true
4605             --  of any entity which comes from source. (if they have predefined
4606             --  type, that type does not appear to come from source, but the
4607             --  entity should not be frozen here).
4608
4609             when N_Loop_Statement =>
4610                exit when not Comes_From_Source (Etype (N))
4611                  and then (No (Nam) or else not Comes_From_Source (Nam));
4612
4613             --  For all other cases, keep looking at parents
4614
4615             when others =>
4616                null;
4617          end case;
4618
4619          --  We fall through the case if we did not yet find the proper
4620          --  place in the free for inserting the freeze node, so climb!
4621
4622          P := Parent_P;
4623       end loop;
4624
4625       --  If the expression appears in a record or an initialization procedure,
4626       --  the freeze nodes are collected and attached to the current scope, to
4627       --  be inserted and analyzed on exit from the scope, to insure that
4628       --  generated entities appear in the correct scope. If the expression is
4629       --  a default for a discriminant specification, the scope is still void.
4630       --  The expression can also appear in the discriminant part of a private
4631       --  or concurrent type.
4632
4633       --  If the expression appears in a constrained subcomponent of an
4634       --  enclosing record declaration, the freeze nodes must be attached to
4635       --  the outer record type so they can eventually be placed in the
4636       --  enclosing declaration list.
4637
4638       --  The other case requiring this special handling is if we are in a
4639       --  default expression, since in that case we are about to freeze a
4640       --  static type, and the freeze scope needs to be the outer scope, not
4641       --  the scope of the subprogram with the default parameter.
4642
4643       --  For default expressions and other spec expressions in generic units,
4644       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4645       --  placing them at the proper place, after the generic unit.
4646
4647       if (In_Spec_Exp and not Inside_A_Generic)
4648         or else Freeze_Outside
4649         or else (Is_Type (Current_Scope)
4650                   and then (not Is_Concurrent_Type (Current_Scope)
4651                              or else not Has_Completion (Current_Scope)))
4652         or else Ekind (Current_Scope) = E_Void
4653       then
4654          declare
4655             N            : constant Node_Id    := Current_Scope;
4656             Freeze_Nodes : List_Id             := No_List;
4657             Pos          : Int                 := Scope_Stack.Last;
4658
4659          begin
4660             if Present (Desig_Typ) then
4661                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4662             end if;
4663
4664             if Present (Typ) then
4665                Freeze_And_Append (Typ, N, Freeze_Nodes);
4666             end if;
4667
4668             if Present (Nam) then
4669                Freeze_And_Append (Nam, N, Freeze_Nodes);
4670             end if;
4671
4672             --  The current scope may be that of a constrained component of
4673             --  an enclosing record declaration, which is above the current
4674             --  scope in the scope stack.
4675             --  If the expression is within a top-level pragma, as for a pre-
4676             --  condition on a library-level subprogram, nothing to do.
4677
4678             if not Is_Compilation_Unit (Current_Scope)
4679               and then Is_Record_Type (Scope (Current_Scope))
4680             then
4681                Pos := Pos - 1;
4682             end if;
4683
4684             if Is_Non_Empty_List (Freeze_Nodes) then
4685                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4686                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4687                     Freeze_Nodes;
4688                else
4689                   Append_List (Freeze_Nodes,
4690                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4691                end if;
4692             end if;
4693          end;
4694
4695          return;
4696       end if;
4697
4698       --  Now we have the right place to do the freezing. First, a special
4699       --  adjustment, if we are in spec-expression analysis mode, these freeze
4700       --  actions must not be thrown away (normally all inserted actions are
4701       --  thrown away in this mode. However, the freeze actions are from static
4702       --  expressions and one of the important reasons we are doing this
4703       --  special analysis is to get these freeze actions. Therefore we turn
4704       --  off the In_Spec_Expression mode to propagate these freeze actions.
4705       --  This also means they get properly analyzed and expanded.
4706
4707       In_Spec_Expression := False;
4708
4709       --  Freeze the designated type of an allocator (RM 13.14(13))
4710
4711       if Present (Desig_Typ) then
4712          Freeze_Before (P, Desig_Typ);
4713       end if;
4714
4715       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4716       --  the enumeration representation clause exception in the loop above.
4717
4718       if Present (Typ) then
4719          Freeze_Before (P, Typ);
4720       end if;
4721
4722       --  Freeze name if one is present (RM 13.14(11))
4723
4724       if Present (Nam) then
4725          Freeze_Before (P, Nam);
4726       end if;
4727
4728       --  Restore In_Spec_Expression flag
4729
4730       In_Spec_Expression := In_Spec_Exp;
4731    end Freeze_Expression;
4732
4733    -----------------------------
4734    -- Freeze_Fixed_Point_Type --
4735    -----------------------------
4736
4737    --  Certain fixed-point types and subtypes, including implicit base types
4738    --  and declared first subtypes, have not yet set up a range. This is
4739    --  because the range cannot be set until the Small and Size values are
4740    --  known, and these are not known till the type is frozen.
4741
4742    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4743    --  whose bounds are unanalyzed real literals. This routine will recognize
4744    --  this case, and transform this range node into a properly typed range
4745    --  with properly analyzed and resolved values.
4746
4747    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4748       Rng   : constant Node_Id    := Scalar_Range (Typ);
4749       Lo    : constant Node_Id    := Low_Bound (Rng);
4750       Hi    : constant Node_Id    := High_Bound (Rng);
4751       Btyp  : constant Entity_Id  := Base_Type (Typ);
4752       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4753       BLo   : constant Node_Id    := Low_Bound (Brng);
4754       BHi   : constant Node_Id    := High_Bound (Brng);
4755       Small : constant Ureal      := Small_Value (Typ);
4756       Loval : Ureal;
4757       Hival : Ureal;
4758       Atype : Entity_Id;
4759
4760       Actual_Size : Nat;
4761
4762       function Fsize (Lov, Hiv : Ureal) return Nat;
4763       --  Returns size of type with given bounds. Also leaves these
4764       --  bounds set as the current bounds of the Typ.
4765
4766       -----------
4767       -- Fsize --
4768       -----------
4769
4770       function Fsize (Lov, Hiv : Ureal) return Nat is
4771       begin
4772          Set_Realval (Lo, Lov);
4773          Set_Realval (Hi, Hiv);
4774          return Minimum_Size (Typ);
4775       end Fsize;
4776
4777    --  Start of processing for Freeze_Fixed_Point_Type
4778
4779    begin
4780       --  If Esize of a subtype has not previously been set, set it now
4781
4782       if Unknown_Esize (Typ) then
4783          Atype := Ancestor_Subtype (Typ);
4784
4785          if Present (Atype) then
4786             Set_Esize (Typ, Esize (Atype));
4787          else
4788             Set_Esize (Typ, Esize (Base_Type (Typ)));
4789          end if;
4790       end if;
4791
4792       --  Immediate return if the range is already analyzed. This means that
4793       --  the range is already set, and does not need to be computed by this
4794       --  routine.
4795
4796       if Analyzed (Rng) then
4797          return;
4798       end if;
4799
4800       --  Immediate return if either of the bounds raises Constraint_Error
4801
4802       if Raises_Constraint_Error (Lo)
4803         or else Raises_Constraint_Error (Hi)
4804       then
4805          return;
4806       end if;
4807
4808       Loval := Realval (Lo);
4809       Hival := Realval (Hi);
4810
4811       --  Ordinary fixed-point case
4812
4813       if Is_Ordinary_Fixed_Point_Type (Typ) then
4814
4815          --  For the ordinary fixed-point case, we are allowed to fudge the
4816          --  end-points up or down by small. Generally we prefer to fudge up,
4817          --  i.e. widen the bounds for non-model numbers so that the end points
4818          --  are included. However there are cases in which this cannot be
4819          --  done, and indeed cases in which we may need to narrow the bounds.
4820          --  The following circuit makes the decision.
4821
4822          --  Note: our terminology here is that Incl_EP means that the bounds
4823          --  are widened by Small if necessary to include the end points, and
4824          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4825          --  end-points if this reduces the size.
4826
4827          --  Note that in the Incl case, all we care about is including the
4828          --  end-points. In the Excl case, we want to narrow the bounds as
4829          --  much as permitted by the RM, to give the smallest possible size.
4830
4831          Fudge : declare
4832             Loval_Incl_EP : Ureal;
4833             Hival_Incl_EP : Ureal;
4834
4835             Loval_Excl_EP : Ureal;
4836             Hival_Excl_EP : Ureal;
4837
4838             Size_Incl_EP  : Nat;
4839             Size_Excl_EP  : Nat;
4840
4841             Model_Num     : Ureal;
4842             First_Subt    : Entity_Id;
4843             Actual_Lo     : Ureal;
4844             Actual_Hi     : Ureal;
4845
4846          begin
4847             --  First step. Base types are required to be symmetrical. Right
4848             --  now, the base type range is a copy of the first subtype range.
4849             --  This will be corrected before we are done, but right away we
4850             --  need to deal with the case where both bounds are non-negative.
4851             --  In this case, we set the low bound to the negative of the high
4852             --  bound, to make sure that the size is computed to include the
4853             --  required sign. Note that we do not need to worry about the
4854             --  case of both bounds negative, because the sign will be dealt
4855             --  with anyway. Furthermore we can't just go making such a bound
4856             --  symmetrical, since in a twos-complement system, there is an
4857             --  extra negative value which could not be accommodated on the
4858             --  positive side.
4859
4860             if Typ = Btyp
4861               and then not UR_Is_Negative (Loval)
4862               and then Hival > Loval
4863             then
4864                Loval := -Hival;
4865                Set_Realval (Lo, Loval);
4866             end if;
4867
4868             --  Compute the fudged bounds. If the number is a model number,
4869             --  then we do nothing to include it, but we are allowed to backoff
4870             --  to the next adjacent model number when we exclude it. If it is
4871             --  not a model number then we straddle the two values with the
4872             --  model numbers on either side.
4873
4874             Model_Num := UR_Trunc (Loval / Small) * Small;
4875
4876             if Loval = Model_Num then
4877                Loval_Incl_EP := Model_Num;
4878             else
4879                Loval_Incl_EP := Model_Num - Small;
4880             end if;
4881
4882             --  The low value excluding the end point is Small greater, but
4883             --  we do not do this exclusion if the low value is positive,
4884             --  since it can't help the size and could actually hurt by
4885             --  crossing the high bound.
4886
4887             if UR_Is_Negative (Loval_Incl_EP) then
4888                Loval_Excl_EP := Loval_Incl_EP + Small;
4889
4890                --  If the value went from negative to zero, then we have the
4891                --  case where Loval_Incl_EP is the model number just below
4892                --  zero, so we want to stick to the negative value for the
4893                --  base type to maintain the condition that the size will
4894                --  include signed values.
4895
4896                if Typ = Btyp
4897                  and then UR_Is_Zero (Loval_Excl_EP)
4898                then
4899                   Loval_Excl_EP := Loval_Incl_EP;
4900                end if;
4901
4902             else
4903                Loval_Excl_EP := Loval_Incl_EP;
4904             end if;
4905
4906             --  Similar processing for upper bound and high value
4907
4908             Model_Num := UR_Trunc (Hival / Small) * Small;
4909
4910             if Hival = Model_Num then
4911                Hival_Incl_EP := Model_Num;
4912             else
4913                Hival_Incl_EP := Model_Num + Small;
4914             end if;
4915
4916             if UR_Is_Positive (Hival_Incl_EP) then
4917                Hival_Excl_EP := Hival_Incl_EP - Small;
4918             else
4919                Hival_Excl_EP := Hival_Incl_EP;
4920             end if;
4921
4922             --  One further adjustment is needed. In the case of subtypes, we
4923             --  cannot go outside the range of the base type, or we get
4924             --  peculiarities, and the base type range is already set. This
4925             --  only applies to the Incl values, since clearly the Excl values
4926             --  are already as restricted as they are allowed to be.
4927
4928             if Typ /= Btyp then
4929                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4930                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4931             end if;
4932
4933             --  Get size including and excluding end points
4934
4935             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4936             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4937
4938             --  No need to exclude end-points if it does not reduce size
4939
4940             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4941                Loval_Excl_EP := Loval_Incl_EP;
4942             end if;
4943
4944             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4945                Hival_Excl_EP := Hival_Incl_EP;
4946             end if;
4947
4948             --  Now we set the actual size to be used. We want to use the
4949             --  bounds fudged up to include the end-points but only if this
4950             --  can be done without violating a specifically given size
4951             --  size clause or causing an unacceptable increase in size.
4952
4953             --  Case of size clause given
4954
4955             if Has_Size_Clause (Typ) then
4956
4957                --  Use the inclusive size only if it is consistent with
4958                --  the explicitly specified size.
4959
4960                if Size_Incl_EP <= RM_Size (Typ) then
4961                   Actual_Lo   := Loval_Incl_EP;
4962                   Actual_Hi   := Hival_Incl_EP;
4963                   Actual_Size := Size_Incl_EP;
4964
4965                --  If the inclusive size is too large, we try excluding
4966                --  the end-points (will be caught later if does not work).
4967
4968                else
4969                   Actual_Lo   := Loval_Excl_EP;
4970                   Actual_Hi   := Hival_Excl_EP;
4971                   Actual_Size := Size_Excl_EP;
4972                end if;
4973
4974             --  Case of size clause not given
4975
4976             else
4977                --  If we have a base type whose corresponding first subtype
4978                --  has an explicit size that is large enough to include our
4979                --  end-points, then do so. There is no point in working hard
4980                --  to get a base type whose size is smaller than the specified
4981                --  size of the first subtype.
4982
4983                First_Subt := First_Subtype (Typ);
4984
4985                if Has_Size_Clause (First_Subt)
4986                  and then Size_Incl_EP <= Esize (First_Subt)
4987                then
4988                   Actual_Size := Size_Incl_EP;
4989                   Actual_Lo   := Loval_Incl_EP;
4990                   Actual_Hi   := Hival_Incl_EP;
4991
4992                --  If excluding the end-points makes the size smaller and
4993                --  results in a size of 8,16,32,64, then we take the smaller
4994                --  size. For the 64 case, this is compulsory. For the other
4995                --  cases, it seems reasonable. We like to include end points
4996                --  if we can, but not at the expense of moving to the next
4997                --  natural boundary of size.
4998
4999                elsif Size_Incl_EP /= Size_Excl_EP
5000                  and then Addressable (Size_Excl_EP)
5001                then
5002                   Actual_Size := Size_Excl_EP;
5003                   Actual_Lo   := Loval_Excl_EP;
5004                   Actual_Hi   := Hival_Excl_EP;
5005
5006                --  Otherwise we can definitely include the end points
5007
5008                else
5009                   Actual_Size := Size_Incl_EP;
5010                   Actual_Lo   := Loval_Incl_EP;
5011                   Actual_Hi   := Hival_Incl_EP;
5012                end if;
5013
5014                --  One pathological case: normally we never fudge a low bound
5015                --  down, since it would seem to increase the size (if it has
5016                --  any effect), but for ranges containing single value, or no
5017                --  values, the high bound can be small too large. Consider:
5018
5019                --    type t is delta 2.0**(-14)
5020                --      range 131072.0 .. 0;
5021
5022                --  That lower bound is *just* outside the range of 32 bits, and
5023                --  does need fudging down in this case. Note that the bounds
5024                --  will always have crossed here, since the high bound will be
5025                --  fudged down if necessary, as in the case of:
5026
5027                --    type t is delta 2.0**(-14)
5028                --      range 131072.0 .. 131072.0;
5029
5030                --  So we detect the situation by looking for crossed bounds,
5031                --  and if the bounds are crossed, and the low bound is greater
5032                --  than zero, we will always back it off by small, since this
5033                --  is completely harmless.
5034
5035                if Actual_Lo > Actual_Hi then
5036                   if UR_Is_Positive (Actual_Lo) then
5037                      Actual_Lo   := Loval_Incl_EP - Small;
5038                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5039
5040                   --  And of course, we need to do exactly the same parallel
5041                   --  fudge for flat ranges in the negative region.
5042
5043                   elsif UR_Is_Negative (Actual_Hi) then
5044                      Actual_Hi := Hival_Incl_EP + Small;
5045                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5046                   end if;
5047                end if;
5048             end if;
5049
5050             Set_Realval (Lo, Actual_Lo);
5051             Set_Realval (Hi, Actual_Hi);
5052          end Fudge;
5053
5054       --  For the decimal case, none of this fudging is required, since there
5055       --  are no end-point problems in the decimal case (the end-points are
5056       --  always included).
5057
5058       else
5059          Actual_Size := Fsize (Loval, Hival);
5060       end if;
5061
5062       --  At this stage, the actual size has been calculated and the proper
5063       --  required bounds are stored in the low and high bounds.
5064
5065       if Actual_Size > 64 then
5066          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5067          Error_Msg_N
5068            ("size required (^) for type& too large, maximum allowed is 64",
5069             Typ);
5070          Actual_Size := 64;
5071       end if;
5072
5073       --  Check size against explicit given size
5074
5075       if Has_Size_Clause (Typ) then
5076          if Actual_Size > RM_Size (Typ) then
5077             Error_Msg_Uint_1 := RM_Size (Typ);
5078             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5079             Error_Msg_NE
5080               ("size given (^) for type& too small, minimum allowed is ^",
5081                Size_Clause (Typ), Typ);
5082
5083          else
5084             Actual_Size := UI_To_Int (Esize (Typ));
5085          end if;
5086
5087       --  Increase size to next natural boundary if no size clause given
5088
5089       else
5090          if Actual_Size <= 8 then
5091             Actual_Size := 8;
5092          elsif Actual_Size <= 16 then
5093             Actual_Size := 16;
5094          elsif Actual_Size <= 32 then
5095             Actual_Size := 32;
5096          else
5097             Actual_Size := 64;
5098          end if;
5099
5100          Init_Esize (Typ, Actual_Size);
5101          Adjust_Esize_For_Alignment (Typ);
5102       end if;
5103
5104       --  If we have a base type, then expand the bounds so that they extend to
5105       --  the full width of the allocated size in bits, to avoid junk range
5106       --  checks on intermediate computations.
5107
5108       if Base_Type (Typ) = Typ then
5109          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5110          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5111       end if;
5112
5113       --  Final step is to reanalyze the bounds using the proper type
5114       --  and set the Corresponding_Integer_Value fields of the literals.
5115
5116       Set_Etype (Lo, Empty);
5117       Set_Analyzed (Lo, False);
5118       Analyze (Lo);
5119
5120       --  Resolve with universal fixed if the base type, and the base type if
5121       --  it is a subtype. Note we can't resolve the base type with itself,
5122       --  that would be a reference before definition.
5123
5124       if Typ = Btyp then
5125          Resolve (Lo, Universal_Fixed);
5126       else
5127          Resolve (Lo, Btyp);
5128       end if;
5129
5130       --  Set corresponding integer value for bound
5131
5132       Set_Corresponding_Integer_Value
5133         (Lo, UR_To_Uint (Realval (Lo) / Small));
5134
5135       --  Similar processing for high bound
5136
5137       Set_Etype (Hi, Empty);
5138       Set_Analyzed (Hi, False);
5139       Analyze (Hi);
5140
5141       if Typ = Btyp then
5142          Resolve (Hi, Universal_Fixed);
5143       else
5144          Resolve (Hi, Btyp);
5145       end if;
5146
5147       Set_Corresponding_Integer_Value
5148         (Hi, UR_To_Uint (Realval (Hi) / Small));
5149
5150       --  Set type of range to correspond to bounds
5151
5152       Set_Etype (Rng, Etype (Lo));
5153
5154       --  Set Esize to calculated size if not set already
5155
5156       if Unknown_Esize (Typ) then
5157          Init_Esize (Typ, Actual_Size);
5158       end if;
5159
5160       --  Set RM_Size if not already set. If already set, check value
5161
5162       declare
5163          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5164
5165       begin
5166          if RM_Size (Typ) /= Uint_0 then
5167             if RM_Size (Typ) < Minsiz then
5168                Error_Msg_Uint_1 := RM_Size (Typ);
5169                Error_Msg_Uint_2 := Minsiz;
5170                Error_Msg_NE
5171                  ("size given (^) for type& too small, minimum allowed is ^",
5172                   Size_Clause (Typ), Typ);
5173             end if;
5174
5175          else
5176             Set_RM_Size (Typ, Minsiz);
5177          end if;
5178       end;
5179    end Freeze_Fixed_Point_Type;
5180
5181    ------------------
5182    -- Freeze_Itype --
5183    ------------------
5184
5185    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5186       L : List_Id;
5187
5188    begin
5189       Set_Has_Delayed_Freeze (T);
5190       L := Freeze_Entity (T, N);
5191
5192       if Is_Non_Empty_List (L) then
5193          Insert_Actions (N, L);
5194       end if;
5195    end Freeze_Itype;
5196
5197    --------------------------
5198    -- Freeze_Static_Object --
5199    --------------------------
5200
5201    procedure Freeze_Static_Object (E : Entity_Id) is
5202
5203       Cannot_Be_Static : exception;
5204       --  Exception raised if the type of a static object cannot be made
5205       --  static. This happens if the type depends on non-global objects.
5206
5207       procedure Ensure_Expression_Is_SA (N : Node_Id);
5208       --  Called to ensure that an expression used as part of a type definition
5209       --  is statically allocatable, which means that the expression type is
5210       --  statically allocatable, and the expression is either static, or a
5211       --  reference to a library level constant.
5212
5213       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5214       --  Called to mark a type as static, checking that it is possible
5215       --  to set the type as static. If it is not possible, then the
5216       --  exception Cannot_Be_Static is raised.
5217
5218       -----------------------------
5219       -- Ensure_Expression_Is_SA --
5220       -----------------------------
5221
5222       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5223          Ent : Entity_Id;
5224
5225       begin
5226          Ensure_Type_Is_SA (Etype (N));
5227
5228          if Is_Static_Expression (N) then
5229             return;
5230
5231          elsif Nkind (N) = N_Identifier then
5232             Ent := Entity (N);
5233
5234             if Present (Ent)
5235               and then Ekind (Ent) = E_Constant
5236               and then Is_Library_Level_Entity (Ent)
5237             then
5238                return;
5239             end if;
5240          end if;
5241
5242          raise Cannot_Be_Static;
5243       end Ensure_Expression_Is_SA;
5244
5245       -----------------------
5246       -- Ensure_Type_Is_SA --
5247       -----------------------
5248
5249       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5250          N : Node_Id;
5251          C : Entity_Id;
5252
5253       begin
5254          --  If type is library level, we are all set
5255
5256          if Is_Library_Level_Entity (Typ) then
5257             return;
5258          end if;
5259
5260          --  We are also OK if the type already marked as statically allocated,
5261          --  which means we processed it before.
5262
5263          if Is_Statically_Allocated (Typ) then
5264             return;
5265          end if;
5266
5267          --  Mark type as statically allocated
5268
5269          Set_Is_Statically_Allocated (Typ);
5270
5271          --  Check that it is safe to statically allocate this type
5272
5273          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5274             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5275             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5276
5277          elsif Is_Array_Type (Typ) then
5278             N := First_Index (Typ);
5279             while Present (N) loop
5280                Ensure_Type_Is_SA (Etype (N));
5281                Next_Index (N);
5282             end loop;
5283
5284             Ensure_Type_Is_SA (Component_Type (Typ));
5285
5286          elsif Is_Access_Type (Typ) then
5287             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5288
5289                declare
5290                   F : Entity_Id;
5291                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5292
5293                begin
5294                   if T /= Standard_Void_Type then
5295                      Ensure_Type_Is_SA (T);
5296                   end if;
5297
5298                   F := First_Formal (Designated_Type (Typ));
5299                   while Present (F) loop
5300                      Ensure_Type_Is_SA (Etype (F));
5301                      Next_Formal (F);
5302                   end loop;
5303                end;
5304
5305             else
5306                Ensure_Type_Is_SA (Designated_Type (Typ));
5307             end if;
5308
5309          elsif Is_Record_Type (Typ) then
5310             C := First_Entity (Typ);
5311             while Present (C) loop
5312                if Ekind (C) = E_Discriminant
5313                  or else Ekind (C) = E_Component
5314                then
5315                   Ensure_Type_Is_SA (Etype (C));
5316
5317                elsif Is_Type (C) then
5318                   Ensure_Type_Is_SA (C);
5319                end if;
5320
5321                Next_Entity (C);
5322             end loop;
5323
5324          elsif Ekind (Typ) = E_Subprogram_Type then
5325             Ensure_Type_Is_SA (Etype (Typ));
5326
5327             C := First_Formal (Typ);
5328             while Present (C) loop
5329                Ensure_Type_Is_SA (Etype (C));
5330                Next_Formal (C);
5331             end loop;
5332
5333          else
5334             raise Cannot_Be_Static;
5335          end if;
5336       end Ensure_Type_Is_SA;
5337
5338    --  Start of processing for Freeze_Static_Object
5339
5340    begin
5341       Ensure_Type_Is_SA (Etype (E));
5342
5343    exception
5344       when Cannot_Be_Static =>
5345
5346          --  If the object that cannot be static is imported or exported, then
5347          --  issue an error message saying that this object cannot be imported
5348          --  or exported. If it has an address clause it is an overlay in the
5349          --  current partition and the static requirement is not relevant.
5350          --  Do not issue any error message when ignoring rep clauses.
5351
5352          if Ignore_Rep_Clauses then
5353             null;
5354
5355          elsif Is_Imported (E) then
5356             if No (Address_Clause (E)) then
5357                Error_Msg_N
5358                  ("& cannot be imported (local type is not constant)", E);
5359             end if;
5360
5361          --  Otherwise must be exported, something is wrong if compiler
5362          --  is marking something as statically allocated which cannot be).
5363
5364          else pragma Assert (Is_Exported (E));
5365             Error_Msg_N
5366               ("& cannot be exported (local type is not constant)", E);
5367          end if;
5368    end Freeze_Static_Object;
5369
5370    -----------------------
5371    -- Freeze_Subprogram --
5372    -----------------------
5373
5374    procedure Freeze_Subprogram (E : Entity_Id) is
5375       Retype : Entity_Id;
5376       F      : Entity_Id;
5377
5378    begin
5379       --  Subprogram may not have an address clause unless it is imported
5380
5381       if Present (Address_Clause (E)) then
5382          if not Is_Imported (E) then
5383             Error_Msg_N
5384               ("address clause can only be given " &
5385                "for imported subprogram",
5386                Name (Address_Clause (E)));
5387          end if;
5388       end if;
5389
5390       --  Reset the Pure indication on an imported subprogram unless an
5391       --  explicit Pure_Function pragma was present. We do this because
5392       --  otherwise it is an insidious error to call a non-pure function from
5393       --  pure unit and have calls mysteriously optimized away. What happens
5394       --  here is that the Import can bypass the normal check to ensure that
5395       --  pure units call only pure subprograms.
5396
5397       if Is_Imported (E)
5398         and then Is_Pure (E)
5399         and then not Has_Pragma_Pure_Function (E)
5400       then
5401          Set_Is_Pure (E, False);
5402       end if;
5403
5404       --  For non-foreign convention subprograms, this is where we create
5405       --  the extra formals (for accessibility level and constrained bit
5406       --  information). We delay this till the freeze point precisely so
5407       --  that we know the convention!
5408
5409       if not Has_Foreign_Convention (E) then
5410          Create_Extra_Formals (E);
5411          Set_Mechanisms (E);
5412
5413          --  If this is convention Ada and a Valued_Procedure, that's odd
5414
5415          if Ekind (E) = E_Procedure
5416            and then Is_Valued_Procedure (E)
5417            and then Convention (E) = Convention_Ada
5418            and then Warn_On_Export_Import
5419          then
5420             Error_Msg_N
5421               ("?Valued_Procedure has no effect for convention Ada", E);
5422             Set_Is_Valued_Procedure (E, False);
5423          end if;
5424
5425       --  Case of foreign convention
5426
5427       else
5428          Set_Mechanisms (E);
5429
5430          --  For foreign conventions, warn about return of an
5431          --  unconstrained array.
5432
5433          --  Note: we *do* allow a return by descriptor for the VMS case,
5434          --  though here there is probably more to be done ???
5435
5436          if Ekind (E) = E_Function then
5437             Retype := Underlying_Type (Etype (E));
5438
5439             --  If no return type, probably some other error, e.g. a
5440             --  missing full declaration, so ignore.
5441
5442             if No (Retype) then
5443                null;
5444
5445             --  If the return type is generic, we have emitted a warning
5446             --  earlier on, and there is nothing else to check here. Specific
5447             --  instantiations may lead to erroneous behavior.
5448
5449             elsif Is_Generic_Type (Etype (E)) then
5450                null;
5451
5452             --  Display warning if returning unconstrained array
5453
5454             elsif Is_Array_Type (Retype)
5455               and then not Is_Constrained (Retype)
5456
5457               --  Exclude cases where descriptor mechanism is set, since the
5458               --  VMS descriptor mechanisms allow such unconstrained returns.
5459
5460               and then Mechanism (E) not in Descriptor_Codes
5461
5462               --  Check appropriate warning is enabled (should we check for
5463               --  Warnings (Off) on specific entities here, probably so???)
5464
5465               and then Warn_On_Export_Import
5466
5467                --  Exclude the VM case, since return of unconstrained arrays
5468                --  is properly handled in both the JVM and .NET cases.
5469
5470               and then VM_Target = No_VM
5471             then
5472                Error_Msg_N
5473                 ("?foreign convention function& should not return " &
5474                   "unconstrained array", E);
5475                return;
5476             end if;
5477          end if;
5478
5479          --  If any of the formals for an exported foreign convention
5480          --  subprogram have defaults, then emit an appropriate warning since
5481          --  this is odd (default cannot be used from non-Ada code)
5482
5483          if Is_Exported (E) then
5484             F := First_Formal (E);
5485             while Present (F) loop
5486                if Warn_On_Export_Import
5487                  and then Present (Default_Value (F))
5488                then
5489                   Error_Msg_N
5490                     ("?parameter cannot be defaulted in non-Ada call",
5491                      Default_Value (F));
5492                end if;
5493
5494                Next_Formal (F);
5495             end loop;
5496          end if;
5497       end if;
5498
5499       --  For VMS, descriptor mechanisms for parameters are allowed only for
5500       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5501       --  allowed for parameters of exported subprograms.
5502
5503       if OpenVMS_On_Target then
5504          if Is_Exported (E) then
5505             F := First_Formal (E);
5506             while Present (F) loop
5507                if Mechanism (F) = By_Descriptor_NCA then
5508                   Error_Msg_N
5509                     ("'N'C'A' descriptor for parameter not permitted", F);
5510                   Error_Msg_N
5511                     ("\can only be used for imported subprogram", F);
5512                end if;
5513
5514                Next_Formal (F);
5515             end loop;
5516
5517          elsif not Is_Imported (E) then
5518             F := First_Formal (E);
5519             while Present (F) loop
5520                if Mechanism (F) in Descriptor_Codes then
5521                   Error_Msg_N
5522                     ("descriptor mechanism for parameter not permitted", F);
5523                   Error_Msg_N
5524                     ("\can only be used for imported/exported subprogram", F);
5525                end if;
5526
5527                Next_Formal (F);
5528             end loop;
5529          end if;
5530       end if;
5531
5532       --  Pragma Inline_Always is disallowed for dispatching subprograms
5533       --  because the address of such subprograms is saved in the dispatch
5534       --  table to support dispatching calls, and dispatching calls cannot
5535       --  be inlined. This is consistent with the restriction against using
5536       --  'Access or 'Address on an Inline_Always subprogram.
5537
5538       if Is_Dispatching_Operation (E)
5539         and then Has_Pragma_Inline_Always (E)
5540       then
5541          Error_Msg_N
5542            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5543       end if;
5544
5545       --  Because of the implicit representation of inherited predefined
5546       --  operators in the front-end, the overriding status of the operation
5547       --  may be affected when a full view of a type is analyzed, and this is
5548       --  not captured by the analysis of the corresponding type declaration.
5549       --  Therefore the correctness of a not-overriding indicator must be
5550       --  rechecked when the subprogram is frozen.
5551
5552       if Nkind (E) = N_Defining_Operator_Symbol
5553         and then not Error_Posted (Parent (E))
5554       then
5555          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5556       end if;
5557    end Freeze_Subprogram;
5558
5559    ----------------------
5560    -- Is_Fully_Defined --
5561    ----------------------
5562
5563    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5564    begin
5565       if Ekind (T) = E_Class_Wide_Type then
5566          return Is_Fully_Defined (Etype (T));
5567
5568       elsif Is_Array_Type (T) then
5569          return Is_Fully_Defined (Component_Type (T));
5570
5571       elsif Is_Record_Type (T)
5572         and not Is_Private_Type (T)
5573       then
5574          --  Verify that the record type has no components with private types
5575          --  without completion.
5576
5577          declare
5578             Comp : Entity_Id;
5579
5580          begin
5581             Comp := First_Component (T);
5582             while Present (Comp) loop
5583                if not Is_Fully_Defined (Etype (Comp)) then
5584                   return False;
5585                end if;
5586
5587                Next_Component (Comp);
5588             end loop;
5589             return True;
5590          end;
5591
5592       --  For the designated type of an access to subprogram, all types in
5593       --  the profile must be fully defined.
5594
5595       elsif Ekind (T) = E_Subprogram_Type then
5596          declare
5597             F : Entity_Id;
5598
5599          begin
5600             F := First_Formal (T);
5601             while Present (F) loop
5602                if not Is_Fully_Defined (Etype (F)) then
5603                   return False;
5604                end if;
5605
5606                Next_Formal (F);
5607             end loop;
5608
5609             return Is_Fully_Defined (Etype (T));
5610          end;
5611
5612       else
5613          return not Is_Private_Type (T)
5614            or else Present (Full_View (Base_Type (T)));
5615       end if;
5616    end Is_Fully_Defined;
5617
5618    ---------------------------------
5619    -- Process_Default_Expressions --
5620    ---------------------------------
5621
5622    procedure Process_Default_Expressions
5623      (E     : Entity_Id;
5624       After : in out Node_Id)
5625    is
5626       Loc    : constant Source_Ptr := Sloc (E);
5627       Dbody  : Node_Id;
5628       Formal : Node_Id;
5629       Dcopy  : Node_Id;
5630       Dnam   : Entity_Id;
5631
5632    begin
5633       Set_Default_Expressions_Processed (E);
5634
5635       --  A subprogram instance and its associated anonymous subprogram share
5636       --  their signature. The default expression functions are defined in the
5637       --  wrapper packages for the anonymous subprogram, and should not be
5638       --  generated again for the instance.
5639
5640       if Is_Generic_Instance (E)
5641         and then Present (Alias (E))
5642         and then Default_Expressions_Processed (Alias (E))
5643       then
5644          return;
5645       end if;
5646
5647       Formal := First_Formal (E);
5648       while Present (Formal) loop
5649          if Present (Default_Value (Formal)) then
5650
5651             --  We work with a copy of the default expression because we
5652             --  do not want to disturb the original, since this would mess
5653             --  up the conformance checking.
5654
5655             Dcopy := New_Copy_Tree (Default_Value (Formal));
5656
5657             --  The analysis of the expression may generate insert actions,
5658             --  which of course must not be executed. We wrap those actions
5659             --  in a procedure that is not called, and later on eliminated.
5660             --  The following cases have no side-effects, and are analyzed
5661             --  directly.
5662
5663             if Nkind (Dcopy) = N_Identifier
5664               or else Nkind (Dcopy) = N_Expanded_Name
5665               or else Nkind (Dcopy) = N_Integer_Literal
5666               or else (Nkind (Dcopy) = N_Real_Literal
5667                         and then not Vax_Float (Etype (Dcopy)))
5668               or else Nkind (Dcopy) = N_Character_Literal
5669               or else Nkind (Dcopy) = N_String_Literal
5670               or else Known_Null (Dcopy)
5671               or else (Nkind (Dcopy) = N_Attribute_Reference
5672                         and then
5673                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5674             then
5675
5676                --  If there is no default function, we must still do a full
5677                --  analyze call on the default value, to ensure that all error
5678                --  checks are performed, e.g. those associated with static
5679                --  evaluation. Note: this branch will always be taken if the
5680                --  analyzer is turned off (but we still need the error checks).
5681
5682                --  Note: the setting of parent here is to meet the requirement
5683                --  that we can only analyze the expression while attached to
5684                --  the tree. Really the requirement is that the parent chain
5685                --  be set, we don't actually need to be in the tree.
5686
5687                Set_Parent (Dcopy, Declaration_Node (Formal));
5688                Analyze (Dcopy);
5689
5690                --  Default expressions are resolved with their own type if the
5691                --  context is generic, to avoid anomalies with private types.
5692
5693                if Ekind (Scope (E)) = E_Generic_Package then
5694                   Resolve (Dcopy);
5695                else
5696                   Resolve (Dcopy, Etype (Formal));
5697                end if;
5698
5699                --  If that resolved expression will raise constraint error,
5700                --  then flag the default value as raising constraint error.
5701                --  This allows a proper error message on the calls.
5702
5703                if Raises_Constraint_Error (Dcopy) then
5704                   Set_Raises_Constraint_Error (Default_Value (Formal));
5705                end if;
5706
5707             --  If the default is a parameterless call, we use the name of
5708             --  the called function directly, and there is no body to build.
5709
5710             elsif Nkind (Dcopy) = N_Function_Call
5711               and then No (Parameter_Associations (Dcopy))
5712             then
5713                null;
5714
5715             --  Else construct and analyze the body of a wrapper procedure
5716             --  that contains an object declaration to hold the expression.
5717             --  Given that this is done only to complete the analysis, it
5718             --  simpler to build a procedure than a function which might
5719             --  involve secondary stack expansion.
5720
5721             else
5722                Dnam := Make_Temporary (Loc, 'D');
5723
5724                Dbody :=
5725                  Make_Subprogram_Body (Loc,
5726                    Specification =>
5727                      Make_Procedure_Specification (Loc,
5728                        Defining_Unit_Name => Dnam),
5729
5730                    Declarations => New_List (
5731                      Make_Object_Declaration (Loc,
5732                        Defining_Identifier =>
5733                          Make_Defining_Identifier (Loc,
5734                            New_Internal_Name ('T')),
5735                          Object_Definition =>
5736                            New_Occurrence_Of (Etype (Formal), Loc),
5737                          Expression => New_Copy_Tree (Dcopy))),
5738
5739                    Handled_Statement_Sequence =>
5740                      Make_Handled_Sequence_Of_Statements (Loc,
5741                        Statements => New_List));
5742
5743                Set_Scope (Dnam, Scope (E));
5744                Set_Assignment_OK (First (Declarations (Dbody)));
5745                Set_Is_Eliminated (Dnam);
5746                Insert_After (After, Dbody);
5747                Analyze (Dbody);
5748                After := Dbody;
5749             end if;
5750          end if;
5751
5752          Next_Formal (Formal);
5753       end loop;
5754    end Process_Default_Expressions;
5755
5756    ----------------------------------------
5757    -- Set_Component_Alignment_If_Not_Set --
5758    ----------------------------------------
5759
5760    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5761    begin
5762       --  Ignore if not base type, subtypes don't need anything
5763
5764       if Typ /= Base_Type (Typ) then
5765          return;
5766       end if;
5767
5768       --  Do not override existing representation
5769
5770       if Is_Packed (Typ) then
5771          return;
5772
5773       elsif Has_Specified_Layout (Typ) then
5774          return;
5775
5776       elsif Component_Alignment (Typ) /= Calign_Default then
5777          return;
5778
5779       else
5780          Set_Component_Alignment
5781            (Typ, Scope_Stack.Table
5782                   (Scope_Stack.Last).Component_Alignment_Default);
5783       end if;
5784    end Set_Component_Alignment_If_Not_Set;
5785
5786    ------------------
5787    -- Undelay_Type --
5788    ------------------
5789
5790    procedure Undelay_Type (T : Entity_Id) is
5791    begin
5792       Set_Has_Delayed_Freeze (T, False);
5793       Set_Freeze_Node (T, Empty);
5794
5795       --  Since we don't want T to have a Freeze_Node, we don't want its
5796       --  Full_View or Corresponding_Record_Type to have one either.
5797
5798       --  ??? Fundamentally, this whole handling is a kludge. What we really
5799       --  want is to be sure that for an Itype that's part of record R and is a
5800       --  subtype of type T, that it's frozen after the later of the freeze
5801       --  points of R and T. We have no way of doing that directly, so what we
5802       --  do is force most such Itypes to be frozen as part of freezing R via
5803       --  this procedure and only delay the ones that need to be delayed
5804       --  (mostly the designated types of access types that are defined as part
5805       --  of the record).
5806
5807       if Is_Private_Type (T)
5808         and then Present (Full_View (T))
5809         and then Is_Itype (Full_View (T))
5810         and then Is_Record_Type (Scope (Full_View (T)))
5811       then
5812          Undelay_Type (Full_View (T));
5813       end if;
5814
5815       if Is_Concurrent_Type (T)
5816         and then Present (Corresponding_Record_Type (T))
5817         and then Is_Itype (Corresponding_Record_Type (T))
5818         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5819       then
5820          Undelay_Type (Corresponding_Record_Type (T));
5821       end if;
5822    end Undelay_Type;
5823
5824    ------------------
5825    -- Warn_Overlay --
5826    ------------------
5827
5828    procedure Warn_Overlay
5829      (Expr : Node_Id;
5830       Typ  : Entity_Id;
5831       Nam  : Entity_Id)
5832    is
5833       Ent : constant Entity_Id := Entity (Nam);
5834       --  The object to which the address clause applies
5835
5836       Init : Node_Id;
5837       Old  : Entity_Id := Empty;
5838       Decl : Node_Id;
5839
5840    begin
5841       --  No warning if address clause overlay warnings are off
5842
5843       if not Address_Clause_Overlay_Warnings then
5844          return;
5845       end if;
5846
5847       --  No warning if there is an explicit initialization
5848
5849       Init := Original_Node (Expression (Declaration_Node (Ent)));
5850
5851       if Present (Init) and then Comes_From_Source (Init) then
5852          return;
5853       end if;
5854
5855       --  We only give the warning for non-imported entities of a type for
5856       --  which a non-null base init proc is defined, or for objects of access
5857       --  types with implicit null initialization, or when Normalize_Scalars
5858       --  applies and the type is scalar or a string type (the latter being
5859       --  tested for because predefined String types are initialized by inline
5860       --  code rather than by an init_proc). Note that we do not give the
5861       --  warning for Initialize_Scalars, since we suppressed initialization
5862       --  in this case.
5863
5864       if Present (Expr)
5865         and then not Is_Imported (Ent)
5866         and then (Has_Non_Null_Base_Init_Proc (Typ)
5867                     or else Is_Access_Type (Typ)
5868                     or else (Normalize_Scalars
5869                               and then (Is_Scalar_Type (Typ)
5870                                          or else Is_String_Type (Typ))))
5871       then
5872          if Nkind (Expr) = N_Attribute_Reference
5873            and then Is_Entity_Name (Prefix (Expr))
5874          then
5875             Old := Entity (Prefix (Expr));
5876
5877          elsif Is_Entity_Name (Expr)
5878            and then Ekind (Entity (Expr)) = E_Constant
5879          then
5880             Decl := Declaration_Node (Entity (Expr));
5881
5882             if Nkind (Decl) = N_Object_Declaration
5883               and then Present (Expression (Decl))
5884               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5885               and then Is_Entity_Name (Prefix (Expression (Decl)))
5886             then
5887                Old := Entity (Prefix (Expression (Decl)));
5888
5889             elsif Nkind (Expr) = N_Function_Call then
5890                return;
5891             end if;
5892
5893          --  A function call (most likely to To_Address) is probably not an
5894          --  overlay, so skip warning. Ditto if the function call was inlined
5895          --  and transformed into an entity.
5896
5897          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5898             return;
5899          end if;
5900
5901          Decl := Next (Parent (Expr));
5902
5903          --  If a pragma Import follows, we assume that it is for the current
5904          --  target of the address clause, and skip the warning.
5905
5906          if Present (Decl)
5907            and then Nkind (Decl) = N_Pragma
5908            and then Pragma_Name (Decl) = Name_Import
5909          then
5910             return;
5911          end if;
5912
5913          if Present (Old) then
5914             Error_Msg_Node_2 := Old;
5915             Error_Msg_N
5916               ("default initialization of & may modify &?",
5917                Nam);
5918          else
5919             Error_Msg_N
5920               ("default initialization of & may modify overlaid storage?",
5921                Nam);
5922          end if;
5923
5924          --  Add friendly warning if initialization comes from a packed array
5925          --  component.
5926
5927          if Is_Record_Type (Typ)  then
5928             declare
5929                Comp : Entity_Id;
5930
5931             begin
5932                Comp := First_Component (Typ);
5933                while Present (Comp) loop
5934                   if Nkind (Parent (Comp)) = N_Component_Declaration
5935                     and then Present (Expression (Parent (Comp)))
5936                   then
5937                      exit;
5938                   elsif Is_Array_Type (Etype (Comp))
5939                      and then Present (Packed_Array_Type (Etype (Comp)))
5940                   then
5941                      Error_Msg_NE
5942                        ("\packed array component& " &
5943                         "will be initialized to zero?",
5944                         Nam, Comp);
5945                      exit;
5946                   else
5947                      Next_Component (Comp);
5948                   end if;
5949                end loop;
5950             end;
5951          end if;
5952
5953          Error_Msg_N
5954            ("\use pragma Import for & to " &
5955             "suppress initialization (RM B.1(24))?",
5956             Nam);
5957       end if;
5958    end Warn_Overlay;
5959
5960 end Freeze;