gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Ch7;  use Sem_Ch7;
  40 with Sem_Ch8;  use Sem_Ch8;
  41 with Sem_Eval; use Sem_Eval;
  42 with Sem_Util; use Sem_Util;
  43 with Sinfo;    use Sinfo;
  44 with Snames;   use Snames;
  45 with Stand;    use Stand;
  46 with Tbuild;   use Tbuild;
  47 with Uintp;    use Uintp;
  48
  49 package body Exp_Ch13 is
  50
  51    ------------------------------------------
  52    -- Expand_N_Attribute_Definition_Clause --
  53    ------------------------------------------
  54
  55    --  Expansion action depends on attribute involved
  56
  57    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  58       Loc : constant Source_Ptr := Sloc (N);
  59       Exp : constant Node_Id    := Expression (N);
  60       Ent : Entity_Id;
  61       V   : Node_Id;
  62
  63    begin
  64       Ent := Entity (Name (N));
  65
  66       if Is_Type (Ent) then
  67          Ent := Underlying_Type (Ent);
  68       end if;
  69
  70       case Get_Attribute_Id (Chars (N)) is
  71
  72          -------------
  73          -- Address --
  74          -------------
  75
  76          when Attribute_Address =>
  77
  78             --  If there is an initialization which did not come from the
  79             --  source program, then it is an artifact of our expansion, and we
  80             --  suppress it. The case we are most concerned about here is the
  81             --  initialization of a packed array to all false, which seems
  82             --  inappropriate for variable to which an address clause is
  83             --  applied. The expression may itself have been rewritten if the
  84             --  type is packed array, so we need to examine whether the
  85             --  original node is in the source. An exception though is the case
  86             --  of an access variable which is default initialized to null, and
  87             --  such initialization is retained.
  88
  89             --  Furthermore, if the initialization is the equivalent aggregate
  90             --  of the type initialization procedure, it replaces an implicit
  91             --  call to the init proc, and must be respected. Note that for
  92             --  packed types we do not build equivalent aggregates.
  93
  94             declare
  95                Decl : constant Node_Id := Declaration_Node (Ent);
  96                Typ  : constant Entity_Id := Etype (Ent);
  97
  98             begin
  99                if Nkind (Decl) = N_Object_Declaration
 100                   and then Present (Expression (Decl))
 101                   and then Nkind (Expression (Decl)) /= N_Null
 102                   and then
 103                    not Comes_From_Source (Original_Node (Expression (Decl)))
 104                then
 105                   if Present (Base_Init_Proc (Typ))
 106                     and then
 107                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 108                   then
 109                      null;
 110                   else
 111                      Set_Expression (Decl, Empty);
 112                   end if;
 113                end if;
 114             end;
 115
 116          ---------------
 117          -- Alignment --
 118          ---------------
 119
 120          when Attribute_Alignment =>
 121
 122             --  As required by Gigi, we guarantee that the operand is an
 123             --  integer literal (this simplifies things in Gigi).
 124
 125             if Nkind (Exp) /= N_Integer_Literal then
 126                Rewrite
 127                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 128             end if;
 129
 130          ------------------
 131          -- Storage_Size --
 132          ------------------
 133
 134          when Attribute_Storage_Size =>
 135
 136             --  If the type is a task type, then assign the value of the
 137             --  storage size to the Size variable associated with the task.
 138             --    task_typeZ := expression
 139
 140             if Ekind (Ent) = E_Task_Type then
 141                Insert_Action (N,
 142                  Make_Assignment_Statement (Loc,
 143                    Name => New_Reference_To (Storage_Size_Variable (Ent), Loc),
 144                    Expression =>
 145                      Convert_To (RTE (RE_Size_Type), Expression (N))));
 146
 147             --  For Storage_Size for an access type, create a variable to hold
 148             --  the value of the specified size with name typeV and expand an
 149             --  assignment statement to initialze this value.
 150
 151             elsif Is_Access_Type (Ent) then
 152                V := Make_Defining_Identifier (Loc,
 153                       New_External_Name (Chars (Ent), 'V'));
 154
 155                Insert_Action (N,
 156                  Make_Object_Declaration (Loc,
 157                    Defining_Identifier => V,
 158                    Object_Definition  =>
 159                      New_Reference_To (RTE (RE_Storage_Offset), Loc),
 160                    Expression =>
 161                      Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 162
 163                Set_Storage_Size_Variable (Ent, Entity_Id (V));
 164             end if;
 165
 166          --  Other attributes require no expansion
 167
 168          when others =>
 169             null;
 170
 171       end case;
 172    end Expand_N_Attribute_Definition_Clause;
 173
 174    ----------------------------
 175    -- Expand_N_Freeze_Entity --
 176    ----------------------------
 177
 178    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 179       E              : constant Entity_Id := Entity (N);
 180       E_Scope        : Entity_Id;
 181       S              : Entity_Id;
 182       In_Other_Scope : Boolean;
 183       In_Outer_Scope : Boolean;
 184       Decl           : Node_Id;
 185       Delete         : Boolean := False;
 186
 187    begin
 188       --  Processing for objects with address clauses
 189
 190       if Is_Object (E) and then Present (Address_Clause (E)) then
 191          Apply_Address_Clause_Check (E, N);
 192          return;
 193
 194       --  Only other items requiring any front end action are types and
 195       --  subprograms.
 196
 197       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 198          return;
 199       end if;
 200
 201       --  Here E is a type or a subprogram
 202
 203       E_Scope := Scope (E);
 204
 205       --  This is an error protection against previous errors
 206
 207       if No (E_Scope) then
 208          return;
 209       end if;
 210
 211       --  If we are freezing entities defined in protected types, they belong
 212       --  in the enclosing scope, given that the original type has been
 213       --  expanded away. The same is true for entities in task types, in
 214       --  particular the parameter records of entries (Entities in bodies are
 215       --  all frozen within the body). If we are in the task body, this is a
 216       --  proper scope.
 217
 218       if Ekind (E_Scope) = E_Protected_Type
 219         or else (Ekind (E_Scope) = E_Task_Type
 220                    and then not Has_Completion (E_Scope))
 221       then
 222          E_Scope := Scope (E_Scope);
 223       end if;
 224
 225       S := Current_Scope;
 226       while S /= Standard_Standard and then S /= E_Scope loop
 227          S := Scope (S);
 228       end loop;
 229
 230       In_Other_Scope := not (S = E_Scope);
 231       In_Outer_Scope := (not In_Other_Scope) and then (S /= Current_Scope);
 232
 233       --  If the entity being frozen is defined in a scope that is not
 234       --  currently on the scope stack, we must establish the proper
 235       --  visibility before freezing the entity and related subprograms.
 236
 237       if In_Other_Scope then
 238          Push_Scope (E_Scope);
 239          Install_Visible_Declarations (E_Scope);
 240
 241          if Ekind (E_Scope) = E_Package         or else
 242             Ekind (E_Scope) = E_Generic_Package or else
 243             Is_Protected_Type (E_Scope)         or else
 244             Is_Task_Type (E_Scope)
 245          then
 246             Install_Private_Declarations (E_Scope);
 247          end if;
 248
 249       --  If the entity is in an outer scope, then that scope needs to
 250       --  temporarily become the current scope so that operations created
 251       --  during type freezing will be declared in the right scope and
 252       --  can properly override any corresponding inherited operations.
 253
 254       elsif In_Outer_Scope then
 255          Push_Scope (E_Scope);
 256       end if;
 257
 258       --  If type, freeze the type
 259
 260       if Is_Type (E) then
 261          Delete := Freeze_Type (N);
 262
 263          --  And for enumeration type, build the enumeration tables
 264
 265          if Is_Enumeration_Type (E) then
 266             Build_Enumeration_Image_Tables (E, N);
 267          end if;
 268
 269       --  If subprogram, freeze the subprogram
 270
 271       elsif Is_Subprogram (E) then
 272          Freeze_Subprogram (N);
 273
 274          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 275          --  entities internally used by the frontend to register primitives
 276          --  covering abstract interfaces. The call to Freeze_Subprogram has
 277          --  already expanded the code that fills the corresponding entry in
 278          --  its secondary dispatch table and therefore the code generator
 279          --  has nothing else to do with this freezing node.
 280
 281          Delete := Present (Abstract_Interface_Alias (E));
 282       end if;
 283
 284       --  Analyze actions generated by freezing. The init_proc contains source
 285       --  expressions that may raise Constraint_Error, and the assignment
 286       --  procedure for complex types needs checks on individual component
 287       --  assignments, but all other freezing actions should be compiled with
 288       --  all checks off.
 289
 290       if Present (Actions (N)) then
 291          Decl := First (Actions (N));
 292          while Present (Decl) loop
 293             if Nkind (Decl) = N_Subprogram_Body
 294               and then (Is_Init_Proc (Defining_Entity (Decl))
 295                           or else
 296                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 297             then
 298                Analyze (Decl);
 299
 300             --  A subprogram body created for a renaming_as_body completes
 301             --  a previous declaration, which may be in a different scope.
 302             --  Establish the proper scope before analysis.
 303
 304             elsif Nkind (Decl) = N_Subprogram_Body
 305               and then Present (Corresponding_Spec (Decl))
 306               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 307             then
 308                Push_Scope (Scope (Corresponding_Spec (Decl)));
 309                Analyze (Decl, Suppress => All_Checks);
 310                Pop_Scope;
 311
 312             else
 313                Analyze (Decl, Suppress => All_Checks);
 314             end if;
 315
 316             Next (Decl);
 317          end loop;
 318       end if;
 319
 320       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 321       --  a loop on all nodes being inserted will work propertly.
 322
 323       if Delete then
 324          Rewrite (N, Make_Null_Statement (Sloc (N)));
 325       end if;
 326
 327       if In_Other_Scope then
 328          if Ekind (Current_Scope) = E_Package then
 329             End_Package_Scope (E_Scope);
 330          else
 331             End_Scope;
 332          end if;
 333
 334       elsif In_Outer_Scope then
 335          Pop_Scope;
 336       end if;
 337    end Expand_N_Freeze_Entity;
 338
 339    -------------------------------------------
 340    -- Expand_N_Record_Representation_Clause --
 341    -------------------------------------------
 342
 343    --  The only expansion required is for the case of a mod clause present,
 344    --  which is removed, and translated into an alignment representation
 345    --  clause inserted immediately after the record rep clause with any
 346    --  initial pragmas inserted at the start of the component clause list.
 347
 348    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 349       Loc     : constant Source_Ptr := Sloc (N);
 350       Rectype : constant Entity_Id  := Entity (Identifier (N));
 351       Mod_Val : Uint;
 352       Citems  : List_Id;
 353       Repitem : Node_Id;
 354       AtM_Nod : Node_Id;
 355
 356    begin
 357       if Present (Mod_Clause (N)) then
 358          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 359          Citems  := Pragmas_Before (Mod_Clause (N));
 360
 361          if Present (Citems) then
 362             Append_List_To (Citems, Component_Clauses (N));
 363             Set_Component_Clauses (N, Citems);
 364          end if;
 365
 366          AtM_Nod :=
 367            Make_Attribute_Definition_Clause (Loc,
 368              Name       => New_Reference_To (Base_Type (Rectype), Loc),
 369              Chars      => Name_Alignment,
 370              Expression => Make_Integer_Literal (Loc, Mod_Val));
 371
 372          Set_From_At_Mod (AtM_Nod);
 373          Insert_After (N, AtM_Nod);
 374          Set_Mod_Clause (N, Empty);
 375       end if;
 376
 377       --  If the record representation clause has no components, then
 378       --  completely remove it.  Note that we also have to remove
 379       --  ourself from the Rep Item list.
 380
 381       if Is_Empty_List (Component_Clauses (N)) then
 382          if First_Rep_Item (Rectype) = N then
 383             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 384          else
 385             Repitem := First_Rep_Item (Rectype);
 386             while Present (Next_Rep_Item (Repitem)) loop
 387                if Next_Rep_Item (Repitem) = N then
 388                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 389                   exit;
 390                end if;
 391
 392                Next_Rep_Item (Repitem);
 393             end loop;
 394          end if;
 395
 396          Rewrite (N,
 397            Make_Null_Statement (Loc));
 398       end if;
 399    end Expand_N_Record_Representation_Clause;
 400
 401 end Exp_Ch13;