gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- You should have received a copy of the GNU General Public License along  --
  19 -- with this program; see file COPYING3.  If not see                        --
  20 -- <http://www.gnu.org/licenses/>.                                          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Elists;   use Elists;
  31 with Errout;   use Errout;
  32 with Exp_Ch3;  use Exp_Ch3;
  33 with Exp_Ch7;  use Exp_Ch7;
  34 with Exp_Disp; use Exp_Disp;
  35 with Exp_Pakd; use Exp_Pakd;
  36 with Exp_Util; use Exp_Util;
  37 with Exp_Tss;  use Exp_Tss;
  38 with Layout;   use Layout;
  39 with Lib;      use Lib;
  40 with Namet;    use Namet;
  41 with Nlists;   use Nlists;
  42 with Nmake;    use Nmake;
  43 with Opt;      use Opt;
  44 with Restrict; use Restrict;
  45 with Rident;   use Rident;
  46 with Sem;      use Sem;
  47 with Sem_Aux;  use Sem_Aux;
  48 with Sem_Cat;  use Sem_Cat;
  49 with Sem_Ch6;  use Sem_Ch6;
  50 with Sem_Ch7;  use Sem_Ch7;
  51 with Sem_Ch8;  use Sem_Ch8;
  52 with Sem_Ch13; use Sem_Ch13;
  53 with Sem_Eval; use Sem_Eval;
  54 with Sem_Mech; use Sem_Mech;
  55 with Sem_Prag; use Sem_Prag;
  56 with Sem_Res;  use Sem_Res;
  57 with Sem_Util; use Sem_Util;
  58 with Sinfo;    use Sinfo;
  59 with Snames;   use Snames;
  60 with Stand;    use Stand;
  61 with Targparm; use Targparm;
  62 with Tbuild;   use Tbuild;
  63 with Ttypes;   use Ttypes;
  64 with Uintp;    use Uintp;
  65 with Urealp;   use Urealp;
  66
  67 package body Freeze is
  68
  69    -----------------------
  70    -- Local Subprograms --
  71    -----------------------
  72
  73    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  74    --  Typ is a type that is being frozen. If no size clause is given,
  75    --  but a default Esize has been computed, then this default Esize is
  76    --  adjusted up if necessary to be consistent with a given alignment,
  77    --  but never to a value greater than Long_Long_Integer'Size. This
  78    --  is used for all discrete types and for fixed-point types.
  79
  80    procedure Build_And_Analyze_Renamed_Body
  81      (Decl  : Node_Id;
  82       New_S : Entity_Id;
  83       After : in out Node_Id);
  84    --  Build body for a renaming declaration, insert in tree and analyze
  85
  86    procedure Check_Address_Clause (E : Entity_Id);
  87    --  Apply legality checks to address clauses for object declarations,
  88    --  at the point the object is frozen.
  89
  90    procedure Check_Strict_Alignment (E : Entity_Id);
  91    --  E is a base type. If E is tagged or has a component that is aliased
  92    --  or tagged or contains something this is aliased or tagged, set
  93    --  Strict_Alignment.
  94
  95    procedure Check_Unsigned_Type (E : Entity_Id);
  96    pragma Inline (Check_Unsigned_Type);
  97    --  If E is a fixed-point or discrete type, then all the necessary work
  98    --  to freeze it is completed except for possible setting of the flag
  99    --  Is_Unsigned_Type, which is done by this procedure. The call has no
 100    --  effect if the entity E is not a discrete or fixed-point type.
 101
 102    procedure Freeze_And_Append
 103      (Ent    : Entity_Id;
 104       N      : Node_Id;
 105       Result : in out List_Id);
 106    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 107    --  nodes to Result, modifying Result from No_List if necessary. N has
 108    --  the same usage as in Freeze_Entity.
 109
 110    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 111    --  Freeze enumeration type. The Esize field is set as processing
 112    --  proceeds (i.e. set by default when the type is declared and then
 113    --  adjusted by rep clauses. What this procedure does is to make sure
 114    --  that if a foreign convention is specified, and no specific size
 115    --  is given, then the size must be at least Integer'Size.
 116
 117    procedure Freeze_Static_Object (E : Entity_Id);
 118    --  If an object is frozen which has Is_Statically_Allocated set, then
 119    --  all referenced types must also be marked with this flag. This routine
 120    --  is in charge of meeting this requirement for the object entity E.
 121
 122    procedure Freeze_Subprogram (E : Entity_Id);
 123    --  Perform freezing actions for a subprogram (create extra formals,
 124    --  and set proper default mechanism values). Note that this routine
 125    --  is not called for internal subprograms, for which neither of these
 126    --  actions is needed (or desirable, we do not want for example to have
 127    --  these extra formals present in initialization procedures, where they
 128    --  would serve no purpose). In this call E is either a subprogram or
 129    --  a subprogram type (i.e. an access to a subprogram).
 130
 131    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 132    --  True if T is not private and has no private components, or has a full
 133    --  view. Used to determine whether the designated type of an access type
 134    --  should be frozen when the access type is frozen. This is done when an
 135    --  allocator is frozen, or an expression that may involve attributes of
 136    --  the designated type. Otherwise freezing the access type does not freeze
 137    --  the designated type.
 138
 139    procedure Process_Default_Expressions
 140      (E     : Entity_Id;
 141       After : in out Node_Id);
 142    --  This procedure is called for each subprogram to complete processing of
 143    --  default expressions at the point where all types are known to be frozen.
 144    --  The expressions must be analyzed in full, to make sure that all error
 145    --  processing is done (they have only been pre-analyzed). If the expression
 146    --  is not an entity or literal, its analysis may generate code which must
 147    --  not be executed. In that case we build a function body to hold that
 148    --  code. This wrapper function serves no other purpose (it used to be
 149    --  called to evaluate the default, but now the default is inlined at each
 150    --  point of call).
 151
 152    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 153    --  Typ is a record or array type that is being frozen. This routine sets
 154    --  the default component alignment from the scope stack values if the
 155    --  alignment is otherwise not specified.
 156
 157    procedure Check_Debug_Info_Needed (T : Entity_Id);
 158    --  As each entity is frozen, this routine is called to deal with the
 159    --  setting of Debug_Info_Needed for the entity. This flag is set if
 160    --  the entity comes from source, or if we are in Debug_Generated_Code
 161    --  mode or if the -gnatdV debug flag is set. However, it never sets
 162    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 163    --  subsidiary entities have the flag set as required.
 164
 165    procedure Undelay_Type (T : Entity_Id);
 166    --  T is a type of a component that we know to be an Itype. We don't want
 167    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 168    --  Full_View or Corresponding_Record_Type.
 169
 170    procedure Warn_Overlay
 171      (Expr : Node_Id;
 172       Typ  : Entity_Id;
 173       Nam  : Node_Id);
 174    --  Expr is the expression for an address clause for entity Nam whose type
 175    --  is Typ. If Typ has a default initialization, and there is no explicit
 176    --  initialization in the source declaration, check whether the address
 177    --  clause might cause overlaying of an entity, and emit a warning on the
 178    --  side effect that the initialization will cause.
 179
 180    -------------------------------
 181    -- Adjust_Esize_For_Alignment --
 182    -------------------------------
 183
 184    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 185       Align : Uint;
 186
 187    begin
 188       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 189          Align := Alignment_In_Bits (Typ);
 190
 191          if Align > Esize (Typ)
 192            and then Align <= Standard_Long_Long_Integer_Size
 193          then
 194             Set_Esize (Typ, Align);
 195          end if;
 196       end if;
 197    end Adjust_Esize_For_Alignment;
 198
 199    ------------------------------------
 200    -- Build_And_Analyze_Renamed_Body --
 201    ------------------------------------
 202
 203    procedure Build_And_Analyze_Renamed_Body
 204      (Decl  : Node_Id;
 205       New_S : Entity_Id;
 206       After : in out Node_Id)
 207    is
 208       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 209       Ent          : constant Entity_Id := Defining_Entity (Decl);
 210       Body_Node    : Node_Id;
 211       Renamed_Subp : Entity_Id;
 212
 213    begin
 214       --  If the renamed subprogram is intrinsic, there is no need for a
 215       --  wrapper body: we set the alias that will be called and expanded which
 216       --  completes the declaration. This transformation is only legal if the
 217       --  renamed entity has already been elaborated.
 218
 219       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 220       --  subprogram, as long as the renaming occurs before the new entity
 221       --  is frozen. See RM 8.5.4 (5).
 222
 223       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 224         and then Is_Entity_Name (Name (Body_Decl))
 225       then
 226          Renamed_Subp := Entity (Name (Body_Decl));
 227       else
 228          Renamed_Subp := Empty;
 229       end if;
 230
 231       if Present (Renamed_Subp)
 232         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 233         and then
 234           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 235             or else Sloc (Renamed_Subp) < Sloc (Ent))
 236
 237         --  We can make the renaming entity intrinsic if the renamed function
 238         --  has an interface name, or if it is one of the shift/rotate
 239         --  operations known to the compiler.
 240
 241         and then (Present (Interface_Name (Renamed_Subp))
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 243                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 244                    or else Chars (Renamed_Subp) = Name_Shift_Left
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right
 246                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 247       then
 248          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 249
 250          if Present (Alias (Renamed_Subp)) then
 251             Set_Alias (Ent, Alias (Renamed_Subp));
 252          else
 253             Set_Alias (Ent, Renamed_Subp);
 254          end if;
 255
 256          Set_Is_Intrinsic_Subprogram (Ent);
 257          Set_Has_Completion (Ent);
 258
 259       else
 260          Body_Node := Build_Renamed_Body (Decl, New_S);
 261          Insert_After (After, Body_Node);
 262          Mark_Rewrite_Insertion (Body_Node);
 263          Analyze (Body_Node);
 264          After := Body_Node;
 265       end if;
 266    end Build_And_Analyze_Renamed_Body;
 267
 268    ------------------------
 269    -- Build_Renamed_Body --
 270    ------------------------
 271
 272    function Build_Renamed_Body
 273      (Decl  : Node_Id;
 274       New_S : Entity_Id) return Node_Id
 275    is
 276       Loc : constant Source_Ptr := Sloc (New_S);
 277       --  We use for the source location of the renamed body, the location of
 278       --  the spec entity. It might seem more natural to use the location of
 279       --  the renaming declaration itself, but that would be wrong, since then
 280       --  the body we create would look as though it was created far too late,
 281       --  and this could cause problems with elaboration order analysis,
 282       --  particularly in connection with instantiations.
 283
 284       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 285       Nam        : constant Node_Id := Name (N);
 286       Old_S      : Entity_Id;
 287       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 288       Actuals    : List_Id := No_List;
 289       Call_Node  : Node_Id;
 290       Call_Name  : Node_Id;
 291       Body_Node  : Node_Id;
 292       Formal     : Entity_Id;
 293       O_Formal   : Entity_Id;
 294       Param_Spec : Node_Id;
 295
 296       Pref : Node_Id := Empty;
 297       --  If the renamed entity is a primitive operation given in prefix form,
 298       --  the prefix is the target object and it has to be added as the first
 299       --  actual in the generated call.
 300
 301    begin
 302       --  Determine the entity being renamed, which is the target of the call
 303       --  statement. If the name is an explicit dereference, this is a renaming
 304       --  of a subprogram type rather than a subprogram. The name itself is
 305       --  fully analyzed.
 306
 307       if Nkind (Nam) = N_Selected_Component then
 308          Old_S := Entity (Selector_Name (Nam));
 309
 310       elsif Nkind (Nam) = N_Explicit_Dereference then
 311          Old_S := Etype (Nam);
 312
 313       elsif Nkind (Nam) = N_Indexed_Component then
 314          if Is_Entity_Name (Prefix (Nam)) then
 315             Old_S := Entity (Prefix (Nam));
 316          else
 317             Old_S := Entity (Selector_Name (Prefix (Nam)));
 318          end if;
 319
 320       elsif Nkind (Nam) = N_Character_Literal then
 321          Old_S := Etype (New_S);
 322
 323       else
 324          Old_S := Entity (Nam);
 325       end if;
 326
 327       if Is_Entity_Name (Nam) then
 328
 329          --  If the renamed entity is a predefined operator, retain full name
 330          --  to ensure its visibility.
 331
 332          if Ekind (Old_S) = E_Operator
 333            and then Nkind (Nam) = N_Expanded_Name
 334          then
 335             Call_Name := New_Copy (Name (N));
 336          else
 337             Call_Name := New_Reference_To (Old_S, Loc);
 338          end if;
 339
 340       else
 341          if Nkind (Nam) = N_Selected_Component
 342            and then Present (First_Formal (Old_S))
 343            and then
 344              (Is_Controlling_Formal (First_Formal (Old_S))
 345                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 346          then
 347
 348             --  Retrieve the target object, to be added as a first actual
 349             --  in the call.
 350
 351             Call_Name := New_Occurrence_Of (Old_S, Loc);
 352             Pref := Prefix (Nam);
 353
 354          else
 355             Call_Name := New_Copy (Name (N));
 356          end if;
 357
 358          --  Original name may have been overloaded, but is fully resolved now
 359
 360          Set_Is_Overloaded (Call_Name, False);
 361       end if;
 362
 363       --  For simple renamings, subsequent calls can be expanded directly as
 364       --  calls to the renamed entity. The body must be generated in any case
 365       --  for calls that may appear elsewhere.
 366
 367       if Ekind_In (Old_S, E_Function, E_Procedure)
 368         and then Nkind (Decl) = N_Subprogram_Declaration
 369       then
 370          Set_Body_To_Inline (Decl, Old_S);
 371       end if;
 372
 373       --  The body generated for this renaming is an internal artifact, and
 374       --  does not  constitute a freeze point for the called entity.
 375
 376       Set_Must_Not_Freeze (Call_Name);
 377
 378       Formal := First_Formal (Defining_Entity (Decl));
 379
 380       if Present (Pref) then
 381          declare
 382             Pref_Type : constant Entity_Id := Etype (Pref);
 383             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 384
 385          begin
 386             --  The controlling formal may be an access parameter, or the
 387             --  actual may be an access value, so adjust accordingly.
 388
 389             if Is_Access_Type (Pref_Type)
 390               and then not Is_Access_Type (Form_Type)
 391             then
 392                Actuals := New_List
 393                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 394
 395             elsif Is_Access_Type (Form_Type)
 396               and then not Is_Access_Type (Pref)
 397             then
 398                Actuals := New_List
 399                  (Make_Attribute_Reference (Loc,
 400                    Attribute_Name => Name_Access,
 401                    Prefix => Relocate_Node (Pref)));
 402             else
 403                Actuals := New_List (Pref);
 404             end if;
 405          end;
 406
 407       elsif Present (Formal) then
 408          Actuals := New_List;
 409
 410       else
 411          Actuals := No_List;
 412       end if;
 413
 414       if Present (Formal) then
 415          while Present (Formal) loop
 416             Append (New_Reference_To (Formal, Loc), Actuals);
 417             Next_Formal (Formal);
 418          end loop;
 419       end if;
 420
 421       --  If the renamed entity is an entry, inherit its profile. For other
 422       --  renamings as bodies, both profiles must be subtype conformant, so it
 423       --  is not necessary to replace the profile given in the declaration.
 424       --  However, default values that are aggregates are rewritten when
 425       --  partially analyzed, so we recover the original aggregate to insure
 426       --  that subsequent conformity checking works. Similarly, if the default
 427       --  expression was constant-folded, recover the original expression.
 428
 429       Formal := First_Formal (Defining_Entity (Decl));
 430
 431       if Present (Formal) then
 432          O_Formal := First_Formal (Old_S);
 433          Param_Spec := First (Parameter_Specifications (Spec));
 434          while Present (Formal) loop
 435             if Is_Entry (Old_S) then
 436                if Nkind (Parameter_Type (Param_Spec)) /=
 437                                                     N_Access_Definition
 438                then
 439                   Set_Etype (Formal, Etype (O_Formal));
 440                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 441                end if;
 442
 443             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 444               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 445                                            Nkind (Default_Value (O_Formal))
 446             then
 447                Set_Expression (Param_Spec,
 448                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 449             end if;
 450
 451             Next_Formal (Formal);
 452             Next_Formal (O_Formal);
 453             Next (Param_Spec);
 454          end loop;
 455       end if;
 456
 457       --  If the renamed entity is a function, the generated body contains a
 458       --  return statement. Otherwise, build a procedure call. If the entity is
 459       --  an entry, subsequent analysis of the call will transform it into the
 460       --  proper entry or protected operation call. If the renamed entity is
 461       --  a character literal, return it directly.
 462
 463       if Ekind (Old_S) = E_Function
 464         or else Ekind (Old_S) = E_Operator
 465         or else (Ekind (Old_S) = E_Subprogram_Type
 466                   and then Etype (Old_S) /= Standard_Void_Type)
 467       then
 468          Call_Node :=
 469            Make_Simple_Return_Statement (Loc,
 470               Expression =>
 471                 Make_Function_Call (Loc,
 472                   Name => Call_Name,
 473                   Parameter_Associations => Actuals));
 474
 475       elsif Ekind (Old_S) = E_Enumeration_Literal then
 476          Call_Node :=
 477            Make_Simple_Return_Statement (Loc,
 478               Expression => New_Occurrence_Of (Old_S, Loc));
 479
 480       elsif Nkind (Nam) = N_Character_Literal then
 481          Call_Node :=
 482            Make_Simple_Return_Statement (Loc,
 483              Expression => Call_Name);
 484
 485       else
 486          Call_Node :=
 487            Make_Procedure_Call_Statement (Loc,
 488              Name => Call_Name,
 489              Parameter_Associations => Actuals);
 490       end if;
 491
 492       --  Create entities for subprogram body and formals
 493
 494       Set_Defining_Unit_Name (Spec,
 495         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 496
 497       Param_Spec := First (Parameter_Specifications (Spec));
 498       while Present (Param_Spec) loop
 499          Set_Defining_Identifier (Param_Spec,
 500            Make_Defining_Identifier (Loc,
 501              Chars => Chars (Defining_Identifier (Param_Spec))));
 502          Next (Param_Spec);
 503       end loop;
 504
 505       Body_Node :=
 506         Make_Subprogram_Body (Loc,
 507           Specification => Spec,
 508           Declarations => New_List,
 509           Handled_Statement_Sequence =>
 510             Make_Handled_Sequence_Of_Statements (Loc,
 511               Statements => New_List (Call_Node)));
 512
 513       if Nkind (Decl) /= N_Subprogram_Declaration then
 514          Rewrite (N,
 515            Make_Subprogram_Declaration (Loc,
 516              Specification => Specification (N)));
 517       end if;
 518
 519       --  Link the body to the entity whose declaration it completes. If
 520       --  the body is analyzed when the renamed entity is frozen, it may
 521       --  be necessary to restore the proper scope (see package Exp_Ch13).
 522
 523       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 524         and then Present (Corresponding_Spec (N))
 525       then
 526          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 527       else
 528          Set_Corresponding_Spec (Body_Node, New_S);
 529       end if;
 530
 531       return Body_Node;
 532    end Build_Renamed_Body;
 533
 534    --------------------------
 535    -- Check_Address_Clause --
 536    --------------------------
 537
 538    procedure Check_Address_Clause (E : Entity_Id) is
 539       Addr : constant Node_Id   := Address_Clause (E);
 540       Expr : Node_Id;
 541       Decl : constant Node_Id   := Declaration_Node (E);
 542       Typ  : constant Entity_Id := Etype (E);
 543
 544    begin
 545       if Present (Addr) then
 546          Expr := Expression (Addr);
 547
 548          if Needs_Constant_Address (Decl, Typ) then
 549             Check_Constant_Address_Clause (Expr, E);
 550
 551             --  Has_Delayed_Freeze was set on E when the address clause was
 552             --  analyzed. Reset the flag now unless freeze actions were
 553             --  attached to it in the mean time.
 554
 555             if No (Freeze_Node (E)) then
 556                Set_Has_Delayed_Freeze (E, False);
 557             end if;
 558          end if;
 559
 560          --  If Rep_Clauses are to be ignored, remove address clause from
 561          --  list attached to entity, because it may be illegal for gigi,
 562          --  for example by breaking order of elaboration..
 563
 564          if Ignore_Rep_Clauses then
 565             declare
 566                Rep : Node_Id;
 567
 568             begin
 569                Rep := First_Rep_Item (E);
 570
 571                if Rep = Addr then
 572                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 573
 574                else
 575                   while Present (Rep)
 576                     and then Next_Rep_Item (Rep) /= Addr
 577                   loop
 578                      Rep := Next_Rep_Item (Rep);
 579                   end loop;
 580                end if;
 581
 582                if Present (Rep) then
 583                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 584                end if;
 585             end;
 586
 587             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 588
 589          elsif not Error_Posted (Expr)
 590            and then not Needs_Finalization (Typ)
 591          then
 592             Warn_Overlay (Expr, Typ, Name (Addr));
 593          end if;
 594       end if;
 595    end Check_Address_Clause;
 596
 597    -----------------------------
 598    -- Check_Compile_Time_Size --
 599    -----------------------------
 600
 601    procedure Check_Compile_Time_Size (T : Entity_Id) is
 602
 603       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 604       --  Sets the compile time known size (32 bits or less) in the Esize
 605       --  field, of T checking for a size clause that was given which attempts
 606       --  to give a smaller size, and also checking for an alignment clause.
 607
 608       function Size_Known (T : Entity_Id) return Boolean;
 609       --  Recursive function that does all the work
 610
 611       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 612       --  If T is a constrained subtype, its size is not known if any of its
 613       --  discriminant constraints is not static and it is not a null record.
 614       --  The test is conservative and doesn't check that the components are
 615       --  in fact constrained by non-static discriminant values. Could be made
 616       --  more precise ???
 617
 618       --------------------
 619       -- Set_Small_Size --
 620       --------------------
 621
 622       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 623       begin
 624          if S > 32 then
 625             return;
 626
 627          --  Don't bother if alignment clause with a value other than 1 is
 628          --  present, because size may be padded up to meet back end alignment
 629          --  requirements, and only the back end knows the rules!
 630
 631          elsif Known_Alignment (T) and then Alignment (T) /= 1 then
 632             return;
 633
 634          --  Check for bad size clause given
 635
 636          elsif Has_Size_Clause (T) then
 637             if RM_Size (T) < S then
 638                Error_Msg_Uint_1 := S;
 639                Error_Msg_NE
 640                  ("size for& too small, minimum allowed is ^",
 641                   Size_Clause (T), T);
 642
 643             elsif Unknown_Esize (T) then
 644                Set_Esize (T, S);
 645             end if;
 646
 647          --  Set sizes if not set already
 648
 649          else
 650             if Unknown_Esize (T) then
 651                Set_Esize (T, S);
 652             end if;
 653
 654             if Unknown_RM_Size (T) then
 655                Set_RM_Size (T, S);
 656             end if;
 657          end if;
 658       end Set_Small_Size;
 659
 660       ----------------
 661       -- Size_Known --
 662       ----------------
 663
 664       function Size_Known (T : Entity_Id) return Boolean is
 665          Index : Entity_Id;
 666          Comp  : Entity_Id;
 667          Ctyp  : Entity_Id;
 668          Low   : Node_Id;
 669          High  : Node_Id;
 670
 671       begin
 672          if Size_Known_At_Compile_Time (T) then
 673             return True;
 674
 675          --  Always True for scalar types. This is true even for generic formal
 676          --  scalar types. We used to return False in the latter case, but the
 677          --  size is known at compile time, even in the template, we just do
 678          --  not know the exact size but that's not the point of this routine.
 679
 680          elsif Is_Scalar_Type (T)
 681            or else Is_Task_Type (T)
 682          then
 683             return True;
 684
 685          --  Array types
 686
 687          elsif Is_Array_Type (T) then
 688
 689             --  String literals always have known size, and we can set it
 690
 691             if Ekind (T) = E_String_Literal_Subtype then
 692                Set_Small_Size (T, Component_Size (T)
 693                                * String_Literal_Length (T));
 694                return True;
 695
 696             --  Unconstrained types never have known at compile time size
 697
 698             elsif not Is_Constrained (T) then
 699                return False;
 700
 701             --  Don't do any recursion on type with error posted, since we may
 702             --  have a malformed type that leads us into a loop.
 703
 704             elsif Error_Posted (T) then
 705                return False;
 706
 707             --  Otherwise if component size unknown, then array size unknown
 708
 709             elsif not Size_Known (Component_Type (T)) then
 710                return False;
 711             end if;
 712
 713             --  Check for all indexes static, and also compute possible size
 714             --  (in case it is less than 32 and may be packable).
 715
 716             declare
 717                Esiz : Uint := Component_Size (T);
 718                Dim  : Uint;
 719
 720             begin
 721                Index := First_Index (T);
 722                while Present (Index) loop
 723                   if Nkind (Index) = N_Range then
 724                      Get_Index_Bounds (Index, Low, High);
 725
 726                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 727                      return False;
 728
 729                   else
 730                      Low  := Type_Low_Bound (Etype (Index));
 731                      High := Type_High_Bound (Etype (Index));
 732                   end if;
 733
 734                   if not Compile_Time_Known_Value (Low)
 735                     or else not Compile_Time_Known_Value (High)
 736                     or else Etype (Index) = Any_Type
 737                   then
 738                      return False;
 739
 740                   else
 741                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 742
 743                      if Dim >= 0 then
 744                         Esiz := Esiz * Dim;
 745                      else
 746                         Esiz := Uint_0;
 747                      end if;
 748                   end if;
 749
 750                   Next_Index (Index);
 751                end loop;
 752
 753                Set_Small_Size (T, Esiz);
 754                return True;
 755             end;
 756
 757          --  Access types always have known at compile time sizes
 758
 759          elsif Is_Access_Type (T) then
 760             return True;
 761
 762          --  For non-generic private types, go to underlying type if present
 763
 764          elsif Is_Private_Type (T)
 765            and then not Is_Generic_Type (T)
 766            and then Present (Underlying_Type (T))
 767          then
 768             --  Don't do any recursion on type with error posted, since we may
 769             --  have a malformed type that leads us into a loop.
 770
 771             if Error_Posted (T) then
 772                return False;
 773             else
 774                return Size_Known (Underlying_Type (T));
 775             end if;
 776
 777          --  Record types
 778
 779          elsif Is_Record_Type (T) then
 780
 781             --  A class-wide type is never considered to have a known size
 782
 783             if Is_Class_Wide_Type (T) then
 784                return False;
 785
 786             --  A subtype of a variant record must not have non-static
 787             --  discriminated components.
 788
 789             elsif T /= Base_Type (T)
 790               and then not Static_Discriminated_Components (T)
 791             then
 792                return False;
 793
 794             --  Don't do any recursion on type with error posted, since we may
 795             --  have a malformed type that leads us into a loop.
 796
 797             elsif Error_Posted (T) then
 798                return False;
 799             end if;
 800
 801             --  Now look at the components of the record
 802
 803             declare
 804                --  The following two variables are used to keep track of the
 805                --  size of packed records if we can tell the size of the packed
 806                --  record in the front end. Packed_Size_Known is True if so far
 807                --  we can figure out the size. It is initialized to True for a
 808                --  packed record, unless the record has discriminants. The
 809                --  reason we eliminate the discriminated case is that we don't
 810                --  know the way the back end lays out discriminated packed
 811                --  records. If Packed_Size_Known is True, then Packed_Size is
 812                --  the size in bits so far.
 813
 814                Packed_Size_Known : Boolean :=
 815                                      Is_Packed (T)
 816                                        and then not Has_Discriminants (T);
 817
 818                Packed_Size : Uint := Uint_0;
 819
 820             begin
 821                --  Test for variant part present
 822
 823                if Has_Discriminants (T)
 824                  and then Present (Parent (T))
 825                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 826                  and then Nkind (Type_Definition (Parent (T))) =
 827                                                N_Record_Definition
 828                  and then not Null_Present (Type_Definition (Parent (T)))
 829                  and then Present (Variant_Part
 830                             (Component_List (Type_Definition (Parent (T)))))
 831                then
 832                   --  If variant part is present, and type is unconstrained,
 833                   --  then we must have defaulted discriminants, or a size
 834                   --  clause must be present for the type, or else the size
 835                   --  is definitely not known at compile time.
 836
 837                   if not Is_Constrained (T)
 838                     and then
 839                       No (Discriminant_Default_Value (First_Discriminant (T)))
 840                     and then Unknown_Esize (T)
 841                   then
 842                      return False;
 843                   end if;
 844                end if;
 845
 846                --  Loop through components
 847
 848                Comp := First_Component_Or_Discriminant (T);
 849                while Present (Comp) loop
 850                   Ctyp := Etype (Comp);
 851
 852                   --  We do not know the packed size if there is a component
 853                   --  clause present (we possibly could, but this would only
 854                   --  help in the case of a record with partial rep clauses.
 855                   --  That's because in the case of full rep clauses, the
 856                   --  size gets figured out anyway by a different circuit).
 857
 858                   if Present (Component_Clause (Comp)) then
 859                      Packed_Size_Known := False;
 860                   end if;
 861
 862                   --  We need to identify a component that is an array where
 863                   --  the index type is an enumeration type with non-standard
 864                   --  representation, and some bound of the type depends on a
 865                   --  discriminant.
 866
 867                   --  This is because gigi computes the size by doing a
 868                   --  substitution of the appropriate discriminant value in
 869                   --  the size expression for the base type, and gigi is not
 870                   --  clever enough to evaluate the resulting expression (which
 871                   --  involves a call to rep_to_pos) at compile time.
 872
 873                   --  It would be nice if gigi would either recognize that
 874                   --  this expression can be computed at compile time, or
 875                   --  alternatively figured out the size from the subtype
 876                   --  directly, where all the information is at hand ???
 877
 878                   if Is_Array_Type (Etype (Comp))
 879                     and then Present (Packed_Array_Type (Etype (Comp)))
 880                   then
 881                      declare
 882                         Ocomp  : constant Entity_Id :=
 883                                    Original_Record_Component (Comp);
 884                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 885                         Ind    : Node_Id;
 886                         Indtyp : Entity_Id;
 887                         Lo, Hi : Node_Id;
 888
 889                      begin
 890                         Ind := First_Index (OCtyp);
 891                         while Present (Ind) loop
 892                            Indtyp := Etype (Ind);
 893
 894                            if Is_Enumeration_Type (Indtyp)
 895                              and then Has_Non_Standard_Rep (Indtyp)
 896                            then
 897                               Lo := Type_Low_Bound  (Indtyp);
 898                               Hi := Type_High_Bound (Indtyp);
 899
 900                               if Is_Entity_Name (Lo)
 901                                 and then Ekind (Entity (Lo)) = E_Discriminant
 902                               then
 903                                  return False;
 904
 905                               elsif Is_Entity_Name (Hi)
 906                                 and then Ekind (Entity (Hi)) = E_Discriminant
 907                               then
 908                                  return False;
 909                               end if;
 910                            end if;
 911
 912                            Next_Index (Ind);
 913                         end loop;
 914                      end;
 915                   end if;
 916
 917                   --  Clearly size of record is not known if the size of one of
 918                   --  the components is not known.
 919
 920                   if not Size_Known (Ctyp) then
 921                      return False;
 922                   end if;
 923
 924                   --  Accumulate packed size if possible
 925
 926                   if Packed_Size_Known then
 927
 928                      --  We can only deal with elementary types, since for
 929                      --  non-elementary components, alignment enters into the
 930                      --  picture, and we don't know enough to handle proper
 931                      --  alignment in this context. Packed arrays count as
 932                      --  elementary if the representation is a modular type.
 933
 934                      if Is_Elementary_Type (Ctyp)
 935                        or else (Is_Array_Type (Ctyp)
 936                                  and then Present (Packed_Array_Type (Ctyp))
 937                                  and then Is_Modular_Integer_Type
 938                                             (Packed_Array_Type (Ctyp)))
 939                      then
 940                         --  If RM_Size is known and static, then we can keep
 941                         --  accumulating the packed size.
 942
 943                         if Known_Static_RM_Size (Ctyp) then
 944
 945                            --  A little glitch, to be removed sometime ???
 946                            --  gigi does not understand zero sizes yet.
 947
 948                            if RM_Size (Ctyp) = Uint_0 then
 949                               Packed_Size_Known := False;
 950
 951                            --  Normal case where we can keep accumulating the
 952                            --  packed array size.
 953
 954                            else
 955                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 956                            end if;
 957
 958                         --  If we have a field whose RM_Size is not known then
 959                         --  we can't figure out the packed size here.
 960
 961                         else
 962                            Packed_Size_Known := False;
 963                         end if;
 964
 965                      --  If we have a non-elementary type we can't figure out
 966                      --  the packed array size (alignment issues).
 967
 968                      else
 969                         Packed_Size_Known := False;
 970                      end if;
 971                   end if;
 972
 973                   Next_Component_Or_Discriminant (Comp);
 974                end loop;
 975
 976                if Packed_Size_Known then
 977                   Set_Small_Size (T, Packed_Size);
 978                end if;
 979
 980                return True;
 981             end;
 982
 983          --  All other cases, size not known at compile time
 984
 985          else
 986             return False;
 987          end if;
 988       end Size_Known;
 989
 990       -------------------------------------
 991       -- Static_Discriminated_Components --
 992       -------------------------------------
 993
 994       function Static_Discriminated_Components
 995         (T : Entity_Id) return Boolean
 996       is
 997          Constraint : Elmt_Id;
 998
 999       begin
1000          if Has_Discriminants (T)
1001            and then Present (Discriminant_Constraint (T))
1002            and then Present (First_Component (T))
1003          then
1004             Constraint := First_Elmt (Discriminant_Constraint (T));
1005             while Present (Constraint) loop
1006                if not Compile_Time_Known_Value (Node (Constraint)) then
1007                   return False;
1008                end if;
1009
1010                Next_Elmt (Constraint);
1011             end loop;
1012          end if;
1013
1014          return True;
1015       end Static_Discriminated_Components;
1016
1017    --  Start of processing for Check_Compile_Time_Size
1018
1019    begin
1020       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1021    end Check_Compile_Time_Size;
1022
1023    -----------------------------
1024    -- Check_Debug_Info_Needed --
1025    -----------------------------
1026
1027    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1028    begin
1029       if Debug_Info_Off (T) then
1030          return;
1031
1032       elsif Comes_From_Source (T)
1033         or else Debug_Generated_Code
1034         or else Debug_Flag_VV
1035         or else Needs_Debug_Info (T)
1036       then
1037          Set_Debug_Info_Needed (T);
1038       end if;
1039    end Check_Debug_Info_Needed;
1040
1041    ----------------------------
1042    -- Check_Strict_Alignment --
1043    ----------------------------
1044
1045    procedure Check_Strict_Alignment (E : Entity_Id) is
1046       Comp  : Entity_Id;
1047
1048    begin
1049       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1050          Set_Strict_Alignment (E);
1051
1052       elsif Is_Array_Type (E) then
1053          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1054
1055       elsif Is_Record_Type (E) then
1056          if Is_Limited_Record (E) then
1057             Set_Strict_Alignment (E);
1058             return;
1059          end if;
1060
1061          Comp := First_Component (E);
1062          while Present (Comp) loop
1063             if not Is_Type (Comp)
1064               and then (Strict_Alignment (Etype (Comp))
1065                          or else Is_Aliased (Comp))
1066             then
1067                Set_Strict_Alignment (E);
1068                return;
1069             end if;
1070
1071             Next_Component (Comp);
1072          end loop;
1073       end if;
1074    end Check_Strict_Alignment;
1075
1076    -------------------------
1077    -- Check_Unsigned_Type --
1078    -------------------------
1079
1080    procedure Check_Unsigned_Type (E : Entity_Id) is
1081       Ancestor : Entity_Id;
1082       Lo_Bound : Node_Id;
1083       Btyp     : Entity_Id;
1084
1085    begin
1086       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1087          return;
1088       end if;
1089
1090       --  Do not attempt to analyze case where range was in error
1091
1092       if No (Scalar_Range (E))
1093         or else Error_Posted (Scalar_Range (E))
1094       then
1095          return;
1096       end if;
1097
1098       --  The situation that is non trivial is something like
1099
1100       --     subtype x1 is integer range -10 .. +10;
1101       --     subtype x2 is x1 range 0 .. V1;
1102       --     subtype x3 is x2 range V2 .. V3;
1103       --     subtype x4 is x3 range V4 .. V5;
1104
1105       --  where Vn are variables. Here the base type is signed, but we still
1106       --  know that x4 is unsigned because of the lower bound of x2.
1107
1108       --  The only way to deal with this is to look up the ancestor chain
1109
1110       Ancestor := E;
1111       loop
1112          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1113             return;
1114          end if;
1115
1116          Lo_Bound := Type_Low_Bound (Ancestor);
1117
1118          if Compile_Time_Known_Value (Lo_Bound) then
1119
1120             if Expr_Rep_Value (Lo_Bound) >= 0 then
1121                Set_Is_Unsigned_Type (E, True);
1122             end if;
1123
1124             return;
1125
1126          else
1127             Ancestor := Ancestor_Subtype (Ancestor);
1128
1129             --  If no ancestor had a static lower bound, go to base type
1130
1131             if No (Ancestor) then
1132
1133                --  Note: the reason we still check for a compile time known
1134                --  value for the base type is that at least in the case of
1135                --  generic formals, we can have bounds that fail this test,
1136                --  and there may be other cases in error situations.
1137
1138                Btyp := Base_Type (E);
1139
1140                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1141                   return;
1142                end if;
1143
1144                Lo_Bound := Type_Low_Bound (Base_Type (E));
1145
1146                if Compile_Time_Known_Value (Lo_Bound)
1147                  and then Expr_Rep_Value (Lo_Bound) >= 0
1148                then
1149                   Set_Is_Unsigned_Type (E, True);
1150                end if;
1151
1152                return;
1153             end if;
1154          end if;
1155       end loop;
1156    end Check_Unsigned_Type;
1157
1158    -------------------------
1159    -- Is_Atomic_Aggregate --
1160    -------------------------
1161
1162    function  Is_Atomic_Aggregate
1163      (E   : Entity_Id;
1164       Typ : Entity_Id) return Boolean
1165    is
1166       Loc   : constant Source_Ptr := Sloc (E);
1167       New_N : Node_Id;
1168       Par   : Node_Id;
1169       Temp  : Entity_Id;
1170
1171    begin
1172       Par := Parent (E);
1173
1174       --  Array may be qualified, so find outer context
1175
1176       if Nkind (Par) = N_Qualified_Expression then
1177          Par := Parent (Par);
1178       end if;
1179
1180       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1181         and then Comes_From_Source (Par)
1182       then
1183          Temp := Make_Temporary (Loc, 'T', E);
1184          New_N :=
1185            Make_Object_Declaration (Loc,
1186              Defining_Identifier => Temp,
1187              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1188              Expression          => Relocate_Node (E));
1189          Insert_Before (Par, New_N);
1190          Analyze (New_N);
1191
1192          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1193          return True;
1194
1195       else
1196          return False;
1197       end if;
1198    end Is_Atomic_Aggregate;
1199
1200    ----------------
1201    -- Freeze_All --
1202    ----------------
1203
1204    --  Note: the easy coding for this procedure would be to just build a
1205    --  single list of freeze nodes and then insert them and analyze them
1206    --  all at once. This won't work, because the analysis of earlier freeze
1207    --  nodes may recursively freeze types which would otherwise appear later
1208    --  on in the freeze list. So we must analyze and expand the freeze nodes
1209    --  as they are generated.
1210
1211    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1212       E     : Entity_Id;
1213       Decl  : Node_Id;
1214
1215       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1216       --  This is the internal recursive routine that does freezing of entities
1217       --  (but NOT the analysis of default expressions, which should not be
1218       --  recursive, we don't want to analyze those till we are sure that ALL
1219       --  the types are frozen).
1220
1221       --------------------
1222       -- Freeze_All_Ent --
1223       --------------------
1224
1225       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1226          E     : Entity_Id;
1227          Flist : List_Id;
1228          Lastn : Node_Id;
1229
1230          procedure Process_Flist;
1231          --  If freeze nodes are present, insert and analyze, and reset cursor
1232          --  for next insertion.
1233
1234          -------------------
1235          -- Process_Flist --
1236          -------------------
1237
1238          procedure Process_Flist is
1239          begin
1240             if Is_Non_Empty_List (Flist) then
1241                Lastn := Next (After);
1242                Insert_List_After_And_Analyze (After, Flist);
1243
1244                if Present (Lastn) then
1245                   After := Prev (Lastn);
1246                else
1247                   After := Last (List_Containing (After));
1248                end if;
1249             end if;
1250          end Process_Flist;
1251
1252       --  Start or processing for Freeze_All_Ent
1253
1254       begin
1255          E := From;
1256          while Present (E) loop
1257
1258             --  If the entity is an inner package which is not a package
1259             --  renaming, then its entities must be frozen at this point. Note
1260             --  that such entities do NOT get frozen at the end of the nested
1261             --  package itself (only library packages freeze).
1262
1263             --  Same is true for task declarations, where anonymous records
1264             --  created for entry parameters must be frozen.
1265
1266             if Ekind (E) = E_Package
1267               and then No (Renamed_Object (E))
1268               and then not Is_Child_Unit (E)
1269               and then not Is_Frozen (E)
1270             then
1271                Push_Scope (E);
1272                Install_Visible_Declarations (E);
1273                Install_Private_Declarations (E);
1274
1275                Freeze_All (First_Entity (E), After);
1276
1277                End_Package_Scope (E);
1278
1279             elsif Ekind (E) in Task_Kind
1280               and then
1281                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1282                    or else
1283                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1284             then
1285                Push_Scope (E);
1286                Freeze_All (First_Entity (E), After);
1287                End_Scope;
1288
1289             --  For a derived tagged type, we must ensure that all the
1290             --  primitive operations of the parent have been frozen, so that
1291             --  their addresses will be in the parent's dispatch table at the
1292             --  point it is inherited.
1293
1294             elsif Ekind (E) = E_Record_Type
1295               and then Is_Tagged_Type (E)
1296               and then Is_Tagged_Type (Etype (E))
1297               and then Is_Derived_Type (E)
1298             then
1299                declare
1300                   Prim_List : constant Elist_Id :=
1301                                Primitive_Operations (Etype (E));
1302
1303                   Prim : Elmt_Id;
1304                   Subp : Entity_Id;
1305
1306                begin
1307                   Prim  := First_Elmt (Prim_List);
1308                   while Present (Prim) loop
1309                      Subp := Node (Prim);
1310
1311                      if Comes_From_Source (Subp)
1312                        and then not Is_Frozen (Subp)
1313                      then
1314                         Flist := Freeze_Entity (Subp, After);
1315                         Process_Flist;
1316                      end if;
1317
1318                      Next_Elmt (Prim);
1319                   end loop;
1320                end;
1321             end if;
1322
1323             if not Is_Frozen (E) then
1324                Flist := Freeze_Entity (E, After);
1325                Process_Flist;
1326             end if;
1327
1328             --  If an incomplete type is still not frozen, this may be a
1329             --  premature freezing because of a body declaration that follows.
1330             --  Indicate where the freezing took place.
1331
1332             --  If the freezing is caused by the end of the current declarative
1333             --  part, it is a Taft Amendment type, and there is no error.
1334
1335             if not Is_Frozen (E)
1336               and then Ekind (E) = E_Incomplete_Type
1337             then
1338                declare
1339                   Bod : constant Node_Id := Next (After);
1340
1341                begin
1342                   if (Nkind_In (Bod, N_Subprogram_Body,
1343                                      N_Entry_Body,
1344                                      N_Package_Body,
1345                                      N_Protected_Body,
1346                                      N_Task_Body)
1347                         or else Nkind (Bod) in N_Body_Stub)
1348                      and then
1349                        List_Containing (After) = List_Containing (Parent (E))
1350                   then
1351                      Error_Msg_Sloc := Sloc (Next (After));
1352                      Error_Msg_NE
1353                        ("type& is frozen# before its full declaration",
1354                          Parent (E), E);
1355                   end if;
1356                end;
1357             end if;
1358
1359             Next_Entity (E);
1360          end loop;
1361       end Freeze_All_Ent;
1362
1363    --  Start of processing for Freeze_All
1364
1365    begin
1366       Freeze_All_Ent (From, After);
1367
1368       --  Now that all types are frozen, we can deal with default expressions
1369       --  that require us to build a default expression functions. This is the
1370       --  point at which such functions are constructed (after all types that
1371       --  might be used in such expressions have been frozen).
1372
1373       --  For subprograms that are renaming_as_body, we create the wrapper
1374       --  bodies as needed.
1375
1376       --  We also add finalization chains to access types whose designated
1377       --  types are controlled. This is normally done when freezing the type,
1378       --  but this misses recursive type definitions where the later members
1379       --  of the recursion introduce controlled components.
1380
1381       --  Loop through entities
1382
1383       E := From;
1384       while Present (E) loop
1385          if Is_Subprogram (E) then
1386
1387             if not Default_Expressions_Processed (E) then
1388                Process_Default_Expressions (E, After);
1389             end if;
1390
1391             if not Has_Completion (E) then
1392                Decl := Unit_Declaration_Node (E);
1393
1394                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1395                   Build_And_Analyze_Renamed_Body (Decl, E, After);
1396
1397                elsif Nkind (Decl) = N_Subprogram_Declaration
1398                  and then Present (Corresponding_Body (Decl))
1399                  and then
1400                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1401                                           = N_Subprogram_Renaming_Declaration
1402                then
1403                   Build_And_Analyze_Renamed_Body
1404                     (Decl, Corresponding_Body (Decl), After);
1405                end if;
1406             end if;
1407
1408          elsif Ekind (E) in Task_Kind
1409            and then
1410              (Nkind (Parent (E)) = N_Task_Type_Declaration
1411                 or else
1412               Nkind (Parent (E)) = N_Single_Task_Declaration)
1413          then
1414             declare
1415                Ent : Entity_Id;
1416
1417             begin
1418                Ent := First_Entity (E);
1419                while Present (Ent) loop
1420                   if Is_Entry (Ent)
1421                     and then not Default_Expressions_Processed (Ent)
1422                   then
1423                      Process_Default_Expressions (Ent, After);
1424                   end if;
1425
1426                   Next_Entity (Ent);
1427                end loop;
1428             end;
1429
1430          elsif Is_Access_Type (E)
1431            and then Comes_From_Source (E)
1432            and then Ekind (Directly_Designated_Type (E)) = E_Incomplete_Type
1433            and then Needs_Finalization (Designated_Type (E))
1434            and then No (Associated_Final_Chain (E))
1435          then
1436             Build_Final_List (Parent (E), E);
1437          end if;
1438
1439          Next_Entity (E);
1440       end loop;
1441    end Freeze_All;
1442
1443    -----------------------
1444    -- Freeze_And_Append --
1445    -----------------------
1446
1447    procedure Freeze_And_Append
1448      (Ent    : Entity_Id;
1449       N      : Node_Id;
1450       Result : in out List_Id)
1451    is
1452       L : constant List_Id := Freeze_Entity (Ent, N);
1453    begin
1454       if Is_Non_Empty_List (L) then
1455          if Result = No_List then
1456             Result := L;
1457          else
1458             Append_List (L, Result);
1459          end if;
1460       end if;
1461    end Freeze_And_Append;
1462
1463    -------------------
1464    -- Freeze_Before --
1465    -------------------
1466
1467    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1468       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1469    begin
1470       if Is_Non_Empty_List (Freeze_Nodes) then
1471          Insert_Actions (N, Freeze_Nodes);
1472       end if;
1473    end Freeze_Before;
1474
1475    -------------------
1476    -- Freeze_Entity --
1477    -------------------
1478
1479    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1480       Loc    : constant Source_Ptr := Sloc (N);
1481       Test_E : Entity_Id := E;
1482       Comp   : Entity_Id;
1483       F_Node : Node_Id;
1484       Result : List_Id;
1485       Indx   : Node_Id;
1486       Formal : Entity_Id;
1487       Atype  : Entity_Id;
1488
1489       Has_Default_Initialization : Boolean := False;
1490       --  This flag gets set to true for a variable with default initialization
1491
1492       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1493       --  Check that an Access or Unchecked_Access attribute with a prefix
1494       --  which is the current instance type can only be applied when the type
1495       --  is limited.
1496
1497       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1498       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1499       --  integer literal without an explicit corresponding size clause. The
1500       --  caller has checked that Utype is a modular integer type.
1501
1502       function After_Last_Declaration return Boolean;
1503       --  If Loc is a freeze_entity that appears after the last declaration
1504       --  in the scope, inhibit error messages on late completion.
1505
1506       procedure Freeze_Record_Type (Rec : Entity_Id);
1507       --  Freeze each component, handle some representation clauses, and freeze
1508       --  primitive operations if this is a tagged type.
1509
1510       ----------------------------
1511       -- After_Last_Declaration --
1512       ----------------------------
1513
1514       function After_Last_Declaration return Boolean is
1515          Spec : constant Node_Id := Parent (Current_Scope);
1516       begin
1517          if Nkind (Spec) = N_Package_Specification then
1518             if Present (Private_Declarations (Spec)) then
1519                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1520             elsif Present (Visible_Declarations (Spec)) then
1521                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1522             else
1523                return False;
1524             end if;
1525          else
1526             return False;
1527          end if;
1528       end After_Last_Declaration;
1529
1530       ----------------------------
1531       -- Check_Current_Instance --
1532       ----------------------------
1533
1534       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1535
1536          Rec_Type : constant Entity_Id :=
1537                       Scope (Defining_Identifier (Comp_Decl));
1538
1539          Decl : constant Node_Id := Parent (Rec_Type);
1540
1541          function Process (N : Node_Id) return Traverse_Result;
1542          --  Process routine to apply check to given node
1543
1544          -------------
1545          -- Process --
1546          -------------
1547
1548          function Process (N : Node_Id) return Traverse_Result is
1549          begin
1550             case Nkind (N) is
1551                when N_Attribute_Reference =>
1552                   if (Attribute_Name (N) = Name_Access
1553                         or else
1554                       Attribute_Name (N) = Name_Unchecked_Access)
1555                     and then Is_Entity_Name (Prefix (N))
1556                     and then Is_Type (Entity (Prefix (N)))
1557                     and then Entity (Prefix (N)) = E
1558                   then
1559                      Error_Msg_N
1560                        ("current instance must be a limited type", Prefix (N));
1561                      return Abandon;
1562                   else
1563                      return OK;
1564                   end if;
1565
1566                when others => return OK;
1567             end case;
1568          end Process;
1569
1570          procedure Traverse is new Traverse_Proc (Process);
1571
1572       --  Start of processing for Check_Current_Instance
1573
1574       begin
1575          --  In Ada95, the (imprecise) rule is that the current instance of a
1576          --  limited type is aliased. In Ada2005, limitedness must be explicit:
1577          --  either a tagged type, or a limited record.
1578
1579          if Is_Limited_Type (Rec_Type)
1580            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1581          then
1582             return;
1583
1584          elsif Nkind (Decl) = N_Full_Type_Declaration
1585            and then Limited_Present (Type_Definition (Decl))
1586          then
1587             return;
1588
1589          else
1590             Traverse (Comp_Decl);
1591          end if;
1592       end Check_Current_Instance;
1593
1594       ------------------------------
1595       -- Check_Suspicious_Modulus --
1596       ------------------------------
1597
1598       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1599          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1600
1601       begin
1602          if Nkind (Decl) = N_Full_Type_Declaration then
1603             declare
1604                Tdef : constant Node_Id := Type_Definition (Decl);
1605             begin
1606                if Nkind (Tdef) = N_Modular_Type_Definition then
1607                   declare
1608                      Modulus : constant Node_Id :=
1609                                  Original_Node (Expression (Tdef));
1610                   begin
1611                      if Nkind (Modulus) = N_Integer_Literal then
1612                         declare
1613                            Modv : constant Uint := Intval (Modulus);
1614                            Sizv : constant Uint := RM_Size (Utype);
1615
1616                         begin
1617                            --  First case, modulus and size are the same. This
1618                            --  happens if you have something like mod 32, with
1619                            --  an explicit size of 32, this is for sure a case
1620                            --  where the warning is given, since it is seems
1621                            --  very unlikely that someone would want e.g. a
1622                            --  five bit type stored in 32 bits. It is much
1623                            --  more likely they wanted a 32-bit type.
1624
1625                            if Modv = Sizv then
1626                               null;
1627
1628                            --  Second case, the modulus is 32 or 64 and no
1629                            --  size clause is present. This is a less clear
1630                            --  case for giving the warning, but in the case
1631                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1632                            --  enough that it is a likely error (and in any
1633                            --  case using 2**5 or 2**6 in these cases seems
1634                            --  clearer. We don't include 8 or 16 here, simply
1635                            --  because in practice 3-bit and 4-bit types are
1636                            --  more common and too many false positives if
1637                            --  we warn in these cases.
1638
1639                            elsif not Has_Size_Clause (Utype)
1640                              and then (Modv = Uint_32 or else Modv = Uint_64)
1641                            then
1642                               null;
1643
1644                            --  No warning needed
1645
1646                            else
1647                               return;
1648                            end if;
1649
1650                            --  If we fall through, give warning
1651
1652                            Error_Msg_Uint_1 := Modv;
1653                            Error_Msg_N
1654                              ("?2 '*'*^' may have been intended here",
1655                               Modulus);
1656                         end;
1657                      end if;
1658                   end;
1659                end if;
1660             end;
1661          end if;
1662       end Check_Suspicious_Modulus;
1663
1664       ------------------------
1665       -- Freeze_Record_Type --
1666       ------------------------
1667
1668       procedure Freeze_Record_Type (Rec : Entity_Id) is
1669          Comp : Entity_Id;
1670          IR   : Node_Id;
1671          ADC  : Node_Id;
1672          Prev : Entity_Id;
1673
1674          Junk : Boolean;
1675          pragma Warnings (Off, Junk);
1676
1677          Unplaced_Component : Boolean := False;
1678          --  Set True if we find at least one component with no component
1679          --  clause (used to warn about useless Pack pragmas).
1680
1681          Placed_Component : Boolean := False;
1682          --  Set True if we find at least one component with a component
1683          --  clause (used to warn about useless Bit_Order pragmas, and also
1684          --  to detect cases where Implicit_Packing may have an effect).
1685
1686          All_Scalar_Components : Boolean := True;
1687          --  Set False if we encounter a component of a non-scalar type
1688
1689          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1690          Scalar_Component_Total_Esize   : Uint := Uint_0;
1691          --  Accumulates total RM_Size values and total Esize values of all
1692          --  scalar components. Used for processing of Implicit_Packing.
1693
1694          function Check_Allocator (N : Node_Id) return Node_Id;
1695          --  If N is an allocator, possibly wrapped in one or more level of
1696          --  qualified expression(s), return the inner allocator node, else
1697          --  return Empty.
1698
1699          procedure Check_Itype (Typ : Entity_Id);
1700          --  If the component subtype is an access to a constrained subtype of
1701          --  an already frozen type, make the subtype frozen as well. It might
1702          --  otherwise be frozen in the wrong scope, and a freeze node on
1703          --  subtype has no effect. Similarly, if the component subtype is a
1704          --  regular (not protected) access to subprogram, set the anonymous
1705          --  subprogram type to frozen as well, to prevent an out-of-scope
1706          --  freeze node at some eventual point of call. Protected operations
1707          --  are handled elsewhere.
1708
1709          ---------------------
1710          -- Check_Allocator --
1711          ---------------------
1712
1713          function Check_Allocator (N : Node_Id) return Node_Id is
1714             Inner : Node_Id;
1715          begin
1716             Inner := N;
1717             loop
1718                if Nkind (Inner) = N_Allocator then
1719                   return Inner;
1720                elsif Nkind (Inner) = N_Qualified_Expression then
1721                   Inner := Expression (Inner);
1722                else
1723                   return Empty;
1724                end if;
1725             end loop;
1726          end Check_Allocator;
1727
1728          -----------------
1729          -- Check_Itype --
1730          -----------------
1731
1732          procedure Check_Itype (Typ : Entity_Id) is
1733             Desig : constant Entity_Id := Designated_Type (Typ);
1734
1735          begin
1736             if not Is_Frozen (Desig)
1737               and then Is_Frozen (Base_Type (Desig))
1738             then
1739                Set_Is_Frozen (Desig);
1740
1741                --  In addition, add an Itype_Reference to ensure that the
1742                --  access subtype is elaborated early enough. This cannot be
1743                --  done if the subtype may depend on discriminants.
1744
1745                if Ekind (Comp) = E_Component
1746                  and then Is_Itype (Etype (Comp))
1747                  and then not Has_Discriminants (Rec)
1748                then
1749                   IR := Make_Itype_Reference (Sloc (Comp));
1750                   Set_Itype (IR, Desig);
1751
1752                   if No (Result) then
1753                      Result := New_List (IR);
1754                   else
1755                      Append (IR, Result);
1756                   end if;
1757                end if;
1758
1759             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1760               and then Convention (Desig) /= Convention_Protected
1761             then
1762                Set_Is_Frozen (Desig);
1763             end if;
1764          end Check_Itype;
1765
1766       --  Start of processing for Freeze_Record_Type
1767
1768       begin
1769          --  If this is a subtype of a controlled type, declared without a
1770          --  constraint, the _controller may not appear in the component list
1771          --  if the parent was not frozen at the point of subtype declaration.
1772          --  Inherit the _controller component now.
1773
1774          if Rec /= Base_Type (Rec)
1775            and then Has_Controlled_Component (Rec)
1776          then
1777             if Nkind (Parent (Rec)) = N_Subtype_Declaration
1778               and then Is_Entity_Name (Subtype_Indication (Parent (Rec)))
1779             then
1780                Set_First_Entity (Rec, First_Entity (Base_Type (Rec)));
1781
1782             --  If this is an internal type without a declaration, as for
1783             --  record component, the base type may not yet be frozen, and its
1784             --  controller has not been created. Add an explicit freeze node
1785             --  for the itype, so it will be frozen after the base type. This
1786             --  freeze node is used to communicate with the expander, in order
1787             --  to create the controller for the enclosing record, and it is
1788             --  deleted afterwards (see exp_ch3). It must not be created when
1789             --  expansion is off, because it might appear in the wrong context
1790             --  for the back end.
1791
1792             elsif Is_Itype (Rec)
1793               and then Has_Delayed_Freeze (Base_Type (Rec))
1794               and then
1795                 Nkind (Associated_Node_For_Itype (Rec)) =
1796                                                      N_Component_Declaration
1797               and then Expander_Active
1798             then
1799                Ensure_Freeze_Node (Rec);
1800             end if;
1801          end if;
1802
1803          --  Freeze components and embedded subtypes
1804
1805          Comp := First_Entity (Rec);
1806          Prev := Empty;
1807          while Present (Comp) loop
1808
1809             --  First handle the component case
1810
1811             if Ekind (Comp) = E_Component
1812               or else Ekind (Comp) = E_Discriminant
1813             then
1814                declare
1815                   CC : constant Node_Id := Component_Clause (Comp);
1816
1817                begin
1818                   --  Freezing a record type freezes the type of each of its
1819                   --  components. However, if the type of the component is
1820                   --  part of this record, we do not want or need a separate
1821                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1822                   --  also set in private type cases. We also can't check for
1823                   --  the Scope being exactly Rec because of private types and
1824                   --  record extensions.
1825
1826                   if Is_Itype (Etype (Comp))
1827                     and then Is_Record_Type (Underlying_Type
1828                                              (Scope (Etype (Comp))))
1829                   then
1830                      Undelay_Type (Etype (Comp));
1831                   end if;
1832
1833                   Freeze_And_Append (Etype (Comp), N, Result);
1834
1835                   --  Check for error of component clause given for variable
1836                   --  sized type. We have to delay this test till this point,
1837                   --  since the component type has to be frozen for us to know
1838                   --  if it is variable length. We omit this test in a generic
1839                   --  context, it will be applied at instantiation time.
1840
1841                   if Present (CC) then
1842                      Placed_Component := True;
1843
1844                      if Inside_A_Generic then
1845                         null;
1846
1847                      elsif not
1848                        Size_Known_At_Compile_Time
1849                          (Underlying_Type (Etype (Comp)))
1850                      then
1851                         Error_Msg_N
1852                           ("component clause not allowed for variable " &
1853                            "length component", CC);
1854                      end if;
1855
1856                   else
1857                      Unplaced_Component := True;
1858                   end if;
1859
1860                   --  Case of component requires byte alignment
1861
1862                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1863
1864                      --  Set the enclosing record to also require byte align
1865
1866                      Set_Must_Be_On_Byte_Boundary (Rec);
1867
1868                      --  Check for component clause that is inconsistent with
1869                      --  the required byte boundary alignment.
1870
1871                      if Present (CC)
1872                        and then Normalized_First_Bit (Comp) mod
1873                                   System_Storage_Unit /= 0
1874                      then
1875                         Error_Msg_N
1876                           ("component & must be byte aligned",
1877                            Component_Name (Component_Clause (Comp)));
1878                      end if;
1879                   end if;
1880                end;
1881             end if;
1882
1883             --  Gather data for possible Implicit_Packing later. Note that at
1884             --  this stage we might be dealing with a real component, or with
1885             --  an implicit subtype declaration.
1886
1887             if not Is_Scalar_Type (Etype (Comp)) then
1888                All_Scalar_Components := False;
1889             else
1890                Scalar_Component_Total_RM_Size :=
1891                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1892                Scalar_Component_Total_Esize :=
1893                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1894             end if;
1895
1896             --  If the component is an Itype with Delayed_Freeze and is either
1897             --  a record or array subtype and its base type has not yet been
1898             --  frozen, we must remove this from the entity list of this record
1899             --  and put it on the entity list of the scope of its base type.
1900             --  Note that we know that this is not the type of a component
1901             --  since we cleared Has_Delayed_Freeze for it in the previous
1902             --  loop. Thus this must be the Designated_Type of an access type,
1903             --  which is the type of a component.
1904
1905             if Is_Itype (Comp)
1906               and then Is_Type (Scope (Comp))
1907               and then Is_Composite_Type (Comp)
1908               and then Base_Type (Comp) /= Comp
1909               and then Has_Delayed_Freeze (Comp)
1910               and then not Is_Frozen (Base_Type (Comp))
1911             then
1912                declare
1913                   Will_Be_Frozen : Boolean := False;
1914                   S              : Entity_Id;
1915
1916                begin
1917                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1918                   --  being defined in a subprogram that's created as part of
1919                   --  the freezing of Rec'Base. In that case, we know that
1920                   --  Comp'Base must have already been frozen by the time we
1921                   --  get to elaborate this because Gigi doesn't elaborate any
1922                   --  bodies until it has elaborated all of the declarative
1923                   --  part. But Is_Frozen will not be set at this point because
1924                   --  we are processing code in lexical order.
1925
1926                   --  We detect this case by going up the Scope chain of Rec
1927                   --  and seeing if we have a subprogram scope before reaching
1928                   --  the top of the scope chain or that of Comp'Base. If we
1929                   --  do, then mark that Comp'Base will actually be frozen. If
1930                   --  so, we merely undelay it.
1931
1932                   S := Scope (Rec);
1933                   while Present (S) loop
1934                      if Is_Subprogram (S) then
1935                         Will_Be_Frozen := True;
1936                         exit;
1937                      elsif S = Scope (Base_Type (Comp)) then
1938                         exit;
1939                      end if;
1940
1941                      S := Scope (S);
1942                   end loop;
1943
1944                   if Will_Be_Frozen then
1945                      Undelay_Type (Comp);
1946                   else
1947                      if Present (Prev) then
1948                         Set_Next_Entity (Prev, Next_Entity (Comp));
1949                      else
1950                         Set_First_Entity (Rec, Next_Entity (Comp));
1951                      end if;
1952
1953                      --  Insert in entity list of scope of base type (which
1954                      --  must be an enclosing scope, because still unfrozen).
1955
1956                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1957                   end if;
1958                end;
1959
1960             --  If the component is an access type with an allocator as default
1961             --  value, the designated type will be frozen by the corresponding
1962             --  expression in init_proc. In order to place the freeze node for
1963             --  the designated type before that for the current record type,
1964             --  freeze it now.
1965
1966             --  Same process if the component is an array of access types,
1967             --  initialized with an aggregate. If the designated type is
1968             --  private, it cannot contain allocators, and it is premature
1969             --  to freeze the type, so we check for this as well.
1970
1971             elsif Is_Access_Type (Etype (Comp))
1972               and then Present (Parent (Comp))
1973               and then Present (Expression (Parent (Comp)))
1974             then
1975                declare
1976                   Alloc : constant Node_Id :=
1977                             Check_Allocator (Expression (Parent (Comp)));
1978
1979                begin
1980                   if Present (Alloc) then
1981
1982                      --  If component is pointer to a classwide type, freeze
1983                      --  the specific type in the expression being allocated.
1984                      --  The expression may be a subtype indication, in which
1985                      --  case freeze the subtype mark.
1986
1987                      if Is_Class_Wide_Type
1988                           (Designated_Type (Etype (Comp)))
1989                      then
1990                         if Is_Entity_Name (Expression (Alloc)) then
1991                            Freeze_And_Append
1992                              (Entity (Expression (Alloc)), N, Result);
1993                         elsif
1994                           Nkind (Expression (Alloc)) = N_Subtype_Indication
1995                         then
1996                            Freeze_And_Append
1997                             (Entity (Subtype_Mark (Expression (Alloc))),
1998                              N, Result);
1999                         end if;
2000
2001                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2002                         Check_Itype (Etype (Comp));
2003
2004                      else
2005                         Freeze_And_Append
2006                           (Designated_Type (Etype (Comp)), N, Result);
2007                      end if;
2008                   end if;
2009                end;
2010
2011             elsif Is_Access_Type (Etype (Comp))
2012               and then Is_Itype (Designated_Type (Etype (Comp)))
2013             then
2014                Check_Itype (Etype (Comp));
2015
2016             elsif Is_Array_Type (Etype (Comp))
2017               and then Is_Access_Type (Component_Type (Etype (Comp)))
2018               and then Present (Parent (Comp))
2019               and then Nkind (Parent (Comp)) = N_Component_Declaration
2020               and then Present (Expression (Parent (Comp)))
2021               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2022               and then Is_Fully_Defined
2023                  (Designated_Type (Component_Type (Etype (Comp))))
2024             then
2025                Freeze_And_Append
2026                  (Designated_Type
2027                    (Component_Type (Etype (Comp))), N, Result);
2028             end if;
2029
2030             Prev := Comp;
2031             Next_Entity (Comp);
2032          end loop;
2033
2034          --  Deal with pragma Bit_Order setting non-standard bit order
2035
2036          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2037             if not Placed_Component then
2038                ADC :=
2039                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2040                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2041                Error_Msg_N
2042                  ("\?since no component clauses were specified", ADC);
2043
2044             --  Here is where we do the processing for reversed bit order
2045
2046             else
2047                Adjust_Record_For_Reverse_Bit_Order (Rec);
2048             end if;
2049          end if;
2050
2051          --  Complete error checking on record representation clause (e.g.
2052          --  overlap of components). This is called after adjusting the
2053          --  record for reverse bit order.
2054
2055          declare
2056             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2057          begin
2058             if Present (RRC) then
2059                Check_Record_Representation_Clause (RRC);
2060             end if;
2061          end;
2062
2063          --  Set OK_To_Reorder_Components depending on debug flags
2064
2065          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2066             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2067                   or else
2068                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2069             then
2070                Set_OK_To_Reorder_Components (Rec);
2071             end if;
2072          end if;
2073
2074          --  Check for useless pragma Pack when all components placed. We only
2075          --  do this check for record types, not subtypes, since a subtype may
2076          --  have all its components placed, and it still makes perfectly good
2077          --  sense to pack other subtypes or the parent type. We do not give
2078          --  this warning if Optimize_Alignment is set to Space, since the
2079          --  pragma Pack does have an effect in this case (it always resets
2080          --  the alignment to one).
2081
2082          if Ekind (Rec) = E_Record_Type
2083            and then Is_Packed (Rec)
2084            and then not Unplaced_Component
2085            and then Optimize_Alignment /= 'S'
2086          then
2087             --  Reset packed status. Probably not necessary, but we do it so
2088             --  that there is no chance of the back end doing something strange
2089             --  with this redundant indication of packing.
2090
2091             Set_Is_Packed (Rec, False);
2092
2093             --  Give warning if redundant constructs warnings on
2094
2095             if Warn_On_Redundant_Constructs then
2096                Error_Msg_N -- CODEFIX
2097                  ("?pragma Pack has no effect, no unplaced components",
2098                   Get_Rep_Pragma (Rec, Name_Pack));
2099             end if;
2100          end if;
2101
2102          --  If this is the record corresponding to a remote type, freeze the
2103          --  remote type here since that is what we are semantically freezing.
2104          --  This prevents the freeze node for that type in an inner scope.
2105
2106          --  Also, Check for controlled components and unchecked unions.
2107          --  Finally, enforce the restriction that access attributes with a
2108          --  current instance prefix can only apply to limited types.
2109
2110          if Ekind (Rec) = E_Record_Type then
2111             if Present (Corresponding_Remote_Type (Rec)) then
2112                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2113             end if;
2114
2115             Comp := First_Component (Rec);
2116             while Present (Comp) loop
2117
2118                --  Do not set Has_Controlled_Component on a class-wide
2119                --  equivalent type. See Make_CW_Equivalent_Type.
2120
2121                if not Is_Class_Wide_Equivalent_Type (Rec)
2122                  and then (Has_Controlled_Component (Etype (Comp))
2123                             or else (Chars (Comp) /= Name_uParent
2124                                       and then Is_Controlled (Etype (Comp)))
2125                             or else (Is_Protected_Type (Etype (Comp))
2126                                       and then Present
2127                                         (Corresponding_Record_Type
2128                                           (Etype (Comp)))
2129                                       and then Has_Controlled_Component
2130                                         (Corresponding_Record_Type
2131                                           (Etype (Comp)))))
2132                then
2133                   Set_Has_Controlled_Component (Rec);
2134                   exit;
2135                end if;
2136
2137                if Has_Unchecked_Union (Etype (Comp)) then
2138                   Set_Has_Unchecked_Union (Rec);
2139                end if;
2140
2141                if Has_Per_Object_Constraint (Comp) then
2142
2143                   --  Scan component declaration for likely misuses of current
2144                   --  instance, either in a constraint or a default expression.
2145
2146                   Check_Current_Instance (Parent (Comp));
2147                end if;
2148
2149                Next_Component (Comp);
2150             end loop;
2151          end if;
2152
2153          Set_Component_Alignment_If_Not_Set (Rec);
2154
2155          --  For first subtypes, check if there are any fixed-point fields with
2156          --  component clauses, where we must check the size. This is not done
2157          --  till the freeze point, since for fixed-point types, we do not know
2158          --  the size until the type is frozen. Similar processing applies to
2159          --  bit packed arrays.
2160
2161          if Is_First_Subtype (Rec) then
2162             Comp := First_Component (Rec);
2163             while Present (Comp) loop
2164                if Present (Component_Clause (Comp))
2165                  and then (Is_Fixed_Point_Type (Etype (Comp))
2166                              or else
2167                            Is_Bit_Packed_Array (Etype (Comp)))
2168                then
2169                   Check_Size
2170                     (Component_Name (Component_Clause (Comp)),
2171                      Etype (Comp),
2172                      Esize (Comp),
2173                      Junk);
2174                end if;
2175
2176                Next_Component (Comp);
2177             end loop;
2178          end if;
2179
2180          --  Generate warning for applying C or C++ convention to a record
2181          --  with discriminants. This is suppressed for the unchecked union
2182          --  case, since the whole point in this case is interface C. We also
2183          --  do not generate this within instantiations, since we will have
2184          --  generated a message on the template.
2185
2186          if Has_Discriminants (E)
2187            and then not Is_Unchecked_Union (E)
2188            and then (Convention (E) = Convention_C
2189                        or else
2190                      Convention (E) = Convention_CPP)
2191            and then Comes_From_Source (E)
2192            and then not In_Instance
2193            and then not Has_Warnings_Off (E)
2194            and then not Has_Warnings_Off (Base_Type (E))
2195          then
2196             declare
2197                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2198                A2    : Node_Id;
2199
2200             begin
2201                if Present (Cprag) then
2202                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2203
2204                   if Convention (E) = Convention_C then
2205                      Error_Msg_N
2206                        ("?variant record has no direct equivalent in C", A2);
2207                   else
2208                      Error_Msg_N
2209                        ("?variant record has no direct equivalent in C++", A2);
2210                   end if;
2211
2212                   Error_Msg_NE
2213                     ("\?use of convention for type& is dubious", A2, E);
2214                end if;
2215             end;
2216          end if;
2217
2218          --  See if Size is too small as is (and implicit packing might help)
2219
2220          if not Is_Packed (Rec)
2221
2222            --  No implicit packing if even one component is explicitly placed
2223
2224            and then not Placed_Component
2225
2226            --  Must have size clause and all scalar components
2227
2228            and then Has_Size_Clause (Rec)
2229            and then All_Scalar_Components
2230
2231            --  Do not try implicit packing on records with discriminants, too
2232            --  complicated, especially in the variant record case.
2233
2234            and then not Has_Discriminants (Rec)
2235
2236            --  We can implicitly pack if the specified size of the record is
2237            --  less than the sum of the object sizes (no point in packing if
2238            --  this is not the case).
2239
2240            and then Esize (Rec) < Scalar_Component_Total_Esize
2241
2242            --  And the total RM size cannot be greater than the specified size
2243            --  since otherwise packing will not get us where we have to be!
2244
2245            and then Esize (Rec) >= Scalar_Component_Total_RM_Size
2246
2247            --  Never do implicit packing in CodePeer mode since we don't do
2248            --  any packing in this mode, since this generates over-complex
2249            --  code that confuses CodePeer, and in general, CodePeer does not
2250            --  care about the internal representation of objects.
2251
2252            and then not CodePeer_Mode
2253          then
2254             --  If implicit packing enabled, do it
2255
2256             if Implicit_Packing then
2257                Set_Is_Packed (Rec);
2258
2259                --  Otherwise flag the size clause
2260
2261             else
2262                declare
2263                   Sz : constant Node_Id := Size_Clause (Rec);
2264                begin
2265                   Error_Msg_NE -- CODEFIX
2266                     ("size given for& too small", Sz, Rec);
2267                   Error_Msg_N -- CODEFIX
2268                     ("\use explicit pragma Pack "
2269                      & "or use pragma Implicit_Packing", Sz);
2270                end;
2271             end if;
2272          end if;
2273       end Freeze_Record_Type;
2274
2275    --  Start of processing for Freeze_Entity
2276
2277    begin
2278       --  We are going to test for various reasons why this entity need not be
2279       --  frozen here, but in the case of an Itype that's defined within a
2280       --  record, that test actually applies to the record.
2281
2282       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2283          Test_E := Scope (E);
2284       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2285         and then Is_Record_Type (Underlying_Type (Scope (E)))
2286       then
2287          Test_E := Underlying_Type (Scope (E));
2288       end if;
2289
2290       --  Do not freeze if already frozen since we only need one freeze node
2291
2292       if Is_Frozen (E) then
2293          return No_List;
2294
2295       --  It is improper to freeze an external entity within a generic because
2296       --  its freeze node will appear in a non-valid context. The entity will
2297       --  be frozen in the proper scope after the current generic is analyzed.
2298
2299       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2300          return No_List;
2301
2302       --  Do not freeze a global entity within an inner scope created during
2303       --  expansion. A call to subprogram E within some internal procedure
2304       --  (a stream attribute for example) might require freezing E, but the
2305       --  freeze node must appear in the same declarative part as E itself.
2306       --  The two-pass elaboration mechanism in gigi guarantees that E will
2307       --  be frozen before the inner call is elaborated. We exclude constants
2308       --  from this test, because deferred constants may be frozen early, and
2309       --  must be diagnosed (e.g. in the case of a deferred constant being used
2310       --  in a default expression). If the enclosing subprogram comes from
2311       --  source, or is a generic instance, then the freeze point is the one
2312       --  mandated by the language, and we freeze the entity. A subprogram that
2313       --  is a child unit body that acts as a spec does not have a spec that
2314       --  comes from source, but can only come from source.
2315
2316       elsif In_Open_Scopes (Scope (Test_E))
2317         and then Scope (Test_E) /= Current_Scope
2318         and then Ekind (Test_E) /= E_Constant
2319       then
2320          declare
2321             S : Entity_Id;
2322
2323          begin
2324             S := Current_Scope;
2325             while Present (S) loop
2326                if Is_Overloadable (S) then
2327                   if Comes_From_Source (S)
2328                     or else Is_Generic_Instance (S)
2329                     or else Is_Child_Unit (S)
2330                   then
2331                      exit;
2332                   else
2333                      return No_List;
2334                   end if;
2335                end if;
2336
2337                S := Scope (S);
2338             end loop;
2339          end;
2340
2341       --  Similarly, an inlined instance body may make reference to global
2342       --  entities, but these references cannot be the proper freezing point
2343       --  for them, and in the absence of inlining freezing will take place in
2344       --  their own scope. Normally instance bodies are analyzed after the
2345       --  enclosing compilation, and everything has been frozen at the proper
2346       --  place, but with front-end inlining an instance body is compiled
2347       --  before the end of the enclosing scope, and as a result out-of-order
2348       --  freezing must be prevented.
2349
2350       elsif Front_End_Inlining
2351         and then In_Instance_Body
2352         and then Present (Scope (Test_E))
2353       then
2354          declare
2355             S : Entity_Id;
2356
2357          begin
2358             S := Scope (Test_E);
2359             while Present (S) loop
2360                if Is_Generic_Instance (S) then
2361                   exit;
2362                else
2363                   S := Scope (S);
2364                end if;
2365             end loop;
2366
2367             if No (S) then
2368                return No_List;
2369             end if;
2370          end;
2371       end if;
2372
2373       --  Deal with delayed aspect specifications. The analysis of the aspect
2374       --  is required to be delayed to the freeze point, so we evaluate the
2375       --  pragma or attribute definition clause in the tree at this point.
2376
2377       --  We also have to deal with the case of Boolean aspects, where the
2378       --  value of the Boolean expression is represented by the setting of
2379       --  the Aspect_Cancel flag on the pragma.
2380
2381       if Has_Delayed_Aspects (E) then
2382          declare
2383             Ritem : Node_Id;
2384             Aitem : Node_Id;
2385
2386          begin
2387             --  Look for aspect specification entries for this entity
2388
2389             Ritem := First_Rep_Item (E);
2390             while Present (Ritem) loop
2391                if Nkind (Ritem) = N_Aspect_Specification
2392                  and then Entity (Ritem) = E
2393                then
2394                   Aitem := Aspect_Rep_Item (Ritem);
2395                   pragma Assert (Is_Delayed_Aspect (Aitem));
2396                   Set_Parent (Aitem, Ritem);
2397
2398                   --  Deal with Boolean case, if no expression, True, otherwise
2399                   --  analyze the expression, check it is static, and if its
2400                   --  value is False, set Aspect_Cancel for the related pragma.
2401
2402                   if Is_Boolean_Aspect (Ritem) then
2403                      declare
2404                         Expr : constant Node_Id := Expression (Ritem);
2405
2406                      begin
2407                         if Present (Expr) then
2408                            Analyze_And_Resolve (Expr, Standard_Boolean);
2409
2410                            if not Is_OK_Static_Expression (Expr) then
2411                               Error_Msg_Name_1 := Chars (Identifier (Ritem));
2412                               Error_Msg_N
2413                                 ("expression for % aspect must be static",
2414                                  Expr);
2415
2416                            elsif Is_False (Expr_Value (Expr)) then
2417                               Set_Aspect_Cancel (Aitem);
2418                            end if;
2419                         end if;
2420                      end;
2421                   end if;
2422
2423                   --  Analyze the pragma after possibly setting Aspect_Cancel
2424
2425                   Analyze (Aitem);
2426                end if;
2427
2428                Next_Rep_Item (Ritem);
2429             end loop;
2430          end;
2431       end if;
2432
2433       --  Here to freeze the entity
2434
2435       Result := No_List;
2436       Set_Is_Frozen (E);
2437
2438       --  Case of entity being frozen is other than a type
2439
2440       if not Is_Type (E) then
2441
2442          --  If entity is exported or imported and does not have an external
2443          --  name, now is the time to provide the appropriate default name.
2444          --  Skip this if the entity is stubbed, since we don't need a name
2445          --  for any stubbed routine. For the case on intrinsics, if no
2446          --  external name is specified, then calls will be handled in
2447          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2448          --  external name is provided, then Expand_Intrinsic_Call leaves
2449          --  calls in place for expansion by GIGI.
2450
2451          if (Is_Imported (E) or else Is_Exported (E))
2452            and then No (Interface_Name (E))
2453            and then Convention (E) /= Convention_Stubbed
2454            and then Convention (E) /= Convention_Intrinsic
2455          then
2456             Set_Encoded_Interface_Name
2457               (E, Get_Default_External_Name (E));
2458
2459          --  If entity is an atomic object appearing in a declaration and
2460          --  the expression is an aggregate, assign it to a temporary to
2461          --  ensure that the actual assignment is done atomically rather
2462          --  than component-wise (the assignment to the temp may be done
2463          --  component-wise, but that is harmless).
2464
2465          elsif Is_Atomic (E)
2466            and then Nkind (Parent (E)) = N_Object_Declaration
2467            and then Present (Expression (Parent (E)))
2468            and then Nkind (Expression (Parent (E))) = N_Aggregate
2469            and then
2470              Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2471          then
2472             null;
2473          end if;
2474
2475          --  For a subprogram, freeze all parameter types and also the return
2476          --  type (RM 13.14(14)). However skip this for internal subprograms.
2477          --  This is also the point where any extra formal parameters are
2478          --  created since we now know whether the subprogram will use a
2479          --  foreign convention.
2480
2481          if Is_Subprogram (E) then
2482             if not Is_Internal (E) then
2483                declare
2484                   F_Type    : Entity_Id;
2485                   R_Type    : Entity_Id;
2486                   Warn_Node : Node_Id;
2487
2488                begin
2489                   --  Loop through formals
2490
2491                   Formal := First_Formal (E);
2492                   while Present (Formal) loop
2493                      F_Type := Etype (Formal);
2494                      Freeze_And_Append (F_Type, N, Result);
2495
2496                      if Is_Private_Type (F_Type)
2497                        and then Is_Private_Type (Base_Type (F_Type))
2498                        and then No (Full_View (Base_Type (F_Type)))
2499                        and then not Is_Generic_Type (F_Type)
2500                        and then not Is_Derived_Type (F_Type)
2501                      then
2502                         --  If the type of a formal is incomplete, subprogram
2503                         --  is being frozen prematurely. Within an instance
2504                         --  (but not within a wrapper package) this is an
2505                         --  artifact of our need to regard the end of an
2506                         --  instantiation as a freeze point. Otherwise it is
2507                         --  a definite error.
2508
2509                         if In_Instance then
2510                            Set_Is_Frozen (E, False);
2511                            return No_List;
2512
2513                         elsif not After_Last_Declaration
2514                           and then not Freezing_Library_Level_Tagged_Type
2515                         then
2516                            Error_Msg_Node_1 := F_Type;
2517                            Error_Msg
2518                              ("type& must be fully defined before this point",
2519                                Loc);
2520                         end if;
2521                      end if;
2522
2523                      --  Check suspicious parameter for C function. These tests
2524                      --  apply only to exported/imported subprograms.
2525
2526                      if Warn_On_Export_Import
2527                        and then Comes_From_Source (E)
2528                        and then (Convention (E) = Convention_C
2529                                    or else
2530                                  Convention (E) = Convention_CPP)
2531                        and then (Is_Imported (E) or else Is_Exported (E))
2532                        and then Convention (E) /= Convention (Formal)
2533                        and then not Has_Warnings_Off (E)
2534                        and then not Has_Warnings_Off (F_Type)
2535                        and then not Has_Warnings_Off (Formal)
2536                      then
2537                         --  Qualify mention of formals with subprogram name
2538
2539                         Error_Msg_Qual_Level := 1;
2540
2541                         --  Check suspicious use of fat C pointer
2542
2543                         if Is_Access_Type (F_Type)
2544                           and then Esize (F_Type) > Ttypes.System_Address_Size
2545                         then
2546                            Error_Msg_N
2547                              ("?type of & does not correspond to C pointer!",
2548                               Formal);
2549
2550                         --  Check suspicious return of boolean
2551
2552                         elsif Root_Type (F_Type) = Standard_Boolean
2553                           and then Convention (F_Type) = Convention_Ada
2554                           and then not Has_Warnings_Off (F_Type)
2555                           and then not Has_Size_Clause (F_Type)
2556                           and then VM_Target = No_VM
2557                         then
2558                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2559                            Error_Msg_N
2560                              ("\use appropriate corresponding type in C "
2561                               & "(e.g. char)?", Formal);
2562
2563                         --  Check suspicious tagged type
2564
2565                         elsif (Is_Tagged_Type (F_Type)
2566                                 or else (Is_Access_Type (F_Type)
2567                                            and then
2568                                              Is_Tagged_Type
2569                                                (Designated_Type (F_Type))))
2570                           and then Convention (E) = Convention_C
2571                         then
2572                            Error_Msg_N
2573                              ("?& involves a tagged type which does not "
2574                               & "correspond to any C type!", Formal);
2575
2576                         --  Check wrong convention subprogram pointer
2577
2578                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2579                           and then not Has_Foreign_Convention (F_Type)
2580                         then
2581                            Error_Msg_N
2582                              ("?subprogram pointer & should "
2583                               & "have foreign convention!", Formal);
2584                            Error_Msg_Sloc := Sloc (F_Type);
2585                            Error_Msg_NE
2586                              ("\?add Convention pragma to declaration of &#",
2587                               Formal, F_Type);
2588                         end if;
2589
2590                         --  Turn off name qualification after message output
2591
2592                         Error_Msg_Qual_Level := 0;
2593                      end if;
2594
2595                      --  Check for unconstrained array in exported foreign
2596                      --  convention case.
2597
2598                      if Has_Foreign_Convention (E)
2599                        and then not Is_Imported (E)
2600                        and then Is_Array_Type (F_Type)
2601                        and then not Is_Constrained (F_Type)
2602                        and then Warn_On_Export_Import
2603
2604                        --  Exclude VM case, since both .NET and JVM can handle
2605                        --  unconstrained arrays without a problem.
2606
2607                        and then VM_Target = No_VM
2608                      then
2609                         Error_Msg_Qual_Level := 1;
2610
2611                         --  If this is an inherited operation, place the
2612                         --  warning on the derived type declaration, rather
2613                         --  than on the original subprogram.
2614
2615                         if Nkind (Original_Node (Parent (E))) =
2616                           N_Full_Type_Declaration
2617                         then
2618                            Warn_Node := Parent (E);
2619
2620                            if Formal = First_Formal (E) then
2621                               Error_Msg_NE
2622                                 ("?in inherited operation&", Warn_Node, E);
2623                            end if;
2624                         else
2625                            Warn_Node := Formal;
2626                         end if;
2627
2628                         Error_Msg_NE
2629                           ("?type of argument& is unconstrained array",
2630                            Warn_Node, Formal);
2631                         Error_Msg_NE
2632                           ("?foreign caller must pass bounds explicitly",
2633                            Warn_Node, Formal);
2634                         Error_Msg_Qual_Level := 0;
2635                      end if;
2636
2637                      if not From_With_Type (F_Type) then
2638                         if Is_Access_Type (F_Type) then
2639                            F_Type := Designated_Type (F_Type);
2640                         end if;
2641
2642                         --  If the formal is an anonymous_access_to_subprogram
2643                         --  freeze the  subprogram type as well, to prevent
2644                         --  scope anomalies in gigi, because there is no other
2645                         --  clear point at which it could be frozen.
2646
2647                         if Is_Itype (Etype (Formal))
2648                           and then Ekind (F_Type) = E_Subprogram_Type
2649                         then
2650                            Freeze_And_Append (F_Type, N, Result);
2651                         end if;
2652                      end if;
2653
2654                      Next_Formal (Formal);
2655                   end loop;
2656
2657                   --  Case of function: similar checks on return type
2658
2659                   if Ekind (E) = E_Function then
2660
2661                      --  Freeze return type
2662
2663                      R_Type := Etype (E);
2664                      Freeze_And_Append (R_Type, N, Result);
2665
2666                      --  Check suspicious return type for C function
2667
2668                      if Warn_On_Export_Import
2669                        and then (Convention (E) = Convention_C
2670                                    or else
2671                                  Convention (E) = Convention_CPP)
2672                        and then (Is_Imported (E) or else Is_Exported (E))
2673                      then
2674                         --  Check suspicious return of fat C pointer
2675
2676                         if Is_Access_Type (R_Type)
2677                           and then Esize (R_Type) > Ttypes.System_Address_Size
2678                           and then not Has_Warnings_Off (E)
2679                           and then not Has_Warnings_Off (R_Type)
2680                         then
2681                            Error_Msg_N
2682                              ("?return type of& does not "
2683                               & "correspond to C pointer!", E);
2684
2685                         --  Check suspicious return of boolean
2686
2687                         elsif Root_Type (R_Type) = Standard_Boolean
2688                           and then Convention (R_Type) = Convention_Ada
2689                           and then VM_Target = No_VM
2690                           and then not Has_Warnings_Off (E)
2691                           and then not Has_Warnings_Off (R_Type)
2692                           and then not Has_Size_Clause (R_Type)
2693                         then
2694                            declare
2695                               N : constant Node_Id :=
2696                                     Result_Definition (Declaration_Node (E));
2697                            begin
2698                               Error_Msg_NE
2699                                 ("return type of & is an 8-bit Ada Boolean?",
2700                                  N, E);
2701                               Error_Msg_NE
2702                                 ("\use appropriate corresponding type in C "
2703                                  & "(e.g. char)?", N, E);
2704                            end;
2705
2706                         --  Check suspicious return tagged type
2707
2708                         elsif (Is_Tagged_Type (R_Type)
2709                                 or else (Is_Access_Type (R_Type)
2710                                            and then
2711                                              Is_Tagged_Type
2712                                                (Designated_Type (R_Type))))
2713                           and then Convention (E) = Convention_C
2714                           and then not Has_Warnings_Off (E)
2715                           and then not Has_Warnings_Off (R_Type)
2716                         then
2717                            Error_Msg_N
2718                              ("?return type of & does not "
2719                               & "correspond to C type!", E);
2720
2721                         --  Check return of wrong convention subprogram pointer
2722
2723                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2724                           and then not Has_Foreign_Convention (R_Type)
2725                           and then not Has_Warnings_Off (E)
2726                           and then not Has_Warnings_Off (R_Type)
2727                         then
2728                            Error_Msg_N
2729                              ("?& should return a foreign "
2730                               & "convention subprogram pointer", E);
2731                            Error_Msg_Sloc := Sloc (R_Type);
2732                            Error_Msg_NE
2733                              ("\?add Convention pragma to declaration of& #",
2734                               E, R_Type);
2735                         end if;
2736                      end if;
2737
2738                      --  Give warning for suspicious return of a result of an
2739                      --  unconstrained array type in a foreign convention
2740                      --  function.
2741
2742                      if Has_Foreign_Convention (E)
2743
2744                        --  We are looking for a return of unconstrained array
2745
2746                        and then Is_Array_Type (R_Type)
2747                        and then not Is_Constrained (R_Type)
2748
2749                        --  Exclude imported routines, the warning does not
2750                        --  belong on the import, but on the routine definition.
2751
2752                        and then not Is_Imported (E)
2753
2754                        --  Exclude VM case, since both .NET and JVM can handle
2755                        --  return of unconstrained arrays without a problem.
2756
2757                        and then VM_Target = No_VM
2758
2759                        --  Check that general warning is enabled, and that it
2760                        --  is not suppressed for this particular case.
2761
2762                        and then Warn_On_Export_Import
2763                        and then not Has_Warnings_Off (E)
2764                        and then not Has_Warnings_Off (R_Type)
2765                      then
2766                         Error_Msg_N
2767                           ("?foreign convention function& should not " &
2768                            "return unconstrained array!", E);
2769                      end if;
2770                   end if;
2771                end;
2772             end if;
2773
2774             --  Must freeze its parent first if it is a derived subprogram
2775
2776             if Present (Alias (E)) then
2777                Freeze_And_Append (Alias (E), N, Result);
2778             end if;
2779
2780             --  We don't freeze internal subprograms, because we don't normally
2781             --  want addition of extra formals or mechanism setting to happen
2782             --  for those. However we do pass through predefined dispatching
2783             --  cases, since extra formals may be needed in some cases, such as
2784             --  for the stream 'Input function (build-in-place formals).
2785
2786             if not Is_Internal (E)
2787               or else Is_Predefined_Dispatching_Operation (E)
2788             then
2789                Freeze_Subprogram (E);
2790             end if;
2791
2792          --  Here for other than a subprogram or type
2793
2794          else
2795             --  If entity has a type, and it is not a generic unit, then
2796             --  freeze it first (RM 13.14(10)).
2797
2798             if Present (Etype (E))
2799               and then Ekind (E) /= E_Generic_Function
2800             then
2801                Freeze_And_Append (Etype (E), N, Result);
2802             end if;
2803
2804             --  Special processing for objects created by object declaration
2805
2806             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2807
2808                --  Abstract type allowed only for C++ imported variables or
2809                --  constants.
2810
2811                --  Note: we inhibit this check for objects that do not come
2812                --  from source because there is at least one case (the
2813                --  expansion of x'class'input where x is abstract) where we
2814                --  legitimately generate an abstract object.
2815
2816                if Is_Abstract_Type (Etype (E))
2817                  and then Comes_From_Source (Parent (E))
2818                  and then not (Is_Imported (E)
2819                                  and then Is_CPP_Class (Etype (E)))
2820                then
2821                   Error_Msg_N ("type of object cannot be abstract",
2822                                Object_Definition (Parent (E)));
2823
2824                   if Is_CPP_Class (Etype (E)) then
2825                      Error_Msg_NE
2826                        ("\} may need a cpp_constructor",
2827                        Object_Definition (Parent (E)), Etype (E));
2828                   end if;
2829                end if;
2830
2831                --  For object created by object declaration, perform required
2832                --  categorization (preelaborate and pure) checks. Defer these
2833                --  checks to freeze time since pragma Import inhibits default
2834                --  initialization and thus pragma Import affects these checks.
2835
2836                Validate_Object_Declaration (Declaration_Node (E));
2837
2838                --  If there is an address clause, check that it is valid
2839
2840                Check_Address_Clause (E);
2841
2842                --  If the object needs any kind of default initialization, an
2843                --  error must be issued if No_Default_Initialization applies.
2844                --  The check doesn't apply to imported objects, which are not
2845                --  ever default initialized, and is why the check is deferred
2846                --  until freezing, at which point we know if Import applies.
2847                --  Deferred constants are also exempted from this test because
2848                --  their completion is explicit, or through an import pragma.
2849
2850                if Ekind (E) = E_Constant
2851                  and then Present (Full_View (E))
2852                then
2853                   null;
2854
2855                elsif Comes_From_Source (E)
2856                  and then not Is_Imported (E)
2857                  and then not Has_Init_Expression (Declaration_Node (E))
2858                  and then
2859                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2860                       and then not No_Initialization (Declaration_Node (E))
2861                       and then not Is_Value_Type (Etype (E))
2862                       and then not Suppress_Init_Proc (Etype (E)))
2863                     or else
2864                       (Needs_Simple_Initialization (Etype (E))
2865                         and then not Is_Internal (E)))
2866                then
2867                   Has_Default_Initialization := True;
2868                   Check_Restriction
2869                     (No_Default_Initialization, Declaration_Node (E));
2870                end if;
2871
2872                --  Check that a Thread_Local_Storage variable does not have
2873                --  default initialization, and any explicit initialization must
2874                --  either be the null constant or a static constant.
2875
2876                if Has_Pragma_Thread_Local_Storage (E) then
2877                   declare
2878                      Decl : constant Node_Id := Declaration_Node (E);
2879                   begin
2880                      if Has_Default_Initialization
2881                        or else
2882                          (Has_Init_Expression (Decl)
2883                             and then
2884                              (No (Expression (Decl))
2885                                 or else not
2886                                   (Is_Static_Expression (Expression (Decl))
2887                                      or else
2888                                    Nkind (Expression (Decl)) = N_Null)))
2889                      then
2890                         Error_Msg_NE
2891                           ("Thread_Local_Storage variable& is "
2892                            & "improperly initialized", Decl, E);
2893                         Error_Msg_NE
2894                           ("\only allowed initialization is explicit "
2895                            & "NULL or static expression", Decl, E);
2896                      end if;
2897                   end;
2898                end if;
2899
2900                --  For imported objects, set Is_Public unless there is also an
2901                --  address clause, which means that there is no external symbol
2902                --  needed for the Import (Is_Public may still be set for other
2903                --  unrelated reasons). Note that we delayed this processing
2904                --  till freeze time so that we can be sure not to set the flag
2905                --  if there is an address clause. If there is such a clause,
2906                --  then the only purpose of the Import pragma is to suppress
2907                --  implicit initialization.
2908
2909                if Is_Imported (E)
2910                  and then No (Address_Clause (E))
2911                then
2912                   Set_Is_Public (E);
2913                end if;
2914
2915                --  For convention C objects of an enumeration type, warn if
2916                --  the size is not integer size and no explicit size given.
2917                --  Skip warning for Boolean, and Character, assume programmer
2918                --  expects 8-bit sizes for these cases.
2919
2920                if (Convention (E) = Convention_C
2921                     or else
2922                    Convention (E) = Convention_CPP)
2923                  and then Is_Enumeration_Type (Etype (E))
2924                  and then not Is_Character_Type (Etype (E))
2925                  and then not Is_Boolean_Type (Etype (E))
2926                  and then Esize (Etype (E)) < Standard_Integer_Size
2927                  and then not Has_Size_Clause (E)
2928                then
2929                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2930                   Error_Msg_N
2931                     ("?convention C enumeration object has size less than ^",
2932                      E);
2933                   Error_Msg_N ("\?use explicit size clause to set size", E);
2934                end if;
2935             end if;
2936
2937             --  Check that a constant which has a pragma Volatile[_Components]
2938             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2939
2940             --  Note: Atomic[_Components] also sets Volatile[_Components]
2941
2942             if Ekind (E) = E_Constant
2943               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2944               and then not Is_Imported (E)
2945             then
2946                --  Make sure we actually have a pragma, and have not merely
2947                --  inherited the indication from elsewhere (e.g. an address
2948                --  clause, which is not good enough in RM terms!)
2949
2950                if Has_Rep_Pragma (E, Name_Atomic)
2951                     or else
2952                   Has_Rep_Pragma (E, Name_Atomic_Components)
2953                then
2954                   Error_Msg_N
2955                     ("stand alone atomic constant must be " &
2956                      "imported (RM C.6(13))", E);
2957
2958                elsif Has_Rep_Pragma (E, Name_Volatile)
2959                        or else
2960                      Has_Rep_Pragma (E, Name_Volatile_Components)
2961                then
2962                   Error_Msg_N
2963                     ("stand alone volatile constant must be " &
2964                      "imported (RM C.6(13))", E);
2965                end if;
2966             end if;
2967
2968             --  Static objects require special handling
2969
2970             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
2971               and then Is_Statically_Allocated (E)
2972             then
2973                Freeze_Static_Object (E);
2974             end if;
2975
2976             --  Remaining step is to layout objects
2977
2978             if Ekind (E) = E_Variable
2979                  or else
2980                Ekind (E) = E_Constant
2981                  or else
2982                Ekind (E) = E_Loop_Parameter
2983                  or else
2984                Is_Formal (E)
2985             then
2986                Layout_Object (E);
2987             end if;
2988          end if;
2989
2990       --  Case of a type or subtype being frozen
2991
2992       else
2993          --  We used to check here that a full type must have preelaborable
2994          --  initialization if it completes a private type specified with
2995          --  pragma Preelaborable_Initialization, but that missed cases where
2996          --  the types occur within a generic package, since the freezing
2997          --  that occurs within a containing scope generally skips traversal
2998          --  of a generic unit's declarations (those will be frozen within
2999          --  instances). This check was moved to Analyze_Package_Specification.
3000
3001          --  The type may be defined in a generic unit. This can occur when
3002          --  freezing a generic function that returns the type (which is
3003          --  defined in a parent unit). It is clearly meaningless to freeze
3004          --  this type. However, if it is a subtype, its size may be determi-
3005          --  nable and used in subsequent checks, so might as well try to
3006          --  compute it.
3007
3008          if Present (Scope (E))
3009            and then Is_Generic_Unit (Scope (E))
3010          then
3011             Check_Compile_Time_Size (E);
3012             return No_List;
3013          end if;
3014
3015          --  Deal with special cases of freezing for subtype
3016
3017          if E /= Base_Type (E) then
3018
3019             --  Before we do anything else, a specialized test for the case of
3020             --  a size given for an array where the array needs to be packed,
3021             --  but was not so the size cannot be honored. This would of course
3022             --  be caught by the backend, and indeed we don't catch all cases.
3023             --  The point is that we can give a better error message in those
3024             --  cases that we do catch with the circuitry here. Also if pragma
3025             --  Implicit_Packing is set, this is where the packing occurs.
3026
3027             --  The reason we do this so early is that the processing in the
3028             --  automatic packing case affects the layout of the base type, so
3029             --  it must be done before we freeze the base type.
3030
3031             if Is_Array_Type (E) then
3032                declare
3033                   Lo, Hi : Node_Id;
3034                   Ctyp   : constant Entity_Id := Component_Type (E);
3035
3036                begin
3037                   --  Check enabling conditions. These are straightforward
3038                   --  except for the test for a limited composite type. This
3039                   --  eliminates the rare case of a array of limited components
3040                   --  where there are issues of whether or not we can go ahead
3041                   --  and pack the array (since we can't freely pack and unpack
3042                   --  arrays if they are limited).
3043
3044                   --  Note that we check the root type explicitly because the
3045                   --  whole point is we are doing this test before we have had
3046                   --  a chance to freeze the base type (and it is that freeze
3047                   --  action that causes stuff to be inherited).
3048
3049                   if Present (Size_Clause (E))
3050                     and then Known_Static_Esize (E)
3051                     and then not Is_Packed (E)
3052                     and then not Has_Pragma_Pack (E)
3053                     and then Number_Dimensions (E) = 1
3054                     and then not Has_Component_Size_Clause (E)
3055                     and then Known_Static_Esize (Ctyp)
3056                     and then not Is_Limited_Composite (E)
3057                     and then not Is_Packed (Root_Type (E))
3058                     and then not Has_Component_Size_Clause (Root_Type (E))
3059                     and then not CodePeer_Mode
3060                   then
3061                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3062
3063                      if Compile_Time_Known_Value (Lo)
3064                        and then Compile_Time_Known_Value (Hi)
3065                        and then Known_Static_RM_Size (Ctyp)
3066                        and then RM_Size (Ctyp) < 64
3067                      then
3068                         declare
3069                            Lov  : constant Uint      := Expr_Value (Lo);
3070                            Hiv  : constant Uint      := Expr_Value (Hi);
3071                            Len  : constant Uint      := UI_Max
3072                                                          (Uint_0,
3073                                                           Hiv - Lov + 1);
3074                            Rsiz : constant Uint      := RM_Size (Ctyp);
3075                            SZ   : constant Node_Id   := Size_Clause (E);
3076                            Btyp : constant Entity_Id := Base_Type (E);
3077
3078                         --  What we are looking for here is the situation where
3079                         --  the RM_Size given would be exactly right if there
3080                         --  was a pragma Pack (resulting in the component size
3081                         --  being the same as the RM_Size). Furthermore, the
3082                         --  component type size must be an odd size (not a
3083                         --  multiple of storage unit). If the component RM size
3084                         --  is an exact number of storage units that is a power
3085                         --  of two, the array is not packed and has a standard
3086                         --  representation.
3087
3088                         begin
3089                            if RM_Size (E) = Len * Rsiz
3090                              and then Rsiz mod System_Storage_Unit /= 0
3091                            then
3092                               --  For implicit packing mode, just set the
3093                               --  component size silently.
3094
3095                               if Implicit_Packing then
3096                                  Set_Component_Size       (Btyp, Rsiz);
3097                                  Set_Is_Bit_Packed_Array  (Btyp);
3098                                  Set_Is_Packed            (Btyp);
3099                                  Set_Has_Non_Standard_Rep (Btyp);
3100
3101                                  --  Otherwise give an error message
3102
3103                               else
3104                                  Error_Msg_NE
3105                                    ("size given for& too small", SZ, E);
3106                                  Error_Msg_N -- CODEFIX
3107                                    ("\use explicit pragma Pack "
3108                                     & "or use pragma Implicit_Packing", SZ);
3109                               end if;
3110
3111                            elsif RM_Size (E) = Len * Rsiz
3112                              and then Implicit_Packing
3113                              and then
3114                                (Rsiz / System_Storage_Unit = 1
3115                                  or else Rsiz / System_Storage_Unit = 2
3116                                  or else Rsiz / System_Storage_Unit = 4)
3117                            then
3118
3119                               --  Not a packed array, but indicate the desired
3120                               --  component size, for the back-end.
3121
3122                               Set_Component_Size (Btyp, Rsiz);
3123                            end if;
3124                         end;
3125                      end if;
3126                   end if;
3127                end;
3128             end if;
3129
3130             --  If ancestor subtype present, freeze that first. Note that this
3131             --  will also get the base type frozen. Need RM reference ???
3132
3133             Atype := Ancestor_Subtype (E);
3134
3135             if Present (Atype) then
3136                Freeze_And_Append (Atype, N, Result);
3137
3138             --  No ancestor subtype present
3139
3140             else
3141                --  See if we have a nearest ancestor that has a predicate.
3142                --  That catches the case of derived type with a predicate.
3143                --  Need RM reference here ???
3144
3145                Atype := Nearest_Ancestor (E);
3146
3147                if Present (Atype) and then Has_Predicates (Atype) then
3148                   Freeze_And_Append (Atype, N, Result);
3149                end if;
3150
3151                --  Freeze base type before freezing the entity (RM 13.14(15))
3152
3153                if E /= Base_Type (E) then
3154                   Freeze_And_Append (Base_Type (E), N, Result);
3155                end if;
3156             end if;
3157
3158          --  For a derived type, freeze its parent type first (RM 13.14(15))
3159
3160          elsif Is_Derived_Type (E) then
3161             Freeze_And_Append (Etype (E), N, Result);
3162             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3163          end if;
3164
3165          --  For array type, freeze index types and component type first
3166          --  before freezing the array (RM 13.14(15)).
3167
3168          if Is_Array_Type (E) then
3169             declare
3170                FS     : constant Entity_Id := First_Subtype (E);
3171                Ctyp   : constant Entity_Id := Component_Type (E);
3172                Clause : Entity_Id;
3173
3174                Non_Standard_Enum : Boolean := False;
3175                --  Set true if any of the index types is an enumeration type
3176                --  with a non-standard representation.
3177
3178             begin
3179                Freeze_And_Append (Ctyp, N, Result);
3180
3181                Indx := First_Index (E);
3182                while Present (Indx) loop
3183                   Freeze_And_Append (Etype (Indx), N, Result);
3184
3185                   if Is_Enumeration_Type (Etype (Indx))
3186                     and then Has_Non_Standard_Rep (Etype (Indx))
3187                   then
3188                      Non_Standard_Enum := True;
3189                   end if;
3190
3191                   Next_Index (Indx);
3192                end loop;
3193
3194                --  Processing that is done only for base types
3195
3196                if Ekind (E) = E_Array_Type then
3197
3198                   --  Propagate flags for component type
3199
3200                   if Is_Controlled (Component_Type (E))
3201                     or else Has_Controlled_Component (Ctyp)
3202                   then
3203                      Set_Has_Controlled_Component (E);
3204                   end if;
3205
3206                   if Has_Unchecked_Union (Component_Type (E)) then
3207                      Set_Has_Unchecked_Union (E);
3208                   end if;
3209
3210                   --  If packing was requested or if the component size was set
3211                   --  explicitly, then see if bit packing is required. This
3212                   --  processing is only done for base types, since all the
3213                   --  representation aspects involved are type-related. This
3214                   --  is not just an optimization, if we start processing the
3215                   --  subtypes, they interfere with the settings on the base
3216                   --  type (this is because Is_Packed has a slightly different
3217                   --  meaning before and after freezing).
3218
3219                   declare
3220                      Csiz : Uint;
3221                      Esiz : Uint;
3222
3223                   begin
3224                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3225                        and then Known_Static_RM_Size (Ctyp)
3226                        and then not Has_Component_Size_Clause (E)
3227                      then
3228                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3229
3230                      elsif Known_Component_Size (E) then
3231                         Csiz := Component_Size (E);
3232
3233                      elsif not Known_Static_Esize (Ctyp) then
3234                         Csiz := Uint_0;
3235
3236                      else
3237                         Esiz := Esize (Ctyp);
3238
3239                         --  We can set the component size if it is less than
3240                         --  16, rounding it up to the next storage unit size.
3241
3242                         if Esiz <= 8 then
3243                            Csiz := Uint_8;
3244                         elsif Esiz <= 16 then
3245                            Csiz := Uint_16;
3246                         else
3247                            Csiz := Uint_0;
3248                         end if;
3249
3250                         --  Set component size up to match alignment if it
3251                         --  would otherwise be less than the alignment. This
3252                         --  deals with cases of types whose alignment exceeds
3253                         --  their size (padded types).
3254
3255                         if Csiz /= 0 then
3256                            declare
3257                               A : constant Uint := Alignment_In_Bits (Ctyp);
3258                            begin
3259                               if Csiz < A then
3260                                  Csiz := A;
3261                               end if;
3262                            end;
3263                         end if;
3264                      end if;
3265
3266                      --  Case of component size that may result in packing
3267
3268                      if 1 <= Csiz and then Csiz <= 64 then
3269                         declare
3270                            Ent         : constant Entity_Id :=
3271                                            First_Subtype (E);
3272                            Pack_Pragma : constant Node_Id :=
3273                                            Get_Rep_Pragma (Ent, Name_Pack);
3274                            Comp_Size_C : constant Node_Id :=
3275                                            Get_Attribute_Definition_Clause
3276                                              (Ent, Attribute_Component_Size);
3277                         begin
3278                            --  Warn if we have pack and component size so that
3279                            --  the pack is ignored.
3280
3281                            --  Note: here we must check for the presence of a
3282                            --  component size before checking for a Pack pragma
3283                            --  to deal with the case where the array type is a
3284                            --  derived type whose parent is currently private.
3285
3286                            if Present (Comp_Size_C)
3287                              and then Has_Pragma_Pack (Ent)
3288                              and then Warn_On_Redundant_Constructs
3289                            then
3290                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3291                               Error_Msg_NE
3292                                 ("?pragma Pack for& ignored!",
3293                                  Pack_Pragma, Ent);
3294                               Error_Msg_N
3295                                 ("\?explicit component size given#!",
3296                                  Pack_Pragma);
3297                               Set_Is_Packed (Base_Type (Ent), False);
3298                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3299                            end if;
3300
3301                            --  Set component size if not already set by a
3302                            --  component size clause.
3303
3304                            if not Present (Comp_Size_C) then
3305                               Set_Component_Size (E, Csiz);
3306                            end if;
3307
3308                            --  Check for base type of 8, 16, 32 bits, where an
3309                            --  unsigned subtype has a length one less than the
3310                            --  base type (e.g. Natural subtype of Integer).
3311
3312                            --  In such cases, if a component size was not set
3313                            --  explicitly, then generate a warning.
3314
3315                            if Has_Pragma_Pack (E)
3316                              and then not Present (Comp_Size_C)
3317                              and then
3318                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3319                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3320                            then
3321                               Error_Msg_Uint_1 := Csiz;
3322
3323                               if Present (Pack_Pragma) then
3324                                  Error_Msg_N
3325                                    ("?pragma Pack causes component size "
3326                                     & "to be ^!", Pack_Pragma);
3327                                  Error_Msg_N
3328                                    ("\?use Component_Size to set "
3329                                     & "desired value!", Pack_Pragma);
3330                               end if;
3331                            end if;
3332
3333                            --  Actual packing is not needed for 8, 16, 32, 64.
3334                            --  Also not needed for 24 if alignment is 1.
3335
3336                            if        Csiz = 8
3337                              or else Csiz = 16
3338                              or else Csiz = 32
3339                              or else Csiz = 64
3340                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3341                            then
3342                               --  Here the array was requested to be packed,
3343                               --  but the packing request had no effect, so
3344                               --  Is_Packed is reset.
3345
3346                               --  Note: semantically this means that we lose
3347                               --  track of the fact that a derived type
3348                               --  inherited a pragma Pack that was non-
3349                               --  effective, but that seems fine.
3350
3351                               --  We regard a Pack pragma as a request to set
3352                               --  a representation characteristic, and this
3353                               --  request may be ignored.
3354
3355                               Set_Is_Packed           (Base_Type (E), False);
3356                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3357
3358                               if Known_Static_Esize (Component_Type (E))
3359                                 and then Esize (Component_Type (E)) = Csiz
3360                               then
3361                                  Set_Has_Non_Standard_Rep
3362                                    (Base_Type (E), False);
3363                               end if;
3364
3365                            --  In all other cases, packing is indeed needed
3366
3367                            else
3368                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3369                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3370                               Set_Is_Packed            (Base_Type (E), True);
3371                            end if;
3372                         end;
3373                      end if;
3374                   end;
3375
3376                   --  Check for Atomic_Components or Aliased with unsuitable
3377                   --  packing or explicit component size clause given.
3378
3379                   if (Has_Atomic_Components (E)
3380                        or else Has_Aliased_Components (E))
3381                     and then (Has_Component_Size_Clause (E)
3382                                or else Is_Packed (E))
3383                   then
3384                      Alias_Atomic_Check : declare
3385
3386                         procedure Complain_CS (T : String);
3387                         --  Outputs error messages for incorrect CS clause or
3388                         --  pragma Pack for aliased or atomic components (T is
3389                         --  "aliased" or "atomic");
3390
3391                         -----------------
3392                         -- Complain_CS --
3393                         -----------------
3394
3395                         procedure Complain_CS (T : String) is
3396                         begin
3397                            if Has_Component_Size_Clause (E) then
3398                               Clause :=
3399                                 Get_Attribute_Definition_Clause
3400                                   (FS, Attribute_Component_Size);
3401
3402                               if Known_Static_Esize (Ctyp) then
3403                                  Error_Msg_N
3404                                    ("incorrect component size for "
3405                                     & T & " components", Clause);
3406                                  Error_Msg_Uint_1 := Esize (Ctyp);
3407                                  Error_Msg_N
3408                                    ("\only allowed value is^", Clause);
3409
3410                               else
3411                                  Error_Msg_N
3412                                    ("component size cannot be given for "
3413                                     & T & " components", Clause);
3414                               end if;
3415
3416                            else
3417                               Error_Msg_N
3418                                 ("cannot pack " & T & " components",
3419                                  Get_Rep_Pragma (FS, Name_Pack));
3420                            end if;
3421
3422                            return;
3423                         end Complain_CS;
3424
3425                      --  Start of processing for Alias_Atomic_Check
3426
3427                      begin
3428                         --  Case where component size has no effect
3429
3430                         if Known_Static_Esize (Ctyp)
3431                           and then Known_Static_RM_Size (Ctyp)
3432                           and then Esize (Ctyp) = RM_Size (Ctyp)
3433                           and then Esize (Ctyp) mod 8 = 0
3434                         then
3435                            null;
3436
3437                         elsif Has_Aliased_Components (E)
3438                           or else Is_Aliased (Ctyp)
3439                         then
3440                            Complain_CS ("aliased");
3441
3442                         elsif Has_Atomic_Components (E)
3443                           or else Is_Atomic (Ctyp)
3444                         then
3445                            Complain_CS ("atomic");
3446                         end if;
3447                      end Alias_Atomic_Check;
3448                   end if;
3449
3450                   --  Warn for case of atomic type
3451
3452                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3453
3454                   if Present (Clause)
3455                     and then not Addressable (Component_Size (FS))
3456                   then
3457                      Error_Msg_NE
3458                        ("non-atomic components of type& may not be "
3459                         & "accessible by separate tasks?", Clause, E);
3460
3461                      if Has_Component_Size_Clause (E) then
3462                         Error_Msg_Sloc :=
3463                           Sloc
3464                             (Get_Attribute_Definition_Clause
3465                                  (FS, Attribute_Component_Size));
3466                         Error_Msg_N
3467                           ("\because of component size clause#?",
3468                            Clause);
3469
3470                      elsif Has_Pragma_Pack (E) then
3471                         Error_Msg_Sloc :=
3472                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3473                         Error_Msg_N
3474                           ("\because of pragma Pack#?", Clause);
3475                      end if;
3476                   end if;
3477
3478                --  Processing that is done only for subtypes
3479
3480                else
3481                   --  Acquire alignment from base type
3482
3483                   if Unknown_Alignment (E) then
3484                      Set_Alignment (E, Alignment (Base_Type (E)));
3485                      Adjust_Esize_Alignment (E);
3486                   end if;
3487                end if;
3488
3489                --  For bit-packed arrays, check the size
3490
3491                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3492                   declare
3493                      SizC : constant Node_Id := Size_Clause (E);
3494
3495                      Discard : Boolean;
3496                      pragma Warnings (Off, Discard);
3497
3498                   begin
3499                      --  It is not clear if it is possible to have no size
3500                      --  clause at this stage, but it is not worth worrying
3501                      --  about. Post error on the entity name in the size
3502                      --  clause if present, else on the type entity itself.
3503
3504                      if Present (SizC) then
3505                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3506                      else
3507                         Check_Size (E, E, RM_Size (E), Discard);
3508                      end if;
3509                   end;
3510                end if;
3511
3512                --  If any of the index types was an enumeration type with a
3513                --  non-standard rep clause, then we indicate that the array
3514                --  type is always packed (even if it is not bit packed).
3515
3516                if Non_Standard_Enum then
3517                   Set_Has_Non_Standard_Rep (Base_Type (E));
3518                   Set_Is_Packed            (Base_Type (E));
3519                end if;
3520
3521                Set_Component_Alignment_If_Not_Set (E);
3522
3523                --  If the array is packed, we must create the packed array
3524                --  type to be used to actually implement the type. This is
3525                --  only needed for real array types (not for string literal
3526                --  types, since they are present only for the front end).
3527
3528                if Is_Packed (E)
3529                  and then Ekind (E) /= E_String_Literal_Subtype
3530                then
3531                   Create_Packed_Array_Type (E);
3532                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3533
3534                   --  Size information of packed array type is copied to the
3535                   --  array type, since this is really the representation. But
3536                   --  do not override explicit existing size values. If the
3537                   --  ancestor subtype is constrained the packed_array_type
3538                   --  will be inherited from it, but the size may have been
3539                   --  provided already, and must not be overridden either.
3540
3541                   if not Has_Size_Clause (E)
3542                     and then
3543                       (No (Ancestor_Subtype (E))
3544                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3545                   then
3546                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3547                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3548                   end if;
3549
3550                   if not Has_Alignment_Clause (E) then
3551                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3552                   end if;
3553                end if;
3554
3555                --  For non-packed arrays set the alignment of the array to the
3556                --  alignment of the component type if it is unknown. Skip this
3557                --  in atomic case (atomic arrays may need larger alignments).
3558
3559                if not Is_Packed (E)
3560                  and then Unknown_Alignment (E)
3561                  and then Known_Alignment (Ctyp)
3562                  and then Known_Static_Component_Size (E)
3563                  and then Known_Static_Esize (Ctyp)
3564                  and then Esize (Ctyp) = Component_Size (E)
3565                  and then not Is_Atomic (E)
3566                then
3567                   Set_Alignment (E, Alignment (Component_Type (E)));
3568                end if;
3569             end;
3570
3571          --  For a class-wide type, the corresponding specific type is
3572          --  frozen as well (RM 13.14(15))
3573
3574          elsif Is_Class_Wide_Type (E) then
3575             Freeze_And_Append (Root_Type (E), N, Result);
3576
3577             --  If the base type of the class-wide type is still incomplete,
3578             --  the class-wide remains unfrozen as well. This is legal when
3579             --  E is the formal of a primitive operation of some other type
3580             --  which is being frozen.
3581
3582             if not Is_Frozen (Root_Type (E)) then
3583                Set_Is_Frozen (E, False);
3584                return Result;
3585             end if;
3586
3587             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3588             --  parent of a derived type) and it is a library-level entity,
3589             --  generate an itype reference for it. Otherwise, its first
3590             --  explicit reference may be in an inner scope, which will be
3591             --  rejected by the back-end.
3592
3593             if Is_Itype (E)
3594               and then Is_Compilation_Unit (Scope (E))
3595             then
3596                declare
3597                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3598
3599                begin
3600                   Set_Itype (Ref, E);
3601                   if No (Result) then
3602                      Result := New_List (Ref);
3603                   else
3604                      Append (Ref, Result);
3605                   end if;
3606                end;
3607             end if;
3608
3609             --  The equivalent type associated with a class-wide subtype needs
3610             --  to be frozen to ensure that its layout is done.
3611
3612             if Ekind (E) = E_Class_Wide_Subtype
3613               and then Present (Equivalent_Type (E))
3614             then
3615                Freeze_And_Append (Equivalent_Type (E), N, Result);
3616             end if;
3617
3618          --  For a record (sub)type, freeze all the component types (RM
3619          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3620          --  Is_Record_Type, because we don't want to attempt the freeze for
3621          --  the case of a private type with record extension (we will do that
3622          --  later when the full type is frozen).
3623
3624          elsif Ekind (E) = E_Record_Type
3625            or else Ekind (E) = E_Record_Subtype
3626          then
3627             Freeze_Record_Type (E);
3628
3629          --  For a concurrent type, freeze corresponding record type. This
3630          --  does not correspond to any specific rule in the RM, but the
3631          --  record type is essentially part of the concurrent type.
3632          --  Freeze as well all local entities. This includes record types
3633          --  created for entry parameter blocks, and whatever local entities
3634          --  may appear in the private part.
3635
3636          elsif Is_Concurrent_Type (E) then
3637             if Present (Corresponding_Record_Type (E)) then
3638                Freeze_And_Append
3639                  (Corresponding_Record_Type (E), N, Result);
3640             end if;
3641
3642             Comp := First_Entity (E);
3643             while Present (Comp) loop
3644                if Is_Type (Comp) then
3645                   Freeze_And_Append (Comp, N, Result);
3646
3647                elsif (Ekind (Comp)) /= E_Function then
3648                   if Is_Itype (Etype (Comp))
3649                     and then Underlying_Type (Scope (Etype (Comp))) = E
3650                   then
3651                      Undelay_Type (Etype (Comp));
3652                   end if;
3653
3654                   Freeze_And_Append (Etype (Comp), N, Result);
3655                end if;
3656
3657                Next_Entity (Comp);
3658             end loop;
3659
3660          --  Private types are required to point to the same freeze node as
3661          --  their corresponding full views. The freeze node itself has to
3662          --  point to the partial view of the entity (because from the partial
3663          --  view, we can retrieve the full view, but not the reverse).
3664          --  However, in order to freeze correctly, we need to freeze the full
3665          --  view. If we are freezing at the end of a scope (or within the
3666          --  scope of the private type), the partial and full views will have
3667          --  been swapped, the full view appears first in the entity chain and
3668          --  the swapping mechanism ensures that the pointers are properly set
3669          --  (on scope exit).
3670
3671          --  If we encounter the partial view before the full view (e.g. when
3672          --  freezing from another scope), we freeze the full view, and then
3673          --  set the pointers appropriately since we cannot rely on swapping to
3674          --  fix things up (subtypes in an outer scope might not get swapped).
3675
3676          elsif Is_Incomplete_Or_Private_Type (E)
3677            and then not Is_Generic_Type (E)
3678          then
3679             --  The construction of the dispatch table associated with library
3680             --  level tagged types forces freezing of all the primitives of the
3681             --  type, which may cause premature freezing of the partial view.
3682             --  For example:
3683
3684             --     package Pkg is
3685             --        type T is tagged private;
3686             --        type DT is new T with private;
3687             --        procedure Prim (X : in out T; Y : in out DT'class);
3688             --     private
3689             --        type T is tagged null record;
3690             --        Obj : T;
3691             --        type DT is new T with null record;
3692             --     end;
3693
3694             --  In this case the type will be frozen later by the usual
3695             --  mechanism: an object declaration, an instantiation, or the
3696             --  end of a declarative part.
3697
3698             if Is_Library_Level_Tagged_Type (E)
3699               and then not Present (Full_View (E))
3700             then
3701                Set_Is_Frozen (E, False);
3702                return Result;
3703
3704             --  Case of full view present
3705
3706             elsif Present (Full_View (E)) then
3707
3708                --  If full view has already been frozen, then no further
3709                --  processing is required
3710
3711                if Is_Frozen (Full_View (E)) then
3712                   Set_Has_Delayed_Freeze (E, False);
3713                   Set_Freeze_Node (E, Empty);
3714                   Check_Debug_Info_Needed (E);
3715
3716                --  Otherwise freeze full view and patch the pointers so that
3717                --  the freeze node will elaborate both views in the back-end.
3718
3719                else
3720                   declare
3721                      Full : constant Entity_Id := Full_View (E);
3722
3723                   begin
3724                      if Is_Private_Type (Full)
3725                        and then Present (Underlying_Full_View (Full))
3726                      then
3727                         Freeze_And_Append
3728                           (Underlying_Full_View (Full), N, Result);
3729                      end if;
3730
3731                      Freeze_And_Append (Full, N, Result);
3732
3733                      if Has_Delayed_Freeze (E) then
3734                         F_Node := Freeze_Node (Full);
3735
3736                         if Present (F_Node) then
3737                            Set_Freeze_Node (E, F_Node);
3738                            Set_Entity (F_Node, E);
3739
3740                         else
3741                            --  {Incomplete,Private}_Subtypes with Full_Views
3742                            --  constrained by discriminants.
3743
3744                            Set_Has_Delayed_Freeze (E, False);
3745                            Set_Freeze_Node (E, Empty);
3746                         end if;
3747                      end if;
3748                   end;
3749
3750                   Check_Debug_Info_Needed (E);
3751                end if;
3752
3753                --  AI-117 requires that the convention of a partial view be the
3754                --  same as the convention of the full view. Note that this is a
3755                --  recognized breach of privacy, but it's essential for logical
3756                --  consistency of representation, and the lack of a rule in
3757                --  RM95 was an oversight.
3758
3759                Set_Convention (E, Convention (Full_View (E)));
3760
3761                Set_Size_Known_At_Compile_Time (E,
3762                  Size_Known_At_Compile_Time (Full_View (E)));
3763
3764                --  Size information is copied from the full view to the
3765                --  incomplete or private view for consistency.
3766
3767                --  We skip this is the full view is not a type. This is very
3768                --  strange of course, and can only happen as a result of
3769                --  certain illegalities, such as a premature attempt to derive
3770                --  from an incomplete type.
3771
3772                if Is_Type (Full_View (E)) then
3773                   Set_Size_Info (E, Full_View (E));
3774                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3775                end if;
3776
3777                return Result;
3778
3779             --  Case of no full view present. If entity is derived or subtype,
3780             --  it is safe to freeze, correctness depends on the frozen status
3781             --  of parent. Otherwise it is either premature usage, or a Taft
3782             --  amendment type, so diagnosis is at the point of use and the
3783             --  type might be frozen later.
3784
3785             elsif E /= Base_Type (E)
3786               or else Is_Derived_Type (E)
3787             then
3788                null;
3789
3790             else
3791                Set_Is_Frozen (E, False);
3792                return No_List;
3793             end if;
3794
3795          --  For access subprogram, freeze types of all formals, the return
3796          --  type was already frozen, since it is the Etype of the function.
3797          --  Formal types can be tagged Taft amendment types, but otherwise
3798          --  they cannot be incomplete.
3799
3800          elsif Ekind (E) = E_Subprogram_Type then
3801             Formal := First_Formal (E);
3802             while Present (Formal) loop
3803                if Ekind (Etype (Formal)) = E_Incomplete_Type
3804                  and then No (Full_View (Etype (Formal)))
3805                  and then not Is_Value_Type (Etype (Formal))
3806                then
3807                   if Is_Tagged_Type (Etype (Formal)) then
3808                      null;
3809
3810                   --  AI05-151: Incomplete types are allowed in access to
3811                   --  subprogram specifications.
3812
3813                   elsif Ada_Version < Ada_2012 then
3814                      Error_Msg_NE
3815                        ("invalid use of incomplete type&", E, Etype (Formal));
3816                   end if;
3817                end if;
3818
3819                Freeze_And_Append (Etype (Formal), N, Result);
3820                Next_Formal (Formal);
3821             end loop;
3822
3823             Freeze_Subprogram (E);
3824
3825          --  For access to a protected subprogram, freeze the equivalent type
3826          --  (however this is not set if we are not generating code or if this
3827          --  is an anonymous type used just for resolution).
3828
3829          elsif Is_Access_Protected_Subprogram_Type (E) then
3830             if Present (Equivalent_Type (E)) then
3831                Freeze_And_Append (Equivalent_Type (E), N, Result);
3832             end if;
3833          end if;
3834
3835          --  Generic types are never seen by the back-end, and are also not
3836          --  processed by the expander (since the expander is turned off for
3837          --  generic processing), so we never need freeze nodes for them.
3838
3839          if Is_Generic_Type (E) then
3840             return Result;
3841          end if;
3842
3843          --  Some special processing for non-generic types to complete
3844          --  representation details not known till the freeze point.
3845
3846          if Is_Fixed_Point_Type (E) then
3847             Freeze_Fixed_Point_Type (E);
3848
3849             --  Some error checks required for ordinary fixed-point type. Defer
3850             --  these till the freeze-point since we need the small and range
3851             --  values. We only do these checks for base types
3852
3853             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3854                if Small_Value (E) < Ureal_2_M_80 then
3855                   Error_Msg_Name_1 := Name_Small;
3856                   Error_Msg_N
3857                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3858
3859                elsif Small_Value (E) > Ureal_2_80 then
3860                   Error_Msg_Name_1 := Name_Small;
3861                   Error_Msg_N
3862                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3863                end if;
3864
3865                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3866                   Error_Msg_Name_1 := Name_First;
3867                   Error_Msg_N
3868                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3869                end if;
3870
3871                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3872                   Error_Msg_Name_1 := Name_Last;
3873                   Error_Msg_N
3874                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3875                end if;
3876             end if;
3877
3878          elsif Is_Enumeration_Type (E) then
3879             Freeze_Enumeration_Type (E);
3880
3881          elsif Is_Integer_Type (E) then
3882             Adjust_Esize_For_Alignment (E);
3883
3884             if Is_Modular_Integer_Type (E)
3885               and then Warn_On_Suspicious_Modulus_Value
3886             then
3887                Check_Suspicious_Modulus (E);
3888             end if;
3889
3890          elsif Is_Access_Type (E) then
3891
3892             --  If a pragma Default_Storage_Pool applies, and this type has no
3893             --  Storage_Pool or Storage_Size clause (which must have occurred
3894             --  before the freezing point), then use the default. This applies
3895             --  only to base types.
3896
3897             if Present (Default_Pool)
3898               and then Is_Base_Type (E)
3899               and then not Has_Storage_Size_Clause (E)
3900               and then No (Associated_Storage_Pool (E))
3901             then
3902                --  Case of pragma Default_Storage_Pool (null)
3903
3904                if Nkind (Default_Pool) = N_Null then
3905                   Set_No_Pool_Assigned (E);
3906
3907                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3908
3909                else
3910                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3911                end if;
3912             end if;
3913
3914             --  Check restriction for standard storage pool
3915
3916             if No (Associated_Storage_Pool (E)) then
3917                Check_Restriction (No_Standard_Storage_Pools, E);
3918             end if;
3919
3920             --  Deal with error message for pure access type. This is not an
3921             --  error in Ada 2005 if there is no pool (see AI-366).
3922
3923             if Is_Pure_Unit_Access_Type (E)
3924               and then (Ada_Version < Ada_2005
3925                          or else not No_Pool_Assigned (E))
3926             then
3927                Error_Msg_N ("named access type not allowed in pure unit", E);
3928
3929                if Ada_Version >= Ada_2005 then
3930                   Error_Msg_N
3931                     ("\would be legal if Storage_Size of 0 given?", E);
3932
3933                elsif No_Pool_Assigned (E) then
3934                   Error_Msg_N
3935                     ("\would be legal in Ada 2005?", E);
3936
3937                else
3938                   Error_Msg_N
3939                     ("\would be legal in Ada 2005 if "
3940                      & "Storage_Size of 0 given?", E);
3941                end if;
3942             end if;
3943          end if;
3944
3945          --  Case of composite types
3946
3947          if Is_Composite_Type (E) then
3948
3949             --  AI-117 requires that all new primitives of a tagged type must
3950             --  inherit the convention of the full view of the type. Inherited
3951             --  and overriding operations are defined to inherit the convention
3952             --  of their parent or overridden subprogram (also specified in
3953             --  AI-117), which will have occurred earlier (in Derive_Subprogram
3954             --  and New_Overloaded_Entity). Here we set the convention of
3955             --  primitives that are still convention Ada, which will ensure
3956             --  that any new primitives inherit the type's convention. Class-
3957             --  wide types can have a foreign convention inherited from their
3958             --  specific type, but are excluded from this since they don't have
3959             --  any associated primitives.
3960
3961             if Is_Tagged_Type (E)
3962               and then not Is_Class_Wide_Type (E)
3963               and then Convention (E) /= Convention_Ada
3964             then
3965                declare
3966                   Prim_List : constant Elist_Id := Primitive_Operations (E);
3967                   Prim      : Elmt_Id;
3968
3969                begin
3970                   Prim := First_Elmt (Prim_List);
3971                   while Present (Prim) loop
3972                      if Convention (Node (Prim)) = Convention_Ada then
3973                         Set_Convention (Node (Prim), Convention (E));
3974                      end if;
3975
3976                      Next_Elmt (Prim);
3977                   end loop;
3978                end;
3979             end if;
3980          end if;
3981
3982          --  Now that all types from which E may depend are frozen, see if the
3983          --  size is known at compile time, if it must be unsigned, or if
3984          --  strict alignment is required
3985
3986          Check_Compile_Time_Size (E);
3987          Check_Unsigned_Type (E);
3988
3989          if Base_Type (E) = E then
3990             Check_Strict_Alignment (E);
3991          end if;
3992
3993          --  Do not allow a size clause for a type which does not have a size
3994          --  that is known at compile time
3995
3996          if Has_Size_Clause (E)
3997            and then not Size_Known_At_Compile_Time (E)
3998          then
3999             --  Suppress this message if errors posted on E, even if we are
4000             --  in all errors mode, since this is often a junk message
4001
4002             if not Error_Posted (E) then
4003                Error_Msg_N
4004                  ("size clause not allowed for variable length type",
4005                   Size_Clause (E));
4006             end if;
4007          end if;
4008
4009          --  Remaining process is to set/verify the representation information,
4010          --  in particular the size and alignment values. This processing is
4011          --  not required for generic types, since generic types do not play
4012          --  any part in code generation, and so the size and alignment values
4013          --  for such types are irrelevant.
4014
4015          if Is_Generic_Type (E) then
4016             return Result;
4017
4018          --  Otherwise we call the layout procedure
4019
4020          else
4021             Layout_Type (E);
4022          end if;
4023
4024          --  End of freeze processing for type entities
4025       end if;
4026
4027       --  Here is where we logically freeze the current entity. If it has a
4028       --  freeze node, then this is the point at which the freeze node is
4029       --  linked into the result list.
4030
4031       if Has_Delayed_Freeze (E) then
4032
4033          --  If a freeze node is already allocated, use it, otherwise allocate
4034          --  a new one. The preallocation happens in the case of anonymous base
4035          --  types, where we preallocate so that we can set First_Subtype_Link.
4036          --  Note that we reset the Sloc to the current freeze location.
4037
4038          if Present (Freeze_Node (E)) then
4039             F_Node := Freeze_Node (E);
4040             Set_Sloc (F_Node, Loc);
4041
4042          else
4043             F_Node := New_Node (N_Freeze_Entity, Loc);
4044             Set_Freeze_Node (E, F_Node);
4045             Set_Access_Types_To_Process (F_Node, No_Elist);
4046             Set_TSS_Elist (F_Node, No_Elist);
4047             Set_Actions (F_Node, No_List);
4048          end if;
4049
4050          Set_Entity (F_Node, E);
4051
4052          if Result = No_List then
4053             Result := New_List (F_Node);
4054          else
4055             Append (F_Node, Result);
4056          end if;
4057
4058          --  A final pass over record types with discriminants. If the type
4059          --  has an incomplete declaration, there may be constrained access
4060          --  subtypes declared elsewhere, which do not depend on the discrimi-
4061          --  nants of the type, and which are used as component types (i.e.
4062          --  the full view is a recursive type). The designated types of these
4063          --  subtypes can only be elaborated after the type itself, and they
4064          --  need an itype reference.
4065
4066          if Ekind (E) = E_Record_Type
4067            and then Has_Discriminants (E)
4068          then
4069             declare
4070                Comp : Entity_Id;
4071                IR   : Node_Id;
4072                Typ  : Entity_Id;
4073
4074             begin
4075                Comp := First_Component (E);
4076                while Present (Comp) loop
4077                   Typ  := Etype (Comp);
4078
4079                   if Ekind (Comp) = E_Component
4080                     and then Is_Access_Type (Typ)
4081                     and then Scope (Typ) /= E
4082                     and then Base_Type (Designated_Type (Typ)) = E
4083                     and then Is_Itype (Designated_Type (Typ))
4084                   then
4085                      IR := Make_Itype_Reference (Sloc (Comp));
4086                      Set_Itype (IR, Designated_Type (Typ));
4087                      Append (IR, Result);
4088                   end if;
4089
4090                   Next_Component (Comp);
4091                end loop;
4092             end;
4093          end if;
4094       end if;
4095
4096       --  When a type is frozen, the first subtype of the type is frozen as
4097       --  well (RM 13.14(15)). This has to be done after freezing the type,
4098       --  since obviously the first subtype depends on its own base type.
4099
4100       if Is_Type (E) then
4101          Freeze_And_Append (First_Subtype (E), N, Result);
4102
4103          --  If we just froze a tagged non-class wide record, then freeze the
4104          --  corresponding class-wide type. This must be done after the tagged
4105          --  type itself is frozen, because the class-wide type refers to the
4106          --  tagged type which generates the class.
4107
4108          if Is_Tagged_Type (E)
4109            and then not Is_Class_Wide_Type (E)
4110            and then Present (Class_Wide_Type (E))
4111          then
4112             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4113          end if;
4114       end if;
4115
4116       Check_Debug_Info_Needed (E);
4117
4118       --  Special handling for subprograms
4119
4120       if Is_Subprogram (E) then
4121
4122          --  If subprogram has address clause then reset Is_Public flag, since
4123          --  we do not want the backend to generate external references.
4124
4125          if Present (Address_Clause (E))
4126            and then not Is_Library_Level_Entity (E)
4127          then
4128             Set_Is_Public (E, False);
4129
4130          --  If no address clause and not intrinsic, then for imported
4131          --  subprogram in main unit, generate descriptor if we are in
4132          --  Propagate_Exceptions mode.
4133
4134          elsif Propagate_Exceptions
4135            and then Is_Imported (E)
4136            and then not Is_Intrinsic_Subprogram (E)
4137            and then Convention (E) /= Convention_Stubbed
4138          then
4139             if Result = No_List then
4140                Result := Empty_List;
4141             end if;
4142          end if;
4143       end if;
4144
4145       return Result;
4146    end Freeze_Entity;
4147
4148    -----------------------------
4149    -- Freeze_Enumeration_Type --
4150    -----------------------------
4151
4152    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4153    begin
4154       --  By default, if no size clause is present, an enumeration type with
4155       --  Convention C is assumed to interface to a C enum, and has integer
4156       --  size. This applies to types. For subtypes, verify that its base
4157       --  type has no size clause either.
4158
4159       if Has_Foreign_Convention (Typ)
4160         and then not Has_Size_Clause (Typ)
4161         and then not Has_Size_Clause (Base_Type (Typ))
4162         and then Esize (Typ) < Standard_Integer_Size
4163       then
4164          Init_Esize (Typ, Standard_Integer_Size);
4165
4166       else
4167          --  If the enumeration type interfaces to C, and it has a size clause
4168          --  that specifies less than int size, it warrants a warning. The
4169          --  user may intend the C type to be an enum or a char, so this is
4170          --  not by itself an error that the Ada compiler can detect, but it
4171          --  it is a worth a heads-up. For Boolean and Character types we
4172          --  assume that the programmer has the proper C type in mind.
4173
4174          if Convention (Typ) = Convention_C
4175            and then Has_Size_Clause (Typ)
4176            and then Esize (Typ) /= Esize (Standard_Integer)
4177            and then not Is_Boolean_Type (Typ)
4178            and then not Is_Character_Type (Typ)
4179          then
4180             Error_Msg_N
4181               ("C enum types have the size of a C int?", Size_Clause (Typ));
4182          end if;
4183
4184          Adjust_Esize_For_Alignment (Typ);
4185       end if;
4186    end Freeze_Enumeration_Type;
4187
4188    -----------------------
4189    -- Freeze_Expression --
4190    -----------------------
4191
4192    procedure Freeze_Expression (N : Node_Id) is
4193       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4194       Typ         : Entity_Id;
4195       Nam         : Entity_Id;
4196       Desig_Typ   : Entity_Id;
4197       P           : Node_Id;
4198       Parent_P    : Node_Id;
4199
4200       Freeze_Outside : Boolean := False;
4201       --  This flag is set true if the entity must be frozen outside the
4202       --  current subprogram. This happens in the case of expander generated
4203       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4204       --  not freeze all entities like other bodies, but which nevertheless
4205       --  may reference entities that have to be frozen before the body and
4206       --  obviously cannot be frozen inside the body.
4207
4208       function In_Exp_Body (N : Node_Id) return Boolean;
4209       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4210       --  it is the handled statement sequence of an expander-generated
4211       --  subprogram (init proc, stream subprogram, or renaming as body).
4212       --  If so, this is not a freezing context.
4213
4214       -----------------
4215       -- In_Exp_Body --
4216       -----------------
4217
4218       function In_Exp_Body (N : Node_Id) return Boolean is
4219          P  : Node_Id;
4220          Id : Entity_Id;
4221
4222       begin
4223          if Nkind (N) = N_Subprogram_Body then
4224             P := N;
4225          else
4226             P := Parent (N);
4227          end if;
4228
4229          if Nkind (P) /= N_Subprogram_Body then
4230             return False;
4231
4232          else
4233             Id := Defining_Unit_Name (Specification (P));
4234
4235             if Nkind (Id) = N_Defining_Identifier
4236               and then (Is_Init_Proc (Id)              or else
4237                         Is_TSS (Id, TSS_Stream_Input)  or else
4238                         Is_TSS (Id, TSS_Stream_Output) or else
4239                         Is_TSS (Id, TSS_Stream_Read)   or else
4240                         Is_TSS (Id, TSS_Stream_Write)  or else
4241                         Nkind (Original_Node (P)) =
4242                           N_Subprogram_Renaming_Declaration)
4243             then
4244                return True;
4245             else
4246                return False;
4247             end if;
4248          end if;
4249       end In_Exp_Body;
4250
4251    --  Start of processing for Freeze_Expression
4252
4253    begin
4254       --  Immediate return if freezing is inhibited. This flag is set by the
4255       --  analyzer to stop freezing on generated expressions that would cause
4256       --  freezing if they were in the source program, but which are not
4257       --  supposed to freeze, since they are created.
4258
4259       if Must_Not_Freeze (N) then
4260          return;
4261       end if;
4262
4263       --  If expression is non-static, then it does not freeze in a default
4264       --  expression, see section "Handling of Default Expressions" in the
4265       --  spec of package Sem for further details. Note that we have to
4266       --  make sure that we actually have a real expression (if we have
4267       --  a subtype indication, we can't test Is_Static_Expression!)
4268
4269       if In_Spec_Exp
4270         and then Nkind (N) in N_Subexpr
4271         and then not Is_Static_Expression (N)
4272       then
4273          return;
4274       end if;
4275
4276       --  Freeze type of expression if not frozen already
4277
4278       Typ := Empty;
4279
4280       if Nkind (N) in N_Has_Etype then
4281          if not Is_Frozen (Etype (N)) then
4282             Typ := Etype (N);
4283
4284          --  Base type may be an derived numeric type that is frozen at
4285          --  the point of declaration, but first_subtype is still unfrozen.
4286
4287          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4288             Typ := First_Subtype (Etype (N));
4289          end if;
4290       end if;
4291
4292       --  For entity name, freeze entity if not frozen already. A special
4293       --  exception occurs for an identifier that did not come from source.
4294       --  We don't let such identifiers freeze a non-internal entity, i.e.
4295       --  an entity that did come from source, since such an identifier was
4296       --  generated by the expander, and cannot have any semantic effect on
4297       --  the freezing semantics. For example, this stops the parameter of
4298       --  an initialization procedure from freezing the variable.
4299
4300       if Is_Entity_Name (N)
4301         and then not Is_Frozen (Entity (N))
4302         and then (Nkind (N) /= N_Identifier
4303                    or else Comes_From_Source (N)
4304                    or else not Comes_From_Source (Entity (N)))
4305       then
4306          Nam := Entity (N);
4307       else
4308          Nam := Empty;
4309       end if;
4310
4311       --  For an allocator freeze designated type if not frozen already
4312
4313       --  For an aggregate whose component type is an access type, freeze the
4314       --  designated type now, so that its freeze does not appear within the
4315       --  loop that might be created in the expansion of the aggregate. If the
4316       --  designated type is a private type without full view, the expression
4317       --  cannot contain an allocator, so the type is not frozen.
4318
4319       --  For a function, we freeze the entity when the subprogram declaration
4320       --  is frozen, but a function call may appear in an initialization proc.
4321       --  before the declaration is frozen. We need to generate the extra
4322       --  formals, if any, to ensure that the expansion of the call includes
4323       --  the proper actuals. This only applies to Ada subprograms, not to
4324       --  imported ones.
4325
4326       Desig_Typ := Empty;
4327
4328       case Nkind (N) is
4329          when N_Allocator =>
4330             Desig_Typ := Designated_Type (Etype (N));
4331
4332          when N_Aggregate =>
4333             if Is_Array_Type (Etype (N))
4334               and then Is_Access_Type (Component_Type (Etype (N)))
4335             then
4336                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4337             end if;
4338
4339          when N_Selected_Component |
4340             N_Indexed_Component    |
4341             N_Slice                =>
4342
4343             if Is_Access_Type (Etype (Prefix (N))) then
4344                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4345             end if;
4346
4347          when N_Identifier =>
4348             if Present (Nam)
4349               and then Ekind (Nam) = E_Function
4350               and then Nkind (Parent (N)) = N_Function_Call
4351               and then Convention (Nam) = Convention_Ada
4352             then
4353                Create_Extra_Formals (Nam);
4354             end if;
4355
4356          when others =>
4357             null;
4358       end case;
4359
4360       if Desig_Typ /= Empty
4361         and then (Is_Frozen (Desig_Typ)
4362                    or else (not Is_Fully_Defined (Desig_Typ)))
4363       then
4364          Desig_Typ := Empty;
4365       end if;
4366
4367       --  All done if nothing needs freezing
4368
4369       if No (Typ)
4370         and then No (Nam)
4371         and then No (Desig_Typ)
4372       then
4373          return;
4374       end if;
4375
4376       --  Loop for looking at the right place to insert the freeze nodes,
4377       --  exiting from the loop when it is appropriate to insert the freeze
4378       --  node before the current node P.
4379
4380       --  Also checks some special exceptions to the freezing rules. These
4381       --  cases result in a direct return, bypassing the freeze action.
4382
4383       P := N;
4384       loop
4385          Parent_P := Parent (P);
4386
4387          --  If we don't have a parent, then we are not in a well-formed tree.
4388          --  This is an unusual case, but there are some legitimate situations
4389          --  in which this occurs, notably when the expressions in the range of
4390          --  a type declaration are resolved. We simply ignore the freeze
4391          --  request in this case. Is this right ???
4392
4393          if No (Parent_P) then
4394             return;
4395          end if;
4396
4397          --  See if we have got to an appropriate point in the tree
4398
4399          case Nkind (Parent_P) is
4400
4401             --  A special test for the exception of (RM 13.14(8)) for the case
4402             --  of per-object expressions (RM 3.8(18)) occurring in component
4403             --  definition or a discrete subtype definition. Note that we test
4404             --  for a component declaration which includes both cases we are
4405             --  interested in, and furthermore the tree does not have explicit
4406             --  nodes for either of these two constructs.
4407
4408             when N_Component_Declaration =>
4409
4410                --  The case we want to test for here is an identifier that is
4411                --  a per-object expression, this is either a discriminant that
4412                --  appears in a context other than the component declaration
4413                --  or it is a reference to the type of the enclosing construct.
4414
4415                --  For either of these cases, we skip the freezing
4416
4417                if not In_Spec_Expression
4418                  and then Nkind (N) = N_Identifier
4419                  and then (Present (Entity (N)))
4420                then
4421                   --  We recognize the discriminant case by just looking for
4422                   --  a reference to a discriminant. It can only be one for
4423                   --  the enclosing construct. Skip freezing in this case.
4424
4425                   if Ekind (Entity (N)) = E_Discriminant then
4426                      return;
4427
4428                   --  For the case of a reference to the enclosing record,
4429                   --  (or task or protected type), we look for a type that
4430                   --  matches the current scope.
4431
4432                   elsif Entity (N) = Current_Scope then
4433                      return;
4434                   end if;
4435                end if;
4436
4437             --  If we have an enumeration literal that appears as the choice in
4438             --  the aggregate of an enumeration representation clause, then
4439             --  freezing does not occur (RM 13.14(10)).
4440
4441             when N_Enumeration_Representation_Clause =>
4442
4443                --  The case we are looking for is an enumeration literal
4444
4445                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4446                  and then Is_Enumeration_Type (Etype (N))
4447                then
4448                   --  If enumeration literal appears directly as the choice,
4449                   --  do not freeze (this is the normal non-overloaded case)
4450
4451                   if Nkind (Parent (N)) = N_Component_Association
4452                     and then First (Choices (Parent (N))) = N
4453                   then
4454                      return;
4455
4456                   --  If enumeration literal appears as the name of function
4457                   --  which is the choice, then also do not freeze. This
4458                   --  happens in the overloaded literal case, where the
4459                   --  enumeration literal is temporarily changed to a function
4460                   --  call for overloading analysis purposes.
4461
4462                   elsif Nkind (Parent (N)) = N_Function_Call
4463                      and then
4464                        Nkind (Parent (Parent (N))) = N_Component_Association
4465                      and then
4466                        First (Choices (Parent (Parent (N)))) = Parent (N)
4467                   then
4468                      return;
4469                   end if;
4470                end if;
4471
4472             --  Normally if the parent is a handled sequence of statements,
4473             --  then the current node must be a statement, and that is an
4474             --  appropriate place to insert a freeze node.
4475
4476             when N_Handled_Sequence_Of_Statements =>
4477
4478                --  An exception occurs when the sequence of statements is for
4479                --  an expander generated body that did not do the usual freeze
4480                --  all operation. In this case we usually want to freeze
4481                --  outside this body, not inside it, and we skip past the
4482                --  subprogram body that we are inside.
4483
4484                if In_Exp_Body (Parent_P) then
4485
4486                   --  However, we *do* want to freeze at this point if we have
4487                   --  an entity to freeze, and that entity is declared *inside*
4488                   --  the body of the expander generated procedure. This case
4489                   --  is recognized by the scope of the type, which is either
4490                   --  the spec for some enclosing body, or (in the case of
4491                   --  init_procs, for which there are no separate specs) the
4492                   --  current scope.
4493
4494                   declare
4495                      Subp : constant Node_Id := Parent (Parent_P);
4496                      Cspc : Entity_Id;
4497
4498                   begin
4499                      if Nkind (Subp) = N_Subprogram_Body then
4500                         Cspc := Corresponding_Spec (Subp);
4501
4502                         if (Present (Typ) and then Scope (Typ) = Cspc)
4503                              or else
4504                            (Present (Nam) and then Scope (Nam) = Cspc)
4505                         then
4506                            exit;
4507
4508                         elsif Present (Typ)
4509                           and then Scope (Typ) = Current_Scope
4510                           and then Current_Scope = Defining_Entity (Subp)
4511                         then
4512                            exit;
4513                         end if;
4514                      end if;
4515                   end;
4516
4517                   --  If not that exception to the exception, then this is
4518                   --  where we delay the freeze till outside the body.
4519
4520                   Parent_P := Parent (Parent_P);
4521                   Freeze_Outside := True;
4522
4523                --  Here if normal case where we are in handled statement
4524                --  sequence and want to do the insertion right there.
4525
4526                else
4527                   exit;
4528                end if;
4529
4530             --  If parent is a body or a spec or a block, then the current node
4531             --  is a statement or declaration and we can insert the freeze node
4532             --  before it.
4533
4534             when N_Package_Specification |
4535                  N_Package_Body          |
4536                  N_Subprogram_Body       |
4537                  N_Task_Body             |
4538                  N_Protected_Body        |
4539                  N_Entry_Body            |
4540                  N_Block_Statement       => exit;
4541
4542             --  The expander is allowed to define types in any statements list,
4543             --  so any of the following parent nodes also mark a freezing point
4544             --  if the actual node is in a list of statements or declarations.
4545
4546             when N_Exception_Handler          |
4547                  N_If_Statement               |
4548                  N_Elsif_Part                 |
4549                  N_Case_Statement_Alternative |
4550                  N_Compilation_Unit_Aux       |
4551                  N_Selective_Accept           |
4552                  N_Accept_Alternative         |
4553                  N_Delay_Alternative          |
4554                  N_Conditional_Entry_Call     |
4555                  N_Entry_Call_Alternative     |
4556                  N_Triggering_Alternative     |
4557                  N_Abortable_Part             |
4558                  N_And_Then                   |
4559                  N_Or_Else                    |
4560                  N_Freeze_Entity              =>
4561
4562                exit when Is_List_Member (P);
4563
4564             --  Note: The N_Loop_Statement is a special case. A type that
4565             --  appears in the source can never be frozen in a loop (this
4566             --  occurs only because of a loop expanded by the expander), so we
4567             --  keep on going. Otherwise we terminate the search. Same is true
4568             --  of any entity which comes from source. (if they have predefined
4569             --  type, that type does not appear to come from source, but the
4570             --  entity should not be frozen here).
4571
4572             when N_Loop_Statement =>
4573                exit when not Comes_From_Source (Etype (N))
4574                  and then (No (Nam) or else not Comes_From_Source (Nam));
4575
4576             --  For all other cases, keep looking at parents
4577
4578             when others =>
4579                null;
4580          end case;
4581
4582          --  We fall through the case if we did not yet find the proper
4583          --  place in the free for inserting the freeze node, so climb!
4584
4585          P := Parent_P;
4586       end loop;
4587
4588       --  If the expression appears in a record or an initialization procedure,
4589       --  the freeze nodes are collected and attached to the current scope, to
4590       --  be inserted and analyzed on exit from the scope, to insure that
4591       --  generated entities appear in the correct scope. If the expression is
4592       --  a default for a discriminant specification, the scope is still void.
4593       --  The expression can also appear in the discriminant part of a private
4594       --  or concurrent type.
4595
4596       --  If the expression appears in a constrained subcomponent of an
4597       --  enclosing record declaration, the freeze nodes must be attached to
4598       --  the outer record type so they can eventually be placed in the
4599       --  enclosing declaration list.
4600
4601       --  The other case requiring this special handling is if we are in a
4602       --  default expression, since in that case we are about to freeze a
4603       --  static type, and the freeze scope needs to be the outer scope, not
4604       --  the scope of the subprogram with the default parameter.
4605
4606       --  For default expressions and other spec expressions in generic units,
4607       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4608       --  placing them at the proper place, after the generic unit.
4609
4610       if (In_Spec_Exp and not Inside_A_Generic)
4611         or else Freeze_Outside
4612         or else (Is_Type (Current_Scope)
4613                   and then (not Is_Concurrent_Type (Current_Scope)
4614                              or else not Has_Completion (Current_Scope)))
4615         or else Ekind (Current_Scope) = E_Void
4616       then
4617          declare
4618             N            : constant Node_Id    := Current_Scope;
4619             Freeze_Nodes : List_Id             := No_List;
4620             Pos          : Int                 := Scope_Stack.Last;
4621
4622          begin
4623             if Present (Desig_Typ) then
4624                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4625             end if;
4626
4627             if Present (Typ) then
4628                Freeze_And_Append (Typ, N, Freeze_Nodes);
4629             end if;
4630
4631             if Present (Nam) then
4632                Freeze_And_Append (Nam, N, Freeze_Nodes);
4633             end if;
4634
4635             --  The current scope may be that of a constrained component of
4636             --  an enclosing record declaration, which is above the current
4637             --  scope in the scope stack.
4638             --  If the expression is within a top-level pragma, as for a pre-
4639             --  condition on a library-level subprogram, nothing to do.
4640
4641             if not Is_Compilation_Unit (Current_Scope)
4642               and then Is_Record_Type (Scope (Current_Scope))
4643             then
4644                Pos := Pos - 1;
4645             end if;
4646
4647             if Is_Non_Empty_List (Freeze_Nodes) then
4648                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4649                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4650                     Freeze_Nodes;
4651                else
4652                   Append_List (Freeze_Nodes,
4653                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4654                end if;
4655             end if;
4656          end;
4657
4658          return;
4659       end if;
4660
4661       --  Now we have the right place to do the freezing. First, a special
4662       --  adjustment, if we are in spec-expression analysis mode, these freeze
4663       --  actions must not be thrown away (normally all inserted actions are
4664       --  thrown away in this mode. However, the freeze actions are from static
4665       --  expressions and one of the important reasons we are doing this
4666       --  special analysis is to get these freeze actions. Therefore we turn
4667       --  off the In_Spec_Expression mode to propagate these freeze actions.
4668       --  This also means they get properly analyzed and expanded.
4669
4670       In_Spec_Expression := False;
4671
4672       --  Freeze the designated type of an allocator (RM 13.14(13))
4673
4674       if Present (Desig_Typ) then
4675          Freeze_Before (P, Desig_Typ);
4676       end if;
4677
4678       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4679       --  the enumeration representation clause exception in the loop above.
4680
4681       if Present (Typ) then
4682          Freeze_Before (P, Typ);
4683       end if;
4684
4685       --  Freeze name if one is present (RM 13.14(11))
4686
4687       if Present (Nam) then
4688          Freeze_Before (P, Nam);
4689       end if;
4690
4691       --  Restore In_Spec_Expression flag
4692
4693       In_Spec_Expression := In_Spec_Exp;
4694    end Freeze_Expression;
4695
4696    -----------------------------
4697    -- Freeze_Fixed_Point_Type --
4698    -----------------------------
4699
4700    --  Certain fixed-point types and subtypes, including implicit base types
4701    --  and declared first subtypes, have not yet set up a range. This is
4702    --  because the range cannot be set until the Small and Size values are
4703    --  known, and these are not known till the type is frozen.
4704
4705    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4706    --  whose bounds are unanalyzed real literals. This routine will recognize
4707    --  this case, and transform this range node into a properly typed range
4708    --  with properly analyzed and resolved values.
4709
4710    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4711       Rng   : constant Node_Id    := Scalar_Range (Typ);
4712       Lo    : constant Node_Id    := Low_Bound (Rng);
4713       Hi    : constant Node_Id    := High_Bound (Rng);
4714       Btyp  : constant Entity_Id  := Base_Type (Typ);
4715       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4716       BLo   : constant Node_Id    := Low_Bound (Brng);
4717       BHi   : constant Node_Id    := High_Bound (Brng);
4718       Small : constant Ureal      := Small_Value (Typ);
4719       Loval : Ureal;
4720       Hival : Ureal;
4721       Atype : Entity_Id;
4722
4723       Actual_Size : Nat;
4724
4725       function Fsize (Lov, Hiv : Ureal) return Nat;
4726       --  Returns size of type with given bounds. Also leaves these
4727       --  bounds set as the current bounds of the Typ.
4728
4729       -----------
4730       -- Fsize --
4731       -----------
4732
4733       function Fsize (Lov, Hiv : Ureal) return Nat is
4734       begin
4735          Set_Realval (Lo, Lov);
4736          Set_Realval (Hi, Hiv);
4737          return Minimum_Size (Typ);
4738       end Fsize;
4739
4740    --  Start of processing for Freeze_Fixed_Point_Type
4741
4742    begin
4743       --  If Esize of a subtype has not previously been set, set it now
4744
4745       if Unknown_Esize (Typ) then
4746          Atype := Ancestor_Subtype (Typ);
4747
4748          if Present (Atype) then
4749             Set_Esize (Typ, Esize (Atype));
4750          else
4751             Set_Esize (Typ, Esize (Base_Type (Typ)));
4752          end if;
4753       end if;
4754
4755       --  Immediate return if the range is already analyzed. This means that
4756       --  the range is already set, and does not need to be computed by this
4757       --  routine.
4758
4759       if Analyzed (Rng) then
4760          return;
4761       end if;
4762
4763       --  Immediate return if either of the bounds raises Constraint_Error
4764
4765       if Raises_Constraint_Error (Lo)
4766         or else Raises_Constraint_Error (Hi)
4767       then
4768          return;
4769       end if;
4770
4771       Loval := Realval (Lo);
4772       Hival := Realval (Hi);
4773
4774       --  Ordinary fixed-point case
4775
4776       if Is_Ordinary_Fixed_Point_Type (Typ) then
4777
4778          --  For the ordinary fixed-point case, we are allowed to fudge the
4779          --  end-points up or down by small. Generally we prefer to fudge up,
4780          --  i.e. widen the bounds for non-model numbers so that the end points
4781          --  are included. However there are cases in which this cannot be
4782          --  done, and indeed cases in which we may need to narrow the bounds.
4783          --  The following circuit makes the decision.
4784
4785          --  Note: our terminology here is that Incl_EP means that the bounds
4786          --  are widened by Small if necessary to include the end points, and
4787          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4788          --  end-points if this reduces the size.
4789
4790          --  Note that in the Incl case, all we care about is including the
4791          --  end-points. In the Excl case, we want to narrow the bounds as
4792          --  much as permitted by the RM, to give the smallest possible size.
4793
4794          Fudge : declare
4795             Loval_Incl_EP : Ureal;
4796             Hival_Incl_EP : Ureal;
4797
4798             Loval_Excl_EP : Ureal;
4799             Hival_Excl_EP : Ureal;
4800
4801             Size_Incl_EP  : Nat;
4802             Size_Excl_EP  : Nat;
4803
4804             Model_Num     : Ureal;
4805             First_Subt    : Entity_Id;
4806             Actual_Lo     : Ureal;
4807             Actual_Hi     : Ureal;
4808
4809          begin
4810             --  First step. Base types are required to be symmetrical. Right
4811             --  now, the base type range is a copy of the first subtype range.
4812             --  This will be corrected before we are done, but right away we
4813             --  need to deal with the case where both bounds are non-negative.
4814             --  In this case, we set the low bound to the negative of the high
4815             --  bound, to make sure that the size is computed to include the
4816             --  required sign. Note that we do not need to worry about the
4817             --  case of both bounds negative, because the sign will be dealt
4818             --  with anyway. Furthermore we can't just go making such a bound
4819             --  symmetrical, since in a twos-complement system, there is an
4820             --  extra negative value which could not be accommodated on the
4821             --  positive side.
4822
4823             if Typ = Btyp
4824               and then not UR_Is_Negative (Loval)
4825               and then Hival > Loval
4826             then
4827                Loval := -Hival;
4828                Set_Realval (Lo, Loval);
4829             end if;
4830
4831             --  Compute the fudged bounds. If the number is a model number,
4832             --  then we do nothing to include it, but we are allowed to backoff
4833             --  to the next adjacent model number when we exclude it. If it is
4834             --  not a model number then we straddle the two values with the
4835             --  model numbers on either side.
4836
4837             Model_Num := UR_Trunc (Loval / Small) * Small;
4838
4839             if Loval = Model_Num then
4840                Loval_Incl_EP := Model_Num;
4841             else
4842                Loval_Incl_EP := Model_Num - Small;
4843             end if;
4844
4845             --  The low value excluding the end point is Small greater, but
4846             --  we do not do this exclusion if the low value is positive,
4847             --  since it can't help the size and could actually hurt by
4848             --  crossing the high bound.
4849
4850             if UR_Is_Negative (Loval_Incl_EP) then
4851                Loval_Excl_EP := Loval_Incl_EP + Small;
4852
4853                --  If the value went from negative to zero, then we have the
4854                --  case where Loval_Incl_EP is the model number just below
4855                --  zero, so we want to stick to the negative value for the
4856                --  base type to maintain the condition that the size will
4857                --  include signed values.
4858
4859                if Typ = Btyp
4860                  and then UR_Is_Zero (Loval_Excl_EP)
4861                then
4862                   Loval_Excl_EP := Loval_Incl_EP;
4863                end if;
4864
4865             else
4866                Loval_Excl_EP := Loval_Incl_EP;
4867             end if;
4868
4869             --  Similar processing for upper bound and high value
4870
4871             Model_Num := UR_Trunc (Hival / Small) * Small;
4872
4873             if Hival = Model_Num then
4874                Hival_Incl_EP := Model_Num;
4875             else
4876                Hival_Incl_EP := Model_Num + Small;
4877             end if;
4878
4879             if UR_Is_Positive (Hival_Incl_EP) then
4880                Hival_Excl_EP := Hival_Incl_EP - Small;
4881             else
4882                Hival_Excl_EP := Hival_Incl_EP;
4883             end if;
4884
4885             --  One further adjustment is needed. In the case of subtypes, we
4886             --  cannot go outside the range of the base type, or we get
4887             --  peculiarities, and the base type range is already set. This
4888             --  only applies to the Incl values, since clearly the Excl values
4889             --  are already as restricted as they are allowed to be.
4890
4891             if Typ /= Btyp then
4892                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
4893                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
4894             end if;
4895
4896             --  Get size including and excluding end points
4897
4898             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
4899             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
4900
4901             --  No need to exclude end-points if it does not reduce size
4902
4903             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
4904                Loval_Excl_EP := Loval_Incl_EP;
4905             end if;
4906
4907             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
4908                Hival_Excl_EP := Hival_Incl_EP;
4909             end if;
4910
4911             --  Now we set the actual size to be used. We want to use the
4912             --  bounds fudged up to include the end-points but only if this
4913             --  can be done without violating a specifically given size
4914             --  size clause or causing an unacceptable increase in size.
4915
4916             --  Case of size clause given
4917
4918             if Has_Size_Clause (Typ) then
4919
4920                --  Use the inclusive size only if it is consistent with
4921                --  the explicitly specified size.
4922
4923                if Size_Incl_EP <= RM_Size (Typ) then
4924                   Actual_Lo   := Loval_Incl_EP;
4925                   Actual_Hi   := Hival_Incl_EP;
4926                   Actual_Size := Size_Incl_EP;
4927
4928                --  If the inclusive size is too large, we try excluding
4929                --  the end-points (will be caught later if does not work).
4930
4931                else
4932                   Actual_Lo   := Loval_Excl_EP;
4933                   Actual_Hi   := Hival_Excl_EP;
4934                   Actual_Size := Size_Excl_EP;
4935                end if;
4936
4937             --  Case of size clause not given
4938
4939             else
4940                --  If we have a base type whose corresponding first subtype
4941                --  has an explicit size that is large enough to include our
4942                --  end-points, then do so. There is no point in working hard
4943                --  to get a base type whose size is smaller than the specified
4944                --  size of the first subtype.
4945
4946                First_Subt := First_Subtype (Typ);
4947
4948                if Has_Size_Clause (First_Subt)
4949                  and then Size_Incl_EP <= Esize (First_Subt)
4950                then
4951                   Actual_Size := Size_Incl_EP;
4952                   Actual_Lo   := Loval_Incl_EP;
4953                   Actual_Hi   := Hival_Incl_EP;
4954
4955                --  If excluding the end-points makes the size smaller and
4956                --  results in a size of 8,16,32,64, then we take the smaller
4957                --  size. For the 64 case, this is compulsory. For the other
4958                --  cases, it seems reasonable. We like to include end points
4959                --  if we can, but not at the expense of moving to the next
4960                --  natural boundary of size.
4961
4962                elsif Size_Incl_EP /= Size_Excl_EP
4963                  and then Addressable (Size_Excl_EP)
4964                then
4965                   Actual_Size := Size_Excl_EP;
4966                   Actual_Lo   := Loval_Excl_EP;
4967                   Actual_Hi   := Hival_Excl_EP;
4968
4969                --  Otherwise we can definitely include the end points
4970
4971                else
4972                   Actual_Size := Size_Incl_EP;
4973                   Actual_Lo   := Loval_Incl_EP;
4974                   Actual_Hi   := Hival_Incl_EP;
4975                end if;
4976
4977                --  One pathological case: normally we never fudge a low bound
4978                --  down, since it would seem to increase the size (if it has
4979                --  any effect), but for ranges containing single value, or no
4980                --  values, the high bound can be small too large. Consider:
4981
4982                --    type t is delta 2.0**(-14)
4983                --      range 131072.0 .. 0;
4984
4985                --  That lower bound is *just* outside the range of 32 bits, and
4986                --  does need fudging down in this case. Note that the bounds
4987                --  will always have crossed here, since the high bound will be
4988                --  fudged down if necessary, as in the case of:
4989
4990                --    type t is delta 2.0**(-14)
4991                --      range 131072.0 .. 131072.0;
4992
4993                --  So we detect the situation by looking for crossed bounds,
4994                --  and if the bounds are crossed, and the low bound is greater
4995                --  than zero, we will always back it off by small, since this
4996                --  is completely harmless.
4997
4998                if Actual_Lo > Actual_Hi then
4999                   if UR_Is_Positive (Actual_Lo) then
5000                      Actual_Lo   := Loval_Incl_EP - Small;
5001                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5002
5003                   --  And of course, we need to do exactly the same parallel
5004                   --  fudge for flat ranges in the negative region.
5005
5006                   elsif UR_Is_Negative (Actual_Hi) then
5007                      Actual_Hi := Hival_Incl_EP + Small;
5008                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5009                   end if;
5010                end if;
5011             end if;
5012
5013             Set_Realval (Lo, Actual_Lo);
5014             Set_Realval (Hi, Actual_Hi);
5015          end Fudge;
5016
5017       --  For the decimal case, none of this fudging is required, since there
5018       --  are no end-point problems in the decimal case (the end-points are
5019       --  always included).
5020
5021       else
5022          Actual_Size := Fsize (Loval, Hival);
5023       end if;
5024
5025       --  At this stage, the actual size has been calculated and the proper
5026       --  required bounds are stored in the low and high bounds.
5027
5028       if Actual_Size > 64 then
5029          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5030          Error_Msg_N
5031            ("size required (^) for type& too large, maximum allowed is 64",
5032             Typ);
5033          Actual_Size := 64;
5034       end if;
5035
5036       --  Check size against explicit given size
5037
5038       if Has_Size_Clause (Typ) then
5039          if Actual_Size > RM_Size (Typ) then
5040             Error_Msg_Uint_1 := RM_Size (Typ);
5041             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5042             Error_Msg_NE
5043               ("size given (^) for type& too small, minimum allowed is ^",
5044                Size_Clause (Typ), Typ);
5045
5046          else
5047             Actual_Size := UI_To_Int (Esize (Typ));
5048          end if;
5049
5050       --  Increase size to next natural boundary if no size clause given
5051
5052       else
5053          if Actual_Size <= 8 then
5054             Actual_Size := 8;
5055          elsif Actual_Size <= 16 then
5056             Actual_Size := 16;
5057          elsif Actual_Size <= 32 then
5058             Actual_Size := 32;
5059          else
5060             Actual_Size := 64;
5061          end if;
5062
5063          Init_Esize (Typ, Actual_Size);
5064          Adjust_Esize_For_Alignment (Typ);
5065       end if;
5066
5067       --  If we have a base type, then expand the bounds so that they extend to
5068       --  the full width of the allocated size in bits, to avoid junk range
5069       --  checks on intermediate computations.
5070
5071       if Base_Type (Typ) = Typ then
5072          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5073          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5074       end if;
5075
5076       --  Final step is to reanalyze the bounds using the proper type
5077       --  and set the Corresponding_Integer_Value fields of the literals.
5078
5079       Set_Etype (Lo, Empty);
5080       Set_Analyzed (Lo, False);
5081       Analyze (Lo);
5082
5083       --  Resolve with universal fixed if the base type, and the base type if
5084       --  it is a subtype. Note we can't resolve the base type with itself,
5085       --  that would be a reference before definition.
5086
5087       if Typ = Btyp then
5088          Resolve (Lo, Universal_Fixed);
5089       else
5090          Resolve (Lo, Btyp);
5091       end if;
5092
5093       --  Set corresponding integer value for bound
5094
5095       Set_Corresponding_Integer_Value
5096         (Lo, UR_To_Uint (Realval (Lo) / Small));
5097
5098       --  Similar processing for high bound
5099
5100       Set_Etype (Hi, Empty);
5101       Set_Analyzed (Hi, False);
5102       Analyze (Hi);
5103
5104       if Typ = Btyp then
5105          Resolve (Hi, Universal_Fixed);
5106       else
5107          Resolve (Hi, Btyp);
5108       end if;
5109
5110       Set_Corresponding_Integer_Value
5111         (Hi, UR_To_Uint (Realval (Hi) / Small));
5112
5113       --  Set type of range to correspond to bounds
5114
5115       Set_Etype (Rng, Etype (Lo));
5116
5117       --  Set Esize to calculated size if not set already
5118
5119       if Unknown_Esize (Typ) then
5120          Init_Esize (Typ, Actual_Size);
5121       end if;
5122
5123       --  Set RM_Size if not already set. If already set, check value
5124
5125       declare
5126          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5127
5128       begin
5129          if RM_Size (Typ) /= Uint_0 then
5130             if RM_Size (Typ) < Minsiz then
5131                Error_Msg_Uint_1 := RM_Size (Typ);
5132                Error_Msg_Uint_2 := Minsiz;
5133                Error_Msg_NE
5134                  ("size given (^) for type& too small, minimum allowed is ^",
5135                   Size_Clause (Typ), Typ);
5136             end if;
5137
5138          else
5139             Set_RM_Size (Typ, Minsiz);
5140          end if;
5141       end;
5142    end Freeze_Fixed_Point_Type;
5143
5144    ------------------
5145    -- Freeze_Itype --
5146    ------------------
5147
5148    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5149       L : List_Id;
5150
5151    begin
5152       Set_Has_Delayed_Freeze (T);
5153       L := Freeze_Entity (T, N);
5154
5155       if Is_Non_Empty_List (L) then
5156          Insert_Actions (N, L);
5157       end if;
5158    end Freeze_Itype;
5159
5160    --------------------------
5161    -- Freeze_Static_Object --
5162    --------------------------
5163
5164    procedure Freeze_Static_Object (E : Entity_Id) is
5165
5166       Cannot_Be_Static : exception;
5167       --  Exception raised if the type of a static object cannot be made
5168       --  static. This happens if the type depends on non-global objects.
5169
5170       procedure Ensure_Expression_Is_SA (N : Node_Id);
5171       --  Called to ensure that an expression used as part of a type definition
5172       --  is statically allocatable, which means that the expression type is
5173       --  statically allocatable, and the expression is either static, or a
5174       --  reference to a library level constant.
5175
5176       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5177       --  Called to mark a type as static, checking that it is possible
5178       --  to set the type as static. If it is not possible, then the
5179       --  exception Cannot_Be_Static is raised.
5180
5181       -----------------------------
5182       -- Ensure_Expression_Is_SA --
5183       -----------------------------
5184
5185       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5186          Ent : Entity_Id;
5187
5188       begin
5189          Ensure_Type_Is_SA (Etype (N));
5190
5191          if Is_Static_Expression (N) then
5192             return;
5193
5194          elsif Nkind (N) = N_Identifier then
5195             Ent := Entity (N);
5196
5197             if Present (Ent)
5198               and then Ekind (Ent) = E_Constant
5199               and then Is_Library_Level_Entity (Ent)
5200             then
5201                return;
5202             end if;
5203          end if;
5204
5205          raise Cannot_Be_Static;
5206       end Ensure_Expression_Is_SA;
5207
5208       -----------------------
5209       -- Ensure_Type_Is_SA --
5210       -----------------------
5211
5212       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5213          N : Node_Id;
5214          C : Entity_Id;
5215
5216       begin
5217          --  If type is library level, we are all set
5218
5219          if Is_Library_Level_Entity (Typ) then
5220             return;
5221          end if;
5222
5223          --  We are also OK if the type already marked as statically allocated,
5224          --  which means we processed it before.
5225
5226          if Is_Statically_Allocated (Typ) then
5227             return;
5228          end if;
5229
5230          --  Mark type as statically allocated
5231
5232          Set_Is_Statically_Allocated (Typ);
5233
5234          --  Check that it is safe to statically allocate this type
5235
5236          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5237             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5238             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5239
5240          elsif Is_Array_Type (Typ) then
5241             N := First_Index (Typ);
5242             while Present (N) loop
5243                Ensure_Type_Is_SA (Etype (N));
5244                Next_Index (N);
5245             end loop;
5246
5247             Ensure_Type_Is_SA (Component_Type (Typ));
5248
5249          elsif Is_Access_Type (Typ) then
5250             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5251
5252                declare
5253                   F : Entity_Id;
5254                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5255
5256                begin
5257                   if T /= Standard_Void_Type then
5258                      Ensure_Type_Is_SA (T);
5259                   end if;
5260
5261                   F := First_Formal (Designated_Type (Typ));
5262                   while Present (F) loop
5263                      Ensure_Type_Is_SA (Etype (F));
5264                      Next_Formal (F);
5265                   end loop;
5266                end;
5267
5268             else
5269                Ensure_Type_Is_SA (Designated_Type (Typ));
5270             end if;
5271
5272          elsif Is_Record_Type (Typ) then
5273             C := First_Entity (Typ);
5274             while Present (C) loop
5275                if Ekind (C) = E_Discriminant
5276                  or else Ekind (C) = E_Component
5277                then
5278                   Ensure_Type_Is_SA (Etype (C));
5279
5280                elsif Is_Type (C) then
5281                   Ensure_Type_Is_SA (C);
5282                end if;
5283
5284                Next_Entity (C);
5285             end loop;
5286
5287          elsif Ekind (Typ) = E_Subprogram_Type then
5288             Ensure_Type_Is_SA (Etype (Typ));
5289
5290             C := First_Formal (Typ);
5291             while Present (C) loop
5292                Ensure_Type_Is_SA (Etype (C));
5293                Next_Formal (C);
5294             end loop;
5295
5296          else
5297             raise Cannot_Be_Static;
5298          end if;
5299       end Ensure_Type_Is_SA;
5300
5301    --  Start of processing for Freeze_Static_Object
5302
5303    begin
5304       Ensure_Type_Is_SA (Etype (E));
5305
5306    exception
5307       when Cannot_Be_Static =>
5308
5309          --  If the object that cannot be static is imported or exported, then
5310          --  issue an error message saying that this object cannot be imported
5311          --  or exported. If it has an address clause it is an overlay in the
5312          --  current partition and the static requirement is not relevant.
5313          --  Do not issue any error message when ignoring rep clauses.
5314
5315          if Ignore_Rep_Clauses then
5316             null;
5317
5318          elsif Is_Imported (E) then
5319             if No (Address_Clause (E)) then
5320                Error_Msg_N
5321                  ("& cannot be imported (local type is not constant)", E);
5322             end if;
5323
5324          --  Otherwise must be exported, something is wrong if compiler
5325          --  is marking something as statically allocated which cannot be).
5326
5327          else pragma Assert (Is_Exported (E));
5328             Error_Msg_N
5329               ("& cannot be exported (local type is not constant)", E);
5330          end if;
5331    end Freeze_Static_Object;
5332
5333    -----------------------
5334    -- Freeze_Subprogram --
5335    -----------------------
5336
5337    procedure Freeze_Subprogram (E : Entity_Id) is
5338       Retype : Entity_Id;
5339       F      : Entity_Id;
5340
5341    begin
5342       --  Subprogram may not have an address clause unless it is imported
5343
5344       if Present (Address_Clause (E)) then
5345          if not Is_Imported (E) then
5346             Error_Msg_N
5347               ("address clause can only be given " &
5348                "for imported subprogram",
5349                Name (Address_Clause (E)));
5350          end if;
5351       end if;
5352
5353       --  Reset the Pure indication on an imported subprogram unless an
5354       --  explicit Pure_Function pragma was present. We do this because
5355       --  otherwise it is an insidious error to call a non-pure function from
5356       --  pure unit and have calls mysteriously optimized away. What happens
5357       --  here is that the Import can bypass the normal check to ensure that
5358       --  pure units call only pure subprograms.
5359
5360       if Is_Imported (E)
5361         and then Is_Pure (E)
5362         and then not Has_Pragma_Pure_Function (E)
5363       then
5364          Set_Is_Pure (E, False);
5365       end if;
5366
5367       --  For non-foreign convention subprograms, this is where we create
5368       --  the extra formals (for accessibility level and constrained bit
5369       --  information). We delay this till the freeze point precisely so
5370       --  that we know the convention!
5371
5372       if not Has_Foreign_Convention (E) then
5373          Create_Extra_Formals (E);
5374          Set_Mechanisms (E);
5375
5376          --  If this is convention Ada and a Valued_Procedure, that's odd
5377
5378          if Ekind (E) = E_Procedure
5379            and then Is_Valued_Procedure (E)
5380            and then Convention (E) = Convention_Ada
5381            and then Warn_On_Export_Import
5382          then
5383             Error_Msg_N
5384               ("?Valued_Procedure has no effect for convention Ada", E);
5385             Set_Is_Valued_Procedure (E, False);
5386          end if;
5387
5388       --  Case of foreign convention
5389
5390       else
5391          Set_Mechanisms (E);
5392
5393          --  For foreign conventions, warn about return of an
5394          --  unconstrained array.
5395
5396          --  Note: we *do* allow a return by descriptor for the VMS case,
5397          --  though here there is probably more to be done ???
5398
5399          if Ekind (E) = E_Function then
5400             Retype := Underlying_Type (Etype (E));
5401
5402             --  If no return type, probably some other error, e.g. a
5403             --  missing full declaration, so ignore.
5404
5405             if No (Retype) then
5406                null;
5407
5408             --  If the return type is generic, we have emitted a warning
5409             --  earlier on, and there is nothing else to check here. Specific
5410             --  instantiations may lead to erroneous behavior.
5411
5412             elsif Is_Generic_Type (Etype (E)) then
5413                null;
5414
5415             --  Display warning if returning unconstrained array
5416
5417             elsif Is_Array_Type (Retype)
5418               and then not Is_Constrained (Retype)
5419
5420               --  Exclude cases where descriptor mechanism is set, since the
5421               --  VMS descriptor mechanisms allow such unconstrained returns.
5422
5423               and then Mechanism (E) not in Descriptor_Codes
5424
5425               --  Check appropriate warning is enabled (should we check for
5426               --  Warnings (Off) on specific entities here, probably so???)
5427
5428               and then Warn_On_Export_Import
5429
5430                --  Exclude the VM case, since return of unconstrained arrays
5431                --  is properly handled in both the JVM and .NET cases.
5432
5433               and then VM_Target = No_VM
5434             then
5435                Error_Msg_N
5436                 ("?foreign convention function& should not return " &
5437                   "unconstrained array", E);
5438                return;
5439             end if;
5440          end if;
5441
5442          --  If any of the formals for an exported foreign convention
5443          --  subprogram have defaults, then emit an appropriate warning since
5444          --  this is odd (default cannot be used from non-Ada code)
5445
5446          if Is_Exported (E) then
5447             F := First_Formal (E);
5448             while Present (F) loop
5449                if Warn_On_Export_Import
5450                  and then Present (Default_Value (F))
5451                then
5452                   Error_Msg_N
5453                     ("?parameter cannot be defaulted in non-Ada call",
5454                      Default_Value (F));
5455                end if;
5456
5457                Next_Formal (F);
5458             end loop;
5459          end if;
5460       end if;
5461
5462       --  For VMS, descriptor mechanisms for parameters are allowed only for
5463       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5464       --  allowed for parameters of exported subprograms.
5465
5466       if OpenVMS_On_Target then
5467          if Is_Exported (E) then
5468             F := First_Formal (E);
5469             while Present (F) loop
5470                if Mechanism (F) = By_Descriptor_NCA then
5471                   Error_Msg_N
5472                     ("'N'C'A' descriptor for parameter not permitted", F);
5473                   Error_Msg_N
5474                     ("\can only be used for imported subprogram", F);
5475                end if;
5476
5477                Next_Formal (F);
5478             end loop;
5479
5480          elsif not Is_Imported (E) then
5481             F := First_Formal (E);
5482             while Present (F) loop
5483                if Mechanism (F) in Descriptor_Codes then
5484                   Error_Msg_N
5485                     ("descriptor mechanism for parameter not permitted", F);
5486                   Error_Msg_N
5487                     ("\can only be used for imported/exported subprogram", F);
5488                end if;
5489
5490                Next_Formal (F);
5491             end loop;
5492          end if;
5493       end if;
5494
5495       --  Pragma Inline_Always is disallowed for dispatching subprograms
5496       --  because the address of such subprograms is saved in the dispatch
5497       --  table to support dispatching calls, and dispatching calls cannot
5498       --  be inlined. This is consistent with the restriction against using
5499       --  'Access or 'Address on an Inline_Always subprogram.
5500
5501       if Is_Dispatching_Operation (E)
5502         and then Has_Pragma_Inline_Always (E)
5503       then
5504          Error_Msg_N
5505            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5506       end if;
5507
5508       --  Because of the implicit representation of inherited predefined
5509       --  operators in the front-end, the overriding status of the operation
5510       --  may be affected when a full view of a type is analyzed, and this is
5511       --  not captured by the analysis of the corresponding type declaration.
5512       --  Therefore the correctness of a not-overriding indicator must be
5513       --  rechecked when the subprogram is frozen.
5514
5515       if Nkind (E) = N_Defining_Operator_Symbol
5516         and then not Error_Posted (Parent (E))
5517       then
5518          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5519       end if;
5520    end Freeze_Subprogram;
5521
5522    ----------------------
5523    -- Is_Fully_Defined --
5524    ----------------------
5525
5526    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5527    begin
5528       if Ekind (T) = E_Class_Wide_Type then
5529          return Is_Fully_Defined (Etype (T));
5530
5531       elsif Is_Array_Type (T) then
5532          return Is_Fully_Defined (Component_Type (T));
5533
5534       elsif Is_Record_Type (T)
5535         and not Is_Private_Type (T)
5536       then
5537          --  Verify that the record type has no components with private types
5538          --  without completion.
5539
5540          declare
5541             Comp : Entity_Id;
5542
5543          begin
5544             Comp := First_Component (T);
5545             while Present (Comp) loop
5546                if not Is_Fully_Defined (Etype (Comp)) then
5547                   return False;
5548                end if;
5549
5550                Next_Component (Comp);
5551             end loop;
5552             return True;
5553          end;
5554
5555       --  For the designated type of an access to subprogram, all types in
5556       --  the profile must be fully defined.
5557
5558       elsif Ekind (T) = E_Subprogram_Type then
5559          declare
5560             F : Entity_Id;
5561
5562          begin
5563             F := First_Formal (T);
5564             while Present (F) loop
5565                if not Is_Fully_Defined (Etype (F)) then
5566                   return False;
5567                end if;
5568
5569                Next_Formal (F);
5570             end loop;
5571
5572             return Is_Fully_Defined (Etype (T));
5573          end;
5574
5575       else
5576          return not Is_Private_Type (T)
5577            or else Present (Full_View (Base_Type (T)));
5578       end if;
5579    end Is_Fully_Defined;
5580
5581    ---------------------------------
5582    -- Process_Default_Expressions --
5583    ---------------------------------
5584
5585    procedure Process_Default_Expressions
5586      (E     : Entity_Id;
5587       After : in out Node_Id)
5588    is
5589       Loc    : constant Source_Ptr := Sloc (E);
5590       Dbody  : Node_Id;
5591       Formal : Node_Id;
5592       Dcopy  : Node_Id;
5593       Dnam   : Entity_Id;
5594
5595    begin
5596       Set_Default_Expressions_Processed (E);
5597
5598       --  A subprogram instance and its associated anonymous subprogram share
5599       --  their signature. The default expression functions are defined in the
5600       --  wrapper packages for the anonymous subprogram, and should not be
5601       --  generated again for the instance.
5602
5603       if Is_Generic_Instance (E)
5604         and then Present (Alias (E))
5605         and then Default_Expressions_Processed (Alias (E))
5606       then
5607          return;
5608       end if;
5609
5610       Formal := First_Formal (E);
5611       while Present (Formal) loop
5612          if Present (Default_Value (Formal)) then
5613
5614             --  We work with a copy of the default expression because we
5615             --  do not want to disturb the original, since this would mess
5616             --  up the conformance checking.
5617
5618             Dcopy := New_Copy_Tree (Default_Value (Formal));
5619
5620             --  The analysis of the expression may generate insert actions,
5621             --  which of course must not be executed. We wrap those actions
5622             --  in a procedure that is not called, and later on eliminated.
5623             --  The following cases have no side-effects, and are analyzed
5624             --  directly.
5625
5626             if Nkind (Dcopy) = N_Identifier
5627               or else Nkind (Dcopy) = N_Expanded_Name
5628               or else Nkind (Dcopy) = N_Integer_Literal
5629               or else (Nkind (Dcopy) = N_Real_Literal
5630                         and then not Vax_Float (Etype (Dcopy)))
5631               or else Nkind (Dcopy) = N_Character_Literal
5632               or else Nkind (Dcopy) = N_String_Literal
5633               or else Known_Null (Dcopy)
5634               or else (Nkind (Dcopy) = N_Attribute_Reference
5635                         and then
5636                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5637             then
5638
5639                --  If there is no default function, we must still do a full
5640                --  analyze call on the default value, to ensure that all error
5641                --  checks are performed, e.g. those associated with static
5642                --  evaluation. Note: this branch will always be taken if the
5643                --  analyzer is turned off (but we still need the error checks).
5644
5645                --  Note: the setting of parent here is to meet the requirement
5646                --  that we can only analyze the expression while attached to
5647                --  the tree. Really the requirement is that the parent chain
5648                --  be set, we don't actually need to be in the tree.
5649
5650                Set_Parent (Dcopy, Declaration_Node (Formal));
5651                Analyze (Dcopy);
5652
5653                --  Default expressions are resolved with their own type if the
5654                --  context is generic, to avoid anomalies with private types.
5655
5656                if Ekind (Scope (E)) = E_Generic_Package then
5657                   Resolve (Dcopy);
5658                else
5659                   Resolve (Dcopy, Etype (Formal));
5660                end if;
5661
5662                --  If that resolved expression will raise constraint error,
5663                --  then flag the default value as raising constraint error.
5664                --  This allows a proper error message on the calls.
5665
5666                if Raises_Constraint_Error (Dcopy) then
5667                   Set_Raises_Constraint_Error (Default_Value (Formal));
5668                end if;
5669
5670             --  If the default is a parameterless call, we use the name of
5671             --  the called function directly, and there is no body to build.
5672
5673             elsif Nkind (Dcopy) = N_Function_Call
5674               and then No (Parameter_Associations (Dcopy))
5675             then
5676                null;
5677
5678             --  Else construct and analyze the body of a wrapper procedure
5679             --  that contains an object declaration to hold the expression.
5680             --  Given that this is done only to complete the analysis, it
5681             --  simpler to build a procedure than a function which might
5682             --  involve secondary stack expansion.
5683
5684             else
5685                Dnam := Make_Temporary (Loc, 'D');
5686
5687                Dbody :=
5688                  Make_Subprogram_Body (Loc,
5689                    Specification =>
5690                      Make_Procedure_Specification (Loc,
5691                        Defining_Unit_Name => Dnam),
5692
5693                    Declarations => New_List (
5694                      Make_Object_Declaration (Loc,
5695                        Defining_Identifier =>
5696                          Make_Defining_Identifier (Loc,
5697                            New_Internal_Name ('T')),
5698                          Object_Definition =>
5699                            New_Occurrence_Of (Etype (Formal), Loc),
5700                          Expression => New_Copy_Tree (Dcopy))),
5701
5702                    Handled_Statement_Sequence =>
5703                      Make_Handled_Sequence_Of_Statements (Loc,
5704                        Statements => New_List));
5705
5706                Set_Scope (Dnam, Scope (E));
5707                Set_Assignment_OK (First (Declarations (Dbody)));
5708                Set_Is_Eliminated (Dnam);
5709                Insert_After (After, Dbody);
5710                Analyze (Dbody);
5711                After := Dbody;
5712             end if;
5713          end if;
5714
5715          Next_Formal (Formal);
5716       end loop;
5717    end Process_Default_Expressions;
5718
5719    ----------------------------------------
5720    -- Set_Component_Alignment_If_Not_Set --
5721    ----------------------------------------
5722
5723    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5724    begin
5725       --  Ignore if not base type, subtypes don't need anything
5726
5727       if Typ /= Base_Type (Typ) then
5728          return;
5729       end if;
5730
5731       --  Do not override existing representation
5732
5733       if Is_Packed (Typ) then
5734          return;
5735
5736       elsif Has_Specified_Layout (Typ) then
5737          return;
5738
5739       elsif Component_Alignment (Typ) /= Calign_Default then
5740          return;
5741
5742       else
5743          Set_Component_Alignment
5744            (Typ, Scope_Stack.Table
5745                   (Scope_Stack.Last).Component_Alignment_Default);
5746       end if;
5747    end Set_Component_Alignment_If_Not_Set;
5748
5749    ------------------
5750    -- Undelay_Type --
5751    ------------------
5752
5753    procedure Undelay_Type (T : Entity_Id) is
5754    begin
5755       Set_Has_Delayed_Freeze (T, False);
5756       Set_Freeze_Node (T, Empty);
5757
5758       --  Since we don't want T to have a Freeze_Node, we don't want its
5759       --  Full_View or Corresponding_Record_Type to have one either.
5760
5761       --  ??? Fundamentally, this whole handling is a kludge. What we really
5762       --  want is to be sure that for an Itype that's part of record R and is a
5763       --  subtype of type T, that it's frozen after the later of the freeze
5764       --  points of R and T. We have no way of doing that directly, so what we
5765       --  do is force most such Itypes to be frozen as part of freezing R via
5766       --  this procedure and only delay the ones that need to be delayed
5767       --  (mostly the designated types of access types that are defined as part
5768       --  of the record).
5769
5770       if Is_Private_Type (T)
5771         and then Present (Full_View (T))
5772         and then Is_Itype (Full_View (T))
5773         and then Is_Record_Type (Scope (Full_View (T)))
5774       then
5775          Undelay_Type (Full_View (T));
5776       end if;
5777
5778       if Is_Concurrent_Type (T)
5779         and then Present (Corresponding_Record_Type (T))
5780         and then Is_Itype (Corresponding_Record_Type (T))
5781         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5782       then
5783          Undelay_Type (Corresponding_Record_Type (T));
5784       end if;
5785    end Undelay_Type;
5786
5787    ------------------
5788    -- Warn_Overlay --
5789    ------------------
5790
5791    procedure Warn_Overlay
5792      (Expr : Node_Id;
5793       Typ  : Entity_Id;
5794       Nam  : Entity_Id)
5795    is
5796       Ent : constant Entity_Id := Entity (Nam);
5797       --  The object to which the address clause applies
5798
5799       Init : Node_Id;
5800       Old  : Entity_Id := Empty;
5801       Decl : Node_Id;
5802
5803    begin
5804       --  No warning if address clause overlay warnings are off
5805
5806       if not Address_Clause_Overlay_Warnings then
5807          return;
5808       end if;
5809
5810       --  No warning if there is an explicit initialization
5811
5812       Init := Original_Node (Expression (Declaration_Node (Ent)));
5813
5814       if Present (Init) and then Comes_From_Source (Init) then
5815          return;
5816       end if;
5817
5818       --  We only give the warning for non-imported entities of a type for
5819       --  which a non-null base init proc is defined, or for objects of access
5820       --  types with implicit null initialization, or when Normalize_Scalars
5821       --  applies and the type is scalar or a string type (the latter being
5822       --  tested for because predefined String types are initialized by inline
5823       --  code rather than by an init_proc). Note that we do not give the
5824       --  warning for Initialize_Scalars, since we suppressed initialization
5825       --  in this case.
5826
5827       if Present (Expr)
5828         and then not Is_Imported (Ent)
5829         and then (Has_Non_Null_Base_Init_Proc (Typ)
5830                     or else Is_Access_Type (Typ)
5831                     or else (Normalize_Scalars
5832                               and then (Is_Scalar_Type (Typ)
5833                                          or else Is_String_Type (Typ))))
5834       then
5835          if Nkind (Expr) = N_Attribute_Reference
5836            and then Is_Entity_Name (Prefix (Expr))
5837          then
5838             Old := Entity (Prefix (Expr));
5839
5840          elsif Is_Entity_Name (Expr)
5841            and then Ekind (Entity (Expr)) = E_Constant
5842          then
5843             Decl := Declaration_Node (Entity (Expr));
5844
5845             if Nkind (Decl) = N_Object_Declaration
5846               and then Present (Expression (Decl))
5847               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5848               and then Is_Entity_Name (Prefix (Expression (Decl)))
5849             then
5850                Old := Entity (Prefix (Expression (Decl)));
5851
5852             elsif Nkind (Expr) = N_Function_Call then
5853                return;
5854             end if;
5855
5856          --  A function call (most likely to To_Address) is probably not an
5857          --  overlay, so skip warning. Ditto if the function call was inlined
5858          --  and transformed into an entity.
5859
5860          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5861             return;
5862          end if;
5863
5864          Decl := Next (Parent (Expr));
5865
5866          --  If a pragma Import follows, we assume that it is for the current
5867          --  target of the address clause, and skip the warning.
5868
5869          if Present (Decl)
5870            and then Nkind (Decl) = N_Pragma
5871            and then Pragma_Name (Decl) = Name_Import
5872          then
5873             return;
5874          end if;
5875
5876          if Present (Old) then
5877             Error_Msg_Node_2 := Old;
5878             Error_Msg_N
5879               ("default initialization of & may modify &?",
5880                Nam);
5881          else
5882             Error_Msg_N
5883               ("default initialization of & may modify overlaid storage?",
5884                Nam);
5885          end if;
5886
5887          --  Add friendly warning if initialization comes from a packed array
5888          --  component.
5889
5890          if Is_Record_Type (Typ)  then
5891             declare
5892                Comp : Entity_Id;
5893
5894             begin
5895                Comp := First_Component (Typ);
5896                while Present (Comp) loop
5897                   if Nkind (Parent (Comp)) = N_Component_Declaration
5898                     and then Present (Expression (Parent (Comp)))
5899                   then
5900                      exit;
5901                   elsif Is_Array_Type (Etype (Comp))
5902                      and then Present (Packed_Array_Type (Etype (Comp)))
5903                   then
5904                      Error_Msg_NE
5905                        ("\packed array component& " &
5906                         "will be initialized to zero?",
5907                         Nam, Comp);
5908                      exit;
5909                   else
5910                      Next_Component (Comp);
5911                   end if;
5912                end loop;
5913             end;
5914          end if;
5915
5916          Error_Msg_N
5917            ("\use pragma Import for & to " &
5918             "suppress initialization (RM B.1(24))?",
5919             Nam);
5920       end if;
5921    end Warn_Overlay;
5922
5923 end Freeze;