gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere.
 365
 366       if Ekind_In (Old_S, E_Function, E_Procedure)
 367         and then Nkind (Decl) = N_Subprogram_Declaration
 368       then
 369          Set_Body_To_Inline (Decl, Old_S);
 370       end if;
 371
 372       --  The body generated for this renaming is an internal artifact, and
 373       --  does not  constitute a freeze point for the called entity.
 374
 375       Set_Must_Not_Freeze (Call_Name);
 376
 377       Formal := First_Formal (Defining_Entity (Decl));
 378
 379       if Present (Pref) then
 380          declare
 381             Pref_Type : constant Entity_Id := Etype (Pref);
 382             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 383
 384          begin
 385             --  The controlling formal may be an access parameter, or the
 386             --  actual may be an access value, so adjust accordingly.
 387
 388             if Is_Access_Type (Pref_Type)
 389               and then not Is_Access_Type (Form_Type)
 390             then
 391                Actuals := New_List
 392                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 393
 394             elsif Is_Access_Type (Form_Type)
 395               and then not Is_Access_Type (Pref)
 396             then
 397                Actuals := New_List
 398                  (Make_Attribute_Reference (Loc,
 399                    Attribute_Name => Name_Access,
 400                    Prefix => Relocate_Node (Pref)));
 401             else
 402                Actuals := New_List (Pref);
 403             end if;
 404          end;
 405
 406       elsif Present (Formal) then
 407          Actuals := New_List;
 408
 409       else
 410          Actuals := No_List;
 411       end if;
 412
 413       if Present (Formal) then
 414          while Present (Formal) loop
 415             Append (New_Reference_To (Formal, Loc), Actuals);
 416             Next_Formal (Formal);
 417          end loop;
 418       end if;
 419
 420       --  If the renamed entity is an entry, inherit its profile. For other
 421       --  renamings as bodies, both profiles must be subtype conformant, so it
 422       --  is not necessary to replace the profile given in the declaration.
 423       --  However, default values that are aggregates are rewritten when
 424       --  partially analyzed, so we recover the original aggregate to insure
 425       --  that subsequent conformity checking works. Similarly, if the default
 426       --  expression was constant-folded, recover the original expression.
 427
 428       Formal := First_Formal (Defining_Entity (Decl));
 429
 430       if Present (Formal) then
 431          O_Formal := First_Formal (Old_S);
 432          Param_Spec := First (Parameter_Specifications (Spec));
 433          while Present (Formal) loop
 434             if Is_Entry (Old_S) then
 435                if Nkind (Parameter_Type (Param_Spec)) /=
 436                                                     N_Access_Definition
 437                then
 438                   Set_Etype (Formal, Etype (O_Formal));
 439                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 440                end if;
 441
 442             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 443               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 444                                            Nkind (Default_Value (O_Formal))
 445             then
 446                Set_Expression (Param_Spec,
 447                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 448             end if;
 449
 450             Next_Formal (Formal);
 451             Next_Formal (O_Formal);
 452             Next (Param_Spec);
 453          end loop;
 454       end if;
 455
 456       --  If the renamed entity is a function, the generated body contains a
 457       --  return statement. Otherwise, build a procedure call. If the entity is
 458       --  an entry, subsequent analysis of the call will transform it into the
 459       --  proper entry or protected operation call. If the renamed entity is
 460       --  a character literal, return it directly.
 461
 462       if Ekind (Old_S) = E_Function
 463         or else Ekind (Old_S) = E_Operator
 464         or else (Ekind (Old_S) = E_Subprogram_Type
 465                   and then Etype (Old_S) /= Standard_Void_Type)
 466       then
 467          Call_Node :=
 468            Make_Simple_Return_Statement (Loc,
 469               Expression =>
 470                 Make_Function_Call (Loc,
 471                   Name => Call_Name,
 472                   Parameter_Associations => Actuals));
 473
 474       elsif Ekind (Old_S) = E_Enumeration_Literal then
 475          Call_Node :=
 476            Make_Simple_Return_Statement (Loc,
 477               Expression => New_Occurrence_Of (Old_S, Loc));
 478
 479       elsif Nkind (Nam) = N_Character_Literal then
 480          Call_Node :=
 481            Make_Simple_Return_Statement (Loc,
 482              Expression => Call_Name);
 483
 484       else
 485          Call_Node :=
 486            Make_Procedure_Call_Statement (Loc,
 487              Name => Call_Name,
 488              Parameter_Associations => Actuals);
 489       end if;
 490
 491       --  Create entities for subprogram body and formals
 492
 493       Set_Defining_Unit_Name (Spec,
 494         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 495
 496       Param_Spec := First (Parameter_Specifications (Spec));
 497       while Present (Param_Spec) loop
 498          Set_Defining_Identifier (Param_Spec,
 499            Make_Defining_Identifier (Loc,
 500              Chars => Chars (Defining_Identifier (Param_Spec))));
 501          Next (Param_Spec);
 502       end loop;
 503
 504       Body_Node :=
 505         Make_Subprogram_Body (Loc,
 506           Specification => Spec,
 507           Declarations => New_List,
 508           Handled_Statement_Sequence =>
 509             Make_Handled_Sequence_Of_Statements (Loc,
 510               Statements => New_List (Call_Node)));
 511
 512       if Nkind (Decl) /= N_Subprogram_Declaration then
 513          Rewrite (N,
 514            Make_Subprogram_Declaration (Loc,
 515              Specification => Specification (N)));
 516       end if;
 517
 518       --  Link the body to the entity whose declaration it completes. If
 519       --  the body is analyzed when the renamed entity is frozen, it may
 520       --  be necessary to restore the proper scope (see package Exp_Ch13).
 521
 522       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 523         and then Present (Corresponding_Spec (N))
 524       then
 525          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 526       else
 527          Set_Corresponding_Spec (Body_Node, New_S);
 528       end if;
 529
 530       return Body_Node;
 531    end Build_Renamed_Body;
 532
 533    --------------------------
 534    -- Check_Address_Clause --
 535    --------------------------
 536
 537    procedure Check_Address_Clause (E : Entity_Id) is
 538       Addr : constant Node_Id   := Address_Clause (E);
 539       Expr : Node_Id;
 540       Decl : constant Node_Id   := Declaration_Node (E);
 541       Typ  : constant Entity_Id := Etype (E);
 542
 543    begin
 544       if Present (Addr) then
 545          Expr := Expression (Addr);
 546
 547          if Needs_Constant_Address (Decl, Typ) then
 548             Check_Constant_Address_Clause (Expr, E);
 549
 550             --  Has_Delayed_Freeze was set on E when the address clause was
 551             --  analyzed. Reset the flag now unless freeze actions were
 552             --  attached to it in the mean time.
 553
 554             if No (Freeze_Node (E)) then
 555                Set_Has_Delayed_Freeze (E, False);
 556             end if;
 557          end if;
 558
 559          --  If Rep_Clauses are to be ignored, remove address clause from
 560          --  list attached to entity, because it may be illegal for gigi,
 561          --  for example by breaking order of elaboration..
 562
 563          if Ignore_Rep_Clauses then
 564             declare
 565                Rep : Node_Id;
 566
 567             begin
 568                Rep := First_Rep_Item (E);
 569
 570                if Rep = Addr then
 571                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 572
 573                else
 574                   while Present (Rep)
 575                     and then Next_Rep_Item (Rep) /= Addr
 576                   loop
 577                      Rep := Next_Rep_Item (Rep);
 578                   end loop;
 579                end if;
 580
 581                if Present (Rep) then
 582                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 583                end if;
 584             end;
 585
 586             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 587
 588          elsif not Error_Posted (Expr)
 589            and then not Needs_Finalization (Typ)
 590          then
 591             Warn_Overlay (Expr, Typ, Name (Addr));
 592          end if;
 593       end if;
 594    end Check_Address_Clause;
 595
 596    -----------------------------
 597    -- Check_Compile_Time_Size --
 598    -----------------------------
 599
 600    procedure Check_Compile_Time_Size (T : Entity_Id) is
 601
 602       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 603       --  Sets the compile time known size (32 bits or less) in the Esize
 604       --  field, of T checking for a size clause that was given which attempts
 605       --  to give a smaller size, and also checking for an alignment clause.
 606
 607       function Size_Known (T : Entity_Id) return Boolean;
 608       --  Recursive function that does all the work
 609
 610       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 611       --  If T is a constrained subtype, its size is not known if any of its
 612       --  discriminant constraints is not static and it is not a null record.
 613       --  The test is conservative and doesn't check that the components are
 614       --  in fact constrained by non-static discriminant values. Could be made
 615       --  more precise ???
 616
 617       --------------------
 618       -- Set_Small_Size --
 619       --------------------
 620
 621       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 622       begin
 623          if S > 32 then
 624             return;
 625
 626          --  Check for bad size clause given
 627
 628          elsif Has_Size_Clause (T) then
 629             if RM_Size (T) < S then
 630                Error_Msg_Uint_1 := S;
 631                Error_Msg_NE
 632                  ("size for& too small, minimum allowed is ^",
 633                   Size_Clause (T), T);
 634             end if;
 635
 636          --  Set size if not set already
 637
 638          elsif Unknown_RM_Size (T) then
 639             Set_RM_Size (T, S);
 640          end if;
 641       end Set_Small_Size;
 642
 643       ----------------
 644       -- Size_Known --
 645       ----------------
 646
 647       function Size_Known (T : Entity_Id) return Boolean is
 648          Index : Entity_Id;
 649          Comp  : Entity_Id;
 650          Ctyp  : Entity_Id;
 651          Low   : Node_Id;
 652          High  : Node_Id;
 653
 654       begin
 655          if Size_Known_At_Compile_Time (T) then
 656             return True;
 657
 658          --  Always True for scalar types. This is true even for generic formal
 659          --  scalar types. We used to return False in the latter case, but the
 660          --  size is known at compile time, even in the template, we just do
 661          --  not know the exact size but that's not the point of this routine.
 662
 663          elsif Is_Scalar_Type (T)
 664            or else Is_Task_Type (T)
 665          then
 666             return True;
 667
 668          --  Array types
 669
 670          elsif Is_Array_Type (T) then
 671
 672             --  String literals always have known size, and we can set it
 673
 674             if Ekind (T) = E_String_Literal_Subtype then
 675                Set_Small_Size (T, Component_Size (T)
 676                                * String_Literal_Length (T));
 677                return True;
 678
 679             --  Unconstrained types never have known at compile time size
 680
 681             elsif not Is_Constrained (T) then
 682                return False;
 683
 684             --  Don't do any recursion on type with error posted, since we may
 685             --  have a malformed type that leads us into a loop.
 686
 687             elsif Error_Posted (T) then
 688                return False;
 689
 690             --  Otherwise if component size unknown, then array size unknown
 691
 692             elsif not Size_Known (Component_Type (T)) then
 693                return False;
 694             end if;
 695
 696             --  Check for all indexes static, and also compute possible size
 697             --  (in case it is less than 32 and may be packable).
 698
 699             declare
 700                Esiz : Uint := Component_Size (T);
 701                Dim  : Uint;
 702
 703             begin
 704                Index := First_Index (T);
 705                while Present (Index) loop
 706                   if Nkind (Index) = N_Range then
 707                      Get_Index_Bounds (Index, Low, High);
 708
 709                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 710                      return False;
 711
 712                   else
 713                      Low  := Type_Low_Bound (Etype (Index));
 714                      High := Type_High_Bound (Etype (Index));
 715                   end if;
 716
 717                   if not Compile_Time_Known_Value (Low)
 718                     or else not Compile_Time_Known_Value (High)
 719                     or else Etype (Index) = Any_Type
 720                   then
 721                      return False;
 722
 723                   else
 724                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 725
 726                      if Dim >= 0 then
 727                         Esiz := Esiz * Dim;
 728                      else
 729                         Esiz := Uint_0;
 730                      end if;
 731                   end if;
 732
 733                   Next_Index (Index);
 734                end loop;
 735
 736                Set_Small_Size (T, Esiz);
 737                return True;
 738             end;
 739
 740          --  Access types always have known at compile time sizes
 741
 742          elsif Is_Access_Type (T) then
 743             return True;
 744
 745          --  For non-generic private types, go to underlying type if present
 746
 747          elsif Is_Private_Type (T)
 748            and then not Is_Generic_Type (T)
 749            and then Present (Underlying_Type (T))
 750          then
 751             --  Don't do any recursion on type with error posted, since we may
 752             --  have a malformed type that leads us into a loop.
 753
 754             if Error_Posted (T) then
 755                return False;
 756             else
 757                return Size_Known (Underlying_Type (T));
 758             end if;
 759
 760          --  Record types
 761
 762          elsif Is_Record_Type (T) then
 763
 764             --  A class-wide type is never considered to have a known size
 765
 766             if Is_Class_Wide_Type (T) then
 767                return False;
 768
 769             --  A subtype of a variant record must not have non-static
 770             --  discriminated components.
 771
 772             elsif T /= Base_Type (T)
 773               and then not Static_Discriminated_Components (T)
 774             then
 775                return False;
 776
 777             --  Don't do any recursion on type with error posted, since we may
 778             --  have a malformed type that leads us into a loop.
 779
 780             elsif Error_Posted (T) then
 781                return False;
 782             end if;
 783
 784             --  Now look at the components of the record
 785
 786             declare
 787                --  The following two variables are used to keep track of the
 788                --  size of packed records if we can tell the size of the packed
 789                --  record in the front end. Packed_Size_Known is True if so far
 790                --  we can figure out the size. It is initialized to True for a
 791                --  packed record, unless the record has discriminants. The
 792                --  reason we eliminate the discriminated case is that we don't
 793                --  know the way the back end lays out discriminated packed
 794                --  records. If Packed_Size_Known is True, then Packed_Size is
 795                --  the size in bits so far.
 796
 797                Packed_Size_Known : Boolean :=
 798                                      Is_Packed (T)
 799                                        and then not Has_Discriminants (T);
 800
 801                Packed_Size : Uint := Uint_0;
 802
 803             begin
 804                --  Test for variant part present
 805
 806                if Has_Discriminants (T)
 807                  and then Present (Parent (T))
 808                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 809                  and then Nkind (Type_Definition (Parent (T))) =
 810                                                N_Record_Definition
 811                  and then not Null_Present (Type_Definition (Parent (T)))
 812                  and then Present (Variant_Part
 813                             (Component_List (Type_Definition (Parent (T)))))
 814                then
 815                   --  If variant part is present, and type is unconstrained,
 816                   --  then we must have defaulted discriminants, or a size
 817                   --  clause must be present for the type, or else the size
 818                   --  is definitely not known at compile time.
 819
 820                   if not Is_Constrained (T)
 821                     and then
 822                       No (Discriminant_Default_Value (First_Discriminant (T)))
 823                     and then Unknown_RM_Size (T)
 824                   then
 825                      return False;
 826                   end if;
 827                end if;
 828
 829                --  Loop through components
 830
 831                Comp := First_Component_Or_Discriminant (T);
 832                while Present (Comp) loop
 833                   Ctyp := Etype (Comp);
 834
 835                   --  We do not know the packed size if there is a component
 836                   --  clause present (we possibly could, but this would only
 837                   --  help in the case of a record with partial rep clauses.
 838                   --  That's because in the case of full rep clauses, the
 839                   --  size gets figured out anyway by a different circuit).
 840
 841                   if Present (Component_Clause (Comp)) then
 842                      Packed_Size_Known := False;
 843                   end if;
 844
 845                   --  We need to identify a component that is an array where
 846                   --  the index type is an enumeration type with non-standard
 847                   --  representation, and some bound of the type depends on a
 848                   --  discriminant.
 849
 850                   --  This is because gigi computes the size by doing a
 851                   --  substitution of the appropriate discriminant value in
 852                   --  the size expression for the base type, and gigi is not
 853                   --  clever enough to evaluate the resulting expression (which
 854                   --  involves a call to rep_to_pos) at compile time.
 855
 856                   --  It would be nice if gigi would either recognize that
 857                   --  this expression can be computed at compile time, or
 858                   --  alternatively figured out the size from the subtype
 859                   --  directly, where all the information is at hand ???
 860
 861                   if Is_Array_Type (Etype (Comp))
 862                     and then Present (Packed_Array_Type (Etype (Comp)))
 863                   then
 864                      declare
 865                         Ocomp  : constant Entity_Id :=
 866                                    Original_Record_Component (Comp);
 867                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 868                         Ind    : Node_Id;
 869                         Indtyp : Entity_Id;
 870                         Lo, Hi : Node_Id;
 871
 872                      begin
 873                         Ind := First_Index (OCtyp);
 874                         while Present (Ind) loop
 875                            Indtyp := Etype (Ind);
 876
 877                            if Is_Enumeration_Type (Indtyp)
 878                              and then Has_Non_Standard_Rep (Indtyp)
 879                            then
 880                               Lo := Type_Low_Bound  (Indtyp);
 881                               Hi := Type_High_Bound (Indtyp);
 882
 883                               if Is_Entity_Name (Lo)
 884                                 and then Ekind (Entity (Lo)) = E_Discriminant
 885                               then
 886                                  return False;
 887
 888                               elsif Is_Entity_Name (Hi)
 889                                 and then Ekind (Entity (Hi)) = E_Discriminant
 890                               then
 891                                  return False;
 892                               end if;
 893                            end if;
 894
 895                            Next_Index (Ind);
 896                         end loop;
 897                      end;
 898                   end if;
 899
 900                   --  Clearly size of record is not known if the size of one of
 901                   --  the components is not known.
 902
 903                   if not Size_Known (Ctyp) then
 904                      return False;
 905                   end if;
 906
 907                   --  Accumulate packed size if possible
 908
 909                   if Packed_Size_Known then
 910
 911                      --  We can only deal with elementary types, since for
 912                      --  non-elementary components, alignment enters into the
 913                      --  picture, and we don't know enough to handle proper
 914                      --  alignment in this context. Packed arrays count as
 915                      --  elementary if the representation is a modular type.
 916
 917                      if Is_Elementary_Type (Ctyp)
 918                        or else (Is_Array_Type (Ctyp)
 919                                  and then Present (Packed_Array_Type (Ctyp))
 920                                  and then Is_Modular_Integer_Type
 921                                             (Packed_Array_Type (Ctyp)))
 922                      then
 923                         --  If RM_Size is known and static, then we can keep
 924                         --  accumulating the packed size.
 925
 926                         if Known_Static_RM_Size (Ctyp) then
 927
 928                            --  A little glitch, to be removed sometime ???
 929                            --  gigi does not understand zero sizes yet.
 930
 931                            if RM_Size (Ctyp) = Uint_0 then
 932                               Packed_Size_Known := False;
 933
 934                            --  Normal case where we can keep accumulating the
 935                            --  packed array size.
 936
 937                            else
 938                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 939                            end if;
 940
 941                         --  If we have a field whose RM_Size is not known then
 942                         --  we can't figure out the packed size here.
 943
 944                         else
 945                            Packed_Size_Known := False;
 946                         end if;
 947
 948                      --  If we have a non-elementary type we can't figure out
 949                      --  the packed array size (alignment issues).
 950
 951                      else
 952                         Packed_Size_Known := False;
 953                      end if;
 954                   end if;
 955
 956                   Next_Component_Or_Discriminant (Comp);
 957                end loop;
 958
 959                if Packed_Size_Known then
 960                   Set_Small_Size (T, Packed_Size);
 961                end if;
 962
 963                return True;
 964             end;
 965
 966          --  All other cases, size not known at compile time
 967
 968          else
 969             return False;
 970          end if;
 971       end Size_Known;
 972
 973       -------------------------------------
 974       -- Static_Discriminated_Components --
 975       -------------------------------------
 976
 977       function Static_Discriminated_Components
 978         (T : Entity_Id) return Boolean
 979       is
 980          Constraint : Elmt_Id;
 981
 982       begin
 983          if Has_Discriminants (T)
 984            and then Present (Discriminant_Constraint (T))
 985            and then Present (First_Component (T))
 986          then
 987             Constraint := First_Elmt (Discriminant_Constraint (T));
 988             while Present (Constraint) loop
 989                if not Compile_Time_Known_Value (Node (Constraint)) then
 990                   return False;
 991                end if;
 992
 993                Next_Elmt (Constraint);
 994             end loop;
 995          end if;
 996
 997          return True;
 998       end Static_Discriminated_Components;
 999
1000    --  Start of processing for Check_Compile_Time_Size
1001
1002    begin
1003       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1004    end Check_Compile_Time_Size;
1005
1006    -----------------------------
1007    -- Check_Debug_Info_Needed --
1008    -----------------------------
1009
1010    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1011    begin
1012       if Debug_Info_Off (T) then
1013          return;
1014
1015       elsif Comes_From_Source (T)
1016         or else Debug_Generated_Code
1017         or else Debug_Flag_VV
1018         or else Needs_Debug_Info (T)
1019       then
1020          Set_Debug_Info_Needed (T);
1021       end if;
1022    end Check_Debug_Info_Needed;
1023
1024    ----------------------------
1025    -- Check_Strict_Alignment --
1026    ----------------------------
1027
1028    procedure Check_Strict_Alignment (E : Entity_Id) is
1029       Comp  : Entity_Id;
1030
1031    begin
1032       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1033          Set_Strict_Alignment (E);
1034
1035       elsif Is_Array_Type (E) then
1036          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1037
1038       elsif Is_Record_Type (E) then
1039          if Is_Limited_Record (E) then
1040             Set_Strict_Alignment (E);
1041             return;
1042          end if;
1043
1044          Comp := First_Component (E);
1045          while Present (Comp) loop
1046             if not Is_Type (Comp)
1047               and then (Strict_Alignment (Etype (Comp))
1048                          or else Is_Aliased (Comp))
1049             then
1050                Set_Strict_Alignment (E);
1051                return;
1052             end if;
1053
1054             Next_Component (Comp);
1055          end loop;
1056       end if;
1057    end Check_Strict_Alignment;
1058
1059    -------------------------
1060    -- Check_Unsigned_Type --
1061    -------------------------
1062
1063    procedure Check_Unsigned_Type (E : Entity_Id) is
1064       Ancestor : Entity_Id;
1065       Lo_Bound : Node_Id;
1066       Btyp     : Entity_Id;
1067
1068    begin
1069       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1070          return;
1071       end if;
1072
1073       --  Do not attempt to analyze case where range was in error
1074
1075       if No (Scalar_Range (E))
1076         or else Error_Posted (Scalar_Range (E))
1077       then
1078          return;
1079       end if;
1080
1081       --  The situation that is non trivial is something like
1082
1083       --     subtype x1 is integer range -10 .. +10;
1084       --     subtype x2 is x1 range 0 .. V1;
1085       --     subtype x3 is x2 range V2 .. V3;
1086       --     subtype x4 is x3 range V4 .. V5;
1087
1088       --  where Vn are variables. Here the base type is signed, but we still
1089       --  know that x4 is unsigned because of the lower bound of x2.
1090
1091       --  The only way to deal with this is to look up the ancestor chain
1092
1093       Ancestor := E;
1094       loop
1095          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1096             return;
1097          end if;
1098
1099          Lo_Bound := Type_Low_Bound (Ancestor);
1100
1101          if Compile_Time_Known_Value (Lo_Bound) then
1102
1103             if Expr_Rep_Value (Lo_Bound) >= 0 then
1104                Set_Is_Unsigned_Type (E, True);
1105             end if;
1106
1107             return;
1108
1109          else
1110             Ancestor := Ancestor_Subtype (Ancestor);
1111
1112             --  If no ancestor had a static lower bound, go to base type
1113
1114             if No (Ancestor) then
1115
1116                --  Note: the reason we still check for a compile time known
1117                --  value for the base type is that at least in the case of
1118                --  generic formals, we can have bounds that fail this test,
1119                --  and there may be other cases in error situations.
1120
1121                Btyp := Base_Type (E);
1122
1123                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1124                   return;
1125                end if;
1126
1127                Lo_Bound := Type_Low_Bound (Base_Type (E));
1128
1129                if Compile_Time_Known_Value (Lo_Bound)
1130                  and then Expr_Rep_Value (Lo_Bound) >= 0
1131                then
1132                   Set_Is_Unsigned_Type (E, True);
1133                end if;
1134
1135                return;
1136             end if;
1137          end if;
1138       end loop;
1139    end Check_Unsigned_Type;
1140
1141    -------------------------
1142    -- Is_Atomic_Aggregate --
1143    -------------------------
1144
1145    function  Is_Atomic_Aggregate
1146      (E   : Entity_Id;
1147       Typ : Entity_Id) return Boolean
1148    is
1149       Loc   : constant Source_Ptr := Sloc (E);
1150       New_N : Node_Id;
1151       Par   : Node_Id;
1152       Temp  : Entity_Id;
1153
1154    begin
1155       Par := Parent (E);
1156
1157       --  Array may be qualified, so find outer context
1158
1159       if Nkind (Par) = N_Qualified_Expression then
1160          Par := Parent (Par);
1161       end if;
1162
1163       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1164         and then Comes_From_Source (Par)
1165       then
1166          Temp := Make_Temporary (Loc, 'T', E);
1167          New_N :=
1168            Make_Object_Declaration (Loc,
1169              Defining_Identifier => Temp,
1170              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1171              Expression          => Relocate_Node (E));
1172          Insert_Before (Par, New_N);
1173          Analyze (New_N);
1174
1175          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1176          return True;
1177
1178       else
1179          return False;
1180       end if;
1181    end Is_Atomic_Aggregate;
1182
1183    ----------------
1184    -- Freeze_All --
1185    ----------------
1186
1187    --  Note: the easy coding for this procedure would be to just build a
1188    --  single list of freeze nodes and then insert them and analyze them
1189    --  all at once. This won't work, because the analysis of earlier freeze
1190    --  nodes may recursively freeze types which would otherwise appear later
1191    --  on in the freeze list. So we must analyze and expand the freeze nodes
1192    --  as they are generated.
1193
1194    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1195       E     : Entity_Id;
1196       Decl  : Node_Id;
1197
1198       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1199       --  This is the internal recursive routine that does freezing of entities
1200       --  (but NOT the analysis of default expressions, which should not be
1201       --  recursive, we don't want to analyze those till we are sure that ALL
1202       --  the types are frozen).
1203
1204       --------------------
1205       -- Freeze_All_Ent --
1206       --------------------
1207
1208       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1209          E     : Entity_Id;
1210          Flist : List_Id;
1211          Lastn : Node_Id;
1212
1213          procedure Process_Flist;
1214          --  If freeze nodes are present, insert and analyze, and reset cursor
1215          --  for next insertion.
1216
1217          -------------------
1218          -- Process_Flist --
1219          -------------------
1220
1221          procedure Process_Flist is
1222          begin
1223             if Is_Non_Empty_List (Flist) then
1224                Lastn := Next (After);
1225                Insert_List_After_And_Analyze (After, Flist);
1226
1227                if Present (Lastn) then
1228                   After := Prev (Lastn);
1229                else
1230                   After := Last (List_Containing (After));
1231                end if;
1232             end if;
1233          end Process_Flist;
1234
1235       --  Start or processing for Freeze_All_Ent
1236
1237       begin
1238          E := From;
1239          while Present (E) loop
1240
1241             --  If the entity is an inner package which is not a package
1242             --  renaming, then its entities must be frozen at this point. Note
1243             --  that such entities do NOT get frozen at the end of the nested
1244             --  package itself (only library packages freeze).
1245
1246             --  Same is true for task declarations, where anonymous records
1247             --  created for entry parameters must be frozen.
1248
1249             if Ekind (E) = E_Package
1250               and then No (Renamed_Object (E))
1251               and then not Is_Child_Unit (E)
1252               and then not Is_Frozen (E)
1253             then
1254                Push_Scope (E);
1255                Install_Visible_Declarations (E);
1256                Install_Private_Declarations (E);
1257
1258                Freeze_All (First_Entity (E), After);
1259
1260                End_Package_Scope (E);
1261
1262                if Is_Generic_Instance (E)
1263                  and then Has_Delayed_Freeze (E)
1264                then
1265                   Set_Has_Delayed_Freeze (E, False);
1266                   Expand_N_Package_Declaration (Unit_Declaration_Node (E));
1267                end if;
1268
1269             elsif Ekind (E) in Task_Kind
1270               and then
1271                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1272                    or else
1273                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1274             then
1275                Push_Scope (E);
1276                Freeze_All (First_Entity (E), After);
1277                End_Scope;
1278
1279             --  For a derived tagged type, we must ensure that all the
1280             --  primitive operations of the parent have been frozen, so that
1281             --  their addresses will be in the parent's dispatch table at the
1282             --  point it is inherited.
1283
1284             elsif Ekind (E) = E_Record_Type
1285               and then Is_Tagged_Type (E)
1286               and then Is_Tagged_Type (Etype (E))
1287               and then Is_Derived_Type (E)
1288             then
1289                declare
1290                   Prim_List : constant Elist_Id :=
1291                                Primitive_Operations (Etype (E));
1292
1293                   Prim : Elmt_Id;
1294                   Subp : Entity_Id;
1295
1296                begin
1297                   Prim := First_Elmt (Prim_List);
1298                   while Present (Prim) loop
1299                      Subp := Node (Prim);
1300
1301                      if Comes_From_Source (Subp)
1302                        and then not Is_Frozen (Subp)
1303                      then
1304                         Flist := Freeze_Entity (Subp, After);
1305                         Process_Flist;
1306                      end if;
1307
1308                      Next_Elmt (Prim);
1309                   end loop;
1310                end;
1311             end if;
1312
1313             if not Is_Frozen (E) then
1314                Flist := Freeze_Entity (E, After);
1315                Process_Flist;
1316
1317             --  If already frozen, and there are delayed aspects, this is where
1318             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1319             --  for a description of how we handle aspect visibility).
1320
1321             elsif Has_Delayed_Aspects (E) then
1322                declare
1323                   Ritem : Node_Id;
1324
1325                begin
1326                   Ritem := First_Rep_Item (E);
1327                   while Present (Ritem) loop
1328                      if Nkind (Ritem) = N_Aspect_Specification
1329                        and then Entity (Ritem) = E
1330                        and then Is_Delayed_Aspect (Ritem)
1331                      then
1332                         Check_Aspect_At_End_Of_Declarations (Ritem);
1333                      end if;
1334
1335                      Ritem := Next_Rep_Item (Ritem);
1336                   end loop;
1337                end;
1338             end if;
1339
1340             --  If an incomplete type is still not frozen, this may be a
1341             --  premature freezing because of a body declaration that follows.
1342             --  Indicate where the freezing took place.
1343
1344             --  If the freezing is caused by the end of the current declarative
1345             --  part, it is a Taft Amendment type, and there is no error.
1346
1347             if not Is_Frozen (E)
1348               and then Ekind (E) = E_Incomplete_Type
1349             then
1350                declare
1351                   Bod : constant Node_Id := Next (After);
1352
1353                begin
1354                   if (Nkind_In (Bod, N_Subprogram_Body,
1355                                      N_Entry_Body,
1356                                      N_Package_Body,
1357                                      N_Protected_Body,
1358                                      N_Task_Body)
1359                         or else Nkind (Bod) in N_Body_Stub)
1360                      and then
1361                        List_Containing (After) = List_Containing (Parent (E))
1362                   then
1363                      Error_Msg_Sloc := Sloc (Next (After));
1364                      Error_Msg_NE
1365                        ("type& is frozen# before its full declaration",
1366                          Parent (E), E);
1367                   end if;
1368                end;
1369             end if;
1370
1371             Next_Entity (E);
1372          end loop;
1373       end Freeze_All_Ent;
1374
1375    --  Start of processing for Freeze_All
1376
1377    begin
1378       Freeze_All_Ent (From, After);
1379
1380       --  Now that all types are frozen, we can deal with default expressions
1381       --  that require us to build a default expression functions. This is the
1382       --  point at which such functions are constructed (after all types that
1383       --  might be used in such expressions have been frozen).
1384
1385       --  For subprograms that are renaming_as_body, we create the wrapper
1386       --  bodies as needed.
1387
1388       --  We also add finalization chains to access types whose designated
1389       --  types are controlled. This is normally done when freezing the type,
1390       --  but this misses recursive type definitions where the later members
1391       --  of the recursion introduce controlled components.
1392
1393       --  Loop through entities
1394
1395       E := From;
1396       while Present (E) loop
1397          if Is_Subprogram (E) then
1398
1399             if not Default_Expressions_Processed (E) then
1400                Process_Default_Expressions (E, After);
1401             end if;
1402
1403             if not Has_Completion (E) then
1404                Decl := Unit_Declaration_Node (E);
1405
1406                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1407                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1408
1409                elsif Nkind (Decl) = N_Subprogram_Declaration
1410                  and then Present (Corresponding_Body (Decl))
1411                  and then
1412                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1413                                           = N_Subprogram_Renaming_Declaration
1414                then
1415                   Build_And_Analyze_Renamed_Body
1416                     (Decl, Corresponding_Body (Decl), After);
1417                end if;
1418             end if;
1419
1420          elsif Ekind (E) in Task_Kind
1421            and then
1422              (Nkind (Parent (E)) = N_Task_Type_Declaration
1423                 or else
1424               Nkind (Parent (E)) = N_Single_Task_Declaration)
1425          then
1426             declare
1427                Ent : Entity_Id;
1428
1429             begin
1430                Ent := First_Entity (E);
1431                while Present (Ent) loop
1432                   if Is_Entry (Ent)
1433                     and then not Default_Expressions_Processed (Ent)
1434                   then
1435                      Process_Default_Expressions (Ent, After);
1436                   end if;
1437
1438                   Next_Entity (Ent);
1439                end loop;
1440             end;
1441
1442          --  We add finalization masters to access types whose designated types
1443          --  require finalization. This is normally done when freezing the
1444          --  type, but this misses recursive type definitions where the later
1445          --  members of the recursion introduce controlled components (such as
1446          --  can happen when incomplete types are involved), as well cases
1447          --  where a component type is private and the controlled full type
1448          --  occurs after the access type is frozen. Cases that don't need a
1449          --  finalization master are generic formal types (the actual type will
1450          --  have it) and types with Java and CIL conventions, since those are
1451          --  used for API bindings. (Are there any other cases that should be
1452          --  excluded here???)
1453
1454          elsif Is_Access_Type (E)
1455            and then Comes_From_Source (E)
1456            and then not Is_Generic_Type (E)
1457            and then Needs_Finalization (Designated_Type (E))
1458          then
1459             Build_Finalization_Master (E);
1460          end if;
1461
1462          Next_Entity (E);
1463       end loop;
1464    end Freeze_All;
1465
1466    -----------------------
1467    -- Freeze_And_Append --
1468    -----------------------
1469
1470    procedure Freeze_And_Append
1471      (Ent    : Entity_Id;
1472       N      : Node_Id;
1473       Result : in out List_Id)
1474    is
1475       L : constant List_Id := Freeze_Entity (Ent, N);
1476    begin
1477       if Is_Non_Empty_List (L) then
1478          if Result = No_List then
1479             Result := L;
1480          else
1481             Append_List (L, Result);
1482          end if;
1483       end if;
1484    end Freeze_And_Append;
1485
1486    -------------------
1487    -- Freeze_Before --
1488    -------------------
1489
1490    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1491       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1492    begin
1493       if Is_Non_Empty_List (Freeze_Nodes) then
1494          Insert_Actions (N, Freeze_Nodes);
1495       end if;
1496    end Freeze_Before;
1497
1498    -------------------
1499    -- Freeze_Entity --
1500    -------------------
1501
1502    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1503       Loc    : constant Source_Ptr := Sloc (N);
1504       Test_E : Entity_Id := E;
1505       Comp   : Entity_Id;
1506       F_Node : Node_Id;
1507       Indx   : Node_Id;
1508       Formal : Entity_Id;
1509       Atype  : Entity_Id;
1510
1511       Result : List_Id := No_List;
1512       --  List of freezing actions, left at No_List if none
1513
1514       Has_Default_Initialization : Boolean := False;
1515       --  This flag gets set to true for a variable with default initialization
1516
1517       procedure Add_To_Result (N : Node_Id);
1518       --  N is a freezing action to be appended to the Result
1519
1520       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1521       --  Check that an Access or Unchecked_Access attribute with a prefix
1522       --  which is the current instance type can only be applied when the type
1523       --  is limited.
1524
1525       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1526       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1527       --  integer literal without an explicit corresponding size clause. The
1528       --  caller has checked that Utype is a modular integer type.
1529
1530       function After_Last_Declaration return Boolean;
1531       --  If Loc is a freeze_entity that appears after the last declaration
1532       --  in the scope, inhibit error messages on late completion.
1533
1534       procedure Freeze_Record_Type (Rec : Entity_Id);
1535       --  Freeze each component, handle some representation clauses, and freeze
1536       --  primitive operations if this is a tagged type.
1537
1538       -------------------
1539       -- Add_To_Result --
1540       -------------------
1541
1542       procedure Add_To_Result (N : Node_Id) is
1543       begin
1544          if No (Result) then
1545             Result := New_List (N);
1546          else
1547             Append (N, Result);
1548          end if;
1549       end Add_To_Result;
1550
1551       ----------------------------
1552       -- After_Last_Declaration --
1553       ----------------------------
1554
1555       function After_Last_Declaration return Boolean is
1556          Spec : constant Node_Id := Parent (Current_Scope);
1557       begin
1558          if Nkind (Spec) = N_Package_Specification then
1559             if Present (Private_Declarations (Spec)) then
1560                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1561             elsif Present (Visible_Declarations (Spec)) then
1562                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1563             else
1564                return False;
1565             end if;
1566          else
1567             return False;
1568          end if;
1569       end After_Last_Declaration;
1570
1571       ----------------------------
1572       -- Check_Current_Instance --
1573       ----------------------------
1574
1575       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1576
1577          Rec_Type : constant Entity_Id :=
1578                       Scope (Defining_Identifier (Comp_Decl));
1579
1580          Decl : constant Node_Id := Parent (Rec_Type);
1581
1582          function Process (N : Node_Id) return Traverse_Result;
1583          --  Process routine to apply check to given node
1584
1585          -------------
1586          -- Process --
1587          -------------
1588
1589          function Process (N : Node_Id) return Traverse_Result is
1590          begin
1591             case Nkind (N) is
1592                when N_Attribute_Reference =>
1593                   if (Attribute_Name (N) = Name_Access
1594                         or else
1595                       Attribute_Name (N) = Name_Unchecked_Access)
1596                     and then Is_Entity_Name (Prefix (N))
1597                     and then Is_Type (Entity (Prefix (N)))
1598                     and then Entity (Prefix (N)) = E
1599                   then
1600                      Error_Msg_N
1601                        ("current instance must be a limited type", Prefix (N));
1602                      return Abandon;
1603                   else
1604                      return OK;
1605                   end if;
1606
1607                when others => return OK;
1608             end case;
1609          end Process;
1610
1611          procedure Traverse is new Traverse_Proc (Process);
1612
1613       --  Start of processing for Check_Current_Instance
1614
1615       begin
1616          --  In Ada95, the (imprecise) rule is that the current instance of a
1617          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1618          --  either a tagged type, or a limited record.
1619
1620          if Is_Limited_Type (Rec_Type)
1621            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1622          then
1623             return;
1624
1625          elsif Nkind (Decl) = N_Full_Type_Declaration
1626            and then Limited_Present (Type_Definition (Decl))
1627          then
1628             return;
1629
1630          else
1631             Traverse (Comp_Decl);
1632          end if;
1633       end Check_Current_Instance;
1634
1635       ------------------------------
1636       -- Check_Suspicious_Modulus --
1637       ------------------------------
1638
1639       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1640          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1641
1642       begin
1643          if Nkind (Decl) = N_Full_Type_Declaration then
1644             declare
1645                Tdef : constant Node_Id := Type_Definition (Decl);
1646             begin
1647                if Nkind (Tdef) = N_Modular_Type_Definition then
1648                   declare
1649                      Modulus : constant Node_Id :=
1650                                  Original_Node (Expression (Tdef));
1651                   begin
1652                      if Nkind (Modulus) = N_Integer_Literal then
1653                         declare
1654                            Modv : constant Uint := Intval (Modulus);
1655                            Sizv : constant Uint := RM_Size (Utype);
1656
1657                         begin
1658                            --  First case, modulus and size are the same. This
1659                            --  happens if you have something like mod 32, with
1660                            --  an explicit size of 32, this is for sure a case
1661                            --  where the warning is given, since it is seems
1662                            --  very unlikely that someone would want e.g. a
1663                            --  five bit type stored in 32 bits. It is much
1664                            --  more likely they wanted a 32-bit type.
1665
1666                            if Modv = Sizv then
1667                               null;
1668
1669                            --  Second case, the modulus is 32 or 64 and no
1670                            --  size clause is present. This is a less clear
1671                            --  case for giving the warning, but in the case
1672                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1673                            --  enough that it is a likely error (and in any
1674                            --  case using 2**5 or 2**6 in these cases seems
1675                            --  clearer. We don't include 8 or 16 here, simply
1676                            --  because in practice 3-bit and 4-bit types are
1677                            --  more common and too many false positives if
1678                            --  we warn in these cases.
1679
1680                            elsif not Has_Size_Clause (Utype)
1681                              and then (Modv = Uint_32 or else Modv = Uint_64)
1682                            then
1683                               null;
1684
1685                            --  No warning needed
1686
1687                            else
1688                               return;
1689                            end if;
1690
1691                            --  If we fall through, give warning
1692
1693                            Error_Msg_Uint_1 := Modv;
1694                            Error_Msg_N
1695                              ("?2 '*'*^' may have been intended here",
1696                               Modulus);
1697                         end;
1698                      end if;
1699                   end;
1700                end if;
1701             end;
1702          end if;
1703       end Check_Suspicious_Modulus;
1704
1705       ------------------------
1706       -- Freeze_Record_Type --
1707       ------------------------
1708
1709       procedure Freeze_Record_Type (Rec : Entity_Id) is
1710          Comp : Entity_Id;
1711          IR   : Node_Id;
1712          ADC  : Node_Id;
1713          Prev : Entity_Id;
1714
1715          Junk : Boolean;
1716          pragma Warnings (Off, Junk);
1717
1718          Unplaced_Component : Boolean := False;
1719          --  Set True if we find at least one component with no component
1720          --  clause (used to warn about useless Pack pragmas).
1721
1722          Placed_Component : Boolean := False;
1723          --  Set True if we find at least one component with a component
1724          --  clause (used to warn about useless Bit_Order pragmas, and also
1725          --  to detect cases where Implicit_Packing may have an effect).
1726
1727          All_Scalar_Components : Boolean := True;
1728          --  Set False if we encounter a component of a non-scalar type
1729
1730          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1731          Scalar_Component_Total_Esize   : Uint := Uint_0;
1732          --  Accumulates total RM_Size values and total Esize values of all
1733          --  scalar components. Used for processing of Implicit_Packing.
1734
1735          function Check_Allocator (N : Node_Id) return Node_Id;
1736          --  If N is an allocator, possibly wrapped in one or more level of
1737          --  qualified expression(s), return the inner allocator node, else
1738          --  return Empty.
1739
1740          procedure Check_Itype (Typ : Entity_Id);
1741          --  If the component subtype is an access to a constrained subtype of
1742          --  an already frozen type, make the subtype frozen as well. It might
1743          --  otherwise be frozen in the wrong scope, and a freeze node on
1744          --  subtype has no effect. Similarly, if the component subtype is a
1745          --  regular (not protected) access to subprogram, set the anonymous
1746          --  subprogram type to frozen as well, to prevent an out-of-scope
1747          --  freeze node at some eventual point of call. Protected operations
1748          --  are handled elsewhere.
1749
1750          ---------------------
1751          -- Check_Allocator --
1752          ---------------------
1753
1754          function Check_Allocator (N : Node_Id) return Node_Id is
1755             Inner : Node_Id;
1756          begin
1757             Inner := N;
1758             loop
1759                if Nkind (Inner) = N_Allocator then
1760                   return Inner;
1761                elsif Nkind (Inner) = N_Qualified_Expression then
1762                   Inner := Expression (Inner);
1763                else
1764                   return Empty;
1765                end if;
1766             end loop;
1767          end Check_Allocator;
1768
1769          -----------------
1770          -- Check_Itype --
1771          -----------------
1772
1773          procedure Check_Itype (Typ : Entity_Id) is
1774             Desig : constant Entity_Id := Designated_Type (Typ);
1775
1776          begin
1777             if not Is_Frozen (Desig)
1778               and then Is_Frozen (Base_Type (Desig))
1779             then
1780                Set_Is_Frozen (Desig);
1781
1782                --  In addition, add an Itype_Reference to ensure that the
1783                --  access subtype is elaborated early enough. This cannot be
1784                --  done if the subtype may depend on discriminants.
1785
1786                if Ekind (Comp) = E_Component
1787                  and then Is_Itype (Etype (Comp))
1788                  and then not Has_Discriminants (Rec)
1789                then
1790                   IR := Make_Itype_Reference (Sloc (Comp));
1791                   Set_Itype (IR, Desig);
1792                   Add_To_Result (IR);
1793                end if;
1794
1795             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1796               and then Convention (Desig) /= Convention_Protected
1797             then
1798                Set_Is_Frozen (Desig);
1799             end if;
1800          end Check_Itype;
1801
1802       --  Start of processing for Freeze_Record_Type
1803
1804       begin
1805          --  Freeze components and embedded subtypes
1806
1807          Comp := First_Entity (Rec);
1808          Prev := Empty;
1809          while Present (Comp) loop
1810
1811             --  First handle the component case
1812
1813             if Ekind (Comp) = E_Component
1814               or else Ekind (Comp) = E_Discriminant
1815             then
1816                declare
1817                   CC : constant Node_Id := Component_Clause (Comp);
1818
1819                begin
1820                   --  Freezing a record type freezes the type of each of its
1821                   --  components. However, if the type of the component is
1822                   --  part of this record, we do not want or need a separate
1823                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1824                   --  also set in private type cases. We also can't check for
1825                   --  the Scope being exactly Rec because of private types and
1826                   --  record extensions.
1827
1828                   if Is_Itype (Etype (Comp))
1829                     and then Is_Record_Type (Underlying_Type
1830                                              (Scope (Etype (Comp))))
1831                   then
1832                      Undelay_Type (Etype (Comp));
1833                   end if;
1834
1835                   Freeze_And_Append (Etype (Comp), N, Result);
1836
1837                   --  Check for error of component clause given for variable
1838                   --  sized type. We have to delay this test till this point,
1839                   --  since the component type has to be frozen for us to know
1840                   --  if it is variable length. We omit this test in a generic
1841                   --  context, it will be applied at instantiation time.
1842
1843                   if Present (CC) then
1844                      Placed_Component := True;
1845
1846                      if Inside_A_Generic then
1847                         null;
1848
1849                      elsif not
1850                        Size_Known_At_Compile_Time
1851                          (Underlying_Type (Etype (Comp)))
1852                      then
1853                         Error_Msg_N
1854                           ("component clause not allowed for variable " &
1855                            "length component", CC);
1856                      end if;
1857
1858                   else
1859                      Unplaced_Component := True;
1860                   end if;
1861
1862                   --  Case of component requires byte alignment
1863
1864                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1865
1866                      --  Set the enclosing record to also require byte align
1867
1868                      Set_Must_Be_On_Byte_Boundary (Rec);
1869
1870                      --  Check for component clause that is inconsistent with
1871                      --  the required byte boundary alignment.
1872
1873                      if Present (CC)
1874                        and then Normalized_First_Bit (Comp) mod
1875                                   System_Storage_Unit /= 0
1876                      then
1877                         Error_Msg_N
1878                           ("component & must be byte aligned",
1879                            Component_Name (Component_Clause (Comp)));
1880                      end if;
1881                   end if;
1882                end;
1883             end if;
1884
1885             --  Gather data for possible Implicit_Packing later. Note that at
1886             --  this stage we might be dealing with a real component, or with
1887             --  an implicit subtype declaration.
1888
1889             if not Is_Scalar_Type (Etype (Comp)) then
1890                All_Scalar_Components := False;
1891             else
1892                Scalar_Component_Total_RM_Size :=
1893                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1894                Scalar_Component_Total_Esize :=
1895                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1896             end if;
1897
1898             --  If the component is an Itype with Delayed_Freeze and is either
1899             --  a record or array subtype and its base type has not yet been
1900             --  frozen, we must remove this from the entity list of this record
1901             --  and put it on the entity list of the scope of its base type.
1902             --  Note that we know that this is not the type of a component
1903             --  since we cleared Has_Delayed_Freeze for it in the previous
1904             --  loop. Thus this must be the Designated_Type of an access type,
1905             --  which is the type of a component.
1906
1907             if Is_Itype (Comp)
1908               and then Is_Type (Scope (Comp))
1909               and then Is_Composite_Type (Comp)
1910               and then Base_Type (Comp) /= Comp
1911               and then Has_Delayed_Freeze (Comp)
1912               and then not Is_Frozen (Base_Type (Comp))
1913             then
1914                declare
1915                   Will_Be_Frozen : Boolean := False;
1916                   S              : Entity_Id;
1917
1918                begin
1919                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1920                   --  being defined in a subprogram that's created as part of
1921                   --  the freezing of Rec'Base. In that case, we know that
1922                   --  Comp'Base must have already been frozen by the time we
1923                   --  get to elaborate this because Gigi doesn't elaborate any
1924                   --  bodies until it has elaborated all of the declarative
1925                   --  part. But Is_Frozen will not be set at this point because
1926                   --  we are processing code in lexical order.
1927
1928                   --  We detect this case by going up the Scope chain of Rec
1929                   --  and seeing if we have a subprogram scope before reaching
1930                   --  the top of the scope chain or that of Comp'Base. If we
1931                   --  do, then mark that Comp'Base will actually be frozen. If
1932                   --  so, we merely undelay it.
1933
1934                   S := Scope (Rec);
1935                   while Present (S) loop
1936                      if Is_Subprogram (S) then
1937                         Will_Be_Frozen := True;
1938                         exit;
1939                      elsif S = Scope (Base_Type (Comp)) then
1940                         exit;
1941                      end if;
1942
1943                      S := Scope (S);
1944                   end loop;
1945
1946                   if Will_Be_Frozen then
1947                      Undelay_Type (Comp);
1948                   else
1949                      if Present (Prev) then
1950                         Set_Next_Entity (Prev, Next_Entity (Comp));
1951                      else
1952                         Set_First_Entity (Rec, Next_Entity (Comp));
1953                      end if;
1954
1955                      --  Insert in entity list of scope of base type (which
1956                      --  must be an enclosing scope, because still unfrozen).
1957
1958                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1959                   end if;
1960                end;
1961
1962             --  If the component is an access type with an allocator as default
1963             --  value, the designated type will be frozen by the corresponding
1964             --  expression in init_proc. In order to place the freeze node for
1965             --  the designated type before that for the current record type,
1966             --  freeze it now.
1967
1968             --  Same process if the component is an array of access types,
1969             --  initialized with an aggregate. If the designated type is
1970             --  private, it cannot contain allocators, and it is premature
1971             --  to freeze the type, so we check for this as well.
1972
1973             elsif Is_Access_Type (Etype (Comp))
1974               and then Present (Parent (Comp))
1975               and then Present (Expression (Parent (Comp)))
1976             then
1977                declare
1978                   Alloc : constant Node_Id :=
1979                             Check_Allocator (Expression (Parent (Comp)));
1980
1981                begin
1982                   if Present (Alloc) then
1983
1984                      --  If component is pointer to a classwide type, freeze
1985                      --  the specific type in the expression being allocated.
1986                      --  The expression may be a subtype indication, in which
1987                      --  case freeze the subtype mark.
1988
1989                      if Is_Class_Wide_Type
1990                           (Designated_Type (Etype (Comp)))
1991                      then
1992                         if Is_Entity_Name (Expression (Alloc)) then
1993                            Freeze_And_Append
1994                              (Entity (Expression (Alloc)), N, Result);
1995                         elsif
1996                           Nkind (Expression (Alloc)) = N_Subtype_Indication
1997                         then
1998                            Freeze_And_Append
1999                             (Entity (Subtype_Mark (Expression (Alloc))),
2000                              N, Result);
2001                         end if;
2002
2003                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2004                         Check_Itype (Etype (Comp));
2005
2006                      else
2007                         Freeze_And_Append
2008                           (Designated_Type (Etype (Comp)), N, Result);
2009                      end if;
2010                   end if;
2011                end;
2012
2013             elsif Is_Access_Type (Etype (Comp))
2014               and then Is_Itype (Designated_Type (Etype (Comp)))
2015             then
2016                Check_Itype (Etype (Comp));
2017
2018             elsif Is_Array_Type (Etype (Comp))
2019               and then Is_Access_Type (Component_Type (Etype (Comp)))
2020               and then Present (Parent (Comp))
2021               and then Nkind (Parent (Comp)) = N_Component_Declaration
2022               and then Present (Expression (Parent (Comp)))
2023               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2024               and then Is_Fully_Defined
2025                  (Designated_Type (Component_Type (Etype (Comp))))
2026             then
2027                Freeze_And_Append
2028                  (Designated_Type
2029                    (Component_Type (Etype (Comp))), N, Result);
2030             end if;
2031
2032             Prev := Comp;
2033             Next_Entity (Comp);
2034          end loop;
2035
2036          --  Deal with Bit_Order aspect specifying a non-default bit order
2037
2038          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2039             if not Placed_Component then
2040                ADC :=
2041                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2042                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2043                Error_Msg_N
2044                  ("\?since no component clauses were specified", ADC);
2045
2046             --  Here is where we do the processing for reversed bit order
2047
2048             else
2049                Adjust_Record_For_Reverse_Bit_Order (Rec);
2050             end if;
2051          end if;
2052
2053          --  Complete error checking on record representation clause (e.g.
2054          --  overlap of components). This is called after adjusting the
2055          --  record for reverse bit order.
2056
2057          declare
2058             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2059          begin
2060             if Present (RRC) then
2061                Check_Record_Representation_Clause (RRC);
2062             end if;
2063          end;
2064
2065          --  Set OK_To_Reorder_Components depending on debug flags
2066
2067          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2068             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2069                   or else
2070                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2071             then
2072                Set_OK_To_Reorder_Components (Rec);
2073             end if;
2074          end if;
2075
2076          --  Check for useless pragma Pack when all components placed. We only
2077          --  do this check for record types, not subtypes, since a subtype may
2078          --  have all its components placed, and it still makes perfectly good
2079          --  sense to pack other subtypes or the parent type. We do not give
2080          --  this warning if Optimize_Alignment is set to Space, since the
2081          --  pragma Pack does have an effect in this case (it always resets
2082          --  the alignment to one).
2083
2084          if Ekind (Rec) = E_Record_Type
2085            and then Is_Packed (Rec)
2086            and then not Unplaced_Component
2087            and then Optimize_Alignment /= 'S'
2088          then
2089             --  Reset packed status. Probably not necessary, but we do it so
2090             --  that there is no chance of the back end doing something strange
2091             --  with this redundant indication of packing.
2092
2093             Set_Is_Packed (Rec, False);
2094
2095             --  Give warning if redundant constructs warnings on
2096
2097             if Warn_On_Redundant_Constructs then
2098                Error_Msg_N -- CODEFIX
2099                  ("?pragma Pack has no effect, no unplaced components",
2100                   Get_Rep_Pragma (Rec, Name_Pack));
2101             end if;
2102          end if;
2103
2104          --  If this is the record corresponding to a remote type, freeze the
2105          --  remote type here since that is what we are semantically freezing.
2106          --  This prevents the freeze node for that type in an inner scope.
2107
2108          --  Also, Check for controlled components and unchecked unions.
2109          --  Finally, enforce the restriction that access attributes with a
2110          --  current instance prefix can only apply to limited types.
2111
2112          if Ekind (Rec) = E_Record_Type then
2113             if Present (Corresponding_Remote_Type (Rec)) then
2114                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2115             end if;
2116
2117             Comp := First_Component (Rec);
2118             while Present (Comp) loop
2119
2120                --  Do not set Has_Controlled_Component on a class-wide
2121                --  equivalent type. See Make_CW_Equivalent_Type.
2122
2123                if not Is_Class_Wide_Equivalent_Type (Rec)
2124                  and then (Has_Controlled_Component (Etype (Comp))
2125                             or else (Chars (Comp) /= Name_uParent
2126                                       and then Is_Controlled (Etype (Comp)))
2127                             or else (Is_Protected_Type (Etype (Comp))
2128                                       and then Present
2129                                         (Corresponding_Record_Type
2130                                           (Etype (Comp)))
2131                                       and then Has_Controlled_Component
2132                                         (Corresponding_Record_Type
2133                                           (Etype (Comp)))))
2134                then
2135                   Set_Has_Controlled_Component (Rec);
2136                   exit;
2137                end if;
2138
2139                if Has_Unchecked_Union (Etype (Comp)) then
2140                   Set_Has_Unchecked_Union (Rec);
2141                end if;
2142
2143                if Has_Per_Object_Constraint (Comp) then
2144
2145                   --  Scan component declaration for likely misuses of current
2146                   --  instance, either in a constraint or a default expression.
2147
2148                   Check_Current_Instance (Parent (Comp));
2149                end if;
2150
2151                Next_Component (Comp);
2152             end loop;
2153          end if;
2154
2155          Set_Component_Alignment_If_Not_Set (Rec);
2156
2157          --  For first subtypes, check if there are any fixed-point fields with
2158          --  component clauses, where we must check the size. This is not done
2159          --  till the freeze point, since for fixed-point types, we do not know
2160          --  the size until the type is frozen. Similar processing applies to
2161          --  bit packed arrays.
2162
2163          if Is_First_Subtype (Rec) then
2164             Comp := First_Component (Rec);
2165             while Present (Comp) loop
2166                if Present (Component_Clause (Comp))
2167                  and then (Is_Fixed_Point_Type (Etype (Comp))
2168                              or else
2169                            Is_Bit_Packed_Array (Etype (Comp)))
2170                then
2171                   Check_Size
2172                     (Component_Name (Component_Clause (Comp)),
2173                      Etype (Comp),
2174                      Esize (Comp),
2175                      Junk);
2176                end if;
2177
2178                Next_Component (Comp);
2179             end loop;
2180          end if;
2181
2182          --  Generate warning for applying C or C++ convention to a record
2183          --  with discriminants. This is suppressed for the unchecked union
2184          --  case, since the whole point in this case is interface C. We also
2185          --  do not generate this within instantiations, since we will have
2186          --  generated a message on the template.
2187
2188          if Has_Discriminants (E)
2189            and then not Is_Unchecked_Union (E)
2190            and then (Convention (E) = Convention_C
2191                        or else
2192                      Convention (E) = Convention_CPP)
2193            and then Comes_From_Source (E)
2194            and then not In_Instance
2195            and then not Has_Warnings_Off (E)
2196            and then not Has_Warnings_Off (Base_Type (E))
2197          then
2198             declare
2199                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2200                A2    : Node_Id;
2201
2202             begin
2203                if Present (Cprag) then
2204                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2205
2206                   if Convention (E) = Convention_C then
2207                      Error_Msg_N
2208                        ("?variant record has no direct equivalent in C", A2);
2209                   else
2210                      Error_Msg_N
2211                        ("?variant record has no direct equivalent in C++", A2);
2212                   end if;
2213
2214                   Error_Msg_NE
2215                     ("\?use of convention for type& is dubious", A2, E);
2216                end if;
2217             end;
2218          end if;
2219
2220          --  See if Size is too small as is (and implicit packing might help)
2221
2222          if not Is_Packed (Rec)
2223
2224            --  No implicit packing if even one component is explicitly placed
2225
2226            and then not Placed_Component
2227
2228            --  Must have size clause and all scalar components
2229
2230            and then Has_Size_Clause (Rec)
2231            and then All_Scalar_Components
2232
2233            --  Do not try implicit packing on records with discriminants, too
2234            --  complicated, especially in the variant record case.
2235
2236            and then not Has_Discriminants (Rec)
2237
2238            --  We can implicitly pack if the specified size of the record is
2239            --  less than the sum of the object sizes (no point in packing if
2240            --  this is not the case).
2241
2242            and then RM_Size (Rec) < Scalar_Component_Total_Esize
2243
2244            --  And the total RM size cannot be greater than the specified size
2245            --  since otherwise packing will not get us where we have to be!
2246
2247            and then RM_Size (Rec) >= Scalar_Component_Total_RM_Size
2248
2249            --  Never do implicit packing in CodePeer or Alfa modes since
2250            --  we don't do any packing in these modes, since this generates
2251            --  over-complex code that confuses static analysis, and in
2252            --  general, neither CodePeer not GNATprove care about the
2253            --  internal representation of objects.
2254
2255            and then not (CodePeer_Mode or Alfa_Mode)
2256          then
2257             --  If implicit packing enabled, do it
2258
2259             if Implicit_Packing then
2260                Set_Is_Packed (Rec);
2261
2262                --  Otherwise flag the size clause
2263
2264             else
2265                declare
2266                   Sz : constant Node_Id := Size_Clause (Rec);
2267                begin
2268                   Error_Msg_NE -- CODEFIX
2269                     ("size given for& too small", Sz, Rec);
2270                   Error_Msg_N -- CODEFIX
2271                     ("\use explicit pragma Pack "
2272                      & "or use pragma Implicit_Packing", Sz);
2273                end;
2274             end if;
2275          end if;
2276       end Freeze_Record_Type;
2277
2278    --  Start of processing for Freeze_Entity
2279
2280    begin
2281       --  We are going to test for various reasons why this entity need not be
2282       --  frozen here, but in the case of an Itype that's defined within a
2283       --  record, that test actually applies to the record.
2284
2285       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2286          Test_E := Scope (E);
2287       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2288         and then Is_Record_Type (Underlying_Type (Scope (E)))
2289       then
2290          Test_E := Underlying_Type (Scope (E));
2291       end if;
2292
2293       --  Do not freeze if already frozen since we only need one freeze node
2294
2295       if Is_Frozen (E) then
2296          return No_List;
2297
2298       --  It is improper to freeze an external entity within a generic because
2299       --  its freeze node will appear in a non-valid context. The entity will
2300       --  be frozen in the proper scope after the current generic is analyzed.
2301
2302       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2303          return No_List;
2304
2305       --  AI05-0213: A formal incomplete type does not freeze the actual. In
2306       --  the instance, the same applies to the subtype renaming the actual.
2307
2308       elsif Is_Private_Type (E)
2309         and then Is_Generic_Actual_Type (E)
2310         and then No (Full_View (Base_Type (E)))
2311         and then Ada_Version >= Ada_2012
2312       then
2313          return No_List;
2314
2315       --  Do not freeze a global entity within an inner scope created during
2316       --  expansion. A call to subprogram E within some internal procedure
2317       --  (a stream attribute for example) might require freezing E, but the
2318       --  freeze node must appear in the same declarative part as E itself.
2319       --  The two-pass elaboration mechanism in gigi guarantees that E will
2320       --  be frozen before the inner call is elaborated. We exclude constants
2321       --  from this test, because deferred constants may be frozen early, and
2322       --  must be diagnosed (e.g. in the case of a deferred constant being used
2323       --  in a default expression). If the enclosing subprogram comes from
2324       --  source, or is a generic instance, then the freeze point is the one
2325       --  mandated by the language, and we freeze the entity. A subprogram that
2326       --  is a child unit body that acts as a spec does not have a spec that
2327       --  comes from source, but can only come from source.
2328
2329       elsif In_Open_Scopes (Scope (Test_E))
2330         and then Scope (Test_E) /= Current_Scope
2331         and then Ekind (Test_E) /= E_Constant
2332       then
2333          declare
2334             S : Entity_Id;
2335
2336          begin
2337             S := Current_Scope;
2338             while Present (S) loop
2339                if Is_Overloadable (S) then
2340                   if Comes_From_Source (S)
2341                     or else Is_Generic_Instance (S)
2342                     or else Is_Child_Unit (S)
2343                   then
2344                      exit;
2345                   else
2346                      return No_List;
2347                   end if;
2348                end if;
2349
2350                S := Scope (S);
2351             end loop;
2352          end;
2353
2354       --  Similarly, an inlined instance body may make reference to global
2355       --  entities, but these references cannot be the proper freezing point
2356       --  for them, and in the absence of inlining freezing will take place in
2357       --  their own scope. Normally instance bodies are analyzed after the
2358       --  enclosing compilation, and everything has been frozen at the proper
2359       --  place, but with front-end inlining an instance body is compiled
2360       --  before the end of the enclosing scope, and as a result out-of-order
2361       --  freezing must be prevented.
2362
2363       elsif Front_End_Inlining
2364         and then In_Instance_Body
2365         and then Present (Scope (Test_E))
2366       then
2367          declare
2368             S : Entity_Id;
2369
2370          begin
2371             S := Scope (Test_E);
2372             while Present (S) loop
2373                if Is_Generic_Instance (S) then
2374                   exit;
2375                else
2376                   S := Scope (S);
2377                end if;
2378             end loop;
2379
2380             if No (S) then
2381                return No_List;
2382             end if;
2383          end;
2384       end if;
2385
2386       --  Deal with delayed aspect specifications. The analysis of the aspect
2387       --  is required to be delayed to the freeze point, so we evaluate the
2388       --  pragma or attribute definition clause in the tree at this point.
2389
2390       if Has_Delayed_Aspects (E) then
2391          declare
2392             Ritem : Node_Id;
2393             Aitem : Node_Id;
2394
2395          begin
2396             --  Look for aspect specification entries for this entity
2397
2398             Ritem := First_Rep_Item (E);
2399             while Present (Ritem) loop
2400                if Nkind (Ritem) = N_Aspect_Specification
2401                  and then Entity (Ritem) = E
2402                  and then Is_Delayed_Aspect (Ritem)
2403                  and then Scope (E) = Current_Scope
2404                then
2405                   Aitem := Aspect_Rep_Item (Ritem);
2406
2407                   --  Skip if this is an aspect with no corresponding pragma
2408                   --  or attribute definition node (such as Default_Value).
2409
2410                   if Present (Aitem) then
2411                      Set_Parent (Aitem, Ritem);
2412                      Analyze (Aitem);
2413                   end if;
2414                end if;
2415
2416                Next_Rep_Item (Ritem);
2417             end loop;
2418          end;
2419       end if;
2420
2421       --  Here to freeze the entity
2422
2423       Set_Is_Frozen (E);
2424
2425       --  Case of entity being frozen is other than a type
2426
2427       if not Is_Type (E) then
2428
2429          --  If entity is exported or imported and does not have an external
2430          --  name, now is the time to provide the appropriate default name.
2431          --  Skip this if the entity is stubbed, since we don't need a name
2432          --  for any stubbed routine. For the case on intrinsics, if no
2433          --  external name is specified, then calls will be handled in
2434          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2435          --  external name is provided, then Expand_Intrinsic_Call leaves
2436          --  calls in place for expansion by GIGI.
2437
2438          if (Is_Imported (E) or else Is_Exported (E))
2439            and then No (Interface_Name (E))
2440            and then Convention (E) /= Convention_Stubbed
2441            and then Convention (E) /= Convention_Intrinsic
2442          then
2443             Set_Encoded_Interface_Name
2444               (E, Get_Default_External_Name (E));
2445
2446          --  If entity is an atomic object appearing in a declaration and
2447          --  the expression is an aggregate, assign it to a temporary to
2448          --  ensure that the actual assignment is done atomically rather
2449          --  than component-wise (the assignment to the temp may be done
2450          --  component-wise, but that is harmless).
2451
2452          elsif Is_Atomic (E)
2453            and then Nkind (Parent (E)) = N_Object_Declaration
2454            and then Present (Expression (Parent (E)))
2455            and then Nkind (Expression (Parent (E))) = N_Aggregate
2456            and then Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2457          then
2458             null;
2459          end if;
2460
2461          --  For a subprogram, freeze all parameter types and also the return
2462          --  type (RM 13.14(14)). However skip this for internal subprograms.
2463          --  This is also the point where any extra formal parameters are
2464          --  created since we now know whether the subprogram will use a
2465          --  foreign convention.
2466
2467          if Is_Subprogram (E) then
2468             if not Is_Internal (E) then
2469                declare
2470                   F_Type    : Entity_Id;
2471                   R_Type    : Entity_Id;
2472                   Warn_Node : Node_Id;
2473
2474                begin
2475                   --  Loop through formals
2476
2477                   Formal := First_Formal (E);
2478                   while Present (Formal) loop
2479                      F_Type := Etype (Formal);
2480
2481                      --  AI05-0151 : incomplete types can appear in a profile.
2482                      --  By the time the entity is frozen, the full view must
2483                      --  be available, unless it is a limited view.
2484
2485                      if Is_Incomplete_Type (F_Type)
2486                        and then Present (Full_View (F_Type))
2487                      then
2488                         F_Type := Full_View (F_Type);
2489                         Set_Etype (Formal, F_Type);
2490                      end if;
2491
2492                      Freeze_And_Append (F_Type, N, Result);
2493
2494                      if Is_Private_Type (F_Type)
2495                        and then Is_Private_Type (Base_Type (F_Type))
2496                        and then No (Full_View (Base_Type (F_Type)))
2497                        and then not Is_Generic_Type (F_Type)
2498                        and then not Is_Derived_Type (F_Type)
2499                      then
2500                         --  If the type of a formal is incomplete, subprogram
2501                         --  is being frozen prematurely. Within an instance
2502                         --  (but not within a wrapper package) this is an
2503                         --  artifact of our need to regard the end of an
2504                         --  instantiation as a freeze point. Otherwise it is
2505                         --  a definite error.
2506
2507                         if In_Instance then
2508                            Set_Is_Frozen (E, False);
2509                            return No_List;
2510
2511                         elsif not After_Last_Declaration
2512                           and then not Freezing_Library_Level_Tagged_Type
2513                         then
2514                            Error_Msg_Node_1 := F_Type;
2515                            Error_Msg
2516                              ("type& must be fully defined before this point",
2517                                Loc);
2518                         end if;
2519                      end if;
2520
2521                      --  Check suspicious parameter for C function. These tests
2522                      --  apply only to exported/imported subprograms.
2523
2524                      if Warn_On_Export_Import
2525                        and then Comes_From_Source (E)
2526                        and then (Convention (E) = Convention_C
2527                                    or else
2528                                  Convention (E) = Convention_CPP)
2529                        and then (Is_Imported (E) or else Is_Exported (E))
2530                        and then Convention (E) /= Convention (Formal)
2531                        and then not Has_Warnings_Off (E)
2532                        and then not Has_Warnings_Off (F_Type)
2533                        and then not Has_Warnings_Off (Formal)
2534                      then
2535                         --  Qualify mention of formals with subprogram name
2536
2537                         Error_Msg_Qual_Level := 1;
2538
2539                         --  Check suspicious use of fat C pointer
2540
2541                         if Is_Access_Type (F_Type)
2542                           and then Esize (F_Type) > Ttypes.System_Address_Size
2543                         then
2544                            Error_Msg_N
2545                              ("?type of & does not correspond to C pointer!",
2546                               Formal);
2547
2548                         --  Check suspicious return of boolean
2549
2550                         elsif Root_Type (F_Type) = Standard_Boolean
2551                           and then Convention (F_Type) = Convention_Ada
2552                           and then not Has_Warnings_Off (F_Type)
2553                           and then not Has_Size_Clause (F_Type)
2554                           and then VM_Target = No_VM
2555                         then
2556                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2557                            Error_Msg_N
2558                              ("\use appropriate corresponding type in C "
2559                               & "(e.g. char)?", Formal);
2560
2561                         --  Check suspicious tagged type
2562
2563                         elsif (Is_Tagged_Type (F_Type)
2564                                 or else (Is_Access_Type (F_Type)
2565                                            and then
2566                                              Is_Tagged_Type
2567                                                (Designated_Type (F_Type))))
2568                           and then Convention (E) = Convention_C
2569                         then
2570                            Error_Msg_N
2571                              ("?& involves a tagged type which does not "
2572                               & "correspond to any C type!", Formal);
2573
2574                         --  Check wrong convention subprogram pointer
2575
2576                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2577                           and then not Has_Foreign_Convention (F_Type)
2578                         then
2579                            Error_Msg_N
2580                              ("?subprogram pointer & should "
2581                               & "have foreign convention!", Formal);
2582                            Error_Msg_Sloc := Sloc (F_Type);
2583                            Error_Msg_NE
2584                              ("\?add Convention pragma to declaration of &#",
2585                               Formal, F_Type);
2586                         end if;
2587
2588                         --  Turn off name qualification after message output
2589
2590                         Error_Msg_Qual_Level := 0;
2591                      end if;
2592
2593                      --  Check for unconstrained array in exported foreign
2594                      --  convention case.
2595
2596                      if Has_Foreign_Convention (E)
2597                        and then not Is_Imported (E)
2598                        and then Is_Array_Type (F_Type)
2599                        and then not Is_Constrained (F_Type)
2600                        and then Warn_On_Export_Import
2601
2602                        --  Exclude VM case, since both .NET and JVM can handle
2603                        --  unconstrained arrays without a problem.
2604
2605                        and then VM_Target = No_VM
2606                      then
2607                         Error_Msg_Qual_Level := 1;
2608
2609                         --  If this is an inherited operation, place the
2610                         --  warning on the derived type declaration, rather
2611                         --  than on the original subprogram.
2612
2613                         if Nkind (Original_Node (Parent (E))) =
2614                           N_Full_Type_Declaration
2615                         then
2616                            Warn_Node := Parent (E);
2617
2618                            if Formal = First_Formal (E) then
2619                               Error_Msg_NE
2620                                 ("?in inherited operation&", Warn_Node, E);
2621                            end if;
2622                         else
2623                            Warn_Node := Formal;
2624                         end if;
2625
2626                         Error_Msg_NE
2627                           ("?type of argument& is unconstrained array",
2628                            Warn_Node, Formal);
2629                         Error_Msg_NE
2630                           ("?foreign caller must pass bounds explicitly",
2631                            Warn_Node, Formal);
2632                         Error_Msg_Qual_Level := 0;
2633                      end if;
2634
2635                      if not From_With_Type (F_Type) then
2636                         if Is_Access_Type (F_Type) then
2637                            F_Type := Designated_Type (F_Type);
2638                         end if;
2639
2640                         --  If the formal is an anonymous_access_to_subprogram
2641                         --  freeze the  subprogram type as well, to prevent
2642                         --  scope anomalies in gigi, because there is no other
2643                         --  clear point at which it could be frozen.
2644
2645                         if Is_Itype (Etype (Formal))
2646                           and then Ekind (F_Type) = E_Subprogram_Type
2647                         then
2648                            Freeze_And_Append (F_Type, N, Result);
2649                         end if;
2650                      end if;
2651
2652                      Next_Formal (Formal);
2653                   end loop;
2654
2655                   --  Case of function: similar checks on return type
2656
2657                   if Ekind (E) = E_Function then
2658
2659                      --  Freeze return type
2660
2661                      R_Type := Etype (E);
2662
2663                      --  AI05-0151: the return type may have been incomplete
2664                      --  at the point of declaration.
2665
2666                      if Ekind (R_Type) = E_Incomplete_Type
2667                        and then Present (Full_View (R_Type))
2668                      then
2669                         R_Type := Full_View (R_Type);
2670                         Set_Etype (E, R_Type);
2671                      end if;
2672
2673                      Freeze_And_Append (R_Type, N, Result);
2674
2675                      --  Check suspicious return type for C function
2676
2677                      if Warn_On_Export_Import
2678                        and then (Convention (E) = Convention_C
2679                                    or else
2680                                  Convention (E) = Convention_CPP)
2681                        and then (Is_Imported (E) or else Is_Exported (E))
2682                      then
2683                         --  Check suspicious return of fat C pointer
2684
2685                         if Is_Access_Type (R_Type)
2686                           and then Esize (R_Type) > Ttypes.System_Address_Size
2687                           and then not Has_Warnings_Off (E)
2688                           and then not Has_Warnings_Off (R_Type)
2689                         then
2690                            Error_Msg_N
2691                              ("?return type of& does not "
2692                               & "correspond to C pointer!", E);
2693
2694                         --  Check suspicious return of boolean
2695
2696                         elsif Root_Type (R_Type) = Standard_Boolean
2697                           and then Convention (R_Type) = Convention_Ada
2698                           and then VM_Target = No_VM
2699                           and then not Has_Warnings_Off (E)
2700                           and then not Has_Warnings_Off (R_Type)
2701                           and then not Has_Size_Clause (R_Type)
2702                         then
2703                            declare
2704                               N : constant Node_Id :=
2705                                     Result_Definition (Declaration_Node (E));
2706                            begin
2707                               Error_Msg_NE
2708                                 ("return type of & is an 8-bit Ada Boolean?",
2709                                  N, E);
2710                               Error_Msg_NE
2711                                 ("\use appropriate corresponding type in C "
2712                                  & "(e.g. char)?", N, E);
2713                            end;
2714
2715                         --  Check suspicious return tagged type
2716
2717                         elsif (Is_Tagged_Type (R_Type)
2718                                 or else (Is_Access_Type (R_Type)
2719                                            and then
2720                                              Is_Tagged_Type
2721                                                (Designated_Type (R_Type))))
2722                           and then Convention (E) = Convention_C
2723                           and then not Has_Warnings_Off (E)
2724                           and then not Has_Warnings_Off (R_Type)
2725                         then
2726                            Error_Msg_N
2727                              ("?return type of & does not "
2728                               & "correspond to C type!", E);
2729
2730                         --  Check return of wrong convention subprogram pointer
2731
2732                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2733                           and then not Has_Foreign_Convention (R_Type)
2734                           and then not Has_Warnings_Off (E)
2735                           and then not Has_Warnings_Off (R_Type)
2736                         then
2737                            Error_Msg_N
2738                              ("?& should return a foreign "
2739                               & "convention subprogram pointer", E);
2740                            Error_Msg_Sloc := Sloc (R_Type);
2741                            Error_Msg_NE
2742                              ("\?add Convention pragma to declaration of& #",
2743                               E, R_Type);
2744                         end if;
2745                      end if;
2746
2747                      --  Give warning for suspicious return of a result of an
2748                      --  unconstrained array type in a foreign convention
2749                      --  function.
2750
2751                      if Has_Foreign_Convention (E)
2752
2753                        --  We are looking for a return of unconstrained array
2754
2755                        and then Is_Array_Type (R_Type)
2756                        and then not Is_Constrained (R_Type)
2757
2758                        --  Exclude imported routines, the warning does not
2759                        --  belong on the import, but rather on the routine
2760                        --  definition.
2761
2762                        and then not Is_Imported (E)
2763
2764                        --  Exclude VM case, since both .NET and JVM can handle
2765                        --  return of unconstrained arrays without a problem.
2766
2767                        and then VM_Target = No_VM
2768
2769                        --  Check that general warning is enabled, and that it
2770                        --  is not suppressed for this particular case.
2771
2772                        and then Warn_On_Export_Import
2773                        and then not Has_Warnings_Off (E)
2774                        and then not Has_Warnings_Off (R_Type)
2775                      then
2776                         Error_Msg_N
2777                           ("?foreign convention function& should not " &
2778                            "return unconstrained array!", E);
2779                      end if;
2780                   end if;
2781                end;
2782             end if;
2783
2784             --  Must freeze its parent first if it is a derived subprogram
2785
2786             if Present (Alias (E)) then
2787                Freeze_And_Append (Alias (E), N, Result);
2788             end if;
2789
2790             --  We don't freeze internal subprograms, because we don't normally
2791             --  want addition of extra formals or mechanism setting to happen
2792             --  for those. However we do pass through predefined dispatching
2793             --  cases, since extra formals may be needed in some cases, such as
2794             --  for the stream 'Input function (build-in-place formals).
2795
2796             if not Is_Internal (E)
2797               or else Is_Predefined_Dispatching_Operation (E)
2798             then
2799                Freeze_Subprogram (E);
2800             end if;
2801
2802          --  Here for other than a subprogram or type
2803
2804          else
2805             --  If entity has a type, and it is not a generic unit, then
2806             --  freeze it first (RM 13.14(10)).
2807
2808             if Present (Etype (E))
2809               and then Ekind (E) /= E_Generic_Function
2810             then
2811                Freeze_And_Append (Etype (E), N, Result);
2812             end if;
2813
2814             --  Special processing for objects created by object declaration
2815
2816             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2817
2818                --  Abstract type allowed only for C++ imported variables or
2819                --  constants.
2820
2821                --  Note: we inhibit this check for objects that do not come
2822                --  from source because there is at least one case (the
2823                --  expansion of x'Class'Input where x is abstract) where we
2824                --  legitimately generate an abstract object.
2825
2826                if Is_Abstract_Type (Etype (E))
2827                  and then Comes_From_Source (Parent (E))
2828                  and then not (Is_Imported (E)
2829                                  and then Is_CPP_Class (Etype (E)))
2830                then
2831                   Error_Msg_N ("type of object cannot be abstract",
2832                                Object_Definition (Parent (E)));
2833
2834                   if Is_CPP_Class (Etype (E)) then
2835                      Error_Msg_NE
2836                        ("\} may need a cpp_constructor",
2837                        Object_Definition (Parent (E)), Etype (E));
2838                   end if;
2839                end if;
2840
2841                --  For object created by object declaration, perform required
2842                --  categorization (preelaborate and pure) checks. Defer these
2843                --  checks to freeze time since pragma Import inhibits default
2844                --  initialization and thus pragma Import affects these checks.
2845
2846                Validate_Object_Declaration (Declaration_Node (E));
2847
2848                --  If there is an address clause, check that it is valid
2849
2850                Check_Address_Clause (E);
2851
2852                --  If the object needs any kind of default initialization, an
2853                --  error must be issued if No_Default_Initialization applies.
2854                --  The check doesn't apply to imported objects, which are not
2855                --  ever default initialized, and is why the check is deferred
2856                --  until freezing, at which point we know if Import applies.
2857                --  Deferred constants are also exempted from this test because
2858                --  their completion is explicit, or through an import pragma.
2859
2860                if Ekind (E) = E_Constant
2861                  and then Present (Full_View (E))
2862                then
2863                   null;
2864
2865                elsif Comes_From_Source (E)
2866                  and then not Is_Imported (E)
2867                  and then not Has_Init_Expression (Declaration_Node (E))
2868                  and then
2869                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2870                       and then not No_Initialization (Declaration_Node (E))
2871                       and then not Is_Value_Type (Etype (E))
2872                       and then not Initialization_Suppressed (Etype (E)))
2873                     or else
2874                       (Needs_Simple_Initialization (Etype (E))
2875                         and then not Is_Internal (E)))
2876                then
2877                   Has_Default_Initialization := True;
2878                   Check_Restriction
2879                     (No_Default_Initialization, Declaration_Node (E));
2880                end if;
2881
2882                --  Check that a Thread_Local_Storage variable does not have
2883                --  default initialization, and any explicit initialization must
2884                --  either be the null constant or a static constant.
2885
2886                if Has_Pragma_Thread_Local_Storage (E) then
2887                   declare
2888                      Decl : constant Node_Id := Declaration_Node (E);
2889                   begin
2890                      if Has_Default_Initialization
2891                        or else
2892                          (Has_Init_Expression (Decl)
2893                             and then
2894                              (No (Expression (Decl))
2895                                 or else not
2896                                   (Is_Static_Expression (Expression (Decl))
2897                                      or else
2898                                    Nkind (Expression (Decl)) = N_Null)))
2899                      then
2900                         Error_Msg_NE
2901                           ("Thread_Local_Storage variable& is "
2902                            & "improperly initialized", Decl, E);
2903                         Error_Msg_NE
2904                           ("\only allowed initialization is explicit "
2905                            & "NULL or static expression", Decl, E);
2906                      end if;
2907                   end;
2908                end if;
2909
2910                --  For imported objects, set Is_Public unless there is also an
2911                --  address clause, which means that there is no external symbol
2912                --  needed for the Import (Is_Public may still be set for other
2913                --  unrelated reasons). Note that we delayed this processing
2914                --  till freeze time so that we can be sure not to set the flag
2915                --  if there is an address clause. If there is such a clause,
2916                --  then the only purpose of the Import pragma is to suppress
2917                --  implicit initialization.
2918
2919                if Is_Imported (E)
2920                  and then No (Address_Clause (E))
2921                then
2922                   Set_Is_Public (E);
2923                end if;
2924
2925                --  For convention C objects of an enumeration type, warn if
2926                --  the size is not integer size and no explicit size given.
2927                --  Skip warning for Boolean, and Character, assume programmer
2928                --  expects 8-bit sizes for these cases.
2929
2930                if (Convention (E) = Convention_C
2931                     or else
2932                    Convention (E) = Convention_CPP)
2933                  and then Is_Enumeration_Type (Etype (E))
2934                  and then not Is_Character_Type (Etype (E))
2935                  and then not Is_Boolean_Type (Etype (E))
2936                  and then Esize (Etype (E)) < Standard_Integer_Size
2937                  and then not Has_Size_Clause (E)
2938                then
2939                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2940                   Error_Msg_N
2941                     ("?convention C enumeration object has size less than ^",
2942                      E);
2943                   Error_Msg_N ("\?use explicit size clause to set size", E);
2944                end if;
2945             end if;
2946
2947             --  Check that a constant which has a pragma Volatile[_Components]
2948             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2949
2950             --  Note: Atomic[_Components] also sets Volatile[_Components]
2951
2952             if Ekind (E) = E_Constant
2953               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2954               and then not Is_Imported (E)
2955             then
2956                --  Make sure we actually have a pragma, and have not merely
2957                --  inherited the indication from elsewhere (e.g. an address
2958                --  clause, which is not good enough in RM terms!)
2959
2960                if Has_Rep_Pragma (E, Name_Atomic)
2961                     or else
2962                   Has_Rep_Pragma (E, Name_Atomic_Components)
2963                then
2964                   Error_Msg_N
2965                     ("stand alone atomic constant must be " &
2966                      "imported (RM C.6(13))", E);
2967
2968                elsif Has_Rep_Pragma (E, Name_Volatile)
2969                        or else
2970                      Has_Rep_Pragma (E, Name_Volatile_Components)
2971                then
2972                   Error_Msg_N
2973                     ("stand alone volatile constant must be " &
2974                      "imported (RM C.6(13))", E);
2975                end if;
2976             end if;
2977
2978             --  Static objects require special handling
2979
2980             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2981               and then Is_Statically_Allocated (E)
2982             then
2983                Freeze_Static_Object (E);
2984             end if;
2985
2986             --  Remaining step is to layout objects
2987
2988             if Ekind (E) = E_Variable
2989                  or else
2990                Ekind (E) = E_Constant
2991                  or else
2992                Ekind (E) = E_Loop_Parameter
2993                  or else
2994                Is_Formal (E)
2995             then
2996                Layout_Object (E);
2997             end if;
2998          end if;
2999
3000       --  Case of a type or subtype being frozen
3001
3002       else
3003          --  We used to check here that a full type must have preelaborable
3004          --  initialization if it completes a private type specified with
3005          --  pragma Preelaborable_Initialization, but that missed cases where
3006          --  the types occur within a generic package, since the freezing
3007          --  that occurs within a containing scope generally skips traversal
3008          --  of a generic unit's declarations (those will be frozen within
3009          --  instances). This check was moved to Analyze_Package_Specification.
3010
3011          --  The type may be defined in a generic unit. This can occur when
3012          --  freezing a generic function that returns the type (which is
3013          --  defined in a parent unit). It is clearly meaningless to freeze
3014          --  this type. However, if it is a subtype, its size may be determi-
3015          --  nable and used in subsequent checks, so might as well try to
3016          --  compute it.
3017
3018          if Present (Scope (E))
3019            and then Is_Generic_Unit (Scope (E))
3020          then
3021             Check_Compile_Time_Size (E);
3022             return No_List;
3023          end if;
3024
3025          --  Deal with special cases of freezing for subtype
3026
3027          if E /= Base_Type (E) then
3028
3029             --  Before we do anything else, a specialized test for the case of
3030             --  a size given for an array where the array needs to be packed,
3031             --  but was not so the size cannot be honored. This would of course
3032             --  be caught by the backend, and indeed we don't catch all cases.
3033             --  The point is that we can give a better error message in those
3034             --  cases that we do catch with the circuitry here. Also if pragma
3035             --  Implicit_Packing is set, this is where the packing occurs.
3036
3037             --  The reason we do this so early is that the processing in the
3038             --  automatic packing case affects the layout of the base type, so
3039             --  it must be done before we freeze the base type.
3040
3041             if Is_Array_Type (E) then
3042                declare
3043                   Lo, Hi : Node_Id;
3044                   Ctyp   : constant Entity_Id := Component_Type (E);
3045
3046                begin
3047                   --  Check enabling conditions. These are straightforward
3048                   --  except for the test for a limited composite type. This
3049                   --  eliminates the rare case of a array of limited components
3050                   --  where there are issues of whether or not we can go ahead
3051                   --  and pack the array (since we can't freely pack and unpack
3052                   --  arrays if they are limited).
3053
3054                   --  Note that we check the root type explicitly because the
3055                   --  whole point is we are doing this test before we have had
3056                   --  a chance to freeze the base type (and it is that freeze
3057                   --  action that causes stuff to be inherited).
3058
3059                   if Present (Size_Clause (E))
3060                     and then Known_Static_RM_Size (E)
3061                     and then not Is_Packed (E)
3062                     and then not Has_Pragma_Pack (E)
3063                     and then Number_Dimensions (E) = 1
3064                     and then not Has_Component_Size_Clause (E)
3065                     and then Known_Static_RM_Size (Ctyp)
3066                     and then not Is_Limited_Composite (E)
3067                     and then not Is_Packed (Root_Type (E))
3068                     and then not Has_Component_Size_Clause (Root_Type (E))
3069                     and then not (CodePeer_Mode or Alfa_Mode)
3070                   then
3071                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3072
3073                      if Compile_Time_Known_Value (Lo)
3074                        and then Compile_Time_Known_Value (Hi)
3075                        and then Known_Static_RM_Size (Ctyp)
3076                        and then RM_Size (Ctyp) < 64
3077                      then
3078                         declare
3079                            Lov  : constant Uint      := Expr_Value (Lo);
3080                            Hiv  : constant Uint      := Expr_Value (Hi);
3081                            Len  : constant Uint      := UI_Max
3082                                                          (Uint_0,
3083                                                           Hiv - Lov + 1);
3084                            Rsiz : constant Uint      := RM_Size (Ctyp);
3085                            SZ   : constant Node_Id   := Size_Clause (E);
3086                            Btyp : constant Entity_Id := Base_Type (E);
3087
3088                         --  What we are looking for here is the situation where
3089                         --  the RM_Size given would be exactly right if there
3090                         --  was a pragma Pack (resulting in the component size
3091                         --  being the same as the RM_Size). Furthermore, the
3092                         --  component type size must be an odd size (not a
3093                         --  multiple of storage unit). If the component RM size
3094                         --  is an exact number of storage units that is a power
3095                         --  of two, the array is not packed and has a standard
3096                         --  representation.
3097
3098                         begin
3099                            if RM_Size (E) = Len * Rsiz
3100                              and then Rsiz mod System_Storage_Unit /= 0
3101                            then
3102                               --  For implicit packing mode, just set the
3103                               --  component size silently.
3104
3105                               if Implicit_Packing then
3106                                  Set_Component_Size       (Btyp, Rsiz);
3107                                  Set_Is_Bit_Packed_Array  (Btyp);
3108                                  Set_Is_Packed            (Btyp);
3109                                  Set_Has_Non_Standard_Rep (Btyp);
3110
3111                                  --  Otherwise give an error message
3112
3113                               else
3114                                  Error_Msg_NE
3115                                    ("size given for& too small", SZ, E);
3116                                  Error_Msg_N -- CODEFIX
3117                                    ("\use explicit pragma Pack "
3118                                     & "or use pragma Implicit_Packing", SZ);
3119                               end if;
3120
3121                            elsif RM_Size (E) = Len * Rsiz
3122                              and then Implicit_Packing
3123                              and then
3124                                (Rsiz / System_Storage_Unit = 1
3125                                  or else Rsiz / System_Storage_Unit = 2
3126                                  or else Rsiz / System_Storage_Unit = 4)
3127                            then
3128
3129                               --  Not a packed array, but indicate the desired
3130                               --  component size, for the back-end.
3131
3132                               Set_Component_Size (Btyp, Rsiz);
3133                            end if;
3134                         end;
3135                      end if;
3136                   end if;
3137                end;
3138             end if;
3139
3140             --  If ancestor subtype present, freeze that first. Note that this
3141             --  will also get the base type frozen. Need RM reference ???
3142
3143             Atype := Ancestor_Subtype (E);
3144
3145             if Present (Atype) then
3146                Freeze_And_Append (Atype, N, Result);
3147
3148             --  No ancestor subtype present
3149
3150             else
3151                --  See if we have a nearest ancestor that has a predicate.
3152                --  That catches the case of derived type with a predicate.
3153                --  Need RM reference here ???
3154
3155                Atype := Nearest_Ancestor (E);
3156
3157                if Present (Atype) and then Has_Predicates (Atype) then
3158                   Freeze_And_Append (Atype, N, Result);
3159                end if;
3160
3161                --  Freeze base type before freezing the entity (RM 13.14(15))
3162
3163                if E /= Base_Type (E) then
3164                   Freeze_And_Append (Base_Type (E), N, Result);
3165                end if;
3166             end if;
3167
3168          --  For a derived type, freeze its parent type first (RM 13.14(15))
3169
3170          elsif Is_Derived_Type (E) then
3171             Freeze_And_Append (Etype (E), N, Result);
3172             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3173          end if;
3174
3175          --  For array type, freeze index types and component type first
3176          --  before freezing the array (RM 13.14(15)).
3177
3178          if Is_Array_Type (E) then
3179             declare
3180                FS     : constant Entity_Id := First_Subtype (E);
3181                Ctyp   : constant Entity_Id := Component_Type (E);
3182                Clause : Entity_Id;
3183
3184                Non_Standard_Enum : Boolean := False;
3185                --  Set true if any of the index types is an enumeration type
3186                --  with a non-standard representation.
3187
3188             begin
3189                Freeze_And_Append (Ctyp, N, Result);
3190
3191                Indx := First_Index (E);
3192                while Present (Indx) loop
3193                   Freeze_And_Append (Etype (Indx), N, Result);
3194
3195                   if Is_Enumeration_Type (Etype (Indx))
3196                     and then Has_Non_Standard_Rep (Etype (Indx))
3197                   then
3198                      Non_Standard_Enum := True;
3199                   end if;
3200
3201                   Next_Index (Indx);
3202                end loop;
3203
3204                --  Processing that is done only for base types
3205
3206                if Ekind (E) = E_Array_Type then
3207
3208                   --  Propagate flags for component type
3209
3210                   if Is_Controlled (Component_Type (E))
3211                     or else Has_Controlled_Component (Ctyp)
3212                   then
3213                      Set_Has_Controlled_Component (E);
3214                   end if;
3215
3216                   if Has_Unchecked_Union (Component_Type (E)) then
3217                      Set_Has_Unchecked_Union (E);
3218                   end if;
3219
3220                   --  If packing was requested or if the component size was set
3221                   --  explicitly, then see if bit packing is required. This
3222                   --  processing is only done for base types, since all the
3223                   --  representation aspects involved are type-related. This
3224                   --  is not just an optimization, if we start processing the
3225                   --  subtypes, they interfere with the settings on the base
3226                   --  type (this is because Is_Packed has a slightly different
3227                   --  meaning before and after freezing).
3228
3229                   declare
3230                      Csiz : Uint;
3231                      Esiz : Uint;
3232
3233                   begin
3234                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3235                        and then Known_Static_RM_Size (Ctyp)
3236                        and then not Has_Component_Size_Clause (E)
3237                      then
3238                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3239
3240                      elsif Known_Component_Size (E) then
3241                         Csiz := Component_Size (E);
3242
3243                      elsif not Known_Static_Esize (Ctyp) then
3244                         Csiz := Uint_0;
3245
3246                      else
3247                         Esiz := Esize (Ctyp);
3248
3249                         --  We can set the component size if it is less than
3250                         --  16, rounding it up to the next storage unit size.
3251
3252                         if Esiz <= 8 then
3253                            Csiz := Uint_8;
3254                         elsif Esiz <= 16 then
3255                            Csiz := Uint_16;
3256                         else
3257                            Csiz := Uint_0;
3258                         end if;
3259
3260                         --  Set component size up to match alignment if it
3261                         --  would otherwise be less than the alignment. This
3262                         --  deals with cases of types whose alignment exceeds
3263                         --  their size (padded types).
3264
3265                         if Csiz /= 0 then
3266                            declare
3267                               A : constant Uint := Alignment_In_Bits (Ctyp);
3268                            begin
3269                               if Csiz < A then
3270                                  Csiz := A;
3271                               end if;
3272                            end;
3273                         end if;
3274                      end if;
3275
3276                      --  Case of component size that may result in packing
3277
3278                      if 1 <= Csiz and then Csiz <= 64 then
3279                         declare
3280                            Ent         : constant Entity_Id :=
3281                                            First_Subtype (E);
3282                            Pack_Pragma : constant Node_Id :=
3283                                            Get_Rep_Pragma (Ent, Name_Pack);
3284                            Comp_Size_C : constant Node_Id :=
3285                                            Get_Attribute_Definition_Clause
3286                                              (Ent, Attribute_Component_Size);
3287                         begin
3288                            --  Warn if we have pack and component size so that
3289                            --  the pack is ignored.
3290
3291                            --  Note: here we must check for the presence of a
3292                            --  component size before checking for a Pack pragma
3293                            --  to deal with the case where the array type is a
3294                            --  derived type whose parent is currently private.
3295
3296                            if Present (Comp_Size_C)
3297                              and then Has_Pragma_Pack (Ent)
3298                              and then Warn_On_Redundant_Constructs
3299                            then
3300                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3301                               Error_Msg_NE
3302                                 ("?pragma Pack for& ignored!",
3303                                  Pack_Pragma, Ent);
3304                               Error_Msg_N
3305                                 ("\?explicit component size given#!",
3306                                  Pack_Pragma);
3307                               Set_Is_Packed (Base_Type (Ent), False);
3308                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3309                            end if;
3310
3311                            --  Set component size if not already set by a
3312                            --  component size clause.
3313
3314                            if not Present (Comp_Size_C) then
3315                               Set_Component_Size (E, Csiz);
3316                            end if;
3317
3318                            --  Check for base type of 8, 16, 32 bits, where an
3319                            --  unsigned subtype has a length one less than the
3320                            --  base type (e.g. Natural subtype of Integer).
3321
3322                            --  In such cases, if a component size was not set
3323                            --  explicitly, then generate a warning.
3324
3325                            if Has_Pragma_Pack (E)
3326                              and then not Present (Comp_Size_C)
3327                              and then
3328                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3329                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3330                            then
3331                               Error_Msg_Uint_1 := Csiz;
3332
3333                               if Present (Pack_Pragma) then
3334                                  Error_Msg_N
3335                                    ("?pragma Pack causes component size "
3336                                     & "to be ^!", Pack_Pragma);
3337                                  Error_Msg_N
3338                                    ("\?use Component_Size to set "
3339                                     & "desired value!", Pack_Pragma);
3340                               end if;
3341                            end if;
3342
3343                            --  Actual packing is not needed for 8, 16, 32, 64.
3344                            --  Also not needed for 24 if alignment is 1.
3345
3346                            if        Csiz = 8
3347                              or else Csiz = 16
3348                              or else Csiz = 32
3349                              or else Csiz = 64
3350                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3351                            then
3352                               --  Here the array was requested to be packed,
3353                               --  but the packing request had no effect, so
3354                               --  Is_Packed is reset.
3355
3356                               --  Note: semantically this means that we lose
3357                               --  track of the fact that a derived type
3358                               --  inherited a pragma Pack that was non-
3359                               --  effective, but that seems fine.
3360
3361                               --  We regard a Pack pragma as a request to set
3362                               --  a representation characteristic, and this
3363                               --  request may be ignored.
3364
3365                               Set_Is_Packed           (Base_Type (E), False);
3366                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3367
3368                               if Known_Static_Esize (Component_Type (E))
3369                                 and then Esize (Component_Type (E)) = Csiz
3370                               then
3371                                  Set_Has_Non_Standard_Rep
3372                                    (Base_Type (E), False);
3373                               end if;
3374
3375                            --  In all other cases, packing is indeed needed
3376
3377                            else
3378                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3379                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3380                               Set_Is_Packed            (Base_Type (E), True);
3381                            end if;
3382                         end;
3383                      end if;
3384                   end;
3385
3386                   --  Check for Atomic_Components or Aliased with unsuitable
3387                   --  packing or explicit component size clause given.
3388
3389                   if (Has_Atomic_Components (E)
3390                        or else Has_Aliased_Components (E))
3391                     and then (Has_Component_Size_Clause (E)
3392                                or else Is_Packed (E))
3393                   then
3394                      Alias_Atomic_Check : declare
3395
3396                         procedure Complain_CS (T : String);
3397                         --  Outputs error messages for incorrect CS clause or
3398                         --  pragma Pack for aliased or atomic components (T is
3399                         --  "aliased" or "atomic");
3400
3401                         -----------------
3402                         -- Complain_CS --
3403                         -----------------
3404
3405                         procedure Complain_CS (T : String) is
3406                         begin
3407                            if Has_Component_Size_Clause (E) then
3408                               Clause :=
3409                                 Get_Attribute_Definition_Clause
3410                                   (FS, Attribute_Component_Size);
3411
3412                               if Known_Static_Esize (Ctyp) then
3413                                  Error_Msg_N
3414                                    ("incorrect component size for "
3415                                     & T & " components", Clause);
3416                                  Error_Msg_Uint_1 := Esize (Ctyp);
3417                                  Error_Msg_N
3418                                    ("\only allowed value is^", Clause);
3419
3420                               else
3421                                  Error_Msg_N
3422                                    ("component size cannot be given for "
3423                                     & T & " components", Clause);
3424                               end if;
3425
3426                            else
3427                               Error_Msg_N
3428                                 ("cannot pack " & T & " components",
3429                                  Get_Rep_Pragma (FS, Name_Pack));
3430                            end if;
3431
3432                            return;
3433                         end Complain_CS;
3434
3435                      --  Start of processing for Alias_Atomic_Check
3436
3437                      begin
3438
3439                         --  If object size of component type isn't known, we
3440                         --  cannot be sure so we defer to the back end.
3441
3442                         if not Known_Static_Esize (Ctyp) then
3443                            null;
3444
3445                         --  Case where component size has no effect. First
3446                         --  check for object size of component type multiple
3447                         --  of the storage unit size.
3448
3449                         elsif Esize (Ctyp) mod System_Storage_Unit = 0
3450
3451                           --  OK in both packing case and component size case
3452                           --  if RM size is known and static and the same as
3453                           --  the object size.
3454
3455                           and then
3456                             ((Known_Static_RM_Size (Ctyp)
3457                                and then Esize (Ctyp) = RM_Size (Ctyp))
3458
3459                              --  Or if we have an explicit component size
3460                              --  clause and the component size and object size
3461                              --  are equal.
3462
3463                              or else
3464                                  (Has_Component_Size_Clause (E)
3465                                  and then Component_Size (E) = Esize (Ctyp)))
3466                         then
3467                            null;
3468
3469                         elsif Has_Aliased_Components (E)
3470                           or else Is_Aliased (Ctyp)
3471                         then
3472                            Complain_CS ("aliased");
3473
3474                         elsif Has_Atomic_Components (E)
3475                           or else Is_Atomic (Ctyp)
3476                         then
3477                            Complain_CS ("atomic");
3478                         end if;
3479                      end Alias_Atomic_Check;
3480                   end if;
3481
3482                   --  Warn for case of atomic type
3483
3484                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3485
3486                   if Present (Clause)
3487                     and then not Addressable (Component_Size (FS))
3488                   then
3489                      Error_Msg_NE
3490                        ("non-atomic components of type& may not be "
3491                         & "accessible by separate tasks?", Clause, E);
3492
3493                      if Has_Component_Size_Clause (E) then
3494                         Error_Msg_Sloc :=
3495                           Sloc
3496                             (Get_Attribute_Definition_Clause
3497                                  (FS, Attribute_Component_Size));
3498                         Error_Msg_N
3499                           ("\because of component size clause#?",
3500                            Clause);
3501
3502                      elsif Has_Pragma_Pack (E) then
3503                         Error_Msg_Sloc :=
3504                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3505                         Error_Msg_N
3506                           ("\because of pragma Pack#?", Clause);
3507                      end if;
3508                   end if;
3509
3510                --  Processing that is done only for subtypes
3511
3512                else
3513                   --  Acquire alignment from base type
3514
3515                   if Unknown_Alignment (E) then
3516                      Set_Alignment (E, Alignment (Base_Type (E)));
3517                      Adjust_Esize_Alignment (E);
3518                   end if;
3519                end if;
3520
3521                --  For bit-packed arrays, check the size
3522
3523                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3524                   declare
3525                      SizC : constant Node_Id := Size_Clause (E);
3526
3527                      Discard : Boolean;
3528                      pragma Warnings (Off, Discard);
3529
3530                   begin
3531                      --  It is not clear if it is possible to have no size
3532                      --  clause at this stage, but it is not worth worrying
3533                      --  about. Post error on the entity name in the size
3534                      --  clause if present, else on the type entity itself.
3535
3536                      if Present (SizC) then
3537                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3538                      else
3539                         Check_Size (E, E, RM_Size (E), Discard);
3540                      end if;
3541                   end;
3542                end if;
3543
3544                --  If any of the index types was an enumeration type with a
3545                --  non-standard rep clause, then we indicate that the array
3546                --  type is always packed (even if it is not bit packed).
3547
3548                if Non_Standard_Enum then
3549                   Set_Has_Non_Standard_Rep (Base_Type (E));
3550                   Set_Is_Packed            (Base_Type (E));
3551                end if;
3552
3553                Set_Component_Alignment_If_Not_Set (E);
3554
3555                --  If the array is packed, we must create the packed array
3556                --  type to be used to actually implement the type. This is
3557                --  only needed for real array types (not for string literal
3558                --  types, since they are present only for the front end).
3559
3560                if Is_Packed (E)
3561                  and then Ekind (E) /= E_String_Literal_Subtype
3562                then
3563                   Create_Packed_Array_Type (E);
3564                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3565
3566                   --  Size information of packed array type is copied to the
3567                   --  array type, since this is really the representation. But
3568                   --  do not override explicit existing size values. If the
3569                   --  ancestor subtype is constrained the packed_array_type
3570                   --  will be inherited from it, but the size may have been
3571                   --  provided already, and must not be overridden either.
3572
3573                   if not Has_Size_Clause (E)
3574                     and then
3575                       (No (Ancestor_Subtype (E))
3576                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3577                   then
3578                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3579                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3580                   end if;
3581
3582                   if not Has_Alignment_Clause (E) then
3583                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3584                   end if;
3585                end if;
3586
3587                --  For non-packed arrays set the alignment of the array to the
3588                --  alignment of the component type if it is unknown. Skip this
3589                --  in atomic case (atomic arrays may need larger alignments).
3590
3591                if not Is_Packed (E)
3592                  and then Unknown_Alignment (E)
3593                  and then Known_Alignment (Ctyp)
3594                  and then Known_Static_Component_Size (E)
3595                  and then Known_Static_Esize (Ctyp)
3596                  and then Esize (Ctyp) = Component_Size (E)
3597                  and then not Is_Atomic (E)
3598                then
3599                   Set_Alignment (E, Alignment (Component_Type (E)));
3600                end if;
3601             end;
3602
3603          --  For a class-wide type, the corresponding specific type is
3604          --  frozen as well (RM 13.14(15))
3605
3606          elsif Is_Class_Wide_Type (E) then
3607             Freeze_And_Append (Root_Type (E), N, Result);
3608
3609             --  If the base type of the class-wide type is still incomplete,
3610             --  the class-wide remains unfrozen as well. This is legal when
3611             --  E is the formal of a primitive operation of some other type
3612             --  which is being frozen.
3613
3614             if not Is_Frozen (Root_Type (E)) then
3615                Set_Is_Frozen (E, False);
3616                return Result;
3617             end if;
3618
3619             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3620             --  parent of a derived type) and it is a library-level entity,
3621             --  generate an itype reference for it. Otherwise, its first
3622             --  explicit reference may be in an inner scope, which will be
3623             --  rejected by the back-end.
3624
3625             if Is_Itype (E)
3626               and then Is_Compilation_Unit (Scope (E))
3627             then
3628                declare
3629                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3630
3631                begin
3632                   Set_Itype (Ref, E);
3633                   Add_To_Result (Ref);
3634                end;
3635             end if;
3636
3637             --  The equivalent type associated with a class-wide subtype needs
3638             --  to be frozen to ensure that its layout is done.
3639
3640             if Ekind (E) = E_Class_Wide_Subtype
3641               and then Present (Equivalent_Type (E))
3642             then
3643                Freeze_And_Append (Equivalent_Type (E), N, Result);
3644             end if;
3645
3646          --  For a record (sub)type, freeze all the component types (RM
3647          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3648          --  Is_Record_Type, because we don't want to attempt the freeze for
3649          --  the case of a private type with record extension (we will do that
3650          --  later when the full type is frozen).
3651
3652          elsif Ekind (E) = E_Record_Type
3653            or else Ekind (E) = E_Record_Subtype
3654          then
3655             Freeze_Record_Type (E);
3656
3657          --  For a concurrent type, freeze corresponding record type. This
3658          --  does not correspond to any specific rule in the RM, but the
3659          --  record type is essentially part of the concurrent type.
3660          --  Freeze as well all local entities. This includes record types
3661          --  created for entry parameter blocks, and whatever local entities
3662          --  may appear in the private part.
3663
3664          elsif Is_Concurrent_Type (E) then
3665             if Present (Corresponding_Record_Type (E)) then
3666                Freeze_And_Append
3667                  (Corresponding_Record_Type (E), N, Result);
3668             end if;
3669
3670             Comp := First_Entity (E);
3671             while Present (Comp) loop
3672                if Is_Type (Comp) then
3673                   Freeze_And_Append (Comp, N, Result);
3674
3675                elsif (Ekind (Comp)) /= E_Function then
3676                   if Is_Itype (Etype (Comp))
3677                     and then Underlying_Type (Scope (Etype (Comp))) = E
3678                   then
3679                      Undelay_Type (Etype (Comp));
3680                   end if;
3681
3682                   Freeze_And_Append (Etype (Comp), N, Result);
3683                end if;
3684
3685                Next_Entity (Comp);
3686             end loop;
3687
3688          --  Private types are required to point to the same freeze node as
3689          --  their corresponding full views. The freeze node itself has to
3690          --  point to the partial view of the entity (because from the partial
3691          --  view, we can retrieve the full view, but not the reverse).
3692          --  However, in order to freeze correctly, we need to freeze the full
3693          --  view. If we are freezing at the end of a scope (or within the
3694          --  scope of the private type), the partial and full views will have
3695          --  been swapped, the full view appears first in the entity chain and
3696          --  the swapping mechanism ensures that the pointers are properly set
3697          --  (on scope exit).
3698
3699          --  If we encounter the partial view before the full view (e.g. when
3700          --  freezing from another scope), we freeze the full view, and then
3701          --  set the pointers appropriately since we cannot rely on swapping to
3702          --  fix things up (subtypes in an outer scope might not get swapped).
3703
3704          elsif Is_Incomplete_Or_Private_Type (E)
3705            and then not Is_Generic_Type (E)
3706          then
3707             --  The construction of the dispatch table associated with library
3708             --  level tagged types forces freezing of all the primitives of the
3709             --  type, which may cause premature freezing of the partial view.
3710             --  For example:
3711
3712             --     package Pkg is
3713             --        type T is tagged private;
3714             --        type DT is new T with private;
3715             --        procedure Prim (X : in out T; Y : in out DT'Class);
3716             --     private
3717             --        type T is tagged null record;
3718             --        Obj : T;
3719             --        type DT is new T with null record;
3720             --     end;
3721
3722             --  In this case the type will be frozen later by the usual
3723             --  mechanism: an object declaration, an instantiation, or the
3724             --  end of a declarative part.
3725
3726             if Is_Library_Level_Tagged_Type (E)
3727               and then not Present (Full_View (E))
3728             then
3729                Set_Is_Frozen (E, False);
3730                return Result;
3731
3732             --  Case of full view present
3733
3734             elsif Present (Full_View (E)) then
3735
3736                --  If full view has already been frozen, then no further
3737                --  processing is required
3738
3739                if Is_Frozen (Full_View (E)) then
3740                   Set_Has_Delayed_Freeze (E, False);
3741                   Set_Freeze_Node (E, Empty);
3742                   Check_Debug_Info_Needed (E);
3743
3744                --  Otherwise freeze full view and patch the pointers so that
3745                --  the freeze node will elaborate both views in the back-end.
3746
3747                else
3748                   declare
3749                      Full : constant Entity_Id := Full_View (E);
3750
3751                   begin
3752                      if Is_Private_Type (Full)
3753                        and then Present (Underlying_Full_View (Full))
3754                      then
3755                         Freeze_And_Append
3756                           (Underlying_Full_View (Full), N, Result);
3757                      end if;
3758
3759                      Freeze_And_Append (Full, N, Result);
3760
3761                      if Has_Delayed_Freeze (E) then
3762                         F_Node := Freeze_Node (Full);
3763
3764                         if Present (F_Node) then
3765                            Set_Freeze_Node (E, F_Node);
3766                            Set_Entity (F_Node, E);
3767
3768                         else
3769                            --  {Incomplete,Private}_Subtypes with Full_Views
3770                            --  constrained by discriminants.
3771
3772                            Set_Has_Delayed_Freeze (E, False);
3773                            Set_Freeze_Node (E, Empty);
3774                         end if;
3775                      end if;
3776                   end;
3777
3778                   Check_Debug_Info_Needed (E);
3779                end if;
3780
3781                --  AI-117 requires that the convention of a partial view be the
3782                --  same as the convention of the full view. Note that this is a
3783                --  recognized breach of privacy, but it's essential for logical
3784                --  consistency of representation, and the lack of a rule in
3785                --  RM95 was an oversight.
3786
3787                Set_Convention (E, Convention (Full_View (E)));
3788
3789                Set_Size_Known_At_Compile_Time (E,
3790                  Size_Known_At_Compile_Time (Full_View (E)));
3791
3792                --  Size information is copied from the full view to the
3793                --  incomplete or private view for consistency.
3794
3795                --  We skip this is the full view is not a type. This is very
3796                --  strange of course, and can only happen as a result of
3797                --  certain illegalities, such as a premature attempt to derive
3798                --  from an incomplete type.
3799
3800                if Is_Type (Full_View (E)) then
3801                   Set_Size_Info (E, Full_View (E));
3802                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3803                end if;
3804
3805                return Result;
3806
3807             --  Case of no full view present. If entity is derived or subtype,
3808             --  it is safe to freeze, correctness depends on the frozen status
3809             --  of parent. Otherwise it is either premature usage, or a Taft
3810             --  amendment type, so diagnosis is at the point of use and the
3811             --  type might be frozen later.
3812
3813             elsif E /= Base_Type (E)
3814               or else Is_Derived_Type (E)
3815             then
3816                null;
3817
3818             else
3819                Set_Is_Frozen (E, False);
3820                return No_List;
3821             end if;
3822
3823          --  For access subprogram, freeze types of all formals, the return
3824          --  type was already frozen, since it is the Etype of the function.
3825          --  Formal types can be tagged Taft amendment types, but otherwise
3826          --  they cannot be incomplete.
3827
3828          elsif Ekind (E) = E_Subprogram_Type then
3829             Formal := First_Formal (E);
3830             while Present (Formal) loop
3831                if Ekind (Etype (Formal)) = E_Incomplete_Type
3832                  and then No (Full_View (Etype (Formal)))
3833                  and then not Is_Value_Type (Etype (Formal))
3834                then
3835                   if Is_Tagged_Type (Etype (Formal)) then
3836                      null;
3837
3838                   --  AI05-151: Incomplete types are allowed in access to
3839                   --  subprogram specifications.
3840
3841                   elsif Ada_Version < Ada_2012 then
3842                      Error_Msg_NE
3843                        ("invalid use of incomplete type&", E, Etype (Formal));
3844                   end if;
3845                end if;
3846
3847                Freeze_And_Append (Etype (Formal), N, Result);
3848                Next_Formal (Formal);
3849             end loop;
3850
3851             Freeze_Subprogram (E);
3852
3853          --  For access to a protected subprogram, freeze the equivalent type
3854          --  (however this is not set if we are not generating code or if this
3855          --  is an anonymous type used just for resolution).
3856
3857          elsif Is_Access_Protected_Subprogram_Type (E) then
3858             if Present (Equivalent_Type (E)) then
3859                Freeze_And_Append (Equivalent_Type (E), N, Result);
3860             end if;
3861          end if;
3862
3863          --  Generic types are never seen by the back-end, and are also not
3864          --  processed by the expander (since the expander is turned off for
3865          --  generic processing), so we never need freeze nodes for them.
3866
3867          if Is_Generic_Type (E) then
3868             return Result;
3869          end if;
3870
3871          --  Some special processing for non-generic types to complete
3872          --  representation details not known till the freeze point.
3873
3874          if Is_Fixed_Point_Type (E) then
3875             Freeze_Fixed_Point_Type (E);
3876
3877             --  Some error checks required for ordinary fixed-point type. Defer
3878             --  these till the freeze-point since we need the small and range
3879             --  values. We only do these checks for base types
3880
3881             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3882                if Small_Value (E) < Ureal_2_M_80 then
3883                   Error_Msg_Name_1 := Name_Small;
3884                   Error_Msg_N
3885                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3886
3887                elsif Small_Value (E) > Ureal_2_80 then
3888                   Error_Msg_Name_1 := Name_Small;
3889                   Error_Msg_N
3890                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3891                end if;
3892
3893                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3894                   Error_Msg_Name_1 := Name_First;
3895                   Error_Msg_N
3896                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3897                end if;
3898
3899                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3900                   Error_Msg_Name_1 := Name_Last;
3901                   Error_Msg_N
3902                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3903                end if;
3904             end if;
3905
3906          elsif Is_Enumeration_Type (E) then
3907             Freeze_Enumeration_Type (E);
3908
3909          elsif Is_Integer_Type (E) then
3910             Adjust_Esize_For_Alignment (E);
3911
3912             if Is_Modular_Integer_Type (E)
3913               and then Warn_On_Suspicious_Modulus_Value
3914             then
3915                Check_Suspicious_Modulus (E);
3916             end if;
3917
3918          elsif Is_Access_Type (E) then
3919
3920             --  If a pragma Default_Storage_Pool applies, and this type has no
3921             --  Storage_Pool or Storage_Size clause (which must have occurred
3922             --  before the freezing point), then use the default. This applies
3923             --  only to base types.
3924
3925             if Present (Default_Pool)
3926               and then Is_Base_Type (E)
3927               and then not Has_Storage_Size_Clause (E)
3928               and then No (Associated_Storage_Pool (E))
3929             then
3930                --  Case of pragma Default_Storage_Pool (null)
3931
3932                if Nkind (Default_Pool) = N_Null then
3933                   Set_No_Pool_Assigned (E);
3934
3935                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3936
3937                else
3938                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3939                end if;
3940             end if;
3941
3942             --  Check restriction for standard storage pool
3943
3944             if No (Associated_Storage_Pool (E)) then
3945                Check_Restriction (No_Standard_Storage_Pools, E);
3946             end if;
3947
3948             --  Deal with error message for pure access type. This is not an
3949             --  error in Ada 2005 if there is no pool (see AI-366).
3950
3951             if Is_Pure_Unit_Access_Type (E)
3952               and then (Ada_Version < Ada_2005
3953                          or else not No_Pool_Assigned (E))
3954             then
3955                Error_Msg_N ("named access type not allowed in pure unit", E);
3956
3957                if Ada_Version >= Ada_2005 then
3958                   Error_Msg_N
3959                     ("\would be legal if Storage_Size of 0 given?", E);
3960
3961                elsif No_Pool_Assigned (E) then
3962                   Error_Msg_N
3963                     ("\would be legal in Ada 2005?", E);
3964
3965                else
3966                   Error_Msg_N
3967                     ("\would be legal in Ada 2005 if "
3968                      & "Storage_Size of 0 given?", E);
3969                end if;
3970             end if;
3971          end if;
3972
3973          --  Case of composite types
3974
3975          if Is_Composite_Type (E) then
3976
3977             --  AI-117 requires that all new primitives of a tagged type must
3978             --  inherit the convention of the full view of the type. Inherited
3979             --  and overriding operations are defined to inherit the convention
3980             --  of their parent or overridden subprogram (also specified in
3981             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3982             --  and New_Overloaded_Entity). Here we set the convention of
3983             --  primitives that are still convention Ada, which will ensure
3984             --  that any new primitives inherit the type's convention. Class-
3985             --  wide types can have a foreign convention inherited from their
3986             --  specific type, but are excluded from this since they don't have
3987             --  any associated primitives.
3988
3989             if Is_Tagged_Type (E)
3990               and then not Is_Class_Wide_Type (E)
3991               and then Convention (E) /= Convention_Ada
3992             then
3993                declare
3994                   Prim_List : constant Elist_Id := Primitive_Operations (E);
3995                   Prim      : Elmt_Id;
3996
3997                begin
3998                   Prim := First_Elmt (Prim_List);
3999                   while Present (Prim) loop
4000                      if Convention (Node (Prim)) = Convention_Ada then
4001                         Set_Convention (Node (Prim), Convention (E));
4002                      end if;
4003
4004                      Next_Elmt (Prim);
4005                   end loop;
4006                end;
4007             end if;
4008          end if;
4009
4010          --  Now that all types from which E may depend are frozen, see if the
4011          --  size is known at compile time, if it must be unsigned, or if
4012          --  strict alignment is required
4013
4014          Check_Compile_Time_Size (E);
4015          Check_Unsigned_Type (E);
4016
4017          if Base_Type (E) = E then
4018             Check_Strict_Alignment (E);
4019          end if;
4020
4021          --  Do not allow a size clause for a type which does not have a size
4022          --  that is known at compile time
4023
4024          if Has_Size_Clause (E)
4025            and then not Size_Known_At_Compile_Time (E)
4026          then
4027             --  Suppress this message if errors posted on E, even if we are
4028             --  in all errors mode, since this is often a junk message
4029
4030             if not Error_Posted (E) then
4031                Error_Msg_N
4032                  ("size clause not allowed for variable length type",
4033                   Size_Clause (E));
4034             end if;
4035          end if;
4036
4037          --  Now we set/verify the representation information, in particular
4038          --  the size and alignment values. This processing is not required for
4039          --  generic types, since generic types do not play any part in code
4040          --  generation, and so the size and alignment values for such types
4041          --  are irrelevant.
4042
4043          if Is_Generic_Type (E) then
4044             return Result;
4045
4046          --  Otherwise we call the layout procedure
4047
4048          else
4049             Layout_Type (E);
4050          end if;
4051
4052          --  If the type has a Defaut_Value/Default_Component_Value aspect,
4053          --  this is where we analye the expression (after the type is frozen,
4054          --  since in the case of Default_Value, we are analyzing with the
4055          --  type itself, and we treat Default_Component_Value similarly for
4056          --  the sake of uniformity.
4057
4058          if Is_First_Subtype (E) and then Has_Default_Aspect (E) then
4059             declare
4060                Nam    : Name_Id;
4061                Aspect : Node_Id;
4062                Exp    : Node_Id;
4063                Typ    : Entity_Id;
4064
4065             begin
4066                if Is_Scalar_Type (E) then
4067                   Nam := Name_Default_Value;
4068                   Typ := E;
4069                else
4070                   Nam := Name_Default_Component_Value;
4071                   Typ := Component_Type (E);
4072                end if;
4073
4074                Aspect := Get_Rep_Item_For_Entity (E, Nam);
4075                Exp := Expression (Aspect);
4076                Analyze_And_Resolve (Exp, Typ);
4077
4078                if Etype (Exp) /= Any_Type then
4079                   if not Is_Static_Expression (Exp) then
4080                      Error_Msg_Name_1 := Nam;
4081                      Flag_Non_Static_Expr
4082                        ("aspect% requires static expression", Exp);
4083                   end if;
4084                end if;
4085             end;
4086          end if;
4087
4088          --  End of freeze processing for type entities
4089       end if;
4090
4091       --  Here is where we logically freeze the current entity. If it has a
4092       --  freeze node, then this is the point at which the freeze node is
4093       --  linked into the result list.
4094
4095       if Has_Delayed_Freeze (E) then
4096
4097          --  If a freeze node is already allocated, use it, otherwise allocate
4098          --  a new one. The preallocation happens in the case of anonymous base
4099          --  types, where we preallocate so that we can set First_Subtype_Link.
4100          --  Note that we reset the Sloc to the current freeze location.
4101
4102          if Present (Freeze_Node (E)) then
4103             F_Node := Freeze_Node (E);
4104             Set_Sloc (F_Node, Loc);
4105
4106          else
4107             F_Node := New_Node (N_Freeze_Entity, Loc);
4108             Set_Freeze_Node (E, F_Node);
4109             Set_Access_Types_To_Process (F_Node, No_Elist);
4110             Set_TSS_Elist (F_Node, No_Elist);
4111             Set_Actions (F_Node, No_List);
4112          end if;
4113
4114          Set_Entity (F_Node, E);
4115          Add_To_Result (F_Node);
4116
4117          --  A final pass over record types with discriminants. If the type
4118          --  has an incomplete declaration, there may be constrained access
4119          --  subtypes declared elsewhere, which do not depend on the discrimi-
4120          --  nants of the type, and which are used as component types (i.e.
4121          --  the full view is a recursive type). The designated types of these
4122          --  subtypes can only be elaborated after the type itself, and they
4123          --  need an itype reference.
4124
4125          if Ekind (E) = E_Record_Type
4126            and then Has_Discriminants (E)
4127          then
4128             declare
4129                Comp : Entity_Id;
4130                IR   : Node_Id;
4131                Typ  : Entity_Id;
4132
4133             begin
4134                Comp := First_Component (E);
4135                while Present (Comp) loop
4136                   Typ  := Etype (Comp);
4137
4138                   if Ekind (Comp) = E_Component
4139                     and then Is_Access_Type (Typ)
4140                     and then Scope (Typ) /= E
4141                     and then Base_Type (Designated_Type (Typ)) = E
4142                     and then Is_Itype (Designated_Type (Typ))
4143                   then
4144                      IR := Make_Itype_Reference (Sloc (Comp));
4145                      Set_Itype (IR, Designated_Type (Typ));
4146                      Append (IR, Result);
4147                   end if;
4148
4149                   Next_Component (Comp);
4150                end loop;
4151             end;
4152          end if;
4153       end if;
4154
4155       --  When a type is frozen, the first subtype of the type is frozen as
4156       --  well (RM 13.14(15)). This has to be done after freezing the type,
4157       --  since obviously the first subtype depends on its own base type.
4158
4159       if Is_Type (E) then
4160          Freeze_And_Append (First_Subtype (E), N, Result);
4161
4162          --  If we just froze a tagged non-class wide record, then freeze the
4163          --  corresponding class-wide type. This must be done after the tagged
4164          --  type itself is frozen, because the class-wide type refers to the
4165          --  tagged type which generates the class.
4166
4167          if Is_Tagged_Type (E)
4168            and then not Is_Class_Wide_Type (E)
4169            and then Present (Class_Wide_Type (E))
4170          then
4171             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4172          end if;
4173       end if;
4174
4175       Check_Debug_Info_Needed (E);
4176
4177       --  Special handling for subprograms
4178
4179       if Is_Subprogram (E) then
4180
4181          --  If subprogram has address clause then reset Is_Public flag, since
4182          --  we do not want the backend to generate external references.
4183
4184          if Present (Address_Clause (E))
4185            and then not Is_Library_Level_Entity (E)
4186          then
4187             Set_Is_Public (E, False);
4188
4189          --  If no address clause and not intrinsic, then for imported
4190          --  subprogram in main unit, generate descriptor if we are in
4191          --  Propagate_Exceptions mode.
4192
4193          --  This is very odd code, it makes a null result, why ???
4194
4195          elsif Propagate_Exceptions
4196            and then Is_Imported (E)
4197            and then not Is_Intrinsic_Subprogram (E)
4198            and then Convention (E) /= Convention_Stubbed
4199          then
4200             if Result = No_List then
4201                Result := Empty_List;
4202             end if;
4203          end if;
4204       end if;
4205
4206       return Result;
4207    end Freeze_Entity;
4208
4209    -----------------------------
4210    -- Freeze_Enumeration_Type --
4211    -----------------------------
4212
4213    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4214    begin
4215       --  By default, if no size clause is present, an enumeration type with
4216       --  Convention C is assumed to interface to a C enum, and has integer
4217       --  size. This applies to types. For subtypes, verify that its base
4218       --  type has no size clause either.
4219
4220       if Has_Foreign_Convention (Typ)
4221         and then not Has_Size_Clause (Typ)
4222         and then not Has_Size_Clause (Base_Type (Typ))
4223         and then Esize (Typ) < Standard_Integer_Size
4224       then
4225          Init_Esize (Typ, Standard_Integer_Size);
4226
4227       else
4228          --  If the enumeration type interfaces to C, and it has a size clause
4229          --  that specifies less than int size, it warrants a warning. The
4230          --  user may intend the C type to be an enum or a char, so this is
4231          --  not by itself an error that the Ada compiler can detect, but it
4232          --  it is a worth a heads-up. For Boolean and Character types we
4233          --  assume that the programmer has the proper C type in mind.
4234
4235          if Convention (Typ) = Convention_C
4236            and then Has_Size_Clause (Typ)
4237            and then Esize (Typ) /= Esize (Standard_Integer)
4238            and then not Is_Boolean_Type (Typ)
4239            and then not Is_Character_Type (Typ)
4240          then
4241             Error_Msg_N
4242               ("C enum types have the size of a C int?", Size_Clause (Typ));
4243          end if;
4244
4245          Adjust_Esize_For_Alignment (Typ);
4246       end if;
4247    end Freeze_Enumeration_Type;
4248
4249    -----------------------
4250    -- Freeze_Expression --
4251    -----------------------
4252
4253    procedure Freeze_Expression (N : Node_Id) is
4254       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4255       Typ         : Entity_Id;
4256       Nam         : Entity_Id;
4257       Desig_Typ   : Entity_Id;
4258       P           : Node_Id;
4259       Parent_P    : Node_Id;
4260
4261       Freeze_Outside : Boolean := False;
4262       --  This flag is set true if the entity must be frozen outside the
4263       --  current subprogram. This happens in the case of expander generated
4264       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4265       --  not freeze all entities like other bodies, but which nevertheless
4266       --  may reference entities that have to be frozen before the body and
4267       --  obviously cannot be frozen inside the body.
4268
4269       function In_Exp_Body (N : Node_Id) return Boolean;
4270       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4271       --  it is the handled statement sequence of an expander-generated
4272       --  subprogram (init proc, stream subprogram, or renaming as body).
4273       --  If so, this is not a freezing context.
4274
4275       -----------------
4276       -- In_Exp_Body --
4277       -----------------
4278
4279       function In_Exp_Body (N : Node_Id) return Boolean is
4280          P  : Node_Id;
4281          Id : Entity_Id;
4282
4283       begin
4284          if Nkind (N) = N_Subprogram_Body then
4285             P := N;
4286          else
4287             P := Parent (N);
4288          end if;
4289
4290          if Nkind (P) /= N_Subprogram_Body then
4291             return False;
4292
4293          else
4294             Id := Defining_Unit_Name (Specification (P));
4295
4296             if Nkind (Id) = N_Defining_Identifier
4297               and then (Is_Init_Proc (Id)              or else
4298                         Is_TSS (Id, TSS_Stream_Input)  or else
4299                         Is_TSS (Id, TSS_Stream_Output) or else
4300                         Is_TSS (Id, TSS_Stream_Read)   or else
4301                         Is_TSS (Id, TSS_Stream_Write)  or else
4302                         Nkind (Original_Node (P)) =
4303                           N_Subprogram_Renaming_Declaration)
4304             then
4305                return True;
4306             else
4307                return False;
4308             end if;
4309          end if;
4310       end In_Exp_Body;
4311
4312    --  Start of processing for Freeze_Expression
4313
4314    begin
4315       --  Immediate return if freezing is inhibited. This flag is set by the
4316       --  analyzer to stop freezing on generated expressions that would cause
4317       --  freezing if they were in the source program, but which are not
4318       --  supposed to freeze, since they are created.
4319
4320       if Must_Not_Freeze (N) then
4321          return;
4322       end if;
4323
4324       --  If expression is non-static, then it does not freeze in a default
4325       --  expression, see section "Handling of Default Expressions" in the
4326       --  spec of package Sem for further details. Note that we have to
4327       --  make sure that we actually have a real expression (if we have
4328       --  a subtype indication, we can't test Is_Static_Expression!)
4329
4330       if In_Spec_Exp
4331         and then Nkind (N) in N_Subexpr
4332         and then not Is_Static_Expression (N)
4333       then
4334          return;
4335       end if;
4336
4337       --  Freeze type of expression if not frozen already
4338
4339       Typ := Empty;
4340
4341       if Nkind (N) in N_Has_Etype then
4342          if not Is_Frozen (Etype (N)) then
4343             Typ := Etype (N);
4344
4345          --  Base type may be an derived numeric type that is frozen at
4346          --  the point of declaration, but first_subtype is still unfrozen.
4347
4348          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4349             Typ := First_Subtype (Etype (N));
4350          end if;
4351       end if;
4352
4353       --  For entity name, freeze entity if not frozen already. A special
4354       --  exception occurs for an identifier that did not come from source.
4355       --  We don't let such identifiers freeze a non-internal entity, i.e.
4356       --  an entity that did come from source, since such an identifier was
4357       --  generated by the expander, and cannot have any semantic effect on
4358       --  the freezing semantics. For example, this stops the parameter of
4359       --  an initialization procedure from freezing the variable.
4360
4361       if Is_Entity_Name (N)
4362         and then not Is_Frozen (Entity (N))
4363         and then (Nkind (N) /= N_Identifier
4364                    or else Comes_From_Source (N)
4365                    or else not Comes_From_Source (Entity (N)))
4366       then
4367          Nam := Entity (N);
4368       else
4369          Nam := Empty;
4370       end if;
4371
4372       --  For an allocator freeze designated type if not frozen already
4373
4374       --  For an aggregate whose component type is an access type, freeze the
4375       --  designated type now, so that its freeze does not appear within the
4376       --  loop that might be created in the expansion of the aggregate. If the
4377       --  designated type is a private type without full view, the expression
4378       --  cannot contain an allocator, so the type is not frozen.
4379
4380       --  For a function, we freeze the entity when the subprogram declaration
4381       --  is frozen, but a function call may appear in an initialization proc.
4382       --  before the declaration is frozen. We need to generate the extra
4383       --  formals, if any, to ensure that the expansion of the call includes
4384       --  the proper actuals. This only applies to Ada subprograms, not to
4385       --  imported ones.
4386
4387       Desig_Typ := Empty;
4388
4389       case Nkind (N) is
4390          when N_Allocator =>
4391             Desig_Typ := Designated_Type (Etype (N));
4392
4393          when N_Aggregate =>
4394             if Is_Array_Type (Etype (N))
4395               and then Is_Access_Type (Component_Type (Etype (N)))
4396             then
4397                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4398             end if;
4399
4400          when N_Selected_Component |
4401             N_Indexed_Component    |
4402             N_Slice                =>
4403
4404             if Is_Access_Type (Etype (Prefix (N))) then
4405                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4406             end if;
4407
4408          when N_Identifier =>
4409             if Present (Nam)
4410               and then Ekind (Nam) = E_Function
4411               and then Nkind (Parent (N)) = N_Function_Call
4412               and then Convention (Nam) = Convention_Ada
4413             then
4414                Create_Extra_Formals (Nam);
4415             end if;
4416
4417          when others =>
4418             null;
4419       end case;
4420
4421       if Desig_Typ /= Empty
4422         and then (Is_Frozen (Desig_Typ)
4423                    or else (not Is_Fully_Defined (Desig_Typ)))
4424       then
4425          Desig_Typ := Empty;
4426       end if;
4427
4428       --  All done if nothing needs freezing
4429
4430       if No (Typ)
4431         and then No (Nam)
4432         and then No (Desig_Typ)
4433       then
4434          return;
4435       end if;
4436
4437       --  Loop for looking at the right place to insert the freeze nodes,
4438       --  exiting from the loop when it is appropriate to insert the freeze
4439       --  node before the current node P.
4440
4441       --  Also checks some special exceptions to the freezing rules. These
4442       --  cases result in a direct return, bypassing the freeze action.
4443
4444       P := N;
4445       loop
4446          Parent_P := Parent (P);
4447
4448          --  If we don't have a parent, then we are not in a well-formed tree.
4449          --  This is an unusual case, but there are some legitimate situations
4450          --  in which this occurs, notably when the expressions in the range of
4451          --  a type declaration are resolved. We simply ignore the freeze
4452          --  request in this case. Is this right ???
4453
4454          if No (Parent_P) then
4455             return;
4456          end if;
4457
4458          --  See if we have got to an appropriate point in the tree
4459
4460          case Nkind (Parent_P) is
4461
4462             --  A special test for the exception of (RM 13.14(8)) for the case
4463             --  of per-object expressions (RM 3.8(18)) occurring in component
4464             --  definition or a discrete subtype definition. Note that we test
4465             --  for a component declaration which includes both cases we are
4466             --  interested in, and furthermore the tree does not have explicit
4467             --  nodes for either of these two constructs.
4468
4469             when N_Component_Declaration =>
4470
4471                --  The case we want to test for here is an identifier that is
4472                --  a per-object expression, this is either a discriminant that
4473                --  appears in a context other than the component declaration
4474                --  or it is a reference to the type of the enclosing construct.
4475
4476                --  For either of these cases, we skip the freezing
4477
4478                if not In_Spec_Expression
4479                  and then Nkind (N) = N_Identifier
4480                  and then (Present (Entity (N)))
4481                then
4482                   --  We recognize the discriminant case by just looking for
4483                   --  a reference to a discriminant. It can only be one for
4484                   --  the enclosing construct. Skip freezing in this case.
4485
4486                   if Ekind (Entity (N)) = E_Discriminant then
4487                      return;
4488
4489                   --  For the case of a reference to the enclosing record,
4490                   --  (or task or protected type), we look for a type that
4491                   --  matches the current scope.
4492
4493                   elsif Entity (N) = Current_Scope then
4494                      return;
4495                   end if;
4496                end if;
4497
4498             --  If we have an enumeration literal that appears as the choice in
4499             --  the aggregate of an enumeration representation clause, then
4500             --  freezing does not occur (RM 13.14(10)).
4501
4502             when N_Enumeration_Representation_Clause =>
4503
4504                --  The case we are looking for is an enumeration literal
4505
4506                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4507                  and then Is_Enumeration_Type (Etype (N))
4508                then
4509                   --  If enumeration literal appears directly as the choice,
4510                   --  do not freeze (this is the normal non-overloaded case)
4511
4512                   if Nkind (Parent (N)) = N_Component_Association
4513                     and then First (Choices (Parent (N))) = N
4514                   then
4515                      return;
4516
4517                   --  If enumeration literal appears as the name of function
4518                   --  which is the choice, then also do not freeze. This
4519                   --  happens in the overloaded literal case, where the
4520                   --  enumeration literal is temporarily changed to a function
4521                   --  call for overloading analysis purposes.
4522
4523                   elsif Nkind (Parent (N)) = N_Function_Call
4524                      and then
4525                        Nkind (Parent (Parent (N))) = N_Component_Association
4526                      and then
4527                        First (Choices (Parent (Parent (N)))) = Parent (N)
4528                   then
4529                      return;
4530                   end if;
4531                end if;
4532
4533             --  Normally if the parent is a handled sequence of statements,
4534             --  then the current node must be a statement, and that is an
4535             --  appropriate place to insert a freeze node.
4536
4537             when N_Handled_Sequence_Of_Statements =>
4538
4539                --  An exception occurs when the sequence of statements is for
4540                --  an expander generated body that did not do the usual freeze
4541                --  all operation. In this case we usually want to freeze
4542                --  outside this body, not inside it, and we skip past the
4543                --  subprogram body that we are inside.
4544
4545                if In_Exp_Body (Parent_P) then
4546
4547                   --  However, we *do* want to freeze at this point if we have
4548                   --  an entity to freeze, and that entity is declared *inside*
4549                   --  the body of the expander generated procedure. This case
4550                   --  is recognized by the scope of the type, which is either
4551                   --  the spec for some enclosing body, or (in the case of
4552                   --  init_procs, for which there are no separate specs) the
4553                   --  current scope.
4554
4555                   declare
4556                      Subp : constant Node_Id := Parent (Parent_P);
4557                      Cspc : Entity_Id;
4558
4559                   begin
4560                      if Nkind (Subp) = N_Subprogram_Body then
4561                         Cspc := Corresponding_Spec (Subp);
4562
4563                         if (Present (Typ) and then Scope (Typ) = Cspc)
4564                              or else
4565                            (Present (Nam) and then Scope (Nam) = Cspc)
4566                         then
4567                            exit;
4568
4569                         elsif Present (Typ)
4570                           and then Scope (Typ) = Current_Scope
4571                           and then Current_Scope = Defining_Entity (Subp)
4572                         then
4573                            exit;
4574                         end if;
4575                      end if;
4576                   end;
4577
4578                   --  If not that exception to the exception, then this is
4579                   --  where we delay the freeze till outside the body.
4580
4581                   Parent_P := Parent (Parent_P);
4582                   Freeze_Outside := True;
4583
4584                --  Here if normal case where we are in handled statement
4585                --  sequence and want to do the insertion right there.
4586
4587                else
4588                   exit;
4589                end if;
4590
4591             --  If parent is a body or a spec or a block, then the current node
4592             --  is a statement or declaration and we can insert the freeze node
4593             --  before it.
4594
4595             when N_Block_Statement       |
4596                  N_Entry_Body            |
4597                  N_Package_Body          |
4598                  N_Package_Specification |
4599                  N_Protected_Body        |
4600                  N_Subprogram_Body       |
4601                  N_Task_Body             => exit;
4602
4603             --  The expander is allowed to define types in any statements list,
4604             --  so any of the following parent nodes also mark a freezing point
4605             --  if the actual node is in a list of statements or declarations.
4606
4607             when N_Abortable_Part             |
4608                  N_Accept_Alternative         |
4609                  N_And_Then                   |
4610                  N_Case_Statement_Alternative |
4611                  N_Compilation_Unit_Aux       |
4612                  N_Conditional_Entry_Call     |
4613                  N_Delay_Alternative          |
4614                  N_Elsif_Part                 |
4615                  N_Entry_Call_Alternative     |
4616                  N_Exception_Handler          |
4617                  N_Extended_Return_Statement  |
4618                  N_Freeze_Entity              |
4619                  N_If_Statement               |
4620                  N_Or_Else                    |
4621                  N_Selective_Accept           |
4622                  N_Triggering_Alternative     =>
4623
4624                exit when Is_List_Member (P);
4625
4626             --  Note: The N_Loop_Statement is a special case. A type that
4627             --  appears in the source can never be frozen in a loop (this
4628             --  occurs only because of a loop expanded by the expander), so we
4629             --  keep on going. Otherwise we terminate the search. Same is true
4630             --  of any entity which comes from source. (if they have predefined
4631             --  type, that type does not appear to come from source, but the
4632             --  entity should not be frozen here).
4633
4634             when N_Loop_Statement =>
4635                exit when not Comes_From_Source (Etype (N))
4636                  and then (No (Nam) or else not Comes_From_Source (Nam));
4637
4638             --  For all other cases, keep looking at parents
4639
4640             when others =>
4641                null;
4642          end case;
4643
4644          --  We fall through the case if we did not yet find the proper
4645          --  place in the free for inserting the freeze node, so climb!
4646
4647          P := Parent_P;
4648       end loop;
4649
4650       --  If the expression appears in a record or an initialization procedure,
4651       --  the freeze nodes are collected and attached to the current scope, to
4652       --  be inserted and analyzed on exit from the scope, to insure that
4653       --  generated entities appear in the correct scope. If the expression is
4654       --  a default for a discriminant specification, the scope is still void.
4655       --  The expression can also appear in the discriminant part of a private
4656       --  or concurrent type.
4657
4658       --  If the expression appears in a constrained subcomponent of an
4659       --  enclosing record declaration, the freeze nodes must be attached to
4660       --  the outer record type so they can eventually be placed in the
4661       --  enclosing declaration list.
4662
4663       --  The other case requiring this special handling is if we are in a
4664       --  default expression, since in that case we are about to freeze a
4665       --  static type, and the freeze scope needs to be the outer scope, not
4666       --  the scope of the subprogram with the default parameter.
4667
4668       --  For default expressions and other spec expressions in generic units,
4669       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4670       --  placing them at the proper place, after the generic unit.
4671
4672       if (In_Spec_Exp and not Inside_A_Generic)
4673         or else Freeze_Outside
4674         or else (Is_Type (Current_Scope)
4675                   and then (not Is_Concurrent_Type (Current_Scope)
4676                              or else not Has_Completion (Current_Scope)))
4677         or else Ekind (Current_Scope) = E_Void
4678       then
4679          declare
4680             N            : constant Node_Id    := Current_Scope;
4681             Freeze_Nodes : List_Id             := No_List;
4682             Pos          : Int                 := Scope_Stack.Last;
4683
4684          begin
4685             if Present (Desig_Typ) then
4686                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4687             end if;
4688
4689             if Present (Typ) then
4690                Freeze_And_Append (Typ, N, Freeze_Nodes);
4691             end if;
4692
4693             if Present (Nam) then
4694                Freeze_And_Append (Nam, N, Freeze_Nodes);
4695             end if;
4696
4697             --  The current scope may be that of a constrained component of
4698             --  an enclosing record declaration, which is above the current
4699             --  scope in the scope stack.
4700             --  If the expression is within a top-level pragma, as for a pre-
4701             --  condition on a library-level subprogram, nothing to do.
4702
4703             if not Is_Compilation_Unit (Current_Scope)
4704               and then Is_Record_Type (Scope (Current_Scope))
4705             then
4706                Pos := Pos - 1;
4707             end if;
4708
4709             if Is_Non_Empty_List (Freeze_Nodes) then
4710                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4711                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4712                     Freeze_Nodes;
4713                else
4714                   Append_List (Freeze_Nodes,
4715                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4716                end if;
4717             end if;
4718          end;
4719
4720          return;
4721       end if;
4722
4723       --  Now we have the right place to do the freezing. First, a special
4724       --  adjustment, if we are in spec-expression analysis mode, these freeze
4725       --  actions must not be thrown away (normally all inserted actions are
4726       --  thrown away in this mode. However, the freeze actions are from static
4727       --  expressions and one of the important reasons we are doing this
4728       --  special analysis is to get these freeze actions. Therefore we turn
4729       --  off the In_Spec_Expression mode to propagate these freeze actions.
4730       --  This also means they get properly analyzed and expanded.
4731
4732       In_Spec_Expression := False;
4733
4734       --  Freeze the designated type of an allocator (RM 13.14(13))
4735
4736       if Present (Desig_Typ) then
4737          Freeze_Before (P, Desig_Typ);
4738       end if;
4739
4740       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4741       --  the enumeration representation clause exception in the loop above.
4742
4743       if Present (Typ) then
4744          Freeze_Before (P, Typ);
4745       end if;
4746
4747       --  Freeze name if one is present (RM 13.14(11))
4748
4749       if Present (Nam) then
4750          Freeze_Before (P, Nam);
4751       end if;
4752
4753       --  Restore In_Spec_Expression flag
4754
4755       In_Spec_Expression := In_Spec_Exp;
4756    end Freeze_Expression;
4757
4758    -----------------------------
4759    -- Freeze_Fixed_Point_Type --
4760    -----------------------------
4761
4762    --  Certain fixed-point types and subtypes, including implicit base types
4763    --  and declared first subtypes, have not yet set up a range. This is
4764    --  because the range cannot be set until the Small and Size values are
4765    --  known, and these are not known till the type is frozen.
4766
4767    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4768    --  whose bounds are unanalyzed real literals. This routine will recognize
4769    --  this case, and transform this range node into a properly typed range
4770    --  with properly analyzed and resolved values.
4771
4772    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4773       Rng   : constant Node_Id    := Scalar_Range (Typ);
4774       Lo    : constant Node_Id    := Low_Bound (Rng);
4775       Hi    : constant Node_Id    := High_Bound (Rng);
4776       Btyp  : constant Entity_Id  := Base_Type (Typ);
4777       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4778       BLo   : constant Node_Id    := Low_Bound (Brng);
4779       BHi   : constant Node_Id    := High_Bound (Brng);
4780       Small : constant Ureal      := Small_Value (Typ);
4781       Loval : Ureal;
4782       Hival : Ureal;
4783       Atype : Entity_Id;
4784
4785       Actual_Size : Nat;
4786
4787       function Fsize (Lov, Hiv : Ureal) return Nat;
4788       --  Returns size of type with given bounds. Also leaves these
4789       --  bounds set as the current bounds of the Typ.
4790
4791       -----------
4792       -- Fsize --
4793       -----------
4794
4795       function Fsize (Lov, Hiv : Ureal) return Nat is
4796       begin
4797          Set_Realval (Lo, Lov);
4798          Set_Realval (Hi, Hiv);
4799          return Minimum_Size (Typ);
4800       end Fsize;
4801
4802    --  Start of processing for Freeze_Fixed_Point_Type
4803
4804    begin
4805       --  If Esize of a subtype has not previously been set, set it now
4806
4807       if Unknown_Esize (Typ) then
4808          Atype := Ancestor_Subtype (Typ);
4809
4810          if Present (Atype) then
4811             Set_Esize (Typ, Esize (Atype));
4812          else
4813             Set_Esize (Typ, Esize (Base_Type (Typ)));
4814          end if;
4815       end if;
4816
4817       --  Immediate return if the range is already analyzed. This means that
4818       --  the range is already set, and does not need to be computed by this
4819       --  routine.
4820
4821       if Analyzed (Rng) then
4822          return;
4823       end if;
4824
4825       --  Immediate return if either of the bounds raises Constraint_Error
4826
4827       if Raises_Constraint_Error (Lo)
4828         or else Raises_Constraint_Error (Hi)
4829       then
4830          return;
4831       end if;
4832
4833       Loval := Realval (Lo);
4834       Hival := Realval (Hi);
4835
4836       --  Ordinary fixed-point case
4837
4838       if Is_Ordinary_Fixed_Point_Type (Typ) then
4839
4840          --  For the ordinary fixed-point case, we are allowed to fudge the
4841          --  end-points up or down by small. Generally we prefer to fudge up,
4842          --  i.e. widen the bounds for non-model numbers so that the end points
4843          --  are included. However there are cases in which this cannot be
4844          --  done, and indeed cases in which we may need to narrow the bounds.
4845          --  The following circuit makes the decision.
4846
4847          --  Note: our terminology here is that Incl_EP means that the bounds
4848          --  are widened by Small if necessary to include the end points, and
4849          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4850          --  end-points if this reduces the size.
4851
4852          --  Note that in the Incl case, all we care about is including the
4853          --  end-points. In the Excl case, we want to narrow the bounds as
4854          --  much as permitted by the RM, to give the smallest possible size.
4855
4856          Fudge : declare
4857             Loval_Incl_EP : Ureal;
4858             Hival_Incl_EP : Ureal;
4859
4860             Loval_Excl_EP : Ureal;
4861             Hival_Excl_EP : Ureal;
4862
4863             Size_Incl_EP  : Nat;
4864             Size_Excl_EP  : Nat;
4865
4866             Model_Num     : Ureal;
4867             First_Subt    : Entity_Id;
4868             Actual_Lo     : Ureal;
4869             Actual_Hi     : Ureal;
4870
4871          begin
4872             --  First step. Base types are required to be symmetrical. Right
4873             --  now, the base type range is a copy of the first subtype range.
4874             --  This will be corrected before we are done, but right away we
4875             --  need to deal with the case where both bounds are non-negative.
4876             --  In this case, we set the low bound to the negative of the high
4877             --  bound, to make sure that the size is computed to include the
4878             --  required sign. Note that we do not need to worry about the
4879             --  case of both bounds negative, because the sign will be dealt
4880             --  with anyway. Furthermore we can't just go making such a bound
4881             --  symmetrical, since in a twos-complement system, there is an
4882             --  extra negative value which could not be accommodated on the
4883             --  positive side.
4884
4885             if Typ = Btyp
4886               and then not UR_Is_Negative (Loval)
4887               and then Hival > Loval
4888             then
4889                Loval := -Hival;
4890                Set_Realval (Lo, Loval);
4891             end if;
4892
4893             --  Compute the fudged bounds. If the number is a model number,
4894             --  then we do nothing to include it, but we are allowed to backoff
4895             --  to the next adjacent model number when we exclude it. If it is
4896             --  not a model number then we straddle the two values with the
4897             --  model numbers on either side.
4898
4899             Model_Num := UR_Trunc (Loval / Small) * Small;
4900
4901             if Loval = Model_Num then
4902                Loval_Incl_EP := Model_Num;
4903             else
4904                Loval_Incl_EP := Model_Num - Small;
4905             end if;
4906
4907             --  The low value excluding the end point is Small greater, but
4908             --  we do not do this exclusion if the low value is positive,
4909             --  since it can't help the size and could actually hurt by
4910             --  crossing the high bound.
4911
4912             if UR_Is_Negative (Loval_Incl_EP) then
4913                Loval_Excl_EP := Loval_Incl_EP + Small;
4914
4915                --  If the value went from negative to zero, then we have the
4916                --  case where Loval_Incl_EP is the model number just below
4917                --  zero, so we want to stick to the negative value for the
4918                --  base type to maintain the condition that the size will
4919                --  include signed values.
4920
4921                if Typ = Btyp
4922                  and then UR_Is_Zero (Loval_Excl_EP)
4923                then
4924                   Loval_Excl_EP := Loval_Incl_EP;
4925                end if;
4926
4927             else
4928                Loval_Excl_EP := Loval_Incl_EP;
4929             end if;
4930
4931             --  Similar processing for upper bound and high value
4932
4933             Model_Num := UR_Trunc (Hival / Small) * Small;
4934
4935             if Hival = Model_Num then
4936                Hival_Incl_EP := Model_Num;
4937             else
4938                Hival_Incl_EP := Model_Num + Small;
4939             end if;
4940
4941             if UR_Is_Positive (Hival_Incl_EP) then
4942                Hival_Excl_EP := Hival_Incl_EP - Small;
4943             else
4944                Hival_Excl_EP := Hival_Incl_EP;
4945             end if;
4946
4947             --  One further adjustment is needed. In the case of subtypes, we
4948             --  cannot go outside the range of the base type, or we get
4949             --  peculiarities, and the base type range is already set. This
4950             --  only applies to the Incl values, since clearly the Excl values
4951             --  are already as restricted as they are allowed to be.
4952
4953             if Typ /= Btyp then
4954                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4955                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4956             end if;
4957
4958             --  Get size including and excluding end points
4959
4960             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4961             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4962
4963             --  No need to exclude end-points if it does not reduce size
4964
4965             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4966                Loval_Excl_EP := Loval_Incl_EP;
4967             end if;
4968
4969             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4970                Hival_Excl_EP := Hival_Incl_EP;
4971             end if;
4972
4973             --  Now we set the actual size to be used. We want to use the
4974             --  bounds fudged up to include the end-points but only if this
4975             --  can be done without violating a specifically given size
4976             --  size clause or causing an unacceptable increase in size.
4977
4978             --  Case of size clause given
4979
4980             if Has_Size_Clause (Typ) then
4981
4982                --  Use the inclusive size only if it is consistent with
4983                --  the explicitly specified size.
4984
4985                if Size_Incl_EP <= RM_Size (Typ) then
4986                   Actual_Lo   := Loval_Incl_EP;
4987                   Actual_Hi   := Hival_Incl_EP;
4988                   Actual_Size := Size_Incl_EP;
4989
4990                --  If the inclusive size is too large, we try excluding
4991                --  the end-points (will be caught later if does not work).
4992
4993                else
4994                   Actual_Lo   := Loval_Excl_EP;
4995                   Actual_Hi   := Hival_Excl_EP;
4996                   Actual_Size := Size_Excl_EP;
4997                end if;
4998
4999             --  Case of size clause not given
5000
5001             else
5002                --  If we have a base type whose corresponding first subtype
5003                --  has an explicit size that is large enough to include our
5004                --  end-points, then do so. There is no point in working hard
5005                --  to get a base type whose size is smaller than the specified
5006                --  size of the first subtype.
5007
5008                First_Subt := First_Subtype (Typ);
5009
5010                if Has_Size_Clause (First_Subt)
5011                  and then Size_Incl_EP <= Esize (First_Subt)
5012                then
5013                   Actual_Size := Size_Incl_EP;
5014                   Actual_Lo   := Loval_Incl_EP;
5015                   Actual_Hi   := Hival_Incl_EP;
5016
5017                --  If excluding the end-points makes the size smaller and
5018                --  results in a size of 8,16,32,64, then we take the smaller
5019                --  size. For the 64 case, this is compulsory. For the other
5020                --  cases, it seems reasonable. We like to include end points
5021                --  if we can, but not at the expense of moving to the next
5022                --  natural boundary of size.
5023
5024                elsif Size_Incl_EP /= Size_Excl_EP
5025                  and then Addressable (Size_Excl_EP)
5026                then
5027                   Actual_Size := Size_Excl_EP;
5028                   Actual_Lo   := Loval_Excl_EP;
5029                   Actual_Hi   := Hival_Excl_EP;
5030
5031                --  Otherwise we can definitely include the end points
5032
5033                else
5034                   Actual_Size := Size_Incl_EP;
5035                   Actual_Lo   := Loval_Incl_EP;
5036                   Actual_Hi   := Hival_Incl_EP;
5037                end if;
5038
5039                --  One pathological case: normally we never fudge a low bound
5040                --  down, since it would seem to increase the size (if it has
5041                --  any effect), but for ranges containing single value, or no
5042                --  values, the high bound can be small too large. Consider:
5043
5044                --    type t is delta 2.0**(-14)
5045                --      range 131072.0 .. 0;
5046
5047                --  That lower bound is *just* outside the range of 32 bits, and
5048                --  does need fudging down in this case. Note that the bounds
5049                --  will always have crossed here, since the high bound will be
5050                --  fudged down if necessary, as in the case of:
5051
5052                --    type t is delta 2.0**(-14)
5053                --      range 131072.0 .. 131072.0;
5054
5055                --  So we detect the situation by looking for crossed bounds,
5056                --  and if the bounds are crossed, and the low bound is greater
5057                --  than zero, we will always back it off by small, since this
5058                --  is completely harmless.
5059
5060                if Actual_Lo > Actual_Hi then
5061                   if UR_Is_Positive (Actual_Lo) then
5062                      Actual_Lo   := Loval_Incl_EP - Small;
5063                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5064
5065                   --  And of course, we need to do exactly the same parallel
5066                   --  fudge for flat ranges in the negative region.
5067
5068                   elsif UR_Is_Negative (Actual_Hi) then
5069                      Actual_Hi := Hival_Incl_EP + Small;
5070                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5071                   end if;
5072                end if;
5073             end if;
5074
5075             Set_Realval (Lo, Actual_Lo);
5076             Set_Realval (Hi, Actual_Hi);
5077          end Fudge;
5078
5079       --  For the decimal case, none of this fudging is required, since there
5080       --  are no end-point problems in the decimal case (the end-points are
5081       --  always included).
5082
5083       else
5084          Actual_Size := Fsize (Loval, Hival);
5085       end if;
5086
5087       --  At this stage, the actual size has been calculated and the proper
5088       --  required bounds are stored in the low and high bounds.
5089
5090       if Actual_Size > 64 then
5091          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5092          Error_Msg_N
5093            ("size required (^) for type& too large, maximum allowed is 64",
5094             Typ);
5095          Actual_Size := 64;
5096       end if;
5097
5098       --  Check size against explicit given size
5099
5100       if Has_Size_Clause (Typ) then
5101          if Actual_Size > RM_Size (Typ) then
5102             Error_Msg_Uint_1 := RM_Size (Typ);
5103             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5104             Error_Msg_NE
5105               ("size given (^) for type& too small, minimum allowed is ^",
5106                Size_Clause (Typ), Typ);
5107
5108          else
5109             Actual_Size := UI_To_Int (Esize (Typ));
5110          end if;
5111
5112       --  Increase size to next natural boundary if no size clause given
5113
5114       else
5115          if Actual_Size <= 8 then
5116             Actual_Size := 8;
5117          elsif Actual_Size <= 16 then
5118             Actual_Size := 16;
5119          elsif Actual_Size <= 32 then
5120             Actual_Size := 32;
5121          else
5122             Actual_Size := 64;
5123          end if;
5124
5125          Init_Esize (Typ, Actual_Size);
5126          Adjust_Esize_For_Alignment (Typ);
5127       end if;
5128
5129       --  If we have a base type, then expand the bounds so that they extend to
5130       --  the full width of the allocated size in bits, to avoid junk range
5131       --  checks on intermediate computations.
5132
5133       if Base_Type (Typ) = Typ then
5134          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5135          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5136       end if;
5137
5138       --  Final step is to reanalyze the bounds using the proper type
5139       --  and set the Corresponding_Integer_Value fields of the literals.
5140
5141       Set_Etype (Lo, Empty);
5142       Set_Analyzed (Lo, False);
5143       Analyze (Lo);
5144
5145       --  Resolve with universal fixed if the base type, and the base type if
5146       --  it is a subtype. Note we can't resolve the base type with itself,
5147       --  that would be a reference before definition.
5148
5149       if Typ = Btyp then
5150          Resolve (Lo, Universal_Fixed);
5151       else
5152          Resolve (Lo, Btyp);
5153       end if;
5154
5155       --  Set corresponding integer value for bound
5156
5157       Set_Corresponding_Integer_Value
5158         (Lo, UR_To_Uint (Realval (Lo) / Small));
5159
5160       --  Similar processing for high bound
5161
5162       Set_Etype (Hi, Empty);
5163       Set_Analyzed (Hi, False);
5164       Analyze (Hi);
5165
5166       if Typ = Btyp then
5167          Resolve (Hi, Universal_Fixed);
5168       else
5169          Resolve (Hi, Btyp);
5170       end if;
5171
5172       Set_Corresponding_Integer_Value
5173         (Hi, UR_To_Uint (Realval (Hi) / Small));
5174
5175       --  Set type of range to correspond to bounds
5176
5177       Set_Etype (Rng, Etype (Lo));
5178
5179       --  Set Esize to calculated size if not set already
5180
5181       if Unknown_Esize (Typ) then
5182          Init_Esize (Typ, Actual_Size);
5183       end if;
5184
5185       --  Set RM_Size if not already set. If already set, check value
5186
5187       declare
5188          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5189
5190       begin
5191          if RM_Size (Typ) /= Uint_0 then
5192             if RM_Size (Typ) < Minsiz then
5193                Error_Msg_Uint_1 := RM_Size (Typ);
5194                Error_Msg_Uint_2 := Minsiz;
5195                Error_Msg_NE
5196                  ("size given (^) for type& too small, minimum allowed is ^",
5197                   Size_Clause (Typ), Typ);
5198             end if;
5199
5200          else
5201             Set_RM_Size (Typ, Minsiz);
5202          end if;
5203       end;
5204    end Freeze_Fixed_Point_Type;
5205
5206    ------------------
5207    -- Freeze_Itype --
5208    ------------------
5209
5210    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5211       L : List_Id;
5212
5213    begin
5214       Set_Has_Delayed_Freeze (T);
5215       L := Freeze_Entity (T, N);
5216
5217       if Is_Non_Empty_List (L) then
5218          Insert_Actions (N, L);
5219       end if;
5220    end Freeze_Itype;
5221
5222    --------------------------
5223    -- Freeze_Static_Object --
5224    --------------------------
5225
5226    procedure Freeze_Static_Object (E : Entity_Id) is
5227
5228       Cannot_Be_Static : exception;
5229       --  Exception raised if the type of a static object cannot be made
5230       --  static. This happens if the type depends on non-global objects.
5231
5232       procedure Ensure_Expression_Is_SA (N : Node_Id);
5233       --  Called to ensure that an expression used as part of a type definition
5234       --  is statically allocatable, which means that the expression type is
5235       --  statically allocatable, and the expression is either static, or a
5236       --  reference to a library level constant.
5237
5238       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5239       --  Called to mark a type as static, checking that it is possible
5240       --  to set the type as static. If it is not possible, then the
5241       --  exception Cannot_Be_Static is raised.
5242
5243       -----------------------------
5244       -- Ensure_Expression_Is_SA --
5245       -----------------------------
5246
5247       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5248          Ent : Entity_Id;
5249
5250       begin
5251          Ensure_Type_Is_SA (Etype (N));
5252
5253          if Is_Static_Expression (N) then
5254             return;
5255
5256          elsif Nkind (N) = N_Identifier then
5257             Ent := Entity (N);
5258
5259             if Present (Ent)
5260               and then Ekind (Ent) = E_Constant
5261               and then Is_Library_Level_Entity (Ent)
5262             then
5263                return;
5264             end if;
5265          end if;
5266
5267          raise Cannot_Be_Static;
5268       end Ensure_Expression_Is_SA;
5269
5270       -----------------------
5271       -- Ensure_Type_Is_SA --
5272       -----------------------
5273
5274       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5275          N : Node_Id;
5276          C : Entity_Id;
5277
5278       begin
5279          --  If type is library level, we are all set
5280
5281          if Is_Library_Level_Entity (Typ) then
5282             return;
5283          end if;
5284
5285          --  We are also OK if the type already marked as statically allocated,
5286          --  which means we processed it before.
5287
5288          if Is_Statically_Allocated (Typ) then
5289             return;
5290          end if;
5291
5292          --  Mark type as statically allocated
5293
5294          Set_Is_Statically_Allocated (Typ);
5295
5296          --  Check that it is safe to statically allocate this type
5297
5298          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5299             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5300             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5301
5302          elsif Is_Array_Type (Typ) then
5303             N := First_Index (Typ);
5304             while Present (N) loop
5305                Ensure_Type_Is_SA (Etype (N));
5306                Next_Index (N);
5307             end loop;
5308
5309             Ensure_Type_Is_SA (Component_Type (Typ));
5310
5311          elsif Is_Access_Type (Typ) then
5312             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5313
5314                declare
5315                   F : Entity_Id;
5316                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5317
5318                begin
5319                   if T /= Standard_Void_Type then
5320                      Ensure_Type_Is_SA (T);
5321                   end if;
5322
5323                   F := First_Formal (Designated_Type (Typ));
5324                   while Present (F) loop
5325                      Ensure_Type_Is_SA (Etype (F));
5326                      Next_Formal (F);
5327                   end loop;
5328                end;
5329
5330             else
5331                Ensure_Type_Is_SA (Designated_Type (Typ));
5332             end if;
5333
5334          elsif Is_Record_Type (Typ) then
5335             C := First_Entity (Typ);
5336             while Present (C) loop
5337                if Ekind (C) = E_Discriminant
5338                  or else Ekind (C) = E_Component
5339                then
5340                   Ensure_Type_Is_SA (Etype (C));
5341
5342                elsif Is_Type (C) then
5343                   Ensure_Type_Is_SA (C);
5344                end if;
5345
5346                Next_Entity (C);
5347             end loop;
5348
5349          elsif Ekind (Typ) = E_Subprogram_Type then
5350             Ensure_Type_Is_SA (Etype (Typ));
5351
5352             C := First_Formal (Typ);
5353             while Present (C) loop
5354                Ensure_Type_Is_SA (Etype (C));
5355                Next_Formal (C);
5356             end loop;
5357
5358          else
5359             raise Cannot_Be_Static;
5360          end if;
5361       end Ensure_Type_Is_SA;
5362
5363    --  Start of processing for Freeze_Static_Object
5364
5365    begin
5366       Ensure_Type_Is_SA (Etype (E));
5367
5368    exception
5369       when Cannot_Be_Static =>
5370
5371          --  If the object that cannot be static is imported or exported, then
5372          --  issue an error message saying that this object cannot be imported
5373          --  or exported. If it has an address clause it is an overlay in the
5374          --  current partition and the static requirement is not relevant.
5375          --  Do not issue any error message when ignoring rep clauses.
5376
5377          if Ignore_Rep_Clauses then
5378             null;
5379
5380          elsif Is_Imported (E) then
5381             if No (Address_Clause (E)) then
5382                Error_Msg_N
5383                  ("& cannot be imported (local type is not constant)", E);
5384             end if;
5385
5386          --  Otherwise must be exported, something is wrong if compiler
5387          --  is marking something as statically allocated which cannot be).
5388
5389          else pragma Assert (Is_Exported (E));
5390             Error_Msg_N
5391               ("& cannot be exported (local type is not constant)", E);
5392          end if;
5393    end Freeze_Static_Object;
5394
5395    -----------------------
5396    -- Freeze_Subprogram --
5397    -----------------------
5398
5399    procedure Freeze_Subprogram (E : Entity_Id) is
5400       Retype : Entity_Id;
5401       F      : Entity_Id;
5402
5403    begin
5404       --  Subprogram may not have an address clause unless it is imported
5405
5406       if Present (Address_Clause (E)) then
5407          if not Is_Imported (E) then
5408             Error_Msg_N
5409               ("address clause can only be given " &
5410                "for imported subprogram",
5411                Name (Address_Clause (E)));
5412          end if;
5413       end if;
5414
5415       --  Reset the Pure indication on an imported subprogram unless an
5416       --  explicit Pure_Function pragma was present. We do this because
5417       --  otherwise it is an insidious error to call a non-pure function from
5418       --  pure unit and have calls mysteriously optimized away. What happens
5419       --  here is that the Import can bypass the normal check to ensure that
5420       --  pure units call only pure subprograms.
5421
5422       if Is_Imported (E)
5423         and then Is_Pure (E)
5424         and then not Has_Pragma_Pure_Function (E)
5425       then
5426          Set_Is_Pure (E, False);
5427       end if;
5428
5429       --  For non-foreign convention subprograms, this is where we create
5430       --  the extra formals (for accessibility level and constrained bit
5431       --  information). We delay this till the freeze point precisely so
5432       --  that we know the convention!
5433
5434       if not Has_Foreign_Convention (E) then
5435          Create_Extra_Formals (E);
5436          Set_Mechanisms (E);
5437
5438          --  If this is convention Ada and a Valued_Procedure, that's odd
5439
5440          if Ekind (E) = E_Procedure
5441            and then Is_Valued_Procedure (E)
5442            and then Convention (E) = Convention_Ada
5443            and then Warn_On_Export_Import
5444          then
5445             Error_Msg_N
5446               ("?Valued_Procedure has no effect for convention Ada", E);
5447             Set_Is_Valued_Procedure (E, False);
5448          end if;
5449
5450       --  Case of foreign convention
5451
5452       else
5453          Set_Mechanisms (E);
5454
5455          --  For foreign conventions, warn about return of an
5456          --  unconstrained array.
5457
5458          --  Note: we *do* allow a return by descriptor for the VMS case,
5459          --  though here there is probably more to be done ???
5460
5461          if Ekind (E) = E_Function then
5462             Retype := Underlying_Type (Etype (E));
5463
5464             --  If no return type, probably some other error, e.g. a
5465             --  missing full declaration, so ignore.
5466
5467             if No (Retype) then
5468                null;
5469
5470             --  If the return type is generic, we have emitted a warning
5471             --  earlier on, and there is nothing else to check here. Specific
5472             --  instantiations may lead to erroneous behavior.
5473
5474             elsif Is_Generic_Type (Etype (E)) then
5475                null;
5476
5477             --  Display warning if returning unconstrained array
5478
5479             elsif Is_Array_Type (Retype)
5480               and then not Is_Constrained (Retype)
5481
5482               --  Exclude cases where descriptor mechanism is set, since the
5483               --  VMS descriptor mechanisms allow such unconstrained returns.
5484
5485               and then Mechanism (E) not in Descriptor_Codes
5486
5487                --  Check appropriate warning is enabled (should we check for
5488                --  Warnings (Off) on specific entities here, probably so???)
5489
5490               and then Warn_On_Export_Import
5491
5492               --  Exclude the VM case, since return of unconstrained arrays
5493               --  is properly handled in both the JVM and .NET cases.
5494
5495               and then VM_Target = No_VM
5496             then
5497                Error_Msg_N
5498                 ("?foreign convention function& should not return " &
5499                   "unconstrained array", E);
5500                return;
5501             end if;
5502          end if;
5503
5504          --  If any of the formals for an exported foreign convention
5505          --  subprogram have defaults, then emit an appropriate warning since
5506          --  this is odd (default cannot be used from non-Ada code)
5507
5508          if Is_Exported (E) then
5509             F := First_Formal (E);
5510             while Present (F) loop
5511                if Warn_On_Export_Import
5512                  and then Present (Default_Value (F))
5513                then
5514                   Error_Msg_N
5515                     ("?parameter cannot be defaulted in non-Ada call",
5516                      Default_Value (F));
5517                end if;
5518
5519                Next_Formal (F);
5520             end loop;
5521          end if;
5522       end if;
5523
5524       --  For VMS, descriptor mechanisms for parameters are allowed only for
5525       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5526       --  allowed for parameters of exported subprograms.
5527
5528       if OpenVMS_On_Target then
5529          if Is_Exported (E) then
5530             F := First_Formal (E);
5531             while Present (F) loop
5532                if Mechanism (F) = By_Descriptor_NCA then
5533                   Error_Msg_N
5534                     ("'N'C'A' descriptor for parameter not permitted", F);
5535                   Error_Msg_N
5536                     ("\can only be used for imported subprogram", F);
5537                end if;
5538
5539                Next_Formal (F);
5540             end loop;
5541
5542          elsif not Is_Imported (E) then
5543             F := First_Formal (E);
5544             while Present (F) loop
5545                if Mechanism (F) in Descriptor_Codes then
5546                   Error_Msg_N
5547                     ("descriptor mechanism for parameter not permitted", F);
5548                   Error_Msg_N
5549                     ("\can only be used for imported/exported subprogram", F);
5550                end if;
5551
5552                Next_Formal (F);
5553             end loop;
5554          end if;
5555       end if;
5556
5557       --  Pragma Inline_Always is disallowed for dispatching subprograms
5558       --  because the address of such subprograms is saved in the dispatch
5559       --  table to support dispatching calls, and dispatching calls cannot
5560       --  be inlined. This is consistent with the restriction against using
5561       --  'Access or 'Address on an Inline_Always subprogram.
5562
5563       if Is_Dispatching_Operation (E)
5564         and then Has_Pragma_Inline_Always (E)
5565       then
5566          Error_Msg_N
5567            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5568       end if;
5569
5570       --  Because of the implicit representation of inherited predefined
5571       --  operators in the front-end, the overriding status of the operation
5572       --  may be affected when a full view of a type is analyzed, and this is
5573       --  not captured by the analysis of the corresponding type declaration.
5574       --  Therefore the correctness of a not-overriding indicator must be
5575       --  rechecked when the subprogram is frozen.
5576
5577       if Nkind (E) = N_Defining_Operator_Symbol
5578         and then not Error_Posted (Parent (E))
5579       then
5580          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5581       end if;
5582    end Freeze_Subprogram;
5583
5584    ----------------------
5585    -- Is_Fully_Defined --
5586    ----------------------
5587
5588    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5589    begin
5590       if Ekind (T) = E_Class_Wide_Type then
5591          return Is_Fully_Defined (Etype (T));
5592
5593       elsif Is_Array_Type (T) then
5594          return Is_Fully_Defined (Component_Type (T));
5595
5596       elsif Is_Record_Type (T)
5597         and not Is_Private_Type (T)
5598       then
5599          --  Verify that the record type has no components with private types
5600          --  without completion.
5601
5602          declare
5603             Comp : Entity_Id;
5604
5605          begin
5606             Comp := First_Component (T);
5607             while Present (Comp) loop
5608                if not Is_Fully_Defined (Etype (Comp)) then
5609                   return False;
5610                end if;
5611
5612                Next_Component (Comp);
5613             end loop;
5614             return True;
5615          end;
5616
5617       --  For the designated type of an access to subprogram, all types in
5618       --  the profile must be fully defined.
5619
5620       elsif Ekind (T) = E_Subprogram_Type then
5621          declare
5622             F : Entity_Id;
5623
5624          begin
5625             F := First_Formal (T);
5626             while Present (F) loop
5627                if not Is_Fully_Defined (Etype (F)) then
5628                   return False;
5629                end if;
5630
5631                Next_Formal (F);
5632             end loop;
5633
5634             return Is_Fully_Defined (Etype (T));
5635          end;
5636
5637       else
5638          return not Is_Private_Type (T)
5639            or else Present (Full_View (Base_Type (T)));
5640       end if;
5641    end Is_Fully_Defined;
5642
5643    ---------------------------------
5644    -- Process_Default_Expressions --
5645    ---------------------------------
5646
5647    procedure Process_Default_Expressions
5648      (E     : Entity_Id;
5649       After : in out Node_Id)
5650    is
5651       Loc    : constant Source_Ptr := Sloc (E);
5652       Dbody  : Node_Id;
5653       Formal : Node_Id;
5654       Dcopy  : Node_Id;
5655       Dnam   : Entity_Id;
5656
5657    begin
5658       Set_Default_Expressions_Processed (E);
5659
5660       --  A subprogram instance and its associated anonymous subprogram share
5661       --  their signature. The default expression functions are defined in the
5662       --  wrapper packages for the anonymous subprogram, and should not be
5663       --  generated again for the instance.
5664
5665       if Is_Generic_Instance (E)
5666         and then Present (Alias (E))
5667         and then Default_Expressions_Processed (Alias (E))
5668       then
5669          return;
5670       end if;
5671
5672       Formal := First_Formal (E);
5673       while Present (Formal) loop
5674          if Present (Default_Value (Formal)) then
5675
5676             --  We work with a copy of the default expression because we
5677             --  do not want to disturb the original, since this would mess
5678             --  up the conformance checking.
5679
5680             Dcopy := New_Copy_Tree (Default_Value (Formal));
5681
5682             --  The analysis of the expression may generate insert actions,
5683             --  which of course must not be executed. We wrap those actions
5684             --  in a procedure that is not called, and later on eliminated.
5685             --  The following cases have no side-effects, and are analyzed
5686             --  directly.
5687
5688             if Nkind (Dcopy) = N_Identifier
5689               or else Nkind (Dcopy) = N_Expanded_Name
5690               or else Nkind (Dcopy) = N_Integer_Literal
5691               or else (Nkind (Dcopy) = N_Real_Literal
5692                         and then not Vax_Float (Etype (Dcopy)))
5693               or else Nkind (Dcopy) = N_Character_Literal
5694               or else Nkind (Dcopy) = N_String_Literal
5695               or else Known_Null (Dcopy)
5696               or else (Nkind (Dcopy) = N_Attribute_Reference
5697                         and then
5698                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5699             then
5700
5701                --  If there is no default function, we must still do a full
5702                --  analyze call on the default value, to ensure that all error
5703                --  checks are performed, e.g. those associated with static
5704                --  evaluation. Note: this branch will always be taken if the
5705                --  analyzer is turned off (but we still need the error checks).
5706
5707                --  Note: the setting of parent here is to meet the requirement
5708                --  that we can only analyze the expression while attached to
5709                --  the tree. Really the requirement is that the parent chain
5710                --  be set, we don't actually need to be in the tree.
5711
5712                Set_Parent (Dcopy, Declaration_Node (Formal));
5713                Analyze (Dcopy);
5714
5715                --  Default expressions are resolved with their own type if the
5716                --  context is generic, to avoid anomalies with private types.
5717
5718                if Ekind (Scope (E)) = E_Generic_Package then
5719                   Resolve (Dcopy);
5720                else
5721                   Resolve (Dcopy, Etype (Formal));
5722                end if;
5723
5724                --  If that resolved expression will raise constraint error,
5725                --  then flag the default value as raising constraint error.
5726                --  This allows a proper error message on the calls.
5727
5728                if Raises_Constraint_Error (Dcopy) then
5729                   Set_Raises_Constraint_Error (Default_Value (Formal));
5730                end if;
5731
5732             --  If the default is a parameterless call, we use the name of
5733             --  the called function directly, and there is no body to build.
5734
5735             elsif Nkind (Dcopy) = N_Function_Call
5736               and then No (Parameter_Associations (Dcopy))
5737             then
5738                null;
5739
5740             --  Else construct and analyze the body of a wrapper procedure
5741             --  that contains an object declaration to hold the expression.
5742             --  Given that this is done only to complete the analysis, it
5743             --  simpler to build a procedure than a function which might
5744             --  involve secondary stack expansion.
5745
5746             else
5747                Dnam := Make_Temporary (Loc, 'D');
5748
5749                Dbody :=
5750                  Make_Subprogram_Body (Loc,
5751                    Specification =>
5752                      Make_Procedure_Specification (Loc,
5753                        Defining_Unit_Name => Dnam),
5754
5755                    Declarations => New_List (
5756                      Make_Object_Declaration (Loc,
5757                        Defining_Identifier => Make_Temporary (Loc, 'T'),
5758                        Object_Definition   =>
5759                          New_Occurrence_Of (Etype (Formal), Loc),
5760                        Expression          => New_Copy_Tree (Dcopy))),
5761
5762                    Handled_Statement_Sequence =>
5763                      Make_Handled_Sequence_Of_Statements (Loc,
5764                        Statements => Empty_List));
5765
5766                Set_Scope (Dnam, Scope (E));
5767                Set_Assignment_OK (First (Declarations (Dbody)));
5768                Set_Is_Eliminated (Dnam);
5769                Insert_After (After, Dbody);
5770                Analyze (Dbody);
5771                After := Dbody;
5772             end if;
5773          end if;
5774
5775          Next_Formal (Formal);
5776       end loop;
5777    end Process_Default_Expressions;
5778
5779    ----------------------------------------
5780    -- Set_Component_Alignment_If_Not_Set --
5781    ----------------------------------------
5782
5783    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5784    begin
5785       --  Ignore if not base type, subtypes don't need anything
5786
5787       if Typ /= Base_Type (Typ) then
5788          return;
5789       end if;
5790
5791       --  Do not override existing representation
5792
5793       if Is_Packed (Typ) then
5794          return;
5795
5796       elsif Has_Specified_Layout (Typ) then
5797          return;
5798
5799       elsif Component_Alignment (Typ) /= Calign_Default then
5800          return;
5801
5802       else
5803          Set_Component_Alignment
5804            (Typ, Scope_Stack.Table
5805                   (Scope_Stack.Last).Component_Alignment_Default);
5806       end if;
5807    end Set_Component_Alignment_If_Not_Set;
5808
5809    ------------------
5810    -- Undelay_Type --
5811    ------------------
5812
5813    procedure Undelay_Type (T : Entity_Id) is
5814    begin
5815       Set_Has_Delayed_Freeze (T, False);
5816       Set_Freeze_Node (T, Empty);
5817
5818       --  Since we don't want T to have a Freeze_Node, we don't want its
5819       --  Full_View or Corresponding_Record_Type to have one either.
5820
5821       --  ??? Fundamentally, this whole handling is a kludge. What we really
5822       --  want is to be sure that for an Itype that's part of record R and is a
5823       --  subtype of type T, that it's frozen after the later of the freeze
5824       --  points of R and T. We have no way of doing that directly, so what we
5825       --  do is force most such Itypes to be frozen as part of freezing R via
5826       --  this procedure and only delay the ones that need to be delayed
5827       --  (mostly the designated types of access types that are defined as part
5828       --  of the record).
5829
5830       if Is_Private_Type (T)
5831         and then Present (Full_View (T))
5832         and then Is_Itype (Full_View (T))
5833         and then Is_Record_Type (Scope (Full_View (T)))
5834       then
5835          Undelay_Type (Full_View (T));
5836       end if;
5837
5838       if Is_Concurrent_Type (T)
5839         and then Present (Corresponding_Record_Type (T))
5840         and then Is_Itype (Corresponding_Record_Type (T))
5841         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5842       then
5843          Undelay_Type (Corresponding_Record_Type (T));
5844       end if;
5845    end Undelay_Type;
5846
5847    ------------------
5848    -- Warn_Overlay --
5849    ------------------
5850
5851    procedure Warn_Overlay
5852      (Expr : Node_Id;
5853       Typ  : Entity_Id;
5854       Nam  : Entity_Id)
5855    is
5856       Ent : constant Entity_Id := Entity (Nam);
5857       --  The object to which the address clause applies
5858
5859       Init : Node_Id;
5860       Old  : Entity_Id := Empty;
5861       Decl : Node_Id;
5862
5863    begin
5864       --  No warning if address clause overlay warnings are off
5865
5866       if not Address_Clause_Overlay_Warnings then
5867          return;
5868       end if;
5869
5870       --  No warning if there is an explicit initialization
5871
5872       Init := Original_Node (Expression (Declaration_Node (Ent)));
5873
5874       if Present (Init) and then Comes_From_Source (Init) then
5875          return;
5876       end if;
5877
5878       --  We only give the warning for non-imported entities of a type for
5879       --  which a non-null base init proc is defined, or for objects of access
5880       --  types with implicit null initialization, or when Normalize_Scalars
5881       --  applies and the type is scalar or a string type (the latter being
5882       --  tested for because predefined String types are initialized by inline
5883       --  code rather than by an init_proc). Note that we do not give the
5884       --  warning for Initialize_Scalars, since we suppressed initialization
5885       --  in this case. Also, do not warn if Suppress_Initialization is set.
5886
5887       if Present (Expr)
5888         and then not Is_Imported (Ent)
5889         and then not Initialization_Suppressed (Typ)
5890         and then (Has_Non_Null_Base_Init_Proc (Typ)
5891                    or else Is_Access_Type (Typ)
5892                    or else (Normalize_Scalars
5893                              and then (Is_Scalar_Type (Typ)
5894                                         or else Is_String_Type (Typ))))
5895       then
5896          if Nkind (Expr) = N_Attribute_Reference
5897            and then Is_Entity_Name (Prefix (Expr))
5898          then
5899             Old := Entity (Prefix (Expr));
5900
5901          elsif Is_Entity_Name (Expr)
5902            and then Ekind (Entity (Expr)) = E_Constant
5903          then
5904             Decl := Declaration_Node (Entity (Expr));
5905
5906             if Nkind (Decl) = N_Object_Declaration
5907               and then Present (Expression (Decl))
5908               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5909               and then Is_Entity_Name (Prefix (Expression (Decl)))
5910             then
5911                Old := Entity (Prefix (Expression (Decl)));
5912
5913             elsif Nkind (Expr) = N_Function_Call then
5914                return;
5915             end if;
5916
5917          --  A function call (most likely to To_Address) is probably not an
5918          --  overlay, so skip warning. Ditto if the function call was inlined
5919          --  and transformed into an entity.
5920
5921          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5922             return;
5923          end if;
5924
5925          Decl := Next (Parent (Expr));
5926
5927          --  If a pragma Import follows, we assume that it is for the current
5928          --  target of the address clause, and skip the warning.
5929
5930          if Present (Decl)
5931            and then Nkind (Decl) = N_Pragma
5932            and then Pragma_Name (Decl) = Name_Import
5933          then
5934             return;
5935          end if;
5936
5937          if Present (Old) then
5938             Error_Msg_Node_2 := Old;
5939             Error_Msg_N
5940               ("default initialization of & may modify &?",
5941                Nam);
5942          else
5943             Error_Msg_N
5944               ("default initialization of & may modify overlaid storage?",
5945                Nam);
5946          end if;
5947
5948          --  Add friendly warning if initialization comes from a packed array
5949          --  component.
5950
5951          if Is_Record_Type (Typ)  then
5952             declare
5953                Comp : Entity_Id;
5954
5955             begin
5956                Comp := First_Component (Typ);
5957                while Present (Comp) loop
5958                   if Nkind (Parent (Comp)) = N_Component_Declaration
5959                     and then Present (Expression (Parent (Comp)))
5960                   then
5961                      exit;
5962                   elsif Is_Array_Type (Etype (Comp))
5963                      and then Present (Packed_Array_Type (Etype (Comp)))
5964                   then
5965                      Error_Msg_NE
5966                        ("\packed array component& " &
5967                         "will be initialized to zero?",
5968                         Nam, Comp);
5969                      exit;
5970                   else
5971                      Next_Component (Comp);
5972                   end if;
5973                end loop;
5974             end;
5975          end if;
5976
5977          Error_Msg_N
5978            ("\use pragma Import for & to " &
5979             "suppress initialization (RM B.1(24))?",
5980             Nam);
5981       end if;
5982    end Warn_Overlay;
5983
5984 end Freeze;