gcc/ada/exp_ch7.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 7                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package contains virtually all expansion mechanisms related to
  28 --    - controlled types
  29 --    - transient scopes
  30
  31 with Atree;    use Atree;
  32 with Debug;    use Debug;
  33 with Einfo;    use Einfo;
  34 with Errout;   use Errout;
  35 with Exp_Ch9;  use Exp_Ch9;
  36 with Exp_Ch11; use Exp_Ch11;
  37 with Exp_Dbug; use Exp_Dbug;
  38 with Exp_Tss;  use Exp_Tss;
  39 with Exp_Util; use Exp_Util;
  40 with Fname;    use Fname;
  41 with Freeze;   use Freeze;
  42 with Hostparm; use Hostparm;
  43 with Lib;      use Lib;
  44 with Nlists;   use Nlists;
  45 with Nmake;    use Nmake;
  46 with Opt;      use Opt;
  47 with Output;   use Output;
  48 with Restrict; use Restrict;
  49 with Rtsfind;  use Rtsfind;
  50 with Targparm; use Targparm;
  51 with Sinfo;    use Sinfo;
  52 with Sem;      use Sem;
  53 with Sem_Ch3;  use Sem_Ch3;
  54 with Sem_Ch7;  use Sem_Ch7;
  55 with Sem_Ch8;  use Sem_Ch8;
  56 with Sem_Res;  use Sem_Res;
  57 with Sem_Type; use Sem_Type;
  58 with Sem_Util; use Sem_Util;
  59 with Snames;   use Snames;
  60 with Stand;    use Stand;
  61 with Tbuild;   use Tbuild;
  62 with Uintp;    use Uintp;
  63
  64 package body Exp_Ch7 is
  65
  66    --------------------------------
  67    -- Transient Scope Management --
  68    --------------------------------
  69
  70    --  A transient scope is created when temporary objects are created by the
  71    --  compiler. These temporary objects are allocated on the secondary stack
  72    --  and the transient scope is responsible for finalizing the object when
  73    --  appropriate and reclaiming the memory at the right time. The temporary
  74    --  objects are generally the objects allocated to store the result of a
  75    --  function returning an unconstrained or a tagged value. Expressions
  76    --  needing to be wrapped in a transient scope (functions calls returning
  77    --  unconstrained or tagged values) may appear in 3 different contexts which
  78    --  lead to 3 different kinds of transient scope expansion:
  79
  80    --   1. In a simple statement (procedure call, assignment, ...). In
  81    --      this case the instruction is wrapped into a transient block.
  82    --      (See Wrap_Transient_Statement for details)
  83
  84    --   2. In an expression of a control structure (test in a IF statement,
  85    --      expression in a CASE statement, ...).
  86    --      (See Wrap_Transient_Expression for details)
  87
  88    --   3. In a expression of an object_declaration. No wrapping is possible
  89    --      here, so the finalization actions, if any are done right after the
  90    --      declaration and the secondary stack deallocation is done in the
  91    --      proper enclosing scope (see Wrap_Transient_Declaration for details)
  92
  93    --  Note about function returning tagged types: It has been decided to
  94    --  always allocate their result in the secondary stack while it is not
  95    --  absolutely mandatory when the tagged type is constrained because the
  96    --  caller knows the size of the returned object and thus could allocate the
  97    --  result in the primary stack. But, allocating them always in the
  98    --  secondary stack simplifies many implementation hassles:
  99
 100    --    - If it is dispatching function call, the computation of the size of
 101    --      the result is possible but complex from the outside.
 102
 103    --    - If the returned type is controlled, the assignment of the returned
 104    --      value to the anonymous object involves an Adjust, and we have no
 105    --      easy way to access the anonymous object created by the back-end
 106
 107    --    - If the returned type is class-wide, this is an unconstrained type
 108    --      anyway
 109
 110    --  Furthermore, the little loss in efficiency which is the result of this
 111    --  decision is not such a big deal because function returning tagged types
 112    --  are not very much used in real life as opposed to functions returning
 113    --  access to a tagged type
 114
 115    --------------------------------------------------
 116    -- Transient Blocks and Finalization Management --
 117    --------------------------------------------------
 118
 119    function Find_Node_To_Be_Wrapped (N : Node_Id) return Node_Id;
 120    --  N is a node wich may generate a transient scope. Loop over the
 121    --  parent pointers of N until it find the appropriate node to
 122    --  wrap. It it returns Empty, it means that no transient scope is
 123    --  needed in this context.
 124
 125    function Make_Clean
 126      (N                          : Node_Id;
 127       Clean                      : Entity_Id;
 128       Mark                       : Entity_Id;
 129       Flist                      : Entity_Id;
 130       Is_Task                    : Boolean;
 131       Is_Master                  : Boolean;
 132       Is_Protected_Subprogram    : Boolean;
 133       Is_Task_Allocation_Block   : Boolean;
 134       Is_Asynchronous_Call_Block : Boolean)
 135       return      Node_Id;
 136    --  Expand a the clean-up procedure for controlled and/or transient
 137    --  block, and/or task master or task body, or blocks used to
 138    --  implement task allocation or asynchronous entry calls, or
 139    --  procedures used to implement protected procedures. Clean is the
 140    --  entity for such a procedure. Mark is the entity for the secondary
 141    --  stack mark, if empty only controlled block clean-up will be
 142    --  performed. Flist is the entity for the local final list, if empty
 143    --  only transient scope clean-up will be performed. The flags
 144    --  Is_Task and Is_Master control the calls to the corresponding
 145    --  finalization actions for a task body or for an entity that is a
 146    --  task master.
 147
 148    procedure Set_Node_To_Be_Wrapped (N : Node_Id);
 149    --  Set the field Node_To_Be_Wrapped of the current scope
 150
 151    procedure Insert_Actions_In_Scope_Around (N : Node_Id);
 152    --  Insert the before-actions kept in the scope stack before N, and the
 153    --  after after-actions, after N which must be a member of a list.
 154
 155    function Make_Transient_Block
 156      (Loc    : Source_Ptr;
 157       Action : Node_Id)
 158       return   Node_Id;
 159    --  Create a transient block whose name is Scope, which is also a
 160    --  controlled block if Flist is not empty and whose only code is
 161    --  Action (either a single statement or single declaration).
 162
 163    type Final_Primitives is (Initialize_Case, Adjust_Case, Finalize_Case);
 164    --  This enumeration type is defined in order to ease sharing code for
 165    --  building finalization procedures for composite types.
 166
 167    Name_Of      : constant array (Final_Primitives) of Name_Id :=
 168                     (Initialize_Case => Name_Initialize,
 169                      Adjust_Case     => Name_Adjust,
 170                      Finalize_Case   => Name_Finalize);
 171
 172    Deep_Name_Of : constant array (Final_Primitives) of TSS_Name_Type :=
 173                     (Initialize_Case => TSS_Deep_Initialize,
 174                      Adjust_Case     => TSS_Deep_Adjust,
 175                      Finalize_Case   => TSS_Deep_Finalize);
 176
 177    procedure Build_Record_Deep_Procs (Typ : Entity_Id);
 178    --  Build the deep Initialize/Adjust/Finalize for a record Typ with
 179    --  Has_Component_Component set and store them using the TSS mechanism.
 180
 181    procedure Build_Array_Deep_Procs (Typ : Entity_Id);
 182    --  Build the deep Initialize/Adjust/Finalize for a record Typ with
 183    --  Has_Controlled_Component set and store them using the TSS mechanism.
 184
 185    function Make_Deep_Proc
 186      (Prim  : Final_Primitives;
 187       Typ   : Entity_Id;
 188       Stmts : List_Id)
 189       return  Node_Id;
 190    --  This function generates the tree for Deep_Initialize, Deep_Adjust
 191    --  or Deep_Finalize procedures according to the first parameter,
 192    --  these procedures operate on the type Typ. The Stmts parameter
 193    --  gives the body of the procedure.
 194
 195    function Make_Deep_Array_Body
 196      (Prim : Final_Primitives;
 197       Typ  : Entity_Id)
 198       return List_Id;
 199    --  This function generates the list of statements for implementing
 200    --  Deep_Initialize, Deep_Adjust or Deep_Finalize procedures
 201    --  according to the first parameter, these procedures operate on the
 202    --  array type Typ.
 203
 204    function Make_Deep_Record_Body
 205      (Prim : Final_Primitives;
 206       Typ  : Entity_Id)
 207       return List_Id;
 208    --  This function generates the list of statements for implementing
 209    --  Deep_Initialize, Deep_Adjust or Deep_Finalize procedures
 210    --  according to the first parameter, these procedures operate on the
 211    --  record type Typ.
 212
 213    procedure Check_Visibly_Controlled
 214      (Prim : Final_Primitives;
 215       Typ  : Entity_Id;
 216       E    : in out Entity_Id;
 217       Cref : in out Node_Id);
 218    --  The controlled operation declared for a derived type may not be
 219    --  overriding, if the controlled operations of the parent type are
 220    --  hidden, for example when the parent is a private type whose full
 221    --  view is controlled. For other primitive operations we modify the
 222    --  name of the operation to indicate that it is not overriding, but
 223    --  this is not possible for Initialize, etc. because they have to be
 224    --  retrievable by name. Before generating the proper call to one of
 225    --  these operations we check whether Typ is known to be controlled at
 226    --  the point of definition. If it is not then we must retrieve the
 227    --  hidden operation of the parent and use it instead.  This is one
 228    --  case that might be solved more cleanly once Overriding pragmas or
 229    --  declarations are in place.
 230
 231    function Convert_View
 232      (Proc : Entity_Id;
 233       Arg  : Node_Id;
 234       Ind  : Pos := 1)
 235       return Node_Id;
 236    --  Proc is one of the Initialize/Adjust/Finalize operations, and
 237    --  Arg is the argument being passed to it. Ind indicates which
 238    --  formal of procedure Proc we are trying to match. This function
 239    --  will, if necessary, generate an conversion between the partial
 240    --  and full view of Arg to match the type of the formal of Proc,
 241    --  or force a conversion to the class-wide type in the case where
 242    --  the operation is abstract.
 243
 244    -----------------------------
 245    -- Finalization Management --
 246    -----------------------------
 247
 248    --  This part describe how Initialization/Adjusment/Finalization procedures
 249    --  are generated and called. Two cases must be considered, types that are
 250    --  Controlled (Is_Controlled flag set) and composite types that contain
 251    --  controlled components (Has_Controlled_Component flag set). In the first
 252    --  case the procedures to call are the user-defined primitive operations
 253    --  Initialize/Adjust/Finalize. In the second case, GNAT generates
 254    --  Deep_Initialize, Deep_Adjust and Deep_Finalize that are in charge of
 255    --  calling the former procedures on the controlled components.
 256
 257    --  For records with Has_Controlled_Component set, a hidden "controller"
 258    --  component is inserted. This controller component contains its own
 259    --  finalization list on which all controlled components are attached
 260    --  creating an indirection on the upper-level Finalization list. This
 261    --  technique facilitates the management of objects whose number of
 262    --  controlled components changes during execution. This controller
 263    --  component is itself controlled and is attached to the upper-level
 264    --  finalization chain. Its adjust primitive is in charge of calling
 265    --  adjust on the components and adusting the finalization pointer to
 266    --  match their new location (see a-finali.adb).
 267
 268    --  It is not possible to use a similar technique for arrays that have
 269    --  Has_Controlled_Component set. In this case, deep procedures are
 270    --  generated that call initialize/adjust/finalize + attachment or
 271    --  detachment on the finalization list for all component.
 272
 273    --  Initialize calls: they are generated for declarations or dynamic
 274    --  allocations of Controlled objects with no initial value. They are
 275    --  always followed by an attachment to the current Finalization
 276    --  Chain. For the dynamic allocation case this the chain attached to
 277    --  the scope of the access type definition otherwise, this is the chain
 278    --  of the current scope.
 279
 280    --  Adjust Calls: They are generated on 2 occasions: (1) for
 281    --  declarations or dynamic allocations of Controlled objects with an
 282    --  initial value. (2) after an assignment. In the first case they are
 283    --  followed by an attachment to the final chain, in the second case
 284    --  they are not.
 285
 286    --  Finalization Calls: They are generated on (1) scope exit, (2)
 287    --  assignments, (3) unchecked deallocations. In case (3) they have to
 288    --  be detached from the final chain, in case (2) they must not and in
 289    --  case (1) this is not important since we are exiting the scope
 290    --  anyway.
 291
 292    --  Other details:
 293    --    - Type extensions will have a new record controller at each derivation
 294    --      level containing controlled components.
 295    --    - For types that are both Is_Controlled and Has_Controlled_Components,
 296    --      the record controller and the object itself are handled separately.
 297    --      It could seem simpler to attach the object at the end of its record
 298    --      controller but this would not tackle view conversions properly.
 299    --    - A classwide type can always potentially have controlled components
 300    --      but the record controller of the corresponding actual type may not
 301    --      be nown at compile time so the dispatch table contains a special
 302    --      field that allows to compute the offset of the record controller
 303    --      dynamically. See s-finimp.Deep_Tag_Attach and a-tags.RC_Offset
 304
 305    --  Here is a simple example of the expansion of a controlled block :
 306
 307    --    declare
 308    --       X : Controlled ;
 309    --       Y : Controlled := Init;
 310    --
 311    --       type R is record
 312    --          C : Controlled;
 313    --       end record;
 314    --       W : R;
 315    --       Z : R := (C => X);
 316    --    begin
 317    --       X := Y;
 318    --       W := Z;
 319    --    end;
 320    --
 321    --  is expanded into
 322    --
 323    --    declare
 324    --       _L : System.FI.Finalizable_Ptr;
 325
 326    --       procedure _Clean is
 327    --       begin
 328    --          Abort_Defer;
 329    --          System.FI.Finalize_List (_L);
 330    --          Abort_Undefer;
 331    --       end _Clean;
 332
 333    --       X : Controlled;
 334    --       begin
 335    --          Abort_Defer;
 336    --          Initialize (X);
 337    --          Attach_To_Final_List (_L, Finalizable (X), 1);
 338    --       at end: Abort_Undefer;
 339    --       Y : Controlled := Init;
 340    --       Adjust (Y);
 341    --       Attach_To_Final_List (_L, Finalizable (Y), 1);
 342    --
 343    --       type R is record
 344    --         _C : Record_Controller;
 345    --          C : Controlled;
 346    --       end record;
 347    --       W : R;
 348    --       begin
 349    --          Abort_Defer;
 350    --          Deep_Initialize (W, _L, 1);
 351    --       at end: Abort_Under;
 352    --       Z : R := (C => X);
 353    --       Deep_Adjust (Z, _L, 1);
 354
 355    --    begin
 356    --       _Assign (X, Y);
 357    --       Deep_Finalize (W, False);
 358    --       <save W's final pointers>
 359    --       W := Z;
 360    --       <restore W's final pointers>
 361    --       Deep_Adjust (W, _L, 0);
 362    --    at end
 363    --       _Clean;
 364    --    end;
 365
 366    function Global_Flist_Ref (Flist_Ref : Node_Id) return Boolean;
 367    --  Return True if Flist_Ref refers to a global final list, either
 368    --  the object GLobal_Final_List which is used to attach standalone
 369    --  objects, or any of the list controllers associated with library
 370    --  level access to controlled objects
 371
 372    procedure Clean_Simple_Protected_Objects (N : Node_Id);
 373    --  Protected objects without entries are not controlled types, and the
 374    --  locks have to be released explicitly when such an object goes out
 375    --  of scope. Traverse declarations in scope to determine whether such
 376    --  objects are present.
 377
 378    ----------------------------
 379    -- Build_Array_Deep_Procs --
 380    ----------------------------
 381
 382    procedure Build_Array_Deep_Procs (Typ : Entity_Id) is
 383    begin
 384       Set_TSS (Typ,
 385         Make_Deep_Proc (
 386           Prim  => Initialize_Case,
 387           Typ   => Typ,
 388           Stmts => Make_Deep_Array_Body (Initialize_Case, Typ)));
 389
 390       if not Is_Return_By_Reference_Type (Typ) then
 391          Set_TSS (Typ,
 392            Make_Deep_Proc (
 393              Prim  => Adjust_Case,
 394              Typ   => Typ,
 395              Stmts => Make_Deep_Array_Body (Adjust_Case, Typ)));
 396       end if;
 397
 398       Set_TSS (Typ,
 399         Make_Deep_Proc (
 400           Prim  => Finalize_Case,
 401           Typ   => Typ,
 402           Stmts => Make_Deep_Array_Body (Finalize_Case, Typ)));
 403    end Build_Array_Deep_Procs;
 404
 405    -----------------------------
 406    -- Build_Controlling_Procs --
 407    -----------------------------
 408
 409    procedure Build_Controlling_Procs (Typ : Entity_Id) is
 410    begin
 411       if Is_Array_Type (Typ) then
 412          Build_Array_Deep_Procs (Typ);
 413
 414       else pragma Assert (Is_Record_Type (Typ));
 415          Build_Record_Deep_Procs (Typ);
 416       end if;
 417    end Build_Controlling_Procs;
 418
 419    ----------------------
 420    -- Build_Final_List --
 421    ----------------------
 422
 423    procedure Build_Final_List (N : Node_Id; Typ : Entity_Id) is
 424       Loc  : constant Source_Ptr := Sloc (N);
 425       Decl : Node_Id;
 426
 427    begin
 428       Set_Associated_Final_Chain (Typ,
 429         Make_Defining_Identifier (Loc,
 430           New_External_Name (Chars (Typ), 'L')));
 431
 432       Decl :=
 433         Make_Object_Declaration (Loc,
 434           Defining_Identifier =>
 435              Associated_Final_Chain (Typ),
 436           Object_Definition   =>
 437             New_Reference_To
 438               (RTE (RE_List_Controller), Loc));
 439
 440       --  The type may have been frozen already, and this is a late freezing
 441       --  action, in which case the declaration must be elaborated at once.
 442       --  If the call is for an allocator, the chain must also be created now,
 443       --  because the freezing of the type does not build one. Otherwise, the
 444       --  declaration is one of the freezing actions for a user-defined type.
 445
 446       if Is_Frozen (Typ)
 447         or else (Nkind (N) = N_Allocator
 448                   and then Ekind (Etype (N)) = E_Anonymous_Access_Type)
 449       then
 450          Insert_Action (N, Decl);
 451       else
 452          Append_Freeze_Action (Typ, Decl);
 453       end if;
 454    end Build_Final_List;
 455
 456    ---------------------
 457    -- Build_Late_Proc --
 458    ---------------------
 459
 460    procedure Build_Late_Proc (Typ : Entity_Id; Nam : Name_Id) is
 461    begin
 462       for Final_Prim in Name_Of'Range loop
 463          if Name_Of (Final_Prim) = Nam then
 464             Set_TSS (Typ,
 465               Make_Deep_Proc (
 466                 Prim  => Final_Prim,
 467                 Typ   => Typ,
 468                 Stmts => Make_Deep_Record_Body (Final_Prim, Typ)));
 469          end if;
 470       end loop;
 471    end Build_Late_Proc;
 472
 473    -----------------------------
 474    -- Build_Record_Deep_Procs --
 475    -----------------------------
 476
 477    procedure Build_Record_Deep_Procs (Typ : Entity_Id) is
 478    begin
 479       Set_TSS (Typ,
 480         Make_Deep_Proc (
 481           Prim  => Initialize_Case,
 482           Typ   => Typ,
 483           Stmts => Make_Deep_Record_Body (Initialize_Case, Typ)));
 484
 485       if not Is_Return_By_Reference_Type (Typ) then
 486          Set_TSS (Typ,
 487            Make_Deep_Proc (
 488              Prim  => Adjust_Case,
 489              Typ   => Typ,
 490              Stmts => Make_Deep_Record_Body (Adjust_Case, Typ)));
 491       end if;
 492
 493       Set_TSS (Typ,
 494         Make_Deep_Proc (
 495           Prim  => Finalize_Case,
 496           Typ   => Typ,
 497           Stmts => Make_Deep_Record_Body (Finalize_Case, Typ)));
 498    end Build_Record_Deep_Procs;
 499
 500    -------------------
 501    -- Cleanup_Array --
 502    -------------------
 503
 504    function Cleanup_Array
 505      (N    : Node_Id;
 506       Obj  : Node_Id;
 507       Typ  : Entity_Id)
 508       return List_Id
 509    is
 510       Loc        : constant Source_Ptr := Sloc (N);
 511       Index_List : List_Id := New_List;
 512
 513       function Free_Component return List_Id;
 514       --  Generate the code to finalize the task or protected  subcomponents
 515       --  of a single component of the array.
 516
 517       function Free_One_Dimension (Dim : Int) return List_Id;
 518       --  Generate a loop over one dimension of the array.
 519
 520       --------------------
 521       -- Free_Component --
 522       --------------------
 523
 524       function Free_Component return List_Id is
 525          Stmts : List_Id := New_List;
 526          Tsk   : Node_Id;
 527          C_Typ : Entity_Id := Component_Type (Typ);
 528
 529       begin
 530          --  Component type is known to contain tasks or protected objects
 531
 532          Tsk :=
 533            Make_Indexed_Component (Loc,
 534              Prefix        => Duplicate_Subexpr_No_Checks (Obj),
 535              Expressions   => Index_List);
 536
 537          Set_Etype (Tsk, C_Typ);
 538
 539          if Is_Task_Type (C_Typ) then
 540             Append_To (Stmts, Cleanup_Task (N, Tsk));
 541
 542          elsif Is_Simple_Protected_Type (C_Typ) then
 543             Append_To (Stmts, Cleanup_Protected_Object (N, Tsk));
 544
 545          elsif Is_Record_Type (C_Typ) then
 546             Stmts := Cleanup_Record (N, Tsk, C_Typ);
 547
 548          elsif Is_Array_Type (C_Typ) then
 549             Stmts := Cleanup_Array (N, Tsk, C_Typ);
 550          end if;
 551
 552          return Stmts;
 553       end Free_Component;
 554
 555       ------------------------
 556       -- Free_One_Dimension --
 557       ------------------------
 558
 559       function Free_One_Dimension (Dim : Int) return List_Id is
 560          Index      : Entity_Id;
 561
 562       begin
 563          if Dim > Number_Dimensions (Typ) then
 564             return Free_Component;
 565
 566          --  Here we generate the required loop
 567
 568          else
 569             Index :=
 570               Make_Defining_Identifier (Loc, New_Internal_Name ('J'));
 571
 572             Append (New_Reference_To (Index, Loc), Index_List);
 573
 574             return New_List (
 575               Make_Implicit_Loop_Statement (N,
 576                 Identifier => Empty,
 577                 Iteration_Scheme =>
 578                   Make_Iteration_Scheme (Loc,
 579                     Loop_Parameter_Specification =>
 580                       Make_Loop_Parameter_Specification (Loc,
 581                         Defining_Identifier => Index,
 582                         Discrete_Subtype_Definition =>
 583                           Make_Attribute_Reference (Loc,
 584                             Prefix => Duplicate_Subexpr (Obj),
 585                             Attribute_Name  => Name_Range,
 586                             Expressions => New_List (
 587                               Make_Integer_Literal (Loc, Dim))))),
 588                 Statements =>  Free_One_Dimension (Dim + 1)));
 589          end if;
 590       end Free_One_Dimension;
 591
 592    --  Start of processing for Cleanup_Array
 593
 594    begin
 595       return Free_One_Dimension (1);
 596    end Cleanup_Array;
 597
 598    --------------------
 599    -- Cleanup_Record --
 600    --------------------
 601
 602    function Cleanup_Record
 603      (N    : Node_Id;
 604       Obj  : Node_Id;
 605       Typ  : Entity_Id)
 606       return List_Id
 607    is
 608       Loc   : constant Source_Ptr := Sloc (N);
 609       Tsk   : Node_Id;
 610       Comp  : Entity_Id;
 611       Stmts : List_Id := New_List;
 612       U_Typ : constant Entity_Id := Underlying_Type (Typ);
 613
 614    begin
 615       if Has_Discriminants (U_Typ)
 616         and then Nkind (Parent (U_Typ)) = N_Full_Type_Declaration
 617         and then
 618           Nkind (Type_Definition (Parent (U_Typ))) = N_Record_Definition
 619         and then
 620           Present
 621             (Variant_Part
 622               (Component_List (Type_Definition (Parent (U_Typ)))))
 623       then
 624          --  For now, do not attempt to free a component that may appear in
 625          --  a variant, and instead issue a warning. Doing this "properly"
 626          --  would require building a case statement and would be quite a
 627          --  mess. Note that the RM only requires that free "work" for the
 628          --  case of a task access value, so already we go way beyond this
 629          --  in that we deal with the array case and non-discriminated
 630          --  record cases.
 631
 632          Error_Msg_N
 633            ("task/protected object in variant record will not be freed?", N);
 634          return New_List (Make_Null_Statement (Loc));
 635       end if;
 636
 637       Comp := First_Component (Typ);
 638
 639       while Present (Comp) loop
 640          if Has_Task (Etype (Comp))
 641            or else Has_Simple_Protected_Object (Etype (Comp))
 642          then
 643             Tsk :=
 644               Make_Selected_Component (Loc,
 645                 Prefix        => Duplicate_Subexpr_No_Checks (Obj),
 646                 Selector_Name => New_Occurrence_Of (Comp, Loc));
 647             Set_Etype (Tsk, Etype (Comp));
 648
 649             if Is_Task_Type (Etype (Comp)) then
 650                Append_To (Stmts, Cleanup_Task (N, Tsk));
 651
 652             elsif Is_Simple_Protected_Type (Etype (Comp)) then
 653                Append_To (Stmts, Cleanup_Protected_Object (N, Tsk));
 654
 655             elsif Is_Record_Type (Etype (Comp)) then
 656
 657                --  Recurse, by generating the prefix of the argument to
 658                --  the eventual cleanup call.
 659
 660                Append_List_To
 661                  (Stmts, Cleanup_Record (N, Tsk, Etype (Comp)));
 662
 663             elsif Is_Array_Type (Etype (Comp)) then
 664                Append_List_To
 665                  (Stmts, Cleanup_Array (N, Tsk, Etype (Comp)));
 666             end if;
 667          end if;
 668
 669          Next_Component (Comp);
 670       end loop;
 671
 672       return Stmts;
 673    end Cleanup_Record;
 674
 675    -------------------------------
 676    --  Cleanup_Protected_Object --
 677    -------------------------------
 678
 679    function Cleanup_Protected_Object
 680      (N    : Node_Id;
 681       Ref  : Node_Id)
 682       return Node_Id
 683    is
 684       Loc : constant Source_Ptr := Sloc (N);
 685
 686    begin
 687       return
 688         Make_Procedure_Call_Statement (Loc,
 689           Name => New_Reference_To (RTE (RE_Finalize_Protection), Loc),
 690           Parameter_Associations => New_List (
 691             Concurrent_Ref (Ref)));
 692    end Cleanup_Protected_Object;
 693
 694    ------------------------------------
 695    -- Clean_Simple_Protected_Objects --
 696    ------------------------------------
 697
 698    procedure Clean_Simple_Protected_Objects (N : Node_Id) is
 699       E     : Entity_Id;
 700       Stmts : List_Id := Statements (Handled_Statement_Sequence (N));
 701       Stmt  : Node_Id := Last (Stmts);
 702
 703    begin
 704       E := First_Entity (Current_Scope);
 705
 706       while Present (E) loop
 707          if (Ekind (E) = E_Variable
 708               or else Ekind (E) = E_Constant)
 709            and then Has_Simple_Protected_Object (Etype (E))
 710            and then not Has_Task (Etype (E))
 711          then
 712             declare
 713                Typ : constant Entity_Id := Etype (E);
 714                Ref : constant Node_Id := New_Occurrence_Of (E, Sloc (Stmt));
 715
 716             begin
 717                if Is_Simple_Protected_Type (Typ) then
 718                   Append_To (Stmts, Cleanup_Protected_Object (N, Ref));
 719
 720                elsif Has_Simple_Protected_Object (Typ) then
 721                   if Is_Record_Type (Typ) then
 722                      Append_List_To (Stmts, Cleanup_Record (N, Ref, Typ));
 723
 724                   elsif Is_Array_Type (Typ) then
 725                      Append_List_To (Stmts, Cleanup_Array (N, Ref, Typ));
 726                   end if;
 727                end if;
 728             end;
 729          end if;
 730
 731          Next_Entity (E);
 732       end loop;
 733
 734       --   Analyze inserted cleanup statements.
 735
 736       if Present (Stmt) then
 737          Stmt := Next (Stmt);
 738
 739          while Present (Stmt) loop
 740             Analyze (Stmt);
 741             Next (Stmt);
 742          end loop;
 743       end if;
 744    end Clean_Simple_Protected_Objects;
 745
 746    ------------------
 747    -- Cleanup_Task --
 748    ------------------
 749
 750    function Cleanup_Task
 751      (N    : Node_Id;
 752       Ref  : Node_Id)
 753       return Node_Id
 754    is
 755       Loc  : constant Source_Ptr := Sloc (N);
 756    begin
 757       return
 758         Make_Procedure_Call_Statement (Loc,
 759           Name => New_Reference_To (RTE (RE_Free_Task), Loc),
 760           Parameter_Associations =>
 761             New_List (Concurrent_Ref (Ref)));
 762    end Cleanup_Task;
 763
 764    ---------------------------------
 765    -- Has_Simple_Protected_Object --
 766    ---------------------------------
 767
 768    function Has_Simple_Protected_Object (T : Entity_Id) return Boolean is
 769       Comp : Entity_Id;
 770
 771    begin
 772       if Is_Simple_Protected_Type (T) then
 773          return True;
 774
 775       elsif Is_Array_Type (T) then
 776          return Has_Simple_Protected_Object (Component_Type (T));
 777
 778       elsif Is_Record_Type (T) then
 779          Comp := First_Component (T);
 780
 781          while Present (Comp) loop
 782             if Has_Simple_Protected_Object (Etype (Comp)) then
 783                return True;
 784             end if;
 785
 786             Next_Component (Comp);
 787          end loop;
 788
 789          return False;
 790
 791       else
 792          return False;
 793       end if;
 794    end Has_Simple_Protected_Object;
 795
 796    ------------------------------
 797    -- Is_Simple_Protected_Type --
 798    ------------------------------
 799
 800    function Is_Simple_Protected_Type (T : Entity_Id) return Boolean is
 801    begin
 802       return Is_Protected_Type (T) and then not Has_Entries (T);
 803    end Is_Simple_Protected_Type;
 804
 805    ------------------------------
 806    -- Check_Visibly_Controlled --
 807    ------------------------------
 808
 809    procedure Check_Visibly_Controlled
 810      (Prim : Final_Primitives;
 811       Typ  : Entity_Id;
 812       E    : in out Entity_Id;
 813       Cref : in out Node_Id)
 814    is
 815       Parent_Type : Entity_Id;
 816       Op          : Entity_Id;
 817
 818    begin
 819       if Is_Derived_Type (Typ)
 820         and then Comes_From_Source (E)
 821         and then Is_Overriding_Operation (E)
 822         and then
 823           (not Is_Predefined_File_Name
 824                      (Unit_File_Name (Get_Source_Unit (Root_Type (Typ)))))
 825       then
 826          --  We know that the explicit operation on the type overrode
 827          --  the inherited operation of the parent, and that the derivation
 828          --  is from a private type that is not visibly controlled.
 829
 830          Parent_Type := Etype (Typ);
 831          Op := Find_Prim_Op (Parent_Type, Name_Of (Prim));
 832
 833          if Present (Op)
 834             and then Is_Hidden (Op)
 835             and then Scope (Scope (Typ)) /= Scope (Op)
 836             and then not In_Open_Scopes (Scope (Typ))
 837          then
 838             --  If the parent operation is not visible, and the derived
 839             --  type is not declared in a child unit, then the explicit
 840             --  operation does not override, and we must use the operation
 841             --  of the parent.
 842
 843             E := Op;
 844
 845             --  Wrap the object to be initialized into the proper
 846             --  unchecked conversion, to be compatible with the operation
 847             --  to be called.
 848
 849             if Nkind (Cref) = N_Unchecked_Type_Conversion then
 850                Cref := Unchecked_Convert_To (Parent_Type, Expression (Cref));
 851             else
 852                Cref := Unchecked_Convert_To (Parent_Type, Cref);
 853             end if;
 854          end if;
 855       end if;
 856    end Check_Visibly_Controlled;
 857
 858    ---------------------
 859    -- Controlled_Type --
 860    ---------------------
 861
 862    function Controlled_Type (T : Entity_Id) return Boolean is
 863
 864       function Has_Some_Controlled_Component (Rec : Entity_Id) return Boolean;
 865       --  If type is not frozen yet, check explicitly among its components,
 866       --  because flag is not necessarily set.
 867
 868       ------------------------------------
 869       --  Has_Some_Controlled_Component --
 870       ------------------------------------
 871
 872       function Has_Some_Controlled_Component (Rec : Entity_Id)
 873         return Boolean
 874       is
 875          Comp : Entity_Id;
 876
 877       begin
 878          if Has_Controlled_Component (Rec) then
 879             return True;
 880
 881          elsif not Is_Frozen (Rec) then
 882             if Is_Record_Type (Rec) then
 883                Comp := First_Entity (Rec);
 884
 885                while Present (Comp) loop
 886                   if not Is_Type (Comp)
 887                     and then Controlled_Type (Etype (Comp))
 888                   then
 889                      return True;
 890                   end if;
 891
 892                   Next_Entity (Comp);
 893                end loop;
 894
 895                return False;
 896
 897             elsif Is_Array_Type (Rec) then
 898                return Is_Controlled (Component_Type (Rec));
 899
 900             else
 901                return Has_Controlled_Component (Rec);
 902             end if;
 903          else
 904             return False;
 905          end if;
 906       end Has_Some_Controlled_Component;
 907
 908    --  Start of processing for Controlled_Type
 909
 910    begin
 911       --  Class-wide types must be treated as controlled because they may
 912       --  contain an extension that has controlled components
 913
 914       --  We can skip this if finalization is not available
 915
 916       return (Is_Class_Wide_Type (T)
 917                 and then not In_Finalization_Root (T)
 918                 and then not Restrictions (No_Finalization))
 919         or else Is_Controlled (T)
 920         or else Has_Some_Controlled_Component (T)
 921         or else (Is_Concurrent_Type (T)
 922                    and then Present (Corresponding_Record_Type (T))
 923                    and then Controlled_Type (Corresponding_Record_Type (T)));
 924    end Controlled_Type;
 925
 926    --------------------------
 927    -- Controller_Component --
 928    --------------------------
 929
 930    function Controller_Component (Typ : Entity_Id) return Entity_Id is
 931       T         : Entity_Id := Base_Type (Typ);
 932       Comp      : Entity_Id;
 933       Comp_Scop : Entity_Id;
 934       Res       : Entity_Id := Empty;
 935       Res_Scop  : Entity_Id := Empty;
 936
 937    begin
 938       if Is_Class_Wide_Type (T) then
 939          T := Root_Type (T);
 940       end if;
 941
 942       if Is_Private_Type (T) then
 943          T := Underlying_Type (T);
 944       end if;
 945
 946       --  Fetch the outermost controller
 947
 948       Comp := First_Entity (T);
 949       while Present (Comp) loop
 950          if Chars (Comp) = Name_uController then
 951             Comp_Scop := Scope (Original_Record_Component (Comp));
 952
 953             --  If this controller is at the outermost level, no need to
 954             --  look for another one
 955
 956             if Comp_Scop = T then
 957                return Comp;
 958
 959             --  Otherwise record the outermost one and continue looking
 960
 961             elsif Res = Empty or else Is_Ancestor (Res_Scop, Comp_Scop) then
 962                Res      := Comp;
 963                Res_Scop := Comp_Scop;
 964             end if;
 965          end if;
 966
 967          Next_Entity (Comp);
 968       end loop;
 969
 970       --  If we fall through the loop, there is no controller component
 971
 972       return Res;
 973    end Controller_Component;
 974
 975    ------------------
 976    -- Convert_View --
 977    ------------------
 978
 979    function Convert_View
 980      (Proc : Entity_Id;
 981       Arg  : Node_Id;
 982       Ind  : Pos := 1)
 983       return Node_Id
 984    is
 985       Fent : Entity_Id := First_Entity (Proc);
 986       Ftyp : Entity_Id;
 987       Atyp : Entity_Id;
 988
 989    begin
 990       for J in 2 .. Ind loop
 991          Next_Entity (Fent);
 992       end loop;
 993
 994       Ftyp := Etype (Fent);
 995
 996       if Nkind (Arg) = N_Type_Conversion
 997         or else Nkind (Arg) = N_Unchecked_Type_Conversion
 998       then
 999          Atyp := Entity (Subtype_Mark (Arg));
1000       else
1001          Atyp := Etype (Arg);
1002       end if;
1003
1004       if Is_Abstract (Proc) and then Is_Tagged_Type (Ftyp) then
1005          return Unchecked_Convert_To (Class_Wide_Type (Ftyp), Arg);
1006
1007       elsif Ftyp /= Atyp
1008         and then Present (Atyp)
1009         and then
1010           (Is_Private_Type (Ftyp) or else Is_Private_Type (Atyp))
1011         and then Underlying_Type (Atyp) = Underlying_Type (Ftyp)
1012       then
1013          return Unchecked_Convert_To (Ftyp, Arg);
1014
1015       --  If the argument is already a conversion, as generated by
1016       --  Make_Init_Call, set the target type to the type of the formal
1017       --  directly, to avoid spurious typing problems.
1018
1019       elsif (Nkind (Arg) = N_Unchecked_Type_Conversion
1020               or else Nkind (Arg) = N_Type_Conversion)
1021         and then not Is_Class_Wide_Type (Atyp)
1022       then
1023          Set_Subtype_Mark (Arg, New_Occurrence_Of (Ftyp, Sloc (Arg)));
1024          Set_Etype (Arg, Ftyp);
1025          return Arg;
1026
1027       else
1028          return Arg;
1029       end if;
1030    end Convert_View;
1031
1032    -------------------------------
1033    -- Establish_Transient_Scope --
1034    -------------------------------
1035
1036    --  This procedure is called each time a transient block has to be inserted
1037    --  that is to say for each call to a function with unconstrained ot tagged
1038    --  result. It creates a new scope on the stack scope in order to enclose
1039    --  all transient variables generated
1040
1041    procedure Establish_Transient_Scope (N : Node_Id; Sec_Stack : Boolean) is
1042       Loc       : constant Source_Ptr := Sloc (N);
1043       Wrap_Node : Node_Id;
1044
1045       Sec_Stk : constant Boolean :=
1046                   Sec_Stack and not Functions_Return_By_DSP_On_Target;
1047       --  We never need a secondary stack if functions return by DSP
1048
1049    begin
1050       --  Do not create a transient scope if we are already inside one
1051
1052       for S in reverse Scope_Stack.First .. Scope_Stack.Last loop
1053
1054          if Scope_Stack.Table (S).Is_Transient then
1055             if Sec_Stk then
1056                Set_Uses_Sec_Stack (Scope_Stack.Table (S).Entity);
1057             end if;
1058
1059             return;
1060
1061          --  If we have encountered Standard there are no enclosing
1062          --  transient scopes.
1063
1064          elsif Scope_Stack.Table (S).Entity = Standard_Standard then
1065             exit;
1066
1067          end if;
1068       end loop;
1069
1070       Wrap_Node := Find_Node_To_Be_Wrapped (N);
1071
1072       --  Case of no wrap node, false alert, no transient scope needed
1073
1074       if No (Wrap_Node) then
1075          null;
1076
1077       elsif Nkind (Wrap_Node) = N_Iteration_Scheme then
1078
1079          --  Create a declaration followed by an assignment, so that
1080          --  the assignment can have its own transient scope.
1081          --  We generate the equivalent of:
1082
1083          --  type Ptr is access all expr_type;
1084          --  Var : Ptr;
1085          --  begin
1086          --     Var := Expr'reference;
1087          --  end;
1088
1089          --  This closely resembles what is done in Remove_Side_Effect,
1090          --  but it has to be done here, before the analysis of the call
1091          --  is completed.
1092
1093          declare
1094             Ptr_Typ : constant Entity_Id :=
1095                         Make_Defining_Identifier (Loc,
1096                           Chars => New_Internal_Name ('A'));
1097             Ptr     : constant Entity_Id :=
1098                         Make_Defining_Identifier (Loc,
1099                           Chars => New_Internal_Name ('T'));
1100
1101             Expr_Type    : constant Entity_Id := Etype (N);
1102             New_Expr     : constant Node_Id := Relocate_Node (N);
1103             Decl         : Node_Id;
1104             Ptr_Typ_Decl : Node_Id;
1105             Stmt         : Node_Id;
1106
1107          begin
1108             Ptr_Typ_Decl :=
1109               Make_Full_Type_Declaration (Loc,
1110                 Defining_Identifier => Ptr_Typ,
1111                 Type_Definition =>
1112                   Make_Access_To_Object_Definition (Loc,
1113                     All_Present => True,
1114                     Subtype_Indication =>
1115                       New_Reference_To (Expr_Type, Loc)));
1116
1117             Decl :=
1118               Make_Object_Declaration (Loc,
1119                  Defining_Identifier => Ptr,
1120                  Object_Definition => New_Occurrence_Of (Ptr_Typ, Loc));
1121
1122             Set_Etype (Ptr, Ptr_Typ);
1123             Stmt :=
1124                Make_Assignment_Statement (Loc,
1125                   Name => New_Occurrence_Of (Ptr, Loc),
1126                   Expression => Make_Reference (Loc, New_Expr));
1127
1128             Set_Analyzed (New_Expr, False);
1129
1130             Insert_List_Before_And_Analyze
1131               (Parent (Wrap_Node),
1132                  New_List (
1133                    Ptr_Typ_Decl,
1134                    Decl,
1135                    Make_Block_Statement (Loc,
1136                      Handled_Statement_Sequence =>
1137                        Make_Handled_Sequence_Of_Statements (Loc,
1138                          New_List (Stmt)))));
1139
1140             Rewrite (N,
1141               Make_Explicit_Dereference (Loc,
1142                 Prefix => New_Reference_To (Ptr, Loc)));
1143             Analyze_And_Resolve (N, Expr_Type);
1144
1145          end;
1146
1147       --  Transient scope is required
1148
1149       else
1150          New_Scope (New_Internal_Entity (E_Block, Current_Scope, Loc, 'B'));
1151          Set_Scope_Is_Transient;
1152
1153          if Sec_Stk then
1154             Set_Uses_Sec_Stack (Current_Scope);
1155             Check_Restriction (No_Secondary_Stack, N);
1156          end if;
1157
1158          Set_Etype (Current_Scope, Standard_Void_Type);
1159          Set_Node_To_Be_Wrapped (Wrap_Node);
1160
1161          if Debug_Flag_W then
1162             Write_Str ("    <Transient>");
1163             Write_Eol;
1164          end if;
1165       end if;
1166    end Establish_Transient_Scope;
1167
1168    ----------------------------
1169    -- Expand_Cleanup_Actions --
1170    ----------------------------
1171
1172    procedure Expand_Cleanup_Actions (N : Node_Id) is
1173       Loc                  :  Source_Ptr;
1174       S                    : constant Entity_Id  :=
1175                                Current_Scope;
1176       Flist                : constant Entity_Id  :=
1177                                Finalization_Chain_Entity (S);
1178       Is_Task              : constant Boolean    :=
1179                                (Nkind (Original_Node (N)) = N_Task_Body);
1180       Is_Master            : constant Boolean    :=
1181                                Nkind (N) /= N_Entry_Body
1182                                  and then Is_Task_Master (N);
1183       Is_Protected         : constant Boolean    :=
1184                                Nkind (N) = N_Subprogram_Body
1185                                  and then Is_Protected_Subprogram_Body (N);
1186       Is_Task_Allocation   : constant Boolean    :=
1187                                Nkind (N) = N_Block_Statement
1188                                  and then Is_Task_Allocation_Block (N);
1189       Is_Asynchronous_Call : constant Boolean    :=
1190                                Nkind (N) = N_Block_Statement
1191                                  and then Is_Asynchronous_Call_Block (N);
1192
1193       Clean     : Entity_Id;
1194       Mark      : Entity_Id := Empty;
1195       New_Decls : constant List_Id := New_List;
1196       Blok      : Node_Id;
1197       Wrapped   : Boolean;
1198       Chain     : Entity_Id := Empty;
1199       Decl      : Node_Id;
1200       Old_Poll  : Boolean;
1201
1202    begin
1203
1204       --  Compute a location that is not directly in the user code in
1205       --  order to avoid to generate confusing debug info. A good
1206       --  approximation is the name of the outer user-defined scope
1207
1208       declare
1209          S1 : Entity_Id := S;
1210
1211       begin
1212          while not Comes_From_Source (S1) and then S1 /= Standard_Standard loop
1213             S1 := Scope (S1);
1214          end loop;
1215
1216          Loc := Sloc (S1);
1217       end;
1218
1219       --  There are cleanup actions only if the secondary stack needs
1220       --  releasing or some finalizations are needed or in the context
1221       --  of tasking
1222
1223       if Uses_Sec_Stack  (Current_Scope)
1224         and then not Sec_Stack_Needed_For_Return (Current_Scope)
1225       then
1226          null;
1227       elsif No (Flist)
1228         and then not Is_Master
1229         and then not Is_Task
1230         and then not Is_Protected
1231         and then not Is_Task_Allocation
1232         and then not Is_Asynchronous_Call
1233       then
1234          Clean_Simple_Protected_Objects (N);
1235          return;
1236       end if;
1237
1238       --  If the current scope is the subprogram body that is the rewriting
1239       --  of a task body, and the descriptors have not been delayed (due to
1240       --  some nested instantiations) do not generate redundant cleanup
1241       --  actions: the cleanup procedure already exists for this body.
1242
1243       if Nkind (N) = N_Subprogram_Body
1244         and then Nkind (Original_Node (N)) = N_Task_Body
1245         and then not Delay_Subprogram_Descriptors (Corresponding_Spec (N))
1246       then
1247          return;
1248       end if;
1249
1250       --  Set polling off, since we don't need to poll during cleanup
1251       --  actions, and indeed for the cleanup routine, which is executed
1252       --  with aborts deferred, we don't want polling.
1253
1254       Old_Poll := Polling_Required;
1255       Polling_Required := False;
1256
1257       --  Make sure we have a declaration list, since we will add to it
1258
1259       if No (Declarations (N)) then
1260          Set_Declarations (N, New_List);
1261       end if;
1262
1263       --  The task activation call has already been built for task
1264       --  allocation blocks.
1265
1266       if not Is_Task_Allocation then
1267          Build_Task_Activation_Call (N);
1268       end if;
1269
1270       if Is_Master then
1271          Establish_Task_Master (N);
1272       end if;
1273
1274       --  If secondary stack is in use, expand:
1275       --    _Mxx : constant Mark_Id := SS_Mark;
1276
1277       --  Suppress calls to SS_Mark and SS_Release if Java_VM,
1278       --  since we never use the secondary stack on the JVM.
1279
1280       if Uses_Sec_Stack (Current_Scope)
1281         and then not Sec_Stack_Needed_For_Return (Current_Scope)
1282         and then not Java_VM
1283       then
1284          Mark := Make_Defining_Identifier (Loc, New_Internal_Name ('M'));
1285          Append_To (New_Decls,
1286            Make_Object_Declaration (Loc,
1287              Defining_Identifier => Mark,
1288              Object_Definition   => New_Reference_To (RTE (RE_Mark_Id), Loc),
1289              Expression =>
1290                Make_Function_Call (Loc,
1291                  Name => New_Reference_To (RTE (RE_SS_Mark), Loc))));
1292
1293          Set_Uses_Sec_Stack (Current_Scope, False);
1294       end if;
1295
1296       --  If finalization list is present then expand:
1297       --   Local_Final_List : System.FI.Finalizable_Ptr;
1298
1299       if Present (Flist) then
1300          Append_To (New_Decls,
1301            Make_Object_Declaration (Loc,
1302              Defining_Identifier => Flist,
1303              Object_Definition   =>
1304                New_Reference_To (RTE (RE_Finalizable_Ptr), Loc)));
1305       end if;
1306
1307       --  Clean-up procedure definition
1308
1309       Clean := Make_Defining_Identifier (Loc, Name_uClean);
1310       Set_Suppress_Elaboration_Warnings (Clean);
1311       Append_To (New_Decls,
1312         Make_Clean (N, Clean, Mark, Flist,
1313           Is_Task,
1314           Is_Master,
1315           Is_Protected,
1316           Is_Task_Allocation,
1317           Is_Asynchronous_Call));
1318
1319       --  If exception handlers are present, wrap the Sequence of
1320       --  statements in a block because it is not possible to get
1321       --  exception handlers and an AT END call in the same scope.
1322
1323       if Present (Exception_Handlers (Handled_Statement_Sequence (N))) then
1324          Blok :=
1325            Make_Block_Statement (Loc,
1326              Handled_Statement_Sequence => Handled_Statement_Sequence (N));
1327          Set_Handled_Statement_Sequence (N,
1328            Make_Handled_Sequence_Of_Statements (Loc, New_List (Blok)));
1329          Wrapped := True;
1330
1331       --  Otherwise we do not wrap
1332
1333       else
1334          Wrapped := False;
1335          Blok    := Empty;
1336       end if;
1337
1338       --  Don't move the _chain Activation_Chain declaration in task
1339       --  allocation blocks. Task allocation blocks use this object
1340       --  in their cleanup handlers, and gigi complains if it is declared
1341       --  in the sequence of statements of the scope that declares the
1342       --  handler.
1343
1344       if Is_Task_Allocation then
1345          Chain := Activation_Chain_Entity (N);
1346          Decl := First (Declarations (N));
1347
1348          while Nkind (Decl) /= N_Object_Declaration
1349            or else Defining_Identifier (Decl) /= Chain
1350          loop
1351             Next (Decl);
1352             pragma Assert (Present (Decl));
1353          end loop;
1354
1355          Remove (Decl);
1356          Prepend_To (New_Decls, Decl);
1357       end if;
1358
1359       --  Now we move the declarations into the Sequence of statements
1360       --  in order to get them protected by the AT END call. It may seem
1361       --  weird to put declarations in the sequence of statement but in
1362       --  fact nothing forbids that at the tree level. We also set the
1363       --  First_Real_Statement field so that we remember where the real
1364       --  statements (i.e. original statements) begin. Note that if we
1365       --  wrapped the statements, the first real statement is inside the
1366       --  inner block. If the First_Real_Statement is already set (as is
1367       --  the case for subprogram bodies that are expansions of task bodies)
1368       --  then do not reset it, because its declarative part would migrate
1369       --  to the statement part.
1370
1371       if not Wrapped then
1372          if No (First_Real_Statement (Handled_Statement_Sequence (N))) then
1373             Set_First_Real_Statement (Handled_Statement_Sequence (N),
1374               First (Statements (Handled_Statement_Sequence (N))));
1375          end if;
1376
1377       else
1378          Set_First_Real_Statement (Handled_Statement_Sequence (N), Blok);
1379       end if;
1380
1381       Append_List_To (Declarations (N),
1382         Statements (Handled_Statement_Sequence (N)));
1383       Set_Statements (Handled_Statement_Sequence (N), Declarations (N));
1384
1385       --  We need to reset the Sloc of the handled statement sequence to
1386       --  properly reflect the new initial "statement" in the sequence.
1387
1388       Set_Sloc
1389         (Handled_Statement_Sequence (N), Sloc (First (Declarations (N))));
1390
1391       --  The declarations of the _Clean procedure and finalization chain
1392       --  replace the old declarations that have been moved inward
1393
1394       Set_Declarations (N, New_Decls);
1395       Analyze_Declarations (New_Decls);
1396
1397       --  The At_End call is attached to the sequence of statements.
1398
1399       declare
1400          HSS : Node_Id;
1401
1402       begin
1403          --  If the construct is a protected subprogram, then the call to
1404          --  the corresponding unprotected program appears in a block which
1405          --  is the last statement in the body, and it is this block that
1406          --  must be covered by the At_End handler.
1407
1408          if Is_Protected then
1409             HSS := Handled_Statement_Sequence
1410               (Last (Statements (Handled_Statement_Sequence (N))));
1411          else
1412             HSS := Handled_Statement_Sequence (N);
1413          end if;
1414
1415          Set_At_End_Proc (HSS, New_Occurrence_Of (Clean, Loc));
1416          Expand_At_End_Handler (HSS, Empty);
1417       end;
1418
1419       --  Restore saved polling mode
1420
1421       Polling_Required := Old_Poll;
1422    end Expand_Cleanup_Actions;
1423
1424    -------------------------------
1425    -- Expand_Ctrl_Function_Call --
1426    -------------------------------
1427
1428    procedure Expand_Ctrl_Function_Call (N : Node_Id) is
1429       Loc     : constant Source_Ptr := Sloc (N);
1430       Rtype   : constant Entity_Id  := Etype (N);
1431       Utype   : constant Entity_Id  := Underlying_Type (Rtype);
1432       Ref     : Node_Id;
1433       Action  : Node_Id;
1434       Action2 : Node_Id := Empty;
1435
1436       Attach_Level : Uint    := Uint_1;
1437       Len_Ref      : Node_Id := Empty;
1438
1439       function Last_Array_Component
1440         (Ref :  Node_Id;
1441          Typ :  Entity_Id)
1442          return Node_Id;
1443       --  Creates a reference to the last component of the array object
1444       --  designated by Ref whose type is Typ.
1445
1446       --------------------------
1447       -- Last_Array_Component --
1448       --------------------------
1449
1450       function Last_Array_Component
1451         (Ref :  Node_Id;
1452          Typ :  Entity_Id)
1453          return Node_Id
1454       is
1455          Index_List : constant List_Id := New_List;
1456
1457       begin
1458          for N in 1 .. Number_Dimensions (Typ) loop
1459             Append_To (Index_List,
1460               Make_Attribute_Reference (Loc,
1461                 Prefix         => Duplicate_Subexpr_No_Checks (Ref),
1462                 Attribute_Name => Name_Last,
1463                 Expressions    => New_List (
1464                   Make_Integer_Literal (Loc, N))));
1465          end loop;
1466
1467          return
1468            Make_Indexed_Component (Loc,
1469              Prefix      => Duplicate_Subexpr (Ref),
1470              Expressions => Index_List);
1471       end Last_Array_Component;
1472
1473    --  Start of processing for Expand_Ctrl_Function_Call
1474
1475    begin
1476       --  Optimization, if the returned value (which is on the sec-stack)
1477       --  is returned again, no need to copy/readjust/finalize, we can just
1478       --  pass the value thru (see Expand_N_Return_Statement), and thus no
1479       --  attachment is needed
1480
1481       if Nkind (Parent (N)) = N_Return_Statement then
1482          return;
1483       end if;
1484
1485       --  Resolution is now finished, make sure we don't start analysis again
1486       --  because of the duplication
1487
1488       Set_Analyzed (N);
1489       Ref := Duplicate_Subexpr_No_Checks (N);
1490
1491       --  Now we can generate the Attach Call, note that this value is
1492       --  always in the (secondary) stack and thus is attached to a singly
1493       --  linked final list:
1494
1495       --    Resx := F (X)'reference;
1496       --    Attach_To_Final_List (_Lx, Resx.all, 1);
1497
1498       --  or when there are controlled components
1499
1500       --    Attach_To_Final_List (_Lx, Resx._controller, 1);
1501
1502       --  or when it is both is_controlled and has_controlled_components
1503
1504       --    Attach_To_Final_List (_Lx, Resx._controller, 1);
1505       --    Attach_To_Final_List (_Lx, Resx, 1);
1506
1507       --  or if it is an array with is_controlled (and has_controlled)
1508
1509       --    Attach_To_Final_List (_Lx, Resx (Resx'last), 3);
1510       --    An attach level of 3 means that a whole array is to be
1511       --    attached to the finalization list (including the controlled
1512       --    components)
1513
1514       --  or if it is an array with has_controlled components but not
1515       --  is_controlled
1516
1517       --    Attach_To_Final_List (_Lx, Resx (Resx'last)._controller, 3);
1518
1519       if Has_Controlled_Component (Rtype) then
1520          declare
1521             T1 : Entity_Id := Rtype;
1522             T2 : Entity_Id := Utype;
1523
1524          begin
1525             if Is_Array_Type (T2) then
1526                Len_Ref :=
1527                  Make_Attribute_Reference (Loc,
1528                  Prefix =>
1529                    Duplicate_Subexpr_Move_Checks
1530                      (Unchecked_Convert_To (T2, Ref)),
1531                  Attribute_Name => Name_Length);
1532             end if;
1533
1534             while Is_Array_Type (T2) loop
1535                if T1 /= T2 then
1536                   Ref := Unchecked_Convert_To (T2, Ref);
1537                end if;
1538
1539                Ref := Last_Array_Component (Ref, T2);
1540                Attach_Level := Uint_3;
1541                T1 := Component_Type (T2);
1542                T2 := Underlying_Type (T1);
1543             end loop;
1544
1545             --  If the type has controlled components, go to the controller
1546             --  except in the case of arrays of controlled objects since in
1547             --  this case objects and their components are already chained
1548             --  and the head of the chain is the last array element.
1549
1550             if Is_Array_Type (Rtype) and then Is_Controlled (T2) then
1551                null;
1552
1553             elsif Has_Controlled_Component (T2) then
1554                if T1 /= T2 then
1555                   Ref := Unchecked_Convert_To (T2, Ref);
1556                end if;
1557
1558                Ref :=
1559                  Make_Selected_Component (Loc,
1560                    Prefix        => Ref,
1561                    Selector_Name => Make_Identifier (Loc, Name_uController));
1562             end if;
1563          end;
1564
1565          --  Here we know that 'Ref' has a controller so we may as well
1566          --  attach it directly
1567
1568          Action :=
1569            Make_Attach_Call (
1570              Obj_Ref      => Ref,
1571              Flist_Ref    => Find_Final_List (Current_Scope),
1572              With_Attach  => Make_Integer_Literal (Loc, Attach_Level));
1573
1574          --  If it is also Is_Controlled we need to attach the global object
1575
1576          if Is_Controlled (Rtype) then
1577             Action2 :=
1578               Make_Attach_Call (
1579                 Obj_Ref      => Duplicate_Subexpr_No_Checks (N),
1580                 Flist_Ref    => Find_Final_List (Current_Scope),
1581                 With_Attach  => Make_Integer_Literal (Loc, Attach_Level));
1582          end if;
1583
1584       else
1585          --  Here, we have a controlled type that does not seem to have
1586          --  controlled components but it could be a class wide type whose
1587          --  further derivations have controlled components. So we don't know
1588          --  if the object itself needs to be attached or if it
1589          --  has a record controller. We need to call a runtime function
1590          --  (Deep_Tag_Attach) which knows what to do thanks to the
1591          --  RC_Offset in the dispatch table.
1592
1593          Action :=
1594            Make_Procedure_Call_Statement (Loc,
1595              Name => New_Reference_To (RTE (RE_Deep_Tag_Attach), Loc),
1596              Parameter_Associations => New_List (
1597                Find_Final_List (Current_Scope),
1598
1599                Make_Attribute_Reference (Loc,
1600                    Prefix => Ref,
1601                    Attribute_Name => Name_Address),
1602
1603                Make_Integer_Literal (Loc, Attach_Level)));
1604       end if;
1605
1606       if Present (Len_Ref) then
1607          Action :=
1608            Make_Implicit_If_Statement (N,
1609              Condition => Make_Op_Gt (Loc,
1610                Left_Opnd  => Len_Ref,
1611                Right_Opnd => Make_Integer_Literal (Loc, 0)),
1612              Then_Statements => New_List (Action));
1613       end if;
1614
1615       Insert_Action (N, Action);
1616       if Present (Action2) then
1617          Insert_Action (N, Action2);
1618       end if;
1619    end Expand_Ctrl_Function_Call;
1620
1621    ---------------------------
1622    -- Expand_N_Package_Body --
1623    ---------------------------
1624
1625    --  Add call to Activate_Tasks if body is an activator (actual
1626    --  processing is in chapter 9).
1627
1628    --  Generate subprogram descriptor for elaboration routine
1629
1630    --  ENcode entity names in package body
1631
1632    procedure Expand_N_Package_Body (N : Node_Id) is
1633       Ent : constant Entity_Id := Corresponding_Spec (N);
1634
1635    begin
1636       --  This is done only for non-generic packages
1637
1638       if Ekind (Ent) = E_Package then
1639          New_Scope (Corresponding_Spec (N));
1640          Build_Task_Activation_Call (N);
1641          Pop_Scope;
1642       end if;
1643
1644       Set_Elaboration_Flag (N, Corresponding_Spec (N));
1645
1646       --  Generate a subprogram descriptor for the elaboration routine of
1647       --  a package body if the package body has no pending instantiations
1648       --  and it has generated at least one exception handler
1649
1650       if Present (Handler_Records (Body_Entity (Ent)))
1651         and then Is_Compilation_Unit (Ent)
1652         and then not Delay_Subprogram_Descriptors (Body_Entity (Ent))
1653       then
1654          Generate_Subprogram_Descriptor_For_Package
1655            (N, Body_Entity (Ent));
1656       end if;
1657
1658       Set_In_Package_Body (Ent, False);
1659
1660       --  Set to encode entity names in package body before gigi is called
1661
1662       Qualify_Entity_Names (N);
1663    end Expand_N_Package_Body;
1664
1665    ----------------------------------
1666    -- Expand_N_Package_Declaration --
1667    ----------------------------------
1668
1669    --  Add call to Activate_Tasks if there are tasks declared and the
1670    --  package has no body. Note that in Ada83,  this may result in
1671    --  premature activation of some tasks, given that we cannot tell
1672    --  whether a body will eventually appear.
1673
1674    procedure Expand_N_Package_Declaration (N : Node_Id) is
1675    begin
1676       if Nkind (Parent (N)) = N_Compilation_Unit
1677         and then not Body_Required (Parent (N))
1678         and then not Unit_Requires_Body (Defining_Entity (N))
1679         and then Present (Activation_Chain_Entity (N))
1680       then
1681          New_Scope (Defining_Entity (N));
1682          Build_Task_Activation_Call (N);
1683          Pop_Scope;
1684       end if;
1685
1686       --  Note: it is not necessary to worry about generating a subprogram
1687       --  descriptor, since the only way to get exception handlers into a
1688       --  package spec is to include instantiations, and that would cause
1689       --  generation of subprogram descriptors to be delayed in any case.
1690
1691       --  Set to encode entity names in package spec before gigi is called
1692
1693       Qualify_Entity_Names (N);
1694    end Expand_N_Package_Declaration;
1695
1696    ---------------------
1697    -- Find_Final_List --
1698    ---------------------
1699
1700    function Find_Final_List
1701      (E    : Entity_Id;
1702       Ref  : Node_Id := Empty)
1703       return Node_Id
1704    is
1705       Loc : constant Source_Ptr := Sloc (Ref);
1706       S   : Entity_Id;
1707       Id  : Entity_Id;
1708       R   : Node_Id;
1709
1710    begin
1711       --  Case of an internal component. The Final list is the record
1712       --  controller of the enclosing record
1713
1714       if Present (Ref) then
1715          R := Ref;
1716          loop
1717             case Nkind (R) is
1718                when N_Unchecked_Type_Conversion | N_Type_Conversion =>
1719                   R := Expression (R);
1720
1721                when N_Indexed_Component | N_Explicit_Dereference =>
1722                   R := Prefix (R);
1723
1724                when  N_Selected_Component =>
1725                   R := Prefix (R);
1726                   exit;
1727
1728                when  N_Identifier =>
1729                   exit;
1730
1731                when others =>
1732                   raise Program_Error;
1733             end case;
1734          end loop;
1735
1736          return
1737            Make_Selected_Component (Loc,
1738              Prefix =>
1739                Make_Selected_Component (Loc,
1740                  Prefix        => R,
1741                  Selector_Name => Make_Identifier (Loc, Name_uController)),
1742              Selector_Name => Make_Identifier (Loc, Name_F));
1743
1744       --  Case of a dynamically allocated object. The final list is the
1745       --  corresponding list controller (The next entity in the scope of
1746       --  the access type with the right type). If the type comes from a
1747       --  With_Type clause, no controller was created, and we use the
1748       --  global chain instead.
1749
1750       elsif Is_Access_Type (E) then
1751          if not From_With_Type (E) then
1752             return
1753               Make_Selected_Component (Loc,
1754                 Prefix        =>
1755                   New_Reference_To
1756                     (Associated_Final_Chain (Base_Type (E)), Loc),
1757                 Selector_Name => Make_Identifier (Loc, Name_F));
1758          else
1759             return New_Reference_To (RTE (RE_Global_Final_List), Sloc (E));
1760          end if;
1761
1762       else
1763          if Is_Dynamic_Scope (E) then
1764             S := E;
1765          else
1766             S := Enclosing_Dynamic_Scope (E);
1767          end if;
1768
1769          --  When the finalization chain entity is 'Error', it means that
1770          --  there should not be any chain at that level and that the
1771          --  enclosing one should be used
1772
1773          --  This is a nasty kludge, see ??? note in exp_ch11
1774
1775          while Finalization_Chain_Entity (S) = Error loop
1776             S := Enclosing_Dynamic_Scope (S);
1777          end loop;
1778
1779          if S = Standard_Standard then
1780             return New_Reference_To (RTE (RE_Global_Final_List), Sloc (E));
1781          else
1782             if No (Finalization_Chain_Entity (S)) then
1783
1784                Id := Make_Defining_Identifier (Sloc (S),
1785                  New_Internal_Name ('F'));
1786                Set_Finalization_Chain_Entity (S, Id);
1787
1788                --  Set momentarily some semantics attributes to allow normal
1789                --  analysis of expansions containing references to this chain.
1790                --  Will be fully decorated during the expansion of the scope
1791                --  itself
1792
1793                Set_Ekind (Id, E_Variable);
1794                Set_Etype (Id, RTE (RE_Finalizable_Ptr));
1795             end if;
1796
1797             return New_Reference_To (Finalization_Chain_Entity (S), Sloc (E));
1798          end if;
1799       end if;
1800    end Find_Final_List;
1801
1802    -----------------------------
1803    -- Find_Node_To_Be_Wrapped --
1804    -----------------------------
1805
1806    function Find_Node_To_Be_Wrapped (N : Node_Id) return Node_Id is
1807       P          : Node_Id;
1808       The_Parent : Node_Id;
1809
1810    begin
1811       The_Parent := N;
1812       loop
1813          P := The_Parent;
1814          pragma Assert (P /= Empty);
1815          The_Parent := Parent (P);
1816
1817          case Nkind (The_Parent) is
1818
1819             --  Simple statement can be wrapped
1820
1821             when N_Pragma               =>
1822                return The_Parent;
1823
1824             --  Usually assignments are good candidate for wrapping
1825             --  except when they have been generated as part of a
1826             --  controlled aggregate where the wrapping should take
1827             --  place more globally.
1828
1829             when N_Assignment_Statement =>
1830                if No_Ctrl_Actions (The_Parent) then
1831                   null;
1832                else
1833                   return The_Parent;
1834                end if;
1835
1836             --  An entry call statement is a special case if it occurs in
1837             --  the context of a Timed_Entry_Call. In this case we wrap
1838             --  the entire timed entry call.
1839
1840             when N_Entry_Call_Statement     |
1841                  N_Procedure_Call_Statement =>
1842                if Nkind (Parent (The_Parent)) = N_Entry_Call_Alternative
1843                  and then
1844                    Nkind (Parent (Parent (The_Parent))) = N_Timed_Entry_Call
1845                then
1846                   return Parent (Parent (The_Parent));
1847                else
1848                   return The_Parent;
1849                end if;
1850
1851             --  Object declarations are also a boundary for the transient scope
1852             --  even if they are not really wrapped
1853             --  (see Wrap_Transient_Declaration)
1854
1855             when N_Object_Declaration          |
1856                  N_Object_Renaming_Declaration |
1857                  N_Subtype_Declaration         =>
1858                return The_Parent;
1859
1860             --  The expression itself is to be wrapped if its parent is a
1861             --  compound statement or any other statement where the expression
1862             --  is known to be scalar
1863
1864             when N_Accept_Alternative               |
1865                  N_Attribute_Definition_Clause      |
1866                  N_Case_Statement                   |
1867                  N_Code_Statement                   |
1868                  N_Delay_Alternative                |
1869                  N_Delay_Until_Statement            |
1870                  N_Delay_Relative_Statement         |
1871                  N_Discriminant_Association         |
1872                  N_Elsif_Part                       |
1873                  N_Entry_Body_Formal_Part           |
1874                  N_Exit_Statement                   |
1875                  N_If_Statement                     |
1876                  N_Iteration_Scheme                 |
1877                  N_Terminate_Alternative            =>
1878                return P;
1879
1880             when N_Attribute_Reference              =>
1881
1882                if Is_Procedure_Attribute_Name
1883                     (Attribute_Name (The_Parent))
1884                then
1885                   return The_Parent;
1886                end if;
1887
1888             --  If the expression is within the iteration scheme of a loop,
1889             --  we must create a declaration for it, followed by an assignment
1890             --  in order to have a usable statement to wrap.
1891
1892             when N_Loop_Parameter_Specification =>
1893                return Parent (The_Parent);
1894
1895             --  The following nodes contains "dummy calls" which don't
1896             --  need to be wrapped.
1897
1898             when N_Parameter_Specification     |
1899                  N_Discriminant_Specification  |
1900                  N_Component_Declaration       =>
1901                return Empty;
1902
1903             --  The return statement is not to be wrapped when the function
1904             --  itself needs wrapping at the outer-level
1905
1906             when N_Return_Statement            =>
1907                if Requires_Transient_Scope (Return_Type (The_Parent)) then
1908                   return Empty;
1909                else
1910                   return The_Parent;
1911                end if;
1912
1913             --  If we leave a scope without having been able to find a node to
1914             --  wrap, something is going wrong but this can happen in error
1915             --  situation that are not detected yet (such as a dynamic string
1916             --  in a pragma export)
1917
1918             when N_Subprogram_Body     |
1919                  N_Package_Declaration |
1920                  N_Package_Body        |
1921                  N_Block_Statement     =>
1922                return Empty;
1923
1924             --  otherwise continue the search
1925
1926             when others =>
1927                null;
1928          end case;
1929       end loop;
1930    end Find_Node_To_Be_Wrapped;
1931
1932    ----------------------
1933    -- Global_Flist_Ref --
1934    ----------------------
1935
1936    function Global_Flist_Ref  (Flist_Ref : Node_Id) return Boolean is
1937       Flist : Entity_Id;
1938
1939    begin
1940       --  Look for the Global_Final_List
1941
1942       if Is_Entity_Name (Flist_Ref) then
1943          Flist := Entity (Flist_Ref);
1944
1945       --  Look for the final list associated with an access to controlled
1946
1947       elsif  Nkind (Flist_Ref) = N_Selected_Component
1948         and then Is_Entity_Name (Prefix (Flist_Ref))
1949       then
1950          Flist :=  Entity (Prefix (Flist_Ref));
1951       else
1952          return False;
1953       end if;
1954
1955       return Present (Flist)
1956         and then Present (Scope (Flist))
1957         and then Enclosing_Dynamic_Scope (Flist) = Standard_Standard;
1958    end Global_Flist_Ref;
1959
1960    ----------------------------------
1961    -- Has_New_Controlled_Component --
1962    ----------------------------------
1963
1964    function Has_New_Controlled_Component (E : Entity_Id) return Boolean is
1965       Comp : Entity_Id;
1966
1967    begin
1968       if not Is_Tagged_Type (E) then
1969          return Has_Controlled_Component (E);
1970       elsif not Is_Derived_Type (E) then
1971          return Has_Controlled_Component (E);
1972       end if;
1973
1974       Comp := First_Component (E);
1975       while Present (Comp) loop
1976
1977          if Chars (Comp) = Name_uParent then
1978             null;
1979
1980          elsif Scope (Original_Record_Component (Comp)) = E
1981            and then Controlled_Type (Etype (Comp))
1982          then
1983             return True;
1984          end if;
1985
1986          Next_Component (Comp);
1987       end loop;
1988
1989       return False;
1990    end Has_New_Controlled_Component;
1991
1992    --------------------------
1993    -- In_Finalization_Root --
1994    --------------------------
1995
1996    --  It would seem simpler to test Scope (RTE (RE_Root_Controlled)) but
1997    --  the purpose of this function is to avoid a circular call to Rtsfind
1998    --  which would been caused by such a test.
1999
2000    function In_Finalization_Root (E : Entity_Id) return Boolean is
2001       S : constant Entity_Id := Scope (E);
2002
2003    begin
2004       return Chars (Scope (S))     = Name_System
2005         and then Chars (S)         = Name_Finalization_Root
2006         and then Scope (Scope (S)) = Standard_Standard;
2007    end  In_Finalization_Root;
2008
2009    ------------------------------------
2010    -- Insert_Actions_In_Scope_Around --
2011    ------------------------------------
2012
2013    procedure Insert_Actions_In_Scope_Around (N : Node_Id) is
2014       SE : Scope_Stack_Entry renames Scope_Stack.Table (Scope_Stack.Last);
2015
2016    begin
2017       if Present (SE.Actions_To_Be_Wrapped_Before) then
2018          Insert_List_Before (N, SE.Actions_To_Be_Wrapped_Before);
2019          SE.Actions_To_Be_Wrapped_Before := No_List;
2020       end if;
2021
2022       if Present (SE.Actions_To_Be_Wrapped_After) then
2023          Insert_List_After (N, SE.Actions_To_Be_Wrapped_After);
2024          SE.Actions_To_Be_Wrapped_After := No_List;
2025       end if;
2026    end Insert_Actions_In_Scope_Around;
2027
2028    -----------------------
2029    -- Make_Adjust_Call --
2030    -----------------------
2031
2032    function Make_Adjust_Call
2033      (Ref          : Node_Id;
2034       Typ          : Entity_Id;
2035       Flist_Ref    : Node_Id;
2036       With_Attach  : Node_Id)
2037       return         List_Id
2038    is
2039       Loc    : constant Source_Ptr := Sloc (Ref);
2040       Res    : constant List_Id    := New_List;
2041       Utyp   : Entity_Id;
2042       Proc   : Entity_Id;
2043       Cref   : Node_Id := Ref;
2044       Cref2  : Node_Id;
2045       Attach : Node_Id := With_Attach;
2046
2047    begin
2048       if Is_Class_Wide_Type (Typ) then
2049          Utyp := Underlying_Type (Base_Type (Root_Type (Typ)));
2050       else
2051          Utyp := Underlying_Type (Base_Type (Typ));
2052       end if;
2053
2054       Set_Assignment_OK (Cref);
2055
2056       --  Deal with non-tagged derivation of private views
2057
2058       if Is_Untagged_Derivation (Typ) then
2059          Utyp := Underlying_Type (Root_Type (Base_Type (Typ)));
2060          Cref := Unchecked_Convert_To (Utyp, Cref);
2061          Set_Assignment_OK (Cref);
2062          --  To prevent problems with UC see 1.156 RH ???
2063       end if;
2064
2065       --  If the underlying_type is a subtype, we are dealing with
2066       --  the completion of a private type. We need to access
2067       --  the base type and generate a conversion to it.
2068
2069       if Utyp /= Base_Type (Utyp) then
2070          pragma Assert (Is_Private_Type (Typ));
2071          Utyp := Base_Type (Utyp);
2072          Cref := Unchecked_Convert_To (Utyp, Cref);
2073       end if;
2074
2075       --  If the object is unanalyzed, set its expected type for use
2076       --  in Convert_View in case an additional conversion is needed.
2077
2078       if No (Etype (Cref))
2079         and then Nkind (Cref) /= N_Unchecked_Type_Conversion
2080       then
2081          Set_Etype (Cref, Typ);
2082       end if;
2083
2084       --  We do not need to attach to one of the Global Final Lists
2085       --  the objects whose type is Finalize_Storage_Only
2086
2087       if Finalize_Storage_Only (Typ)
2088         and then (Global_Flist_Ref (Flist_Ref)
2089           or else Entity (Constant_Value (RTE (RE_Garbage_Collected)))
2090                   = Standard_True)
2091       then
2092          Attach := Make_Integer_Literal (Loc, 0);
2093       end if;
2094
2095       --  Generate:
2096       --    Deep_Adjust (Flist_Ref, Ref, With_Attach);
2097
2098       if Has_Controlled_Component (Utyp)
2099         or else Is_Class_Wide_Type (Typ)
2100       then
2101          if Is_Tagged_Type (Utyp) then
2102             Proc := Find_Prim_Op (Utyp, TSS_Deep_Adjust);
2103
2104          else
2105             Proc := TSS (Utyp, TSS_Deep_Adjust);
2106          end if;
2107
2108          Cref := Convert_View (Proc, Cref, 2);
2109
2110          Append_To (Res,
2111            Make_Procedure_Call_Statement (Loc,
2112              Name => New_Reference_To (Proc, Loc),
2113              Parameter_Associations =>
2114                New_List (Flist_Ref, Cref, Attach)));
2115
2116       --  Generate:
2117       --    if With_Attach then
2118       --       Attach_To_Final_List (Ref, Flist_Ref);
2119       --    end if;
2120       --    Adjust (Ref);
2121
2122       else -- Is_Controlled (Utyp)
2123
2124          Proc  := Find_Prim_Op (Utyp, Name_Of (Adjust_Case));
2125          Cref  := Convert_View (Proc, Cref);
2126          Cref2 := New_Copy_Tree (Cref);
2127
2128          Append_To (Res,
2129            Make_Procedure_Call_Statement (Loc,
2130            Name => New_Reference_To (Proc, Loc),
2131            Parameter_Associations => New_List (Cref2)));
2132
2133          Append_To (Res, Make_Attach_Call (Cref, Flist_Ref, Attach));
2134       end if;
2135
2136       return Res;
2137    end Make_Adjust_Call;
2138
2139    ----------------------
2140    -- Make_Attach_Call --
2141    ----------------------
2142
2143    --  Generate:
2144    --    System.FI.Attach_To_Final_List (Flist, Ref, Nb_Link)
2145
2146    function Make_Attach_Call
2147      (Obj_Ref      : Node_Id;
2148       Flist_Ref    : Node_Id;
2149       With_Attach  : Node_Id)
2150       return Node_Id
2151    is
2152       Loc : constant Source_Ptr := Sloc (Obj_Ref);
2153
2154    begin
2155       --  Optimization: If the number of links is statically '0', don't
2156       --  call the attach_proc.
2157
2158       if Nkind (With_Attach) = N_Integer_Literal
2159         and then Intval (With_Attach) = Uint_0
2160       then
2161          return Make_Null_Statement (Loc);
2162       end if;
2163
2164       return
2165         Make_Procedure_Call_Statement (Loc,
2166           Name => New_Reference_To (RTE (RE_Attach_To_Final_List), Loc),
2167           Parameter_Associations => New_List (
2168             Flist_Ref,
2169             OK_Convert_To (RTE (RE_Finalizable), Obj_Ref),
2170             With_Attach));
2171    end Make_Attach_Call;
2172
2173    ----------------
2174    -- Make_Clean --
2175    ----------------
2176
2177    function Make_Clean
2178      (N                          : Node_Id;
2179       Clean                      : Entity_Id;
2180       Mark                       : Entity_Id;
2181       Flist                      : Entity_Id;
2182       Is_Task                    : Boolean;
2183       Is_Master                  : Boolean;
2184       Is_Protected_Subprogram    : Boolean;
2185       Is_Task_Allocation_Block   : Boolean;
2186       Is_Asynchronous_Call_Block : Boolean)
2187       return      Node_Id
2188    is
2189       Loc  : constant Source_Ptr := Sloc (Clean);
2190       Stmt : constant List_Id    := New_List;
2191
2192       Sbody        : Node_Id;
2193       Spec         : Node_Id;
2194       Name         : Node_Id;
2195       Param        : Node_Id;
2196       Unlock       : Node_Id;
2197       Param_Type   : Entity_Id;
2198       Pid          : Entity_Id := Empty;
2199       Cancel_Param : Entity_Id;
2200
2201    begin
2202       if Is_Task then
2203          if Restricted_Profile then
2204             Append_To
2205               (Stmt, Build_Runtime_Call (Loc, RE_Complete_Restricted_Task));
2206          else
2207             Append_To (Stmt, Build_Runtime_Call (Loc, RE_Complete_Task));
2208          end if;
2209
2210       elsif Is_Master then
2211          if Restrictions (No_Task_Hierarchy) = False then
2212             Append_To (Stmt, Build_Runtime_Call (Loc, RE_Complete_Master));
2213          end if;
2214
2215       elsif Is_Protected_Subprogram then
2216
2217          --  Add statements to the cleanup handler of the (ordinary)
2218          --  subprogram expanded to implement a protected subprogram,
2219          --  unlocking the protected object parameter and undeferring abortion.
2220          --  If this is a protected procedure, and the object contains
2221          --  entries, this also calls the entry service routine.
2222
2223          --  NOTE: This cleanup handler references _object, a parameter
2224          --        to the procedure.
2225
2226          --  Find the _object parameter representing the protected object.
2227
2228          Spec := Parent (Corresponding_Spec (N));
2229
2230          Param := First (Parameter_Specifications (Spec));
2231          loop
2232             Param_Type := Etype (Parameter_Type (Param));
2233
2234             if Ekind (Param_Type) = E_Record_Type then
2235                Pid := Corresponding_Concurrent_Type (Param_Type);
2236             end if;
2237
2238             exit when not Present (Param) or else Present (Pid);
2239             Next (Param);
2240          end loop;
2241
2242          pragma Assert (Present (Param));
2243
2244          --  If the associated protected object declares entries,
2245          --  a protected procedure has to service entry queues.
2246          --  In this case, add
2247
2248          --  Service_Entries (_object._object'Access);
2249
2250          --  _object is the record used to implement the protected object.
2251          --  It is a parameter to the protected subprogram.
2252
2253          if Nkind (Specification (N)) = N_Procedure_Specification
2254            and then Has_Entries (Pid)
2255          then
2256             if Abort_Allowed
2257               or else Restrictions (No_Entry_Queue) = False
2258               or else Number_Entries (Pid) > 1
2259             then
2260                Name := New_Reference_To (RTE (RE_Service_Entries), Loc);
2261             else
2262                Name := New_Reference_To (RTE (RE_Service_Entry), Loc);
2263             end if;
2264
2265             Append_To (Stmt,
2266               Make_Procedure_Call_Statement (Loc,
2267                 Name => Name,
2268                 Parameter_Associations => New_List (
2269                   Make_Attribute_Reference (Loc,
2270                     Prefix =>
2271                       Make_Selected_Component (Loc,
2272                         Prefix => New_Reference_To (
2273                           Defining_Identifier (Param), Loc),
2274                         Selector_Name =>
2275                           Make_Identifier (Loc, Name_uObject)),
2276                     Attribute_Name => Name_Unchecked_Access))));
2277          end if;
2278
2279          --  Unlock (_object._object'Access);
2280
2281          --  _object is the record used to implement the protected object.
2282          --  It is a parameter to the protected subprogram.
2283
2284          --  If the protected object is controlled (i.e it has entries or
2285          --  needs finalization for interrupt handling), call Unlock_Entries,
2286          --  except if the protected object follows the ravenscar profile, in
2287          --  which case call Unlock_Entry, otherwise call the simplified
2288          --  version, Unlock.
2289
2290          if Has_Entries (Pid)
2291            or else Has_Interrupt_Handler (Pid)
2292            or else (Has_Attach_Handler (Pid) and then not Restricted_Profile)
2293          then
2294             if Abort_Allowed
2295               or else Restrictions (No_Entry_Queue) = False
2296               or else Number_Entries (Pid) > 1
2297             then
2298                Unlock := New_Reference_To (RTE (RE_Unlock_Entries), Loc);
2299             else
2300                Unlock := New_Reference_To (RTE (RE_Unlock_Entry), Loc);
2301             end if;
2302
2303          else
2304             Unlock := New_Reference_To (RTE (RE_Unlock), Loc);
2305          end if;
2306
2307          Append_To (Stmt,
2308            Make_Procedure_Call_Statement (Loc,
2309              Name => Unlock,
2310              Parameter_Associations => New_List (
2311                Make_Attribute_Reference (Loc,
2312                  Prefix =>
2313                    Make_Selected_Component (Loc,
2314                      Prefix =>
2315                        New_Reference_To (Defining_Identifier (Param), Loc),
2316                      Selector_Name =>
2317                        Make_Identifier (Loc, Name_uObject)),
2318                  Attribute_Name => Name_Unchecked_Access))));
2319
2320          if Abort_Allowed then
2321             --  Abort_Undefer;
2322
2323             Append_To (Stmt,
2324               Make_Procedure_Call_Statement (Loc,
2325                 Name =>
2326                   New_Reference_To (
2327                     RTE (RE_Abort_Undefer), Loc),
2328                 Parameter_Associations => Empty_List));
2329          end if;
2330
2331       elsif Is_Task_Allocation_Block then
2332
2333          --  Add a call to Expunge_Unactivated_Tasks to the cleanup
2334          --  handler of a block created for the dynamic allocation of
2335          --  tasks:
2336
2337          --  Expunge_Unactivated_Tasks (_chain);
2338
2339          --  where _chain is the list of tasks created by the allocator
2340          --  but not yet activated. This list will be empty unless
2341          --  the block completes abnormally.
2342
2343          --  This only applies to dynamically allocated tasks;
2344          --  other unactivated tasks are completed by Complete_Task or
2345          --  Complete_Master.
2346
2347          --  NOTE: This cleanup handler references _chain, a local
2348          --        object.
2349
2350          Append_To (Stmt,
2351            Make_Procedure_Call_Statement (Loc,
2352              Name =>
2353                New_Reference_To (
2354                  RTE (RE_Expunge_Unactivated_Tasks), Loc),
2355              Parameter_Associations => New_List (
2356                New_Reference_To (Activation_Chain_Entity (N), Loc))));
2357
2358       elsif Is_Asynchronous_Call_Block then
2359
2360          --  Add a call to attempt to cancel the asynchronous entry call
2361          --  whenever the block containing the abortable part is exited.
2362
2363          --  NOTE: This cleanup handler references C, a local object
2364
2365          --  Get the argument to the Cancel procedure
2366          Cancel_Param := Entry_Cancel_Parameter (Entity (Identifier (N)));
2367
2368          --  If it is of type Communication_Block, this must be a
2369          --  protected entry call.
2370
2371          if Is_RTE (Etype (Cancel_Param), RE_Communication_Block) then
2372
2373             Append_To (Stmt,
2374
2375             --  if Enqueued (Cancel_Parameter) then
2376
2377               Make_Implicit_If_Statement (Clean,
2378                 Condition => Make_Function_Call (Loc,
2379                   Name => New_Reference_To (
2380                     RTE (RE_Enqueued), Loc),
2381                   Parameter_Associations => New_List (
2382                     New_Reference_To (Cancel_Param, Loc))),
2383                 Then_Statements => New_List (
2384
2385             --  Cancel_Protected_Entry_Call (Cancel_Param);
2386
2387                   Make_Procedure_Call_Statement (Loc,
2388                     Name => New_Reference_To (
2389                       RTE (RE_Cancel_Protected_Entry_Call), Loc),
2390                     Parameter_Associations => New_List (
2391                       New_Reference_To (Cancel_Param, Loc))))));
2392
2393          --  Asynchronous delay
2394
2395          elsif Is_RTE (Etype (Cancel_Param), RE_Delay_Block) then
2396             Append_To (Stmt,
2397               Make_Procedure_Call_Statement (Loc,
2398                 Name => New_Reference_To (RTE (RE_Cancel_Async_Delay), Loc),
2399                 Parameter_Associations => New_List (
2400                   Make_Attribute_Reference (Loc,
2401                     Prefix => New_Reference_To (Cancel_Param, Loc),
2402                     Attribute_Name => Name_Unchecked_Access))));
2403
2404          --  Task entry call
2405
2406          else
2407             --  Append call to Cancel_Task_Entry_Call (C);
2408
2409             Append_To (Stmt,
2410               Make_Procedure_Call_Statement (Loc,
2411                 Name => New_Reference_To (
2412                   RTE (RE_Cancel_Task_Entry_Call),
2413                   Loc),
2414                 Parameter_Associations => New_List (
2415                   New_Reference_To (Cancel_Param, Loc))));
2416
2417          end if;
2418       end if;
2419
2420       if Present (Flist) then
2421          Append_To (Stmt,
2422            Make_Procedure_Call_Statement (Loc,
2423              Name => New_Reference_To (RTE (RE_Finalize_List), Loc),
2424              Parameter_Associations => New_List (
2425                     New_Reference_To (Flist, Loc))));
2426       end if;
2427
2428       if Present (Mark) then
2429          Append_To (Stmt,
2430            Make_Procedure_Call_Statement (Loc,
2431              Name => New_Reference_To (RTE (RE_SS_Release), Loc),
2432              Parameter_Associations => New_List (
2433                     New_Reference_To (Mark, Loc))));
2434       end if;
2435
2436       Sbody :=
2437         Make_Subprogram_Body (Loc,
2438           Specification =>
2439             Make_Procedure_Specification (Loc,
2440               Defining_Unit_Name => Clean),
2441
2442           Declarations  => New_List,
2443
2444           Handled_Statement_Sequence =>
2445             Make_Handled_Sequence_Of_Statements (Loc,
2446               Statements => Stmt));
2447
2448       if Present (Flist) or else Is_Task or else Is_Master then
2449          Wrap_Cleanup_Procedure (Sbody);
2450       end if;
2451
2452       --  We do not want debug information for _Clean routines,
2453       --  since it just confuses the debugging operation unless
2454       --  we are debugging generated code.
2455
2456       if not Debug_Generated_Code then
2457          Set_Debug_Info_Off (Clean, True);
2458       end if;
2459
2460       return Sbody;
2461    end Make_Clean;
2462
2463    --------------------------
2464    -- Make_Deep_Array_Body --
2465    --------------------------
2466
2467    --  Array components are initialized and adjusted in the normal order
2468    --  and finalized in the reverse order. Exceptions are handled and
2469    --  Program_Error is re-raise in the Adjust and Finalize case
2470    --  (RM 7.6.1(12)). Generate the following code :
2471    --
2472    --  procedure Deep_<P>   --  with <P> being Initialize or Adjust or Finalize
2473    --   (L : in out Finalizable_Ptr;
2474    --    V : in out Typ)
2475    --  is
2476    --  begin
2477    --     for J1 in             Typ'First (1) .. Typ'Last (1) loop
2478    --               ^ reverse ^  --  in the finalization case
2479    --        ...
2480    --           for J2 in Typ'First (n) .. Typ'Last (n) loop
2481    --                 Make_<P>_Call (Typ, V (J1, .. , Jn), L, V);
2482    --           end loop;
2483    --        ...
2484    --     end loop;
2485    --  exception                                --  not in the
2486    --     when others => raise Program_Error;   --     Initialize case
2487    --  end Deep_<P>;
2488
2489    function Make_Deep_Array_Body
2490      (Prim : Final_Primitives;
2491       Typ  : Entity_Id)
2492       return List_Id
2493    is
2494       Loc : constant Source_Ptr := Sloc (Typ);
2495
2496       Index_List : constant List_Id := New_List;
2497       --  Stores the list of references to the indexes (one per dimension)
2498
2499       function One_Component return List_Id;
2500       --  Create one statement to initialize/adjust/finalize one array
2501       --  component, designated by a full set of indices.
2502
2503       function One_Dimension (N : Int) return List_Id;
2504       --  Create loop to deal with one dimension of the array. The single
2505       --  statement in the body of the loop initializes the inner dimensions if
2506       --  any, or else a single component.
2507
2508       -------------------
2509       -- One_Component --
2510       -------------------
2511
2512       function One_Component return List_Id is
2513          Comp_Typ : constant Entity_Id := Component_Type (Typ);
2514          Comp_Ref : constant Node_Id :=
2515                       Make_Indexed_Component (Loc,
2516                         Prefix      => Make_Identifier (Loc, Name_V),
2517                         Expressions => Index_List);
2518
2519       begin
2520          --  Set the etype of the component Reference, which is used to
2521          --  determine whether a conversion to a parent type is needed.
2522
2523          Set_Etype (Comp_Ref, Comp_Typ);
2524
2525          case Prim is
2526             when Initialize_Case =>
2527                return Make_Init_Call (Comp_Ref, Comp_Typ,
2528                         Make_Identifier (Loc, Name_L),
2529                         Make_Identifier (Loc, Name_B));
2530
2531             when Adjust_Case =>
2532                return Make_Adjust_Call (Comp_Ref, Comp_Typ,
2533                         Make_Identifier (Loc, Name_L),
2534                         Make_Identifier (Loc, Name_B));
2535
2536             when Finalize_Case =>
2537                return Make_Final_Call (Comp_Ref, Comp_Typ,
2538                         Make_Identifier (Loc, Name_B));
2539          end case;
2540       end One_Component;
2541
2542       -------------------
2543       -- One_Dimension --
2544       -------------------
2545
2546       function One_Dimension (N : Int) return List_Id is
2547          Index : Entity_Id;
2548
2549       begin
2550          if N > Number_Dimensions (Typ) then
2551             return One_Component;
2552
2553          else
2554             Index :=
2555               Make_Defining_Identifier (Loc, New_External_Name ('J', N));
2556
2557             Append_To (Index_List, New_Reference_To (Index, Loc));
2558
2559             return New_List (
2560               Make_Implicit_Loop_Statement (Typ,
2561                 Identifier => Empty,
2562                 Iteration_Scheme =>
2563                   Make_Iteration_Scheme (Loc,
2564                     Loop_Parameter_Specification =>
2565                       Make_Loop_Parameter_Specification (Loc,
2566                         Defining_Identifier => Index,
2567                         Discrete_Subtype_Definition =>
2568                           Make_Attribute_Reference (Loc,
2569                             Prefix => Make_Identifier (Loc, Name_V),
2570                             Attribute_Name  => Name_Range,
2571                             Expressions => New_List (
2572                               Make_Integer_Literal (Loc, N))),
2573                         Reverse_Present => Prim = Finalize_Case)),
2574                 Statements => One_Dimension (N + 1)));
2575          end if;
2576       end One_Dimension;
2577
2578    --  Start of processing for Make_Deep_Array_Body
2579
2580    begin
2581       return One_Dimension (1);
2582    end Make_Deep_Array_Body;
2583
2584    --------------------
2585    -- Make_Deep_Proc --
2586    --------------------
2587
2588    --  Generate:
2589    --    procedure DEEP_<prim>
2590    --      (L : IN OUT Finalizable_Ptr;    -- not for Finalize
2591    --       V : IN OUT <typ>;
2592    --       B : IN Short_Short_Integer) is
2593    --    begin
2594    --       <stmts>;
2595    --    exception                   --  Finalize and Adjust Cases only
2596    --       raise Program_Error;     --  idem
2597    --    end DEEP_<prim>;
2598
2599    function Make_Deep_Proc
2600      (Prim  : Final_Primitives;
2601       Typ   : Entity_Id;
2602       Stmts : List_Id)
2603       return Entity_Id
2604    is
2605       Loc       : constant Source_Ptr := Sloc (Typ);
2606       Formals   : List_Id;
2607       Proc_Name : Entity_Id;
2608       Handler   : List_Id := No_List;
2609       Type_B    : Entity_Id;
2610
2611    begin
2612       if Prim = Finalize_Case then
2613          Formals := New_List;
2614          Type_B := Standard_Boolean;
2615
2616       else
2617          Formals := New_List (
2618            Make_Parameter_Specification (Loc,
2619              Defining_Identifier => Make_Defining_Identifier (Loc, Name_L),
2620              In_Present          => True,
2621              Out_Present         => True,
2622              Parameter_Type      =>
2623                New_Reference_To (RTE (RE_Finalizable_Ptr), Loc)));
2624          Type_B := Standard_Short_Short_Integer;
2625       end if;
2626
2627       Append_To (Formals,
2628         Make_Parameter_Specification (Loc,
2629           Defining_Identifier => Make_Defining_Identifier (Loc, Name_V),
2630           In_Present          => True,
2631           Out_Present         => True,
2632           Parameter_Type      => New_Reference_To (Typ, Loc)));
2633
2634       Append_To (Formals,
2635         Make_Parameter_Specification (Loc,
2636           Defining_Identifier => Make_Defining_Identifier (Loc, Name_B),
2637           Parameter_Type      => New_Reference_To (Type_B, Loc)));
2638
2639       if Prim = Finalize_Case or else Prim = Adjust_Case then
2640          Handler := New_List (
2641            Make_Exception_Handler (Loc,
2642              Exception_Choices => New_List (Make_Others_Choice (Loc)),
2643              Statements        => New_List (
2644                Make_Raise_Program_Error (Loc,
2645                  Reason => PE_Finalize_Raised_Exception))));
2646       end if;
2647
2648       Proc_Name :=
2649         Make_Defining_Identifier (Loc,
2650           Chars => Make_TSS_Name (Typ, Deep_Name_Of (Prim)));
2651
2652       Discard_Node (
2653         Make_Subprogram_Body (Loc,
2654           Specification =>
2655             Make_Procedure_Specification (Loc,
2656               Defining_Unit_Name       => Proc_Name,
2657               Parameter_Specifications => Formals),
2658
2659           Declarations =>  Empty_List,
2660           Handled_Statement_Sequence =>
2661             Make_Handled_Sequence_Of_Statements (Loc,
2662               Statements         => Stmts,
2663               Exception_Handlers => Handler)));
2664
2665       return Proc_Name;
2666    end Make_Deep_Proc;
2667
2668    ---------------------------
2669    -- Make_Deep_Record_Body --
2670    ---------------------------
2671
2672    --  The Deep procedures call the appropriate Controlling proc on the
2673    --  the controller component. In the init case, it also attach the
2674    --  controller to the current finalization list.
2675
2676    function Make_Deep_Record_Body
2677      (Prim : Final_Primitives;
2678       Typ  : Entity_Id)
2679       return List_Id
2680    is
2681       Loc            : constant Source_Ptr := Sloc (Typ);
2682       Controller_Typ : Entity_Id;
2683       Obj_Ref        : constant Node_Id := Make_Identifier (Loc, Name_V);
2684       Controller_Ref : constant Node_Id :=
2685                          Make_Selected_Component (Loc,
2686                            Prefix        => Obj_Ref,
2687                            Selector_Name =>
2688                              Make_Identifier (Loc, Name_uController));
2689       Res            : constant List_Id := New_List;
2690
2691    begin
2692       if Is_Return_By_Reference_Type (Typ) then
2693          Controller_Typ := RTE (RE_Limited_Record_Controller);
2694       else
2695          Controller_Typ := RTE (RE_Record_Controller);
2696       end if;
2697
2698       case Prim is
2699          when Initialize_Case =>
2700             Append_List_To (Res,
2701               Make_Init_Call (
2702                 Ref          => Controller_Ref,
2703                 Typ          => Controller_Typ,
2704                 Flist_Ref    => Make_Identifier (Loc, Name_L),
2705                 With_Attach  => Make_Identifier (Loc, Name_B)));
2706
2707             --  When the type is also a controlled type by itself,
2708             --  Initialize it and attach it to the finalization chain
2709
2710             if Is_Controlled (Typ) then
2711                Append_To (Res,
2712                  Make_Procedure_Call_Statement (Loc,
2713                    Name => New_Reference_To (
2714                      Find_Prim_Op (Typ, Name_Of (Prim)), Loc),
2715                    Parameter_Associations =>
2716                      New_List (New_Copy_Tree (Obj_Ref))));
2717
2718                Append_To (Res, Make_Attach_Call (
2719                  Obj_Ref      => New_Copy_Tree (Obj_Ref),
2720                  Flist_Ref    => Make_Identifier (Loc, Name_L),
2721                  With_Attach => Make_Identifier (Loc, Name_B)));
2722             end if;
2723
2724          when Adjust_Case =>
2725             Append_List_To (Res,
2726               Make_Adjust_Call (Controller_Ref, Controller_Typ,
2727                 Make_Identifier (Loc, Name_L),
2728                 Make_Identifier (Loc, Name_B)));
2729
2730             --  When the type is also a controlled type by itself,
2731             --  Adjust it it and attach it to the finalization chain
2732
2733             if Is_Controlled (Typ) then
2734                Append_To (Res,
2735                  Make_Procedure_Call_Statement (Loc,
2736                    Name => New_Reference_To (
2737                      Find_Prim_Op (Typ, Name_Of (Prim)), Loc),
2738                    Parameter_Associations =>
2739                      New_List (New_Copy_Tree (Obj_Ref))));
2740
2741                Append_To (Res, Make_Attach_Call (
2742                  Obj_Ref      => New_Copy_Tree (Obj_Ref),
2743                  Flist_Ref    => Make_Identifier (Loc, Name_L),
2744                  With_Attach => Make_Identifier (Loc, Name_B)));
2745             end if;
2746
2747          when Finalize_Case =>
2748             if Is_Controlled (Typ) then
2749                Append_To (Res,
2750                  Make_Implicit_If_Statement (Obj_Ref,
2751                    Condition => Make_Identifier (Loc, Name_B),
2752                    Then_Statements => New_List (
2753                      Make_Procedure_Call_Statement (Loc,
2754                        Name => New_Reference_To (RTE (RE_Finalize_One), Loc),
2755                        Parameter_Associations => New_List (
2756                          OK_Convert_To (RTE (RE_Finalizable),
2757                            New_Copy_Tree (Obj_Ref))))),
2758
2759                    Else_Statements => New_List (
2760                      Make_Procedure_Call_Statement (Loc,
2761                        Name => New_Reference_To (
2762                          Find_Prim_Op (Typ, Name_Of (Prim)), Loc),
2763                        Parameter_Associations =>
2764                         New_List (New_Copy_Tree (Obj_Ref))))));
2765             end if;
2766
2767             Append_List_To (Res,
2768               Make_Final_Call (Controller_Ref, Controller_Typ,
2769                 Make_Identifier (Loc, Name_B)));
2770       end case;
2771       return Res;
2772    end Make_Deep_Record_Body;
2773
2774    ----------------------
2775    -- Make_Final_Call --
2776    ----------------------
2777
2778    function Make_Final_Call
2779      (Ref         : Node_Id;
2780       Typ         : Entity_Id;
2781       With_Detach : Node_Id)
2782       return        List_Id
2783    is
2784       Loc   : constant Source_Ptr := Sloc (Ref);
2785       Res   : constant List_Id    := New_List;
2786       Cref  : Node_Id;
2787       Cref2 : Node_Id;
2788       Proc  : Entity_Id;
2789       Utyp  : Entity_Id;
2790
2791    begin
2792       if Is_Class_Wide_Type (Typ) then
2793          Utyp := Root_Type (Typ);
2794          Cref := Ref;
2795
2796       elsif Is_Concurrent_Type (Typ) then
2797          Utyp := Corresponding_Record_Type (Typ);
2798          Cref := Convert_Concurrent (Ref, Typ);
2799
2800       elsif Is_Private_Type (Typ)
2801         and then Present (Full_View (Typ))
2802         and then Is_Concurrent_Type (Full_View (Typ))
2803       then
2804          Utyp := Corresponding_Record_Type (Full_View (Typ));
2805          Cref := Convert_Concurrent (Ref, Full_View (Typ));
2806       else
2807          Utyp := Typ;
2808          Cref := Ref;
2809       end if;
2810
2811       Utyp := Underlying_Type (Base_Type (Utyp));
2812       Set_Assignment_OK (Cref);
2813
2814       --  Deal with non-tagged derivation of private views
2815
2816       if Is_Untagged_Derivation (Typ) then
2817          Utyp := Underlying_Type (Root_Type (Base_Type (Typ)));
2818          Cref := Unchecked_Convert_To (Utyp, Cref);
2819          Set_Assignment_OK (Cref);
2820          --  To prevent problems with UC see 1.156 RH ???
2821       end if;
2822
2823       --  If the underlying_type is a subtype, we are dealing with
2824       --  the completion of a private type. We need to access
2825       --  the base type and generate a conversion to it.
2826
2827       if Utyp /= Base_Type (Utyp) then
2828          pragma Assert (Is_Private_Type (Typ));
2829          Utyp := Base_Type (Utyp);
2830          Cref := Unchecked_Convert_To (Utyp, Cref);
2831       end if;
2832
2833       --  Generate:
2834       --    Deep_Finalize (Ref, With_Detach);
2835
2836       if Has_Controlled_Component (Utyp)
2837         or else Is_Class_Wide_Type (Typ)
2838       then
2839          if Is_Tagged_Type (Utyp) then
2840             Proc := Find_Prim_Op (Utyp, TSS_Deep_Finalize);
2841          else
2842             Proc := TSS (Utyp, TSS_Deep_Finalize);
2843          end if;
2844
2845          Cref := Convert_View (Proc, Cref);
2846
2847          Append_To (Res,
2848            Make_Procedure_Call_Statement (Loc,
2849              Name => New_Reference_To (Proc, Loc),
2850              Parameter_Associations =>
2851                New_List (Cref, With_Detach)));
2852
2853       --  Generate:
2854       --    if With_Detach then
2855       --       Finalize_One (Ref);
2856       --    else
2857       --       Finalize (Ref);
2858       --    end if;
2859
2860       else
2861          Proc := Find_Prim_Op (Utyp, Name_Of (Finalize_Case));
2862
2863          if Chars (With_Detach) = Chars (Standard_True) then
2864             Append_To (Res,
2865               Make_Procedure_Call_Statement (Loc,
2866                 Name => New_Reference_To (RTE (RE_Finalize_One), Loc),
2867                 Parameter_Associations => New_List (
2868                   OK_Convert_To (RTE (RE_Finalizable), Cref))));
2869
2870          elsif Chars (With_Detach) = Chars (Standard_False) then
2871             Append_To (Res,
2872               Make_Procedure_Call_Statement (Loc,
2873                 Name => New_Reference_To (Proc, Loc),
2874                 Parameter_Associations =>
2875                   New_List (Convert_View (Proc, Cref))));
2876
2877          else
2878             Cref2 := New_Copy_Tree (Cref);
2879             Append_To (Res,
2880               Make_Implicit_If_Statement (Ref,
2881                 Condition => With_Detach,
2882                 Then_Statements => New_List (
2883                   Make_Procedure_Call_Statement (Loc,
2884                     Name => New_Reference_To (RTE (RE_Finalize_One), Loc),
2885                     Parameter_Associations => New_List (
2886                       OK_Convert_To (RTE (RE_Finalizable), Cref)))),
2887
2888                 Else_Statements => New_List (
2889                   Make_Procedure_Call_Statement (Loc,
2890                     Name => New_Reference_To (Proc, Loc),
2891                     Parameter_Associations =>
2892                       New_List (Convert_View (Proc, Cref2))))));
2893          end if;
2894       end if;
2895
2896       return Res;
2897    end Make_Final_Call;
2898
2899    --------------------
2900    -- Make_Init_Call --
2901    --------------------
2902
2903    function Make_Init_Call
2904      (Ref          : Node_Id;
2905       Typ          : Entity_Id;
2906       Flist_Ref    : Node_Id;
2907       With_Attach  : Node_Id)
2908       return         List_Id
2909    is
2910       Loc     : constant Source_Ptr := Sloc (Ref);
2911       Is_Conc : Boolean;
2912       Res     : constant List_Id := New_List;
2913       Proc    : Entity_Id;
2914       Utyp    : Entity_Id;
2915       Cref    : Node_Id;
2916       Cref2   : Node_Id;
2917       Attach  : Node_Id := With_Attach;
2918
2919    begin
2920       if Is_Concurrent_Type (Typ) then
2921          Is_Conc := True;
2922          Utyp    := Corresponding_Record_Type (Typ);
2923          Cref    := Convert_Concurrent (Ref, Typ);
2924
2925       elsif Is_Private_Type (Typ)
2926         and then Present (Full_View (Typ))
2927         and then Is_Concurrent_Type (Underlying_Type (Typ))
2928       then
2929          Is_Conc := True;
2930          Utyp    := Corresponding_Record_Type (Underlying_Type (Typ));
2931          Cref    := Convert_Concurrent (Ref, Underlying_Type (Typ));
2932
2933       else
2934          Is_Conc := False;
2935          Utyp    := Typ;
2936          Cref    := Ref;
2937       end if;
2938
2939       Utyp := Underlying_Type (Base_Type (Utyp));
2940
2941       Set_Assignment_OK (Cref);
2942
2943       --  Deal with non-tagged derivation of private views
2944
2945       if Is_Untagged_Derivation (Typ)
2946         and then not Is_Conc
2947       then
2948          Utyp := Underlying_Type (Root_Type (Base_Type (Typ)));
2949          Cref := Unchecked_Convert_To (Utyp, Cref);
2950          Set_Assignment_OK (Cref);
2951          --  To prevent problems with UC see 1.156 RH ???
2952       end if;
2953
2954       --  If the underlying_type is a subtype, we are dealing with
2955       --  the completion of a private type. We need to access
2956       --  the base type and generate a conversion to it.
2957
2958       if Utyp /= Base_Type (Utyp) then
2959          pragma Assert (Is_Private_Type (Typ));
2960          Utyp := Base_Type (Utyp);
2961          Cref := Unchecked_Convert_To (Utyp, Cref);
2962       end if;
2963
2964       --  We do not need to attach to one of the Global Final Lists
2965       --  the objects whose type is Finalize_Storage_Only
2966
2967       if Finalize_Storage_Only (Typ)
2968         and then (Global_Flist_Ref (Flist_Ref)
2969           or else Entity (Constant_Value (RTE (RE_Garbage_Collected)))
2970                   = Standard_True)
2971       then
2972          Attach := Make_Integer_Literal (Loc, 0);
2973       end if;
2974
2975       --  Generate:
2976       --    Deep_Initialize (Ref, Flist_Ref);
2977
2978       if Has_Controlled_Component (Utyp) then
2979          Proc := TSS (Utyp, Deep_Name_Of (Initialize_Case));
2980
2981          Cref := Convert_View (Proc, Cref, 2);
2982
2983          Append_To (Res,
2984            Make_Procedure_Call_Statement (Loc,
2985              Name => New_Reference_To (Proc, Loc),
2986              Parameter_Associations => New_List (
2987                Node1 => Flist_Ref,
2988                Node2 => Cref,
2989                Node3 => Attach)));
2990
2991       --  Generate:
2992       --    Attach_To_Final_List (Ref, Flist_Ref);
2993       --    Initialize (Ref);
2994
2995       else -- Is_Controlled (Utyp)
2996          Proc  := Find_Prim_Op (Utyp, Name_Of (Initialize_Case));
2997          Check_Visibly_Controlled (Initialize_Case, Typ, Proc, Cref);
2998
2999          Cref  := Convert_View (Proc, Cref);
3000          Cref2 := New_Copy_Tree (Cref);
3001
3002          Append_To (Res,
3003            Make_Procedure_Call_Statement (Loc,
3004            Name => New_Reference_To (Proc, Loc),
3005            Parameter_Associations => New_List (Cref2)));
3006
3007          Append_To (Res,
3008            Make_Attach_Call (Cref, Flist_Ref, Attach));
3009       end if;
3010
3011       return Res;
3012    end Make_Init_Call;
3013
3014    --------------------------
3015    -- Make_Transient_Block --
3016    --------------------------
3017
3018    --  If finalization is involved, this function just wraps the instruction
3019    --  into a block whose name is the transient block entity, and then
3020    --  Expand_Cleanup_Actions (called on the expansion of the handled
3021    --  sequence of statements will do the necessary expansions for
3022    --  cleanups).
3023
3024    function Make_Transient_Block
3025      (Loc    : Source_Ptr;
3026       Action : Node_Id)
3027       return   Node_Id
3028    is
3029       Flist  : constant Entity_Id := Finalization_Chain_Entity (Current_Scope);
3030       Decls  : constant List_Id   := New_List;
3031       Par    : constant Node_Id   := Parent (Action);
3032       Instrs : constant List_Id   := New_List (Action);
3033       Blk    : Node_Id;
3034
3035    begin
3036       --  Case where only secondary stack use is involved
3037
3038       if Uses_Sec_Stack (Current_Scope)
3039         and then No (Flist)
3040         and then Nkind (Action) /= N_Return_Statement
3041         and then Nkind (Par) /= N_Exception_Handler
3042       then
3043
3044          declare
3045             S  : Entity_Id;
3046             K  : Entity_Kind;
3047          begin
3048             S := Scope (Current_Scope);
3049             loop
3050                K := Ekind (S);
3051
3052                --  At the outer level, no need to release the sec stack
3053
3054                if S = Standard_Standard then
3055                   Set_Uses_Sec_Stack (Current_Scope, False);
3056                   exit;
3057
3058                --  In a function, only release the sec stack if the
3059                --  function does not return on the sec stack otherwise
3060                --  the result may be lost. The caller is responsible for
3061                --  releasing.
3062
3063                elsif K = E_Function then
3064                   Set_Uses_Sec_Stack (Current_Scope, False);
3065
3066                   if not Requires_Transient_Scope (Etype (S)) then
3067                      if not Functions_Return_By_DSP_On_Target then
3068                         Set_Uses_Sec_Stack (S, True);
3069                         Check_Restriction (No_Secondary_Stack, Action);
3070                      end if;
3071                   end if;
3072
3073                   exit;
3074
3075                --  In a loop or entry we should install a block encompassing
3076                --  all the construct. For now just release right away.
3077
3078                elsif K = E_Loop or else K = E_Entry then
3079                   exit;
3080
3081                --  In a procedure or a block, we release on exit of the
3082                --  procedure or block. ??? memory leak can be created by
3083                --  recursive calls.
3084
3085                elsif K = E_Procedure
3086                  or else K = E_Block
3087                then
3088                   if not Functions_Return_By_DSP_On_Target then
3089                      Set_Uses_Sec_Stack (S, True);
3090                      Check_Restriction (No_Secondary_Stack, Action);
3091                   end if;
3092
3093                   Set_Uses_Sec_Stack (Current_Scope, False);
3094                   exit;
3095
3096                else
3097                   S := Scope (S);
3098                end if;
3099             end loop;
3100          end;
3101       end if;
3102
3103       --  Insert actions stuck in the transient scopes as well as all
3104       --  freezing nodes needed by those actions
3105
3106       Insert_Actions_In_Scope_Around (Action);
3107
3108       declare
3109          Last_Inserted : Node_Id := Prev (Action);
3110
3111       begin
3112          if Present (Last_Inserted) then
3113             Freeze_All (First_Entity (Current_Scope), Last_Inserted);
3114          end if;
3115       end;
3116
3117       Blk :=
3118         Make_Block_Statement (Loc,
3119           Identifier => New_Reference_To (Current_Scope, Loc),
3120           Declarations => Decls,
3121           Handled_Statement_Sequence =>
3122             Make_Handled_Sequence_Of_Statements (Loc, Statements => Instrs),
3123           Has_Created_Identifier => True);
3124
3125       --  When the transient scope was established, we pushed the entry for
3126       --  the transient scope onto the scope stack, so that the scope was
3127       --  active for the installation of finalizable entities etc. Now we
3128       --  must remove this entry, since we have constructed a proper block.
3129
3130       Pop_Scope;
3131
3132       return Blk;
3133    end Make_Transient_Block;
3134
3135    ------------------------
3136    -- Node_To_Be_Wrapped --
3137    ------------------------
3138
3139    function Node_To_Be_Wrapped return Node_Id is
3140    begin
3141       return Scope_Stack.Table (Scope_Stack.Last).Node_To_Be_Wrapped;
3142    end Node_To_Be_Wrapped;
3143
3144    ----------------------------
3145    -- Set_Node_To_Be_Wrapped --
3146    ----------------------------
3147
3148    procedure Set_Node_To_Be_Wrapped (N : Node_Id) is
3149    begin
3150       Scope_Stack.Table (Scope_Stack.Last).Node_To_Be_Wrapped := N;
3151    end Set_Node_To_Be_Wrapped;
3152
3153    ----------------------------------
3154    -- Store_After_Actions_In_Scope --
3155    ----------------------------------
3156
3157    procedure Store_After_Actions_In_Scope (L : List_Id) is
3158       SE : Scope_Stack_Entry renames Scope_Stack.Table (Scope_Stack.Last);
3159
3160    begin
3161       if Present (SE.Actions_To_Be_Wrapped_After) then
3162          Insert_List_Before_And_Analyze (
3163           First (SE.Actions_To_Be_Wrapped_After), L);
3164
3165       else
3166          SE.Actions_To_Be_Wrapped_After := L;
3167
3168          if Is_List_Member (SE.Node_To_Be_Wrapped) then
3169             Set_Parent (L, Parent (SE.Node_To_Be_Wrapped));
3170          else
3171             Set_Parent (L, SE.Node_To_Be_Wrapped);
3172          end if;
3173
3174          Analyze_List (L);
3175       end if;
3176    end Store_After_Actions_In_Scope;
3177
3178    -----------------------------------
3179    -- Store_Before_Actions_In_Scope --
3180    -----------------------------------
3181
3182    procedure Store_Before_Actions_In_Scope (L : List_Id) is
3183       SE : Scope_Stack_Entry renames Scope_Stack.Table (Scope_Stack.Last);
3184
3185    begin
3186       if Present (SE.Actions_To_Be_Wrapped_Before) then
3187          Insert_List_After_And_Analyze (
3188            Last (SE.Actions_To_Be_Wrapped_Before), L);
3189
3190       else
3191          SE.Actions_To_Be_Wrapped_Before := L;
3192
3193          if Is_List_Member (SE.Node_To_Be_Wrapped) then
3194             Set_Parent (L, Parent (SE.Node_To_Be_Wrapped));
3195          else
3196             Set_Parent (L, SE.Node_To_Be_Wrapped);
3197          end if;
3198
3199          Analyze_List (L);
3200       end if;
3201    end Store_Before_Actions_In_Scope;
3202
3203    --------------------------------
3204    -- Wrap_Transient_Declaration --
3205    --------------------------------
3206
3207    --  If a transient scope has been established during the processing of the
3208    --  Expression of an Object_Declaration, it is not possible to wrap the
3209    --  declaration into a transient block as usual case, otherwise the object
3210    --  would be itself declared in the wrong scope. Therefore, all entities (if
3211    --  any) defined in the transient block are moved to the proper enclosing
3212    --  scope, furthermore, if they are controlled variables they are finalized
3213    --  right after the declaration. The finalization list of the transient
3214    --  scope is defined as a renaming of the enclosing one so during their
3215    --  initialization they will be attached to the proper finalization
3216    --  list. For instance, the following declaration :
3217
3218    --        X : Typ := F (G (A), G (B));
3219
3220    --  (where G(A) and G(B) return controlled values, expanded as _v1 and _v2)
3221    --  is expanded into :
3222
3223    --    _local_final_list_1 : Finalizable_Ptr;
3224    --    X : Typ := [ complex Expression-Action ];
3225    --    Finalize_One(_v1);
3226    --    Finalize_One (_v2);
3227
3228    procedure Wrap_Transient_Declaration (N : Node_Id) is
3229       S           : Entity_Id;
3230       LC          : Entity_Id := Empty;
3231       Nodes       : List_Id;
3232       Loc         : constant Source_Ptr := Sloc (N);
3233       Enclosing_S : Entity_Id;
3234       Uses_SS     : Boolean;
3235       Next_N      : constant Node_Id := Next (N);
3236
3237    begin
3238       S := Current_Scope;
3239       Enclosing_S := Scope (S);
3240
3241       --  Insert Actions kept in the Scope stack
3242
3243       Insert_Actions_In_Scope_Around (N);
3244
3245       --  If the declaration is consuming some secondary stack, mark the
3246       --  Enclosing scope appropriately.
3247
3248       Uses_SS := Uses_Sec_Stack (S);
3249       Pop_Scope;
3250
3251       --  Create a List controller and rename the final list to be its
3252       --  internal final pointer:
3253       --       Lxxx : Simple_List_Controller;
3254       --       Fxxx : Finalizable_Ptr renames Lxxx.F;
3255
3256       if Present (Finalization_Chain_Entity (S)) then
3257          LC := Make_Defining_Identifier (Loc, New_Internal_Name ('L'));
3258
3259          Nodes := New_List (
3260            Make_Object_Declaration (Loc,
3261              Defining_Identifier => LC,
3262              Object_Definition   =>
3263                New_Reference_To (RTE (RE_Simple_List_Controller), Loc)),
3264
3265            Make_Object_Renaming_Declaration (Loc,
3266              Defining_Identifier => Finalization_Chain_Entity (S),
3267              Subtype_Mark => New_Reference_To (RTE (RE_Finalizable_Ptr), Loc),
3268              Name =>
3269                Make_Selected_Component (Loc,
3270                  Prefix        => New_Reference_To (LC, Loc),
3271                  Selector_Name => Make_Identifier (Loc, Name_F))));
3272
3273          --  Put the declaration at the beginning of the declaration part
3274          --  to make sure it will be before all other actions that have been
3275          --  inserted before N.
3276
3277          Insert_List_Before_And_Analyze (First (List_Containing (N)), Nodes);
3278
3279          --  Generate the Finalization calls by finalizing the list
3280          --  controller right away. It will be re-finalized on scope
3281          --  exit but it doesn't matter. It cannot be done when the
3282          --  call initializes a renaming object though because in this
3283          --  case, the object becomes a pointer to the temporary and thus
3284          --  increases its life span.
3285
3286          if Nkind (N) = N_Object_Renaming_Declaration
3287            and then Controlled_Type (Etype (Defining_Identifier (N)))
3288          then
3289             null;
3290
3291          else
3292             Nodes :=
3293               Make_Final_Call (
3294                    Ref         => New_Reference_To (LC, Loc),
3295                    Typ         => Etype (LC),
3296                    With_Detach => New_Reference_To (Standard_False, Loc));
3297             if Present (Next_N) then
3298                Insert_List_Before_And_Analyze (Next_N, Nodes);
3299             else
3300                Append_List_To (List_Containing (N), Nodes);
3301             end if;
3302          end if;
3303       end if;
3304
3305       --  Put the local entities back in the enclosing scope, and set the
3306       --  Is_Public flag appropriately.
3307
3308       Transfer_Entities (S, Enclosing_S);
3309
3310       --  Mark the enclosing dynamic scope so that the sec stack will be
3311       --  released upon its exit unless this is a function that returns on
3312       --  the sec stack in which case this will be done by the caller.
3313
3314       if Uses_SS then
3315          S := Enclosing_Dynamic_Scope (S);
3316
3317          if Ekind (S) = E_Function
3318            and then Requires_Transient_Scope (Etype (S))
3319          then
3320             null;
3321          else
3322             Set_Uses_Sec_Stack (S);
3323             Check_Restriction (No_Secondary_Stack, N);
3324          end if;
3325       end if;
3326    end Wrap_Transient_Declaration;
3327
3328    -------------------------------
3329    -- Wrap_Transient_Expression --
3330    -------------------------------
3331
3332    --  Insert actions before <Expression>:
3333
3334    --  (lines marked with <CTRL> are expanded only in presence of Controlled
3335    --   objects needing finalization)
3336
3337    --     _E : Etyp;
3338    --     declare
3339    --        _M : constant Mark_Id := SS_Mark;
3340    --        Local_Final_List : System.FI.Finalizable_Ptr;    <CTRL>
3341
3342    --        procedure _Clean is
3343    --        begin
3344    --           Abort_Defer;
3345    --           System.FI.Finalize_List (Local_Final_List);   <CTRL>
3346    --           SS_Release (M);
3347    --           Abort_Undefer;
3348    --        end _Clean;
3349
3350    --     begin
3351    --        _E := <Expression>;
3352    --     at end
3353    --        _Clean;
3354    --     end;
3355
3356    --    then expression is replaced by _E
3357
3358    procedure Wrap_Transient_Expression (N : Node_Id) is
3359       Loc  : constant Source_Ptr := Sloc (N);
3360       E    : constant Entity_Id :=
3361                Make_Defining_Identifier (Loc, New_Internal_Name ('E'));
3362       Etyp : constant Entity_Id := Etype (N);
3363
3364    begin
3365       Insert_Actions (N, New_List (
3366         Make_Object_Declaration (Loc,
3367           Defining_Identifier => E,
3368           Object_Definition   => New_Reference_To (Etyp, Loc)),
3369
3370         Make_Transient_Block (Loc,
3371           Action =>
3372             Make_Assignment_Statement (Loc,
3373               Name       => New_Reference_To (E, Loc),
3374               Expression => Relocate_Node (N)))));
3375
3376       Rewrite (N, New_Reference_To (E, Loc));
3377       Analyze_And_Resolve (N, Etyp);
3378    end Wrap_Transient_Expression;
3379
3380    ------------------------------
3381    -- Wrap_Transient_Statement --
3382    ------------------------------
3383
3384    --  Transform <Instruction> into
3385
3386    --  (lines marked with <CTRL> are expanded only in presence of Controlled
3387    --   objects needing finalization)
3388
3389    --    declare
3390    --       _M : Mark_Id := SS_Mark;
3391    --       Local_Final_List : System.FI.Finalizable_Ptr ;    <CTRL>
3392
3393    --       procedure _Clean is
3394    --       begin
3395    --          Abort_Defer;
3396    --          System.FI.Finalize_List (Local_Final_List);    <CTRL>
3397    --          SS_Release (_M);
3398    --          Abort_Undefer;
3399    --       end _Clean;
3400
3401    --    begin
3402    --       <Instr uction>;
3403    --    at end
3404    --       _Clean;
3405    --    end;
3406
3407    procedure Wrap_Transient_Statement (N : Node_Id) is
3408       Loc           : constant Source_Ptr := Sloc (N);
3409       New_Statement : constant Node_Id := Relocate_Node (N);
3410
3411    begin
3412       Rewrite (N, Make_Transient_Block (Loc, New_Statement));
3413
3414       --  With the scope stack back to normal, we can call analyze on the
3415       --  resulting block. At this point, the transient scope is being
3416       --  treated like a perfectly normal scope, so there is nothing
3417       --  special about it.
3418
3419       --  Note: Wrap_Transient_Statement is called with the node already
3420       --  analyzed (i.e. Analyzed (N) is True). This is important, since
3421       --  otherwise we would get a recursive processing of the node when
3422       --  we do this Analyze call.
3423
3424       Analyze (N);
3425    end Wrap_Transient_Statement;
3426
3427 end Exp_Ch7;