gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- You should have received a copy of the GNU General Public License along  --
  19 -- with this program; see file COPYING3.  If not see                        --
  20 -- <http://www.gnu.org/licenses/>.                                          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Elists;   use Elists;
  31 with Errout;   use Errout;
  32 with Exp_Ch3;  use Exp_Ch3;
  33 with Exp_Ch7;  use Exp_Ch7;
  34 with Exp_Disp; use Exp_Disp;
  35 with Exp_Pakd; use Exp_Pakd;
  36 with Exp_Util; use Exp_Util;
  37 with Exp_Tss;  use Exp_Tss;
  38 with Layout;   use Layout;
  39 with Lib;      use Lib;
  40 with Namet;    use Namet;
  41 with Nlists;   use Nlists;
  42 with Nmake;    use Nmake;
  43 with Opt;      use Opt;
  44 with Restrict; use Restrict;
  45 with Rident;   use Rident;
  46 with Sem;      use Sem;
  47 with Sem_Aux;  use Sem_Aux;
  48 with Sem_Cat;  use Sem_Cat;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch7;  use Sem_Ch7;
  51 with Sem_Ch8;  use Sem_Ch8;
  52 with Sem_Ch13; use Sem_Ch13;
  53 with Sem_Eval; use Sem_Eval;
  54 with Sem_Mech; use Sem_Mech;
  55 with Sem_Prag; use Sem_Prag;
  56 with Sem_Res;  use Sem_Res;
  57 with Sem_Util; use Sem_Util;
  58 with Sinfo;    use Sinfo;
  59 with Snames;   use Snames;
  60 with Stand;    use Stand;
  61 with Targparm; use Targparm;
  62 with Tbuild;   use Tbuild;
  63 with Ttypes;   use Ttypes;
  64 with Uintp;    use Uintp;
  65 with Urealp;   use Urealp;
  66
  67 package body Freeze is
  68
  69    -----------------------
  70    -- Local Subprograms --
  71    -----------------------
  72
  73    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  74    --  Typ is a type that is being frozen. If no size clause is given,
  75    --  but a default Esize has been computed, then this default Esize is
  76    --  adjusted up if necessary to be consistent with a given alignment,
  77    --  but never to a value greater than Long_Long_Integer'Size. This
  78    --  is used for all discrete types and for fixed-point types.
  79
  80    procedure Build_And_Analyze_Renamed_Body
  81      (Decl  : Node_Id;
  82       New_S : Entity_Id;
  83       After : in out Node_Id);
  84    --  Build body for a renaming declaration, insert in tree and analyze
  85
  86    procedure Check_Address_Clause (E : Entity_Id);
  87    --  Apply legality checks to address clauses for object declarations,
  88    --  at the point the object is frozen.
  89
  90    procedure Check_Strict_Alignment (E : Entity_Id);
  91    --  E is a base type. If E is tagged or has a component that is aliased
  92    --  or tagged or contains something this is aliased or tagged, set
  93    --  Strict_Alignment.
  94
  95    procedure Check_Unsigned_Type (E : Entity_Id);
  96    pragma Inline (Check_Unsigned_Type);
  97    --  If E is a fixed-point or discrete type, then all the necessary work
  98    --  to freeze it is completed except for possible setting of the flag
  99    --  Is_Unsigned_Type, which is done by this procedure. The call has no
 100    --  effect if the entity E is not a discrete or fixed-point type.
 101
 102    procedure Freeze_And_Append
 103      (Ent    : Entity_Id;
 104       Loc    : Source_Ptr;
 105       Result : in out List_Id);
 106    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 107    --  nodes to Result, modifying Result from No_List if necessary.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing
 142    --  of default expressions at the point where all types are known to be
 143    --  frozen. The expressions must be analyzed in full, to make sure that
 144    --  all error processing is done (they have only been pre-analyzed). If
 145    --  the expression is not an entity or literal, its analysis may generate
 146    --  code which must not be executed. In that case we build a function
 147    --  body to hold that code. This wrapper function serves no other purpose
 148    --  (it used to be called to evaluate the default, but now the default is
 149    --  inlined at each point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine
 153    --  sets the default component alignment from the scope stack values
 154    --  if the alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype.
 166    --  We don't want this to have a Freeze_Node, so ensure it doesn't.
 167    --  Do the same for any Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrisic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere.
 365
 366       if Ekind_In (Old_S, E_Function, E_Procedure)
 367         and then Nkind (Decl) = N_Subprogram_Declaration
 368       then
 369          Set_Body_To_Inline (Decl, Old_S);
 370       end if;
 371
 372       --  The body generated for this renaming is an internal artifact, and
 373       --  does not  constitute a freeze point for the called entity.
 374
 375       Set_Must_Not_Freeze (Call_Name);
 376
 377       Formal := First_Formal (Defining_Entity (Decl));
 378
 379       if Present (Pref) then
 380          declare
 381             Pref_Type : constant Entity_Id := Etype (Pref);
 382             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 383
 384          begin
 385             --  The controlling formal may be an access parameter, or the
 386             --  actual may be an access value, so adjust accordingly.
 387
 388             if Is_Access_Type (Pref_Type)
 389               and then not Is_Access_Type (Form_Type)
 390             then
 391                Actuals := New_List
 392                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 393
 394             elsif Is_Access_Type (Form_Type)
 395               and then not Is_Access_Type (Pref)
 396             then
 397                Actuals := New_List
 398                  (Make_Attribute_Reference (Loc,
 399                    Attribute_Name => Name_Access,
 400                    Prefix => Relocate_Node (Pref)));
 401             else
 402                Actuals := New_List (Pref);
 403             end if;
 404          end;
 405
 406       elsif Present (Formal) then
 407          Actuals := New_List;
 408
 409       else
 410          Actuals := No_List;
 411       end if;
 412
 413       if Present (Formal) then
 414          while Present (Formal) loop
 415             Append (New_Reference_To (Formal, Loc), Actuals);
 416             Next_Formal (Formal);
 417          end loop;
 418       end if;
 419
 420       --  If the renamed entity is an entry, inherit its profile. For other
 421       --  renamings as bodies, both profiles must be subtype conformant, so it
 422       --  is not necessary to replace the profile given in the declaration.
 423       --  However, default values that are aggregates are rewritten when
 424       --  partially analyzed, so we recover the original aggregate to insure
 425       --  that subsequent conformity checking works. Similarly, if the default
 426       --  expression was constant-folded, recover the original expression.
 427
 428       Formal := First_Formal (Defining_Entity (Decl));
 429
 430       if Present (Formal) then
 431          O_Formal := First_Formal (Old_S);
 432          Param_Spec := First (Parameter_Specifications (Spec));
 433          while Present (Formal) loop
 434             if Is_Entry (Old_S) then
 435                if Nkind (Parameter_Type (Param_Spec)) /=
 436                                                     N_Access_Definition
 437                then
 438                   Set_Etype (Formal, Etype (O_Formal));
 439                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 440                end if;
 441
 442             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 443               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 444                                            Nkind (Default_Value (O_Formal))
 445             then
 446                Set_Expression (Param_Spec,
 447                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 448             end if;
 449
 450             Next_Formal (Formal);
 451             Next_Formal (O_Formal);
 452             Next (Param_Spec);
 453          end loop;
 454       end if;
 455
 456       --  If the renamed entity is a function, the generated body contains a
 457       --  return statement. Otherwise, build a procedure call. If the entity is
 458       --  an entry, subsequent analysis of the call will transform it into the
 459       --  proper entry or protected operation call. If the renamed entity is
 460       --  a character literal, return it directly.
 461
 462       if Ekind (Old_S) = E_Function
 463         or else Ekind (Old_S) = E_Operator
 464         or else (Ekind (Old_S) = E_Subprogram_Type
 465                   and then Etype (Old_S) /= Standard_Void_Type)
 466       then
 467          Call_Node :=
 468            Make_Simple_Return_Statement (Loc,
 469               Expression =>
 470                 Make_Function_Call (Loc,
 471                   Name => Call_Name,
 472                   Parameter_Associations => Actuals));
 473
 474       elsif Ekind (Old_S) = E_Enumeration_Literal then
 475          Call_Node :=
 476            Make_Simple_Return_Statement (Loc,
 477               Expression => New_Occurrence_Of (Old_S, Loc));
 478
 479       elsif Nkind (Nam) = N_Character_Literal then
 480          Call_Node :=
 481            Make_Simple_Return_Statement (Loc,
 482              Expression => Call_Name);
 483
 484       else
 485          Call_Node :=
 486            Make_Procedure_Call_Statement (Loc,
 487              Name => Call_Name,
 488              Parameter_Associations => Actuals);
 489       end if;
 490
 491       --  Create entities for subprogram body and formals
 492
 493       Set_Defining_Unit_Name (Spec,
 494         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 495
 496       Param_Spec := First (Parameter_Specifications (Spec));
 497       while Present (Param_Spec) loop
 498          Set_Defining_Identifier (Param_Spec,
 499            Make_Defining_Identifier (Loc,
 500              Chars => Chars (Defining_Identifier (Param_Spec))));
 501          Next (Param_Spec);
 502       end loop;
 503
 504       Body_Node :=
 505         Make_Subprogram_Body (Loc,
 506           Specification => Spec,
 507           Declarations => New_List,
 508           Handled_Statement_Sequence =>
 509             Make_Handled_Sequence_Of_Statements (Loc,
 510               Statements => New_List (Call_Node)));
 511
 512       if Nkind (Decl) /= N_Subprogram_Declaration then
 513          Rewrite (N,
 514            Make_Subprogram_Declaration (Loc,
 515              Specification => Specification (N)));
 516       end if;
 517
 518       --  Link the body to the entity whose declaration it completes. If
 519       --  the body is analyzed when the renamed entity is frozen, it may
 520       --  be necessary to restore the proper scope (see package Exp_Ch13).
 521
 522       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 523         and then Present (Corresponding_Spec (N))
 524       then
 525          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 526       else
 527          Set_Corresponding_Spec (Body_Node, New_S);
 528       end if;
 529
 530       return Body_Node;
 531    end Build_Renamed_Body;
 532
 533    --------------------------
 534    -- Check_Address_Clause --
 535    --------------------------
 536
 537    procedure Check_Address_Clause (E : Entity_Id) is
 538       Addr : constant Node_Id   := Address_Clause (E);
 539       Expr : Node_Id;
 540       Decl : constant Node_Id   := Declaration_Node (E);
 541       Typ  : constant Entity_Id := Etype (E);
 542
 543    begin
 544       if Present (Addr) then
 545          Expr := Expression (Addr);
 546
 547          if Needs_Constant_Address (Decl, Typ) then
 548             Check_Constant_Address_Clause (Expr, E);
 549
 550             --  Has_Delayed_Freeze was set on E when the address clause was
 551             --  analyzed. Reset the flag now unless freeze actions were
 552             --  attached to it in the mean time.
 553
 554             if No (Freeze_Node (E)) then
 555                Set_Has_Delayed_Freeze (E, False);
 556             end if;
 557          end if;
 558
 559          --  If Rep_Clauses are to be ignored, remove address clause from
 560          --  list attached to entity, because it may be illegal for gigi,
 561          --  for example by breaking order of elaboration..
 562
 563          if Ignore_Rep_Clauses then
 564             declare
 565                Rep : Node_Id;
 566
 567             begin
 568                Rep := First_Rep_Item (E);
 569
 570                if Rep = Addr then
 571                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 572
 573                else
 574                   while Present (Rep)
 575                     and then Next_Rep_Item (Rep) /= Addr
 576                   loop
 577                      Rep := Next_Rep_Item (Rep);
 578                   end loop;
 579                end if;
 580
 581                if Present (Rep) then
 582                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 583                end if;
 584             end;
 585
 586             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 587
 588          elsif not Error_Posted (Expr)
 589            and then not Needs_Finalization (Typ)
 590          then
 591             Warn_Overlay (Expr, Typ, Name (Addr));
 592          end if;
 593       end if;
 594    end Check_Address_Clause;
 595
 596    -----------------------------
 597    -- Check_Compile_Time_Size --
 598    -----------------------------
 599
 600    procedure Check_Compile_Time_Size (T : Entity_Id) is
 601
 602       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 603       --  Sets the compile time known size (32 bits or less) in the Esize
 604       --  field, of T checking for a size clause that was given which attempts
 605       --  to give a smaller size, and also checking for an alignment clause.
 606
 607       function Size_Known (T : Entity_Id) return Boolean;
 608       --  Recursive function that does all the work
 609
 610       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 611       --  If T is a constrained subtype, its size is not known if any of its
 612       --  discriminant constraints is not static and it is not a null record.
 613       --  The test is conservative and doesn't check that the components are
 614       --  in fact constrained by non-static discriminant values. Could be made
 615       --  more precise ???
 616
 617       --------------------
 618       -- Set_Small_Size --
 619       --------------------
 620
 621       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 622       begin
 623          if S > 32 then
 624             return;
 625
 626          --  Don't bother if alignment clause with a value other than 1 is
 627          --  present, because size may be padded up to meet back end alignment
 628          --  requirements, and only the back end knows the rules!
 629
 630          elsif Known_Alignment (T) and then Alignment (T) /= 1 then
 631             return;
 632
 633          --  Check for bad size clause given
 634
 635          elsif Has_Size_Clause (T) then
 636             if RM_Size (T) < S then
 637                Error_Msg_Uint_1 := S;
 638                Error_Msg_NE
 639                  ("size for& too small, minimum allowed is ^",
 640                   Size_Clause (T), T);
 641
 642             elsif Unknown_Esize (T) then
 643                Set_Esize (T, S);
 644             end if;
 645
 646          --  Set sizes if not set already
 647
 648          else
 649             if Unknown_Esize (T) then
 650                Set_Esize (T, S);
 651             end if;
 652
 653             if Unknown_RM_Size (T) then
 654                Set_RM_Size (T, S);
 655             end if;
 656          end if;
 657       end Set_Small_Size;
 658
 659       ----------------
 660       -- Size_Known --
 661       ----------------
 662
 663       function Size_Known (T : Entity_Id) return Boolean is
 664          Index : Entity_Id;
 665          Comp  : Entity_Id;
 666          Ctyp  : Entity_Id;
 667          Low   : Node_Id;
 668          High  : Node_Id;
 669
 670       begin
 671          if Size_Known_At_Compile_Time (T) then
 672             return True;
 673
 674          --  Always True for scalar types. This is true even for generic formal
 675          --  scalar types. We used to return False in the latter case, but the
 676          --  size is known at compile time, even in the template, we just do
 677          --  not know the exact size but that's not the point of this routine.
 678
 679          elsif Is_Scalar_Type (T)
 680            or else Is_Task_Type (T)
 681          then
 682             return True;
 683
 684          --  Array types
 685
 686          elsif Is_Array_Type (T) then
 687
 688             --  String literals always have known size, and we can set it
 689
 690             if Ekind (T) = E_String_Literal_Subtype then
 691                Set_Small_Size (T, Component_Size (T)
 692                                * String_Literal_Length (T));
 693                return True;
 694
 695             --  Unconstrained types never have known at compile time size
 696
 697             elsif not Is_Constrained (T) then
 698                return False;
 699
 700             --  Don't do any recursion on type with error posted, since we may
 701             --  have a malformed type that leads us into a loop.
 702
 703             elsif Error_Posted (T) then
 704                return False;
 705
 706             --  Otherwise if component size unknown, then array size unknown
 707
 708             elsif not Size_Known (Component_Type (T)) then
 709                return False;
 710             end if;
 711
 712             --  Check for all indexes static, and also compute possible size
 713             --  (in case it is less than 32 and may be packable).
 714
 715             declare
 716                Esiz : Uint := Component_Size (T);
 717                Dim  : Uint;
 718
 719             begin
 720                Index := First_Index (T);
 721                while Present (Index) loop
 722                   if Nkind (Index) = N_Range then
 723                      Get_Index_Bounds (Index, Low, High);
 724
 725                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 726                      return False;
 727
 728                   else
 729                      Low  := Type_Low_Bound (Etype (Index));
 730                      High := Type_High_Bound (Etype (Index));
 731                   end if;
 732
 733                   if not Compile_Time_Known_Value (Low)
 734                     or else not Compile_Time_Known_Value (High)
 735                     or else Etype (Index) = Any_Type
 736                   then
 737                      return False;
 738
 739                   else
 740                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 741
 742                      if Dim >= 0 then
 743                         Esiz := Esiz * Dim;
 744                      else
 745                         Esiz := Uint_0;
 746                      end if;
 747                   end if;
 748
 749                   Next_Index (Index);
 750                end loop;
 751
 752                Set_Small_Size (T, Esiz);
 753                return True;
 754             end;
 755
 756          --  Access types always have known at compile time sizes
 757
 758          elsif Is_Access_Type (T) then
 759             return True;
 760
 761          --  For non-generic private types, go to underlying type if present
 762
 763          elsif Is_Private_Type (T)
 764            and then not Is_Generic_Type (T)
 765            and then Present (Underlying_Type (T))
 766          then
 767             --  Don't do any recursion on type with error posted, since we may
 768             --  have a malformed type that leads us into a loop.
 769
 770             if Error_Posted (T) then
 771                return False;
 772             else
 773                return Size_Known (Underlying_Type (T));
 774             end if;
 775
 776          --  Record types
 777
 778          elsif Is_Record_Type (T) then
 779
 780             --  A class-wide type is never considered to have a known size
 781
 782             if Is_Class_Wide_Type (T) then
 783                return False;
 784
 785             --  A subtype of a variant record must not have non-static
 786             --  discriminanted components.
 787
 788             elsif T /= Base_Type (T)
 789               and then not Static_Discriminated_Components (T)
 790             then
 791                return False;
 792
 793             --  Don't do any recursion on type with error posted, since we may
 794             --  have a malformed type that leads us into a loop.
 795
 796             elsif Error_Posted (T) then
 797                return False;
 798             end if;
 799
 800             --  Now look at the components of the record
 801
 802             declare
 803                --  The following two variables are used to keep track of the
 804                --  size of packed records if we can tell the size of the packed
 805                --  record in the front end. Packed_Size_Known is True if so far
 806                --  we can figure out the size. It is initialized to True for a
 807                --  packed record, unless the record has discriminants. The
 808                --  reason we eliminate the discriminated case is that we don't
 809                --  know the way the back end lays out discriminated packed
 810                --  records. If Packed_Size_Known is True, then Packed_Size is
 811                --  the size in bits so far.
 812
 813                Packed_Size_Known : Boolean :=
 814                                      Is_Packed (T)
 815                                        and then not Has_Discriminants (T);
 816
 817                Packed_Size : Uint := Uint_0;
 818
 819             begin
 820                --  Test for variant part present
 821
 822                if Has_Discriminants (T)
 823                  and then Present (Parent (T))
 824                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 825                  and then Nkind (Type_Definition (Parent (T))) =
 826                                                N_Record_Definition
 827                  and then not Null_Present (Type_Definition (Parent (T)))
 828                  and then Present (Variant_Part
 829                             (Component_List (Type_Definition (Parent (T)))))
 830                then
 831                   --  If variant part is present, and type is unconstrained,
 832                   --  then we must have defaulted discriminants, or a size
 833                   --  clause must be present for the type, or else the size
 834                   --  is definitely not known at compile time.
 835
 836                   if not Is_Constrained (T)
 837                     and then
 838                       No (Discriminant_Default_Value (First_Discriminant (T)))
 839                     and then Unknown_Esize (T)
 840                   then
 841                      return False;
 842                   end if;
 843                end if;
 844
 845                --  Loop through components
 846
 847                Comp := First_Component_Or_Discriminant (T);
 848                while Present (Comp) loop
 849                   Ctyp := Etype (Comp);
 850
 851                   --  We do not know the packed size if there is a component
 852                   --  clause present (we possibly could, but this would only
 853                   --  help in the case of a record with partial rep clauses.
 854                   --  That's because in the case of full rep clauses, the
 855                   --  size gets figured out anyway by a different circuit).
 856
 857                   if Present (Component_Clause (Comp)) then
 858                      Packed_Size_Known := False;
 859                   end if;
 860
 861                   --  We need to identify a component that is an array where
 862                   --  the index type is an enumeration type with non-standard
 863                   --  representation, and some bound of the type depends on a
 864                   --  discriminant.
 865
 866                   --  This is because gigi computes the size by doing a
 867                   --  substitution of the appropriate discriminant value in
 868                   --  the size expression for the base type, and gigi is not
 869                   --  clever enough to evaluate the resulting expression (which
 870                   --  involves a call to rep_to_pos) at compile time.
 871
 872                   --  It would be nice if gigi would either recognize that
 873                   --  this expression can be computed at compile time, or
 874                   --  alternatively figured out the size from the subtype
 875                   --  directly, where all the information is at hand ???
 876
 877                   if Is_Array_Type (Etype (Comp))
 878                     and then Present (Packed_Array_Type (Etype (Comp)))
 879                   then
 880                      declare
 881                         Ocomp  : constant Entity_Id :=
 882                                    Original_Record_Component (Comp);
 883                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 884                         Ind    : Node_Id;
 885                         Indtyp : Entity_Id;
 886                         Lo, Hi : Node_Id;
 887
 888                      begin
 889                         Ind := First_Index (OCtyp);
 890                         while Present (Ind) loop
 891                            Indtyp := Etype (Ind);
 892
 893                            if Is_Enumeration_Type (Indtyp)
 894                              and then Has_Non_Standard_Rep (Indtyp)
 895                            then
 896                               Lo := Type_Low_Bound  (Indtyp);
 897                               Hi := Type_High_Bound (Indtyp);
 898
 899                               if Is_Entity_Name (Lo)
 900                                 and then Ekind (Entity (Lo)) = E_Discriminant
 901                               then
 902                                  return False;
 903
 904                               elsif Is_Entity_Name (Hi)
 905                                 and then Ekind (Entity (Hi)) = E_Discriminant
 906                               then
 907                                  return False;
 908                               end if;
 909                            end if;
 910
 911                            Next_Index (Ind);
 912                         end loop;
 913                      end;
 914                   end if;
 915
 916                   --  Clearly size of record is not known if the size of one of
 917                   --  the components is not known.
 918
 919                   if not Size_Known (Ctyp) then
 920                      return False;
 921                   end if;
 922
 923                   --  Accumulate packed size if possible
 924
 925                   if Packed_Size_Known then
 926
 927                      --  We can only deal with elementary types, since for
 928                      --  non-elementary components, alignment enters into the
 929                      --  picture, and we don't know enough to handle proper
 930                      --  alignment in this context. Packed arrays count as
 931                      --  elementary if the representation is a modular type.
 932
 933                      if Is_Elementary_Type (Ctyp)
 934                        or else (Is_Array_Type (Ctyp)
 935                                  and then Present (Packed_Array_Type (Ctyp))
 936                                  and then Is_Modular_Integer_Type
 937                                             (Packed_Array_Type (Ctyp)))
 938                      then
 939                         --  If RM_Size is known and static, then we can keep
 940                         --  accumulating the packed size.
 941
 942                         if Known_Static_RM_Size (Ctyp) then
 943
 944                            --  A little glitch, to be removed sometime ???
 945                            --  gigi does not understand zero sizes yet.
 946
 947                            if RM_Size (Ctyp) = Uint_0 then
 948                               Packed_Size_Known := False;
 949
 950                            --  Normal case where we can keep accumulating the
 951                            --  packed array size.
 952
 953                            else
 954                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 955                            end if;
 956
 957                         --  If we have a field whose RM_Size is not known then
 958                         --  we can't figure out the packed size here.
 959
 960                         else
 961                            Packed_Size_Known := False;
 962                         end if;
 963
 964                      --  If we have a non-elementary type we can't figure out
 965                      --  the packed array size (alignment issues).
 966
 967                      else
 968                         Packed_Size_Known := False;
 969                      end if;
 970                   end if;
 971
 972                   Next_Component_Or_Discriminant (Comp);
 973                end loop;
 974
 975                if Packed_Size_Known then
 976                   Set_Small_Size (T, Packed_Size);
 977                end if;
 978
 979                return True;
 980             end;
 981
 982          --  All other cases, size not known at compile time
 983
 984          else
 985             return False;
 986          end if;
 987       end Size_Known;
 988
 989       -------------------------------------
 990       -- Static_Discriminated_Components --
 991       -------------------------------------
 992
 993       function Static_Discriminated_Components
 994         (T : Entity_Id) return Boolean
 995       is
 996          Constraint : Elmt_Id;
 997
 998       begin
 999          if Has_Discriminants (T)
1000            and then Present (Discriminant_Constraint (T))
1001            and then Present (First_Component (T))
1002          then
1003             Constraint := First_Elmt (Discriminant_Constraint (T));
1004             while Present (Constraint) loop
1005                if not Compile_Time_Known_Value (Node (Constraint)) then
1006                   return False;
1007                end if;
1008
1009                Next_Elmt (Constraint);
1010             end loop;
1011          end if;
1012
1013          return True;
1014       end Static_Discriminated_Components;
1015
1016    --  Start of processing for Check_Compile_Time_Size
1017
1018    begin
1019       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1020    end Check_Compile_Time_Size;
1021
1022    -----------------------------
1023    -- Check_Debug_Info_Needed --
1024    -----------------------------
1025
1026    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1027    begin
1028       if Debug_Info_Off (T) then
1029          return;
1030
1031       elsif Comes_From_Source (T)
1032         or else Debug_Generated_Code
1033         or else Debug_Flag_VV
1034         or else Needs_Debug_Info (T)
1035       then
1036          Set_Debug_Info_Needed (T);
1037       end if;
1038    end Check_Debug_Info_Needed;
1039
1040    ----------------------------
1041    -- Check_Strict_Alignment --
1042    ----------------------------
1043
1044    procedure Check_Strict_Alignment (E : Entity_Id) is
1045       Comp  : Entity_Id;
1046
1047    begin
1048       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1049          Set_Strict_Alignment (E);
1050
1051       elsif Is_Array_Type (E) then
1052          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1053
1054       elsif Is_Record_Type (E) then
1055          if Is_Limited_Record (E) then
1056             Set_Strict_Alignment (E);
1057             return;
1058          end if;
1059
1060          Comp := First_Component (E);
1061
1062          while Present (Comp) loop
1063             if not Is_Type (Comp)
1064               and then (Strict_Alignment (Etype (Comp))
1065                          or else Is_Aliased (Comp))
1066             then
1067                Set_Strict_Alignment (E);
1068                return;
1069             end if;
1070
1071             Next_Component (Comp);
1072          end loop;
1073       end if;
1074    end Check_Strict_Alignment;
1075
1076    -------------------------
1077    -- Check_Unsigned_Type --
1078    -------------------------
1079
1080    procedure Check_Unsigned_Type (E : Entity_Id) is
1081       Ancestor : Entity_Id;
1082       Lo_Bound : Node_Id;
1083       Btyp     : Entity_Id;
1084
1085    begin
1086       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1087          return;
1088       end if;
1089
1090       --  Do not attempt to analyze case where range was in error
1091
1092       if No (Scalar_Range (E))
1093         or else Error_Posted (Scalar_Range (E))
1094       then
1095          return;
1096       end if;
1097
1098       --  The situation that is non trivial is something like
1099
1100       --     subtype x1 is integer range -10 .. +10;
1101       --     subtype x2 is x1 range 0 .. V1;
1102       --     subtype x3 is x2 range V2 .. V3;
1103       --     subtype x4 is x3 range V4 .. V5;
1104
1105       --  where Vn are variables. Here the base type is signed, but we still
1106       --  know that x4 is unsigned because of the lower bound of x2.
1107
1108       --  The only way to deal with this is to look up the ancestor chain
1109
1110       Ancestor := E;
1111       loop
1112          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1113             return;
1114          end if;
1115
1116          Lo_Bound := Type_Low_Bound (Ancestor);
1117
1118          if Compile_Time_Known_Value (Lo_Bound) then
1119
1120             if Expr_Rep_Value (Lo_Bound) >= 0 then
1121                Set_Is_Unsigned_Type (E, True);
1122             end if;
1123
1124             return;
1125
1126          else
1127             Ancestor := Ancestor_Subtype (Ancestor);
1128
1129             --  If no ancestor had a static lower bound, go to base type
1130
1131             if No (Ancestor) then
1132
1133                --  Note: the reason we still check for a compile time known
1134                --  value for the base type is that at least in the case of
1135                --  generic formals, we can have bounds that fail this test,
1136                --  and there may be other cases in error situations.
1137
1138                Btyp := Base_Type (E);
1139
1140                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1141                   return;
1142                end if;
1143
1144                Lo_Bound := Type_Low_Bound (Base_Type (E));
1145
1146                if Compile_Time_Known_Value (Lo_Bound)
1147                  and then Expr_Rep_Value (Lo_Bound) >= 0
1148                then
1149                   Set_Is_Unsigned_Type (E, True);
1150                end if;
1151
1152                return;
1153             end if;
1154          end if;
1155       end loop;
1156    end Check_Unsigned_Type;
1157
1158    -------------------------
1159    -- Is_Atomic_Aggregate --
1160    -------------------------
1161
1162    function  Is_Atomic_Aggregate
1163      (E   : Entity_Id;
1164       Typ : Entity_Id) return Boolean
1165    is
1166       Loc   : constant Source_Ptr := Sloc (E);
1167       New_N : Node_Id;
1168       Par   : Node_Id;
1169       Temp  : Entity_Id;
1170
1171    begin
1172       Par := Parent (E);
1173
1174       --  Array may be qualified, so find outer context
1175
1176       if Nkind (Par) = N_Qualified_Expression then
1177          Par := Parent (Par);
1178       end if;
1179
1180       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1181         and then Comes_From_Source (Par)
1182       then
1183          Temp := Make_Temporary (Loc, 'T', E);
1184          New_N :=
1185            Make_Object_Declaration (Loc,
1186              Defining_Identifier => Temp,
1187              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1188              Expression          => Relocate_Node (E));
1189          Insert_Before (Par, New_N);
1190          Analyze (New_N);
1191
1192          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1193          return True;
1194
1195       else
1196          return False;
1197       end if;
1198    end Is_Atomic_Aggregate;
1199
1200    ----------------
1201    -- Freeze_All --
1202    ----------------
1203
1204    --  Note: the easy coding for this procedure would be to just build a
1205    --  single list of freeze nodes and then insert them and analyze them
1206    --  all at once. This won't work, because the analysis of earlier freeze
1207    --  nodes may recursively freeze types which would otherwise appear later
1208    --  on in the freeze list. So we must analyze and expand the freeze nodes
1209    --  as they are generated.
1210
1211    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1212       Loc   : constant Source_Ptr := Sloc (After);
1213       E     : Entity_Id;
1214       Decl  : Node_Id;
1215
1216       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1217       --  This is the internal recursive routine that does freezing of entities
1218       --  (but NOT the analysis of default expressions, which should not be
1219       --  recursive, we don't want to analyze those till we are sure that ALL
1220       --  the types are frozen).
1221
1222       --------------------
1223       -- Freeze_All_Ent --
1224       --------------------
1225
1226       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1227          E     : Entity_Id;
1228          Flist : List_Id;
1229          Lastn : Node_Id;
1230
1231          procedure Process_Flist;
1232          --  If freeze nodes are present, insert and analyze, and reset cursor
1233          --  for next insertion.
1234
1235          -------------------
1236          -- Process_Flist --
1237          -------------------
1238
1239          procedure Process_Flist is
1240          begin
1241             if Is_Non_Empty_List (Flist) then
1242                Lastn := Next (After);
1243                Insert_List_After_And_Analyze (After, Flist);
1244
1245                if Present (Lastn) then
1246                   After := Prev (Lastn);
1247                else
1248                   After := Last (List_Containing (After));
1249                end if;
1250             end if;
1251          end Process_Flist;
1252
1253       --  Start or processing for Freeze_All_Ent
1254
1255       begin
1256          E := From;
1257          while Present (E) loop
1258
1259             --  If the entity is an inner package which is not a package
1260             --  renaming, then its entities must be frozen at this point. Note
1261             --  that such entities do NOT get frozen at the end of the nested
1262             --  package itself (only library packages freeze).
1263
1264             --  Same is true for task declarations, where anonymous records
1265             --  created for entry parameters must be frozen.
1266
1267             if Ekind (E) = E_Package
1268               and then No (Renamed_Object (E))
1269               and then not Is_Child_Unit (E)
1270               and then not Is_Frozen (E)
1271             then
1272                Push_Scope (E);
1273                Install_Visible_Declarations (E);
1274                Install_Private_Declarations (E);
1275
1276                Freeze_All (First_Entity (E), After);
1277
1278                End_Package_Scope (E);
1279
1280             elsif Ekind (E) in Task_Kind
1281               and then
1282                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1283                    or else
1284                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1285             then
1286                Push_Scope (E);
1287                Freeze_All (First_Entity (E), After);
1288                End_Scope;
1289
1290             --  For a derived tagged type, we must ensure that all the
1291             --  primitive operations of the parent have been frozen, so that
1292             --  their addresses will be in the parent's dispatch table at the
1293             --  point it is inherited.
1294
1295             elsif Ekind (E) = E_Record_Type
1296               and then Is_Tagged_Type (E)
1297               and then Is_Tagged_Type (Etype (E))
1298               and then Is_Derived_Type (E)
1299             then
1300                declare
1301                   Prim_List : constant Elist_Id :=
1302                                Primitive_Operations (Etype (E));
1303
1304                   Prim : Elmt_Id;
1305                   Subp : Entity_Id;
1306
1307                begin
1308                   Prim  := First_Elmt (Prim_List);
1309                   while Present (Prim) loop
1310                      Subp := Node (Prim);
1311
1312                      if Comes_From_Source (Subp)
1313                        and then not Is_Frozen (Subp)
1314                      then
1315                         Flist := Freeze_Entity (Subp, Loc);
1316                         Process_Flist;
1317                      end if;
1318
1319                      Next_Elmt (Prim);
1320                   end loop;
1321                end;
1322             end if;
1323
1324             if not Is_Frozen (E) then
1325                Flist := Freeze_Entity (E, Loc);
1326                Process_Flist;
1327             end if;
1328
1329             --  If an incomplete type is still not frozen, this may be a
1330             --  premature freezing because of a body declaration that follows.
1331             --  Indicate where the freezing took place.
1332
1333             --  If the freezing is caused by the end of the current declarative
1334             --  part, it is a Taft Amendment type, and there is no error.
1335
1336             if not Is_Frozen (E)
1337               and then Ekind (E) = E_Incomplete_Type
1338             then
1339                declare
1340                   Bod : constant Node_Id := Next (After);
1341
1342                begin
1343                   if (Nkind_In (Bod, N_Subprogram_Body,
1344                                      N_Entry_Body,
1345                                      N_Package_Body,
1346                                      N_Protected_Body,
1347                                      N_Task_Body)
1348                         or else Nkind (Bod) in N_Body_Stub)
1349                      and then
1350                        List_Containing (After) = List_Containing (Parent (E))
1351                   then
1352                      Error_Msg_Sloc := Sloc (Next (After));
1353                      Error_Msg_NE
1354                        ("type& is frozen# before its full declaration",
1355                          Parent (E), E);
1356                   end if;
1357                end;
1358             end if;
1359
1360             Next_Entity (E);
1361          end loop;
1362       end Freeze_All_Ent;
1363
1364    --  Start of processing for Freeze_All
1365
1366    begin
1367       Freeze_All_Ent (From, After);
1368
1369       --  Now that all types are frozen, we can deal with default expressions
1370       --  that require us to build a default expression functions. This is the
1371       --  point at which such functions are constructed (after all types that
1372       --  might be used in such expressions have been frozen).
1373
1374       --  For subprograms that are renaming_as_body, we create the wrapper
1375       --  bodies as needed.
1376
1377       --  We also add finalization chains to access types whose designated
1378       --  types are controlled. This is normally done when freezing the type,
1379       --  but this misses recursive type definitions where the later members
1380       --  of the recursion introduce controlled components.
1381
1382       --  Loop through entities
1383
1384       E := From;
1385       while Present (E) loop
1386          if Is_Subprogram (E) then
1387
1388             if not Default_Expressions_Processed (E) then
1389                Process_Default_Expressions (E, After);
1390             end if;
1391
1392             if not Has_Completion (E) then
1393                Decl := Unit_Declaration_Node (E);
1394
1395                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1396                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1397
1398                elsif Nkind (Decl) = N_Subprogram_Declaration
1399                  and then Present (Corresponding_Body (Decl))
1400                  and then
1401                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1402                                           = N_Subprogram_Renaming_Declaration
1403                then
1404                   Build_And_Analyze_Renamed_Body
1405                     (Decl, Corresponding_Body (Decl), After);
1406                end if;
1407             end if;
1408
1409          elsif Ekind (E) in Task_Kind
1410            and then
1411              (Nkind (Parent (E)) = N_Task_Type_Declaration
1412                 or else
1413               Nkind (Parent (E)) = N_Single_Task_Declaration)
1414          then
1415             declare
1416                Ent : Entity_Id;
1417
1418             begin
1419                Ent := First_Entity (E);
1420                while Present (Ent) loop
1421                   if Is_Entry (Ent)
1422                     and then not Default_Expressions_Processed (Ent)
1423                   then
1424                      Process_Default_Expressions (Ent, After);
1425                   end if;
1426
1427                   Next_Entity (Ent);
1428                end loop;
1429             end;
1430
1431          elsif Is_Access_Type (E)
1432            and then Comes_From_Source (E)
1433            and then Ekind (Directly_Designated_Type (E)) = E_Incomplete_Type
1434            and then Needs_Finalization (Designated_Type (E))
1435            and then No (Associated_Final_Chain (E))
1436          then
1437             Build_Final_List (Parent (E), E);
1438          end if;
1439
1440          Next_Entity (E);
1441       end loop;
1442    end Freeze_All;
1443
1444    -----------------------
1445    -- Freeze_And_Append --
1446    -----------------------
1447
1448    procedure Freeze_And_Append
1449      (Ent    : Entity_Id;
1450       Loc    : Source_Ptr;
1451       Result : in out List_Id)
1452    is
1453       L : constant List_Id := Freeze_Entity (Ent, Loc);
1454    begin
1455       if Is_Non_Empty_List (L) then
1456          if Result = No_List then
1457             Result := L;
1458          else
1459             Append_List (L, Result);
1460          end if;
1461       end if;
1462    end Freeze_And_Append;
1463
1464    -------------------
1465    -- Freeze_Before --
1466    -------------------
1467
1468    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1469       Freeze_Nodes : constant List_Id := Freeze_Entity (T, Sloc (N));
1470    begin
1471       if Is_Non_Empty_List (Freeze_Nodes) then
1472          Insert_Actions (N, Freeze_Nodes);
1473       end if;
1474    end Freeze_Before;
1475
1476    -------------------
1477    -- Freeze_Entity --
1478    -------------------
1479
1480    function Freeze_Entity (E : Entity_Id; Loc : Source_Ptr) return List_Id is
1481       Test_E : Entity_Id := E;
1482       Comp   : Entity_Id;
1483       F_Node : Node_Id;
1484       Result : List_Id;
1485       Indx   : Node_Id;
1486       Formal : Entity_Id;
1487       Atype  : Entity_Id;
1488
1489       Has_Default_Initialization : Boolean := False;
1490       --  This flag gets set to true for a variable with default initialization
1491
1492       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1493       --  Check that an Access or Unchecked_Access attribute with a prefix
1494       --  which is the current instance type can only be applied when the type
1495       --  is limited.
1496
1497       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1498       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1499       --  integer literal without an explicit corresponding size clause. The
1500       --  caller has checked that Utype is a modular integer type.
1501
1502       function After_Last_Declaration return Boolean;
1503       --  If Loc is a freeze_entity that appears after the last declaration
1504       --  in the scope, inhibit error messages on late completion.
1505
1506       procedure Freeze_Record_Type (Rec : Entity_Id);
1507       --  Freeze each component, handle some representation clauses, and freeze
1508       --  primitive operations if this is a tagged type.
1509
1510       ----------------------------
1511       -- After_Last_Declaration --
1512       ----------------------------
1513
1514       function After_Last_Declaration return Boolean is
1515          Spec : constant Node_Id := Parent (Current_Scope);
1516       begin
1517          if Nkind (Spec) = N_Package_Specification then
1518             if Present (Private_Declarations (Spec)) then
1519                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1520             elsif Present (Visible_Declarations (Spec)) then
1521                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1522             else
1523                return False;
1524             end if;
1525          else
1526             return False;
1527          end if;
1528       end After_Last_Declaration;
1529
1530       ----------------------------
1531       -- Check_Current_Instance --
1532       ----------------------------
1533
1534       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1535
1536          Rec_Type : constant Entity_Id :=
1537                       Scope (Defining_Identifier (Comp_Decl));
1538
1539          Decl : constant Node_Id := Parent (Rec_Type);
1540
1541          function Process (N : Node_Id) return Traverse_Result;
1542          --  Process routine to apply check to given node
1543
1544          -------------
1545          -- Process --
1546          -------------
1547
1548          function Process (N : Node_Id) return Traverse_Result is
1549          begin
1550             case Nkind (N) is
1551                when N_Attribute_Reference =>
1552                   if (Attribute_Name (N) = Name_Access
1553                         or else
1554                       Attribute_Name (N) = Name_Unchecked_Access)
1555                     and then Is_Entity_Name (Prefix (N))
1556                     and then Is_Type (Entity (Prefix (N)))
1557                     and then Entity (Prefix (N)) = E
1558                   then
1559                      Error_Msg_N
1560                        ("current instance must be a limited type", Prefix (N));
1561                      return Abandon;
1562                   else
1563                      return OK;
1564                   end if;
1565
1566                when others => return OK;
1567             end case;
1568          end Process;
1569
1570          procedure Traverse is new Traverse_Proc (Process);
1571
1572       --  Start of processing for Check_Current_Instance
1573
1574       begin
1575          --  In Ada95, the (imprecise) rule is that the current instance of a
1576          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1577          --  either a tagged type, or a limited record.
1578
1579          if Is_Limited_Type (Rec_Type)
1580            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1581          then
1582             return;
1583
1584          elsif Nkind (Decl) = N_Full_Type_Declaration
1585            and then Limited_Present (Type_Definition (Decl))
1586          then
1587             return;
1588
1589          else
1590             Traverse (Comp_Decl);
1591          end if;
1592       end Check_Current_Instance;
1593
1594       ------------------------------
1595       -- Check_Suspicious_Modulus --
1596       ------------------------------
1597
1598       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1599          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1600
1601       begin
1602          if Nkind (Decl) = N_Full_Type_Declaration then
1603             declare
1604                Tdef : constant Node_Id := Type_Definition (Decl);
1605             begin
1606                if Nkind (Tdef) = N_Modular_Type_Definition then
1607                   declare
1608                      Modulus : constant Node_Id :=
1609                                  Original_Node (Expression (Tdef));
1610                   begin
1611                      if Nkind (Modulus) = N_Integer_Literal then
1612                         declare
1613                            Modv : constant Uint := Intval (Modulus);
1614                            Sizv : constant Uint := RM_Size (Utype);
1615
1616                         begin
1617                            --  First case, modulus and size are the same. This
1618                            --  happens if you have something like mod 32, with
1619                            --  an explicit size of 32, this is for sure a case
1620                            --  where the warning is given, since it is seems
1621                            --  very unlikely that someone would want e.g. a
1622                            --  five bit type stored in 32 bits. It is much
1623                            --  more likely they wanted a 32-bit type.
1624
1625                            if Modv = Sizv then
1626                               null;
1627
1628                            --  Second case, the modulus is 32 or 64 and no
1629                            --  size clause is present. This is a less clear
1630                            --  case for giving the warning, but in the case
1631                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1632                            --  enough that it is a likely error (and in any
1633                            --  case using 2**5 or 2**6 in these cases seems
1634                            --  clearer. We don't include 8 or 16 here, simply
1635                            --  because in practice 3-bit and 4-bit types are
1636                            --  more common and too many false positives if
1637                            --  we warn in these cases.
1638
1639                            elsif not Has_Size_Clause (Utype)
1640                              and then (Modv = Uint_32 or else Modv = Uint_64)
1641                            then
1642                               null;
1643
1644                            --  No warning needed
1645
1646                            else
1647                               return;
1648                            end if;
1649
1650                            --  If we fall through, give warning
1651
1652                            Error_Msg_Uint_1 := Modv;
1653                            Error_Msg_N
1654                              ("?2 '*'*^' may have been intended here",
1655                               Modulus);
1656                         end;
1657                      end if;
1658                   end;
1659                end if;
1660             end;
1661          end if;
1662       end Check_Suspicious_Modulus;
1663
1664       ------------------------
1665       -- Freeze_Record_Type --
1666       ------------------------
1667
1668       procedure Freeze_Record_Type (Rec : Entity_Id) is
1669          Comp : Entity_Id;
1670          IR   : Node_Id;
1671          ADC  : Node_Id;
1672          Prev : Entity_Id;
1673
1674          Junk : Boolean;
1675          pragma Warnings (Off, Junk);
1676
1677          Unplaced_Component : Boolean := False;
1678          --  Set True if we find at least one component with no component
1679          --  clause (used to warn about useless Pack pragmas).
1680
1681          Placed_Component : Boolean := False;
1682          --  Set True if we find at least one component with a component
1683          --  clause (used to warn about useless Bit_Order pragmas, and also
1684          --  to detect cases where Implicit_Packing may have an effect).
1685
1686          All_Scalar_Components : Boolean := True;
1687          --  Set False if we encounter a component of a non-scalar type
1688
1689          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1690          Scalar_Component_Total_Esize   : Uint := Uint_0;
1691          --  Accumulates total RM_Size values and total Esize values of all
1692          --  scalar components. Used for processing of Implicit_Packing.
1693
1694          function Check_Allocator (N : Node_Id) return Node_Id;
1695          --  If N is an allocator, possibly wrapped in one or more level of
1696          --  qualified expression(s), return the inner allocator node, else
1697          --  return Empty.
1698
1699          procedure Check_Itype (Typ : Entity_Id);
1700          --  If the component subtype is an access to a constrained subtype of
1701          --  an already frozen type, make the subtype frozen as well. It might
1702          --  otherwise be frozen in the wrong scope, and a freeze node on
1703          --  subtype has no effect. Similarly, if the component subtype is a
1704          --  regular (not protected) access to subprogram, set the anonymous
1705          --  subprogram type to frozen as well, to prevent an out-of-scope
1706          --  freeze node at some eventual point of call. Protected operations
1707          --  are handled elsewhere.
1708
1709          ---------------------
1710          -- Check_Allocator --
1711          ---------------------
1712
1713          function Check_Allocator (N : Node_Id) return Node_Id is
1714             Inner : Node_Id;
1715          begin
1716             Inner := N;
1717             loop
1718                if Nkind (Inner) = N_Allocator then
1719                   return Inner;
1720                elsif Nkind (Inner) = N_Qualified_Expression then
1721                   Inner := Expression (Inner);
1722                else
1723                   return Empty;
1724                end if;
1725             end loop;
1726          end Check_Allocator;
1727
1728          -----------------
1729          -- Check_Itype --
1730          -----------------
1731
1732          procedure Check_Itype (Typ : Entity_Id) is
1733             Desig : constant Entity_Id := Designated_Type (Typ);
1734
1735          begin
1736             if not Is_Frozen (Desig)
1737               and then Is_Frozen (Base_Type (Desig))
1738             then
1739                Set_Is_Frozen (Desig);
1740
1741                --  In addition, add an Itype_Reference to ensure that the
1742                --  access subtype is elaborated early enough. This cannot be
1743                --  done if the subtype may depend on discriminants.
1744
1745                if Ekind (Comp) = E_Component
1746                  and then Is_Itype (Etype (Comp))
1747                  and then not Has_Discriminants (Rec)
1748                then
1749                   IR := Make_Itype_Reference (Sloc (Comp));
1750                   Set_Itype (IR, Desig);
1751
1752                   if No (Result) then
1753                      Result := New_List (IR);
1754                   else
1755                      Append (IR, Result);
1756                   end if;
1757                end if;
1758
1759             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1760               and then Convention (Desig) /= Convention_Protected
1761             then
1762                Set_Is_Frozen (Desig);
1763             end if;
1764          end Check_Itype;
1765
1766       --  Start of processing for Freeze_Record_Type
1767
1768       begin
1769          --  If this is a subtype of a controlled type, declared without a
1770          --  constraint, the _controller may not appear in the component list
1771          --  if the parent was not frozen at the point of subtype declaration.
1772          --  Inherit the _controller component now.
1773
1774          if Rec /= Base_Type (Rec)
1775            and then Has_Controlled_Component (Rec)
1776          then
1777             if Nkind (Parent (Rec)) = N_Subtype_Declaration
1778               and then Is_Entity_Name (Subtype_Indication (Parent (Rec)))
1779             then
1780                Set_First_Entity (Rec, First_Entity (Base_Type (Rec)));
1781
1782             --  If this is an internal type without a declaration, as for
1783             --  record component, the base type may not yet be frozen, and its
1784             --  controller has not been created. Add an explicit freeze node
1785             --  for the itype, so it will be frozen after the base type. This
1786             --  freeze node is used to communicate with the expander, in order
1787             --  to create the controller for the enclosing record, and it is
1788             --  deleted afterwards (see exp_ch3). It must not be created when
1789             --  expansion is off, because it might appear in the wrong context
1790             --  for the back end.
1791
1792             elsif Is_Itype (Rec)
1793               and then Has_Delayed_Freeze (Base_Type (Rec))
1794               and then
1795                 Nkind (Associated_Node_For_Itype (Rec)) =
1796                                                      N_Component_Declaration
1797               and then Expander_Active
1798             then
1799                Ensure_Freeze_Node (Rec);
1800             end if;
1801          end if;
1802
1803          --  Freeze components and embedded subtypes
1804
1805          Comp := First_Entity (Rec);
1806          Prev := Empty;
1807          while Present (Comp) loop
1808
1809             --  First handle the component case
1810
1811             if Ekind (Comp) = E_Component
1812               or else Ekind (Comp) = E_Discriminant
1813             then
1814                declare
1815                   CC : constant Node_Id := Component_Clause (Comp);
1816
1817                begin
1818                   --  Freezing a record type freezes the type of each of its
1819                   --  components. However, if the type of the component is
1820                   --  part of this record, we do not want or need a separate
1821                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1822                   --  also set in private type cases. We also can't check for
1823                   --  the Scope being exactly Rec because of private types and
1824                   --  record extensions.
1825
1826                   if Is_Itype (Etype (Comp))
1827                     and then Is_Record_Type (Underlying_Type
1828                                              (Scope (Etype (Comp))))
1829                   then
1830                      Undelay_Type (Etype (Comp));
1831                   end if;
1832
1833                   Freeze_And_Append (Etype (Comp), Loc, Result);
1834
1835                   --  Check for error of component clause given for variable
1836                   --  sized type. We have to delay this test till this point,
1837                   --  since the component type has to be frozen for us to know
1838                   --  if it is variable length. We omit this test in a generic
1839                   --  context, it will be applied at instantiation time.
1840
1841                   if Present (CC) then
1842                      Placed_Component := True;
1843
1844                      if Inside_A_Generic then
1845                         null;
1846
1847                      elsif not
1848                        Size_Known_At_Compile_Time
1849                          (Underlying_Type (Etype (Comp)))
1850                      then
1851                         Error_Msg_N
1852                           ("component clause not allowed for variable " &
1853                            "length component", CC);
1854                      end if;
1855
1856                   else
1857                      Unplaced_Component := True;
1858                   end if;
1859
1860                   --  Case of component requires byte alignment
1861
1862                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1863
1864                      --  Set the enclosing record to also require byte align
1865
1866                      Set_Must_Be_On_Byte_Boundary (Rec);
1867
1868                      --  Check for component clause that is inconsistent with
1869                      --  the required byte boundary alignment.
1870
1871                      if Present (CC)
1872                        and then Normalized_First_Bit (Comp) mod
1873                                   System_Storage_Unit /= 0
1874                      then
1875                         Error_Msg_N
1876                           ("component & must be byte aligned",
1877                            Component_Name (Component_Clause (Comp)));
1878                      end if;
1879                   end if;
1880                end;
1881             end if;
1882
1883             --  Gather data for possible Implicit_Packing later. Note that at
1884             --  this stage we might be dealing with a real component, or with
1885             --  an implicit subtype declaration.
1886
1887             if not Is_Scalar_Type (Etype (Comp)) then
1888                All_Scalar_Components := False;
1889             else
1890                Scalar_Component_Total_RM_Size :=
1891                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1892                Scalar_Component_Total_Esize :=
1893                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1894             end if;
1895
1896             --  If the component is an Itype with Delayed_Freeze and is either
1897             --  a record or array subtype and its base type has not yet been
1898             --  frozen, we must remove this from the entity list of this record
1899             --  and put it on the entity list of the scope of its base type.
1900             --  Note that we know that this is not the type of a component
1901             --  since we cleared Has_Delayed_Freeze for it in the previous
1902             --  loop. Thus this must be the Designated_Type of an access type,
1903             --  which is the type of a component.
1904
1905             if Is_Itype (Comp)
1906               and then Is_Type (Scope (Comp))
1907               and then Is_Composite_Type (Comp)
1908               and then Base_Type (Comp) /= Comp
1909               and then Has_Delayed_Freeze (Comp)
1910               and then not Is_Frozen (Base_Type (Comp))
1911             then
1912                declare
1913                   Will_Be_Frozen : Boolean := False;
1914                   S              : Entity_Id;
1915
1916                begin
1917                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1918                   --  being defined in a subprogram that's created as part of
1919                   --  the freezing of Rec'Base. In that case, we know that
1920                   --  Comp'Base must have already been frozen by the time we
1921                   --  get to elaborate this because Gigi doesn't elaborate any
1922                   --  bodies until it has elaborated all of the declarative
1923                   --  part. But Is_Frozen will not be set at this point because
1924                   --  we are processing code in lexical order.
1925
1926                   --  We detect this case by going up the Scope chain of Rec
1927                   --  and seeing if we have a subprogram scope before reaching
1928                   --  the top of the scope chain or that of Comp'Base. If we
1929                   --  do, then mark that Comp'Base will actually be frozen. If
1930                   --  so, we merely undelay it.
1931
1932                   S := Scope (Rec);
1933                   while Present (S) loop
1934                      if Is_Subprogram (S) then
1935                         Will_Be_Frozen := True;
1936                         exit;
1937                      elsif S = Scope (Base_Type (Comp)) then
1938                         exit;
1939                      end if;
1940
1941                      S := Scope (S);
1942                   end loop;
1943
1944                   if Will_Be_Frozen then
1945                      Undelay_Type (Comp);
1946                   else
1947                      if Present (Prev) then
1948                         Set_Next_Entity (Prev, Next_Entity (Comp));
1949                      else
1950                         Set_First_Entity (Rec, Next_Entity (Comp));
1951                      end if;
1952
1953                      --  Insert in entity list of scope of base type (which
1954                      --  must be an enclosing scope, because still unfrozen).
1955
1956                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1957                   end if;
1958                end;
1959
1960             --  If the component is an access type with an allocator as default
1961             --  value, the designated type will be frozen by the corresponding
1962             --  expression in init_proc. In order to place the freeze node for
1963             --  the designated type before that for the current record type,
1964             --  freeze it now.
1965
1966             --  Same process if the component is an array of access types,
1967             --  initialized with an aggregate. If the designated type is
1968             --  private, it cannot contain allocators, and it is premature
1969             --  to freeze the type, so we check for this as well.
1970
1971             elsif Is_Access_Type (Etype (Comp))
1972               and then Present (Parent (Comp))
1973               and then Present (Expression (Parent (Comp)))
1974             then
1975                declare
1976                   Alloc : constant Node_Id :=
1977                             Check_Allocator (Expression (Parent (Comp)));
1978
1979                begin
1980                   if Present (Alloc) then
1981
1982                      --  If component is pointer to a classwide type, freeze
1983                      --  the specific type in the expression being allocated.
1984                      --  The expression may be a subtype indication, in which
1985                      --  case freeze the subtype mark.
1986
1987                      if Is_Class_Wide_Type
1988                           (Designated_Type (Etype (Comp)))
1989                      then
1990                         if Is_Entity_Name (Expression (Alloc)) then
1991                            Freeze_And_Append
1992                              (Entity (Expression (Alloc)), Loc, Result);
1993                         elsif
1994                           Nkind (Expression (Alloc)) = N_Subtype_Indication
1995                         then
1996                            Freeze_And_Append
1997                             (Entity (Subtype_Mark (Expression (Alloc))),
1998                               Loc, Result);
1999                         end if;
2000
2001                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2002                         Check_Itype (Etype (Comp));
2003
2004                      else
2005                         Freeze_And_Append
2006                           (Designated_Type (Etype (Comp)), Loc, Result);
2007                      end if;
2008                   end if;
2009                end;
2010
2011             elsif Is_Access_Type (Etype (Comp))
2012               and then Is_Itype (Designated_Type (Etype (Comp)))
2013             then
2014                Check_Itype (Etype (Comp));
2015
2016             elsif Is_Array_Type (Etype (Comp))
2017               and then Is_Access_Type (Component_Type (Etype (Comp)))
2018               and then Present (Parent (Comp))
2019               and then Nkind (Parent (Comp)) = N_Component_Declaration
2020               and then Present (Expression (Parent (Comp)))
2021               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2022               and then Is_Fully_Defined
2023                  (Designated_Type (Component_Type (Etype (Comp))))
2024             then
2025                Freeze_And_Append
2026                  (Designated_Type
2027                    (Component_Type (Etype (Comp))), Loc, Result);
2028             end if;
2029
2030             Prev := Comp;
2031             Next_Entity (Comp);
2032          end loop;
2033
2034          --  Deal with pragma Bit_Order setting non-standard bit order
2035
2036          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2037             if not Placed_Component then
2038                ADC :=
2039                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2040                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2041                Error_Msg_N
2042                  ("\?since no component clauses were specified", ADC);
2043
2044             --  Here is where we do the processing for reversed bit order
2045
2046             else
2047                Adjust_Record_For_Reverse_Bit_Order (Rec);
2048             end if;
2049          end if;
2050
2051          --  Complete error checking on record representation clause (e.g.
2052          --  overlap of components). This is called after adjusting the
2053          --  record for reverse bit order.
2054
2055          declare
2056             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2057          begin
2058             if Present (RRC) then
2059                Check_Record_Representation_Clause (RRC);
2060             end if;
2061          end;
2062
2063          --  Set OK_To_Reorder_Components depending on debug flags
2064
2065          if Rec = Base_Type (Rec)
2066            and then Convention (Rec) = Convention_Ada
2067          then
2068             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2069                   or else
2070                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2071             then
2072                Set_OK_To_Reorder_Components (Rec);
2073             end if;
2074          end if;
2075
2076          --  Check for useless pragma Pack when all components placed. We only
2077          --  do this check for record types, not subtypes, since a subtype may
2078          --  have all its components placed, and it still makes perfectly good
2079          --  sense to pack other subtypes or the parent type. We do not give
2080          --  this warning if Optimize_Alignment is set to Space, since the
2081          --  pragma Pack does have an effect in this case (it always resets
2082          --  the alignment to one).
2083
2084          if Ekind (Rec) = E_Record_Type
2085            and then Is_Packed (Rec)
2086            and then not Unplaced_Component
2087            and then Optimize_Alignment /= 'S'
2088          then
2089             --  Reset packed status. Probably not necessary, but we do it so
2090             --  that there is no chance of the back end doing something strange
2091             --  with this redundant indication of packing.
2092
2093             Set_Is_Packed (Rec, False);
2094
2095             --  Give warning if redundant constructs warnings on
2096
2097             if Warn_On_Redundant_Constructs then
2098                Error_Msg_N -- CODEFIX
2099                  ("?pragma Pack has no effect, no unplaced components",
2100                   Get_Rep_Pragma (Rec, Name_Pack));
2101             end if;
2102          end if;
2103
2104          --  If this is the record corresponding to a remote type, freeze the
2105          --  remote type here since that is what we are semantically freezing.
2106          --  This prevents the freeze node for that type in an inner scope.
2107
2108          --  Also, Check for controlled components and unchecked unions.
2109          --  Finally, enforce the restriction that access attributes with a
2110          --  current instance prefix can only apply to limited types.
2111
2112          if Ekind (Rec) = E_Record_Type then
2113             if Present (Corresponding_Remote_Type (Rec)) then
2114                Freeze_And_Append
2115                  (Corresponding_Remote_Type (Rec), Loc, Result);
2116             end if;
2117
2118             Comp := First_Component (Rec);
2119             while Present (Comp) loop
2120
2121                --  Do not set Has_Controlled_Component on a class-wide
2122                --  equivalent type. See Make_CW_Equivalent_Type.
2123
2124                if not Is_Class_Wide_Equivalent_Type (Rec)
2125                  and then (Has_Controlled_Component (Etype (Comp))
2126                             or else (Chars (Comp) /= Name_uParent
2127                                       and then Is_Controlled (Etype (Comp)))
2128                             or else (Is_Protected_Type (Etype (Comp))
2129                                       and then Present
2130                                         (Corresponding_Record_Type
2131                                           (Etype (Comp)))
2132                                       and then Has_Controlled_Component
2133                                         (Corresponding_Record_Type
2134                                           (Etype (Comp)))))
2135                then
2136                   Set_Has_Controlled_Component (Rec);
2137                   exit;
2138                end if;
2139
2140                if Has_Unchecked_Union (Etype (Comp)) then
2141                   Set_Has_Unchecked_Union (Rec);
2142                end if;
2143
2144                if Has_Per_Object_Constraint (Comp) then
2145
2146                   --  Scan component declaration for likely misuses of current
2147                   --  instance, either in a constraint or a default expression.
2148
2149                   Check_Current_Instance (Parent (Comp));
2150                end if;
2151
2152                Next_Component (Comp);
2153             end loop;
2154          end if;
2155
2156          Set_Component_Alignment_If_Not_Set (Rec);
2157
2158          --  For first subtypes, check if there are any fixed-point fields with
2159          --  component clauses, where we must check the size. This is not done
2160          --  till the freeze point, since for fixed-point types, we do not know
2161          --  the size until the type is frozen. Similar processing applies to
2162          --  bit packed arrays.
2163
2164          if Is_First_Subtype (Rec) then
2165             Comp := First_Component (Rec);
2166
2167             while Present (Comp) loop
2168                if Present (Component_Clause (Comp))
2169                  and then (Is_Fixed_Point_Type (Etype (Comp))
2170                              or else
2171                            Is_Bit_Packed_Array (Etype (Comp)))
2172                then
2173                   Check_Size
2174                     (Component_Name (Component_Clause (Comp)),
2175                      Etype (Comp),
2176                      Esize (Comp),
2177                      Junk);
2178                end if;
2179
2180                Next_Component (Comp);
2181             end loop;
2182          end if;
2183
2184          --  Generate warning for applying C or C++ convention to a record
2185          --  with discriminants. This is suppressed for the unchecked union
2186          --  case, since the whole point in this case is interface C. We also
2187          --  do not generate this within instantiations, since we will have
2188          --  generated a message on the template.
2189
2190          if Has_Discriminants (E)
2191            and then not Is_Unchecked_Union (E)
2192            and then (Convention (E) = Convention_C
2193                        or else
2194                      Convention (E) = Convention_CPP)
2195            and then Comes_From_Source (E)
2196            and then not In_Instance
2197            and then not Has_Warnings_Off (E)
2198            and then not Has_Warnings_Off (Base_Type (E))
2199          then
2200             declare
2201                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2202                A2    : Node_Id;
2203
2204             begin
2205                if Present (Cprag) then
2206                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2207
2208                   if Convention (E) = Convention_C then
2209                      Error_Msg_N
2210                        ("?variant record has no direct equivalent in C", A2);
2211                   else
2212                      Error_Msg_N
2213                        ("?variant record has no direct equivalent in C++", A2);
2214                   end if;
2215
2216                   Error_Msg_NE
2217                     ("\?use of convention for type& is dubious", A2, E);
2218                end if;
2219             end;
2220          end if;
2221
2222          --  See if Size is too small as is (and implicit packing might help)
2223
2224          if not Is_Packed (Rec)
2225
2226            --  No implicit packing if even one component is explicitly placed
2227
2228            and then not Placed_Component
2229
2230            --  Must have size clause and all scalar components
2231
2232            and then Has_Size_Clause (Rec)
2233            and then All_Scalar_Components
2234
2235            --  Do not try implicit packing on records with discriminants, too
2236            --  complicated, especially in the variant record case.
2237
2238            and then not Has_Discriminants (Rec)
2239
2240            --  We can implicitly pack if the specified size of the record is
2241            --  less than the sum of the object sizes (no point in packing if
2242            --  this is not the case).
2243
2244            and then Esize (Rec) < Scalar_Component_Total_Esize
2245
2246            --  And the total RM size cannot be greater than the specified size
2247            --  since otherwise packing will not get us where we have to be!
2248
2249            and then Esize (Rec) >= Scalar_Component_Total_RM_Size
2250
2251            --  Never do implicit packing in CodePeer mode since we don't do
2252            --  any packing in this mode, since this generates over-complex
2253            --  code that confuses CodePeer, and in general, CodePeer does not
2254            --  care about the internal representation of objects.
2255
2256            and then not CodePeer_Mode
2257          then
2258             --  If implicit packing enabled, do it
2259
2260             if Implicit_Packing then
2261                Set_Is_Packed (Rec);
2262
2263                --  Otherwise flag the size clause
2264
2265             else
2266                declare
2267                   Sz : constant Node_Id := Size_Clause (Rec);
2268                begin
2269                   Error_Msg_NE -- CODEFIX
2270                     ("size given for& too small", Sz, Rec);
2271                   Error_Msg_N -- CODEFIX
2272                     ("\use explicit pragma Pack "
2273                      & "or use pragma Implicit_Packing", Sz);
2274                end;
2275             end if;
2276          end if;
2277       end Freeze_Record_Type;
2278
2279    --  Start of processing for Freeze_Entity
2280
2281    begin
2282       --  We are going to test for various reasons why this entity need not be
2283       --  frozen here, but in the case of an Itype that's defined within a
2284       --  record, that test actually applies to the record.
2285
2286       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2287          Test_E := Scope (E);
2288       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2289         and then Is_Record_Type (Underlying_Type (Scope (E)))
2290       then
2291          Test_E := Underlying_Type (Scope (E));
2292       end if;
2293
2294       --  Do not freeze if already frozen since we only need one freeze node
2295
2296       if Is_Frozen (E) then
2297          return No_List;
2298
2299       --  It is improper to freeze an external entity within a generic because
2300       --  its freeze node will appear in a non-valid context. The entity will
2301       --  be frozen in the proper scope after the current generic is analyzed.
2302
2303       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2304          return No_List;
2305
2306       --  Do not freeze a global entity within an inner scope created during
2307       --  expansion. A call to subprogram E within some internal procedure
2308       --  (a stream attribute for example) might require freezing E, but the
2309       --  freeze node must appear in the same declarative part as E itself.
2310       --  The two-pass elaboration mechanism in gigi guarantees that E will
2311       --  be frozen before the inner call is elaborated. We exclude constants
2312       --  from this test, because deferred constants may be frozen early, and
2313       --  must be diagnosed (e.g. in the case of a deferred constant being used
2314       --  in a default expression). If the enclosing subprogram comes from
2315       --  source, or is a generic instance, then the freeze point is the one
2316       --  mandated by the language, and we freeze the entity. A subprogram that
2317       --  is a child unit body that acts as a spec does not have a spec that
2318       --  comes from source, but can only come from source.
2319
2320       elsif In_Open_Scopes (Scope (Test_E))
2321         and then Scope (Test_E) /= Current_Scope
2322         and then Ekind (Test_E) /= E_Constant
2323       then
2324          declare
2325             S : Entity_Id := Current_Scope;
2326
2327          begin
2328
2329             while Present (S) loop
2330                if Is_Overloadable (S) then
2331                   if Comes_From_Source (S)
2332                     or else Is_Generic_Instance (S)
2333                     or else Is_Child_Unit (S)
2334                   then
2335                      exit;
2336                   else
2337                      return No_List;
2338                   end if;
2339                end if;
2340
2341                S := Scope (S);
2342             end loop;
2343          end;
2344
2345       --  Similarly, an inlined instance body may make reference to global
2346       --  entities, but these references cannot be the proper freezing point
2347       --  for them, and in the absence of inlining freezing will take place in
2348       --  their own scope. Normally instance bodies are analyzed after the
2349       --  enclosing compilation, and everything has been frozen at the proper
2350       --  place, but with front-end inlining an instance body is compiled
2351       --  before the end of the enclosing scope, and as a result out-of-order
2352       --  freezing must be prevented.
2353
2354       elsif Front_End_Inlining
2355         and then In_Instance_Body
2356         and then Present (Scope (Test_E))
2357       then
2358          declare
2359             S : Entity_Id := Scope (Test_E);
2360
2361          begin
2362             while Present (S) loop
2363                if Is_Generic_Instance (S) then
2364                   exit;
2365                else
2366                   S := Scope (S);
2367                end if;
2368             end loop;
2369
2370             if No (S) then
2371                return No_List;
2372             end if;
2373          end;
2374       end if;
2375
2376       --  Here to freeze the entity
2377
2378       Result := No_List;
2379       Set_Is_Frozen (E);
2380
2381       --  Case of entity being frozen is other than a type
2382
2383       if not Is_Type (E) then
2384
2385          --  If entity is exported or imported and does not have an external
2386          --  name, now is the time to provide the appropriate default name.
2387          --  Skip this if the entity is stubbed, since we don't need a name
2388          --  for any stubbed routine. For the case on intrinsics, if no
2389          --  external name is specified, then calls will be handled in
2390          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2391          --  external name is provided, then Expand_Intrinsic_Call leaves
2392          --  calls in place for expansion by GIGI.
2393
2394          if (Is_Imported (E) or else Is_Exported (E))
2395            and then No (Interface_Name (E))
2396            and then Convention (E) /= Convention_Stubbed
2397            and then Convention (E) /= Convention_Intrinsic
2398          then
2399             Set_Encoded_Interface_Name
2400               (E, Get_Default_External_Name (E));
2401
2402          --  If entity is an atomic object appearing in a declaration and
2403          --  the expression is an aggregate, assign it to a temporary to
2404          --  ensure that the actual assignment is done atomically rather
2405          --  than component-wise (the assignment to the temp may be done
2406          --  component-wise, but that is harmless).
2407
2408          elsif Is_Atomic (E)
2409            and then Nkind (Parent (E)) = N_Object_Declaration
2410            and then Present (Expression (Parent (E)))
2411            and then Nkind (Expression (Parent (E))) = N_Aggregate
2412            and then
2413              Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2414          then
2415             null;
2416          end if;
2417
2418          --  For a subprogram, freeze all parameter types and also the return
2419          --  type (RM 13.14(14)). However skip this for internal subprograms.
2420          --  This is also the point where any extra formal parameters are
2421          --  created since we now know whether the subprogram will use a
2422          --  foreign convention.
2423
2424          if Is_Subprogram (E) then
2425             if not Is_Internal (E) then
2426                declare
2427                   F_Type    : Entity_Id;
2428                   R_Type    : Entity_Id;
2429                   Warn_Node : Node_Id;
2430
2431                begin
2432                   --  Loop through formals
2433
2434                   Formal := First_Formal (E);
2435                   while Present (Formal) loop
2436                      F_Type := Etype (Formal);
2437                      Freeze_And_Append (F_Type, Loc, Result);
2438
2439                      if Is_Private_Type (F_Type)
2440                        and then Is_Private_Type (Base_Type (F_Type))
2441                        and then No (Full_View (Base_Type (F_Type)))
2442                        and then not Is_Generic_Type (F_Type)
2443                        and then not Is_Derived_Type (F_Type)
2444                      then
2445                         --  If the type of a formal is incomplete, subprogram
2446                         --  is being frozen prematurely. Within an instance
2447                         --  (but not within a wrapper package) this is an
2448                         --  artifact of our need to regard the end of an
2449                         --  instantiation as a freeze point. Otherwise it is
2450                         --  a definite error.
2451
2452                         if In_Instance then
2453                            Set_Is_Frozen (E, False);
2454                            return No_List;
2455
2456                         elsif not After_Last_Declaration
2457                           and then not Freezing_Library_Level_Tagged_Type
2458                         then
2459                            Error_Msg_Node_1 := F_Type;
2460                            Error_Msg
2461                              ("type& must be fully defined before this point",
2462                                Loc);
2463                         end if;
2464                      end if;
2465
2466                      --  Check suspicious parameter for C function. These tests
2467                      --  apply only to exported/imported subprograms.
2468
2469                      if Warn_On_Export_Import
2470                        and then Comes_From_Source (E)
2471                        and then (Convention (E) = Convention_C
2472                                    or else
2473                                  Convention (E) = Convention_CPP)
2474                        and then (Is_Imported (E) or else Is_Exported (E))
2475                        and then Convention (E) /= Convention (Formal)
2476                        and then not Has_Warnings_Off (E)
2477                        and then not Has_Warnings_Off (F_Type)
2478                        and then not Has_Warnings_Off (Formal)
2479                      then
2480                         --  Qualify mention of formals with subprogram name
2481
2482                         Error_Msg_Qual_Level := 1;
2483
2484                         --  Check suspicious use of fat C pointer
2485
2486                         if Is_Access_Type (F_Type)
2487                           and then Esize (F_Type) > Ttypes.System_Address_Size
2488                         then
2489                            Error_Msg_N
2490                              ("?type of & does not correspond to C pointer!",
2491                               Formal);
2492
2493                         --  Check suspicious return of boolean
2494
2495                         elsif Root_Type (F_Type) = Standard_Boolean
2496                           and then Convention (F_Type) = Convention_Ada
2497                           and then not Has_Warnings_Off (F_Type)
2498                           and then not Has_Size_Clause (F_Type)
2499                           and then VM_Target = No_VM
2500                         then
2501                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2502                            Error_Msg_N
2503                              ("\use appropriate corresponding type in C "
2504                               & "(e.g. char)?", Formal);
2505
2506                         --  Check suspicious tagged type
2507
2508                         elsif (Is_Tagged_Type (F_Type)
2509                                 or else (Is_Access_Type (F_Type)
2510                                            and then
2511                                              Is_Tagged_Type
2512                                                (Designated_Type (F_Type))))
2513                           and then Convention (E) = Convention_C
2514                         then
2515                            Error_Msg_N
2516                              ("?& involves a tagged type which does not "
2517                               & "correspond to any C type!", Formal);
2518
2519                         --  Check wrong convention subprogram pointer
2520
2521                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2522                           and then not Has_Foreign_Convention (F_Type)
2523                         then
2524                            Error_Msg_N
2525                              ("?subprogram pointer & should "
2526                               & "have foreign convention!", Formal);
2527                            Error_Msg_Sloc := Sloc (F_Type);
2528                            Error_Msg_NE
2529                              ("\?add Convention pragma to declaration of &#",
2530                               Formal, F_Type);
2531                         end if;
2532
2533                         --  Turn off name qualification after message output
2534
2535                         Error_Msg_Qual_Level := 0;
2536                      end if;
2537
2538                      --  Check for unconstrained array in exported foreign
2539                      --  convention case.
2540
2541                      if Has_Foreign_Convention (E)
2542                        and then not Is_Imported (E)
2543                        and then Is_Array_Type (F_Type)
2544                        and then not Is_Constrained (F_Type)
2545                        and then Warn_On_Export_Import
2546
2547                        --  Exclude VM case, since both .NET and JVM can handle
2548                        --  unconstrained arrays without a problem.
2549
2550                        and then VM_Target = No_VM
2551                      then
2552                         Error_Msg_Qual_Level := 1;
2553
2554                         --  If this is an inherited operation, place the
2555                         --  warning on the derived type declaration, rather
2556                         --  than on the original subprogram.
2557
2558                         if Nkind (Original_Node (Parent (E))) =
2559                           N_Full_Type_Declaration
2560                         then
2561                            Warn_Node := Parent (E);
2562
2563                            if Formal = First_Formal (E) then
2564                               Error_Msg_NE
2565                                 ("?in inherited operation&", Warn_Node, E);
2566                            end if;
2567                         else
2568                            Warn_Node := Formal;
2569                         end if;
2570
2571                         Error_Msg_NE
2572                           ("?type of argument& is unconstrained array",
2573                            Warn_Node, Formal);
2574                         Error_Msg_NE
2575                           ("?foreign caller must pass bounds explicitly",
2576                            Warn_Node, Formal);
2577                         Error_Msg_Qual_Level := 0;
2578                      end if;
2579
2580                      if not From_With_Type (F_Type) then
2581                         if Is_Access_Type (F_Type) then
2582                            F_Type := Designated_Type (F_Type);
2583                         end if;
2584
2585                         --  If the formal is an anonymous_access_to_subprogram
2586                         --  freeze the  subprogram type as well, to prevent
2587                         --  scope anomalies in gigi, because there is no other
2588                         --  clear point at which it could be frozen.
2589
2590                         if Is_Itype (Etype (Formal))
2591                           and then Ekind (F_Type) = E_Subprogram_Type
2592                         then
2593                            Freeze_And_Append (F_Type, Loc, Result);
2594                         end if;
2595                      end if;
2596
2597                      Next_Formal (Formal);
2598                   end loop;
2599
2600                   --  Case of function: similar checks on return type
2601
2602                   if Ekind (E) = E_Function then
2603
2604                      --  Freeze return type
2605
2606                      R_Type := Etype (E);
2607                      Freeze_And_Append (R_Type, Loc, Result);
2608
2609                      --  Check suspicious return type for C function
2610
2611                      if Warn_On_Export_Import
2612                        and then (Convention (E) = Convention_C
2613                                    or else
2614                                  Convention (E) = Convention_CPP)
2615                        and then (Is_Imported (E) or else Is_Exported (E))
2616                      then
2617                         --  Check suspicious return of fat C pointer
2618
2619                         if Is_Access_Type (R_Type)
2620                           and then Esize (R_Type) > Ttypes.System_Address_Size
2621                           and then not Has_Warnings_Off (E)
2622                           and then not Has_Warnings_Off (R_Type)
2623                         then
2624                            Error_Msg_N
2625                              ("?return type of& does not "
2626                               & "correspond to C pointer!", E);
2627
2628                         --  Check suspicious return of boolean
2629
2630                         elsif Root_Type (R_Type) = Standard_Boolean
2631                           and then Convention (R_Type) = Convention_Ada
2632                           and then VM_Target = No_VM
2633                           and then not Has_Warnings_Off (E)
2634                           and then not Has_Warnings_Off (R_Type)
2635                           and then not Has_Size_Clause (R_Type)
2636                         then
2637                            declare
2638                               N : constant Node_Id :=
2639                                     Result_Definition (Declaration_Node (E));
2640                            begin
2641                               Error_Msg_NE
2642                                 ("return type of & is an 8-bit Ada Boolean?",
2643                                  N, E);
2644                               Error_Msg_NE
2645                                 ("\use appropriate corresponding type in C "
2646                                  & "(e.g. char)?", N, E);
2647                            end;
2648
2649                         --  Check suspicious return tagged type
2650
2651                         elsif (Is_Tagged_Type (R_Type)
2652                                 or else (Is_Access_Type (R_Type)
2653                                            and then
2654                                              Is_Tagged_Type
2655                                                (Designated_Type (R_Type))))
2656                           and then Convention (E) = Convention_C
2657                           and then not Has_Warnings_Off (E)
2658                           and then not Has_Warnings_Off (R_Type)
2659                         then
2660                            Error_Msg_N
2661                              ("?return type of & does not "
2662                               & "correspond to C type!", E);
2663
2664                         --  Check return of wrong convention subprogram pointer
2665
2666                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2667                           and then not Has_Foreign_Convention (R_Type)
2668                           and then not Has_Warnings_Off (E)
2669                           and then not Has_Warnings_Off (R_Type)
2670                         then
2671                            Error_Msg_N
2672                              ("?& should return a foreign "
2673                               & "convention subprogram pointer", E);
2674                            Error_Msg_Sloc := Sloc (R_Type);
2675                            Error_Msg_NE
2676                              ("\?add Convention pragma to declaration of& #",
2677                               E, R_Type);
2678                         end if;
2679                      end if;
2680
2681                      --  Give warning for suspicous return of a result of an
2682                      --  unconstrained array type in a foreign convention
2683                      --  function.
2684
2685                      if Has_Foreign_Convention (E)
2686
2687                        --  We are looking for a return of unconstrained array
2688
2689                        and then Is_Array_Type (R_Type)
2690                        and then not Is_Constrained (R_Type)
2691
2692                        --  Exclude imported routines, the warning does not
2693                        --  belong on the import, but on the routine definition.
2694
2695                        and then not Is_Imported (E)
2696
2697                        --  Exclude VM case, since both .NET and JVM can handle
2698                        --  return of unconstrained arrays without a problem.
2699
2700                        and then VM_Target = No_VM
2701
2702                        --  Check that general warning is enabled, and that it
2703                        --  is not suppressed for this particular case.
2704
2705                        and then Warn_On_Export_Import
2706                        and then not Has_Warnings_Off (E)
2707                        and then not Has_Warnings_Off (R_Type)
2708                      then
2709                         Error_Msg_N
2710                           ("?foreign convention function& should not " &
2711                            "return unconstrained array!", E);
2712                      end if;
2713                   end if;
2714                end;
2715             end if;
2716
2717             --  Must freeze its parent first if it is a derived subprogram
2718
2719             if Present (Alias (E)) then
2720                Freeze_And_Append (Alias (E), Loc, Result);
2721             end if;
2722
2723             --  We don't freeze internal subprograms, because we don't normally
2724             --  want addition of extra formals or mechanism setting to happen
2725             --  for those. However we do pass through predefined dispatching
2726             --  cases, since extra formals may be needed in some cases, such as
2727             --  for the stream 'Input function (build-in-place formals).
2728
2729             if not Is_Internal (E)
2730               or else Is_Predefined_Dispatching_Operation (E)
2731             then
2732                Freeze_Subprogram (E);
2733             end if;
2734
2735          --  Here for other than a subprogram or type
2736
2737          else
2738             --  If entity has a type, and it is not a generic unit, then
2739             --  freeze it first (RM 13.14(10)).
2740
2741             if Present (Etype (E))
2742               and then Ekind (E) /= E_Generic_Function
2743             then
2744                Freeze_And_Append (Etype (E), Loc, Result);
2745             end if;
2746
2747             --  Special processing for objects created by object declaration
2748
2749             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2750
2751                --  Abstract type allowed only for C++ imported variables or
2752                --  constants.
2753
2754                --  Note: we inhibit this check for objects that do not come
2755                --  from source because there is at least one case (the
2756                --  expansion of x'class'input where x is abstract) where we
2757                --  legitimately generate an abstract object.
2758
2759                if Is_Abstract_Type (Etype (E))
2760                  and then Comes_From_Source (Parent (E))
2761                  and then not (Is_Imported (E)
2762                                  and then Is_CPP_Class (Etype (E)))
2763                then
2764                   Error_Msg_N ("type of object cannot be abstract",
2765                                Object_Definition (Parent (E)));
2766
2767                   if Is_CPP_Class (Etype (E)) then
2768                      Error_Msg_NE
2769                        ("\} may need a cpp_constructor",
2770                        Object_Definition (Parent (E)), Etype (E));
2771                   end if;
2772                end if;
2773
2774                --  For object created by object declaration, perform required
2775                --  categorization (preelaborate and pure) checks. Defer these
2776                --  checks to freeze time since pragma Import inhibits default
2777                --  initialization and thus pragma Import affects these checks.
2778
2779                Validate_Object_Declaration (Declaration_Node (E));
2780
2781                --  If there is an address clause, check that it is valid
2782
2783                Check_Address_Clause (E);
2784
2785                --  If the object needs any kind of default initialization, an
2786                --  error must be issued if No_Default_Initialization applies.
2787                --  The check doesn't apply to imported objects, which are not
2788                --  ever default initialized, and is why the check is deferred
2789                --  until freezing, at which point we know if Import applies.
2790                --  Deferred constants are also exempted from this test because
2791                --  their completion is explicit, or through an import pragma.
2792
2793                if Ekind (E) = E_Constant
2794                  and then Present (Full_View (E))
2795                then
2796                   null;
2797
2798                elsif Comes_From_Source (E)
2799                  and then not Is_Imported (E)
2800                  and then not Has_Init_Expression (Declaration_Node (E))
2801                  and then
2802                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2803                       and then not No_Initialization (Declaration_Node (E))
2804                       and then not Is_Value_Type (Etype (E))
2805                       and then not Suppress_Init_Proc (Etype (E)))
2806                     or else
2807                       (Needs_Simple_Initialization (Etype (E))
2808                         and then not Is_Internal (E)))
2809                then
2810                   Has_Default_Initialization := True;
2811                   Check_Restriction
2812                     (No_Default_Initialization, Declaration_Node (E));
2813                end if;
2814
2815                --  Check that a Thread_Local_Storage variable does not have
2816                --  default initialization, and any explicit initialization must
2817                --  either be the null constant or a static constant.
2818
2819                if Has_Pragma_Thread_Local_Storage (E) then
2820                   declare
2821                      Decl : constant Node_Id := Declaration_Node (E);
2822                   begin
2823                      if Has_Default_Initialization
2824                        or else
2825                          (Has_Init_Expression (Decl)
2826                             and then
2827                              (No (Expression (Decl))
2828                                 or else not
2829                                   (Is_Static_Expression (Expression (Decl))
2830                                      or else
2831                                    Nkind (Expression (Decl)) = N_Null)))
2832                      then
2833                         Error_Msg_NE
2834                           ("Thread_Local_Storage variable& is "
2835                            & "improperly initialized", Decl, E);
2836                         Error_Msg_NE
2837                           ("\only allowed initialization is explicit "
2838                            & "NULL or static expression", Decl, E);
2839                      end if;
2840                   end;
2841                end if;
2842
2843                --  For imported objects, set Is_Public unless there is also an
2844                --  address clause, which means that there is no external symbol
2845                --  needed for the Import (Is_Public may still be set for other
2846                --  unrelated reasons). Note that we delayed this processing
2847                --  till freeze time so that we can be sure not to set the flag
2848                --  if there is an address clause. If there is such a clause,
2849                --  then the only purpose of the Import pragma is to suppress
2850                --  implicit initialization.
2851
2852                if Is_Imported (E)
2853                  and then No (Address_Clause (E))
2854                then
2855                   Set_Is_Public (E);
2856                end if;
2857
2858                --  For convention C objects of an enumeration type, warn if
2859                --  the size is not integer size and no explicit size given.
2860                --  Skip warning for Boolean, and Character, assume programmer
2861                --  expects 8-bit sizes for these cases.
2862
2863                if (Convention (E) = Convention_C
2864                     or else
2865                    Convention (E) = Convention_CPP)
2866                  and then Is_Enumeration_Type (Etype (E))
2867                  and then not Is_Character_Type (Etype (E))
2868                  and then not Is_Boolean_Type (Etype (E))
2869                  and then Esize (Etype (E)) < Standard_Integer_Size
2870                  and then not Has_Size_Clause (E)
2871                then
2872                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2873                   Error_Msg_N
2874                     ("?convention C enumeration object has size less than ^",
2875                      E);
2876                   Error_Msg_N ("\?use explicit size clause to set size", E);
2877                end if;
2878             end if;
2879
2880             --  Check that a constant which has a pragma Volatile[_Components]
2881             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2882
2883             --  Note: Atomic[_Components] also sets Volatile[_Components]
2884
2885             if Ekind (E) = E_Constant
2886               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2887               and then not Is_Imported (E)
2888             then
2889                --  Make sure we actually have a pragma, and have not merely
2890                --  inherited the indication from elsewhere (e.g. an address
2891                --  clause, which is not good enough in RM terms!)
2892
2893                if Has_Rep_Pragma (E, Name_Atomic)
2894                     or else
2895                   Has_Rep_Pragma (E, Name_Atomic_Components)
2896                then
2897                   Error_Msg_N
2898                     ("stand alone atomic constant must be " &
2899                      "imported (RM C.6(13))", E);
2900
2901                elsif Has_Rep_Pragma (E, Name_Volatile)
2902                        or else
2903                      Has_Rep_Pragma (E, Name_Volatile_Components)
2904                then
2905                   Error_Msg_N
2906                     ("stand alone volatile constant must be " &
2907                      "imported (RM C.6(13))", E);
2908                end if;
2909             end if;
2910
2911             --  Static objects require special handling
2912
2913             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2914               and then Is_Statically_Allocated (E)
2915             then
2916                Freeze_Static_Object (E);
2917             end if;
2918
2919             --  Remaining step is to layout objects
2920
2921             if Ekind (E) = E_Variable
2922                  or else
2923                Ekind (E) = E_Constant
2924                  or else
2925                Ekind (E) = E_Loop_Parameter
2926                  or else
2927                Is_Formal (E)
2928             then
2929                Layout_Object (E);
2930             end if;
2931          end if;
2932
2933       --  Case of a type or subtype being frozen
2934
2935       else
2936          --  We used to check here that a full type must have preelaborable
2937          --  initialization if it completes a private type specified with
2938          --  pragma Preelaborable_Intialization, but that missed cases where
2939          --  the types occur within a generic package, since the freezing
2940          --  that occurs within a containing scope generally skips traversal
2941          --  of a generic unit's declarations (those will be frozen within
2942          --  instances). This check was moved to Analyze_Package_Specification.
2943
2944          --  The type may be defined in a generic unit. This can occur when
2945          --  freezing a generic function that returns the type (which is
2946          --  defined in a parent unit). It is clearly meaningless to freeze
2947          --  this type. However, if it is a subtype, its size may be determi-
2948          --  nable and used in subsequent checks, so might as well try to
2949          --  compute it.
2950
2951          if Present (Scope (E))
2952            and then Is_Generic_Unit (Scope (E))
2953          then
2954             Check_Compile_Time_Size (E);
2955             return No_List;
2956          end if;
2957
2958          --  Deal with special cases of freezing for subtype
2959
2960          if E /= Base_Type (E) then
2961
2962             --  Before we do anything else, a specialized test for the case of
2963             --  a size given for an array where the array needs to be packed,
2964             --  but was not so the size cannot be honored. This would of course
2965             --  be caught by the backend, and indeed we don't catch all cases.
2966             --  The point is that we can give a better error message in those
2967             --  cases that we do catch with the circuitry here. Also if pragma
2968             --  Implicit_Packing is set, this is where the packing occurs.
2969
2970             --  The reason we do this so early is that the processing in the
2971             --  automatic packing case affects the layout of the base type, so
2972             --  it must be done before we freeze the base type.
2973
2974             if Is_Array_Type (E) then
2975                declare
2976                   Lo, Hi : Node_Id;
2977                   Ctyp   : constant Entity_Id := Component_Type (E);
2978
2979                begin
2980                   --  Check enabling conditions. These are straightforward
2981                   --  except for the test for a limited composite type. This
2982                   --  eliminates the rare case of a array of limited components
2983                   --  where there are issues of whether or not we can go ahead
2984                   --  and pack the array (since we can't freely pack and unpack
2985                   --  arrays if they are limited).
2986
2987                   --  Note that we check the root type explicitly because the
2988                   --  whole point is we are doing this test before we have had
2989                   --  a chance to freeze the base type (and it is that freeze
2990                   --  action that causes stuff to be inherited).
2991
2992                   if Present (Size_Clause (E))
2993                     and then Known_Static_Esize (E)
2994                     and then not Is_Packed (E)
2995                     and then not Has_Pragma_Pack (E)
2996                     and then Number_Dimensions (E) = 1
2997                     and then not Has_Component_Size_Clause (E)
2998                     and then Known_Static_Esize (Ctyp)
2999                     and then not Is_Limited_Composite (E)
3000                     and then not Is_Packed (Root_Type (E))
3001                     and then not Has_Component_Size_Clause (Root_Type (E))
3002                     and then not CodePeer_Mode
3003                   then
3004                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3005
3006                      if Compile_Time_Known_Value (Lo)
3007                        and then Compile_Time_Known_Value (Hi)
3008                        and then Known_Static_RM_Size (Ctyp)
3009                        and then RM_Size (Ctyp) < 64
3010                      then
3011                         declare
3012                            Lov  : constant Uint      := Expr_Value (Lo);
3013                            Hiv  : constant Uint      := Expr_Value (Hi);
3014                            Len  : constant Uint      := UI_Max
3015                                                          (Uint_0,
3016                                                           Hiv - Lov + 1);
3017                            Rsiz : constant Uint      := RM_Size (Ctyp);
3018                            SZ   : constant Node_Id   := Size_Clause (E);
3019                            Btyp : constant Entity_Id := Base_Type (E);
3020
3021                         --  What we are looking for here is the situation where
3022                         --  the RM_Size given would be exactly right if there
3023                         --  was a pragma Pack (resulting in the component size
3024                         --  being the same as the RM_Size). Furthermore, the
3025                         --  component type size must be an odd size (not a
3026                         --  multiple of storage unit). If the component RM size
3027                         --  is an exact number of storage units that is a power
3028                         --  of two, the array is not packed and has a standard
3029                         --  representation.
3030
3031                         begin
3032                            if RM_Size (E) = Len * Rsiz
3033                              and then Rsiz mod System_Storage_Unit /= 0
3034                            then
3035                               --  For implicit packing mode, just set the
3036                               --  component size silently.
3037
3038                               if Implicit_Packing then
3039                                  Set_Component_Size       (Btyp, Rsiz);
3040                                  Set_Is_Bit_Packed_Array  (Btyp);
3041                                  Set_Is_Packed            (Btyp);
3042                                  Set_Has_Non_Standard_Rep (Btyp);
3043
3044                                  --  Otherwise give an error message
3045
3046                               else
3047                                  Error_Msg_NE
3048                                    ("size given for& too small", SZ, E);
3049                                  Error_Msg_N -- CODEFIX
3050                                    ("\use explicit pragma Pack "
3051                                     & "or use pragma Implicit_Packing", SZ);
3052                               end if;
3053
3054                            elsif RM_Size (E) = Len * Rsiz
3055                              and then Implicit_Packing
3056                              and then
3057                                (Rsiz / System_Storage_Unit = 1
3058                                  or else Rsiz / System_Storage_Unit = 2
3059                                  or else Rsiz / System_Storage_Unit = 4)
3060                            then
3061
3062                               --  Not a packed array, but indicate the desired
3063                               --  component size, for the back-end.
3064
3065                               Set_Component_Size (Btyp, Rsiz);
3066                            end if;
3067                         end;
3068                      end if;
3069                   end if;
3070                end;
3071             end if;
3072
3073             --  If ancestor subtype present, freeze that first. Note that this
3074             --  will also get the base type frozen.
3075
3076             Atype := Ancestor_Subtype (E);
3077
3078             if Present (Atype) then
3079                Freeze_And_Append (Atype, Loc, Result);
3080
3081             --  Otherwise freeze the base type of the entity before freezing
3082             --  the entity itself (RM 13.14(15)).
3083
3084             elsif E /= Base_Type (E) then
3085                Freeze_And_Append (Base_Type (E), Loc, Result);
3086             end if;
3087
3088          --  For a derived type, freeze its parent type first (RM 13.14(15))
3089
3090          elsif Is_Derived_Type (E) then
3091             Freeze_And_Append (Etype (E), Loc, Result);
3092             Freeze_And_Append (First_Subtype (Etype (E)), Loc, Result);
3093          end if;
3094
3095          --  For array type, freeze index types and component type first
3096          --  before freezing the array (RM 13.14(15)).
3097
3098          if Is_Array_Type (E) then
3099             declare
3100                FS     : constant Entity_Id := First_Subtype (E);
3101                Ctyp   : constant Entity_Id := Component_Type (E);
3102                Clause : Entity_Id;
3103
3104                Non_Standard_Enum : Boolean := False;
3105                --  Set true if any of the index types is an enumeration type
3106                --  with a non-standard representation.
3107
3108             begin
3109                Freeze_And_Append (Ctyp, Loc, Result);
3110
3111                Indx := First_Index (E);
3112                while Present (Indx) loop
3113                   Freeze_And_Append (Etype (Indx), Loc, Result);
3114
3115                   if Is_Enumeration_Type (Etype (Indx))
3116                     and then Has_Non_Standard_Rep (Etype (Indx))
3117                   then
3118                      Non_Standard_Enum := True;
3119                   end if;
3120
3121                   Next_Index (Indx);
3122                end loop;
3123
3124                --  Processing that is done only for base types
3125
3126                if Ekind (E) = E_Array_Type then
3127
3128                   --  Propagate flags for component type
3129
3130                   if Is_Controlled (Component_Type (E))
3131                     or else Has_Controlled_Component (Ctyp)
3132                   then
3133                      Set_Has_Controlled_Component (E);
3134                   end if;
3135
3136                   if Has_Unchecked_Union (Component_Type (E)) then
3137                      Set_Has_Unchecked_Union (E);
3138                   end if;
3139
3140                   --  If packing was requested or if the component size was set
3141                   --  explicitly, then see if bit packing is required. This
3142                   --  processing is only done for base types, since all the
3143                   --  representation aspects involved are type-related. This
3144                   --  is not just an optimization, if we start processing the
3145                   --  subtypes, they interfere with the settings on the base
3146                   --  type (this is because Is_Packed has a slightly different
3147                   --  meaning before and after freezing).
3148
3149                   declare
3150                      Csiz : Uint;
3151                      Esiz : Uint;
3152
3153                   begin
3154                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3155                        and then Known_Static_RM_Size (Ctyp)
3156                        and then not Has_Component_Size_Clause (E)
3157                      then
3158                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3159
3160                      elsif Known_Component_Size (E) then
3161                         Csiz := Component_Size (E);
3162
3163                      elsif not Known_Static_Esize (Ctyp) then
3164                         Csiz := Uint_0;
3165
3166                      else
3167                         Esiz := Esize (Ctyp);
3168
3169                         --  We can set the component size if it is less than
3170                         --  16, rounding it up to the next storage unit size.
3171
3172                         if Esiz <= 8 then
3173                            Csiz := Uint_8;
3174                         elsif Esiz <= 16 then
3175                            Csiz := Uint_16;
3176                         else
3177                            Csiz := Uint_0;
3178                         end if;
3179
3180                         --  Set component size up to match alignment if it
3181                         --  would otherwise be less than the alignment. This
3182                         --  deals with cases of types whose alignment exceeds
3183                         --  their size (padded types).
3184
3185                         if Csiz /= 0 then
3186                            declare
3187                               A : constant Uint := Alignment_In_Bits (Ctyp);
3188                            begin
3189                               if Csiz < A then
3190                                  Csiz := A;
3191                               end if;
3192                            end;
3193                         end if;
3194                      end if;
3195
3196                      --  Case of component size that may result in packing
3197
3198                      if 1 <= Csiz and then Csiz <= 64 then
3199                         declare
3200                            Ent         : constant Entity_Id :=
3201                                            First_Subtype (E);
3202                            Pack_Pragma : constant Node_Id :=
3203                                            Get_Rep_Pragma (Ent, Name_Pack);
3204                            Comp_Size_C : constant Node_Id :=
3205                                            Get_Attribute_Definition_Clause
3206                                              (Ent, Attribute_Component_Size);
3207                         begin
3208                            --  Warn if we have pack and component size so that
3209                            --  the pack is ignored.
3210
3211                            --  Note: here we must check for the presence of a
3212                            --  component size before checking for a Pack pragma
3213                            --  to deal with the case where the array type is a
3214                            --  derived type whose parent is currently private.
3215
3216                            if Present (Comp_Size_C)
3217                              and then Has_Pragma_Pack (Ent)
3218                              and then Warn_On_Redundant_Constructs
3219                            then
3220                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3221                               Error_Msg_NE
3222                                 ("?pragma Pack for& ignored!",
3223                                  Pack_Pragma, Ent);
3224                               Error_Msg_N
3225                                 ("\?explicit component size given#!",
3226                                  Pack_Pragma);
3227                               Set_Is_Packed (Base_Type (Ent), False);
3228                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3229                            end if;
3230
3231                            --  Set component size if not already set by a
3232                            --  component size clause.
3233
3234                            if not Present (Comp_Size_C) then
3235                               Set_Component_Size (E, Csiz);
3236                            end if;
3237
3238                            --  Check for base type of 8, 16, 32 bits, where an
3239                            --  unsigned subtype has a length one less than the
3240                            --  base type (e.g. Natural subtype of Integer).
3241
3242                            --  In such cases, if a component size was not set
3243                            --  explicitly, then generate a warning.
3244
3245                            if Has_Pragma_Pack (E)
3246                              and then not Present (Comp_Size_C)
3247                              and then
3248                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3249                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3250                            then
3251                               Error_Msg_Uint_1 := Csiz;
3252
3253                               if Present (Pack_Pragma) then
3254                                  Error_Msg_N
3255                                    ("?pragma Pack causes component size "
3256                                     & "to be ^!", Pack_Pragma);
3257                                  Error_Msg_N
3258                                    ("\?use Component_Size to set "
3259                                     & "desired value!", Pack_Pragma);
3260                               end if;
3261                            end if;
3262
3263                            --  Actual packing is not needed for 8, 16, 32, 64.
3264                            --  Also not needed for 24 if alignment is 1.
3265
3266                            if        Csiz = 8
3267                              or else Csiz = 16
3268                              or else Csiz = 32
3269                              or else Csiz = 64
3270                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3271                            then
3272                               --  Here the array was requested to be packed,
3273                               --  but the packing request had no effect, so
3274                               --  Is_Packed is reset.
3275
3276                               --  Note: semantically this means that we lose
3277                               --  track of the fact that a derived type
3278                               --  inherited a pragma Pack that was non-
3279                               --  effective, but that seems fine.
3280
3281                               --  We regard a Pack pragma as a request to set
3282                               --  a representation characteristic, and this
3283                               --  request may be ignored.
3284
3285                               Set_Is_Packed           (Base_Type (E), False);
3286                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3287
3288                               if Known_Static_Esize (Component_Type (E))
3289                                 and then Esize (Component_Type (E)) = Csiz
3290                               then
3291                                  Set_Has_Non_Standard_Rep
3292                                    (Base_Type (E), False);
3293                               end if;
3294
3295                            --  In all other cases, packing is indeed needed
3296
3297                            else
3298                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3299                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3300                               Set_Is_Packed            (Base_Type (E), True);
3301                            end if;
3302                         end;
3303                      end if;
3304                   end;
3305
3306                   --  Check for Atomic_Components or Aliased with unsuitable
3307                   --  packing or explicit component size clause given.
3308
3309                   if (Has_Atomic_Components (E)
3310                        or else Has_Aliased_Components (E))
3311                     and then (Has_Component_Size_Clause (E)
3312                                or else Is_Packed (E))
3313                   then
3314                      Alias_Atomic_Check : declare
3315
3316                         procedure Complain_CS (T : String);
3317                         --  Outputs error messages for incorrect CS clause or
3318                         --  pragma Pack for aliased or atomic components (T is
3319                         --  "aliased" or "atomic");
3320
3321                         -----------------
3322                         -- Complain_CS --
3323                         -----------------
3324
3325                         procedure Complain_CS (T : String) is
3326                         begin
3327                            if Has_Component_Size_Clause (E) then
3328                               Clause :=
3329                                 Get_Attribute_Definition_Clause
3330                                   (FS, Attribute_Component_Size);
3331
3332                               if Known_Static_Esize (Ctyp) then
3333                                  Error_Msg_N
3334                                    ("incorrect component size for "
3335                                     & T & " components", Clause);
3336                                  Error_Msg_Uint_1 := Esize (Ctyp);
3337                                  Error_Msg_N
3338                                    ("\only allowed value is^", Clause);
3339
3340                               else
3341                                  Error_Msg_N
3342                                    ("component size cannot be given for "
3343                                     & T & " components", Clause);
3344                               end if;
3345
3346                            else
3347                               Error_Msg_N
3348                                 ("cannot pack " & T & " components",
3349                                  Get_Rep_Pragma (FS, Name_Pack));
3350                            end if;
3351
3352                            return;
3353                         end Complain_CS;
3354
3355                      --  Start of processing for Alias_Atomic_Check
3356
3357                      begin
3358                         --  Case where component size has no effect
3359
3360                         if Known_Static_Esize (Ctyp)
3361                           and then Known_Static_RM_Size (Ctyp)
3362                           and then Esize (Ctyp) = RM_Size (Ctyp)
3363                           and then Esize (Ctyp) mod 8 = 0
3364                         then
3365                            null;
3366
3367                         elsif Has_Aliased_Components (E)
3368                           or else Is_Aliased (Ctyp)
3369                         then
3370                            Complain_CS ("aliased");
3371
3372                         elsif Has_Atomic_Components (E)
3373                           or else Is_Atomic (Ctyp)
3374                         then
3375                            Complain_CS ("atomic");
3376                         end if;
3377                      end Alias_Atomic_Check;
3378                   end if;
3379
3380                   --  Warn for case of atomic type
3381
3382                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3383
3384                   if Present (Clause)
3385                     and then not Addressable (Component_Size (FS))
3386                   then
3387                      Error_Msg_NE
3388                        ("non-atomic components of type& may not be "
3389                         & "accessible by separate tasks?", Clause, E);
3390
3391                      if Has_Component_Size_Clause (E) then
3392                         Error_Msg_Sloc :=
3393                           Sloc
3394                             (Get_Attribute_Definition_Clause
3395                                  (FS, Attribute_Component_Size));
3396                         Error_Msg_N
3397                           ("\because of component size clause#?",
3398                            Clause);
3399
3400                      elsif Has_Pragma_Pack (E) then
3401                         Error_Msg_Sloc :=
3402                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3403                         Error_Msg_N
3404                           ("\because of pragma Pack#?", Clause);
3405                      end if;
3406                   end if;
3407
3408                --  Processing that is done only for subtypes
3409
3410                else
3411                   --  Acquire alignment from base type
3412
3413                   if Unknown_Alignment (E) then
3414                      Set_Alignment (E, Alignment (Base_Type (E)));
3415                      Adjust_Esize_Alignment (E);
3416                   end if;
3417                end if;
3418
3419                --  For bit-packed arrays, check the size
3420
3421                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3422                   declare
3423                      SizC : constant Node_Id := Size_Clause (E);
3424
3425                      Discard : Boolean;
3426                      pragma Warnings (Off, Discard);
3427
3428                   begin
3429                      --  It is not clear if it is possible to have no size
3430                      --  clause at this stage, but it is not worth worrying
3431                      --  about. Post error on the entity name in the size
3432                      --  clause if present, else on the type entity itself.
3433
3434                      if Present (SizC) then
3435                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3436                      else
3437                         Check_Size (E, E, RM_Size (E), Discard);
3438                      end if;
3439                   end;
3440                end if;
3441
3442                --  If any of the index types was an enumeration type with
3443                --  a non-standard rep clause, then we indicate that the
3444                --  array type is always packed (even if it is not bit packed).
3445
3446                if Non_Standard_Enum then
3447                   Set_Has_Non_Standard_Rep (Base_Type (E));
3448                   Set_Is_Packed            (Base_Type (E));
3449                end if;
3450
3451                Set_Component_Alignment_If_Not_Set (E);
3452
3453                --  If the array is packed, we must create the packed array
3454                --  type to be used to actually implement the type. This is
3455                --  only needed for real array types (not for string literal
3456                --  types, since they are present only for the front end).
3457
3458                if Is_Packed (E)
3459                  and then Ekind (E) /= E_String_Literal_Subtype
3460                then
3461                   Create_Packed_Array_Type (E);
3462                   Freeze_And_Append (Packed_Array_Type (E), Loc, Result);
3463
3464                   --  Size information of packed array type is copied to the
3465                   --  array type, since this is really the representation. But
3466                   --  do not override explicit existing size values. If the
3467                   --  ancestor subtype is constrained the packed_array_type
3468                   --  will be inherited from it, but the size may have been
3469                   --  provided already, and must not be overridden either.
3470
3471                   if not Has_Size_Clause (E)
3472                     and then
3473                       (No (Ancestor_Subtype (E))
3474                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3475                   then
3476                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3477                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3478                   end if;
3479
3480                   if not Has_Alignment_Clause (E) then
3481                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3482                   end if;
3483                end if;
3484
3485                --  For non-packed arrays set the alignment of the array to the
3486                --  alignment of the component type if it is unknown. Skip this
3487                --  in atomic case (atomic arrays may need larger alignments).
3488
3489                if not Is_Packed (E)
3490                  and then Unknown_Alignment (E)
3491                  and then Known_Alignment (Ctyp)
3492                  and then Known_Static_Component_Size (E)
3493                  and then Known_Static_Esize (Ctyp)
3494                  and then Esize (Ctyp) = Component_Size (E)
3495                  and then not Is_Atomic (E)
3496                then
3497                   Set_Alignment (E, Alignment (Component_Type (E)));
3498                end if;
3499             end;
3500
3501          --  For a class-wide type, the corresponding specific type is
3502          --  frozen as well (RM 13.14(15))
3503
3504          elsif Is_Class_Wide_Type (E) then
3505             Freeze_And_Append (Root_Type (E), Loc, Result);
3506
3507             --  If the base type of the class-wide type is still incomplete,
3508             --  the class-wide remains unfrozen as well. This is legal when
3509             --  E is the formal of a primitive operation of some other type
3510             --  which is being frozen.
3511
3512             if not Is_Frozen (Root_Type (E)) then
3513                Set_Is_Frozen (E, False);
3514                return Result;
3515             end if;
3516
3517             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3518             --  parent of a derived type) and it is a library-level entity,
3519             --  generate an itype reference for it. Otherwise, its first
3520             --  explicit reference may be in an inner scope, which will be
3521             --  rejected by the back-end.
3522
3523             if Is_Itype (E)
3524               and then Is_Compilation_Unit (Scope (E))
3525             then
3526                declare
3527                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3528
3529                begin
3530                   Set_Itype (Ref, E);
3531                   if No (Result) then
3532                      Result := New_List (Ref);
3533                   else
3534                      Append (Ref, Result);
3535                   end if;
3536                end;
3537             end if;
3538
3539             --  The equivalent type associated with a class-wide subtype needs
3540             --  to be frozen to ensure that its layout is done.
3541
3542             if Ekind (E) = E_Class_Wide_Subtype
3543               and then Present (Equivalent_Type (E))
3544             then
3545                Freeze_And_Append (Equivalent_Type (E), Loc, Result);
3546             end if;
3547
3548          --  For a record (sub)type, freeze all the component types (RM
3549          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3550          --  Is_Record_Type, because we don't want to attempt the freeze for
3551          --  the case of a private type with record extension (we will do that
3552          --  later when the full type is frozen).
3553
3554          elsif Ekind (E) = E_Record_Type
3555            or else Ekind (E) = E_Record_Subtype
3556          then
3557             Freeze_Record_Type (E);
3558
3559          --  For a concurrent type, freeze corresponding record type. This
3560          --  does not correspond to any specific rule in the RM, but the
3561          --  record type is essentially part of the concurrent type.
3562          --  Freeze as well all local entities. This includes record types
3563          --  created for entry parameter blocks, and whatever local entities
3564          --  may appear in the private part.
3565
3566          elsif Is_Concurrent_Type (E) then
3567             if Present (Corresponding_Record_Type (E)) then
3568                Freeze_And_Append
3569                  (Corresponding_Record_Type (E), Loc, Result);
3570             end if;
3571
3572             Comp := First_Entity (E);
3573             while Present (Comp) loop
3574                if Is_Type (Comp) then
3575                   Freeze_And_Append (Comp, Loc, Result);
3576
3577                elsif (Ekind (Comp)) /= E_Function then
3578                   if Is_Itype (Etype (Comp))
3579                     and then Underlying_Type (Scope (Etype (Comp))) = E
3580                   then
3581                      Undelay_Type (Etype (Comp));
3582                   end if;
3583
3584                   Freeze_And_Append (Etype (Comp), Loc, Result);
3585                end if;
3586
3587                Next_Entity (Comp);
3588             end loop;
3589
3590          --  Private types are required to point to the same freeze node as
3591          --  their corresponding full views. The freeze node itself has to
3592          --  point to the partial view of the entity (because from the partial
3593          --  view, we can retrieve the full view, but not the reverse).
3594          --  However, in order to freeze correctly, we need to freeze the full
3595          --  view. If we are freezing at the end of a scope (or within the
3596          --  scope of the private type), the partial and full views will have
3597          --  been swapped, the full view appears first in the entity chain and
3598          --  the swapping mechanism ensures that the pointers are properly set
3599          --  (on scope exit).
3600
3601          --  If we encounter the partial view before the full view (e.g. when
3602          --  freezing from another scope), we freeze the full view, and then
3603          --  set the pointers appropriately since we cannot rely on swapping to
3604          --  fix things up (subtypes in an outer scope might not get swapped).
3605
3606          elsif Is_Incomplete_Or_Private_Type (E)
3607            and then not Is_Generic_Type (E)
3608          then
3609             --  The construction of the dispatch table associated with library
3610             --  level tagged types forces freezing of all the primitives of the
3611             --  type, which may cause premature freezing of the partial view.
3612             --  For example:
3613
3614             --     package Pkg is
3615             --        type T is tagged private;
3616             --        type DT is new T with private;
3617             --        procedure Prim (X : in out T; Y : in out DT'class);
3618             --     private
3619             --        type T is tagged null record;
3620             --        Obj : T;
3621             --        type DT is new T with null record;
3622             --     end;
3623
3624             --  In this case the type will be frozen later by the usual
3625             --  mechanism: an object declaration, an instantiation, or the
3626             --  end of a declarative part.
3627
3628             if Is_Library_Level_Tagged_Type (E)
3629               and then not Present (Full_View (E))
3630             then
3631                Set_Is_Frozen (E, False);
3632                return Result;
3633
3634             --  Case of full view present
3635
3636             elsif Present (Full_View (E)) then
3637
3638                --  If full view has already been frozen, then no further
3639                --  processing is required
3640
3641                if Is_Frozen (Full_View (E)) then
3642
3643                   Set_Has_Delayed_Freeze (E, False);
3644                   Set_Freeze_Node (E, Empty);
3645                   Check_Debug_Info_Needed (E);
3646
3647                --  Otherwise freeze full view and patch the pointers so that
3648                --  the freeze node will elaborate both views in the back-end.
3649
3650                else
3651                   declare
3652                      Full : constant Entity_Id := Full_View (E);
3653
3654                   begin
3655                      if Is_Private_Type (Full)
3656                        and then Present (Underlying_Full_View (Full))
3657                      then
3658                         Freeze_And_Append
3659                           (Underlying_Full_View (Full), Loc, Result);
3660                      end if;
3661
3662                      Freeze_And_Append (Full, Loc, Result);
3663
3664                      if Has_Delayed_Freeze (E) then
3665                         F_Node := Freeze_Node (Full);
3666
3667                         if Present (F_Node) then
3668                            Set_Freeze_Node (E, F_Node);
3669                            Set_Entity (F_Node, E);
3670
3671                         else
3672                            --  {Incomplete,Private}_Subtypes with Full_Views
3673                            --  constrained by discriminants.
3674
3675                            Set_Has_Delayed_Freeze (E, False);
3676                            Set_Freeze_Node (E, Empty);
3677                         end if;
3678                      end if;
3679                   end;
3680
3681                   Check_Debug_Info_Needed (E);
3682                end if;
3683
3684                --  AI-117 requires that the convention of a partial view be the
3685                --  same as the convention of the full view. Note that this is a
3686                --  recognized breach of privacy, but it's essential for logical
3687                --  consistency of representation, and the lack of a rule in
3688                --  RM95 was an oversight.
3689
3690                Set_Convention (E, Convention (Full_View (E)));
3691
3692                Set_Size_Known_At_Compile_Time (E,
3693                  Size_Known_At_Compile_Time (Full_View (E)));
3694
3695                --  Size information is copied from the full view to the
3696                --  incomplete or private view for consistency.
3697
3698                --  We skip this is the full view is not a type. This is very
3699                --  strange of course, and can only happen as a result of
3700                --  certain illegalities, such as a premature attempt to derive
3701                --  from an incomplete type.
3702
3703                if Is_Type (Full_View (E)) then
3704                   Set_Size_Info (E, Full_View (E));
3705                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3706                end if;
3707
3708                return Result;
3709
3710             --  Case of no full view present. If entity is derived or subtype,
3711             --  it is safe to freeze, correctness depends on the frozen status
3712             --  of parent. Otherwise it is either premature usage, or a Taft
3713             --  amendment type, so diagnosis is at the point of use and the
3714             --  type might be frozen later.
3715
3716             elsif E /= Base_Type (E)
3717               or else Is_Derived_Type (E)
3718             then
3719                null;
3720
3721             else
3722                Set_Is_Frozen (E, False);
3723                return No_List;
3724             end if;
3725
3726          --  For access subprogram, freeze types of all formals, the return
3727          --  type was already frozen, since it is the Etype of the function.
3728          --  Formal types can be tagged Taft amendment types, but otherwise
3729          --  they cannot be incomplete.
3730
3731          elsif Ekind (E) = E_Subprogram_Type then
3732             Formal := First_Formal (E);
3733
3734             while Present (Formal) loop
3735                if Ekind (Etype (Formal)) = E_Incomplete_Type
3736                  and then No (Full_View (Etype (Formal)))
3737                  and then not Is_Value_Type (Etype (Formal))
3738                then
3739                   if Is_Tagged_Type (Etype (Formal)) then
3740                      null;
3741                   else
3742                      Error_Msg_NE
3743                        ("invalid use of incomplete type&", E, Etype (Formal));
3744                   end if;
3745                end if;
3746
3747                Freeze_And_Append (Etype (Formal), Loc, Result);
3748                Next_Formal (Formal);
3749             end loop;
3750
3751             Freeze_Subprogram (E);
3752
3753          --  For access to a protected subprogram, freeze the equivalent type
3754          --  (however this is not set if we are not generating code or if this
3755          --  is an anonymous type used just for resolution).
3756
3757          elsif Is_Access_Protected_Subprogram_Type (E) then
3758             if Present (Equivalent_Type (E)) then
3759                Freeze_And_Append (Equivalent_Type (E), Loc, Result);
3760             end if;
3761          end if;
3762
3763          --  Generic types are never seen by the back-end, and are also not
3764          --  processed by the expander (since the expander is turned off for
3765          --  generic processing), so we never need freeze nodes for them.
3766
3767          if Is_Generic_Type (E) then
3768             return Result;
3769          end if;
3770
3771          --  Some special processing for non-generic types to complete
3772          --  representation details not known till the freeze point.
3773
3774          if Is_Fixed_Point_Type (E) then
3775             Freeze_Fixed_Point_Type (E);
3776
3777             --  Some error checks required for ordinary fixed-point type. Defer
3778             --  these till the freeze-point since we need the small and range
3779             --  values. We only do these checks for base types
3780
3781             if Is_Ordinary_Fixed_Point_Type (E)
3782               and then E = Base_Type (E)
3783             then
3784                if Small_Value (E) < Ureal_2_M_80 then
3785                   Error_Msg_Name_1 := Name_Small;
3786                   Error_Msg_N
3787                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3788
3789                elsif Small_Value (E) > Ureal_2_80 then
3790                   Error_Msg_Name_1 := Name_Small;
3791                   Error_Msg_N
3792                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3793                end if;
3794
3795                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3796                   Error_Msg_Name_1 := Name_First;
3797                   Error_Msg_N
3798                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3799                end if;
3800
3801                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3802                   Error_Msg_Name_1 := Name_Last;
3803                   Error_Msg_N
3804                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3805                end if;
3806             end if;
3807
3808          elsif Is_Enumeration_Type (E) then
3809             Freeze_Enumeration_Type (E);
3810
3811          elsif Is_Integer_Type (E) then
3812             Adjust_Esize_For_Alignment (E);
3813
3814             if Is_Modular_Integer_Type (E)
3815               and then Warn_On_Suspicious_Modulus_Value
3816             then
3817                Check_Suspicious_Modulus (E);
3818             end if;
3819
3820          elsif Is_Access_Type (E) then
3821
3822             --  Check restriction for standard storage pool
3823
3824             if No (Associated_Storage_Pool (E)) then
3825                Check_Restriction (No_Standard_Storage_Pools, E);
3826             end if;
3827
3828             --  Deal with error message for pure access type. This is not an
3829             --  error in Ada 2005 if there is no pool (see AI-366).
3830
3831             if Is_Pure_Unit_Access_Type (E)
3832               and then (Ada_Version < Ada_2005
3833                          or else not No_Pool_Assigned (E))
3834             then
3835                Error_Msg_N ("named access type not allowed in pure unit", E);
3836
3837                if Ada_Version >= Ada_2005 then
3838                   Error_Msg_N
3839                     ("\would be legal if Storage_Size of 0 given?", E);
3840
3841                elsif No_Pool_Assigned (E) then
3842                   Error_Msg_N
3843                     ("\would be legal in Ada 2005?", E);
3844
3845                else
3846                   Error_Msg_N
3847                     ("\would be legal in Ada 2005 if "
3848                      & "Storage_Size of 0 given?", E);
3849                end if;
3850             end if;
3851          end if;
3852
3853          --  Case of composite types
3854
3855          if Is_Composite_Type (E) then
3856
3857             --  AI-117 requires that all new primitives of a tagged type must
3858             --  inherit the convention of the full view of the type. Inherited
3859             --  and overriding operations are defined to inherit the convention
3860             --  of their parent or overridden subprogram (also specified in
3861             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3862             --  and New_Overloaded_Entity). Here we set the convention of
3863             --  primitives that are still convention Ada, which will ensure
3864             --  that any new primitives inherit the type's convention. Class-
3865             --  wide types can have a foreign convention inherited from their
3866             --  specific type, but are excluded from this since they don't have
3867             --  any associated primitives.
3868
3869             if Is_Tagged_Type (E)
3870               and then not Is_Class_Wide_Type (E)
3871               and then Convention (E) /= Convention_Ada
3872             then
3873                declare
3874                   Prim_List : constant Elist_Id := Primitive_Operations (E);
3875                   Prim      : Elmt_Id;
3876                begin
3877                   Prim := First_Elmt (Prim_List);
3878                   while Present (Prim) loop
3879                      if Convention (Node (Prim)) = Convention_Ada then
3880                         Set_Convention (Node (Prim), Convention (E));
3881                      end if;
3882
3883                      Next_Elmt (Prim);
3884                   end loop;
3885                end;
3886             end if;
3887          end if;
3888
3889          --  Now that all types from which E may depend are frozen, see if the
3890          --  size is known at compile time, if it must be unsigned, or if
3891          --  strict alignment is required
3892
3893          Check_Compile_Time_Size (E);
3894          Check_Unsigned_Type (E);
3895
3896          if Base_Type (E) = E then
3897             Check_Strict_Alignment (E);
3898          end if;
3899
3900          --  Do not allow a size clause for a type which does not have a size
3901          --  that is known at compile time
3902
3903          if Has_Size_Clause (E)
3904            and then not Size_Known_At_Compile_Time (E)
3905          then
3906             --  Suppress this message if errors posted on E, even if we are
3907             --  in all errors mode, since this is often a junk message
3908
3909             if not Error_Posted (E) then
3910                Error_Msg_N
3911                  ("size clause not allowed for variable length type",
3912                   Size_Clause (E));
3913             end if;
3914          end if;
3915
3916          --  Remaining process is to set/verify the representation information,
3917          --  in particular the size and alignment values. This processing is
3918          --  not required for generic types, since generic types do not play
3919          --  any part in code generation, and so the size and alignment values
3920          --  for such types are irrelevant.
3921
3922          if Is_Generic_Type (E) then
3923             return Result;
3924
3925          --  Otherwise we call the layout procedure
3926
3927          else
3928             Layout_Type (E);
3929          end if;
3930
3931          --  End of freeze processing for type entities
3932       end if;
3933
3934       --  Here is where we logically freeze the current entity. If it has a
3935       --  freeze node, then this is the point at which the freeze node is
3936       --  linked into the result list.
3937
3938       if Has_Delayed_Freeze (E) then
3939
3940          --  If a freeze node is already allocated, use it, otherwise allocate
3941          --  a new one. The preallocation happens in the case of anonymous base
3942          --  types, where we preallocate so that we can set First_Subtype_Link.
3943          --  Note that we reset the Sloc to the current freeze location.
3944
3945          if Present (Freeze_Node (E)) then
3946             F_Node := Freeze_Node (E);
3947             Set_Sloc (F_Node, Loc);
3948
3949          else
3950             F_Node := New_Node (N_Freeze_Entity, Loc);
3951             Set_Freeze_Node (E, F_Node);
3952             Set_Access_Types_To_Process (F_Node, No_Elist);
3953             Set_TSS_Elist (F_Node, No_Elist);
3954             Set_Actions (F_Node, No_List);
3955          end if;
3956
3957          Set_Entity (F_Node, E);
3958
3959          if Result = No_List then
3960             Result := New_List (F_Node);
3961          else
3962             Append (F_Node, Result);
3963          end if;
3964
3965          --  A final pass over record types with discriminants. If the type
3966          --  has an incomplete declaration, there may be constrained access
3967          --  subtypes declared elsewhere, which do not depend on the discrimi-
3968          --  nants of the type, and which are used as component types (i.e.
3969          --  the full view is a recursive type). The designated types of these
3970          --  subtypes can only be elaborated after the type itself, and they
3971          --  need an itype reference.
3972
3973          if Ekind (E) = E_Record_Type
3974            and then Has_Discriminants (E)
3975          then
3976             declare
3977                Comp : Entity_Id;
3978                IR   : Node_Id;
3979                Typ  : Entity_Id;
3980
3981             begin
3982                Comp := First_Component (E);
3983
3984                while Present (Comp) loop
3985                   Typ  := Etype (Comp);
3986
3987                   if Ekind (Comp) = E_Component
3988                     and then Is_Access_Type (Typ)
3989                     and then Scope (Typ) /= E
3990                     and then Base_Type (Designated_Type (Typ)) = E
3991                     and then Is_Itype (Designated_Type (Typ))
3992                   then
3993                      IR := Make_Itype_Reference (Sloc (Comp));
3994                      Set_Itype (IR, Designated_Type (Typ));
3995                      Append (IR, Result);
3996                   end if;
3997
3998                   Next_Component (Comp);
3999                end loop;
4000             end;
4001          end if;
4002       end if;
4003
4004       --  When a type is frozen, the first subtype of the type is frozen as
4005       --  well (RM 13.14(15)). This has to be done after freezing the type,
4006       --  since obviously the first subtype depends on its own base type.
4007
4008       if Is_Type (E) then
4009          Freeze_And_Append (First_Subtype (E), Loc, Result);
4010
4011          --  If we just froze a tagged non-class wide record, then freeze the
4012          --  corresponding class-wide type. This must be done after the tagged
4013          --  type itself is frozen, because the class-wide type refers to the
4014          --  tagged type which generates the class.
4015
4016          if Is_Tagged_Type (E)
4017            and then not Is_Class_Wide_Type (E)
4018            and then Present (Class_Wide_Type (E))
4019          then
4020             Freeze_And_Append (Class_Wide_Type (E), Loc, Result);
4021          end if;
4022       end if;
4023
4024       Check_Debug_Info_Needed (E);
4025
4026       --  Special handling for subprograms
4027
4028       if Is_Subprogram (E) then
4029
4030          --  If subprogram has address clause then reset Is_Public flag, since
4031          --  we do not want the backend to generate external references.
4032
4033          if Present (Address_Clause (E))
4034            and then not Is_Library_Level_Entity (E)
4035          then
4036             Set_Is_Public (E, False);
4037
4038          --  If no address clause and not intrinsic, then for imported
4039          --  subprogram in main unit, generate descriptor if we are in
4040          --  Propagate_Exceptions mode.
4041
4042          elsif Propagate_Exceptions
4043            and then Is_Imported (E)
4044            and then not Is_Intrinsic_Subprogram (E)
4045            and then Convention (E) /= Convention_Stubbed
4046          then
4047             if Result = No_List then
4048                Result := Empty_List;
4049             end if;
4050          end if;
4051       end if;
4052
4053       return Result;
4054    end Freeze_Entity;
4055
4056    -----------------------------
4057    -- Freeze_Enumeration_Type --
4058    -----------------------------
4059
4060    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4061    begin
4062       --  By default, if no size clause is present, an enumeration type with
4063       --  Convention C is assumed to interface to a C enum, and has integer
4064       --  size. This applies to types. For subtypes, verify that its base
4065       --  type has no size clause either.
4066
4067       if Has_Foreign_Convention (Typ)
4068         and then not Has_Size_Clause (Typ)
4069         and then not Has_Size_Clause (Base_Type (Typ))
4070         and then Esize (Typ) < Standard_Integer_Size
4071       then
4072          Init_Esize (Typ, Standard_Integer_Size);
4073
4074       else
4075          --  If the enumeration type interfaces to C, and it has a size clause
4076          --  that specifies less than int size, it warrants a warning. The
4077          --  user may intend the C type to be an enum or a char, so this is
4078          --  not by itself an error that the Ada compiler can detect, but it
4079          --  it is a worth a heads-up. For Boolean and Character types we
4080          --  assume that the programmer has the proper C type in mind.
4081
4082          if Convention (Typ) = Convention_C
4083            and then Has_Size_Clause (Typ)
4084            and then Esize (Typ) /= Esize (Standard_Integer)
4085            and then not Is_Boolean_Type (Typ)
4086            and then not Is_Character_Type (Typ)
4087          then
4088             Error_Msg_N
4089               ("C enum types have the size of a C int?", Size_Clause (Typ));
4090          end if;
4091
4092          Adjust_Esize_For_Alignment (Typ);
4093       end if;
4094    end Freeze_Enumeration_Type;
4095
4096    -----------------------
4097    -- Freeze_Expression --
4098    -----------------------
4099
4100    procedure Freeze_Expression (N : Node_Id) is
4101       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4102       Typ         : Entity_Id;
4103       Nam         : Entity_Id;
4104       Desig_Typ   : Entity_Id;
4105       P           : Node_Id;
4106       Parent_P    : Node_Id;
4107
4108       Freeze_Outside : Boolean := False;
4109       --  This flag is set true if the entity must be frozen outside the
4110       --  current subprogram. This happens in the case of expander generated
4111       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4112       --  not freeze all entities like other bodies, but which nevertheless
4113       --  may reference entities that have to be frozen before the body and
4114       --  obviously cannot be frozen inside the body.
4115
4116       function In_Exp_Body (N : Node_Id) return Boolean;
4117       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4118       --  it is the handled statement sequence of an expander-generated
4119       --  subprogram (init proc, stream subprogram, or renaming as body).
4120       --  If so, this is not a freezing context.
4121
4122       -----------------
4123       -- In_Exp_Body --
4124       -----------------
4125
4126       function In_Exp_Body (N : Node_Id) return Boolean is
4127          P  : Node_Id;
4128          Id : Entity_Id;
4129
4130       begin
4131          if Nkind (N) = N_Subprogram_Body then
4132             P := N;
4133          else
4134             P := Parent (N);
4135          end if;
4136
4137          if Nkind (P) /= N_Subprogram_Body then
4138             return False;
4139
4140          else
4141             Id := Defining_Unit_Name (Specification (P));
4142
4143             if Nkind (Id) = N_Defining_Identifier
4144               and then (Is_Init_Proc (Id)              or else
4145                         Is_TSS (Id, TSS_Stream_Input)  or else
4146                         Is_TSS (Id, TSS_Stream_Output) or else
4147                         Is_TSS (Id, TSS_Stream_Read)   or else
4148                         Is_TSS (Id, TSS_Stream_Write)  or else
4149                         Nkind (Original_Node (P)) =
4150                           N_Subprogram_Renaming_Declaration)
4151             then
4152                return True;
4153             else
4154                return False;
4155             end if;
4156          end if;
4157       end In_Exp_Body;
4158
4159    --  Start of processing for Freeze_Expression
4160
4161    begin
4162       --  Immediate return if freezing is inhibited. This flag is set by the
4163       --  analyzer to stop freezing on generated expressions that would cause
4164       --  freezing if they were in the source program, but which are not
4165       --  supposed to freeze, since they are created.
4166
4167       if Must_Not_Freeze (N) then
4168          return;
4169       end if;
4170
4171       --  If expression is non-static, then it does not freeze in a default
4172       --  expression, see section "Handling of Default Expressions" in the
4173       --  spec of package Sem for further details. Note that we have to
4174       --  make sure that we actually have a real expression (if we have
4175       --  a subtype indication, we can't test Is_Static_Expression!)
4176
4177       if In_Spec_Exp
4178         and then Nkind (N) in N_Subexpr
4179         and then not Is_Static_Expression (N)
4180       then
4181          return;
4182       end if;
4183
4184       --  Freeze type of expression if not frozen already
4185
4186       Typ := Empty;
4187
4188       if Nkind (N) in N_Has_Etype then
4189          if not Is_Frozen (Etype (N)) then
4190             Typ := Etype (N);
4191
4192          --  Base type may be an derived numeric type that is frozen at
4193          --  the point of declaration, but first_subtype is still unfrozen.
4194
4195          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4196             Typ := First_Subtype (Etype (N));
4197          end if;
4198       end if;
4199
4200       --  For entity name, freeze entity if not frozen already. A special
4201       --  exception occurs for an identifier that did not come from source.
4202       --  We don't let such identifiers freeze a non-internal entity, i.e.
4203       --  an entity that did come from source, since such an identifier was
4204       --  generated by the expander, and cannot have any semantic effect on
4205       --  the freezing semantics. For example, this stops the parameter of
4206       --  an initialization procedure from freezing the variable.
4207
4208       if Is_Entity_Name (N)
4209         and then not Is_Frozen (Entity (N))
4210         and then (Nkind (N) /= N_Identifier
4211                    or else Comes_From_Source (N)
4212                    or else not Comes_From_Source (Entity (N)))
4213       then
4214          Nam := Entity (N);
4215       else
4216          Nam := Empty;
4217       end if;
4218
4219       --  For an allocator freeze designated type if not frozen already
4220
4221       --  For an aggregate whose component type is an access type, freeze the
4222       --  designated type now, so that its freeze does not appear within the
4223       --  loop that might be created in the expansion of the aggregate. If the
4224       --  designated type is a private type without full view, the expression
4225       --  cannot contain an allocator, so the type is not frozen.
4226
4227       --  For a function, we freeze the entity when the subprogram declaration
4228       --  is frozen, but a function call may appear in an initialization proc.
4229       --  before the declaration is frozen. We need to generate the extra
4230       --  formals, if any, to ensure that the expansion of the call includes
4231       --  the proper actuals. This only applies to Ada subprograms, not to
4232       --  imported ones.
4233
4234       Desig_Typ := Empty;
4235
4236       case Nkind (N) is
4237          when N_Allocator =>
4238             Desig_Typ := Designated_Type (Etype (N));
4239
4240          when N_Aggregate =>
4241             if Is_Array_Type (Etype (N))
4242               and then Is_Access_Type (Component_Type (Etype (N)))
4243             then
4244                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4245             end if;
4246
4247          when N_Selected_Component |
4248             N_Indexed_Component    |
4249             N_Slice                =>
4250
4251             if Is_Access_Type (Etype (Prefix (N))) then
4252                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4253             end if;
4254
4255          when N_Identifier =>
4256             if Present (Nam)
4257               and then Ekind (Nam) = E_Function
4258               and then Nkind (Parent (N)) = N_Function_Call
4259               and then Convention (Nam) = Convention_Ada
4260             then
4261                Create_Extra_Formals (Nam);
4262             end if;
4263
4264          when others =>
4265             null;
4266       end case;
4267
4268       if Desig_Typ /= Empty
4269         and then (Is_Frozen (Desig_Typ)
4270                    or else (not Is_Fully_Defined (Desig_Typ)))
4271       then
4272          Desig_Typ := Empty;
4273       end if;
4274
4275       --  All done if nothing needs freezing
4276
4277       if No (Typ)
4278         and then No (Nam)
4279         and then No (Desig_Typ)
4280       then
4281          return;
4282       end if;
4283
4284       --  Loop for looking at the right place to insert the freeze nodes,
4285       --  exiting from the loop when it is appropriate to insert the freeze
4286       --  node before the current node P.
4287
4288       --  Also checks some special exceptions to the freezing rules. These
4289       --  cases result in a direct return, bypassing the freeze action.
4290
4291       P := N;
4292       loop
4293          Parent_P := Parent (P);
4294
4295          --  If we don't have a parent, then we are not in a well-formed tree.
4296          --  This is an unusual case, but there are some legitimate situations
4297          --  in which this occurs, notably when the expressions in the range of
4298          --  a type declaration are resolved. We simply ignore the freeze
4299          --  request in this case. Is this right ???
4300
4301          if No (Parent_P) then
4302             return;
4303          end if;
4304
4305          --  See if we have got to an appropriate point in the tree
4306
4307          case Nkind (Parent_P) is
4308
4309             --  A special test for the exception of (RM 13.14(8)) for the case
4310             --  of per-object expressions (RM 3.8(18)) occurring in component
4311             --  definition or a discrete subtype definition. Note that we test
4312             --  for a component declaration which includes both cases we are
4313             --  interested in, and furthermore the tree does not have explicit
4314             --  nodes for either of these two constructs.
4315
4316             when N_Component_Declaration =>
4317
4318                --  The case we want to test for here is an identifier that is
4319                --  a per-object expression, this is either a discriminant that
4320                --  appears in a context other than the component declaration
4321                --  or it is a reference to the type of the enclosing construct.
4322
4323                --  For either of these cases, we skip the freezing
4324
4325                if not In_Spec_Expression
4326                  and then Nkind (N) = N_Identifier
4327                  and then (Present (Entity (N)))
4328                then
4329                   --  We recognize the discriminant case by just looking for
4330                   --  a reference to a discriminant. It can only be one for
4331                   --  the enclosing construct. Skip freezing in this case.
4332
4333                   if Ekind (Entity (N)) = E_Discriminant then
4334                      return;
4335
4336                   --  For the case of a reference to the enclosing record,
4337                   --  (or task or protected type), we look for a type that
4338                   --  matches the current scope.
4339
4340                   elsif Entity (N) = Current_Scope then
4341                      return;
4342                   end if;
4343                end if;
4344
4345             --  If we have an enumeration literal that appears as the choice in
4346             --  the aggregate of an enumeration representation clause, then
4347             --  freezing does not occur (RM 13.14(10)).
4348
4349             when N_Enumeration_Representation_Clause =>
4350
4351                --  The case we are looking for is an enumeration literal
4352
4353                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4354                  and then Is_Enumeration_Type (Etype (N))
4355                then
4356                   --  If enumeration literal appears directly as the choice,
4357                   --  do not freeze (this is the normal non-overloaded case)
4358
4359                   if Nkind (Parent (N)) = N_Component_Association
4360                     and then First (Choices (Parent (N))) = N
4361                   then
4362                      return;
4363
4364                   --  If enumeration literal appears as the name of function
4365                   --  which is the choice, then also do not freeze. This
4366                   --  happens in the overloaded literal case, where the
4367                   --  enumeration literal is temporarily changed to a function
4368                   --  call for overloading analysis purposes.
4369
4370                   elsif Nkind (Parent (N)) = N_Function_Call
4371                      and then
4372                        Nkind (Parent (Parent (N))) = N_Component_Association
4373                      and then
4374                        First (Choices (Parent (Parent (N)))) = Parent (N)
4375                   then
4376                      return;
4377                   end if;
4378                end if;
4379
4380             --  Normally if the parent is a handled sequence of statements,
4381             --  then the current node must be a statement, and that is an
4382             --  appropriate place to insert a freeze node.
4383
4384             when N_Handled_Sequence_Of_Statements =>
4385
4386                --  An exception occurs when the sequence of statements is for
4387                --  an expander generated body that did not do the usual freeze
4388                --  all operation. In this case we usually want to freeze
4389                --  outside this body, not inside it, and we skip past the
4390                --  subprogram body that we are inside.
4391
4392                if In_Exp_Body (Parent_P) then
4393
4394                   --  However, we *do* want to freeze at this point if we have
4395                   --  an entity to freeze, and that entity is declared *inside*
4396                   --  the body of the expander generated procedure. This case
4397                   --  is recognized by the scope of the type, which is either
4398                   --  the spec for some enclosing body, or (in the case of
4399                   --  init_procs, for which there are no separate specs) the
4400                   --  current scope.
4401
4402                   declare
4403                      Subp : constant Node_Id := Parent (Parent_P);
4404                      Cspc : Entity_Id;
4405
4406                   begin
4407                      if Nkind (Subp) = N_Subprogram_Body then
4408                         Cspc := Corresponding_Spec (Subp);
4409
4410                         if (Present (Typ) and then Scope (Typ) = Cspc)
4411                              or else
4412                            (Present (Nam) and then Scope (Nam) = Cspc)
4413                         then
4414                            exit;
4415
4416                         elsif Present (Typ)
4417                           and then Scope (Typ) = Current_Scope
4418                           and then Current_Scope = Defining_Entity (Subp)
4419                         then
4420                            exit;
4421                         end if;
4422                      end if;
4423                   end;
4424
4425                   --  If not that exception to the exception, then this is
4426                   --  where we delay the freeze till outside the body.
4427
4428                   Parent_P := Parent (Parent_P);
4429                   Freeze_Outside := True;
4430
4431                --  Here if normal case where we are in handled statement
4432                --  sequence and want to do the insertion right there.
4433
4434                else
4435                   exit;
4436                end if;
4437
4438             --  If parent is a body or a spec or a block, then the current node
4439             --  is a statement or declaration and we can insert the freeze node
4440             --  before it.
4441
4442             when N_Package_Specification |
4443                  N_Package_Body          |
4444                  N_Subprogram_Body       |
4445                  N_Task_Body             |
4446                  N_Protected_Body        |
4447                  N_Entry_Body            |
4448                  N_Block_Statement       => exit;
4449
4450             --  The expander is allowed to define types in any statements list,
4451             --  so any of the following parent nodes also mark a freezing point
4452             --  if the actual node is in a list of statements or declarations.
4453
4454             when N_Exception_Handler          |
4455                  N_If_Statement               |
4456                  N_Elsif_Part                 |
4457                  N_Case_Statement_Alternative |
4458                  N_Compilation_Unit_Aux       |
4459                  N_Selective_Accept           |
4460                  N_Accept_Alternative         |
4461                  N_Delay_Alternative          |
4462                  N_Conditional_Entry_Call     |
4463                  N_Entry_Call_Alternative     |
4464                  N_Triggering_Alternative     |
4465                  N_Abortable_Part             |
4466                  N_And_Then                   |
4467                  N_Or_Else                    |
4468                  N_Freeze_Entity              =>
4469
4470                exit when Is_List_Member (P);
4471
4472             --  Note: The N_Loop_Statement is a special case. A type that
4473             --  appears in the source can never be frozen in a loop (this
4474             --  occurs only because of a loop expanded by the expander), so we
4475             --  keep on going. Otherwise we terminate the search. Same is true
4476             --  of any entity which comes from source. (if they have predefined
4477             --  type, that type does not appear to come from source, but the
4478             --  entity should not be frozen here).
4479
4480             when N_Loop_Statement =>
4481                exit when not Comes_From_Source (Etype (N))
4482                  and then (No (Nam) or else not Comes_From_Source (Nam));
4483
4484             --  For all other cases, keep looking at parents
4485
4486             when others =>
4487                null;
4488          end case;
4489
4490          --  We fall through the case if we did not yet find the proper
4491          --  place in the free for inserting the freeze node, so climb!
4492
4493          P := Parent_P;
4494       end loop;
4495
4496       --  If the expression appears in a record or an initialization procedure,
4497       --  the freeze nodes are collected and attached to the current scope, to
4498       --  be inserted and analyzed on exit from the scope, to insure that
4499       --  generated entities appear in the correct scope. If the expression is
4500       --  a default for a discriminant specification, the scope is still void.
4501       --  The expression can also appear in the discriminant part of a private
4502       --  or concurrent type.
4503
4504       --  If the expression appears in a constrained subcomponent of an
4505       --  enclosing record declaration, the freeze nodes must be attached to
4506       --  the outer record type so they can eventually be placed in the
4507       --  enclosing declaration list.
4508
4509       --  The other case requiring this special handling is if we are in a
4510       --  default expression, since in that case we are about to freeze a
4511       --  static type, and the freeze scope needs to be the outer scope, not
4512       --  the scope of the subprogram with the default parameter.
4513
4514       --  For default expressions and other spec expressions in generic units,
4515       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4516       --  placing them at the proper place, after the generic unit.
4517
4518       if (In_Spec_Exp and not Inside_A_Generic)
4519         or else Freeze_Outside
4520         or else (Is_Type (Current_Scope)
4521                   and then (not Is_Concurrent_Type (Current_Scope)
4522                              or else not Has_Completion (Current_Scope)))
4523         or else Ekind (Current_Scope) = E_Void
4524       then
4525          declare
4526             Loc          : constant Source_Ptr := Sloc (Current_Scope);
4527             Freeze_Nodes : List_Id := No_List;
4528             Pos          : Int := Scope_Stack.Last;
4529
4530          begin
4531             if Present (Desig_Typ) then
4532                Freeze_And_Append (Desig_Typ, Loc, Freeze_Nodes);
4533             end if;
4534
4535             if Present (Typ) then
4536                Freeze_And_Append (Typ, Loc, Freeze_Nodes);
4537             end if;
4538
4539             if Present (Nam) then
4540                Freeze_And_Append (Nam, Loc, Freeze_Nodes);
4541             end if;
4542
4543             --  The current scope may be that of a constrained component of
4544             --  an enclosing record declaration, which is above the current
4545             --  scope in the scope stack.
4546
4547             if Is_Record_Type (Scope (Current_Scope)) then
4548                Pos := Pos - 1;
4549             end if;
4550
4551             if Is_Non_Empty_List (Freeze_Nodes) then
4552                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4553                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4554                       Freeze_Nodes;
4555                else
4556                   Append_List (Freeze_Nodes,
4557                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4558                end if;
4559             end if;
4560          end;
4561
4562          return;
4563       end if;
4564
4565       --  Now we have the right place to do the freezing. First, a special
4566       --  adjustment, if we are in spec-expression analysis mode, these freeze
4567       --  actions must not be thrown away (normally all inserted actions are
4568       --  thrown away in this mode. However, the freeze actions are from static
4569       --  expressions and one of the important reasons we are doing this
4570       --  special analysis is to get these freeze actions. Therefore we turn
4571       --  off the In_Spec_Expression mode to propagate these freeze actions.
4572       --  This also means they get properly analyzed and expanded.
4573
4574       In_Spec_Expression := False;
4575
4576       --  Freeze the designated type of an allocator (RM 13.14(13))
4577
4578       if Present (Desig_Typ) then
4579          Freeze_Before (P, Desig_Typ);
4580       end if;
4581
4582       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4583       --  the enumeration representation clause exception in the loop above.
4584
4585       if Present (Typ) then
4586          Freeze_Before (P, Typ);
4587       end if;
4588
4589       --  Freeze name if one is present (RM 13.14(11))
4590
4591       if Present (Nam) then
4592          Freeze_Before (P, Nam);
4593       end if;
4594
4595       --  Restore In_Spec_Expression flag
4596
4597       In_Spec_Expression := In_Spec_Exp;
4598    end Freeze_Expression;
4599
4600    -----------------------------
4601    -- Freeze_Fixed_Point_Type --
4602    -----------------------------
4603
4604    --  Certain fixed-point types and subtypes, including implicit base types
4605    --  and declared first subtypes, have not yet set up a range. This is
4606    --  because the range cannot be set until the Small and Size values are
4607    --  known, and these are not known till the type is frozen.
4608
4609    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4610    --  whose bounds are unanalyzed real literals. This routine will recognize
4611    --  this case, and transform this range node into a properly typed range
4612    --  with properly analyzed and resolved values.
4613
4614    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4615       Rng   : constant Node_Id    := Scalar_Range (Typ);
4616       Lo    : constant Node_Id    := Low_Bound (Rng);
4617       Hi    : constant Node_Id    := High_Bound (Rng);
4618       Btyp  : constant Entity_Id  := Base_Type (Typ);
4619       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4620       BLo   : constant Node_Id    := Low_Bound (Brng);
4621       BHi   : constant Node_Id    := High_Bound (Brng);
4622       Small : constant Ureal      := Small_Value (Typ);
4623       Loval : Ureal;
4624       Hival : Ureal;
4625       Atype : Entity_Id;
4626
4627       Actual_Size : Nat;
4628
4629       function Fsize (Lov, Hiv : Ureal) return Nat;
4630       --  Returns size of type with given bounds. Also leaves these
4631       --  bounds set as the current bounds of the Typ.
4632
4633       -----------
4634       -- Fsize --
4635       -----------
4636
4637       function Fsize (Lov, Hiv : Ureal) return Nat is
4638       begin
4639          Set_Realval (Lo, Lov);
4640          Set_Realval (Hi, Hiv);
4641          return Minimum_Size (Typ);
4642       end Fsize;
4643
4644    --  Start of processing for Freeze_Fixed_Point_Type
4645
4646    begin
4647       --  If Esize of a subtype has not previously been set, set it now
4648
4649       if Unknown_Esize (Typ) then
4650          Atype := Ancestor_Subtype (Typ);
4651
4652          if Present (Atype) then
4653             Set_Esize (Typ, Esize (Atype));
4654          else
4655             Set_Esize (Typ, Esize (Base_Type (Typ)));
4656          end if;
4657       end if;
4658
4659       --  Immediate return if the range is already analyzed. This means that
4660       --  the range is already set, and does not need to be computed by this
4661       --  routine.
4662
4663       if Analyzed (Rng) then
4664          return;
4665       end if;
4666
4667       --  Immediate return if either of the bounds raises Constraint_Error
4668
4669       if Raises_Constraint_Error (Lo)
4670         or else Raises_Constraint_Error (Hi)
4671       then
4672          return;
4673       end if;
4674
4675       Loval := Realval (Lo);
4676       Hival := Realval (Hi);
4677
4678       --  Ordinary fixed-point case
4679
4680       if Is_Ordinary_Fixed_Point_Type (Typ) then
4681
4682          --  For the ordinary fixed-point case, we are allowed to fudge the
4683          --  end-points up or down by small. Generally we prefer to fudge up,
4684          --  i.e. widen the bounds for non-model numbers so that the end points
4685          --  are included. However there are cases in which this cannot be
4686          --  done, and indeed cases in which we may need to narrow the bounds.
4687          --  The following circuit makes the decision.
4688
4689          --  Note: our terminology here is that Incl_EP means that the bounds
4690          --  are widened by Small if necessary to include the end points, and
4691          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4692          --  end-points if this reduces the size.
4693
4694          --  Note that in the Incl case, all we care about is including the
4695          --  end-points. In the Excl case, we want to narrow the bounds as
4696          --  much as permitted by the RM, to give the smallest possible size.
4697
4698          Fudge : declare
4699             Loval_Incl_EP : Ureal;
4700             Hival_Incl_EP : Ureal;
4701
4702             Loval_Excl_EP : Ureal;
4703             Hival_Excl_EP : Ureal;
4704
4705             Size_Incl_EP  : Nat;
4706             Size_Excl_EP  : Nat;
4707
4708             Model_Num     : Ureal;
4709             First_Subt    : Entity_Id;
4710             Actual_Lo     : Ureal;
4711             Actual_Hi     : Ureal;
4712
4713          begin
4714             --  First step. Base types are required to be symmetrical. Right
4715             --  now, the base type range is a copy of the first subtype range.
4716             --  This will be corrected before we are done, but right away we
4717             --  need to deal with the case where both bounds are non-negative.
4718             --  In this case, we set the low bound to the negative of the high
4719             --  bound, to make sure that the size is computed to include the
4720             --  required sign. Note that we do not need to worry about the
4721             --  case of both bounds negative, because the sign will be dealt
4722             --  with anyway. Furthermore we can't just go making such a bound
4723             --  symmetrical, since in a twos-complement system, there is an
4724             --  extra negative value which could not be accommodated on the
4725             --  positive side.
4726
4727             if Typ = Btyp
4728               and then not UR_Is_Negative (Loval)
4729               and then Hival > Loval
4730             then
4731                Loval := -Hival;
4732                Set_Realval (Lo, Loval);
4733             end if;
4734
4735             --  Compute the fudged bounds. If the number is a model number,
4736             --  then we do nothing to include it, but we are allowed to backoff
4737             --  to the next adjacent model number when we exclude it. If it is
4738             --  not a model number then we straddle the two values with the
4739             --  model numbers on either side.
4740
4741             Model_Num := UR_Trunc (Loval / Small) * Small;
4742
4743             if Loval = Model_Num then
4744                Loval_Incl_EP := Model_Num;
4745             else
4746                Loval_Incl_EP := Model_Num - Small;
4747             end if;
4748
4749             --  The low value excluding the end point is Small greater, but
4750             --  we do not do this exclusion if the low value is positive,
4751             --  since it can't help the size and could actually hurt by
4752             --  crossing the high bound.
4753
4754             if UR_Is_Negative (Loval_Incl_EP) then
4755                Loval_Excl_EP := Loval_Incl_EP + Small;
4756
4757                --  If the value went from negative to zero, then we have the
4758                --  case where Loval_Incl_EP is the model number just below
4759                --  zero, so we want to stick to the negative value for the
4760                --  base type to maintain the condition that the size will
4761                --  include signed values.
4762
4763                if Typ = Btyp
4764                  and then UR_Is_Zero (Loval_Excl_EP)
4765                then
4766                   Loval_Excl_EP := Loval_Incl_EP;
4767                end if;
4768
4769             else
4770                Loval_Excl_EP := Loval_Incl_EP;
4771             end if;
4772
4773             --  Similar processing for upper bound and high value
4774
4775             Model_Num := UR_Trunc (Hival / Small) * Small;
4776
4777             if Hival = Model_Num then
4778                Hival_Incl_EP := Model_Num;
4779             else
4780                Hival_Incl_EP := Model_Num + Small;
4781             end if;
4782
4783             if UR_Is_Positive (Hival_Incl_EP) then
4784                Hival_Excl_EP := Hival_Incl_EP - Small;
4785             else
4786                Hival_Excl_EP := Hival_Incl_EP;
4787             end if;
4788
4789             --  One further adjustment is needed. In the case of subtypes, we
4790             --  cannot go outside the range of the base type, or we get
4791             --  peculiarities, and the base type range is already set. This
4792             --  only applies to the Incl values, since clearly the Excl values
4793             --  are already as restricted as they are allowed to be.
4794
4795             if Typ /= Btyp then
4796                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4797                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4798             end if;
4799
4800             --  Get size including and excluding end points
4801
4802             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4803             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4804
4805             --  No need to exclude end-points if it does not reduce size
4806
4807             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4808                Loval_Excl_EP := Loval_Incl_EP;
4809             end if;
4810
4811             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4812                Hival_Excl_EP := Hival_Incl_EP;
4813             end if;
4814
4815             --  Now we set the actual size to be used. We want to use the
4816             --  bounds fudged up to include the end-points but only if this
4817             --  can be done without violating a specifically given size
4818             --  size clause or causing an unacceptable increase in size.
4819
4820             --  Case of size clause given
4821
4822             if Has_Size_Clause (Typ) then
4823
4824                --  Use the inclusive size only if it is consistent with
4825                --  the explicitly specified size.
4826
4827                if Size_Incl_EP <= RM_Size (Typ) then
4828                   Actual_Lo   := Loval_Incl_EP;
4829                   Actual_Hi   := Hival_Incl_EP;
4830                   Actual_Size := Size_Incl_EP;
4831
4832                --  If the inclusive size is too large, we try excluding
4833                --  the end-points (will be caught later if does not work).
4834
4835                else
4836                   Actual_Lo   := Loval_Excl_EP;
4837                   Actual_Hi   := Hival_Excl_EP;
4838                   Actual_Size := Size_Excl_EP;
4839                end if;
4840
4841             --  Case of size clause not given
4842
4843             else
4844                --  If we have a base type whose corresponding first subtype
4845                --  has an explicit size that is large enough to include our
4846                --  end-points, then do so. There is no point in working hard
4847                --  to get a base type whose size is smaller than the specified
4848                --  size of the first subtype.
4849
4850                First_Subt := First_Subtype (Typ);
4851
4852                if Has_Size_Clause (First_Subt)
4853                  and then Size_Incl_EP <= Esize (First_Subt)
4854                then
4855                   Actual_Size := Size_Incl_EP;
4856                   Actual_Lo   := Loval_Incl_EP;
4857                   Actual_Hi   := Hival_Incl_EP;
4858
4859                --  If excluding the end-points makes the size smaller and
4860                --  results in a size of 8,16,32,64, then we take the smaller
4861                --  size. For the 64 case, this is compulsory. For the other
4862                --  cases, it seems reasonable. We like to include end points
4863                --  if we can, but not at the expense of moving to the next
4864                --  natural boundary of size.
4865
4866                elsif Size_Incl_EP /= Size_Excl_EP
4867                  and then Addressable (Size_Excl_EP)
4868                then
4869                   Actual_Size := Size_Excl_EP;
4870                   Actual_Lo   := Loval_Excl_EP;
4871                   Actual_Hi   := Hival_Excl_EP;
4872
4873                --  Otherwise we can definitely include the end points
4874
4875                else
4876                   Actual_Size := Size_Incl_EP;
4877                   Actual_Lo   := Loval_Incl_EP;
4878                   Actual_Hi   := Hival_Incl_EP;
4879                end if;
4880
4881                --  One pathological case: normally we never fudge a low bound
4882                --  down, since it would seem to increase the size (if it has
4883                --  any effect), but for ranges containing single value, or no
4884                --  values, the high bound can be small too large. Consider:
4885
4886                --    type t is delta 2.0**(-14)
4887                --      range 131072.0 .. 0;
4888
4889                --  That lower bound is *just* outside the range of 32 bits, and
4890                --  does need fudging down in this case. Note that the bounds
4891                --  will always have crossed here, since the high bound will be
4892                --  fudged down if necessary, as in the case of:
4893
4894                --    type t is delta 2.0**(-14)
4895                --      range 131072.0 .. 131072.0;
4896
4897                --  So we detect the situation by looking for crossed bounds,
4898                --  and if the bounds are crossed, and the low bound is greater
4899                --  than zero, we will always back it off by small, since this
4900                --  is completely harmless.
4901
4902                if Actual_Lo > Actual_Hi then
4903                   if UR_Is_Positive (Actual_Lo) then
4904                      Actual_Lo   := Loval_Incl_EP - Small;
4905                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
4906
4907                   --  And of course, we need to do exactly the same parallel
4908                   --  fudge for flat ranges in the negative region.
4909
4910                   elsif UR_Is_Negative (Actual_Hi) then
4911                      Actual_Hi := Hival_Incl_EP + Small;
4912                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
4913                   end if;
4914                end if;
4915             end if;
4916
4917             Set_Realval (Lo, Actual_Lo);
4918             Set_Realval (Hi, Actual_Hi);
4919          end Fudge;
4920
4921       --  For the decimal case, none of this fudging is required, since there
4922       --  are no end-point problems in the decimal case (the end-points are
4923       --  always included).
4924
4925       else
4926          Actual_Size := Fsize (Loval, Hival);
4927       end if;
4928
4929       --  At this stage, the actual size has been calculated and the proper
4930       --  required bounds are stored in the low and high bounds.
4931
4932       if Actual_Size > 64 then
4933          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
4934          Error_Msg_N
4935            ("size required (^) for type& too large, maximum allowed is 64",
4936             Typ);
4937          Actual_Size := 64;
4938       end if;
4939
4940       --  Check size against explicit given size
4941
4942       if Has_Size_Clause (Typ) then
4943          if Actual_Size > RM_Size (Typ) then
4944             Error_Msg_Uint_1 := RM_Size (Typ);
4945             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
4946             Error_Msg_NE
4947               ("size given (^) for type& too small, minimum allowed is ^",
4948                Size_Clause (Typ), Typ);
4949
4950          else
4951             Actual_Size := UI_To_Int (Esize (Typ));
4952          end if;
4953
4954       --  Increase size to next natural boundary if no size clause given
4955
4956       else
4957          if Actual_Size <= 8 then
4958             Actual_Size := 8;
4959          elsif Actual_Size <= 16 then
4960             Actual_Size := 16;
4961          elsif Actual_Size <= 32 then
4962             Actual_Size := 32;
4963          else
4964             Actual_Size := 64;
4965          end if;
4966
4967          Init_Esize (Typ, Actual_Size);
4968          Adjust_Esize_For_Alignment (Typ);
4969       end if;
4970
4971       --  If we have a base type, then expand the bounds so that they extend to
4972       --  the full width of the allocated size in bits, to avoid junk range
4973       --  checks on intermediate computations.
4974
4975       if Base_Type (Typ) = Typ then
4976          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
4977          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
4978       end if;
4979
4980       --  Final step is to reanalyze the bounds using the proper type
4981       --  and set the Corresponding_Integer_Value fields of the literals.
4982
4983       Set_Etype (Lo, Empty);
4984       Set_Analyzed (Lo, False);
4985       Analyze (Lo);
4986
4987       --  Resolve with universal fixed if the base type, and the base type if
4988       --  it is a subtype. Note we can't resolve the base type with itself,
4989       --  that would be a reference before definition.
4990
4991       if Typ = Btyp then
4992          Resolve (Lo, Universal_Fixed);
4993       else
4994          Resolve (Lo, Btyp);
4995       end if;
4996
4997       --  Set corresponding integer value for bound
4998
4999       Set_Corresponding_Integer_Value
5000         (Lo, UR_To_Uint (Realval (Lo) / Small));
5001
5002       --  Similar processing for high bound
5003
5004       Set_Etype (Hi, Empty);
5005       Set_Analyzed (Hi, False);
5006       Analyze (Hi);
5007
5008       if Typ = Btyp then
5009          Resolve (Hi, Universal_Fixed);
5010       else
5011          Resolve (Hi, Btyp);
5012       end if;
5013
5014       Set_Corresponding_Integer_Value
5015         (Hi, UR_To_Uint (Realval (Hi) / Small));
5016
5017       --  Set type of range to correspond to bounds
5018
5019       Set_Etype (Rng, Etype (Lo));
5020
5021       --  Set Esize to calculated size if not set already
5022
5023       if Unknown_Esize (Typ) then
5024          Init_Esize (Typ, Actual_Size);
5025       end if;
5026
5027       --  Set RM_Size if not already set. If already set, check value
5028
5029       declare
5030          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5031
5032       begin
5033          if RM_Size (Typ) /= Uint_0 then
5034             if RM_Size (Typ) < Minsiz then
5035                Error_Msg_Uint_1 := RM_Size (Typ);
5036                Error_Msg_Uint_2 := Minsiz;
5037                Error_Msg_NE
5038                  ("size given (^) for type& too small, minimum allowed is ^",
5039                   Size_Clause (Typ), Typ);
5040             end if;
5041
5042          else
5043             Set_RM_Size (Typ, Minsiz);
5044          end if;
5045       end;
5046    end Freeze_Fixed_Point_Type;
5047
5048    ------------------
5049    -- Freeze_Itype --
5050    ------------------
5051
5052    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5053       L : List_Id;
5054
5055    begin
5056       Set_Has_Delayed_Freeze (T);
5057       L := Freeze_Entity (T, Sloc (N));
5058
5059       if Is_Non_Empty_List (L) then
5060          Insert_Actions (N, L);
5061       end if;
5062    end Freeze_Itype;
5063
5064    --------------------------
5065    -- Freeze_Static_Object --
5066    --------------------------
5067
5068    procedure Freeze_Static_Object (E : Entity_Id) is
5069
5070       Cannot_Be_Static : exception;
5071       --  Exception raised if the type of a static object cannot be made
5072       --  static. This happens if the type depends on non-global objects.
5073
5074       procedure Ensure_Expression_Is_SA (N : Node_Id);
5075       --  Called to ensure that an expression used as part of a type definition
5076       --  is statically allocatable, which means that the expression type is
5077       --  statically allocatable, and the expression is either static, or a
5078       --  reference to a library level constant.
5079
5080       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5081       --  Called to mark a type as static, checking that it is possible
5082       --  to set the type as static. If it is not possible, then the
5083       --  exception Cannot_Be_Static is raised.
5084
5085       -----------------------------
5086       -- Ensure_Expression_Is_SA --
5087       -----------------------------
5088
5089       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5090          Ent : Entity_Id;
5091
5092       begin
5093          Ensure_Type_Is_SA (Etype (N));
5094
5095          if Is_Static_Expression (N) then
5096             return;
5097
5098          elsif Nkind (N) = N_Identifier then
5099             Ent := Entity (N);
5100
5101             if Present (Ent)
5102               and then Ekind (Ent) = E_Constant
5103               and then Is_Library_Level_Entity (Ent)
5104             then
5105                return;
5106             end if;
5107          end if;
5108
5109          raise Cannot_Be_Static;
5110       end Ensure_Expression_Is_SA;
5111
5112       -----------------------
5113       -- Ensure_Type_Is_SA --
5114       -----------------------
5115
5116       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5117          N : Node_Id;
5118          C : Entity_Id;
5119
5120       begin
5121          --  If type is library level, we are all set
5122
5123          if Is_Library_Level_Entity (Typ) then
5124             return;
5125          end if;
5126
5127          --  We are also OK if the type already marked as statically allocated,
5128          --  which means we processed it before.
5129
5130          if Is_Statically_Allocated (Typ) then
5131             return;
5132          end if;
5133
5134          --  Mark type as statically allocated
5135
5136          Set_Is_Statically_Allocated (Typ);
5137
5138          --  Check that it is safe to statically allocate this type
5139
5140          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5141             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5142             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5143
5144          elsif Is_Array_Type (Typ) then
5145             N := First_Index (Typ);
5146             while Present (N) loop
5147                Ensure_Type_Is_SA (Etype (N));
5148                Next_Index (N);
5149             end loop;
5150
5151             Ensure_Type_Is_SA (Component_Type (Typ));
5152
5153          elsif Is_Access_Type (Typ) then
5154             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5155
5156                declare
5157                   F : Entity_Id;
5158                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5159
5160                begin
5161                   if T /= Standard_Void_Type then
5162                      Ensure_Type_Is_SA (T);
5163                   end if;
5164
5165                   F := First_Formal (Designated_Type (Typ));
5166
5167                   while Present (F) loop
5168                      Ensure_Type_Is_SA (Etype (F));
5169                      Next_Formal (F);
5170                   end loop;
5171                end;
5172
5173             else
5174                Ensure_Type_Is_SA (Designated_Type (Typ));
5175             end if;
5176
5177          elsif Is_Record_Type (Typ) then
5178             C := First_Entity (Typ);
5179             while Present (C) loop
5180                if Ekind (C) = E_Discriminant
5181                  or else Ekind (C) = E_Component
5182                then
5183                   Ensure_Type_Is_SA (Etype (C));
5184
5185                elsif Is_Type (C) then
5186                   Ensure_Type_Is_SA (C);
5187                end if;
5188
5189                Next_Entity (C);
5190             end loop;
5191
5192          elsif Ekind (Typ) = E_Subprogram_Type then
5193             Ensure_Type_Is_SA (Etype (Typ));
5194
5195             C := First_Formal (Typ);
5196             while Present (C) loop
5197                Ensure_Type_Is_SA (Etype (C));
5198                Next_Formal (C);
5199             end loop;
5200
5201          else
5202             raise Cannot_Be_Static;
5203          end if;
5204       end Ensure_Type_Is_SA;
5205
5206    --  Start of processing for Freeze_Static_Object
5207
5208    begin
5209       Ensure_Type_Is_SA (Etype (E));
5210
5211    exception
5212       when Cannot_Be_Static =>
5213
5214          --  If the object that cannot be static is imported or exported, then
5215          --  issue an error message saying that this object cannot be imported
5216          --  or exported. If it has an address clause it is an overlay in the
5217          --  current partition and the static requirement is not relevant.
5218          --  Do not issue any error message when ignoring rep clauses.
5219
5220          if Ignore_Rep_Clauses then
5221             null;
5222
5223          elsif Is_Imported (E) then
5224             if No (Address_Clause (E)) then
5225                Error_Msg_N
5226                  ("& cannot be imported (local type is not constant)", E);
5227             end if;
5228
5229          --  Otherwise must be exported, something is wrong if compiler
5230          --  is marking something as statically allocated which cannot be).
5231
5232          else pragma Assert (Is_Exported (E));
5233             Error_Msg_N
5234               ("& cannot be exported (local type is not constant)", E);
5235          end if;
5236    end Freeze_Static_Object;
5237
5238    -----------------------
5239    -- Freeze_Subprogram --
5240    -----------------------
5241
5242    procedure Freeze_Subprogram (E : Entity_Id) is
5243       Retype : Entity_Id;
5244       F      : Entity_Id;
5245
5246    begin
5247       --  Subprogram may not have an address clause unless it is imported
5248
5249       if Present (Address_Clause (E)) then
5250          if not Is_Imported (E) then
5251             Error_Msg_N
5252               ("address clause can only be given " &
5253                "for imported subprogram",
5254                Name (Address_Clause (E)));
5255          end if;
5256       end if;
5257
5258       --  Reset the Pure indication on an imported subprogram unless an
5259       --  explicit Pure_Function pragma was present. We do this because
5260       --  otherwise it is an insidious error to call a non-pure function from
5261       --  pure unit and have calls mysteriously optimized away. What happens
5262       --  here is that the Import can bypass the normal check to ensure that
5263       --  pure units call only pure subprograms.
5264
5265       if Is_Imported (E)
5266         and then Is_Pure (E)
5267         and then not Has_Pragma_Pure_Function (E)
5268       then
5269          Set_Is_Pure (E, False);
5270       end if;
5271
5272       --  For non-foreign convention subprograms, this is where we create
5273       --  the extra formals (for accessibility level and constrained bit
5274       --  information). We delay this till the freeze point precisely so
5275       --  that we know the convention!
5276
5277       if not Has_Foreign_Convention (E) then
5278          Create_Extra_Formals (E);
5279          Set_Mechanisms (E);
5280
5281          --  If this is convention Ada and a Valued_Procedure, that's odd
5282
5283          if Ekind (E) = E_Procedure
5284            and then Is_Valued_Procedure (E)
5285            and then Convention (E) = Convention_Ada
5286            and then Warn_On_Export_Import
5287          then
5288             Error_Msg_N
5289               ("?Valued_Procedure has no effect for convention Ada", E);
5290             Set_Is_Valued_Procedure (E, False);
5291          end if;
5292
5293       --  Case of foreign convention
5294
5295       else
5296          Set_Mechanisms (E);
5297
5298          --  For foreign conventions, warn about return of an
5299          --  unconstrained array.
5300
5301          --  Note: we *do* allow a return by descriptor for the VMS case,
5302          --  though here there is probably more to be done ???
5303
5304          if Ekind (E) = E_Function then
5305             Retype := Underlying_Type (Etype (E));
5306
5307             --  If no return type, probably some other error, e.g. a
5308             --  missing full declaration, so ignore.
5309
5310             if No (Retype) then
5311                null;
5312
5313             --  If the return type is generic, we have emitted a warning
5314             --  earlier on, and there is nothing else to check here. Specific
5315             --  instantiations may lead to erroneous behavior.
5316
5317             elsif Is_Generic_Type (Etype (E)) then
5318                null;
5319
5320             --  Display warning if returning unconstrained array
5321
5322             elsif Is_Array_Type (Retype)
5323               and then not Is_Constrained (Retype)
5324
5325               --  Exclude cases where descriptor mechanism is set, since the
5326               --  VMS descriptor mechanisms allow such unconstrained returns.
5327
5328               and then Mechanism (E) not in Descriptor_Codes
5329
5330               --  Check appropriate warning is enabled (should we check for
5331               --  Warnings (Off) on specific entities here, probably so???)
5332
5333               and then Warn_On_Export_Import
5334
5335                --  Exclude the VM case, since return of unconstrained arrays
5336                --  is properly handled in both the JVM and .NET cases.
5337
5338               and then VM_Target = No_VM
5339             then
5340                Error_Msg_N
5341                 ("?foreign convention function& should not return " &
5342                   "unconstrained array", E);
5343                return;
5344             end if;
5345          end if;
5346
5347          --  If any of the formals for an exported foreign convention
5348          --  subprogram have defaults, then emit an appropriate warning since
5349          --  this is odd (default cannot be used from non-Ada code)
5350
5351          if Is_Exported (E) then
5352             F := First_Formal (E);
5353             while Present (F) loop
5354                if Warn_On_Export_Import
5355                  and then Present (Default_Value (F))
5356                then
5357                   Error_Msg_N
5358                     ("?parameter cannot be defaulted in non-Ada call",
5359                      Default_Value (F));
5360                end if;
5361
5362                Next_Formal (F);
5363             end loop;
5364          end if;
5365       end if;
5366
5367       --  For VMS, descriptor mechanisms for parameters are allowed only for
5368       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5369       --  allowed for parameters of exported subprograms.
5370
5371       if OpenVMS_On_Target then
5372          if Is_Exported (E) then
5373             F := First_Formal (E);
5374             while Present (F) loop
5375                if Mechanism (F) = By_Descriptor_NCA then
5376                   Error_Msg_N
5377                     ("'N'C'A' descriptor for parameter not permitted", F);
5378                   Error_Msg_N
5379                     ("\can only be used for imported subprogram", F);
5380                end if;
5381
5382                Next_Formal (F);
5383             end loop;
5384
5385          elsif not Is_Imported (E) then
5386             F := First_Formal (E);
5387             while Present (F) loop
5388                if Mechanism (F) in Descriptor_Codes then
5389                   Error_Msg_N
5390                     ("descriptor mechanism for parameter not permitted", F);
5391                   Error_Msg_N
5392                     ("\can only be used for imported/exported subprogram", F);
5393                end if;
5394
5395                Next_Formal (F);
5396             end loop;
5397          end if;
5398       end if;
5399
5400       --  Pragma Inline_Always is disallowed for dispatching subprograms
5401       --  because the address of such subprograms is saved in the dispatch
5402       --  table to support dispatching calls, and dispatching calls cannot
5403       --  be inlined. This is consistent with the restriction against using
5404       --  'Access or 'Address on an Inline_Always subprogram.
5405
5406       if Is_Dispatching_Operation (E)
5407         and then Has_Pragma_Inline_Always (E)
5408       then
5409          Error_Msg_N
5410            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5411       end if;
5412
5413       --  Because of the implicit representation of inherited predefined
5414       --  operators in the front-end, the overriding status of the operation
5415       --  may be affected when a full view of a type is analyzed, and this is
5416       --  not captured by the analysis of the corresponding type declaration.
5417       --  Therefore the correctness of a not-overriding indicator must be
5418       --  rechecked when the subprogram is frozen.
5419
5420       if Nkind (E) = N_Defining_Operator_Symbol
5421         and then not Error_Posted (Parent (E))
5422       then
5423          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5424       end if;
5425    end Freeze_Subprogram;
5426
5427    ----------------------
5428    -- Is_Fully_Defined --
5429    ----------------------
5430
5431    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5432    begin
5433       if Ekind (T) = E_Class_Wide_Type then
5434          return Is_Fully_Defined (Etype (T));
5435
5436       elsif Is_Array_Type (T) then
5437          return Is_Fully_Defined (Component_Type (T));
5438
5439       elsif Is_Record_Type (T)
5440         and not Is_Private_Type (T)
5441       then
5442          --  Verify that the record type has no components with private types
5443          --  without completion.
5444
5445          declare
5446             Comp : Entity_Id;
5447
5448          begin
5449             Comp := First_Component (T);
5450
5451             while Present (Comp) loop
5452                if not Is_Fully_Defined (Etype (Comp)) then
5453                   return False;
5454                end if;
5455
5456                Next_Component (Comp);
5457             end loop;
5458             return True;
5459          end;
5460
5461       --  For the designated type of an access to subprogram, all types in
5462       --  the profile must be fully defined.
5463
5464       elsif Ekind (T) = E_Subprogram_Type then
5465          declare
5466             F : Entity_Id;
5467
5468          begin
5469             F := First_Formal (T);
5470             while Present (F) loop
5471                if not Is_Fully_Defined (Etype (F)) then
5472                   return False;
5473                end if;
5474
5475                Next_Formal (F);
5476             end loop;
5477
5478             return Is_Fully_Defined (Etype (T));
5479          end;
5480
5481       else
5482          return not Is_Private_Type (T)
5483            or else Present (Full_View (Base_Type (T)));
5484       end if;
5485    end Is_Fully_Defined;
5486
5487    ---------------------------------
5488    -- Process_Default_Expressions --
5489    ---------------------------------
5490
5491    procedure Process_Default_Expressions
5492      (E     : Entity_Id;
5493       After : in out Node_Id)
5494    is
5495       Loc    : constant Source_Ptr := Sloc (E);
5496       Dbody  : Node_Id;
5497       Formal : Node_Id;
5498       Dcopy  : Node_Id;
5499       Dnam   : Entity_Id;
5500
5501    begin
5502       Set_Default_Expressions_Processed (E);
5503
5504       --  A subprogram instance and its associated anonymous subprogram share
5505       --  their signature. The default expression functions are defined in the
5506       --  wrapper packages for the anonymous subprogram, and should not be
5507       --  generated again for the instance.
5508
5509       if Is_Generic_Instance (E)
5510         and then Present (Alias (E))
5511         and then Default_Expressions_Processed (Alias (E))
5512       then
5513          return;
5514       end if;
5515
5516       Formal := First_Formal (E);
5517       while Present (Formal) loop
5518          if Present (Default_Value (Formal)) then
5519
5520             --  We work with a copy of the default expression because we
5521             --  do not want to disturb the original, since this would mess
5522             --  up the conformance checking.
5523
5524             Dcopy := New_Copy_Tree (Default_Value (Formal));
5525
5526             --  The analysis of the expression may generate insert actions,
5527             --  which of course must not be executed. We wrap those actions
5528             --  in a procedure that is not called, and later on eliminated.
5529             --  The following cases have no side-effects, and are analyzed
5530             --  directly.
5531
5532             if Nkind (Dcopy) = N_Identifier
5533               or else Nkind (Dcopy) = N_Expanded_Name
5534               or else Nkind (Dcopy) = N_Integer_Literal
5535               or else (Nkind (Dcopy) = N_Real_Literal
5536                         and then not Vax_Float (Etype (Dcopy)))
5537               or else Nkind (Dcopy) = N_Character_Literal
5538               or else Nkind (Dcopy) = N_String_Literal
5539               or else Known_Null (Dcopy)
5540               or else (Nkind (Dcopy) = N_Attribute_Reference
5541                         and then
5542                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5543             then
5544
5545                --  If there is no default function, we must still do a full
5546                --  analyze call on the default value, to ensure that all error
5547                --  checks are performed, e.g. those associated with static
5548                --  evaluation. Note: this branch will always be taken if the
5549                --  analyzer is turned off (but we still need the error checks).
5550
5551                --  Note: the setting of parent here is to meet the requirement
5552                --  that we can only analyze the expression while attached to
5553                --  the tree. Really the requirement is that the parent chain
5554                --  be set, we don't actually need to be in the tree.
5555
5556                Set_Parent (Dcopy, Declaration_Node (Formal));
5557                Analyze (Dcopy);
5558
5559                --  Default expressions are resolved with their own type if the
5560                --  context is generic, to avoid anomalies with private types.
5561
5562                if Ekind (Scope (E)) = E_Generic_Package then
5563                   Resolve (Dcopy);
5564                else
5565                   Resolve (Dcopy, Etype (Formal));
5566                end if;
5567
5568                --  If that resolved expression will raise constraint error,
5569                --  then flag the default value as raising constraint error.
5570                --  This allows a proper error message on the calls.
5571
5572                if Raises_Constraint_Error (Dcopy) then
5573                   Set_Raises_Constraint_Error (Default_Value (Formal));
5574                end if;
5575
5576             --  If the default is a parameterless call, we use the name of
5577             --  the called function directly, and there is no body to build.
5578
5579             elsif Nkind (Dcopy) = N_Function_Call
5580               and then No (Parameter_Associations (Dcopy))
5581             then
5582                null;
5583
5584             --  Else construct and analyze the body of a wrapper procedure
5585             --  that contains an object declaration to hold the expression.
5586             --  Given that this is done only to complete the analysis, it
5587             --  simpler to build a procedure than a function which might
5588             --  involve secondary stack expansion.
5589
5590             else
5591                Dnam := Make_Temporary (Loc, 'D');
5592
5593                Dbody :=
5594                  Make_Subprogram_Body (Loc,
5595                    Specification =>
5596                      Make_Procedure_Specification (Loc,
5597                        Defining_Unit_Name => Dnam),
5598
5599                    Declarations => New_List (
5600                      Make_Object_Declaration (Loc,
5601                        Defining_Identifier =>
5602                          Make_Defining_Identifier (Loc,
5603                            New_Internal_Name ('T')),
5604                          Object_Definition =>
5605                            New_Occurrence_Of (Etype (Formal), Loc),
5606                          Expression => New_Copy_Tree (Dcopy))),
5607
5608                    Handled_Statement_Sequence =>
5609                      Make_Handled_Sequence_Of_Statements (Loc,
5610                        Statements => New_List));
5611
5612                Set_Scope (Dnam, Scope (E));
5613                Set_Assignment_OK (First (Declarations (Dbody)));
5614                Set_Is_Eliminated (Dnam);
5615                Insert_After (After, Dbody);
5616                Analyze (Dbody);
5617                After := Dbody;
5618             end if;
5619          end if;
5620
5621          Next_Formal (Formal);
5622       end loop;
5623    end Process_Default_Expressions;
5624
5625    ----------------------------------------
5626    -- Set_Component_Alignment_If_Not_Set --
5627    ----------------------------------------
5628
5629    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5630    begin
5631       --  Ignore if not base type, subtypes don't need anything
5632
5633       if Typ /= Base_Type (Typ) then
5634          return;
5635       end if;
5636
5637       --  Do not override existing representation
5638
5639       if Is_Packed (Typ) then
5640          return;
5641
5642       elsif Has_Specified_Layout (Typ) then
5643          return;
5644
5645       elsif Component_Alignment (Typ) /= Calign_Default then
5646          return;
5647
5648       else
5649          Set_Component_Alignment
5650            (Typ, Scope_Stack.Table
5651                   (Scope_Stack.Last).Component_Alignment_Default);
5652       end if;
5653    end Set_Component_Alignment_If_Not_Set;
5654
5655    ------------------
5656    -- Undelay_Type --
5657    ------------------
5658
5659    procedure Undelay_Type (T : Entity_Id) is
5660    begin
5661       Set_Has_Delayed_Freeze (T, False);
5662       Set_Freeze_Node (T, Empty);
5663
5664       --  Since we don't want T to have a Freeze_Node, we don't want its
5665       --  Full_View or Corresponding_Record_Type to have one either.
5666
5667       --  ??? Fundamentally, this whole handling is a kludge. What we really
5668       --  want is to be sure that for an Itype that's part of record R and is a
5669       --  subtype of type T, that it's frozen after the later of the freeze
5670       --  points of R and T. We have no way of doing that directly, so what we
5671       --  do is force most such Itypes to be frozen as part of freezing R via
5672       --  this procedure and only delay the ones that need to be delayed
5673       --  (mostly the designated types of access types that are defined as part
5674       --  of the record).
5675
5676       if Is_Private_Type (T)
5677         and then Present (Full_View (T))
5678         and then Is_Itype (Full_View (T))
5679         and then Is_Record_Type (Scope (Full_View (T)))
5680       then
5681          Undelay_Type (Full_View (T));
5682       end if;
5683
5684       if Is_Concurrent_Type (T)
5685         and then Present (Corresponding_Record_Type (T))
5686         and then Is_Itype (Corresponding_Record_Type (T))
5687         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5688       then
5689          Undelay_Type (Corresponding_Record_Type (T));
5690       end if;
5691    end Undelay_Type;
5692
5693    ------------------
5694    -- Warn_Overlay --
5695    ------------------
5696
5697    procedure Warn_Overlay
5698      (Expr : Node_Id;
5699       Typ  : Entity_Id;
5700       Nam  : Entity_Id)
5701    is
5702       Ent : constant Entity_Id := Entity (Nam);
5703       --  The object to which the address clause applies
5704
5705       Init : Node_Id;
5706       Old  : Entity_Id := Empty;
5707       Decl : Node_Id;
5708
5709    begin
5710       --  No warning if address clause overlay warnings are off
5711
5712       if not Address_Clause_Overlay_Warnings then
5713          return;
5714       end if;
5715
5716       --  No warning if there is an explicit initialization
5717
5718       Init := Original_Node (Expression (Declaration_Node (Ent)));
5719
5720       if Present (Init) and then Comes_From_Source (Init) then
5721          return;
5722       end if;
5723
5724       --  We only give the warning for non-imported entities of a type for
5725       --  which a non-null base init proc is defined, or for objects of access
5726       --  types with implicit null initialization, or when Normalize_Scalars
5727       --  applies and the type is scalar or a string type (the latter being
5728       --  tested for because predefined String types are initialized by inline
5729       --  code rather than by an init_proc). Note that we do not give the
5730       --  warning for Initialize_Scalars, since we suppressed initialization
5731       --  in this case.
5732
5733       if Present (Expr)
5734         and then not Is_Imported (Ent)
5735         and then (Has_Non_Null_Base_Init_Proc (Typ)
5736                     or else Is_Access_Type (Typ)
5737                     or else (Normalize_Scalars
5738                               and then (Is_Scalar_Type (Typ)
5739                                          or else Is_String_Type (Typ))))
5740       then
5741          if Nkind (Expr) = N_Attribute_Reference
5742            and then Is_Entity_Name (Prefix (Expr))
5743          then
5744             Old := Entity (Prefix (Expr));
5745
5746          elsif Is_Entity_Name (Expr)
5747            and then Ekind (Entity (Expr)) = E_Constant
5748          then
5749             Decl := Declaration_Node (Entity (Expr));
5750
5751             if Nkind (Decl) = N_Object_Declaration
5752               and then Present (Expression (Decl))
5753               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5754               and then Is_Entity_Name (Prefix (Expression (Decl)))
5755             then
5756                Old := Entity (Prefix (Expression (Decl)));
5757
5758             elsif Nkind (Expr) = N_Function_Call then
5759                return;
5760             end if;
5761
5762          --  A function call (most likely to To_Address) is probably not an
5763          --  overlay, so skip warning. Ditto if the function call was inlined
5764          --  and transformed into an entity.
5765
5766          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5767             return;
5768          end if;
5769
5770          Decl := Next (Parent (Expr));
5771
5772          --  If a pragma Import follows, we assume that it is for the current
5773          --  target of the address clause, and skip the warning.
5774
5775          if Present (Decl)
5776            and then Nkind (Decl) = N_Pragma
5777            and then Pragma_Name (Decl) = Name_Import
5778          then
5779             return;
5780          end if;
5781
5782          if Present (Old) then
5783             Error_Msg_Node_2 := Old;
5784             Error_Msg_N
5785               ("default initialization of & may modify &?",
5786                Nam);
5787          else
5788             Error_Msg_N
5789               ("default initialization of & may modify overlaid storage?",
5790                Nam);
5791          end if;
5792
5793          --  Add friendly warning if initialization comes from a packed array
5794          --  component.
5795
5796          if Is_Record_Type (Typ)  then
5797             declare
5798                Comp : Entity_Id;
5799
5800             begin
5801                Comp := First_Component (Typ);
5802
5803                while Present (Comp) loop
5804                   if Nkind (Parent (Comp)) = N_Component_Declaration
5805                     and then Present (Expression (Parent (Comp)))
5806                   then
5807                      exit;
5808                   elsif Is_Array_Type (Etype (Comp))
5809                      and then Present (Packed_Array_Type (Etype (Comp)))
5810                   then
5811                      Error_Msg_NE
5812                        ("\packed array component& " &
5813                         "will be initialized to zero?",
5814                         Nam, Comp);
5815                      exit;
5816                   else
5817                      Next_Component (Comp);
5818                   end if;
5819                end loop;
5820             end;
5821          end if;
5822
5823          Error_Msg_N
5824            ("\use pragma Import for & to " &
5825             "suppress initialization (RM B.1(24))?",
5826             Nam);
5827       end if;
5828    end Warn_Overlay;
5829
5830 end Freeze;