gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- You should have received a copy of the GNU General Public License along  --
  19 -- with this program; see file COPYING3.  If not see                        --
  20 -- <http://www.gnu.org/licenses/>.                                          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Elists;   use Elists;
  31 with Errout;   use Errout;
  32 with Exp_Ch3;  use Exp_Ch3;
  33 with Exp_Ch7;  use Exp_Ch7;
  34 with Exp_Disp; use Exp_Disp;
  35 with Exp_Pakd; use Exp_Pakd;
  36 with Exp_Util; use Exp_Util;
  37 with Exp_Tss;  use Exp_Tss;
  38 with Layout;   use Layout;
  39 with Lib;      use Lib;
  40 with Namet;    use Namet;
  41 with Nlists;   use Nlists;
  42 with Nmake;    use Nmake;
  43 with Opt;      use Opt;
  44 with Restrict; use Restrict;
  45 with Rident;   use Rident;
  46 with Sem;      use Sem;
  47 with Sem_Aux;  use Sem_Aux;
  48 with Sem_Cat;  use Sem_Cat;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch7;  use Sem_Ch7;
  51 with Sem_Ch8;  use Sem_Ch8;
  52 with Sem_Ch13; use Sem_Ch13;
  53 with Sem_Eval; use Sem_Eval;
  54 with Sem_Mech; use Sem_Mech;
  55 with Sem_Prag; use Sem_Prag;
  56 with Sem_Res;  use Sem_Res;
  57 with Sem_Util; use Sem_Util;
  58 with Sinfo;    use Sinfo;
  59 with Snames;   use Snames;
  60 with Stand;    use Stand;
  61 with Targparm; use Targparm;
  62 with Tbuild;   use Tbuild;
  63 with Ttypes;   use Ttypes;
  64 with Uintp;    use Uintp;
  65 with Urealp;   use Urealp;
  66
  67 package body Freeze is
  68
  69    -----------------------
  70    -- Local Subprograms --
  71    -----------------------
  72
  73    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  74    --  Typ is a type that is being frozen. If no size clause is given,
  75    --  but a default Esize has been computed, then this default Esize is
  76    --  adjusted up if necessary to be consistent with a given alignment,
  77    --  but never to a value greater than Long_Long_Integer'Size. This
  78    --  is used for all discrete types and for fixed-point types.
  79
  80    procedure Build_And_Analyze_Renamed_Body
  81      (Decl  : Node_Id;
  82       New_S : Entity_Id;
  83       After : in out Node_Id);
  84    --  Build body for a renaming declaration, insert in tree and analyze
  85
  86    procedure Check_Address_Clause (E : Entity_Id);
  87    --  Apply legality checks to address clauses for object declarations,
  88    --  at the point the object is frozen.
  89
  90    procedure Check_Strict_Alignment (E : Entity_Id);
  91    --  E is a base type. If E is tagged or has a component that is aliased
  92    --  or tagged or contains something this is aliased or tagged, set
  93    --  Strict_Alignment.
  94
  95    procedure Check_Unsigned_Type (E : Entity_Id);
  96    pragma Inline (Check_Unsigned_Type);
  97    --  If E is a fixed-point or discrete type, then all the necessary work
  98    --  to freeze it is completed except for possible setting of the flag
  99    --  Is_Unsigned_Type, which is done by this procedure. The call has no
 100    --  effect if the entity E is not a discrete or fixed-point type.
 101
 102    procedure Freeze_And_Append
 103      (Ent    : Entity_Id;
 104       N      : Node_Id;
 105       Result : in out List_Id);
 106    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 107    --  nodes to Result, modifying Result from No_List if necessary. N has
 108    --  the same usage as in Freeze_Entity.
 109
 110    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 111    --  Freeze enumeration type. The Esize field is set as processing
 112    --  proceeds (i.e. set by default when the type is declared and then
 113    --  adjusted by rep clauses. What this procedure does is to make sure
 114    --  that if a foreign convention is specified, and no specific size
 115    --  is given, then the size must be at least Integer'Size.
 116
 117    procedure Freeze_Static_Object (E : Entity_Id);
 118    --  If an object is frozen which has Is_Statically_Allocated set, then
 119    --  all referenced types must also be marked with this flag. This routine
 120    --  is in charge of meeting this requirement for the object entity E.
 121
 122    procedure Freeze_Subprogram (E : Entity_Id);
 123    --  Perform freezing actions for a subprogram (create extra formals,
 124    --  and set proper default mechanism values). Note that this routine
 125    --  is not called for internal subprograms, for which neither of these
 126    --  actions is needed (or desirable, we do not want for example to have
 127    --  these extra formals present in initialization procedures, where they
 128    --  would serve no purpose). In this call E is either a subprogram or
 129    --  a subprogram type (i.e. an access to a subprogram).
 130
 131    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 132    --  True if T is not private and has no private components, or has a full
 133    --  view. Used to determine whether the designated type of an access type
 134    --  should be frozen when the access type is frozen. This is done when an
 135    --  allocator is frozen, or an expression that may involve attributes of
 136    --  the designated type. Otherwise freezing the access type does not freeze
 137    --  the designated type.
 138
 139    procedure Process_Default_Expressions
 140      (E     : Entity_Id;
 141       After : in out Node_Id);
 142    --  This procedure is called for each subprogram to complete processing of
 143    --  default expressions at the point where all types are known to be frozen.
 144    --  The expressions must be analyzed in full, to make sure that all error
 145    --  processing is done (they have only been pre-analyzed). If the expression
 146    --  is not an entity or literal, its analysis may generate code which must
 147    --  not be executed. In that case we build a function body to hold that
 148    --  code. This wrapper function serves no other purpose (it used to be
 149    --  called to evaluate the default, but now the default is inlined at each
 150    --  point of call).
 151
 152    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 153    --  Typ is a record or array type that is being frozen. This routine sets
 154    --  the default component alignment from the scope stack values if the
 155    --  alignment is otherwise not specified.
 156
 157    procedure Check_Debug_Info_Needed (T : Entity_Id);
 158    --  As each entity is frozen, this routine is called to deal with the
 159    --  setting of Debug_Info_Needed for the entity. This flag is set if
 160    --  the entity comes from source, or if we are in Debug_Generated_Code
 161    --  mode or if the -gnatdV debug flag is set. However, it never sets
 162    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 163    --  subsidiary entities have the flag set as required.
 164
 165    procedure Undelay_Type (T : Entity_Id);
 166    --  T is a type of a component that we know to be an Itype. We don't want
 167    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 168    --  Full_View or Corresponding_Record_Type.
 169
 170    procedure Warn_Overlay
 171      (Expr : Node_Id;
 172       Typ  : Entity_Id;
 173       Nam  : Node_Id);
 174    --  Expr is the expression for an address clause for entity Nam whose type
 175    --  is Typ. If Typ has a default initialization, and there is no explicit
 176    --  initialization in the source declaration, check whether the address
 177    --  clause might cause overlaying of an entity, and emit a warning on the
 178    --  side effect that the initialization will cause.
 179
 180    -------------------------------
 181    -- Adjust_Esize_For_Alignment --
 182    -------------------------------
 183
 184    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 185       Align : Uint;
 186
 187    begin
 188       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 189          Align := Alignment_In_Bits (Typ);
 190
 191          if Align > Esize (Typ)
 192            and then Align <= Standard_Long_Long_Integer_Size
 193          then
 194             Set_Esize (Typ, Align);
 195          end if;
 196       end if;
 197    end Adjust_Esize_For_Alignment;
 198
 199    ------------------------------------
 200    -- Build_And_Analyze_Renamed_Body --
 201    ------------------------------------
 202
 203    procedure Build_And_Analyze_Renamed_Body
 204      (Decl  : Node_Id;
 205       New_S : Entity_Id;
 206       After : in out Node_Id)
 207    is
 208       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 209       Ent          : constant Entity_Id := Defining_Entity (Decl);
 210       Body_Node    : Node_Id;
 211       Renamed_Subp : Entity_Id;
 212
 213    begin
 214       --  If the renamed subprogram is intrinsic, there is no need for a
 215       --  wrapper body: we set the alias that will be called and expanded which
 216       --  completes the declaration. This transformation is only legal if the
 217       --  renamed entity has already been elaborated.
 218
 219       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 220       --  subprogram, as long as the renaming occurs before the new entity
 221       --  is frozen. See RM 8.5.4 (5).
 222
 223       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 224         and then Is_Entity_Name (Name (Body_Decl))
 225       then
 226          Renamed_Subp := Entity (Name (Body_Decl));
 227       else
 228          Renamed_Subp := Empty;
 229       end if;
 230
 231       if Present (Renamed_Subp)
 232         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 233         and then
 234           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 235             or else Sloc (Renamed_Subp) < Sloc (Ent))
 236
 237         --  We can make the renaming entity intrinsic if the renamed function
 238         --  has an interface name, or if it is one of the shift/rotate
 239         --  operations known to the compiler.
 240
 241         and then (Present (Interface_Name (Renamed_Subp))
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 243                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 244                    or else Chars (Renamed_Subp) = Name_Shift_Left
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right
 246                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 247       then
 248          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 249
 250          if Present (Alias (Renamed_Subp)) then
 251             Set_Alias (Ent, Alias (Renamed_Subp));
 252          else
 253             Set_Alias (Ent, Renamed_Subp);
 254          end if;
 255
 256          Set_Is_Intrinsic_Subprogram (Ent);
 257          Set_Has_Completion (Ent);
 258
 259       else
 260          Body_Node := Build_Renamed_Body (Decl, New_S);
 261          Insert_After (After, Body_Node);
 262          Mark_Rewrite_Insertion (Body_Node);
 263          Analyze (Body_Node);
 264          After := Body_Node;
 265       end if;
 266    end Build_And_Analyze_Renamed_Body;
 267
 268    ------------------------
 269    -- Build_Renamed_Body --
 270    ------------------------
 271
 272    function Build_Renamed_Body
 273      (Decl  : Node_Id;
 274       New_S : Entity_Id) return Node_Id
 275    is
 276       Loc : constant Source_Ptr := Sloc (New_S);
 277       --  We use for the source location of the renamed body, the location of
 278       --  the spec entity. It might seem more natural to use the location of
 279       --  the renaming declaration itself, but that would be wrong, since then
 280       --  the body we create would look as though it was created far too late,
 281       --  and this could cause problems with elaboration order analysis,
 282       --  particularly in connection with instantiations.
 283
 284       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 285       Nam        : constant Node_Id := Name (N);
 286       Old_S      : Entity_Id;
 287       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 288       Actuals    : List_Id := No_List;
 289       Call_Node  : Node_Id;
 290       Call_Name  : Node_Id;
 291       Body_Node  : Node_Id;
 292       Formal     : Entity_Id;
 293       O_Formal   : Entity_Id;
 294       Param_Spec : Node_Id;
 295
 296       Pref : Node_Id := Empty;
 297       --  If the renamed entity is a primitive operation given in prefix form,
 298       --  the prefix is the target object and it has to be added as the first
 299       --  actual in the generated call.
 300
 301    begin
 302       --  Determine the entity being renamed, which is the target of the call
 303       --  statement. If the name is an explicit dereference, this is a renaming
 304       --  of a subprogram type rather than a subprogram. The name itself is
 305       --  fully analyzed.
 306
 307       if Nkind (Nam) = N_Selected_Component then
 308          Old_S := Entity (Selector_Name (Nam));
 309
 310       elsif Nkind (Nam) = N_Explicit_Dereference then
 311          Old_S := Etype (Nam);
 312
 313       elsif Nkind (Nam) = N_Indexed_Component then
 314          if Is_Entity_Name (Prefix (Nam)) then
 315             Old_S := Entity (Prefix (Nam));
 316          else
 317             Old_S := Entity (Selector_Name (Prefix (Nam)));
 318          end if;
 319
 320       elsif Nkind (Nam) = N_Character_Literal then
 321          Old_S := Etype (New_S);
 322
 323       else
 324          Old_S := Entity (Nam);
 325       end if;
 326
 327       if Is_Entity_Name (Nam) then
 328
 329          --  If the renamed entity is a predefined operator, retain full name
 330          --  to ensure its visibility.
 331
 332          if Ekind (Old_S) = E_Operator
 333            and then Nkind (Nam) = N_Expanded_Name
 334          then
 335             Call_Name := New_Copy (Name (N));
 336          else
 337             Call_Name := New_Reference_To (Old_S, Loc);
 338          end if;
 339
 340       else
 341          if Nkind (Nam) = N_Selected_Component
 342            and then Present (First_Formal (Old_S))
 343            and then
 344              (Is_Controlling_Formal (First_Formal (Old_S))
 345                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 346          then
 347
 348             --  Retrieve the target object, to be added as a first actual
 349             --  in the call.
 350
 351             Call_Name := New_Occurrence_Of (Old_S, Loc);
 352             Pref := Prefix (Nam);
 353
 354          else
 355             Call_Name := New_Copy (Name (N));
 356          end if;
 357
 358          --  Original name may have been overloaded, but is fully resolved now
 359
 360          Set_Is_Overloaded (Call_Name, False);
 361       end if;
 362
 363       --  For simple renamings, subsequent calls can be expanded directly as
 364       --  calls to the renamed entity. The body must be generated in any case
 365       --  for calls that may appear elsewhere.
 366
 367       if Ekind_In (Old_S, E_Function, E_Procedure)
 368         and then Nkind (Decl) = N_Subprogram_Declaration
 369       then
 370          Set_Body_To_Inline (Decl, Old_S);
 371       end if;
 372
 373       --  The body generated for this renaming is an internal artifact, and
 374       --  does not  constitute a freeze point for the called entity.
 375
 376       Set_Must_Not_Freeze (Call_Name);
 377
 378       Formal := First_Formal (Defining_Entity (Decl));
 379
 380       if Present (Pref) then
 381          declare
 382             Pref_Type : constant Entity_Id := Etype (Pref);
 383             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 384
 385          begin
 386             --  The controlling formal may be an access parameter, or the
 387             --  actual may be an access value, so adjust accordingly.
 388
 389             if Is_Access_Type (Pref_Type)
 390               and then not Is_Access_Type (Form_Type)
 391             then
 392                Actuals := New_List
 393                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 394
 395             elsif Is_Access_Type (Form_Type)
 396               and then not Is_Access_Type (Pref)
 397             then
 398                Actuals := New_List
 399                  (Make_Attribute_Reference (Loc,
 400                    Attribute_Name => Name_Access,
 401                    Prefix => Relocate_Node (Pref)));
 402             else
 403                Actuals := New_List (Pref);
 404             end if;
 405          end;
 406
 407       elsif Present (Formal) then
 408          Actuals := New_List;
 409
 410       else
 411          Actuals := No_List;
 412       end if;
 413
 414       if Present (Formal) then
 415          while Present (Formal) loop
 416             Append (New_Reference_To (Formal, Loc), Actuals);
 417             Next_Formal (Formal);
 418          end loop;
 419       end if;
 420
 421       --  If the renamed entity is an entry, inherit its profile. For other
 422       --  renamings as bodies, both profiles must be subtype conformant, so it
 423       --  is not necessary to replace the profile given in the declaration.
 424       --  However, default values that are aggregates are rewritten when
 425       --  partially analyzed, so we recover the original aggregate to insure
 426       --  that subsequent conformity checking works. Similarly, if the default
 427       --  expression was constant-folded, recover the original expression.
 428
 429       Formal := First_Formal (Defining_Entity (Decl));
 430
 431       if Present (Formal) then
 432          O_Formal := First_Formal (Old_S);
 433          Param_Spec := First (Parameter_Specifications (Spec));
 434          while Present (Formal) loop
 435             if Is_Entry (Old_S) then
 436                if Nkind (Parameter_Type (Param_Spec)) /=
 437                                                     N_Access_Definition
 438                then
 439                   Set_Etype (Formal, Etype (O_Formal));
 440                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 441                end if;
 442
 443             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 444               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 445                                            Nkind (Default_Value (O_Formal))
 446             then
 447                Set_Expression (Param_Spec,
 448                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 449             end if;
 450
 451             Next_Formal (Formal);
 452             Next_Formal (O_Formal);
 453             Next (Param_Spec);
 454          end loop;
 455       end if;
 456
 457       --  If the renamed entity is a function, the generated body contains a
 458       --  return statement. Otherwise, build a procedure call. If the entity is
 459       --  an entry, subsequent analysis of the call will transform it into the
 460       --  proper entry or protected operation call. If the renamed entity is
 461       --  a character literal, return it directly.
 462
 463       if Ekind (Old_S) = E_Function
 464         or else Ekind (Old_S) = E_Operator
 465         or else (Ekind (Old_S) = E_Subprogram_Type
 466                   and then Etype (Old_S) /= Standard_Void_Type)
 467       then
 468          Call_Node :=
 469            Make_Simple_Return_Statement (Loc,
 470               Expression =>
 471                 Make_Function_Call (Loc,
 472                   Name => Call_Name,
 473                   Parameter_Associations => Actuals));
 474
 475       elsif Ekind (Old_S) = E_Enumeration_Literal then
 476          Call_Node :=
 477            Make_Simple_Return_Statement (Loc,
 478               Expression => New_Occurrence_Of (Old_S, Loc));
 479
 480       elsif Nkind (Nam) = N_Character_Literal then
 481          Call_Node :=
 482            Make_Simple_Return_Statement (Loc,
 483              Expression => Call_Name);
 484
 485       else
 486          Call_Node :=
 487            Make_Procedure_Call_Statement (Loc,
 488              Name => Call_Name,
 489              Parameter_Associations => Actuals);
 490       end if;
 491
 492       --  Create entities for subprogram body and formals
 493
 494       Set_Defining_Unit_Name (Spec,
 495         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 496
 497       Param_Spec := First (Parameter_Specifications (Spec));
 498       while Present (Param_Spec) loop
 499          Set_Defining_Identifier (Param_Spec,
 500            Make_Defining_Identifier (Loc,
 501              Chars => Chars (Defining_Identifier (Param_Spec))));
 502          Next (Param_Spec);
 503       end loop;
 504
 505       Body_Node :=
 506         Make_Subprogram_Body (Loc,
 507           Specification => Spec,
 508           Declarations => New_List,
 509           Handled_Statement_Sequence =>
 510             Make_Handled_Sequence_Of_Statements (Loc,
 511               Statements => New_List (Call_Node)));
 512
 513       if Nkind (Decl) /= N_Subprogram_Declaration then
 514          Rewrite (N,
 515            Make_Subprogram_Declaration (Loc,
 516              Specification => Specification (N)));
 517       end if;
 518
 519       --  Link the body to the entity whose declaration it completes. If
 520       --  the body is analyzed when the renamed entity is frozen, it may
 521       --  be necessary to restore the proper scope (see package Exp_Ch13).
 522
 523       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 524         and then Present (Corresponding_Spec (N))
 525       then
 526          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 527       else
 528          Set_Corresponding_Spec (Body_Node, New_S);
 529       end if;
 530
 531       return Body_Node;
 532    end Build_Renamed_Body;
 533
 534    --------------------------
 535    -- Check_Address_Clause --
 536    --------------------------
 537
 538    procedure Check_Address_Clause (E : Entity_Id) is
 539       Addr : constant Node_Id   := Address_Clause (E);
 540       Expr : Node_Id;
 541       Decl : constant Node_Id   := Declaration_Node (E);
 542       Typ  : constant Entity_Id := Etype (E);
 543
 544    begin
 545       if Present (Addr) then
 546          Expr := Expression (Addr);
 547
 548          if Needs_Constant_Address (Decl, Typ) then
 549             Check_Constant_Address_Clause (Expr, E);
 550
 551             --  Has_Delayed_Freeze was set on E when the address clause was
 552             --  analyzed. Reset the flag now unless freeze actions were
 553             --  attached to it in the mean time.
 554
 555             if No (Freeze_Node (E)) then
 556                Set_Has_Delayed_Freeze (E, False);
 557             end if;
 558          end if;
 559
 560          --  If Rep_Clauses are to be ignored, remove address clause from
 561          --  list attached to entity, because it may be illegal for gigi,
 562          --  for example by breaking order of elaboration..
 563
 564          if Ignore_Rep_Clauses then
 565             declare
 566                Rep : Node_Id;
 567
 568             begin
 569                Rep := First_Rep_Item (E);
 570
 571                if Rep = Addr then
 572                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 573
 574                else
 575                   while Present (Rep)
 576                     and then Next_Rep_Item (Rep) /= Addr
 577                   loop
 578                      Rep := Next_Rep_Item (Rep);
 579                   end loop;
 580                end if;
 581
 582                if Present (Rep) then
 583                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 584                end if;
 585             end;
 586
 587             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 588
 589          elsif not Error_Posted (Expr)
 590            and then not Needs_Finalization (Typ)
 591          then
 592             Warn_Overlay (Expr, Typ, Name (Addr));
 593          end if;
 594       end if;
 595    end Check_Address_Clause;
 596
 597    -----------------------------
 598    -- Check_Compile_Time_Size --
 599    -----------------------------
 600
 601    procedure Check_Compile_Time_Size (T : Entity_Id) is
 602
 603       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 604       --  Sets the compile time known size (32 bits or less) in the Esize
 605       --  field, of T checking for a size clause that was given which attempts
 606       --  to give a smaller size, and also checking for an alignment clause.
 607
 608       function Size_Known (T : Entity_Id) return Boolean;
 609       --  Recursive function that does all the work
 610
 611       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 612       --  If T is a constrained subtype, its size is not known if any of its
 613       --  discriminant constraints is not static and it is not a null record.
 614       --  The test is conservative and doesn't check that the components are
 615       --  in fact constrained by non-static discriminant values. Could be made
 616       --  more precise ???
 617
 618       --------------------
 619       -- Set_Small_Size --
 620       --------------------
 621
 622       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 623       begin
 624          if S > 32 then
 625             return;
 626
 627          --  Don't bother if alignment clause with a value other than 1 is
 628          --  present, because size may be padded up to meet back end alignment
 629          --  requirements, and only the back end knows the rules!
 630
 631          elsif Known_Alignment (T) and then Alignment (T) /= 1 then
 632             return;
 633
 634          --  Check for bad size clause given
 635
 636          elsif Has_Size_Clause (T) then
 637             if RM_Size (T) < S then
 638                Error_Msg_Uint_1 := S;
 639                Error_Msg_NE
 640                  ("size for& too small, minimum allowed is ^",
 641                   Size_Clause (T), T);
 642
 643             elsif Unknown_Esize (T) then
 644                Set_Esize (T, S);
 645             end if;
 646
 647          --  Set sizes if not set already
 648
 649          else
 650             if Unknown_Esize (T) then
 651                Set_Esize (T, S);
 652             end if;
 653
 654             if Unknown_RM_Size (T) then
 655                Set_RM_Size (T, S);
 656             end if;
 657          end if;
 658       end Set_Small_Size;
 659
 660       ----------------
 661       -- Size_Known --
 662       ----------------
 663
 664       function Size_Known (T : Entity_Id) return Boolean is
 665          Index : Entity_Id;
 666          Comp  : Entity_Id;
 667          Ctyp  : Entity_Id;
 668          Low   : Node_Id;
 669          High  : Node_Id;
 670
 671       begin
 672          if Size_Known_At_Compile_Time (T) then
 673             return True;
 674
 675          --  Always True for scalar types. This is true even for generic formal
 676          --  scalar types. We used to return False in the latter case, but the
 677          --  size is known at compile time, even in the template, we just do
 678          --  not know the exact size but that's not the point of this routine.
 679
 680          elsif Is_Scalar_Type (T)
 681            or else Is_Task_Type (T)
 682          then
 683             return True;
 684
 685          --  Array types
 686
 687          elsif Is_Array_Type (T) then
 688
 689             --  String literals always have known size, and we can set it
 690
 691             if Ekind (T) = E_String_Literal_Subtype then
 692                Set_Small_Size (T, Component_Size (T)
 693                                * String_Literal_Length (T));
 694                return True;
 695
 696             --  Unconstrained types never have known at compile time size
 697
 698             elsif not Is_Constrained (T) then
 699                return False;
 700
 701             --  Don't do any recursion on type with error posted, since we may
 702             --  have a malformed type that leads us into a loop.
 703
 704             elsif Error_Posted (T) then
 705                return False;
 706
 707             --  Otherwise if component size unknown, then array size unknown
 708
 709             elsif not Size_Known (Component_Type (T)) then
 710                return False;
 711             end if;
 712
 713             --  Check for all indexes static, and also compute possible size
 714             --  (in case it is less than 32 and may be packable).
 715
 716             declare
 717                Esiz : Uint := Component_Size (T);
 718                Dim  : Uint;
 719
 720             begin
 721                Index := First_Index (T);
 722                while Present (Index) loop
 723                   if Nkind (Index) = N_Range then
 724                      Get_Index_Bounds (Index, Low, High);
 725
 726                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 727                      return False;
 728
 729                   else
 730                      Low  := Type_Low_Bound (Etype (Index));
 731                      High := Type_High_Bound (Etype (Index));
 732                   end if;
 733
 734                   if not Compile_Time_Known_Value (Low)
 735                     or else not Compile_Time_Known_Value (High)
 736                     or else Etype (Index) = Any_Type
 737                   then
 738                      return False;
 739
 740                   else
 741                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 742
 743                      if Dim >= 0 then
 744                         Esiz := Esiz * Dim;
 745                      else
 746                         Esiz := Uint_0;
 747                      end if;
 748                   end if;
 749
 750                   Next_Index (Index);
 751                end loop;
 752
 753                Set_Small_Size (T, Esiz);
 754                return True;
 755             end;
 756
 757          --  Access types always have known at compile time sizes
 758
 759          elsif Is_Access_Type (T) then
 760             return True;
 761
 762          --  For non-generic private types, go to underlying type if present
 763
 764          elsif Is_Private_Type (T)
 765            and then not Is_Generic_Type (T)
 766            and then Present (Underlying_Type (T))
 767          then
 768             --  Don't do any recursion on type with error posted, since we may
 769             --  have a malformed type that leads us into a loop.
 770
 771             if Error_Posted (T) then
 772                return False;
 773             else
 774                return Size_Known (Underlying_Type (T));
 775             end if;
 776
 777          --  Record types
 778
 779          elsif Is_Record_Type (T) then
 780
 781             --  A class-wide type is never considered to have a known size
 782
 783             if Is_Class_Wide_Type (T) then
 784                return False;
 785
 786             --  A subtype of a variant record must not have non-static
 787             --  discriminated components.
 788
 789             elsif T /= Base_Type (T)
 790               and then not Static_Discriminated_Components (T)
 791             then
 792                return False;
 793
 794             --  Don't do any recursion on type with error posted, since we may
 795             --  have a malformed type that leads us into a loop.
 796
 797             elsif Error_Posted (T) then
 798                return False;
 799             end if;
 800
 801             --  Now look at the components of the record
 802
 803             declare
 804                --  The following two variables are used to keep track of the
 805                --  size of packed records if we can tell the size of the packed
 806                --  record in the front end. Packed_Size_Known is True if so far
 807                --  we can figure out the size. It is initialized to True for a
 808                --  packed record, unless the record has discriminants. The
 809                --  reason we eliminate the discriminated case is that we don't
 810                --  know the way the back end lays out discriminated packed
 811                --  records. If Packed_Size_Known is True, then Packed_Size is
 812                --  the size in bits so far.
 813
 814                Packed_Size_Known : Boolean :=
 815                                      Is_Packed (T)
 816                                        and then not Has_Discriminants (T);
 817
 818                Packed_Size : Uint := Uint_0;
 819
 820             begin
 821                --  Test for variant part present
 822
 823                if Has_Discriminants (T)
 824                  and then Present (Parent (T))
 825                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 826                  and then Nkind (Type_Definition (Parent (T))) =
 827                                                N_Record_Definition
 828                  and then not Null_Present (Type_Definition (Parent (T)))
 829                  and then Present (Variant_Part
 830                             (Component_List (Type_Definition (Parent (T)))))
 831                then
 832                   --  If variant part is present, and type is unconstrained,
 833                   --  then we must have defaulted discriminants, or a size
 834                   --  clause must be present for the type, or else the size
 835                   --  is definitely not known at compile time.
 836
 837                   if not Is_Constrained (T)
 838                     and then
 839                       No (Discriminant_Default_Value (First_Discriminant (T)))
 840                     and then Unknown_Esize (T)
 841                   then
 842                      return False;
 843                   end if;
 844                end if;
 845
 846                --  Loop through components
 847
 848                Comp := First_Component_Or_Discriminant (T);
 849                while Present (Comp) loop
 850                   Ctyp := Etype (Comp);
 851
 852                   --  We do not know the packed size if there is a component
 853                   --  clause present (we possibly could, but this would only
 854                   --  help in the case of a record with partial rep clauses.
 855                   --  That's because in the case of full rep clauses, the
 856                   --  size gets figured out anyway by a different circuit).
 857
 858                   if Present (Component_Clause (Comp)) then
 859                      Packed_Size_Known := False;
 860                   end if;
 861
 862                   --  We need to identify a component that is an array where
 863                   --  the index type is an enumeration type with non-standard
 864                   --  representation, and some bound of the type depends on a
 865                   --  discriminant.
 866
 867                   --  This is because gigi computes the size by doing a
 868                   --  substitution of the appropriate discriminant value in
 869                   --  the size expression for the base type, and gigi is not
 870                   --  clever enough to evaluate the resulting expression (which
 871                   --  involves a call to rep_to_pos) at compile time.
 872
 873                   --  It would be nice if gigi would either recognize that
 874                   --  this expression can be computed at compile time, or
 875                   --  alternatively figured out the size from the subtype
 876                   --  directly, where all the information is at hand ???
 877
 878                   if Is_Array_Type (Etype (Comp))
 879                     and then Present (Packed_Array_Type (Etype (Comp)))
 880                   then
 881                      declare
 882                         Ocomp  : constant Entity_Id :=
 883                                    Original_Record_Component (Comp);
 884                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 885                         Ind    : Node_Id;
 886                         Indtyp : Entity_Id;
 887                         Lo, Hi : Node_Id;
 888
 889                      begin
 890                         Ind := First_Index (OCtyp);
 891                         while Present (Ind) loop
 892                            Indtyp := Etype (Ind);
 893
 894                            if Is_Enumeration_Type (Indtyp)
 895                              and then Has_Non_Standard_Rep (Indtyp)
 896                            then
 897                               Lo := Type_Low_Bound  (Indtyp);
 898                               Hi := Type_High_Bound (Indtyp);
 899
 900                               if Is_Entity_Name (Lo)
 901                                 and then Ekind (Entity (Lo)) = E_Discriminant
 902                               then
 903                                  return False;
 904
 905                               elsif Is_Entity_Name (Hi)
 906                                 and then Ekind (Entity (Hi)) = E_Discriminant
 907                               then
 908                                  return False;
 909                               end if;
 910                            end if;
 911
 912                            Next_Index (Ind);
 913                         end loop;
 914                      end;
 915                   end if;
 916
 917                   --  Clearly size of record is not known if the size of one of
 918                   --  the components is not known.
 919
 920                   if not Size_Known (Ctyp) then
 921                      return False;
 922                   end if;
 923
 924                   --  Accumulate packed size if possible
 925
 926                   if Packed_Size_Known then
 927
 928                      --  We can only deal with elementary types, since for
 929                      --  non-elementary components, alignment enters into the
 930                      --  picture, and we don't know enough to handle proper
 931                      --  alignment in this context. Packed arrays count as
 932                      --  elementary if the representation is a modular type.
 933
 934                      if Is_Elementary_Type (Ctyp)
 935                        or else (Is_Array_Type (Ctyp)
 936                                  and then Present (Packed_Array_Type (Ctyp))
 937                                  and then Is_Modular_Integer_Type
 938                                             (Packed_Array_Type (Ctyp)))
 939                      then
 940                         --  If RM_Size is known and static, then we can keep
 941                         --  accumulating the packed size.
 942
 943                         if Known_Static_RM_Size (Ctyp) then
 944
 945                            --  A little glitch, to be removed sometime ???
 946                            --  gigi does not understand zero sizes yet.
 947
 948                            if RM_Size (Ctyp) = Uint_0 then
 949                               Packed_Size_Known := False;
 950
 951                            --  Normal case where we can keep accumulating the
 952                            --  packed array size.
 953
 954                            else
 955                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 956                            end if;
 957
 958                         --  If we have a field whose RM_Size is not known then
 959                         --  we can't figure out the packed size here.
 960
 961                         else
 962                            Packed_Size_Known := False;
 963                         end if;
 964
 965                      --  If we have a non-elementary type we can't figure out
 966                      --  the packed array size (alignment issues).
 967
 968                      else
 969                         Packed_Size_Known := False;
 970                      end if;
 971                   end if;
 972
 973                   Next_Component_Or_Discriminant (Comp);
 974                end loop;
 975
 976                if Packed_Size_Known then
 977                   Set_Small_Size (T, Packed_Size);
 978                end if;
 979
 980                return True;
 981             end;
 982
 983          --  All other cases, size not known at compile time
 984
 985          else
 986             return False;
 987          end if;
 988       end Size_Known;
 989
 990       -------------------------------------
 991       -- Static_Discriminated_Components --
 992       -------------------------------------
 993
 994       function Static_Discriminated_Components
 995         (T : Entity_Id) return Boolean
 996       is
 997          Constraint : Elmt_Id;
 998
 999       begin
1000          if Has_Discriminants (T)
1001            and then Present (Discriminant_Constraint (T))
1002            and then Present (First_Component (T))
1003          then
1004             Constraint := First_Elmt (Discriminant_Constraint (T));
1005             while Present (Constraint) loop
1006                if not Compile_Time_Known_Value (Node (Constraint)) then
1007                   return False;
1008                end if;
1009
1010                Next_Elmt (Constraint);
1011             end loop;
1012          end if;
1013
1014          return True;
1015       end Static_Discriminated_Components;
1016
1017    --  Start of processing for Check_Compile_Time_Size
1018
1019    begin
1020       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1021    end Check_Compile_Time_Size;
1022
1023    -----------------------------
1024    -- Check_Debug_Info_Needed --
1025    -----------------------------
1026
1027    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1028    begin
1029       if Debug_Info_Off (T) then
1030          return;
1031
1032       elsif Comes_From_Source (T)
1033         or else Debug_Generated_Code
1034         or else Debug_Flag_VV
1035         or else Needs_Debug_Info (T)
1036       then
1037          Set_Debug_Info_Needed (T);
1038       end if;
1039    end Check_Debug_Info_Needed;
1040
1041    ----------------------------
1042    -- Check_Strict_Alignment --
1043    ----------------------------
1044
1045    procedure Check_Strict_Alignment (E : Entity_Id) is
1046       Comp  : Entity_Id;
1047
1048    begin
1049       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1050          Set_Strict_Alignment (E);
1051
1052       elsif Is_Array_Type (E) then
1053          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1054
1055       elsif Is_Record_Type (E) then
1056          if Is_Limited_Record (E) then
1057             Set_Strict_Alignment (E);
1058             return;
1059          end if;
1060
1061          Comp := First_Component (E);
1062          while Present (Comp) loop
1063             if not Is_Type (Comp)
1064               and then (Strict_Alignment (Etype (Comp))
1065                          or else Is_Aliased (Comp))
1066             then
1067                Set_Strict_Alignment (E);
1068                return;
1069             end if;
1070
1071             Next_Component (Comp);
1072          end loop;
1073       end if;
1074    end Check_Strict_Alignment;
1075
1076    -------------------------
1077    -- Check_Unsigned_Type --
1078    -------------------------
1079
1080    procedure Check_Unsigned_Type (E : Entity_Id) is
1081       Ancestor : Entity_Id;
1082       Lo_Bound : Node_Id;
1083       Btyp     : Entity_Id;
1084
1085    begin
1086       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1087          return;
1088       end if;
1089
1090       --  Do not attempt to analyze case where range was in error
1091
1092       if No (Scalar_Range (E))
1093         or else Error_Posted (Scalar_Range (E))
1094       then
1095          return;
1096       end if;
1097
1098       --  The situation that is non trivial is something like
1099
1100       --     subtype x1 is integer range -10 .. +10;
1101       --     subtype x2 is x1 range 0 .. V1;
1102       --     subtype x3 is x2 range V2 .. V3;
1103       --     subtype x4 is x3 range V4 .. V5;
1104
1105       --  where Vn are variables. Here the base type is signed, but we still
1106       --  know that x4 is unsigned because of the lower bound of x2.
1107
1108       --  The only way to deal with this is to look up the ancestor chain
1109
1110       Ancestor := E;
1111       loop
1112          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1113             return;
1114          end if;
1115
1116          Lo_Bound := Type_Low_Bound (Ancestor);
1117
1118          if Compile_Time_Known_Value (Lo_Bound) then
1119
1120             if Expr_Rep_Value (Lo_Bound) >= 0 then
1121                Set_Is_Unsigned_Type (E, True);
1122             end if;
1123
1124             return;
1125
1126          else
1127             Ancestor := Ancestor_Subtype (Ancestor);
1128
1129             --  If no ancestor had a static lower bound, go to base type
1130
1131             if No (Ancestor) then
1132
1133                --  Note: the reason we still check for a compile time known
1134                --  value for the base type is that at least in the case of
1135                --  generic formals, we can have bounds that fail this test,
1136                --  and there may be other cases in error situations.
1137
1138                Btyp := Base_Type (E);
1139
1140                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1141                   return;
1142                end if;
1143
1144                Lo_Bound := Type_Low_Bound (Base_Type (E));
1145
1146                if Compile_Time_Known_Value (Lo_Bound)
1147                  and then Expr_Rep_Value (Lo_Bound) >= 0
1148                then
1149                   Set_Is_Unsigned_Type (E, True);
1150                end if;
1151
1152                return;
1153             end if;
1154          end if;
1155       end loop;
1156    end Check_Unsigned_Type;
1157
1158    -------------------------
1159    -- Is_Atomic_Aggregate --
1160    -------------------------
1161
1162    function  Is_Atomic_Aggregate
1163      (E   : Entity_Id;
1164       Typ : Entity_Id) return Boolean
1165    is
1166       Loc   : constant Source_Ptr := Sloc (E);
1167       New_N : Node_Id;
1168       Par   : Node_Id;
1169       Temp  : Entity_Id;
1170
1171    begin
1172       Par := Parent (E);
1173
1174       --  Array may be qualified, so find outer context
1175
1176       if Nkind (Par) = N_Qualified_Expression then
1177          Par := Parent (Par);
1178       end if;
1179
1180       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1181         and then Comes_From_Source (Par)
1182       then
1183          Temp := Make_Temporary (Loc, 'T', E);
1184          New_N :=
1185            Make_Object_Declaration (Loc,
1186              Defining_Identifier => Temp,
1187              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1188              Expression          => Relocate_Node (E));
1189          Insert_Before (Par, New_N);
1190          Analyze (New_N);
1191
1192          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1193          return True;
1194
1195       else
1196          return False;
1197       end if;
1198    end Is_Atomic_Aggregate;
1199
1200    ----------------
1201    -- Freeze_All --
1202    ----------------
1203
1204    --  Note: the easy coding for this procedure would be to just build a
1205    --  single list of freeze nodes and then insert them and analyze them
1206    --  all at once. This won't work, because the analysis of earlier freeze
1207    --  nodes may recursively freeze types which would otherwise appear later
1208    --  on in the freeze list. So we must analyze and expand the freeze nodes
1209    --  as they are generated.
1210
1211    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1212       E     : Entity_Id;
1213       Decl  : Node_Id;
1214
1215       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1216       --  This is the internal recursive routine that does freezing of entities
1217       --  (but NOT the analysis of default expressions, which should not be
1218       --  recursive, we don't want to analyze those till we are sure that ALL
1219       --  the types are frozen).
1220
1221       --------------------
1222       -- Freeze_All_Ent --
1223       --------------------
1224
1225       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1226          E     : Entity_Id;
1227          Flist : List_Id;
1228          Lastn : Node_Id;
1229
1230          procedure Process_Flist;
1231          --  If freeze nodes are present, insert and analyze, and reset cursor
1232          --  for next insertion.
1233
1234          -------------------
1235          -- Process_Flist --
1236          -------------------
1237
1238          procedure Process_Flist is
1239          begin
1240             if Is_Non_Empty_List (Flist) then
1241                Lastn := Next (After);
1242                Insert_List_After_And_Analyze (After, Flist);
1243
1244                if Present (Lastn) then
1245                   After := Prev (Lastn);
1246                else
1247                   After := Last (List_Containing (After));
1248                end if;
1249             end if;
1250          end Process_Flist;
1251
1252       --  Start or processing for Freeze_All_Ent
1253
1254       begin
1255          E := From;
1256          while Present (E) loop
1257
1258             --  If the entity is an inner package which is not a package
1259             --  renaming, then its entities must be frozen at this point. Note
1260             --  that such entities do NOT get frozen at the end of the nested
1261             --  package itself (only library packages freeze).
1262
1263             --  Same is true for task declarations, where anonymous records
1264             --  created for entry parameters must be frozen.
1265
1266             if Ekind (E) = E_Package
1267               and then No (Renamed_Object (E))
1268               and then not Is_Child_Unit (E)
1269               and then not Is_Frozen (E)
1270             then
1271                Push_Scope (E);
1272                Install_Visible_Declarations (E);
1273                Install_Private_Declarations (E);
1274
1275                Freeze_All (First_Entity (E), After);
1276
1277                End_Package_Scope (E);
1278
1279             elsif Ekind (E) in Task_Kind
1280               and then
1281                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1282                    or else
1283                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1284             then
1285                Push_Scope (E);
1286                Freeze_All (First_Entity (E), After);
1287                End_Scope;
1288
1289             --  For a derived tagged type, we must ensure that all the
1290             --  primitive operations of the parent have been frozen, so that
1291             --  their addresses will be in the parent's dispatch table at the
1292             --  point it is inherited.
1293
1294             elsif Ekind (E) = E_Record_Type
1295               and then Is_Tagged_Type (E)
1296               and then Is_Tagged_Type (Etype (E))
1297               and then Is_Derived_Type (E)
1298             then
1299                declare
1300                   Prim_List : constant Elist_Id :=
1301                                Primitive_Operations (Etype (E));
1302
1303                   Prim : Elmt_Id;
1304                   Subp : Entity_Id;
1305
1306                begin
1307                   Prim  := First_Elmt (Prim_List);
1308                   while Present (Prim) loop
1309                      Subp := Node (Prim);
1310
1311                      if Comes_From_Source (Subp)
1312                        and then not Is_Frozen (Subp)
1313                      then
1314                         Flist := Freeze_Entity (Subp, After);
1315                         Process_Flist;
1316                      end if;
1317
1318                      Next_Elmt (Prim);
1319                   end loop;
1320                end;
1321             end if;
1322
1323             if not Is_Frozen (E) then
1324                Flist := Freeze_Entity (E, After);
1325                Process_Flist;
1326
1327             --  If already frozen, and there are delayed aspects, this is where
1328             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1329             --  for a description of how we handle aspect visibility).
1330
1331             elsif Has_Delayed_Aspects (E) then
1332                declare
1333                   Ritem : Node_Id;
1334
1335                begin
1336                   Ritem := First_Rep_Item (E);
1337                   while Present (Ritem) loop
1338                      if Nkind (Ritem) = N_Aspect_Specification
1339                        and then Entity (Ritem) = E
1340                        and then Is_Delayed_Aspect (Ritem)
1341                      then
1342                         Check_Aspect_At_End_Of_Declarations (Ritem);
1343                      end if;
1344
1345                      Ritem := Next_Rep_Item (Ritem);
1346                   end loop;
1347                end;
1348             end if;
1349
1350             --  If an incomplete type is still not frozen, this may be a
1351             --  premature freezing because of a body declaration that follows.
1352             --  Indicate where the freezing took place.
1353
1354             --  If the freezing is caused by the end of the current declarative
1355             --  part, it is a Taft Amendment type, and there is no error.
1356
1357             if not Is_Frozen (E)
1358               and then Ekind (E) = E_Incomplete_Type
1359             then
1360                declare
1361                   Bod : constant Node_Id := Next (After);
1362
1363                begin
1364                   if (Nkind_In (Bod, N_Subprogram_Body,
1365                                      N_Entry_Body,
1366                                      N_Package_Body,
1367                                      N_Protected_Body,
1368                                      N_Task_Body)
1369                         or else Nkind (Bod) in N_Body_Stub)
1370                      and then
1371                        List_Containing (After) = List_Containing (Parent (E))
1372                   then
1373                      Error_Msg_Sloc := Sloc (Next (After));
1374                      Error_Msg_NE
1375                        ("type& is frozen# before its full declaration",
1376                          Parent (E), E);
1377                   end if;
1378                end;
1379             end if;
1380
1381             Next_Entity (E);
1382          end loop;
1383       end Freeze_All_Ent;
1384
1385    --  Start of processing for Freeze_All
1386
1387    begin
1388       Freeze_All_Ent (From, After);
1389
1390       --  Now that all types are frozen, we can deal with default expressions
1391       --  that require us to build a default expression functions. This is the
1392       --  point at which such functions are constructed (after all types that
1393       --  might be used in such expressions have been frozen).
1394
1395       --  For subprograms that are renaming_as_body, we create the wrapper
1396       --  bodies as needed.
1397
1398       --  We also add finalization chains to access types whose designated
1399       --  types are controlled. This is normally done when freezing the type,
1400       --  but this misses recursive type definitions where the later members
1401       --  of the recursion introduce controlled components.
1402
1403       --  Loop through entities
1404
1405       E := From;
1406       while Present (E) loop
1407          if Is_Subprogram (E) then
1408
1409             if not Default_Expressions_Processed (E) then
1410                Process_Default_Expressions (E, After);
1411             end if;
1412
1413             if not Has_Completion (E) then
1414                Decl := Unit_Declaration_Node (E);
1415
1416                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1417                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1418
1419                elsif Nkind (Decl) = N_Subprogram_Declaration
1420                  and then Present (Corresponding_Body (Decl))
1421                  and then
1422                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1423                                           = N_Subprogram_Renaming_Declaration
1424                then
1425                   Build_And_Analyze_Renamed_Body
1426                     (Decl, Corresponding_Body (Decl), After);
1427                end if;
1428             end if;
1429
1430          elsif Ekind (E) in Task_Kind
1431            and then
1432              (Nkind (Parent (E)) = N_Task_Type_Declaration
1433                 or else
1434               Nkind (Parent (E)) = N_Single_Task_Declaration)
1435          then
1436             declare
1437                Ent : Entity_Id;
1438
1439             begin
1440                Ent := First_Entity (E);
1441                while Present (Ent) loop
1442                   if Is_Entry (Ent)
1443                     and then not Default_Expressions_Processed (Ent)
1444                   then
1445                      Process_Default_Expressions (Ent, After);
1446                   end if;
1447
1448                   Next_Entity (Ent);
1449                end loop;
1450             end;
1451
1452          elsif Is_Access_Type (E)
1453            and then Comes_From_Source (E)
1454            and then Ekind (Directly_Designated_Type (E)) = E_Incomplete_Type
1455            and then Needs_Finalization (Designated_Type (E))
1456            and then No (Associated_Final_Chain (E))
1457          then
1458             Build_Final_List (Parent (E), E);
1459          end if;
1460
1461          Next_Entity (E);
1462       end loop;
1463    end Freeze_All;
1464
1465    -----------------------
1466    -- Freeze_And_Append --
1467    -----------------------
1468
1469    procedure Freeze_And_Append
1470      (Ent    : Entity_Id;
1471       N      : Node_Id;
1472       Result : in out List_Id)
1473    is
1474       L : constant List_Id := Freeze_Entity (Ent, N);
1475    begin
1476       if Is_Non_Empty_List (L) then
1477          if Result = No_List then
1478             Result := L;
1479          else
1480             Append_List (L, Result);
1481          end if;
1482       end if;
1483    end Freeze_And_Append;
1484
1485    -------------------
1486    -- Freeze_Before --
1487    -------------------
1488
1489    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1490       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1491    begin
1492       if Is_Non_Empty_List (Freeze_Nodes) then
1493          Insert_Actions (N, Freeze_Nodes);
1494       end if;
1495    end Freeze_Before;
1496
1497    -------------------
1498    -- Freeze_Entity --
1499    -------------------
1500
1501    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1502       Loc    : constant Source_Ptr := Sloc (N);
1503       Test_E : Entity_Id := E;
1504       Comp   : Entity_Id;
1505       F_Node : Node_Id;
1506       Result : List_Id;
1507       Indx   : Node_Id;
1508       Formal : Entity_Id;
1509       Atype  : Entity_Id;
1510
1511       Has_Default_Initialization : Boolean := False;
1512       --  This flag gets set to true for a variable with default initialization
1513
1514       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1515       --  Check that an Access or Unchecked_Access attribute with a prefix
1516       --  which is the current instance type can only be applied when the type
1517       --  is limited.
1518
1519       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1520       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1521       --  integer literal without an explicit corresponding size clause. The
1522       --  caller has checked that Utype is a modular integer type.
1523
1524       function After_Last_Declaration return Boolean;
1525       --  If Loc is a freeze_entity that appears after the last declaration
1526       --  in the scope, inhibit error messages on late completion.
1527
1528       procedure Freeze_Record_Type (Rec : Entity_Id);
1529       --  Freeze each component, handle some representation clauses, and freeze
1530       --  primitive operations if this is a tagged type.
1531
1532       ----------------------------
1533       -- After_Last_Declaration --
1534       ----------------------------
1535
1536       function After_Last_Declaration return Boolean is
1537          Spec : constant Node_Id := Parent (Current_Scope);
1538       begin
1539          if Nkind (Spec) = N_Package_Specification then
1540             if Present (Private_Declarations (Spec)) then
1541                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1542             elsif Present (Visible_Declarations (Spec)) then
1543                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1544             else
1545                return False;
1546             end if;
1547          else
1548             return False;
1549          end if;
1550       end After_Last_Declaration;
1551
1552       ----------------------------
1553       -- Check_Current_Instance --
1554       ----------------------------
1555
1556       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1557
1558          Rec_Type : constant Entity_Id :=
1559                       Scope (Defining_Identifier (Comp_Decl));
1560
1561          Decl : constant Node_Id := Parent (Rec_Type);
1562
1563          function Process (N : Node_Id) return Traverse_Result;
1564          --  Process routine to apply check to given node
1565
1566          -------------
1567          -- Process --
1568          -------------
1569
1570          function Process (N : Node_Id) return Traverse_Result is
1571          begin
1572             case Nkind (N) is
1573                when N_Attribute_Reference =>
1574                   if (Attribute_Name (N) = Name_Access
1575                         or else
1576                       Attribute_Name (N) = Name_Unchecked_Access)
1577                     and then Is_Entity_Name (Prefix (N))
1578                     and then Is_Type (Entity (Prefix (N)))
1579                     and then Entity (Prefix (N)) = E
1580                   then
1581                      Error_Msg_N
1582                        ("current instance must be a limited type", Prefix (N));
1583                      return Abandon;
1584                   else
1585                      return OK;
1586                   end if;
1587
1588                when others => return OK;
1589             end case;
1590          end Process;
1591
1592          procedure Traverse is new Traverse_Proc (Process);
1593
1594       --  Start of processing for Check_Current_Instance
1595
1596       begin
1597          --  In Ada95, the (imprecise) rule is that the current instance of a
1598          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1599          --  either a tagged type, or a limited record.
1600
1601          if Is_Limited_Type (Rec_Type)
1602            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1603          then
1604             return;
1605
1606          elsif Nkind (Decl) = N_Full_Type_Declaration
1607            and then Limited_Present (Type_Definition (Decl))
1608          then
1609             return;
1610
1611          else
1612             Traverse (Comp_Decl);
1613          end if;
1614       end Check_Current_Instance;
1615
1616       ------------------------------
1617       -- Check_Suspicious_Modulus --
1618       ------------------------------
1619
1620       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1621          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1622
1623       begin
1624          if Nkind (Decl) = N_Full_Type_Declaration then
1625             declare
1626                Tdef : constant Node_Id := Type_Definition (Decl);
1627             begin
1628                if Nkind (Tdef) = N_Modular_Type_Definition then
1629                   declare
1630                      Modulus : constant Node_Id :=
1631                                  Original_Node (Expression (Tdef));
1632                   begin
1633                      if Nkind (Modulus) = N_Integer_Literal then
1634                         declare
1635                            Modv : constant Uint := Intval (Modulus);
1636                            Sizv : constant Uint := RM_Size (Utype);
1637
1638                         begin
1639                            --  First case, modulus and size are the same. This
1640                            --  happens if you have something like mod 32, with
1641                            --  an explicit size of 32, this is for sure a case
1642                            --  where the warning is given, since it is seems
1643                            --  very unlikely that someone would want e.g. a
1644                            --  five bit type stored in 32 bits. It is much
1645                            --  more likely they wanted a 32-bit type.
1646
1647                            if Modv = Sizv then
1648                               null;
1649
1650                            --  Second case, the modulus is 32 or 64 and no
1651                            --  size clause is present. This is a less clear
1652                            --  case for giving the warning, but in the case
1653                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1654                            --  enough that it is a likely error (and in any
1655                            --  case using 2**5 or 2**6 in these cases seems
1656                            --  clearer. We don't include 8 or 16 here, simply
1657                            --  because in practice 3-bit and 4-bit types are
1658                            --  more common and too many false positives if
1659                            --  we warn in these cases.
1660
1661                            elsif not Has_Size_Clause (Utype)
1662                              and then (Modv = Uint_32 or else Modv = Uint_64)
1663                            then
1664                               null;
1665
1666                            --  No warning needed
1667
1668                            else
1669                               return;
1670                            end if;
1671
1672                            --  If we fall through, give warning
1673
1674                            Error_Msg_Uint_1 := Modv;
1675                            Error_Msg_N
1676                              ("?2 '*'*^' may have been intended here",
1677                               Modulus);
1678                         end;
1679                      end if;
1680                   end;
1681                end if;
1682             end;
1683          end if;
1684       end Check_Suspicious_Modulus;
1685
1686       ------------------------
1687       -- Freeze_Record_Type --
1688       ------------------------
1689
1690       procedure Freeze_Record_Type (Rec : Entity_Id) is
1691          Comp : Entity_Id;
1692          IR   : Node_Id;
1693          ADC  : Node_Id;
1694          Prev : Entity_Id;
1695
1696          Junk : Boolean;
1697          pragma Warnings (Off, Junk);
1698
1699          Unplaced_Component : Boolean := False;
1700          --  Set True if we find at least one component with no component
1701          --  clause (used to warn about useless Pack pragmas).
1702
1703          Placed_Component : Boolean := False;
1704          --  Set True if we find at least one component with a component
1705          --  clause (used to warn about useless Bit_Order pragmas, and also
1706          --  to detect cases where Implicit_Packing may have an effect).
1707
1708          All_Scalar_Components : Boolean := True;
1709          --  Set False if we encounter a component of a non-scalar type
1710
1711          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1712          Scalar_Component_Total_Esize   : Uint := Uint_0;
1713          --  Accumulates total RM_Size values and total Esize values of all
1714          --  scalar components. Used for processing of Implicit_Packing.
1715
1716          function Check_Allocator (N : Node_Id) return Node_Id;
1717          --  If N is an allocator, possibly wrapped in one or more level of
1718          --  qualified expression(s), return the inner allocator node, else
1719          --  return Empty.
1720
1721          procedure Check_Itype (Typ : Entity_Id);
1722          --  If the component subtype is an access to a constrained subtype of
1723          --  an already frozen type, make the subtype frozen as well. It might
1724          --  otherwise be frozen in the wrong scope, and a freeze node on
1725          --  subtype has no effect. Similarly, if the component subtype is a
1726          --  regular (not protected) access to subprogram, set the anonymous
1727          --  subprogram type to frozen as well, to prevent an out-of-scope
1728          --  freeze node at some eventual point of call. Protected operations
1729          --  are handled elsewhere.
1730
1731          ---------------------
1732          -- Check_Allocator --
1733          ---------------------
1734
1735          function Check_Allocator (N : Node_Id) return Node_Id is
1736             Inner : Node_Id;
1737          begin
1738             Inner := N;
1739             loop
1740                if Nkind (Inner) = N_Allocator then
1741                   return Inner;
1742                elsif Nkind (Inner) = N_Qualified_Expression then
1743                   Inner := Expression (Inner);
1744                else
1745                   return Empty;
1746                end if;
1747             end loop;
1748          end Check_Allocator;
1749
1750          -----------------
1751          -- Check_Itype --
1752          -----------------
1753
1754          procedure Check_Itype (Typ : Entity_Id) is
1755             Desig : constant Entity_Id := Designated_Type (Typ);
1756
1757          begin
1758             if not Is_Frozen (Desig)
1759               and then Is_Frozen (Base_Type (Desig))
1760             then
1761                Set_Is_Frozen (Desig);
1762
1763                --  In addition, add an Itype_Reference to ensure that the
1764                --  access subtype is elaborated early enough. This cannot be
1765                --  done if the subtype may depend on discriminants.
1766
1767                if Ekind (Comp) = E_Component
1768                  and then Is_Itype (Etype (Comp))
1769                  and then not Has_Discriminants (Rec)
1770                then
1771                   IR := Make_Itype_Reference (Sloc (Comp));
1772                   Set_Itype (IR, Desig);
1773
1774                   if No (Result) then
1775                      Result := New_List (IR);
1776                   else
1777                      Append (IR, Result);
1778                   end if;
1779                end if;
1780
1781             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1782               and then Convention (Desig) /= Convention_Protected
1783             then
1784                Set_Is_Frozen (Desig);
1785             end if;
1786          end Check_Itype;
1787
1788       --  Start of processing for Freeze_Record_Type
1789
1790       begin
1791          --  If this is a subtype of a controlled type, declared without a
1792          --  constraint, the _controller may not appear in the component list
1793          --  if the parent was not frozen at the point of subtype declaration.
1794          --  Inherit the _controller component now.
1795
1796          if Rec /= Base_Type (Rec)
1797            and then Has_Controlled_Component (Rec)
1798          then
1799             if Nkind (Parent (Rec)) = N_Subtype_Declaration
1800               and then Is_Entity_Name (Subtype_Indication (Parent (Rec)))
1801             then
1802                Set_First_Entity (Rec, First_Entity (Base_Type (Rec)));
1803
1804             --  If this is an internal type without a declaration, as for
1805             --  record component, the base type may not yet be frozen, and its
1806             --  controller has not been created. Add an explicit freeze node
1807             --  for the itype, so it will be frozen after the base type. This
1808             --  freeze node is used to communicate with the expander, in order
1809             --  to create the controller for the enclosing record, and it is
1810             --  deleted afterwards (see exp_ch3). It must not be created when
1811             --  expansion is off, because it might appear in the wrong context
1812             --  for the back end.
1813
1814             elsif Is_Itype (Rec)
1815               and then Has_Delayed_Freeze (Base_Type (Rec))
1816               and then
1817                 Nkind (Associated_Node_For_Itype (Rec)) =
1818                                                      N_Component_Declaration
1819               and then Expander_Active
1820             then
1821                Ensure_Freeze_Node (Rec);
1822             end if;
1823          end if;
1824
1825          --  Freeze components and embedded subtypes
1826
1827          Comp := First_Entity (Rec);
1828          Prev := Empty;
1829          while Present (Comp) loop
1830
1831             --  First handle the component case
1832
1833             if Ekind (Comp) = E_Component
1834               or else Ekind (Comp) = E_Discriminant
1835             then
1836                declare
1837                   CC : constant Node_Id := Component_Clause (Comp);
1838
1839                begin
1840                   --  Freezing a record type freezes the type of each of its
1841                   --  components. However, if the type of the component is
1842                   --  part of this record, we do not want or need a separate
1843                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1844                   --  also set in private type cases. We also can't check for
1845                   --  the Scope being exactly Rec because of private types and
1846                   --  record extensions.
1847
1848                   if Is_Itype (Etype (Comp))
1849                     and then Is_Record_Type (Underlying_Type
1850                                              (Scope (Etype (Comp))))
1851                   then
1852                      Undelay_Type (Etype (Comp));
1853                   end if;
1854
1855                   Freeze_And_Append (Etype (Comp), N, Result);
1856
1857                   --  Check for error of component clause given for variable
1858                   --  sized type. We have to delay this test till this point,
1859                   --  since the component type has to be frozen for us to know
1860                   --  if it is variable length. We omit this test in a generic
1861                   --  context, it will be applied at instantiation time.
1862
1863                   if Present (CC) then
1864                      Placed_Component := True;
1865
1866                      if Inside_A_Generic then
1867                         null;
1868
1869                      elsif not
1870                        Size_Known_At_Compile_Time
1871                          (Underlying_Type (Etype (Comp)))
1872                      then
1873                         Error_Msg_N
1874                           ("component clause not allowed for variable " &
1875                            "length component", CC);
1876                      end if;
1877
1878                   else
1879                      Unplaced_Component := True;
1880                   end if;
1881
1882                   --  Case of component requires byte alignment
1883
1884                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1885
1886                      --  Set the enclosing record to also require byte align
1887
1888                      Set_Must_Be_On_Byte_Boundary (Rec);
1889
1890                      --  Check for component clause that is inconsistent with
1891                      --  the required byte boundary alignment.
1892
1893                      if Present (CC)
1894                        and then Normalized_First_Bit (Comp) mod
1895                                   System_Storage_Unit /= 0
1896                      then
1897                         Error_Msg_N
1898                           ("component & must be byte aligned",
1899                            Component_Name (Component_Clause (Comp)));
1900                      end if;
1901                   end if;
1902                end;
1903             end if;
1904
1905             --  Gather data for possible Implicit_Packing later. Note that at
1906             --  this stage we might be dealing with a real component, or with
1907             --  an implicit subtype declaration.
1908
1909             if not Is_Scalar_Type (Etype (Comp)) then
1910                All_Scalar_Components := False;
1911             else
1912                Scalar_Component_Total_RM_Size :=
1913                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1914                Scalar_Component_Total_Esize :=
1915                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1916             end if;
1917
1918             --  If the component is an Itype with Delayed_Freeze and is either
1919             --  a record or array subtype and its base type has not yet been
1920             --  frozen, we must remove this from the entity list of this record
1921             --  and put it on the entity list of the scope of its base type.
1922             --  Note that we know that this is not the type of a component
1923             --  since we cleared Has_Delayed_Freeze for it in the previous
1924             --  loop. Thus this must be the Designated_Type of an access type,
1925             --  which is the type of a component.
1926
1927             if Is_Itype (Comp)
1928               and then Is_Type (Scope (Comp))
1929               and then Is_Composite_Type (Comp)
1930               and then Base_Type (Comp) /= Comp
1931               and then Has_Delayed_Freeze (Comp)
1932               and then not Is_Frozen (Base_Type (Comp))
1933             then
1934                declare
1935                   Will_Be_Frozen : Boolean := False;
1936                   S              : Entity_Id;
1937
1938                begin
1939                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1940                   --  being defined in a subprogram that's created as part of
1941                   --  the freezing of Rec'Base. In that case, we know that
1942                   --  Comp'Base must have already been frozen by the time we
1943                   --  get to elaborate this because Gigi doesn't elaborate any
1944                   --  bodies until it has elaborated all of the declarative
1945                   --  part. But Is_Frozen will not be set at this point because
1946                   --  we are processing code in lexical order.
1947
1948                   --  We detect this case by going up the Scope chain of Rec
1949                   --  and seeing if we have a subprogram scope before reaching
1950                   --  the top of the scope chain or that of Comp'Base. If we
1951                   --  do, then mark that Comp'Base will actually be frozen. If
1952                   --  so, we merely undelay it.
1953
1954                   S := Scope (Rec);
1955                   while Present (S) loop
1956                      if Is_Subprogram (S) then
1957                         Will_Be_Frozen := True;
1958                         exit;
1959                      elsif S = Scope (Base_Type (Comp)) then
1960                         exit;
1961                      end if;
1962
1963                      S := Scope (S);
1964                   end loop;
1965
1966                   if Will_Be_Frozen then
1967                      Undelay_Type (Comp);
1968                   else
1969                      if Present (Prev) then
1970                         Set_Next_Entity (Prev, Next_Entity (Comp));
1971                      else
1972                         Set_First_Entity (Rec, Next_Entity (Comp));
1973                      end if;
1974
1975                      --  Insert in entity list of scope of base type (which
1976                      --  must be an enclosing scope, because still unfrozen).
1977
1978                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1979                   end if;
1980                end;
1981
1982             --  If the component is an access type with an allocator as default
1983             --  value, the designated type will be frozen by the corresponding
1984             --  expression in init_proc. In order to place the freeze node for
1985             --  the designated type before that for the current record type,
1986             --  freeze it now.
1987
1988             --  Same process if the component is an array of access types,
1989             --  initialized with an aggregate. If the designated type is
1990             --  private, it cannot contain allocators, and it is premature
1991             --  to freeze the type, so we check for this as well.
1992
1993             elsif Is_Access_Type (Etype (Comp))
1994               and then Present (Parent (Comp))
1995               and then Present (Expression (Parent (Comp)))
1996             then
1997                declare
1998                   Alloc : constant Node_Id :=
1999                             Check_Allocator (Expression (Parent (Comp)));
2000
2001                begin
2002                   if Present (Alloc) then
2003
2004                      --  If component is pointer to a classwide type, freeze
2005                      --  the specific type in the expression being allocated.
2006                      --  The expression may be a subtype indication, in which
2007                      --  case freeze the subtype mark.
2008
2009                      if Is_Class_Wide_Type
2010                           (Designated_Type (Etype (Comp)))
2011                      then
2012                         if Is_Entity_Name (Expression (Alloc)) then
2013                            Freeze_And_Append
2014                              (Entity (Expression (Alloc)), N, Result);
2015                         elsif
2016                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2017                         then
2018                            Freeze_And_Append
2019                             (Entity (Subtype_Mark (Expression (Alloc))),
2020                              N, Result);
2021                         end if;
2022
2023                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2024                         Check_Itype (Etype (Comp));
2025
2026                      else
2027                         Freeze_And_Append
2028                           (Designated_Type (Etype (Comp)), N, Result);
2029                      end if;
2030                   end if;
2031                end;
2032
2033             elsif Is_Access_Type (Etype (Comp))
2034               and then Is_Itype (Designated_Type (Etype (Comp)))
2035             then
2036                Check_Itype (Etype (Comp));
2037
2038             elsif Is_Array_Type (Etype (Comp))
2039               and then Is_Access_Type (Component_Type (Etype (Comp)))
2040               and then Present (Parent (Comp))
2041               and then Nkind (Parent (Comp)) = N_Component_Declaration
2042               and then Present (Expression (Parent (Comp)))
2043               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2044               and then Is_Fully_Defined
2045                  (Designated_Type (Component_Type (Etype (Comp))))
2046             then
2047                Freeze_And_Append
2048                  (Designated_Type
2049                    (Component_Type (Etype (Comp))), N, Result);
2050             end if;
2051
2052             Prev := Comp;
2053             Next_Entity (Comp);
2054          end loop;
2055
2056          --  Deal with pragma Bit_Order setting non-standard bit order
2057
2058          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2059             if not Placed_Component then
2060                ADC :=
2061                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2062                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2063                Error_Msg_N
2064                  ("\?since no component clauses were specified", ADC);
2065
2066             --  Here is where we do the processing for reversed bit order
2067
2068             else
2069                Adjust_Record_For_Reverse_Bit_Order (Rec);
2070             end if;
2071          end if;
2072
2073          --  Complete error checking on record representation clause (e.g.
2074          --  overlap of components). This is called after adjusting the
2075          --  record for reverse bit order.
2076
2077          declare
2078             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2079          begin
2080             if Present (RRC) then
2081                Check_Record_Representation_Clause (RRC);
2082             end if;
2083          end;
2084
2085          --  Set OK_To_Reorder_Components depending on debug flags
2086
2087          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2088             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2089                   or else
2090                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2091             then
2092                Set_OK_To_Reorder_Components (Rec);
2093             end if;
2094          end if;
2095
2096          --  Check for useless pragma Pack when all components placed. We only
2097          --  do this check for record types, not subtypes, since a subtype may
2098          --  have all its components placed, and it still makes perfectly good
2099          --  sense to pack other subtypes or the parent type. We do not give
2100          --  this warning if Optimize_Alignment is set to Space, since the
2101          --  pragma Pack does have an effect in this case (it always resets
2102          --  the alignment to one).
2103
2104          if Ekind (Rec) = E_Record_Type
2105            and then Is_Packed (Rec)
2106            and then not Unplaced_Component
2107            and then Optimize_Alignment /= 'S'
2108          then
2109             --  Reset packed status. Probably not necessary, but we do it so
2110             --  that there is no chance of the back end doing something strange
2111             --  with this redundant indication of packing.
2112
2113             Set_Is_Packed (Rec, False);
2114
2115             --  Give warning if redundant constructs warnings on
2116
2117             if Warn_On_Redundant_Constructs then
2118                Error_Msg_N -- CODEFIX
2119                  ("?pragma Pack has no effect, no unplaced components",
2120                   Get_Rep_Pragma (Rec, Name_Pack));
2121             end if;
2122          end if;
2123
2124          --  If this is the record corresponding to a remote type, freeze the
2125          --  remote type here since that is what we are semantically freezing.
2126          --  This prevents the freeze node for that type in an inner scope.
2127
2128          --  Also, Check for controlled components and unchecked unions.
2129          --  Finally, enforce the restriction that access attributes with a
2130          --  current instance prefix can only apply to limited types.
2131
2132          if Ekind (Rec) = E_Record_Type then
2133             if Present (Corresponding_Remote_Type (Rec)) then
2134                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2135             end if;
2136
2137             Comp := First_Component (Rec);
2138             while Present (Comp) loop
2139
2140                --  Do not set Has_Controlled_Component on a class-wide
2141                --  equivalent type. See Make_CW_Equivalent_Type.
2142
2143                if not Is_Class_Wide_Equivalent_Type (Rec)
2144                  and then (Has_Controlled_Component (Etype (Comp))
2145                             or else (Chars (Comp) /= Name_uParent
2146                                       and then Is_Controlled (Etype (Comp)))
2147                             or else (Is_Protected_Type (Etype (Comp))
2148                                       and then Present
2149                                         (Corresponding_Record_Type
2150                                           (Etype (Comp)))
2151                                       and then Has_Controlled_Component
2152                                         (Corresponding_Record_Type
2153                                           (Etype (Comp)))))
2154                then
2155                   Set_Has_Controlled_Component (Rec);
2156                   exit;
2157                end if;
2158
2159                if Has_Unchecked_Union (Etype (Comp)) then
2160                   Set_Has_Unchecked_Union (Rec);
2161                end if;
2162
2163                if Has_Per_Object_Constraint (Comp) then
2164
2165                   --  Scan component declaration for likely misuses of current
2166                   --  instance, either in a constraint or a default expression.
2167
2168                   Check_Current_Instance (Parent (Comp));
2169                end if;
2170
2171                Next_Component (Comp);
2172             end loop;
2173          end if;
2174
2175          Set_Component_Alignment_If_Not_Set (Rec);
2176
2177          --  For first subtypes, check if there are any fixed-point fields with
2178          --  component clauses, where we must check the size. This is not done
2179          --  till the freeze point, since for fixed-point types, we do not know
2180          --  the size until the type is frozen. Similar processing applies to
2181          --  bit packed arrays.
2182
2183          if Is_First_Subtype (Rec) then
2184             Comp := First_Component (Rec);
2185             while Present (Comp) loop
2186                if Present (Component_Clause (Comp))
2187                  and then (Is_Fixed_Point_Type (Etype (Comp))
2188                              or else
2189                            Is_Bit_Packed_Array (Etype (Comp)))
2190                then
2191                   Check_Size
2192                     (Component_Name (Component_Clause (Comp)),
2193                      Etype (Comp),
2194                      Esize (Comp),
2195                      Junk);
2196                end if;
2197
2198                Next_Component (Comp);
2199             end loop;
2200          end if;
2201
2202          --  Generate warning for applying C or C++ convention to a record
2203          --  with discriminants. This is suppressed for the unchecked union
2204          --  case, since the whole point in this case is interface C. We also
2205          --  do not generate this within instantiations, since we will have
2206          --  generated a message on the template.
2207
2208          if Has_Discriminants (E)
2209            and then not Is_Unchecked_Union (E)
2210            and then (Convention (E) = Convention_C
2211                        or else
2212                      Convention (E) = Convention_CPP)
2213            and then Comes_From_Source (E)
2214            and then not In_Instance
2215            and then not Has_Warnings_Off (E)
2216            and then not Has_Warnings_Off (Base_Type (E))
2217          then
2218             declare
2219                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2220                A2    : Node_Id;
2221
2222             begin
2223                if Present (Cprag) then
2224                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2225
2226                   if Convention (E) = Convention_C then
2227                      Error_Msg_N
2228                        ("?variant record has no direct equivalent in C", A2);
2229                   else
2230                      Error_Msg_N
2231                        ("?variant record has no direct equivalent in C++", A2);
2232                   end if;
2233
2234                   Error_Msg_NE
2235                     ("\?use of convention for type& is dubious", A2, E);
2236                end if;
2237             end;
2238          end if;
2239
2240          --  See if Size is too small as is (and implicit packing might help)
2241
2242          if not Is_Packed (Rec)
2243
2244            --  No implicit packing if even one component is explicitly placed
2245
2246            and then not Placed_Component
2247
2248            --  Must have size clause and all scalar components
2249
2250            and then Has_Size_Clause (Rec)
2251            and then All_Scalar_Components
2252
2253            --  Do not try implicit packing on records with discriminants, too
2254            --  complicated, especially in the variant record case.
2255
2256            and then not Has_Discriminants (Rec)
2257
2258            --  We can implicitly pack if the specified size of the record is
2259            --  less than the sum of the object sizes (no point in packing if
2260            --  this is not the case).
2261
2262            and then Esize (Rec) < Scalar_Component_Total_Esize
2263
2264            --  And the total RM size cannot be greater than the specified size
2265            --  since otherwise packing will not get us where we have to be!
2266
2267            and then Esize (Rec) >= Scalar_Component_Total_RM_Size
2268
2269            --  Never do implicit packing in CodePeer mode since we don't do
2270            --  any packing in this mode, since this generates over-complex
2271            --  code that confuses CodePeer, and in general, CodePeer does not
2272            --  care about the internal representation of objects.
2273
2274            and then not CodePeer_Mode
2275          then
2276             --  If implicit packing enabled, do it
2277
2278             if Implicit_Packing then
2279                Set_Is_Packed (Rec);
2280
2281                --  Otherwise flag the size clause
2282
2283             else
2284                declare
2285                   Sz : constant Node_Id := Size_Clause (Rec);
2286                begin
2287                   Error_Msg_NE -- CODEFIX
2288                     ("size given for& too small", Sz, Rec);
2289                   Error_Msg_N -- CODEFIX
2290                     ("\use explicit pragma Pack "
2291                      & "or use pragma Implicit_Packing", Sz);
2292                end;
2293             end if;
2294          end if;
2295       end Freeze_Record_Type;
2296
2297    --  Start of processing for Freeze_Entity
2298
2299    begin
2300       --  We are going to test for various reasons why this entity need not be
2301       --  frozen here, but in the case of an Itype that's defined within a
2302       --  record, that test actually applies to the record.
2303
2304       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2305          Test_E := Scope (E);
2306       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2307         and then Is_Record_Type (Underlying_Type (Scope (E)))
2308       then
2309          Test_E := Underlying_Type (Scope (E));
2310       end if;
2311
2312       --  Do not freeze if already frozen since we only need one freeze node
2313
2314       if Is_Frozen (E) then
2315          return No_List;
2316
2317       --  It is improper to freeze an external entity within a generic because
2318       --  its freeze node will appear in a non-valid context. The entity will
2319       --  be frozen in the proper scope after the current generic is analyzed.
2320
2321       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2322          return No_List;
2323
2324       --  Do not freeze a global entity within an inner scope created during
2325       --  expansion. A call to subprogram E within some internal procedure
2326       --  (a stream attribute for example) might require freezing E, but the
2327       --  freeze node must appear in the same declarative part as E itself.
2328       --  The two-pass elaboration mechanism in gigi guarantees that E will
2329       --  be frozen before the inner call is elaborated. We exclude constants
2330       --  from this test, because deferred constants may be frozen early, and
2331       --  must be diagnosed (e.g. in the case of a deferred constant being used
2332       --  in a default expression). If the enclosing subprogram comes from
2333       --  source, or is a generic instance, then the freeze point is the one
2334       --  mandated by the language, and we freeze the entity. A subprogram that
2335       --  is a child unit body that acts as a spec does not have a spec that
2336       --  comes from source, but can only come from source.
2337
2338       elsif In_Open_Scopes (Scope (Test_E))
2339         and then Scope (Test_E) /= Current_Scope
2340         and then Ekind (Test_E) /= E_Constant
2341       then
2342          declare
2343             S : Entity_Id;
2344
2345          begin
2346             S := Current_Scope;
2347             while Present (S) loop
2348                if Is_Overloadable (S) then
2349                   if Comes_From_Source (S)
2350                     or else Is_Generic_Instance (S)
2351                     or else Is_Child_Unit (S)
2352                   then
2353                      exit;
2354                   else
2355                      return No_List;
2356                   end if;
2357                end if;
2358
2359                S := Scope (S);
2360             end loop;
2361          end;
2362
2363       --  Similarly, an inlined instance body may make reference to global
2364       --  entities, but these references cannot be the proper freezing point
2365       --  for them, and in the absence of inlining freezing will take place in
2366       --  their own scope. Normally instance bodies are analyzed after the
2367       --  enclosing compilation, and everything has been frozen at the proper
2368       --  place, but with front-end inlining an instance body is compiled
2369       --  before the end of the enclosing scope, and as a result out-of-order
2370       --  freezing must be prevented.
2371
2372       elsif Front_End_Inlining
2373         and then In_Instance_Body
2374         and then Present (Scope (Test_E))
2375       then
2376          declare
2377             S : Entity_Id;
2378
2379          begin
2380             S := Scope (Test_E);
2381             while Present (S) loop
2382                if Is_Generic_Instance (S) then
2383                   exit;
2384                else
2385                   S := Scope (S);
2386                end if;
2387             end loop;
2388
2389             if No (S) then
2390                return No_List;
2391             end if;
2392          end;
2393       end if;
2394
2395       --  Deal with delayed aspect specifications. The analysis of the aspect
2396       --  is required to be delayed to the freeze point, so we evaluate the
2397       --  pragma or attribute definition clause in the tree at this point.
2398
2399       --  We also have to deal with the case of Boolean aspects, where the
2400       --  value of the Boolean expression is represented by the setting of
2401       --  the Aspect_Cancel flag on the pragma.
2402
2403       if Has_Delayed_Aspects (E) then
2404          declare
2405             Ritem : Node_Id;
2406             Aitem : Node_Id;
2407
2408          begin
2409             --  Look for aspect specification entries for this entity
2410
2411             Ritem := First_Rep_Item (E);
2412             while Present (Ritem) loop
2413                if Nkind (Ritem) = N_Aspect_Specification
2414                  and then Entity (Ritem) = E
2415                  and then Is_Delayed_Aspect (Ritem)
2416                then
2417                   Aitem := Aspect_Rep_Item (Ritem);
2418                   Set_Parent (Aitem, Ritem);
2419
2420                   --  Deal with Boolean case, if no expression, True, otherwise
2421                   --  analyze the expression, check it is static, and if its
2422                   --  value is False, set Aspect_Cancel for the related pragma.
2423
2424                   if Is_Boolean_Aspect (Ritem) then
2425                      declare
2426                         Expr : constant Node_Id := Expression (Ritem);
2427
2428                      begin
2429                         if Present (Expr) then
2430                            Analyze_And_Resolve (Expr, Standard_Boolean);
2431
2432                            if not Is_OK_Static_Expression (Expr) then
2433                               Error_Msg_Name_1 := Chars (Identifier (Ritem));
2434                               Error_Msg_N
2435                                 ("expression for % aspect must be static",
2436                                  Expr);
2437
2438                            elsif Is_False (Expr_Value (Expr)) then
2439                               Set_Aspect_Cancel (Aitem);
2440                            end if;
2441                         end if;
2442                      end;
2443                   end if;
2444
2445                   --  Analyze the pragma after possibly setting Aspect_Cancel
2446
2447                   Analyze (Aitem);
2448                end if;
2449
2450                Next_Rep_Item (Ritem);
2451             end loop;
2452          end;
2453       end if;
2454
2455       --  Here to freeze the entity
2456
2457       Result := No_List;
2458       Set_Is_Frozen (E);
2459
2460       --  Case of entity being frozen is other than a type
2461
2462       if not Is_Type (E) then
2463
2464          --  If entity is exported or imported and does not have an external
2465          --  name, now is the time to provide the appropriate default name.
2466          --  Skip this if the entity is stubbed, since we don't need a name
2467          --  for any stubbed routine. For the case on intrinsics, if no
2468          --  external name is specified, then calls will be handled in
2469          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2470          --  external name is provided, then Expand_Intrinsic_Call leaves
2471          --  calls in place for expansion by GIGI.
2472
2473          if (Is_Imported (E) or else Is_Exported (E))
2474            and then No (Interface_Name (E))
2475            and then Convention (E) /= Convention_Stubbed
2476            and then Convention (E) /= Convention_Intrinsic
2477          then
2478             Set_Encoded_Interface_Name
2479               (E, Get_Default_External_Name (E));
2480
2481          --  If entity is an atomic object appearing in a declaration and
2482          --  the expression is an aggregate, assign it to a temporary to
2483          --  ensure that the actual assignment is done atomically rather
2484          --  than component-wise (the assignment to the temp may be done
2485          --  component-wise, but that is harmless).
2486
2487          elsif Is_Atomic (E)
2488            and then Nkind (Parent (E)) = N_Object_Declaration
2489            and then Present (Expression (Parent (E)))
2490            and then Nkind (Expression (Parent (E))) = N_Aggregate
2491            and then
2492              Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2493          then
2494             null;
2495          end if;
2496
2497          --  For a subprogram, freeze all parameter types and also the return
2498          --  type (RM 13.14(14)). However skip this for internal subprograms.
2499          --  This is also the point where any extra formal parameters are
2500          --  created since we now know whether the subprogram will use a
2501          --  foreign convention.
2502
2503          if Is_Subprogram (E) then
2504             if not Is_Internal (E) then
2505                declare
2506                   F_Type    : Entity_Id;
2507                   R_Type    : Entity_Id;
2508                   Warn_Node : Node_Id;
2509
2510                begin
2511                   --  Loop through formals
2512
2513                   Formal := First_Formal (E);
2514                   while Present (Formal) loop
2515                      F_Type := Etype (Formal);
2516                      Freeze_And_Append (F_Type, N, Result);
2517
2518                      if Is_Private_Type (F_Type)
2519                        and then Is_Private_Type (Base_Type (F_Type))
2520                        and then No (Full_View (Base_Type (F_Type)))
2521                        and then not Is_Generic_Type (F_Type)
2522                        and then not Is_Derived_Type (F_Type)
2523                      then
2524                         --  If the type of a formal is incomplete, subprogram
2525                         --  is being frozen prematurely. Within an instance
2526                         --  (but not within a wrapper package) this is an
2527                         --  artifact of our need to regard the end of an
2528                         --  instantiation as a freeze point. Otherwise it is
2529                         --  a definite error.
2530
2531                         if In_Instance then
2532                            Set_Is_Frozen (E, False);
2533                            return No_List;
2534
2535                         elsif not After_Last_Declaration
2536                           and then not Freezing_Library_Level_Tagged_Type
2537                         then
2538                            Error_Msg_Node_1 := F_Type;
2539                            Error_Msg
2540                              ("type& must be fully defined before this point",
2541                                Loc);
2542                         end if;
2543                      end if;
2544
2545                      --  Check suspicious parameter for C function. These tests
2546                      --  apply only to exported/imported subprograms.
2547
2548                      if Warn_On_Export_Import
2549                        and then Comes_From_Source (E)
2550                        and then (Convention (E) = Convention_C
2551                                    or else
2552                                  Convention (E) = Convention_CPP)
2553                        and then (Is_Imported (E) or else Is_Exported (E))
2554                        and then Convention (E) /= Convention (Formal)
2555                        and then not Has_Warnings_Off (E)
2556                        and then not Has_Warnings_Off (F_Type)
2557                        and then not Has_Warnings_Off (Formal)
2558                      then
2559                         --  Qualify mention of formals with subprogram name
2560
2561                         Error_Msg_Qual_Level := 1;
2562
2563                         --  Check suspicious use of fat C pointer
2564
2565                         if Is_Access_Type (F_Type)
2566                           and then Esize (F_Type) > Ttypes.System_Address_Size
2567                         then
2568                            Error_Msg_N
2569                              ("?type of & does not correspond to C pointer!",
2570                               Formal);
2571
2572                         --  Check suspicious return of boolean
2573
2574                         elsif Root_Type (F_Type) = Standard_Boolean
2575                           and then Convention (F_Type) = Convention_Ada
2576                           and then not Has_Warnings_Off (F_Type)
2577                           and then not Has_Size_Clause (F_Type)
2578                           and then VM_Target = No_VM
2579                         then
2580                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2581                            Error_Msg_N
2582                              ("\use appropriate corresponding type in C "
2583                               & "(e.g. char)?", Formal);
2584
2585                         --  Check suspicious tagged type
2586
2587                         elsif (Is_Tagged_Type (F_Type)
2588                                 or else (Is_Access_Type (F_Type)
2589                                            and then
2590                                              Is_Tagged_Type
2591                                                (Designated_Type (F_Type))))
2592                           and then Convention (E) = Convention_C
2593                         then
2594                            Error_Msg_N
2595                              ("?& involves a tagged type which does not "
2596                               & "correspond to any C type!", Formal);
2597
2598                         --  Check wrong convention subprogram pointer
2599
2600                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2601                           and then not Has_Foreign_Convention (F_Type)
2602                         then
2603                            Error_Msg_N
2604                              ("?subprogram pointer & should "
2605                               & "have foreign convention!", Formal);
2606                            Error_Msg_Sloc := Sloc (F_Type);
2607                            Error_Msg_NE
2608                              ("\?add Convention pragma to declaration of &#",
2609                               Formal, F_Type);
2610                         end if;
2611
2612                         --  Turn off name qualification after message output
2613
2614                         Error_Msg_Qual_Level := 0;
2615                      end if;
2616
2617                      --  Check for unconstrained array in exported foreign
2618                      --  convention case.
2619
2620                      if Has_Foreign_Convention (E)
2621                        and then not Is_Imported (E)
2622                        and then Is_Array_Type (F_Type)
2623                        and then not Is_Constrained (F_Type)
2624                        and then Warn_On_Export_Import
2625
2626                        --  Exclude VM case, since both .NET and JVM can handle
2627                        --  unconstrained arrays without a problem.
2628
2629                        and then VM_Target = No_VM
2630                      then
2631                         Error_Msg_Qual_Level := 1;
2632
2633                         --  If this is an inherited operation, place the
2634                         --  warning on the derived type declaration, rather
2635                         --  than on the original subprogram.
2636
2637                         if Nkind (Original_Node (Parent (E))) =
2638                           N_Full_Type_Declaration
2639                         then
2640                            Warn_Node := Parent (E);
2641
2642                            if Formal = First_Formal (E) then
2643                               Error_Msg_NE
2644                                 ("?in inherited operation&", Warn_Node, E);
2645                            end if;
2646                         else
2647                            Warn_Node := Formal;
2648                         end if;
2649
2650                         Error_Msg_NE
2651                           ("?type of argument& is unconstrained array",
2652                            Warn_Node, Formal);
2653                         Error_Msg_NE
2654                           ("?foreign caller must pass bounds explicitly",
2655                            Warn_Node, Formal);
2656                         Error_Msg_Qual_Level := 0;
2657                      end if;
2658
2659                      if not From_With_Type (F_Type) then
2660                         if Is_Access_Type (F_Type) then
2661                            F_Type := Designated_Type (F_Type);
2662                         end if;
2663
2664                         --  If the formal is an anonymous_access_to_subprogram
2665                         --  freeze the  subprogram type as well, to prevent
2666                         --  scope anomalies in gigi, because there is no other
2667                         --  clear point at which it could be frozen.
2668
2669                         if Is_Itype (Etype (Formal))
2670                           and then Ekind (F_Type) = E_Subprogram_Type
2671                         then
2672                            Freeze_And_Append (F_Type, N, Result);
2673                         end if;
2674                      end if;
2675
2676                      Next_Formal (Formal);
2677                   end loop;
2678
2679                   --  Case of function: similar checks on return type
2680
2681                   if Ekind (E) = E_Function then
2682
2683                      --  Freeze return type
2684
2685                      R_Type := Etype (E);
2686                      Freeze_And_Append (R_Type, N, Result);
2687
2688                      --  Check suspicious return type for C function
2689
2690                      if Warn_On_Export_Import
2691                        and then (Convention (E) = Convention_C
2692                                    or else
2693                                  Convention (E) = Convention_CPP)
2694                        and then (Is_Imported (E) or else Is_Exported (E))
2695                      then
2696                         --  Check suspicious return of fat C pointer
2697
2698                         if Is_Access_Type (R_Type)
2699                           and then Esize (R_Type) > Ttypes.System_Address_Size
2700                           and then not Has_Warnings_Off (E)
2701                           and then not Has_Warnings_Off (R_Type)
2702                         then
2703                            Error_Msg_N
2704                              ("?return type of& does not "
2705                               & "correspond to C pointer!", E);
2706
2707                         --  Check suspicious return of boolean
2708
2709                         elsif Root_Type (R_Type) = Standard_Boolean
2710                           and then Convention (R_Type) = Convention_Ada
2711                           and then VM_Target = No_VM
2712                           and then not Has_Warnings_Off (E)
2713                           and then not Has_Warnings_Off (R_Type)
2714                           and then not Has_Size_Clause (R_Type)
2715                         then
2716                            declare
2717                               N : constant Node_Id :=
2718                                     Result_Definition (Declaration_Node (E));
2719                            begin
2720                               Error_Msg_NE
2721                                 ("return type of & is an 8-bit Ada Boolean?",
2722                                  N, E);
2723                               Error_Msg_NE
2724                                 ("\use appropriate corresponding type in C "
2725                                  & "(e.g. char)?", N, E);
2726                            end;
2727
2728                         --  Check suspicious return tagged type
2729
2730                         elsif (Is_Tagged_Type (R_Type)
2731                                 or else (Is_Access_Type (R_Type)
2732                                            and then
2733                                              Is_Tagged_Type
2734                                                (Designated_Type (R_Type))))
2735                           and then Convention (E) = Convention_C
2736                           and then not Has_Warnings_Off (E)
2737                           and then not Has_Warnings_Off (R_Type)
2738                         then
2739                            Error_Msg_N
2740                              ("?return type of & does not "
2741                               & "correspond to C type!", E);
2742
2743                         --  Check return of wrong convention subprogram pointer
2744
2745                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2746                           and then not Has_Foreign_Convention (R_Type)
2747                           and then not Has_Warnings_Off (E)
2748                           and then not Has_Warnings_Off (R_Type)
2749                         then
2750                            Error_Msg_N
2751                              ("?& should return a foreign "
2752                               & "convention subprogram pointer", E);
2753                            Error_Msg_Sloc := Sloc (R_Type);
2754                            Error_Msg_NE
2755                              ("\?add Convention pragma to declaration of& #",
2756                               E, R_Type);
2757                         end if;
2758                      end if;
2759
2760                      --  Give warning for suspicious return of a result of an
2761                      --  unconstrained array type in a foreign convention
2762                      --  function.
2763
2764                      if Has_Foreign_Convention (E)
2765
2766                        --  We are looking for a return of unconstrained array
2767
2768                        and then Is_Array_Type (R_Type)
2769                        and then not Is_Constrained (R_Type)
2770
2771                        --  Exclude imported routines, the warning does not
2772                        --  belong on the import, but on the routine definition.
2773
2774                        and then not Is_Imported (E)
2775
2776                        --  Exclude VM case, since both .NET and JVM can handle
2777                        --  return of unconstrained arrays without a problem.
2778
2779                        and then VM_Target = No_VM
2780
2781                        --  Check that general warning is enabled, and that it
2782                        --  is not suppressed for this particular case.
2783
2784                        and then Warn_On_Export_Import
2785                        and then not Has_Warnings_Off (E)
2786                        and then not Has_Warnings_Off (R_Type)
2787                      then
2788                         Error_Msg_N
2789                           ("?foreign convention function& should not " &
2790                            "return unconstrained array!", E);
2791                      end if;
2792                   end if;
2793                end;
2794             end if;
2795
2796             --  Must freeze its parent first if it is a derived subprogram
2797
2798             if Present (Alias (E)) then
2799                Freeze_And_Append (Alias (E), N, Result);
2800             end if;
2801
2802             --  We don't freeze internal subprograms, because we don't normally
2803             --  want addition of extra formals or mechanism setting to happen
2804             --  for those. However we do pass through predefined dispatching
2805             --  cases, since extra formals may be needed in some cases, such as
2806             --  for the stream 'Input function (build-in-place formals).
2807
2808             if not Is_Internal (E)
2809               or else Is_Predefined_Dispatching_Operation (E)
2810             then
2811                Freeze_Subprogram (E);
2812             end if;
2813
2814          --  Here for other than a subprogram or type
2815
2816          else
2817             --  If entity has a type, and it is not a generic unit, then
2818             --  freeze it first (RM 13.14(10)).
2819
2820             if Present (Etype (E))
2821               and then Ekind (E) /= E_Generic_Function
2822             then
2823                Freeze_And_Append (Etype (E), N, Result);
2824             end if;
2825
2826             --  Special processing for objects created by object declaration
2827
2828             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2829
2830                --  Abstract type allowed only for C++ imported variables or
2831                --  constants.
2832
2833                --  Note: we inhibit this check for objects that do not come
2834                --  from source because there is at least one case (the
2835                --  expansion of x'class'input where x is abstract) where we
2836                --  legitimately generate an abstract object.
2837
2838                if Is_Abstract_Type (Etype (E))
2839                  and then Comes_From_Source (Parent (E))
2840                  and then not (Is_Imported (E)
2841                                  and then Is_CPP_Class (Etype (E)))
2842                then
2843                   Error_Msg_N ("type of object cannot be abstract",
2844                                Object_Definition (Parent (E)));
2845
2846                   if Is_CPP_Class (Etype (E)) then
2847                      Error_Msg_NE
2848                        ("\} may need a cpp_constructor",
2849                        Object_Definition (Parent (E)), Etype (E));
2850                   end if;
2851                end if;
2852
2853                --  For object created by object declaration, perform required
2854                --  categorization (preelaborate and pure) checks. Defer these
2855                --  checks to freeze time since pragma Import inhibits default
2856                --  initialization and thus pragma Import affects these checks.
2857
2858                Validate_Object_Declaration (Declaration_Node (E));
2859
2860                --  If there is an address clause, check that it is valid
2861
2862                Check_Address_Clause (E);
2863
2864                --  If the object needs any kind of default initialization, an
2865                --  error must be issued if No_Default_Initialization applies.
2866                --  The check doesn't apply to imported objects, which are not
2867                --  ever default initialized, and is why the check is deferred
2868                --  until freezing, at which point we know if Import applies.
2869                --  Deferred constants are also exempted from this test because
2870                --  their completion is explicit, or through an import pragma.
2871
2872                if Ekind (E) = E_Constant
2873                  and then Present (Full_View (E))
2874                then
2875                   null;
2876
2877                elsif Comes_From_Source (E)
2878                  and then not Is_Imported (E)
2879                  and then not Has_Init_Expression (Declaration_Node (E))
2880                  and then
2881                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2882                       and then not No_Initialization (Declaration_Node (E))
2883                       and then not Is_Value_Type (Etype (E))
2884                       and then not Suppress_Init_Proc (Etype (E)))
2885                     or else
2886                       (Needs_Simple_Initialization (Etype (E))
2887                         and then not Is_Internal (E)))
2888                then
2889                   Has_Default_Initialization := True;
2890                   Check_Restriction
2891                     (No_Default_Initialization, Declaration_Node (E));
2892                end if;
2893
2894                --  Check that a Thread_Local_Storage variable does not have
2895                --  default initialization, and any explicit initialization must
2896                --  either be the null constant or a static constant.
2897
2898                if Has_Pragma_Thread_Local_Storage (E) then
2899                   declare
2900                      Decl : constant Node_Id := Declaration_Node (E);
2901                   begin
2902                      if Has_Default_Initialization
2903                        or else
2904                          (Has_Init_Expression (Decl)
2905                             and then
2906                              (No (Expression (Decl))
2907                                 or else not
2908                                   (Is_Static_Expression (Expression (Decl))
2909                                      or else
2910                                    Nkind (Expression (Decl)) = N_Null)))
2911                      then
2912                         Error_Msg_NE
2913                           ("Thread_Local_Storage variable& is "
2914                            & "improperly initialized", Decl, E);
2915                         Error_Msg_NE
2916                           ("\only allowed initialization is explicit "
2917                            & "NULL or static expression", Decl, E);
2918                      end if;
2919                   end;
2920                end if;
2921
2922                --  For imported objects, set Is_Public unless there is also an
2923                --  address clause, which means that there is no external symbol
2924                --  needed for the Import (Is_Public may still be set for other
2925                --  unrelated reasons). Note that we delayed this processing
2926                --  till freeze time so that we can be sure not to set the flag
2927                --  if there is an address clause. If there is such a clause,
2928                --  then the only purpose of the Import pragma is to suppress
2929                --  implicit initialization.
2930
2931                if Is_Imported (E)
2932                  and then No (Address_Clause (E))
2933                then
2934                   Set_Is_Public (E);
2935                end if;
2936
2937                --  For convention C objects of an enumeration type, warn if
2938                --  the size is not integer size and no explicit size given.
2939                --  Skip warning for Boolean, and Character, assume programmer
2940                --  expects 8-bit sizes for these cases.
2941
2942                if (Convention (E) = Convention_C
2943                     or else
2944                    Convention (E) = Convention_CPP)
2945                  and then Is_Enumeration_Type (Etype (E))
2946                  and then not Is_Character_Type (Etype (E))
2947                  and then not Is_Boolean_Type (Etype (E))
2948                  and then Esize (Etype (E)) < Standard_Integer_Size
2949                  and then not Has_Size_Clause (E)
2950                then
2951                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2952                   Error_Msg_N
2953                     ("?convention C enumeration object has size less than ^",
2954                      E);
2955                   Error_Msg_N ("\?use explicit size clause to set size", E);
2956                end if;
2957             end if;
2958
2959             --  Check that a constant which has a pragma Volatile[_Components]
2960             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2961
2962             --  Note: Atomic[_Components] also sets Volatile[_Components]
2963
2964             if Ekind (E) = E_Constant
2965               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2966               and then not Is_Imported (E)
2967             then
2968                --  Make sure we actually have a pragma, and have not merely
2969                --  inherited the indication from elsewhere (e.g. an address
2970                --  clause, which is not good enough in RM terms!)
2971
2972                if Has_Rep_Pragma (E, Name_Atomic)
2973                     or else
2974                   Has_Rep_Pragma (E, Name_Atomic_Components)
2975                then
2976                   Error_Msg_N
2977                     ("stand alone atomic constant must be " &
2978                      "imported (RM C.6(13))", E);
2979
2980                elsif Has_Rep_Pragma (E, Name_Volatile)
2981                        or else
2982                      Has_Rep_Pragma (E, Name_Volatile_Components)
2983                then
2984                   Error_Msg_N
2985                     ("stand alone volatile constant must be " &
2986                      "imported (RM C.6(13))", E);
2987                end if;
2988             end if;
2989
2990             --  Static objects require special handling
2991
2992             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2993               and then Is_Statically_Allocated (E)
2994             then
2995                Freeze_Static_Object (E);
2996             end if;
2997
2998             --  Remaining step is to layout objects
2999
3000             if Ekind (E) = E_Variable
3001                  or else
3002                Ekind (E) = E_Constant
3003                  or else
3004                Ekind (E) = E_Loop_Parameter
3005                  or else
3006                Is_Formal (E)
3007             then
3008                Layout_Object (E);
3009             end if;
3010          end if;
3011
3012       --  Case of a type or subtype being frozen
3013
3014       else
3015          --  We used to check here that a full type must have preelaborable
3016          --  initialization if it completes a private type specified with
3017          --  pragma Preelaborable_Initialization, but that missed cases where
3018          --  the types occur within a generic package, since the freezing
3019          --  that occurs within a containing scope generally skips traversal
3020          --  of a generic unit's declarations (those will be frozen within
3021          --  instances). This check was moved to Analyze_Package_Specification.
3022
3023          --  The type may be defined in a generic unit. This can occur when
3024          --  freezing a generic function that returns the type (which is
3025          --  defined in a parent unit). It is clearly meaningless to freeze
3026          --  this type. However, if it is a subtype, its size may be determi-
3027          --  nable and used in subsequent checks, so might as well try to
3028          --  compute it.
3029
3030          if Present (Scope (E))
3031            and then Is_Generic_Unit (Scope (E))
3032          then
3033             Check_Compile_Time_Size (E);
3034             return No_List;
3035          end if;
3036
3037          --  Deal with special cases of freezing for subtype
3038
3039          if E /= Base_Type (E) then
3040
3041             --  Before we do anything else, a specialized test for the case of
3042             --  a size given for an array where the array needs to be packed,
3043             --  but was not so the size cannot be honored. This would of course
3044             --  be caught by the backend, and indeed we don't catch all cases.
3045             --  The point is that we can give a better error message in those
3046             --  cases that we do catch with the circuitry here. Also if pragma
3047             --  Implicit_Packing is set, this is where the packing occurs.
3048
3049             --  The reason we do this so early is that the processing in the
3050             --  automatic packing case affects the layout of the base type, so
3051             --  it must be done before we freeze the base type.
3052
3053             if Is_Array_Type (E) then
3054                declare
3055                   Lo, Hi : Node_Id;
3056                   Ctyp   : constant Entity_Id := Component_Type (E);
3057
3058                begin
3059                   --  Check enabling conditions. These are straightforward
3060                   --  except for the test for a limited composite type. This
3061                   --  eliminates the rare case of a array of limited components
3062                   --  where there are issues of whether or not we can go ahead
3063                   --  and pack the array (since we can't freely pack and unpack
3064                   --  arrays if they are limited).
3065
3066                   --  Note that we check the root type explicitly because the
3067                   --  whole point is we are doing this test before we have had
3068                   --  a chance to freeze the base type (and it is that freeze
3069                   --  action that causes stuff to be inherited).
3070
3071                   if Present (Size_Clause (E))
3072                     and then Known_Static_Esize (E)
3073                     and then not Is_Packed (E)
3074                     and then not Has_Pragma_Pack (E)
3075                     and then Number_Dimensions (E) = 1
3076                     and then not Has_Component_Size_Clause (E)
3077                     and then Known_Static_Esize (Ctyp)
3078                     and then not Is_Limited_Composite (E)
3079                     and then not Is_Packed (Root_Type (E))
3080                     and then not Has_Component_Size_Clause (Root_Type (E))
3081                     and then not CodePeer_Mode
3082                   then
3083                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3084
3085                      if Compile_Time_Known_Value (Lo)
3086                        and then Compile_Time_Known_Value (Hi)
3087                        and then Known_Static_RM_Size (Ctyp)
3088                        and then RM_Size (Ctyp) < 64
3089                      then
3090                         declare
3091                            Lov  : constant Uint      := Expr_Value (Lo);
3092                            Hiv  : constant Uint      := Expr_Value (Hi);
3093                            Len  : constant Uint      := UI_Max
3094                                                          (Uint_0,
3095                                                           Hiv - Lov + 1);
3096                            Rsiz : constant Uint      := RM_Size (Ctyp);
3097                            SZ   : constant Node_Id   := Size_Clause (E);
3098                            Btyp : constant Entity_Id := Base_Type (E);
3099
3100                         --  What we are looking for here is the situation where
3101                         --  the RM_Size given would be exactly right if there
3102                         --  was a pragma Pack (resulting in the component size
3103                         --  being the same as the RM_Size). Furthermore, the
3104                         --  component type size must be an odd size (not a
3105                         --  multiple of storage unit). If the component RM size
3106                         --  is an exact number of storage units that is a power
3107                         --  of two, the array is not packed and has a standard
3108                         --  representation.
3109
3110                         begin
3111                            if RM_Size (E) = Len * Rsiz
3112                              and then Rsiz mod System_Storage_Unit /= 0
3113                            then
3114                               --  For implicit packing mode, just set the
3115                               --  component size silently.
3116
3117                               if Implicit_Packing then
3118                                  Set_Component_Size       (Btyp, Rsiz);
3119                                  Set_Is_Bit_Packed_Array  (Btyp);
3120                                  Set_Is_Packed            (Btyp);
3121                                  Set_Has_Non_Standard_Rep (Btyp);
3122
3123                                  --  Otherwise give an error message
3124
3125                               else
3126                                  Error_Msg_NE
3127                                    ("size given for& too small", SZ, E);
3128                                  Error_Msg_N -- CODEFIX
3129                                    ("\use explicit pragma Pack "
3130                                     & "or use pragma Implicit_Packing", SZ);
3131                               end if;
3132
3133                            elsif RM_Size (E) = Len * Rsiz
3134                              and then Implicit_Packing
3135                              and then
3136                                (Rsiz / System_Storage_Unit = 1
3137                                  or else Rsiz / System_Storage_Unit = 2
3138                                  or else Rsiz / System_Storage_Unit = 4)
3139                            then
3140
3141                               --  Not a packed array, but indicate the desired
3142                               --  component size, for the back-end.
3143
3144                               Set_Component_Size (Btyp, Rsiz);
3145                            end if;
3146                         end;
3147                      end if;
3148                   end if;
3149                end;
3150             end if;
3151
3152             --  If ancestor subtype present, freeze that first. Note that this
3153             --  will also get the base type frozen. Need RM reference ???
3154
3155             Atype := Ancestor_Subtype (E);
3156
3157             if Present (Atype) then
3158                Freeze_And_Append (Atype, N, Result);
3159
3160             --  No ancestor subtype present
3161
3162             else
3163                --  See if we have a nearest ancestor that has a predicate.
3164                --  That catches the case of derived type with a predicate.
3165                --  Need RM reference here ???
3166
3167                Atype := Nearest_Ancestor (E);
3168
3169                if Present (Atype) and then Has_Predicates (Atype) then
3170                   Freeze_And_Append (Atype, N, Result);
3171                end if;
3172
3173                --  Freeze base type before freezing the entity (RM 13.14(15))
3174
3175                if E /= Base_Type (E) then
3176                   Freeze_And_Append (Base_Type (E), N, Result);
3177                end if;
3178             end if;
3179
3180          --  For a derived type, freeze its parent type first (RM 13.14(15))
3181
3182          elsif Is_Derived_Type (E) then
3183             Freeze_And_Append (Etype (E), N, Result);
3184             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3185          end if;
3186
3187          --  For array type, freeze index types and component type first
3188          --  before freezing the array (RM 13.14(15)).
3189
3190          if Is_Array_Type (E) then
3191             declare
3192                FS     : constant Entity_Id := First_Subtype (E);
3193                Ctyp   : constant Entity_Id := Component_Type (E);
3194                Clause : Entity_Id;
3195
3196                Non_Standard_Enum : Boolean := False;
3197                --  Set true if any of the index types is an enumeration type
3198                --  with a non-standard representation.
3199
3200             begin
3201                Freeze_And_Append (Ctyp, N, Result);
3202
3203                Indx := First_Index (E);
3204                while Present (Indx) loop
3205                   Freeze_And_Append (Etype (Indx), N, Result);
3206
3207                   if Is_Enumeration_Type (Etype (Indx))
3208                     and then Has_Non_Standard_Rep (Etype (Indx))
3209                   then
3210                      Non_Standard_Enum := True;
3211                   end if;
3212
3213                   Next_Index (Indx);
3214                end loop;
3215
3216                --  Processing that is done only for base types
3217
3218                if Ekind (E) = E_Array_Type then
3219
3220                   --  Propagate flags for component type
3221
3222                   if Is_Controlled (Component_Type (E))
3223                     or else Has_Controlled_Component (Ctyp)
3224                   then
3225                      Set_Has_Controlled_Component (E);
3226                   end if;
3227
3228                   if Has_Unchecked_Union (Component_Type (E)) then
3229                      Set_Has_Unchecked_Union (E);
3230                   end if;
3231
3232                   --  If packing was requested or if the component size was set
3233                   --  explicitly, then see if bit packing is required. This
3234                   --  processing is only done for base types, since all the
3235                   --  representation aspects involved are type-related. This
3236                   --  is not just an optimization, if we start processing the
3237                   --  subtypes, they interfere with the settings on the base
3238                   --  type (this is because Is_Packed has a slightly different
3239                   --  meaning before and after freezing).
3240
3241                   declare
3242                      Csiz : Uint;
3243                      Esiz : Uint;
3244
3245                   begin
3246                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3247                        and then Known_Static_RM_Size (Ctyp)
3248                        and then not Has_Component_Size_Clause (E)
3249                      then
3250                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3251
3252                      elsif Known_Component_Size (E) then
3253                         Csiz := Component_Size (E);
3254
3255                      elsif not Known_Static_Esize (Ctyp) then
3256                         Csiz := Uint_0;
3257
3258                      else
3259                         Esiz := Esize (Ctyp);
3260
3261                         --  We can set the component size if it is less than
3262                         --  16, rounding it up to the next storage unit size.
3263
3264                         if Esiz <= 8 then
3265                            Csiz := Uint_8;
3266                         elsif Esiz <= 16 then
3267                            Csiz := Uint_16;
3268                         else
3269                            Csiz := Uint_0;
3270                         end if;
3271
3272                         --  Set component size up to match alignment if it
3273                         --  would otherwise be less than the alignment. This
3274                         --  deals with cases of types whose alignment exceeds
3275                         --  their size (padded types).
3276
3277                         if Csiz /= 0 then
3278                            declare
3279                               A : constant Uint := Alignment_In_Bits (Ctyp);
3280                            begin
3281                               if Csiz < A then
3282                                  Csiz := A;
3283                               end if;
3284                            end;
3285                         end if;
3286                      end if;
3287
3288                      --  Case of component size that may result in packing
3289
3290                      if 1 <= Csiz and then Csiz <= 64 then
3291                         declare
3292                            Ent         : constant Entity_Id :=
3293                                            First_Subtype (E);
3294                            Pack_Pragma : constant Node_Id :=
3295                                            Get_Rep_Pragma (Ent, Name_Pack);
3296                            Comp_Size_C : constant Node_Id :=
3297                                            Get_Attribute_Definition_Clause
3298                                              (Ent, Attribute_Component_Size);
3299                         begin
3300                            --  Warn if we have pack and component size so that
3301                            --  the pack is ignored.
3302
3303                            --  Note: here we must check for the presence of a
3304                            --  component size before checking for a Pack pragma
3305                            --  to deal with the case where the array type is a
3306                            --  derived type whose parent is currently private.
3307
3308                            if Present (Comp_Size_C)
3309                              and then Has_Pragma_Pack (Ent)
3310                              and then Warn_On_Redundant_Constructs
3311                            then
3312                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3313                               Error_Msg_NE
3314                                 ("?pragma Pack for& ignored!",
3315                                  Pack_Pragma, Ent);
3316                               Error_Msg_N
3317                                 ("\?explicit component size given#!",
3318                                  Pack_Pragma);
3319                               Set_Is_Packed (Base_Type (Ent), False);
3320                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3321                            end if;
3322
3323                            --  Set component size if not already set by a
3324                            --  component size clause.
3325
3326                            if not Present (Comp_Size_C) then
3327                               Set_Component_Size (E, Csiz);
3328                            end if;
3329
3330                            --  Check for base type of 8, 16, 32 bits, where an
3331                            --  unsigned subtype has a length one less than the
3332                            --  base type (e.g. Natural subtype of Integer).
3333
3334                            --  In such cases, if a component size was not set
3335                            --  explicitly, then generate a warning.
3336
3337                            if Has_Pragma_Pack (E)
3338                              and then not Present (Comp_Size_C)
3339                              and then
3340                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3341                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3342                            then
3343                               Error_Msg_Uint_1 := Csiz;
3344
3345                               if Present (Pack_Pragma) then
3346                                  Error_Msg_N
3347                                    ("?pragma Pack causes component size "
3348                                     & "to be ^!", Pack_Pragma);
3349                                  Error_Msg_N
3350                                    ("\?use Component_Size to set "
3351                                     & "desired value!", Pack_Pragma);
3352                               end if;
3353                            end if;
3354
3355                            --  Actual packing is not needed for 8, 16, 32, 64.
3356                            --  Also not needed for 24 if alignment is 1.
3357
3358                            if        Csiz = 8
3359                              or else Csiz = 16
3360                              or else Csiz = 32
3361                              or else Csiz = 64
3362                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3363                            then
3364                               --  Here the array was requested to be packed,
3365                               --  but the packing request had no effect, so
3366                               --  Is_Packed is reset.
3367
3368                               --  Note: semantically this means that we lose
3369                               --  track of the fact that a derived type
3370                               --  inherited a pragma Pack that was non-
3371                               --  effective, but that seems fine.
3372
3373                               --  We regard a Pack pragma as a request to set
3374                               --  a representation characteristic, and this
3375                               --  request may be ignored.
3376
3377                               Set_Is_Packed           (Base_Type (E), False);
3378                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3379
3380                               if Known_Static_Esize (Component_Type (E))
3381                                 and then Esize (Component_Type (E)) = Csiz
3382                               then
3383                                  Set_Has_Non_Standard_Rep
3384                                    (Base_Type (E), False);
3385                               end if;
3386
3387                            --  In all other cases, packing is indeed needed
3388
3389                            else
3390                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3391                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3392                               Set_Is_Packed            (Base_Type (E), True);
3393                            end if;
3394                         end;
3395                      end if;
3396                   end;
3397
3398                   --  Check for Atomic_Components or Aliased with unsuitable
3399                   --  packing or explicit component size clause given.
3400
3401                   if (Has_Atomic_Components (E)
3402                        or else Has_Aliased_Components (E))
3403                     and then (Has_Component_Size_Clause (E)
3404                                or else Is_Packed (E))
3405                   then
3406                      Alias_Atomic_Check : declare
3407
3408                         procedure Complain_CS (T : String);
3409                         --  Outputs error messages for incorrect CS clause or
3410                         --  pragma Pack for aliased or atomic components (T is
3411                         --  "aliased" or "atomic");
3412
3413                         -----------------
3414                         -- Complain_CS --
3415                         -----------------
3416
3417                         procedure Complain_CS (T : String) is
3418                         begin
3419                            if Has_Component_Size_Clause (E) then
3420                               Clause :=
3421                                 Get_Attribute_Definition_Clause
3422                                   (FS, Attribute_Component_Size);
3423
3424                               if Known_Static_Esize (Ctyp) then
3425                                  Error_Msg_N
3426                                    ("incorrect component size for "
3427                                     & T & " components", Clause);
3428                                  Error_Msg_Uint_1 := Esize (Ctyp);
3429                                  Error_Msg_N
3430                                    ("\only allowed value is^", Clause);
3431
3432                               else
3433                                  Error_Msg_N
3434                                    ("component size cannot be given for "
3435                                     & T & " components", Clause);
3436                               end if;
3437
3438                            else
3439                               Error_Msg_N
3440                                 ("cannot pack " & T & " components",
3441                                  Get_Rep_Pragma (FS, Name_Pack));
3442                            end if;
3443
3444                            return;
3445                         end Complain_CS;
3446
3447                      --  Start of processing for Alias_Atomic_Check
3448
3449                      begin
3450                         --  Case where component size has no effect
3451
3452                         if Known_Static_Esize (Ctyp)
3453                           and then Known_Static_RM_Size (Ctyp)
3454                           and then Esize (Ctyp) = RM_Size (Ctyp)
3455                           and then Esize (Ctyp) mod 8 = 0
3456                         then
3457                            null;
3458
3459                         elsif Has_Aliased_Components (E)
3460                           or else Is_Aliased (Ctyp)
3461                         then
3462                            Complain_CS ("aliased");
3463
3464                         elsif Has_Atomic_Components (E)
3465                           or else Is_Atomic (Ctyp)
3466                         then
3467                            Complain_CS ("atomic");
3468                         end if;
3469                      end Alias_Atomic_Check;
3470                   end if;
3471
3472                   --  Warn for case of atomic type
3473
3474                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3475
3476                   if Present (Clause)
3477                     and then not Addressable (Component_Size (FS))
3478                   then
3479                      Error_Msg_NE
3480                        ("non-atomic components of type& may not be "
3481                         & "accessible by separate tasks?", Clause, E);
3482
3483                      if Has_Component_Size_Clause (E) then
3484                         Error_Msg_Sloc :=
3485                           Sloc
3486                             (Get_Attribute_Definition_Clause
3487                                  (FS, Attribute_Component_Size));
3488                         Error_Msg_N
3489                           ("\because of component size clause#?",
3490                            Clause);
3491
3492                      elsif Has_Pragma_Pack (E) then
3493                         Error_Msg_Sloc :=
3494                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3495                         Error_Msg_N
3496                           ("\because of pragma Pack#?", Clause);
3497                      end if;
3498                   end if;
3499
3500                --  Processing that is done only for subtypes
3501
3502                else
3503                   --  Acquire alignment from base type
3504
3505                   if Unknown_Alignment (E) then
3506                      Set_Alignment (E, Alignment (Base_Type (E)));
3507                      Adjust_Esize_Alignment (E);
3508                   end if;
3509                end if;
3510
3511                --  For bit-packed arrays, check the size
3512
3513                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3514                   declare
3515                      SizC : constant Node_Id := Size_Clause (E);
3516
3517                      Discard : Boolean;
3518                      pragma Warnings (Off, Discard);
3519
3520                   begin
3521                      --  It is not clear if it is possible to have no size
3522                      --  clause at this stage, but it is not worth worrying
3523                      --  about. Post error on the entity name in the size
3524                      --  clause if present, else on the type entity itself.
3525
3526                      if Present (SizC) then
3527                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3528                      else
3529                         Check_Size (E, E, RM_Size (E), Discard);
3530                      end if;
3531                   end;
3532                end if;
3533
3534                --  If any of the index types was an enumeration type with a
3535                --  non-standard rep clause, then we indicate that the array
3536                --  type is always packed (even if it is not bit packed).
3537
3538                if Non_Standard_Enum then
3539                   Set_Has_Non_Standard_Rep (Base_Type (E));
3540                   Set_Is_Packed            (Base_Type (E));
3541                end if;
3542
3543                Set_Component_Alignment_If_Not_Set (E);
3544
3545                --  If the array is packed, we must create the packed array
3546                --  type to be used to actually implement the type. This is
3547                --  only needed for real array types (not for string literal
3548                --  types, since they are present only for the front end).
3549
3550                if Is_Packed (E)
3551                  and then Ekind (E) /= E_String_Literal_Subtype
3552                then
3553                   Create_Packed_Array_Type (E);
3554                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3555
3556                   --  Size information of packed array type is copied to the
3557                   --  array type, since this is really the representation. But
3558                   --  do not override explicit existing size values. If the
3559                   --  ancestor subtype is constrained the packed_array_type
3560                   --  will be inherited from it, but the size may have been
3561                   --  provided already, and must not be overridden either.
3562
3563                   if not Has_Size_Clause (E)
3564                     and then
3565                       (No (Ancestor_Subtype (E))
3566                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3567                   then
3568                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3569                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3570                   end if;
3571
3572                   if not Has_Alignment_Clause (E) then
3573                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3574                   end if;
3575                end if;
3576
3577                --  For non-packed arrays set the alignment of the array to the
3578                --  alignment of the component type if it is unknown. Skip this
3579                --  in atomic case (atomic arrays may need larger alignments).
3580
3581                if not Is_Packed (E)
3582                  and then Unknown_Alignment (E)
3583                  and then Known_Alignment (Ctyp)
3584                  and then Known_Static_Component_Size (E)
3585                  and then Known_Static_Esize (Ctyp)
3586                  and then Esize (Ctyp) = Component_Size (E)
3587                  and then not Is_Atomic (E)
3588                then
3589                   Set_Alignment (E, Alignment (Component_Type (E)));
3590                end if;
3591             end;
3592
3593          --  For a class-wide type, the corresponding specific type is
3594          --  frozen as well (RM 13.14(15))
3595
3596          elsif Is_Class_Wide_Type (E) then
3597             Freeze_And_Append (Root_Type (E), N, Result);
3598
3599             --  If the base type of the class-wide type is still incomplete,
3600             --  the class-wide remains unfrozen as well. This is legal when
3601             --  E is the formal of a primitive operation of some other type
3602             --  which is being frozen.
3603
3604             if not Is_Frozen (Root_Type (E)) then
3605                Set_Is_Frozen (E, False);
3606                return Result;
3607             end if;
3608
3609             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3610             --  parent of a derived type) and it is a library-level entity,
3611             --  generate an itype reference for it. Otherwise, its first
3612             --  explicit reference may be in an inner scope, which will be
3613             --  rejected by the back-end.
3614
3615             if Is_Itype (E)
3616               and then Is_Compilation_Unit (Scope (E))
3617             then
3618                declare
3619                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3620
3621                begin
3622                   Set_Itype (Ref, E);
3623                   if No (Result) then
3624                      Result := New_List (Ref);
3625                   else
3626                      Append (Ref, Result);
3627                   end if;
3628                end;
3629             end if;
3630
3631             --  The equivalent type associated with a class-wide subtype needs
3632             --  to be frozen to ensure that its layout is done.
3633
3634             if Ekind (E) = E_Class_Wide_Subtype
3635               and then Present (Equivalent_Type (E))
3636             then
3637                Freeze_And_Append (Equivalent_Type (E), N, Result);
3638             end if;
3639
3640          --  For a record (sub)type, freeze all the component types (RM
3641          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3642          --  Is_Record_Type, because we don't want to attempt the freeze for
3643          --  the case of a private type with record extension (we will do that
3644          --  later when the full type is frozen).
3645
3646          elsif Ekind (E) = E_Record_Type
3647            or else Ekind (E) = E_Record_Subtype
3648          then
3649             Freeze_Record_Type (E);
3650
3651          --  For a concurrent type, freeze corresponding record type. This
3652          --  does not correspond to any specific rule in the RM, but the
3653          --  record type is essentially part of the concurrent type.
3654          --  Freeze as well all local entities. This includes record types
3655          --  created for entry parameter blocks, and whatever local entities
3656          --  may appear in the private part.
3657
3658          elsif Is_Concurrent_Type (E) then
3659             if Present (Corresponding_Record_Type (E)) then
3660                Freeze_And_Append
3661                  (Corresponding_Record_Type (E), N, Result);
3662             end if;
3663
3664             Comp := First_Entity (E);
3665             while Present (Comp) loop
3666                if Is_Type (Comp) then
3667                   Freeze_And_Append (Comp, N, Result);
3668
3669                elsif (Ekind (Comp)) /= E_Function then
3670                   if Is_Itype (Etype (Comp))
3671                     and then Underlying_Type (Scope (Etype (Comp))) = E
3672                   then
3673                      Undelay_Type (Etype (Comp));
3674                   end if;
3675
3676                   Freeze_And_Append (Etype (Comp), N, Result);
3677                end if;
3678
3679                Next_Entity (Comp);
3680             end loop;
3681
3682          --  Private types are required to point to the same freeze node as
3683          --  their corresponding full views. The freeze node itself has to
3684          --  point to the partial view of the entity (because from the partial
3685          --  view, we can retrieve the full view, but not the reverse).
3686          --  However, in order to freeze correctly, we need to freeze the full
3687          --  view. If we are freezing at the end of a scope (or within the
3688          --  scope of the private type), the partial and full views will have
3689          --  been swapped, the full view appears first in the entity chain and
3690          --  the swapping mechanism ensures that the pointers are properly set
3691          --  (on scope exit).
3692
3693          --  If we encounter the partial view before the full view (e.g. when
3694          --  freezing from another scope), we freeze the full view, and then
3695          --  set the pointers appropriately since we cannot rely on swapping to
3696          --  fix things up (subtypes in an outer scope might not get swapped).
3697
3698          elsif Is_Incomplete_Or_Private_Type (E)
3699            and then not Is_Generic_Type (E)
3700          then
3701             --  The construction of the dispatch table associated with library
3702             --  level tagged types forces freezing of all the primitives of the
3703             --  type, which may cause premature freezing of the partial view.
3704             --  For example:
3705
3706             --     package Pkg is
3707             --        type T is tagged private;
3708             --        type DT is new T with private;
3709             --        procedure Prim (X : in out T; Y : in out DT'class);
3710             --     private
3711             --        type T is tagged null record;
3712             --        Obj : T;
3713             --        type DT is new T with null record;
3714             --     end;
3715
3716             --  In this case the type will be frozen later by the usual
3717             --  mechanism: an object declaration, an instantiation, or the
3718             --  end of a declarative part.
3719
3720             if Is_Library_Level_Tagged_Type (E)
3721               and then not Present (Full_View (E))
3722             then
3723                Set_Is_Frozen (E, False);
3724                return Result;
3725
3726             --  Case of full view present
3727
3728             elsif Present (Full_View (E)) then
3729
3730                --  If full view has already been frozen, then no further
3731                --  processing is required
3732
3733                if Is_Frozen (Full_View (E)) then
3734                   Set_Has_Delayed_Freeze (E, False);
3735                   Set_Freeze_Node (E, Empty);
3736                   Check_Debug_Info_Needed (E);
3737
3738                --  Otherwise freeze full view and patch the pointers so that
3739                --  the freeze node will elaborate both views in the back-end.
3740
3741                else
3742                   declare
3743                      Full : constant Entity_Id := Full_View (E);
3744
3745                   begin
3746                      if Is_Private_Type (Full)
3747                        and then Present (Underlying_Full_View (Full))
3748                      then
3749                         Freeze_And_Append
3750                           (Underlying_Full_View (Full), N, Result);
3751                      end if;
3752
3753                      Freeze_And_Append (Full, N, Result);
3754
3755                      if Has_Delayed_Freeze (E) then
3756                         F_Node := Freeze_Node (Full);
3757
3758                         if Present (F_Node) then
3759                            Set_Freeze_Node (E, F_Node);
3760                            Set_Entity (F_Node, E);
3761
3762                         else
3763                            --  {Incomplete,Private}_Subtypes with Full_Views
3764                            --  constrained by discriminants.
3765
3766                            Set_Has_Delayed_Freeze (E, False);
3767                            Set_Freeze_Node (E, Empty);
3768                         end if;
3769                      end if;
3770                   end;
3771
3772                   Check_Debug_Info_Needed (E);
3773                end if;
3774
3775                --  AI-117 requires that the convention of a partial view be the
3776                --  same as the convention of the full view. Note that this is a
3777                --  recognized breach of privacy, but it's essential for logical
3778                --  consistency of representation, and the lack of a rule in
3779                --  RM95 was an oversight.
3780
3781                Set_Convention (E, Convention (Full_View (E)));
3782
3783                Set_Size_Known_At_Compile_Time (E,
3784                  Size_Known_At_Compile_Time (Full_View (E)));
3785
3786                --  Size information is copied from the full view to the
3787                --  incomplete or private view for consistency.
3788
3789                --  We skip this is the full view is not a type. This is very
3790                --  strange of course, and can only happen as a result of
3791                --  certain illegalities, such as a premature attempt to derive
3792                --  from an incomplete type.
3793
3794                if Is_Type (Full_View (E)) then
3795                   Set_Size_Info (E, Full_View (E));
3796                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3797                end if;
3798
3799                return Result;
3800
3801             --  Case of no full view present. If entity is derived or subtype,
3802             --  it is safe to freeze, correctness depends on the frozen status
3803             --  of parent. Otherwise it is either premature usage, or a Taft
3804             --  amendment type, so diagnosis is at the point of use and the
3805             --  type might be frozen later.
3806
3807             elsif E /= Base_Type (E)
3808               or else Is_Derived_Type (E)
3809             then
3810                null;
3811
3812             else
3813                Set_Is_Frozen (E, False);
3814                return No_List;
3815             end if;
3816
3817          --  For access subprogram, freeze types of all formals, the return
3818          --  type was already frozen, since it is the Etype of the function.
3819          --  Formal types can be tagged Taft amendment types, but otherwise
3820          --  they cannot be incomplete.
3821
3822          elsif Ekind (E) = E_Subprogram_Type then
3823             Formal := First_Formal (E);
3824             while Present (Formal) loop
3825                if Ekind (Etype (Formal)) = E_Incomplete_Type
3826                  and then No (Full_View (Etype (Formal)))
3827                  and then not Is_Value_Type (Etype (Formal))
3828                then
3829                   if Is_Tagged_Type (Etype (Formal)) then
3830                      null;
3831
3832                   --  AI05-151: Incomplete types are allowed in access to
3833                   --  subprogram specifications.
3834
3835                   elsif Ada_Version < Ada_2012 then
3836                      Error_Msg_NE
3837                        ("invalid use of incomplete type&", E, Etype (Formal));
3838                   end if;
3839                end if;
3840
3841                Freeze_And_Append (Etype (Formal), N, Result);
3842                Next_Formal (Formal);
3843             end loop;
3844
3845             Freeze_Subprogram (E);
3846
3847          --  For access to a protected subprogram, freeze the equivalent type
3848          --  (however this is not set if we are not generating code or if this
3849          --  is an anonymous type used just for resolution).
3850
3851          elsif Is_Access_Protected_Subprogram_Type (E) then
3852             if Present (Equivalent_Type (E)) then
3853                Freeze_And_Append (Equivalent_Type (E), N, Result);
3854             end if;
3855          end if;
3856
3857          --  Generic types are never seen by the back-end, and are also not
3858          --  processed by the expander (since the expander is turned off for
3859          --  generic processing), so we never need freeze nodes for them.
3860
3861          if Is_Generic_Type (E) then
3862             return Result;
3863          end if;
3864
3865          --  Some special processing for non-generic types to complete
3866          --  representation details not known till the freeze point.
3867
3868          if Is_Fixed_Point_Type (E) then
3869             Freeze_Fixed_Point_Type (E);
3870
3871             --  Some error checks required for ordinary fixed-point type. Defer
3872             --  these till the freeze-point since we need the small and range
3873             --  values. We only do these checks for base types
3874
3875             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3876                if Small_Value (E) < Ureal_2_M_80 then
3877                   Error_Msg_Name_1 := Name_Small;
3878                   Error_Msg_N
3879                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3880
3881                elsif Small_Value (E) > Ureal_2_80 then
3882                   Error_Msg_Name_1 := Name_Small;
3883                   Error_Msg_N
3884                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3885                end if;
3886
3887                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3888                   Error_Msg_Name_1 := Name_First;
3889                   Error_Msg_N
3890                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3891                end if;
3892
3893                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3894                   Error_Msg_Name_1 := Name_Last;
3895                   Error_Msg_N
3896                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3897                end if;
3898             end if;
3899
3900          elsif Is_Enumeration_Type (E) then
3901             Freeze_Enumeration_Type (E);
3902
3903          elsif Is_Integer_Type (E) then
3904             Adjust_Esize_For_Alignment (E);
3905
3906             if Is_Modular_Integer_Type (E)
3907               and then Warn_On_Suspicious_Modulus_Value
3908             then
3909                Check_Suspicious_Modulus (E);
3910             end if;
3911
3912          elsif Is_Access_Type (E) then
3913
3914             --  If a pragma Default_Storage_Pool applies, and this type has no
3915             --  Storage_Pool or Storage_Size clause (which must have occurred
3916             --  before the freezing point), then use the default. This applies
3917             --  only to base types.
3918
3919             if Present (Default_Pool)
3920               and then Is_Base_Type (E)
3921               and then not Has_Storage_Size_Clause (E)
3922               and then No (Associated_Storage_Pool (E))
3923             then
3924                --  Case of pragma Default_Storage_Pool (null)
3925
3926                if Nkind (Default_Pool) = N_Null then
3927                   Set_No_Pool_Assigned (E);
3928
3929                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3930
3931                else
3932                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3933                end if;
3934             end if;
3935
3936             --  Check restriction for standard storage pool
3937
3938             if No (Associated_Storage_Pool (E)) then
3939                Check_Restriction (No_Standard_Storage_Pools, E);
3940             end if;
3941
3942             --  Deal with error message for pure access type. This is not an
3943             --  error in Ada 2005 if there is no pool (see AI-366).
3944
3945             if Is_Pure_Unit_Access_Type (E)
3946               and then (Ada_Version < Ada_2005
3947                          or else not No_Pool_Assigned (E))
3948             then
3949                Error_Msg_N ("named access type not allowed in pure unit", E);
3950
3951                if Ada_Version >= Ada_2005 then
3952                   Error_Msg_N
3953                     ("\would be legal if Storage_Size of 0 given?", E);
3954
3955                elsif No_Pool_Assigned (E) then
3956                   Error_Msg_N
3957                     ("\would be legal in Ada 2005?", E);
3958
3959                else
3960                   Error_Msg_N
3961                     ("\would be legal in Ada 2005 if "
3962                      & "Storage_Size of 0 given?", E);
3963                end if;
3964             end if;
3965          end if;
3966
3967          --  Case of composite types
3968
3969          if Is_Composite_Type (E) then
3970
3971             --  AI-117 requires that all new primitives of a tagged type must
3972             --  inherit the convention of the full view of the type. Inherited
3973             --  and overriding operations are defined to inherit the convention
3974             --  of their parent or overridden subprogram (also specified in
3975             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3976             --  and New_Overloaded_Entity). Here we set the convention of
3977             --  primitives that are still convention Ada, which will ensure
3978             --  that any new primitives inherit the type's convention. Class-
3979             --  wide types can have a foreign convention inherited from their
3980             --  specific type, but are excluded from this since they don't have
3981             --  any associated primitives.
3982
3983             if Is_Tagged_Type (E)
3984               and then not Is_Class_Wide_Type (E)
3985               and then Convention (E) /= Convention_Ada
3986             then
3987                declare
3988                   Prim_List : constant Elist_Id := Primitive_Operations (E);
3989                   Prim      : Elmt_Id;
3990
3991                begin
3992                   Prim := First_Elmt (Prim_List);
3993                   while Present (Prim) loop
3994                      if Convention (Node (Prim)) = Convention_Ada then
3995                         Set_Convention (Node (Prim), Convention (E));
3996                      end if;
3997
3998                      Next_Elmt (Prim);
3999                   end loop;
4000                end;
4001             end if;
4002          end if;
4003
4004          --  Now that all types from which E may depend are frozen, see if the
4005          --  size is known at compile time, if it must be unsigned, or if
4006          --  strict alignment is required
4007
4008          Check_Compile_Time_Size (E);
4009          Check_Unsigned_Type (E);
4010
4011          if Base_Type (E) = E then
4012             Check_Strict_Alignment (E);
4013          end if;
4014
4015          --  Do not allow a size clause for a type which does not have a size
4016          --  that is known at compile time
4017
4018          if Has_Size_Clause (E)
4019            and then not Size_Known_At_Compile_Time (E)
4020          then
4021             --  Suppress this message if errors posted on E, even if we are
4022             --  in all errors mode, since this is often a junk message
4023
4024             if not Error_Posted (E) then
4025                Error_Msg_N
4026                  ("size clause not allowed for variable length type",
4027                   Size_Clause (E));
4028             end if;
4029          end if;
4030
4031          --  Remaining process is to set/verify the representation information,
4032          --  in particular the size and alignment values. This processing is
4033          --  not required for generic types, since generic types do not play
4034          --  any part in code generation, and so the size and alignment values
4035          --  for such types are irrelevant.
4036
4037          if Is_Generic_Type (E) then
4038             return Result;
4039
4040          --  Otherwise we call the layout procedure
4041
4042          else
4043             Layout_Type (E);
4044          end if;
4045
4046          --  End of freeze processing for type entities
4047       end if;
4048
4049       --  Here is where we logically freeze the current entity. If it has a
4050       --  freeze node, then this is the point at which the freeze node is
4051       --  linked into the result list.
4052
4053       if Has_Delayed_Freeze (E) then
4054
4055          --  If a freeze node is already allocated, use it, otherwise allocate
4056          --  a new one. The preallocation happens in the case of anonymous base
4057          --  types, where we preallocate so that we can set First_Subtype_Link.
4058          --  Note that we reset the Sloc to the current freeze location.
4059
4060          if Present (Freeze_Node (E)) then
4061             F_Node := Freeze_Node (E);
4062             Set_Sloc (F_Node, Loc);
4063
4064          else
4065             F_Node := New_Node (N_Freeze_Entity, Loc);
4066             Set_Freeze_Node (E, F_Node);
4067             Set_Access_Types_To_Process (F_Node, No_Elist);
4068             Set_TSS_Elist (F_Node, No_Elist);
4069             Set_Actions (F_Node, No_List);
4070          end if;
4071
4072          Set_Entity (F_Node, E);
4073
4074          if Result = No_List then
4075             Result := New_List (F_Node);
4076          else
4077             Append (F_Node, Result);
4078          end if;
4079
4080          --  A final pass over record types with discriminants. If the type
4081          --  has an incomplete declaration, there may be constrained access
4082          --  subtypes declared elsewhere, which do not depend on the discrimi-
4083          --  nants of the type, and which are used as component types (i.e.
4084          --  the full view is a recursive type). The designated types of these
4085          --  subtypes can only be elaborated after the type itself, and they
4086          --  need an itype reference.
4087
4088          if Ekind (E) = E_Record_Type
4089            and then Has_Discriminants (E)
4090          then
4091             declare
4092                Comp : Entity_Id;
4093                IR   : Node_Id;
4094                Typ  : Entity_Id;
4095
4096             begin
4097                Comp := First_Component (E);
4098                while Present (Comp) loop
4099                   Typ  := Etype (Comp);
4100
4101                   if Ekind (Comp) = E_Component
4102                     and then Is_Access_Type (Typ)
4103                     and then Scope (Typ) /= E
4104                     and then Base_Type (Designated_Type (Typ)) = E
4105                     and then Is_Itype (Designated_Type (Typ))
4106                   then
4107                      IR := Make_Itype_Reference (Sloc (Comp));
4108                      Set_Itype (IR, Designated_Type (Typ));
4109                      Append (IR, Result);
4110                   end if;
4111
4112                   Next_Component (Comp);
4113                end loop;
4114             end;
4115          end if;
4116       end if;
4117
4118       --  When a type is frozen, the first subtype of the type is frozen as
4119       --  well (RM 13.14(15)). This has to be done after freezing the type,
4120       --  since obviously the first subtype depends on its own base type.
4121
4122       if Is_Type (E) then
4123          Freeze_And_Append (First_Subtype (E), N, Result);
4124
4125          --  If we just froze a tagged non-class wide record, then freeze the
4126          --  corresponding class-wide type. This must be done after the tagged
4127          --  type itself is frozen, because the class-wide type refers to the
4128          --  tagged type which generates the class.
4129
4130          if Is_Tagged_Type (E)
4131            and then not Is_Class_Wide_Type (E)
4132            and then Present (Class_Wide_Type (E))
4133          then
4134             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4135          end if;
4136       end if;
4137
4138       Check_Debug_Info_Needed (E);
4139
4140       --  Special handling for subprograms
4141
4142       if Is_Subprogram (E) then
4143
4144          --  If subprogram has address clause then reset Is_Public flag, since
4145          --  we do not want the backend to generate external references.
4146
4147          if Present (Address_Clause (E))
4148            and then not Is_Library_Level_Entity (E)
4149          then
4150             Set_Is_Public (E, False);
4151
4152          --  If no address clause and not intrinsic, then for imported
4153          --  subprogram in main unit, generate descriptor if we are in
4154          --  Propagate_Exceptions mode.
4155
4156          elsif Propagate_Exceptions
4157            and then Is_Imported (E)
4158            and then not Is_Intrinsic_Subprogram (E)
4159            and then Convention (E) /= Convention_Stubbed
4160          then
4161             if Result = No_List then
4162                Result := Empty_List;
4163             end if;
4164          end if;
4165       end if;
4166
4167       return Result;
4168    end Freeze_Entity;
4169
4170    -----------------------------
4171    -- Freeze_Enumeration_Type --
4172    -----------------------------
4173
4174    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4175    begin
4176       --  By default, if no size clause is present, an enumeration type with
4177       --  Convention C is assumed to interface to a C enum, and has integer
4178       --  size. This applies to types. For subtypes, verify that its base
4179       --  type has no size clause either.
4180
4181       if Has_Foreign_Convention (Typ)
4182         and then not Has_Size_Clause (Typ)
4183         and then not Has_Size_Clause (Base_Type (Typ))
4184         and then Esize (Typ) < Standard_Integer_Size
4185       then
4186          Init_Esize (Typ, Standard_Integer_Size);
4187
4188       else
4189          --  If the enumeration type interfaces to C, and it has a size clause
4190          --  that specifies less than int size, it warrants a warning. The
4191          --  user may intend the C type to be an enum or a char, so this is
4192          --  not by itself an error that the Ada compiler can detect, but it
4193          --  it is a worth a heads-up. For Boolean and Character types we
4194          --  assume that the programmer has the proper C type in mind.
4195
4196          if Convention (Typ) = Convention_C
4197            and then Has_Size_Clause (Typ)
4198            and then Esize (Typ) /= Esize (Standard_Integer)
4199            and then not Is_Boolean_Type (Typ)
4200            and then not Is_Character_Type (Typ)
4201          then
4202             Error_Msg_N
4203               ("C enum types have the size of a C int?", Size_Clause (Typ));
4204          end if;
4205
4206          Adjust_Esize_For_Alignment (Typ);
4207       end if;
4208    end Freeze_Enumeration_Type;
4209
4210    -----------------------
4211    -- Freeze_Expression --
4212    -----------------------
4213
4214    procedure Freeze_Expression (N : Node_Id) is
4215       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4216       Typ         : Entity_Id;
4217       Nam         : Entity_Id;
4218       Desig_Typ   : Entity_Id;
4219       P           : Node_Id;
4220       Parent_P    : Node_Id;
4221
4222       Freeze_Outside : Boolean := False;
4223       --  This flag is set true if the entity must be frozen outside the
4224       --  current subprogram. This happens in the case of expander generated
4225       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4226       --  not freeze all entities like other bodies, but which nevertheless
4227       --  may reference entities that have to be frozen before the body and
4228       --  obviously cannot be frozen inside the body.
4229
4230       function In_Exp_Body (N : Node_Id) return Boolean;
4231       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4232       --  it is the handled statement sequence of an expander-generated
4233       --  subprogram (init proc, stream subprogram, or renaming as body).
4234       --  If so, this is not a freezing context.
4235
4236       -----------------
4237       -- In_Exp_Body --
4238       -----------------
4239
4240       function In_Exp_Body (N : Node_Id) return Boolean is
4241          P  : Node_Id;
4242          Id : Entity_Id;
4243
4244       begin
4245          if Nkind (N) = N_Subprogram_Body then
4246             P := N;
4247          else
4248             P := Parent (N);
4249          end if;
4250
4251          if Nkind (P) /= N_Subprogram_Body then
4252             return False;
4253
4254          else
4255             Id := Defining_Unit_Name (Specification (P));
4256
4257             if Nkind (Id) = N_Defining_Identifier
4258               and then (Is_Init_Proc (Id)              or else
4259                         Is_TSS (Id, TSS_Stream_Input)  or else
4260                         Is_TSS (Id, TSS_Stream_Output) or else
4261                         Is_TSS (Id, TSS_Stream_Read)   or else
4262                         Is_TSS (Id, TSS_Stream_Write)  or else
4263                         Nkind (Original_Node (P)) =
4264                           N_Subprogram_Renaming_Declaration)
4265             then
4266                return True;
4267             else
4268                return False;
4269             end if;
4270          end if;
4271       end In_Exp_Body;
4272
4273    --  Start of processing for Freeze_Expression
4274
4275    begin
4276       --  Immediate return if freezing is inhibited. This flag is set by the
4277       --  analyzer to stop freezing on generated expressions that would cause
4278       --  freezing if they were in the source program, but which are not
4279       --  supposed to freeze, since they are created.
4280
4281       if Must_Not_Freeze (N) then
4282          return;
4283       end if;
4284
4285       --  If expression is non-static, then it does not freeze in a default
4286       --  expression, see section "Handling of Default Expressions" in the
4287       --  spec of package Sem for further details. Note that we have to
4288       --  make sure that we actually have a real expression (if we have
4289       --  a subtype indication, we can't test Is_Static_Expression!)
4290
4291       if In_Spec_Exp
4292         and then Nkind (N) in N_Subexpr
4293         and then not Is_Static_Expression (N)
4294       then
4295          return;
4296       end if;
4297
4298       --  Freeze type of expression if not frozen already
4299
4300       Typ := Empty;
4301
4302       if Nkind (N) in N_Has_Etype then
4303          if not Is_Frozen (Etype (N)) then
4304             Typ := Etype (N);
4305
4306          --  Base type may be an derived numeric type that is frozen at
4307          --  the point of declaration, but first_subtype is still unfrozen.
4308
4309          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4310             Typ := First_Subtype (Etype (N));
4311          end if;
4312       end if;
4313
4314       --  For entity name, freeze entity if not frozen already. A special
4315       --  exception occurs for an identifier that did not come from source.
4316       --  We don't let such identifiers freeze a non-internal entity, i.e.
4317       --  an entity that did come from source, since such an identifier was
4318       --  generated by the expander, and cannot have any semantic effect on
4319       --  the freezing semantics. For example, this stops the parameter of
4320       --  an initialization procedure from freezing the variable.
4321
4322       if Is_Entity_Name (N)
4323         and then not Is_Frozen (Entity (N))
4324         and then (Nkind (N) /= N_Identifier
4325                    or else Comes_From_Source (N)
4326                    or else not Comes_From_Source (Entity (N)))
4327       then
4328          Nam := Entity (N);
4329       else
4330          Nam := Empty;
4331       end if;
4332
4333       --  For an allocator freeze designated type if not frozen already
4334
4335       --  For an aggregate whose component type is an access type, freeze the
4336       --  designated type now, so that its freeze does not appear within the
4337       --  loop that might be created in the expansion of the aggregate. If the
4338       --  designated type is a private type without full view, the expression
4339       --  cannot contain an allocator, so the type is not frozen.
4340
4341       --  For a function, we freeze the entity when the subprogram declaration
4342       --  is frozen, but a function call may appear in an initialization proc.
4343       --  before the declaration is frozen. We need to generate the extra
4344       --  formals, if any, to ensure that the expansion of the call includes
4345       --  the proper actuals. This only applies to Ada subprograms, not to
4346       --  imported ones.
4347
4348       Desig_Typ := Empty;
4349
4350       case Nkind (N) is
4351          when N_Allocator =>
4352             Desig_Typ := Designated_Type (Etype (N));
4353
4354          when N_Aggregate =>
4355             if Is_Array_Type (Etype (N))
4356               and then Is_Access_Type (Component_Type (Etype (N)))
4357             then
4358                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4359             end if;
4360
4361          when N_Selected_Component |
4362             N_Indexed_Component    |
4363             N_Slice                =>
4364
4365             if Is_Access_Type (Etype (Prefix (N))) then
4366                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4367             end if;
4368
4369          when N_Identifier =>
4370             if Present (Nam)
4371               and then Ekind (Nam) = E_Function
4372               and then Nkind (Parent (N)) = N_Function_Call
4373               and then Convention (Nam) = Convention_Ada
4374             then
4375                Create_Extra_Formals (Nam);
4376             end if;
4377
4378          when others =>
4379             null;
4380       end case;
4381
4382       if Desig_Typ /= Empty
4383         and then (Is_Frozen (Desig_Typ)
4384                    or else (not Is_Fully_Defined (Desig_Typ)))
4385       then
4386          Desig_Typ := Empty;
4387       end if;
4388
4389       --  All done if nothing needs freezing
4390
4391       if No (Typ)
4392         and then No (Nam)
4393         and then No (Desig_Typ)
4394       then
4395          return;
4396       end if;
4397
4398       --  Loop for looking at the right place to insert the freeze nodes,
4399       --  exiting from the loop when it is appropriate to insert the freeze
4400       --  node before the current node P.
4401
4402       --  Also checks some special exceptions to the freezing rules. These
4403       --  cases result in a direct return, bypassing the freeze action.
4404
4405       P := N;
4406       loop
4407          Parent_P := Parent (P);
4408
4409          --  If we don't have a parent, then we are not in a well-formed tree.
4410          --  This is an unusual case, but there are some legitimate situations
4411          --  in which this occurs, notably when the expressions in the range of
4412          --  a type declaration are resolved. We simply ignore the freeze
4413          --  request in this case. Is this right ???
4414
4415          if No (Parent_P) then
4416             return;
4417          end if;
4418
4419          --  See if we have got to an appropriate point in the tree
4420
4421          case Nkind (Parent_P) is
4422
4423             --  A special test for the exception of (RM 13.14(8)) for the case
4424             --  of per-object expressions (RM 3.8(18)) occurring in component
4425             --  definition or a discrete subtype definition. Note that we test
4426             --  for a component declaration which includes both cases we are
4427             --  interested in, and furthermore the tree does not have explicit
4428             --  nodes for either of these two constructs.
4429
4430             when N_Component_Declaration =>
4431
4432                --  The case we want to test for here is an identifier that is
4433                --  a per-object expression, this is either a discriminant that
4434                --  appears in a context other than the component declaration
4435                --  or it is a reference to the type of the enclosing construct.
4436
4437                --  For either of these cases, we skip the freezing
4438
4439                if not In_Spec_Expression
4440                  and then Nkind (N) = N_Identifier
4441                  and then (Present (Entity (N)))
4442                then
4443                   --  We recognize the discriminant case by just looking for
4444                   --  a reference to a discriminant. It can only be one for
4445                   --  the enclosing construct. Skip freezing in this case.
4446
4447                   if Ekind (Entity (N)) = E_Discriminant then
4448                      return;
4449
4450                   --  For the case of a reference to the enclosing record,
4451                   --  (or task or protected type), we look for a type that
4452                   --  matches the current scope.
4453
4454                   elsif Entity (N) = Current_Scope then
4455                      return;
4456                   end if;
4457                end if;
4458
4459             --  If we have an enumeration literal that appears as the choice in
4460             --  the aggregate of an enumeration representation clause, then
4461             --  freezing does not occur (RM 13.14(10)).
4462
4463             when N_Enumeration_Representation_Clause =>
4464
4465                --  The case we are looking for is an enumeration literal
4466
4467                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4468                  and then Is_Enumeration_Type (Etype (N))
4469                then
4470                   --  If enumeration literal appears directly as the choice,
4471                   --  do not freeze (this is the normal non-overloaded case)
4472
4473                   if Nkind (Parent (N)) = N_Component_Association
4474                     and then First (Choices (Parent (N))) = N
4475                   then
4476                      return;
4477
4478                   --  If enumeration literal appears as the name of function
4479                   --  which is the choice, then also do not freeze. This
4480                   --  happens in the overloaded literal case, where the
4481                   --  enumeration literal is temporarily changed to a function
4482                   --  call for overloading analysis purposes.
4483
4484                   elsif Nkind (Parent (N)) = N_Function_Call
4485                      and then
4486                        Nkind (Parent (Parent (N))) = N_Component_Association
4487                      and then
4488                        First (Choices (Parent (Parent (N)))) = Parent (N)
4489                   then
4490                      return;
4491                   end if;
4492                end if;
4493
4494             --  Normally if the parent is a handled sequence of statements,
4495             --  then the current node must be a statement, and that is an
4496             --  appropriate place to insert a freeze node.
4497
4498             when N_Handled_Sequence_Of_Statements =>
4499
4500                --  An exception occurs when the sequence of statements is for
4501                --  an expander generated body that did not do the usual freeze
4502                --  all operation. In this case we usually want to freeze
4503                --  outside this body, not inside it, and we skip past the
4504                --  subprogram body that we are inside.
4505
4506                if In_Exp_Body (Parent_P) then
4507
4508                   --  However, we *do* want to freeze at this point if we have
4509                   --  an entity to freeze, and that entity is declared *inside*
4510                   --  the body of the expander generated procedure. This case
4511                   --  is recognized by the scope of the type, which is either
4512                   --  the spec for some enclosing body, or (in the case of
4513                   --  init_procs, for which there are no separate specs) the
4514                   --  current scope.
4515
4516                   declare
4517                      Subp : constant Node_Id := Parent (Parent_P);
4518                      Cspc : Entity_Id;
4519
4520                   begin
4521                      if Nkind (Subp) = N_Subprogram_Body then
4522                         Cspc := Corresponding_Spec (Subp);
4523
4524                         if (Present (Typ) and then Scope (Typ) = Cspc)
4525                              or else
4526                            (Present (Nam) and then Scope (Nam) = Cspc)
4527                         then
4528                            exit;
4529
4530                         elsif Present (Typ)
4531                           and then Scope (Typ) = Current_Scope
4532                           and then Current_Scope = Defining_Entity (Subp)
4533                         then
4534                            exit;
4535                         end if;
4536                      end if;
4537                   end;
4538
4539                   --  If not that exception to the exception, then this is
4540                   --  where we delay the freeze till outside the body.
4541
4542                   Parent_P := Parent (Parent_P);
4543                   Freeze_Outside := True;
4544
4545                --  Here if normal case where we are in handled statement
4546                --  sequence and want to do the insertion right there.
4547
4548                else
4549                   exit;
4550                end if;
4551
4552             --  If parent is a body or a spec or a block, then the current node
4553             --  is a statement or declaration and we can insert the freeze node
4554             --  before it.
4555
4556             when N_Package_Specification |
4557                  N_Package_Body          |
4558                  N_Subprogram_Body       |
4559                  N_Task_Body             |
4560                  N_Protected_Body        |
4561                  N_Entry_Body            |
4562                  N_Block_Statement       => exit;
4563
4564             --  The expander is allowed to define types in any statements list,
4565             --  so any of the following parent nodes also mark a freezing point
4566             --  if the actual node is in a list of statements or declarations.
4567
4568             when N_Exception_Handler          |
4569                  N_If_Statement               |
4570                  N_Elsif_Part                 |
4571                  N_Case_Statement_Alternative |
4572                  N_Compilation_Unit_Aux       |
4573                  N_Selective_Accept           |
4574                  N_Accept_Alternative         |
4575                  N_Delay_Alternative          |
4576                  N_Conditional_Entry_Call     |
4577                  N_Entry_Call_Alternative     |
4578                  N_Triggering_Alternative     |
4579                  N_Abortable_Part             |
4580                  N_And_Then                   |
4581                  N_Or_Else                    |
4582                  N_Freeze_Entity              =>
4583
4584                exit when Is_List_Member (P);
4585
4586             --  Note: The N_Loop_Statement is a special case. A type that
4587             --  appears in the source can never be frozen in a loop (this
4588             --  occurs only because of a loop expanded by the expander), so we
4589             --  keep on going. Otherwise we terminate the search. Same is true
4590             --  of any entity which comes from source. (if they have predefined
4591             --  type, that type does not appear to come from source, but the
4592             --  entity should not be frozen here).
4593
4594             when N_Loop_Statement =>
4595                exit when not Comes_From_Source (Etype (N))
4596                  and then (No (Nam) or else not Comes_From_Source (Nam));
4597
4598             --  For all other cases, keep looking at parents
4599
4600             when others =>
4601                null;
4602          end case;
4603
4604          --  We fall through the case if we did not yet find the proper
4605          --  place in the free for inserting the freeze node, so climb!
4606
4607          P := Parent_P;
4608       end loop;
4609
4610       --  If the expression appears in a record or an initialization procedure,
4611       --  the freeze nodes are collected and attached to the current scope, to
4612       --  be inserted and analyzed on exit from the scope, to insure that
4613       --  generated entities appear in the correct scope. If the expression is
4614       --  a default for a discriminant specification, the scope is still void.
4615       --  The expression can also appear in the discriminant part of a private
4616       --  or concurrent type.
4617
4618       --  If the expression appears in a constrained subcomponent of an
4619       --  enclosing record declaration, the freeze nodes must be attached to
4620       --  the outer record type so they can eventually be placed in the
4621       --  enclosing declaration list.
4622
4623       --  The other case requiring this special handling is if we are in a
4624       --  default expression, since in that case we are about to freeze a
4625       --  static type, and the freeze scope needs to be the outer scope, not
4626       --  the scope of the subprogram with the default parameter.
4627
4628       --  For default expressions and other spec expressions in generic units,
4629       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4630       --  placing them at the proper place, after the generic unit.
4631
4632       if (In_Spec_Exp and not Inside_A_Generic)
4633         or else Freeze_Outside
4634         or else (Is_Type (Current_Scope)
4635                   and then (not Is_Concurrent_Type (Current_Scope)
4636                              or else not Has_Completion (Current_Scope)))
4637         or else Ekind (Current_Scope) = E_Void
4638       then
4639          declare
4640             N            : constant Node_Id    := Current_Scope;
4641             Freeze_Nodes : List_Id             := No_List;
4642             Pos          : Int                 := Scope_Stack.Last;
4643
4644          begin
4645             if Present (Desig_Typ) then
4646                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4647             end if;
4648
4649             if Present (Typ) then
4650                Freeze_And_Append (Typ, N, Freeze_Nodes);
4651             end if;
4652
4653             if Present (Nam) then
4654                Freeze_And_Append (Nam, N, Freeze_Nodes);
4655             end if;
4656
4657             --  The current scope may be that of a constrained component of
4658             --  an enclosing record declaration, which is above the current
4659             --  scope in the scope stack.
4660             --  If the expression is within a top-level pragma, as for a pre-
4661             --  condition on a library-level subprogram, nothing to do.
4662
4663             if not Is_Compilation_Unit (Current_Scope)
4664               and then Is_Record_Type (Scope (Current_Scope))
4665             then
4666                Pos := Pos - 1;
4667             end if;
4668
4669             if Is_Non_Empty_List (Freeze_Nodes) then
4670                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4671                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4672                     Freeze_Nodes;
4673                else
4674                   Append_List (Freeze_Nodes,
4675                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4676                end if;
4677             end if;
4678          end;
4679
4680          return;
4681       end if;
4682
4683       --  Now we have the right place to do the freezing. First, a special
4684       --  adjustment, if we are in spec-expression analysis mode, these freeze
4685       --  actions must not be thrown away (normally all inserted actions are
4686       --  thrown away in this mode. However, the freeze actions are from static
4687       --  expressions and one of the important reasons we are doing this
4688       --  special analysis is to get these freeze actions. Therefore we turn
4689       --  off the In_Spec_Expression mode to propagate these freeze actions.
4690       --  This also means they get properly analyzed and expanded.
4691
4692       In_Spec_Expression := False;
4693
4694       --  Freeze the designated type of an allocator (RM 13.14(13))
4695
4696       if Present (Desig_Typ) then
4697          Freeze_Before (P, Desig_Typ);
4698       end if;
4699
4700       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4701       --  the enumeration representation clause exception in the loop above.
4702
4703       if Present (Typ) then
4704          Freeze_Before (P, Typ);
4705       end if;
4706
4707       --  Freeze name if one is present (RM 13.14(11))
4708
4709       if Present (Nam) then
4710          Freeze_Before (P, Nam);
4711       end if;
4712
4713       --  Restore In_Spec_Expression flag
4714
4715       In_Spec_Expression := In_Spec_Exp;
4716    end Freeze_Expression;
4717
4718    -----------------------------
4719    -- Freeze_Fixed_Point_Type --
4720    -----------------------------
4721
4722    --  Certain fixed-point types and subtypes, including implicit base types
4723    --  and declared first subtypes, have not yet set up a range. This is
4724    --  because the range cannot be set until the Small and Size values are
4725    --  known, and these are not known till the type is frozen.
4726
4727    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4728    --  whose bounds are unanalyzed real literals. This routine will recognize
4729    --  this case, and transform this range node into a properly typed range
4730    --  with properly analyzed and resolved values.
4731
4732    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4733       Rng   : constant Node_Id    := Scalar_Range (Typ);
4734       Lo    : constant Node_Id    := Low_Bound (Rng);
4735       Hi    : constant Node_Id    := High_Bound (Rng);
4736       Btyp  : constant Entity_Id  := Base_Type (Typ);
4737       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4738       BLo   : constant Node_Id    := Low_Bound (Brng);
4739       BHi   : constant Node_Id    := High_Bound (Brng);
4740       Small : constant Ureal      := Small_Value (Typ);
4741       Loval : Ureal;
4742       Hival : Ureal;
4743       Atype : Entity_Id;
4744
4745       Actual_Size : Nat;
4746
4747       function Fsize (Lov, Hiv : Ureal) return Nat;
4748       --  Returns size of type with given bounds. Also leaves these
4749       --  bounds set as the current bounds of the Typ.
4750
4751       -----------
4752       -- Fsize --
4753       -----------
4754
4755       function Fsize (Lov, Hiv : Ureal) return Nat is
4756       begin
4757          Set_Realval (Lo, Lov);
4758          Set_Realval (Hi, Hiv);
4759          return Minimum_Size (Typ);
4760       end Fsize;
4761
4762    --  Start of processing for Freeze_Fixed_Point_Type
4763
4764    begin
4765       --  If Esize of a subtype has not previously been set, set it now
4766
4767       if Unknown_Esize (Typ) then
4768          Atype := Ancestor_Subtype (Typ);
4769
4770          if Present (Atype) then
4771             Set_Esize (Typ, Esize (Atype));
4772          else
4773             Set_Esize (Typ, Esize (Base_Type (Typ)));
4774          end if;
4775       end if;
4776
4777       --  Immediate return if the range is already analyzed. This means that
4778       --  the range is already set, and does not need to be computed by this
4779       --  routine.
4780
4781       if Analyzed (Rng) then
4782          return;
4783       end if;
4784
4785       --  Immediate return if either of the bounds raises Constraint_Error
4786
4787       if Raises_Constraint_Error (Lo)
4788         or else Raises_Constraint_Error (Hi)
4789       then
4790          return;
4791       end if;
4792
4793       Loval := Realval (Lo);
4794       Hival := Realval (Hi);
4795
4796       --  Ordinary fixed-point case
4797
4798       if Is_Ordinary_Fixed_Point_Type (Typ) then
4799
4800          --  For the ordinary fixed-point case, we are allowed to fudge the
4801          --  end-points up or down by small. Generally we prefer to fudge up,
4802          --  i.e. widen the bounds for non-model numbers so that the end points
4803          --  are included. However there are cases in which this cannot be
4804          --  done, and indeed cases in which we may need to narrow the bounds.
4805          --  The following circuit makes the decision.
4806
4807          --  Note: our terminology here is that Incl_EP means that the bounds
4808          --  are widened by Small if necessary to include the end points, and
4809          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4810          --  end-points if this reduces the size.
4811
4812          --  Note that in the Incl case, all we care about is including the
4813          --  end-points. In the Excl case, we want to narrow the bounds as
4814          --  much as permitted by the RM, to give the smallest possible size.
4815
4816          Fudge : declare
4817             Loval_Incl_EP : Ureal;
4818             Hival_Incl_EP : Ureal;
4819
4820             Loval_Excl_EP : Ureal;
4821             Hival_Excl_EP : Ureal;
4822
4823             Size_Incl_EP  : Nat;
4824             Size_Excl_EP  : Nat;
4825
4826             Model_Num     : Ureal;
4827             First_Subt    : Entity_Id;
4828             Actual_Lo     : Ureal;
4829             Actual_Hi     : Ureal;
4830
4831          begin
4832             --  First step. Base types are required to be symmetrical. Right
4833             --  now, the base type range is a copy of the first subtype range.
4834             --  This will be corrected before we are done, but right away we
4835             --  need to deal with the case where both bounds are non-negative.
4836             --  In this case, we set the low bound to the negative of the high
4837             --  bound, to make sure that the size is computed to include the
4838             --  required sign. Note that we do not need to worry about the
4839             --  case of both bounds negative, because the sign will be dealt
4840             --  with anyway. Furthermore we can't just go making such a bound
4841             --  symmetrical, since in a twos-complement system, there is an
4842             --  extra negative value which could not be accommodated on the
4843             --  positive side.
4844
4845             if Typ = Btyp
4846               and then not UR_Is_Negative (Loval)
4847               and then Hival > Loval
4848             then
4849                Loval := -Hival;
4850                Set_Realval (Lo, Loval);
4851             end if;
4852
4853             --  Compute the fudged bounds. If the number is a model number,
4854             --  then we do nothing to include it, but we are allowed to backoff
4855             --  to the next adjacent model number when we exclude it. If it is
4856             --  not a model number then we straddle the two values with the
4857             --  model numbers on either side.
4858
4859             Model_Num := UR_Trunc (Loval / Small) * Small;
4860
4861             if Loval = Model_Num then
4862                Loval_Incl_EP := Model_Num;
4863             else
4864                Loval_Incl_EP := Model_Num - Small;
4865             end if;
4866
4867             --  The low value excluding the end point is Small greater, but
4868             --  we do not do this exclusion if the low value is positive,
4869             --  since it can't help the size and could actually hurt by
4870             --  crossing the high bound.
4871
4872             if UR_Is_Negative (Loval_Incl_EP) then
4873                Loval_Excl_EP := Loval_Incl_EP + Small;
4874
4875                --  If the value went from negative to zero, then we have the
4876                --  case where Loval_Incl_EP is the model number just below
4877                --  zero, so we want to stick to the negative value for the
4878                --  base type to maintain the condition that the size will
4879                --  include signed values.
4880
4881                if Typ = Btyp
4882                  and then UR_Is_Zero (Loval_Excl_EP)
4883                then
4884                   Loval_Excl_EP := Loval_Incl_EP;
4885                end if;
4886
4887             else
4888                Loval_Excl_EP := Loval_Incl_EP;
4889             end if;
4890
4891             --  Similar processing for upper bound and high value
4892
4893             Model_Num := UR_Trunc (Hival / Small) * Small;
4894
4895             if Hival = Model_Num then
4896                Hival_Incl_EP := Model_Num;
4897             else
4898                Hival_Incl_EP := Model_Num + Small;
4899             end if;
4900
4901             if UR_Is_Positive (Hival_Incl_EP) then
4902                Hival_Excl_EP := Hival_Incl_EP - Small;
4903             else
4904                Hival_Excl_EP := Hival_Incl_EP;
4905             end if;
4906
4907             --  One further adjustment is needed. In the case of subtypes, we
4908             --  cannot go outside the range of the base type, or we get
4909             --  peculiarities, and the base type range is already set. This
4910             --  only applies to the Incl values, since clearly the Excl values
4911             --  are already as restricted as they are allowed to be.
4912
4913             if Typ /= Btyp then
4914                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4915                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4916             end if;
4917
4918             --  Get size including and excluding end points
4919
4920             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4921             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4922
4923             --  No need to exclude end-points if it does not reduce size
4924
4925             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4926                Loval_Excl_EP := Loval_Incl_EP;
4927             end if;
4928
4929             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4930                Hival_Excl_EP := Hival_Incl_EP;
4931             end if;
4932
4933             --  Now we set the actual size to be used. We want to use the
4934             --  bounds fudged up to include the end-points but only if this
4935             --  can be done without violating a specifically given size
4936             --  size clause or causing an unacceptable increase in size.
4937
4938             --  Case of size clause given
4939
4940             if Has_Size_Clause (Typ) then
4941
4942                --  Use the inclusive size only if it is consistent with
4943                --  the explicitly specified size.
4944
4945                if Size_Incl_EP <= RM_Size (Typ) then
4946                   Actual_Lo   := Loval_Incl_EP;
4947                   Actual_Hi   := Hival_Incl_EP;
4948                   Actual_Size := Size_Incl_EP;
4949
4950                --  If the inclusive size is too large, we try excluding
4951                --  the end-points (will be caught later if does not work).
4952
4953                else
4954                   Actual_Lo   := Loval_Excl_EP;
4955                   Actual_Hi   := Hival_Excl_EP;
4956                   Actual_Size := Size_Excl_EP;
4957                end if;
4958
4959             --  Case of size clause not given
4960
4961             else
4962                --  If we have a base type whose corresponding first subtype
4963                --  has an explicit size that is large enough to include our
4964                --  end-points, then do so. There is no point in working hard
4965                --  to get a base type whose size is smaller than the specified
4966                --  size of the first subtype.
4967
4968                First_Subt := First_Subtype (Typ);
4969
4970                if Has_Size_Clause (First_Subt)
4971                  and then Size_Incl_EP <= Esize (First_Subt)
4972                then
4973                   Actual_Size := Size_Incl_EP;
4974                   Actual_Lo   := Loval_Incl_EP;
4975                   Actual_Hi   := Hival_Incl_EP;
4976
4977                --  If excluding the end-points makes the size smaller and
4978                --  results in a size of 8,16,32,64, then we take the smaller
4979                --  size. For the 64 case, this is compulsory. For the other
4980                --  cases, it seems reasonable. We like to include end points
4981                --  if we can, but not at the expense of moving to the next
4982                --  natural boundary of size.
4983
4984                elsif Size_Incl_EP /= Size_Excl_EP
4985                  and then Addressable (Size_Excl_EP)
4986                then
4987                   Actual_Size := Size_Excl_EP;
4988                   Actual_Lo   := Loval_Excl_EP;
4989                   Actual_Hi   := Hival_Excl_EP;
4990
4991                --  Otherwise we can definitely include the end points
4992
4993                else
4994                   Actual_Size := Size_Incl_EP;
4995                   Actual_Lo   := Loval_Incl_EP;
4996                   Actual_Hi   := Hival_Incl_EP;
4997                end if;
4998
4999                --  One pathological case: normally we never fudge a low bound
5000                --  down, since it would seem to increase the size (if it has
5001                --  any effect), but for ranges containing single value, or no
5002                --  values, the high bound can be small too large. Consider:
5003
5004                --    type t is delta 2.0**(-14)
5005                --      range 131072.0 .. 0;
5006
5007                --  That lower bound is *just* outside the range of 32 bits, and
5008                --  does need fudging down in this case. Note that the bounds
5009                --  will always have crossed here, since the high bound will be
5010                --  fudged down if necessary, as in the case of:
5011
5012                --    type t is delta 2.0**(-14)
5013                --      range 131072.0 .. 131072.0;
5014
5015                --  So we detect the situation by looking for crossed bounds,
5016                --  and if the bounds are crossed, and the low bound is greater
5017                --  than zero, we will always back it off by small, since this
5018                --  is completely harmless.
5019
5020                if Actual_Lo > Actual_Hi then
5021                   if UR_Is_Positive (Actual_Lo) then
5022                      Actual_Lo   := Loval_Incl_EP - Small;
5023                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5024
5025                   --  And of course, we need to do exactly the same parallel
5026                   --  fudge for flat ranges in the negative region.
5027
5028                   elsif UR_Is_Negative (Actual_Hi) then
5029                      Actual_Hi := Hival_Incl_EP + Small;
5030                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5031                   end if;
5032                end if;
5033             end if;
5034
5035             Set_Realval (Lo, Actual_Lo);
5036             Set_Realval (Hi, Actual_Hi);
5037          end Fudge;
5038
5039       --  For the decimal case, none of this fudging is required, since there
5040       --  are no end-point problems in the decimal case (the end-points are
5041       --  always included).
5042
5043       else
5044          Actual_Size := Fsize (Loval, Hival);
5045       end if;
5046
5047       --  At this stage, the actual size has been calculated and the proper
5048       --  required bounds are stored in the low and high bounds.
5049
5050       if Actual_Size > 64 then
5051          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5052          Error_Msg_N
5053            ("size required (^) for type& too large, maximum allowed is 64",
5054             Typ);
5055          Actual_Size := 64;
5056       end if;
5057
5058       --  Check size against explicit given size
5059
5060       if Has_Size_Clause (Typ) then
5061          if Actual_Size > RM_Size (Typ) then
5062             Error_Msg_Uint_1 := RM_Size (Typ);
5063             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5064             Error_Msg_NE
5065               ("size given (^) for type& too small, minimum allowed is ^",
5066                Size_Clause (Typ), Typ);
5067
5068          else
5069             Actual_Size := UI_To_Int (Esize (Typ));
5070          end if;
5071
5072       --  Increase size to next natural boundary if no size clause given
5073
5074       else
5075          if Actual_Size <= 8 then
5076             Actual_Size := 8;
5077          elsif Actual_Size <= 16 then
5078             Actual_Size := 16;
5079          elsif Actual_Size <= 32 then
5080             Actual_Size := 32;
5081          else
5082             Actual_Size := 64;
5083          end if;
5084
5085          Init_Esize (Typ, Actual_Size);
5086          Adjust_Esize_For_Alignment (Typ);
5087       end if;
5088
5089       --  If we have a base type, then expand the bounds so that they extend to
5090       --  the full width of the allocated size in bits, to avoid junk range
5091       --  checks on intermediate computations.
5092
5093       if Base_Type (Typ) = Typ then
5094          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5095          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5096       end if;
5097
5098       --  Final step is to reanalyze the bounds using the proper type
5099       --  and set the Corresponding_Integer_Value fields of the literals.
5100
5101       Set_Etype (Lo, Empty);
5102       Set_Analyzed (Lo, False);
5103       Analyze (Lo);
5104
5105       --  Resolve with universal fixed if the base type, and the base type if
5106       --  it is a subtype. Note we can't resolve the base type with itself,
5107       --  that would be a reference before definition.
5108
5109       if Typ = Btyp then
5110          Resolve (Lo, Universal_Fixed);
5111       else
5112          Resolve (Lo, Btyp);
5113       end if;
5114
5115       --  Set corresponding integer value for bound
5116
5117       Set_Corresponding_Integer_Value
5118         (Lo, UR_To_Uint (Realval (Lo) / Small));
5119
5120       --  Similar processing for high bound
5121
5122       Set_Etype (Hi, Empty);
5123       Set_Analyzed (Hi, False);
5124       Analyze (Hi);
5125
5126       if Typ = Btyp then
5127          Resolve (Hi, Universal_Fixed);
5128       else
5129          Resolve (Hi, Btyp);
5130       end if;
5131
5132       Set_Corresponding_Integer_Value
5133         (Hi, UR_To_Uint (Realval (Hi) / Small));
5134
5135       --  Set type of range to correspond to bounds
5136
5137       Set_Etype (Rng, Etype (Lo));
5138
5139       --  Set Esize to calculated size if not set already
5140
5141       if Unknown_Esize (Typ) then
5142          Init_Esize (Typ, Actual_Size);
5143       end if;
5144
5145       --  Set RM_Size if not already set. If already set, check value
5146
5147       declare
5148          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5149
5150       begin
5151          if RM_Size (Typ) /= Uint_0 then
5152             if RM_Size (Typ) < Minsiz then
5153                Error_Msg_Uint_1 := RM_Size (Typ);
5154                Error_Msg_Uint_2 := Minsiz;
5155                Error_Msg_NE
5156                  ("size given (^) for type& too small, minimum allowed is ^",
5157                   Size_Clause (Typ), Typ);
5158             end if;
5159
5160          else
5161             Set_RM_Size (Typ, Minsiz);
5162          end if;
5163       end;
5164    end Freeze_Fixed_Point_Type;
5165
5166    ------------------
5167    -- Freeze_Itype --
5168    ------------------
5169
5170    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5171       L : List_Id;
5172
5173    begin
5174       Set_Has_Delayed_Freeze (T);
5175       L := Freeze_Entity (T, N);
5176
5177       if Is_Non_Empty_List (L) then
5178          Insert_Actions (N, L);
5179       end if;
5180    end Freeze_Itype;
5181
5182    --------------------------
5183    -- Freeze_Static_Object --
5184    --------------------------
5185
5186    procedure Freeze_Static_Object (E : Entity_Id) is
5187
5188       Cannot_Be_Static : exception;
5189       --  Exception raised if the type of a static object cannot be made
5190       --  static. This happens if the type depends on non-global objects.
5191
5192       procedure Ensure_Expression_Is_SA (N : Node_Id);
5193       --  Called to ensure that an expression used as part of a type definition
5194       --  is statically allocatable, which means that the expression type is
5195       --  statically allocatable, and the expression is either static, or a
5196       --  reference to a library level constant.
5197
5198       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5199       --  Called to mark a type as static, checking that it is possible
5200       --  to set the type as static. If it is not possible, then the
5201       --  exception Cannot_Be_Static is raised.
5202
5203       -----------------------------
5204       -- Ensure_Expression_Is_SA --
5205       -----------------------------
5206
5207       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5208          Ent : Entity_Id;
5209
5210       begin
5211          Ensure_Type_Is_SA (Etype (N));
5212
5213          if Is_Static_Expression (N) then
5214             return;
5215
5216          elsif Nkind (N) = N_Identifier then
5217             Ent := Entity (N);
5218
5219             if Present (Ent)
5220               and then Ekind (Ent) = E_Constant
5221               and then Is_Library_Level_Entity (Ent)
5222             then
5223                return;
5224             end if;
5225          end if;
5226
5227          raise Cannot_Be_Static;
5228       end Ensure_Expression_Is_SA;
5229
5230       -----------------------
5231       -- Ensure_Type_Is_SA --
5232       -----------------------
5233
5234       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5235          N : Node_Id;
5236          C : Entity_Id;
5237
5238       begin
5239          --  If type is library level, we are all set
5240
5241          if Is_Library_Level_Entity (Typ) then
5242             return;
5243          end if;
5244
5245          --  We are also OK if the type already marked as statically allocated,
5246          --  which means we processed it before.
5247
5248          if Is_Statically_Allocated (Typ) then
5249             return;
5250          end if;
5251
5252          --  Mark type as statically allocated
5253
5254          Set_Is_Statically_Allocated (Typ);
5255
5256          --  Check that it is safe to statically allocate this type
5257
5258          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5259             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5260             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5261
5262          elsif Is_Array_Type (Typ) then
5263             N := First_Index (Typ);
5264             while Present (N) loop
5265                Ensure_Type_Is_SA (Etype (N));
5266                Next_Index (N);
5267             end loop;
5268
5269             Ensure_Type_Is_SA (Component_Type (Typ));
5270
5271          elsif Is_Access_Type (Typ) then
5272             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5273
5274                declare
5275                   F : Entity_Id;
5276                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5277
5278                begin
5279                   if T /= Standard_Void_Type then
5280                      Ensure_Type_Is_SA (T);
5281                   end if;
5282
5283                   F := First_Formal (Designated_Type (Typ));
5284                   while Present (F) loop
5285                      Ensure_Type_Is_SA (Etype (F));
5286                      Next_Formal (F);
5287                   end loop;
5288                end;
5289
5290             else
5291                Ensure_Type_Is_SA (Designated_Type (Typ));
5292             end if;
5293
5294          elsif Is_Record_Type (Typ) then
5295             C := First_Entity (Typ);
5296             while Present (C) loop
5297                if Ekind (C) = E_Discriminant
5298                  or else Ekind (C) = E_Component
5299                then
5300                   Ensure_Type_Is_SA (Etype (C));
5301
5302                elsif Is_Type (C) then
5303                   Ensure_Type_Is_SA (C);
5304                end if;
5305
5306                Next_Entity (C);
5307             end loop;
5308
5309          elsif Ekind (Typ) = E_Subprogram_Type then
5310             Ensure_Type_Is_SA (Etype (Typ));
5311
5312             C := First_Formal (Typ);
5313             while Present (C) loop
5314                Ensure_Type_Is_SA (Etype (C));
5315                Next_Formal (C);
5316             end loop;
5317
5318          else
5319             raise Cannot_Be_Static;
5320          end if;
5321       end Ensure_Type_Is_SA;
5322
5323    --  Start of processing for Freeze_Static_Object
5324
5325    begin
5326       Ensure_Type_Is_SA (Etype (E));
5327
5328    exception
5329       when Cannot_Be_Static =>
5330
5331          --  If the object that cannot be static is imported or exported, then
5332          --  issue an error message saying that this object cannot be imported
5333          --  or exported. If it has an address clause it is an overlay in the
5334          --  current partition and the static requirement is not relevant.
5335          --  Do not issue any error message when ignoring rep clauses.
5336
5337          if Ignore_Rep_Clauses then
5338             null;
5339
5340          elsif Is_Imported (E) then
5341             if No (Address_Clause (E)) then
5342                Error_Msg_N
5343                  ("& cannot be imported (local type is not constant)", E);
5344             end if;
5345
5346          --  Otherwise must be exported, something is wrong if compiler
5347          --  is marking something as statically allocated which cannot be).
5348
5349          else pragma Assert (Is_Exported (E));
5350             Error_Msg_N
5351               ("& cannot be exported (local type is not constant)", E);
5352          end if;
5353    end Freeze_Static_Object;
5354
5355    -----------------------
5356    -- Freeze_Subprogram --
5357    -----------------------
5358
5359    procedure Freeze_Subprogram (E : Entity_Id) is
5360       Retype : Entity_Id;
5361       F      : Entity_Id;
5362
5363    begin
5364       --  Subprogram may not have an address clause unless it is imported
5365
5366       if Present (Address_Clause (E)) then
5367          if not Is_Imported (E) then
5368             Error_Msg_N
5369               ("address clause can only be given " &
5370                "for imported subprogram",
5371                Name (Address_Clause (E)));
5372          end if;
5373       end if;
5374
5375       --  Reset the Pure indication on an imported subprogram unless an
5376       --  explicit Pure_Function pragma was present. We do this because
5377       --  otherwise it is an insidious error to call a non-pure function from
5378       --  pure unit and have calls mysteriously optimized away. What happens
5379       --  here is that the Import can bypass the normal check to ensure that
5380       --  pure units call only pure subprograms.
5381
5382       if Is_Imported (E)
5383         and then Is_Pure (E)
5384         and then not Has_Pragma_Pure_Function (E)
5385       then
5386          Set_Is_Pure (E, False);
5387       end if;
5388
5389       --  For non-foreign convention subprograms, this is where we create
5390       --  the extra formals (for accessibility level and constrained bit
5391       --  information). We delay this till the freeze point precisely so
5392       --  that we know the convention!
5393
5394       if not Has_Foreign_Convention (E) then
5395          Create_Extra_Formals (E);
5396          Set_Mechanisms (E);
5397
5398          --  If this is convention Ada and a Valued_Procedure, that's odd
5399
5400          if Ekind (E) = E_Procedure
5401            and then Is_Valued_Procedure (E)
5402            and then Convention (E) = Convention_Ada
5403            and then Warn_On_Export_Import
5404          then
5405             Error_Msg_N
5406               ("?Valued_Procedure has no effect for convention Ada", E);
5407             Set_Is_Valued_Procedure (E, False);
5408          end if;
5409
5410       --  Case of foreign convention
5411
5412       else
5413          Set_Mechanisms (E);
5414
5415          --  For foreign conventions, warn about return of an
5416          --  unconstrained array.
5417
5418          --  Note: we *do* allow a return by descriptor for the VMS case,
5419          --  though here there is probably more to be done ???
5420
5421          if Ekind (E) = E_Function then
5422             Retype := Underlying_Type (Etype (E));
5423
5424             --  If no return type, probably some other error, e.g. a
5425             --  missing full declaration, so ignore.
5426
5427             if No (Retype) then
5428                null;
5429
5430             --  If the return type is generic, we have emitted a warning
5431             --  earlier on, and there is nothing else to check here. Specific
5432             --  instantiations may lead to erroneous behavior.
5433
5434             elsif Is_Generic_Type (Etype (E)) then
5435                null;
5436
5437             --  Display warning if returning unconstrained array
5438
5439             elsif Is_Array_Type (Retype)
5440               and then not Is_Constrained (Retype)
5441
5442               --  Exclude cases where descriptor mechanism is set, since the
5443               --  VMS descriptor mechanisms allow such unconstrained returns.
5444
5445               and then Mechanism (E) not in Descriptor_Codes
5446
5447               --  Check appropriate warning is enabled (should we check for
5448               --  Warnings (Off) on specific entities here, probably so???)
5449
5450               and then Warn_On_Export_Import
5451
5452                --  Exclude the VM case, since return of unconstrained arrays
5453                --  is properly handled in both the JVM and .NET cases.
5454
5455               and then VM_Target = No_VM
5456             then
5457                Error_Msg_N
5458                 ("?foreign convention function& should not return " &
5459                   "unconstrained array", E);
5460                return;
5461             end if;
5462          end if;
5463
5464          --  If any of the formals for an exported foreign convention
5465          --  subprogram have defaults, then emit an appropriate warning since
5466          --  this is odd (default cannot be used from non-Ada code)
5467
5468          if Is_Exported (E) then
5469             F := First_Formal (E);
5470             while Present (F) loop
5471                if Warn_On_Export_Import
5472                  and then Present (Default_Value (F))
5473                then
5474                   Error_Msg_N
5475                     ("?parameter cannot be defaulted in non-Ada call",
5476                      Default_Value (F));
5477                end if;
5478
5479                Next_Formal (F);
5480             end loop;
5481          end if;
5482       end if;
5483
5484       --  For VMS, descriptor mechanisms for parameters are allowed only for
5485       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5486       --  allowed for parameters of exported subprograms.
5487
5488       if OpenVMS_On_Target then
5489          if Is_Exported (E) then
5490             F := First_Formal (E);
5491             while Present (F) loop
5492                if Mechanism (F) = By_Descriptor_NCA then
5493                   Error_Msg_N
5494                     ("'N'C'A' descriptor for parameter not permitted", F);
5495                   Error_Msg_N
5496                     ("\can only be used for imported subprogram", F);
5497                end if;
5498
5499                Next_Formal (F);
5500             end loop;
5501
5502          elsif not Is_Imported (E) then
5503             F := First_Formal (E);
5504             while Present (F) loop
5505                if Mechanism (F) in Descriptor_Codes then
5506                   Error_Msg_N
5507                     ("descriptor mechanism for parameter not permitted", F);
5508                   Error_Msg_N
5509                     ("\can only be used for imported/exported subprogram", F);
5510                end if;
5511
5512                Next_Formal (F);
5513             end loop;
5514          end if;
5515       end if;
5516
5517       --  Pragma Inline_Always is disallowed for dispatching subprograms
5518       --  because the address of such subprograms is saved in the dispatch
5519       --  table to support dispatching calls, and dispatching calls cannot
5520       --  be inlined. This is consistent with the restriction against using
5521       --  'Access or 'Address on an Inline_Always subprogram.
5522
5523       if Is_Dispatching_Operation (E)
5524         and then Has_Pragma_Inline_Always (E)
5525       then
5526          Error_Msg_N
5527            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5528       end if;
5529
5530       --  Because of the implicit representation of inherited predefined
5531       --  operators in the front-end, the overriding status of the operation
5532       --  may be affected when a full view of a type is analyzed, and this is
5533       --  not captured by the analysis of the corresponding type declaration.
5534       --  Therefore the correctness of a not-overriding indicator must be
5535       --  rechecked when the subprogram is frozen.
5536
5537       if Nkind (E) = N_Defining_Operator_Symbol
5538         and then not Error_Posted (Parent (E))
5539       then
5540          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5541       end if;
5542    end Freeze_Subprogram;
5543
5544    ----------------------
5545    -- Is_Fully_Defined --
5546    ----------------------
5547
5548    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5549    begin
5550       if Ekind (T) = E_Class_Wide_Type then
5551          return Is_Fully_Defined (Etype (T));
5552
5553       elsif Is_Array_Type (T) then
5554          return Is_Fully_Defined (Component_Type (T));
5555
5556       elsif Is_Record_Type (T)
5557         and not Is_Private_Type (T)
5558       then
5559          --  Verify that the record type has no components with private types
5560          --  without completion.
5561
5562          declare
5563             Comp : Entity_Id;
5564
5565          begin
5566             Comp := First_Component (T);
5567             while Present (Comp) loop
5568                if not Is_Fully_Defined (Etype (Comp)) then
5569                   return False;
5570                end if;
5571
5572                Next_Component (Comp);
5573             end loop;
5574             return True;
5575          end;
5576
5577       --  For the designated type of an access to subprogram, all types in
5578       --  the profile must be fully defined.
5579
5580       elsif Ekind (T) = E_Subprogram_Type then
5581          declare
5582             F : Entity_Id;
5583
5584          begin
5585             F := First_Formal (T);
5586             while Present (F) loop
5587                if not Is_Fully_Defined (Etype (F)) then
5588                   return False;
5589                end if;
5590
5591                Next_Formal (F);
5592             end loop;
5593
5594             return Is_Fully_Defined (Etype (T));
5595          end;
5596
5597       else
5598          return not Is_Private_Type (T)
5599            or else Present (Full_View (Base_Type (T)));
5600       end if;
5601    end Is_Fully_Defined;
5602
5603    ---------------------------------
5604    -- Process_Default_Expressions --
5605    ---------------------------------
5606
5607    procedure Process_Default_Expressions
5608      (E     : Entity_Id;
5609       After : in out Node_Id)
5610    is
5611       Loc    : constant Source_Ptr := Sloc (E);
5612       Dbody  : Node_Id;
5613       Formal : Node_Id;
5614       Dcopy  : Node_Id;
5615       Dnam   : Entity_Id;
5616
5617    begin
5618       Set_Default_Expressions_Processed (E);
5619
5620       --  A subprogram instance and its associated anonymous subprogram share
5621       --  their signature. The default expression functions are defined in the
5622       --  wrapper packages for the anonymous subprogram, and should not be
5623       --  generated again for the instance.
5624
5625       if Is_Generic_Instance (E)
5626         and then Present (Alias (E))
5627         and then Default_Expressions_Processed (Alias (E))
5628       then
5629          return;
5630       end if;
5631
5632       Formal := First_Formal (E);
5633       while Present (Formal) loop
5634          if Present (Default_Value (Formal)) then
5635
5636             --  We work with a copy of the default expression because we
5637             --  do not want to disturb the original, since this would mess
5638             --  up the conformance checking.
5639
5640             Dcopy := New_Copy_Tree (Default_Value (Formal));
5641
5642             --  The analysis of the expression may generate insert actions,
5643             --  which of course must not be executed. We wrap those actions
5644             --  in a procedure that is not called, and later on eliminated.
5645             --  The following cases have no side-effects, and are analyzed
5646             --  directly.
5647
5648             if Nkind (Dcopy) = N_Identifier
5649               or else Nkind (Dcopy) = N_Expanded_Name
5650               or else Nkind (Dcopy) = N_Integer_Literal
5651               or else (Nkind (Dcopy) = N_Real_Literal
5652                         and then not Vax_Float (Etype (Dcopy)))
5653               or else Nkind (Dcopy) = N_Character_Literal
5654               or else Nkind (Dcopy) = N_String_Literal
5655               or else Known_Null (Dcopy)
5656               or else (Nkind (Dcopy) = N_Attribute_Reference
5657                         and then
5658                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5659             then
5660
5661                --  If there is no default function, we must still do a full
5662                --  analyze call on the default value, to ensure that all error
5663                --  checks are performed, e.g. those associated with static
5664                --  evaluation. Note: this branch will always be taken if the
5665                --  analyzer is turned off (but we still need the error checks).
5666
5667                --  Note: the setting of parent here is to meet the requirement
5668                --  that we can only analyze the expression while attached to
5669                --  the tree. Really the requirement is that the parent chain
5670                --  be set, we don't actually need to be in the tree.
5671
5672                Set_Parent (Dcopy, Declaration_Node (Formal));
5673                Analyze (Dcopy);
5674
5675                --  Default expressions are resolved with their own type if the
5676                --  context is generic, to avoid anomalies with private types.
5677
5678                if Ekind (Scope (E)) = E_Generic_Package then
5679                   Resolve (Dcopy);
5680                else
5681                   Resolve (Dcopy, Etype (Formal));
5682                end if;
5683
5684                --  If that resolved expression will raise constraint error,
5685                --  then flag the default value as raising constraint error.
5686                --  This allows a proper error message on the calls.
5687
5688                if Raises_Constraint_Error (Dcopy) then
5689                   Set_Raises_Constraint_Error (Default_Value (Formal));
5690                end if;
5691
5692             --  If the default is a parameterless call, we use the name of
5693             --  the called function directly, and there is no body to build.
5694
5695             elsif Nkind (Dcopy) = N_Function_Call
5696               and then No (Parameter_Associations (Dcopy))
5697             then
5698                null;
5699
5700             --  Else construct and analyze the body of a wrapper procedure
5701             --  that contains an object declaration to hold the expression.
5702             --  Given that this is done only to complete the analysis, it
5703             --  simpler to build a procedure than a function which might
5704             --  involve secondary stack expansion.
5705
5706             else
5707                Dnam := Make_Temporary (Loc, 'D');
5708
5709                Dbody :=
5710                  Make_Subprogram_Body (Loc,
5711                    Specification =>
5712                      Make_Procedure_Specification (Loc,
5713                        Defining_Unit_Name => Dnam),
5714
5715                    Declarations => New_List (
5716                      Make_Object_Declaration (Loc,
5717                        Defining_Identifier =>
5718                          Make_Defining_Identifier (Loc,
5719                            New_Internal_Name ('T')),
5720                          Object_Definition =>
5721                            New_Occurrence_Of (Etype (Formal), Loc),
5722                          Expression => New_Copy_Tree (Dcopy))),
5723
5724                    Handled_Statement_Sequence =>
5725                      Make_Handled_Sequence_Of_Statements (Loc,
5726                        Statements => New_List));
5727
5728                Set_Scope (Dnam, Scope (E));
5729                Set_Assignment_OK (First (Declarations (Dbody)));
5730                Set_Is_Eliminated (Dnam);
5731                Insert_After (After, Dbody);
5732                Analyze (Dbody);
5733                After := Dbody;
5734             end if;
5735          end if;
5736
5737          Next_Formal (Formal);
5738       end loop;
5739    end Process_Default_Expressions;
5740
5741    ----------------------------------------
5742    -- Set_Component_Alignment_If_Not_Set --
5743    ----------------------------------------
5744
5745    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5746    begin
5747       --  Ignore if not base type, subtypes don't need anything
5748
5749       if Typ /= Base_Type (Typ) then
5750          return;
5751       end if;
5752
5753       --  Do not override existing representation
5754
5755       if Is_Packed (Typ) then
5756          return;
5757
5758       elsif Has_Specified_Layout (Typ) then
5759          return;
5760
5761       elsif Component_Alignment (Typ) /= Calign_Default then
5762          return;
5763
5764       else
5765          Set_Component_Alignment
5766            (Typ, Scope_Stack.Table
5767                   (Scope_Stack.Last).Component_Alignment_Default);
5768       end if;
5769    end Set_Component_Alignment_If_Not_Set;
5770
5771    ------------------
5772    -- Undelay_Type --
5773    ------------------
5774
5775    procedure Undelay_Type (T : Entity_Id) is
5776    begin
5777       Set_Has_Delayed_Freeze (T, False);
5778       Set_Freeze_Node (T, Empty);
5779
5780       --  Since we don't want T to have a Freeze_Node, we don't want its
5781       --  Full_View or Corresponding_Record_Type to have one either.
5782
5783       --  ??? Fundamentally, this whole handling is a kludge. What we really
5784       --  want is to be sure that for an Itype that's part of record R and is a
5785       --  subtype of type T, that it's frozen after the later of the freeze
5786       --  points of R and T. We have no way of doing that directly, so what we
5787       --  do is force most such Itypes to be frozen as part of freezing R via
5788       --  this procedure and only delay the ones that need to be delayed
5789       --  (mostly the designated types of access types that are defined as part
5790       --  of the record).
5791
5792       if Is_Private_Type (T)
5793         and then Present (Full_View (T))
5794         and then Is_Itype (Full_View (T))
5795         and then Is_Record_Type (Scope (Full_View (T)))
5796       then
5797          Undelay_Type (Full_View (T));
5798       end if;
5799
5800       if Is_Concurrent_Type (T)
5801         and then Present (Corresponding_Record_Type (T))
5802         and then Is_Itype (Corresponding_Record_Type (T))
5803         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5804       then
5805          Undelay_Type (Corresponding_Record_Type (T));
5806       end if;
5807    end Undelay_Type;
5808
5809    ------------------
5810    -- Warn_Overlay --
5811    ------------------
5812
5813    procedure Warn_Overlay
5814      (Expr : Node_Id;
5815       Typ  : Entity_Id;
5816       Nam  : Entity_Id)
5817    is
5818       Ent : constant Entity_Id := Entity (Nam);
5819       --  The object to which the address clause applies
5820
5821       Init : Node_Id;
5822       Old  : Entity_Id := Empty;
5823       Decl : Node_Id;
5824
5825    begin
5826       --  No warning if address clause overlay warnings are off
5827
5828       if not Address_Clause_Overlay_Warnings then
5829          return;
5830       end if;
5831
5832       --  No warning if there is an explicit initialization
5833
5834       Init := Original_Node (Expression (Declaration_Node (Ent)));
5835
5836       if Present (Init) and then Comes_From_Source (Init) then
5837          return;
5838       end if;
5839
5840       --  We only give the warning for non-imported entities of a type for
5841       --  which a non-null base init proc is defined, or for objects of access
5842       --  types with implicit null initialization, or when Normalize_Scalars
5843       --  applies and the type is scalar or a string type (the latter being
5844       --  tested for because predefined String types are initialized by inline
5845       --  code rather than by an init_proc). Note that we do not give the
5846       --  warning for Initialize_Scalars, since we suppressed initialization
5847       --  in this case.
5848
5849       if Present (Expr)
5850         and then not Is_Imported (Ent)
5851         and then (Has_Non_Null_Base_Init_Proc (Typ)
5852                     or else Is_Access_Type (Typ)
5853                     or else (Normalize_Scalars
5854                               and then (Is_Scalar_Type (Typ)
5855                                          or else Is_String_Type (Typ))))
5856       then
5857          if Nkind (Expr) = N_Attribute_Reference
5858            and then Is_Entity_Name (Prefix (Expr))
5859          then
5860             Old := Entity (Prefix (Expr));
5861
5862          elsif Is_Entity_Name (Expr)
5863            and then Ekind (Entity (Expr)) = E_Constant
5864          then
5865             Decl := Declaration_Node (Entity (Expr));
5866
5867             if Nkind (Decl) = N_Object_Declaration
5868               and then Present (Expression (Decl))
5869               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5870               and then Is_Entity_Name (Prefix (Expression (Decl)))
5871             then
5872                Old := Entity (Prefix (Expression (Decl)));
5873
5874             elsif Nkind (Expr) = N_Function_Call then
5875                return;
5876             end if;
5877
5878          --  A function call (most likely to To_Address) is probably not an
5879          --  overlay, so skip warning. Ditto if the function call was inlined
5880          --  and transformed into an entity.
5881
5882          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5883             return;
5884          end if;
5885
5886          Decl := Next (Parent (Expr));
5887
5888          --  If a pragma Import follows, we assume that it is for the current
5889          --  target of the address clause, and skip the warning.
5890
5891          if Present (Decl)
5892            and then Nkind (Decl) = N_Pragma
5893            and then Pragma_Name (Decl) = Name_Import
5894          then
5895             return;
5896          end if;
5897
5898          if Present (Old) then
5899             Error_Msg_Node_2 := Old;
5900             Error_Msg_N
5901               ("default initialization of & may modify &?",
5902                Nam);
5903          else
5904             Error_Msg_N
5905               ("default initialization of & may modify overlaid storage?",
5906                Nam);
5907          end if;
5908
5909          --  Add friendly warning if initialization comes from a packed array
5910          --  component.
5911
5912          if Is_Record_Type (Typ)  then
5913             declare
5914                Comp : Entity_Id;
5915
5916             begin
5917                Comp := First_Component (Typ);
5918                while Present (Comp) loop
5919                   if Nkind (Parent (Comp)) = N_Component_Declaration
5920                     and then Present (Expression (Parent (Comp)))
5921                   then
5922                      exit;
5923                   elsif Is_Array_Type (Etype (Comp))
5924                      and then Present (Packed_Array_Type (Etype (Comp)))
5925                   then
5926                      Error_Msg_NE
5927                        ("\packed array component& " &
5928                         "will be initialized to zero?",
5929                         Nam, Comp);
5930                      exit;
5931                   else
5932                      Next_Component (Comp);
5933                   end if;
5934                end loop;
5935             end;
5936          end if;
5937
5938          Error_Msg_N
5939            ("\use pragma Import for & to " &
5940             "suppress initialization (RM B.1(24))?",
5941             Nam);
5942       end if;
5943    end Warn_Overlay;
5944
5945 end Freeze;