gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere.
 365
 366       if Ekind_In (Old_S, E_Function, E_Procedure)
 367         and then Nkind (Decl) = N_Subprogram_Declaration
 368       then
 369          Set_Body_To_Inline (Decl, Old_S);
 370       end if;
 371
 372       --  The body generated for this renaming is an internal artifact, and
 373       --  does not  constitute a freeze point for the called entity.
 374
 375       Set_Must_Not_Freeze (Call_Name);
 376
 377       Formal := First_Formal (Defining_Entity (Decl));
 378
 379       if Present (Pref) then
 380          declare
 381             Pref_Type : constant Entity_Id := Etype (Pref);
 382             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 383
 384          begin
 385             --  The controlling formal may be an access parameter, or the
 386             --  actual may be an access value, so adjust accordingly.
 387
 388             if Is_Access_Type (Pref_Type)
 389               and then not Is_Access_Type (Form_Type)
 390             then
 391                Actuals := New_List
 392                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 393
 394             elsif Is_Access_Type (Form_Type)
 395               and then not Is_Access_Type (Pref)
 396             then
 397                Actuals := New_List
 398                  (Make_Attribute_Reference (Loc,
 399                    Attribute_Name => Name_Access,
 400                    Prefix => Relocate_Node (Pref)));
 401             else
 402                Actuals := New_List (Pref);
 403             end if;
 404          end;
 405
 406       elsif Present (Formal) then
 407          Actuals := New_List;
 408
 409       else
 410          Actuals := No_List;
 411       end if;
 412
 413       if Present (Formal) then
 414          while Present (Formal) loop
 415             Append (New_Reference_To (Formal, Loc), Actuals);
 416             Next_Formal (Formal);
 417          end loop;
 418       end if;
 419
 420       --  If the renamed entity is an entry, inherit its profile. For other
 421       --  renamings as bodies, both profiles must be subtype conformant, so it
 422       --  is not necessary to replace the profile given in the declaration.
 423       --  However, default values that are aggregates are rewritten when
 424       --  partially analyzed, so we recover the original aggregate to insure
 425       --  that subsequent conformity checking works. Similarly, if the default
 426       --  expression was constant-folded, recover the original expression.
 427
 428       Formal := First_Formal (Defining_Entity (Decl));
 429
 430       if Present (Formal) then
 431          O_Formal := First_Formal (Old_S);
 432          Param_Spec := First (Parameter_Specifications (Spec));
 433          while Present (Formal) loop
 434             if Is_Entry (Old_S) then
 435                if Nkind (Parameter_Type (Param_Spec)) /=
 436                                                     N_Access_Definition
 437                then
 438                   Set_Etype (Formal, Etype (O_Formal));
 439                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 440                end if;
 441
 442             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 443               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 444                                            Nkind (Default_Value (O_Formal))
 445             then
 446                Set_Expression (Param_Spec,
 447                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 448             end if;
 449
 450             Next_Formal (Formal);
 451             Next_Formal (O_Formal);
 452             Next (Param_Spec);
 453          end loop;
 454       end if;
 455
 456       --  If the renamed entity is a function, the generated body contains a
 457       --  return statement. Otherwise, build a procedure call. If the entity is
 458       --  an entry, subsequent analysis of the call will transform it into the
 459       --  proper entry or protected operation call. If the renamed entity is
 460       --  a character literal, return it directly.
 461
 462       if Ekind (Old_S) = E_Function
 463         or else Ekind (Old_S) = E_Operator
 464         or else (Ekind (Old_S) = E_Subprogram_Type
 465                   and then Etype (Old_S) /= Standard_Void_Type)
 466       then
 467          Call_Node :=
 468            Make_Simple_Return_Statement (Loc,
 469               Expression =>
 470                 Make_Function_Call (Loc,
 471                   Name => Call_Name,
 472                   Parameter_Associations => Actuals));
 473
 474       elsif Ekind (Old_S) = E_Enumeration_Literal then
 475          Call_Node :=
 476            Make_Simple_Return_Statement (Loc,
 477               Expression => New_Occurrence_Of (Old_S, Loc));
 478
 479       elsif Nkind (Nam) = N_Character_Literal then
 480          Call_Node :=
 481            Make_Simple_Return_Statement (Loc,
 482              Expression => Call_Name);
 483
 484       else
 485          Call_Node :=
 486            Make_Procedure_Call_Statement (Loc,
 487              Name => Call_Name,
 488              Parameter_Associations => Actuals);
 489       end if;
 490
 491       --  Create entities for subprogram body and formals
 492
 493       Set_Defining_Unit_Name (Spec,
 494         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 495
 496       Param_Spec := First (Parameter_Specifications (Spec));
 497       while Present (Param_Spec) loop
 498          Set_Defining_Identifier (Param_Spec,
 499            Make_Defining_Identifier (Loc,
 500              Chars => Chars (Defining_Identifier (Param_Spec))));
 501          Next (Param_Spec);
 502       end loop;
 503
 504       Body_Node :=
 505         Make_Subprogram_Body (Loc,
 506           Specification => Spec,
 507           Declarations => New_List,
 508           Handled_Statement_Sequence =>
 509             Make_Handled_Sequence_Of_Statements (Loc,
 510               Statements => New_List (Call_Node)));
 511
 512       if Nkind (Decl) /= N_Subprogram_Declaration then
 513          Rewrite (N,
 514            Make_Subprogram_Declaration (Loc,
 515              Specification => Specification (N)));
 516       end if;
 517
 518       --  Link the body to the entity whose declaration it completes. If
 519       --  the body is analyzed when the renamed entity is frozen, it may
 520       --  be necessary to restore the proper scope (see package Exp_Ch13).
 521
 522       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 523         and then Present (Corresponding_Spec (N))
 524       then
 525          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 526       else
 527          Set_Corresponding_Spec (Body_Node, New_S);
 528       end if;
 529
 530       return Body_Node;
 531    end Build_Renamed_Body;
 532
 533    --------------------------
 534    -- Check_Address_Clause --
 535    --------------------------
 536
 537    procedure Check_Address_Clause (E : Entity_Id) is
 538       Addr : constant Node_Id   := Address_Clause (E);
 539       Expr : Node_Id;
 540       Decl : constant Node_Id   := Declaration_Node (E);
 541       Typ  : constant Entity_Id := Etype (E);
 542
 543    begin
 544       if Present (Addr) then
 545          Expr := Expression (Addr);
 546
 547          if Needs_Constant_Address (Decl, Typ) then
 548             Check_Constant_Address_Clause (Expr, E);
 549
 550             --  Has_Delayed_Freeze was set on E when the address clause was
 551             --  analyzed. Reset the flag now unless freeze actions were
 552             --  attached to it in the mean time.
 553
 554             if No (Freeze_Node (E)) then
 555                Set_Has_Delayed_Freeze (E, False);
 556             end if;
 557          end if;
 558
 559          --  If Rep_Clauses are to be ignored, remove address clause from
 560          --  list attached to entity, because it may be illegal for gigi,
 561          --  for example by breaking order of elaboration..
 562
 563          if Ignore_Rep_Clauses then
 564             declare
 565                Rep : Node_Id;
 566
 567             begin
 568                Rep := First_Rep_Item (E);
 569
 570                if Rep = Addr then
 571                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 572
 573                else
 574                   while Present (Rep)
 575                     and then Next_Rep_Item (Rep) /= Addr
 576                   loop
 577                      Rep := Next_Rep_Item (Rep);
 578                   end loop;
 579                end if;
 580
 581                if Present (Rep) then
 582                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 583                end if;
 584             end;
 585
 586             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 587
 588          elsif not Error_Posted (Expr)
 589            and then not Needs_Finalization (Typ)
 590          then
 591             Warn_Overlay (Expr, Typ, Name (Addr));
 592          end if;
 593       end if;
 594    end Check_Address_Clause;
 595
 596    -----------------------------
 597    -- Check_Compile_Time_Size --
 598    -----------------------------
 599
 600    procedure Check_Compile_Time_Size (T : Entity_Id) is
 601
 602       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 603       --  Sets the compile time known size (32 bits or less) in the Esize
 604       --  field, of T checking for a size clause that was given which attempts
 605       --  to give a smaller size, and also checking for an alignment clause.
 606
 607       function Size_Known (T : Entity_Id) return Boolean;
 608       --  Recursive function that does all the work
 609
 610       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 611       --  If T is a constrained subtype, its size is not known if any of its
 612       --  discriminant constraints is not static and it is not a null record.
 613       --  The test is conservative and doesn't check that the components are
 614       --  in fact constrained by non-static discriminant values. Could be made
 615       --  more precise ???
 616
 617       --------------------
 618       -- Set_Small_Size --
 619       --------------------
 620
 621       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 622       begin
 623          if S > 32 then
 624             return;
 625
 626          --  Don't bother if alignment clause with a value other than 1 is
 627          --  present, because size may be padded up to meet back end alignment
 628          --  requirements, and only the back end knows the rules!
 629
 630          elsif Known_Alignment (T) and then Alignment (T) /= 1 then
 631             return;
 632
 633          --  Check for bad size clause given
 634
 635          elsif Has_Size_Clause (T) then
 636             if RM_Size (T) < S then
 637                Error_Msg_Uint_1 := S;
 638                Error_Msg_NE
 639                  ("size for& too small, minimum allowed is ^",
 640                   Size_Clause (T), T);
 641
 642             elsif Unknown_Esize (T) then
 643                Set_Esize (T, S);
 644             end if;
 645
 646          --  Set sizes if not set already
 647
 648          else
 649             if Unknown_Esize (T) then
 650                Set_Esize (T, S);
 651             end if;
 652
 653             if Unknown_RM_Size (T) then
 654                Set_RM_Size (T, S);
 655             end if;
 656          end if;
 657       end Set_Small_Size;
 658
 659       ----------------
 660       -- Size_Known --
 661       ----------------
 662
 663       function Size_Known (T : Entity_Id) return Boolean is
 664          Index : Entity_Id;
 665          Comp  : Entity_Id;
 666          Ctyp  : Entity_Id;
 667          Low   : Node_Id;
 668          High  : Node_Id;
 669
 670       begin
 671          if Size_Known_At_Compile_Time (T) then
 672             return True;
 673
 674          --  Always True for scalar types. This is true even for generic formal
 675          --  scalar types. We used to return False in the latter case, but the
 676          --  size is known at compile time, even in the template, we just do
 677          --  not know the exact size but that's not the point of this routine.
 678
 679          elsif Is_Scalar_Type (T)
 680            or else Is_Task_Type (T)
 681          then
 682             return True;
 683
 684          --  Array types
 685
 686          elsif Is_Array_Type (T) then
 687
 688             --  String literals always have known size, and we can set it
 689
 690             if Ekind (T) = E_String_Literal_Subtype then
 691                Set_Small_Size (T, Component_Size (T)
 692                                * String_Literal_Length (T));
 693                return True;
 694
 695             --  Unconstrained types never have known at compile time size
 696
 697             elsif not Is_Constrained (T) then
 698                return False;
 699
 700             --  Don't do any recursion on type with error posted, since we may
 701             --  have a malformed type that leads us into a loop.
 702
 703             elsif Error_Posted (T) then
 704                return False;
 705
 706             --  Otherwise if component size unknown, then array size unknown
 707
 708             elsif not Size_Known (Component_Type (T)) then
 709                return False;
 710             end if;
 711
 712             --  Check for all indexes static, and also compute possible size
 713             --  (in case it is less than 32 and may be packable).
 714
 715             declare
 716                Esiz : Uint := Component_Size (T);
 717                Dim  : Uint;
 718
 719             begin
 720                Index := First_Index (T);
 721                while Present (Index) loop
 722                   if Nkind (Index) = N_Range then
 723                      Get_Index_Bounds (Index, Low, High);
 724
 725                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 726                      return False;
 727
 728                   else
 729                      Low  := Type_Low_Bound (Etype (Index));
 730                      High := Type_High_Bound (Etype (Index));
 731                   end if;
 732
 733                   if not Compile_Time_Known_Value (Low)
 734                     or else not Compile_Time_Known_Value (High)
 735                     or else Etype (Index) = Any_Type
 736                   then
 737                      return False;
 738
 739                   else
 740                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 741
 742                      if Dim >= 0 then
 743                         Esiz := Esiz * Dim;
 744                      else
 745                         Esiz := Uint_0;
 746                      end if;
 747                   end if;
 748
 749                   Next_Index (Index);
 750                end loop;
 751
 752                Set_Small_Size (T, Esiz);
 753                return True;
 754             end;
 755
 756          --  Access types always have known at compile time sizes
 757
 758          elsif Is_Access_Type (T) then
 759             return True;
 760
 761          --  For non-generic private types, go to underlying type if present
 762
 763          elsif Is_Private_Type (T)
 764            and then not Is_Generic_Type (T)
 765            and then Present (Underlying_Type (T))
 766          then
 767             --  Don't do any recursion on type with error posted, since we may
 768             --  have a malformed type that leads us into a loop.
 769
 770             if Error_Posted (T) then
 771                return False;
 772             else
 773                return Size_Known (Underlying_Type (T));
 774             end if;
 775
 776          --  Record types
 777
 778          elsif Is_Record_Type (T) then
 779
 780             --  A class-wide type is never considered to have a known size
 781
 782             if Is_Class_Wide_Type (T) then
 783                return False;
 784
 785             --  A subtype of a variant record must not have non-static
 786             --  discriminated components.
 787
 788             elsif T /= Base_Type (T)
 789               and then not Static_Discriminated_Components (T)
 790             then
 791                return False;
 792
 793             --  Don't do any recursion on type with error posted, since we may
 794             --  have a malformed type that leads us into a loop.
 795
 796             elsif Error_Posted (T) then
 797                return False;
 798             end if;
 799
 800             --  Now look at the components of the record
 801
 802             declare
 803                --  The following two variables are used to keep track of the
 804                --  size of packed records if we can tell the size of the packed
 805                --  record in the front end. Packed_Size_Known is True if so far
 806                --  we can figure out the size. It is initialized to True for a
 807                --  packed record, unless the record has discriminants. The
 808                --  reason we eliminate the discriminated case is that we don't
 809                --  know the way the back end lays out discriminated packed
 810                --  records. If Packed_Size_Known is True, then Packed_Size is
 811                --  the size in bits so far.
 812
 813                Packed_Size_Known : Boolean :=
 814                                      Is_Packed (T)
 815                                        and then not Has_Discriminants (T);
 816
 817                Packed_Size : Uint := Uint_0;
 818
 819             begin
 820                --  Test for variant part present
 821
 822                if Has_Discriminants (T)
 823                  and then Present (Parent (T))
 824                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 825                  and then Nkind (Type_Definition (Parent (T))) =
 826                                                N_Record_Definition
 827                  and then not Null_Present (Type_Definition (Parent (T)))
 828                  and then Present (Variant_Part
 829                             (Component_List (Type_Definition (Parent (T)))))
 830                then
 831                   --  If variant part is present, and type is unconstrained,
 832                   --  then we must have defaulted discriminants, or a size
 833                   --  clause must be present for the type, or else the size
 834                   --  is definitely not known at compile time.
 835
 836                   if not Is_Constrained (T)
 837                     and then
 838                       No (Discriminant_Default_Value (First_Discriminant (T)))
 839                     and then Unknown_Esize (T)
 840                   then
 841                      return False;
 842                   end if;
 843                end if;
 844
 845                --  Loop through components
 846
 847                Comp := First_Component_Or_Discriminant (T);
 848                while Present (Comp) loop
 849                   Ctyp := Etype (Comp);
 850
 851                   --  We do not know the packed size if there is a component
 852                   --  clause present (we possibly could, but this would only
 853                   --  help in the case of a record with partial rep clauses.
 854                   --  That's because in the case of full rep clauses, the
 855                   --  size gets figured out anyway by a different circuit).
 856
 857                   if Present (Component_Clause (Comp)) then
 858                      Packed_Size_Known := False;
 859                   end if;
 860
 861                   --  We need to identify a component that is an array where
 862                   --  the index type is an enumeration type with non-standard
 863                   --  representation, and some bound of the type depends on a
 864                   --  discriminant.
 865
 866                   --  This is because gigi computes the size by doing a
 867                   --  substitution of the appropriate discriminant value in
 868                   --  the size expression for the base type, and gigi is not
 869                   --  clever enough to evaluate the resulting expression (which
 870                   --  involves a call to rep_to_pos) at compile time.
 871
 872                   --  It would be nice if gigi would either recognize that
 873                   --  this expression can be computed at compile time, or
 874                   --  alternatively figured out the size from the subtype
 875                   --  directly, where all the information is at hand ???
 876
 877                   if Is_Array_Type (Etype (Comp))
 878                     and then Present (Packed_Array_Type (Etype (Comp)))
 879                   then
 880                      declare
 881                         Ocomp  : constant Entity_Id :=
 882                                    Original_Record_Component (Comp);
 883                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 884                         Ind    : Node_Id;
 885                         Indtyp : Entity_Id;
 886                         Lo, Hi : Node_Id;
 887
 888                      begin
 889                         Ind := First_Index (OCtyp);
 890                         while Present (Ind) loop
 891                            Indtyp := Etype (Ind);
 892
 893                            if Is_Enumeration_Type (Indtyp)
 894                              and then Has_Non_Standard_Rep (Indtyp)
 895                            then
 896                               Lo := Type_Low_Bound  (Indtyp);
 897                               Hi := Type_High_Bound (Indtyp);
 898
 899                               if Is_Entity_Name (Lo)
 900                                 and then Ekind (Entity (Lo)) = E_Discriminant
 901                               then
 902                                  return False;
 903
 904                               elsif Is_Entity_Name (Hi)
 905                                 and then Ekind (Entity (Hi)) = E_Discriminant
 906                               then
 907                                  return False;
 908                               end if;
 909                            end if;
 910
 911                            Next_Index (Ind);
 912                         end loop;
 913                      end;
 914                   end if;
 915
 916                   --  Clearly size of record is not known if the size of one of
 917                   --  the components is not known.
 918
 919                   if not Size_Known (Ctyp) then
 920                      return False;
 921                   end if;
 922
 923                   --  Accumulate packed size if possible
 924
 925                   if Packed_Size_Known then
 926
 927                      --  We can only deal with elementary types, since for
 928                      --  non-elementary components, alignment enters into the
 929                      --  picture, and we don't know enough to handle proper
 930                      --  alignment in this context. Packed arrays count as
 931                      --  elementary if the representation is a modular type.
 932
 933                      if Is_Elementary_Type (Ctyp)
 934                        or else (Is_Array_Type (Ctyp)
 935                                  and then Present (Packed_Array_Type (Ctyp))
 936                                  and then Is_Modular_Integer_Type
 937                                             (Packed_Array_Type (Ctyp)))
 938                      then
 939                         --  If RM_Size is known and static, then we can keep
 940                         --  accumulating the packed size.
 941
 942                         if Known_Static_RM_Size (Ctyp) then
 943
 944                            --  A little glitch, to be removed sometime ???
 945                            --  gigi does not understand zero sizes yet.
 946
 947                            if RM_Size (Ctyp) = Uint_0 then
 948                               Packed_Size_Known := False;
 949
 950                            --  Normal case where we can keep accumulating the
 951                            --  packed array size.
 952
 953                            else
 954                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 955                            end if;
 956
 957                         --  If we have a field whose RM_Size is not known then
 958                         --  we can't figure out the packed size here.
 959
 960                         else
 961                            Packed_Size_Known := False;
 962                         end if;
 963
 964                      --  If we have a non-elementary type we can't figure out
 965                      --  the packed array size (alignment issues).
 966
 967                      else
 968                         Packed_Size_Known := False;
 969                      end if;
 970                   end if;
 971
 972                   Next_Component_Or_Discriminant (Comp);
 973                end loop;
 974
 975                if Packed_Size_Known then
 976                   Set_Small_Size (T, Packed_Size);
 977                end if;
 978
 979                return True;
 980             end;
 981
 982          --  All other cases, size not known at compile time
 983
 984          else
 985             return False;
 986          end if;
 987       end Size_Known;
 988
 989       -------------------------------------
 990       -- Static_Discriminated_Components --
 991       -------------------------------------
 992
 993       function Static_Discriminated_Components
 994         (T : Entity_Id) return Boolean
 995       is
 996          Constraint : Elmt_Id;
 997
 998       begin
 999          if Has_Discriminants (T)
1000            and then Present (Discriminant_Constraint (T))
1001            and then Present (First_Component (T))
1002          then
1003             Constraint := First_Elmt (Discriminant_Constraint (T));
1004             while Present (Constraint) loop
1005                if not Compile_Time_Known_Value (Node (Constraint)) then
1006                   return False;
1007                end if;
1008
1009                Next_Elmt (Constraint);
1010             end loop;
1011          end if;
1012
1013          return True;
1014       end Static_Discriminated_Components;
1015
1016    --  Start of processing for Check_Compile_Time_Size
1017
1018    begin
1019       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1020    end Check_Compile_Time_Size;
1021
1022    -----------------------------
1023    -- Check_Debug_Info_Needed --
1024    -----------------------------
1025
1026    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1027    begin
1028       if Debug_Info_Off (T) then
1029          return;
1030
1031       elsif Comes_From_Source (T)
1032         or else Debug_Generated_Code
1033         or else Debug_Flag_VV
1034         or else Needs_Debug_Info (T)
1035       then
1036          Set_Debug_Info_Needed (T);
1037       end if;
1038    end Check_Debug_Info_Needed;
1039
1040    ----------------------------
1041    -- Check_Strict_Alignment --
1042    ----------------------------
1043
1044    procedure Check_Strict_Alignment (E : Entity_Id) is
1045       Comp  : Entity_Id;
1046
1047    begin
1048       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1049          Set_Strict_Alignment (E);
1050
1051       elsif Is_Array_Type (E) then
1052          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1053
1054       elsif Is_Record_Type (E) then
1055          if Is_Limited_Record (E) then
1056             Set_Strict_Alignment (E);
1057             return;
1058          end if;
1059
1060          Comp := First_Component (E);
1061          while Present (Comp) loop
1062             if not Is_Type (Comp)
1063               and then (Strict_Alignment (Etype (Comp))
1064                          or else Is_Aliased (Comp))
1065             then
1066                Set_Strict_Alignment (E);
1067                return;
1068             end if;
1069
1070             Next_Component (Comp);
1071          end loop;
1072       end if;
1073    end Check_Strict_Alignment;
1074
1075    -------------------------
1076    -- Check_Unsigned_Type --
1077    -------------------------
1078
1079    procedure Check_Unsigned_Type (E : Entity_Id) is
1080       Ancestor : Entity_Id;
1081       Lo_Bound : Node_Id;
1082       Btyp     : Entity_Id;
1083
1084    begin
1085       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1086          return;
1087       end if;
1088
1089       --  Do not attempt to analyze case where range was in error
1090
1091       if No (Scalar_Range (E))
1092         or else Error_Posted (Scalar_Range (E))
1093       then
1094          return;
1095       end if;
1096
1097       --  The situation that is non trivial is something like
1098
1099       --     subtype x1 is integer range -10 .. +10;
1100       --     subtype x2 is x1 range 0 .. V1;
1101       --     subtype x3 is x2 range V2 .. V3;
1102       --     subtype x4 is x3 range V4 .. V5;
1103
1104       --  where Vn are variables. Here the base type is signed, but we still
1105       --  know that x4 is unsigned because of the lower bound of x2.
1106
1107       --  The only way to deal with this is to look up the ancestor chain
1108
1109       Ancestor := E;
1110       loop
1111          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1112             return;
1113          end if;
1114
1115          Lo_Bound := Type_Low_Bound (Ancestor);
1116
1117          if Compile_Time_Known_Value (Lo_Bound) then
1118
1119             if Expr_Rep_Value (Lo_Bound) >= 0 then
1120                Set_Is_Unsigned_Type (E, True);
1121             end if;
1122
1123             return;
1124
1125          else
1126             Ancestor := Ancestor_Subtype (Ancestor);
1127
1128             --  If no ancestor had a static lower bound, go to base type
1129
1130             if No (Ancestor) then
1131
1132                --  Note: the reason we still check for a compile time known
1133                --  value for the base type is that at least in the case of
1134                --  generic formals, we can have bounds that fail this test,
1135                --  and there may be other cases in error situations.
1136
1137                Btyp := Base_Type (E);
1138
1139                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1140                   return;
1141                end if;
1142
1143                Lo_Bound := Type_Low_Bound (Base_Type (E));
1144
1145                if Compile_Time_Known_Value (Lo_Bound)
1146                  and then Expr_Rep_Value (Lo_Bound) >= 0
1147                then
1148                   Set_Is_Unsigned_Type (E, True);
1149                end if;
1150
1151                return;
1152             end if;
1153          end if;
1154       end loop;
1155    end Check_Unsigned_Type;
1156
1157    -------------------------
1158    -- Is_Atomic_Aggregate --
1159    -------------------------
1160
1161    function  Is_Atomic_Aggregate
1162      (E   : Entity_Id;
1163       Typ : Entity_Id) return Boolean
1164    is
1165       Loc   : constant Source_Ptr := Sloc (E);
1166       New_N : Node_Id;
1167       Par   : Node_Id;
1168       Temp  : Entity_Id;
1169
1170    begin
1171       Par := Parent (E);
1172
1173       --  Array may be qualified, so find outer context
1174
1175       if Nkind (Par) = N_Qualified_Expression then
1176          Par := Parent (Par);
1177       end if;
1178
1179       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1180         and then Comes_From_Source (Par)
1181       then
1182          Temp := Make_Temporary (Loc, 'T', E);
1183          New_N :=
1184            Make_Object_Declaration (Loc,
1185              Defining_Identifier => Temp,
1186              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1187              Expression          => Relocate_Node (E));
1188          Insert_Before (Par, New_N);
1189          Analyze (New_N);
1190
1191          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1192          return True;
1193       else
1194          return False;
1195       end if;
1196    end Is_Atomic_Aggregate;
1197
1198    ----------------
1199    -- Freeze_All --
1200    ----------------
1201
1202    --  Note: the easy coding for this procedure would be to just build a
1203    --  single list of freeze nodes and then insert them and analyze them
1204    --  all at once. This won't work, because the analysis of earlier freeze
1205    --  nodes may recursively freeze types which would otherwise appear later
1206    --  on in the freeze list. So we must analyze and expand the freeze nodes
1207    --  as they are generated.
1208
1209    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1210       E     : Entity_Id;
1211       Decl  : Node_Id;
1212
1213       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1214       --  This is the internal recursive routine that does freezing of entities
1215       --  (but NOT the analysis of default expressions, which should not be
1216       --  recursive, we don't want to analyze those till we are sure that ALL
1217       --  the types are frozen).
1218
1219       --------------------
1220       -- Freeze_All_Ent --
1221       --------------------
1222
1223       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1224          E     : Entity_Id;
1225          Flist : List_Id;
1226          Lastn : Node_Id;
1227
1228          procedure Process_Flist;
1229          --  If freeze nodes are present, insert and analyze, and reset cursor
1230          --  for next insertion.
1231
1232          -------------------
1233          -- Process_Flist --
1234          -------------------
1235
1236          procedure Process_Flist is
1237          begin
1238             if Is_Non_Empty_List (Flist) then
1239                Lastn := Next (After);
1240                Insert_List_After_And_Analyze (After, Flist);
1241
1242                if Present (Lastn) then
1243                   After := Prev (Lastn);
1244                else
1245                   After := Last (List_Containing (After));
1246                end if;
1247             end if;
1248          end Process_Flist;
1249
1250       --  Start or processing for Freeze_All_Ent
1251
1252       begin
1253          E := From;
1254          while Present (E) loop
1255
1256             --  If the entity is an inner package which is not a package
1257             --  renaming, then its entities must be frozen at this point. Note
1258             --  that such entities do NOT get frozen at the end of the nested
1259             --  package itself (only library packages freeze).
1260
1261             --  Same is true for task declarations, where anonymous records
1262             --  created for entry parameters must be frozen.
1263
1264             if Ekind (E) = E_Package
1265               and then No (Renamed_Object (E))
1266               and then not Is_Child_Unit (E)
1267               and then not Is_Frozen (E)
1268             then
1269                Push_Scope (E);
1270                Install_Visible_Declarations (E);
1271                Install_Private_Declarations (E);
1272
1273                Freeze_All (First_Entity (E), After);
1274
1275                End_Package_Scope (E);
1276
1277             elsif Ekind (E) in Task_Kind
1278               and then
1279                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1280                    or else
1281                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1282             then
1283                Push_Scope (E);
1284                Freeze_All (First_Entity (E), After);
1285                End_Scope;
1286
1287             --  For a derived tagged type, we must ensure that all the
1288             --  primitive operations of the parent have been frozen, so that
1289             --  their addresses will be in the parent's dispatch table at the
1290             --  point it is inherited.
1291
1292             elsif Ekind (E) = E_Record_Type
1293               and then Is_Tagged_Type (E)
1294               and then Is_Tagged_Type (Etype (E))
1295               and then Is_Derived_Type (E)
1296             then
1297                declare
1298                   Prim_List : constant Elist_Id :=
1299                                Primitive_Operations (Etype (E));
1300
1301                   Prim : Elmt_Id;
1302                   Subp : Entity_Id;
1303
1304                begin
1305                   Prim := First_Elmt (Prim_List);
1306                   while Present (Prim) loop
1307                      Subp := Node (Prim);
1308
1309                      if Comes_From_Source (Subp)
1310                        and then not Is_Frozen (Subp)
1311                      then
1312                         Flist := Freeze_Entity (Subp, After);
1313                         Process_Flist;
1314                      end if;
1315
1316                      Next_Elmt (Prim);
1317                   end loop;
1318                end;
1319             end if;
1320
1321             if not Is_Frozen (E) then
1322                Flist := Freeze_Entity (E, After);
1323                Process_Flist;
1324
1325             --  If already frozen, and there are delayed aspects, this is where
1326             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1327             --  for a description of how we handle aspect visibility).
1328
1329             elsif Has_Delayed_Aspects (E) then
1330                declare
1331                   Ritem : Node_Id;
1332
1333                begin
1334                   Ritem := First_Rep_Item (E);
1335                   while Present (Ritem) loop
1336                      if Nkind (Ritem) = N_Aspect_Specification
1337                        and then Entity (Ritem) = E
1338                        and then Is_Delayed_Aspect (Ritem)
1339                      then
1340                         Check_Aspect_At_End_Of_Declarations (Ritem);
1341                      end if;
1342
1343                      Ritem := Next_Rep_Item (Ritem);
1344                   end loop;
1345                end;
1346             end if;
1347
1348             --  If an incomplete type is still not frozen, this may be a
1349             --  premature freezing because of a body declaration that follows.
1350             --  Indicate where the freezing took place.
1351
1352             --  If the freezing is caused by the end of the current declarative
1353             --  part, it is a Taft Amendment type, and there is no error.
1354
1355             if not Is_Frozen (E)
1356               and then Ekind (E) = E_Incomplete_Type
1357             then
1358                declare
1359                   Bod : constant Node_Id := Next (After);
1360
1361                begin
1362                   if (Nkind_In (Bod, N_Subprogram_Body,
1363                                      N_Entry_Body,
1364                                      N_Package_Body,
1365                                      N_Protected_Body,
1366                                      N_Task_Body)
1367                         or else Nkind (Bod) in N_Body_Stub)
1368                      and then
1369                        List_Containing (After) = List_Containing (Parent (E))
1370                   then
1371                      Error_Msg_Sloc := Sloc (Next (After));
1372                      Error_Msg_NE
1373                        ("type& is frozen# before its full declaration",
1374                          Parent (E), E);
1375                   end if;
1376                end;
1377             end if;
1378
1379             Next_Entity (E);
1380          end loop;
1381       end Freeze_All_Ent;
1382
1383    --  Start of processing for Freeze_All
1384
1385    begin
1386       Freeze_All_Ent (From, After);
1387
1388       --  Now that all types are frozen, we can deal with default expressions
1389       --  that require us to build a default expression functions. This is the
1390       --  point at which such functions are constructed (after all types that
1391       --  might be used in such expressions have been frozen).
1392
1393       --  For subprograms that are renaming_as_body, we create the wrapper
1394       --  bodies as needed.
1395
1396       --  We also add finalization chains to access types whose designated
1397       --  types are controlled. This is normally done when freezing the type,
1398       --  but this misses recursive type definitions where the later members
1399       --  of the recursion introduce controlled components.
1400
1401       --  Loop through entities
1402
1403       E := From;
1404       while Present (E) loop
1405          if Is_Subprogram (E) then
1406
1407             if not Default_Expressions_Processed (E) then
1408                Process_Default_Expressions (E, After);
1409             end if;
1410
1411             if not Has_Completion (E) then
1412                Decl := Unit_Declaration_Node (E);
1413
1414                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1415                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1416
1417                elsif Nkind (Decl) = N_Subprogram_Declaration
1418                  and then Present (Corresponding_Body (Decl))
1419                  and then
1420                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1421                                           = N_Subprogram_Renaming_Declaration
1422                then
1423                   Build_And_Analyze_Renamed_Body
1424                     (Decl, Corresponding_Body (Decl), After);
1425                end if;
1426             end if;
1427
1428          elsif Ekind (E) in Task_Kind
1429            and then
1430              (Nkind (Parent (E)) = N_Task_Type_Declaration
1431                 or else
1432               Nkind (Parent (E)) = N_Single_Task_Declaration)
1433          then
1434             declare
1435                Ent : Entity_Id;
1436
1437             begin
1438                Ent := First_Entity (E);
1439                while Present (Ent) loop
1440                   if Is_Entry (Ent)
1441                     and then not Default_Expressions_Processed (Ent)
1442                   then
1443                      Process_Default_Expressions (Ent, After);
1444                   end if;
1445
1446                   Next_Entity (Ent);
1447                end loop;
1448             end;
1449
1450          --  We add finalization collections to access types whose designated
1451          --  types require finalization. This is normally done when freezing
1452          --  the type, but this misses recursive type definitions where the
1453          --  later members of the recursion introduce controlled components
1454          --  (such as can happen when incomplete types are involved), as well
1455          --  cases where a component type is private and the controlled full
1456          --  type occurs after the access type is frozen. Cases that don't
1457          --  need a finalization collection are generic formal types (the
1458          --  actual type will have it) and types with Java and CIL conventions,
1459          --  since those are used for API bindings. (Are there any other cases
1460          --  that should be excluded here???)
1461
1462          elsif Is_Access_Type (E)
1463            and then Comes_From_Source (E)
1464            and then not Is_Generic_Type (E)
1465            and then Needs_Finalization (Designated_Type (E))
1466            and then No (Associated_Collection (E))
1467            and then Convention (Designated_Type (E)) /= Convention_Java
1468            and then Convention (Designated_Type (E)) /= Convention_CIL
1469          then
1470             Build_Finalization_Collection (E);
1471          end if;
1472
1473          Next_Entity (E);
1474       end loop;
1475    end Freeze_All;
1476
1477    -----------------------
1478    -- Freeze_And_Append --
1479    -----------------------
1480
1481    procedure Freeze_And_Append
1482      (Ent    : Entity_Id;
1483       N      : Node_Id;
1484       Result : in out List_Id)
1485    is
1486       L : constant List_Id := Freeze_Entity (Ent, N);
1487    begin
1488       if Is_Non_Empty_List (L) then
1489          if Result = No_List then
1490             Result := L;
1491          else
1492             Append_List (L, Result);
1493          end if;
1494       end if;
1495    end Freeze_And_Append;
1496
1497    -------------------
1498    -- Freeze_Before --
1499    -------------------
1500
1501    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1502       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1503    begin
1504       if Is_Non_Empty_List (Freeze_Nodes) then
1505          Insert_Actions (N, Freeze_Nodes);
1506       end if;
1507    end Freeze_Before;
1508
1509    -------------------
1510    -- Freeze_Entity --
1511    -------------------
1512
1513    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1514       Loc    : constant Source_Ptr := Sloc (N);
1515       Test_E : Entity_Id := E;
1516       Comp   : Entity_Id;
1517       F_Node : Node_Id;
1518       Indx   : Node_Id;
1519       Formal : Entity_Id;
1520       Atype  : Entity_Id;
1521
1522       Result : List_Id := No_List;
1523       --  List of freezing actions, left at No_List if none
1524
1525       Has_Default_Initialization : Boolean := False;
1526       --  This flag gets set to true for a variable with default initialization
1527
1528       procedure Add_To_Result (N : Node_Id);
1529       --  N is a freezing action to be appended to the Result
1530
1531       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1532       --  Check that an Access or Unchecked_Access attribute with a prefix
1533       --  which is the current instance type can only be applied when the type
1534       --  is limited.
1535
1536       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1537       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1538       --  integer literal without an explicit corresponding size clause. The
1539       --  caller has checked that Utype is a modular integer type.
1540
1541       function After_Last_Declaration return Boolean;
1542       --  If Loc is a freeze_entity that appears after the last declaration
1543       --  in the scope, inhibit error messages on late completion.
1544
1545       procedure Freeze_Record_Type (Rec : Entity_Id);
1546       --  Freeze each component, handle some representation clauses, and freeze
1547       --  primitive operations if this is a tagged type.
1548
1549       -------------------
1550       -- Add_To_Result --
1551       -------------------
1552
1553       procedure Add_To_Result (N : Node_Id) is
1554       begin
1555          if No (Result) then
1556             Result := New_List (N);
1557          else
1558             Append (N, Result);
1559          end if;
1560       end Add_To_Result;
1561
1562       ----------------------------
1563       -- After_Last_Declaration --
1564       ----------------------------
1565
1566       function After_Last_Declaration return Boolean is
1567          Spec : constant Node_Id := Parent (Current_Scope);
1568       begin
1569          if Nkind (Spec) = N_Package_Specification then
1570             if Present (Private_Declarations (Spec)) then
1571                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1572             elsif Present (Visible_Declarations (Spec)) then
1573                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1574             else
1575                return False;
1576             end if;
1577          else
1578             return False;
1579          end if;
1580       end After_Last_Declaration;
1581
1582       ----------------------------
1583       -- Check_Current_Instance --
1584       ----------------------------
1585
1586       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1587
1588          Rec_Type : constant Entity_Id :=
1589                       Scope (Defining_Identifier (Comp_Decl));
1590
1591          Decl : constant Node_Id := Parent (Rec_Type);
1592
1593          function Process (N : Node_Id) return Traverse_Result;
1594          --  Process routine to apply check to given node
1595
1596          -------------
1597          -- Process --
1598          -------------
1599
1600          function Process (N : Node_Id) return Traverse_Result is
1601          begin
1602             case Nkind (N) is
1603                when N_Attribute_Reference =>
1604                   if (Attribute_Name (N) = Name_Access
1605                         or else
1606                       Attribute_Name (N) = Name_Unchecked_Access)
1607                     and then Is_Entity_Name (Prefix (N))
1608                     and then Is_Type (Entity (Prefix (N)))
1609                     and then Entity (Prefix (N)) = E
1610                   then
1611                      Error_Msg_N
1612                        ("current instance must be a limited type", Prefix (N));
1613                      return Abandon;
1614                   else
1615                      return OK;
1616                   end if;
1617
1618                when others => return OK;
1619             end case;
1620          end Process;
1621
1622          procedure Traverse is new Traverse_Proc (Process);
1623
1624       --  Start of processing for Check_Current_Instance
1625
1626       begin
1627          --  In Ada95, the (imprecise) rule is that the current instance of a
1628          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1629          --  either a tagged type, or a limited record.
1630
1631          if Is_Limited_Type (Rec_Type)
1632            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1633          then
1634             return;
1635
1636          elsif Nkind (Decl) = N_Full_Type_Declaration
1637            and then Limited_Present (Type_Definition (Decl))
1638          then
1639             return;
1640
1641          else
1642             Traverse (Comp_Decl);
1643          end if;
1644       end Check_Current_Instance;
1645
1646       ------------------------------
1647       -- Check_Suspicious_Modulus --
1648       ------------------------------
1649
1650       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1651          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1652
1653       begin
1654          if Nkind (Decl) = N_Full_Type_Declaration then
1655             declare
1656                Tdef : constant Node_Id := Type_Definition (Decl);
1657             begin
1658                if Nkind (Tdef) = N_Modular_Type_Definition then
1659                   declare
1660                      Modulus : constant Node_Id :=
1661                                  Original_Node (Expression (Tdef));
1662                   begin
1663                      if Nkind (Modulus) = N_Integer_Literal then
1664                         declare
1665                            Modv : constant Uint := Intval (Modulus);
1666                            Sizv : constant Uint := RM_Size (Utype);
1667
1668                         begin
1669                            --  First case, modulus and size are the same. This
1670                            --  happens if you have something like mod 32, with
1671                            --  an explicit size of 32, this is for sure a case
1672                            --  where the warning is given, since it is seems
1673                            --  very unlikely that someone would want e.g. a
1674                            --  five bit type stored in 32 bits. It is much
1675                            --  more likely they wanted a 32-bit type.
1676
1677                            if Modv = Sizv then
1678                               null;
1679
1680                            --  Second case, the modulus is 32 or 64 and no
1681                            --  size clause is present. This is a less clear
1682                            --  case for giving the warning, but in the case
1683                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1684                            --  enough that it is a likely error (and in any
1685                            --  case using 2**5 or 2**6 in these cases seems
1686                            --  clearer. We don't include 8 or 16 here, simply
1687                            --  because in practice 3-bit and 4-bit types are
1688                            --  more common and too many false positives if
1689                            --  we warn in these cases.
1690
1691                            elsif not Has_Size_Clause (Utype)
1692                              and then (Modv = Uint_32 or else Modv = Uint_64)
1693                            then
1694                               null;
1695
1696                            --  No warning needed
1697
1698                            else
1699                               return;
1700                            end if;
1701
1702                            --  If we fall through, give warning
1703
1704                            Error_Msg_Uint_1 := Modv;
1705                            Error_Msg_N
1706                              ("?2 '*'*^' may have been intended here",
1707                               Modulus);
1708                         end;
1709                      end if;
1710                   end;
1711                end if;
1712             end;
1713          end if;
1714       end Check_Suspicious_Modulus;
1715
1716       ------------------------
1717       -- Freeze_Record_Type --
1718       ------------------------
1719
1720       procedure Freeze_Record_Type (Rec : Entity_Id) is
1721          Comp : Entity_Id;
1722          IR   : Node_Id;
1723          ADC  : Node_Id;
1724          Prev : Entity_Id;
1725
1726          Junk : Boolean;
1727          pragma Warnings (Off, Junk);
1728
1729          Unplaced_Component : Boolean := False;
1730          --  Set True if we find at least one component with no component
1731          --  clause (used to warn about useless Pack pragmas).
1732
1733          Placed_Component : Boolean := False;
1734          --  Set True if we find at least one component with a component
1735          --  clause (used to warn about useless Bit_Order pragmas, and also
1736          --  to detect cases where Implicit_Packing may have an effect).
1737
1738          All_Scalar_Components : Boolean := True;
1739          --  Set False if we encounter a component of a non-scalar type
1740
1741          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1742          Scalar_Component_Total_Esize   : Uint := Uint_0;
1743          --  Accumulates total RM_Size values and total Esize values of all
1744          --  scalar components. Used for processing of Implicit_Packing.
1745
1746          function Check_Allocator (N : Node_Id) return Node_Id;
1747          --  If N is an allocator, possibly wrapped in one or more level of
1748          --  qualified expression(s), return the inner allocator node, else
1749          --  return Empty.
1750
1751          procedure Check_Itype (Typ : Entity_Id);
1752          --  If the component subtype is an access to a constrained subtype of
1753          --  an already frozen type, make the subtype frozen as well. It might
1754          --  otherwise be frozen in the wrong scope, and a freeze node on
1755          --  subtype has no effect. Similarly, if the component subtype is a
1756          --  regular (not protected) access to subprogram, set the anonymous
1757          --  subprogram type to frozen as well, to prevent an out-of-scope
1758          --  freeze node at some eventual point of call. Protected operations
1759          --  are handled elsewhere.
1760
1761          ---------------------
1762          -- Check_Allocator --
1763          ---------------------
1764
1765          function Check_Allocator (N : Node_Id) return Node_Id is
1766             Inner : Node_Id;
1767          begin
1768             Inner := N;
1769             loop
1770                if Nkind (Inner) = N_Allocator then
1771                   return Inner;
1772                elsif Nkind (Inner) = N_Qualified_Expression then
1773                   Inner := Expression (Inner);
1774                else
1775                   return Empty;
1776                end if;
1777             end loop;
1778          end Check_Allocator;
1779
1780          -----------------
1781          -- Check_Itype --
1782          -----------------
1783
1784          procedure Check_Itype (Typ : Entity_Id) is
1785             Desig : constant Entity_Id := Designated_Type (Typ);
1786
1787          begin
1788             if not Is_Frozen (Desig)
1789               and then Is_Frozen (Base_Type (Desig))
1790             then
1791                Set_Is_Frozen (Desig);
1792
1793                --  In addition, add an Itype_Reference to ensure that the
1794                --  access subtype is elaborated early enough. This cannot be
1795                --  done if the subtype may depend on discriminants.
1796
1797                if Ekind (Comp) = E_Component
1798                  and then Is_Itype (Etype (Comp))
1799                  and then not Has_Discriminants (Rec)
1800                then
1801                   IR := Make_Itype_Reference (Sloc (Comp));
1802                   Set_Itype (IR, Desig);
1803                   Add_To_Result (IR);
1804                end if;
1805
1806             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1807               and then Convention (Desig) /= Convention_Protected
1808             then
1809                Set_Is_Frozen (Desig);
1810             end if;
1811          end Check_Itype;
1812
1813       --  Start of processing for Freeze_Record_Type
1814
1815       begin
1816          --  Freeze components and embedded subtypes
1817
1818          Comp := First_Entity (Rec);
1819          Prev := Empty;
1820          while Present (Comp) loop
1821
1822             --  First handle the component case
1823
1824             if Ekind (Comp) = E_Component
1825               or else Ekind (Comp) = E_Discriminant
1826             then
1827                declare
1828                   CC : constant Node_Id := Component_Clause (Comp);
1829
1830                begin
1831                   --  Freezing a record type freezes the type of each of its
1832                   --  components. However, if the type of the component is
1833                   --  part of this record, we do not want or need a separate
1834                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1835                   --  also set in private type cases. We also can't check for
1836                   --  the Scope being exactly Rec because of private types and
1837                   --  record extensions.
1838
1839                   if Is_Itype (Etype (Comp))
1840                     and then Is_Record_Type (Underlying_Type
1841                                              (Scope (Etype (Comp))))
1842                   then
1843                      Undelay_Type (Etype (Comp));
1844                   end if;
1845
1846                   Freeze_And_Append (Etype (Comp), N, Result);
1847
1848                   --  Check for error of component clause given for variable
1849                   --  sized type. We have to delay this test till this point,
1850                   --  since the component type has to be frozen for us to know
1851                   --  if it is variable length. We omit this test in a generic
1852                   --  context, it will be applied at instantiation time.
1853
1854                   if Present (CC) then
1855                      Placed_Component := True;
1856
1857                      if Inside_A_Generic then
1858                         null;
1859
1860                      elsif not
1861                        Size_Known_At_Compile_Time
1862                          (Underlying_Type (Etype (Comp)))
1863                      then
1864                         Error_Msg_N
1865                           ("component clause not allowed for variable " &
1866                            "length component", CC);
1867                      end if;
1868
1869                   else
1870                      Unplaced_Component := True;
1871                   end if;
1872
1873                   --  Case of component requires byte alignment
1874
1875                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1876
1877                      --  Set the enclosing record to also require byte align
1878
1879                      Set_Must_Be_On_Byte_Boundary (Rec);
1880
1881                      --  Check for component clause that is inconsistent with
1882                      --  the required byte boundary alignment.
1883
1884                      if Present (CC)
1885                        and then Normalized_First_Bit (Comp) mod
1886                                   System_Storage_Unit /= 0
1887                      then
1888                         Error_Msg_N
1889                           ("component & must be byte aligned",
1890                            Component_Name (Component_Clause (Comp)));
1891                      end if;
1892                   end if;
1893                end;
1894             end if;
1895
1896             --  Gather data for possible Implicit_Packing later. Note that at
1897             --  this stage we might be dealing with a real component, or with
1898             --  an implicit subtype declaration.
1899
1900             if not Is_Scalar_Type (Etype (Comp)) then
1901                All_Scalar_Components := False;
1902             else
1903                Scalar_Component_Total_RM_Size :=
1904                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1905                Scalar_Component_Total_Esize :=
1906                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1907             end if;
1908
1909             --  If the component is an Itype with Delayed_Freeze and is either
1910             --  a record or array subtype and its base type has not yet been
1911             --  frozen, we must remove this from the entity list of this record
1912             --  and put it on the entity list of the scope of its base type.
1913             --  Note that we know that this is not the type of a component
1914             --  since we cleared Has_Delayed_Freeze for it in the previous
1915             --  loop. Thus this must be the Designated_Type of an access type,
1916             --  which is the type of a component.
1917
1918             if Is_Itype (Comp)
1919               and then Is_Type (Scope (Comp))
1920               and then Is_Composite_Type (Comp)
1921               and then Base_Type (Comp) /= Comp
1922               and then Has_Delayed_Freeze (Comp)
1923               and then not Is_Frozen (Base_Type (Comp))
1924             then
1925                declare
1926                   Will_Be_Frozen : Boolean := False;
1927                   S              : Entity_Id;
1928
1929                begin
1930                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1931                   --  being defined in a subprogram that's created as part of
1932                   --  the freezing of Rec'Base. In that case, we know that
1933                   --  Comp'Base must have already been frozen by the time we
1934                   --  get to elaborate this because Gigi doesn't elaborate any
1935                   --  bodies until it has elaborated all of the declarative
1936                   --  part. But Is_Frozen will not be set at this point because
1937                   --  we are processing code in lexical order.
1938
1939                   --  We detect this case by going up the Scope chain of Rec
1940                   --  and seeing if we have a subprogram scope before reaching
1941                   --  the top of the scope chain or that of Comp'Base. If we
1942                   --  do, then mark that Comp'Base will actually be frozen. If
1943                   --  so, we merely undelay it.
1944
1945                   S := Scope (Rec);
1946                   while Present (S) loop
1947                      if Is_Subprogram (S) then
1948                         Will_Be_Frozen := True;
1949                         exit;
1950                      elsif S = Scope (Base_Type (Comp)) then
1951                         exit;
1952                      end if;
1953
1954                      S := Scope (S);
1955                   end loop;
1956
1957                   if Will_Be_Frozen then
1958                      Undelay_Type (Comp);
1959                   else
1960                      if Present (Prev) then
1961                         Set_Next_Entity (Prev, Next_Entity (Comp));
1962                      else
1963                         Set_First_Entity (Rec, Next_Entity (Comp));
1964                      end if;
1965
1966                      --  Insert in entity list of scope of base type (which
1967                      --  must be an enclosing scope, because still unfrozen).
1968
1969                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1970                   end if;
1971                end;
1972
1973             --  If the component is an access type with an allocator as default
1974             --  value, the designated type will be frozen by the corresponding
1975             --  expression in init_proc. In order to place the freeze node for
1976             --  the designated type before that for the current record type,
1977             --  freeze it now.
1978
1979             --  Same process if the component is an array of access types,
1980             --  initialized with an aggregate. If the designated type is
1981             --  private, it cannot contain allocators, and it is premature
1982             --  to freeze the type, so we check for this as well.
1983
1984             elsif Is_Access_Type (Etype (Comp))
1985               and then Present (Parent (Comp))
1986               and then Present (Expression (Parent (Comp)))
1987             then
1988                declare
1989                   Alloc : constant Node_Id :=
1990                             Check_Allocator (Expression (Parent (Comp)));
1991
1992                begin
1993                   if Present (Alloc) then
1994
1995                      --  If component is pointer to a classwide type, freeze
1996                      --  the specific type in the expression being allocated.
1997                      --  The expression may be a subtype indication, in which
1998                      --  case freeze the subtype mark.
1999
2000                      if Is_Class_Wide_Type
2001                           (Designated_Type (Etype (Comp)))
2002                      then
2003                         if Is_Entity_Name (Expression (Alloc)) then
2004                            Freeze_And_Append
2005                              (Entity (Expression (Alloc)), N, Result);
2006                         elsif
2007                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2008                         then
2009                            Freeze_And_Append
2010                             (Entity (Subtype_Mark (Expression (Alloc))),
2011                              N, Result);
2012                         end if;
2013
2014                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2015                         Check_Itype (Etype (Comp));
2016
2017                      else
2018                         Freeze_And_Append
2019                           (Designated_Type (Etype (Comp)), N, Result);
2020                      end if;
2021                   end if;
2022                end;
2023
2024             elsif Is_Access_Type (Etype (Comp))
2025               and then Is_Itype (Designated_Type (Etype (Comp)))
2026             then
2027                Check_Itype (Etype (Comp));
2028
2029             elsif Is_Array_Type (Etype (Comp))
2030               and then Is_Access_Type (Component_Type (Etype (Comp)))
2031               and then Present (Parent (Comp))
2032               and then Nkind (Parent (Comp)) = N_Component_Declaration
2033               and then Present (Expression (Parent (Comp)))
2034               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2035               and then Is_Fully_Defined
2036                  (Designated_Type (Component_Type (Etype (Comp))))
2037             then
2038                Freeze_And_Append
2039                  (Designated_Type
2040                    (Component_Type (Etype (Comp))), N, Result);
2041             end if;
2042
2043             Prev := Comp;
2044             Next_Entity (Comp);
2045          end loop;
2046
2047          --  Deal with pragma Bit_Order setting non-standard bit order
2048
2049          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2050             if not Placed_Component then
2051                ADC :=
2052                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2053                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2054                Error_Msg_N
2055                  ("\?since no component clauses were specified", ADC);
2056
2057             --  Here is where we do the processing for reversed bit order
2058
2059             else
2060                Adjust_Record_For_Reverse_Bit_Order (Rec);
2061             end if;
2062          end if;
2063
2064          --  Complete error checking on record representation clause (e.g.
2065          --  overlap of components). This is called after adjusting the
2066          --  record for reverse bit order.
2067
2068          declare
2069             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2070          begin
2071             if Present (RRC) then
2072                Check_Record_Representation_Clause (RRC);
2073             end if;
2074          end;
2075
2076          --  Set OK_To_Reorder_Components depending on debug flags
2077
2078          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2079             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2080                   or else
2081                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2082             then
2083                Set_OK_To_Reorder_Components (Rec);
2084             end if;
2085          end if;
2086
2087          --  Check for useless pragma Pack when all components placed. We only
2088          --  do this check for record types, not subtypes, since a subtype may
2089          --  have all its components placed, and it still makes perfectly good
2090          --  sense to pack other subtypes or the parent type. We do not give
2091          --  this warning if Optimize_Alignment is set to Space, since the
2092          --  pragma Pack does have an effect in this case (it always resets
2093          --  the alignment to one).
2094
2095          if Ekind (Rec) = E_Record_Type
2096            and then Is_Packed (Rec)
2097            and then not Unplaced_Component
2098            and then Optimize_Alignment /= 'S'
2099          then
2100             --  Reset packed status. Probably not necessary, but we do it so
2101             --  that there is no chance of the back end doing something strange
2102             --  with this redundant indication of packing.
2103
2104             Set_Is_Packed (Rec, False);
2105
2106             --  Give warning if redundant constructs warnings on
2107
2108             if Warn_On_Redundant_Constructs then
2109                Error_Msg_N -- CODEFIX
2110                  ("?pragma Pack has no effect, no unplaced components",
2111                   Get_Rep_Pragma (Rec, Name_Pack));
2112             end if;
2113          end if;
2114
2115          --  If this is the record corresponding to a remote type, freeze the
2116          --  remote type here since that is what we are semantically freezing.
2117          --  This prevents the freeze node for that type in an inner scope.
2118
2119          --  Also, Check for controlled components and unchecked unions.
2120          --  Finally, enforce the restriction that access attributes with a
2121          --  current instance prefix can only apply to limited types.
2122
2123          if Ekind (Rec) = E_Record_Type then
2124             if Present (Corresponding_Remote_Type (Rec)) then
2125                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2126             end if;
2127
2128             Comp := First_Component (Rec);
2129             while Present (Comp) loop
2130
2131                --  Do not set Has_Controlled_Component on a class-wide
2132                --  equivalent type. See Make_CW_Equivalent_Type.
2133
2134                if not Is_Class_Wide_Equivalent_Type (Rec)
2135                  and then (Has_Controlled_Component (Etype (Comp))
2136                             or else (Chars (Comp) /= Name_uParent
2137                                       and then Is_Controlled (Etype (Comp)))
2138                             or else (Is_Protected_Type (Etype (Comp))
2139                                       and then Present
2140                                         (Corresponding_Record_Type
2141                                           (Etype (Comp)))
2142                                       and then Has_Controlled_Component
2143                                         (Corresponding_Record_Type
2144                                           (Etype (Comp)))))
2145                then
2146                   Set_Has_Controlled_Component (Rec);
2147                   exit;
2148                end if;
2149
2150                if Has_Unchecked_Union (Etype (Comp)) then
2151                   Set_Has_Unchecked_Union (Rec);
2152                end if;
2153
2154                if Has_Per_Object_Constraint (Comp) then
2155
2156                   --  Scan component declaration for likely misuses of current
2157                   --  instance, either in a constraint or a default expression.
2158
2159                   Check_Current_Instance (Parent (Comp));
2160                end if;
2161
2162                Next_Component (Comp);
2163             end loop;
2164          end if;
2165
2166          Set_Component_Alignment_If_Not_Set (Rec);
2167
2168          --  For first subtypes, check if there are any fixed-point fields with
2169          --  component clauses, where we must check the size. This is not done
2170          --  till the freeze point, since for fixed-point types, we do not know
2171          --  the size until the type is frozen. Similar processing applies to
2172          --  bit packed arrays.
2173
2174          if Is_First_Subtype (Rec) then
2175             Comp := First_Component (Rec);
2176             while Present (Comp) loop
2177                if Present (Component_Clause (Comp))
2178                  and then (Is_Fixed_Point_Type (Etype (Comp))
2179                              or else
2180                            Is_Bit_Packed_Array (Etype (Comp)))
2181                then
2182                   Check_Size
2183                     (Component_Name (Component_Clause (Comp)),
2184                      Etype (Comp),
2185                      Esize (Comp),
2186                      Junk);
2187                end if;
2188
2189                Next_Component (Comp);
2190             end loop;
2191          end if;
2192
2193          --  Generate warning for applying C or C++ convention to a record
2194          --  with discriminants. This is suppressed for the unchecked union
2195          --  case, since the whole point in this case is interface C. We also
2196          --  do not generate this within instantiations, since we will have
2197          --  generated a message on the template.
2198
2199          if Has_Discriminants (E)
2200            and then not Is_Unchecked_Union (E)
2201            and then (Convention (E) = Convention_C
2202                        or else
2203                      Convention (E) = Convention_CPP)
2204            and then Comes_From_Source (E)
2205            and then not In_Instance
2206            and then not Has_Warnings_Off (E)
2207            and then not Has_Warnings_Off (Base_Type (E))
2208          then
2209             declare
2210                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2211                A2    : Node_Id;
2212
2213             begin
2214                if Present (Cprag) then
2215                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2216
2217                   if Convention (E) = Convention_C then
2218                      Error_Msg_N
2219                        ("?variant record has no direct equivalent in C", A2);
2220                   else
2221                      Error_Msg_N
2222                        ("?variant record has no direct equivalent in C++", A2);
2223                   end if;
2224
2225                   Error_Msg_NE
2226                     ("\?use of convention for type& is dubious", A2, E);
2227                end if;
2228             end;
2229          end if;
2230
2231          --  See if Size is too small as is (and implicit packing might help)
2232
2233          if not Is_Packed (Rec)
2234
2235            --  No implicit packing if even one component is explicitly placed
2236
2237            and then not Placed_Component
2238
2239            --  Must have size clause and all scalar components
2240
2241            and then Has_Size_Clause (Rec)
2242            and then All_Scalar_Components
2243
2244            --  Do not try implicit packing on records with discriminants, too
2245            --  complicated, especially in the variant record case.
2246
2247            and then not Has_Discriminants (Rec)
2248
2249            --  We can implicitly pack if the specified size of the record is
2250            --  less than the sum of the object sizes (no point in packing if
2251            --  this is not the case).
2252
2253            and then Esize (Rec) < Scalar_Component_Total_Esize
2254
2255            --  And the total RM size cannot be greater than the specified size
2256            --  since otherwise packing will not get us where we have to be!
2257
2258            and then Esize (Rec) >= Scalar_Component_Total_RM_Size
2259
2260            --  Never do implicit packing in CodePeer mode since we don't do
2261            --  any packing in this mode, since this generates over-complex
2262            --  code that confuses CodePeer, and in general, CodePeer does not
2263            --  care about the internal representation of objects.
2264
2265            and then not CodePeer_Mode
2266          then
2267             --  If implicit packing enabled, do it
2268
2269             if Implicit_Packing then
2270                Set_Is_Packed (Rec);
2271
2272                --  Otherwise flag the size clause
2273
2274             else
2275                declare
2276                   Sz : constant Node_Id := Size_Clause (Rec);
2277                begin
2278                   Error_Msg_NE -- CODEFIX
2279                     ("size given for& too small", Sz, Rec);
2280                   Error_Msg_N -- CODEFIX
2281                     ("\use explicit pragma Pack "
2282                      & "or use pragma Implicit_Packing", Sz);
2283                end;
2284             end if;
2285          end if;
2286       end Freeze_Record_Type;
2287
2288    --  Start of processing for Freeze_Entity
2289
2290    begin
2291       --  We are going to test for various reasons why this entity need not be
2292       --  frozen here, but in the case of an Itype that's defined within a
2293       --  record, that test actually applies to the record.
2294
2295       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2296          Test_E := Scope (E);
2297       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2298         and then Is_Record_Type (Underlying_Type (Scope (E)))
2299       then
2300          Test_E := Underlying_Type (Scope (E));
2301       end if;
2302
2303       --  Do not freeze if already frozen since we only need one freeze node
2304
2305       if Is_Frozen (E) then
2306          return No_List;
2307
2308       --  It is improper to freeze an external entity within a generic because
2309       --  its freeze node will appear in a non-valid context. The entity will
2310       --  be frozen in the proper scope after the current generic is analyzed.
2311
2312       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2313          return No_List;
2314
2315       --  Do not freeze a global entity within an inner scope created during
2316       --  expansion. A call to subprogram E within some internal procedure
2317       --  (a stream attribute for example) might require freezing E, but the
2318       --  freeze node must appear in the same declarative part as E itself.
2319       --  The two-pass elaboration mechanism in gigi guarantees that E will
2320       --  be frozen before the inner call is elaborated. We exclude constants
2321       --  from this test, because deferred constants may be frozen early, and
2322       --  must be diagnosed (e.g. in the case of a deferred constant being used
2323       --  in a default expression). If the enclosing subprogram comes from
2324       --  source, or is a generic instance, then the freeze point is the one
2325       --  mandated by the language, and we freeze the entity. A subprogram that
2326       --  is a child unit body that acts as a spec does not have a spec that
2327       --  comes from source, but can only come from source.
2328
2329       elsif In_Open_Scopes (Scope (Test_E))
2330         and then Scope (Test_E) /= Current_Scope
2331         and then Ekind (Test_E) /= E_Constant
2332       then
2333          declare
2334             S : Entity_Id;
2335
2336          begin
2337             S := Current_Scope;
2338             while Present (S) loop
2339                if Is_Overloadable (S) then
2340                   if Comes_From_Source (S)
2341                     or else Is_Generic_Instance (S)
2342                     or else Is_Child_Unit (S)
2343                   then
2344                      exit;
2345                   else
2346                      return No_List;
2347                   end if;
2348                end if;
2349
2350                S := Scope (S);
2351             end loop;
2352          end;
2353
2354       --  Similarly, an inlined instance body may make reference to global
2355       --  entities, but these references cannot be the proper freezing point
2356       --  for them, and in the absence of inlining freezing will take place in
2357       --  their own scope. Normally instance bodies are analyzed after the
2358       --  enclosing compilation, and everything has been frozen at the proper
2359       --  place, but with front-end inlining an instance body is compiled
2360       --  before the end of the enclosing scope, and as a result out-of-order
2361       --  freezing must be prevented.
2362
2363       elsif Front_End_Inlining
2364         and then In_Instance_Body
2365         and then Present (Scope (Test_E))
2366       then
2367          declare
2368             S : Entity_Id;
2369
2370          begin
2371             S := Scope (Test_E);
2372             while Present (S) loop
2373                if Is_Generic_Instance (S) then
2374                   exit;
2375                else
2376                   S := Scope (S);
2377                end if;
2378             end loop;
2379
2380             if No (S) then
2381                return No_List;
2382             end if;
2383          end;
2384       end if;
2385
2386       --  Deal with delayed aspect specifications. The analysis of the aspect
2387       --  is required to be delayed to the freeze point, so we evaluate the
2388       --  pragma or attribute definition clause in the tree at this point.
2389
2390       if Has_Delayed_Aspects (E) then
2391          declare
2392             Ritem : Node_Id;
2393             Aitem : Node_Id;
2394
2395          begin
2396             --  Look for aspect specification entries for this entity
2397
2398             Ritem := First_Rep_Item (E);
2399             while Present (Ritem) loop
2400                if Nkind (Ritem) = N_Aspect_Specification
2401                  and then Entity (Ritem) = E
2402                  and then Is_Delayed_Aspect (Ritem)
2403                then
2404                   Aitem := Aspect_Rep_Item (Ritem);
2405
2406                   --  Skip if this is an aspect with no corresponding pragma
2407                   --  or attribute definition node (such as Default_Value).
2408
2409                   if Present (Aitem) then
2410                      Set_Parent (Aitem, Ritem);
2411                      Analyze (Aitem);
2412                   end if;
2413                end if;
2414
2415                Next_Rep_Item (Ritem);
2416             end loop;
2417          end;
2418       end if;
2419
2420       --  Here to freeze the entity
2421
2422       Set_Is_Frozen (E);
2423
2424       --  Case of entity being frozen is other than a type
2425
2426       if not Is_Type (E) then
2427
2428          --  If entity is exported or imported and does not have an external
2429          --  name, now is the time to provide the appropriate default name.
2430          --  Skip this if the entity is stubbed, since we don't need a name
2431          --  for any stubbed routine. For the case on intrinsics, if no
2432          --  external name is specified, then calls will be handled in
2433          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2434          --  external name is provided, then Expand_Intrinsic_Call leaves
2435          --  calls in place for expansion by GIGI.
2436
2437          if (Is_Imported (E) or else Is_Exported (E))
2438            and then No (Interface_Name (E))
2439            and then Convention (E) /= Convention_Stubbed
2440            and then Convention (E) /= Convention_Intrinsic
2441          then
2442             Set_Encoded_Interface_Name
2443               (E, Get_Default_External_Name (E));
2444
2445          --  If entity is an atomic object appearing in a declaration and
2446          --  the expression is an aggregate, assign it to a temporary to
2447          --  ensure that the actual assignment is done atomically rather
2448          --  than component-wise (the assignment to the temp may be done
2449          --  component-wise, but that is harmless).
2450
2451          elsif Is_Atomic (E)
2452            and then Nkind (Parent (E)) = N_Object_Declaration
2453            and then Present (Expression (Parent (E)))
2454            and then Nkind (Expression (Parent (E))) = N_Aggregate
2455            and then Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2456          then
2457             null;
2458          end if;
2459
2460          --  For a subprogram, freeze all parameter types and also the return
2461          --  type (RM 13.14(14)). However skip this for internal subprograms.
2462          --  This is also the point where any extra formal parameters are
2463          --  created since we now know whether the subprogram will use a
2464          --  foreign convention.
2465
2466          if Is_Subprogram (E) then
2467             if not Is_Internal (E) then
2468                declare
2469                   F_Type    : Entity_Id;
2470                   R_Type    : Entity_Id;
2471                   Warn_Node : Node_Id;
2472
2473                begin
2474                   --  Loop through formals
2475
2476                   Formal := First_Formal (E);
2477                   while Present (Formal) loop
2478                      F_Type := Etype (Formal);
2479                      Freeze_And_Append (F_Type, N, Result);
2480
2481                      if Is_Private_Type (F_Type)
2482                        and then Is_Private_Type (Base_Type (F_Type))
2483                        and then No (Full_View (Base_Type (F_Type)))
2484                        and then not Is_Generic_Type (F_Type)
2485                        and then not Is_Derived_Type (F_Type)
2486                      then
2487                         --  If the type of a formal is incomplete, subprogram
2488                         --  is being frozen prematurely. Within an instance
2489                         --  (but not within a wrapper package) this is an
2490                         --  artifact of our need to regard the end of an
2491                         --  instantiation as a freeze point. Otherwise it is
2492                         --  a definite error.
2493
2494                         if In_Instance then
2495                            Set_Is_Frozen (E, False);
2496                            return No_List;
2497
2498                         elsif not After_Last_Declaration
2499                           and then not Freezing_Library_Level_Tagged_Type
2500                         then
2501                            Error_Msg_Node_1 := F_Type;
2502                            Error_Msg
2503                              ("type& must be fully defined before this point",
2504                                Loc);
2505                         end if;
2506                      end if;
2507
2508                      --  Check suspicious parameter for C function. These tests
2509                      --  apply only to exported/imported subprograms.
2510
2511                      if Warn_On_Export_Import
2512                        and then Comes_From_Source (E)
2513                        and then (Convention (E) = Convention_C
2514                                    or else
2515                                  Convention (E) = Convention_CPP)
2516                        and then (Is_Imported (E) or else Is_Exported (E))
2517                        and then Convention (E) /= Convention (Formal)
2518                        and then not Has_Warnings_Off (E)
2519                        and then not Has_Warnings_Off (F_Type)
2520                        and then not Has_Warnings_Off (Formal)
2521                      then
2522                         --  Qualify mention of formals with subprogram name
2523
2524                         Error_Msg_Qual_Level := 1;
2525
2526                         --  Check suspicious use of fat C pointer
2527
2528                         if Is_Access_Type (F_Type)
2529                           and then Esize (F_Type) > Ttypes.System_Address_Size
2530                         then
2531                            Error_Msg_N
2532                              ("?type of & does not correspond to C pointer!",
2533                               Formal);
2534
2535                         --  Check suspicious return of boolean
2536
2537                         elsif Root_Type (F_Type) = Standard_Boolean
2538                           and then Convention (F_Type) = Convention_Ada
2539                           and then not Has_Warnings_Off (F_Type)
2540                           and then not Has_Size_Clause (F_Type)
2541                           and then VM_Target = No_VM
2542                         then
2543                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2544                            Error_Msg_N
2545                              ("\use appropriate corresponding type in C "
2546                               & "(e.g. char)?", Formal);
2547
2548                         --  Check suspicious tagged type
2549
2550                         elsif (Is_Tagged_Type (F_Type)
2551                                 or else (Is_Access_Type (F_Type)
2552                                            and then
2553                                              Is_Tagged_Type
2554                                                (Designated_Type (F_Type))))
2555                           and then Convention (E) = Convention_C
2556                         then
2557                            Error_Msg_N
2558                              ("?& involves a tagged type which does not "
2559                               & "correspond to any C type!", Formal);
2560
2561                         --  Check wrong convention subprogram pointer
2562
2563                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2564                           and then not Has_Foreign_Convention (F_Type)
2565                         then
2566                            Error_Msg_N
2567                              ("?subprogram pointer & should "
2568                               & "have foreign convention!", Formal);
2569                            Error_Msg_Sloc := Sloc (F_Type);
2570                            Error_Msg_NE
2571                              ("\?add Convention pragma to declaration of &#",
2572                               Formal, F_Type);
2573                         end if;
2574
2575                         --  Turn off name qualification after message output
2576
2577                         Error_Msg_Qual_Level := 0;
2578                      end if;
2579
2580                      --  Check for unconstrained array in exported foreign
2581                      --  convention case.
2582
2583                      if Has_Foreign_Convention (E)
2584                        and then not Is_Imported (E)
2585                        and then Is_Array_Type (F_Type)
2586                        and then not Is_Constrained (F_Type)
2587                        and then Warn_On_Export_Import
2588
2589                        --  Exclude VM case, since both .NET and JVM can handle
2590                        --  unconstrained arrays without a problem.
2591
2592                        and then VM_Target = No_VM
2593                      then
2594                         Error_Msg_Qual_Level := 1;
2595
2596                         --  If this is an inherited operation, place the
2597                         --  warning on the derived type declaration, rather
2598                         --  than on the original subprogram.
2599
2600                         if Nkind (Original_Node (Parent (E))) =
2601                           N_Full_Type_Declaration
2602                         then
2603                            Warn_Node := Parent (E);
2604
2605                            if Formal = First_Formal (E) then
2606                               Error_Msg_NE
2607                                 ("?in inherited operation&", Warn_Node, E);
2608                            end if;
2609                         else
2610                            Warn_Node := Formal;
2611                         end if;
2612
2613                         Error_Msg_NE
2614                           ("?type of argument& is unconstrained array",
2615                            Warn_Node, Formal);
2616                         Error_Msg_NE
2617                           ("?foreign caller must pass bounds explicitly",
2618                            Warn_Node, Formal);
2619                         Error_Msg_Qual_Level := 0;
2620                      end if;
2621
2622                      if not From_With_Type (F_Type) then
2623                         if Is_Access_Type (F_Type) then
2624                            F_Type := Designated_Type (F_Type);
2625                         end if;
2626
2627                         --  If the formal is an anonymous_access_to_subprogram
2628                         --  freeze the  subprogram type as well, to prevent
2629                         --  scope anomalies in gigi, because there is no other
2630                         --  clear point at which it could be frozen.
2631
2632                         if Is_Itype (Etype (Formal))
2633                           and then Ekind (F_Type) = E_Subprogram_Type
2634                         then
2635                            Freeze_And_Append (F_Type, N, Result);
2636                         end if;
2637                      end if;
2638
2639                      Next_Formal (Formal);
2640                   end loop;
2641
2642                   --  Case of function: similar checks on return type
2643
2644                   if Ekind (E) = E_Function then
2645
2646                      --  Freeze return type
2647
2648                      R_Type := Etype (E);
2649                      Freeze_And_Append (R_Type, N, Result);
2650
2651                      --  Check suspicious return type for C function
2652
2653                      if Warn_On_Export_Import
2654                        and then (Convention (E) = Convention_C
2655                                    or else
2656                                  Convention (E) = Convention_CPP)
2657                        and then (Is_Imported (E) or else Is_Exported (E))
2658                      then
2659                         --  Check suspicious return of fat C pointer
2660
2661                         if Is_Access_Type (R_Type)
2662                           and then Esize (R_Type) > Ttypes.System_Address_Size
2663                           and then not Has_Warnings_Off (E)
2664                           and then not Has_Warnings_Off (R_Type)
2665                         then
2666                            Error_Msg_N
2667                              ("?return type of& does not "
2668                               & "correspond to C pointer!", E);
2669
2670                         --  Check suspicious return of boolean
2671
2672                         elsif Root_Type (R_Type) = Standard_Boolean
2673                           and then Convention (R_Type) = Convention_Ada
2674                           and then VM_Target = No_VM
2675                           and then not Has_Warnings_Off (E)
2676                           and then not Has_Warnings_Off (R_Type)
2677                           and then not Has_Size_Clause (R_Type)
2678                         then
2679                            declare
2680                               N : constant Node_Id :=
2681                                     Result_Definition (Declaration_Node (E));
2682                            begin
2683                               Error_Msg_NE
2684                                 ("return type of & is an 8-bit Ada Boolean?",
2685                                  N, E);
2686                               Error_Msg_NE
2687                                 ("\use appropriate corresponding type in C "
2688                                  & "(e.g. char)?", N, E);
2689                            end;
2690
2691                         --  Check suspicious return tagged type
2692
2693                         elsif (Is_Tagged_Type (R_Type)
2694                                 or else (Is_Access_Type (R_Type)
2695                                            and then
2696                                              Is_Tagged_Type
2697                                                (Designated_Type (R_Type))))
2698                           and then Convention (E) = Convention_C
2699                           and then not Has_Warnings_Off (E)
2700                           and then not Has_Warnings_Off (R_Type)
2701                         then
2702                            Error_Msg_N
2703                              ("?return type of & does not "
2704                               & "correspond to C type!", E);
2705
2706                         --  Check return of wrong convention subprogram pointer
2707
2708                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2709                           and then not Has_Foreign_Convention (R_Type)
2710                           and then not Has_Warnings_Off (E)
2711                           and then not Has_Warnings_Off (R_Type)
2712                         then
2713                            Error_Msg_N
2714                              ("?& should return a foreign "
2715                               & "convention subprogram pointer", E);
2716                            Error_Msg_Sloc := Sloc (R_Type);
2717                            Error_Msg_NE
2718                              ("\?add Convention pragma to declaration of& #",
2719                               E, R_Type);
2720                         end if;
2721                      end if;
2722
2723                      --  Give warning for suspicious return of a result of an
2724                      --  unconstrained array type in a foreign convention
2725                      --  function.
2726
2727                      if Has_Foreign_Convention (E)
2728
2729                         --  We are looking for a return of unconstrained array
2730
2731                        and then Is_Array_Type (R_Type)
2732                        and then not Is_Constrained (R_Type)
2733
2734                         --  Exclude imported routines, the warning does not
2735                         --  belong on the import, but rather on the routine
2736                         --  definition.
2737
2738                        and then not Is_Imported (E)
2739
2740                         --  Exclude VM case, since both .NET and JVM can handle
2741                         --  return of unconstrained arrays without a problem.
2742
2743                        and then VM_Target = No_VM
2744
2745                         --  Check that general warning is enabled, and that it
2746                         --  is not suppressed for this particular case.
2747
2748                        and then Warn_On_Export_Import
2749                        and then not Has_Warnings_Off (E)
2750                        and then not Has_Warnings_Off (R_Type)
2751                      then
2752                         Error_Msg_N
2753                           ("?foreign convention function& should not " &
2754                            "return unconstrained array!", E);
2755                      end if;
2756                   end if;
2757                end;
2758             end if;
2759
2760             --  Must freeze its parent first if it is a derived subprogram
2761
2762             if Present (Alias (E)) then
2763                Freeze_And_Append (Alias (E), N, Result);
2764             end if;
2765
2766             --  We don't freeze internal subprograms, because we don't normally
2767             --  want addition of extra formals or mechanism setting to happen
2768             --  for those. However we do pass through predefined dispatching
2769             --  cases, since extra formals may be needed in some cases, such as
2770             --  for the stream 'Input function (build-in-place formals).
2771
2772             if not Is_Internal (E)
2773               or else Is_Predefined_Dispatching_Operation (E)
2774             then
2775                Freeze_Subprogram (E);
2776             end if;
2777
2778          --  Here for other than a subprogram or type
2779
2780          else
2781             --  If entity has a type, and it is not a generic unit, then
2782             --  freeze it first (RM 13.14(10)).
2783
2784             if Present (Etype (E))
2785               and then Ekind (E) /= E_Generic_Function
2786             then
2787                Freeze_And_Append (Etype (E), N, Result);
2788             end if;
2789
2790             --  Special processing for objects created by object declaration
2791
2792             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2793
2794                --  Abstract type allowed only for C++ imported variables or
2795                --  constants.
2796
2797                --  Note: we inhibit this check for objects that do not come
2798                --  from source because there is at least one case (the
2799                --  expansion of x'class'input where x is abstract) where we
2800                --  legitimately generate an abstract object.
2801
2802                if Is_Abstract_Type (Etype (E))
2803                  and then Comes_From_Source (Parent (E))
2804                  and then not (Is_Imported (E)
2805                                  and then Is_CPP_Class (Etype (E)))
2806                then
2807                   Error_Msg_N ("type of object cannot be abstract",
2808                                Object_Definition (Parent (E)));
2809
2810                   if Is_CPP_Class (Etype (E)) then
2811                      Error_Msg_NE
2812                        ("\} may need a cpp_constructor",
2813                        Object_Definition (Parent (E)), Etype (E));
2814                   end if;
2815                end if;
2816
2817                --  For object created by object declaration, perform required
2818                --  categorization (preelaborate and pure) checks. Defer these
2819                --  checks to freeze time since pragma Import inhibits default
2820                --  initialization and thus pragma Import affects these checks.
2821
2822                Validate_Object_Declaration (Declaration_Node (E));
2823
2824                --  If there is an address clause, check that it is valid
2825
2826                Check_Address_Clause (E);
2827
2828                --  If the object needs any kind of default initialization, an
2829                --  error must be issued if No_Default_Initialization applies.
2830                --  The check doesn't apply to imported objects, which are not
2831                --  ever default initialized, and is why the check is deferred
2832                --  until freezing, at which point we know if Import applies.
2833                --  Deferred constants are also exempted from this test because
2834                --  their completion is explicit, or through an import pragma.
2835
2836                if Ekind (E) = E_Constant
2837                  and then Present (Full_View (E))
2838                then
2839                   null;
2840
2841                elsif Comes_From_Source (E)
2842                  and then not Is_Imported (E)
2843                  and then not Has_Init_Expression (Declaration_Node (E))
2844                  and then
2845                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2846                       and then not No_Initialization (Declaration_Node (E))
2847                       and then not Is_Value_Type (Etype (E))
2848                       and then not Initialization_Suppressed (Etype (E)))
2849                     or else
2850                       (Needs_Simple_Initialization (Etype (E))
2851                         and then not Is_Internal (E)))
2852                then
2853                   Has_Default_Initialization := True;
2854                   Check_Restriction
2855                     (No_Default_Initialization, Declaration_Node (E));
2856                end if;
2857
2858                --  Check that a Thread_Local_Storage variable does not have
2859                --  default initialization, and any explicit initialization must
2860                --  either be the null constant or a static constant.
2861
2862                if Has_Pragma_Thread_Local_Storage (E) then
2863                   declare
2864                      Decl : constant Node_Id := Declaration_Node (E);
2865                   begin
2866                      if Has_Default_Initialization
2867                        or else
2868                          (Has_Init_Expression (Decl)
2869                             and then
2870                              (No (Expression (Decl))
2871                                 or else not
2872                                   (Is_Static_Expression (Expression (Decl))
2873                                      or else
2874                                    Nkind (Expression (Decl)) = N_Null)))
2875                      then
2876                         Error_Msg_NE
2877                           ("Thread_Local_Storage variable& is "
2878                            & "improperly initialized", Decl, E);
2879                         Error_Msg_NE
2880                           ("\only allowed initialization is explicit "
2881                            & "NULL or static expression", Decl, E);
2882                      end if;
2883                   end;
2884                end if;
2885
2886                --  For imported objects, set Is_Public unless there is also an
2887                --  address clause, which means that there is no external symbol
2888                --  needed for the Import (Is_Public may still be set for other
2889                --  unrelated reasons). Note that we delayed this processing
2890                --  till freeze time so that we can be sure not to set the flag
2891                --  if there is an address clause. If there is such a clause,
2892                --  then the only purpose of the Import pragma is to suppress
2893                --  implicit initialization.
2894
2895                if Is_Imported (E)
2896                  and then No (Address_Clause (E))
2897                then
2898                   Set_Is_Public (E);
2899                end if;
2900
2901                --  For convention C objects of an enumeration type, warn if
2902                --  the size is not integer size and no explicit size given.
2903                --  Skip warning for Boolean, and Character, assume programmer
2904                --  expects 8-bit sizes for these cases.
2905
2906                if (Convention (E) = Convention_C
2907                     or else
2908                    Convention (E) = Convention_CPP)
2909                  and then Is_Enumeration_Type (Etype (E))
2910                  and then not Is_Character_Type (Etype (E))
2911                  and then not Is_Boolean_Type (Etype (E))
2912                  and then Esize (Etype (E)) < Standard_Integer_Size
2913                  and then not Has_Size_Clause (E)
2914                then
2915                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2916                   Error_Msg_N
2917                     ("?convention C enumeration object has size less than ^",
2918                      E);
2919                   Error_Msg_N ("\?use explicit size clause to set size", E);
2920                end if;
2921             end if;
2922
2923             --  Check that a constant which has a pragma Volatile[_Components]
2924             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2925
2926             --  Note: Atomic[_Components] also sets Volatile[_Components]
2927
2928             if Ekind (E) = E_Constant
2929               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2930               and then not Is_Imported (E)
2931             then
2932                --  Make sure we actually have a pragma, and have not merely
2933                --  inherited the indication from elsewhere (e.g. an address
2934                --  clause, which is not good enough in RM terms!)
2935
2936                if Has_Rep_Pragma (E, Name_Atomic)
2937                     or else
2938                   Has_Rep_Pragma (E, Name_Atomic_Components)
2939                then
2940                   Error_Msg_N
2941                     ("stand alone atomic constant must be " &
2942                      "imported (RM C.6(13))", E);
2943
2944                elsif Has_Rep_Pragma (E, Name_Volatile)
2945                        or else
2946                      Has_Rep_Pragma (E, Name_Volatile_Components)
2947                then
2948                   Error_Msg_N
2949                     ("stand alone volatile constant must be " &
2950                      "imported (RM C.6(13))", E);
2951                end if;
2952             end if;
2953
2954             --  Static objects require special handling
2955
2956             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2957               and then Is_Statically_Allocated (E)
2958             then
2959                Freeze_Static_Object (E);
2960             end if;
2961
2962             --  Remaining step is to layout objects
2963
2964             if Ekind (E) = E_Variable
2965                  or else
2966                Ekind (E) = E_Constant
2967                  or else
2968                Ekind (E) = E_Loop_Parameter
2969                  or else
2970                Is_Formal (E)
2971             then
2972                Layout_Object (E);
2973             end if;
2974          end if;
2975
2976       --  Case of a type or subtype being frozen
2977
2978       else
2979          --  We used to check here that a full type must have preelaborable
2980          --  initialization if it completes a private type specified with
2981          --  pragma Preelaborable_Initialization, but that missed cases where
2982          --  the types occur within a generic package, since the freezing
2983          --  that occurs within a containing scope generally skips traversal
2984          --  of a generic unit's declarations (those will be frozen within
2985          --  instances). This check was moved to Analyze_Package_Specification.
2986
2987          --  The type may be defined in a generic unit. This can occur when
2988          --  freezing a generic function that returns the type (which is
2989          --  defined in a parent unit). It is clearly meaningless to freeze
2990          --  this type. However, if it is a subtype, its size may be determi-
2991          --  nable and used in subsequent checks, so might as well try to
2992          --  compute it.
2993
2994          if Present (Scope (E))
2995            and then Is_Generic_Unit (Scope (E))
2996          then
2997             Check_Compile_Time_Size (E);
2998             return No_List;
2999          end if;
3000
3001          --  Deal with special cases of freezing for subtype
3002
3003          if E /= Base_Type (E) then
3004
3005             --  Before we do anything else, a specialized test for the case of
3006             --  a size given for an array where the array needs to be packed,
3007             --  but was not so the size cannot be honored. This would of course
3008             --  be caught by the backend, and indeed we don't catch all cases.
3009             --  The point is that we can give a better error message in those
3010             --  cases that we do catch with the circuitry here. Also if pragma
3011             --  Implicit_Packing is set, this is where the packing occurs.
3012
3013             --  The reason we do this so early is that the processing in the
3014             --  automatic packing case affects the layout of the base type, so
3015             --  it must be done before we freeze the base type.
3016
3017             if Is_Array_Type (E) then
3018                declare
3019                   Lo, Hi : Node_Id;
3020                   Ctyp   : constant Entity_Id := Component_Type (E);
3021
3022                begin
3023                   --  Check enabling conditions. These are straightforward
3024                   --  except for the test for a limited composite type. This
3025                   --  eliminates the rare case of a array of limited components
3026                   --  where there are issues of whether or not we can go ahead
3027                   --  and pack the array (since we can't freely pack and unpack
3028                   --  arrays if they are limited).
3029
3030                   --  Note that we check the root type explicitly because the
3031                   --  whole point is we are doing this test before we have had
3032                   --  a chance to freeze the base type (and it is that freeze
3033                   --  action that causes stuff to be inherited).
3034
3035                   if Present (Size_Clause (E))
3036                     and then Known_Static_Esize (E)
3037                     and then not Is_Packed (E)
3038                     and then not Has_Pragma_Pack (E)
3039                     and then Number_Dimensions (E) = 1
3040                     and then not Has_Component_Size_Clause (E)
3041                     and then Known_Static_Esize (Ctyp)
3042                     and then not Is_Limited_Composite (E)
3043                     and then not Is_Packed (Root_Type (E))
3044                     and then not Has_Component_Size_Clause (Root_Type (E))
3045                     and then not CodePeer_Mode
3046                   then
3047                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3048
3049                      if Compile_Time_Known_Value (Lo)
3050                        and then Compile_Time_Known_Value (Hi)
3051                        and then Known_Static_RM_Size (Ctyp)
3052                        and then RM_Size (Ctyp) < 64
3053                      then
3054                         declare
3055                            Lov  : constant Uint      := Expr_Value (Lo);
3056                            Hiv  : constant Uint      := Expr_Value (Hi);
3057                            Len  : constant Uint      := UI_Max
3058                                                          (Uint_0,
3059                                                           Hiv - Lov + 1);
3060                            Rsiz : constant Uint      := RM_Size (Ctyp);
3061                            SZ   : constant Node_Id   := Size_Clause (E);
3062                            Btyp : constant Entity_Id := Base_Type (E);
3063
3064                         --  What we are looking for here is the situation where
3065                         --  the RM_Size given would be exactly right if there
3066                         --  was a pragma Pack (resulting in the component size
3067                         --  being the same as the RM_Size). Furthermore, the
3068                         --  component type size must be an odd size (not a
3069                         --  multiple of storage unit). If the component RM size
3070                         --  is an exact number of storage units that is a power
3071                         --  of two, the array is not packed and has a standard
3072                         --  representation.
3073
3074                         begin
3075                            if RM_Size (E) = Len * Rsiz
3076                              and then Rsiz mod System_Storage_Unit /= 0
3077                            then
3078                               --  For implicit packing mode, just set the
3079                               --  component size silently.
3080
3081                               if Implicit_Packing then
3082                                  Set_Component_Size       (Btyp, Rsiz);
3083                                  Set_Is_Bit_Packed_Array  (Btyp);
3084                                  Set_Is_Packed            (Btyp);
3085                                  Set_Has_Non_Standard_Rep (Btyp);
3086
3087                                  --  Otherwise give an error message
3088
3089                               else
3090                                  Error_Msg_NE
3091                                    ("size given for& too small", SZ, E);
3092                                  Error_Msg_N -- CODEFIX
3093                                    ("\use explicit pragma Pack "
3094                                     & "or use pragma Implicit_Packing", SZ);
3095                               end if;
3096
3097                            elsif RM_Size (E) = Len * Rsiz
3098                              and then Implicit_Packing
3099                              and then
3100                                (Rsiz / System_Storage_Unit = 1
3101                                  or else Rsiz / System_Storage_Unit = 2
3102                                  or else Rsiz / System_Storage_Unit = 4)
3103                            then
3104
3105                               --  Not a packed array, but indicate the desired
3106                               --  component size, for the back-end.
3107
3108                               Set_Component_Size (Btyp, Rsiz);
3109                            end if;
3110                         end;
3111                      end if;
3112                   end if;
3113                end;
3114             end if;
3115
3116             --  If ancestor subtype present, freeze that first. Note that this
3117             --  will also get the base type frozen. Need RM reference ???
3118
3119             Atype := Ancestor_Subtype (E);
3120
3121             if Present (Atype) then
3122                Freeze_And_Append (Atype, N, Result);
3123
3124             --  No ancestor subtype present
3125
3126             else
3127                --  See if we have a nearest ancestor that has a predicate.
3128                --  That catches the case of derived type with a predicate.
3129                --  Need RM reference here ???
3130
3131                Atype := Nearest_Ancestor (E);
3132
3133                if Present (Atype) and then Has_Predicates (Atype) then
3134                   Freeze_And_Append (Atype, N, Result);
3135                end if;
3136
3137                --  Freeze base type before freezing the entity (RM 13.14(15))
3138
3139                if E /= Base_Type (E) then
3140                   Freeze_And_Append (Base_Type (E), N, Result);
3141                end if;
3142             end if;
3143
3144          --  For a derived type, freeze its parent type first (RM 13.14(15))
3145
3146          elsif Is_Derived_Type (E) then
3147             Freeze_And_Append (Etype (E), N, Result);
3148             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3149          end if;
3150
3151          --  For array type, freeze index types and component type first
3152          --  before freezing the array (RM 13.14(15)).
3153
3154          if Is_Array_Type (E) then
3155             declare
3156                FS     : constant Entity_Id := First_Subtype (E);
3157                Ctyp   : constant Entity_Id := Component_Type (E);
3158                Clause : Entity_Id;
3159
3160                Non_Standard_Enum : Boolean := False;
3161                --  Set true if any of the index types is an enumeration type
3162                --  with a non-standard representation.
3163
3164             begin
3165                Freeze_And_Append (Ctyp, N, Result);
3166
3167                Indx := First_Index (E);
3168                while Present (Indx) loop
3169                   Freeze_And_Append (Etype (Indx), N, Result);
3170
3171                   if Is_Enumeration_Type (Etype (Indx))
3172                     and then Has_Non_Standard_Rep (Etype (Indx))
3173                   then
3174                      Non_Standard_Enum := True;
3175                   end if;
3176
3177                   Next_Index (Indx);
3178                end loop;
3179
3180                --  Processing that is done only for base types
3181
3182                if Ekind (E) = E_Array_Type then
3183
3184                   --  Propagate flags for component type
3185
3186                   if Is_Controlled (Component_Type (E))
3187                     or else Has_Controlled_Component (Ctyp)
3188                   then
3189                      Set_Has_Controlled_Component (E);
3190                   end if;
3191
3192                   if Has_Unchecked_Union (Component_Type (E)) then
3193                      Set_Has_Unchecked_Union (E);
3194                   end if;
3195
3196                   --  If packing was requested or if the component size was set
3197                   --  explicitly, then see if bit packing is required. This
3198                   --  processing is only done for base types, since all the
3199                   --  representation aspects involved are type-related. This
3200                   --  is not just an optimization, if we start processing the
3201                   --  subtypes, they interfere with the settings on the base
3202                   --  type (this is because Is_Packed has a slightly different
3203                   --  meaning before and after freezing).
3204
3205                   declare
3206                      Csiz : Uint;
3207                      Esiz : Uint;
3208
3209                   begin
3210                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3211                        and then Known_Static_RM_Size (Ctyp)
3212                        and then not Has_Component_Size_Clause (E)
3213                      then
3214                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3215
3216                      elsif Known_Component_Size (E) then
3217                         Csiz := Component_Size (E);
3218
3219                      elsif not Known_Static_Esize (Ctyp) then
3220                         Csiz := Uint_0;
3221
3222                      else
3223                         Esiz := Esize (Ctyp);
3224
3225                         --  We can set the component size if it is less than
3226                         --  16, rounding it up to the next storage unit size.
3227
3228                         if Esiz <= 8 then
3229                            Csiz := Uint_8;
3230                         elsif Esiz <= 16 then
3231                            Csiz := Uint_16;
3232                         else
3233                            Csiz := Uint_0;
3234                         end if;
3235
3236                         --  Set component size up to match alignment if it
3237                         --  would otherwise be less than the alignment. This
3238                         --  deals with cases of types whose alignment exceeds
3239                         --  their size (padded types).
3240
3241                         if Csiz /= 0 then
3242                            declare
3243                               A : constant Uint := Alignment_In_Bits (Ctyp);
3244                            begin
3245                               if Csiz < A then
3246                                  Csiz := A;
3247                               end if;
3248                            end;
3249                         end if;
3250                      end if;
3251
3252                      --  Case of component size that may result in packing
3253
3254                      if 1 <= Csiz and then Csiz <= 64 then
3255                         declare
3256                            Ent         : constant Entity_Id :=
3257                                            First_Subtype (E);
3258                            Pack_Pragma : constant Node_Id :=
3259                                            Get_Rep_Pragma (Ent, Name_Pack);
3260                            Comp_Size_C : constant Node_Id :=
3261                                            Get_Attribute_Definition_Clause
3262                                              (Ent, Attribute_Component_Size);
3263                         begin
3264                            --  Warn if we have pack and component size so that
3265                            --  the pack is ignored.
3266
3267                            --  Note: here we must check for the presence of a
3268                            --  component size before checking for a Pack pragma
3269                            --  to deal with the case where the array type is a
3270                            --  derived type whose parent is currently private.
3271
3272                            if Present (Comp_Size_C)
3273                              and then Has_Pragma_Pack (Ent)
3274                              and then Warn_On_Redundant_Constructs
3275                            then
3276                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3277                               Error_Msg_NE
3278                                 ("?pragma Pack for& ignored!",
3279                                  Pack_Pragma, Ent);
3280                               Error_Msg_N
3281                                 ("\?explicit component size given#!",
3282                                  Pack_Pragma);
3283                               Set_Is_Packed (Base_Type (Ent), False);
3284                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3285                            end if;
3286
3287                            --  Set component size if not already set by a
3288                            --  component size clause.
3289
3290                            if not Present (Comp_Size_C) then
3291                               Set_Component_Size (E, Csiz);
3292                            end if;
3293
3294                            --  Check for base type of 8, 16, 32 bits, where an
3295                            --  unsigned subtype has a length one less than the
3296                            --  base type (e.g. Natural subtype of Integer).
3297
3298                            --  In such cases, if a component size was not set
3299                            --  explicitly, then generate a warning.
3300
3301                            if Has_Pragma_Pack (E)
3302                              and then not Present (Comp_Size_C)
3303                              and then
3304                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3305                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3306                            then
3307                               Error_Msg_Uint_1 := Csiz;
3308
3309                               if Present (Pack_Pragma) then
3310                                  Error_Msg_N
3311                                    ("?pragma Pack causes component size "
3312                                     & "to be ^!", Pack_Pragma);
3313                                  Error_Msg_N
3314                                    ("\?use Component_Size to set "
3315                                     & "desired value!", Pack_Pragma);
3316                               end if;
3317                            end if;
3318
3319                            --  Actual packing is not needed for 8, 16, 32, 64.
3320                            --  Also not needed for 24 if alignment is 1.
3321
3322                            if        Csiz = 8
3323                              or else Csiz = 16
3324                              or else Csiz = 32
3325                              or else Csiz = 64
3326                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3327                            then
3328                               --  Here the array was requested to be packed,
3329                               --  but the packing request had no effect, so
3330                               --  Is_Packed is reset.
3331
3332                               --  Note: semantically this means that we lose
3333                               --  track of the fact that a derived type
3334                               --  inherited a pragma Pack that was non-
3335                               --  effective, but that seems fine.
3336
3337                               --  We regard a Pack pragma as a request to set
3338                               --  a representation characteristic, and this
3339                               --  request may be ignored.
3340
3341                               Set_Is_Packed           (Base_Type (E), False);
3342                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3343
3344                               if Known_Static_Esize (Component_Type (E))
3345                                 and then Esize (Component_Type (E)) = Csiz
3346                               then
3347                                  Set_Has_Non_Standard_Rep
3348                                    (Base_Type (E), False);
3349                               end if;
3350
3351                            --  In all other cases, packing is indeed needed
3352
3353                            else
3354                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3355                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3356                               Set_Is_Packed            (Base_Type (E), True);
3357                            end if;
3358                         end;
3359                      end if;
3360                   end;
3361
3362                   --  Check for Atomic_Components or Aliased with unsuitable
3363                   --  packing or explicit component size clause given.
3364
3365                   if (Has_Atomic_Components (E)
3366                        or else Has_Aliased_Components (E))
3367                     and then (Has_Component_Size_Clause (E)
3368                                or else Is_Packed (E))
3369                   then
3370                      Alias_Atomic_Check : declare
3371
3372                         procedure Complain_CS (T : String);
3373                         --  Outputs error messages for incorrect CS clause or
3374                         --  pragma Pack for aliased or atomic components (T is
3375                         --  "aliased" or "atomic");
3376
3377                         -----------------
3378                         -- Complain_CS --
3379                         -----------------
3380
3381                         procedure Complain_CS (T : String) is
3382                         begin
3383                            if Has_Component_Size_Clause (E) then
3384                               Clause :=
3385                                 Get_Attribute_Definition_Clause
3386                                   (FS, Attribute_Component_Size);
3387
3388                               if Known_Static_Esize (Ctyp) then
3389                                  Error_Msg_N
3390                                    ("incorrect component size for "
3391                                     & T & " components", Clause);
3392                                  Error_Msg_Uint_1 := Esize (Ctyp);
3393                                  Error_Msg_N
3394                                    ("\only allowed value is^", Clause);
3395
3396                               else
3397                                  Error_Msg_N
3398                                    ("component size cannot be given for "
3399                                     & T & " components", Clause);
3400                               end if;
3401
3402                            else
3403                               Error_Msg_N
3404                                 ("cannot pack " & T & " components",
3405                                  Get_Rep_Pragma (FS, Name_Pack));
3406                            end if;
3407
3408                            return;
3409                         end Complain_CS;
3410
3411                      --  Start of processing for Alias_Atomic_Check
3412
3413                      begin
3414                         --  Case where component size has no effect. First
3415                         --  check for object size of component type known
3416                         --  and a multiple of the storage unit size.
3417
3418                         if Known_Static_Esize (Ctyp)
3419                           and then Esize (Ctyp) mod System_Storage_Unit = 0
3420
3421                           --  OK in both packing case and component size case
3422                           --  if RM size is known and static and the same as
3423                           --  the object size.
3424
3425                           and then
3426                             ((Known_Static_RM_Size (Ctyp)
3427                                and then Esize (Ctyp) = RM_Size (Ctyp))
3428
3429                              --  Or if we have an explicit component size
3430                              --  clause and the component size and object size
3431                              --  are equal.
3432
3433                              or else
3434                                  (Has_Component_Size_Clause (E)
3435                                  and then Component_Size (E) = Esize (Ctyp)))
3436                         then
3437                            null;
3438
3439                         elsif Has_Aliased_Components (E)
3440                           or else Is_Aliased (Ctyp)
3441                         then
3442                            Complain_CS ("aliased");
3443
3444                         elsif Has_Atomic_Components (E)
3445                           or else Is_Atomic (Ctyp)
3446                         then
3447                            Complain_CS ("atomic");
3448                         end if;
3449                      end Alias_Atomic_Check;
3450                   end if;
3451
3452                   --  Warn for case of atomic type
3453
3454                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3455
3456                   if Present (Clause)
3457                     and then not Addressable (Component_Size (FS))
3458                   then
3459                      Error_Msg_NE
3460                        ("non-atomic components of type& may not be "
3461                         & "accessible by separate tasks?", Clause, E);
3462
3463                      if Has_Component_Size_Clause (E) then
3464                         Error_Msg_Sloc :=
3465                           Sloc
3466                             (Get_Attribute_Definition_Clause
3467                                  (FS, Attribute_Component_Size));
3468                         Error_Msg_N
3469                           ("\because of component size clause#?",
3470                            Clause);
3471
3472                      elsif Has_Pragma_Pack (E) then
3473                         Error_Msg_Sloc :=
3474                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3475                         Error_Msg_N
3476                           ("\because of pragma Pack#?", Clause);
3477                      end if;
3478                   end if;
3479
3480                --  Processing that is done only for subtypes
3481
3482                else
3483                   --  Acquire alignment from base type
3484
3485                   if Unknown_Alignment (E) then
3486                      Set_Alignment (E, Alignment (Base_Type (E)));
3487                      Adjust_Esize_Alignment (E);
3488                   end if;
3489                end if;
3490
3491                --  For bit-packed arrays, check the size
3492
3493                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3494                   declare
3495                      SizC : constant Node_Id := Size_Clause (E);
3496
3497                      Discard : Boolean;
3498                      pragma Warnings (Off, Discard);
3499
3500                   begin
3501                      --  It is not clear if it is possible to have no size
3502                      --  clause at this stage, but it is not worth worrying
3503                      --  about. Post error on the entity name in the size
3504                      --  clause if present, else on the type entity itself.
3505
3506                      if Present (SizC) then
3507                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3508                      else
3509                         Check_Size (E, E, RM_Size (E), Discard);
3510                      end if;
3511                   end;
3512                end if;
3513
3514                --  If any of the index types was an enumeration type with a
3515                --  non-standard rep clause, then we indicate that the array
3516                --  type is always packed (even if it is not bit packed).
3517
3518                if Non_Standard_Enum then
3519                   Set_Has_Non_Standard_Rep (Base_Type (E));
3520                   Set_Is_Packed            (Base_Type (E));
3521                end if;
3522
3523                Set_Component_Alignment_If_Not_Set (E);
3524
3525                --  If the array is packed, we must create the packed array
3526                --  type to be used to actually implement the type. This is
3527                --  only needed for real array types (not for string literal
3528                --  types, since they are present only for the front end).
3529
3530                if Is_Packed (E)
3531                  and then Ekind (E) /= E_String_Literal_Subtype
3532                then
3533                   Create_Packed_Array_Type (E);
3534                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3535
3536                   --  Size information of packed array type is copied to the
3537                   --  array type, since this is really the representation. But
3538                   --  do not override explicit existing size values. If the
3539                   --  ancestor subtype is constrained the packed_array_type
3540                   --  will be inherited from it, but the size may have been
3541                   --  provided already, and must not be overridden either.
3542
3543                   if not Has_Size_Clause (E)
3544                     and then
3545                       (No (Ancestor_Subtype (E))
3546                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3547                   then
3548                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3549                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3550                   end if;
3551
3552                   if not Has_Alignment_Clause (E) then
3553                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3554                   end if;
3555                end if;
3556
3557                --  For non-packed arrays set the alignment of the array to the
3558                --  alignment of the component type if it is unknown. Skip this
3559                --  in atomic case (atomic arrays may need larger alignments).
3560
3561                if not Is_Packed (E)
3562                  and then Unknown_Alignment (E)
3563                  and then Known_Alignment (Ctyp)
3564                  and then Known_Static_Component_Size (E)
3565                  and then Known_Static_Esize (Ctyp)
3566                  and then Esize (Ctyp) = Component_Size (E)
3567                  and then not Is_Atomic (E)
3568                then
3569                   Set_Alignment (E, Alignment (Component_Type (E)));
3570                end if;
3571             end;
3572
3573          --  For a class-wide type, the corresponding specific type is
3574          --  frozen as well (RM 13.14(15))
3575
3576          elsif Is_Class_Wide_Type (E) then
3577             Freeze_And_Append (Root_Type (E), N, Result);
3578
3579             --  If the base type of the class-wide type is still incomplete,
3580             --  the class-wide remains unfrozen as well. This is legal when
3581             --  E is the formal of a primitive operation of some other type
3582             --  which is being frozen.
3583
3584             if not Is_Frozen (Root_Type (E)) then
3585                Set_Is_Frozen (E, False);
3586                return Result;
3587             end if;
3588
3589             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3590             --  parent of a derived type) and it is a library-level entity,
3591             --  generate an itype reference for it. Otherwise, its first
3592             --  explicit reference may be in an inner scope, which will be
3593             --  rejected by the back-end.
3594
3595             if Is_Itype (E)
3596               and then Is_Compilation_Unit (Scope (E))
3597             then
3598                declare
3599                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3600
3601                begin
3602                   Set_Itype (Ref, E);
3603                   Add_To_Result (Ref);
3604                end;
3605             end if;
3606
3607             --  The equivalent type associated with a class-wide subtype needs
3608             --  to be frozen to ensure that its layout is done.
3609
3610             if Ekind (E) = E_Class_Wide_Subtype
3611               and then Present (Equivalent_Type (E))
3612             then
3613                Freeze_And_Append (Equivalent_Type (E), N, Result);
3614             end if;
3615
3616          --  For a record (sub)type, freeze all the component types (RM
3617          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3618          --  Is_Record_Type, because we don't want to attempt the freeze for
3619          --  the case of a private type with record extension (we will do that
3620          --  later when the full type is frozen).
3621
3622          elsif Ekind (E) = E_Record_Type
3623            or else Ekind (E) = E_Record_Subtype
3624          then
3625             Freeze_Record_Type (E);
3626
3627          --  For a concurrent type, freeze corresponding record type. This
3628          --  does not correspond to any specific rule in the RM, but the
3629          --  record type is essentially part of the concurrent type.
3630          --  Freeze as well all local entities. This includes record types
3631          --  created for entry parameter blocks, and whatever local entities
3632          --  may appear in the private part.
3633
3634          elsif Is_Concurrent_Type (E) then
3635             if Present (Corresponding_Record_Type (E)) then
3636                Freeze_And_Append
3637                  (Corresponding_Record_Type (E), N, Result);
3638             end if;
3639
3640             Comp := First_Entity (E);
3641             while Present (Comp) loop
3642                if Is_Type (Comp) then
3643                   Freeze_And_Append (Comp, N, Result);
3644
3645                elsif (Ekind (Comp)) /= E_Function then
3646                   if Is_Itype (Etype (Comp))
3647                     and then Underlying_Type (Scope (Etype (Comp))) = E
3648                   then
3649                      Undelay_Type (Etype (Comp));
3650                   end if;
3651
3652                   Freeze_And_Append (Etype (Comp), N, Result);
3653                end if;
3654
3655                Next_Entity (Comp);
3656             end loop;
3657
3658          --  Private types are required to point to the same freeze node as
3659          --  their corresponding full views. The freeze node itself has to
3660          --  point to the partial view of the entity (because from the partial
3661          --  view, we can retrieve the full view, but not the reverse).
3662          --  However, in order to freeze correctly, we need to freeze the full
3663          --  view. If we are freezing at the end of a scope (or within the
3664          --  scope of the private type), the partial and full views will have
3665          --  been swapped, the full view appears first in the entity chain and
3666          --  the swapping mechanism ensures that the pointers are properly set
3667          --  (on scope exit).
3668
3669          --  If we encounter the partial view before the full view (e.g. when
3670          --  freezing from another scope), we freeze the full view, and then
3671          --  set the pointers appropriately since we cannot rely on swapping to
3672          --  fix things up (subtypes in an outer scope might not get swapped).
3673
3674          elsif Is_Incomplete_Or_Private_Type (E)
3675            and then not Is_Generic_Type (E)
3676          then
3677             --  The construction of the dispatch table associated with library
3678             --  level tagged types forces freezing of all the primitives of the
3679             --  type, which may cause premature freezing of the partial view.
3680             --  For example:
3681
3682             --     package Pkg is
3683             --        type T is tagged private;
3684             --        type DT is new T with private;
3685             --        procedure Prim (X : in out T; Y : in out DT'class);
3686             --     private
3687             --        type T is tagged null record;
3688             --        Obj : T;
3689             --        type DT is new T with null record;
3690             --     end;
3691
3692             --  In this case the type will be frozen later by the usual
3693             --  mechanism: an object declaration, an instantiation, or the
3694             --  end of a declarative part.
3695
3696             if Is_Library_Level_Tagged_Type (E)
3697               and then not Present (Full_View (E))
3698             then
3699                Set_Is_Frozen (E, False);
3700                return Result;
3701
3702             --  Case of full view present
3703
3704             elsif Present (Full_View (E)) then
3705
3706                --  If full view has already been frozen, then no further
3707                --  processing is required
3708
3709                if Is_Frozen (Full_View (E)) then
3710                   Set_Has_Delayed_Freeze (E, False);
3711                   Set_Freeze_Node (E, Empty);
3712                   Check_Debug_Info_Needed (E);
3713
3714                --  Otherwise freeze full view and patch the pointers so that
3715                --  the freeze node will elaborate both views in the back-end.
3716
3717                else
3718                   declare
3719                      Full : constant Entity_Id := Full_View (E);
3720
3721                   begin
3722                      if Is_Private_Type (Full)
3723                        and then Present (Underlying_Full_View (Full))
3724                      then
3725                         Freeze_And_Append
3726                           (Underlying_Full_View (Full), N, Result);
3727                      end if;
3728
3729                      Freeze_And_Append (Full, N, Result);
3730
3731                      if Has_Delayed_Freeze (E) then
3732                         F_Node := Freeze_Node (Full);
3733
3734                         if Present (F_Node) then
3735                            Set_Freeze_Node (E, F_Node);
3736                            Set_Entity (F_Node, E);
3737
3738                         else
3739                            --  {Incomplete,Private}_Subtypes with Full_Views
3740                            --  constrained by discriminants.
3741
3742                            Set_Has_Delayed_Freeze (E, False);
3743                            Set_Freeze_Node (E, Empty);
3744                         end if;
3745                      end if;
3746                   end;
3747
3748                   Check_Debug_Info_Needed (E);
3749                end if;
3750
3751                --  AI-117 requires that the convention of a partial view be the
3752                --  same as the convention of the full view. Note that this is a
3753                --  recognized breach of privacy, but it's essential for logical
3754                --  consistency of representation, and the lack of a rule in
3755                --  RM95 was an oversight.
3756
3757                Set_Convention (E, Convention (Full_View (E)));
3758
3759                Set_Size_Known_At_Compile_Time (E,
3760                  Size_Known_At_Compile_Time (Full_View (E)));
3761
3762                --  Size information is copied from the full view to the
3763                --  incomplete or private view for consistency.
3764
3765                --  We skip this is the full view is not a type. This is very
3766                --  strange of course, and can only happen as a result of
3767                --  certain illegalities, such as a premature attempt to derive
3768                --  from an incomplete type.
3769
3770                if Is_Type (Full_View (E)) then
3771                   Set_Size_Info (E, Full_View (E));
3772                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3773                end if;
3774
3775                return Result;
3776
3777             --  Case of no full view present. If entity is derived or subtype,
3778             --  it is safe to freeze, correctness depends on the frozen status
3779             --  of parent. Otherwise it is either premature usage, or a Taft
3780             --  amendment type, so diagnosis is at the point of use and the
3781             --  type might be frozen later.
3782
3783             elsif E /= Base_Type (E)
3784               or else Is_Derived_Type (E)
3785             then
3786                null;
3787
3788             else
3789                Set_Is_Frozen (E, False);
3790                return No_List;
3791             end if;
3792
3793          --  For access subprogram, freeze types of all formals, the return
3794          --  type was already frozen, since it is the Etype of the function.
3795          --  Formal types can be tagged Taft amendment types, but otherwise
3796          --  they cannot be incomplete.
3797
3798          elsif Ekind (E) = E_Subprogram_Type then
3799             Formal := First_Formal (E);
3800             while Present (Formal) loop
3801                if Ekind (Etype (Formal)) = E_Incomplete_Type
3802                  and then No (Full_View (Etype (Formal)))
3803                  and then not Is_Value_Type (Etype (Formal))
3804                then
3805                   if Is_Tagged_Type (Etype (Formal)) then
3806                      null;
3807
3808                   --  AI05-151: Incomplete types are allowed in access to
3809                   --  subprogram specifications.
3810
3811                   elsif Ada_Version < Ada_2012 then
3812                      Error_Msg_NE
3813                        ("invalid use of incomplete type&", E, Etype (Formal));
3814                   end if;
3815                end if;
3816
3817                Freeze_And_Append (Etype (Formal), N, Result);
3818                Next_Formal (Formal);
3819             end loop;
3820
3821             Freeze_Subprogram (E);
3822
3823          --  For access to a protected subprogram, freeze the equivalent type
3824          --  (however this is not set if we are not generating code or if this
3825          --  is an anonymous type used just for resolution).
3826
3827          elsif Is_Access_Protected_Subprogram_Type (E) then
3828             if Present (Equivalent_Type (E)) then
3829                Freeze_And_Append (Equivalent_Type (E), N, Result);
3830             end if;
3831          end if;
3832
3833          --  Generic types are never seen by the back-end, and are also not
3834          --  processed by the expander (since the expander is turned off for
3835          --  generic processing), so we never need freeze nodes for them.
3836
3837          if Is_Generic_Type (E) then
3838             return Result;
3839          end if;
3840
3841          --  Some special processing for non-generic types to complete
3842          --  representation details not known till the freeze point.
3843
3844          if Is_Fixed_Point_Type (E) then
3845             Freeze_Fixed_Point_Type (E);
3846
3847             --  Some error checks required for ordinary fixed-point type. Defer
3848             --  these till the freeze-point since we need the small and range
3849             --  values. We only do these checks for base types
3850
3851             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3852                if Small_Value (E) < Ureal_2_M_80 then
3853                   Error_Msg_Name_1 := Name_Small;
3854                   Error_Msg_N
3855                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3856
3857                elsif Small_Value (E) > Ureal_2_80 then
3858                   Error_Msg_Name_1 := Name_Small;
3859                   Error_Msg_N
3860                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3861                end if;
3862
3863                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3864                   Error_Msg_Name_1 := Name_First;
3865                   Error_Msg_N
3866                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3867                end if;
3868
3869                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3870                   Error_Msg_Name_1 := Name_Last;
3871                   Error_Msg_N
3872                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3873                end if;
3874             end if;
3875
3876          elsif Is_Enumeration_Type (E) then
3877             Freeze_Enumeration_Type (E);
3878
3879          elsif Is_Integer_Type (E) then
3880             Adjust_Esize_For_Alignment (E);
3881
3882             if Is_Modular_Integer_Type (E)
3883               and then Warn_On_Suspicious_Modulus_Value
3884             then
3885                Check_Suspicious_Modulus (E);
3886             end if;
3887
3888          elsif Is_Access_Type (E) then
3889
3890             --  If a pragma Default_Storage_Pool applies, and this type has no
3891             --  Storage_Pool or Storage_Size clause (which must have occurred
3892             --  before the freezing point), then use the default. This applies
3893             --  only to base types.
3894
3895             if Present (Default_Pool)
3896               and then Is_Base_Type (E)
3897               and then not Has_Storage_Size_Clause (E)
3898               and then No (Associated_Storage_Pool (E))
3899             then
3900                --  Case of pragma Default_Storage_Pool (null)
3901
3902                if Nkind (Default_Pool) = N_Null then
3903                   Set_No_Pool_Assigned (E);
3904
3905                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3906
3907                else
3908                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3909                end if;
3910             end if;
3911
3912             --  Check restriction for standard storage pool
3913
3914             if No (Associated_Storage_Pool (E)) then
3915                Check_Restriction (No_Standard_Storage_Pools, E);
3916             end if;
3917
3918             --  Deal with error message for pure access type. This is not an
3919             --  error in Ada 2005 if there is no pool (see AI-366).
3920
3921             if Is_Pure_Unit_Access_Type (E)
3922               and then (Ada_Version < Ada_2005
3923                           or else not No_Pool_Assigned (E))
3924             then
3925                Error_Msg_N ("named access type not allowed in pure unit", E);
3926
3927                if Ada_Version >= Ada_2005 then
3928                   Error_Msg_N
3929                     ("\would be legal if Storage_Size of 0 given?", E);
3930
3931                elsif No_Pool_Assigned (E) then
3932                   Error_Msg_N
3933                     ("\would be legal in Ada 2005?", E);
3934
3935                else
3936                   Error_Msg_N
3937                     ("\would be legal in Ada 2005 if "
3938                      & "Storage_Size of 0 given?", E);
3939                end if;
3940             end if;
3941          end if;
3942
3943          --  Case of composite types
3944
3945          if Is_Composite_Type (E) then
3946
3947             --  AI-117 requires that all new primitives of a tagged type must
3948             --  inherit the convention of the full view of the type. Inherited
3949             --  and overriding operations are defined to inherit the convention
3950             --  of their parent or overridden subprogram (also specified in
3951             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3952             --  and New_Overloaded_Entity). Here we set the convention of
3953             --  primitives that are still convention Ada, which will ensure
3954             --  that any new primitives inherit the type's convention. Class-
3955             --  wide types can have a foreign convention inherited from their
3956             --  specific type, but are excluded from this since they don't have
3957             --  any associated primitives.
3958
3959             if Is_Tagged_Type (E)
3960               and then not Is_Class_Wide_Type (E)
3961               and then Convention (E) /= Convention_Ada
3962             then
3963                declare
3964                   Prim_List : constant Elist_Id := Primitive_Operations (E);
3965                   Prim      : Elmt_Id;
3966
3967                begin
3968                   Prim := First_Elmt (Prim_List);
3969                   while Present (Prim) loop
3970                      if Convention (Node (Prim)) = Convention_Ada then
3971                         Set_Convention (Node (Prim), Convention (E));
3972                      end if;
3973
3974                      Next_Elmt (Prim);
3975                   end loop;
3976                end;
3977             end if;
3978          end if;
3979
3980          --  Now that all types from which E may depend are frozen, see if the
3981          --  size is known at compile time, if it must be unsigned, or if
3982          --  strict alignment is required
3983
3984          Check_Compile_Time_Size (E);
3985          Check_Unsigned_Type (E);
3986
3987          if Base_Type (E) = E then
3988             Check_Strict_Alignment (E);
3989          end if;
3990
3991          --  Do not allow a size clause for a type which does not have a size
3992          --  that is known at compile time
3993
3994          if Has_Size_Clause (E)
3995            and then not Size_Known_At_Compile_Time (E)
3996          then
3997             --  Suppress this message if errors posted on E, even if we are
3998             --  in all errors mode, since this is often a junk message
3999
4000             if not Error_Posted (E) then
4001                Error_Msg_N
4002                  ("size clause not allowed for variable length type",
4003                   Size_Clause (E));
4004             end if;
4005          end if;
4006
4007          --  Now we set/verify the representation information, in particular
4008          --  the size and alignment values. This processing is not required for
4009          --  generic types, since generic types do not play any part in code
4010          --  generation, and so the size and alignment values for such types
4011          --  are irrelevant.
4012
4013          if Is_Generic_Type (E) then
4014             return Result;
4015
4016          --  Otherwise we call the layout procedure
4017
4018          else
4019             Layout_Type (E);
4020          end if;
4021
4022          --  If the type has a Defaut_Value/Default_Component_Value aspect,
4023          --  this is where we analye the expression (after the type is frozen,
4024          --  since in the case of Default_Value, we are analyzing with the
4025          --  type itself, and we treat Default_Component_Value similarly for
4026          --  the sake of uniformity.
4027
4028          if Is_First_Subtype (E) and then Has_Default_Aspect (E) then
4029             declare
4030                Nam    : Name_Id;
4031                Aspect : Node_Id;
4032                Exp    : Node_Id;
4033                Typ    : Entity_Id;
4034
4035             begin
4036                if Is_Scalar_Type (E) then
4037                   Nam := Name_Default_Value;
4038                   Typ := E;
4039                else
4040                   Nam := Name_Default_Component_Value;
4041                   Typ := Component_Type (E);
4042                end if;
4043
4044                Aspect := Get_Rep_Item_For_Entity (E, Nam);
4045                Exp := Expression (Aspect);
4046                Analyze_And_Resolve (Exp, Typ);
4047
4048                if Etype (Exp) /= Any_Type then
4049                   if not Is_Static_Expression (Exp) then
4050                      Error_Msg_Name_1 := Nam;
4051                      Flag_Non_Static_Expr
4052                        ("aspect% requires static expression", Exp);
4053                   end if;
4054                end if;
4055             end;
4056          end if;
4057
4058          --  End of freeze processing for type entities
4059       end if;
4060
4061       --  Here is where we logically freeze the current entity. If it has a
4062       --  freeze node, then this is the point at which the freeze node is
4063       --  linked into the result list.
4064
4065       if Has_Delayed_Freeze (E) then
4066
4067          --  If a freeze node is already allocated, use it, otherwise allocate
4068          --  a new one. The preallocation happens in the case of anonymous base
4069          --  types, where we preallocate so that we can set First_Subtype_Link.
4070          --  Note that we reset the Sloc to the current freeze location.
4071
4072          if Present (Freeze_Node (E)) then
4073             F_Node := Freeze_Node (E);
4074             Set_Sloc (F_Node, Loc);
4075
4076          else
4077             F_Node := New_Node (N_Freeze_Entity, Loc);
4078             Set_Freeze_Node (E, F_Node);
4079             Set_Access_Types_To_Process (F_Node, No_Elist);
4080             Set_TSS_Elist (F_Node, No_Elist);
4081             Set_Actions (F_Node, No_List);
4082          end if;
4083
4084          Set_Entity (F_Node, E);
4085          Add_To_Result (F_Node);
4086
4087          --  A final pass over record types with discriminants. If the type
4088          --  has an incomplete declaration, there may be constrained access
4089          --  subtypes declared elsewhere, which do not depend on the discrimi-
4090          --  nants of the type, and which are used as component types (i.e.
4091          --  the full view is a recursive type). The designated types of these
4092          --  subtypes can only be elaborated after the type itself, and they
4093          --  need an itype reference.
4094
4095          if Ekind (E) = E_Record_Type
4096            and then Has_Discriminants (E)
4097          then
4098             declare
4099                Comp : Entity_Id;
4100                IR   : Node_Id;
4101                Typ  : Entity_Id;
4102
4103             begin
4104                Comp := First_Component (E);
4105                while Present (Comp) loop
4106                   Typ  := Etype (Comp);
4107
4108                   if Ekind (Comp) = E_Component
4109                     and then Is_Access_Type (Typ)
4110                     and then Scope (Typ) /= E
4111                     and then Base_Type (Designated_Type (Typ)) = E
4112                     and then Is_Itype (Designated_Type (Typ))
4113                   then
4114                      IR := Make_Itype_Reference (Sloc (Comp));
4115                      Set_Itype (IR, Designated_Type (Typ));
4116                      Append (IR, Result);
4117                   end if;
4118
4119                   Next_Component (Comp);
4120                end loop;
4121             end;
4122          end if;
4123       end if;
4124
4125       --  When a type is frozen, the first subtype of the type is frozen as
4126       --  well (RM 13.14(15)). This has to be done after freezing the type,
4127       --  since obviously the first subtype depends on its own base type.
4128
4129       if Is_Type (E) then
4130          Freeze_And_Append (First_Subtype (E), N, Result);
4131
4132          --  If we just froze a tagged non-class wide record, then freeze the
4133          --  corresponding class-wide type. This must be done after the tagged
4134          --  type itself is frozen, because the class-wide type refers to the
4135          --  tagged type which generates the class.
4136
4137          if Is_Tagged_Type (E)
4138            and then not Is_Class_Wide_Type (E)
4139            and then Present (Class_Wide_Type (E))
4140          then
4141             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4142          end if;
4143       end if;
4144
4145       Check_Debug_Info_Needed (E);
4146
4147       --  Special handling for subprograms
4148
4149       if Is_Subprogram (E) then
4150
4151          --  If subprogram has address clause then reset Is_Public flag, since
4152          --  we do not want the backend to generate external references.
4153
4154          if Present (Address_Clause (E))
4155            and then not Is_Library_Level_Entity (E)
4156          then
4157             Set_Is_Public (E, False);
4158
4159          --  If no address clause and not intrinsic, then for imported
4160          --  subprogram in main unit, generate descriptor if we are in
4161          --  Propagate_Exceptions mode.
4162
4163          --  This is very odd code, it makes a null result, why ???
4164
4165          elsif Propagate_Exceptions
4166            and then Is_Imported (E)
4167            and then not Is_Intrinsic_Subprogram (E)
4168            and then Convention (E) /= Convention_Stubbed
4169          then
4170             if Result = No_List then
4171                Result := Empty_List;
4172             end if;
4173          end if;
4174       end if;
4175
4176       return Result;
4177    end Freeze_Entity;
4178
4179    -----------------------------
4180    -- Freeze_Enumeration_Type --
4181    -----------------------------
4182
4183    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4184    begin
4185       --  By default, if no size clause is present, an enumeration type with
4186       --  Convention C is assumed to interface to a C enum, and has integer
4187       --  size. This applies to types. For subtypes, verify that its base
4188       --  type has no size clause either.
4189
4190       if Has_Foreign_Convention (Typ)
4191         and then not Has_Size_Clause (Typ)
4192         and then not Has_Size_Clause (Base_Type (Typ))
4193         and then Esize (Typ) < Standard_Integer_Size
4194       then
4195          Init_Esize (Typ, Standard_Integer_Size);
4196
4197       else
4198          --  If the enumeration type interfaces to C, and it has a size clause
4199          --  that specifies less than int size, it warrants a warning. The
4200          --  user may intend the C type to be an enum or a char, so this is
4201          --  not by itself an error that the Ada compiler can detect, but it
4202          --  it is a worth a heads-up. For Boolean and Character types we
4203          --  assume that the programmer has the proper C type in mind.
4204
4205          if Convention (Typ) = Convention_C
4206            and then Has_Size_Clause (Typ)
4207            and then Esize (Typ) /= Esize (Standard_Integer)
4208            and then not Is_Boolean_Type (Typ)
4209            and then not Is_Character_Type (Typ)
4210          then
4211             Error_Msg_N
4212               ("C enum types have the size of a C int?", Size_Clause (Typ));
4213          end if;
4214
4215          Adjust_Esize_For_Alignment (Typ);
4216       end if;
4217    end Freeze_Enumeration_Type;
4218
4219    -----------------------
4220    -- Freeze_Expression --
4221    -----------------------
4222
4223    procedure Freeze_Expression (N : Node_Id) is
4224       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4225       Typ         : Entity_Id;
4226       Nam         : Entity_Id;
4227       Desig_Typ   : Entity_Id;
4228       P           : Node_Id;
4229       Parent_P    : Node_Id;
4230
4231       Freeze_Outside : Boolean := False;
4232       --  This flag is set true if the entity must be frozen outside the
4233       --  current subprogram. This happens in the case of expander generated
4234       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4235       --  not freeze all entities like other bodies, but which nevertheless
4236       --  may reference entities that have to be frozen before the body and
4237       --  obviously cannot be frozen inside the body.
4238
4239       function In_Exp_Body (N : Node_Id) return Boolean;
4240       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4241       --  it is the handled statement sequence of an expander-generated
4242       --  subprogram (init proc, stream subprogram, or renaming as body).
4243       --  If so, this is not a freezing context.
4244
4245       -----------------
4246       -- In_Exp_Body --
4247       -----------------
4248
4249       function In_Exp_Body (N : Node_Id) return Boolean is
4250          P  : Node_Id;
4251          Id : Entity_Id;
4252
4253       begin
4254          if Nkind (N) = N_Subprogram_Body then
4255             P := N;
4256          else
4257             P := Parent (N);
4258          end if;
4259
4260          if Nkind (P) /= N_Subprogram_Body then
4261             return False;
4262
4263          else
4264             Id := Defining_Unit_Name (Specification (P));
4265
4266             if Nkind (Id) = N_Defining_Identifier
4267               and then (Is_Init_Proc (Id)              or else
4268                         Is_TSS (Id, TSS_Stream_Input)  or else
4269                         Is_TSS (Id, TSS_Stream_Output) or else
4270                         Is_TSS (Id, TSS_Stream_Read)   or else
4271                         Is_TSS (Id, TSS_Stream_Write)  or else
4272                         Nkind (Original_Node (P)) =
4273                           N_Subprogram_Renaming_Declaration)
4274             then
4275                return True;
4276             else
4277                return False;
4278             end if;
4279          end if;
4280       end In_Exp_Body;
4281
4282    --  Start of processing for Freeze_Expression
4283
4284    begin
4285       --  Immediate return if freezing is inhibited. This flag is set by the
4286       --  analyzer to stop freezing on generated expressions that would cause
4287       --  freezing if they were in the source program, but which are not
4288       --  supposed to freeze, since they are created.
4289
4290       if Must_Not_Freeze (N) then
4291          return;
4292       end if;
4293
4294       --  If expression is non-static, then it does not freeze in a default
4295       --  expression, see section "Handling of Default Expressions" in the
4296       --  spec of package Sem for further details. Note that we have to
4297       --  make sure that we actually have a real expression (if we have
4298       --  a subtype indication, we can't test Is_Static_Expression!)
4299
4300       if In_Spec_Exp
4301         and then Nkind (N) in N_Subexpr
4302         and then not Is_Static_Expression (N)
4303       then
4304          return;
4305       end if;
4306
4307       --  Freeze type of expression if not frozen already
4308
4309       Typ := Empty;
4310
4311       if Nkind (N) in N_Has_Etype then
4312          if not Is_Frozen (Etype (N)) then
4313             Typ := Etype (N);
4314
4315          --  Base type may be an derived numeric type that is frozen at
4316          --  the point of declaration, but first_subtype is still unfrozen.
4317
4318          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4319             Typ := First_Subtype (Etype (N));
4320          end if;
4321       end if;
4322
4323       --  For entity name, freeze entity if not frozen already. A special
4324       --  exception occurs for an identifier that did not come from source.
4325       --  We don't let such identifiers freeze a non-internal entity, i.e.
4326       --  an entity that did come from source, since such an identifier was
4327       --  generated by the expander, and cannot have any semantic effect on
4328       --  the freezing semantics. For example, this stops the parameter of
4329       --  an initialization procedure from freezing the variable.
4330
4331       if Is_Entity_Name (N)
4332         and then not Is_Frozen (Entity (N))
4333         and then (Nkind (N) /= N_Identifier
4334                    or else Comes_From_Source (N)
4335                    or else not Comes_From_Source (Entity (N)))
4336       then
4337          Nam := Entity (N);
4338       else
4339          Nam := Empty;
4340       end if;
4341
4342       --  For an allocator freeze designated type if not frozen already
4343
4344       --  For an aggregate whose component type is an access type, freeze the
4345       --  designated type now, so that its freeze does not appear within the
4346       --  loop that might be created in the expansion of the aggregate. If the
4347       --  designated type is a private type without full view, the expression
4348       --  cannot contain an allocator, so the type is not frozen.
4349
4350       --  For a function, we freeze the entity when the subprogram declaration
4351       --  is frozen, but a function call may appear in an initialization proc.
4352       --  before the declaration is frozen. We need to generate the extra
4353       --  formals, if any, to ensure that the expansion of the call includes
4354       --  the proper actuals. This only applies to Ada subprograms, not to
4355       --  imported ones.
4356
4357       Desig_Typ := Empty;
4358
4359       case Nkind (N) is
4360          when N_Allocator =>
4361             Desig_Typ := Designated_Type (Etype (N));
4362
4363          when N_Aggregate =>
4364             if Is_Array_Type (Etype (N))
4365               and then Is_Access_Type (Component_Type (Etype (N)))
4366             then
4367                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4368             end if;
4369
4370          when N_Selected_Component |
4371             N_Indexed_Component    |
4372             N_Slice                =>
4373
4374             if Is_Access_Type (Etype (Prefix (N))) then
4375                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4376             end if;
4377
4378          when N_Identifier =>
4379             if Present (Nam)
4380               and then Ekind (Nam) = E_Function
4381               and then Nkind (Parent (N)) = N_Function_Call
4382               and then Convention (Nam) = Convention_Ada
4383             then
4384                Create_Extra_Formals (Nam);
4385             end if;
4386
4387          when others =>
4388             null;
4389       end case;
4390
4391       if Desig_Typ /= Empty
4392         and then (Is_Frozen (Desig_Typ)
4393                    or else (not Is_Fully_Defined (Desig_Typ)))
4394       then
4395          Desig_Typ := Empty;
4396       end if;
4397
4398       --  All done if nothing needs freezing
4399
4400       if No (Typ)
4401         and then No (Nam)
4402         and then No (Desig_Typ)
4403       then
4404          return;
4405       end if;
4406
4407       --  Loop for looking at the right place to insert the freeze nodes,
4408       --  exiting from the loop when it is appropriate to insert the freeze
4409       --  node before the current node P.
4410
4411       --  Also checks some special exceptions to the freezing rules. These
4412       --  cases result in a direct return, bypassing the freeze action.
4413
4414       P := N;
4415       loop
4416          Parent_P := Parent (P);
4417
4418          --  If we don't have a parent, then we are not in a well-formed tree.
4419          --  This is an unusual case, but there are some legitimate situations
4420          --  in which this occurs, notably when the expressions in the range of
4421          --  a type declaration are resolved. We simply ignore the freeze
4422          --  request in this case. Is this right ???
4423
4424          if No (Parent_P) then
4425             return;
4426          end if;
4427
4428          --  See if we have got to an appropriate point in the tree
4429
4430          case Nkind (Parent_P) is
4431
4432             --  A special test for the exception of (RM 13.14(8)) for the case
4433             --  of per-object expressions (RM 3.8(18)) occurring in component
4434             --  definition or a discrete subtype definition. Note that we test
4435             --  for a component declaration which includes both cases we are
4436             --  interested in, and furthermore the tree does not have explicit
4437             --  nodes for either of these two constructs.
4438
4439             when N_Component_Declaration =>
4440
4441                --  The case we want to test for here is an identifier that is
4442                --  a per-object expression, this is either a discriminant that
4443                --  appears in a context other than the component declaration
4444                --  or it is a reference to the type of the enclosing construct.
4445
4446                --  For either of these cases, we skip the freezing
4447
4448                if not In_Spec_Expression
4449                  and then Nkind (N) = N_Identifier
4450                  and then (Present (Entity (N)))
4451                then
4452                   --  We recognize the discriminant case by just looking for
4453                   --  a reference to a discriminant. It can only be one for
4454                   --  the enclosing construct. Skip freezing in this case.
4455
4456                   if Ekind (Entity (N)) = E_Discriminant then
4457                      return;
4458
4459                   --  For the case of a reference to the enclosing record,
4460                   --  (or task or protected type), we look for a type that
4461                   --  matches the current scope.
4462
4463                   elsif Entity (N) = Current_Scope then
4464                      return;
4465                   end if;
4466                end if;
4467
4468             --  If we have an enumeration literal that appears as the choice in
4469             --  the aggregate of an enumeration representation clause, then
4470             --  freezing does not occur (RM 13.14(10)).
4471
4472             when N_Enumeration_Representation_Clause =>
4473
4474                --  The case we are looking for is an enumeration literal
4475
4476                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4477                  and then Is_Enumeration_Type (Etype (N))
4478                then
4479                   --  If enumeration literal appears directly as the choice,
4480                   --  do not freeze (this is the normal non-overloaded case)
4481
4482                   if Nkind (Parent (N)) = N_Component_Association
4483                     and then First (Choices (Parent (N))) = N
4484                   then
4485                      return;
4486
4487                   --  If enumeration literal appears as the name of function
4488                   --  which is the choice, then also do not freeze. This
4489                   --  happens in the overloaded literal case, where the
4490                   --  enumeration literal is temporarily changed to a function
4491                   --  call for overloading analysis purposes.
4492
4493                   elsif Nkind (Parent (N)) = N_Function_Call
4494                      and then
4495                        Nkind (Parent (Parent (N))) = N_Component_Association
4496                      and then
4497                        First (Choices (Parent (Parent (N)))) = Parent (N)
4498                   then
4499                      return;
4500                   end if;
4501                end if;
4502
4503             --  Normally if the parent is a handled sequence of statements,
4504             --  then the current node must be a statement, and that is an
4505             --  appropriate place to insert a freeze node.
4506
4507             when N_Handled_Sequence_Of_Statements =>
4508
4509                --  An exception occurs when the sequence of statements is for
4510                --  an expander generated body that did not do the usual freeze
4511                --  all operation. In this case we usually want to freeze
4512                --  outside this body, not inside it, and we skip past the
4513                --  subprogram body that we are inside.
4514
4515                if In_Exp_Body (Parent_P) then
4516
4517                   --  However, we *do* want to freeze at this point if we have
4518                   --  an entity to freeze, and that entity is declared *inside*
4519                   --  the body of the expander generated procedure. This case
4520                   --  is recognized by the scope of the type, which is either
4521                   --  the spec for some enclosing body, or (in the case of
4522                   --  init_procs, for which there are no separate specs) the
4523                   --  current scope.
4524
4525                   declare
4526                      Subp : constant Node_Id := Parent (Parent_P);
4527                      Cspc : Entity_Id;
4528
4529                   begin
4530                      if Nkind (Subp) = N_Subprogram_Body then
4531                         Cspc := Corresponding_Spec (Subp);
4532
4533                         if (Present (Typ) and then Scope (Typ) = Cspc)
4534                              or else
4535                            (Present (Nam) and then Scope (Nam) = Cspc)
4536                         then
4537                            exit;
4538
4539                         elsif Present (Typ)
4540                           and then Scope (Typ) = Current_Scope
4541                           and then Current_Scope = Defining_Entity (Subp)
4542                         then
4543                            exit;
4544                         end if;
4545                      end if;
4546                   end;
4547
4548                   --  If not that exception to the exception, then this is
4549                   --  where we delay the freeze till outside the body.
4550
4551                   Parent_P := Parent (Parent_P);
4552                   Freeze_Outside := True;
4553
4554                --  Here if normal case where we are in handled statement
4555                --  sequence and want to do the insertion right there.
4556
4557                else
4558                   exit;
4559                end if;
4560
4561             --  If parent is a body or a spec or a block, then the current node
4562             --  is a statement or declaration and we can insert the freeze node
4563             --  before it.
4564
4565             when N_Block_Statement       |
4566                  N_Entry_Body            |
4567                  N_Package_Body          |
4568                  N_Package_Specification |
4569                  N_Protected_Body        |
4570                  N_Subprogram_Body       |
4571                  N_Task_Body             => exit;
4572
4573             --  The expander is allowed to define types in any statements list,
4574             --  so any of the following parent nodes also mark a freezing point
4575             --  if the actual node is in a list of statements or declarations.
4576
4577             when N_Abortable_Part             |
4578                  N_Accept_Alternative         |
4579                  N_And_Then                   |
4580                  N_Case_Statement_Alternative |
4581                  N_Compilation_Unit_Aux       |
4582                  N_Conditional_Entry_Call     |
4583                  N_Delay_Alternative          |
4584                  N_Elsif_Part                 |
4585                  N_Entry_Call_Alternative     |
4586                  N_Exception_Handler          |
4587                  N_Extended_Return_Statement  |
4588                  N_Freeze_Entity              |
4589                  N_If_Statement               |
4590                  N_Or_Else                    |
4591                  N_Selective_Accept           |
4592                  N_Triggering_Alternative     =>
4593
4594                exit when Is_List_Member (P);
4595
4596             --  Note: The N_Loop_Statement is a special case. A type that
4597             --  appears in the source can never be frozen in a loop (this
4598             --  occurs only because of a loop expanded by the expander), so we
4599             --  keep on going. Otherwise we terminate the search. Same is true
4600             --  of any entity which comes from source. (if they have predefined
4601             --  type, that type does not appear to come from source, but the
4602             --  entity should not be frozen here).
4603
4604             when N_Loop_Statement =>
4605                exit when not Comes_From_Source (Etype (N))
4606                  and then (No (Nam) or else not Comes_From_Source (Nam));
4607
4608             --  For all other cases, keep looking at parents
4609
4610             when others =>
4611                null;
4612          end case;
4613
4614          --  We fall through the case if we did not yet find the proper
4615          --  place in the free for inserting the freeze node, so climb!
4616
4617          P := Parent_P;
4618       end loop;
4619
4620       --  If the expression appears in a record or an initialization procedure,
4621       --  the freeze nodes are collected and attached to the current scope, to
4622       --  be inserted and analyzed on exit from the scope, to insure that
4623       --  generated entities appear in the correct scope. If the expression is
4624       --  a default for a discriminant specification, the scope is still void.
4625       --  The expression can also appear in the discriminant part of a private
4626       --  or concurrent type.
4627
4628       --  If the expression appears in a constrained subcomponent of an
4629       --  enclosing record declaration, the freeze nodes must be attached to
4630       --  the outer record type so they can eventually be placed in the
4631       --  enclosing declaration list.
4632
4633       --  The other case requiring this special handling is if we are in a
4634       --  default expression, since in that case we are about to freeze a
4635       --  static type, and the freeze scope needs to be the outer scope, not
4636       --  the scope of the subprogram with the default parameter.
4637
4638       --  For default expressions and other spec expressions in generic units,
4639       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4640       --  placing them at the proper place, after the generic unit.
4641
4642       if (In_Spec_Exp and not Inside_A_Generic)
4643         or else Freeze_Outside
4644         or else (Is_Type (Current_Scope)
4645                   and then (not Is_Concurrent_Type (Current_Scope)
4646                              or else not Has_Completion (Current_Scope)))
4647         or else Ekind (Current_Scope) = E_Void
4648       then
4649          declare
4650             N            : constant Node_Id    := Current_Scope;
4651             Freeze_Nodes : List_Id             := No_List;
4652             Pos          : Int                 := Scope_Stack.Last;
4653
4654          begin
4655             if Present (Desig_Typ) then
4656                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4657             end if;
4658
4659             if Present (Typ) then
4660                Freeze_And_Append (Typ, N, Freeze_Nodes);
4661             end if;
4662
4663             if Present (Nam) then
4664                Freeze_And_Append (Nam, N, Freeze_Nodes);
4665             end if;
4666
4667             --  The current scope may be that of a constrained component of
4668             --  an enclosing record declaration, which is above the current
4669             --  scope in the scope stack.
4670             --  If the expression is within a top-level pragma, as for a pre-
4671             --  condition on a library-level subprogram, nothing to do.
4672
4673             if not Is_Compilation_Unit (Current_Scope)
4674               and then Is_Record_Type (Scope (Current_Scope))
4675             then
4676                Pos := Pos - 1;
4677             end if;
4678
4679             if Is_Non_Empty_List (Freeze_Nodes) then
4680                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4681                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4682                     Freeze_Nodes;
4683                else
4684                   Append_List (Freeze_Nodes,
4685                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4686                end if;
4687             end if;
4688          end;
4689
4690          return;
4691       end if;
4692
4693       --  Now we have the right place to do the freezing. First, a special
4694       --  adjustment, if we are in spec-expression analysis mode, these freeze
4695       --  actions must not be thrown away (normally all inserted actions are
4696       --  thrown away in this mode. However, the freeze actions are from static
4697       --  expressions and one of the important reasons we are doing this
4698       --  special analysis is to get these freeze actions. Therefore we turn
4699       --  off the In_Spec_Expression mode to propagate these freeze actions.
4700       --  This also means they get properly analyzed and expanded.
4701
4702       In_Spec_Expression := False;
4703
4704       --  Freeze the designated type of an allocator (RM 13.14(13))
4705
4706       if Present (Desig_Typ) then
4707          Freeze_Before (P, Desig_Typ);
4708       end if;
4709
4710       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4711       --  the enumeration representation clause exception in the loop above.
4712
4713       if Present (Typ) then
4714          Freeze_Before (P, Typ);
4715       end if;
4716
4717       --  Freeze name if one is present (RM 13.14(11))
4718
4719       if Present (Nam) then
4720          Freeze_Before (P, Nam);
4721       end if;
4722
4723       --  Restore In_Spec_Expression flag
4724
4725       In_Spec_Expression := In_Spec_Exp;
4726    end Freeze_Expression;
4727
4728    -----------------------------
4729    -- Freeze_Fixed_Point_Type --
4730    -----------------------------
4731
4732    --  Certain fixed-point types and subtypes, including implicit base types
4733    --  and declared first subtypes, have not yet set up a range. This is
4734    --  because the range cannot be set until the Small and Size values are
4735    --  known, and these are not known till the type is frozen.
4736
4737    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4738    --  whose bounds are unanalyzed real literals. This routine will recognize
4739    --  this case, and transform this range node into a properly typed range
4740    --  with properly analyzed and resolved values.
4741
4742    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4743       Rng   : constant Node_Id    := Scalar_Range (Typ);
4744       Lo    : constant Node_Id    := Low_Bound (Rng);
4745       Hi    : constant Node_Id    := High_Bound (Rng);
4746       Btyp  : constant Entity_Id  := Base_Type (Typ);
4747       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4748       BLo   : constant Node_Id    := Low_Bound (Brng);
4749       BHi   : constant Node_Id    := High_Bound (Brng);
4750       Small : constant Ureal      := Small_Value (Typ);
4751       Loval : Ureal;
4752       Hival : Ureal;
4753       Atype : Entity_Id;
4754
4755       Actual_Size : Nat;
4756
4757       function Fsize (Lov, Hiv : Ureal) return Nat;
4758       --  Returns size of type with given bounds. Also leaves these
4759       --  bounds set as the current bounds of the Typ.
4760
4761       -----------
4762       -- Fsize --
4763       -----------
4764
4765       function Fsize (Lov, Hiv : Ureal) return Nat is
4766       begin
4767          Set_Realval (Lo, Lov);
4768          Set_Realval (Hi, Hiv);
4769          return Minimum_Size (Typ);
4770       end Fsize;
4771
4772    --  Start of processing for Freeze_Fixed_Point_Type
4773
4774    begin
4775       --  If Esize of a subtype has not previously been set, set it now
4776
4777       if Unknown_Esize (Typ) then
4778          Atype := Ancestor_Subtype (Typ);
4779
4780          if Present (Atype) then
4781             Set_Esize (Typ, Esize (Atype));
4782          else
4783             Set_Esize (Typ, Esize (Base_Type (Typ)));
4784          end if;
4785       end if;
4786
4787       --  Immediate return if the range is already analyzed. This means that
4788       --  the range is already set, and does not need to be computed by this
4789       --  routine.
4790
4791       if Analyzed (Rng) then
4792          return;
4793       end if;
4794
4795       --  Immediate return if either of the bounds raises Constraint_Error
4796
4797       if Raises_Constraint_Error (Lo)
4798         or else Raises_Constraint_Error (Hi)
4799       then
4800          return;
4801       end if;
4802
4803       Loval := Realval (Lo);
4804       Hival := Realval (Hi);
4805
4806       --  Ordinary fixed-point case
4807
4808       if Is_Ordinary_Fixed_Point_Type (Typ) then
4809
4810          --  For the ordinary fixed-point case, we are allowed to fudge the
4811          --  end-points up or down by small. Generally we prefer to fudge up,
4812          --  i.e. widen the bounds for non-model numbers so that the end points
4813          --  are included. However there are cases in which this cannot be
4814          --  done, and indeed cases in which we may need to narrow the bounds.
4815          --  The following circuit makes the decision.
4816
4817          --  Note: our terminology here is that Incl_EP means that the bounds
4818          --  are widened by Small if necessary to include the end points, and
4819          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4820          --  end-points if this reduces the size.
4821
4822          --  Note that in the Incl case, all we care about is including the
4823          --  end-points. In the Excl case, we want to narrow the bounds as
4824          --  much as permitted by the RM, to give the smallest possible size.
4825
4826          Fudge : declare
4827             Loval_Incl_EP : Ureal;
4828             Hival_Incl_EP : Ureal;
4829
4830             Loval_Excl_EP : Ureal;
4831             Hival_Excl_EP : Ureal;
4832
4833             Size_Incl_EP  : Nat;
4834             Size_Excl_EP  : Nat;
4835
4836             Model_Num     : Ureal;
4837             First_Subt    : Entity_Id;
4838             Actual_Lo     : Ureal;
4839             Actual_Hi     : Ureal;
4840
4841          begin
4842             --  First step. Base types are required to be symmetrical. Right
4843             --  now, the base type range is a copy of the first subtype range.
4844             --  This will be corrected before we are done, but right away we
4845             --  need to deal with the case where both bounds are non-negative.
4846             --  In this case, we set the low bound to the negative of the high
4847             --  bound, to make sure that the size is computed to include the
4848             --  required sign. Note that we do not need to worry about the
4849             --  case of both bounds negative, because the sign will be dealt
4850             --  with anyway. Furthermore we can't just go making such a bound
4851             --  symmetrical, since in a twos-complement system, there is an
4852             --  extra negative value which could not be accommodated on the
4853             --  positive side.
4854
4855             if Typ = Btyp
4856               and then not UR_Is_Negative (Loval)
4857               and then Hival > Loval
4858             then
4859                Loval := -Hival;
4860                Set_Realval (Lo, Loval);
4861             end if;
4862
4863             --  Compute the fudged bounds. If the number is a model number,
4864             --  then we do nothing to include it, but we are allowed to backoff
4865             --  to the next adjacent model number when we exclude it. If it is
4866             --  not a model number then we straddle the two values with the
4867             --  model numbers on either side.
4868
4869             Model_Num := UR_Trunc (Loval / Small) * Small;
4870
4871             if Loval = Model_Num then
4872                Loval_Incl_EP := Model_Num;
4873             else
4874                Loval_Incl_EP := Model_Num - Small;
4875             end if;
4876
4877             --  The low value excluding the end point is Small greater, but
4878             --  we do not do this exclusion if the low value is positive,
4879             --  since it can't help the size and could actually hurt by
4880             --  crossing the high bound.
4881
4882             if UR_Is_Negative (Loval_Incl_EP) then
4883                Loval_Excl_EP := Loval_Incl_EP + Small;
4884
4885                --  If the value went from negative to zero, then we have the
4886                --  case where Loval_Incl_EP is the model number just below
4887                --  zero, so we want to stick to the negative value for the
4888                --  base type to maintain the condition that the size will
4889                --  include signed values.
4890
4891                if Typ = Btyp
4892                  and then UR_Is_Zero (Loval_Excl_EP)
4893                then
4894                   Loval_Excl_EP := Loval_Incl_EP;
4895                end if;
4896
4897             else
4898                Loval_Excl_EP := Loval_Incl_EP;
4899             end if;
4900
4901             --  Similar processing for upper bound and high value
4902
4903             Model_Num := UR_Trunc (Hival / Small) * Small;
4904
4905             if Hival = Model_Num then
4906                Hival_Incl_EP := Model_Num;
4907             else
4908                Hival_Incl_EP := Model_Num + Small;
4909             end if;
4910
4911             if UR_Is_Positive (Hival_Incl_EP) then
4912                Hival_Excl_EP := Hival_Incl_EP - Small;
4913             else
4914                Hival_Excl_EP := Hival_Incl_EP;
4915             end if;
4916
4917             --  One further adjustment is needed. In the case of subtypes, we
4918             --  cannot go outside the range of the base type, or we get
4919             --  peculiarities, and the base type range is already set. This
4920             --  only applies to the Incl values, since clearly the Excl values
4921             --  are already as restricted as they are allowed to be.
4922
4923             if Typ /= Btyp then
4924                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4925                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4926             end if;
4927
4928             --  Get size including and excluding end points
4929
4930             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4931             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4932
4933             --  No need to exclude end-points if it does not reduce size
4934
4935             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4936                Loval_Excl_EP := Loval_Incl_EP;
4937             end if;
4938
4939             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4940                Hival_Excl_EP := Hival_Incl_EP;
4941             end if;
4942
4943             --  Now we set the actual size to be used. We want to use the
4944             --  bounds fudged up to include the end-points but only if this
4945             --  can be done without violating a specifically given size
4946             --  size clause or causing an unacceptable increase in size.
4947
4948             --  Case of size clause given
4949
4950             if Has_Size_Clause (Typ) then
4951
4952                --  Use the inclusive size only if it is consistent with
4953                --  the explicitly specified size.
4954
4955                if Size_Incl_EP <= RM_Size (Typ) then
4956                   Actual_Lo   := Loval_Incl_EP;
4957                   Actual_Hi   := Hival_Incl_EP;
4958                   Actual_Size := Size_Incl_EP;
4959
4960                --  If the inclusive size is too large, we try excluding
4961                --  the end-points (will be caught later if does not work).
4962
4963                else
4964                   Actual_Lo   := Loval_Excl_EP;
4965                   Actual_Hi   := Hival_Excl_EP;
4966                   Actual_Size := Size_Excl_EP;
4967                end if;
4968
4969             --  Case of size clause not given
4970
4971             else
4972                --  If we have a base type whose corresponding first subtype
4973                --  has an explicit size that is large enough to include our
4974                --  end-points, then do so. There is no point in working hard
4975                --  to get a base type whose size is smaller than the specified
4976                --  size of the first subtype.
4977
4978                First_Subt := First_Subtype (Typ);
4979
4980                if Has_Size_Clause (First_Subt)
4981                  and then Size_Incl_EP <= Esize (First_Subt)
4982                then
4983                   Actual_Size := Size_Incl_EP;
4984                   Actual_Lo   := Loval_Incl_EP;
4985                   Actual_Hi   := Hival_Incl_EP;
4986
4987                --  If excluding the end-points makes the size smaller and
4988                --  results in a size of 8,16,32,64, then we take the smaller
4989                --  size. For the 64 case, this is compulsory. For the other
4990                --  cases, it seems reasonable. We like to include end points
4991                --  if we can, but not at the expense of moving to the next
4992                --  natural boundary of size.
4993
4994                elsif Size_Incl_EP /= Size_Excl_EP
4995                  and then Addressable (Size_Excl_EP)
4996                then
4997                   Actual_Size := Size_Excl_EP;
4998                   Actual_Lo   := Loval_Excl_EP;
4999                   Actual_Hi   := Hival_Excl_EP;
5000
5001                --  Otherwise we can definitely include the end points
5002
5003                else
5004                   Actual_Size := Size_Incl_EP;
5005                   Actual_Lo   := Loval_Incl_EP;
5006                   Actual_Hi   := Hival_Incl_EP;
5007                end if;
5008
5009                --  One pathological case: normally we never fudge a low bound
5010                --  down, since it would seem to increase the size (if it has
5011                --  any effect), but for ranges containing single value, or no
5012                --  values, the high bound can be small too large. Consider:
5013
5014                --    type t is delta 2.0**(-14)
5015                --      range 131072.0 .. 0;
5016
5017                --  That lower bound is *just* outside the range of 32 bits, and
5018                --  does need fudging down in this case. Note that the bounds
5019                --  will always have crossed here, since the high bound will be
5020                --  fudged down if necessary, as in the case of:
5021
5022                --    type t is delta 2.0**(-14)
5023                --      range 131072.0 .. 131072.0;
5024
5025                --  So we detect the situation by looking for crossed bounds,
5026                --  and if the bounds are crossed, and the low bound is greater
5027                --  than zero, we will always back it off by small, since this
5028                --  is completely harmless.
5029
5030                if Actual_Lo > Actual_Hi then
5031                   if UR_Is_Positive (Actual_Lo) then
5032                      Actual_Lo   := Loval_Incl_EP - Small;
5033                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5034
5035                   --  And of course, we need to do exactly the same parallel
5036                   --  fudge for flat ranges in the negative region.
5037
5038                   elsif UR_Is_Negative (Actual_Hi) then
5039                      Actual_Hi := Hival_Incl_EP + Small;
5040                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5041                   end if;
5042                end if;
5043             end if;
5044
5045             Set_Realval (Lo, Actual_Lo);
5046             Set_Realval (Hi, Actual_Hi);
5047          end Fudge;
5048
5049       --  For the decimal case, none of this fudging is required, since there
5050       --  are no end-point problems in the decimal case (the end-points are
5051       --  always included).
5052
5053       else
5054          Actual_Size := Fsize (Loval, Hival);
5055       end if;
5056
5057       --  At this stage, the actual size has been calculated and the proper
5058       --  required bounds are stored in the low and high bounds.
5059
5060       if Actual_Size > 64 then
5061          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5062          Error_Msg_N
5063            ("size required (^) for type& too large, maximum allowed is 64",
5064             Typ);
5065          Actual_Size := 64;
5066       end if;
5067
5068       --  Check size against explicit given size
5069
5070       if Has_Size_Clause (Typ) then
5071          if Actual_Size > RM_Size (Typ) then
5072             Error_Msg_Uint_1 := RM_Size (Typ);
5073             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5074             Error_Msg_NE
5075               ("size given (^) for type& too small, minimum allowed is ^",
5076                Size_Clause (Typ), Typ);
5077
5078          else
5079             Actual_Size := UI_To_Int (Esize (Typ));
5080          end if;
5081
5082       --  Increase size to next natural boundary if no size clause given
5083
5084       else
5085          if Actual_Size <= 8 then
5086             Actual_Size := 8;
5087          elsif Actual_Size <= 16 then
5088             Actual_Size := 16;
5089          elsif Actual_Size <= 32 then
5090             Actual_Size := 32;
5091          else
5092             Actual_Size := 64;
5093          end if;
5094
5095          Init_Esize (Typ, Actual_Size);
5096          Adjust_Esize_For_Alignment (Typ);
5097       end if;
5098
5099       --  If we have a base type, then expand the bounds so that they extend to
5100       --  the full width of the allocated size in bits, to avoid junk range
5101       --  checks on intermediate computations.
5102
5103       if Base_Type (Typ) = Typ then
5104          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5105          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5106       end if;
5107
5108       --  Final step is to reanalyze the bounds using the proper type
5109       --  and set the Corresponding_Integer_Value fields of the literals.
5110
5111       Set_Etype (Lo, Empty);
5112       Set_Analyzed (Lo, False);
5113       Analyze (Lo);
5114
5115       --  Resolve with universal fixed if the base type, and the base type if
5116       --  it is a subtype. Note we can't resolve the base type with itself,
5117       --  that would be a reference before definition.
5118
5119       if Typ = Btyp then
5120          Resolve (Lo, Universal_Fixed);
5121       else
5122          Resolve (Lo, Btyp);
5123       end if;
5124
5125       --  Set corresponding integer value for bound
5126
5127       Set_Corresponding_Integer_Value
5128         (Lo, UR_To_Uint (Realval (Lo) / Small));
5129
5130       --  Similar processing for high bound
5131
5132       Set_Etype (Hi, Empty);
5133       Set_Analyzed (Hi, False);
5134       Analyze (Hi);
5135
5136       if Typ = Btyp then
5137          Resolve (Hi, Universal_Fixed);
5138       else
5139          Resolve (Hi, Btyp);
5140       end if;
5141
5142       Set_Corresponding_Integer_Value
5143         (Hi, UR_To_Uint (Realval (Hi) / Small));
5144
5145       --  Set type of range to correspond to bounds
5146
5147       Set_Etype (Rng, Etype (Lo));
5148
5149       --  Set Esize to calculated size if not set already
5150
5151       if Unknown_Esize (Typ) then
5152          Init_Esize (Typ, Actual_Size);
5153       end if;
5154
5155       --  Set RM_Size if not already set. If already set, check value
5156
5157       declare
5158          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5159
5160       begin
5161          if RM_Size (Typ) /= Uint_0 then
5162             if RM_Size (Typ) < Minsiz then
5163                Error_Msg_Uint_1 := RM_Size (Typ);
5164                Error_Msg_Uint_2 := Minsiz;
5165                Error_Msg_NE
5166                  ("size given (^) for type& too small, minimum allowed is ^",
5167                   Size_Clause (Typ), Typ);
5168             end if;
5169
5170          else
5171             Set_RM_Size (Typ, Minsiz);
5172          end if;
5173       end;
5174    end Freeze_Fixed_Point_Type;
5175
5176    ------------------
5177    -- Freeze_Itype --
5178    ------------------
5179
5180    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5181       L : List_Id;
5182
5183    begin
5184       Set_Has_Delayed_Freeze (T);
5185       L := Freeze_Entity (T, N);
5186
5187       if Is_Non_Empty_List (L) then
5188          Insert_Actions (N, L);
5189       end if;
5190    end Freeze_Itype;
5191
5192    --------------------------
5193    -- Freeze_Static_Object --
5194    --------------------------
5195
5196    procedure Freeze_Static_Object (E : Entity_Id) is
5197
5198       Cannot_Be_Static : exception;
5199       --  Exception raised if the type of a static object cannot be made
5200       --  static. This happens if the type depends on non-global objects.
5201
5202       procedure Ensure_Expression_Is_SA (N : Node_Id);
5203       --  Called to ensure that an expression used as part of a type definition
5204       --  is statically allocatable, which means that the expression type is
5205       --  statically allocatable, and the expression is either static, or a
5206       --  reference to a library level constant.
5207
5208       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5209       --  Called to mark a type as static, checking that it is possible
5210       --  to set the type as static. If it is not possible, then the
5211       --  exception Cannot_Be_Static is raised.
5212
5213       -----------------------------
5214       -- Ensure_Expression_Is_SA --
5215       -----------------------------
5216
5217       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5218          Ent : Entity_Id;
5219
5220       begin
5221          Ensure_Type_Is_SA (Etype (N));
5222
5223          if Is_Static_Expression (N) then
5224             return;
5225
5226          elsif Nkind (N) = N_Identifier then
5227             Ent := Entity (N);
5228
5229             if Present (Ent)
5230               and then Ekind (Ent) = E_Constant
5231               and then Is_Library_Level_Entity (Ent)
5232             then
5233                return;
5234             end if;
5235          end if;
5236
5237          raise Cannot_Be_Static;
5238       end Ensure_Expression_Is_SA;
5239
5240       -----------------------
5241       -- Ensure_Type_Is_SA --
5242       -----------------------
5243
5244       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5245          N : Node_Id;
5246          C : Entity_Id;
5247
5248       begin
5249          --  If type is library level, we are all set
5250
5251          if Is_Library_Level_Entity (Typ) then
5252             return;
5253          end if;
5254
5255          --  We are also OK if the type already marked as statically allocated,
5256          --  which means we processed it before.
5257
5258          if Is_Statically_Allocated (Typ) then
5259             return;
5260          end if;
5261
5262          --  Mark type as statically allocated
5263
5264          Set_Is_Statically_Allocated (Typ);
5265
5266          --  Check that it is safe to statically allocate this type
5267
5268          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5269             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5270             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5271
5272          elsif Is_Array_Type (Typ) then
5273             N := First_Index (Typ);
5274             while Present (N) loop
5275                Ensure_Type_Is_SA (Etype (N));
5276                Next_Index (N);
5277             end loop;
5278
5279             Ensure_Type_Is_SA (Component_Type (Typ));
5280
5281          elsif Is_Access_Type (Typ) then
5282             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5283
5284                declare
5285                   F : Entity_Id;
5286                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5287
5288                begin
5289                   if T /= Standard_Void_Type then
5290                      Ensure_Type_Is_SA (T);
5291                   end if;
5292
5293                   F := First_Formal (Designated_Type (Typ));
5294                   while Present (F) loop
5295                      Ensure_Type_Is_SA (Etype (F));
5296                      Next_Formal (F);
5297                   end loop;
5298                end;
5299
5300             else
5301                Ensure_Type_Is_SA (Designated_Type (Typ));
5302             end if;
5303
5304          elsif Is_Record_Type (Typ) then
5305             C := First_Entity (Typ);
5306             while Present (C) loop
5307                if Ekind (C) = E_Discriminant
5308                  or else Ekind (C) = E_Component
5309                then
5310                   Ensure_Type_Is_SA (Etype (C));
5311
5312                elsif Is_Type (C) then
5313                   Ensure_Type_Is_SA (C);
5314                end if;
5315
5316                Next_Entity (C);
5317             end loop;
5318
5319          elsif Ekind (Typ) = E_Subprogram_Type then
5320             Ensure_Type_Is_SA (Etype (Typ));
5321
5322             C := First_Formal (Typ);
5323             while Present (C) loop
5324                Ensure_Type_Is_SA (Etype (C));
5325                Next_Formal (C);
5326             end loop;
5327
5328          else
5329             raise Cannot_Be_Static;
5330          end if;
5331       end Ensure_Type_Is_SA;
5332
5333    --  Start of processing for Freeze_Static_Object
5334
5335    begin
5336       Ensure_Type_Is_SA (Etype (E));
5337
5338    exception
5339       when Cannot_Be_Static =>
5340
5341          --  If the object that cannot be static is imported or exported, then
5342          --  issue an error message saying that this object cannot be imported
5343          --  or exported. If it has an address clause it is an overlay in the
5344          --  current partition and the static requirement is not relevant.
5345          --  Do not issue any error message when ignoring rep clauses.
5346
5347          if Ignore_Rep_Clauses then
5348             null;
5349
5350          elsif Is_Imported (E) then
5351             if No (Address_Clause (E)) then
5352                Error_Msg_N
5353                  ("& cannot be imported (local type is not constant)", E);
5354             end if;
5355
5356          --  Otherwise must be exported, something is wrong if compiler
5357          --  is marking something as statically allocated which cannot be).
5358
5359          else pragma Assert (Is_Exported (E));
5360             Error_Msg_N
5361               ("& cannot be exported (local type is not constant)", E);
5362          end if;
5363    end Freeze_Static_Object;
5364
5365    -----------------------
5366    -- Freeze_Subprogram --
5367    -----------------------
5368
5369    procedure Freeze_Subprogram (E : Entity_Id) is
5370       Retype : Entity_Id;
5371       F      : Entity_Id;
5372
5373    begin
5374       --  Subprogram may not have an address clause unless it is imported
5375
5376       if Present (Address_Clause (E)) then
5377          if not Is_Imported (E) then
5378             Error_Msg_N
5379               ("address clause can only be given " &
5380                "for imported subprogram",
5381                Name (Address_Clause (E)));
5382          end if;
5383       end if;
5384
5385       --  Reset the Pure indication on an imported subprogram unless an
5386       --  explicit Pure_Function pragma was present. We do this because
5387       --  otherwise it is an insidious error to call a non-pure function from
5388       --  pure unit and have calls mysteriously optimized away. What happens
5389       --  here is that the Import can bypass the normal check to ensure that
5390       --  pure units call only pure subprograms.
5391
5392       if Is_Imported (E)
5393         and then Is_Pure (E)
5394         and then not Has_Pragma_Pure_Function (E)
5395       then
5396          Set_Is_Pure (E, False);
5397       end if;
5398
5399       --  For non-foreign convention subprograms, this is where we create
5400       --  the extra formals (for accessibility level and constrained bit
5401       --  information). We delay this till the freeze point precisely so
5402       --  that we know the convention!
5403
5404       if not Has_Foreign_Convention (E) then
5405          Create_Extra_Formals (E);
5406          Set_Mechanisms (E);
5407
5408          --  If this is convention Ada and a Valued_Procedure, that's odd
5409
5410          if Ekind (E) = E_Procedure
5411            and then Is_Valued_Procedure (E)
5412            and then Convention (E) = Convention_Ada
5413            and then Warn_On_Export_Import
5414          then
5415             Error_Msg_N
5416               ("?Valued_Procedure has no effect for convention Ada", E);
5417             Set_Is_Valued_Procedure (E, False);
5418          end if;
5419
5420       --  Case of foreign convention
5421
5422       else
5423          Set_Mechanisms (E);
5424
5425          --  For foreign conventions, warn about return of an
5426          --  unconstrained array.
5427
5428          --  Note: we *do* allow a return by descriptor for the VMS case,
5429          --  though here there is probably more to be done ???
5430
5431          if Ekind (E) = E_Function then
5432             Retype := Underlying_Type (Etype (E));
5433
5434             --  If no return type, probably some other error, e.g. a
5435             --  missing full declaration, so ignore.
5436
5437             if No (Retype) then
5438                null;
5439
5440             --  If the return type is generic, we have emitted a warning
5441             --  earlier on, and there is nothing else to check here. Specific
5442             --  instantiations may lead to erroneous behavior.
5443
5444             elsif Is_Generic_Type (Etype (E)) then
5445                null;
5446
5447             --  Display warning if returning unconstrained array
5448
5449             elsif Is_Array_Type (Retype)
5450               and then not Is_Constrained (Retype)
5451
5452                --  Exclude cases where descriptor mechanism is set, since the
5453                --  VMS descriptor mechanisms allow such unconstrained returns.
5454
5455               and then Mechanism (E) not in Descriptor_Codes
5456
5457                --  Check appropriate warning is enabled (should we check for
5458                --  Warnings (Off) on specific entities here, probably so???)
5459
5460               and then Warn_On_Export_Import
5461
5462                --  Exclude the VM case, since return of unconstrained arrays
5463                --  is properly handled in both the JVM and .NET cases.
5464
5465               and then VM_Target = No_VM
5466             then
5467                Error_Msg_N
5468                 ("?foreign convention function& should not return " &
5469                   "unconstrained array", E);
5470                return;
5471             end if;
5472          end if;
5473
5474          --  If any of the formals for an exported foreign convention
5475          --  subprogram have defaults, then emit an appropriate warning since
5476          --  this is odd (default cannot be used from non-Ada code)
5477
5478          if Is_Exported (E) then
5479             F := First_Formal (E);
5480             while Present (F) loop
5481                if Warn_On_Export_Import
5482                  and then Present (Default_Value (F))
5483                then
5484                   Error_Msg_N
5485                     ("?parameter cannot be defaulted in non-Ada call",
5486                      Default_Value (F));
5487                end if;
5488
5489                Next_Formal (F);
5490             end loop;
5491          end if;
5492       end if;
5493
5494       --  For VMS, descriptor mechanisms for parameters are allowed only for
5495       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5496       --  allowed for parameters of exported subprograms.
5497
5498       if OpenVMS_On_Target then
5499          if Is_Exported (E) then
5500             F := First_Formal (E);
5501             while Present (F) loop
5502                if Mechanism (F) = By_Descriptor_NCA then
5503                   Error_Msg_N
5504                     ("'N'C'A' descriptor for parameter not permitted", F);
5505                   Error_Msg_N
5506                     ("\can only be used for imported subprogram", F);
5507                end if;
5508
5509                Next_Formal (F);
5510             end loop;
5511
5512          elsif not Is_Imported (E) then
5513             F := First_Formal (E);
5514             while Present (F) loop
5515                if Mechanism (F) in Descriptor_Codes then
5516                   Error_Msg_N
5517                     ("descriptor mechanism for parameter not permitted", F);
5518                   Error_Msg_N
5519                     ("\can only be used for imported/exported subprogram", F);
5520                end if;
5521
5522                Next_Formal (F);
5523             end loop;
5524          end if;
5525       end if;
5526
5527       --  Pragma Inline_Always is disallowed for dispatching subprograms
5528       --  because the address of such subprograms is saved in the dispatch
5529       --  table to support dispatching calls, and dispatching calls cannot
5530       --  be inlined. This is consistent with the restriction against using
5531       --  'Access or 'Address on an Inline_Always subprogram.
5532
5533       if Is_Dispatching_Operation (E)
5534         and then Has_Pragma_Inline_Always (E)
5535       then
5536          Error_Msg_N
5537            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5538       end if;
5539
5540       --  Because of the implicit representation of inherited predefined
5541       --  operators in the front-end, the overriding status of the operation
5542       --  may be affected when a full view of a type is analyzed, and this is
5543       --  not captured by the analysis of the corresponding type declaration.
5544       --  Therefore the correctness of a not-overriding indicator must be
5545       --  rechecked when the subprogram is frozen.
5546
5547       if Nkind (E) = N_Defining_Operator_Symbol
5548         and then not Error_Posted (Parent (E))
5549       then
5550          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5551       end if;
5552    end Freeze_Subprogram;
5553
5554    ----------------------
5555    -- Is_Fully_Defined --
5556    ----------------------
5557
5558    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5559    begin
5560       if Ekind (T) = E_Class_Wide_Type then
5561          return Is_Fully_Defined (Etype (T));
5562
5563       elsif Is_Array_Type (T) then
5564          return Is_Fully_Defined (Component_Type (T));
5565
5566       elsif Is_Record_Type (T)
5567         and not Is_Private_Type (T)
5568       then
5569          --  Verify that the record type has no components with private types
5570          --  without completion.
5571
5572          declare
5573             Comp : Entity_Id;
5574
5575          begin
5576             Comp := First_Component (T);
5577             while Present (Comp) loop
5578                if not Is_Fully_Defined (Etype (Comp)) then
5579                   return False;
5580                end if;
5581
5582                Next_Component (Comp);
5583             end loop;
5584             return True;
5585          end;
5586
5587       --  For the designated type of an access to subprogram, all types in
5588       --  the profile must be fully defined.
5589
5590       elsif Ekind (T) = E_Subprogram_Type then
5591          declare
5592             F : Entity_Id;
5593
5594          begin
5595             F := First_Formal (T);
5596             while Present (F) loop
5597                if not Is_Fully_Defined (Etype (F)) then
5598                   return False;
5599                end if;
5600
5601                Next_Formal (F);
5602             end loop;
5603
5604             return Is_Fully_Defined (Etype (T));
5605          end;
5606
5607       else
5608          return not Is_Private_Type (T)
5609            or else Present (Full_View (Base_Type (T)));
5610       end if;
5611    end Is_Fully_Defined;
5612
5613    ---------------------------------
5614    -- Process_Default_Expressions --
5615    ---------------------------------
5616
5617    procedure Process_Default_Expressions
5618      (E     : Entity_Id;
5619       After : in out Node_Id)
5620    is
5621       Loc    : constant Source_Ptr := Sloc (E);
5622       Dbody  : Node_Id;
5623       Formal : Node_Id;
5624       Dcopy  : Node_Id;
5625       Dnam   : Entity_Id;
5626
5627    begin
5628       Set_Default_Expressions_Processed (E);
5629
5630       --  A subprogram instance and its associated anonymous subprogram share
5631       --  their signature. The default expression functions are defined in the
5632       --  wrapper packages for the anonymous subprogram, and should not be
5633       --  generated again for the instance.
5634
5635       if Is_Generic_Instance (E)
5636         and then Present (Alias (E))
5637         and then Default_Expressions_Processed (Alias (E))
5638       then
5639          return;
5640       end if;
5641
5642       Formal := First_Formal (E);
5643       while Present (Formal) loop
5644          if Present (Default_Value (Formal)) then
5645
5646             --  We work with a copy of the default expression because we
5647             --  do not want to disturb the original, since this would mess
5648             --  up the conformance checking.
5649
5650             Dcopy := New_Copy_Tree (Default_Value (Formal));
5651
5652             --  The analysis of the expression may generate insert actions,
5653             --  which of course must not be executed. We wrap those actions
5654             --  in a procedure that is not called, and later on eliminated.
5655             --  The following cases have no side-effects, and are analyzed
5656             --  directly.
5657
5658             if Nkind (Dcopy) = N_Identifier
5659               or else Nkind (Dcopy) = N_Expanded_Name
5660               or else Nkind (Dcopy) = N_Integer_Literal
5661               or else (Nkind (Dcopy) = N_Real_Literal
5662                         and then not Vax_Float (Etype (Dcopy)))
5663               or else Nkind (Dcopy) = N_Character_Literal
5664               or else Nkind (Dcopy) = N_String_Literal
5665               or else Known_Null (Dcopy)
5666               or else (Nkind (Dcopy) = N_Attribute_Reference
5667                         and then
5668                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5669             then
5670
5671                --  If there is no default function, we must still do a full
5672                --  analyze call on the default value, to ensure that all error
5673                --  checks are performed, e.g. those associated with static
5674                --  evaluation. Note: this branch will always be taken if the
5675                --  analyzer is turned off (but we still need the error checks).
5676
5677                --  Note: the setting of parent here is to meet the requirement
5678                --  that we can only analyze the expression while attached to
5679                --  the tree. Really the requirement is that the parent chain
5680                --  be set, we don't actually need to be in the tree.
5681
5682                Set_Parent (Dcopy, Declaration_Node (Formal));
5683                Analyze (Dcopy);
5684
5685                --  Default expressions are resolved with their own type if the
5686                --  context is generic, to avoid anomalies with private types.
5687
5688                if Ekind (Scope (E)) = E_Generic_Package then
5689                   Resolve (Dcopy);
5690                else
5691                   Resolve (Dcopy, Etype (Formal));
5692                end if;
5693
5694                --  If that resolved expression will raise constraint error,
5695                --  then flag the default value as raising constraint error.
5696                --  This allows a proper error message on the calls.
5697
5698                if Raises_Constraint_Error (Dcopy) then
5699                   Set_Raises_Constraint_Error (Default_Value (Formal));
5700                end if;
5701
5702             --  If the default is a parameterless call, we use the name of
5703             --  the called function directly, and there is no body to build.
5704
5705             elsif Nkind (Dcopy) = N_Function_Call
5706               and then No (Parameter_Associations (Dcopy))
5707             then
5708                null;
5709
5710             --  Else construct and analyze the body of a wrapper procedure
5711             --  that contains an object declaration to hold the expression.
5712             --  Given that this is done only to complete the analysis, it
5713             --  simpler to build a procedure than a function which might
5714             --  involve secondary stack expansion.
5715
5716             else
5717                Dnam := Make_Temporary (Loc, 'D');
5718
5719                Dbody :=
5720                  Make_Subprogram_Body (Loc,
5721                    Specification =>
5722                      Make_Procedure_Specification (Loc,
5723                        Defining_Unit_Name => Dnam),
5724
5725                    Declarations => New_List (
5726                      Make_Object_Declaration (Loc,
5727                        Defining_Identifier =>
5728                          Make_Temporary (Loc, 'T'),
5729                        Object_Definition =>
5730                          New_Occurrence_Of (Etype (Formal), Loc),
5731                        Expression => New_Copy_Tree (Dcopy))),
5732
5733                    Handled_Statement_Sequence =>
5734                      Make_Handled_Sequence_Of_Statements (Loc,
5735                        Statements => New_List));
5736
5737                Set_Scope (Dnam, Scope (E));
5738                Set_Assignment_OK (First (Declarations (Dbody)));
5739                Set_Is_Eliminated (Dnam);
5740                Insert_After (After, Dbody);
5741                Analyze (Dbody);
5742                After := Dbody;
5743             end if;
5744          end if;
5745
5746          Next_Formal (Formal);
5747       end loop;
5748    end Process_Default_Expressions;
5749
5750    ----------------------------------------
5751    -- Set_Component_Alignment_If_Not_Set --
5752    ----------------------------------------
5753
5754    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5755    begin
5756       --  Ignore if not base type, subtypes don't need anything
5757
5758       if Typ /= Base_Type (Typ) then
5759          return;
5760       end if;
5761
5762       --  Do not override existing representation
5763
5764       if Is_Packed (Typ) then
5765          return;
5766
5767       elsif Has_Specified_Layout (Typ) then
5768          return;
5769
5770       elsif Component_Alignment (Typ) /= Calign_Default then
5771          return;
5772
5773       else
5774          Set_Component_Alignment
5775            (Typ, Scope_Stack.Table
5776                   (Scope_Stack.Last).Component_Alignment_Default);
5777       end if;
5778    end Set_Component_Alignment_If_Not_Set;
5779
5780    ------------------
5781    -- Undelay_Type --
5782    ------------------
5783
5784    procedure Undelay_Type (T : Entity_Id) is
5785    begin
5786       Set_Has_Delayed_Freeze (T, False);
5787       Set_Freeze_Node (T, Empty);
5788
5789       --  Since we don't want T to have a Freeze_Node, we don't want its
5790       --  Full_View or Corresponding_Record_Type to have one either.
5791
5792       --  ??? Fundamentally, this whole handling is a kludge. What we really
5793       --  want is to be sure that for an Itype that's part of record R and is a
5794       --  subtype of type T, that it's frozen after the later of the freeze
5795       --  points of R and T. We have no way of doing that directly, so what we
5796       --  do is force most such Itypes to be frozen as part of freezing R via
5797       --  this procedure and only delay the ones that need to be delayed
5798       --  (mostly the designated types of access types that are defined as part
5799       --  of the record).
5800
5801       if Is_Private_Type (T)
5802         and then Present (Full_View (T))
5803         and then Is_Itype (Full_View (T))
5804         and then Is_Record_Type (Scope (Full_View (T)))
5805       then
5806          Undelay_Type (Full_View (T));
5807       end if;
5808
5809       if Is_Concurrent_Type (T)
5810         and then Present (Corresponding_Record_Type (T))
5811         and then Is_Itype (Corresponding_Record_Type (T))
5812         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5813       then
5814          Undelay_Type (Corresponding_Record_Type (T));
5815       end if;
5816    end Undelay_Type;
5817
5818    ------------------
5819    -- Warn_Overlay --
5820    ------------------
5821
5822    procedure Warn_Overlay
5823      (Expr : Node_Id;
5824       Typ  : Entity_Id;
5825       Nam  : Entity_Id)
5826    is
5827       Ent : constant Entity_Id := Entity (Nam);
5828       --  The object to which the address clause applies
5829
5830       Init : Node_Id;
5831       Old  : Entity_Id := Empty;
5832       Decl : Node_Id;
5833
5834    begin
5835       --  No warning if address clause overlay warnings are off
5836
5837       if not Address_Clause_Overlay_Warnings then
5838          return;
5839       end if;
5840
5841       --  No warning if there is an explicit initialization
5842
5843       Init := Original_Node (Expression (Declaration_Node (Ent)));
5844
5845       if Present (Init) and then Comes_From_Source (Init) then
5846          return;
5847       end if;
5848
5849       --  We only give the warning for non-imported entities of a type for
5850       --  which a non-null base init proc is defined, or for objects of access
5851       --  types with implicit null initialization, or when Normalize_Scalars
5852       --  applies and the type is scalar or a string type (the latter being
5853       --  tested for because predefined String types are initialized by inline
5854       --  code rather than by an init_proc). Note that we do not give the
5855       --  warning for Initialize_Scalars, since we suppressed initialization
5856       --  in this case. Also, do not warn if Suppress_Initialization is set.
5857
5858       if Present (Expr)
5859         and then not Is_Imported (Ent)
5860         and then not Initialization_Suppressed (Typ)
5861         and then (Has_Non_Null_Base_Init_Proc (Typ)
5862                    or else Is_Access_Type (Typ)
5863                    or else (Normalize_Scalars
5864                              and then (Is_Scalar_Type (Typ)
5865                                         or else Is_String_Type (Typ))))
5866       then
5867          if Nkind (Expr) = N_Attribute_Reference
5868            and then Is_Entity_Name (Prefix (Expr))
5869          then
5870             Old := Entity (Prefix (Expr));
5871
5872          elsif Is_Entity_Name (Expr)
5873            and then Ekind (Entity (Expr)) = E_Constant
5874          then
5875             Decl := Declaration_Node (Entity (Expr));
5876
5877             if Nkind (Decl) = N_Object_Declaration
5878               and then Present (Expression (Decl))
5879               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5880               and then Is_Entity_Name (Prefix (Expression (Decl)))
5881             then
5882                Old := Entity (Prefix (Expression (Decl)));
5883
5884             elsif Nkind (Expr) = N_Function_Call then
5885                return;
5886             end if;
5887
5888          --  A function call (most likely to To_Address) is probably not an
5889          --  overlay, so skip warning. Ditto if the function call was inlined
5890          --  and transformed into an entity.
5891
5892          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5893             return;
5894          end if;
5895
5896          Decl := Next (Parent (Expr));
5897
5898          --  If a pragma Import follows, we assume that it is for the current
5899          --  target of the address clause, and skip the warning.
5900
5901          if Present (Decl)
5902            and then Nkind (Decl) = N_Pragma
5903            and then Pragma_Name (Decl) = Name_Import
5904          then
5905             return;
5906          end if;
5907
5908          if Present (Old) then
5909             Error_Msg_Node_2 := Old;
5910             Error_Msg_N
5911               ("default initialization of & may modify &?",
5912                Nam);
5913          else
5914             Error_Msg_N
5915               ("default initialization of & may modify overlaid storage?",
5916                Nam);
5917          end if;
5918
5919          --  Add friendly warning if initialization comes from a packed array
5920          --  component.
5921
5922          if Is_Record_Type (Typ)  then
5923             declare
5924                Comp : Entity_Id;
5925
5926             begin
5927                Comp := First_Component (Typ);
5928                while Present (Comp) loop
5929                   if Nkind (Parent (Comp)) = N_Component_Declaration
5930                     and then Present (Expression (Parent (Comp)))
5931                   then
5932                      exit;
5933                   elsif Is_Array_Type (Etype (Comp))
5934                      and then Present (Packed_Array_Type (Etype (Comp)))
5935                   then
5936                      Error_Msg_NE
5937                        ("\packed array component& " &
5938                         "will be initialized to zero?",
5939                         Nam, Comp);
5940                      exit;
5941                   else
5942                      Next_Component (Comp);
5943                   end if;
5944                end loop;
5945             end;
5946          end if;
5947
5948          Error_Msg_N
5949            ("\use pragma Import for & to " &
5950             "suppress initialization (RM B.1(24))?",
5951             Nam);
5952       end if;
5953    end Warn_Overlay;
5954
5955 end Freeze;