gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere. This is not done in the case
 365       --  where the subprogram is an instantiation because the actual proper
 366       --  body has not been built yet.
 367
 368       if Ekind_In (Old_S, E_Function, E_Procedure)
 369         and then Nkind (Decl) = N_Subprogram_Declaration
 370         and then not Is_Generic_Instance (Old_S)
 371       then
 372          Set_Body_To_Inline (Decl, Old_S);
 373       end if;
 374
 375       --  The body generated for this renaming is an internal artifact, and
 376       --  does not  constitute a freeze point for the called entity.
 377
 378       Set_Must_Not_Freeze (Call_Name);
 379
 380       Formal := First_Formal (Defining_Entity (Decl));
 381
 382       if Present (Pref) then
 383          declare
 384             Pref_Type : constant Entity_Id := Etype (Pref);
 385             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 386
 387          begin
 388             --  The controlling formal may be an access parameter, or the
 389             --  actual may be an access value, so adjust accordingly.
 390
 391             if Is_Access_Type (Pref_Type)
 392               and then not Is_Access_Type (Form_Type)
 393             then
 394                Actuals := New_List
 395                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 396
 397             elsif Is_Access_Type (Form_Type)
 398               and then not Is_Access_Type (Pref)
 399             then
 400                Actuals := New_List
 401                  (Make_Attribute_Reference (Loc,
 402                    Attribute_Name => Name_Access,
 403                    Prefix => Relocate_Node (Pref)));
 404             else
 405                Actuals := New_List (Pref);
 406             end if;
 407          end;
 408
 409       elsif Present (Formal) then
 410          Actuals := New_List;
 411
 412       else
 413          Actuals := No_List;
 414       end if;
 415
 416       if Present (Formal) then
 417          while Present (Formal) loop
 418             Append (New_Reference_To (Formal, Loc), Actuals);
 419             Next_Formal (Formal);
 420          end loop;
 421       end if;
 422
 423       --  If the renamed entity is an entry, inherit its profile. For other
 424       --  renamings as bodies, both profiles must be subtype conformant, so it
 425       --  is not necessary to replace the profile given in the declaration.
 426       --  However, default values that are aggregates are rewritten when
 427       --  partially analyzed, so we recover the original aggregate to insure
 428       --  that subsequent conformity checking works. Similarly, if the default
 429       --  expression was constant-folded, recover the original expression.
 430
 431       Formal := First_Formal (Defining_Entity (Decl));
 432
 433       if Present (Formal) then
 434          O_Formal := First_Formal (Old_S);
 435          Param_Spec := First (Parameter_Specifications (Spec));
 436          while Present (Formal) loop
 437             if Is_Entry (Old_S) then
 438                if Nkind (Parameter_Type (Param_Spec)) /=
 439                                                     N_Access_Definition
 440                then
 441                   Set_Etype (Formal, Etype (O_Formal));
 442                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 443                end if;
 444
 445             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 446               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 447                                            Nkind (Default_Value (O_Formal))
 448             then
 449                Set_Expression (Param_Spec,
 450                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 451             end if;
 452
 453             Next_Formal (Formal);
 454             Next_Formal (O_Formal);
 455             Next (Param_Spec);
 456          end loop;
 457       end if;
 458
 459       --  If the renamed entity is a function, the generated body contains a
 460       --  return statement. Otherwise, build a procedure call. If the entity is
 461       --  an entry, subsequent analysis of the call will transform it into the
 462       --  proper entry or protected operation call. If the renamed entity is
 463       --  a character literal, return it directly.
 464
 465       if Ekind (Old_S) = E_Function
 466         or else Ekind (Old_S) = E_Operator
 467         or else (Ekind (Old_S) = E_Subprogram_Type
 468                   and then Etype (Old_S) /= Standard_Void_Type)
 469       then
 470          Call_Node :=
 471            Make_Simple_Return_Statement (Loc,
 472               Expression =>
 473                 Make_Function_Call (Loc,
 474                   Name => Call_Name,
 475                   Parameter_Associations => Actuals));
 476
 477       elsif Ekind (Old_S) = E_Enumeration_Literal then
 478          Call_Node :=
 479            Make_Simple_Return_Statement (Loc,
 480               Expression => New_Occurrence_Of (Old_S, Loc));
 481
 482       elsif Nkind (Nam) = N_Character_Literal then
 483          Call_Node :=
 484            Make_Simple_Return_Statement (Loc,
 485              Expression => Call_Name);
 486
 487       else
 488          Call_Node :=
 489            Make_Procedure_Call_Statement (Loc,
 490              Name => Call_Name,
 491              Parameter_Associations => Actuals);
 492       end if;
 493
 494       --  Create entities for subprogram body and formals
 495
 496       Set_Defining_Unit_Name (Spec,
 497         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 498
 499       Param_Spec := First (Parameter_Specifications (Spec));
 500       while Present (Param_Spec) loop
 501          Set_Defining_Identifier (Param_Spec,
 502            Make_Defining_Identifier (Loc,
 503              Chars => Chars (Defining_Identifier (Param_Spec))));
 504          Next (Param_Spec);
 505       end loop;
 506
 507       Body_Node :=
 508         Make_Subprogram_Body (Loc,
 509           Specification => Spec,
 510           Declarations => New_List,
 511           Handled_Statement_Sequence =>
 512             Make_Handled_Sequence_Of_Statements (Loc,
 513               Statements => New_List (Call_Node)));
 514
 515       if Nkind (Decl) /= N_Subprogram_Declaration then
 516          Rewrite (N,
 517            Make_Subprogram_Declaration (Loc,
 518              Specification => Specification (N)));
 519       end if;
 520
 521       --  Link the body to the entity whose declaration it completes. If
 522       --  the body is analyzed when the renamed entity is frozen, it may
 523       --  be necessary to restore the proper scope (see package Exp_Ch13).
 524
 525       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 526         and then Present (Corresponding_Spec (N))
 527       then
 528          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 529       else
 530          Set_Corresponding_Spec (Body_Node, New_S);
 531       end if;
 532
 533       return Body_Node;
 534    end Build_Renamed_Body;
 535
 536    --------------------------
 537    -- Check_Address_Clause --
 538    --------------------------
 539
 540    procedure Check_Address_Clause (E : Entity_Id) is
 541       Addr : constant Node_Id   := Address_Clause (E);
 542       Expr : Node_Id;
 543       Decl : constant Node_Id   := Declaration_Node (E);
 544       Typ  : constant Entity_Id := Etype (E);
 545
 546    begin
 547       if Present (Addr) then
 548          Expr := Expression (Addr);
 549
 550          if Needs_Constant_Address (Decl, Typ) then
 551             Check_Constant_Address_Clause (Expr, E);
 552
 553             --  Has_Delayed_Freeze was set on E when the address clause was
 554             --  analyzed. Reset the flag now unless freeze actions were
 555             --  attached to it in the mean time.
 556
 557             if No (Freeze_Node (E)) then
 558                Set_Has_Delayed_Freeze (E, False);
 559             end if;
 560          end if;
 561
 562          --  If Rep_Clauses are to be ignored, remove address clause from
 563          --  list attached to entity, because it may be illegal for gigi,
 564          --  for example by breaking order of elaboration..
 565
 566          if Ignore_Rep_Clauses then
 567             declare
 568                Rep : Node_Id;
 569
 570             begin
 571                Rep := First_Rep_Item (E);
 572
 573                if Rep = Addr then
 574                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 575
 576                else
 577                   while Present (Rep)
 578                     and then Next_Rep_Item (Rep) /= Addr
 579                   loop
 580                      Rep := Next_Rep_Item (Rep);
 581                   end loop;
 582                end if;
 583
 584                if Present (Rep) then
 585                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 586                end if;
 587             end;
 588
 589             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 590
 591          elsif not Error_Posted (Expr)
 592            and then not Needs_Finalization (Typ)
 593          then
 594             Warn_Overlay (Expr, Typ, Name (Addr));
 595          end if;
 596       end if;
 597    end Check_Address_Clause;
 598
 599    -----------------------------
 600    -- Check_Compile_Time_Size --
 601    -----------------------------
 602
 603    procedure Check_Compile_Time_Size (T : Entity_Id) is
 604
 605       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 606       --  Sets the compile time known size (32 bits or less) in the Esize
 607       --  field, of T checking for a size clause that was given which attempts
 608       --  to give a smaller size, and also checking for an alignment clause.
 609
 610       function Size_Known (T : Entity_Id) return Boolean;
 611       --  Recursive function that does all the work
 612
 613       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 614       --  If T is a constrained subtype, its size is not known if any of its
 615       --  discriminant constraints is not static and it is not a null record.
 616       --  The test is conservative and doesn't check that the components are
 617       --  in fact constrained by non-static discriminant values. Could be made
 618       --  more precise ???
 619
 620       --------------------
 621       -- Set_Small_Size --
 622       --------------------
 623
 624       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 625       begin
 626          if S > 32 then
 627             return;
 628
 629          --  Check for bad size clause given
 630
 631          elsif Has_Size_Clause (T) then
 632             if RM_Size (T) < S then
 633                Error_Msg_Uint_1 := S;
 634                Error_Msg_NE
 635                  ("size for& too small, minimum allowed is ^",
 636                   Size_Clause (T), T);
 637             end if;
 638
 639          --  Set size if not set already
 640
 641          elsif Unknown_RM_Size (T) then
 642             Set_RM_Size (T, S);
 643          end if;
 644       end Set_Small_Size;
 645
 646       ----------------
 647       -- Size_Known --
 648       ----------------
 649
 650       function Size_Known (T : Entity_Id) return Boolean is
 651          Index : Entity_Id;
 652          Comp  : Entity_Id;
 653          Ctyp  : Entity_Id;
 654          Low   : Node_Id;
 655          High  : Node_Id;
 656
 657       begin
 658          if Size_Known_At_Compile_Time (T) then
 659             return True;
 660
 661          --  Always True for scalar types. This is true even for generic formal
 662          --  scalar types. We used to return False in the latter case, but the
 663          --  size is known at compile time, even in the template, we just do
 664          --  not know the exact size but that's not the point of this routine.
 665
 666          elsif Is_Scalar_Type (T)
 667            or else Is_Task_Type (T)
 668          then
 669             return True;
 670
 671          --  Array types
 672
 673          elsif Is_Array_Type (T) then
 674
 675             --  String literals always have known size, and we can set it
 676
 677             if Ekind (T) = E_String_Literal_Subtype then
 678                Set_Small_Size (T, Component_Size (T)
 679                                * String_Literal_Length (T));
 680                return True;
 681
 682             --  Unconstrained types never have known at compile time size
 683
 684             elsif not Is_Constrained (T) then
 685                return False;
 686
 687             --  Don't do any recursion on type with error posted, since we may
 688             --  have a malformed type that leads us into a loop.
 689
 690             elsif Error_Posted (T) then
 691                return False;
 692
 693             --  Otherwise if component size unknown, then array size unknown
 694
 695             elsif not Size_Known (Component_Type (T)) then
 696                return False;
 697             end if;
 698
 699             --  Check for all indexes static, and also compute possible size
 700             --  (in case it is less than 32 and may be packable).
 701
 702             declare
 703                Esiz : Uint := Component_Size (T);
 704                Dim  : Uint;
 705
 706             begin
 707                Index := First_Index (T);
 708                while Present (Index) loop
 709                   if Nkind (Index) = N_Range then
 710                      Get_Index_Bounds (Index, Low, High);
 711
 712                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 713                      return False;
 714
 715                   else
 716                      Low  := Type_Low_Bound (Etype (Index));
 717                      High := Type_High_Bound (Etype (Index));
 718                   end if;
 719
 720                   if not Compile_Time_Known_Value (Low)
 721                     or else not Compile_Time_Known_Value (High)
 722                     or else Etype (Index) = Any_Type
 723                   then
 724                      return False;
 725
 726                   else
 727                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 728
 729                      if Dim >= 0 then
 730                         Esiz := Esiz * Dim;
 731                      else
 732                         Esiz := Uint_0;
 733                      end if;
 734                   end if;
 735
 736                   Next_Index (Index);
 737                end loop;
 738
 739                Set_Small_Size (T, Esiz);
 740                return True;
 741             end;
 742
 743          --  Access types always have known at compile time sizes
 744
 745          elsif Is_Access_Type (T) then
 746             return True;
 747
 748          --  For non-generic private types, go to underlying type if present
 749
 750          elsif Is_Private_Type (T)
 751            and then not Is_Generic_Type (T)
 752            and then Present (Underlying_Type (T))
 753          then
 754             --  Don't do any recursion on type with error posted, since we may
 755             --  have a malformed type that leads us into a loop.
 756
 757             if Error_Posted (T) then
 758                return False;
 759             else
 760                return Size_Known (Underlying_Type (T));
 761             end if;
 762
 763          --  Record types
 764
 765          elsif Is_Record_Type (T) then
 766
 767             --  A class-wide type is never considered to have a known size
 768
 769             if Is_Class_Wide_Type (T) then
 770                return False;
 771
 772             --  A subtype of a variant record must not have non-static
 773             --  discriminated components.
 774
 775             elsif T /= Base_Type (T)
 776               and then not Static_Discriminated_Components (T)
 777             then
 778                return False;
 779
 780             --  Don't do any recursion on type with error posted, since we may
 781             --  have a malformed type that leads us into a loop.
 782
 783             elsif Error_Posted (T) then
 784                return False;
 785             end if;
 786
 787             --  Now look at the components of the record
 788
 789             declare
 790                --  The following two variables are used to keep track of the
 791                --  size of packed records if we can tell the size of the packed
 792                --  record in the front end. Packed_Size_Known is True if so far
 793                --  we can figure out the size. It is initialized to True for a
 794                --  packed record, unless the record has discriminants. The
 795                --  reason we eliminate the discriminated case is that we don't
 796                --  know the way the back end lays out discriminated packed
 797                --  records. If Packed_Size_Known is True, then Packed_Size is
 798                --  the size in bits so far.
 799
 800                Packed_Size_Known : Boolean :=
 801                                      Is_Packed (T)
 802                                        and then not Has_Discriminants (T);
 803
 804                Packed_Size : Uint := Uint_0;
 805
 806             begin
 807                --  Test for variant part present
 808
 809                if Has_Discriminants (T)
 810                  and then Present (Parent (T))
 811                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 812                  and then Nkind (Type_Definition (Parent (T))) =
 813                                                N_Record_Definition
 814                  and then not Null_Present (Type_Definition (Parent (T)))
 815                  and then Present (Variant_Part
 816                             (Component_List (Type_Definition (Parent (T)))))
 817                then
 818                   --  If variant part is present, and type is unconstrained,
 819                   --  then we must have defaulted discriminants, or a size
 820                   --  clause must be present for the type, or else the size
 821                   --  is definitely not known at compile time.
 822
 823                   if not Is_Constrained (T)
 824                     and then
 825                       No (Discriminant_Default_Value (First_Discriminant (T)))
 826                     and then Unknown_RM_Size (T)
 827                   then
 828                      return False;
 829                   end if;
 830                end if;
 831
 832                --  Loop through components
 833
 834                Comp := First_Component_Or_Discriminant (T);
 835                while Present (Comp) loop
 836                   Ctyp := Etype (Comp);
 837
 838                   --  We do not know the packed size if there is a component
 839                   --  clause present (we possibly could, but this would only
 840                   --  help in the case of a record with partial rep clauses.
 841                   --  That's because in the case of full rep clauses, the
 842                   --  size gets figured out anyway by a different circuit).
 843
 844                   if Present (Component_Clause (Comp)) then
 845                      Packed_Size_Known := False;
 846                   end if;
 847
 848                   --  We need to identify a component that is an array where
 849                   --  the index type is an enumeration type with non-standard
 850                   --  representation, and some bound of the type depends on a
 851                   --  discriminant.
 852
 853                   --  This is because gigi computes the size by doing a
 854                   --  substitution of the appropriate discriminant value in
 855                   --  the size expression for the base type, and gigi is not
 856                   --  clever enough to evaluate the resulting expression (which
 857                   --  involves a call to rep_to_pos) at compile time.
 858
 859                   --  It would be nice if gigi would either recognize that
 860                   --  this expression can be computed at compile time, or
 861                   --  alternatively figured out the size from the subtype
 862                   --  directly, where all the information is at hand ???
 863
 864                   if Is_Array_Type (Etype (Comp))
 865                     and then Present (Packed_Array_Type (Etype (Comp)))
 866                   then
 867                      declare
 868                         Ocomp  : constant Entity_Id :=
 869                                    Original_Record_Component (Comp);
 870                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 871                         Ind    : Node_Id;
 872                         Indtyp : Entity_Id;
 873                         Lo, Hi : Node_Id;
 874
 875                      begin
 876                         Ind := First_Index (OCtyp);
 877                         while Present (Ind) loop
 878                            Indtyp := Etype (Ind);
 879
 880                            if Is_Enumeration_Type (Indtyp)
 881                              and then Has_Non_Standard_Rep (Indtyp)
 882                            then
 883                               Lo := Type_Low_Bound  (Indtyp);
 884                               Hi := Type_High_Bound (Indtyp);
 885
 886                               if Is_Entity_Name (Lo)
 887                                 and then Ekind (Entity (Lo)) = E_Discriminant
 888                               then
 889                                  return False;
 890
 891                               elsif Is_Entity_Name (Hi)
 892                                 and then Ekind (Entity (Hi)) = E_Discriminant
 893                               then
 894                                  return False;
 895                               end if;
 896                            end if;
 897
 898                            Next_Index (Ind);
 899                         end loop;
 900                      end;
 901                   end if;
 902
 903                   --  Clearly size of record is not known if the size of one of
 904                   --  the components is not known.
 905
 906                   if not Size_Known (Ctyp) then
 907                      return False;
 908                   end if;
 909
 910                   --  Accumulate packed size if possible
 911
 912                   if Packed_Size_Known then
 913
 914                      --  We can only deal with elementary types, since for
 915                      --  non-elementary components, alignment enters into the
 916                      --  picture, and we don't know enough to handle proper
 917                      --  alignment in this context. Packed arrays count as
 918                      --  elementary if the representation is a modular type.
 919
 920                      if Is_Elementary_Type (Ctyp)
 921                        or else (Is_Array_Type (Ctyp)
 922                                  and then Present (Packed_Array_Type (Ctyp))
 923                                  and then Is_Modular_Integer_Type
 924                                             (Packed_Array_Type (Ctyp)))
 925                      then
 926                         --  If RM_Size is known and static, then we can keep
 927                         --  accumulating the packed size.
 928
 929                         if Known_Static_RM_Size (Ctyp) then
 930
 931                            --  A little glitch, to be removed sometime ???
 932                            --  gigi does not understand zero sizes yet.
 933
 934                            if RM_Size (Ctyp) = Uint_0 then
 935                               Packed_Size_Known := False;
 936
 937                            --  Normal case where we can keep accumulating the
 938                            --  packed array size.
 939
 940                            else
 941                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 942                            end if;
 943
 944                         --  If we have a field whose RM_Size is not known then
 945                         --  we can't figure out the packed size here.
 946
 947                         else
 948                            Packed_Size_Known := False;
 949                         end if;
 950
 951                      --  If we have a non-elementary type we can't figure out
 952                      --  the packed array size (alignment issues).
 953
 954                      else
 955                         Packed_Size_Known := False;
 956                      end if;
 957                   end if;
 958
 959                   Next_Component_Or_Discriminant (Comp);
 960                end loop;
 961
 962                if Packed_Size_Known then
 963                   Set_Small_Size (T, Packed_Size);
 964                end if;
 965
 966                return True;
 967             end;
 968
 969          --  All other cases, size not known at compile time
 970
 971          else
 972             return False;
 973          end if;
 974       end Size_Known;
 975
 976       -------------------------------------
 977       -- Static_Discriminated_Components --
 978       -------------------------------------
 979
 980       function Static_Discriminated_Components
 981         (T : Entity_Id) return Boolean
 982       is
 983          Constraint : Elmt_Id;
 984
 985       begin
 986          if Has_Discriminants (T)
 987            and then Present (Discriminant_Constraint (T))
 988            and then Present (First_Component (T))
 989          then
 990             Constraint := First_Elmt (Discriminant_Constraint (T));
 991             while Present (Constraint) loop
 992                if not Compile_Time_Known_Value (Node (Constraint)) then
 993                   return False;
 994                end if;
 995
 996                Next_Elmt (Constraint);
 997             end loop;
 998          end if;
 999
1000          return True;
1001       end Static_Discriminated_Components;
1002
1003    --  Start of processing for Check_Compile_Time_Size
1004
1005    begin
1006       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1007    end Check_Compile_Time_Size;
1008
1009    -----------------------------
1010    -- Check_Debug_Info_Needed --
1011    -----------------------------
1012
1013    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1014    begin
1015       if Debug_Info_Off (T) then
1016          return;
1017
1018       elsif Comes_From_Source (T)
1019         or else Debug_Generated_Code
1020         or else Debug_Flag_VV
1021         or else Needs_Debug_Info (T)
1022       then
1023          Set_Debug_Info_Needed (T);
1024       end if;
1025    end Check_Debug_Info_Needed;
1026
1027    ----------------------------
1028    -- Check_Strict_Alignment --
1029    ----------------------------
1030
1031    procedure Check_Strict_Alignment (E : Entity_Id) is
1032       Comp  : Entity_Id;
1033
1034    begin
1035       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1036          Set_Strict_Alignment (E);
1037
1038       elsif Is_Array_Type (E) then
1039          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1040
1041       elsif Is_Record_Type (E) then
1042          if Is_Limited_Record (E) then
1043             Set_Strict_Alignment (E);
1044             return;
1045          end if;
1046
1047          Comp := First_Component (E);
1048          while Present (Comp) loop
1049             if not Is_Type (Comp)
1050               and then (Strict_Alignment (Etype (Comp))
1051                          or else Is_Aliased (Comp))
1052             then
1053                Set_Strict_Alignment (E);
1054                return;
1055             end if;
1056
1057             Next_Component (Comp);
1058          end loop;
1059       end if;
1060    end Check_Strict_Alignment;
1061
1062    -------------------------
1063    -- Check_Unsigned_Type --
1064    -------------------------
1065
1066    procedure Check_Unsigned_Type (E : Entity_Id) is
1067       Ancestor : Entity_Id;
1068       Lo_Bound : Node_Id;
1069       Btyp     : Entity_Id;
1070
1071    begin
1072       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1073          return;
1074       end if;
1075
1076       --  Do not attempt to analyze case where range was in error
1077
1078       if No (Scalar_Range (E))
1079         or else Error_Posted (Scalar_Range (E))
1080       then
1081          return;
1082       end if;
1083
1084       --  The situation that is non trivial is something like
1085
1086       --     subtype x1 is integer range -10 .. +10;
1087       --     subtype x2 is x1 range 0 .. V1;
1088       --     subtype x3 is x2 range V2 .. V3;
1089       --     subtype x4 is x3 range V4 .. V5;
1090
1091       --  where Vn are variables. Here the base type is signed, but we still
1092       --  know that x4 is unsigned because of the lower bound of x2.
1093
1094       --  The only way to deal with this is to look up the ancestor chain
1095
1096       Ancestor := E;
1097       loop
1098          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1099             return;
1100          end if;
1101
1102          Lo_Bound := Type_Low_Bound (Ancestor);
1103
1104          if Compile_Time_Known_Value (Lo_Bound) then
1105
1106             if Expr_Rep_Value (Lo_Bound) >= 0 then
1107                Set_Is_Unsigned_Type (E, True);
1108             end if;
1109
1110             return;
1111
1112          else
1113             Ancestor := Ancestor_Subtype (Ancestor);
1114
1115             --  If no ancestor had a static lower bound, go to base type
1116
1117             if No (Ancestor) then
1118
1119                --  Note: the reason we still check for a compile time known
1120                --  value for the base type is that at least in the case of
1121                --  generic formals, we can have bounds that fail this test,
1122                --  and there may be other cases in error situations.
1123
1124                Btyp := Base_Type (E);
1125
1126                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1127                   return;
1128                end if;
1129
1130                Lo_Bound := Type_Low_Bound (Base_Type (E));
1131
1132                if Compile_Time_Known_Value (Lo_Bound)
1133                  and then Expr_Rep_Value (Lo_Bound) >= 0
1134                then
1135                   Set_Is_Unsigned_Type (E, True);
1136                end if;
1137
1138                return;
1139             end if;
1140          end if;
1141       end loop;
1142    end Check_Unsigned_Type;
1143
1144    -------------------------
1145    -- Is_Atomic_Aggregate --
1146    -------------------------
1147
1148    function  Is_Atomic_Aggregate
1149      (E   : Entity_Id;
1150       Typ : Entity_Id) return Boolean
1151    is
1152       Loc   : constant Source_Ptr := Sloc (E);
1153       New_N : Node_Id;
1154       Par   : Node_Id;
1155       Temp  : Entity_Id;
1156
1157    begin
1158       Par := Parent (E);
1159
1160       --  Array may be qualified, so find outer context
1161
1162       if Nkind (Par) = N_Qualified_Expression then
1163          Par := Parent (Par);
1164       end if;
1165
1166       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1167         and then Comes_From_Source (Par)
1168       then
1169          Temp := Make_Temporary (Loc, 'T', E);
1170          New_N :=
1171            Make_Object_Declaration (Loc,
1172              Defining_Identifier => Temp,
1173              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1174              Expression          => Relocate_Node (E));
1175          Insert_Before (Par, New_N);
1176          Analyze (New_N);
1177
1178          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1179          return True;
1180
1181       else
1182          return False;
1183       end if;
1184    end Is_Atomic_Aggregate;
1185
1186    ----------------
1187    -- Freeze_All --
1188    ----------------
1189
1190    --  Note: the easy coding for this procedure would be to just build a
1191    --  single list of freeze nodes and then insert them and analyze them
1192    --  all at once. This won't work, because the analysis of earlier freeze
1193    --  nodes may recursively freeze types which would otherwise appear later
1194    --  on in the freeze list. So we must analyze and expand the freeze nodes
1195    --  as they are generated.
1196
1197    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1198       E     : Entity_Id;
1199       Decl  : Node_Id;
1200
1201       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1202       --  This is the internal recursive routine that does freezing of entities
1203       --  (but NOT the analysis of default expressions, which should not be
1204       --  recursive, we don't want to analyze those till we are sure that ALL
1205       --  the types are frozen).
1206
1207       --------------------
1208       -- Freeze_All_Ent --
1209       --------------------
1210
1211       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1212          E     : Entity_Id;
1213          Flist : List_Id;
1214          Lastn : Node_Id;
1215
1216          procedure Process_Flist;
1217          --  If freeze nodes are present, insert and analyze, and reset cursor
1218          --  for next insertion.
1219
1220          -------------------
1221          -- Process_Flist --
1222          -------------------
1223
1224          procedure Process_Flist is
1225          begin
1226             if Is_Non_Empty_List (Flist) then
1227                Lastn := Next (After);
1228                Insert_List_After_And_Analyze (After, Flist);
1229
1230                if Present (Lastn) then
1231                   After := Prev (Lastn);
1232                else
1233                   After := Last (List_Containing (After));
1234                end if;
1235             end if;
1236          end Process_Flist;
1237
1238       --  Start or processing for Freeze_All_Ent
1239
1240       begin
1241          E := From;
1242          while Present (E) loop
1243
1244             --  If the entity is an inner package which is not a package
1245             --  renaming, then its entities must be frozen at this point. Note
1246             --  that such entities do NOT get frozen at the end of the nested
1247             --  package itself (only library packages freeze).
1248
1249             --  Same is true for task declarations, where anonymous records
1250             --  created for entry parameters must be frozen.
1251
1252             if Ekind (E) = E_Package
1253               and then No (Renamed_Object (E))
1254               and then not Is_Child_Unit (E)
1255               and then not Is_Frozen (E)
1256             then
1257                Push_Scope (E);
1258                Install_Visible_Declarations (E);
1259                Install_Private_Declarations (E);
1260
1261                Freeze_All (First_Entity (E), After);
1262
1263                End_Package_Scope (E);
1264
1265                if Is_Generic_Instance (E)
1266                  and then Has_Delayed_Freeze (E)
1267                then
1268                   Set_Has_Delayed_Freeze (E, False);
1269                   Expand_N_Package_Declaration (Unit_Declaration_Node (E));
1270                end if;
1271
1272             elsif Ekind (E) in Task_Kind
1273               and then
1274                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1275                    or else
1276                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1277             then
1278                Push_Scope (E);
1279                Freeze_All (First_Entity (E), After);
1280                End_Scope;
1281
1282             --  For a derived tagged type, we must ensure that all the
1283             --  primitive operations of the parent have been frozen, so that
1284             --  their addresses will be in the parent's dispatch table at the
1285             --  point it is inherited.
1286
1287             elsif Ekind (E) = E_Record_Type
1288               and then Is_Tagged_Type (E)
1289               and then Is_Tagged_Type (Etype (E))
1290               and then Is_Derived_Type (E)
1291             then
1292                declare
1293                   Prim_List : constant Elist_Id :=
1294                                Primitive_Operations (Etype (E));
1295
1296                   Prim : Elmt_Id;
1297                   Subp : Entity_Id;
1298
1299                begin
1300                   Prim := First_Elmt (Prim_List);
1301                   while Present (Prim) loop
1302                      Subp := Node (Prim);
1303
1304                      if Comes_From_Source (Subp)
1305                        and then not Is_Frozen (Subp)
1306                      then
1307                         Flist := Freeze_Entity (Subp, After);
1308                         Process_Flist;
1309                      end if;
1310
1311                      Next_Elmt (Prim);
1312                   end loop;
1313                end;
1314             end if;
1315
1316             if not Is_Frozen (E) then
1317                Flist := Freeze_Entity (E, After);
1318                Process_Flist;
1319
1320             --  If already frozen, and there are delayed aspects, this is where
1321             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1322             --  for a description of how we handle aspect visibility).
1323
1324             elsif Has_Delayed_Aspects (E) then
1325                declare
1326                   Ritem : Node_Id;
1327
1328                begin
1329                   Ritem := First_Rep_Item (E);
1330                   while Present (Ritem) loop
1331                      if Nkind (Ritem) = N_Aspect_Specification
1332                        and then Entity (Ritem) = E
1333                        and then Is_Delayed_Aspect (Ritem)
1334                      then
1335                         Check_Aspect_At_End_Of_Declarations (Ritem);
1336                      end if;
1337
1338                      Ritem := Next_Rep_Item (Ritem);
1339                   end loop;
1340                end;
1341             end if;
1342
1343             --  If an incomplete type is still not frozen, this may be a
1344             --  premature freezing because of a body declaration that follows.
1345             --  Indicate where the freezing took place.
1346
1347             --  If the freezing is caused by the end of the current declarative
1348             --  part, it is a Taft Amendment type, and there is no error.
1349
1350             if not Is_Frozen (E)
1351               and then Ekind (E) = E_Incomplete_Type
1352             then
1353                declare
1354                   Bod : constant Node_Id := Next (After);
1355
1356                begin
1357                   if (Nkind_In (Bod, N_Subprogram_Body,
1358                                      N_Entry_Body,
1359                                      N_Package_Body,
1360                                      N_Protected_Body,
1361                                      N_Task_Body)
1362                         or else Nkind (Bod) in N_Body_Stub)
1363                      and then
1364                        List_Containing (After) = List_Containing (Parent (E))
1365                   then
1366                      Error_Msg_Sloc := Sloc (Next (After));
1367                      Error_Msg_NE
1368                        ("type& is frozen# before its full declaration",
1369                          Parent (E), E);
1370                   end if;
1371                end;
1372             end if;
1373
1374             Next_Entity (E);
1375          end loop;
1376       end Freeze_All_Ent;
1377
1378    --  Start of processing for Freeze_All
1379
1380    begin
1381       Freeze_All_Ent (From, After);
1382
1383       --  Now that all types are frozen, we can deal with default expressions
1384       --  that require us to build a default expression functions. This is the
1385       --  point at which such functions are constructed (after all types that
1386       --  might be used in such expressions have been frozen).
1387
1388       --  For subprograms that are renaming_as_body, we create the wrapper
1389       --  bodies as needed.
1390
1391       --  We also add finalization chains to access types whose designated
1392       --  types are controlled. This is normally done when freezing the type,
1393       --  but this misses recursive type definitions where the later members
1394       --  of the recursion introduce controlled components.
1395
1396       --  Loop through entities
1397
1398       E := From;
1399       while Present (E) loop
1400          if Is_Subprogram (E) then
1401
1402             if not Default_Expressions_Processed (E) then
1403                Process_Default_Expressions (E, After);
1404             end if;
1405
1406             if not Has_Completion (E) then
1407                Decl := Unit_Declaration_Node (E);
1408
1409                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1410                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1411
1412                elsif Nkind (Decl) = N_Subprogram_Declaration
1413                  and then Present (Corresponding_Body (Decl))
1414                  and then
1415                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1416                                           = N_Subprogram_Renaming_Declaration
1417                then
1418                   Build_And_Analyze_Renamed_Body
1419                     (Decl, Corresponding_Body (Decl), After);
1420                end if;
1421             end if;
1422
1423          elsif Ekind (E) in Task_Kind
1424            and then
1425              (Nkind (Parent (E)) = N_Task_Type_Declaration
1426                 or else
1427               Nkind (Parent (E)) = N_Single_Task_Declaration)
1428          then
1429             declare
1430                Ent : Entity_Id;
1431
1432             begin
1433                Ent := First_Entity (E);
1434                while Present (Ent) loop
1435                   if Is_Entry (Ent)
1436                     and then not Default_Expressions_Processed (Ent)
1437                   then
1438                      Process_Default_Expressions (Ent, After);
1439                   end if;
1440
1441                   Next_Entity (Ent);
1442                end loop;
1443             end;
1444
1445          --  We add finalization masters to access types whose designated types
1446          --  require finalization. This is normally done when freezing the
1447          --  type, but this misses recursive type definitions where the later
1448          --  members of the recursion introduce controlled components (such as
1449          --  can happen when incomplete types are involved), as well cases
1450          --  where a component type is private and the controlled full type
1451          --  occurs after the access type is frozen. Cases that don't need a
1452          --  finalization master are generic formal types (the actual type will
1453          --  have it) and types with Java and CIL conventions, since those are
1454          --  used for API bindings. (Are there any other cases that should be
1455          --  excluded here???)
1456
1457          elsif Is_Access_Type (E)
1458            and then Comes_From_Source (E)
1459            and then not Is_Generic_Type (E)
1460            and then Needs_Finalization (Designated_Type (E))
1461          then
1462             Build_Finalization_Master (E);
1463          end if;
1464
1465          Next_Entity (E);
1466       end loop;
1467    end Freeze_All;
1468
1469    -----------------------
1470    -- Freeze_And_Append --
1471    -----------------------
1472
1473    procedure Freeze_And_Append
1474      (Ent    : Entity_Id;
1475       N      : Node_Id;
1476       Result : in out List_Id)
1477    is
1478       L : constant List_Id := Freeze_Entity (Ent, N);
1479    begin
1480       if Is_Non_Empty_List (L) then
1481          if Result = No_List then
1482             Result := L;
1483          else
1484             Append_List (L, Result);
1485          end if;
1486       end if;
1487    end Freeze_And_Append;
1488
1489    -------------------
1490    -- Freeze_Before --
1491    -------------------
1492
1493    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1494       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1495    begin
1496       if Is_Non_Empty_List (Freeze_Nodes) then
1497          Insert_Actions (N, Freeze_Nodes);
1498       end if;
1499    end Freeze_Before;
1500
1501    -------------------
1502    -- Freeze_Entity --
1503    -------------------
1504
1505    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1506       Loc    : constant Source_Ptr := Sloc (N);
1507       Test_E : Entity_Id := E;
1508       Comp   : Entity_Id;
1509       F_Node : Node_Id;
1510       Indx   : Node_Id;
1511       Formal : Entity_Id;
1512       Atype  : Entity_Id;
1513
1514       Result : List_Id := No_List;
1515       --  List of freezing actions, left at No_List if none
1516
1517       Has_Default_Initialization : Boolean := False;
1518       --  This flag gets set to true for a variable with default initialization
1519
1520       procedure Add_To_Result (N : Node_Id);
1521       --  N is a freezing action to be appended to the Result
1522
1523       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1524       --  Check that an Access or Unchecked_Access attribute with a prefix
1525       --  which is the current instance type can only be applied when the type
1526       --  is limited.
1527
1528       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1529       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1530       --  integer literal without an explicit corresponding size clause. The
1531       --  caller has checked that Utype is a modular integer type.
1532
1533       function After_Last_Declaration return Boolean;
1534       --  If Loc is a freeze_entity that appears after the last declaration
1535       --  in the scope, inhibit error messages on late completion.
1536
1537       procedure Freeze_Record_Type (Rec : Entity_Id);
1538       --  Freeze each component, handle some representation clauses, and freeze
1539       --  primitive operations if this is a tagged type.
1540
1541       -------------------
1542       -- Add_To_Result --
1543       -------------------
1544
1545       procedure Add_To_Result (N : Node_Id) is
1546       begin
1547          if No (Result) then
1548             Result := New_List (N);
1549          else
1550             Append (N, Result);
1551          end if;
1552       end Add_To_Result;
1553
1554       ----------------------------
1555       -- After_Last_Declaration --
1556       ----------------------------
1557
1558       function After_Last_Declaration return Boolean is
1559          Spec : constant Node_Id := Parent (Current_Scope);
1560       begin
1561          if Nkind (Spec) = N_Package_Specification then
1562             if Present (Private_Declarations (Spec)) then
1563                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1564             elsif Present (Visible_Declarations (Spec)) then
1565                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1566             else
1567                return False;
1568             end if;
1569          else
1570             return False;
1571          end if;
1572       end After_Last_Declaration;
1573
1574       ----------------------------
1575       -- Check_Current_Instance --
1576       ----------------------------
1577
1578       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1579
1580          Rec_Type : constant Entity_Id :=
1581                       Scope (Defining_Identifier (Comp_Decl));
1582
1583          Decl : constant Node_Id := Parent (Rec_Type);
1584
1585          function Process (N : Node_Id) return Traverse_Result;
1586          --  Process routine to apply check to given node
1587
1588          -------------
1589          -- Process --
1590          -------------
1591
1592          function Process (N : Node_Id) return Traverse_Result is
1593          begin
1594             case Nkind (N) is
1595                when N_Attribute_Reference =>
1596                   if (Attribute_Name (N) = Name_Access
1597                         or else
1598                       Attribute_Name (N) = Name_Unchecked_Access)
1599                     and then Is_Entity_Name (Prefix (N))
1600                     and then Is_Type (Entity (Prefix (N)))
1601                     and then Entity (Prefix (N)) = E
1602                   then
1603                      Error_Msg_N
1604                        ("current instance must be a limited type", Prefix (N));
1605                      return Abandon;
1606                   else
1607                      return OK;
1608                   end if;
1609
1610                when others => return OK;
1611             end case;
1612          end Process;
1613
1614          procedure Traverse is new Traverse_Proc (Process);
1615
1616       --  Start of processing for Check_Current_Instance
1617
1618       begin
1619          --  In Ada95, the (imprecise) rule is that the current instance of a
1620          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1621          --  either a tagged type, or a limited record.
1622
1623          if Is_Limited_Type (Rec_Type)
1624            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1625          then
1626             return;
1627
1628          elsif Nkind (Decl) = N_Full_Type_Declaration
1629            and then Limited_Present (Type_Definition (Decl))
1630          then
1631             return;
1632
1633          else
1634             Traverse (Comp_Decl);
1635          end if;
1636       end Check_Current_Instance;
1637
1638       ------------------------------
1639       -- Check_Suspicious_Modulus --
1640       ------------------------------
1641
1642       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1643          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1644
1645       begin
1646          if Nkind (Decl) = N_Full_Type_Declaration then
1647             declare
1648                Tdef : constant Node_Id := Type_Definition (Decl);
1649             begin
1650                if Nkind (Tdef) = N_Modular_Type_Definition then
1651                   declare
1652                      Modulus : constant Node_Id :=
1653                                  Original_Node (Expression (Tdef));
1654                   begin
1655                      if Nkind (Modulus) = N_Integer_Literal then
1656                         declare
1657                            Modv : constant Uint := Intval (Modulus);
1658                            Sizv : constant Uint := RM_Size (Utype);
1659
1660                         begin
1661                            --  First case, modulus and size are the same. This
1662                            --  happens if you have something like mod 32, with
1663                            --  an explicit size of 32, this is for sure a case
1664                            --  where the warning is given, since it is seems
1665                            --  very unlikely that someone would want e.g. a
1666                            --  five bit type stored in 32 bits. It is much
1667                            --  more likely they wanted a 32-bit type.
1668
1669                            if Modv = Sizv then
1670                               null;
1671
1672                            --  Second case, the modulus is 32 or 64 and no
1673                            --  size clause is present. This is a less clear
1674                            --  case for giving the warning, but in the case
1675                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1676                            --  enough that it is a likely error (and in any
1677                            --  case using 2**5 or 2**6 in these cases seems
1678                            --  clearer. We don't include 8 or 16 here, simply
1679                            --  because in practice 3-bit and 4-bit types are
1680                            --  more common and too many false positives if
1681                            --  we warn in these cases.
1682
1683                            elsif not Has_Size_Clause (Utype)
1684                              and then (Modv = Uint_32 or else Modv = Uint_64)
1685                            then
1686                               null;
1687
1688                            --  No warning needed
1689
1690                            else
1691                               return;
1692                            end if;
1693
1694                            --  If we fall through, give warning
1695
1696                            Error_Msg_Uint_1 := Modv;
1697                            Error_Msg_N
1698                              ("?2 '*'*^' may have been intended here",
1699                               Modulus);
1700                         end;
1701                      end if;
1702                   end;
1703                end if;
1704             end;
1705          end if;
1706       end Check_Suspicious_Modulus;
1707
1708       ------------------------
1709       -- Freeze_Record_Type --
1710       ------------------------
1711
1712       procedure Freeze_Record_Type (Rec : Entity_Id) is
1713          Comp : Entity_Id;
1714          IR   : Node_Id;
1715          ADC  : Node_Id;
1716          Prev : Entity_Id;
1717
1718          Junk : Boolean;
1719          pragma Warnings (Off, Junk);
1720
1721          Unplaced_Component : Boolean := False;
1722          --  Set True if we find at least one component with no component
1723          --  clause (used to warn about useless Pack pragmas).
1724
1725          Placed_Component : Boolean := False;
1726          --  Set True if we find at least one component with a component
1727          --  clause (used to warn about useless Bit_Order pragmas, and also
1728          --  to detect cases where Implicit_Packing may have an effect).
1729
1730          All_Scalar_Components : Boolean := True;
1731          --  Set False if we encounter a component of a non-scalar type
1732
1733          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1734          Scalar_Component_Total_Esize   : Uint := Uint_0;
1735          --  Accumulates total RM_Size values and total Esize values of all
1736          --  scalar components. Used for processing of Implicit_Packing.
1737
1738          function Check_Allocator (N : Node_Id) return Node_Id;
1739          --  If N is an allocator, possibly wrapped in one or more level of
1740          --  qualified expression(s), return the inner allocator node, else
1741          --  return Empty.
1742
1743          procedure Check_Itype (Typ : Entity_Id);
1744          --  If the component subtype is an access to a constrained subtype of
1745          --  an already frozen type, make the subtype frozen as well. It might
1746          --  otherwise be frozen in the wrong scope, and a freeze node on
1747          --  subtype has no effect. Similarly, if the component subtype is a
1748          --  regular (not protected) access to subprogram, set the anonymous
1749          --  subprogram type to frozen as well, to prevent an out-of-scope
1750          --  freeze node at some eventual point of call. Protected operations
1751          --  are handled elsewhere.
1752
1753          ---------------------
1754          -- Check_Allocator --
1755          ---------------------
1756
1757          function Check_Allocator (N : Node_Id) return Node_Id is
1758             Inner : Node_Id;
1759          begin
1760             Inner := N;
1761             loop
1762                if Nkind (Inner) = N_Allocator then
1763                   return Inner;
1764                elsif Nkind (Inner) = N_Qualified_Expression then
1765                   Inner := Expression (Inner);
1766                else
1767                   return Empty;
1768                end if;
1769             end loop;
1770          end Check_Allocator;
1771
1772          -----------------
1773          -- Check_Itype --
1774          -----------------
1775
1776          procedure Check_Itype (Typ : Entity_Id) is
1777             Desig : constant Entity_Id := Designated_Type (Typ);
1778
1779          begin
1780             if not Is_Frozen (Desig)
1781               and then Is_Frozen (Base_Type (Desig))
1782             then
1783                Set_Is_Frozen (Desig);
1784
1785                --  In addition, add an Itype_Reference to ensure that the
1786                --  access subtype is elaborated early enough. This cannot be
1787                --  done if the subtype may depend on discriminants.
1788
1789                if Ekind (Comp) = E_Component
1790                  and then Is_Itype (Etype (Comp))
1791                  and then not Has_Discriminants (Rec)
1792                then
1793                   IR := Make_Itype_Reference (Sloc (Comp));
1794                   Set_Itype (IR, Desig);
1795                   Add_To_Result (IR);
1796                end if;
1797
1798             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1799               and then Convention (Desig) /= Convention_Protected
1800             then
1801                Set_Is_Frozen (Desig);
1802             end if;
1803          end Check_Itype;
1804
1805       --  Start of processing for Freeze_Record_Type
1806
1807       begin
1808          --  Freeze components and embedded subtypes
1809
1810          Comp := First_Entity (Rec);
1811          Prev := Empty;
1812          while Present (Comp) loop
1813
1814             --  First handle the component case
1815
1816             if Ekind (Comp) = E_Component
1817               or else Ekind (Comp) = E_Discriminant
1818             then
1819                declare
1820                   CC : constant Node_Id := Component_Clause (Comp);
1821
1822                begin
1823                   --  Freezing a record type freezes the type of each of its
1824                   --  components. However, if the type of the component is
1825                   --  part of this record, we do not want or need a separate
1826                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1827                   --  also set in private type cases. We also can't check for
1828                   --  the Scope being exactly Rec because of private types and
1829                   --  record extensions.
1830
1831                   if Is_Itype (Etype (Comp))
1832                     and then Is_Record_Type (Underlying_Type
1833                                              (Scope (Etype (Comp))))
1834                   then
1835                      Undelay_Type (Etype (Comp));
1836                   end if;
1837
1838                   Freeze_And_Append (Etype (Comp), N, Result);
1839
1840                   --  Check for error of component clause given for variable
1841                   --  sized type. We have to delay this test till this point,
1842                   --  since the component type has to be frozen for us to know
1843                   --  if it is variable length. We omit this test in a generic
1844                   --  context, it will be applied at instantiation time.
1845
1846                   --  We also omit this test in CodePeer mode, since we do not
1847                   --  have sufficient info on size and representation clauses.
1848
1849                   if Present (CC) then
1850                      Placed_Component := True;
1851
1852                      if Inside_A_Generic then
1853                         null;
1854
1855                      elsif CodePeer_Mode then
1856                         null;
1857
1858                      elsif not
1859                        Size_Known_At_Compile_Time
1860                          (Underlying_Type (Etype (Comp)))
1861                      then
1862                         Error_Msg_N
1863                           ("component clause not allowed for variable " &
1864                            "length component", CC);
1865                      end if;
1866
1867                   else
1868                      Unplaced_Component := True;
1869                   end if;
1870
1871                   --  Case of component requires byte alignment
1872
1873                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1874
1875                      --  Set the enclosing record to also require byte align
1876
1877                      Set_Must_Be_On_Byte_Boundary (Rec);
1878
1879                      --  Check for component clause that is inconsistent with
1880                      --  the required byte boundary alignment.
1881
1882                      if Present (CC)
1883                        and then Normalized_First_Bit (Comp) mod
1884                                   System_Storage_Unit /= 0
1885                      then
1886                         Error_Msg_N
1887                           ("component & must be byte aligned",
1888                            Component_Name (Component_Clause (Comp)));
1889                      end if;
1890                   end if;
1891                end;
1892             end if;
1893
1894             --  Gather data for possible Implicit_Packing later. Note that at
1895             --  this stage we might be dealing with a real component, or with
1896             --  an implicit subtype declaration.
1897
1898             if not Is_Scalar_Type (Etype (Comp)) then
1899                All_Scalar_Components := False;
1900             else
1901                Scalar_Component_Total_RM_Size :=
1902                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1903                Scalar_Component_Total_Esize :=
1904                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1905             end if;
1906
1907             --  If the component is an Itype with Delayed_Freeze and is either
1908             --  a record or array subtype and its base type has not yet been
1909             --  frozen, we must remove this from the entity list of this record
1910             --  and put it on the entity list of the scope of its base type.
1911             --  Note that we know that this is not the type of a component
1912             --  since we cleared Has_Delayed_Freeze for it in the previous
1913             --  loop. Thus this must be the Designated_Type of an access type,
1914             --  which is the type of a component.
1915
1916             if Is_Itype (Comp)
1917               and then Is_Type (Scope (Comp))
1918               and then Is_Composite_Type (Comp)
1919               and then Base_Type (Comp) /= Comp
1920               and then Has_Delayed_Freeze (Comp)
1921               and then not Is_Frozen (Base_Type (Comp))
1922             then
1923                declare
1924                   Will_Be_Frozen : Boolean := False;
1925                   S              : Entity_Id;
1926
1927                begin
1928                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1929                   --  being defined in a subprogram that's created as part of
1930                   --  the freezing of Rec'Base. In that case, we know that
1931                   --  Comp'Base must have already been frozen by the time we
1932                   --  get to elaborate this because Gigi doesn't elaborate any
1933                   --  bodies until it has elaborated all of the declarative
1934                   --  part. But Is_Frozen will not be set at this point because
1935                   --  we are processing code in lexical order.
1936
1937                   --  We detect this case by going up the Scope chain of Rec
1938                   --  and seeing if we have a subprogram scope before reaching
1939                   --  the top of the scope chain or that of Comp'Base. If we
1940                   --  do, then mark that Comp'Base will actually be frozen. If
1941                   --  so, we merely undelay it.
1942
1943                   S := Scope (Rec);
1944                   while Present (S) loop
1945                      if Is_Subprogram (S) then
1946                         Will_Be_Frozen := True;
1947                         exit;
1948                      elsif S = Scope (Base_Type (Comp)) then
1949                         exit;
1950                      end if;
1951
1952                      S := Scope (S);
1953                   end loop;
1954
1955                   if Will_Be_Frozen then
1956                      Undelay_Type (Comp);
1957                   else
1958                      if Present (Prev) then
1959                         Set_Next_Entity (Prev, Next_Entity (Comp));
1960                      else
1961                         Set_First_Entity (Rec, Next_Entity (Comp));
1962                      end if;
1963
1964                      --  Insert in entity list of scope of base type (which
1965                      --  must be an enclosing scope, because still unfrozen).
1966
1967                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1968                   end if;
1969                end;
1970
1971             --  If the component is an access type with an allocator as default
1972             --  value, the designated type will be frozen by the corresponding
1973             --  expression in init_proc. In order to place the freeze node for
1974             --  the designated type before that for the current record type,
1975             --  freeze it now.
1976
1977             --  Same process if the component is an array of access types,
1978             --  initialized with an aggregate. If the designated type is
1979             --  private, it cannot contain allocators, and it is premature
1980             --  to freeze the type, so we check for this as well.
1981
1982             elsif Is_Access_Type (Etype (Comp))
1983               and then Present (Parent (Comp))
1984               and then Present (Expression (Parent (Comp)))
1985             then
1986                declare
1987                   Alloc : constant Node_Id :=
1988                             Check_Allocator (Expression (Parent (Comp)));
1989
1990                begin
1991                   if Present (Alloc) then
1992
1993                      --  If component is pointer to a classwide type, freeze
1994                      --  the specific type in the expression being allocated.
1995                      --  The expression may be a subtype indication, in which
1996                      --  case freeze the subtype mark.
1997
1998                      if Is_Class_Wide_Type
1999                           (Designated_Type (Etype (Comp)))
2000                      then
2001                         if Is_Entity_Name (Expression (Alloc)) then
2002                            Freeze_And_Append
2003                              (Entity (Expression (Alloc)), N, Result);
2004                         elsif
2005                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2006                         then
2007                            Freeze_And_Append
2008                             (Entity (Subtype_Mark (Expression (Alloc))),
2009                              N, Result);
2010                         end if;
2011
2012                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2013                         Check_Itype (Etype (Comp));
2014
2015                      else
2016                         Freeze_And_Append
2017                           (Designated_Type (Etype (Comp)), N, Result);
2018                      end if;
2019                   end if;
2020                end;
2021
2022             elsif Is_Access_Type (Etype (Comp))
2023               and then Is_Itype (Designated_Type (Etype (Comp)))
2024             then
2025                Check_Itype (Etype (Comp));
2026
2027             elsif Is_Array_Type (Etype (Comp))
2028               and then Is_Access_Type (Component_Type (Etype (Comp)))
2029               and then Present (Parent (Comp))
2030               and then Nkind (Parent (Comp)) = N_Component_Declaration
2031               and then Present (Expression (Parent (Comp)))
2032               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2033               and then Is_Fully_Defined
2034                  (Designated_Type (Component_Type (Etype (Comp))))
2035             then
2036                Freeze_And_Append
2037                  (Designated_Type
2038                    (Component_Type (Etype (Comp))), N, Result);
2039             end if;
2040
2041             Prev := Comp;
2042             Next_Entity (Comp);
2043          end loop;
2044
2045          --  Deal with Bit_Order aspect specifying a non-default bit order
2046
2047          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2048             if not Placed_Component then
2049                ADC :=
2050                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2051                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2052                Error_Msg_N
2053                  ("\?since no component clauses were specified", ADC);
2054
2055             --  Here is where we do the processing for reversed bit order
2056
2057             else
2058                Adjust_Record_For_Reverse_Bit_Order (Rec);
2059             end if;
2060          end if;
2061
2062          --  Complete error checking on record representation clause (e.g.
2063          --  overlap of components). This is called after adjusting the
2064          --  record for reverse bit order.
2065
2066          declare
2067             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2068          begin
2069             if Present (RRC) then
2070                Check_Record_Representation_Clause (RRC);
2071             end if;
2072          end;
2073
2074          --  Set OK_To_Reorder_Components depending on debug flags
2075
2076          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2077             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2078                   or else
2079                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2080             then
2081                Set_OK_To_Reorder_Components (Rec);
2082             end if;
2083          end if;
2084
2085          --  Check for useless pragma Pack when all components placed. We only
2086          --  do this check for record types, not subtypes, since a subtype may
2087          --  have all its components placed, and it still makes perfectly good
2088          --  sense to pack other subtypes or the parent type. We do not give
2089          --  this warning if Optimize_Alignment is set to Space, since the
2090          --  pragma Pack does have an effect in this case (it always resets
2091          --  the alignment to one).
2092
2093          if Ekind (Rec) = E_Record_Type
2094            and then Is_Packed (Rec)
2095            and then not Unplaced_Component
2096            and then Optimize_Alignment /= 'S'
2097          then
2098             --  Reset packed status. Probably not necessary, but we do it so
2099             --  that there is no chance of the back end doing something strange
2100             --  with this redundant indication of packing.
2101
2102             Set_Is_Packed (Rec, False);
2103
2104             --  Give warning if redundant constructs warnings on
2105
2106             if Warn_On_Redundant_Constructs then
2107                Error_Msg_N -- CODEFIX
2108                  ("?pragma Pack has no effect, no unplaced components",
2109                   Get_Rep_Pragma (Rec, Name_Pack));
2110             end if;
2111          end if;
2112
2113          --  If this is the record corresponding to a remote type, freeze the
2114          --  remote type here since that is what we are semantically freezing.
2115          --  This prevents the freeze node for that type in an inner scope.
2116
2117          --  Also, Check for controlled components and unchecked unions.
2118          --  Finally, enforce the restriction that access attributes with a
2119          --  current instance prefix can only apply to limited types.
2120
2121          if Ekind (Rec) = E_Record_Type then
2122             if Present (Corresponding_Remote_Type (Rec)) then
2123                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2124             end if;
2125
2126             Comp := First_Component (Rec);
2127             while Present (Comp) loop
2128
2129                --  Do not set Has_Controlled_Component on a class-wide
2130                --  equivalent type. See Make_CW_Equivalent_Type.
2131
2132                if not Is_Class_Wide_Equivalent_Type (Rec)
2133                  and then (Has_Controlled_Component (Etype (Comp))
2134                             or else (Chars (Comp) /= Name_uParent
2135                                       and then Is_Controlled (Etype (Comp)))
2136                             or else (Is_Protected_Type (Etype (Comp))
2137                                       and then Present
2138                                         (Corresponding_Record_Type
2139                                           (Etype (Comp)))
2140                                       and then Has_Controlled_Component
2141                                         (Corresponding_Record_Type
2142                                           (Etype (Comp)))))
2143                then
2144                   Set_Has_Controlled_Component (Rec);
2145                   exit;
2146                end if;
2147
2148                if Has_Unchecked_Union (Etype (Comp)) then
2149                   Set_Has_Unchecked_Union (Rec);
2150                end if;
2151
2152                if Has_Per_Object_Constraint (Comp) then
2153
2154                   --  Scan component declaration for likely misuses of current
2155                   --  instance, either in a constraint or a default expression.
2156
2157                   Check_Current_Instance (Parent (Comp));
2158                end if;
2159
2160                Next_Component (Comp);
2161             end loop;
2162          end if;
2163
2164          Set_Component_Alignment_If_Not_Set (Rec);
2165
2166          --  For first subtypes, check if there are any fixed-point fields with
2167          --  component clauses, where we must check the size. This is not done
2168          --  till the freeze point, since for fixed-point types, we do not know
2169          --  the size until the type is frozen. Similar processing applies to
2170          --  bit packed arrays.
2171
2172          if Is_First_Subtype (Rec) then
2173             Comp := First_Component (Rec);
2174             while Present (Comp) loop
2175                if Present (Component_Clause (Comp))
2176                  and then (Is_Fixed_Point_Type (Etype (Comp))
2177                              or else
2178                            Is_Bit_Packed_Array (Etype (Comp)))
2179                then
2180                   Check_Size
2181                     (Component_Name (Component_Clause (Comp)),
2182                      Etype (Comp),
2183                      Esize (Comp),
2184                      Junk);
2185                end if;
2186
2187                Next_Component (Comp);
2188             end loop;
2189          end if;
2190
2191          --  Generate warning for applying C or C++ convention to a record
2192          --  with discriminants. This is suppressed for the unchecked union
2193          --  case, since the whole point in this case is interface C. We also
2194          --  do not generate this within instantiations, since we will have
2195          --  generated a message on the template.
2196
2197          if Has_Discriminants (E)
2198            and then not Is_Unchecked_Union (E)
2199            and then (Convention (E) = Convention_C
2200                        or else
2201                      Convention (E) = Convention_CPP)
2202            and then Comes_From_Source (E)
2203            and then not In_Instance
2204            and then not Has_Warnings_Off (E)
2205            and then not Has_Warnings_Off (Base_Type (E))
2206          then
2207             declare
2208                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2209                A2    : Node_Id;
2210
2211             begin
2212                if Present (Cprag) then
2213                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2214
2215                   if Convention (E) = Convention_C then
2216                      Error_Msg_N
2217                        ("?variant record has no direct equivalent in C", A2);
2218                   else
2219                      Error_Msg_N
2220                        ("?variant record has no direct equivalent in C++", A2);
2221                   end if;
2222
2223                   Error_Msg_NE
2224                     ("\?use of convention for type& is dubious", A2, E);
2225                end if;
2226             end;
2227          end if;
2228
2229          --  See if Size is too small as is (and implicit packing might help)
2230
2231          if not Is_Packed (Rec)
2232
2233            --  No implicit packing if even one component is explicitly placed
2234
2235            and then not Placed_Component
2236
2237            --  Must have size clause and all scalar components
2238
2239            and then Has_Size_Clause (Rec)
2240            and then All_Scalar_Components
2241
2242            --  Do not try implicit packing on records with discriminants, too
2243            --  complicated, especially in the variant record case.
2244
2245            and then not Has_Discriminants (Rec)
2246
2247            --  We can implicitly pack if the specified size of the record is
2248            --  less than the sum of the object sizes (no point in packing if
2249            --  this is not the case).
2250
2251            and then RM_Size (Rec) < Scalar_Component_Total_Esize
2252
2253            --  And the total RM size cannot be greater than the specified size
2254            --  since otherwise packing will not get us where we have to be!
2255
2256            and then RM_Size (Rec) >= Scalar_Component_Total_RM_Size
2257
2258            --  Never do implicit packing in CodePeer or Alfa modes since
2259            --  we don't do any packing in these modes, since this generates
2260            --  over-complex code that confuses static analysis, and in
2261            --  general, neither CodePeer not GNATprove care about the
2262            --  internal representation of objects.
2263
2264            and then not (CodePeer_Mode or Alfa_Mode)
2265          then
2266             --  If implicit packing enabled, do it
2267
2268             if Implicit_Packing then
2269                Set_Is_Packed (Rec);
2270
2271                --  Otherwise flag the size clause
2272
2273             else
2274                declare
2275                   Sz : constant Node_Id := Size_Clause (Rec);
2276                begin
2277                   Error_Msg_NE -- CODEFIX
2278                     ("size given for& too small", Sz, Rec);
2279                   Error_Msg_N -- CODEFIX
2280                     ("\use explicit pragma Pack "
2281                      & "or use pragma Implicit_Packing", Sz);
2282                end;
2283             end if;
2284          end if;
2285       end Freeze_Record_Type;
2286
2287    --  Start of processing for Freeze_Entity
2288
2289    begin
2290       --  We are going to test for various reasons why this entity need not be
2291       --  frozen here, but in the case of an Itype that's defined within a
2292       --  record, that test actually applies to the record.
2293
2294       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2295          Test_E := Scope (E);
2296       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2297         and then Is_Record_Type (Underlying_Type (Scope (E)))
2298       then
2299          Test_E := Underlying_Type (Scope (E));
2300       end if;
2301
2302       --  Do not freeze if already frozen since we only need one freeze node
2303
2304       if Is_Frozen (E) then
2305          return No_List;
2306
2307       --  It is improper to freeze an external entity within a generic because
2308       --  its freeze node will appear in a non-valid context. The entity will
2309       --  be frozen in the proper scope after the current generic is analyzed.
2310
2311       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2312          return No_List;
2313
2314       --  AI05-0213: A formal incomplete type does not freeze the actual. In
2315       --  the instance, the same applies to the subtype renaming the actual.
2316
2317       elsif Is_Private_Type (E)
2318         and then Is_Generic_Actual_Type (E)
2319         and then No (Full_View (Base_Type (E)))
2320         and then Ada_Version >= Ada_2012
2321       then
2322          return No_List;
2323
2324       --  Do not freeze a global entity within an inner scope created during
2325       --  expansion. A call to subprogram E within some internal procedure
2326       --  (a stream attribute for example) might require freezing E, but the
2327       --  freeze node must appear in the same declarative part as E itself.
2328       --  The two-pass elaboration mechanism in gigi guarantees that E will
2329       --  be frozen before the inner call is elaborated. We exclude constants
2330       --  from this test, because deferred constants may be frozen early, and
2331       --  must be diagnosed (e.g. in the case of a deferred constant being used
2332       --  in a default expression). If the enclosing subprogram comes from
2333       --  source, or is a generic instance, then the freeze point is the one
2334       --  mandated by the language, and we freeze the entity. A subprogram that
2335       --  is a child unit body that acts as a spec does not have a spec that
2336       --  comes from source, but can only come from source.
2337
2338       elsif In_Open_Scopes (Scope (Test_E))
2339         and then Scope (Test_E) /= Current_Scope
2340         and then Ekind (Test_E) /= E_Constant
2341       then
2342          declare
2343             S : Entity_Id;
2344
2345          begin
2346             S := Current_Scope;
2347             while Present (S) loop
2348                if Is_Overloadable (S) then
2349                   if Comes_From_Source (S)
2350                     or else Is_Generic_Instance (S)
2351                     or else Is_Child_Unit (S)
2352                   then
2353                      exit;
2354                   else
2355                      return No_List;
2356                   end if;
2357                end if;
2358
2359                S := Scope (S);
2360             end loop;
2361          end;
2362
2363       --  Similarly, an inlined instance body may make reference to global
2364       --  entities, but these references cannot be the proper freezing point
2365       --  for them, and in the absence of inlining freezing will take place in
2366       --  their own scope. Normally instance bodies are analyzed after the
2367       --  enclosing compilation, and everything has been frozen at the proper
2368       --  place, but with front-end inlining an instance body is compiled
2369       --  before the end of the enclosing scope, and as a result out-of-order
2370       --  freezing must be prevented.
2371
2372       elsif Front_End_Inlining
2373         and then In_Instance_Body
2374         and then Present (Scope (Test_E))
2375       then
2376          declare
2377             S : Entity_Id;
2378
2379          begin
2380             S := Scope (Test_E);
2381             while Present (S) loop
2382                if Is_Generic_Instance (S) then
2383                   exit;
2384                else
2385                   S := Scope (S);
2386                end if;
2387             end loop;
2388
2389             if No (S) then
2390                return No_List;
2391             end if;
2392          end;
2393       end if;
2394
2395       --  Deal with delayed aspect specifications. The analysis of the aspect
2396       --  is required to be delayed to the freeze point, so we evaluate the
2397       --  pragma or attribute definition clause in the tree at this point.
2398
2399       if Has_Delayed_Aspects (E) then
2400          declare
2401             Ritem : Node_Id;
2402             Aitem : Node_Id;
2403
2404          begin
2405             --  Look for aspect specification entries for this entity
2406
2407             Ritem := First_Rep_Item (E);
2408             while Present (Ritem) loop
2409                if Nkind (Ritem) = N_Aspect_Specification
2410                  and then Entity (Ritem) = E
2411                  and then Is_Delayed_Aspect (Ritem)
2412                  and then Scope (E) = Current_Scope
2413                then
2414                   Aitem := Aspect_Rep_Item (Ritem);
2415
2416                   --  Skip if this is an aspect with no corresponding pragma
2417                   --  or attribute definition node (such as Default_Value).
2418
2419                   if Present (Aitem) then
2420                      Set_Parent (Aitem, Ritem);
2421                      Analyze (Aitem);
2422                   end if;
2423                end if;
2424
2425                Next_Rep_Item (Ritem);
2426             end loop;
2427          end;
2428       end if;
2429
2430       --  Here to freeze the entity
2431
2432       Set_Is_Frozen (E);
2433
2434       --  Case of entity being frozen is other than a type
2435
2436       if not Is_Type (E) then
2437
2438          --  If entity is exported or imported and does not have an external
2439          --  name, now is the time to provide the appropriate default name.
2440          --  Skip this if the entity is stubbed, since we don't need a name
2441          --  for any stubbed routine. For the case on intrinsics, if no
2442          --  external name is specified, then calls will be handled in
2443          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2444          --  external name is provided, then Expand_Intrinsic_Call leaves
2445          --  calls in place for expansion by GIGI.
2446
2447          if (Is_Imported (E) or else Is_Exported (E))
2448            and then No (Interface_Name (E))
2449            and then Convention (E) /= Convention_Stubbed
2450            and then Convention (E) /= Convention_Intrinsic
2451          then
2452             Set_Encoded_Interface_Name
2453               (E, Get_Default_External_Name (E));
2454
2455          --  If entity is an atomic object appearing in a declaration and
2456          --  the expression is an aggregate, assign it to a temporary to
2457          --  ensure that the actual assignment is done atomically rather
2458          --  than component-wise (the assignment to the temp may be done
2459          --  component-wise, but that is harmless).
2460
2461          elsif Is_Atomic (E)
2462            and then Nkind (Parent (E)) = N_Object_Declaration
2463            and then Present (Expression (Parent (E)))
2464            and then Nkind (Expression (Parent (E))) = N_Aggregate
2465            and then Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2466          then
2467             null;
2468          end if;
2469
2470          --  For a subprogram, freeze all parameter types and also the return
2471          --  type (RM 13.14(14)). However skip this for internal subprograms.
2472          --  This is also the point where any extra formal parameters are
2473          --  created since we now know whether the subprogram will use a
2474          --  foreign convention.
2475
2476          if Is_Subprogram (E) then
2477             if not Is_Internal (E) then
2478                declare
2479                   F_Type    : Entity_Id;
2480                   R_Type    : Entity_Id;
2481                   Warn_Node : Node_Id;
2482
2483                begin
2484                   --  Loop through formals
2485
2486                   Formal := First_Formal (E);
2487                   while Present (Formal) loop
2488                      F_Type := Etype (Formal);
2489
2490                      --  AI05-0151 : incomplete types can appear in a profile.
2491                      --  By the time the entity is frozen, the full view must
2492                      --  be available, unless it is a limited view.
2493
2494                      if Is_Incomplete_Type (F_Type)
2495                        and then Present (Full_View (F_Type))
2496                      then
2497                         F_Type := Full_View (F_Type);
2498                         Set_Etype (Formal, F_Type);
2499                      end if;
2500
2501                      Freeze_And_Append (F_Type, N, Result);
2502
2503                      if Is_Private_Type (F_Type)
2504                        and then Is_Private_Type (Base_Type (F_Type))
2505                        and then No (Full_View (Base_Type (F_Type)))
2506                        and then not Is_Generic_Type (F_Type)
2507                        and then not Is_Derived_Type (F_Type)
2508                      then
2509                         --  If the type of a formal is incomplete, subprogram
2510                         --  is being frozen prematurely. Within an instance
2511                         --  (but not within a wrapper package) this is an
2512                         --  artifact of our need to regard the end of an
2513                         --  instantiation as a freeze point. Otherwise it is
2514                         --  a definite error.
2515
2516                         if In_Instance then
2517                            Set_Is_Frozen (E, False);
2518                            return No_List;
2519
2520                         elsif not After_Last_Declaration
2521                           and then not Freezing_Library_Level_Tagged_Type
2522                         then
2523                            Error_Msg_Node_1 := F_Type;
2524                            Error_Msg
2525                              ("type& must be fully defined before this point",
2526                                Loc);
2527                         end if;
2528                      end if;
2529
2530                      --  Check suspicious parameter for C function. These tests
2531                      --  apply only to exported/imported subprograms.
2532
2533                      if Warn_On_Export_Import
2534                        and then Comes_From_Source (E)
2535                        and then (Convention (E) = Convention_C
2536                                    or else
2537                                  Convention (E) = Convention_CPP)
2538                        and then (Is_Imported (E) or else Is_Exported (E))
2539                        and then Convention (E) /= Convention (Formal)
2540                        and then not Has_Warnings_Off (E)
2541                        and then not Has_Warnings_Off (F_Type)
2542                        and then not Has_Warnings_Off (Formal)
2543                      then
2544                         --  Qualify mention of formals with subprogram name
2545
2546                         Error_Msg_Qual_Level := 1;
2547
2548                         --  Check suspicious use of fat C pointer
2549
2550                         if Is_Access_Type (F_Type)
2551                           and then Esize (F_Type) > Ttypes.System_Address_Size
2552                         then
2553                            Error_Msg_N
2554                              ("?type of & does not correspond to C pointer!",
2555                               Formal);
2556
2557                         --  Check suspicious return of boolean
2558
2559                         elsif Root_Type (F_Type) = Standard_Boolean
2560                           and then Convention (F_Type) = Convention_Ada
2561                           and then not Has_Warnings_Off (F_Type)
2562                           and then not Has_Size_Clause (F_Type)
2563                           and then VM_Target = No_VM
2564                         then
2565                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2566                            Error_Msg_N
2567                              ("\use appropriate corresponding type in C "
2568                               & "(e.g. char)?", Formal);
2569
2570                         --  Check suspicious tagged type
2571
2572                         elsif (Is_Tagged_Type (F_Type)
2573                                 or else (Is_Access_Type (F_Type)
2574                                            and then
2575                                              Is_Tagged_Type
2576                                                (Designated_Type (F_Type))))
2577                           and then Convention (E) = Convention_C
2578                         then
2579                            Error_Msg_N
2580                              ("?& involves a tagged type which does not "
2581                               & "correspond to any C type!", Formal);
2582
2583                         --  Check wrong convention subprogram pointer
2584
2585                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2586                           and then not Has_Foreign_Convention (F_Type)
2587                         then
2588                            Error_Msg_N
2589                              ("?subprogram pointer & should "
2590                               & "have foreign convention!", Formal);
2591                            Error_Msg_Sloc := Sloc (F_Type);
2592                            Error_Msg_NE
2593                              ("\?add Convention pragma to declaration of &#",
2594                               Formal, F_Type);
2595                         end if;
2596
2597                         --  Turn off name qualification after message output
2598
2599                         Error_Msg_Qual_Level := 0;
2600                      end if;
2601
2602                      --  Check for unconstrained array in exported foreign
2603                      --  convention case.
2604
2605                      if Has_Foreign_Convention (E)
2606                        and then not Is_Imported (E)
2607                        and then Is_Array_Type (F_Type)
2608                        and then not Is_Constrained (F_Type)
2609                        and then Warn_On_Export_Import
2610
2611                        --  Exclude VM case, since both .NET and JVM can handle
2612                        --  unconstrained arrays without a problem.
2613
2614                        and then VM_Target = No_VM
2615                      then
2616                         Error_Msg_Qual_Level := 1;
2617
2618                         --  If this is an inherited operation, place the
2619                         --  warning on the derived type declaration, rather
2620                         --  than on the original subprogram.
2621
2622                         if Nkind (Original_Node (Parent (E))) =
2623                           N_Full_Type_Declaration
2624                         then
2625                            Warn_Node := Parent (E);
2626
2627                            if Formal = First_Formal (E) then
2628                               Error_Msg_NE
2629                                 ("?in inherited operation&", Warn_Node, E);
2630                            end if;
2631                         else
2632                            Warn_Node := Formal;
2633                         end if;
2634
2635                         Error_Msg_NE
2636                           ("?type of argument& is unconstrained array",
2637                            Warn_Node, Formal);
2638                         Error_Msg_NE
2639                           ("?foreign caller must pass bounds explicitly",
2640                            Warn_Node, Formal);
2641                         Error_Msg_Qual_Level := 0;
2642                      end if;
2643
2644                      if not From_With_Type (F_Type) then
2645                         if Is_Access_Type (F_Type) then
2646                            F_Type := Designated_Type (F_Type);
2647                         end if;
2648
2649                         --  If the formal is an anonymous_access_to_subprogram
2650                         --  freeze the  subprogram type as well, to prevent
2651                         --  scope anomalies in gigi, because there is no other
2652                         --  clear point at which it could be frozen.
2653
2654                         if Is_Itype (Etype (Formal))
2655                           and then Ekind (F_Type) = E_Subprogram_Type
2656                         then
2657                            Freeze_And_Append (F_Type, N, Result);
2658                         end if;
2659                      end if;
2660
2661                      Next_Formal (Formal);
2662                   end loop;
2663
2664                   --  Case of function: similar checks on return type
2665
2666                   if Ekind (E) = E_Function then
2667
2668                      --  Freeze return type
2669
2670                      R_Type := Etype (E);
2671
2672                      --  AI05-0151: the return type may have been incomplete
2673                      --  at the point of declaration.
2674
2675                      if Ekind (R_Type) = E_Incomplete_Type
2676                        and then Present (Full_View (R_Type))
2677                      then
2678                         R_Type := Full_View (R_Type);
2679                         Set_Etype (E, R_Type);
2680                      end if;
2681
2682                      Freeze_And_Append (R_Type, N, Result);
2683
2684                      --  Check suspicious return type for C function
2685
2686                      if Warn_On_Export_Import
2687                        and then (Convention (E) = Convention_C
2688                                    or else
2689                                  Convention (E) = Convention_CPP)
2690                        and then (Is_Imported (E) or else Is_Exported (E))
2691                      then
2692                         --  Check suspicious return of fat C pointer
2693
2694                         if Is_Access_Type (R_Type)
2695                           and then Esize (R_Type) > Ttypes.System_Address_Size
2696                           and then not Has_Warnings_Off (E)
2697                           and then not Has_Warnings_Off (R_Type)
2698                         then
2699                            Error_Msg_N
2700                              ("?return type of& does not "
2701                               & "correspond to C pointer!", E);
2702
2703                         --  Check suspicious return of boolean
2704
2705                         elsif Root_Type (R_Type) = Standard_Boolean
2706                           and then Convention (R_Type) = Convention_Ada
2707                           and then VM_Target = No_VM
2708                           and then not Has_Warnings_Off (E)
2709                           and then not Has_Warnings_Off (R_Type)
2710                           and then not Has_Size_Clause (R_Type)
2711                         then
2712                            declare
2713                               N : constant Node_Id :=
2714                                     Result_Definition (Declaration_Node (E));
2715                            begin
2716                               Error_Msg_NE
2717                                 ("return type of & is an 8-bit Ada Boolean?",
2718                                  N, E);
2719                               Error_Msg_NE
2720                                 ("\use appropriate corresponding type in C "
2721                                  & "(e.g. char)?", N, E);
2722                            end;
2723
2724                         --  Check suspicious return tagged type
2725
2726                         elsif (Is_Tagged_Type (R_Type)
2727                                 or else (Is_Access_Type (R_Type)
2728                                            and then
2729                                              Is_Tagged_Type
2730                                                (Designated_Type (R_Type))))
2731                           and then Convention (E) = Convention_C
2732                           and then not Has_Warnings_Off (E)
2733                           and then not Has_Warnings_Off (R_Type)
2734                         then
2735                            Error_Msg_N
2736                              ("?return type of & does not "
2737                               & "correspond to C type!", E);
2738
2739                         --  Check return of wrong convention subprogram pointer
2740
2741                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2742                           and then not Has_Foreign_Convention (R_Type)
2743                           and then not Has_Warnings_Off (E)
2744                           and then not Has_Warnings_Off (R_Type)
2745                         then
2746                            Error_Msg_N
2747                              ("?& should return a foreign "
2748                               & "convention subprogram pointer", E);
2749                            Error_Msg_Sloc := Sloc (R_Type);
2750                            Error_Msg_NE
2751                              ("\?add Convention pragma to declaration of& #",
2752                               E, R_Type);
2753                         end if;
2754                      end if;
2755
2756                      --  Give warning for suspicious return of a result of an
2757                      --  unconstrained array type in a foreign convention
2758                      --  function.
2759
2760                      if Has_Foreign_Convention (E)
2761
2762                        --  We are looking for a return of unconstrained array
2763
2764                        and then Is_Array_Type (R_Type)
2765                        and then not Is_Constrained (R_Type)
2766
2767                        --  Exclude imported routines, the warning does not
2768                        --  belong on the import, but rather on the routine
2769                        --  definition.
2770
2771                        and then not Is_Imported (E)
2772
2773                        --  Exclude VM case, since both .NET and JVM can handle
2774                        --  return of unconstrained arrays without a problem.
2775
2776                        and then VM_Target = No_VM
2777
2778                        --  Check that general warning is enabled, and that it
2779                        --  is not suppressed for this particular case.
2780
2781                        and then Warn_On_Export_Import
2782                        and then not Has_Warnings_Off (E)
2783                        and then not Has_Warnings_Off (R_Type)
2784                      then
2785                         Error_Msg_N
2786                           ("?foreign convention function& should not " &
2787                            "return unconstrained array!", E);
2788                      end if;
2789                   end if;
2790                end;
2791             end if;
2792
2793             --  Must freeze its parent first if it is a derived subprogram
2794
2795             if Present (Alias (E)) then
2796                Freeze_And_Append (Alias (E), N, Result);
2797             end if;
2798
2799             --  We don't freeze internal subprograms, because we don't normally
2800             --  want addition of extra formals or mechanism setting to happen
2801             --  for those. However we do pass through predefined dispatching
2802             --  cases, since extra formals may be needed in some cases, such as
2803             --  for the stream 'Input function (build-in-place formals).
2804
2805             if not Is_Internal (E)
2806               or else Is_Predefined_Dispatching_Operation (E)
2807             then
2808                Freeze_Subprogram (E);
2809             end if;
2810
2811          --  Here for other than a subprogram or type
2812
2813          else
2814             --  If entity has a type, and it is not a generic unit, then
2815             --  freeze it first (RM 13.14(10)).
2816
2817             if Present (Etype (E))
2818               and then Ekind (E) /= E_Generic_Function
2819             then
2820                Freeze_And_Append (Etype (E), N, Result);
2821             end if;
2822
2823             --  Special processing for objects created by object declaration
2824
2825             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2826
2827                --  Abstract type allowed only for C++ imported variables or
2828                --  constants.
2829
2830                --  Note: we inhibit this check for objects that do not come
2831                --  from source because there is at least one case (the
2832                --  expansion of x'Class'Input where x is abstract) where we
2833                --  legitimately generate an abstract object.
2834
2835                if Is_Abstract_Type (Etype (E))
2836                  and then Comes_From_Source (Parent (E))
2837                  and then not (Is_Imported (E)
2838                                  and then Is_CPP_Class (Etype (E)))
2839                then
2840                   Error_Msg_N ("type of object cannot be abstract",
2841                                Object_Definition (Parent (E)));
2842
2843                   if Is_CPP_Class (Etype (E)) then
2844                      Error_Msg_NE
2845                        ("\} may need a cpp_constructor",
2846                        Object_Definition (Parent (E)), Etype (E));
2847                   end if;
2848                end if;
2849
2850                --  For object created by object declaration, perform required
2851                --  categorization (preelaborate and pure) checks. Defer these
2852                --  checks to freeze time since pragma Import inhibits default
2853                --  initialization and thus pragma Import affects these checks.
2854
2855                Validate_Object_Declaration (Declaration_Node (E));
2856
2857                --  If there is an address clause, check that it is valid
2858
2859                Check_Address_Clause (E);
2860
2861                --  If the object needs any kind of default initialization, an
2862                --  error must be issued if No_Default_Initialization applies.
2863                --  The check doesn't apply to imported objects, which are not
2864                --  ever default initialized, and is why the check is deferred
2865                --  until freezing, at which point we know if Import applies.
2866                --  Deferred constants are also exempted from this test because
2867                --  their completion is explicit, or through an import pragma.
2868
2869                if Ekind (E) = E_Constant
2870                  and then Present (Full_View (E))
2871                then
2872                   null;
2873
2874                elsif Comes_From_Source (E)
2875                  and then not Is_Imported (E)
2876                  and then not Has_Init_Expression (Declaration_Node (E))
2877                  and then
2878                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2879                       and then not No_Initialization (Declaration_Node (E))
2880                       and then not Is_Value_Type (Etype (E))
2881                       and then not Initialization_Suppressed (Etype (E)))
2882                     or else
2883                       (Needs_Simple_Initialization (Etype (E))
2884                         and then not Is_Internal (E)))
2885                then
2886                   Has_Default_Initialization := True;
2887                   Check_Restriction
2888                     (No_Default_Initialization, Declaration_Node (E));
2889                end if;
2890
2891                --  Check that a Thread_Local_Storage variable does not have
2892                --  default initialization, and any explicit initialization must
2893                --  either be the null constant or a static constant.
2894
2895                if Has_Pragma_Thread_Local_Storage (E) then
2896                   declare
2897                      Decl : constant Node_Id := Declaration_Node (E);
2898                   begin
2899                      if Has_Default_Initialization
2900                        or else
2901                          (Has_Init_Expression (Decl)
2902                             and then
2903                              (No (Expression (Decl))
2904                                 or else not
2905                                   (Is_Static_Expression (Expression (Decl))
2906                                      or else
2907                                    Nkind (Expression (Decl)) = N_Null)))
2908                      then
2909                         Error_Msg_NE
2910                           ("Thread_Local_Storage variable& is "
2911                            & "improperly initialized", Decl, E);
2912                         Error_Msg_NE
2913                           ("\only allowed initialization is explicit "
2914                            & "NULL or static expression", Decl, E);
2915                      end if;
2916                   end;
2917                end if;
2918
2919                --  For imported objects, set Is_Public unless there is also an
2920                --  address clause, which means that there is no external symbol
2921                --  needed for the Import (Is_Public may still be set for other
2922                --  unrelated reasons). Note that we delayed this processing
2923                --  till freeze time so that we can be sure not to set the flag
2924                --  if there is an address clause. If there is such a clause,
2925                --  then the only purpose of the Import pragma is to suppress
2926                --  implicit initialization.
2927
2928                if Is_Imported (E)
2929                  and then No (Address_Clause (E))
2930                then
2931                   Set_Is_Public (E);
2932                end if;
2933
2934                --  For convention C objects of an enumeration type, warn if
2935                --  the size is not integer size and no explicit size given.
2936                --  Skip warning for Boolean, and Character, assume programmer
2937                --  expects 8-bit sizes for these cases.
2938
2939                if (Convention (E) = Convention_C
2940                     or else
2941                    Convention (E) = Convention_CPP)
2942                  and then Is_Enumeration_Type (Etype (E))
2943                  and then not Is_Character_Type (Etype (E))
2944                  and then not Is_Boolean_Type (Etype (E))
2945                  and then Esize (Etype (E)) < Standard_Integer_Size
2946                  and then not Has_Size_Clause (E)
2947                then
2948                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2949                   Error_Msg_N
2950                     ("?convention C enumeration object has size less than ^",
2951                      E);
2952                   Error_Msg_N ("\?use explicit size clause to set size", E);
2953                end if;
2954             end if;
2955
2956             --  Check that a constant which has a pragma Volatile[_Components]
2957             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2958
2959             --  Note: Atomic[_Components] also sets Volatile[_Components]
2960
2961             if Ekind (E) = E_Constant
2962               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2963               and then not Is_Imported (E)
2964             then
2965                --  Make sure we actually have a pragma, and have not merely
2966                --  inherited the indication from elsewhere (e.g. an address
2967                --  clause, which is not good enough in RM terms!)
2968
2969                if Has_Rep_Pragma (E, Name_Atomic)
2970                     or else
2971                   Has_Rep_Pragma (E, Name_Atomic_Components)
2972                then
2973                   Error_Msg_N
2974                     ("stand alone atomic constant must be " &
2975                      "imported (RM C.6(13))", E);
2976
2977                elsif Has_Rep_Pragma (E, Name_Volatile)
2978                        or else
2979                      Has_Rep_Pragma (E, Name_Volatile_Components)
2980                then
2981                   Error_Msg_N
2982                     ("stand alone volatile constant must be " &
2983                      "imported (RM C.6(13))", E);
2984                end if;
2985             end if;
2986
2987             --  Static objects require special handling
2988
2989             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2990               and then Is_Statically_Allocated (E)
2991             then
2992                Freeze_Static_Object (E);
2993             end if;
2994
2995             --  Remaining step is to layout objects
2996
2997             if Ekind (E) = E_Variable
2998                  or else
2999                Ekind (E) = E_Constant
3000                  or else
3001                Ekind (E) = E_Loop_Parameter
3002                  or else
3003                Is_Formal (E)
3004             then
3005                Layout_Object (E);
3006             end if;
3007          end if;
3008
3009       --  Case of a type or subtype being frozen
3010
3011       else
3012          --  We used to check here that a full type must have preelaborable
3013          --  initialization if it completes a private type specified with
3014          --  pragma Preelaborable_Initialization, but that missed cases where
3015          --  the types occur within a generic package, since the freezing
3016          --  that occurs within a containing scope generally skips traversal
3017          --  of a generic unit's declarations (those will be frozen within
3018          --  instances). This check was moved to Analyze_Package_Specification.
3019
3020          --  The type may be defined in a generic unit. This can occur when
3021          --  freezing a generic function that returns the type (which is
3022          --  defined in a parent unit). It is clearly meaningless to freeze
3023          --  this type. However, if it is a subtype, its size may be determi-
3024          --  nable and used in subsequent checks, so might as well try to
3025          --  compute it.
3026
3027          if Present (Scope (E))
3028            and then Is_Generic_Unit (Scope (E))
3029          then
3030             Check_Compile_Time_Size (E);
3031             return No_List;
3032          end if;
3033
3034          --  Deal with special cases of freezing for subtype
3035
3036          if E /= Base_Type (E) then
3037
3038             --  Before we do anything else, a specialized test for the case of
3039             --  a size given for an array where the array needs to be packed,
3040             --  but was not so the size cannot be honored. This would of course
3041             --  be caught by the backend, and indeed we don't catch all cases.
3042             --  The point is that we can give a better error message in those
3043             --  cases that we do catch with the circuitry here. Also if pragma
3044             --  Implicit_Packing is set, this is where the packing occurs.
3045
3046             --  The reason we do this so early is that the processing in the
3047             --  automatic packing case affects the layout of the base type, so
3048             --  it must be done before we freeze the base type.
3049
3050             if Is_Array_Type (E) then
3051                declare
3052                   Lo, Hi : Node_Id;
3053                   Ctyp   : constant Entity_Id := Component_Type (E);
3054
3055                begin
3056                   --  Check enabling conditions. These are straightforward
3057                   --  except for the test for a limited composite type. This
3058                   --  eliminates the rare case of a array of limited components
3059                   --  where there are issues of whether or not we can go ahead
3060                   --  and pack the array (since we can't freely pack and unpack
3061                   --  arrays if they are limited).
3062
3063                   --  Note that we check the root type explicitly because the
3064                   --  whole point is we are doing this test before we have had
3065                   --  a chance to freeze the base type (and it is that freeze
3066                   --  action that causes stuff to be inherited).
3067
3068                   if Present (Size_Clause (E))
3069                     and then Known_Static_RM_Size (E)
3070                     and then not Is_Packed (E)
3071                     and then not Has_Pragma_Pack (E)
3072                     and then Number_Dimensions (E) = 1
3073                     and then not Has_Component_Size_Clause (E)
3074                     and then Known_Static_RM_Size (Ctyp)
3075                     and then not Is_Limited_Composite (E)
3076                     and then not Is_Packed (Root_Type (E))
3077                     and then not Has_Component_Size_Clause (Root_Type (E))
3078                     and then not (CodePeer_Mode or Alfa_Mode)
3079                   then
3080                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3081
3082                      if Compile_Time_Known_Value (Lo)
3083                        and then Compile_Time_Known_Value (Hi)
3084                        and then Known_Static_RM_Size (Ctyp)
3085                        and then RM_Size (Ctyp) < 64
3086                      then
3087                         declare
3088                            Lov  : constant Uint      := Expr_Value (Lo);
3089                            Hiv  : constant Uint      := Expr_Value (Hi);
3090                            Len  : constant Uint      := UI_Max
3091                                                          (Uint_0,
3092                                                           Hiv - Lov + 1);
3093                            Rsiz : constant Uint      := RM_Size (Ctyp);
3094                            SZ   : constant Node_Id   := Size_Clause (E);
3095                            Btyp : constant Entity_Id := Base_Type (E);
3096
3097                         --  What we are looking for here is the situation where
3098                         --  the RM_Size given would be exactly right if there
3099                         --  was a pragma Pack (resulting in the component size
3100                         --  being the same as the RM_Size). Furthermore, the
3101                         --  component type size must be an odd size (not a
3102                         --  multiple of storage unit). If the component RM size
3103                         --  is an exact number of storage units that is a power
3104                         --  of two, the array is not packed and has a standard
3105                         --  representation.
3106
3107                         begin
3108                            if RM_Size (E) = Len * Rsiz
3109                              and then Rsiz mod System_Storage_Unit /= 0
3110                            then
3111                               --  For implicit packing mode, just set the
3112                               --  component size silently.
3113
3114                               if Implicit_Packing then
3115                                  Set_Component_Size       (Btyp, Rsiz);
3116                                  Set_Is_Bit_Packed_Array  (Btyp);
3117                                  Set_Is_Packed            (Btyp);
3118                                  Set_Has_Non_Standard_Rep (Btyp);
3119
3120                                  --  Otherwise give an error message
3121
3122                               else
3123                                  Error_Msg_NE
3124                                    ("size given for& too small", SZ, E);
3125                                  Error_Msg_N -- CODEFIX
3126                                    ("\use explicit pragma Pack "
3127                                     & "or use pragma Implicit_Packing", SZ);
3128                               end if;
3129
3130                            elsif RM_Size (E) = Len * Rsiz
3131                              and then Implicit_Packing
3132                              and then
3133                                (Rsiz / System_Storage_Unit = 1
3134                                  or else Rsiz / System_Storage_Unit = 2
3135                                  or else Rsiz / System_Storage_Unit = 4)
3136                            then
3137
3138                               --  Not a packed array, but indicate the desired
3139                               --  component size, for the back-end.
3140
3141                               Set_Component_Size (Btyp, Rsiz);
3142                            end if;
3143                         end;
3144                      end if;
3145                   end if;
3146                end;
3147             end if;
3148
3149             --  If ancestor subtype present, freeze that first. Note that this
3150             --  will also get the base type frozen. Need RM reference ???
3151
3152             Atype := Ancestor_Subtype (E);
3153
3154             if Present (Atype) then
3155                Freeze_And_Append (Atype, N, Result);
3156
3157             --  No ancestor subtype present
3158
3159             else
3160                --  See if we have a nearest ancestor that has a predicate.
3161                --  That catches the case of derived type with a predicate.
3162                --  Need RM reference here ???
3163
3164                Atype := Nearest_Ancestor (E);
3165
3166                if Present (Atype) and then Has_Predicates (Atype) then
3167                   Freeze_And_Append (Atype, N, Result);
3168                end if;
3169
3170                --  Freeze base type before freezing the entity (RM 13.14(15))
3171
3172                if E /= Base_Type (E) then
3173                   Freeze_And_Append (Base_Type (E), N, Result);
3174                end if;
3175             end if;
3176
3177          --  For a derived type, freeze its parent type first (RM 13.14(15))
3178
3179          elsif Is_Derived_Type (E) then
3180             Freeze_And_Append (Etype (E), N, Result);
3181             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3182          end if;
3183
3184          --  For array type, freeze index types and component type first
3185          --  before freezing the array (RM 13.14(15)).
3186
3187          if Is_Array_Type (E) then
3188             declare
3189                FS     : constant Entity_Id := First_Subtype (E);
3190                Ctyp   : constant Entity_Id := Component_Type (E);
3191                Clause : Entity_Id;
3192
3193                Non_Standard_Enum : Boolean := False;
3194                --  Set true if any of the index types is an enumeration type
3195                --  with a non-standard representation.
3196
3197             begin
3198                Freeze_And_Append (Ctyp, N, Result);
3199
3200                Indx := First_Index (E);
3201                while Present (Indx) loop
3202                   Freeze_And_Append (Etype (Indx), N, Result);
3203
3204                   if Is_Enumeration_Type (Etype (Indx))
3205                     and then Has_Non_Standard_Rep (Etype (Indx))
3206                   then
3207                      Non_Standard_Enum := True;
3208                   end if;
3209
3210                   Next_Index (Indx);
3211                end loop;
3212
3213                --  Processing that is done only for base types
3214
3215                if Ekind (E) = E_Array_Type then
3216
3217                   --  Propagate flags for component type
3218
3219                   if Is_Controlled (Component_Type (E))
3220                     or else Has_Controlled_Component (Ctyp)
3221                   then
3222                      Set_Has_Controlled_Component (E);
3223                   end if;
3224
3225                   if Has_Unchecked_Union (Component_Type (E)) then
3226                      Set_Has_Unchecked_Union (E);
3227                   end if;
3228
3229                   --  If packing was requested or if the component size was set
3230                   --  explicitly, then see if bit packing is required. This
3231                   --  processing is only done for base types, since all the
3232                   --  representation aspects involved are type-related. This
3233                   --  is not just an optimization, if we start processing the
3234                   --  subtypes, they interfere with the settings on the base
3235                   --  type (this is because Is_Packed has a slightly different
3236                   --  meaning before and after freezing).
3237
3238                   declare
3239                      Csiz : Uint;
3240                      Esiz : Uint;
3241
3242                   begin
3243                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3244                        and then Known_Static_RM_Size (Ctyp)
3245                        and then not Has_Component_Size_Clause (E)
3246                      then
3247                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3248
3249                      elsif Known_Component_Size (E) then
3250                         Csiz := Component_Size (E);
3251
3252                      elsif not Known_Static_Esize (Ctyp) then
3253                         Csiz := Uint_0;
3254
3255                      else
3256                         Esiz := Esize (Ctyp);
3257
3258                         --  We can set the component size if it is less than
3259                         --  16, rounding it up to the next storage unit size.
3260
3261                         if Esiz <= 8 then
3262                            Csiz := Uint_8;
3263                         elsif Esiz <= 16 then
3264                            Csiz := Uint_16;
3265                         else
3266                            Csiz := Uint_0;
3267                         end if;
3268
3269                         --  Set component size up to match alignment if it
3270                         --  would otherwise be less than the alignment. This
3271                         --  deals with cases of types whose alignment exceeds
3272                         --  their size (padded types).
3273
3274                         if Csiz /= 0 then
3275                            declare
3276                               A : constant Uint := Alignment_In_Bits (Ctyp);
3277                            begin
3278                               if Csiz < A then
3279                                  Csiz := A;
3280                               end if;
3281                            end;
3282                         end if;
3283                      end if;
3284
3285                      --  Case of component size that may result in packing
3286
3287                      if 1 <= Csiz and then Csiz <= 64 then
3288                         declare
3289                            Ent         : constant Entity_Id :=
3290                                            First_Subtype (E);
3291                            Pack_Pragma : constant Node_Id :=
3292                                            Get_Rep_Pragma (Ent, Name_Pack);
3293                            Comp_Size_C : constant Node_Id :=
3294                                            Get_Attribute_Definition_Clause
3295                                              (Ent, Attribute_Component_Size);
3296                         begin
3297                            --  Warn if we have pack and component size so that
3298                            --  the pack is ignored.
3299
3300                            --  Note: here we must check for the presence of a
3301                            --  component size before checking for a Pack pragma
3302                            --  to deal with the case where the array type is a
3303                            --  derived type whose parent is currently private.
3304
3305                            if Present (Comp_Size_C)
3306                              and then Has_Pragma_Pack (Ent)
3307                              and then Warn_On_Redundant_Constructs
3308                            then
3309                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3310                               Error_Msg_NE
3311                                 ("?pragma Pack for& ignored!",
3312                                  Pack_Pragma, Ent);
3313                               Error_Msg_N
3314                                 ("\?explicit component size given#!",
3315                                  Pack_Pragma);
3316                               Set_Is_Packed (Base_Type (Ent), False);
3317                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3318                            end if;
3319
3320                            --  Set component size if not already set by a
3321                            --  component size clause.
3322
3323                            if not Present (Comp_Size_C) then
3324                               Set_Component_Size (E, Csiz);
3325                            end if;
3326
3327                            --  Check for base type of 8, 16, 32 bits, where an
3328                            --  unsigned subtype has a length one less than the
3329                            --  base type (e.g. Natural subtype of Integer).
3330
3331                            --  In such cases, if a component size was not set
3332                            --  explicitly, then generate a warning.
3333
3334                            if Has_Pragma_Pack (E)
3335                              and then not Present (Comp_Size_C)
3336                              and then
3337                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3338                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3339                            then
3340                               Error_Msg_Uint_1 := Csiz;
3341
3342                               if Present (Pack_Pragma) then
3343                                  Error_Msg_N
3344                                    ("?pragma Pack causes component size "
3345                                     & "to be ^!", Pack_Pragma);
3346                                  Error_Msg_N
3347                                    ("\?use Component_Size to set "
3348                                     & "desired value!", Pack_Pragma);
3349                               end if;
3350                            end if;
3351
3352                            --  Actual packing is not needed for 8, 16, 32, 64.
3353                            --  Also not needed for 24 if alignment is 1.
3354
3355                            if        Csiz = 8
3356                              or else Csiz = 16
3357                              or else Csiz = 32
3358                              or else Csiz = 64
3359                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3360                            then
3361                               --  Here the array was requested to be packed,
3362                               --  but the packing request had no effect, so
3363                               --  Is_Packed is reset.
3364
3365                               --  Note: semantically this means that we lose
3366                               --  track of the fact that a derived type
3367                               --  inherited a pragma Pack that was non-
3368                               --  effective, but that seems fine.
3369
3370                               --  We regard a Pack pragma as a request to set
3371                               --  a representation characteristic, and this
3372                               --  request may be ignored.
3373
3374                               Set_Is_Packed           (Base_Type (E), False);
3375                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3376
3377                               if Known_Static_Esize (Component_Type (E))
3378                                 and then Esize (Component_Type (E)) = Csiz
3379                               then
3380                                  Set_Has_Non_Standard_Rep
3381                                    (Base_Type (E), False);
3382                               end if;
3383
3384                            --  In all other cases, packing is indeed needed
3385
3386                            else
3387                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3388                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3389                               Set_Is_Packed            (Base_Type (E), True);
3390                            end if;
3391                         end;
3392                      end if;
3393                   end;
3394
3395                   --  Check for Atomic_Components or Aliased with unsuitable
3396                   --  packing or explicit component size clause given.
3397
3398                   if (Has_Atomic_Components (E)
3399                        or else Has_Aliased_Components (E))
3400                     and then (Has_Component_Size_Clause (E)
3401                                or else Is_Packed (E))
3402                   then
3403                      Alias_Atomic_Check : declare
3404
3405                         procedure Complain_CS (T : String);
3406                         --  Outputs error messages for incorrect CS clause or
3407                         --  pragma Pack for aliased or atomic components (T is
3408                         --  "aliased" or "atomic");
3409
3410                         -----------------
3411                         -- Complain_CS --
3412                         -----------------
3413
3414                         procedure Complain_CS (T : String) is
3415                         begin
3416                            if Has_Component_Size_Clause (E) then
3417                               Clause :=
3418                                 Get_Attribute_Definition_Clause
3419                                   (FS, Attribute_Component_Size);
3420
3421                               if Known_Static_Esize (Ctyp) then
3422                                  Error_Msg_N
3423                                    ("incorrect component size for "
3424                                     & T & " components", Clause);
3425                                  Error_Msg_Uint_1 := Esize (Ctyp);
3426                                  Error_Msg_N
3427                                    ("\only allowed value is^", Clause);
3428
3429                               else
3430                                  Error_Msg_N
3431                                    ("component size cannot be given for "
3432                                     & T & " components", Clause);
3433                               end if;
3434
3435                            else
3436                               Error_Msg_N
3437                                 ("cannot pack " & T & " components",
3438                                  Get_Rep_Pragma (FS, Name_Pack));
3439                            end if;
3440
3441                            return;
3442                         end Complain_CS;
3443
3444                      --  Start of processing for Alias_Atomic_Check
3445
3446                      begin
3447
3448                         --  If object size of component type isn't known, we
3449                         --  cannot be sure so we defer to the back end.
3450
3451                         if not Known_Static_Esize (Ctyp) then
3452                            null;
3453
3454                         --  Case where component size has no effect. First
3455                         --  check for object size of component type multiple
3456                         --  of the storage unit size.
3457
3458                         elsif Esize (Ctyp) mod System_Storage_Unit = 0
3459
3460                           --  OK in both packing case and component size case
3461                           --  if RM size is known and static and the same as
3462                           --  the object size.
3463
3464                           and then
3465                             ((Known_Static_RM_Size (Ctyp)
3466                                and then Esize (Ctyp) = RM_Size (Ctyp))
3467
3468                              --  Or if we have an explicit component size
3469                              --  clause and the component size and object size
3470                              --  are equal.
3471
3472                              or else
3473                                  (Has_Component_Size_Clause (E)
3474                                  and then Component_Size (E) = Esize (Ctyp)))
3475                         then
3476                            null;
3477
3478                         elsif Has_Aliased_Components (E)
3479                           or else Is_Aliased (Ctyp)
3480                         then
3481                            Complain_CS ("aliased");
3482
3483                         elsif Has_Atomic_Components (E)
3484                           or else Is_Atomic (Ctyp)
3485                         then
3486                            Complain_CS ("atomic");
3487                         end if;
3488                      end Alias_Atomic_Check;
3489                   end if;
3490
3491                   --  Warn for case of atomic type
3492
3493                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3494
3495                   if Present (Clause)
3496                     and then not Addressable (Component_Size (FS))
3497                   then
3498                      Error_Msg_NE
3499                        ("non-atomic components of type& may not be "
3500                         & "accessible by separate tasks?", Clause, E);
3501
3502                      if Has_Component_Size_Clause (E) then
3503                         Error_Msg_Sloc :=
3504                           Sloc
3505                             (Get_Attribute_Definition_Clause
3506                                  (FS, Attribute_Component_Size));
3507                         Error_Msg_N
3508                           ("\because of component size clause#?",
3509                            Clause);
3510
3511                      elsif Has_Pragma_Pack (E) then
3512                         Error_Msg_Sloc :=
3513                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3514                         Error_Msg_N
3515                           ("\because of pragma Pack#?", Clause);
3516                      end if;
3517                   end if;
3518
3519                --  Processing that is done only for subtypes
3520
3521                else
3522                   --  Acquire alignment from base type
3523
3524                   if Unknown_Alignment (E) then
3525                      Set_Alignment (E, Alignment (Base_Type (E)));
3526                      Adjust_Esize_Alignment (E);
3527                   end if;
3528                end if;
3529
3530                --  For bit-packed arrays, check the size
3531
3532                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3533                   declare
3534                      SizC : constant Node_Id := Size_Clause (E);
3535
3536                      Discard : Boolean;
3537                      pragma Warnings (Off, Discard);
3538
3539                   begin
3540                      --  It is not clear if it is possible to have no size
3541                      --  clause at this stage, but it is not worth worrying
3542                      --  about. Post error on the entity name in the size
3543                      --  clause if present, else on the type entity itself.
3544
3545                      if Present (SizC) then
3546                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3547                      else
3548                         Check_Size (E, E, RM_Size (E), Discard);
3549                      end if;
3550                   end;
3551                end if;
3552
3553                --  If any of the index types was an enumeration type with a
3554                --  non-standard rep clause, then we indicate that the array
3555                --  type is always packed (even if it is not bit packed).
3556
3557                if Non_Standard_Enum then
3558                   Set_Has_Non_Standard_Rep (Base_Type (E));
3559                   Set_Is_Packed            (Base_Type (E));
3560                end if;
3561
3562                Set_Component_Alignment_If_Not_Set (E);
3563
3564                --  If the array is packed, we must create the packed array
3565                --  type to be used to actually implement the type. This is
3566                --  only needed for real array types (not for string literal
3567                --  types, since they are present only for the front end).
3568
3569                if Is_Packed (E)
3570                  and then Ekind (E) /= E_String_Literal_Subtype
3571                then
3572                   Create_Packed_Array_Type (E);
3573                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3574
3575                   --  Size information of packed array type is copied to the
3576                   --  array type, since this is really the representation. But
3577                   --  do not override explicit existing size values. If the
3578                   --  ancestor subtype is constrained the packed_array_type
3579                   --  will be inherited from it, but the size may have been
3580                   --  provided already, and must not be overridden either.
3581
3582                   if not Has_Size_Clause (E)
3583                     and then
3584                       (No (Ancestor_Subtype (E))
3585                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3586                   then
3587                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3588                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3589                   end if;
3590
3591                   if not Has_Alignment_Clause (E) then
3592                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3593                   end if;
3594                end if;
3595
3596                --  For non-packed arrays set the alignment of the array to the
3597                --  alignment of the component type if it is unknown. Skip this
3598                --  in atomic case (atomic arrays may need larger alignments).
3599
3600                if not Is_Packed (E)
3601                  and then Unknown_Alignment (E)
3602                  and then Known_Alignment (Ctyp)
3603                  and then Known_Static_Component_Size (E)
3604                  and then Known_Static_Esize (Ctyp)
3605                  and then Esize (Ctyp) = Component_Size (E)
3606                  and then not Is_Atomic (E)
3607                then
3608                   Set_Alignment (E, Alignment (Component_Type (E)));
3609                end if;
3610             end;
3611
3612          --  For a class-wide type, the corresponding specific type is
3613          --  frozen as well (RM 13.14(15))
3614
3615          elsif Is_Class_Wide_Type (E) then
3616             Freeze_And_Append (Root_Type (E), N, Result);
3617
3618             --  If the base type of the class-wide type is still incomplete,
3619             --  the class-wide remains unfrozen as well. This is legal when
3620             --  E is the formal of a primitive operation of some other type
3621             --  which is being frozen.
3622
3623             if not Is_Frozen (Root_Type (E)) then
3624                Set_Is_Frozen (E, False);
3625                return Result;
3626             end if;
3627
3628             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3629             --  parent of a derived type) and it is a library-level entity,
3630             --  generate an itype reference for it. Otherwise, its first
3631             --  explicit reference may be in an inner scope, which will be
3632             --  rejected by the back-end.
3633
3634             if Is_Itype (E)
3635               and then Is_Compilation_Unit (Scope (E))
3636             then
3637                declare
3638                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3639
3640                begin
3641                   Set_Itype (Ref, E);
3642                   Add_To_Result (Ref);
3643                end;
3644             end if;
3645
3646             --  The equivalent type associated with a class-wide subtype needs
3647             --  to be frozen to ensure that its layout is done.
3648
3649             if Ekind (E) = E_Class_Wide_Subtype
3650               and then Present (Equivalent_Type (E))
3651             then
3652                Freeze_And_Append (Equivalent_Type (E), N, Result);
3653             end if;
3654
3655          --  For a record (sub)type, freeze all the component types (RM
3656          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3657          --  Is_Record_Type, because we don't want to attempt the freeze for
3658          --  the case of a private type with record extension (we will do that
3659          --  later when the full type is frozen).
3660
3661          elsif Ekind (E) = E_Record_Type
3662            or else Ekind (E) = E_Record_Subtype
3663          then
3664             Freeze_Record_Type (E);
3665
3666          --  For a concurrent type, freeze corresponding record type. This
3667          --  does not correspond to any specific rule in the RM, but the
3668          --  record type is essentially part of the concurrent type.
3669          --  Freeze as well all local entities. This includes record types
3670          --  created for entry parameter blocks, and whatever local entities
3671          --  may appear in the private part.
3672
3673          elsif Is_Concurrent_Type (E) then
3674             if Present (Corresponding_Record_Type (E)) then
3675                Freeze_And_Append
3676                  (Corresponding_Record_Type (E), N, Result);
3677             end if;
3678
3679             Comp := First_Entity (E);
3680             while Present (Comp) loop
3681                if Is_Type (Comp) then
3682                   Freeze_And_Append (Comp, N, Result);
3683
3684                elsif (Ekind (Comp)) /= E_Function then
3685                   if Is_Itype (Etype (Comp))
3686                     and then Underlying_Type (Scope (Etype (Comp))) = E
3687                   then
3688                      Undelay_Type (Etype (Comp));
3689                   end if;
3690
3691                   Freeze_And_Append (Etype (Comp), N, Result);
3692                end if;
3693
3694                Next_Entity (Comp);
3695             end loop;
3696
3697          --  Private types are required to point to the same freeze node as
3698          --  their corresponding full views. The freeze node itself has to
3699          --  point to the partial view of the entity (because from the partial
3700          --  view, we can retrieve the full view, but not the reverse).
3701          --  However, in order to freeze correctly, we need to freeze the full
3702          --  view. If we are freezing at the end of a scope (or within the
3703          --  scope of the private type), the partial and full views will have
3704          --  been swapped, the full view appears first in the entity chain and
3705          --  the swapping mechanism ensures that the pointers are properly set
3706          --  (on scope exit).
3707
3708          --  If we encounter the partial view before the full view (e.g. when
3709          --  freezing from another scope), we freeze the full view, and then
3710          --  set the pointers appropriately since we cannot rely on swapping to
3711          --  fix things up (subtypes in an outer scope might not get swapped).
3712
3713          elsif Is_Incomplete_Or_Private_Type (E)
3714            and then not Is_Generic_Type (E)
3715          then
3716             --  The construction of the dispatch table associated with library
3717             --  level tagged types forces freezing of all the primitives of the
3718             --  type, which may cause premature freezing of the partial view.
3719             --  For example:
3720
3721             --     package Pkg is
3722             --        type T is tagged private;
3723             --        type DT is new T with private;
3724             --        procedure Prim (X : in out T; Y : in out DT'Class);
3725             --     private
3726             --        type T is tagged null record;
3727             --        Obj : T;
3728             --        type DT is new T with null record;
3729             --     end;
3730
3731             --  In this case the type will be frozen later by the usual
3732             --  mechanism: an object declaration, an instantiation, or the
3733             --  end of a declarative part.
3734
3735             if Is_Library_Level_Tagged_Type (E)
3736               and then not Present (Full_View (E))
3737             then
3738                Set_Is_Frozen (E, False);
3739                return Result;
3740
3741             --  Case of full view present
3742
3743             elsif Present (Full_View (E)) then
3744
3745                --  If full view has already been frozen, then no further
3746                --  processing is required
3747
3748                if Is_Frozen (Full_View (E)) then
3749                   Set_Has_Delayed_Freeze (E, False);
3750                   Set_Freeze_Node (E, Empty);
3751                   Check_Debug_Info_Needed (E);
3752
3753                --  Otherwise freeze full view and patch the pointers so that
3754                --  the freeze node will elaborate both views in the back-end.
3755
3756                else
3757                   declare
3758                      Full : constant Entity_Id := Full_View (E);
3759
3760                   begin
3761                      if Is_Private_Type (Full)
3762                        and then Present (Underlying_Full_View (Full))
3763                      then
3764                         Freeze_And_Append
3765                           (Underlying_Full_View (Full), N, Result);
3766                      end if;
3767
3768                      Freeze_And_Append (Full, N, Result);
3769
3770                      if Has_Delayed_Freeze (E) then
3771                         F_Node := Freeze_Node (Full);
3772
3773                         if Present (F_Node) then
3774                            Set_Freeze_Node (E, F_Node);
3775                            Set_Entity (F_Node, E);
3776
3777                         else
3778                            --  {Incomplete,Private}_Subtypes with Full_Views
3779                            --  constrained by discriminants.
3780
3781                            Set_Has_Delayed_Freeze (E, False);
3782                            Set_Freeze_Node (E, Empty);
3783                         end if;
3784                      end if;
3785                   end;
3786
3787                   Check_Debug_Info_Needed (E);
3788                end if;
3789
3790                --  AI-117 requires that the convention of a partial view be the
3791                --  same as the convention of the full view. Note that this is a
3792                --  recognized breach of privacy, but it's essential for logical
3793                --  consistency of representation, and the lack of a rule in
3794                --  RM95 was an oversight.
3795
3796                Set_Convention (E, Convention (Full_View (E)));
3797
3798                Set_Size_Known_At_Compile_Time (E,
3799                  Size_Known_At_Compile_Time (Full_View (E)));
3800
3801                --  Size information is copied from the full view to the
3802                --  incomplete or private view for consistency.
3803
3804                --  We skip this is the full view is not a type. This is very
3805                --  strange of course, and can only happen as a result of
3806                --  certain illegalities, such as a premature attempt to derive
3807                --  from an incomplete type.
3808
3809                if Is_Type (Full_View (E)) then
3810                   Set_Size_Info (E, Full_View (E));
3811                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3812                end if;
3813
3814                return Result;
3815
3816             --  Case of no full view present. If entity is derived or subtype,
3817             --  it is safe to freeze, correctness depends on the frozen status
3818             --  of parent. Otherwise it is either premature usage, or a Taft
3819             --  amendment type, so diagnosis is at the point of use and the
3820             --  type might be frozen later.
3821
3822             elsif E /= Base_Type (E)
3823               or else Is_Derived_Type (E)
3824             then
3825                null;
3826
3827             else
3828                Set_Is_Frozen (E, False);
3829                return No_List;
3830             end if;
3831
3832          --  For access subprogram, freeze types of all formals, the return
3833          --  type was already frozen, since it is the Etype of the function.
3834          --  Formal types can be tagged Taft amendment types, but otherwise
3835          --  they cannot be incomplete.
3836
3837          elsif Ekind (E) = E_Subprogram_Type then
3838             Formal := First_Formal (E);
3839             while Present (Formal) loop
3840                if Ekind (Etype (Formal)) = E_Incomplete_Type
3841                  and then No (Full_View (Etype (Formal)))
3842                  and then not Is_Value_Type (Etype (Formal))
3843                then
3844                   if Is_Tagged_Type (Etype (Formal)) then
3845                      null;
3846
3847                   --  AI05-151: Incomplete types are allowed in access to
3848                   --  subprogram specifications.
3849
3850                   elsif Ada_Version < Ada_2012 then
3851                      Error_Msg_NE
3852                        ("invalid use of incomplete type&", E, Etype (Formal));
3853                   end if;
3854                end if;
3855
3856                Freeze_And_Append (Etype (Formal), N, Result);
3857                Next_Formal (Formal);
3858             end loop;
3859
3860             Freeze_Subprogram (E);
3861
3862          --  For access to a protected subprogram, freeze the equivalent type
3863          --  (however this is not set if we are not generating code or if this
3864          --  is an anonymous type used just for resolution).
3865
3866          elsif Is_Access_Protected_Subprogram_Type (E) then
3867             if Present (Equivalent_Type (E)) then
3868                Freeze_And_Append (Equivalent_Type (E), N, Result);
3869             end if;
3870          end if;
3871
3872          --  Generic types are never seen by the back-end, and are also not
3873          --  processed by the expander (since the expander is turned off for
3874          --  generic processing), so we never need freeze nodes for them.
3875
3876          if Is_Generic_Type (E) then
3877             return Result;
3878          end if;
3879
3880          --  Some special processing for non-generic types to complete
3881          --  representation details not known till the freeze point.
3882
3883          if Is_Fixed_Point_Type (E) then
3884             Freeze_Fixed_Point_Type (E);
3885
3886             --  Some error checks required for ordinary fixed-point type. Defer
3887             --  these till the freeze-point since we need the small and range
3888             --  values. We only do these checks for base types
3889
3890             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3891                if Small_Value (E) < Ureal_2_M_80 then
3892                   Error_Msg_Name_1 := Name_Small;
3893                   Error_Msg_N
3894                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3895
3896                elsif Small_Value (E) > Ureal_2_80 then
3897                   Error_Msg_Name_1 := Name_Small;
3898                   Error_Msg_N
3899                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3900                end if;
3901
3902                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3903                   Error_Msg_Name_1 := Name_First;
3904                   Error_Msg_N
3905                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3906                end if;
3907
3908                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3909                   Error_Msg_Name_1 := Name_Last;
3910                   Error_Msg_N
3911                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3912                end if;
3913             end if;
3914
3915          elsif Is_Enumeration_Type (E) then
3916             Freeze_Enumeration_Type (E);
3917
3918          elsif Is_Integer_Type (E) then
3919             Adjust_Esize_For_Alignment (E);
3920
3921             if Is_Modular_Integer_Type (E)
3922               and then Warn_On_Suspicious_Modulus_Value
3923             then
3924                Check_Suspicious_Modulus (E);
3925             end if;
3926
3927          elsif Is_Access_Type (E) then
3928
3929             --  If a pragma Default_Storage_Pool applies, and this type has no
3930             --  Storage_Pool or Storage_Size clause (which must have occurred
3931             --  before the freezing point), then use the default. This applies
3932             --  only to base types.
3933
3934             if Present (Default_Pool)
3935               and then Is_Base_Type (E)
3936               and then not Has_Storage_Size_Clause (E)
3937               and then No (Associated_Storage_Pool (E))
3938             then
3939                --  Case of pragma Default_Storage_Pool (null)
3940
3941                if Nkind (Default_Pool) = N_Null then
3942                   Set_No_Pool_Assigned (E);
3943
3944                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3945
3946                else
3947                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3948                end if;
3949             end if;
3950
3951             --  Check restriction for standard storage pool
3952
3953             if No (Associated_Storage_Pool (E)) then
3954                Check_Restriction (No_Standard_Storage_Pools, E);
3955             end if;
3956
3957             --  Deal with error message for pure access type. This is not an
3958             --  error in Ada 2005 if there is no pool (see AI-366).
3959
3960             if Is_Pure_Unit_Access_Type (E)
3961               and then (Ada_Version < Ada_2005
3962                          or else not No_Pool_Assigned (E))
3963             then
3964                Error_Msg_N ("named access type not allowed in pure unit", E);
3965
3966                if Ada_Version >= Ada_2005 then
3967                   Error_Msg_N
3968                     ("\would be legal if Storage_Size of 0 given?", E);
3969
3970                elsif No_Pool_Assigned (E) then
3971                   Error_Msg_N
3972                     ("\would be legal in Ada 2005?", E);
3973
3974                else
3975                   Error_Msg_N
3976                     ("\would be legal in Ada 2005 if "
3977                      & "Storage_Size of 0 given?", E);
3978                end if;
3979             end if;
3980          end if;
3981
3982          --  Case of composite types
3983
3984          if Is_Composite_Type (E) then
3985
3986             --  AI-117 requires that all new primitives of a tagged type must
3987             --  inherit the convention of the full view of the type. Inherited
3988             --  and overriding operations are defined to inherit the convention
3989             --  of their parent or overridden subprogram (also specified in
3990             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3991             --  and New_Overloaded_Entity). Here we set the convention of
3992             --  primitives that are still convention Ada, which will ensure
3993             --  that any new primitives inherit the type's convention. Class-
3994             --  wide types can have a foreign convention inherited from their
3995             --  specific type, but are excluded from this since they don't have
3996             --  any associated primitives.
3997
3998             if Is_Tagged_Type (E)
3999               and then not Is_Class_Wide_Type (E)
4000               and then Convention (E) /= Convention_Ada
4001             then
4002                declare
4003                   Prim_List : constant Elist_Id := Primitive_Operations (E);
4004                   Prim      : Elmt_Id;
4005
4006                begin
4007                   Prim := First_Elmt (Prim_List);
4008                   while Present (Prim) loop
4009                      if Convention (Node (Prim)) = Convention_Ada then
4010                         Set_Convention (Node (Prim), Convention (E));
4011                      end if;
4012
4013                      Next_Elmt (Prim);
4014                   end loop;
4015                end;
4016             end if;
4017          end if;
4018
4019          --  Now that all types from which E may depend are frozen, see if the
4020          --  size is known at compile time, if it must be unsigned, or if
4021          --  strict alignment is required
4022
4023          Check_Compile_Time_Size (E);
4024          Check_Unsigned_Type (E);
4025
4026          if Base_Type (E) = E then
4027             Check_Strict_Alignment (E);
4028          end if;
4029
4030          --  Do not allow a size clause for a type which does not have a size
4031          --  that is known at compile time
4032
4033          if Has_Size_Clause (E)
4034            and then not Size_Known_At_Compile_Time (E)
4035          then
4036             --  Suppress this message if errors posted on E, even if we are
4037             --  in all errors mode, since this is often a junk message
4038
4039             if not Error_Posted (E) then
4040                Error_Msg_N
4041                  ("size clause not allowed for variable length type",
4042                   Size_Clause (E));
4043             end if;
4044          end if;
4045
4046          --  Now we set/verify the representation information, in particular
4047          --  the size and alignment values. This processing is not required for
4048          --  generic types, since generic types do not play any part in code
4049          --  generation, and so the size and alignment values for such types
4050          --  are irrelevant.
4051
4052          if Is_Generic_Type (E) then
4053             return Result;
4054
4055          --  Otherwise we call the layout procedure
4056
4057          else
4058             Layout_Type (E);
4059          end if;
4060
4061          --  If the type has a Defaut_Value/Default_Component_Value aspect,
4062          --  this is where we analye the expression (after the type is frozen,
4063          --  since in the case of Default_Value, we are analyzing with the
4064          --  type itself, and we treat Default_Component_Value similarly for
4065          --  the sake of uniformity.
4066
4067          if Is_First_Subtype (E) and then Has_Default_Aspect (E) then
4068             declare
4069                Nam    : Name_Id;
4070                Aspect : Node_Id;
4071                Exp    : Node_Id;
4072                Typ    : Entity_Id;
4073
4074             begin
4075                if Is_Scalar_Type (E) then
4076                   Nam := Name_Default_Value;
4077                   Typ := E;
4078                else
4079                   Nam := Name_Default_Component_Value;
4080                   Typ := Component_Type (E);
4081                end if;
4082
4083                Aspect := Get_Rep_Item_For_Entity (E, Nam);
4084                Exp := Expression (Aspect);
4085                Analyze_And_Resolve (Exp, Typ);
4086
4087                if Etype (Exp) /= Any_Type then
4088                   if not Is_Static_Expression (Exp) then
4089                      Error_Msg_Name_1 := Nam;
4090                      Flag_Non_Static_Expr
4091                        ("aspect% requires static expression", Exp);
4092                   end if;
4093                end if;
4094             end;
4095          end if;
4096
4097          --  End of freeze processing for type entities
4098       end if;
4099
4100       --  Here is where we logically freeze the current entity. If it has a
4101       --  freeze node, then this is the point at which the freeze node is
4102       --  linked into the result list.
4103
4104       if Has_Delayed_Freeze (E) then
4105
4106          --  If a freeze node is already allocated, use it, otherwise allocate
4107          --  a new one. The preallocation happens in the case of anonymous base
4108          --  types, where we preallocate so that we can set First_Subtype_Link.
4109          --  Note that we reset the Sloc to the current freeze location.
4110
4111          if Present (Freeze_Node (E)) then
4112             F_Node := Freeze_Node (E);
4113             Set_Sloc (F_Node, Loc);
4114
4115          else
4116             F_Node := New_Node (N_Freeze_Entity, Loc);
4117             Set_Freeze_Node (E, F_Node);
4118             Set_Access_Types_To_Process (F_Node, No_Elist);
4119             Set_TSS_Elist (F_Node, No_Elist);
4120             Set_Actions (F_Node, No_List);
4121          end if;
4122
4123          Set_Entity (F_Node, E);
4124          Add_To_Result (F_Node);
4125
4126          --  A final pass over record types with discriminants. If the type
4127          --  has an incomplete declaration, there may be constrained access
4128          --  subtypes declared elsewhere, which do not depend on the discrimi-
4129          --  nants of the type, and which are used as component types (i.e.
4130          --  the full view is a recursive type). The designated types of these
4131          --  subtypes can only be elaborated after the type itself, and they
4132          --  need an itype reference.
4133
4134          if Ekind (E) = E_Record_Type
4135            and then Has_Discriminants (E)
4136          then
4137             declare
4138                Comp : Entity_Id;
4139                IR   : Node_Id;
4140                Typ  : Entity_Id;
4141
4142             begin
4143                Comp := First_Component (E);
4144                while Present (Comp) loop
4145                   Typ  := Etype (Comp);
4146
4147                   if Ekind (Comp) = E_Component
4148                     and then Is_Access_Type (Typ)
4149                     and then Scope (Typ) /= E
4150                     and then Base_Type (Designated_Type (Typ)) = E
4151                     and then Is_Itype (Designated_Type (Typ))
4152                   then
4153                      IR := Make_Itype_Reference (Sloc (Comp));
4154                      Set_Itype (IR, Designated_Type (Typ));
4155                      Append (IR, Result);
4156                   end if;
4157
4158                   Next_Component (Comp);
4159                end loop;
4160             end;
4161          end if;
4162       end if;
4163
4164       --  When a type is frozen, the first subtype of the type is frozen as
4165       --  well (RM 13.14(15)). This has to be done after freezing the type,
4166       --  since obviously the first subtype depends on its own base type.
4167
4168       if Is_Type (E) then
4169          Freeze_And_Append (First_Subtype (E), N, Result);
4170
4171          --  If we just froze a tagged non-class wide record, then freeze the
4172          --  corresponding class-wide type. This must be done after the tagged
4173          --  type itself is frozen, because the class-wide type refers to the
4174          --  tagged type which generates the class.
4175
4176          if Is_Tagged_Type (E)
4177            and then not Is_Class_Wide_Type (E)
4178            and then Present (Class_Wide_Type (E))
4179          then
4180             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4181          end if;
4182       end if;
4183
4184       Check_Debug_Info_Needed (E);
4185
4186       --  Special handling for subprograms
4187
4188       if Is_Subprogram (E) then
4189
4190          --  If subprogram has address clause then reset Is_Public flag, since
4191          --  we do not want the backend to generate external references.
4192
4193          if Present (Address_Clause (E))
4194            and then not Is_Library_Level_Entity (E)
4195          then
4196             Set_Is_Public (E, False);
4197
4198          --  If no address clause and not intrinsic, then for imported
4199          --  subprogram in main unit, generate descriptor if we are in
4200          --  Propagate_Exceptions mode.
4201
4202          --  This is very odd code, it makes a null result, why ???
4203
4204          elsif Propagate_Exceptions
4205            and then Is_Imported (E)
4206            and then not Is_Intrinsic_Subprogram (E)
4207            and then Convention (E) /= Convention_Stubbed
4208          then
4209             if Result = No_List then
4210                Result := Empty_List;
4211             end if;
4212          end if;
4213       end if;
4214
4215       return Result;
4216    end Freeze_Entity;
4217
4218    -----------------------------
4219    -- Freeze_Enumeration_Type --
4220    -----------------------------
4221
4222    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4223    begin
4224       --  By default, if no size clause is present, an enumeration type with
4225       --  Convention C is assumed to interface to a C enum, and has integer
4226       --  size. This applies to types. For subtypes, verify that its base
4227       --  type has no size clause either.
4228
4229       if Has_Foreign_Convention (Typ)
4230         and then not Has_Size_Clause (Typ)
4231         and then not Has_Size_Clause (Base_Type (Typ))
4232         and then Esize (Typ) < Standard_Integer_Size
4233       then
4234          Init_Esize (Typ, Standard_Integer_Size);
4235
4236       else
4237          --  If the enumeration type interfaces to C, and it has a size clause
4238          --  that specifies less than int size, it warrants a warning. The
4239          --  user may intend the C type to be an enum or a char, so this is
4240          --  not by itself an error that the Ada compiler can detect, but it
4241          --  it is a worth a heads-up. For Boolean and Character types we
4242          --  assume that the programmer has the proper C type in mind.
4243
4244          if Convention (Typ) = Convention_C
4245            and then Has_Size_Clause (Typ)
4246            and then Esize (Typ) /= Esize (Standard_Integer)
4247            and then not Is_Boolean_Type (Typ)
4248            and then not Is_Character_Type (Typ)
4249          then
4250             Error_Msg_N
4251               ("C enum types have the size of a C int?", Size_Clause (Typ));
4252          end if;
4253
4254          Adjust_Esize_For_Alignment (Typ);
4255       end if;
4256    end Freeze_Enumeration_Type;
4257
4258    -----------------------
4259    -- Freeze_Expression --
4260    -----------------------
4261
4262    procedure Freeze_Expression (N : Node_Id) is
4263       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4264       Typ         : Entity_Id;
4265       Nam         : Entity_Id;
4266       Desig_Typ   : Entity_Id;
4267       P           : Node_Id;
4268       Parent_P    : Node_Id;
4269
4270       Freeze_Outside : Boolean := False;
4271       --  This flag is set true if the entity must be frozen outside the
4272       --  current subprogram. This happens in the case of expander generated
4273       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4274       --  not freeze all entities like other bodies, but which nevertheless
4275       --  may reference entities that have to be frozen before the body and
4276       --  obviously cannot be frozen inside the body.
4277
4278       function In_Exp_Body (N : Node_Id) return Boolean;
4279       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4280       --  it is the handled statement sequence of an expander-generated
4281       --  subprogram (init proc, stream subprogram, or renaming as body).
4282       --  If so, this is not a freezing context.
4283
4284       -----------------
4285       -- In_Exp_Body --
4286       -----------------
4287
4288       function In_Exp_Body (N : Node_Id) return Boolean is
4289          P  : Node_Id;
4290          Id : Entity_Id;
4291
4292       begin
4293          if Nkind (N) = N_Subprogram_Body then
4294             P := N;
4295          else
4296             P := Parent (N);
4297          end if;
4298
4299          if Nkind (P) /= N_Subprogram_Body then
4300             return False;
4301
4302          else
4303             Id := Defining_Unit_Name (Specification (P));
4304
4305             if Nkind (Id) = N_Defining_Identifier
4306               and then (Is_Init_Proc (Id)              or else
4307                         Is_TSS (Id, TSS_Stream_Input)  or else
4308                         Is_TSS (Id, TSS_Stream_Output) or else
4309                         Is_TSS (Id, TSS_Stream_Read)   or else
4310                         Is_TSS (Id, TSS_Stream_Write)  or else
4311                         Nkind (Original_Node (P)) =
4312                           N_Subprogram_Renaming_Declaration)
4313             then
4314                return True;
4315             else
4316                return False;
4317             end if;
4318          end if;
4319       end In_Exp_Body;
4320
4321    --  Start of processing for Freeze_Expression
4322
4323    begin
4324       --  Immediate return if freezing is inhibited. This flag is set by the
4325       --  analyzer to stop freezing on generated expressions that would cause
4326       --  freezing if they were in the source program, but which are not
4327       --  supposed to freeze, since they are created.
4328
4329       if Must_Not_Freeze (N) then
4330          return;
4331       end if;
4332
4333       --  If expression is non-static, then it does not freeze in a default
4334       --  expression, see section "Handling of Default Expressions" in the
4335       --  spec of package Sem for further details. Note that we have to
4336       --  make sure that we actually have a real expression (if we have
4337       --  a subtype indication, we can't test Is_Static_Expression!)
4338
4339       if In_Spec_Exp
4340         and then Nkind (N) in N_Subexpr
4341         and then not Is_Static_Expression (N)
4342       then
4343          return;
4344       end if;
4345
4346       --  Freeze type of expression if not frozen already
4347
4348       Typ := Empty;
4349
4350       if Nkind (N) in N_Has_Etype then
4351          if not Is_Frozen (Etype (N)) then
4352             Typ := Etype (N);
4353
4354          --  Base type may be an derived numeric type that is frozen at
4355          --  the point of declaration, but first_subtype is still unfrozen.
4356
4357          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4358             Typ := First_Subtype (Etype (N));
4359          end if;
4360       end if;
4361
4362       --  For entity name, freeze entity if not frozen already. A special
4363       --  exception occurs for an identifier that did not come from source.
4364       --  We don't let such identifiers freeze a non-internal entity, i.e.
4365       --  an entity that did come from source, since such an identifier was
4366       --  generated by the expander, and cannot have any semantic effect on
4367       --  the freezing semantics. For example, this stops the parameter of
4368       --  an initialization procedure from freezing the variable.
4369
4370       if Is_Entity_Name (N)
4371         and then not Is_Frozen (Entity (N))
4372         and then (Nkind (N) /= N_Identifier
4373                    or else Comes_From_Source (N)
4374                    or else not Comes_From_Source (Entity (N)))
4375       then
4376          Nam := Entity (N);
4377       else
4378          Nam := Empty;
4379       end if;
4380
4381       --  For an allocator freeze designated type if not frozen already
4382
4383       --  For an aggregate whose component type is an access type, freeze the
4384       --  designated type now, so that its freeze does not appear within the
4385       --  loop that might be created in the expansion of the aggregate. If the
4386       --  designated type is a private type without full view, the expression
4387       --  cannot contain an allocator, so the type is not frozen.
4388
4389       --  For a function, we freeze the entity when the subprogram declaration
4390       --  is frozen, but a function call may appear in an initialization proc.
4391       --  before the declaration is frozen. We need to generate the extra
4392       --  formals, if any, to ensure that the expansion of the call includes
4393       --  the proper actuals. This only applies to Ada subprograms, not to
4394       --  imported ones.
4395
4396       Desig_Typ := Empty;
4397
4398       case Nkind (N) is
4399          when N_Allocator =>
4400             Desig_Typ := Designated_Type (Etype (N));
4401
4402          when N_Aggregate =>
4403             if Is_Array_Type (Etype (N))
4404               and then Is_Access_Type (Component_Type (Etype (N)))
4405             then
4406                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4407             end if;
4408
4409          when N_Selected_Component |
4410             N_Indexed_Component    |
4411             N_Slice                =>
4412
4413             if Is_Access_Type (Etype (Prefix (N))) then
4414                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4415             end if;
4416
4417          when N_Identifier =>
4418             if Present (Nam)
4419               and then Ekind (Nam) = E_Function
4420               and then Nkind (Parent (N)) = N_Function_Call
4421               and then Convention (Nam) = Convention_Ada
4422             then
4423                Create_Extra_Formals (Nam);
4424             end if;
4425
4426          when others =>
4427             null;
4428       end case;
4429
4430       if Desig_Typ /= Empty
4431         and then (Is_Frozen (Desig_Typ)
4432                    or else (not Is_Fully_Defined (Desig_Typ)))
4433       then
4434          Desig_Typ := Empty;
4435       end if;
4436
4437       --  All done if nothing needs freezing
4438
4439       if No (Typ)
4440         and then No (Nam)
4441         and then No (Desig_Typ)
4442       then
4443          return;
4444       end if;
4445
4446       --  Loop for looking at the right place to insert the freeze nodes,
4447       --  exiting from the loop when it is appropriate to insert the freeze
4448       --  node before the current node P.
4449
4450       --  Also checks some special exceptions to the freezing rules. These
4451       --  cases result in a direct return, bypassing the freeze action.
4452
4453       P := N;
4454       loop
4455          Parent_P := Parent (P);
4456
4457          --  If we don't have a parent, then we are not in a well-formed tree.
4458          --  This is an unusual case, but there are some legitimate situations
4459          --  in which this occurs, notably when the expressions in the range of
4460          --  a type declaration are resolved. We simply ignore the freeze
4461          --  request in this case. Is this right ???
4462
4463          if No (Parent_P) then
4464             return;
4465          end if;
4466
4467          --  See if we have got to an appropriate point in the tree
4468
4469          case Nkind (Parent_P) is
4470
4471             --  A special test for the exception of (RM 13.14(8)) for the case
4472             --  of per-object expressions (RM 3.8(18)) occurring in component
4473             --  definition or a discrete subtype definition. Note that we test
4474             --  for a component declaration which includes both cases we are
4475             --  interested in, and furthermore the tree does not have explicit
4476             --  nodes for either of these two constructs.
4477
4478             when N_Component_Declaration =>
4479
4480                --  The case we want to test for here is an identifier that is
4481                --  a per-object expression, this is either a discriminant that
4482                --  appears in a context other than the component declaration
4483                --  or it is a reference to the type of the enclosing construct.
4484
4485                --  For either of these cases, we skip the freezing
4486
4487                if not In_Spec_Expression
4488                  and then Nkind (N) = N_Identifier
4489                  and then (Present (Entity (N)))
4490                then
4491                   --  We recognize the discriminant case by just looking for
4492                   --  a reference to a discriminant. It can only be one for
4493                   --  the enclosing construct. Skip freezing in this case.
4494
4495                   if Ekind (Entity (N)) = E_Discriminant then
4496                      return;
4497
4498                   --  For the case of a reference to the enclosing record,
4499                   --  (or task or protected type), we look for a type that
4500                   --  matches the current scope.
4501
4502                   elsif Entity (N) = Current_Scope then
4503                      return;
4504                   end if;
4505                end if;
4506
4507             --  If we have an enumeration literal that appears as the choice in
4508             --  the aggregate of an enumeration representation clause, then
4509             --  freezing does not occur (RM 13.14(10)).
4510
4511             when N_Enumeration_Representation_Clause =>
4512
4513                --  The case we are looking for is an enumeration literal
4514
4515                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4516                  and then Is_Enumeration_Type (Etype (N))
4517                then
4518                   --  If enumeration literal appears directly as the choice,
4519                   --  do not freeze (this is the normal non-overloaded case)
4520
4521                   if Nkind (Parent (N)) = N_Component_Association
4522                     and then First (Choices (Parent (N))) = N
4523                   then
4524                      return;
4525
4526                   --  If enumeration literal appears as the name of function
4527                   --  which is the choice, then also do not freeze. This
4528                   --  happens in the overloaded literal case, where the
4529                   --  enumeration literal is temporarily changed to a function
4530                   --  call for overloading analysis purposes.
4531
4532                   elsif Nkind (Parent (N)) = N_Function_Call
4533                      and then
4534                        Nkind (Parent (Parent (N))) = N_Component_Association
4535                      and then
4536                        First (Choices (Parent (Parent (N)))) = Parent (N)
4537                   then
4538                      return;
4539                   end if;
4540                end if;
4541
4542             --  Normally if the parent is a handled sequence of statements,
4543             --  then the current node must be a statement, and that is an
4544             --  appropriate place to insert a freeze node.
4545
4546             when N_Handled_Sequence_Of_Statements =>
4547
4548                --  An exception occurs when the sequence of statements is for
4549                --  an expander generated body that did not do the usual freeze
4550                --  all operation. In this case we usually want to freeze
4551                --  outside this body, not inside it, and we skip past the
4552                --  subprogram body that we are inside.
4553
4554                if In_Exp_Body (Parent_P) then
4555
4556                   --  However, we *do* want to freeze at this point if we have
4557                   --  an entity to freeze, and that entity is declared *inside*
4558                   --  the body of the expander generated procedure. This case
4559                   --  is recognized by the scope of the type, which is either
4560                   --  the spec for some enclosing body, or (in the case of
4561                   --  init_procs, for which there are no separate specs) the
4562                   --  current scope.
4563
4564                   declare
4565                      Subp : constant Node_Id := Parent (Parent_P);
4566                      Cspc : Entity_Id;
4567
4568                   begin
4569                      if Nkind (Subp) = N_Subprogram_Body then
4570                         Cspc := Corresponding_Spec (Subp);
4571
4572                         if (Present (Typ) and then Scope (Typ) = Cspc)
4573                              or else
4574                            (Present (Nam) and then Scope (Nam) = Cspc)
4575                         then
4576                            exit;
4577
4578                         elsif Present (Typ)
4579                           and then Scope (Typ) = Current_Scope
4580                           and then Current_Scope = Defining_Entity (Subp)
4581                         then
4582                            exit;
4583                         end if;
4584                      end if;
4585                   end;
4586
4587                   --  If not that exception to the exception, then this is
4588                   --  where we delay the freeze till outside the body.
4589
4590                   Parent_P := Parent (Parent_P);
4591                   Freeze_Outside := True;
4592
4593                --  Here if normal case where we are in handled statement
4594                --  sequence and want to do the insertion right there.
4595
4596                else
4597                   exit;
4598                end if;
4599
4600             --  If parent is a body or a spec or a block, then the current node
4601             --  is a statement or declaration and we can insert the freeze node
4602             --  before it.
4603
4604             when N_Block_Statement       |
4605                  N_Entry_Body            |
4606                  N_Package_Body          |
4607                  N_Package_Specification |
4608                  N_Protected_Body        |
4609                  N_Subprogram_Body       |
4610                  N_Task_Body             => exit;
4611
4612             --  The expander is allowed to define types in any statements list,
4613             --  so any of the following parent nodes also mark a freezing point
4614             --  if the actual node is in a list of statements or declarations.
4615
4616             when N_Abortable_Part             |
4617                  N_Accept_Alternative         |
4618                  N_And_Then                   |
4619                  N_Case_Statement_Alternative |
4620                  N_Compilation_Unit_Aux       |
4621                  N_Conditional_Entry_Call     |
4622                  N_Delay_Alternative          |
4623                  N_Elsif_Part                 |
4624                  N_Entry_Call_Alternative     |
4625                  N_Exception_Handler          |
4626                  N_Extended_Return_Statement  |
4627                  N_Freeze_Entity              |
4628                  N_If_Statement               |
4629                  N_Or_Else                    |
4630                  N_Selective_Accept           |
4631                  N_Triggering_Alternative     =>
4632
4633                exit when Is_List_Member (P);
4634
4635             --  Note: The N_Loop_Statement is a special case. A type that
4636             --  appears in the source can never be frozen in a loop (this
4637             --  occurs only because of a loop expanded by the expander), so we
4638             --  keep on going. Otherwise we terminate the search. Same is true
4639             --  of any entity which comes from source. (if they have predefined
4640             --  type, that type does not appear to come from source, but the
4641             --  entity should not be frozen here).
4642
4643             when N_Loop_Statement =>
4644                exit when not Comes_From_Source (Etype (N))
4645                  and then (No (Nam) or else not Comes_From_Source (Nam));
4646
4647             --  For all other cases, keep looking at parents
4648
4649             when others =>
4650                null;
4651          end case;
4652
4653          --  We fall through the case if we did not yet find the proper
4654          --  place in the free for inserting the freeze node, so climb!
4655
4656          P := Parent_P;
4657       end loop;
4658
4659       --  If the expression appears in a record or an initialization procedure,
4660       --  the freeze nodes are collected and attached to the current scope, to
4661       --  be inserted and analyzed on exit from the scope, to insure that
4662       --  generated entities appear in the correct scope. If the expression is
4663       --  a default for a discriminant specification, the scope is still void.
4664       --  The expression can also appear in the discriminant part of a private
4665       --  or concurrent type.
4666
4667       --  If the expression appears in a constrained subcomponent of an
4668       --  enclosing record declaration, the freeze nodes must be attached to
4669       --  the outer record type so they can eventually be placed in the
4670       --  enclosing declaration list.
4671
4672       --  The other case requiring this special handling is if we are in a
4673       --  default expression, since in that case we are about to freeze a
4674       --  static type, and the freeze scope needs to be the outer scope, not
4675       --  the scope of the subprogram with the default parameter.
4676
4677       --  For default expressions and other spec expressions in generic units,
4678       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4679       --  placing them at the proper place, after the generic unit.
4680
4681       if (In_Spec_Exp and not Inside_A_Generic)
4682         or else Freeze_Outside
4683         or else (Is_Type (Current_Scope)
4684                   and then (not Is_Concurrent_Type (Current_Scope)
4685                              or else not Has_Completion (Current_Scope)))
4686         or else Ekind (Current_Scope) = E_Void
4687       then
4688          declare
4689             N            : constant Node_Id    := Current_Scope;
4690             Freeze_Nodes : List_Id             := No_List;
4691             Pos          : Int                 := Scope_Stack.Last;
4692
4693          begin
4694             if Present (Desig_Typ) then
4695                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4696             end if;
4697
4698             if Present (Typ) then
4699                Freeze_And_Append (Typ, N, Freeze_Nodes);
4700             end if;
4701
4702             if Present (Nam) then
4703                Freeze_And_Append (Nam, N, Freeze_Nodes);
4704             end if;
4705
4706             --  The current scope may be that of a constrained component of
4707             --  an enclosing record declaration, which is above the current
4708             --  scope in the scope stack.
4709             --  If the expression is within a top-level pragma, as for a pre-
4710             --  condition on a library-level subprogram, nothing to do.
4711
4712             if not Is_Compilation_Unit (Current_Scope)
4713               and then Is_Record_Type (Scope (Current_Scope))
4714             then
4715                Pos := Pos - 1;
4716             end if;
4717
4718             if Is_Non_Empty_List (Freeze_Nodes) then
4719                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4720                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4721                     Freeze_Nodes;
4722                else
4723                   Append_List (Freeze_Nodes,
4724                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4725                end if;
4726             end if;
4727          end;
4728
4729          return;
4730       end if;
4731
4732       --  Now we have the right place to do the freezing. First, a special
4733       --  adjustment, if we are in spec-expression analysis mode, these freeze
4734       --  actions must not be thrown away (normally all inserted actions are
4735       --  thrown away in this mode. However, the freeze actions are from static
4736       --  expressions and one of the important reasons we are doing this
4737       --  special analysis is to get these freeze actions. Therefore we turn
4738       --  off the In_Spec_Expression mode to propagate these freeze actions.
4739       --  This also means they get properly analyzed and expanded.
4740
4741       In_Spec_Expression := False;
4742
4743       --  Freeze the designated type of an allocator (RM 13.14(13))
4744
4745       if Present (Desig_Typ) then
4746          Freeze_Before (P, Desig_Typ);
4747       end if;
4748
4749       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4750       --  the enumeration representation clause exception in the loop above.
4751
4752       if Present (Typ) then
4753          Freeze_Before (P, Typ);
4754       end if;
4755
4756       --  Freeze name if one is present (RM 13.14(11))
4757
4758       if Present (Nam) then
4759          Freeze_Before (P, Nam);
4760       end if;
4761
4762       --  Restore In_Spec_Expression flag
4763
4764       In_Spec_Expression := In_Spec_Exp;
4765    end Freeze_Expression;
4766
4767    -----------------------------
4768    -- Freeze_Fixed_Point_Type --
4769    -----------------------------
4770
4771    --  Certain fixed-point types and subtypes, including implicit base types
4772    --  and declared first subtypes, have not yet set up a range. This is
4773    --  because the range cannot be set until the Small and Size values are
4774    --  known, and these are not known till the type is frozen.
4775
4776    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4777    --  whose bounds are unanalyzed real literals. This routine will recognize
4778    --  this case, and transform this range node into a properly typed range
4779    --  with properly analyzed and resolved values.
4780
4781    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4782       Rng   : constant Node_Id    := Scalar_Range (Typ);
4783       Lo    : constant Node_Id    := Low_Bound (Rng);
4784       Hi    : constant Node_Id    := High_Bound (Rng);
4785       Btyp  : constant Entity_Id  := Base_Type (Typ);
4786       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4787       BLo   : constant Node_Id    := Low_Bound (Brng);
4788       BHi   : constant Node_Id    := High_Bound (Brng);
4789       Small : constant Ureal      := Small_Value (Typ);
4790       Loval : Ureal;
4791       Hival : Ureal;
4792       Atype : Entity_Id;
4793
4794       Actual_Size : Nat;
4795
4796       function Fsize (Lov, Hiv : Ureal) return Nat;
4797       --  Returns size of type with given bounds. Also leaves these
4798       --  bounds set as the current bounds of the Typ.
4799
4800       -----------
4801       -- Fsize --
4802       -----------
4803
4804       function Fsize (Lov, Hiv : Ureal) return Nat is
4805       begin
4806          Set_Realval (Lo, Lov);
4807          Set_Realval (Hi, Hiv);
4808          return Minimum_Size (Typ);
4809       end Fsize;
4810
4811    --  Start of processing for Freeze_Fixed_Point_Type
4812
4813    begin
4814       --  If Esize of a subtype has not previously been set, set it now
4815
4816       if Unknown_Esize (Typ) then
4817          Atype := Ancestor_Subtype (Typ);
4818
4819          if Present (Atype) then
4820             Set_Esize (Typ, Esize (Atype));
4821          else
4822             Set_Esize (Typ, Esize (Base_Type (Typ)));
4823          end if;
4824       end if;
4825
4826       --  Immediate return if the range is already analyzed. This means that
4827       --  the range is already set, and does not need to be computed by this
4828       --  routine.
4829
4830       if Analyzed (Rng) then
4831          return;
4832       end if;
4833
4834       --  Immediate return if either of the bounds raises Constraint_Error
4835
4836       if Raises_Constraint_Error (Lo)
4837         or else Raises_Constraint_Error (Hi)
4838       then
4839          return;
4840       end if;
4841
4842       Loval := Realval (Lo);
4843       Hival := Realval (Hi);
4844
4845       --  Ordinary fixed-point case
4846
4847       if Is_Ordinary_Fixed_Point_Type (Typ) then
4848
4849          --  For the ordinary fixed-point case, we are allowed to fudge the
4850          --  end-points up or down by small. Generally we prefer to fudge up,
4851          --  i.e. widen the bounds for non-model numbers so that the end points
4852          --  are included. However there are cases in which this cannot be
4853          --  done, and indeed cases in which we may need to narrow the bounds.
4854          --  The following circuit makes the decision.
4855
4856          --  Note: our terminology here is that Incl_EP means that the bounds
4857          --  are widened by Small if necessary to include the end points, and
4858          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4859          --  end-points if this reduces the size.
4860
4861          --  Note that in the Incl case, all we care about is including the
4862          --  end-points. In the Excl case, we want to narrow the bounds as
4863          --  much as permitted by the RM, to give the smallest possible size.
4864
4865          Fudge : declare
4866             Loval_Incl_EP : Ureal;
4867             Hival_Incl_EP : Ureal;
4868
4869             Loval_Excl_EP : Ureal;
4870             Hival_Excl_EP : Ureal;
4871
4872             Size_Incl_EP  : Nat;
4873             Size_Excl_EP  : Nat;
4874
4875             Model_Num     : Ureal;
4876             First_Subt    : Entity_Id;
4877             Actual_Lo     : Ureal;
4878             Actual_Hi     : Ureal;
4879
4880          begin
4881             --  First step. Base types are required to be symmetrical. Right
4882             --  now, the base type range is a copy of the first subtype range.
4883             --  This will be corrected before we are done, but right away we
4884             --  need to deal with the case where both bounds are non-negative.
4885             --  In this case, we set the low bound to the negative of the high
4886             --  bound, to make sure that the size is computed to include the
4887             --  required sign. Note that we do not need to worry about the
4888             --  case of both bounds negative, because the sign will be dealt
4889             --  with anyway. Furthermore we can't just go making such a bound
4890             --  symmetrical, since in a twos-complement system, there is an
4891             --  extra negative value which could not be accommodated on the
4892             --  positive side.
4893
4894             if Typ = Btyp
4895               and then not UR_Is_Negative (Loval)
4896               and then Hival > Loval
4897             then
4898                Loval := -Hival;
4899                Set_Realval (Lo, Loval);
4900             end if;
4901
4902             --  Compute the fudged bounds. If the number is a model number,
4903             --  then we do nothing to include it, but we are allowed to backoff
4904             --  to the next adjacent model number when we exclude it. If it is
4905             --  not a model number then we straddle the two values with the
4906             --  model numbers on either side.
4907
4908             Model_Num := UR_Trunc (Loval / Small) * Small;
4909
4910             if Loval = Model_Num then
4911                Loval_Incl_EP := Model_Num;
4912             else
4913                Loval_Incl_EP := Model_Num - Small;
4914             end if;
4915
4916             --  The low value excluding the end point is Small greater, but
4917             --  we do not do this exclusion if the low value is positive,
4918             --  since it can't help the size and could actually hurt by
4919             --  crossing the high bound.
4920
4921             if UR_Is_Negative (Loval_Incl_EP) then
4922                Loval_Excl_EP := Loval_Incl_EP + Small;
4923
4924                --  If the value went from negative to zero, then we have the
4925                --  case where Loval_Incl_EP is the model number just below
4926                --  zero, so we want to stick to the negative value for the
4927                --  base type to maintain the condition that the size will
4928                --  include signed values.
4929
4930                if Typ = Btyp
4931                  and then UR_Is_Zero (Loval_Excl_EP)
4932                then
4933                   Loval_Excl_EP := Loval_Incl_EP;
4934                end if;
4935
4936             else
4937                Loval_Excl_EP := Loval_Incl_EP;
4938             end if;
4939
4940             --  Similar processing for upper bound and high value
4941
4942             Model_Num := UR_Trunc (Hival / Small) * Small;
4943
4944             if Hival = Model_Num then
4945                Hival_Incl_EP := Model_Num;
4946             else
4947                Hival_Incl_EP := Model_Num + Small;
4948             end if;
4949
4950             if UR_Is_Positive (Hival_Incl_EP) then
4951                Hival_Excl_EP := Hival_Incl_EP - Small;
4952             else
4953                Hival_Excl_EP := Hival_Incl_EP;
4954             end if;
4955
4956             --  One further adjustment is needed. In the case of subtypes, we
4957             --  cannot go outside the range of the base type, or we get
4958             --  peculiarities, and the base type range is already set. This
4959             --  only applies to the Incl values, since clearly the Excl values
4960             --  are already as restricted as they are allowed to be.
4961
4962             if Typ /= Btyp then
4963                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4964                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4965             end if;
4966
4967             --  Get size including and excluding end points
4968
4969             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4970             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4971
4972             --  No need to exclude end-points if it does not reduce size
4973
4974             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4975                Loval_Excl_EP := Loval_Incl_EP;
4976             end if;
4977
4978             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4979                Hival_Excl_EP := Hival_Incl_EP;
4980             end if;
4981
4982             --  Now we set the actual size to be used. We want to use the
4983             --  bounds fudged up to include the end-points but only if this
4984             --  can be done without violating a specifically given size
4985             --  size clause or causing an unacceptable increase in size.
4986
4987             --  Case of size clause given
4988
4989             if Has_Size_Clause (Typ) then
4990
4991                --  Use the inclusive size only if it is consistent with
4992                --  the explicitly specified size.
4993
4994                if Size_Incl_EP <= RM_Size (Typ) then
4995                   Actual_Lo   := Loval_Incl_EP;
4996                   Actual_Hi   := Hival_Incl_EP;
4997                   Actual_Size := Size_Incl_EP;
4998
4999                --  If the inclusive size is too large, we try excluding
5000                --  the end-points (will be caught later if does not work).
5001
5002                else
5003                   Actual_Lo   := Loval_Excl_EP;
5004                   Actual_Hi   := Hival_Excl_EP;
5005                   Actual_Size := Size_Excl_EP;
5006                end if;
5007
5008             --  Case of size clause not given
5009
5010             else
5011                --  If we have a base type whose corresponding first subtype
5012                --  has an explicit size that is large enough to include our
5013                --  end-points, then do so. There is no point in working hard
5014                --  to get a base type whose size is smaller than the specified
5015                --  size of the first subtype.
5016
5017                First_Subt := First_Subtype (Typ);
5018
5019                if Has_Size_Clause (First_Subt)
5020                  and then Size_Incl_EP <= Esize (First_Subt)
5021                then
5022                   Actual_Size := Size_Incl_EP;
5023                   Actual_Lo   := Loval_Incl_EP;
5024                   Actual_Hi   := Hival_Incl_EP;
5025
5026                --  If excluding the end-points makes the size smaller and
5027                --  results in a size of 8,16,32,64, then we take the smaller
5028                --  size. For the 64 case, this is compulsory. For the other
5029                --  cases, it seems reasonable. We like to include end points
5030                --  if we can, but not at the expense of moving to the next
5031                --  natural boundary of size.
5032
5033                elsif Size_Incl_EP /= Size_Excl_EP
5034                  and then Addressable (Size_Excl_EP)
5035                then
5036                   Actual_Size := Size_Excl_EP;
5037                   Actual_Lo   := Loval_Excl_EP;
5038                   Actual_Hi   := Hival_Excl_EP;
5039
5040                --  Otherwise we can definitely include the end points
5041
5042                else
5043                   Actual_Size := Size_Incl_EP;
5044                   Actual_Lo   := Loval_Incl_EP;
5045                   Actual_Hi   := Hival_Incl_EP;
5046                end if;
5047
5048                --  One pathological case: normally we never fudge a low bound
5049                --  down, since it would seem to increase the size (if it has
5050                --  any effect), but for ranges containing single value, or no
5051                --  values, the high bound can be small too large. Consider:
5052
5053                --    type t is delta 2.0**(-14)
5054                --      range 131072.0 .. 0;
5055
5056                --  That lower bound is *just* outside the range of 32 bits, and
5057                --  does need fudging down in this case. Note that the bounds
5058                --  will always have crossed here, since the high bound will be
5059                --  fudged down if necessary, as in the case of:
5060
5061                --    type t is delta 2.0**(-14)
5062                --      range 131072.0 .. 131072.0;
5063
5064                --  So we detect the situation by looking for crossed bounds,
5065                --  and if the bounds are crossed, and the low bound is greater
5066                --  than zero, we will always back it off by small, since this
5067                --  is completely harmless.
5068
5069                if Actual_Lo > Actual_Hi then
5070                   if UR_Is_Positive (Actual_Lo) then
5071                      Actual_Lo   := Loval_Incl_EP - Small;
5072                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5073
5074                   --  And of course, we need to do exactly the same parallel
5075                   --  fudge for flat ranges in the negative region.
5076
5077                   elsif UR_Is_Negative (Actual_Hi) then
5078                      Actual_Hi := Hival_Incl_EP + Small;
5079                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5080                   end if;
5081                end if;
5082             end if;
5083
5084             Set_Realval (Lo, Actual_Lo);
5085             Set_Realval (Hi, Actual_Hi);
5086          end Fudge;
5087
5088       --  For the decimal case, none of this fudging is required, since there
5089       --  are no end-point problems in the decimal case (the end-points are
5090       --  always included).
5091
5092       else
5093          Actual_Size := Fsize (Loval, Hival);
5094       end if;
5095
5096       --  At this stage, the actual size has been calculated and the proper
5097       --  required bounds are stored in the low and high bounds.
5098
5099       if Actual_Size > 64 then
5100          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5101          Error_Msg_N
5102            ("size required (^) for type& too large, maximum allowed is 64",
5103             Typ);
5104          Actual_Size := 64;
5105       end if;
5106
5107       --  Check size against explicit given size
5108
5109       if Has_Size_Clause (Typ) then
5110          if Actual_Size > RM_Size (Typ) then
5111             Error_Msg_Uint_1 := RM_Size (Typ);
5112             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5113             Error_Msg_NE
5114               ("size given (^) for type& too small, minimum allowed is ^",
5115                Size_Clause (Typ), Typ);
5116
5117          else
5118             Actual_Size := UI_To_Int (Esize (Typ));
5119          end if;
5120
5121       --  Increase size to next natural boundary if no size clause given
5122
5123       else
5124          if Actual_Size <= 8 then
5125             Actual_Size := 8;
5126          elsif Actual_Size <= 16 then
5127             Actual_Size := 16;
5128          elsif Actual_Size <= 32 then
5129             Actual_Size := 32;
5130          else
5131             Actual_Size := 64;
5132          end if;
5133
5134          Init_Esize (Typ, Actual_Size);
5135          Adjust_Esize_For_Alignment (Typ);
5136       end if;
5137
5138       --  If we have a base type, then expand the bounds so that they extend to
5139       --  the full width of the allocated size in bits, to avoid junk range
5140       --  checks on intermediate computations.
5141
5142       if Base_Type (Typ) = Typ then
5143          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5144          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5145       end if;
5146
5147       --  Final step is to reanalyze the bounds using the proper type
5148       --  and set the Corresponding_Integer_Value fields of the literals.
5149
5150       Set_Etype (Lo, Empty);
5151       Set_Analyzed (Lo, False);
5152       Analyze (Lo);
5153
5154       --  Resolve with universal fixed if the base type, and the base type if
5155       --  it is a subtype. Note we can't resolve the base type with itself,
5156       --  that would be a reference before definition.
5157
5158       if Typ = Btyp then
5159          Resolve (Lo, Universal_Fixed);
5160       else
5161          Resolve (Lo, Btyp);
5162       end if;
5163
5164       --  Set corresponding integer value for bound
5165
5166       Set_Corresponding_Integer_Value
5167         (Lo, UR_To_Uint (Realval (Lo) / Small));
5168
5169       --  Similar processing for high bound
5170
5171       Set_Etype (Hi, Empty);
5172       Set_Analyzed (Hi, False);
5173       Analyze (Hi);
5174
5175       if Typ = Btyp then
5176          Resolve (Hi, Universal_Fixed);
5177       else
5178          Resolve (Hi, Btyp);
5179       end if;
5180
5181       Set_Corresponding_Integer_Value
5182         (Hi, UR_To_Uint (Realval (Hi) / Small));
5183
5184       --  Set type of range to correspond to bounds
5185
5186       Set_Etype (Rng, Etype (Lo));
5187
5188       --  Set Esize to calculated size if not set already
5189
5190       if Unknown_Esize (Typ) then
5191          Init_Esize (Typ, Actual_Size);
5192       end if;
5193
5194       --  Set RM_Size if not already set. If already set, check value
5195
5196       declare
5197          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5198
5199       begin
5200          if RM_Size (Typ) /= Uint_0 then
5201             if RM_Size (Typ) < Minsiz then
5202                Error_Msg_Uint_1 := RM_Size (Typ);
5203                Error_Msg_Uint_2 := Minsiz;
5204                Error_Msg_NE
5205                  ("size given (^) for type& too small, minimum allowed is ^",
5206                   Size_Clause (Typ), Typ);
5207             end if;
5208
5209          else
5210             Set_RM_Size (Typ, Minsiz);
5211          end if;
5212       end;
5213    end Freeze_Fixed_Point_Type;
5214
5215    ------------------
5216    -- Freeze_Itype --
5217    ------------------
5218
5219    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5220       L : List_Id;
5221
5222    begin
5223       Set_Has_Delayed_Freeze (T);
5224       L := Freeze_Entity (T, N);
5225
5226       if Is_Non_Empty_List (L) then
5227          Insert_Actions (N, L);
5228       end if;
5229    end Freeze_Itype;
5230
5231    --------------------------
5232    -- Freeze_Static_Object --
5233    --------------------------
5234
5235    procedure Freeze_Static_Object (E : Entity_Id) is
5236
5237       Cannot_Be_Static : exception;
5238       --  Exception raised if the type of a static object cannot be made
5239       --  static. This happens if the type depends on non-global objects.
5240
5241       procedure Ensure_Expression_Is_SA (N : Node_Id);
5242       --  Called to ensure that an expression used as part of a type definition
5243       --  is statically allocatable, which means that the expression type is
5244       --  statically allocatable, and the expression is either static, or a
5245       --  reference to a library level constant.
5246
5247       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5248       --  Called to mark a type as static, checking that it is possible
5249       --  to set the type as static. If it is not possible, then the
5250       --  exception Cannot_Be_Static is raised.
5251
5252       -----------------------------
5253       -- Ensure_Expression_Is_SA --
5254       -----------------------------
5255
5256       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5257          Ent : Entity_Id;
5258
5259       begin
5260          Ensure_Type_Is_SA (Etype (N));
5261
5262          if Is_Static_Expression (N) then
5263             return;
5264
5265          elsif Nkind (N) = N_Identifier then
5266             Ent := Entity (N);
5267
5268             if Present (Ent)
5269               and then Ekind (Ent) = E_Constant
5270               and then Is_Library_Level_Entity (Ent)
5271             then
5272                return;
5273             end if;
5274          end if;
5275
5276          raise Cannot_Be_Static;
5277       end Ensure_Expression_Is_SA;
5278
5279       -----------------------
5280       -- Ensure_Type_Is_SA --
5281       -----------------------
5282
5283       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5284          N : Node_Id;
5285          C : Entity_Id;
5286
5287       begin
5288          --  If type is library level, we are all set
5289
5290          if Is_Library_Level_Entity (Typ) then
5291             return;
5292          end if;
5293
5294          --  We are also OK if the type already marked as statically allocated,
5295          --  which means we processed it before.
5296
5297          if Is_Statically_Allocated (Typ) then
5298             return;
5299          end if;
5300
5301          --  Mark type as statically allocated
5302
5303          Set_Is_Statically_Allocated (Typ);
5304
5305          --  Check that it is safe to statically allocate this type
5306
5307          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5308             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5309             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5310
5311          elsif Is_Array_Type (Typ) then
5312             N := First_Index (Typ);
5313             while Present (N) loop
5314                Ensure_Type_Is_SA (Etype (N));
5315                Next_Index (N);
5316             end loop;
5317
5318             Ensure_Type_Is_SA (Component_Type (Typ));
5319
5320          elsif Is_Access_Type (Typ) then
5321             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5322
5323                declare
5324                   F : Entity_Id;
5325                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5326
5327                begin
5328                   if T /= Standard_Void_Type then
5329                      Ensure_Type_Is_SA (T);
5330                   end if;
5331
5332                   F := First_Formal (Designated_Type (Typ));
5333                   while Present (F) loop
5334                      Ensure_Type_Is_SA (Etype (F));
5335                      Next_Formal (F);
5336                   end loop;
5337                end;
5338
5339             else
5340                Ensure_Type_Is_SA (Designated_Type (Typ));
5341             end if;
5342
5343          elsif Is_Record_Type (Typ) then
5344             C := First_Entity (Typ);
5345             while Present (C) loop
5346                if Ekind (C) = E_Discriminant
5347                  or else Ekind (C) = E_Component
5348                then
5349                   Ensure_Type_Is_SA (Etype (C));
5350
5351                elsif Is_Type (C) then
5352                   Ensure_Type_Is_SA (C);
5353                end if;
5354
5355                Next_Entity (C);
5356             end loop;
5357
5358          elsif Ekind (Typ) = E_Subprogram_Type then
5359             Ensure_Type_Is_SA (Etype (Typ));
5360
5361             C := First_Formal (Typ);
5362             while Present (C) loop
5363                Ensure_Type_Is_SA (Etype (C));
5364                Next_Formal (C);
5365             end loop;
5366
5367          else
5368             raise Cannot_Be_Static;
5369          end if;
5370       end Ensure_Type_Is_SA;
5371
5372    --  Start of processing for Freeze_Static_Object
5373
5374    begin
5375       Ensure_Type_Is_SA (Etype (E));
5376
5377    exception
5378       when Cannot_Be_Static =>
5379
5380          --  If the object that cannot be static is imported or exported, then
5381          --  issue an error message saying that this object cannot be imported
5382          --  or exported. If it has an address clause it is an overlay in the
5383          --  current partition and the static requirement is not relevant.
5384          --  Do not issue any error message when ignoring rep clauses.
5385
5386          if Ignore_Rep_Clauses then
5387             null;
5388
5389          elsif Is_Imported (E) then
5390             if No (Address_Clause (E)) then
5391                Error_Msg_N
5392                  ("& cannot be imported (local type is not constant)", E);
5393             end if;
5394
5395          --  Otherwise must be exported, something is wrong if compiler
5396          --  is marking something as statically allocated which cannot be).
5397
5398          else pragma Assert (Is_Exported (E));
5399             Error_Msg_N
5400               ("& cannot be exported (local type is not constant)", E);
5401          end if;
5402    end Freeze_Static_Object;
5403
5404    -----------------------
5405    -- Freeze_Subprogram --
5406    -----------------------
5407
5408    procedure Freeze_Subprogram (E : Entity_Id) is
5409       Retype : Entity_Id;
5410       F      : Entity_Id;
5411
5412    begin
5413       --  Subprogram may not have an address clause unless it is imported
5414
5415       if Present (Address_Clause (E)) then
5416          if not Is_Imported (E) then
5417             Error_Msg_N
5418               ("address clause can only be given " &
5419                "for imported subprogram",
5420                Name (Address_Clause (E)));
5421          end if;
5422       end if;
5423
5424       --  Reset the Pure indication on an imported subprogram unless an
5425       --  explicit Pure_Function pragma was present. We do this because
5426       --  otherwise it is an insidious error to call a non-pure function from
5427       --  pure unit and have calls mysteriously optimized away. What happens
5428       --  here is that the Import can bypass the normal check to ensure that
5429       --  pure units call only pure subprograms.
5430
5431       if Is_Imported (E)
5432         and then Is_Pure (E)
5433         and then not Has_Pragma_Pure_Function (E)
5434       then
5435          Set_Is_Pure (E, False);
5436       end if;
5437
5438       --  For non-foreign convention subprograms, this is where we create
5439       --  the extra formals (for accessibility level and constrained bit
5440       --  information). We delay this till the freeze point precisely so
5441       --  that we know the convention!
5442
5443       if not Has_Foreign_Convention (E) then
5444          Create_Extra_Formals (E);
5445          Set_Mechanisms (E);
5446
5447          --  If this is convention Ada and a Valued_Procedure, that's odd
5448
5449          if Ekind (E) = E_Procedure
5450            and then Is_Valued_Procedure (E)
5451            and then Convention (E) = Convention_Ada
5452            and then Warn_On_Export_Import
5453          then
5454             Error_Msg_N
5455               ("?Valued_Procedure has no effect for convention Ada", E);
5456             Set_Is_Valued_Procedure (E, False);
5457          end if;
5458
5459       --  Case of foreign convention
5460
5461       else
5462          Set_Mechanisms (E);
5463
5464          --  For foreign conventions, warn about return of an
5465          --  unconstrained array.
5466
5467          --  Note: we *do* allow a return by descriptor for the VMS case,
5468          --  though here there is probably more to be done ???
5469
5470          if Ekind (E) = E_Function then
5471             Retype := Underlying_Type (Etype (E));
5472
5473             --  If no return type, probably some other error, e.g. a
5474             --  missing full declaration, so ignore.
5475
5476             if No (Retype) then
5477                null;
5478
5479             --  If the return type is generic, we have emitted a warning
5480             --  earlier on, and there is nothing else to check here. Specific
5481             --  instantiations may lead to erroneous behavior.
5482
5483             elsif Is_Generic_Type (Etype (E)) then
5484                null;
5485
5486             --  Display warning if returning unconstrained array
5487
5488             elsif Is_Array_Type (Retype)
5489               and then not Is_Constrained (Retype)
5490
5491               --  Exclude cases where descriptor mechanism is set, since the
5492               --  VMS descriptor mechanisms allow such unconstrained returns.
5493
5494               and then Mechanism (E) not in Descriptor_Codes
5495
5496                --  Check appropriate warning is enabled (should we check for
5497                --  Warnings (Off) on specific entities here, probably so???)
5498
5499               and then Warn_On_Export_Import
5500
5501               --  Exclude the VM case, since return of unconstrained arrays
5502               --  is properly handled in both the JVM and .NET cases.
5503
5504               and then VM_Target = No_VM
5505             then
5506                Error_Msg_N
5507                 ("?foreign convention function& should not return " &
5508                   "unconstrained array", E);
5509                return;
5510             end if;
5511          end if;
5512
5513          --  If any of the formals for an exported foreign convention
5514          --  subprogram have defaults, then emit an appropriate warning since
5515          --  this is odd (default cannot be used from non-Ada code)
5516
5517          if Is_Exported (E) then
5518             F := First_Formal (E);
5519             while Present (F) loop
5520                if Warn_On_Export_Import
5521                  and then Present (Default_Value (F))
5522                then
5523                   Error_Msg_N
5524                     ("?parameter cannot be defaulted in non-Ada call",
5525                      Default_Value (F));
5526                end if;
5527
5528                Next_Formal (F);
5529             end loop;
5530          end if;
5531       end if;
5532
5533       --  For VMS, descriptor mechanisms for parameters are allowed only for
5534       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5535       --  allowed for parameters of exported subprograms.
5536
5537       if OpenVMS_On_Target then
5538          if Is_Exported (E) then
5539             F := First_Formal (E);
5540             while Present (F) loop
5541                if Mechanism (F) = By_Descriptor_NCA then
5542                   Error_Msg_N
5543                     ("'N'C'A' descriptor for parameter not permitted", F);
5544                   Error_Msg_N
5545                     ("\can only be used for imported subprogram", F);
5546                end if;
5547
5548                Next_Formal (F);
5549             end loop;
5550
5551          elsif not Is_Imported (E) then
5552             F := First_Formal (E);
5553             while Present (F) loop
5554                if Mechanism (F) in Descriptor_Codes then
5555                   Error_Msg_N
5556                     ("descriptor mechanism for parameter not permitted", F);
5557                   Error_Msg_N
5558                     ("\can only be used for imported/exported subprogram", F);
5559                end if;
5560
5561                Next_Formal (F);
5562             end loop;
5563          end if;
5564       end if;
5565
5566       --  Pragma Inline_Always is disallowed for dispatching subprograms
5567       --  because the address of such subprograms is saved in the dispatch
5568       --  table to support dispatching calls, and dispatching calls cannot
5569       --  be inlined. This is consistent with the restriction against using
5570       --  'Access or 'Address on an Inline_Always subprogram.
5571
5572       if Is_Dispatching_Operation (E)
5573         and then Has_Pragma_Inline_Always (E)
5574       then
5575          Error_Msg_N
5576            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5577       end if;
5578
5579       --  Because of the implicit representation of inherited predefined
5580       --  operators in the front-end, the overriding status of the operation
5581       --  may be affected when a full view of a type is analyzed, and this is
5582       --  not captured by the analysis of the corresponding type declaration.
5583       --  Therefore the correctness of a not-overriding indicator must be
5584       --  rechecked when the subprogram is frozen.
5585
5586       if Nkind (E) = N_Defining_Operator_Symbol
5587         and then not Error_Posted (Parent (E))
5588       then
5589          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5590       end if;
5591    end Freeze_Subprogram;
5592
5593    ----------------------
5594    -- Is_Fully_Defined --
5595    ----------------------
5596
5597    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5598    begin
5599       if Ekind (T) = E_Class_Wide_Type then
5600          return Is_Fully_Defined (Etype (T));
5601
5602       elsif Is_Array_Type (T) then
5603          return Is_Fully_Defined (Component_Type (T));
5604
5605       elsif Is_Record_Type (T)
5606         and not Is_Private_Type (T)
5607       then
5608          --  Verify that the record type has no components with private types
5609          --  without completion.
5610
5611          declare
5612             Comp : Entity_Id;
5613
5614          begin
5615             Comp := First_Component (T);
5616             while Present (Comp) loop
5617                if not Is_Fully_Defined (Etype (Comp)) then
5618                   return False;
5619                end if;
5620
5621                Next_Component (Comp);
5622             end loop;
5623             return True;
5624          end;
5625
5626       --  For the designated type of an access to subprogram, all types in
5627       --  the profile must be fully defined.
5628
5629       elsif Ekind (T) = E_Subprogram_Type then
5630          declare
5631             F : Entity_Id;
5632
5633          begin
5634             F := First_Formal (T);
5635             while Present (F) loop
5636                if not Is_Fully_Defined (Etype (F)) then
5637                   return False;
5638                end if;
5639
5640                Next_Formal (F);
5641             end loop;
5642
5643             return Is_Fully_Defined (Etype (T));
5644          end;
5645
5646       else
5647          return not Is_Private_Type (T)
5648            or else Present (Full_View (Base_Type (T)));
5649       end if;
5650    end Is_Fully_Defined;
5651
5652    ---------------------------------
5653    -- Process_Default_Expressions --
5654    ---------------------------------
5655
5656    procedure Process_Default_Expressions
5657      (E     : Entity_Id;
5658       After : in out Node_Id)
5659    is
5660       Loc    : constant Source_Ptr := Sloc (E);
5661       Dbody  : Node_Id;
5662       Formal : Node_Id;
5663       Dcopy  : Node_Id;
5664       Dnam   : Entity_Id;
5665
5666    begin
5667       Set_Default_Expressions_Processed (E);
5668
5669       --  A subprogram instance and its associated anonymous subprogram share
5670       --  their signature. The default expression functions are defined in the
5671       --  wrapper packages for the anonymous subprogram, and should not be
5672       --  generated again for the instance.
5673
5674       if Is_Generic_Instance (E)
5675         and then Present (Alias (E))
5676         and then Default_Expressions_Processed (Alias (E))
5677       then
5678          return;
5679       end if;
5680
5681       Formal := First_Formal (E);
5682       while Present (Formal) loop
5683          if Present (Default_Value (Formal)) then
5684
5685             --  We work with a copy of the default expression because we
5686             --  do not want to disturb the original, since this would mess
5687             --  up the conformance checking.
5688
5689             Dcopy := New_Copy_Tree (Default_Value (Formal));
5690
5691             --  The analysis of the expression may generate insert actions,
5692             --  which of course must not be executed. We wrap those actions
5693             --  in a procedure that is not called, and later on eliminated.
5694             --  The following cases have no side-effects, and are analyzed
5695             --  directly.
5696
5697             if Nkind (Dcopy) = N_Identifier
5698               or else Nkind (Dcopy) = N_Expanded_Name
5699               or else Nkind (Dcopy) = N_Integer_Literal
5700               or else (Nkind (Dcopy) = N_Real_Literal
5701                         and then not Vax_Float (Etype (Dcopy)))
5702               or else Nkind (Dcopy) = N_Character_Literal
5703               or else Nkind (Dcopy) = N_String_Literal
5704               or else Known_Null (Dcopy)
5705               or else (Nkind (Dcopy) = N_Attribute_Reference
5706                         and then
5707                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5708             then
5709
5710                --  If there is no default function, we must still do a full
5711                --  analyze call on the default value, to ensure that all error
5712                --  checks are performed, e.g. those associated with static
5713                --  evaluation. Note: this branch will always be taken if the
5714                --  analyzer is turned off (but we still need the error checks).
5715
5716                --  Note: the setting of parent here is to meet the requirement
5717                --  that we can only analyze the expression while attached to
5718                --  the tree. Really the requirement is that the parent chain
5719                --  be set, we don't actually need to be in the tree.
5720
5721                Set_Parent (Dcopy, Declaration_Node (Formal));
5722                Analyze (Dcopy);
5723
5724                --  Default expressions are resolved with their own type if the
5725                --  context is generic, to avoid anomalies with private types.
5726
5727                if Ekind (Scope (E)) = E_Generic_Package then
5728                   Resolve (Dcopy);
5729                else
5730                   Resolve (Dcopy, Etype (Formal));
5731                end if;
5732
5733                --  If that resolved expression will raise constraint error,
5734                --  then flag the default value as raising constraint error.
5735                --  This allows a proper error message on the calls.
5736
5737                if Raises_Constraint_Error (Dcopy) then
5738                   Set_Raises_Constraint_Error (Default_Value (Formal));
5739                end if;
5740
5741             --  If the default is a parameterless call, we use the name of
5742             --  the called function directly, and there is no body to build.
5743
5744             elsif Nkind (Dcopy) = N_Function_Call
5745               and then No (Parameter_Associations (Dcopy))
5746             then
5747                null;
5748
5749             --  Else construct and analyze the body of a wrapper procedure
5750             --  that contains an object declaration to hold the expression.
5751             --  Given that this is done only to complete the analysis, it
5752             --  simpler to build a procedure than a function which might
5753             --  involve secondary stack expansion.
5754
5755             else
5756                Dnam := Make_Temporary (Loc, 'D');
5757
5758                Dbody :=
5759                  Make_Subprogram_Body (Loc,
5760                    Specification =>
5761                      Make_Procedure_Specification (Loc,
5762                        Defining_Unit_Name => Dnam),
5763
5764                    Declarations => New_List (
5765                      Make_Object_Declaration (Loc,
5766                        Defining_Identifier => Make_Temporary (Loc, 'T'),
5767                        Object_Definition   =>
5768                          New_Occurrence_Of (Etype (Formal), Loc),
5769                        Expression          => New_Copy_Tree (Dcopy))),
5770
5771                    Handled_Statement_Sequence =>
5772                      Make_Handled_Sequence_Of_Statements (Loc,
5773                        Statements => Empty_List));
5774
5775                Set_Scope (Dnam, Scope (E));
5776                Set_Assignment_OK (First (Declarations (Dbody)));
5777                Set_Is_Eliminated (Dnam);
5778                Insert_After (After, Dbody);
5779                Analyze (Dbody);
5780                After := Dbody;
5781             end if;
5782          end if;
5783
5784          Next_Formal (Formal);
5785       end loop;
5786    end Process_Default_Expressions;
5787
5788    ----------------------------------------
5789    -- Set_Component_Alignment_If_Not_Set --
5790    ----------------------------------------
5791
5792    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5793    begin
5794       --  Ignore if not base type, subtypes don't need anything
5795
5796       if Typ /= Base_Type (Typ) then
5797          return;
5798       end if;
5799
5800       --  Do not override existing representation
5801
5802       if Is_Packed (Typ) then
5803          return;
5804
5805       elsif Has_Specified_Layout (Typ) then
5806          return;
5807
5808       elsif Component_Alignment (Typ) /= Calign_Default then
5809          return;
5810
5811       else
5812          Set_Component_Alignment
5813            (Typ, Scope_Stack.Table
5814                   (Scope_Stack.Last).Component_Alignment_Default);
5815       end if;
5816    end Set_Component_Alignment_If_Not_Set;
5817
5818    ------------------
5819    -- Undelay_Type --
5820    ------------------
5821
5822    procedure Undelay_Type (T : Entity_Id) is
5823    begin
5824       Set_Has_Delayed_Freeze (T, False);
5825       Set_Freeze_Node (T, Empty);
5826
5827       --  Since we don't want T to have a Freeze_Node, we don't want its
5828       --  Full_View or Corresponding_Record_Type to have one either.
5829
5830       --  ??? Fundamentally, this whole handling is a kludge. What we really
5831       --  want is to be sure that for an Itype that's part of record R and is a
5832       --  subtype of type T, that it's frozen after the later of the freeze
5833       --  points of R and T. We have no way of doing that directly, so what we
5834       --  do is force most such Itypes to be frozen as part of freezing R via
5835       --  this procedure and only delay the ones that need to be delayed
5836       --  (mostly the designated types of access types that are defined as part
5837       --  of the record).
5838
5839       if Is_Private_Type (T)
5840         and then Present (Full_View (T))
5841         and then Is_Itype (Full_View (T))
5842         and then Is_Record_Type (Scope (Full_View (T)))
5843       then
5844          Undelay_Type (Full_View (T));
5845       end if;
5846
5847       if Is_Concurrent_Type (T)
5848         and then Present (Corresponding_Record_Type (T))
5849         and then Is_Itype (Corresponding_Record_Type (T))
5850         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5851       then
5852          Undelay_Type (Corresponding_Record_Type (T));
5853       end if;
5854    end Undelay_Type;
5855
5856    ------------------
5857    -- Warn_Overlay --
5858    ------------------
5859
5860    procedure Warn_Overlay
5861      (Expr : Node_Id;
5862       Typ  : Entity_Id;
5863       Nam  : Entity_Id)
5864    is
5865       Ent : constant Entity_Id := Entity (Nam);
5866       --  The object to which the address clause applies
5867
5868       Init : Node_Id;
5869       Old  : Entity_Id := Empty;
5870       Decl : Node_Id;
5871
5872    begin
5873       --  No warning if address clause overlay warnings are off
5874
5875       if not Address_Clause_Overlay_Warnings then
5876          return;
5877       end if;
5878
5879       --  No warning if there is an explicit initialization
5880
5881       Init := Original_Node (Expression (Declaration_Node (Ent)));
5882
5883       if Present (Init) and then Comes_From_Source (Init) then
5884          return;
5885       end if;
5886
5887       --  We only give the warning for non-imported entities of a type for
5888       --  which a non-null base init proc is defined, or for objects of access
5889       --  types with implicit null initialization, or when Normalize_Scalars
5890       --  applies and the type is scalar or a string type (the latter being
5891       --  tested for because predefined String types are initialized by inline
5892       --  code rather than by an init_proc). Note that we do not give the
5893       --  warning for Initialize_Scalars, since we suppressed initialization
5894       --  in this case. Also, do not warn if Suppress_Initialization is set.
5895
5896       if Present (Expr)
5897         and then not Is_Imported (Ent)
5898         and then not Initialization_Suppressed (Typ)
5899         and then (Has_Non_Null_Base_Init_Proc (Typ)
5900                    or else Is_Access_Type (Typ)
5901                    or else (Normalize_Scalars
5902                              and then (Is_Scalar_Type (Typ)
5903                                         or else Is_String_Type (Typ))))
5904       then
5905          if Nkind (Expr) = N_Attribute_Reference
5906            and then Is_Entity_Name (Prefix (Expr))
5907          then
5908             Old := Entity (Prefix (Expr));
5909
5910          elsif Is_Entity_Name (Expr)
5911            and then Ekind (Entity (Expr)) = E_Constant
5912          then
5913             Decl := Declaration_Node (Entity (Expr));
5914
5915             if Nkind (Decl) = N_Object_Declaration
5916               and then Present (Expression (Decl))
5917               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5918               and then Is_Entity_Name (Prefix (Expression (Decl)))
5919             then
5920                Old := Entity (Prefix (Expression (Decl)));
5921
5922             elsif Nkind (Expr) = N_Function_Call then
5923                return;
5924             end if;
5925
5926          --  A function call (most likely to To_Address) is probably not an
5927          --  overlay, so skip warning. Ditto if the function call was inlined
5928          --  and transformed into an entity.
5929
5930          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5931             return;
5932          end if;
5933
5934          Decl := Next (Parent (Expr));
5935
5936          --  If a pragma Import follows, we assume that it is for the current
5937          --  target of the address clause, and skip the warning.
5938
5939          if Present (Decl)
5940            and then Nkind (Decl) = N_Pragma
5941            and then Pragma_Name (Decl) = Name_Import
5942          then
5943             return;
5944          end if;
5945
5946          if Present (Old) then
5947             Error_Msg_Node_2 := Old;
5948             Error_Msg_N
5949               ("default initialization of & may modify &?",
5950                Nam);
5951          else
5952             Error_Msg_N
5953               ("default initialization of & may modify overlaid storage?",
5954                Nam);
5955          end if;
5956
5957          --  Add friendly warning if initialization comes from a packed array
5958          --  component.
5959
5960          if Is_Record_Type (Typ)  then
5961             declare
5962                Comp : Entity_Id;
5963
5964             begin
5965                Comp := First_Component (Typ);
5966                while Present (Comp) loop
5967                   if Nkind (Parent (Comp)) = N_Component_Declaration
5968                     and then Present (Expression (Parent (Comp)))
5969                   then
5970                      exit;
5971                   elsif Is_Array_Type (Etype (Comp))
5972                      and then Present (Packed_Array_Type (Etype (Comp)))
5973                   then
5974                      Error_Msg_NE
5975                        ("\packed array component& " &
5976                         "will be initialized to zero?",
5977                         Nam, Comp);
5978                      exit;
5979                   else
5980                      Next_Component (Comp);
5981                   end if;
5982                end loop;
5983             end;
5984          end if;
5985
5986          Error_Msg_N
5987            ("\use pragma Import for & to " &
5988             "suppress initialization (RM B.1(24))?",
5989             Nam);
5990       end if;
5991    end Warn_Overlay;
5992
5993 end Freeze;