gcc/ada/exp_dbug.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ D B U G                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1996-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Alloc;    use Alloc;
  28 with Atree;    use Atree;
  29 with Debug;    use Debug;
  30 with Einfo;    use Einfo;
  31 with Namet;    use Namet;
  32 with Nlists;   use Nlists;
  33 with Nmake;    use Nmake;
  34 with Opt;      use Opt;
  35 with Output;   use Output;
  36 with Sem_Eval; use Sem_Eval;
  37 with Sem_Util; use Sem_Util;
  38 with Sinfo;    use Sinfo;
  39 with Snames;   use Snames;
  40 with Stand;    use Stand;
  41 with Stringt;  use Stringt;
  42 with Table;
  43 with Urealp;   use Urealp;
  44
  45 package body Exp_Dbug is
  46
  47    --  The following table is used to queue up the entities passed as
  48    --  arguments to Qualify_Entity_Names for later processing when
  49    --  Qualify_All_Entity_Names is called.
  50
  51    package Name_Qualify_Units is new Table.Table (
  52      Table_Component_Type => Node_Id,
  53      Table_Index_Type     => Nat,
  54      Table_Low_Bound      => 1,
  55      Table_Initial        => Alloc.Name_Qualify_Units_Initial,
  56      Table_Increment      => Alloc.Name_Qualify_Units_Increment,
  57      Table_Name           => "Name_Qualify_Units");
  58
  59    --------------------------------
  60    -- Use of Qualification Flags --
  61    --------------------------------
  62
  63    --  There are two flags used to keep track of qualification of entities
  64
  65    --    Has_Fully_Qualified_Name
  66    --    Has_Qualified_Name
  67
  68    --  The difference between these is as follows. Has_Qualified_Name is
  69    --  set to indicate that the name has been qualified as required by the
  70    --  spec of this package. As described there, this may involve the full
  71    --  qualification for the name, but for some entities, notably procedure
  72    --  local variables, this full qualification is not required.
  73
  74    --  The flag Has_Fully_Qualified_Name is set if indeed the name has been
  75    --  fully qualified in the Ada sense. If Has_Fully_Qualified_Name is set,
  76    --  then Has_Qualified_Name is also set, but the other way round is not
  77    --  the case.
  78
  79    --  Consider the following example:
  80
  81    --     with ...
  82    --     procedure X is
  83    --       B : Ddd.Ttt;
  84    --       procedure Y is ..
  85
  86    --  Here B is a procedure local variable, so it does not need fully
  87    --  qualification. The flag Has_Qualified_Name will be set on the
  88    --  first attempt to qualify B, to indicate that the job is done
  89    --  and need not be redone.
  90
  91    --  But Y is qualified as x__y, since procedures are always fully
  92    --  qualified, so the first time that an attempt is made to qualify
  93    --  the name y, it will be replaced by x__y, and both flags are set.
  94
  95    --  Why the two flags? Well there are cases where we derive type names
  96    --  from object names. As noted in the spec, type names are always
  97    --  fully qualified. Suppose for example that the backend has to build
  98    --  a padded type for variable B. then it will construct the PAD name
  99    --  from B, but it requires full qualification, so the fully qualified
 100    --  type name will be x__b___PAD. The two flags allow the circuit for
 101    --  building this name to realize efficiently that b needs further
 102    --  qualification.
 103
 104    --------------------
 105    -- Homonym_Suffix --
 106    --------------------
 107
 108    --  The string defined here (and its associated length) is used to
 109    --  gather the homonym string that will be appended to Name_Buffer
 110    --  when the name is complete. Strip_Suffixes appends to this string
 111    --  as does Append_Homonym_Number, and Output_Homonym_Numbers_Suffix
 112    --  appends the string to the end of Name_Buffer.
 113
 114    Homonym_Numbers : String (1 .. 256);
 115    Homonym_Len     : Natural := 0;
 116
 117    ----------------------
 118    -- Local Procedures --
 119    ----------------------
 120
 121    procedure Add_Uint_To_Buffer (U : Uint);
 122    --  Add image of universal integer to Name_Buffer, updating Name_Len
 123
 124    procedure Add_Real_To_Buffer (U : Ureal);
 125    --  Add nnn_ddd to Name_Buffer, where nnn and ddd are integer values of
 126    --  the normalized numerator and denominator of the given real value.
 127
 128    procedure Append_Homonym_Number (E : Entity_Id);
 129    --  If the entity E has homonyms in the same scope, then make an entry
 130    --  in the Homonym_Numbers array, bumping Homonym_Count accordingly.
 131
 132    function Bounds_Match_Size (E : Entity_Id) return  Boolean;
 133    --  Determine whether the bounds of E match the size of the type. This is
 134    --  used to determine whether encoding is required for a discrete type.
 135
 136    procedure Output_Homonym_Numbers_Suffix;
 137    --  If homonym numbers are stored, then output them into Name_Buffer
 138
 139    procedure Prepend_String_To_Buffer (S : String);
 140    --  Prepend given string to the contents of the string buffer, updating
 141    --  the value in Name_Len (i.e. string is added at start of buffer).
 142
 143    procedure Prepend_Uint_To_Buffer (U : Uint);
 144    --  Prepend image of universal integer to Name_Buffer, updating Name_Len
 145
 146    procedure Qualify_Entity_Name (Ent : Entity_Id);
 147    --  If not already done, replaces the Chars field of the given entity
 148    --  with the appropriate fully qualified name.
 149
 150    procedure Strip_Suffixes (BNPE_Suffix_Found : in out Boolean);
 151    --  Given an qualified entity name in Name_Buffer, remove any plain X or
 152    --  X{nb} qualification suffix. The contents of Name_Buffer is not changed
 153    --  but Name_Len may be adjusted on return to remove the suffix. If a
 154    --  BNPE suffix is found and stripped, then BNPE_Suffix_Found is set to
 155    --  True. If no suffix is found, then BNPE_Suffix_Found is not modified.
 156    --  This routine also searches for a homonym suffix, and if one is found
 157    --  it is also stripped, and the entries are added to the global homonym
 158    --  list (Homonym_Numbers) so that they can later be put back.
 159
 160    ------------------------
 161    -- Add_Real_To_Buffer --
 162    ------------------------
 163
 164    procedure Add_Real_To_Buffer (U : Ureal) is
 165    begin
 166       Add_Uint_To_Buffer (Norm_Num (U));
 167       Add_Str_To_Name_Buffer ("_");
 168       Add_Uint_To_Buffer (Norm_Den (U));
 169    end Add_Real_To_Buffer;
 170
 171    ------------------------
 172    -- Add_Uint_To_Buffer --
 173    ------------------------
 174
 175    procedure Add_Uint_To_Buffer (U : Uint) is
 176    begin
 177       if U < 0 then
 178          Add_Uint_To_Buffer (-U);
 179          Add_Char_To_Name_Buffer ('m');
 180       else
 181          UI_Image (U, Decimal);
 182          Add_Str_To_Name_Buffer (UI_Image_Buffer (1 .. UI_Image_Length));
 183       end if;
 184    end Add_Uint_To_Buffer;
 185
 186    ---------------------------
 187    -- Append_Homonym_Number --
 188    ---------------------------
 189
 190    procedure Append_Homonym_Number (E : Entity_Id) is
 191
 192       procedure Add_Nat_To_H (Nr : Nat);
 193       --  Little procedure to append Nr to Homonym_Numbers
 194
 195       ------------------
 196       -- Add_Nat_To_H --
 197       ------------------
 198
 199       procedure Add_Nat_To_H (Nr : Nat) is
 200       begin
 201          if Nr >= 10 then
 202             Add_Nat_To_H (Nr / 10);
 203          end if;
 204
 205          Homonym_Len := Homonym_Len + 1;
 206          Homonym_Numbers (Homonym_Len) :=
 207            Character'Val (Nr mod 10 + Character'Pos ('0'));
 208       end Add_Nat_To_H;
 209
 210    --  Start of processing for Append_Homonym_Number
 211
 212    begin
 213       if Has_Homonym (E) then
 214          declare
 215             H  : Entity_Id := Homonym (E);
 216             Nr : Nat := 1;
 217
 218          begin
 219             while Present (H) loop
 220                if Scope (H) = Scope (E) then
 221                   Nr := Nr + 1;
 222                end if;
 223
 224                H := Homonym (H);
 225             end loop;
 226
 227             if Homonym_Len > 0 then
 228                Homonym_Len := Homonym_Len + 1;
 229                Homonym_Numbers (Homonym_Len) := '_';
 230             end if;
 231
 232             Add_Nat_To_H (Nr);
 233          end;
 234       end if;
 235    end Append_Homonym_Number;
 236
 237    -----------------------
 238    -- Bounds_Match_Size --
 239    -----------------------
 240
 241    function Bounds_Match_Size (E : Entity_Id) return Boolean is
 242       Siz : Uint;
 243
 244    begin
 245       if not Is_OK_Static_Subtype (E) then
 246          return False;
 247
 248       elsif Is_Integer_Type (E)
 249         and then Subtypes_Statically_Match (E, Base_Type (E))
 250       then
 251          return True;
 252
 253       --  Here we check if the static bounds match the natural size, which is
 254       --  the size passed through with the debugging information. This is the
 255       --  Esize rounded up to 8, 16, 32 or 64 as appropriate.
 256
 257       else
 258          declare
 259             Umark  : constant Uintp.Save_Mark := Uintp.Mark;
 260             Result : Boolean;
 261
 262          begin
 263             if Esize (E) <= 8 then
 264                Siz := Uint_8;
 265             elsif Esize (E) <= 16 then
 266                Siz := Uint_16;
 267             elsif Esize (E) <= 32 then
 268                Siz := Uint_32;
 269             else
 270                Siz := Uint_64;
 271             end if;
 272
 273             if Is_Modular_Integer_Type (E) or else Is_Enumeration_Type (E) then
 274                Result :=
 275                  Expr_Rep_Value (Type_Low_Bound (E)) = 0
 276                    and then
 277                  2 ** Siz - Expr_Rep_Value (Type_High_Bound (E)) = 1;
 278
 279             else
 280                Result :=
 281                  Expr_Rep_Value (Type_Low_Bound (E)) + 2 ** (Siz - 1) = 0
 282                    and then
 283                  2 ** (Siz - 1) - Expr_Rep_Value (Type_High_Bound (E)) = 1;
 284             end if;
 285
 286             Release (Umark);
 287             return Result;
 288          end;
 289       end if;
 290    end Bounds_Match_Size;
 291
 292    --------------------------------
 293    -- Debug_Renaming_Declaration --
 294    --------------------------------
 295
 296    function Debug_Renaming_Declaration (N : Node_Id) return Node_Id is
 297       Loc : constant Source_Ptr := Sloc (N);
 298       Ent : constant Node_Id    := Defining_Entity (N);
 299       Nam : constant Node_Id    := Name (N);
 300       Rnm : Name_Id;
 301       Ren : Node_Id;
 302       Lit : Entity_Id;
 303       Typ : Entity_Id;
 304       Res : Node_Id;
 305       Def : Entity_Id;
 306
 307       function Output_Subscript (N : Node_Id; S : String) return Boolean;
 308       --  Outputs a single subscript value as ?nnn (subscript is compile time
 309       --  known value with value nnn) or as ?e (subscript is local constant
 310       --  with name e), where S supplies the proper string to use for ?.
 311       --  Returns False if the subscript is not of an appropriate type to
 312       --  output in one of these two forms. The result is prepended to the
 313       --  name stored in Name_Buffer.
 314
 315       ----------------------
 316       -- Output_Subscript --
 317       ----------------------
 318
 319       function Output_Subscript (N : Node_Id; S : String) return Boolean is
 320       begin
 321          if Compile_Time_Known_Value (N) then
 322             Prepend_Uint_To_Buffer (Expr_Value (N));
 323
 324          elsif Nkind (N) = N_Identifier
 325            and then Scope (Entity (N)) = Scope (Ent)
 326            and then Ekind (Entity (N)) = E_Constant
 327          then
 328             Prepend_String_To_Buffer (Get_Name_String (Chars (Entity (N))));
 329
 330          else
 331             return False;
 332          end if;
 333
 334          Prepend_String_To_Buffer (S);
 335          return True;
 336       end Output_Subscript;
 337
 338    --  Start of processing for Debug_Renaming_Declaration
 339
 340    begin
 341       if not Comes_From_Source (N)
 342         and then not Needs_Debug_Info (Ent)
 343       then
 344          return Empty;
 345       end if;
 346
 347       --  Prepare entity name for type declaration
 348
 349       Get_Name_String (Chars (Ent));
 350
 351       case Nkind (N) is
 352          when N_Object_Renaming_Declaration =>
 353             Add_Str_To_Name_Buffer ("___XR");
 354
 355          when N_Exception_Renaming_Declaration =>
 356             Add_Str_To_Name_Buffer ("___XRE");
 357
 358          when N_Package_Renaming_Declaration =>
 359             Add_Str_To_Name_Buffer ("___XRP");
 360
 361             --  If it is a child unit create a fully qualified name, to
 362             --  disambiguate multiple child units with the same name and
 363             --  different parents.
 364
 365             if Is_Child_Unit (Ent) then
 366                Prepend_String_To_Buffer ("__");
 367                Prepend_String_To_Buffer
 368                  (Get_Name_String (Chars (Scope (Ent))));
 369             end if;
 370
 371          when others =>
 372             return Empty;
 373       end case;
 374
 375       Rnm := Name_Find;
 376
 377       --  Get renamed entity and compute suffix
 378
 379       Name_Len := 0;
 380       Ren := Nam;
 381       loop
 382          case Nkind (Ren) is
 383
 384             when N_Identifier =>
 385                exit;
 386
 387             when N_Expanded_Name =>
 388
 389                --  The entity field for an N_Expanded_Name is on the expanded
 390                --  name node itself, so we are done here too.
 391
 392                exit;
 393
 394             when N_Selected_Component =>
 395                Prepend_String_To_Buffer
 396                  (Get_Name_String (Chars (Selector_Name (Ren))));
 397                Prepend_String_To_Buffer ("XR");
 398                Ren := Prefix (Ren);
 399
 400             when N_Indexed_Component =>
 401                declare
 402                   X : Node_Id := Last (Expressions (Ren));
 403
 404                begin
 405                   while Present (X) loop
 406                      if not Output_Subscript (X, "XS") then
 407                         Set_Materialize_Entity (Ent);
 408                         return Empty;
 409                      end if;
 410
 411                      Prev (X);
 412                   end loop;
 413                end;
 414
 415                Ren := Prefix (Ren);
 416
 417             when N_Slice =>
 418
 419                Typ := Etype (First_Index (Etype (Nam)));
 420
 421                if not Output_Subscript (Type_High_Bound (Typ), "XS") then
 422                   Set_Materialize_Entity (Ent);
 423                   return Empty;
 424                end if;
 425
 426                if not Output_Subscript (Type_Low_Bound  (Typ), "XL") then
 427                   Set_Materialize_Entity (Ent);
 428                   return Empty;
 429                end if;
 430
 431                Ren := Prefix (Ren);
 432
 433             when N_Explicit_Dereference =>
 434                Prepend_String_To_Buffer ("XA");
 435                Ren := Prefix (Ren);
 436
 437             --  For now, anything else simply results in no translation
 438
 439             when others =>
 440                Set_Materialize_Entity (Ent);
 441                return Empty;
 442          end case;
 443       end loop;
 444
 445       Prepend_String_To_Buffer ("___XE");
 446
 447       --  For now, the literal name contains only the suffix. The Entity_Id
 448       --  value for the name is used to create a link from this literal name
 449       --  to the renamed entity using the Debug_Renaming_Link field. Then the
 450       --  Qualify_Entity_Name procedure uses this link to create the proper
 451       --  fully qualified name.
 452
 453       --  The reason we do things this way is that we really need to copy the
 454       --  qualification of the renamed entity, and it is really much easier to
 455       --  do this after the renamed entity has itself been fully qualified.
 456
 457       Lit := Make_Defining_Identifier (Loc, Chars => Name_Enter);
 458       Set_Debug_Renaming_Link (Lit, Entity (Ren));
 459
 460       --  Return the appropriate enumeration type
 461
 462       Def := Make_Defining_Identifier (Loc, Chars => Rnm);
 463       Res :=
 464         Make_Full_Type_Declaration (Loc,
 465           Defining_Identifier => Def,
 466           Type_Definition =>
 467             Make_Enumeration_Type_Definition (Loc,
 468               Literals => New_List (Lit)));
 469
 470       Set_Needs_Debug_Info (Def);
 471       Set_Needs_Debug_Info (Lit);
 472
 473       Set_Discard_Names (Defining_Identifier (Res));
 474       return Res;
 475
 476    --  If we get an exception, just figure it is a case that we cannot
 477    --  successfully handle using our current approach, since this is
 478    --  only for debugging, no need to take the compilation with us!
 479
 480    exception
 481       when others =>
 482          return Make_Null_Statement (Loc);
 483    end Debug_Renaming_Declaration;
 484
 485    ----------------------
 486    -- Get_Encoded_Name --
 487    ----------------------
 488
 489    --  Note: see spec for details on encodings
 490
 491    procedure Get_Encoded_Name (E : Entity_Id) is
 492       Has_Suffix : Boolean;
 493
 494    begin
 495       --  If not generating code, there is no need to create encoded
 496       --  names, and problems when the back-end is called to annotate
 497       --  types without full code generation. See comments at beginning
 498       --  of Get_External_Name_With_Suffix for additional details.
 499
 500       if Operating_Mode /= Generate_Code then
 501          return;
 502       end if;
 503
 504       Get_Name_String (Chars (E));
 505
 506       --  Nothing to do if we do not have a type
 507
 508       if not Is_Type (E)
 509
 510       --  Or if this is an enumeration base type
 511
 512         or else (Is_Enumeration_Type (E)
 513                    and then E = Base_Type (E))
 514
 515       --  Or if this is a dummy type for a renaming
 516
 517         or else (Name_Len >= 3 and then
 518                    Name_Buffer (Name_Len - 2 .. Name_Len) = "_XR")
 519
 520         or else (Name_Len >= 4 and then
 521                    (Name_Buffer (Name_Len - 3 .. Name_Len) = "_XRE"
 522                       or else
 523                     Name_Buffer (Name_Len - 3 .. Name_Len) = "_XRP"))
 524
 525       --  For all these cases, just return the name unchanged
 526
 527       then
 528          Name_Buffer (Name_Len + 1) := ASCII.Nul;
 529          return;
 530       end if;
 531
 532       Has_Suffix := True;
 533
 534       --  Fixed-point case
 535
 536       if Is_Fixed_Point_Type (E) then
 537          Get_External_Name_With_Suffix (E, "XF_");
 538          Add_Real_To_Buffer (Delta_Value (E));
 539
 540          if Small_Value (E) /= Delta_Value (E) then
 541             Add_Str_To_Name_Buffer ("_");
 542             Add_Real_To_Buffer (Small_Value (E));
 543          end if;
 544
 545       --  Vax floating-point case
 546
 547       elsif Vax_Float (E) then
 548
 549          if Digits_Value (Base_Type (E)) = 6 then
 550             Get_External_Name_With_Suffix (E, "XFF");
 551
 552          elsif Digits_Value (Base_Type (E)) = 9 then
 553             Get_External_Name_With_Suffix (E, "XFF");
 554
 555          else
 556             pragma Assert (Digits_Value (Base_Type (E)) = 15);
 557             Get_External_Name_With_Suffix (E, "XFG");
 558          end if;
 559
 560       --  Discrete case where bounds do not match size
 561
 562       elsif Is_Discrete_Type (E)
 563         and then not Bounds_Match_Size (E)
 564       then
 565          declare
 566             Lo : constant Node_Id := Type_Low_Bound (E);
 567             Hi : constant Node_Id := Type_High_Bound (E);
 568
 569             Lo_Con : constant Boolean := Compile_Time_Known_Value (Lo);
 570             Hi_Con : constant Boolean := Compile_Time_Known_Value (Hi);
 571
 572             Lo_Discr : constant Boolean :=
 573                          Nkind (Lo) = N_Identifier
 574                            and then
 575                          Ekind (Entity (Lo)) = E_Discriminant;
 576
 577             Hi_Discr : constant Boolean :=
 578                          Nkind (Hi) = N_Identifier
 579                            and then
 580                          Ekind (Entity (Hi)) = E_Discriminant;
 581
 582             Lo_Encode : constant Boolean := Lo_Con or Lo_Discr;
 583             Hi_Encode : constant Boolean := Hi_Con or Hi_Discr;
 584
 585             Biased : constant Boolean := Has_Biased_Representation (E);
 586
 587          begin
 588             if Biased then
 589                Get_External_Name_With_Suffix (E, "XB");
 590             else
 591                Get_External_Name_With_Suffix (E, "XD");
 592             end if;
 593
 594             if Lo_Encode or Hi_Encode then
 595                if Biased then
 596                   Add_Str_To_Name_Buffer ("_");
 597                else
 598                   if Lo_Encode then
 599                      if Hi_Encode then
 600                         Add_Str_To_Name_Buffer ("LU_");
 601                      else
 602                         Add_Str_To_Name_Buffer ("L_");
 603                      end if;
 604                   else
 605                      Add_Str_To_Name_Buffer ("U_");
 606                   end if;
 607                end if;
 608
 609                if Lo_Con then
 610                   Add_Uint_To_Buffer (Expr_Rep_Value (Lo));
 611                elsif Lo_Discr then
 612                   Get_Name_String_And_Append (Chars (Entity (Lo)));
 613                end if;
 614
 615                if Lo_Encode and Hi_Encode then
 616                   Add_Str_To_Name_Buffer ("__");
 617                end if;
 618
 619                if Hi_Con then
 620                   Add_Uint_To_Buffer (Expr_Rep_Value (Hi));
 621                elsif Hi_Discr then
 622                   Get_Name_String_And_Append (Chars (Entity (Hi)));
 623                end if;
 624             end if;
 625          end;
 626
 627       --  For all other cases, the encoded name is the normal type name
 628
 629       else
 630          Has_Suffix := False;
 631          Get_External_Name (E, Has_Suffix);
 632       end if;
 633
 634       if Debug_Flag_B and then Has_Suffix then
 635          Write_Str ("**** type ");
 636          Write_Name (Chars (E));
 637          Write_Str (" is encoded as ");
 638          Write_Str (Name_Buffer (1 .. Name_Len));
 639          Write_Eol;
 640       end if;
 641
 642       Name_Buffer (Name_Len + 1) := ASCII.NUL;
 643    end Get_Encoded_Name;
 644
 645    -----------------------
 646    -- Get_External_Name --
 647    -----------------------
 648
 649    procedure Get_External_Name (Entity : Entity_Id; Has_Suffix : Boolean) is
 650       E    : Entity_Id := Entity;
 651       Kind : Entity_Kind;
 652
 653       procedure Get_Qualified_Name_And_Append (Entity : Entity_Id);
 654       --  Appends fully qualified name of given entity to Name_Buffer
 655
 656       -----------------------------------
 657       -- Get_Qualified_Name_And_Append --
 658       -----------------------------------
 659
 660       procedure Get_Qualified_Name_And_Append (Entity : Entity_Id) is
 661       begin
 662          --  If the entity is a compilation unit, its scope is Standard,
 663          --  there is no outer scope, and the no further qualification
 664          --  is required.
 665
 666          --  If the front end has already computed a fully qualified name,
 667          --  then it is also the case that no further qualification is
 668          --  required
 669
 670          if Present (Scope (Scope (Entity)))
 671            and then not Has_Fully_Qualified_Name (Entity)
 672          then
 673             Get_Qualified_Name_And_Append (Scope (Entity));
 674             Add_Str_To_Name_Buffer ("__");
 675             Get_Name_String_And_Append (Chars (Entity));
 676             Append_Homonym_Number (Entity);
 677
 678          else
 679             Get_Name_String_And_Append (Chars (Entity));
 680          end if;
 681
 682       end Get_Qualified_Name_And_Append;
 683
 684    --  Start of processing for Get_External_Name
 685
 686    begin
 687       Name_Len := 0;
 688
 689       --  If this is a child unit, we want the child
 690
 691       if Nkind (E) = N_Defining_Program_Unit_Name then
 692          E := Defining_Identifier (Entity);
 693       end if;
 694
 695       Kind := Ekind (E);
 696
 697       --  Case of interface name being used
 698
 699       if (Kind = E_Procedure or else
 700           Kind = E_Function  or else
 701           Kind = E_Constant  or else
 702           Kind = E_Variable  or else
 703           Kind = E_Exception)
 704         and then Present (Interface_Name (E))
 705         and then No (Address_Clause (E))
 706         and then not Has_Suffix
 707       then
 708          Add_String_To_Name_Buffer (Strval (Interface_Name (E)));
 709
 710       --  All other cases besides the interface name case
 711
 712       else
 713          --  If this is a library level subprogram (i.e. a subprogram that is a
 714          --  compilation unit other than a subunit), then we prepend _ada_ to
 715          --  ensure distinctions required as described in the spec.
 716
 717          --  Check explicitly for child units, because those are not flagged
 718          --  as Compilation_Units by lib. Should they be ???
 719
 720          if Is_Subprogram (E)
 721            and then (Is_Compilation_Unit (E) or Is_Child_Unit (E))
 722            and then not Has_Suffix
 723          then
 724             Add_Str_To_Name_Buffer ("_ada_");
 725          end if;
 726
 727          --  If the entity is a subprogram instance that is not a compilation
 728          --  unit, generate the name of the original Ada entity, which is the
 729          --  one gdb needs.
 730
 731          if Is_Generic_Instance (E)
 732            and then Is_Subprogram (E)
 733            and then not Is_Compilation_Unit (Scope (E))
 734            and then (Ekind (Scope (E)) = E_Package
 735                       or else
 736                      Ekind (Scope (E)) = E_Package_Body)
 737            and then Present (Related_Instance (Scope (E)))
 738          then
 739             E := Related_Instance (Scope (E));
 740          end if;
 741
 742          Get_Qualified_Name_And_Append (E);
 743       end if;
 744
 745       Name_Buffer (Name_Len + 1) := ASCII.Nul;
 746    end Get_External_Name;
 747
 748    -----------------------------------
 749    -- Get_External_Name_With_Suffix --
 750    -----------------------------------
 751
 752    procedure Get_External_Name_With_Suffix
 753      (Entity : Entity_Id;
 754       Suffix : String)
 755    is
 756       Has_Suffix : constant Boolean := (Suffix /= "");
 757
 758    begin
 759       --  If we are not in code generation mode, this procedure may still be
 760       --  called from Back_End (more specifically - from gigi for doing type
 761       --  representation annotation or some representation-specific checks).
 762       --  But in this mode there is no need to mess with external names.
 763
 764       --  Furthermore, the call causes difficulties in this case because the
 765       --  string representing the homonym number is not correctly reset as a
 766       --  part of the call to Output_Homonym_Numbers_Suffix (which is not
 767       --  called in gigi).
 768
 769       if Operating_Mode /= Generate_Code then
 770          return;
 771       end if;
 772
 773       Get_External_Name (Entity, Has_Suffix);
 774
 775       if Has_Suffix then
 776          Add_Str_To_Name_Buffer ("___");
 777          Add_Str_To_Name_Buffer (Suffix);
 778          Name_Buffer (Name_Len + 1) := ASCII.Nul;
 779       end if;
 780    end Get_External_Name_With_Suffix;
 781
 782    --------------------------
 783    -- Get_Variant_Encoding --
 784    --------------------------
 785
 786    procedure Get_Variant_Encoding (V : Node_Id) is
 787       Choice : Node_Id;
 788
 789       procedure Choice_Val (Typ : Character; Choice : Node_Id);
 790       --  Output encoded value for a single choice value. Typ is the key
 791       --  character ('S', 'F', or 'T') that precedes the choice value.
 792
 793       ----------------
 794       -- Choice_Val --
 795       ----------------
 796
 797       procedure Choice_Val (Typ : Character; Choice : Node_Id) is
 798       begin
 799          if Nkind (Choice) = N_Integer_Literal then
 800             Add_Char_To_Name_Buffer (Typ);
 801             Add_Uint_To_Buffer (Intval (Choice));
 802
 803          --  Character literal with no entity present (this is the case
 804          --  Standard.Character or Standard.Wide_Character as root type)
 805
 806          elsif Nkind (Choice) = N_Character_Literal
 807            and then No (Entity (Choice))
 808          then
 809             Add_Char_To_Name_Buffer (Typ);
 810             Add_Uint_To_Buffer (Char_Literal_Value (Choice));
 811
 812          else
 813             declare
 814                Ent : constant Entity_Id := Entity (Choice);
 815
 816             begin
 817                if Ekind (Ent) = E_Enumeration_Literal then
 818                   Add_Char_To_Name_Buffer (Typ);
 819                   Add_Uint_To_Buffer (Enumeration_Rep (Ent));
 820
 821                else
 822                   pragma Assert (Ekind (Ent) = E_Constant);
 823                   Choice_Val (Typ, Constant_Value (Ent));
 824                end if;
 825             end;
 826          end if;
 827       end Choice_Val;
 828
 829    --  Start of processing for Get_Variant_Encoding
 830
 831    begin
 832       Name_Len := 0;
 833
 834       Choice := First (Discrete_Choices (V));
 835       while Present (Choice) loop
 836          if Nkind (Choice) = N_Others_Choice then
 837             Add_Char_To_Name_Buffer ('O');
 838
 839          elsif Nkind (Choice) = N_Range then
 840             Choice_Val ('R', Low_Bound (Choice));
 841             Choice_Val ('T', High_Bound (Choice));
 842
 843          elsif Is_Entity_Name (Choice)
 844            and then Is_Type (Entity (Choice))
 845          then
 846             Choice_Val ('R', Type_Low_Bound (Entity (Choice)));
 847             Choice_Val ('T', Type_High_Bound (Entity (Choice)));
 848
 849          elsif Nkind (Choice) = N_Subtype_Indication then
 850             declare
 851                Rang : constant Node_Id :=
 852                         Range_Expression (Constraint (Choice));
 853             begin
 854                Choice_Val ('R', Low_Bound (Rang));
 855                Choice_Val ('T', High_Bound (Rang));
 856             end;
 857
 858          else
 859             Choice_Val ('S', Choice);
 860          end if;
 861
 862          Next (Choice);
 863       end loop;
 864
 865       Name_Buffer (Name_Len + 1) := ASCII.NUL;
 866
 867       if Debug_Flag_B then
 868          declare
 869             VP : constant Node_Id := Parent (V);    -- Variant_Part
 870             CL : constant Node_Id := Parent (VP);   -- Component_List
 871             RD : constant Node_Id := Parent (CL);   -- Record_Definition
 872             FT : constant Node_Id := Parent (RD);   -- Full_Type_Declaration
 873
 874          begin
 875             Write_Str ("**** variant for type ");
 876             Write_Name (Chars (Defining_Identifier (FT)));
 877             Write_Str (" is encoded as ");
 878             Write_Str (Name_Buffer (1 .. Name_Len));
 879             Write_Eol;
 880          end;
 881       end if;
 882    end Get_Variant_Encoding;
 883
 884    ------------------------------------
 885    -- Get_Secondary_DT_External_Name --
 886    ------------------------------------
 887
 888    procedure Get_Secondary_DT_External_Name
 889      (Typ             : Entity_Id;
 890       Ancestor_Typ    : Entity_Id;
 891       Suffix_Index    : Int) is
 892    begin
 893       Get_External_Name (Typ, Has_Suffix => False);
 894
 895       if Ancestor_Typ /= Typ then
 896          declare
 897             Len      : constant Natural := Name_Len;
 898             Save_Str : constant String (1 .. Name_Len)
 899                          := Name_Buffer (1 .. Name_Len);
 900          begin
 901             Get_External_Name (Ancestor_Typ, Has_Suffix => False);
 902
 903             --  Append the extended name of the ancestor to the
 904             --  extended name of Typ
 905
 906             Name_Buffer (Len + 2 .. Len + Name_Len + 1) :=
 907               Name_Buffer (1 .. Name_Len);
 908             Name_Buffer (1 .. Len) := Save_Str;
 909             Name_Buffer (Len + 1) := '_';
 910             Name_Len := Len + Name_Len + 1;
 911          end;
 912       end if;
 913
 914       Add_Nat_To_Name_Buffer (Suffix_Index);
 915    end Get_Secondary_DT_External_Name;
 916
 917    ---------------------------------
 918    -- Make_Packed_Array_Type_Name --
 919    ---------------------------------
 920
 921    function Make_Packed_Array_Type_Name
 922      (Typ   : Entity_Id;
 923       Csize : Uint)
 924       return  Name_Id
 925    is
 926    begin
 927       Get_Name_String (Chars (Typ));
 928       Add_Str_To_Name_Buffer ("___XP");
 929       Add_Uint_To_Buffer (Csize);
 930       return Name_Find;
 931    end Make_Packed_Array_Type_Name;
 932
 933    -----------------------------------
 934    -- Output_Homonym_Numbers_Suffix --
 935    -----------------------------------
 936
 937    procedure Output_Homonym_Numbers_Suffix is
 938       J : Natural;
 939
 940    begin
 941       if Homonym_Len > 0 then
 942
 943          --  Check for all 1's, in which case we do not output
 944
 945          J := 1;
 946          loop
 947             exit when Homonym_Numbers (J) /= '1';
 948
 949             --  If we reached end of string we do not output
 950
 951             if J = Homonym_Len then
 952                Homonym_Len := 0;
 953                return;
 954             end if;
 955
 956             exit when Homonym_Numbers (J + 1) /= '_';
 957             J := J + 2;
 958          end loop;
 959
 960          --  If we exit the loop then suffix must be output
 961
 962          Add_Str_To_Name_Buffer ("__");
 963          Add_Str_To_Name_Buffer (Homonym_Numbers (1 .. Homonym_Len));
 964          Homonym_Len := 0;
 965       end if;
 966    end Output_Homonym_Numbers_Suffix;
 967
 968    ------------------------------
 969    -- Prepend_String_To_Buffer --
 970    ------------------------------
 971
 972    procedure Prepend_String_To_Buffer (S : String) is
 973       N : constant Integer := S'Length;
 974    begin
 975       Name_Buffer (1 + N .. Name_Len + N) := Name_Buffer (1 .. Name_Len);
 976       Name_Buffer (1 .. N) := S;
 977       Name_Len := Name_Len + N;
 978    end Prepend_String_To_Buffer;
 979
 980    ----------------------------
 981    -- Prepend_Uint_To_Buffer --
 982    ----------------------------
 983
 984    procedure Prepend_Uint_To_Buffer (U : Uint) is
 985    begin
 986       if U < 0 then
 987          Prepend_String_To_Buffer ("m");
 988          Prepend_Uint_To_Buffer (-U);
 989       else
 990          UI_Image (U, Decimal);
 991          Prepend_String_To_Buffer (UI_Image_Buffer (1 .. UI_Image_Length));
 992       end if;
 993    end Prepend_Uint_To_Buffer;
 994
 995    ------------------------------
 996    -- Qualify_All_Entity_Names --
 997    ------------------------------
 998
 999    procedure Qualify_All_Entity_Names is
1000       E   : Entity_Id;
1001       Ent : Entity_Id;
1002
1003    begin
1004       for J in Name_Qualify_Units.First .. Name_Qualify_Units.Last loop
1005          E := Defining_Entity (Name_Qualify_Units.Table (J));
1006          Qualify_Entity_Name (E);
1007
1008          Ent := First_Entity (E);
1009          while Present (Ent) loop
1010             Qualify_Entity_Name (Ent);
1011             Next_Entity (Ent);
1012
1013             --  There are odd cases where Last_Entity (E) = E. This happens
1014             --  in the case of renaming of packages. This test avoids getting
1015             --  stuck in such cases.
1016
1017             exit when Ent = E;
1018          end loop;
1019       end loop;
1020    end Qualify_All_Entity_Names;
1021
1022    -------------------------
1023    -- Qualify_Entity_Name --
1024    -------------------------
1025
1026    procedure Qualify_Entity_Name (Ent : Entity_Id) is
1027
1028       Full_Qualify_Name : String (1 .. Name_Buffer'Length);
1029       Full_Qualify_Len  : Natural := 0;
1030       --  Used to accumulate fully qualified name of subprogram
1031
1032       procedure Fully_Qualify_Name (E : Entity_Id);
1033       --  Used to qualify a subprogram or type name, where full
1034       --  qualification up to Standard is always used. Name is set
1035       --  in Full_Qualify_Name with the length in Full_Qualify_Len.
1036       --  Note that this routine does not prepend the _ada_ string
1037       --  required for library subprograms (this is done in the back end).
1038
1039       function Is_BNPE (S : Entity_Id) return Boolean;
1040       --  Determines if S is a BNPE, i.e. Body-Nested Package Entity, which
1041       --  is defined to be a package which is immediately nested within a
1042       --  package body.
1043
1044       function Qualify_Needed (S : Entity_Id) return Boolean;
1045       --  Given a scope, determines if the scope is to be included in the
1046       --  fully qualified name, True if so, False if not.
1047
1048       procedure Set_BNPE_Suffix (E : Entity_Id);
1049       --  Recursive routine to append the BNPE qualification suffix. Works
1050       --  from right to left with E being the current entity in the list.
1051       --  The result does NOT have the trailing n's and trailing b stripped.
1052       --  The caller must do this required stripping.
1053
1054       procedure Set_Entity_Name (E : Entity_Id);
1055       --  Internal recursive routine that does most of the work. This routine
1056       --  leaves the result sitting in Name_Buffer and Name_Len.
1057
1058       BNPE_Suffix_Needed : Boolean := False;
1059       --  Set true if a body-nested package entity suffix is required
1060
1061       Save_Chars : constant Name_Id := Chars (Ent);
1062       --  Save original name
1063
1064       ------------------------
1065       -- Fully_Qualify_Name --
1066       ------------------------
1067
1068       procedure Fully_Qualify_Name (E : Entity_Id) is
1069          Discard : Boolean := False;
1070
1071       begin
1072          --  Ignore empty entry (can happen in error cases)
1073
1074          if No (E) then
1075             return;
1076
1077          --  If this we are qualifying entities local to a generic
1078          --  instance, use the name of the original instantiation,
1079          --  not that of the anonymous subprogram in the wrapper
1080          --  package, so that gdb doesn't have to know about these.
1081
1082          elsif Is_Generic_Instance (E)
1083            and then Is_Subprogram (E)
1084            and then not Comes_From_Source (E)
1085            and then not Is_Compilation_Unit (Scope (E))
1086          then
1087             Fully_Qualify_Name (Related_Instance (Scope (E)));
1088             return;
1089          end if;
1090
1091          --  If we reached fully qualified name, then just copy it
1092
1093          if Has_Fully_Qualified_Name (E) then
1094             Get_Name_String (Chars (E));
1095             Strip_Suffixes (Discard);
1096             Full_Qualify_Name (1 .. Name_Len) := Name_Buffer (1 .. Name_Len);
1097             Full_Qualify_Len := Name_Len;
1098             Set_Has_Fully_Qualified_Name (Ent);
1099
1100          --  Case of non-fully qualified name
1101
1102          else
1103             if Scope (E) = Standard_Standard then
1104                Set_Has_Fully_Qualified_Name (Ent);
1105             else
1106                Fully_Qualify_Name (Scope (E));
1107                Full_Qualify_Name (Full_Qualify_Len + 1) := '_';
1108                Full_Qualify_Name (Full_Qualify_Len + 2) := '_';
1109                Full_Qualify_Len := Full_Qualify_Len + 2;
1110             end if;
1111
1112             if Has_Qualified_Name (E) then
1113                Get_Unqualified_Name_String (Chars (E));
1114             else
1115                Get_Name_String (Chars (E));
1116             end if;
1117
1118             --  A special check here, we never add internal block or loop
1119             --  names, since they intefere with debugging. We identify these
1120             --  by the fact that they start with an upper case B or L.
1121             --  But do add these if what we are qualifying is a __clean
1122             --  procedure since those need to be made unique.
1123
1124             if (Name_Buffer (1) = 'B' or else Name_Buffer (1) = 'L')
1125                 and then (not Debug_Flag_VV)
1126                 and then Full_Qualify_Len > 2
1127                 and then Chars (Ent) /= Name_uClean
1128             then
1129                Full_Qualify_Len := Full_Qualify_Len - 2;
1130
1131             else
1132                Full_Qualify_Name
1133                  (Full_Qualify_Len + 1 .. Full_Qualify_Len + Name_Len) :=
1134                    Name_Buffer (1 .. Name_Len);
1135                Full_Qualify_Len := Full_Qualify_Len + Name_Len;
1136                Append_Homonym_Number (E);
1137             end if;
1138          end if;
1139
1140          if Is_BNPE (E) then
1141             BNPE_Suffix_Needed := True;
1142          end if;
1143       end Fully_Qualify_Name;
1144
1145       -------------
1146       -- Is_BNPE --
1147       -------------
1148
1149       function Is_BNPE (S : Entity_Id) return Boolean is
1150       begin
1151          return
1152            Ekind (S) = E_Package
1153              and then Is_Package_Body_Entity (S);
1154       end Is_BNPE;
1155
1156       --------------------
1157       -- Qualify_Needed --
1158       --------------------
1159
1160       function Qualify_Needed (S : Entity_Id) return Boolean is
1161       begin
1162          --  If we got all the way to Standard, then we have certainly
1163          --  fully qualified the name, so set the flag appropriately,
1164          --  and then return False, since we are most certainly done!
1165
1166          if S = Standard_Standard then
1167             Set_Has_Fully_Qualified_Name (Ent, True);
1168             return False;
1169
1170          --  Otherwise figure out if further qualification is required
1171
1172          else
1173             return
1174               Is_Subprogram (Ent)
1175                 or else
1176               Ekind (Ent) = E_Subprogram_Body
1177                 or else
1178                   (Ekind (S) /= E_Block
1179                     and then not Is_Dynamic_Scope (S));
1180          end if;
1181       end Qualify_Needed;
1182
1183       ---------------------
1184       -- Set_BNPE_Suffix --
1185       ---------------------
1186
1187       procedure Set_BNPE_Suffix (E : Entity_Id) is
1188          S : constant Entity_Id := Scope (E);
1189
1190       begin
1191          if Qualify_Needed (S) then
1192             Set_BNPE_Suffix (S);
1193
1194             if Is_BNPE (E) then
1195                Add_Char_To_Name_Buffer ('b');
1196             else
1197                Add_Char_To_Name_Buffer ('n');
1198             end if;
1199
1200          else
1201             Add_Char_To_Name_Buffer ('X');
1202          end if;
1203       end Set_BNPE_Suffix;
1204
1205       ---------------------
1206       -- Set_Entity_Name --
1207       ---------------------
1208
1209       procedure Set_Entity_Name (E : Entity_Id) is
1210          S : constant Entity_Id := Scope (E);
1211
1212       begin
1213          --  If we reach an already qualified name, just take the encoding
1214          --  except that we strip the package body suffixes, since these
1215          --  will be separately put on later.
1216
1217          if Has_Qualified_Name (E) then
1218             Get_Name_String_And_Append (Chars (E));
1219             Strip_Suffixes (BNPE_Suffix_Needed);
1220
1221             --  If the top level name we are adding is itself fully
1222             --  qualified, then that means that the name that we are
1223             --  preparing for the Fully_Qualify_Name call will also
1224             --  generate a fully qualified name.
1225
1226             if Has_Fully_Qualified_Name (E) then
1227                Set_Has_Fully_Qualified_Name (Ent);
1228             end if;
1229
1230          --  Case where upper level name is not encoded yet
1231
1232          else
1233             --  Recurse if further qualification required
1234
1235             if Qualify_Needed (S) then
1236                Set_Entity_Name (S);
1237                Add_Str_To_Name_Buffer ("__");
1238             end if;
1239
1240             --  Otherwise get name and note if it is a NPBE
1241
1242             Get_Name_String_And_Append (Chars (E));
1243
1244             if Is_BNPE (E) then
1245                BNPE_Suffix_Needed := True;
1246             end if;
1247
1248             Append_Homonym_Number (E);
1249          end if;
1250       end Set_Entity_Name;
1251
1252    --  Start of processing for Qualify_Entity_Name
1253
1254    begin
1255       if Has_Qualified_Name (Ent) then
1256          return;
1257
1258       --  Here is where we create the proper link for renaming
1259
1260       elsif Ekind (Ent) = E_Enumeration_Literal
1261         and then Present (Debug_Renaming_Link (Ent))
1262       then
1263          Name_Len := 0;
1264          Qualify_Entity_Name (Debug_Renaming_Link (Ent));
1265          Get_Name_String (Chars (Ent));
1266          Prepend_String_To_Buffer
1267            (Get_Name_String (Chars (Debug_Renaming_Link (Ent))));
1268          Set_Chars (Ent, Name_Enter);
1269          Set_Has_Qualified_Name (Ent);
1270          return;
1271
1272       elsif Is_Subprogram (Ent)
1273         or else Ekind (Ent) = E_Subprogram_Body
1274         or else Is_Type (Ent)
1275       then
1276          Fully_Qualify_Name (Ent);
1277          Name_Len := Full_Qualify_Len;
1278          Name_Buffer (1 .. Name_Len) := Full_Qualify_Name (1 .. Name_Len);
1279
1280       elsif Qualify_Needed (Scope (Ent)) then
1281          Name_Len := 0;
1282          Set_Entity_Name (Ent);
1283
1284       else
1285          Set_Has_Qualified_Name (Ent);
1286          return;
1287       end if;
1288
1289       --  Fall through with a fully qualified name in Name_Buffer/Name_Len
1290
1291       Output_Homonym_Numbers_Suffix;
1292
1293       --  Add body-nested package suffix if required
1294
1295       if BNPE_Suffix_Needed
1296         and then Ekind (Ent) /= E_Enumeration_Literal
1297       then
1298          Set_BNPE_Suffix (Ent);
1299
1300          --  Strip trailing n's and last trailing b as required. note that
1301          --  we know there is at least one b, or no suffix would be generated.
1302
1303          while Name_Buffer (Name_Len) = 'n' loop
1304             Name_Len := Name_Len - 1;
1305          end loop;
1306
1307          Name_Len := Name_Len - 1;
1308       end if;
1309
1310       Set_Chars (Ent, Name_Enter);
1311       Set_Has_Qualified_Name (Ent);
1312
1313       if Debug_Flag_BB then
1314          Write_Str ("*** ");
1315          Write_Name (Save_Chars);
1316          Write_Str (" qualified as ");
1317          Write_Name (Chars (Ent));
1318          Write_Eol;
1319       end if;
1320    end Qualify_Entity_Name;
1321
1322    --------------------------
1323    -- Qualify_Entity_Names --
1324    --------------------------
1325
1326    procedure Qualify_Entity_Names (N : Node_Id) is
1327    begin
1328       Name_Qualify_Units.Append (N);
1329    end Qualify_Entity_Names;
1330
1331    --------------------
1332    -- Strip_Suffixes --
1333    --------------------
1334
1335    procedure Strip_Suffixes (BNPE_Suffix_Found : in out Boolean) is
1336       SL : Natural;
1337
1338    begin
1339       --  Search for and strip BNPE suffix
1340
1341       for J in reverse 2 .. Name_Len loop
1342          if Name_Buffer (J) = 'X' then
1343             Name_Len := J - 1;
1344             BNPE_Suffix_Found := True;
1345             exit;
1346          end if;
1347
1348          exit when Name_Buffer (J) /= 'b' and then Name_Buffer (J) /= 'n';
1349       end loop;
1350
1351       --  Search for and strip homonym numbers suffix
1352
1353       for J in reverse 2 .. Name_Len - 2 loop
1354          if Name_Buffer (J) = '_'
1355            and then Name_Buffer (J + 1) = '_'
1356          then
1357             if Name_Buffer (J + 2) in '0' .. '9' then
1358                if Homonym_Len > 0 then
1359                   Homonym_Len := Homonym_Len + 1;
1360                   Homonym_Numbers (Homonym_Len) := '-';
1361                end if;
1362
1363                SL := Name_Len - (J + 1);
1364
1365                Homonym_Numbers (Homonym_Len + 1 .. Homonym_Len + SL) :=
1366                  Name_Buffer (J + 2 .. Name_Len);
1367                Name_Len := J - 1;
1368                Homonym_Len := Homonym_Len + SL;
1369             end if;
1370
1371             exit;
1372          end if;
1373       end loop;
1374    end Strip_Suffixes;
1375
1376 end Exp_Dbug;