gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere. This is not done in the case
 365       --  where the subprogram is an instantiation because the actual proper
 366       --  body has not been built yet.
 367
 368       if Ekind_In (Old_S, E_Function, E_Procedure)
 369         and then Nkind (Decl) = N_Subprogram_Declaration
 370         and then not Is_Generic_Instance (Old_S)
 371       then
 372          Set_Body_To_Inline (Decl, Old_S);
 373       end if;
 374
 375       --  The body generated for this renaming is an internal artifact, and
 376       --  does not  constitute a freeze point for the called entity.
 377
 378       Set_Must_Not_Freeze (Call_Name);
 379
 380       Formal := First_Formal (Defining_Entity (Decl));
 381
 382       if Present (Pref) then
 383          declare
 384             Pref_Type : constant Entity_Id := Etype (Pref);
 385             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 386
 387          begin
 388             --  The controlling formal may be an access parameter, or the
 389             --  actual may be an access value, so adjust accordingly.
 390
 391             if Is_Access_Type (Pref_Type)
 392               and then not Is_Access_Type (Form_Type)
 393             then
 394                Actuals := New_List
 395                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 396
 397             elsif Is_Access_Type (Form_Type)
 398               and then not Is_Access_Type (Pref)
 399             then
 400                Actuals := New_List
 401                  (Make_Attribute_Reference (Loc,
 402                    Attribute_Name => Name_Access,
 403                    Prefix => Relocate_Node (Pref)));
 404             else
 405                Actuals := New_List (Pref);
 406             end if;
 407          end;
 408
 409       elsif Present (Formal) then
 410          Actuals := New_List;
 411
 412       else
 413          Actuals := No_List;
 414       end if;
 415
 416       if Present (Formal) then
 417          while Present (Formal) loop
 418             Append (New_Reference_To (Formal, Loc), Actuals);
 419             Next_Formal (Formal);
 420          end loop;
 421       end if;
 422
 423       --  If the renamed entity is an entry, inherit its profile. For other
 424       --  renamings as bodies, both profiles must be subtype conformant, so it
 425       --  is not necessary to replace the profile given in the declaration.
 426       --  However, default values that are aggregates are rewritten when
 427       --  partially analyzed, so we recover the original aggregate to insure
 428       --  that subsequent conformity checking works. Similarly, if the default
 429       --  expression was constant-folded, recover the original expression.
 430
 431       Formal := First_Formal (Defining_Entity (Decl));
 432
 433       if Present (Formal) then
 434          O_Formal := First_Formal (Old_S);
 435          Param_Spec := First (Parameter_Specifications (Spec));
 436          while Present (Formal) loop
 437             if Is_Entry (Old_S) then
 438                if Nkind (Parameter_Type (Param_Spec)) /=
 439                                                     N_Access_Definition
 440                then
 441                   Set_Etype (Formal, Etype (O_Formal));
 442                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 443                end if;
 444
 445             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 446               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 447                                            Nkind (Default_Value (O_Formal))
 448             then
 449                Set_Expression (Param_Spec,
 450                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 451             end if;
 452
 453             Next_Formal (Formal);
 454             Next_Formal (O_Formal);
 455             Next (Param_Spec);
 456          end loop;
 457       end if;
 458
 459       --  If the renamed entity is a function, the generated body contains a
 460       --  return statement. Otherwise, build a procedure call. If the entity is
 461       --  an entry, subsequent analysis of the call will transform it into the
 462       --  proper entry or protected operation call. If the renamed entity is
 463       --  a character literal, return it directly.
 464
 465       if Ekind (Old_S) = E_Function
 466         or else Ekind (Old_S) = E_Operator
 467         or else (Ekind (Old_S) = E_Subprogram_Type
 468                   and then Etype (Old_S) /= Standard_Void_Type)
 469       then
 470          Call_Node :=
 471            Make_Simple_Return_Statement (Loc,
 472               Expression =>
 473                 Make_Function_Call (Loc,
 474                   Name => Call_Name,
 475                   Parameter_Associations => Actuals));
 476
 477       elsif Ekind (Old_S) = E_Enumeration_Literal then
 478          Call_Node :=
 479            Make_Simple_Return_Statement (Loc,
 480               Expression => New_Occurrence_Of (Old_S, Loc));
 481
 482       elsif Nkind (Nam) = N_Character_Literal then
 483          Call_Node :=
 484            Make_Simple_Return_Statement (Loc,
 485              Expression => Call_Name);
 486
 487       else
 488          Call_Node :=
 489            Make_Procedure_Call_Statement (Loc,
 490              Name => Call_Name,
 491              Parameter_Associations => Actuals);
 492       end if;
 493
 494       --  Create entities for subprogram body and formals
 495
 496       Set_Defining_Unit_Name (Spec,
 497         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 498
 499       Param_Spec := First (Parameter_Specifications (Spec));
 500       while Present (Param_Spec) loop
 501          Set_Defining_Identifier (Param_Spec,
 502            Make_Defining_Identifier (Loc,
 503              Chars => Chars (Defining_Identifier (Param_Spec))));
 504          Next (Param_Spec);
 505       end loop;
 506
 507       Body_Node :=
 508         Make_Subprogram_Body (Loc,
 509           Specification => Spec,
 510           Declarations => New_List,
 511           Handled_Statement_Sequence =>
 512             Make_Handled_Sequence_Of_Statements (Loc,
 513               Statements => New_List (Call_Node)));
 514
 515       if Nkind (Decl) /= N_Subprogram_Declaration then
 516          Rewrite (N,
 517            Make_Subprogram_Declaration (Loc,
 518              Specification => Specification (N)));
 519       end if;
 520
 521       --  Link the body to the entity whose declaration it completes. If
 522       --  the body is analyzed when the renamed entity is frozen, it may
 523       --  be necessary to restore the proper scope (see package Exp_Ch13).
 524
 525       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 526         and then Present (Corresponding_Spec (N))
 527       then
 528          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 529       else
 530          Set_Corresponding_Spec (Body_Node, New_S);
 531       end if;
 532
 533       return Body_Node;
 534    end Build_Renamed_Body;
 535
 536    --------------------------
 537    -- Check_Address_Clause --
 538    --------------------------
 539
 540    procedure Check_Address_Clause (E : Entity_Id) is
 541       Addr : constant Node_Id   := Address_Clause (E);
 542       Expr : Node_Id;
 543       Decl : constant Node_Id   := Declaration_Node (E);
 544       Typ  : constant Entity_Id := Etype (E);
 545
 546    begin
 547       if Present (Addr) then
 548          Expr := Expression (Addr);
 549
 550          if Needs_Constant_Address (Decl, Typ) then
 551             Check_Constant_Address_Clause (Expr, E);
 552
 553             --  Has_Delayed_Freeze was set on E when the address clause was
 554             --  analyzed. Reset the flag now unless freeze actions were
 555             --  attached to it in the mean time.
 556
 557             if No (Freeze_Node (E)) then
 558                Set_Has_Delayed_Freeze (E, False);
 559             end if;
 560          end if;
 561
 562          --  If Rep_Clauses are to be ignored, remove address clause from
 563          --  list attached to entity, because it may be illegal for gigi,
 564          --  for example by breaking order of elaboration..
 565
 566          if Ignore_Rep_Clauses then
 567             declare
 568                Rep : Node_Id;
 569
 570             begin
 571                Rep := First_Rep_Item (E);
 572
 573                if Rep = Addr then
 574                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 575
 576                else
 577                   while Present (Rep)
 578                     and then Next_Rep_Item (Rep) /= Addr
 579                   loop
 580                      Rep := Next_Rep_Item (Rep);
 581                   end loop;
 582                end if;
 583
 584                if Present (Rep) then
 585                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 586                end if;
 587             end;
 588
 589             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 590
 591          elsif not Error_Posted (Expr)
 592            and then not Needs_Finalization (Typ)
 593          then
 594             Warn_Overlay (Expr, Typ, Name (Addr));
 595          end if;
 596       end if;
 597    end Check_Address_Clause;
 598
 599    -----------------------------
 600    -- Check_Compile_Time_Size --
 601    -----------------------------
 602
 603    procedure Check_Compile_Time_Size (T : Entity_Id) is
 604
 605       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 606       --  Sets the compile time known size (32 bits or less) in the Esize
 607       --  field, of T checking for a size clause that was given which attempts
 608       --  to give a smaller size, and also checking for an alignment clause.
 609
 610       function Size_Known (T : Entity_Id) return Boolean;
 611       --  Recursive function that does all the work
 612
 613       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 614       --  If T is a constrained subtype, its size is not known if any of its
 615       --  discriminant constraints is not static and it is not a null record.
 616       --  The test is conservative and doesn't check that the components are
 617       --  in fact constrained by non-static discriminant values. Could be made
 618       --  more precise ???
 619
 620       --------------------
 621       -- Set_Small_Size --
 622       --------------------
 623
 624       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 625       begin
 626          if S > 32 then
 627             return;
 628
 629          --  Check for bad size clause given
 630
 631          elsif Has_Size_Clause (T) then
 632             if RM_Size (T) < S then
 633                Error_Msg_Uint_1 := S;
 634                Error_Msg_NE
 635                  ("size for& too small, minimum allowed is ^",
 636                   Size_Clause (T), T);
 637             end if;
 638
 639          --  Set size if not set already
 640
 641          elsif Unknown_RM_Size (T) then
 642             Set_RM_Size (T, S);
 643          end if;
 644       end Set_Small_Size;
 645
 646       ----------------
 647       -- Size_Known --
 648       ----------------
 649
 650       function Size_Known (T : Entity_Id) return Boolean is
 651          Index : Entity_Id;
 652          Comp  : Entity_Id;
 653          Ctyp  : Entity_Id;
 654          Low   : Node_Id;
 655          High  : Node_Id;
 656
 657       begin
 658          if Size_Known_At_Compile_Time (T) then
 659             return True;
 660
 661          --  Always True for scalar types. This is true even for generic formal
 662          --  scalar types. We used to return False in the latter case, but the
 663          --  size is known at compile time, even in the template, we just do
 664          --  not know the exact size but that's not the point of this routine.
 665
 666          elsif Is_Scalar_Type (T)
 667            or else Is_Task_Type (T)
 668          then
 669             return True;
 670
 671          --  Array types
 672
 673          elsif Is_Array_Type (T) then
 674
 675             --  String literals always have known size, and we can set it
 676
 677             if Ekind (T) = E_String_Literal_Subtype then
 678                Set_Small_Size (T, Component_Size (T)
 679                                * String_Literal_Length (T));
 680                return True;
 681
 682             --  Unconstrained types never have known at compile time size
 683
 684             elsif not Is_Constrained (T) then
 685                return False;
 686
 687             --  Don't do any recursion on type with error posted, since we may
 688             --  have a malformed type that leads us into a loop.
 689
 690             elsif Error_Posted (T) then
 691                return False;
 692
 693             --  Otherwise if component size unknown, then array size unknown
 694
 695             elsif not Size_Known (Component_Type (T)) then
 696                return False;
 697             end if;
 698
 699             --  Check for all indexes static, and also compute possible size
 700             --  (in case it is less than 32 and may be packable).
 701
 702             declare
 703                Esiz : Uint := Component_Size (T);
 704                Dim  : Uint;
 705
 706             begin
 707                Index := First_Index (T);
 708                while Present (Index) loop
 709                   if Nkind (Index) = N_Range then
 710                      Get_Index_Bounds (Index, Low, High);
 711
 712                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 713                      return False;
 714
 715                   else
 716                      Low  := Type_Low_Bound (Etype (Index));
 717                      High := Type_High_Bound (Etype (Index));
 718                   end if;
 719
 720                   if not Compile_Time_Known_Value (Low)
 721                     or else not Compile_Time_Known_Value (High)
 722                     or else Etype (Index) = Any_Type
 723                   then
 724                      return False;
 725
 726                   else
 727                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 728
 729                      if Dim >= 0 then
 730                         Esiz := Esiz * Dim;
 731                      else
 732                         Esiz := Uint_0;
 733                      end if;
 734                   end if;
 735
 736                   Next_Index (Index);
 737                end loop;
 738
 739                Set_Small_Size (T, Esiz);
 740                return True;
 741             end;
 742
 743          --  Access types always have known at compile time sizes
 744
 745          elsif Is_Access_Type (T) then
 746             return True;
 747
 748          --  For non-generic private types, go to underlying type if present
 749
 750          elsif Is_Private_Type (T)
 751            and then not Is_Generic_Type (T)
 752            and then Present (Underlying_Type (T))
 753          then
 754             --  Don't do any recursion on type with error posted, since we may
 755             --  have a malformed type that leads us into a loop.
 756
 757             if Error_Posted (T) then
 758                return False;
 759             else
 760                return Size_Known (Underlying_Type (T));
 761             end if;
 762
 763          --  Record types
 764
 765          elsif Is_Record_Type (T) then
 766
 767             --  A class-wide type is never considered to have a known size
 768
 769             if Is_Class_Wide_Type (T) then
 770                return False;
 771
 772             --  A subtype of a variant record must not have non-static
 773             --  discriminated components.
 774
 775             elsif T /= Base_Type (T)
 776               and then not Static_Discriminated_Components (T)
 777             then
 778                return False;
 779
 780             --  Don't do any recursion on type with error posted, since we may
 781             --  have a malformed type that leads us into a loop.
 782
 783             elsif Error_Posted (T) then
 784                return False;
 785             end if;
 786
 787             --  Now look at the components of the record
 788
 789             declare
 790                --  The following two variables are used to keep track of the
 791                --  size of packed records if we can tell the size of the packed
 792                --  record in the front end. Packed_Size_Known is True if so far
 793                --  we can figure out the size. It is initialized to True for a
 794                --  packed record, unless the record has discriminants. The
 795                --  reason we eliminate the discriminated case is that we don't
 796                --  know the way the back end lays out discriminated packed
 797                --  records. If Packed_Size_Known is True, then Packed_Size is
 798                --  the size in bits so far.
 799
 800                Packed_Size_Known : Boolean :=
 801                                      Is_Packed (T)
 802                                        and then not Has_Discriminants (T);
 803
 804                Packed_Size : Uint := Uint_0;
 805
 806             begin
 807                --  Test for variant part present
 808
 809                if Has_Discriminants (T)
 810                  and then Present (Parent (T))
 811                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 812                  and then Nkind (Type_Definition (Parent (T))) =
 813                                                N_Record_Definition
 814                  and then not Null_Present (Type_Definition (Parent (T)))
 815                  and then Present (Variant_Part
 816                             (Component_List (Type_Definition (Parent (T)))))
 817                then
 818                   --  If variant part is present, and type is unconstrained,
 819                   --  then we must have defaulted discriminants, or a size
 820                   --  clause must be present for the type, or else the size
 821                   --  is definitely not known at compile time.
 822
 823                   if not Is_Constrained (T)
 824                     and then
 825                       No (Discriminant_Default_Value (First_Discriminant (T)))
 826                     and then Unknown_RM_Size (T)
 827                   then
 828                      return False;
 829                   end if;
 830                end if;
 831
 832                --  Loop through components
 833
 834                Comp := First_Component_Or_Discriminant (T);
 835                while Present (Comp) loop
 836                   Ctyp := Etype (Comp);
 837
 838                   --  We do not know the packed size if there is a component
 839                   --  clause present (we possibly could, but this would only
 840                   --  help in the case of a record with partial rep clauses.
 841                   --  That's because in the case of full rep clauses, the
 842                   --  size gets figured out anyway by a different circuit).
 843
 844                   if Present (Component_Clause (Comp)) then
 845                      Packed_Size_Known := False;
 846                   end if;
 847
 848                   --  We need to identify a component that is an array where
 849                   --  the index type is an enumeration type with non-standard
 850                   --  representation, and some bound of the type depends on a
 851                   --  discriminant.
 852
 853                   --  This is because gigi computes the size by doing a
 854                   --  substitution of the appropriate discriminant value in
 855                   --  the size expression for the base type, and gigi is not
 856                   --  clever enough to evaluate the resulting expression (which
 857                   --  involves a call to rep_to_pos) at compile time.
 858
 859                   --  It would be nice if gigi would either recognize that
 860                   --  this expression can be computed at compile time, or
 861                   --  alternatively figured out the size from the subtype
 862                   --  directly, where all the information is at hand ???
 863
 864                   if Is_Array_Type (Etype (Comp))
 865                     and then Present (Packed_Array_Type (Etype (Comp)))
 866                   then
 867                      declare
 868                         Ocomp  : constant Entity_Id :=
 869                                    Original_Record_Component (Comp);
 870                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 871                         Ind    : Node_Id;
 872                         Indtyp : Entity_Id;
 873                         Lo, Hi : Node_Id;
 874
 875                      begin
 876                         Ind := First_Index (OCtyp);
 877                         while Present (Ind) loop
 878                            Indtyp := Etype (Ind);
 879
 880                            if Is_Enumeration_Type (Indtyp)
 881                              and then Has_Non_Standard_Rep (Indtyp)
 882                            then
 883                               Lo := Type_Low_Bound  (Indtyp);
 884                               Hi := Type_High_Bound (Indtyp);
 885
 886                               if Is_Entity_Name (Lo)
 887                                 and then Ekind (Entity (Lo)) = E_Discriminant
 888                               then
 889                                  return False;
 890
 891                               elsif Is_Entity_Name (Hi)
 892                                 and then Ekind (Entity (Hi)) = E_Discriminant
 893                               then
 894                                  return False;
 895                               end if;
 896                            end if;
 897
 898                            Next_Index (Ind);
 899                         end loop;
 900                      end;
 901                   end if;
 902
 903                   --  Clearly size of record is not known if the size of one of
 904                   --  the components is not known.
 905
 906                   if not Size_Known (Ctyp) then
 907                      return False;
 908                   end if;
 909
 910                   --  Accumulate packed size if possible
 911
 912                   if Packed_Size_Known then
 913
 914                      --  We can only deal with elementary types, since for
 915                      --  non-elementary components, alignment enters into the
 916                      --  picture, and we don't know enough to handle proper
 917                      --  alignment in this context. Packed arrays count as
 918                      --  elementary if the representation is a modular type.
 919
 920                      if Is_Elementary_Type (Ctyp)
 921                        or else (Is_Array_Type (Ctyp)
 922                                  and then Present (Packed_Array_Type (Ctyp))
 923                                  and then Is_Modular_Integer_Type
 924                                             (Packed_Array_Type (Ctyp)))
 925                      then
 926                         --  If RM_Size is known and static, then we can keep
 927                         --  accumulating the packed size.
 928
 929                         if Known_Static_RM_Size (Ctyp) then
 930
 931                            --  A little glitch, to be removed sometime ???
 932                            --  gigi does not understand zero sizes yet.
 933
 934                            if RM_Size (Ctyp) = Uint_0 then
 935                               Packed_Size_Known := False;
 936
 937                            --  Normal case where we can keep accumulating the
 938                            --  packed array size.
 939
 940                            else
 941                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 942                            end if;
 943
 944                         --  If we have a field whose RM_Size is not known then
 945                         --  we can't figure out the packed size here.
 946
 947                         else
 948                            Packed_Size_Known := False;
 949                         end if;
 950
 951                      --  If we have a non-elementary type we can't figure out
 952                      --  the packed array size (alignment issues).
 953
 954                      else
 955                         Packed_Size_Known := False;
 956                      end if;
 957                   end if;
 958
 959                   Next_Component_Or_Discriminant (Comp);
 960                end loop;
 961
 962                if Packed_Size_Known then
 963                   Set_Small_Size (T, Packed_Size);
 964                end if;
 965
 966                return True;
 967             end;
 968
 969          --  All other cases, size not known at compile time
 970
 971          else
 972             return False;
 973          end if;
 974       end Size_Known;
 975
 976       -------------------------------------
 977       -- Static_Discriminated_Components --
 978       -------------------------------------
 979
 980       function Static_Discriminated_Components
 981         (T : Entity_Id) return Boolean
 982       is
 983          Constraint : Elmt_Id;
 984
 985       begin
 986          if Has_Discriminants (T)
 987            and then Present (Discriminant_Constraint (T))
 988            and then Present (First_Component (T))
 989          then
 990             Constraint := First_Elmt (Discriminant_Constraint (T));
 991             while Present (Constraint) loop
 992                if not Compile_Time_Known_Value (Node (Constraint)) then
 993                   return False;
 994                end if;
 995
 996                Next_Elmt (Constraint);
 997             end loop;
 998          end if;
 999
1000          return True;
1001       end Static_Discriminated_Components;
1002
1003    --  Start of processing for Check_Compile_Time_Size
1004
1005    begin
1006       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1007    end Check_Compile_Time_Size;
1008
1009    -----------------------------
1010    -- Check_Debug_Info_Needed --
1011    -----------------------------
1012
1013    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1014    begin
1015       if Debug_Info_Off (T) then
1016          return;
1017
1018       elsif Comes_From_Source (T)
1019         or else Debug_Generated_Code
1020         or else Debug_Flag_VV
1021         or else Needs_Debug_Info (T)
1022       then
1023          Set_Debug_Info_Needed (T);
1024       end if;
1025    end Check_Debug_Info_Needed;
1026
1027    ----------------------------
1028    -- Check_Strict_Alignment --
1029    ----------------------------
1030
1031    procedure Check_Strict_Alignment (E : Entity_Id) is
1032       Comp  : Entity_Id;
1033
1034    begin
1035       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1036          Set_Strict_Alignment (E);
1037
1038       elsif Is_Array_Type (E) then
1039          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1040
1041       elsif Is_Record_Type (E) then
1042          if Is_Limited_Record (E) then
1043             Set_Strict_Alignment (E);
1044             return;
1045          end if;
1046
1047          Comp := First_Component (E);
1048          while Present (Comp) loop
1049             if not Is_Type (Comp)
1050               and then (Strict_Alignment (Etype (Comp))
1051                          or else Is_Aliased (Comp))
1052             then
1053                Set_Strict_Alignment (E);
1054                return;
1055             end if;
1056
1057             Next_Component (Comp);
1058          end loop;
1059       end if;
1060    end Check_Strict_Alignment;
1061
1062    -------------------------
1063    -- Check_Unsigned_Type --
1064    -------------------------
1065
1066    procedure Check_Unsigned_Type (E : Entity_Id) is
1067       Ancestor : Entity_Id;
1068       Lo_Bound : Node_Id;
1069       Btyp     : Entity_Id;
1070
1071    begin
1072       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1073          return;
1074       end if;
1075
1076       --  Do not attempt to analyze case where range was in error
1077
1078       if No (Scalar_Range (E))
1079         or else Error_Posted (Scalar_Range (E))
1080       then
1081          return;
1082       end if;
1083
1084       --  The situation that is non trivial is something like
1085
1086       --     subtype x1 is integer range -10 .. +10;
1087       --     subtype x2 is x1 range 0 .. V1;
1088       --     subtype x3 is x2 range V2 .. V3;
1089       --     subtype x4 is x3 range V4 .. V5;
1090
1091       --  where Vn are variables. Here the base type is signed, but we still
1092       --  know that x4 is unsigned because of the lower bound of x2.
1093
1094       --  The only way to deal with this is to look up the ancestor chain
1095
1096       Ancestor := E;
1097       loop
1098          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1099             return;
1100          end if;
1101
1102          Lo_Bound := Type_Low_Bound (Ancestor);
1103
1104          if Compile_Time_Known_Value (Lo_Bound) then
1105
1106             if Expr_Rep_Value (Lo_Bound) >= 0 then
1107                Set_Is_Unsigned_Type (E, True);
1108             end if;
1109
1110             return;
1111
1112          else
1113             Ancestor := Ancestor_Subtype (Ancestor);
1114
1115             --  If no ancestor had a static lower bound, go to base type
1116
1117             if No (Ancestor) then
1118
1119                --  Note: the reason we still check for a compile time known
1120                --  value for the base type is that at least in the case of
1121                --  generic formals, we can have bounds that fail this test,
1122                --  and there may be other cases in error situations.
1123
1124                Btyp := Base_Type (E);
1125
1126                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1127                   return;
1128                end if;
1129
1130                Lo_Bound := Type_Low_Bound (Base_Type (E));
1131
1132                if Compile_Time_Known_Value (Lo_Bound)
1133                  and then Expr_Rep_Value (Lo_Bound) >= 0
1134                then
1135                   Set_Is_Unsigned_Type (E, True);
1136                end if;
1137
1138                return;
1139             end if;
1140          end if;
1141       end loop;
1142    end Check_Unsigned_Type;
1143
1144    -------------------------
1145    -- Is_Atomic_Aggregate --
1146    -------------------------
1147
1148    function  Is_Atomic_Aggregate
1149      (E   : Entity_Id;
1150       Typ : Entity_Id) return Boolean
1151    is
1152       Loc   : constant Source_Ptr := Sloc (E);
1153       New_N : Node_Id;
1154       Par   : Node_Id;
1155       Temp  : Entity_Id;
1156
1157    begin
1158       Par := Parent (E);
1159
1160       --  Array may be qualified, so find outer context
1161
1162       if Nkind (Par) = N_Qualified_Expression then
1163          Par := Parent (Par);
1164       end if;
1165
1166       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1167         and then Comes_From_Source (Par)
1168       then
1169          Temp := Make_Temporary (Loc, 'T', E);
1170          New_N :=
1171            Make_Object_Declaration (Loc,
1172              Defining_Identifier => Temp,
1173              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1174              Expression          => Relocate_Node (E));
1175          Insert_Before (Par, New_N);
1176          Analyze (New_N);
1177
1178          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1179          return True;
1180
1181       else
1182          return False;
1183       end if;
1184    end Is_Atomic_Aggregate;
1185
1186    ----------------
1187    -- Freeze_All --
1188    ----------------
1189
1190    --  Note: the easy coding for this procedure would be to just build a
1191    --  single list of freeze nodes and then insert them and analyze them
1192    --  all at once. This won't work, because the analysis of earlier freeze
1193    --  nodes may recursively freeze types which would otherwise appear later
1194    --  on in the freeze list. So we must analyze and expand the freeze nodes
1195    --  as they are generated.
1196
1197    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1198       E     : Entity_Id;
1199       Decl  : Node_Id;
1200
1201       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1202       --  This is the internal recursive routine that does freezing of entities
1203       --  (but NOT the analysis of default expressions, which should not be
1204       --  recursive, we don't want to analyze those till we are sure that ALL
1205       --  the types are frozen).
1206
1207       --------------------
1208       -- Freeze_All_Ent --
1209       --------------------
1210
1211       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1212          E     : Entity_Id;
1213          Flist : List_Id;
1214          Lastn : Node_Id;
1215
1216          procedure Process_Flist;
1217          --  If freeze nodes are present, insert and analyze, and reset cursor
1218          --  for next insertion.
1219
1220          -------------------
1221          -- Process_Flist --
1222          -------------------
1223
1224          procedure Process_Flist is
1225          begin
1226             if Is_Non_Empty_List (Flist) then
1227                Lastn := Next (After);
1228                Insert_List_After_And_Analyze (After, Flist);
1229
1230                if Present (Lastn) then
1231                   After := Prev (Lastn);
1232                else
1233                   After := Last (List_Containing (After));
1234                end if;
1235             end if;
1236          end Process_Flist;
1237
1238       --  Start or processing for Freeze_All_Ent
1239
1240       begin
1241          E := From;
1242          while Present (E) loop
1243
1244             --  If the entity is an inner package which is not a package
1245             --  renaming, then its entities must be frozen at this point. Note
1246             --  that such entities do NOT get frozen at the end of the nested
1247             --  package itself (only library packages freeze).
1248
1249             --  Same is true for task declarations, where anonymous records
1250             --  created for entry parameters must be frozen.
1251
1252             if Ekind (E) = E_Package
1253               and then No (Renamed_Object (E))
1254               and then not Is_Child_Unit (E)
1255               and then not Is_Frozen (E)
1256             then
1257                Push_Scope (E);
1258                Install_Visible_Declarations (E);
1259                Install_Private_Declarations (E);
1260
1261                Freeze_All (First_Entity (E), After);
1262
1263                End_Package_Scope (E);
1264
1265                if Is_Generic_Instance (E)
1266                  and then Has_Delayed_Freeze (E)
1267                then
1268                   Set_Has_Delayed_Freeze (E, False);
1269                   Expand_N_Package_Declaration (Unit_Declaration_Node (E));
1270                end if;
1271
1272             elsif Ekind (E) in Task_Kind
1273               and then
1274                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1275                    or else
1276                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1277             then
1278                Push_Scope (E);
1279                Freeze_All (First_Entity (E), After);
1280                End_Scope;
1281
1282             --  For a derived tagged type, we must ensure that all the
1283             --  primitive operations of the parent have been frozen, so that
1284             --  their addresses will be in the parent's dispatch table at the
1285             --  point it is inherited.
1286
1287             elsif Ekind (E) = E_Record_Type
1288               and then Is_Tagged_Type (E)
1289               and then Is_Tagged_Type (Etype (E))
1290               and then Is_Derived_Type (E)
1291             then
1292                declare
1293                   Prim_List : constant Elist_Id :=
1294                                Primitive_Operations (Etype (E));
1295
1296                   Prim : Elmt_Id;
1297                   Subp : Entity_Id;
1298
1299                begin
1300                   Prim := First_Elmt (Prim_List);
1301                   while Present (Prim) loop
1302                      Subp := Node (Prim);
1303
1304                      if Comes_From_Source (Subp)
1305                        and then not Is_Frozen (Subp)
1306                      then
1307                         Flist := Freeze_Entity (Subp, After);
1308                         Process_Flist;
1309                      end if;
1310
1311                      Next_Elmt (Prim);
1312                   end loop;
1313                end;
1314             end if;
1315
1316             if not Is_Frozen (E) then
1317                Flist := Freeze_Entity (E, After);
1318                Process_Flist;
1319
1320             --  If already frozen, and there are delayed aspects, this is where
1321             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1322             --  for a description of how we handle aspect visibility).
1323
1324             elsif Has_Delayed_Aspects (E) then
1325                declare
1326                   Ritem : Node_Id;
1327
1328                begin
1329                   Ritem := First_Rep_Item (E);
1330                   while Present (Ritem) loop
1331                      if Nkind (Ritem) = N_Aspect_Specification
1332                        and then Entity (Ritem) = E
1333                        and then Is_Delayed_Aspect (Ritem)
1334                      then
1335                         Check_Aspect_At_End_Of_Declarations (Ritem);
1336                      end if;
1337
1338                      Ritem := Next_Rep_Item (Ritem);
1339                   end loop;
1340                end;
1341             end if;
1342
1343             --  If an incomplete type is still not frozen, this may be a
1344             --  premature freezing because of a body declaration that follows.
1345             --  Indicate where the freezing took place. Freezing will happen
1346             --  if the body comes from source, but not if it is internally
1347             --  generated, for example as the body of a type invariant.
1348
1349             --  If the freezing is caused by the end of the current declarative
1350             --  part, it is a Taft Amendment type, and there is no error.
1351
1352             if not Is_Frozen (E)
1353               and then Ekind (E) = E_Incomplete_Type
1354             then
1355                declare
1356                   Bod : constant Node_Id := Next (After);
1357
1358                begin
1359                   --  The presence of a body freezes all entities previously
1360                   --  declared in the current list of declarations, but this
1361                   --  does not apply if the body does not come from source.
1362                   --  A type invariant is transformed into a subprogram body
1363                   --  which is placed at the end of the private part of the
1364                   --  current package, but this body does not freeze incomplete
1365                   --  types that may be declared in this private part.
1366
1367                   if (Nkind_In (Bod, N_Subprogram_Body,
1368                                      N_Entry_Body,
1369                                      N_Package_Body,
1370                                      N_Protected_Body,
1371                                      N_Task_Body)
1372                         or else Nkind (Bod) in N_Body_Stub)
1373                     and then
1374                       List_Containing (After) = List_Containing (Parent (E))
1375                     and then Comes_From_Source (Bod)
1376                   then
1377                      Error_Msg_Sloc := Sloc (Next (After));
1378                      Error_Msg_NE
1379                        ("type& is frozen# before its full declaration",
1380                          Parent (E), E);
1381                   end if;
1382                end;
1383             end if;
1384
1385             Next_Entity (E);
1386          end loop;
1387       end Freeze_All_Ent;
1388
1389    --  Start of processing for Freeze_All
1390
1391    begin
1392       Freeze_All_Ent (From, After);
1393
1394       --  Now that all types are frozen, we can deal with default expressions
1395       --  that require us to build a default expression functions. This is the
1396       --  point at which such functions are constructed (after all types that
1397       --  might be used in such expressions have been frozen).
1398
1399       --  For subprograms that are renaming_as_body, we create the wrapper
1400       --  bodies as needed.
1401
1402       --  We also add finalization chains to access types whose designated
1403       --  types are controlled. This is normally done when freezing the type,
1404       --  but this misses recursive type definitions where the later members
1405       --  of the recursion introduce controlled components.
1406
1407       --  Loop through entities
1408
1409       E := From;
1410       while Present (E) loop
1411          if Is_Subprogram (E) then
1412
1413             if not Default_Expressions_Processed (E) then
1414                Process_Default_Expressions (E, After);
1415             end if;
1416
1417             if not Has_Completion (E) then
1418                Decl := Unit_Declaration_Node (E);
1419
1420                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1421                   if Error_Posted (Decl) then
1422                      Set_Has_Completion (E);
1423                   else
1424                      Build_And_Analyze_Renamed_Body (Decl, E, After);
1425                   end if;
1426
1427                elsif Nkind (Decl) = N_Subprogram_Declaration
1428                  and then Present (Corresponding_Body (Decl))
1429                  and then
1430                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1431                                           = N_Subprogram_Renaming_Declaration
1432                then
1433                   Build_And_Analyze_Renamed_Body
1434                     (Decl, Corresponding_Body (Decl), After);
1435                end if;
1436             end if;
1437
1438          elsif Ekind (E) in Task_Kind
1439            and then
1440              (Nkind (Parent (E)) = N_Task_Type_Declaration
1441                 or else
1442               Nkind (Parent (E)) = N_Single_Task_Declaration)
1443          then
1444             declare
1445                Ent : Entity_Id;
1446
1447             begin
1448                Ent := First_Entity (E);
1449                while Present (Ent) loop
1450                   if Is_Entry (Ent)
1451                     and then not Default_Expressions_Processed (Ent)
1452                   then
1453                      Process_Default_Expressions (Ent, After);
1454                   end if;
1455
1456                   Next_Entity (Ent);
1457                end loop;
1458             end;
1459
1460          --  We add finalization masters to access types whose designated types
1461          --  require finalization. This is normally done when freezing the
1462          --  type, but this misses recursive type definitions where the later
1463          --  members of the recursion introduce controlled components (such as
1464          --  can happen when incomplete types are involved), as well cases
1465          --  where a component type is private and the controlled full type
1466          --  occurs after the access type is frozen. Cases that don't need a
1467          --  finalization master are generic formal types (the actual type will
1468          --  have it) and types with Java and CIL conventions, since those are
1469          --  used for API bindings. (Are there any other cases that should be
1470          --  excluded here???)
1471
1472          elsif Is_Access_Type (E)
1473            and then Comes_From_Source (E)
1474            and then not Is_Generic_Type (E)
1475            and then Needs_Finalization (Designated_Type (E))
1476          then
1477             Build_Finalization_Master (E);
1478          end if;
1479
1480          Next_Entity (E);
1481       end loop;
1482    end Freeze_All;
1483
1484    -----------------------
1485    -- Freeze_And_Append --
1486    -----------------------
1487
1488    procedure Freeze_And_Append
1489      (Ent    : Entity_Id;
1490       N      : Node_Id;
1491       Result : in out List_Id)
1492    is
1493       L : constant List_Id := Freeze_Entity (Ent, N);
1494    begin
1495       if Is_Non_Empty_List (L) then
1496          if Result = No_List then
1497             Result := L;
1498          else
1499             Append_List (L, Result);
1500          end if;
1501       end if;
1502    end Freeze_And_Append;
1503
1504    -------------------
1505    -- Freeze_Before --
1506    -------------------
1507
1508    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1509       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1510    begin
1511       if Is_Non_Empty_List (Freeze_Nodes) then
1512          Insert_Actions (N, Freeze_Nodes);
1513       end if;
1514    end Freeze_Before;
1515
1516    -------------------
1517    -- Freeze_Entity --
1518    -------------------
1519
1520    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1521       Loc    : constant Source_Ptr := Sloc (N);
1522       Test_E : Entity_Id := E;
1523       Comp   : Entity_Id;
1524       F_Node : Node_Id;
1525       Indx   : Node_Id;
1526       Formal : Entity_Id;
1527       Atype  : Entity_Id;
1528
1529       Result : List_Id := No_List;
1530       --  List of freezing actions, left at No_List if none
1531
1532       Has_Default_Initialization : Boolean := False;
1533       --  This flag gets set to true for a variable with default initialization
1534
1535       procedure Add_To_Result (N : Node_Id);
1536       --  N is a freezing action to be appended to the Result
1537
1538       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1539       --  Check that an Access or Unchecked_Access attribute with a prefix
1540       --  which is the current instance type can only be applied when the type
1541       --  is limited.
1542
1543       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1544       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1545       --  integer literal without an explicit corresponding size clause. The
1546       --  caller has checked that Utype is a modular integer type.
1547
1548       function After_Last_Declaration return Boolean;
1549       --  If Loc is a freeze_entity that appears after the last declaration
1550       --  in the scope, inhibit error messages on late completion.
1551
1552       procedure Freeze_Record_Type (Rec : Entity_Id);
1553       --  Freeze each component, handle some representation clauses, and freeze
1554       --  primitive operations if this is a tagged type.
1555
1556       -------------------
1557       -- Add_To_Result --
1558       -------------------
1559
1560       procedure Add_To_Result (N : Node_Id) is
1561       begin
1562          if No (Result) then
1563             Result := New_List (N);
1564          else
1565             Append (N, Result);
1566          end if;
1567       end Add_To_Result;
1568
1569       ----------------------------
1570       -- After_Last_Declaration --
1571       ----------------------------
1572
1573       function After_Last_Declaration return Boolean is
1574          Spec : constant Node_Id := Parent (Current_Scope);
1575       begin
1576          if Nkind (Spec) = N_Package_Specification then
1577             if Present (Private_Declarations (Spec)) then
1578                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1579             elsif Present (Visible_Declarations (Spec)) then
1580                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1581             else
1582                return False;
1583             end if;
1584          else
1585             return False;
1586          end if;
1587       end After_Last_Declaration;
1588
1589       ----------------------------
1590       -- Check_Current_Instance --
1591       ----------------------------
1592
1593       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1594
1595          function Is_Aliased_View_Of_Type (Typ : Entity_Id) return Boolean;
1596          --  Determine whether Typ is compatible with the rules for aliased
1597          --  views of types as defined in RM 3.10 in the various dialects.
1598
1599          function Process (N : Node_Id) return Traverse_Result;
1600          --  Process routine to apply check to given node
1601
1602          -----------------------------
1603          -- Is_Aliased_View_Of_Type --
1604          -----------------------------
1605
1606          function Is_Aliased_View_Of_Type (Typ : Entity_Id) return Boolean is
1607             Typ_Decl : constant Node_Id := Parent (Typ);
1608
1609          begin
1610             --  Common case
1611
1612             if Nkind (Typ_Decl) = N_Full_Type_Declaration
1613               and then Limited_Present (Type_Definition (Typ_Decl))
1614             then
1615                return True;
1616
1617             --  The following paragraphs describe what a legal aliased view of
1618             --  a type is in the various dialects of Ada.
1619
1620             --  Ada 95
1621
1622             --  The current instance of a limited type, and a formal parameter
1623             --  or generic formal object of a tagged type.
1624
1625             --  Ada 95 limited type
1626             --    * Type with reserved word "limited"
1627             --    * A protected or task type
1628             --    * A composite type with limited component
1629
1630             elsif Ada_Version <= Ada_95 then
1631                return Is_Limited_Type (Typ);
1632
1633             --  Ada 2005
1634
1635             --  The current instance of a limited tagged type, a protected
1636             --  type, a task type, or a type that has the reserved word
1637             --  "limited" in its full definition ... a formal parameter or
1638             --  generic formal object of a tagged type.
1639
1640             --  Ada 2005 limited type
1641             --    * Type with reserved word "limited", "synchronized", "task"
1642             --      or "protected"
1643             --    * A composite type with limited component
1644             --    * A derived type whose parent is a non-interface limited type
1645
1646             elsif Ada_Version = Ada_2005 then
1647                return
1648                  (Is_Limited_Type (Typ) and then Is_Tagged_Type (Typ))
1649                    or else
1650                      (Is_Derived_Type (Typ)
1651                        and then not Is_Interface (Etype (Typ))
1652                        and then Is_Limited_Type (Etype (Typ)));
1653
1654             --  Ada 2012 and beyond
1655
1656             --  The current instance of an immutably limited type ... a formal
1657             --  parameter or generic formal object of a tagged type.
1658
1659             --  Ada 2012 limited type
1660             --    * Type with reserved word "limited", "synchronized", "task"
1661             --      or "protected"
1662             --    * A composite type with limited component
1663             --    * A derived type whose parent is a non-interface limited type
1664             --    * An incomplete view
1665
1666             --  Ada 2012 immutably limited type
1667             --    * Explicitly limited record type
1668             --    * Record extension with "limited" present
1669             --    * Non-formal limited private type that is either tagged
1670             --      or has at least one access discriminant with a default
1671             --      expression
1672             --    * Task type, protected type or synchronized interface
1673             --    * Type derived from immutably limited type
1674
1675             else
1676                return
1677                  Is_Immutably_Limited_Type (Typ)
1678                    or else Is_Incomplete_Type (Typ);
1679             end if;
1680          end Is_Aliased_View_Of_Type;
1681
1682          -------------
1683          -- Process --
1684          -------------
1685
1686          function Process (N : Node_Id) return Traverse_Result is
1687          begin
1688             case Nkind (N) is
1689                when N_Attribute_Reference =>
1690                   if (Attribute_Name (N) = Name_Access
1691                         or else
1692                       Attribute_Name (N) = Name_Unchecked_Access)
1693                     and then Is_Entity_Name (Prefix (N))
1694                     and then Is_Type (Entity (Prefix (N)))
1695                     and then Entity (Prefix (N)) = E
1696                   then
1697                      Error_Msg_N
1698                        ("current instance must be a limited type", Prefix (N));
1699                      return Abandon;
1700                   else
1701                      return OK;
1702                   end if;
1703
1704                when others => return OK;
1705             end case;
1706          end Process;
1707
1708          procedure Traverse is new Traverse_Proc (Process);
1709
1710          --  Local variables
1711
1712          Rec_Type : constant Entity_Id :=
1713                       Scope (Defining_Identifier (Comp_Decl));
1714
1715       --  Start of processing for Check_Current_Instance
1716
1717       begin
1718          if not Is_Aliased_View_Of_Type (Rec_Type) then
1719             Traverse (Comp_Decl);
1720          end if;
1721       end Check_Current_Instance;
1722
1723       ------------------------------
1724       -- Check_Suspicious_Modulus --
1725       ------------------------------
1726
1727       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1728          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1729
1730       begin
1731          if Nkind (Decl) = N_Full_Type_Declaration then
1732             declare
1733                Tdef : constant Node_Id := Type_Definition (Decl);
1734
1735             begin
1736                if Nkind (Tdef) = N_Modular_Type_Definition then
1737                   declare
1738                      Modulus : constant Node_Id :=
1739                                  Original_Node (Expression (Tdef));
1740                   begin
1741                      if Nkind (Modulus) = N_Integer_Literal then
1742                         declare
1743                            Modv : constant Uint := Intval (Modulus);
1744                            Sizv : constant Uint := RM_Size (Utype);
1745
1746                         begin
1747                            --  First case, modulus and size are the same. This
1748                            --  happens if you have something like mod 32, with
1749                            --  an explicit size of 32, this is for sure a case
1750                            --  where the warning is given, since it is seems
1751                            --  very unlikely that someone would want e.g. a
1752                            --  five bit type stored in 32 bits. It is much
1753                            --  more likely they wanted a 32-bit type.
1754
1755                            if Modv = Sizv then
1756                               null;
1757
1758                            --  Second case, the modulus is 32 or 64 and no
1759                            --  size clause is present. This is a less clear
1760                            --  case for giving the warning, but in the case
1761                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1762                            --  enough that it is a likely error (and in any
1763                            --  case using 2**5 or 2**6 in these cases seems
1764                            --  clearer. We don't include 8 or 16 here, simply
1765                            --  because in practice 3-bit and 4-bit types are
1766                            --  more common and too many false positives if
1767                            --  we warn in these cases.
1768
1769                            elsif not Has_Size_Clause (Utype)
1770                              and then (Modv = Uint_32 or else Modv = Uint_64)
1771                            then
1772                               null;
1773
1774                            --  No warning needed
1775
1776                            else
1777                               return;
1778                            end if;
1779
1780                            --  If we fall through, give warning
1781
1782                            Error_Msg_Uint_1 := Modv;
1783                            Error_Msg_N
1784                              ("?2 '*'*^' may have been intended here",
1785                               Modulus);
1786                         end;
1787                      end if;
1788                   end;
1789                end if;
1790             end;
1791          end if;
1792       end Check_Suspicious_Modulus;
1793
1794       ------------------------
1795       -- Freeze_Record_Type --
1796       ------------------------
1797
1798       procedure Freeze_Record_Type (Rec : Entity_Id) is
1799          Comp : Entity_Id;
1800          IR   : Node_Id;
1801          ADC  : Node_Id;
1802          Prev : Entity_Id;
1803
1804          Junk : Boolean;
1805          pragma Warnings (Off, Junk);
1806
1807          Unplaced_Component : Boolean := False;
1808          --  Set True if we find at least one component with no component
1809          --  clause (used to warn about useless Pack pragmas).
1810
1811          Placed_Component : Boolean := False;
1812          --  Set True if we find at least one component with a component
1813          --  clause (used to warn about useless Bit_Order pragmas, and also
1814          --  to detect cases where Implicit_Packing may have an effect).
1815
1816          All_Scalar_Components : Boolean := True;
1817          --  Set False if we encounter a component of a non-scalar type
1818
1819          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1820          Scalar_Component_Total_Esize   : Uint := Uint_0;
1821          --  Accumulates total RM_Size values and total Esize values of all
1822          --  scalar components. Used for processing of Implicit_Packing.
1823
1824          function Check_Allocator (N : Node_Id) return Node_Id;
1825          --  If N is an allocator, possibly wrapped in one or more level of
1826          --  qualified expression(s), return the inner allocator node, else
1827          --  return Empty.
1828
1829          procedure Check_Itype (Typ : Entity_Id);
1830          --  If the component subtype is an access to a constrained subtype of
1831          --  an already frozen type, make the subtype frozen as well. It might
1832          --  otherwise be frozen in the wrong scope, and a freeze node on
1833          --  subtype has no effect. Similarly, if the component subtype is a
1834          --  regular (not protected) access to subprogram, set the anonymous
1835          --  subprogram type to frozen as well, to prevent an out-of-scope
1836          --  freeze node at some eventual point of call. Protected operations
1837          --  are handled elsewhere.
1838
1839          ---------------------
1840          -- Check_Allocator --
1841          ---------------------
1842
1843          function Check_Allocator (N : Node_Id) return Node_Id is
1844             Inner : Node_Id;
1845          begin
1846             Inner := N;
1847             loop
1848                if Nkind (Inner) = N_Allocator then
1849                   return Inner;
1850                elsif Nkind (Inner) = N_Qualified_Expression then
1851                   Inner := Expression (Inner);
1852                else
1853                   return Empty;
1854                end if;
1855             end loop;
1856          end Check_Allocator;
1857
1858          -----------------
1859          -- Check_Itype --
1860          -----------------
1861
1862          procedure Check_Itype (Typ : Entity_Id) is
1863             Desig : constant Entity_Id := Designated_Type (Typ);
1864
1865          begin
1866             if not Is_Frozen (Desig)
1867               and then Is_Frozen (Base_Type (Desig))
1868             then
1869                Set_Is_Frozen (Desig);
1870
1871                --  In addition, add an Itype_Reference to ensure that the
1872                --  access subtype is elaborated early enough. This cannot be
1873                --  done if the subtype may depend on discriminants.
1874
1875                if Ekind (Comp) = E_Component
1876                  and then Is_Itype (Etype (Comp))
1877                  and then not Has_Discriminants (Rec)
1878                then
1879                   IR := Make_Itype_Reference (Sloc (Comp));
1880                   Set_Itype (IR, Desig);
1881                   Add_To_Result (IR);
1882                end if;
1883
1884             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1885               and then Convention (Desig) /= Convention_Protected
1886             then
1887                Set_Is_Frozen (Desig);
1888             end if;
1889          end Check_Itype;
1890
1891       --  Start of processing for Freeze_Record_Type
1892
1893       begin
1894          --  Freeze components and embedded subtypes
1895
1896          Comp := First_Entity (Rec);
1897          Prev := Empty;
1898          while Present (Comp) loop
1899
1900             --  First handle the component case
1901
1902             if Ekind (Comp) = E_Component
1903               or else Ekind (Comp) = E_Discriminant
1904             then
1905                declare
1906                   CC : constant Node_Id := Component_Clause (Comp);
1907
1908                begin
1909                   --  Freezing a record type freezes the type of each of its
1910                   --  components. However, if the type of the component is
1911                   --  part of this record, we do not want or need a separate
1912                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1913                   --  also set in private type cases. We also can't check for
1914                   --  the Scope being exactly Rec because of private types and
1915                   --  record extensions.
1916
1917                   if Is_Itype (Etype (Comp))
1918                     and then Is_Record_Type (Underlying_Type
1919                                              (Scope (Etype (Comp))))
1920                   then
1921                      Undelay_Type (Etype (Comp));
1922                   end if;
1923
1924                   Freeze_And_Append (Etype (Comp), N, Result);
1925
1926                   --  Check for error of component clause given for variable
1927                   --  sized type. We have to delay this test till this point,
1928                   --  since the component type has to be frozen for us to know
1929                   --  if it is variable length. We omit this test in a generic
1930                   --  context, it will be applied at instantiation time.
1931
1932                   --  We also omit this test in CodePeer mode, since we do not
1933                   --  have sufficient info on size and representation clauses.
1934
1935                   if Present (CC) then
1936                      Placed_Component := True;
1937
1938                      if Inside_A_Generic then
1939                         null;
1940
1941                      elsif CodePeer_Mode then
1942                         null;
1943
1944                      elsif not
1945                        Size_Known_At_Compile_Time
1946                          (Underlying_Type (Etype (Comp)))
1947                      then
1948                         Error_Msg_N
1949                           ("component clause not allowed for variable " &
1950                            "length component", CC);
1951                      end if;
1952
1953                   else
1954                      Unplaced_Component := True;
1955                   end if;
1956
1957                   --  Case of component requires byte alignment
1958
1959                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1960
1961                      --  Set the enclosing record to also require byte align
1962
1963                      Set_Must_Be_On_Byte_Boundary (Rec);
1964
1965                      --  Check for component clause that is inconsistent with
1966                      --  the required byte boundary alignment.
1967
1968                      if Present (CC)
1969                        and then Normalized_First_Bit (Comp) mod
1970                                   System_Storage_Unit /= 0
1971                      then
1972                         Error_Msg_N
1973                           ("component & must be byte aligned",
1974                            Component_Name (Component_Clause (Comp)));
1975                      end if;
1976                   end if;
1977                end;
1978             end if;
1979
1980             --  Gather data for possible Implicit_Packing later. Note that at
1981             --  this stage we might be dealing with a real component, or with
1982             --  an implicit subtype declaration.
1983
1984             if not Is_Scalar_Type (Etype (Comp)) then
1985                All_Scalar_Components := False;
1986             else
1987                Scalar_Component_Total_RM_Size :=
1988                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1989                Scalar_Component_Total_Esize :=
1990                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1991             end if;
1992
1993             --  If the component is an Itype with Delayed_Freeze and is either
1994             --  a record or array subtype and its base type has not yet been
1995             --  frozen, we must remove this from the entity list of this record
1996             --  and put it on the entity list of the scope of its base type.
1997             --  Note that we know that this is not the type of a component
1998             --  since we cleared Has_Delayed_Freeze for it in the previous
1999             --  loop. Thus this must be the Designated_Type of an access type,
2000             --  which is the type of a component.
2001
2002             if Is_Itype (Comp)
2003               and then Is_Type (Scope (Comp))
2004               and then Is_Composite_Type (Comp)
2005               and then Base_Type (Comp) /= Comp
2006               and then Has_Delayed_Freeze (Comp)
2007               and then not Is_Frozen (Base_Type (Comp))
2008             then
2009                declare
2010                   Will_Be_Frozen : Boolean := False;
2011                   S              : Entity_Id;
2012
2013                begin
2014                   --  We have a pretty bad kludge here. Suppose Rec is subtype
2015                   --  being defined in a subprogram that's created as part of
2016                   --  the freezing of Rec'Base. In that case, we know that
2017                   --  Comp'Base must have already been frozen by the time we
2018                   --  get to elaborate this because Gigi doesn't elaborate any
2019                   --  bodies until it has elaborated all of the declarative
2020                   --  part. But Is_Frozen will not be set at this point because
2021                   --  we are processing code in lexical order.
2022
2023                   --  We detect this case by going up the Scope chain of Rec
2024                   --  and seeing if we have a subprogram scope before reaching
2025                   --  the top of the scope chain or that of Comp'Base. If we
2026                   --  do, then mark that Comp'Base will actually be frozen. If
2027                   --  so, we merely undelay it.
2028
2029                   S := Scope (Rec);
2030                   while Present (S) loop
2031                      if Is_Subprogram (S) then
2032                         Will_Be_Frozen := True;
2033                         exit;
2034                      elsif S = Scope (Base_Type (Comp)) then
2035                         exit;
2036                      end if;
2037
2038                      S := Scope (S);
2039                   end loop;
2040
2041                   if Will_Be_Frozen then
2042                      Undelay_Type (Comp);
2043                   else
2044                      if Present (Prev) then
2045                         Set_Next_Entity (Prev, Next_Entity (Comp));
2046                      else
2047                         Set_First_Entity (Rec, Next_Entity (Comp));
2048                      end if;
2049
2050                      --  Insert in entity list of scope of base type (which
2051                      --  must be an enclosing scope, because still unfrozen).
2052
2053                      Append_Entity (Comp, Scope (Base_Type (Comp)));
2054                   end if;
2055                end;
2056
2057             --  If the component is an access type with an allocator as default
2058             --  value, the designated type will be frozen by the corresponding
2059             --  expression in init_proc. In order to place the freeze node for
2060             --  the designated type before that for the current record type,
2061             --  freeze it now.
2062
2063             --  Same process if the component is an array of access types,
2064             --  initialized with an aggregate. If the designated type is
2065             --  private, it cannot contain allocators, and it is premature
2066             --  to freeze the type, so we check for this as well.
2067
2068             elsif Is_Access_Type (Etype (Comp))
2069               and then Present (Parent (Comp))
2070               and then Present (Expression (Parent (Comp)))
2071             then
2072                declare
2073                   Alloc : constant Node_Id :=
2074                             Check_Allocator (Expression (Parent (Comp)));
2075
2076                begin
2077                   if Present (Alloc) then
2078
2079                      --  If component is pointer to a classwide type, freeze
2080                      --  the specific type in the expression being allocated.
2081                      --  The expression may be a subtype indication, in which
2082                      --  case freeze the subtype mark.
2083
2084                      if Is_Class_Wide_Type
2085                           (Designated_Type (Etype (Comp)))
2086                      then
2087                         if Is_Entity_Name (Expression (Alloc)) then
2088                            Freeze_And_Append
2089                              (Entity (Expression (Alloc)), N, Result);
2090                         elsif
2091                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2092                         then
2093                            Freeze_And_Append
2094                             (Entity (Subtype_Mark (Expression (Alloc))),
2095                              N, Result);
2096                         end if;
2097
2098                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2099                         Check_Itype (Etype (Comp));
2100
2101                      else
2102                         Freeze_And_Append
2103                           (Designated_Type (Etype (Comp)), N, Result);
2104                      end if;
2105                   end if;
2106                end;
2107
2108             elsif Is_Access_Type (Etype (Comp))
2109               and then Is_Itype (Designated_Type (Etype (Comp)))
2110             then
2111                Check_Itype (Etype (Comp));
2112
2113             elsif Is_Array_Type (Etype (Comp))
2114               and then Is_Access_Type (Component_Type (Etype (Comp)))
2115               and then Present (Parent (Comp))
2116               and then Nkind (Parent (Comp)) = N_Component_Declaration
2117               and then Present (Expression (Parent (Comp)))
2118               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2119               and then Is_Fully_Defined
2120                  (Designated_Type (Component_Type (Etype (Comp))))
2121             then
2122                Freeze_And_Append
2123                  (Designated_Type
2124                    (Component_Type (Etype (Comp))), N, Result);
2125             end if;
2126
2127             Prev := Comp;
2128             Next_Entity (Comp);
2129          end loop;
2130
2131          --  Deal with Bit_Order aspect specifying a non-default bit order
2132
2133          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2134             if not Placed_Component then
2135                ADC :=
2136                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2137                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2138                Error_Msg_N
2139                  ("\?since no component clauses were specified", ADC);
2140
2141             --  Here is where we do the processing for reversed bit order
2142
2143             else
2144                Adjust_Record_For_Reverse_Bit_Order (Rec);
2145             end if;
2146          end if;
2147
2148          --  Complete error checking on record representation clause (e.g.
2149          --  overlap of components). This is called after adjusting the
2150          --  record for reverse bit order.
2151
2152          declare
2153             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2154          begin
2155             if Present (RRC) then
2156                Check_Record_Representation_Clause (RRC);
2157             end if;
2158          end;
2159
2160          --  Set OK_To_Reorder_Components depending on debug flags
2161
2162          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2163             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2164                   or else
2165                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2166             then
2167                Set_OK_To_Reorder_Components (Rec);
2168             end if;
2169          end if;
2170
2171          --  Check for useless pragma Pack when all components placed. We only
2172          --  do this check for record types, not subtypes, since a subtype may
2173          --  have all its components placed, and it still makes perfectly good
2174          --  sense to pack other subtypes or the parent type. We do not give
2175          --  this warning if Optimize_Alignment is set to Space, since the
2176          --  pragma Pack does have an effect in this case (it always resets
2177          --  the alignment to one).
2178
2179          if Ekind (Rec) = E_Record_Type
2180            and then Is_Packed (Rec)
2181            and then not Unplaced_Component
2182            and then Optimize_Alignment /= 'S'
2183          then
2184             --  Reset packed status. Probably not necessary, but we do it so
2185             --  that there is no chance of the back end doing something strange
2186             --  with this redundant indication of packing.
2187
2188             Set_Is_Packed (Rec, False);
2189
2190             --  Give warning if redundant constructs warnings on
2191
2192             if Warn_On_Redundant_Constructs then
2193                Error_Msg_N -- CODEFIX
2194                  ("?pragma Pack has no effect, no unplaced components",
2195                   Get_Rep_Pragma (Rec, Name_Pack));
2196             end if;
2197          end if;
2198
2199          --  If this is the record corresponding to a remote type, freeze the
2200          --  remote type here since that is what we are semantically freezing.
2201          --  This prevents the freeze node for that type in an inner scope.
2202
2203          --  Also, Check for controlled components and unchecked unions.
2204          --  Finally, enforce the restriction that access attributes with a
2205          --  current instance prefix can only apply to limited types.
2206
2207          if Ekind (Rec) = E_Record_Type then
2208             if Present (Corresponding_Remote_Type (Rec)) then
2209                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2210             end if;
2211
2212             Comp := First_Component (Rec);
2213             while Present (Comp) loop
2214
2215                --  Do not set Has_Controlled_Component on a class-wide
2216                --  equivalent type. See Make_CW_Equivalent_Type.
2217
2218                if not Is_Class_Wide_Equivalent_Type (Rec)
2219                  and then (Has_Controlled_Component (Etype (Comp))
2220                             or else (Chars (Comp) /= Name_uParent
2221                                       and then Is_Controlled (Etype (Comp)))
2222                             or else (Is_Protected_Type (Etype (Comp))
2223                                       and then Present
2224                                         (Corresponding_Record_Type
2225                                           (Etype (Comp)))
2226                                       and then Has_Controlled_Component
2227                                         (Corresponding_Record_Type
2228                                           (Etype (Comp)))))
2229                then
2230                   Set_Has_Controlled_Component (Rec);
2231                end if;
2232
2233                if Has_Unchecked_Union (Etype (Comp)) then
2234                   Set_Has_Unchecked_Union (Rec);
2235                end if;
2236
2237                --  Scan component declaration for likely misuses of current
2238                --  instance, either in a constraint or a default expression.
2239
2240                if Has_Per_Object_Constraint (Comp) then
2241                   Check_Current_Instance (Parent (Comp));
2242                end if;
2243
2244                Next_Component (Comp);
2245             end loop;
2246          end if;
2247
2248          Set_Component_Alignment_If_Not_Set (Rec);
2249
2250          --  For first subtypes, check if there are any fixed-point fields with
2251          --  component clauses, where we must check the size. This is not done
2252          --  till the freeze point, since for fixed-point types, we do not know
2253          --  the size until the type is frozen. Similar processing applies to
2254          --  bit packed arrays.
2255
2256          if Is_First_Subtype (Rec) then
2257             Comp := First_Component (Rec);
2258             while Present (Comp) loop
2259                if Present (Component_Clause (Comp))
2260                  and then (Is_Fixed_Point_Type (Etype (Comp))
2261                              or else
2262                            Is_Bit_Packed_Array (Etype (Comp)))
2263                then
2264                   Check_Size
2265                     (Component_Name (Component_Clause (Comp)),
2266                      Etype (Comp),
2267                      Esize (Comp),
2268                      Junk);
2269                end if;
2270
2271                Next_Component (Comp);
2272             end loop;
2273          end if;
2274
2275          --  Generate warning for applying C or C++ convention to a record
2276          --  with discriminants. This is suppressed for the unchecked union
2277          --  case, since the whole point in this case is interface C. We also
2278          --  do not generate this within instantiations, since we will have
2279          --  generated a message on the template.
2280
2281          if Has_Discriminants (E)
2282            and then not Is_Unchecked_Union (E)
2283            and then (Convention (E) = Convention_C
2284                        or else
2285                      Convention (E) = Convention_CPP)
2286            and then Comes_From_Source (E)
2287            and then not In_Instance
2288            and then not Has_Warnings_Off (E)
2289            and then not Has_Warnings_Off (Base_Type (E))
2290          then
2291             declare
2292                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2293                A2    : Node_Id;
2294
2295             begin
2296                if Present (Cprag) then
2297                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2298
2299                   if Convention (E) = Convention_C then
2300                      Error_Msg_N
2301                        ("?variant record has no direct equivalent in C", A2);
2302                   else
2303                      Error_Msg_N
2304                        ("?variant record has no direct equivalent in C++", A2);
2305                   end if;
2306
2307                   Error_Msg_NE
2308                     ("\?use of convention for type& is dubious", A2, E);
2309                end if;
2310             end;
2311          end if;
2312
2313          --  See if Size is too small as is (and implicit packing might help)
2314
2315          if not Is_Packed (Rec)
2316
2317            --  No implicit packing if even one component is explicitly placed
2318
2319            and then not Placed_Component
2320
2321            --  Must have size clause and all scalar components
2322
2323            and then Has_Size_Clause (Rec)
2324            and then All_Scalar_Components
2325
2326            --  Do not try implicit packing on records with discriminants, too
2327            --  complicated, especially in the variant record case.
2328
2329            and then not Has_Discriminants (Rec)
2330
2331            --  We can implicitly pack if the specified size of the record is
2332            --  less than the sum of the object sizes (no point in packing if
2333            --  this is not the case).
2334
2335            and then RM_Size (Rec) < Scalar_Component_Total_Esize
2336
2337            --  And the total RM size cannot be greater than the specified size
2338            --  since otherwise packing will not get us where we have to be!
2339
2340            and then RM_Size (Rec) >= Scalar_Component_Total_RM_Size
2341
2342            --  Never do implicit packing in CodePeer or Alfa modes since
2343            --  we don't do any packing in these modes, since this generates
2344            --  over-complex code that confuses static analysis, and in
2345            --  general, neither CodePeer not GNATprove care about the
2346            --  internal representation of objects.
2347
2348            and then not (CodePeer_Mode or Alfa_Mode)
2349          then
2350             --  If implicit packing enabled, do it
2351
2352             if Implicit_Packing then
2353                Set_Is_Packed (Rec);
2354
2355                --  Otherwise flag the size clause
2356
2357             else
2358                declare
2359                   Sz : constant Node_Id := Size_Clause (Rec);
2360                begin
2361                   Error_Msg_NE -- CODEFIX
2362                     ("size given for& too small", Sz, Rec);
2363                   Error_Msg_N -- CODEFIX
2364                     ("\use explicit pragma Pack "
2365                      & "or use pragma Implicit_Packing", Sz);
2366                end;
2367             end if;
2368          end if;
2369       end Freeze_Record_Type;
2370
2371    --  Start of processing for Freeze_Entity
2372
2373    begin
2374       --  We are going to test for various reasons why this entity need not be
2375       --  frozen here, but in the case of an Itype that's defined within a
2376       --  record, that test actually applies to the record.
2377
2378       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2379          Test_E := Scope (E);
2380       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2381         and then Is_Record_Type (Underlying_Type (Scope (E)))
2382       then
2383          Test_E := Underlying_Type (Scope (E));
2384       end if;
2385
2386       --  Do not freeze if already frozen since we only need one freeze node
2387
2388       if Is_Frozen (E) then
2389          return No_List;
2390
2391       --  It is improper to freeze an external entity within a generic because
2392       --  its freeze node will appear in a non-valid context. The entity will
2393       --  be frozen in the proper scope after the current generic is analyzed.
2394
2395       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2396          return No_List;
2397
2398       --  AI05-0213: A formal incomplete type does not freeze the actual. In
2399       --  the instance, the same applies to the subtype renaming the actual.
2400
2401       elsif Is_Private_Type (E)
2402         and then Is_Generic_Actual_Type (E)
2403         and then No (Full_View (Base_Type (E)))
2404         and then Ada_Version >= Ada_2012
2405       then
2406          return No_List;
2407
2408       --  Do not freeze a global entity within an inner scope created during
2409       --  expansion. A call to subprogram E within some internal procedure
2410       --  (a stream attribute for example) might require freezing E, but the
2411       --  freeze node must appear in the same declarative part as E itself.
2412       --  The two-pass elaboration mechanism in gigi guarantees that E will
2413       --  be frozen before the inner call is elaborated. We exclude constants
2414       --  from this test, because deferred constants may be frozen early, and
2415       --  must be diagnosed (e.g. in the case of a deferred constant being used
2416       --  in a default expression). If the enclosing subprogram comes from
2417       --  source, or is a generic instance, then the freeze point is the one
2418       --  mandated by the language, and we freeze the entity. A subprogram that
2419       --  is a child unit body that acts as a spec does not have a spec that
2420       --  comes from source, but can only come from source.
2421
2422       elsif In_Open_Scopes (Scope (Test_E))
2423         and then Scope (Test_E) /= Current_Scope
2424         and then Ekind (Test_E) /= E_Constant
2425       then
2426          declare
2427             S : Entity_Id;
2428
2429          begin
2430             S := Current_Scope;
2431             while Present (S) loop
2432                if Is_Overloadable (S) then
2433                   if Comes_From_Source (S)
2434                     or else Is_Generic_Instance (S)
2435                     or else Is_Child_Unit (S)
2436                   then
2437                      exit;
2438                   else
2439                      return No_List;
2440                   end if;
2441                end if;
2442
2443                S := Scope (S);
2444             end loop;
2445          end;
2446
2447       --  Similarly, an inlined instance body may make reference to global
2448       --  entities, but these references cannot be the proper freezing point
2449       --  for them, and in the absence of inlining freezing will take place in
2450       --  their own scope. Normally instance bodies are analyzed after the
2451       --  enclosing compilation, and everything has been frozen at the proper
2452       --  place, but with front-end inlining an instance body is compiled
2453       --  before the end of the enclosing scope, and as a result out-of-order
2454       --  freezing must be prevented.
2455
2456       elsif Front_End_Inlining
2457         and then In_Instance_Body
2458         and then Present (Scope (Test_E))
2459       then
2460          declare
2461             S : Entity_Id;
2462
2463          begin
2464             S := Scope (Test_E);
2465             while Present (S) loop
2466                if Is_Generic_Instance (S) then
2467                   exit;
2468                else
2469                   S := Scope (S);
2470                end if;
2471             end loop;
2472
2473             if No (S) then
2474                return No_List;
2475             end if;
2476          end;
2477       end if;
2478
2479       --  Deal with delayed aspect specifications. The analysis of the aspect
2480       --  is required to be delayed to the freeze point, so we evaluate the
2481       --  pragma or attribute definition clause in the tree at this point.
2482
2483       if Has_Delayed_Aspects (E) then
2484          declare
2485             Ritem : Node_Id;
2486             Aitem : Node_Id;
2487
2488          begin
2489             --  Look for aspect specification entries for this entity
2490
2491             Ritem := First_Rep_Item (E);
2492             while Present (Ritem) loop
2493                if Nkind (Ritem) = N_Aspect_Specification
2494                  and then Entity (Ritem) = E
2495                  and then Is_Delayed_Aspect (Ritem)
2496                  and then Scope (E) = Current_Scope
2497                then
2498                   Aitem := Aspect_Rep_Item (Ritem);
2499
2500                   --  Skip if this is an aspect with no corresponding pragma
2501                   --  or attribute definition node (such as Default_Value).
2502
2503                   if Present (Aitem) then
2504                      Set_Parent (Aitem, Ritem);
2505                      Analyze (Aitem);
2506                   end if;
2507                end if;
2508
2509                Next_Rep_Item (Ritem);
2510             end loop;
2511          end;
2512       end if;
2513
2514       --  Here to freeze the entity
2515
2516       Set_Is_Frozen (E);
2517
2518       --  Case of entity being frozen is other than a type
2519
2520       if not Is_Type (E) then
2521
2522          --  If entity is exported or imported and does not have an external
2523          --  name, now is the time to provide the appropriate default name.
2524          --  Skip this if the entity is stubbed, since we don't need a name
2525          --  for any stubbed routine. For the case on intrinsics, if no
2526          --  external name is specified, then calls will be handled in
2527          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2528          --  external name is provided, then Expand_Intrinsic_Call leaves
2529          --  calls in place for expansion by GIGI.
2530
2531          if (Is_Imported (E) or else Is_Exported (E))
2532            and then No (Interface_Name (E))
2533            and then Convention (E) /= Convention_Stubbed
2534            and then Convention (E) /= Convention_Intrinsic
2535          then
2536             Set_Encoded_Interface_Name
2537               (E, Get_Default_External_Name (E));
2538
2539          --  If entity is an atomic object appearing in a declaration and
2540          --  the expression is an aggregate, assign it to a temporary to
2541          --  ensure that the actual assignment is done atomically rather
2542          --  than component-wise (the assignment to the temp may be done
2543          --  component-wise, but that is harmless).
2544
2545          elsif Is_Atomic (E)
2546            and then Nkind (Parent (E)) = N_Object_Declaration
2547            and then Present (Expression (Parent (E)))
2548            and then Nkind (Expression (Parent (E))) = N_Aggregate
2549            and then Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2550          then
2551             null;
2552          end if;
2553
2554          --  For a subprogram, freeze all parameter types and also the return
2555          --  type (RM 13.14(14)). However skip this for internal subprograms.
2556          --  This is also the point where any extra formal parameters are
2557          --  created since we now know whether the subprogram will use a
2558          --  foreign convention.
2559
2560          if Is_Subprogram (E) then
2561             if not Is_Internal (E) then
2562                declare
2563                   F_Type    : Entity_Id;
2564                   R_Type    : Entity_Id;
2565                   Warn_Node : Node_Id;
2566
2567                begin
2568                   --  Loop through formals
2569
2570                   Formal := First_Formal (E);
2571                   while Present (Formal) loop
2572                      F_Type := Etype (Formal);
2573
2574                      --  AI05-0151 : incomplete types can appear in a profile.
2575                      --  By the time the entity is frozen, the full view must
2576                      --  be available, unless it is a limited view.
2577
2578                      if Is_Incomplete_Type (F_Type)
2579                        and then Present (Full_View (F_Type))
2580                      then
2581                         F_Type := Full_View (F_Type);
2582                         Set_Etype (Formal, F_Type);
2583                      end if;
2584
2585                      Freeze_And_Append (F_Type, N, Result);
2586
2587                      if Is_Private_Type (F_Type)
2588                        and then Is_Private_Type (Base_Type (F_Type))
2589                        and then No (Full_View (Base_Type (F_Type)))
2590                        and then not Is_Generic_Type (F_Type)
2591                        and then not Is_Derived_Type (F_Type)
2592                      then
2593                         --  If the type of a formal is incomplete, subprogram
2594                         --  is being frozen prematurely. Within an instance
2595                         --  (but not within a wrapper package) this is an
2596                         --  artifact of our need to regard the end of an
2597                         --  instantiation as a freeze point. Otherwise it is
2598                         --  a definite error.
2599
2600                         if In_Instance then
2601                            Set_Is_Frozen (E, False);
2602                            return No_List;
2603
2604                         elsif not After_Last_Declaration
2605                           and then not Freezing_Library_Level_Tagged_Type
2606                         then
2607                            Error_Msg_Node_1 := F_Type;
2608                            Error_Msg
2609                              ("type& must be fully defined before this point",
2610                                Loc);
2611                         end if;
2612                      end if;
2613
2614                      --  Check suspicious parameter for C function. These tests
2615                      --  apply only to exported/imported subprograms.
2616
2617                      if Warn_On_Export_Import
2618                        and then Comes_From_Source (E)
2619                        and then (Convention (E) = Convention_C
2620                                    or else
2621                                  Convention (E) = Convention_CPP)
2622                        and then (Is_Imported (E) or else Is_Exported (E))
2623                        and then Convention (E) /= Convention (Formal)
2624                        and then not Has_Warnings_Off (E)
2625                        and then not Has_Warnings_Off (F_Type)
2626                        and then not Has_Warnings_Off (Formal)
2627                      then
2628                         --  Qualify mention of formals with subprogram name
2629
2630                         Error_Msg_Qual_Level := 1;
2631
2632                         --  Check suspicious use of fat C pointer
2633
2634                         if Is_Access_Type (F_Type)
2635                           and then Esize (F_Type) > Ttypes.System_Address_Size
2636                         then
2637                            Error_Msg_N
2638                              ("?type of & does not correspond to C pointer!",
2639                               Formal);
2640
2641                         --  Check suspicious return of boolean
2642
2643                         elsif Root_Type (F_Type) = Standard_Boolean
2644                           and then Convention (F_Type) = Convention_Ada
2645                           and then not Has_Warnings_Off (F_Type)
2646                           and then not Has_Size_Clause (F_Type)
2647                           and then VM_Target = No_VM
2648                         then
2649                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2650                            Error_Msg_N
2651                              ("\use appropriate corresponding type in C "
2652                               & "(e.g. char)?", Formal);
2653
2654                         --  Check suspicious tagged type
2655
2656                         elsif (Is_Tagged_Type (F_Type)
2657                                 or else (Is_Access_Type (F_Type)
2658                                            and then
2659                                              Is_Tagged_Type
2660                                                (Designated_Type (F_Type))))
2661                           and then Convention (E) = Convention_C
2662                         then
2663                            Error_Msg_N
2664                              ("?& involves a tagged type which does not "
2665                               & "correspond to any C type!", Formal);
2666
2667                         --  Check wrong convention subprogram pointer
2668
2669                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2670                           and then not Has_Foreign_Convention (F_Type)
2671                         then
2672                            Error_Msg_N
2673                              ("?subprogram pointer & should "
2674                               & "have foreign convention!", Formal);
2675                            Error_Msg_Sloc := Sloc (F_Type);
2676                            Error_Msg_NE
2677                              ("\?add Convention pragma to declaration of &#",
2678                               Formal, F_Type);
2679                         end if;
2680
2681                         --  Turn off name qualification after message output
2682
2683                         Error_Msg_Qual_Level := 0;
2684                      end if;
2685
2686                      --  Check for unconstrained array in exported foreign
2687                      --  convention case.
2688
2689                      if Has_Foreign_Convention (E)
2690                        and then not Is_Imported (E)
2691                        and then Is_Array_Type (F_Type)
2692                        and then not Is_Constrained (F_Type)
2693                        and then Warn_On_Export_Import
2694
2695                        --  Exclude VM case, since both .NET and JVM can handle
2696                        --  unconstrained arrays without a problem.
2697
2698                        and then VM_Target = No_VM
2699                      then
2700                         Error_Msg_Qual_Level := 1;
2701
2702                         --  If this is an inherited operation, place the
2703                         --  warning on the derived type declaration, rather
2704                         --  than on the original subprogram.
2705
2706                         if Nkind (Original_Node (Parent (E))) =
2707                           N_Full_Type_Declaration
2708                         then
2709                            Warn_Node := Parent (E);
2710
2711                            if Formal = First_Formal (E) then
2712                               Error_Msg_NE
2713                                 ("?in inherited operation&", Warn_Node, E);
2714                            end if;
2715                         else
2716                            Warn_Node := Formal;
2717                         end if;
2718
2719                         Error_Msg_NE
2720                           ("?type of argument& is unconstrained array",
2721                            Warn_Node, Formal);
2722                         Error_Msg_NE
2723                           ("?foreign caller must pass bounds explicitly",
2724                            Warn_Node, Formal);
2725                         Error_Msg_Qual_Level := 0;
2726                      end if;
2727
2728                      if not From_With_Type (F_Type) then
2729                         if Is_Access_Type (F_Type) then
2730                            F_Type := Designated_Type (F_Type);
2731                         end if;
2732
2733                         --  If the formal is an anonymous_access_to_subprogram
2734                         --  freeze the  subprogram type as well, to prevent
2735                         --  scope anomalies in gigi, because there is no other
2736                         --  clear point at which it could be frozen.
2737
2738                         if Is_Itype (Etype (Formal))
2739                           and then Ekind (F_Type) = E_Subprogram_Type
2740                         then
2741                            Freeze_And_Append (F_Type, N, Result);
2742                         end if;
2743                      end if;
2744
2745                      Next_Formal (Formal);
2746                   end loop;
2747
2748                   --  Case of function: similar checks on return type
2749
2750                   if Ekind (E) = E_Function then
2751
2752                      --  Freeze return type
2753
2754                      R_Type := Etype (E);
2755
2756                      --  AI05-0151: the return type may have been incomplete
2757                      --  at the point of declaration.
2758
2759                      if Ekind (R_Type) = E_Incomplete_Type
2760                        and then Present (Full_View (R_Type))
2761                      then
2762                         R_Type := Full_View (R_Type);
2763                         Set_Etype (E, R_Type);
2764                      end if;
2765
2766                      Freeze_And_Append (R_Type, N, Result);
2767
2768                      --  Check suspicious return type for C function
2769
2770                      if Warn_On_Export_Import
2771                        and then (Convention (E) = Convention_C
2772                                    or else
2773                                  Convention (E) = Convention_CPP)
2774                        and then (Is_Imported (E) or else Is_Exported (E))
2775                      then
2776                         --  Check suspicious return of fat C pointer
2777
2778                         if Is_Access_Type (R_Type)
2779                           and then Esize (R_Type) > Ttypes.System_Address_Size
2780                           and then not Has_Warnings_Off (E)
2781                           and then not Has_Warnings_Off (R_Type)
2782                         then
2783                            Error_Msg_N
2784                              ("?return type of& does not "
2785                               & "correspond to C pointer!", E);
2786
2787                         --  Check suspicious return of boolean
2788
2789                         elsif Root_Type (R_Type) = Standard_Boolean
2790                           and then Convention (R_Type) = Convention_Ada
2791                           and then VM_Target = No_VM
2792                           and then not Has_Warnings_Off (E)
2793                           and then not Has_Warnings_Off (R_Type)
2794                           and then not Has_Size_Clause (R_Type)
2795                         then
2796                            declare
2797                               N : constant Node_Id :=
2798                                     Result_Definition (Declaration_Node (E));
2799                            begin
2800                               Error_Msg_NE
2801                                 ("return type of & is an 8-bit Ada Boolean?",
2802                                  N, E);
2803                               Error_Msg_NE
2804                                 ("\use appropriate corresponding type in C "
2805                                  & "(e.g. char)?", N, E);
2806                            end;
2807
2808                         --  Check suspicious return tagged type
2809
2810                         elsif (Is_Tagged_Type (R_Type)
2811                                 or else (Is_Access_Type (R_Type)
2812                                            and then
2813                                              Is_Tagged_Type
2814                                                (Designated_Type (R_Type))))
2815                           and then Convention (E) = Convention_C
2816                           and then not Has_Warnings_Off (E)
2817                           and then not Has_Warnings_Off (R_Type)
2818                         then
2819                            Error_Msg_N
2820                              ("?return type of & does not "
2821                               & "correspond to C type!", E);
2822
2823                         --  Check return of wrong convention subprogram pointer
2824
2825                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2826                           and then not Has_Foreign_Convention (R_Type)
2827                           and then not Has_Warnings_Off (E)
2828                           and then not Has_Warnings_Off (R_Type)
2829                         then
2830                            Error_Msg_N
2831                              ("?& should return a foreign "
2832                               & "convention subprogram pointer", E);
2833                            Error_Msg_Sloc := Sloc (R_Type);
2834                            Error_Msg_NE
2835                              ("\?add Convention pragma to declaration of& #",
2836                               E, R_Type);
2837                         end if;
2838                      end if;
2839
2840                      --  Give warning for suspicious return of a result of an
2841                      --  unconstrained array type in a foreign convention
2842                      --  function.
2843
2844                      if Has_Foreign_Convention (E)
2845
2846                        --  We are looking for a return of unconstrained array
2847
2848                        and then Is_Array_Type (R_Type)
2849                        and then not Is_Constrained (R_Type)
2850
2851                        --  Exclude imported routines, the warning does not
2852                        --  belong on the import, but rather on the routine
2853                        --  definition.
2854
2855                        and then not Is_Imported (E)
2856
2857                        --  Exclude VM case, since both .NET and JVM can handle
2858                        --  return of unconstrained arrays without a problem.
2859
2860                        and then VM_Target = No_VM
2861
2862                        --  Check that general warning is enabled, and that it
2863                        --  is not suppressed for this particular case.
2864
2865                        and then Warn_On_Export_Import
2866                        and then not Has_Warnings_Off (E)
2867                        and then not Has_Warnings_Off (R_Type)
2868                      then
2869                         Error_Msg_N
2870                           ("?foreign convention function& should not " &
2871                            "return unconstrained array!", E);
2872                      end if;
2873                   end if;
2874                end;
2875             end if;
2876
2877             --  Must freeze its parent first if it is a derived subprogram
2878
2879             if Present (Alias (E)) then
2880                Freeze_And_Append (Alias (E), N, Result);
2881             end if;
2882
2883             --  We don't freeze internal subprograms, because we don't normally
2884             --  want addition of extra formals or mechanism setting to happen
2885             --  for those. However we do pass through predefined dispatching
2886             --  cases, since extra formals may be needed in some cases, such as
2887             --  for the stream 'Input function (build-in-place formals).
2888
2889             if not Is_Internal (E)
2890               or else Is_Predefined_Dispatching_Operation (E)
2891             then
2892                Freeze_Subprogram (E);
2893             end if;
2894
2895          --  Here for other than a subprogram or type
2896
2897          else
2898             --  If entity has a type, and it is not a generic unit, then
2899             --  freeze it first (RM 13.14(10)).
2900
2901             if Present (Etype (E))
2902               and then Ekind (E) /= E_Generic_Function
2903             then
2904                Freeze_And_Append (Etype (E), N, Result);
2905             end if;
2906
2907             --  Special processing for objects created by object declaration
2908
2909             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2910
2911                --  Abstract type allowed only for C++ imported variables or
2912                --  constants.
2913
2914                --  Note: we inhibit this check for objects that do not come
2915                --  from source because there is at least one case (the
2916                --  expansion of x'Class'Input where x is abstract) where we
2917                --  legitimately generate an abstract object.
2918
2919                if Is_Abstract_Type (Etype (E))
2920                  and then Comes_From_Source (Parent (E))
2921                  and then not (Is_Imported (E)
2922                                  and then Is_CPP_Class (Etype (E)))
2923                then
2924                   Error_Msg_N ("type of object cannot be abstract",
2925                                Object_Definition (Parent (E)));
2926
2927                   if Is_CPP_Class (Etype (E)) then
2928                      Error_Msg_NE
2929                        ("\} may need a cpp_constructor",
2930                        Object_Definition (Parent (E)), Etype (E));
2931                   end if;
2932                end if;
2933
2934                --  For object created by object declaration, perform required
2935                --  categorization (preelaborate and pure) checks. Defer these
2936                --  checks to freeze time since pragma Import inhibits default
2937                --  initialization and thus pragma Import affects these checks.
2938
2939                Validate_Object_Declaration (Declaration_Node (E));
2940
2941                --  If there is an address clause, check that it is valid
2942
2943                Check_Address_Clause (E);
2944
2945                --  If the object needs any kind of default initialization, an
2946                --  error must be issued if No_Default_Initialization applies.
2947                --  The check doesn't apply to imported objects, which are not
2948                --  ever default initialized, and is why the check is deferred
2949                --  until freezing, at which point we know if Import applies.
2950                --  Deferred constants are also exempted from this test because
2951                --  their completion is explicit, or through an import pragma.
2952
2953                if Ekind (E) = E_Constant
2954                  and then Present (Full_View (E))
2955                then
2956                   null;
2957
2958                elsif Comes_From_Source (E)
2959                  and then not Is_Imported (E)
2960                  and then not Has_Init_Expression (Declaration_Node (E))
2961                  and then
2962                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2963                       and then not No_Initialization (Declaration_Node (E))
2964                       and then not Is_Value_Type (Etype (E))
2965                       and then not Initialization_Suppressed (Etype (E)))
2966                     or else
2967                       (Needs_Simple_Initialization (Etype (E))
2968                         and then not Is_Internal (E)))
2969                then
2970                   Has_Default_Initialization := True;
2971                   Check_Restriction
2972                     (No_Default_Initialization, Declaration_Node (E));
2973                end if;
2974
2975                --  Check that a Thread_Local_Storage variable does not have
2976                --  default initialization, and any explicit initialization must
2977                --  either be the null constant or a static constant.
2978
2979                if Has_Pragma_Thread_Local_Storage (E) then
2980                   declare
2981                      Decl : constant Node_Id := Declaration_Node (E);
2982                   begin
2983                      if Has_Default_Initialization
2984                        or else
2985                          (Has_Init_Expression (Decl)
2986                             and then
2987                              (No (Expression (Decl))
2988                                 or else not
2989                                   (Is_Static_Expression (Expression (Decl))
2990                                      or else
2991                                    Nkind (Expression (Decl)) = N_Null)))
2992                      then
2993                         Error_Msg_NE
2994                           ("Thread_Local_Storage variable& is "
2995                            & "improperly initialized", Decl, E);
2996                         Error_Msg_NE
2997                           ("\only allowed initialization is explicit "
2998                            & "NULL or static expression", Decl, E);
2999                      end if;
3000                   end;
3001                end if;
3002
3003                --  For imported objects, set Is_Public unless there is also an
3004                --  address clause, which means that there is no external symbol
3005                --  needed for the Import (Is_Public may still be set for other
3006                --  unrelated reasons). Note that we delayed this processing
3007                --  till freeze time so that we can be sure not to set the flag
3008                --  if there is an address clause. If there is such a clause,
3009                --  then the only purpose of the Import pragma is to suppress
3010                --  implicit initialization.
3011
3012                if Is_Imported (E)
3013                  and then No (Address_Clause (E))
3014                then
3015                   Set_Is_Public (E);
3016                end if;
3017
3018                --  For convention C objects of an enumeration type, warn if
3019                --  the size is not integer size and no explicit size given.
3020                --  Skip warning for Boolean, and Character, assume programmer
3021                --  expects 8-bit sizes for these cases.
3022
3023                if (Convention (E) = Convention_C
3024                     or else
3025                    Convention (E) = Convention_CPP)
3026                  and then Is_Enumeration_Type (Etype (E))
3027                  and then not Is_Character_Type (Etype (E))
3028                  and then not Is_Boolean_Type (Etype (E))
3029                  and then Esize (Etype (E)) < Standard_Integer_Size
3030                  and then not Has_Size_Clause (E)
3031                then
3032                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
3033                   Error_Msg_N
3034                     ("?convention C enumeration object has size less than ^",
3035                      E);
3036                   Error_Msg_N ("\?use explicit size clause to set size", E);
3037                end if;
3038             end if;
3039
3040             --  Check that a constant which has a pragma Volatile[_Components]
3041             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
3042
3043             --  Note: Atomic[_Components] also sets Volatile[_Components]
3044
3045             if Ekind (E) = E_Constant
3046               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
3047               and then not Is_Imported (E)
3048             then
3049                --  Make sure we actually have a pragma, and have not merely
3050                --  inherited the indication from elsewhere (e.g. an address
3051                --  clause, which is not good enough in RM terms!)
3052
3053                if Has_Rep_Pragma (E, Name_Atomic)
3054                     or else
3055                   Has_Rep_Pragma (E, Name_Atomic_Components)
3056                then
3057                   Error_Msg_N
3058                     ("stand alone atomic constant must be " &
3059                      "imported (RM C.6(13))", E);
3060
3061                elsif Has_Rep_Pragma (E, Name_Volatile)
3062                        or else
3063                      Has_Rep_Pragma (E, Name_Volatile_Components)
3064                then
3065                   Error_Msg_N
3066                     ("stand alone volatile constant must be " &
3067                      "imported (RM C.6(13))", E);
3068                end if;
3069             end if;
3070
3071             --  Static objects require special handling
3072
3073             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
3074               and then Is_Statically_Allocated (E)
3075             then
3076                Freeze_Static_Object (E);
3077             end if;
3078
3079             --  Remaining step is to layout objects
3080
3081             if Ekind (E) = E_Variable
3082                  or else
3083                Ekind (E) = E_Constant
3084                  or else
3085                Ekind (E) = E_Loop_Parameter
3086                  or else
3087                Is_Formal (E)
3088             then
3089                Layout_Object (E);
3090             end if;
3091          end if;
3092
3093       --  Case of a type or subtype being frozen
3094
3095       else
3096          --  We used to check here that a full type must have preelaborable
3097          --  initialization if it completes a private type specified with
3098          --  pragma Preelaborable_Initialization, but that missed cases where
3099          --  the types occur within a generic package, since the freezing
3100          --  that occurs within a containing scope generally skips traversal
3101          --  of a generic unit's declarations (those will be frozen within
3102          --  instances). This check was moved to Analyze_Package_Specification.
3103
3104          --  The type may be defined in a generic unit. This can occur when
3105          --  freezing a generic function that returns the type (which is
3106          --  defined in a parent unit). It is clearly meaningless to freeze
3107          --  this type. However, if it is a subtype, its size may be determi-
3108          --  nable and used in subsequent checks, so might as well try to
3109          --  compute it.
3110
3111          --  In Ada 2012, Freeze_Entities is also used in the front end to
3112          --  trigger the analysis of aspect expressions, so in this case we
3113          --  want to continue the freezing process.
3114
3115          if Present (Scope (E))
3116            and then Is_Generic_Unit (Scope (E))
3117            and then not Has_Predicates (E)
3118          then
3119             Check_Compile_Time_Size (E);
3120             return No_List;
3121          end if;
3122
3123          --  Deal with special cases of freezing for subtype
3124
3125          if E /= Base_Type (E) then
3126
3127             --  Before we do anything else, a specialized test for the case of
3128             --  a size given for an array where the array needs to be packed,
3129             --  but was not so the size cannot be honored. This would of course
3130             --  be caught by the backend, and indeed we don't catch all cases.
3131             --  The point is that we can give a better error message in those
3132             --  cases that we do catch with the circuitry here. Also if pragma
3133             --  Implicit_Packing is set, this is where the packing occurs.
3134
3135             --  The reason we do this so early is that the processing in the
3136             --  automatic packing case affects the layout of the base type, so
3137             --  it must be done before we freeze the base type.
3138
3139             if Is_Array_Type (E) then
3140                declare
3141                   Lo, Hi : Node_Id;
3142                   Ctyp   : constant Entity_Id := Component_Type (E);
3143
3144                begin
3145                   --  Check enabling conditions. These are straightforward
3146                   --  except for the test for a limited composite type. This
3147                   --  eliminates the rare case of a array of limited components
3148                   --  where there are issues of whether or not we can go ahead
3149                   --  and pack the array (since we can't freely pack and unpack
3150                   --  arrays if they are limited).
3151
3152                   --  Note that we check the root type explicitly because the
3153                   --  whole point is we are doing this test before we have had
3154                   --  a chance to freeze the base type (and it is that freeze
3155                   --  action that causes stuff to be inherited).
3156
3157                   if Present (Size_Clause (E))
3158                     and then Known_Static_RM_Size (E)
3159                     and then not Is_Packed (E)
3160                     and then not Has_Pragma_Pack (E)
3161                     and then Number_Dimensions (E) = 1
3162                     and then not Has_Component_Size_Clause (E)
3163                     and then Known_Static_RM_Size (Ctyp)
3164                     and then not Is_Limited_Composite (E)
3165                     and then not Is_Packed (Root_Type (E))
3166                     and then not Has_Component_Size_Clause (Root_Type (E))
3167                     and then not (CodePeer_Mode or Alfa_Mode)
3168                   then
3169                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3170
3171                      if Compile_Time_Known_Value (Lo)
3172                        and then Compile_Time_Known_Value (Hi)
3173                        and then Known_Static_RM_Size (Ctyp)
3174                        and then RM_Size (Ctyp) < 64
3175                      then
3176                         declare
3177                            Lov  : constant Uint      := Expr_Value (Lo);
3178                            Hiv  : constant Uint      := Expr_Value (Hi);
3179                            Len  : constant Uint      := UI_Max
3180                                                          (Uint_0,
3181                                                           Hiv - Lov + 1);
3182                            Rsiz : constant Uint      := RM_Size (Ctyp);
3183                            SZ   : constant Node_Id   := Size_Clause (E);
3184                            Btyp : constant Entity_Id := Base_Type (E);
3185
3186                         --  What we are looking for here is the situation where
3187                         --  the RM_Size given would be exactly right if there
3188                         --  was a pragma Pack (resulting in the component size
3189                         --  being the same as the RM_Size). Furthermore, the
3190                         --  component type size must be an odd size (not a
3191                         --  multiple of storage unit). If the component RM size
3192                         --  is an exact number of storage units that is a power
3193                         --  of two, the array is not packed and has a standard
3194                         --  representation.
3195
3196                         begin
3197                            if RM_Size (E) = Len * Rsiz
3198                              and then Rsiz mod System_Storage_Unit /= 0
3199                            then
3200                               --  For implicit packing mode, just set the
3201                               --  component size silently.
3202
3203                               if Implicit_Packing then
3204                                  Set_Component_Size       (Btyp, Rsiz);
3205                                  Set_Is_Bit_Packed_Array  (Btyp);
3206                                  Set_Is_Packed            (Btyp);
3207                                  Set_Has_Non_Standard_Rep (Btyp);
3208
3209                                  --  Otherwise give an error message
3210
3211                               else
3212                                  Error_Msg_NE
3213                                    ("size given for& too small", SZ, E);
3214                                  Error_Msg_N -- CODEFIX
3215                                    ("\use explicit pragma Pack "
3216                                     & "or use pragma Implicit_Packing", SZ);
3217                               end if;
3218
3219                            elsif RM_Size (E) = Len * Rsiz
3220                              and then Implicit_Packing
3221                              and then
3222                                (Rsiz / System_Storage_Unit = 1
3223                                  or else Rsiz / System_Storage_Unit = 2
3224                                  or else Rsiz / System_Storage_Unit = 4)
3225                            then
3226
3227                               --  Not a packed array, but indicate the desired
3228                               --  component size, for the back-end.
3229
3230                               Set_Component_Size (Btyp, Rsiz);
3231                            end if;
3232                         end;
3233                      end if;
3234                   end if;
3235                end;
3236             end if;
3237
3238             --  If ancestor subtype present, freeze that first. Note that this
3239             --  will also get the base type frozen. Need RM reference ???
3240
3241             Atype := Ancestor_Subtype (E);
3242
3243             if Present (Atype) then
3244                Freeze_And_Append (Atype, N, Result);
3245
3246             --  No ancestor subtype present
3247
3248             else
3249                --  See if we have a nearest ancestor that has a predicate.
3250                --  That catches the case of derived type with a predicate.
3251                --  Need RM reference here ???
3252
3253                Atype := Nearest_Ancestor (E);
3254
3255                if Present (Atype) and then Has_Predicates (Atype) then
3256                   Freeze_And_Append (Atype, N, Result);
3257                end if;
3258
3259                --  Freeze base type before freezing the entity (RM 13.14(15))
3260
3261                if E /= Base_Type (E) then
3262                   Freeze_And_Append (Base_Type (E), N, Result);
3263                end if;
3264             end if;
3265
3266          --  For a derived type, freeze its parent type first (RM 13.14(15))
3267
3268          elsif Is_Derived_Type (E) then
3269             Freeze_And_Append (Etype (E), N, Result);
3270             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3271          end if;
3272
3273          --  For array type, freeze index types and component type first
3274          --  before freezing the array (RM 13.14(15)).
3275
3276          if Is_Array_Type (E) then
3277             declare
3278                FS     : constant Entity_Id := First_Subtype (E);
3279                Ctyp   : constant Entity_Id := Component_Type (E);
3280                Clause : Entity_Id;
3281
3282                Non_Standard_Enum : Boolean := False;
3283                --  Set true if any of the index types is an enumeration type
3284                --  with a non-standard representation.
3285
3286             begin
3287                Freeze_And_Append (Ctyp, N, Result);
3288
3289                Indx := First_Index (E);
3290                while Present (Indx) loop
3291                   Freeze_And_Append (Etype (Indx), N, Result);
3292
3293                   if Is_Enumeration_Type (Etype (Indx))
3294                     and then Has_Non_Standard_Rep (Etype (Indx))
3295                   then
3296                      Non_Standard_Enum := True;
3297                   end if;
3298
3299                   Next_Index (Indx);
3300                end loop;
3301
3302                --  Processing that is done only for base types
3303
3304                if Ekind (E) = E_Array_Type then
3305
3306                   --  Propagate flags for component type
3307
3308                   if Is_Controlled (Component_Type (E))
3309                     or else Has_Controlled_Component (Ctyp)
3310                   then
3311                      Set_Has_Controlled_Component (E);
3312                   end if;
3313
3314                   if Has_Unchecked_Union (Component_Type (E)) then
3315                      Set_Has_Unchecked_Union (E);
3316                   end if;
3317
3318                   --  If packing was requested or if the component size was set
3319                   --  explicitly, then see if bit packing is required. This
3320                   --  processing is only done for base types, since all the
3321                   --  representation aspects involved are type-related. This
3322                   --  is not just an optimization, if we start processing the
3323                   --  subtypes, they interfere with the settings on the base
3324                   --  type (this is because Is_Packed has a slightly different
3325                   --  meaning before and after freezing).
3326
3327                   declare
3328                      Csiz : Uint;
3329                      Esiz : Uint;
3330
3331                   begin
3332                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3333                        and then Known_Static_RM_Size (Ctyp)
3334                        and then not Has_Component_Size_Clause (E)
3335                      then
3336                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3337
3338                      elsif Known_Component_Size (E) then
3339                         Csiz := Component_Size (E);
3340
3341                      elsif not Known_Static_Esize (Ctyp) then
3342                         Csiz := Uint_0;
3343
3344                      else
3345                         Esiz := Esize (Ctyp);
3346
3347                         --  We can set the component size if it is less than
3348                         --  16, rounding it up to the next storage unit size.
3349
3350                         if Esiz <= 8 then
3351                            Csiz := Uint_8;
3352                         elsif Esiz <= 16 then
3353                            Csiz := Uint_16;
3354                         else
3355                            Csiz := Uint_0;
3356                         end if;
3357
3358                         --  Set component size up to match alignment if it
3359                         --  would otherwise be less than the alignment. This
3360                         --  deals with cases of types whose alignment exceeds
3361                         --  their size (padded types).
3362
3363                         if Csiz /= 0 then
3364                            declare
3365                               A : constant Uint := Alignment_In_Bits (Ctyp);
3366                            begin
3367                               if Csiz < A then
3368                                  Csiz := A;
3369                               end if;
3370                            end;
3371                         end if;
3372                      end if;
3373
3374                      --  Case of component size that may result in packing
3375
3376                      if 1 <= Csiz and then Csiz <= 64 then
3377                         declare
3378                            Ent         : constant Entity_Id :=
3379                                            First_Subtype (E);
3380                            Pack_Pragma : constant Node_Id :=
3381                                            Get_Rep_Pragma (Ent, Name_Pack);
3382                            Comp_Size_C : constant Node_Id :=
3383                                            Get_Attribute_Definition_Clause
3384                                              (Ent, Attribute_Component_Size);
3385                         begin
3386                            --  Warn if we have pack and component size so that
3387                            --  the pack is ignored.
3388
3389                            --  Note: here we must check for the presence of a
3390                            --  component size before checking for a Pack pragma
3391                            --  to deal with the case where the array type is a
3392                            --  derived type whose parent is currently private.
3393
3394                            if Present (Comp_Size_C)
3395                              and then Has_Pragma_Pack (Ent)
3396                              and then Warn_On_Redundant_Constructs
3397                            then
3398                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3399                               Error_Msg_NE
3400                                 ("?pragma Pack for& ignored!",
3401                                  Pack_Pragma, Ent);
3402                               Error_Msg_N
3403                                 ("\?explicit component size given#!",
3404                                  Pack_Pragma);
3405                               Set_Is_Packed (Base_Type (Ent), False);
3406                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3407                            end if;
3408
3409                            --  Set component size if not already set by a
3410                            --  component size clause.
3411
3412                            if not Present (Comp_Size_C) then
3413                               Set_Component_Size (E, Csiz);
3414                            end if;
3415
3416                            --  Check for base type of 8, 16, 32 bits, where an
3417                            --  unsigned subtype has a length one less than the
3418                            --  base type (e.g. Natural subtype of Integer).
3419
3420                            --  In such cases, if a component size was not set
3421                            --  explicitly, then generate a warning.
3422
3423                            if Has_Pragma_Pack (E)
3424                              and then not Present (Comp_Size_C)
3425                              and then
3426                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3427                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3428                            then
3429                               Error_Msg_Uint_1 := Csiz;
3430
3431                               if Present (Pack_Pragma) then
3432                                  Error_Msg_N
3433                                    ("?pragma Pack causes component size "
3434                                     & "to be ^!", Pack_Pragma);
3435                                  Error_Msg_N
3436                                    ("\?use Component_Size to set "
3437                                     & "desired value!", Pack_Pragma);
3438                               end if;
3439                            end if;
3440
3441                            --  Actual packing is not needed for 8, 16, 32, 64.
3442                            --  Also not needed for 24 if alignment is 1.
3443
3444                            if        Csiz = 8
3445                              or else Csiz = 16
3446                              or else Csiz = 32
3447                              or else Csiz = 64
3448                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3449                            then
3450                               --  Here the array was requested to be packed,
3451                               --  but the packing request had no effect, so
3452                               --  Is_Packed is reset.
3453
3454                               --  Note: semantically this means that we lose
3455                               --  track of the fact that a derived type
3456                               --  inherited a pragma Pack that was non-
3457                               --  effective, but that seems fine.
3458
3459                               --  We regard a Pack pragma as a request to set
3460                               --  a representation characteristic, and this
3461                               --  request may be ignored.
3462
3463                               Set_Is_Packed           (Base_Type (E), False);
3464                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3465
3466                               if Known_Static_Esize (Component_Type (E))
3467                                 and then Esize (Component_Type (E)) = Csiz
3468                               then
3469                                  Set_Has_Non_Standard_Rep
3470                                    (Base_Type (E), False);
3471                               end if;
3472
3473                            --  In all other cases, packing is indeed needed
3474
3475                            else
3476                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3477                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3478                               Set_Is_Packed            (Base_Type (E), True);
3479                            end if;
3480                         end;
3481                      end if;
3482                   end;
3483
3484                   --  Check for Atomic_Components or Aliased with unsuitable
3485                   --  packing or explicit component size clause given.
3486
3487                   if (Has_Atomic_Components (E)
3488                        or else Has_Aliased_Components (E))
3489                     and then (Has_Component_Size_Clause (E)
3490                                or else Is_Packed (E))
3491                   then
3492                      Alias_Atomic_Check : declare
3493
3494                         procedure Complain_CS (T : String);
3495                         --  Outputs error messages for incorrect CS clause or
3496                         --  pragma Pack for aliased or atomic components (T is
3497                         --  "aliased" or "atomic");
3498
3499                         -----------------
3500                         -- Complain_CS --
3501                         -----------------
3502
3503                         procedure Complain_CS (T : String) is
3504                         begin
3505                            if Has_Component_Size_Clause (E) then
3506                               Clause :=
3507                                 Get_Attribute_Definition_Clause
3508                                   (FS, Attribute_Component_Size);
3509
3510                               if Known_Static_Esize (Ctyp) then
3511                                  Error_Msg_N
3512                                    ("incorrect component size for "
3513                                     & T & " components", Clause);
3514                                  Error_Msg_Uint_1 := Esize (Ctyp);
3515                                  Error_Msg_N
3516                                    ("\only allowed value is^", Clause);
3517
3518                               else
3519                                  Error_Msg_N
3520                                    ("component size cannot be given for "
3521                                     & T & " components", Clause);
3522                               end if;
3523
3524                            else
3525                               Error_Msg_N
3526                                 ("cannot pack " & T & " components",
3527                                  Get_Rep_Pragma (FS, Name_Pack));
3528                            end if;
3529
3530                            return;
3531                         end Complain_CS;
3532
3533                      --  Start of processing for Alias_Atomic_Check
3534
3535                      begin
3536
3537                         --  If object size of component type isn't known, we
3538                         --  cannot be sure so we defer to the back end.
3539
3540                         if not Known_Static_Esize (Ctyp) then
3541                            null;
3542
3543                         --  Case where component size has no effect. First
3544                         --  check for object size of component type multiple
3545                         --  of the storage unit size.
3546
3547                         elsif Esize (Ctyp) mod System_Storage_Unit = 0
3548
3549                           --  OK in both packing case and component size case
3550                           --  if RM size is known and static and the same as
3551                           --  the object size.
3552
3553                           and then
3554                             ((Known_Static_RM_Size (Ctyp)
3555                                and then Esize (Ctyp) = RM_Size (Ctyp))
3556
3557                              --  Or if we have an explicit component size
3558                              --  clause and the component size and object size
3559                              --  are equal.
3560
3561                              or else
3562                                  (Has_Component_Size_Clause (E)
3563                                  and then Component_Size (E) = Esize (Ctyp)))
3564                         then
3565                            null;
3566
3567                         elsif Has_Aliased_Components (E)
3568                           or else Is_Aliased (Ctyp)
3569                         then
3570                            Complain_CS ("aliased");
3571
3572                         elsif Has_Atomic_Components (E)
3573                           or else Is_Atomic (Ctyp)
3574                         then
3575                            Complain_CS ("atomic");
3576                         end if;
3577                      end Alias_Atomic_Check;
3578                   end if;
3579
3580                   --  Warn for case of atomic type
3581
3582                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3583
3584                   if Present (Clause)
3585                     and then not Addressable (Component_Size (FS))
3586                   then
3587                      Error_Msg_NE
3588                        ("non-atomic components of type& may not be "
3589                         & "accessible by separate tasks?", Clause, E);
3590
3591                      if Has_Component_Size_Clause (E) then
3592                         Error_Msg_Sloc :=
3593                           Sloc
3594                             (Get_Attribute_Definition_Clause
3595                                  (FS, Attribute_Component_Size));
3596                         Error_Msg_N
3597                           ("\because of component size clause#?",
3598                            Clause);
3599
3600                      elsif Has_Pragma_Pack (E) then
3601                         Error_Msg_Sloc :=
3602                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3603                         Error_Msg_N
3604                           ("\because of pragma Pack#?", Clause);
3605                      end if;
3606                   end if;
3607
3608                --  Processing that is done only for subtypes
3609
3610                else
3611                   --  Acquire alignment from base type
3612
3613                   if Unknown_Alignment (E) then
3614                      Set_Alignment (E, Alignment (Base_Type (E)));
3615                      Adjust_Esize_Alignment (E);
3616                   end if;
3617                end if;
3618
3619                --  For bit-packed arrays, check the size
3620
3621                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3622                   declare
3623                      SizC : constant Node_Id := Size_Clause (E);
3624
3625                      Discard : Boolean;
3626                      pragma Warnings (Off, Discard);
3627
3628                   begin
3629                      --  It is not clear if it is possible to have no size
3630                      --  clause at this stage, but it is not worth worrying
3631                      --  about. Post error on the entity name in the size
3632                      --  clause if present, else on the type entity itself.
3633
3634                      if Present (SizC) then
3635                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3636                      else
3637                         Check_Size (E, E, RM_Size (E), Discard);
3638                      end if;
3639                   end;
3640                end if;
3641
3642                --  If any of the index types was an enumeration type with a
3643                --  non-standard rep clause, then we indicate that the array
3644                --  type is always packed (even if it is not bit packed).
3645
3646                if Non_Standard_Enum then
3647                   Set_Has_Non_Standard_Rep (Base_Type (E));
3648                   Set_Is_Packed            (Base_Type (E));
3649                end if;
3650
3651                Set_Component_Alignment_If_Not_Set (E);
3652
3653                --  If the array is packed, we must create the packed array
3654                --  type to be used to actually implement the type. This is
3655                --  only needed for real array types (not for string literal
3656                --  types, since they are present only for the front end).
3657
3658                if Is_Packed (E)
3659                  and then Ekind (E) /= E_String_Literal_Subtype
3660                then
3661                   Create_Packed_Array_Type (E);
3662                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3663
3664                   --  Size information of packed array type is copied to the
3665                   --  array type, since this is really the representation. But
3666                   --  do not override explicit existing size values. If the
3667                   --  ancestor subtype is constrained the packed_array_type
3668                   --  will be inherited from it, but the size may have been
3669                   --  provided already, and must not be overridden either.
3670
3671                   if not Has_Size_Clause (E)
3672                     and then
3673                       (No (Ancestor_Subtype (E))
3674                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3675                   then
3676                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3677                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3678                   end if;
3679
3680                   if not Has_Alignment_Clause (E) then
3681                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3682                   end if;
3683                end if;
3684
3685                --  For non-packed arrays set the alignment of the array to the
3686                --  alignment of the component type if it is unknown. Skip this
3687                --  in atomic case (atomic arrays may need larger alignments).
3688
3689                if not Is_Packed (E)
3690                  and then Unknown_Alignment (E)
3691                  and then Known_Alignment (Ctyp)
3692                  and then Known_Static_Component_Size (E)
3693                  and then Known_Static_Esize (Ctyp)
3694                  and then Esize (Ctyp) = Component_Size (E)
3695                  and then not Is_Atomic (E)
3696                then
3697                   Set_Alignment (E, Alignment (Component_Type (E)));
3698                end if;
3699             end;
3700
3701          --  For a class-wide type, the corresponding specific type is
3702          --  frozen as well (RM 13.14(15))
3703
3704          elsif Is_Class_Wide_Type (E) then
3705             Freeze_And_Append (Root_Type (E), N, Result);
3706
3707             --  If the base type of the class-wide type is still incomplete,
3708             --  the class-wide remains unfrozen as well. This is legal when
3709             --  E is the formal of a primitive operation of some other type
3710             --  which is being frozen.
3711
3712             if not Is_Frozen (Root_Type (E)) then
3713                Set_Is_Frozen (E, False);
3714                return Result;
3715             end if;
3716
3717             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3718             --  parent of a derived type) and it is a library-level entity,
3719             --  generate an itype reference for it. Otherwise, its first
3720             --  explicit reference may be in an inner scope, which will be
3721             --  rejected by the back-end.
3722
3723             if Is_Itype (E)
3724               and then Is_Compilation_Unit (Scope (E))
3725             then
3726                declare
3727                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3728
3729                begin
3730                   Set_Itype (Ref, E);
3731                   Add_To_Result (Ref);
3732                end;
3733             end if;
3734
3735             --  The equivalent type associated with a class-wide subtype needs
3736             --  to be frozen to ensure that its layout is done.
3737
3738             if Ekind (E) = E_Class_Wide_Subtype
3739               and then Present (Equivalent_Type (E))
3740             then
3741                Freeze_And_Append (Equivalent_Type (E), N, Result);
3742             end if;
3743
3744          --  For a record (sub)type, freeze all the component types (RM
3745          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3746          --  Is_Record_Type, because we don't want to attempt the freeze for
3747          --  the case of a private type with record extension (we will do that
3748          --  later when the full type is frozen).
3749
3750          elsif Ekind (E) = E_Record_Type
3751            or else Ekind (E) = E_Record_Subtype
3752          then
3753             Freeze_Record_Type (E);
3754
3755          --  For a concurrent type, freeze corresponding record type. This
3756          --  does not correspond to any specific rule in the RM, but the
3757          --  record type is essentially part of the concurrent type.
3758          --  Freeze as well all local entities. This includes record types
3759          --  created for entry parameter blocks, and whatever local entities
3760          --  may appear in the private part.
3761
3762          elsif Is_Concurrent_Type (E) then
3763             if Present (Corresponding_Record_Type (E)) then
3764                Freeze_And_Append
3765                  (Corresponding_Record_Type (E), N, Result);
3766             end if;
3767
3768             Comp := First_Entity (E);
3769             while Present (Comp) loop
3770                if Is_Type (Comp) then
3771                   Freeze_And_Append (Comp, N, Result);
3772
3773                elsif (Ekind (Comp)) /= E_Function then
3774                   if Is_Itype (Etype (Comp))
3775                     and then Underlying_Type (Scope (Etype (Comp))) = E
3776                   then
3777                      Undelay_Type (Etype (Comp));
3778                   end if;
3779
3780                   Freeze_And_Append (Etype (Comp), N, Result);
3781                end if;
3782
3783                Next_Entity (Comp);
3784             end loop;
3785
3786          --  Private types are required to point to the same freeze node as
3787          --  their corresponding full views. The freeze node itself has to
3788          --  point to the partial view of the entity (because from the partial
3789          --  view, we can retrieve the full view, but not the reverse).
3790          --  However, in order to freeze correctly, we need to freeze the full
3791          --  view. If we are freezing at the end of a scope (or within the
3792          --  scope of the private type), the partial and full views will have
3793          --  been swapped, the full view appears first in the entity chain and
3794          --  the swapping mechanism ensures that the pointers are properly set
3795          --  (on scope exit).
3796
3797          --  If we encounter the partial view before the full view (e.g. when
3798          --  freezing from another scope), we freeze the full view, and then
3799          --  set the pointers appropriately since we cannot rely on swapping to
3800          --  fix things up (subtypes in an outer scope might not get swapped).
3801
3802          elsif Is_Incomplete_Or_Private_Type (E)
3803            and then not Is_Generic_Type (E)
3804          then
3805             --  The construction of the dispatch table associated with library
3806             --  level tagged types forces freezing of all the primitives of the
3807             --  type, which may cause premature freezing of the partial view.
3808             --  For example:
3809
3810             --     package Pkg is
3811             --        type T is tagged private;
3812             --        type DT is new T with private;
3813             --        procedure Prim (X : in out T; Y : in out DT'Class);
3814             --     private
3815             --        type T is tagged null record;
3816             --        Obj : T;
3817             --        type DT is new T with null record;
3818             --     end;
3819
3820             --  In this case the type will be frozen later by the usual
3821             --  mechanism: an object declaration, an instantiation, or the
3822             --  end of a declarative part.
3823
3824             if Is_Library_Level_Tagged_Type (E)
3825               and then not Present (Full_View (E))
3826             then
3827                Set_Is_Frozen (E, False);
3828                return Result;
3829
3830             --  Case of full view present
3831
3832             elsif Present (Full_View (E)) then
3833
3834                --  If full view has already been frozen, then no further
3835                --  processing is required
3836
3837                if Is_Frozen (Full_View (E)) then
3838                   Set_Has_Delayed_Freeze (E, False);
3839                   Set_Freeze_Node (E, Empty);
3840                   Check_Debug_Info_Needed (E);
3841
3842                --  Otherwise freeze full view and patch the pointers so that
3843                --  the freeze node will elaborate both views in the back-end.
3844
3845                else
3846                   declare
3847                      Full : constant Entity_Id := Full_View (E);
3848
3849                   begin
3850                      if Is_Private_Type (Full)
3851                        and then Present (Underlying_Full_View (Full))
3852                      then
3853                         Freeze_And_Append
3854                           (Underlying_Full_View (Full), N, Result);
3855                      end if;
3856
3857                      Freeze_And_Append (Full, N, Result);
3858
3859                      if Has_Delayed_Freeze (E) then
3860                         F_Node := Freeze_Node (Full);
3861
3862                         if Present (F_Node) then
3863                            Set_Freeze_Node (E, F_Node);
3864                            Set_Entity (F_Node, E);
3865
3866                         else
3867                            --  {Incomplete,Private}_Subtypes with Full_Views
3868                            --  constrained by discriminants.
3869
3870                            Set_Has_Delayed_Freeze (E, False);
3871                            Set_Freeze_Node (E, Empty);
3872                         end if;
3873                      end if;
3874                   end;
3875
3876                   Check_Debug_Info_Needed (E);
3877                end if;
3878
3879                --  AI-117 requires that the convention of a partial view be the
3880                --  same as the convention of the full view. Note that this is a
3881                --  recognized breach of privacy, but it's essential for logical
3882                --  consistency of representation, and the lack of a rule in
3883                --  RM95 was an oversight.
3884
3885                Set_Convention (E, Convention (Full_View (E)));
3886
3887                Set_Size_Known_At_Compile_Time (E,
3888                  Size_Known_At_Compile_Time (Full_View (E)));
3889
3890                --  Size information is copied from the full view to the
3891                --  incomplete or private view for consistency.
3892
3893                --  We skip this is the full view is not a type. This is very
3894                --  strange of course, and can only happen as a result of
3895                --  certain illegalities, such as a premature attempt to derive
3896                --  from an incomplete type.
3897
3898                if Is_Type (Full_View (E)) then
3899                   Set_Size_Info (E, Full_View (E));
3900                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3901                end if;
3902
3903                return Result;
3904
3905             --  Case of no full view present. If entity is derived or subtype,
3906             --  it is safe to freeze, correctness depends on the frozen status
3907             --  of parent. Otherwise it is either premature usage, or a Taft
3908             --  amendment type, so diagnosis is at the point of use and the
3909             --  type might be frozen later.
3910
3911             elsif E /= Base_Type (E)
3912               or else Is_Derived_Type (E)
3913             then
3914                null;
3915
3916             else
3917                Set_Is_Frozen (E, False);
3918                return No_List;
3919             end if;
3920
3921          --  For access subprogram, freeze types of all formals, the return
3922          --  type was already frozen, since it is the Etype of the function.
3923          --  Formal types can be tagged Taft amendment types, but otherwise
3924          --  they cannot be incomplete.
3925
3926          elsif Ekind (E) = E_Subprogram_Type then
3927             Formal := First_Formal (E);
3928             while Present (Formal) loop
3929                if Ekind (Etype (Formal)) = E_Incomplete_Type
3930                  and then No (Full_View (Etype (Formal)))
3931                  and then not Is_Value_Type (Etype (Formal))
3932                then
3933                   if Is_Tagged_Type (Etype (Formal)) then
3934                      null;
3935
3936                   --  AI05-151: Incomplete types are allowed in access to
3937                   --  subprogram specifications.
3938
3939                   elsif Ada_Version < Ada_2012 then
3940                      Error_Msg_NE
3941                        ("invalid use of incomplete type&", E, Etype (Formal));
3942                   end if;
3943                end if;
3944
3945                Freeze_And_Append (Etype (Formal), N, Result);
3946                Next_Formal (Formal);
3947             end loop;
3948
3949             Freeze_Subprogram (E);
3950
3951          --  For access to a protected subprogram, freeze the equivalent type
3952          --  (however this is not set if we are not generating code or if this
3953          --  is an anonymous type used just for resolution).
3954
3955          elsif Is_Access_Protected_Subprogram_Type (E) then
3956             if Present (Equivalent_Type (E)) then
3957                Freeze_And_Append (Equivalent_Type (E), N, Result);
3958             end if;
3959          end if;
3960
3961          --  Generic types are never seen by the back-end, and are also not
3962          --  processed by the expander (since the expander is turned off for
3963          --  generic processing), so we never need freeze nodes for them.
3964
3965          if Is_Generic_Type (E) then
3966             return Result;
3967          end if;
3968
3969          --  Some special processing for non-generic types to complete
3970          --  representation details not known till the freeze point.
3971
3972          if Is_Fixed_Point_Type (E) then
3973             Freeze_Fixed_Point_Type (E);
3974
3975             --  Some error checks required for ordinary fixed-point type. Defer
3976             --  these till the freeze-point since we need the small and range
3977             --  values. We only do these checks for base types
3978
3979             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3980                if Small_Value (E) < Ureal_2_M_80 then
3981                   Error_Msg_Name_1 := Name_Small;
3982                   Error_Msg_N
3983                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3984
3985                elsif Small_Value (E) > Ureal_2_80 then
3986                   Error_Msg_Name_1 := Name_Small;
3987                   Error_Msg_N
3988                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3989                end if;
3990
3991                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3992                   Error_Msg_Name_1 := Name_First;
3993                   Error_Msg_N
3994                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3995                end if;
3996
3997                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3998                   Error_Msg_Name_1 := Name_Last;
3999                   Error_Msg_N
4000                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
4001                end if;
4002             end if;
4003
4004          elsif Is_Enumeration_Type (E) then
4005             Freeze_Enumeration_Type (E);
4006
4007          elsif Is_Integer_Type (E) then
4008             Adjust_Esize_For_Alignment (E);
4009
4010             if Is_Modular_Integer_Type (E)
4011               and then Warn_On_Suspicious_Modulus_Value
4012             then
4013                Check_Suspicious_Modulus (E);
4014             end if;
4015
4016          elsif Is_Access_Type (E) then
4017
4018             --  If a pragma Default_Storage_Pool applies, and this type has no
4019             --  Storage_Pool or Storage_Size clause (which must have occurred
4020             --  before the freezing point), then use the default. This applies
4021             --  only to base types.
4022
4023             if Present (Default_Pool)
4024               and then Is_Base_Type (E)
4025               and then not Has_Storage_Size_Clause (E)
4026               and then No (Associated_Storage_Pool (E))
4027             then
4028                --  Case of pragma Default_Storage_Pool (null)
4029
4030                if Nkind (Default_Pool) = N_Null then
4031                   Set_No_Pool_Assigned (E);
4032
4033                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
4034
4035                else
4036                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
4037                end if;
4038             end if;
4039
4040             --  Check restriction for standard storage pool
4041
4042             if No (Associated_Storage_Pool (E)) then
4043                Check_Restriction (No_Standard_Storage_Pools, E);
4044             end if;
4045
4046             --  Deal with error message for pure access type. This is not an
4047             --  error in Ada 2005 if there is no pool (see AI-366).
4048
4049             if Is_Pure_Unit_Access_Type (E)
4050               and then (Ada_Version < Ada_2005
4051                          or else not No_Pool_Assigned (E))
4052             then
4053                Error_Msg_N ("named access type not allowed in pure unit", E);
4054
4055                if Ada_Version >= Ada_2005 then
4056                   Error_Msg_N
4057                     ("\would be legal if Storage_Size of 0 given?", E);
4058
4059                elsif No_Pool_Assigned (E) then
4060                   Error_Msg_N
4061                     ("\would be legal in Ada 2005?", E);
4062
4063                else
4064                   Error_Msg_N
4065                     ("\would be legal in Ada 2005 if "
4066                      & "Storage_Size of 0 given?", E);
4067                end if;
4068             end if;
4069          end if;
4070
4071          --  Case of composite types
4072
4073          if Is_Composite_Type (E) then
4074
4075             --  AI-117 requires that all new primitives of a tagged type must
4076             --  inherit the convention of the full view of the type. Inherited
4077             --  and overriding operations are defined to inherit the convention
4078             --  of their parent or overridden subprogram (also specified in
4079             --  AI-117), which will have occurred earlier (in Derive_Subprogram
4080             --  and New_Overloaded_Entity). Here we set the convention of
4081             --  primitives that are still convention Ada, which will ensure
4082             --  that any new primitives inherit the type's convention. Class-
4083             --  wide types can have a foreign convention inherited from their
4084             --  specific type, but are excluded from this since they don't have
4085             --  any associated primitives.
4086
4087             if Is_Tagged_Type (E)
4088               and then not Is_Class_Wide_Type (E)
4089               and then Convention (E) /= Convention_Ada
4090             then
4091                declare
4092                   Prim_List : constant Elist_Id := Primitive_Operations (E);
4093                   Prim      : Elmt_Id;
4094
4095                begin
4096                   Prim := First_Elmt (Prim_List);
4097                   while Present (Prim) loop
4098                      if Convention (Node (Prim)) = Convention_Ada then
4099                         Set_Convention (Node (Prim), Convention (E));
4100                      end if;
4101
4102                      Next_Elmt (Prim);
4103                   end loop;
4104                end;
4105             end if;
4106          end if;
4107
4108          --  Now that all types from which E may depend are frozen, see if the
4109          --  size is known at compile time, if it must be unsigned, or if
4110          --  strict alignment is required
4111
4112          Check_Compile_Time_Size (E);
4113          Check_Unsigned_Type (E);
4114
4115          if Base_Type (E) = E then
4116             Check_Strict_Alignment (E);
4117          end if;
4118
4119          --  Do not allow a size clause for a type which does not have a size
4120          --  that is known at compile time
4121
4122          if Has_Size_Clause (E)
4123            and then not Size_Known_At_Compile_Time (E)
4124          then
4125             --  Suppress this message if errors posted on E, even if we are
4126             --  in all errors mode, since this is often a junk message
4127
4128             if not Error_Posted (E) then
4129                Error_Msg_N
4130                  ("size clause not allowed for variable length type",
4131                   Size_Clause (E));
4132             end if;
4133          end if;
4134
4135          --  Now we set/verify the representation information, in particular
4136          --  the size and alignment values. This processing is not required for
4137          --  generic types, since generic types do not play any part in code
4138          --  generation, and so the size and alignment values for such types
4139          --  are irrelevant.
4140
4141          if Is_Generic_Type (E) then
4142             return Result;
4143
4144          --  Otherwise we call the layout procedure
4145
4146          else
4147             Layout_Type (E);
4148          end if;
4149
4150          --  If this is an access to subprogram whose designated type is itself
4151          --  a subprogram type, the return type of this anonymous subprogram
4152          --  type must be decorated as well.
4153
4154          if Ekind (E) = E_Anonymous_Access_Subprogram_Type
4155            and then Ekind (Designated_Type (E)) = E_Subprogram_Type
4156          then
4157             Layout_Type (Etype (Designated_Type (E)));
4158          end if;
4159
4160          --  If the type has a Defaut_Value/Default_Component_Value aspect,
4161          --  this is where we analye the expression (after the type is frozen,
4162          --  since in the case of Default_Value, we are analyzing with the
4163          --  type itself, and we treat Default_Component_Value similarly for
4164          --  the sake of uniformity.
4165
4166          if Is_First_Subtype (E) and then Has_Default_Aspect (E) then
4167             declare
4168                Nam    : Name_Id;
4169                Exp    : Node_Id;
4170                Typ    : Entity_Id;
4171
4172             begin
4173                if Is_Scalar_Type (E) then
4174                   Nam := Name_Default_Value;
4175                   Typ := E;
4176                   Exp := Default_Aspect_Value (Typ);
4177                else
4178                   Nam := Name_Default_Component_Value;
4179                   Exp := Default_Aspect_Component_Value (E);
4180                   Typ := Component_Type (E);
4181                end if;
4182
4183                Analyze_And_Resolve (Exp, Typ);
4184
4185                if Etype (Exp) /= Any_Type then
4186                   if not Is_Static_Expression (Exp) then
4187                      Error_Msg_Name_1 := Nam;
4188                      Flag_Non_Static_Expr
4189                        ("aspect% requires static expression", Exp);
4190                   end if;
4191                end if;
4192             end;
4193          end if;
4194
4195          --  End of freeze processing for type entities
4196       end if;
4197
4198       --  Here is where we logically freeze the current entity. If it has a
4199       --  freeze node, then this is the point at which the freeze node is
4200       --  linked into the result list.
4201
4202       if Has_Delayed_Freeze (E) then
4203
4204          --  If a freeze node is already allocated, use it, otherwise allocate
4205          --  a new one. The preallocation happens in the case of anonymous base
4206          --  types, where we preallocate so that we can set First_Subtype_Link.
4207          --  Note that we reset the Sloc to the current freeze location.
4208
4209          if Present (Freeze_Node (E)) then
4210             F_Node := Freeze_Node (E);
4211             Set_Sloc (F_Node, Loc);
4212
4213          else
4214             F_Node := New_Node (N_Freeze_Entity, Loc);
4215             Set_Freeze_Node (E, F_Node);
4216             Set_Access_Types_To_Process (F_Node, No_Elist);
4217             Set_TSS_Elist (F_Node, No_Elist);
4218             Set_Actions (F_Node, No_List);
4219          end if;
4220
4221          Set_Entity (F_Node, E);
4222          Add_To_Result (F_Node);
4223
4224          --  A final pass over record types with discriminants. If the type
4225          --  has an incomplete declaration, there may be constrained access
4226          --  subtypes declared elsewhere, which do not depend on the discrimi-
4227          --  nants of the type, and which are used as component types (i.e.
4228          --  the full view is a recursive type). The designated types of these
4229          --  subtypes can only be elaborated after the type itself, and they
4230          --  need an itype reference.
4231
4232          if Ekind (E) = E_Record_Type
4233            and then Has_Discriminants (E)
4234          then
4235             declare
4236                Comp : Entity_Id;
4237                IR   : Node_Id;
4238                Typ  : Entity_Id;
4239
4240             begin
4241                Comp := First_Component (E);
4242                while Present (Comp) loop
4243                   Typ  := Etype (Comp);
4244
4245                   if Ekind (Comp) = E_Component
4246                     and then Is_Access_Type (Typ)
4247                     and then Scope (Typ) /= E
4248                     and then Base_Type (Designated_Type (Typ)) = E
4249                     and then Is_Itype (Designated_Type (Typ))
4250                   then
4251                      IR := Make_Itype_Reference (Sloc (Comp));
4252                      Set_Itype (IR, Designated_Type (Typ));
4253                      Append (IR, Result);
4254                   end if;
4255
4256                   Next_Component (Comp);
4257                end loop;
4258             end;
4259          end if;
4260       end if;
4261
4262       --  When a type is frozen, the first subtype of the type is frozen as
4263       --  well (RM 13.14(15)). This has to be done after freezing the type,
4264       --  since obviously the first subtype depends on its own base type.
4265
4266       if Is_Type (E) then
4267          Freeze_And_Append (First_Subtype (E), N, Result);
4268
4269          --  If we just froze a tagged non-class wide record, then freeze the
4270          --  corresponding class-wide type. This must be done after the tagged
4271          --  type itself is frozen, because the class-wide type refers to the
4272          --  tagged type which generates the class.
4273
4274          if Is_Tagged_Type (E)
4275            and then not Is_Class_Wide_Type (E)
4276            and then Present (Class_Wide_Type (E))
4277          then
4278             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4279          end if;
4280       end if;
4281
4282       Check_Debug_Info_Needed (E);
4283
4284       --  Special handling for subprograms
4285
4286       if Is_Subprogram (E) then
4287
4288          --  If subprogram has address clause then reset Is_Public flag, since
4289          --  we do not want the backend to generate external references.
4290
4291          if Present (Address_Clause (E))
4292            and then not Is_Library_Level_Entity (E)
4293          then
4294             Set_Is_Public (E, False);
4295
4296          --  If no address clause and not intrinsic, then for imported
4297          --  subprogram in main unit, generate descriptor if we are in
4298          --  Propagate_Exceptions mode.
4299
4300          --  This is very odd code, it makes a null result, why ???
4301
4302          elsif Propagate_Exceptions
4303            and then Is_Imported (E)
4304            and then not Is_Intrinsic_Subprogram (E)
4305            and then Convention (E) /= Convention_Stubbed
4306          then
4307             if Result = No_List then
4308                Result := Empty_List;
4309             end if;
4310          end if;
4311       end if;
4312
4313       return Result;
4314    end Freeze_Entity;
4315
4316    -----------------------------
4317    -- Freeze_Enumeration_Type --
4318    -----------------------------
4319
4320    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4321    begin
4322       --  By default, if no size clause is present, an enumeration type with
4323       --  Convention C is assumed to interface to a C enum, and has integer
4324       --  size. This applies to types. For subtypes, verify that its base
4325       --  type has no size clause either. Treat other foreign conventions
4326       --  in the same way, and also make sure alignment is set right.
4327
4328       if Has_Foreign_Convention (Typ)
4329         and then not Has_Size_Clause (Typ)
4330         and then not Has_Size_Clause (Base_Type (Typ))
4331         and then Esize (Typ) < Standard_Integer_Size
4332       then
4333          Init_Esize (Typ, Standard_Integer_Size);
4334          Set_Alignment (Typ, Alignment (Standard_Integer));
4335
4336       else
4337          --  If the enumeration type interfaces to C, and it has a size clause
4338          --  that specifies less than int size, it warrants a warning. The
4339          --  user may intend the C type to be an enum or a char, so this is
4340          --  not by itself an error that the Ada compiler can detect, but it
4341          --  it is a worth a heads-up. For Boolean and Character types we
4342          --  assume that the programmer has the proper C type in mind.
4343
4344          if Convention (Typ) = Convention_C
4345            and then Has_Size_Clause (Typ)
4346            and then Esize (Typ) /= Esize (Standard_Integer)
4347            and then not Is_Boolean_Type (Typ)
4348            and then not Is_Character_Type (Typ)
4349          then
4350             Error_Msg_N
4351               ("C enum types have the size of a C int?", Size_Clause (Typ));
4352          end if;
4353
4354          Adjust_Esize_For_Alignment (Typ);
4355       end if;
4356    end Freeze_Enumeration_Type;
4357
4358    -----------------------
4359    -- Freeze_Expression --
4360    -----------------------
4361
4362    procedure Freeze_Expression (N : Node_Id) is
4363       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4364       Typ         : Entity_Id;
4365       Nam         : Entity_Id;
4366       Desig_Typ   : Entity_Id;
4367       P           : Node_Id;
4368       Parent_P    : Node_Id;
4369
4370       Freeze_Outside : Boolean := False;
4371       --  This flag is set true if the entity must be frozen outside the
4372       --  current subprogram. This happens in the case of expander generated
4373       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4374       --  not freeze all entities like other bodies, but which nevertheless
4375       --  may reference entities that have to be frozen before the body and
4376       --  obviously cannot be frozen inside the body.
4377
4378       function In_Exp_Body (N : Node_Id) return Boolean;
4379       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4380       --  it is the handled statement sequence of an expander-generated
4381       --  subprogram (init proc, stream subprogram, or renaming as body).
4382       --  If so, this is not a freezing context.
4383
4384       -----------------
4385       -- In_Exp_Body --
4386       -----------------
4387
4388       function In_Exp_Body (N : Node_Id) return Boolean is
4389          P  : Node_Id;
4390          Id : Entity_Id;
4391
4392       begin
4393          if Nkind (N) = N_Subprogram_Body then
4394             P := N;
4395          else
4396             P := Parent (N);
4397          end if;
4398
4399          if Nkind (P) /= N_Subprogram_Body then
4400             return False;
4401
4402          else
4403             Id := Defining_Unit_Name (Specification (P));
4404
4405             if Nkind (Id) = N_Defining_Identifier
4406               and then (Is_Init_Proc (Id)              or else
4407                         Is_TSS (Id, TSS_Stream_Input)  or else
4408                         Is_TSS (Id, TSS_Stream_Output) or else
4409                         Is_TSS (Id, TSS_Stream_Read)   or else
4410                         Is_TSS (Id, TSS_Stream_Write)  or else
4411                         Nkind (Original_Node (P)) =
4412                           N_Subprogram_Renaming_Declaration)
4413             then
4414                return True;
4415             else
4416                return False;
4417             end if;
4418          end if;
4419       end In_Exp_Body;
4420
4421    --  Start of processing for Freeze_Expression
4422
4423    begin
4424       --  Immediate return if freezing is inhibited. This flag is set by the
4425       --  analyzer to stop freezing on generated expressions that would cause
4426       --  freezing if they were in the source program, but which are not
4427       --  supposed to freeze, since they are created.
4428
4429       if Must_Not_Freeze (N) then
4430          return;
4431       end if;
4432
4433       --  If expression is non-static, then it does not freeze in a default
4434       --  expression, see section "Handling of Default Expressions" in the
4435       --  spec of package Sem for further details. Note that we have to make
4436       --  sure that we actually have a real expression (if we have a subtype
4437       --  indication, we can't test Is_Static_Expression!) However, we exclude
4438       --  the case of the prefix of an attribute of a static scalar subtype
4439       --  from this early return, because static subtype attributes should
4440       --  always cause freezing, even in default expressions, but the attribute
4441       --  may not have been marked as static yet (because in Resolve_Attribute,
4442       --  the call to Eval_Attribute follows the call of Freeze_Expression on
4443       --  the prefix).
4444
4445       if In_Spec_Exp
4446         and then Nkind (N) in N_Subexpr
4447         and then not Is_Static_Expression (N)
4448         and then (Nkind (Parent (N)) /= N_Attribute_Reference
4449                    or else not (Is_Entity_Name (N)
4450                                  and then Is_Type (Entity (N))
4451                                  and then Is_Static_Subtype (Entity (N))))
4452       then
4453          return;
4454       end if;
4455
4456       --  Freeze type of expression if not frozen already
4457
4458       Typ := Empty;
4459
4460       if Nkind (N) in N_Has_Etype then
4461          if not Is_Frozen (Etype (N)) then
4462             Typ := Etype (N);
4463
4464          --  Base type may be an derived numeric type that is frozen at
4465          --  the point of declaration, but first_subtype is still unfrozen.
4466
4467          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4468             Typ := First_Subtype (Etype (N));
4469          end if;
4470       end if;
4471
4472       --  For entity name, freeze entity if not frozen already. A special
4473       --  exception occurs for an identifier that did not come from source.
4474       --  We don't let such identifiers freeze a non-internal entity, i.e.
4475       --  an entity that did come from source, since such an identifier was
4476       --  generated by the expander, and cannot have any semantic effect on
4477       --  the freezing semantics. For example, this stops the parameter of
4478       --  an initialization procedure from freezing the variable.
4479
4480       if Is_Entity_Name (N)
4481         and then not Is_Frozen (Entity (N))
4482         and then (Nkind (N) /= N_Identifier
4483                    or else Comes_From_Source (N)
4484                    or else not Comes_From_Source (Entity (N)))
4485       then
4486          Nam := Entity (N);
4487       else
4488          Nam := Empty;
4489       end if;
4490
4491       --  For an allocator freeze designated type if not frozen already
4492
4493       --  For an aggregate whose component type is an access type, freeze the
4494       --  designated type now, so that its freeze does not appear within the
4495       --  loop that might be created in the expansion of the aggregate. If the
4496       --  designated type is a private type without full view, the expression
4497       --  cannot contain an allocator, so the type is not frozen.
4498
4499       --  For a function, we freeze the entity when the subprogram declaration
4500       --  is frozen, but a function call may appear in an initialization proc.
4501       --  before the declaration is frozen. We need to generate the extra
4502       --  formals, if any, to ensure that the expansion of the call includes
4503       --  the proper actuals. This only applies to Ada subprograms, not to
4504       --  imported ones.
4505
4506       Desig_Typ := Empty;
4507
4508       case Nkind (N) is
4509          when N_Allocator =>
4510             Desig_Typ := Designated_Type (Etype (N));
4511
4512          when N_Aggregate =>
4513             if Is_Array_Type (Etype (N))
4514               and then Is_Access_Type (Component_Type (Etype (N)))
4515             then
4516                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4517             end if;
4518
4519          when N_Selected_Component |
4520             N_Indexed_Component    |
4521             N_Slice                =>
4522
4523             if Is_Access_Type (Etype (Prefix (N))) then
4524                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4525             end if;
4526
4527          when N_Identifier =>
4528             if Present (Nam)
4529               and then Ekind (Nam) = E_Function
4530               and then Nkind (Parent (N)) = N_Function_Call
4531               and then Convention (Nam) = Convention_Ada
4532             then
4533                Create_Extra_Formals (Nam);
4534             end if;
4535
4536          when others =>
4537             null;
4538       end case;
4539
4540       if Desig_Typ /= Empty
4541         and then (Is_Frozen (Desig_Typ)
4542                    or else (not Is_Fully_Defined (Desig_Typ)))
4543       then
4544          Desig_Typ := Empty;
4545       end if;
4546
4547       --  All done if nothing needs freezing
4548
4549       if No (Typ)
4550         and then No (Nam)
4551         and then No (Desig_Typ)
4552       then
4553          return;
4554       end if;
4555
4556       --  Loop for looking at the right place to insert the freeze nodes,
4557       --  exiting from the loop when it is appropriate to insert the freeze
4558       --  node before the current node P.
4559
4560       --  Also checks some special exceptions to the freezing rules. These
4561       --  cases result in a direct return, bypassing the freeze action.
4562
4563       P := N;
4564       loop
4565          Parent_P := Parent (P);
4566
4567          --  If we don't have a parent, then we are not in a well-formed tree.
4568          --  This is an unusual case, but there are some legitimate situations
4569          --  in which this occurs, notably when the expressions in the range of
4570          --  a type declaration are resolved. We simply ignore the freeze
4571          --  request in this case. Is this right ???
4572
4573          if No (Parent_P) then
4574             return;
4575          end if;
4576
4577          --  See if we have got to an appropriate point in the tree
4578
4579          case Nkind (Parent_P) is
4580
4581             --  A special test for the exception of (RM 13.14(8)) for the case
4582             --  of per-object expressions (RM 3.8(18)) occurring in component
4583             --  definition or a discrete subtype definition. Note that we test
4584             --  for a component declaration which includes both cases we are
4585             --  interested in, and furthermore the tree does not have explicit
4586             --  nodes for either of these two constructs.
4587
4588             when N_Component_Declaration =>
4589
4590                --  The case we want to test for here is an identifier that is
4591                --  a per-object expression, this is either a discriminant that
4592                --  appears in a context other than the component declaration
4593                --  or it is a reference to the type of the enclosing construct.
4594
4595                --  For either of these cases, we skip the freezing
4596
4597                if not In_Spec_Expression
4598                  and then Nkind (N) = N_Identifier
4599                  and then (Present (Entity (N)))
4600                then
4601                   --  We recognize the discriminant case by just looking for
4602                   --  a reference to a discriminant. It can only be one for
4603                   --  the enclosing construct. Skip freezing in this case.
4604
4605                   if Ekind (Entity (N)) = E_Discriminant then
4606                      return;
4607
4608                   --  For the case of a reference to the enclosing record,
4609                   --  (or task or protected type), we look for a type that
4610                   --  matches the current scope.
4611
4612                   elsif Entity (N) = Current_Scope then
4613                      return;
4614                   end if;
4615                end if;
4616
4617             --  If we have an enumeration literal that appears as the choice in
4618             --  the aggregate of an enumeration representation clause, then
4619             --  freezing does not occur (RM 13.14(10)).
4620
4621             when N_Enumeration_Representation_Clause =>
4622
4623                --  The case we are looking for is an enumeration literal
4624
4625                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4626                  and then Is_Enumeration_Type (Etype (N))
4627                then
4628                   --  If enumeration literal appears directly as the choice,
4629                   --  do not freeze (this is the normal non-overloaded case)
4630
4631                   if Nkind (Parent (N)) = N_Component_Association
4632                     and then First (Choices (Parent (N))) = N
4633                   then
4634                      return;
4635
4636                   --  If enumeration literal appears as the name of function
4637                   --  which is the choice, then also do not freeze. This
4638                   --  happens in the overloaded literal case, where the
4639                   --  enumeration literal is temporarily changed to a function
4640                   --  call for overloading analysis purposes.
4641
4642                   elsif Nkind (Parent (N)) = N_Function_Call
4643                      and then
4644                        Nkind (Parent (Parent (N))) = N_Component_Association
4645                      and then
4646                        First (Choices (Parent (Parent (N)))) = Parent (N)
4647                   then
4648                      return;
4649                   end if;
4650                end if;
4651
4652             --  Normally if the parent is a handled sequence of statements,
4653             --  then the current node must be a statement, and that is an
4654             --  appropriate place to insert a freeze node.
4655
4656             when N_Handled_Sequence_Of_Statements =>
4657
4658                --  An exception occurs when the sequence of statements is for
4659                --  an expander generated body that did not do the usual freeze
4660                --  all operation. In this case we usually want to freeze
4661                --  outside this body, not inside it, and we skip past the
4662                --  subprogram body that we are inside.
4663
4664                if In_Exp_Body (Parent_P) then
4665
4666                   --  However, we *do* want to freeze at this point if we have
4667                   --  an entity to freeze, and that entity is declared *inside*
4668                   --  the body of the expander generated procedure. This case
4669                   --  is recognized by the scope of the type, which is either
4670                   --  the spec for some enclosing body, or (in the case of
4671                   --  init_procs, for which there are no separate specs) the
4672                   --  current scope.
4673
4674                   declare
4675                      Subp : constant Node_Id := Parent (Parent_P);
4676                      Cspc : Entity_Id;
4677
4678                   begin
4679                      if Nkind (Subp) = N_Subprogram_Body then
4680                         Cspc := Corresponding_Spec (Subp);
4681
4682                         if (Present (Typ) and then Scope (Typ) = Cspc)
4683                              or else
4684                            (Present (Nam) and then Scope (Nam) = Cspc)
4685                         then
4686                            exit;
4687
4688                         elsif Present (Typ)
4689                           and then Scope (Typ) = Current_Scope
4690                           and then Current_Scope = Defining_Entity (Subp)
4691                         then
4692                            exit;
4693                         end if;
4694                      end if;
4695                   end;
4696
4697                   --  If not that exception to the exception, then this is
4698                   --  where we delay the freeze till outside the body.
4699
4700                   Parent_P := Parent (Parent_P);
4701                   Freeze_Outside := True;
4702
4703                --  Here if normal case where we are in handled statement
4704                --  sequence and want to do the insertion right there.
4705
4706                else
4707                   exit;
4708                end if;
4709
4710             --  If parent is a body or a spec or a block, then the current node
4711             --  is a statement or declaration and we can insert the freeze node
4712             --  before it.
4713
4714             when N_Block_Statement       |
4715                  N_Entry_Body            |
4716                  N_Package_Body          |
4717                  N_Package_Specification |
4718                  N_Protected_Body        |
4719                  N_Subprogram_Body       |
4720                  N_Task_Body             => exit;
4721
4722             --  The expander is allowed to define types in any statements list,
4723             --  so any of the following parent nodes also mark a freezing point
4724             --  if the actual node is in a list of statements or declarations.
4725
4726             when N_Abortable_Part             |
4727                  N_Accept_Alternative         |
4728                  N_And_Then                   |
4729                  N_Case_Statement_Alternative |
4730                  N_Compilation_Unit_Aux       |
4731                  N_Conditional_Entry_Call     |
4732                  N_Delay_Alternative          |
4733                  N_Elsif_Part                 |
4734                  N_Entry_Call_Alternative     |
4735                  N_Exception_Handler          |
4736                  N_Extended_Return_Statement  |
4737                  N_Freeze_Entity              |
4738                  N_If_Statement               |
4739                  N_Or_Else                    |
4740                  N_Selective_Accept           |
4741                  N_Triggering_Alternative     =>
4742
4743                exit when Is_List_Member (P);
4744
4745             --  Note: The N_Loop_Statement is a special case. A type that
4746             --  appears in the source can never be frozen in a loop (this
4747             --  occurs only because of a loop expanded by the expander), so we
4748             --  keep on going. Otherwise we terminate the search. Same is true
4749             --  of any entity which comes from source. (if they have predefined
4750             --  type, that type does not appear to come from source, but the
4751             --  entity should not be frozen here).
4752
4753             when N_Loop_Statement =>
4754                exit when not Comes_From_Source (Etype (N))
4755                  and then (No (Nam) or else not Comes_From_Source (Nam));
4756
4757             --  For all other cases, keep looking at parents
4758
4759             when others =>
4760                null;
4761          end case;
4762
4763          --  We fall through the case if we did not yet find the proper
4764          --  place in the free for inserting the freeze node, so climb!
4765
4766          P := Parent_P;
4767       end loop;
4768
4769       --  If the expression appears in a record or an initialization procedure,
4770       --  the freeze nodes are collected and attached to the current scope, to
4771       --  be inserted and analyzed on exit from the scope, to insure that
4772       --  generated entities appear in the correct scope. If the expression is
4773       --  a default for a discriminant specification, the scope is still void.
4774       --  The expression can also appear in the discriminant part of a private
4775       --  or concurrent type.
4776
4777       --  If the expression appears in a constrained subcomponent of an
4778       --  enclosing record declaration, the freeze nodes must be attached to
4779       --  the outer record type so they can eventually be placed in the
4780       --  enclosing declaration list.
4781
4782       --  The other case requiring this special handling is if we are in a
4783       --  default expression, since in that case we are about to freeze a
4784       --  static type, and the freeze scope needs to be the outer scope, not
4785       --  the scope of the subprogram with the default parameter.
4786
4787       --  For default expressions and other spec expressions in generic units,
4788       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4789       --  placing them at the proper place, after the generic unit.
4790
4791       if (In_Spec_Exp and not Inside_A_Generic)
4792         or else Freeze_Outside
4793         or else (Is_Type (Current_Scope)
4794                   and then (not Is_Concurrent_Type (Current_Scope)
4795                              or else not Has_Completion (Current_Scope)))
4796         or else Ekind (Current_Scope) = E_Void
4797       then
4798          declare
4799             N            : constant Node_Id    := Current_Scope;
4800             Freeze_Nodes : List_Id             := No_List;
4801             Pos          : Int                 := Scope_Stack.Last;
4802
4803          begin
4804             if Present (Desig_Typ) then
4805                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4806             end if;
4807
4808             if Present (Typ) then
4809                Freeze_And_Append (Typ, N, Freeze_Nodes);
4810             end if;
4811
4812             if Present (Nam) then
4813                Freeze_And_Append (Nam, N, Freeze_Nodes);
4814             end if;
4815
4816             --  The current scope may be that of a constrained component of
4817             --  an enclosing record declaration, which is above the current
4818             --  scope in the scope stack.
4819             --  If the expression is within a top-level pragma, as for a pre-
4820             --  condition on a library-level subprogram, nothing to do.
4821
4822             if not Is_Compilation_Unit (Current_Scope)
4823               and then Is_Record_Type (Scope (Current_Scope))
4824             then
4825                Pos := Pos - 1;
4826             end if;
4827
4828             if Is_Non_Empty_List (Freeze_Nodes) then
4829                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4830                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4831                     Freeze_Nodes;
4832                else
4833                   Append_List (Freeze_Nodes,
4834                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4835                end if;
4836             end if;
4837          end;
4838
4839          return;
4840       end if;
4841
4842       --  Now we have the right place to do the freezing. First, a special
4843       --  adjustment, if we are in spec-expression analysis mode, these freeze
4844       --  actions must not be thrown away (normally all inserted actions are
4845       --  thrown away in this mode. However, the freeze actions are from static
4846       --  expressions and one of the important reasons we are doing this
4847       --  special analysis is to get these freeze actions. Therefore we turn
4848       --  off the In_Spec_Expression mode to propagate these freeze actions.
4849       --  This also means they get properly analyzed and expanded.
4850
4851       In_Spec_Expression := False;
4852
4853       --  Freeze the designated type of an allocator (RM 13.14(13))
4854
4855       if Present (Desig_Typ) then
4856          Freeze_Before (P, Desig_Typ);
4857       end if;
4858
4859       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4860       --  the enumeration representation clause exception in the loop above.
4861
4862       if Present (Typ) then
4863          Freeze_Before (P, Typ);
4864       end if;
4865
4866       --  Freeze name if one is present (RM 13.14(11))
4867
4868       if Present (Nam) then
4869          Freeze_Before (P, Nam);
4870       end if;
4871
4872       --  Restore In_Spec_Expression flag
4873
4874       In_Spec_Expression := In_Spec_Exp;
4875    end Freeze_Expression;
4876
4877    -----------------------------
4878    -- Freeze_Fixed_Point_Type --
4879    -----------------------------
4880
4881    --  Certain fixed-point types and subtypes, including implicit base types
4882    --  and declared first subtypes, have not yet set up a range. This is
4883    --  because the range cannot be set until the Small and Size values are
4884    --  known, and these are not known till the type is frozen.
4885
4886    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4887    --  whose bounds are unanalyzed real literals. This routine will recognize
4888    --  this case, and transform this range node into a properly typed range
4889    --  with properly analyzed and resolved values.
4890
4891    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4892       Rng   : constant Node_Id    := Scalar_Range (Typ);
4893       Lo    : constant Node_Id    := Low_Bound (Rng);
4894       Hi    : constant Node_Id    := High_Bound (Rng);
4895       Btyp  : constant Entity_Id  := Base_Type (Typ);
4896       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4897       BLo   : constant Node_Id    := Low_Bound (Brng);
4898       BHi   : constant Node_Id    := High_Bound (Brng);
4899       Small : constant Ureal      := Small_Value (Typ);
4900       Loval : Ureal;
4901       Hival : Ureal;
4902       Atype : Entity_Id;
4903
4904       Actual_Size : Nat;
4905
4906       function Fsize (Lov, Hiv : Ureal) return Nat;
4907       --  Returns size of type with given bounds. Also leaves these
4908       --  bounds set as the current bounds of the Typ.
4909
4910       -----------
4911       -- Fsize --
4912       -----------
4913
4914       function Fsize (Lov, Hiv : Ureal) return Nat is
4915       begin
4916          Set_Realval (Lo, Lov);
4917          Set_Realval (Hi, Hiv);
4918          return Minimum_Size (Typ);
4919       end Fsize;
4920
4921    --  Start of processing for Freeze_Fixed_Point_Type
4922
4923    begin
4924       --  If Esize of a subtype has not previously been set, set it now
4925
4926       if Unknown_Esize (Typ) then
4927          Atype := Ancestor_Subtype (Typ);
4928
4929          if Present (Atype) then
4930             Set_Esize (Typ, Esize (Atype));
4931          else
4932             Set_Esize (Typ, Esize (Base_Type (Typ)));
4933          end if;
4934       end if;
4935
4936       --  Immediate return if the range is already analyzed. This means that
4937       --  the range is already set, and does not need to be computed by this
4938       --  routine.
4939
4940       if Analyzed (Rng) then
4941          return;
4942       end if;
4943
4944       --  Immediate return if either of the bounds raises Constraint_Error
4945
4946       if Raises_Constraint_Error (Lo)
4947         or else Raises_Constraint_Error (Hi)
4948       then
4949          return;
4950       end if;
4951
4952       Loval := Realval (Lo);
4953       Hival := Realval (Hi);
4954
4955       --  Ordinary fixed-point case
4956
4957       if Is_Ordinary_Fixed_Point_Type (Typ) then
4958
4959          --  For the ordinary fixed-point case, we are allowed to fudge the
4960          --  end-points up or down by small. Generally we prefer to fudge up,
4961          --  i.e. widen the bounds for non-model numbers so that the end points
4962          --  are included. However there are cases in which this cannot be
4963          --  done, and indeed cases in which we may need to narrow the bounds.
4964          --  The following circuit makes the decision.
4965
4966          --  Note: our terminology here is that Incl_EP means that the bounds
4967          --  are widened by Small if necessary to include the end points, and
4968          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4969          --  end-points if this reduces the size.
4970
4971          --  Note that in the Incl case, all we care about is including the
4972          --  end-points. In the Excl case, we want to narrow the bounds as
4973          --  much as permitted by the RM, to give the smallest possible size.
4974
4975          Fudge : declare
4976             Loval_Incl_EP : Ureal;
4977             Hival_Incl_EP : Ureal;
4978
4979             Loval_Excl_EP : Ureal;
4980             Hival_Excl_EP : Ureal;
4981
4982             Size_Incl_EP  : Nat;
4983             Size_Excl_EP  : Nat;
4984
4985             Model_Num     : Ureal;
4986             First_Subt    : Entity_Id;
4987             Actual_Lo     : Ureal;
4988             Actual_Hi     : Ureal;
4989
4990          begin
4991             --  First step. Base types are required to be symmetrical. Right
4992             --  now, the base type range is a copy of the first subtype range.
4993             --  This will be corrected before we are done, but right away we
4994             --  need to deal with the case where both bounds are non-negative.
4995             --  In this case, we set the low bound to the negative of the high
4996             --  bound, to make sure that the size is computed to include the
4997             --  required sign. Note that we do not need to worry about the
4998             --  case of both bounds negative, because the sign will be dealt
4999             --  with anyway. Furthermore we can't just go making such a bound
5000             --  symmetrical, since in a twos-complement system, there is an
5001             --  extra negative value which could not be accommodated on the
5002             --  positive side.
5003
5004             if Typ = Btyp
5005               and then not UR_Is_Negative (Loval)
5006               and then Hival > Loval
5007             then
5008                Loval := -Hival;
5009                Set_Realval (Lo, Loval);
5010             end if;
5011
5012             --  Compute the fudged bounds. If the number is a model number,
5013             --  then we do nothing to include it, but we are allowed to backoff
5014             --  to the next adjacent model number when we exclude it. If it is
5015             --  not a model number then we straddle the two values with the
5016             --  model numbers on either side.
5017
5018             Model_Num := UR_Trunc (Loval / Small) * Small;
5019
5020             if Loval = Model_Num then
5021                Loval_Incl_EP := Model_Num;
5022             else
5023                Loval_Incl_EP := Model_Num - Small;
5024             end if;
5025
5026             --  The low value excluding the end point is Small greater, but
5027             --  we do not do this exclusion if the low value is positive,
5028             --  since it can't help the size and could actually hurt by
5029             --  crossing the high bound.
5030
5031             if UR_Is_Negative (Loval_Incl_EP) then
5032                Loval_Excl_EP := Loval_Incl_EP + Small;
5033
5034                --  If the value went from negative to zero, then we have the
5035                --  case where Loval_Incl_EP is the model number just below
5036                --  zero, so we want to stick to the negative value for the
5037                --  base type to maintain the condition that the size will
5038                --  include signed values.
5039
5040                if Typ = Btyp
5041                  and then UR_Is_Zero (Loval_Excl_EP)
5042                then
5043                   Loval_Excl_EP := Loval_Incl_EP;
5044                end if;
5045
5046             else
5047                Loval_Excl_EP := Loval_Incl_EP;
5048             end if;
5049
5050             --  Similar processing for upper bound and high value
5051
5052             Model_Num := UR_Trunc (Hival / Small) * Small;
5053
5054             if Hival = Model_Num then
5055                Hival_Incl_EP := Model_Num;
5056             else
5057                Hival_Incl_EP := Model_Num + Small;
5058             end if;
5059
5060             if UR_Is_Positive (Hival_Incl_EP) then
5061                Hival_Excl_EP := Hival_Incl_EP - Small;
5062             else
5063                Hival_Excl_EP := Hival_Incl_EP;
5064             end if;
5065
5066             --  One further adjustment is needed. In the case of subtypes, we
5067             --  cannot go outside the range of the base type, or we get
5068             --  peculiarities, and the base type range is already set. This
5069             --  only applies to the Incl values, since clearly the Excl values
5070             --  are already as restricted as they are allowed to be.
5071
5072             if Typ /= Btyp then
5073                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
5074                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
5075             end if;
5076
5077             --  Get size including and excluding end points
5078
5079             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
5080             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
5081
5082             --  No need to exclude end-points if it does not reduce size
5083
5084             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
5085                Loval_Excl_EP := Loval_Incl_EP;
5086             end if;
5087
5088             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
5089                Hival_Excl_EP := Hival_Incl_EP;
5090             end if;
5091
5092             --  Now we set the actual size to be used. We want to use the
5093             --  bounds fudged up to include the end-points but only if this
5094             --  can be done without violating a specifically given size
5095             --  size clause or causing an unacceptable increase in size.
5096
5097             --  Case of size clause given
5098
5099             if Has_Size_Clause (Typ) then
5100
5101                --  Use the inclusive size only if it is consistent with
5102                --  the explicitly specified size.
5103
5104                if Size_Incl_EP <= RM_Size (Typ) then
5105                   Actual_Lo   := Loval_Incl_EP;
5106                   Actual_Hi   := Hival_Incl_EP;
5107                   Actual_Size := Size_Incl_EP;
5108
5109                --  If the inclusive size is too large, we try excluding
5110                --  the end-points (will be caught later if does not work).
5111
5112                else
5113                   Actual_Lo   := Loval_Excl_EP;
5114                   Actual_Hi   := Hival_Excl_EP;
5115                   Actual_Size := Size_Excl_EP;
5116                end if;
5117
5118             --  Case of size clause not given
5119
5120             else
5121                --  If we have a base type whose corresponding first subtype
5122                --  has an explicit size that is large enough to include our
5123                --  end-points, then do so. There is no point in working hard
5124                --  to get a base type whose size is smaller than the specified
5125                --  size of the first subtype.
5126
5127                First_Subt := First_Subtype (Typ);
5128
5129                if Has_Size_Clause (First_Subt)
5130                  and then Size_Incl_EP <= Esize (First_Subt)
5131                then
5132                   Actual_Size := Size_Incl_EP;
5133                   Actual_Lo   := Loval_Incl_EP;
5134                   Actual_Hi   := Hival_Incl_EP;
5135
5136                --  If excluding the end-points makes the size smaller and
5137                --  results in a size of 8,16,32,64, then we take the smaller
5138                --  size. For the 64 case, this is compulsory. For the other
5139                --  cases, it seems reasonable. We like to include end points
5140                --  if we can, but not at the expense of moving to the next
5141                --  natural boundary of size.
5142
5143                elsif Size_Incl_EP /= Size_Excl_EP
5144                  and then Addressable (Size_Excl_EP)
5145                then
5146                   Actual_Size := Size_Excl_EP;
5147                   Actual_Lo   := Loval_Excl_EP;
5148                   Actual_Hi   := Hival_Excl_EP;
5149
5150                --  Otherwise we can definitely include the end points
5151
5152                else
5153                   Actual_Size := Size_Incl_EP;
5154                   Actual_Lo   := Loval_Incl_EP;
5155                   Actual_Hi   := Hival_Incl_EP;
5156                end if;
5157
5158                --  One pathological case: normally we never fudge a low bound
5159                --  down, since it would seem to increase the size (if it has
5160                --  any effect), but for ranges containing single value, or no
5161                --  values, the high bound can be small too large. Consider:
5162
5163                --    type t is delta 2.0**(-14)
5164                --      range 131072.0 .. 0;
5165
5166                --  That lower bound is *just* outside the range of 32 bits, and
5167                --  does need fudging down in this case. Note that the bounds
5168                --  will always have crossed here, since the high bound will be
5169                --  fudged down if necessary, as in the case of:
5170
5171                --    type t is delta 2.0**(-14)
5172                --      range 131072.0 .. 131072.0;
5173
5174                --  So we detect the situation by looking for crossed bounds,
5175                --  and if the bounds are crossed, and the low bound is greater
5176                --  than zero, we will always back it off by small, since this
5177                --  is completely harmless.
5178
5179                if Actual_Lo > Actual_Hi then
5180                   if UR_Is_Positive (Actual_Lo) then
5181                      Actual_Lo   := Loval_Incl_EP - Small;
5182                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5183
5184                   --  And of course, we need to do exactly the same parallel
5185                   --  fudge for flat ranges in the negative region.
5186
5187                   elsif UR_Is_Negative (Actual_Hi) then
5188                      Actual_Hi := Hival_Incl_EP + Small;
5189                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5190                   end if;
5191                end if;
5192             end if;
5193
5194             Set_Realval (Lo, Actual_Lo);
5195             Set_Realval (Hi, Actual_Hi);
5196          end Fudge;
5197
5198       --  For the decimal case, none of this fudging is required, since there
5199       --  are no end-point problems in the decimal case (the end-points are
5200       --  always included).
5201
5202       else
5203          Actual_Size := Fsize (Loval, Hival);
5204       end if;
5205
5206       --  At this stage, the actual size has been calculated and the proper
5207       --  required bounds are stored in the low and high bounds.
5208
5209       if Actual_Size > 64 then
5210          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5211          Error_Msg_N
5212            ("size required (^) for type& too large, maximum allowed is 64",
5213             Typ);
5214          Actual_Size := 64;
5215       end if;
5216
5217       --  Check size against explicit given size
5218
5219       if Has_Size_Clause (Typ) then
5220          if Actual_Size > RM_Size (Typ) then
5221             Error_Msg_Uint_1 := RM_Size (Typ);
5222             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5223             Error_Msg_NE
5224               ("size given (^) for type& too small, minimum allowed is ^",
5225                Size_Clause (Typ), Typ);
5226
5227          else
5228             Actual_Size := UI_To_Int (Esize (Typ));
5229          end if;
5230
5231       --  Increase size to next natural boundary if no size clause given
5232
5233       else
5234          if Actual_Size <= 8 then
5235             Actual_Size := 8;
5236          elsif Actual_Size <= 16 then
5237             Actual_Size := 16;
5238          elsif Actual_Size <= 32 then
5239             Actual_Size := 32;
5240          else
5241             Actual_Size := 64;
5242          end if;
5243
5244          Init_Esize (Typ, Actual_Size);
5245          Adjust_Esize_For_Alignment (Typ);
5246       end if;
5247
5248       --  If we have a base type, then expand the bounds so that they extend to
5249       --  the full width of the allocated size in bits, to avoid junk range
5250       --  checks on intermediate computations.
5251
5252       if Base_Type (Typ) = Typ then
5253          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5254          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5255       end if;
5256
5257       --  Final step is to reanalyze the bounds using the proper type
5258       --  and set the Corresponding_Integer_Value fields of the literals.
5259
5260       Set_Etype (Lo, Empty);
5261       Set_Analyzed (Lo, False);
5262       Analyze (Lo);
5263
5264       --  Resolve with universal fixed if the base type, and the base type if
5265       --  it is a subtype. Note we can't resolve the base type with itself,
5266       --  that would be a reference before definition.
5267
5268       if Typ = Btyp then
5269          Resolve (Lo, Universal_Fixed);
5270       else
5271          Resolve (Lo, Btyp);
5272       end if;
5273
5274       --  Set corresponding integer value for bound
5275
5276       Set_Corresponding_Integer_Value
5277         (Lo, UR_To_Uint (Realval (Lo) / Small));
5278
5279       --  Similar processing for high bound
5280
5281       Set_Etype (Hi, Empty);
5282       Set_Analyzed (Hi, False);
5283       Analyze (Hi);
5284
5285       if Typ = Btyp then
5286          Resolve (Hi, Universal_Fixed);
5287       else
5288          Resolve (Hi, Btyp);
5289       end if;
5290
5291       Set_Corresponding_Integer_Value
5292         (Hi, UR_To_Uint (Realval (Hi) / Small));
5293
5294       --  Set type of range to correspond to bounds
5295
5296       Set_Etype (Rng, Etype (Lo));
5297
5298       --  Set Esize to calculated size if not set already
5299
5300       if Unknown_Esize (Typ) then
5301          Init_Esize (Typ, Actual_Size);
5302       end if;
5303
5304       --  Set RM_Size if not already set. If already set, check value
5305
5306       declare
5307          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5308
5309       begin
5310          if RM_Size (Typ) /= Uint_0 then
5311             if RM_Size (Typ) < Minsiz then
5312                Error_Msg_Uint_1 := RM_Size (Typ);
5313                Error_Msg_Uint_2 := Minsiz;
5314                Error_Msg_NE
5315                  ("size given (^) for type& too small, minimum allowed is ^",
5316                   Size_Clause (Typ), Typ);
5317             end if;
5318
5319          else
5320             Set_RM_Size (Typ, Minsiz);
5321          end if;
5322       end;
5323    end Freeze_Fixed_Point_Type;
5324
5325    ------------------
5326    -- Freeze_Itype --
5327    ------------------
5328
5329    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5330       L : List_Id;
5331
5332    begin
5333       Set_Has_Delayed_Freeze (T);
5334       L := Freeze_Entity (T, N);
5335
5336       if Is_Non_Empty_List (L) then
5337          Insert_Actions (N, L);
5338       end if;
5339    end Freeze_Itype;
5340
5341    --------------------------
5342    -- Freeze_Static_Object --
5343    --------------------------
5344
5345    procedure Freeze_Static_Object (E : Entity_Id) is
5346
5347       Cannot_Be_Static : exception;
5348       --  Exception raised if the type of a static object cannot be made
5349       --  static. This happens if the type depends on non-global objects.
5350
5351       procedure Ensure_Expression_Is_SA (N : Node_Id);
5352       --  Called to ensure that an expression used as part of a type definition
5353       --  is statically allocatable, which means that the expression type is
5354       --  statically allocatable, and the expression is either static, or a
5355       --  reference to a library level constant.
5356
5357       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5358       --  Called to mark a type as static, checking that it is possible
5359       --  to set the type as static. If it is not possible, then the
5360       --  exception Cannot_Be_Static is raised.
5361
5362       -----------------------------
5363       -- Ensure_Expression_Is_SA --
5364       -----------------------------
5365
5366       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5367          Ent : Entity_Id;
5368
5369       begin
5370          Ensure_Type_Is_SA (Etype (N));
5371
5372          if Is_Static_Expression (N) then
5373             return;
5374
5375          elsif Nkind (N) = N_Identifier then
5376             Ent := Entity (N);
5377
5378             if Present (Ent)
5379               and then Ekind (Ent) = E_Constant
5380               and then Is_Library_Level_Entity (Ent)
5381             then
5382                return;
5383             end if;
5384          end if;
5385
5386          raise Cannot_Be_Static;
5387       end Ensure_Expression_Is_SA;
5388
5389       -----------------------
5390       -- Ensure_Type_Is_SA --
5391       -----------------------
5392
5393       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5394          N : Node_Id;
5395          C : Entity_Id;
5396
5397       begin
5398          --  If type is library level, we are all set
5399
5400          if Is_Library_Level_Entity (Typ) then
5401             return;
5402          end if;
5403
5404          --  We are also OK if the type already marked as statically allocated,
5405          --  which means we processed it before.
5406
5407          if Is_Statically_Allocated (Typ) then
5408             return;
5409          end if;
5410
5411          --  Mark type as statically allocated
5412
5413          Set_Is_Statically_Allocated (Typ);
5414
5415          --  Check that it is safe to statically allocate this type
5416
5417          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5418             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5419             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5420
5421          elsif Is_Array_Type (Typ) then
5422             N := First_Index (Typ);
5423             while Present (N) loop
5424                Ensure_Type_Is_SA (Etype (N));
5425                Next_Index (N);
5426             end loop;
5427
5428             Ensure_Type_Is_SA (Component_Type (Typ));
5429
5430          elsif Is_Access_Type (Typ) then
5431             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5432
5433                declare
5434                   F : Entity_Id;
5435                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5436
5437                begin
5438                   if T /= Standard_Void_Type then
5439                      Ensure_Type_Is_SA (T);
5440                   end if;
5441
5442                   F := First_Formal (Designated_Type (Typ));
5443                   while Present (F) loop
5444                      Ensure_Type_Is_SA (Etype (F));
5445                      Next_Formal (F);
5446                   end loop;
5447                end;
5448
5449             else
5450                Ensure_Type_Is_SA (Designated_Type (Typ));
5451             end if;
5452
5453          elsif Is_Record_Type (Typ) then
5454             C := First_Entity (Typ);
5455             while Present (C) loop
5456                if Ekind (C) = E_Discriminant
5457                  or else Ekind (C) = E_Component
5458                then
5459                   Ensure_Type_Is_SA (Etype (C));
5460
5461                elsif Is_Type (C) then
5462                   Ensure_Type_Is_SA (C);
5463                end if;
5464
5465                Next_Entity (C);
5466             end loop;
5467
5468          elsif Ekind (Typ) = E_Subprogram_Type then
5469             Ensure_Type_Is_SA (Etype (Typ));
5470
5471             C := First_Formal (Typ);
5472             while Present (C) loop
5473                Ensure_Type_Is_SA (Etype (C));
5474                Next_Formal (C);
5475             end loop;
5476
5477          else
5478             raise Cannot_Be_Static;
5479          end if;
5480       end Ensure_Type_Is_SA;
5481
5482    --  Start of processing for Freeze_Static_Object
5483
5484    begin
5485       Ensure_Type_Is_SA (Etype (E));
5486
5487    exception
5488       when Cannot_Be_Static =>
5489
5490          --  If the object that cannot be static is imported or exported, then
5491          --  issue an error message saying that this object cannot be imported
5492          --  or exported. If it has an address clause it is an overlay in the
5493          --  current partition and the static requirement is not relevant.
5494          --  Do not issue any error message when ignoring rep clauses.
5495
5496          if Ignore_Rep_Clauses then
5497             null;
5498
5499          elsif Is_Imported (E) then
5500             if No (Address_Clause (E)) then
5501                Error_Msg_N
5502                  ("& cannot be imported (local type is not constant)", E);
5503             end if;
5504
5505          --  Otherwise must be exported, something is wrong if compiler
5506          --  is marking something as statically allocated which cannot be).
5507
5508          else pragma Assert (Is_Exported (E));
5509             Error_Msg_N
5510               ("& cannot be exported (local type is not constant)", E);
5511          end if;
5512    end Freeze_Static_Object;
5513
5514    -----------------------
5515    -- Freeze_Subprogram --
5516    -----------------------
5517
5518    procedure Freeze_Subprogram (E : Entity_Id) is
5519       Retype : Entity_Id;
5520       F      : Entity_Id;
5521
5522    begin
5523       --  Subprogram may not have an address clause unless it is imported
5524
5525       if Present (Address_Clause (E)) then
5526          if not Is_Imported (E) then
5527             Error_Msg_N
5528               ("address clause can only be given " &
5529                "for imported subprogram",
5530                Name (Address_Clause (E)));
5531          end if;
5532       end if;
5533
5534       --  Reset the Pure indication on an imported subprogram unless an
5535       --  explicit Pure_Function pragma was present. We do this because
5536       --  otherwise it is an insidious error to call a non-pure function from
5537       --  pure unit and have calls mysteriously optimized away. What happens
5538       --  here is that the Import can bypass the normal check to ensure that
5539       --  pure units call only pure subprograms.
5540
5541       if Is_Imported (E)
5542         and then Is_Pure (E)
5543         and then not Has_Pragma_Pure_Function (E)
5544       then
5545          Set_Is_Pure (E, False);
5546       end if;
5547
5548       --  For non-foreign convention subprograms, this is where we create
5549       --  the extra formals (for accessibility level and constrained bit
5550       --  information). We delay this till the freeze point precisely so
5551       --  that we know the convention!
5552
5553       if not Has_Foreign_Convention (E) then
5554          Create_Extra_Formals (E);
5555          Set_Mechanisms (E);
5556
5557          --  If this is convention Ada and a Valued_Procedure, that's odd
5558
5559          if Ekind (E) = E_Procedure
5560            and then Is_Valued_Procedure (E)
5561            and then Convention (E) = Convention_Ada
5562            and then Warn_On_Export_Import
5563          then
5564             Error_Msg_N
5565               ("?Valued_Procedure has no effect for convention Ada", E);
5566             Set_Is_Valued_Procedure (E, False);
5567          end if;
5568
5569       --  Case of foreign convention
5570
5571       else
5572          Set_Mechanisms (E);
5573
5574          --  For foreign conventions, warn about return of an
5575          --  unconstrained array.
5576
5577          --  Note: we *do* allow a return by descriptor for the VMS case,
5578          --  though here there is probably more to be done ???
5579
5580          if Ekind (E) = E_Function then
5581             Retype := Underlying_Type (Etype (E));
5582
5583             --  If no return type, probably some other error, e.g. a
5584             --  missing full declaration, so ignore.
5585
5586             if No (Retype) then
5587                null;
5588
5589             --  If the return type is generic, we have emitted a warning
5590             --  earlier on, and there is nothing else to check here. Specific
5591             --  instantiations may lead to erroneous behavior.
5592
5593             elsif Is_Generic_Type (Etype (E)) then
5594                null;
5595
5596             --  Display warning if returning unconstrained array
5597
5598             elsif Is_Array_Type (Retype)
5599               and then not Is_Constrained (Retype)
5600
5601               --  Exclude cases where descriptor mechanism is set, since the
5602               --  VMS descriptor mechanisms allow such unconstrained returns.
5603
5604               and then Mechanism (E) not in Descriptor_Codes
5605
5606                --  Check appropriate warning is enabled (should we check for
5607                --  Warnings (Off) on specific entities here, probably so???)
5608
5609               and then Warn_On_Export_Import
5610
5611               --  Exclude the VM case, since return of unconstrained arrays
5612               --  is properly handled in both the JVM and .NET cases.
5613
5614               and then VM_Target = No_VM
5615             then
5616                Error_Msg_N
5617                 ("?foreign convention function& should not return " &
5618                   "unconstrained array", E);
5619                return;
5620             end if;
5621          end if;
5622
5623          --  If any of the formals for an exported foreign convention
5624          --  subprogram have defaults, then emit an appropriate warning since
5625          --  this is odd (default cannot be used from non-Ada code)
5626
5627          if Is_Exported (E) then
5628             F := First_Formal (E);
5629             while Present (F) loop
5630                if Warn_On_Export_Import
5631                  and then Present (Default_Value (F))
5632                then
5633                   Error_Msg_N
5634                     ("?parameter cannot be defaulted in non-Ada call",
5635                      Default_Value (F));
5636                end if;
5637
5638                Next_Formal (F);
5639             end loop;
5640          end if;
5641       end if;
5642
5643       --  For VMS, descriptor mechanisms for parameters are allowed only for
5644       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5645       --  allowed for parameters of exported subprograms.
5646
5647       if OpenVMS_On_Target then
5648          if Is_Exported (E) then
5649             F := First_Formal (E);
5650             while Present (F) loop
5651                if Mechanism (F) = By_Descriptor_NCA then
5652                   Error_Msg_N
5653                     ("'N'C'A' descriptor for parameter not permitted", F);
5654                   Error_Msg_N
5655                     ("\can only be used for imported subprogram", F);
5656                end if;
5657
5658                Next_Formal (F);
5659             end loop;
5660
5661          elsif not Is_Imported (E) then
5662             F := First_Formal (E);
5663             while Present (F) loop
5664                if Mechanism (F) in Descriptor_Codes then
5665                   Error_Msg_N
5666                     ("descriptor mechanism for parameter not permitted", F);
5667                   Error_Msg_N
5668                     ("\can only be used for imported/exported subprogram", F);
5669                end if;
5670
5671                Next_Formal (F);
5672             end loop;
5673          end if;
5674       end if;
5675
5676       --  Pragma Inline_Always is disallowed for dispatching subprograms
5677       --  because the address of such subprograms is saved in the dispatch
5678       --  table to support dispatching calls, and dispatching calls cannot
5679       --  be inlined. This is consistent with the restriction against using
5680       --  'Access or 'Address on an Inline_Always subprogram.
5681
5682       if Is_Dispatching_Operation (E)
5683         and then Has_Pragma_Inline_Always (E)
5684       then
5685          Error_Msg_N
5686            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5687       end if;
5688
5689       --  Because of the implicit representation of inherited predefined
5690       --  operators in the front-end, the overriding status of the operation
5691       --  may be affected when a full view of a type is analyzed, and this is
5692       --  not captured by the analysis of the corresponding type declaration.
5693       --  Therefore the correctness of a not-overriding indicator must be
5694       --  rechecked when the subprogram is frozen.
5695
5696       if Nkind (E) = N_Defining_Operator_Symbol
5697         and then not Error_Posted (Parent (E))
5698       then
5699          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5700       end if;
5701    end Freeze_Subprogram;
5702
5703    ----------------------
5704    -- Is_Fully_Defined --
5705    ----------------------
5706
5707    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5708    begin
5709       if Ekind (T) = E_Class_Wide_Type then
5710          return Is_Fully_Defined (Etype (T));
5711
5712       elsif Is_Array_Type (T) then
5713          return Is_Fully_Defined (Component_Type (T));
5714
5715       elsif Is_Record_Type (T)
5716         and not Is_Private_Type (T)
5717       then
5718          --  Verify that the record type has no components with private types
5719          --  without completion.
5720
5721          declare
5722             Comp : Entity_Id;
5723
5724          begin
5725             Comp := First_Component (T);
5726             while Present (Comp) loop
5727                if not Is_Fully_Defined (Etype (Comp)) then
5728                   return False;
5729                end if;
5730
5731                Next_Component (Comp);
5732             end loop;
5733             return True;
5734          end;
5735
5736       --  For the designated type of an access to subprogram, all types in
5737       --  the profile must be fully defined.
5738
5739       elsif Ekind (T) = E_Subprogram_Type then
5740          declare
5741             F : Entity_Id;
5742
5743          begin
5744             F := First_Formal (T);
5745             while Present (F) loop
5746                if not Is_Fully_Defined (Etype (F)) then
5747                   return False;
5748                end if;
5749
5750                Next_Formal (F);
5751             end loop;
5752
5753             return Is_Fully_Defined (Etype (T));
5754          end;
5755
5756       else
5757          return not Is_Private_Type (T)
5758            or else Present (Full_View (Base_Type (T)));
5759       end if;
5760    end Is_Fully_Defined;
5761
5762    ---------------------------------
5763    -- Process_Default_Expressions --
5764    ---------------------------------
5765
5766    procedure Process_Default_Expressions
5767      (E     : Entity_Id;
5768       After : in out Node_Id)
5769    is
5770       Loc    : constant Source_Ptr := Sloc (E);
5771       Dbody  : Node_Id;
5772       Formal : Node_Id;
5773       Dcopy  : Node_Id;
5774       Dnam   : Entity_Id;
5775
5776    begin
5777       Set_Default_Expressions_Processed (E);
5778
5779       --  A subprogram instance and its associated anonymous subprogram share
5780       --  their signature. The default expression functions are defined in the
5781       --  wrapper packages for the anonymous subprogram, and should not be
5782       --  generated again for the instance.
5783
5784       if Is_Generic_Instance (E)
5785         and then Present (Alias (E))
5786         and then Default_Expressions_Processed (Alias (E))
5787       then
5788          return;
5789       end if;
5790
5791       Formal := First_Formal (E);
5792       while Present (Formal) loop
5793          if Present (Default_Value (Formal)) then
5794
5795             --  We work with a copy of the default expression because we
5796             --  do not want to disturb the original, since this would mess
5797             --  up the conformance checking.
5798
5799             Dcopy := New_Copy_Tree (Default_Value (Formal));
5800
5801             --  The analysis of the expression may generate insert actions,
5802             --  which of course must not be executed. We wrap those actions
5803             --  in a procedure that is not called, and later on eliminated.
5804             --  The following cases have no side-effects, and are analyzed
5805             --  directly.
5806
5807             if Nkind (Dcopy) = N_Identifier
5808               or else Nkind (Dcopy) = N_Expanded_Name
5809               or else Nkind (Dcopy) = N_Integer_Literal
5810               or else (Nkind (Dcopy) = N_Real_Literal
5811                         and then not Vax_Float (Etype (Dcopy)))
5812               or else Nkind (Dcopy) = N_Character_Literal
5813               or else Nkind (Dcopy) = N_String_Literal
5814               or else Known_Null (Dcopy)
5815               or else (Nkind (Dcopy) = N_Attribute_Reference
5816                         and then
5817                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5818             then
5819
5820                --  If there is no default function, we must still do a full
5821                --  analyze call on the default value, to ensure that all error
5822                --  checks are performed, e.g. those associated with static
5823                --  evaluation. Note: this branch will always be taken if the
5824                --  analyzer is turned off (but we still need the error checks).
5825
5826                --  Note: the setting of parent here is to meet the requirement
5827                --  that we can only analyze the expression while attached to
5828                --  the tree. Really the requirement is that the parent chain
5829                --  be set, we don't actually need to be in the tree.
5830
5831                Set_Parent (Dcopy, Declaration_Node (Formal));
5832                Analyze (Dcopy);
5833
5834                --  Default expressions are resolved with their own type if the
5835                --  context is generic, to avoid anomalies with private types.
5836
5837                if Ekind (Scope (E)) = E_Generic_Package then
5838                   Resolve (Dcopy);
5839                else
5840                   Resolve (Dcopy, Etype (Formal));
5841                end if;
5842
5843                --  If that resolved expression will raise constraint error,
5844                --  then flag the default value as raising constraint error.
5845                --  This allows a proper error message on the calls.
5846
5847                if Raises_Constraint_Error (Dcopy) then
5848                   Set_Raises_Constraint_Error (Default_Value (Formal));
5849                end if;
5850
5851             --  If the default is a parameterless call, we use the name of
5852             --  the called function directly, and there is no body to build.
5853
5854             elsif Nkind (Dcopy) = N_Function_Call
5855               and then No (Parameter_Associations (Dcopy))
5856             then
5857                null;
5858
5859             --  Else construct and analyze the body of a wrapper procedure
5860             --  that contains an object declaration to hold the expression.
5861             --  Given that this is done only to complete the analysis, it
5862             --  simpler to build a procedure than a function which might
5863             --  involve secondary stack expansion.
5864
5865             else
5866                Dnam := Make_Temporary (Loc, 'D');
5867
5868                Dbody :=
5869                  Make_Subprogram_Body (Loc,
5870                    Specification =>
5871                      Make_Procedure_Specification (Loc,
5872                        Defining_Unit_Name => Dnam),
5873
5874                    Declarations => New_List (
5875                      Make_Object_Declaration (Loc,
5876                        Defining_Identifier => Make_Temporary (Loc, 'T'),
5877                        Object_Definition   =>
5878                          New_Occurrence_Of (Etype (Formal), Loc),
5879                        Expression          => New_Copy_Tree (Dcopy))),
5880
5881                    Handled_Statement_Sequence =>
5882                      Make_Handled_Sequence_Of_Statements (Loc,
5883                        Statements => Empty_List));
5884
5885                Set_Scope (Dnam, Scope (E));
5886                Set_Assignment_OK (First (Declarations (Dbody)));
5887                Set_Is_Eliminated (Dnam);
5888                Insert_After (After, Dbody);
5889                Analyze (Dbody);
5890                After := Dbody;
5891             end if;
5892          end if;
5893
5894          Next_Formal (Formal);
5895       end loop;
5896    end Process_Default_Expressions;
5897
5898    ----------------------------------------
5899    -- Set_Component_Alignment_If_Not_Set --
5900    ----------------------------------------
5901
5902    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5903    begin
5904       --  Ignore if not base type, subtypes don't need anything
5905
5906       if Typ /= Base_Type (Typ) then
5907          return;
5908       end if;
5909
5910       --  Do not override existing representation
5911
5912       if Is_Packed (Typ) then
5913          return;
5914
5915       elsif Has_Specified_Layout (Typ) then
5916          return;
5917
5918       elsif Component_Alignment (Typ) /= Calign_Default then
5919          return;
5920
5921       else
5922          Set_Component_Alignment
5923            (Typ, Scope_Stack.Table
5924                   (Scope_Stack.Last).Component_Alignment_Default);
5925       end if;
5926    end Set_Component_Alignment_If_Not_Set;
5927
5928    ------------------
5929    -- Undelay_Type --
5930    ------------------
5931
5932    procedure Undelay_Type (T : Entity_Id) is
5933    begin
5934       Set_Has_Delayed_Freeze (T, False);
5935       Set_Freeze_Node (T, Empty);
5936
5937       --  Since we don't want T to have a Freeze_Node, we don't want its
5938       --  Full_View or Corresponding_Record_Type to have one either.
5939
5940       --  ??? Fundamentally, this whole handling is a kludge. What we really
5941       --  want is to be sure that for an Itype that's part of record R and is a
5942       --  subtype of type T, that it's frozen after the later of the freeze
5943       --  points of R and T. We have no way of doing that directly, so what we
5944       --  do is force most such Itypes to be frozen as part of freezing R via
5945       --  this procedure and only delay the ones that need to be delayed
5946       --  (mostly the designated types of access types that are defined as part
5947       --  of the record).
5948
5949       if Is_Private_Type (T)
5950         and then Present (Full_View (T))
5951         and then Is_Itype (Full_View (T))
5952         and then Is_Record_Type (Scope (Full_View (T)))
5953       then
5954          Undelay_Type (Full_View (T));
5955       end if;
5956
5957       if Is_Concurrent_Type (T)
5958         and then Present (Corresponding_Record_Type (T))
5959         and then Is_Itype (Corresponding_Record_Type (T))
5960         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5961       then
5962          Undelay_Type (Corresponding_Record_Type (T));
5963       end if;
5964    end Undelay_Type;
5965
5966    ------------------
5967    -- Warn_Overlay --
5968    ------------------
5969
5970    procedure Warn_Overlay
5971      (Expr : Node_Id;
5972       Typ  : Entity_Id;
5973       Nam  : Entity_Id)
5974    is
5975       Ent : constant Entity_Id := Entity (Nam);
5976       --  The object to which the address clause applies
5977
5978       Init : Node_Id;
5979       Old  : Entity_Id := Empty;
5980       Decl : Node_Id;
5981
5982    begin
5983       --  No warning if address clause overlay warnings are off
5984
5985       if not Address_Clause_Overlay_Warnings then
5986          return;
5987       end if;
5988
5989       --  No warning if there is an explicit initialization
5990
5991       Init := Original_Node (Expression (Declaration_Node (Ent)));
5992
5993       if Present (Init) and then Comes_From_Source (Init) then
5994          return;
5995       end if;
5996
5997       --  We only give the warning for non-imported entities of a type for
5998       --  which a non-null base init proc is defined, or for objects of access
5999       --  types with implicit null initialization, or when Normalize_Scalars
6000       --  applies and the type is scalar or a string type (the latter being
6001       --  tested for because predefined String types are initialized by inline
6002       --  code rather than by an init_proc). Note that we do not give the
6003       --  warning for Initialize_Scalars, since we suppressed initialization
6004       --  in this case. Also, do not warn if Suppress_Initialization is set.
6005
6006       if Present (Expr)
6007         and then not Is_Imported (Ent)
6008         and then not Initialization_Suppressed (Typ)
6009         and then (Has_Non_Null_Base_Init_Proc (Typ)
6010                    or else Is_Access_Type (Typ)
6011                    or else (Normalize_Scalars
6012                              and then (Is_Scalar_Type (Typ)
6013                                         or else Is_String_Type (Typ))))
6014       then
6015          if Nkind (Expr) = N_Attribute_Reference
6016            and then Is_Entity_Name (Prefix (Expr))
6017          then
6018             Old := Entity (Prefix (Expr));
6019
6020          elsif Is_Entity_Name (Expr)
6021            and then Ekind (Entity (Expr)) = E_Constant
6022          then
6023             Decl := Declaration_Node (Entity (Expr));
6024
6025             if Nkind (Decl) = N_Object_Declaration
6026               and then Present (Expression (Decl))
6027               and then Nkind (Expression (Decl)) = N_Attribute_Reference
6028               and then Is_Entity_Name (Prefix (Expression (Decl)))
6029             then
6030                Old := Entity (Prefix (Expression (Decl)));
6031
6032             elsif Nkind (Expr) = N_Function_Call then
6033                return;
6034             end if;
6035
6036          --  A function call (most likely to To_Address) is probably not an
6037          --  overlay, so skip warning. Ditto if the function call was inlined
6038          --  and transformed into an entity.
6039
6040          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
6041             return;
6042          end if;
6043
6044          Decl := Next (Parent (Expr));
6045
6046          --  If a pragma Import follows, we assume that it is for the current
6047          --  target of the address clause, and skip the warning.
6048
6049          if Present (Decl)
6050            and then Nkind (Decl) = N_Pragma
6051            and then Pragma_Name (Decl) = Name_Import
6052          then
6053             return;
6054          end if;
6055
6056          if Present (Old) then
6057             Error_Msg_Node_2 := Old;
6058             Error_Msg_N
6059               ("default initialization of & may modify &?",
6060                Nam);
6061          else
6062             Error_Msg_N
6063               ("default initialization of & may modify overlaid storage?",
6064                Nam);
6065          end if;
6066
6067          --  Add friendly warning if initialization comes from a packed array
6068          --  component.
6069
6070          if Is_Record_Type (Typ)  then
6071             declare
6072                Comp : Entity_Id;
6073
6074             begin
6075                Comp := First_Component (Typ);
6076                while Present (Comp) loop
6077                   if Nkind (Parent (Comp)) = N_Component_Declaration
6078                     and then Present (Expression (Parent (Comp)))
6079                   then
6080                      exit;
6081                   elsif Is_Array_Type (Etype (Comp))
6082                      and then Present (Packed_Array_Type (Etype (Comp)))
6083                   then
6084                      Error_Msg_NE
6085                        ("\packed array component& " &
6086                         "will be initialized to zero?",
6087                         Nam, Comp);
6088                      exit;
6089                   else
6090                      Next_Component (Comp);
6091                   end if;
6092                end loop;
6093             end;
6094          end if;
6095
6096          Error_Msg_N
6097            ("\use pragma Import for & to " &
6098             "suppress initialization (RM B.1(24))?",
6099             Nam);
6100       end if;
6101    end Warn_Overlay;
6102
6103 end Freeze;