gcc/ada/exp_ch11.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 1                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Casing;   use Casing;
  29 with Debug;    use Debug;
  30 with Einfo;    use Einfo;
  31 with Errout;   use Errout;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Util; use Exp_Util;
  34 with Hostparm; use Hostparm;
  35 with Inline;   use Inline;
  36 with Lib;      use Lib;
  37 with Namet;    use Namet;
  38 with Nlists;   use Nlists;
  39 with Nmake;    use Nmake;
  40 with Opt;      use Opt;
  41 with Rtsfind;  use Rtsfind;
  42 with Restrict; use Restrict;
  43 with Rident;   use Rident;
  44 with Sem;      use Sem;
  45 with Sem_Ch5;  use Sem_Ch5;
  46 with Sem_Ch8;  use Sem_Ch8;
  47 with Sem_Res;  use Sem_Res;
  48 with Sem_Util; use Sem_Util;
  49 with Sinfo;    use Sinfo;
  50 with Sinput;   use Sinput;
  51 with Snames;   use Snames;
  52 with Stand;    use Stand;
  53 with Stringt;  use Stringt;
  54 with Targparm; use Targparm;
  55 with Tbuild;   use Tbuild;
  56 with Uintp;    use Uintp;
  57 with Uname;    use Uname;
  58
  59 package body Exp_Ch11 is
  60
  61    SD_List : List_Id;
  62    --  This list gathers the values SDn'Unrestricted_Access used to
  63    --  construct the unit exception table. It is set to Empty_List if
  64    --  there are no subprogram descriptors.
  65
  66    -----------------------
  67    -- Local Subprograms --
  68    -----------------------
  69
  70    procedure Expand_Exception_Handler_Tables (HSS : Node_Id);
  71    --  Subsidiary procedure called by Expand_Exception_Handlers if zero
  72    --  cost exception handling is installed for this target. Replaces the
  73    --  exception handler structure with appropriate labeled code and tables
  74    --  that allow the zero cost exception handling circuits to find the
  75    --  correct handler (see unit Ada.Exceptions for details).
  76
  77    procedure Generate_Subprogram_Descriptor
  78      (N     : Node_Id;
  79       Loc   : Source_Ptr;
  80       Spec  : Entity_Id;
  81       Slist : List_Id);
  82    --  Procedure called to generate a subprogram descriptor. N is the
  83    --  subprogram body node or, in the case of an imported subprogram, is
  84    --  Empty, and Spec is the entity of the sunprogram. For details of the
  85    --  required structure, see package System.Exceptions. The generated
  86    --  subprogram descriptor is appended to Slist. Loc provides the
  87    --  source location to be used for the generated descriptor.
  88
  89    ---------------------------
  90    -- Expand_At_End_Handler --
  91    ---------------------------
  92
  93    --  For a handled statement sequence that has a cleanup (At_End_Proc
  94    --  field set), an exception handler of the following form is required:
  95
  96    --     exception
  97    --       when all others =>
  98    --          cleanup call
  99    --          raise;
 100
 101    --  Note: this exception handler is treated rather specially by
 102    --  subsequent expansion in two respects:
 103
 104    --    The normal call to Undefer_Abort is omitted
 105    --    The raise call does not do Defer_Abort
 106
 107    --  This is because the current tasking code seems to assume that
 108    --  the call to the cleanup routine that is made from an exception
 109    --  handler for the abort signal is called with aborts deferred.
 110
 111    --  This expansion is only done if we have front end exception handling.
 112    --  If we have back end exception handling, then the AT END handler is
 113    --  left alone, and cleanups (including the exceptional case) are handled
 114    --  by the back end.
 115
 116    --  In the front end case, the exception handler described above handles
 117    --  the exceptional case. The AT END handler is left in the generated tree
 118    --  and the code generator (e.g. gigi) must still handle proper generation
 119    --  of cleanup calls for the non-exceptional case.
 120
 121    procedure Expand_At_End_Handler (HSS : Node_Id; Block : Node_Id) is
 122       Clean   : constant Entity_Id  := Entity (At_End_Proc (HSS));
 123       Loc     : constant Source_Ptr := Sloc (Clean);
 124       Ohandle : Node_Id;
 125       Stmnts  : List_Id;
 126
 127    begin
 128       pragma Assert (Present (Clean));
 129       pragma Assert (No (Exception_Handlers (HSS)));
 130
 131       --  Don't expand if back end exception handling active
 132
 133       if Exception_Mechanism = Back_End_ZCX_Exceptions then
 134          return;
 135       end if;
 136
 137       --  Don't expand an At End handler if we have already had configurable
 138       --  run-time violations, since likely this will just be a matter of
 139       --  generating useless cascaded messages
 140
 141       if Configurable_Run_Time_Violations > 0 then
 142          return;
 143       end if;
 144
 145       if Restriction_Active (No_Exception_Handlers) then
 146          return;
 147       end if;
 148
 149       if Present (Block) then
 150          New_Scope (Block);
 151       end if;
 152
 153       Ohandle :=
 154         Make_Others_Choice (Loc);
 155       Set_All_Others (Ohandle);
 156
 157       Stmnts := New_List (
 158         Make_Procedure_Call_Statement (Loc,
 159           Name => New_Occurrence_Of (Clean, Loc)),
 160         Make_Raise_Statement (Loc));
 161
 162       Set_Exception_Handlers (HSS, New_List (
 163         Make_Exception_Handler (Loc,
 164           Exception_Choices => New_List (Ohandle),
 165           Statements        => Stmnts)));
 166
 167       Analyze_List (Stmnts, Suppress => All_Checks);
 168       Expand_Exception_Handlers (HSS);
 169
 170       if Present (Block) then
 171          Pop_Scope;
 172       end if;
 173    end Expand_At_End_Handler;
 174
 175    -------------------------------------
 176    -- Expand_Exception_Handler_Tables --
 177    -------------------------------------
 178
 179    --  See Ada.Exceptions specification for full details of the data
 180    --  structures that we need to construct here. As an example of the
 181    --  transformation that is required, given the structure:
 182
 183    --     declare
 184    --        {declarations}
 185    --        ..
 186    --     begin
 187    --        {statements-1}
 188    --        ...
 189    --     exception
 190    --        when a | b =>
 191    --           {statements-2}
 192    --           ...
 193    --        when others =>
 194    --           {statements-3}
 195    --           ...
 196    --     end;
 197
 198    --  We transform this into:
 199
 200    --     declare
 201    --        {declarations}
 202    --        ...
 203    --        L1 : label;
 204    --        L2 : label;
 205    --        L3 : label;
 206    --        L4 : Label;
 207    --        L5 : label;
 208
 209    --     begin
 210    --        <<L1>>
 211    --           {statements-1}
 212    --        <<L2>>
 213
 214    --     exception
 215
 216    --        when a | b =>
 217    --           <<L3>>
 218    --           {statements-2}
 219
 220    --           HR2 : constant Handler_Record := (
 221    --                   Lo      => L1'Address,
 222    --                   Hi      => L2'Address,
 223    --                   Id      => a'Identity,
 224    --                   Handler => L5'Address);
 225
 226    --           HR3 : constant Handler_Record := (
 227    --                   Lo      => L1'Address,
 228    --                   Hi      => L2'Address,
 229    --                   Id      => b'Identity,
 230    --                   Handler => L4'Address);
 231
 232    --        when others =>
 233    --           <<L4>>
 234    --           {statements-3}
 235
 236    --           HR1 : constant Handler_Record := (
 237    --                   Lo      => L1'Address,
 238    --                   Hi      => L2'Address,
 239    --                   Id      => Others_Id,
 240    --                   Handler => L4'Address);
 241    --     end;
 242
 243    --  The exception handlers in the transformed version are marked with the
 244    --  Zero_Cost_Handling flag set, and all gigi does in this case is simply
 245    --  to put the handler code somewhere. It can optionally be put inline
 246    --  between the goto L3 and the label <<L3>> (which is why we generate
 247    --  that goto in the first place).
 248
 249    procedure Expand_Exception_Handler_Tables (HSS : Node_Id) is
 250       Loc     : constant Source_Ptr := Sloc (HSS);
 251       Handlrs : constant List_Id    := Exception_Handlers (HSS);
 252       Stms    : constant List_Id    := Statements (HSS);
 253       Handler : Node_Id;
 254
 255       Hlist : List_Id;
 256       --  This is the list to which handlers are to be appended. It is
 257       --  either the list for the enclosing subprogram, or the enclosing
 258       --  selective accept statement (which will turn into a subprogram
 259       --  during expansion later on).
 260
 261       L1 : constant Entity_Id :=
 262              Make_Defining_Identifier (Loc,
 263                Chars => New_Internal_Name ('L'));
 264
 265       L2 : constant Entity_Id :=
 266              Make_Defining_Identifier (Loc,
 267                Chars => New_Internal_Name ('L'));
 268
 269       Lnn    : Entity_Id;
 270       Choice : Node_Id;
 271       E_Id   : Node_Id;
 272       HR_Ent : Node_Id;
 273       HL_Ref : Node_Id;
 274       Item   : Node_Id;
 275
 276       Subp_Entity : Entity_Id;
 277       --  This is the entity for the subprogram (or library level package)
 278       --  to which the handler record is to be attached for later reference
 279       --  in a subprogram descriptor for this entity.
 280
 281       procedure Append_To_Stms (N : Node_Id);
 282       --  Append given statement to the end of the statements of the
 283       --  handled sequence of statements and analyze it in place.
 284
 285       function Inside_Selective_Accept return Boolean;
 286       --  This function is called if we are inside the scope of an entry
 287       --  or task. It checks if the handler is appearing in the context
 288       --  of a selective accept statement. If so, Hlist is set to
 289       --  temporarily park the handlers in the N_Accept_Alternative.
 290       --  node. They will subsequently be moved to the procedure entity
 291       --  for the procedure built for this alternative. The statements that
 292       --  follow the Accept within the alternative are not inside the Accept
 293       --  for purposes of this test, and handlers that may appear within
 294       --  them belong in the enclosing task procedure.
 295
 296       procedure Set_Hlist;
 297       --  Sets the handler list corresponding to Subp_Entity
 298
 299       --------------------
 300       -- Append_To_Stms --
 301       --------------------
 302
 303       procedure Append_To_Stms (N : Node_Id) is
 304       begin
 305          Insert_After_And_Analyze (Last (Stms), N);
 306          Set_Exception_Junk (N);
 307       end Append_To_Stms;
 308
 309       -----------------------------
 310       -- Inside_Selective_Accept --
 311       -----------------------------
 312
 313       function Inside_Selective_Accept return Boolean is
 314          Parnt : Node_Id;
 315          Curr  : Node_Id := HSS;
 316
 317       begin
 318          Parnt := Parent (HSS);
 319          while Nkind (Parnt) /= N_Compilation_Unit loop
 320             if Nkind (Parnt) = N_Accept_Alternative
 321               and then Curr = Accept_Statement (Parnt)
 322             then
 323                if Present (Accept_Handler_Records (Parnt)) then
 324                   Hlist := Accept_Handler_Records (Parnt);
 325                else
 326                   Hlist := New_List;
 327                   Set_Accept_Handler_Records (Parnt, Hlist);
 328                end if;
 329
 330                return True;
 331             else
 332                Curr  := Parnt;
 333                Parnt := Parent (Parnt);
 334             end if;
 335          end loop;
 336
 337          return False;
 338       end Inside_Selective_Accept;
 339
 340       ---------------
 341       -- Set_Hlist --
 342       ---------------
 343
 344       procedure Set_Hlist is
 345       begin
 346          --  Never try to inline a subprogram with exception handlers
 347
 348          Set_Is_Inlined (Subp_Entity, False);
 349
 350          if Present (Subp_Entity)
 351            and then Present (Handler_Records (Subp_Entity))
 352          then
 353             Hlist := Handler_Records (Subp_Entity);
 354          else
 355             Hlist := New_List;
 356             Set_Handler_Records (Subp_Entity, Hlist);
 357          end if;
 358       end Set_Hlist;
 359
 360    --  Start of processing for Expand_Exception_Handler_Tables
 361
 362    begin
 363       --  Nothing to do if this handler has already been processed
 364
 365       if Zero_Cost_Handling (HSS) then
 366          return;
 367       end if;
 368
 369       Set_Zero_Cost_Handling (HSS);
 370
 371       --  Find the parent subprogram or package scope containing this
 372       --  exception frame. This should always find a real package or
 373       --  subprogram. If it does not it will stop at Standard, but
 374       --  this cannot legitimately occur.
 375
 376       --  We only stop at library level packages, for inner packages
 377       --  we always attach handlers to the containing procedure.
 378
 379       Subp_Entity := Current_Scope;
 380       Scope_Loop : loop
 381
 382          --  Never need tables expanded inside a generic template
 383
 384          if Is_Generic_Unit (Subp_Entity) then
 385             return;
 386
 387          --  Stop if we reached containing subprogram. Go to protected
 388          --  subprogram if there is one defined.
 389
 390          elsif Ekind (Subp_Entity) = E_Function
 391            or else Ekind (Subp_Entity) = E_Procedure
 392          then
 393             if Present (Protected_Body_Subprogram (Subp_Entity)) then
 394                Subp_Entity := Protected_Body_Subprogram (Subp_Entity);
 395             end if;
 396
 397             Set_Hlist;
 398             exit Scope_Loop;
 399
 400          --  Case of within an entry
 401
 402          elsif Is_Entry (Subp_Entity) then
 403
 404             --  Protected entry, use corresponding body subprogram
 405
 406             if Present (Protected_Body_Subprogram (Subp_Entity)) then
 407                Subp_Entity := Protected_Body_Subprogram (Subp_Entity);
 408                Set_Hlist;
 409                exit Scope_Loop;
 410
 411             --  Check if we are within a selective accept alternative
 412
 413             elsif Inside_Selective_Accept then
 414
 415                --  As a side effect, Inside_Selective_Accept set Hlist,
 416                --  in much the same manner as Set_Hlist, except that
 417                --  the list involved was the one for the selective accept.
 418
 419                exit Scope_Loop;
 420             end if;
 421
 422          --  Case of within library level package
 423
 424          elsif Ekind (Subp_Entity) = E_Package
 425            and then Is_Compilation_Unit (Subp_Entity)
 426          then
 427             if Is_Body_Name (Unit_Name (Get_Code_Unit (HSS))) then
 428                Subp_Entity := Body_Entity (Subp_Entity);
 429             end if;
 430
 431             Set_Hlist;
 432             exit Scope_Loop;
 433
 434          --  Task type case
 435
 436          elsif Ekind (Subp_Entity) = E_Task_Type then
 437
 438             --  Check if we are within a selective accept alternative
 439
 440             if Inside_Selective_Accept then
 441
 442                --  As a side effect, Inside_Selective_Accept set Hlist,
 443                --  in much the same manner as Set_Hlist, except that the
 444                --  list involved was the one for the selective accept.
 445
 446                exit Scope_Loop;
 447
 448             --  Stop if we reached task type with task body procedure,
 449             --  use the task body procedure.
 450
 451             elsif Present (Get_Task_Body_Procedure (Subp_Entity)) then
 452                Subp_Entity := Get_Task_Body_Procedure (Subp_Entity);
 453                Set_Hlist;
 454                exit Scope_Loop;
 455             end if;
 456          end if;
 457
 458          --  If we fall through, keep looking
 459
 460          Subp_Entity := Scope (Subp_Entity);
 461       end loop Scope_Loop;
 462
 463       pragma Assert (Subp_Entity /= Standard_Standard);
 464
 465       --  Analyze standard labels
 466
 467       Analyze_Label_Entity (L1);
 468       Analyze_Label_Entity (L2);
 469
 470       Insert_Before_And_Analyze (First (Stms),
 471         Make_Label (Loc,
 472           Identifier => New_Occurrence_Of (L1, Loc)));
 473       Set_Exception_Junk (First (Stms));
 474
 475       Append_To_Stms (
 476         Make_Label (Loc,
 477           Identifier => New_Occurrence_Of (L2, Loc)));
 478
 479       --  Loop through exception handlers
 480
 481       Handler := First_Non_Pragma (Handlrs);
 482       while Present (Handler) loop
 483          Set_Zero_Cost_Handling (Handler);
 484
 485          --  Add label at start of handler, and goto at the end
 486
 487          Lnn :=
 488            Make_Defining_Identifier (Loc,
 489              Chars => New_Internal_Name ('L'));
 490
 491          Analyze_Label_Entity (Lnn);
 492
 493          Item :=
 494            Make_Label (Loc,
 495              Identifier => New_Occurrence_Of (Lnn, Loc));
 496          Set_Exception_Junk (Item);
 497          Insert_Before_And_Analyze (First (Statements (Handler)), Item);
 498
 499          --  Loop through choices
 500
 501          Choice := First (Exception_Choices (Handler));
 502          while Present (Choice) loop
 503
 504             --  Others (or all others) choice
 505
 506             if Nkind (Choice) = N_Others_Choice then
 507                if All_Others (Choice) then
 508                   E_Id := New_Occurrence_Of (RTE (RE_All_Others_Id), Loc);
 509                else
 510                   E_Id := New_Occurrence_Of (RTE (RE_Others_Id), Loc);
 511                end if;
 512
 513             --  Special case of VMS_Exception. Not clear what we will do
 514             --  eventually here if and when we implement zero cost exceptions
 515             --  on VMS. But at least for now, don't blow up trying to take
 516             --  a garbage code address for such an exception.
 517
 518             elsif Is_VMS_Exception (Entity (Choice)) then
 519                E_Id := New_Occurrence_Of (RTE (RE_Null_Id), Loc);
 520
 521             --  Normal case of specific exception choice
 522
 523             else
 524                E_Id :=
 525                  Make_Attribute_Reference (Loc,
 526                    Prefix => New_Occurrence_Of (Entity (Choice), Loc),
 527                    Attribute_Name => Name_Identity);
 528             end if;
 529
 530             HR_Ent :=
 531               Make_Defining_Identifier (Loc,
 532                 Chars => New_Internal_Name ('H'));
 533
 534             HL_Ref :=
 535               Make_Attribute_Reference (Loc,
 536                 Prefix => New_Occurrence_Of (HR_Ent, Loc),
 537                 Attribute_Name => Name_Unrestricted_Access);
 538
 539             --  Now we need to add the entry for the new handler record to
 540             --  the list of handler records for the current subprogram.
 541
 542             --  Normally we end up generating the handler records in exactly
 543             --  the right order. Here right order means innermost first,
 544             --  since the table will be searched sequentially. Since we
 545             --  generally expand from outside to inside, the order is just
 546             --  what we want, and we need to append the new entry to the
 547             --  end of the list.
 548
 549             --  However, there are exceptions, notably in the case where
 550             --  a generic body is inserted later on. See for example the
 551             --  case of ACVC test C37213J, which has the following form:
 552
 553             --    generic package x ... end x;
 554             --    package body x is
 555             --    begin
 556             --       ...
 557             --    exception  (1)
 558             --       ...
 559             --    end x;
 560
 561             --    ...
 562
 563             --    declare
 564             --       package q is new x;
 565             --    begin
 566             --       ...
 567             --    exception (2)
 568             --       ...
 569             --    end;
 570
 571             --  In this case, we will expand exception handler (2) first,
 572             --  since the expansion of (1) is delayed till later when the
 573             --  generic body is inserted. But (1) belongs before (2) in
 574             --  the chain.
 575
 576             --  Note that scopes are not totally ordered, because two
 577             --  scopes can be in parallel blocks, so that it does not
 578             --  matter what order these entries appear in. An ordering
 579             --  relation exists if one scope is inside another, and what
 580             --  we really want is some partial ordering.
 581
 582             --  A simple, not very efficient, but adequate algorithm to
 583             --  achieve this partial ordering is to search the list for
 584             --  the first entry containing the given scope, and put the
 585             --  new entry just before it.
 586
 587             declare
 588                New_Scop : constant Entity_Id := Current_Scope;
 589                Ent      : Node_Id;
 590
 591             begin
 592                Ent := First (Hlist);
 593                loop
 594                   --  If all searched, then we can just put the new
 595                   --  entry at the end of the list (it actually does
 596                   --  not matter where we put it in this case).
 597
 598                   if No (Ent) then
 599                      Append_To (Hlist, HL_Ref);
 600                      exit;
 601
 602                   --  If the current scope is within the scope of the
 603                   --  entry then insert the entry before to retain the
 604                   --  proper order as per above discussion.
 605
 606                   --  Note that for equal entries, we just keep going,
 607                   --  which is fine, the entry will end up at the end
 608                   --  of the list where it belongs.
 609
 610                   elsif Scope_Within
 611                           (New_Scop, Scope (Entity (Prefix (Ent))))
 612                   then
 613                      Insert_Before (Ent, HL_Ref);
 614                      exit;
 615
 616                   --  Otherwise keep looking
 617
 618                   else
 619                      Next (Ent);
 620                   end if;
 621                end loop;
 622             end;
 623
 624             Item :=
 625               Make_Object_Declaration (Loc,
 626                 Defining_Identifier => HR_Ent,
 627                 Constant_Present    => True,
 628                 Aliased_Present     => True,
 629                 Object_Definition   =>
 630                   New_Occurrence_Of (RTE (RE_Handler_Record), Loc),
 631
 632                 Expression          =>
 633                   Make_Aggregate (Loc,
 634                     Expressions => New_List (
 635                       Make_Attribute_Reference (Loc,             -- Lo
 636                         Prefix => New_Occurrence_Of (L1, Loc),
 637                         Attribute_Name => Name_Address),
 638
 639                       Make_Attribute_Reference (Loc,             -- Hi
 640                         Prefix => New_Occurrence_Of (L2, Loc),
 641                         Attribute_Name => Name_Address),
 642
 643                       E_Id,                                      -- Id
 644
 645                       Make_Attribute_Reference (Loc,
 646                         Prefix => New_Occurrence_Of (Lnn, Loc),  -- Handler
 647                         Attribute_Name => Name_Address))));
 648
 649             Set_Handler_List_Entry (Item, HL_Ref);
 650             Set_Exception_Junk (Item);
 651             Insert_After_And_Analyze (Last (Statements (Handler)), Item);
 652             Set_Is_Statically_Allocated (HR_Ent);
 653
 654             --  If this is a late insertion (from body instance) it is being
 655             --  inserted in the component list of an already analyzed aggre-
 656             --  gate, and must be analyzed explicitly.
 657
 658             Analyze_And_Resolve (HL_Ref, RTE (RE_Handler_Record_Ptr));
 659
 660             Next (Choice);
 661          end loop;
 662
 663          Next_Non_Pragma (Handler);
 664       end loop;
 665    end Expand_Exception_Handler_Tables;
 666
 667    -------------------------------
 668    -- Expand_Exception_Handlers --
 669    -------------------------------
 670
 671    procedure Expand_Exception_Handlers (HSS : Node_Id) is
 672       Handlrs       : constant List_Id := Exception_Handlers (HSS);
 673       Loc           : Source_Ptr;
 674       Handler       : Node_Id;
 675       Others_Choice : Boolean;
 676       Obj_Decl      : Node_Id;
 677
 678       procedure Prepend_Call_To_Handler
 679         (Proc : RE_Id;
 680          Args : List_Id := No_List);
 681       --  Routine to prepend a call to the procedure referenced by Proc at
 682       --  the start of the handler code for the current Handler.
 683
 684       -----------------------------
 685       -- Prepend_Call_To_Handler --
 686       -----------------------------
 687
 688       procedure Prepend_Call_To_Handler
 689         (Proc : RE_Id;
 690          Args : List_Id := No_List)
 691       is
 692          Ent : constant Entity_Id := RTE (Proc);
 693
 694       begin
 695          --  If we have no Entity, then we are probably in no run time mode
 696          --  or some weird error has occured. In either case do do nothing!
 697
 698          if Present (Ent) then
 699             declare
 700                Call : constant Node_Id :=
 701                         Make_Procedure_Call_Statement (Loc,
 702                           Name => New_Occurrence_Of (RTE (Proc), Loc),
 703                           Parameter_Associations => Args);
 704
 705             begin
 706                Prepend_To (Statements (Handler), Call);
 707                Analyze (Call, Suppress => All_Checks);
 708             end;
 709          end if;
 710       end Prepend_Call_To_Handler;
 711
 712    --  Start of processing for Expand_Exception_Handlers
 713
 714    begin
 715       --  Loop through handlers
 716
 717       Handler := First_Non_Pragma (Handlrs);
 718       Handler_Loop : while Present (Handler) loop
 719          Loc := Sloc (Handler);
 720
 721          --  Remove source handler if gnat debug flag N is set
 722
 723          if Debug_Flag_Dot_X and then Comes_From_Source (Handler) then
 724             declare
 725                H : constant Node_Id := Handler;
 726             begin
 727                Next_Non_Pragma (Handler);
 728                Remove (H);
 729                goto Continue_Handler_Loop;
 730             end;
 731          end if;
 732
 733          --  If an exception occurrence is present, then we must declare it
 734          --  and initialize it from the value stored in the TSD
 735
 736          --     declare
 737          --        name : Exception_Occurrence;
 738          --
 739          --     begin
 740          --        Save_Occurrence (name, Get_Current_Excep.all)
 741          --        ...
 742          --     end;
 743
 744          if Present (Choice_Parameter (Handler)) then
 745             declare
 746                Cparm : constant Entity_Id  := Choice_Parameter (Handler);
 747                Clc   : constant Source_Ptr := Sloc (Cparm);
 748                Save  : Node_Id;
 749
 750             begin
 751                Save :=
 752                  Make_Procedure_Call_Statement (Loc,
 753                    Name =>
 754                      New_Occurrence_Of (RTE (RE_Save_Occurrence), Loc),
 755                    Parameter_Associations => New_List (
 756                      New_Occurrence_Of (Cparm, Clc),
 757                      Make_Explicit_Dereference (Loc,
 758                        Make_Function_Call (Loc,
 759                          Name => Make_Explicit_Dereference (Loc,
 760                            New_Occurrence_Of
 761                              (RTE (RE_Get_Current_Excep), Loc))))));
 762
 763                Mark_Rewrite_Insertion (Save);
 764                Prepend (Save, Statements (Handler));
 765
 766                Obj_Decl :=
 767                  Make_Object_Declaration (Clc,
 768                    Defining_Identifier => Cparm,
 769                    Object_Definition   =>
 770                      New_Occurrence_Of
 771                        (RTE (RE_Exception_Occurrence), Clc));
 772                Set_No_Initialization (Obj_Decl, True);
 773
 774                Rewrite (Handler,
 775                  Make_Exception_Handler (Loc,
 776                    Exception_Choices => Exception_Choices (Handler),
 777
 778                    Statements => New_List (
 779                      Make_Block_Statement (Loc,
 780                        Declarations => New_List (Obj_Decl),
 781                        Handled_Statement_Sequence =>
 782                          Make_Handled_Sequence_Of_Statements (Loc,
 783                            Statements => Statements (Handler))))));
 784
 785                Analyze_List (Statements (Handler), Suppress => All_Checks);
 786             end;
 787          end if;
 788
 789          --  The processing at this point is rather different for the
 790          --  JVM case, so we completely separate the processing.
 791
 792          --  For the JVM case, we unconditionally call Update_Exception,
 793          --  passing a call to the intrinsic function Current_Target_Exception
 794          --  (see JVM version of Ada.Exceptions in 4jexcept.adb for details).
 795
 796          if Hostparm.Java_VM then
 797             declare
 798                Arg : constant Node_Id :=
 799                        Make_Function_Call (Loc,
 800                          Name => New_Occurrence_Of
 801                                    (RTE (RE_Current_Target_Exception), Loc));
 802             begin
 803                Prepend_Call_To_Handler (RE_Update_Exception, New_List (Arg));
 804             end;
 805
 806          --  For the normal case, we have to worry about the state of abort
 807          --  deferral. Generally, we defer abort during runtime handling of
 808          --  exceptions. When control is passed to the handler, then in the
 809          --  normal case we undefer aborts. In any case this entire handling
 810          --  is relevant only if aborts are allowed!
 811
 812          elsif Abort_Allowed then
 813
 814             --  There are some special cases in which we do not do the
 815             --  undefer. In particular a finalization (AT END) handler
 816             --  wants to operate with aborts still deferred.
 817
 818             --  We also suppress the call if this is the special handler
 819             --  for Abort_Signal, since if we are aborting, we want to keep
 820             --  aborts deferred (one abort is enough thank you very much :-)
 821
 822             --  If abort really needs to be deferred the expander must add
 823             --  this call explicitly, see Exp_Ch9.Expand_N_Asynchronous_Select.
 824
 825             Others_Choice :=
 826               Nkind (First (Exception_Choices (Handler))) = N_Others_Choice;
 827
 828             if (Others_Choice
 829                  or else Entity (First (Exception_Choices (Handler))) /=
 830                                                       Stand.Abort_Signal)
 831               and then not
 832                 (Others_Choice
 833                    and then All_Others (First (Exception_Choices (Handler))))
 834               and then Abort_Allowed
 835             then
 836                Prepend_Call_To_Handler (RE_Abort_Undefer);
 837             end if;
 838          end if;
 839
 840          Next_Non_Pragma (Handler);
 841
 842       <<Continue_Handler_Loop>>
 843          null;
 844       end loop Handler_Loop;
 845
 846       --  If all handlers got removed by gnatdN, then remove the list
 847
 848       if Debug_Flag_Dot_X
 849         and then Is_Empty_List (Exception_Handlers (HSS))
 850       then
 851          Set_Exception_Handlers (HSS, No_List);
 852       end if;
 853
 854       --  The last step for expanding exception handlers is to expand the
 855       --  exception tables if zero cost exception handling is active.
 856
 857       if Exception_Mechanism = Front_End_ZCX_Exceptions then
 858          Expand_Exception_Handler_Tables (HSS);
 859       end if;
 860    end Expand_Exception_Handlers;
 861
 862    ------------------------------------
 863    -- Expand_N_Exception_Declaration --
 864    ------------------------------------
 865
 866    --  Generates:
 867    --     exceptE : constant String := "A.B.EXCEP";   -- static data
 868    --     except : exception_data :=  (
 869    --                    Handled_By_Other => False,
 870    --                    Lang             => 'A',
 871    --                    Name_Length      => exceptE'Length,
 872    --                    Full_Name        => exceptE'Address,
 873    --                    HTable_Ptr       => null,
 874    --                    Import_Code      => 0,
 875    --                    Raise_Hook       => null,
 876    --                    );
 877
 878    --  (protecting test only needed if not at library level)
 879    --
 880    --     exceptF : Boolean := True --  static data
 881    --     if exceptF then
 882    --        exceptF := False;
 883    --        Register_Exception (except'Unchecked_Access);
 884    --     end if;
 885
 886    procedure Expand_N_Exception_Declaration (N : Node_Id) is
 887       Loc     : constant Source_Ptr := Sloc (N);
 888       Id      : constant Entity_Id  := Defining_Identifier (N);
 889       L       : List_Id             := New_List;
 890       Flag_Id : Entity_Id;
 891
 892       Name_Exname : constant Name_Id := New_External_Name (Chars (Id), 'E');
 893       Exname      : constant Node_Id :=
 894                       Make_Defining_Identifier (Loc, Name_Exname);
 895
 896    begin
 897       --  There is no expansion needed when compiling for the JVM since the
 898       --  JVM has a built-in exception mechanism. See 4jexcept.ads for details.
 899
 900       if Hostparm.Java_VM then
 901          return;
 902       end if;
 903
 904       --  Definition of the external name: nam : constant String := "A.B.NAME";
 905
 906       Insert_Action (N,
 907         Make_Object_Declaration (Loc,
 908           Defining_Identifier => Exname,
 909           Constant_Present    => True,
 910           Object_Definition   => New_Occurrence_Of (Standard_String, Loc),
 911           Expression => Make_String_Literal (Loc, Full_Qualified_Name (Id))));
 912
 913       Set_Is_Statically_Allocated (Exname);
 914
 915       --  Create the aggregate list for type Standard.Exception_Type:
 916       --  Handled_By_Other component: False
 917
 918       Append_To (L, New_Occurrence_Of (Standard_False, Loc));
 919
 920       --  Lang component: 'A'
 921
 922       Append_To (L,
 923         Make_Character_Literal (Loc,
 924           Chars              =>  Name_uA,
 925           Char_Literal_Value =>  UI_From_Int (Character'Pos ('A'))));
 926
 927       --  Name_Length component: Nam'Length
 928
 929       Append_To (L,
 930         Make_Attribute_Reference (Loc,
 931           Prefix         => New_Occurrence_Of (Exname, Loc),
 932           Attribute_Name => Name_Length));
 933
 934       --  Full_Name component: Standard.A_Char!(Nam'Address)
 935
 936       Append_To (L, Unchecked_Convert_To (Standard_A_Char,
 937         Make_Attribute_Reference (Loc,
 938           Prefix         => New_Occurrence_Of (Exname, Loc),
 939           Attribute_Name => Name_Address)));
 940
 941       --  HTable_Ptr component: null
 942
 943       Append_To (L, Make_Null (Loc));
 944
 945       --  Import_Code component: 0
 946
 947       Append_To (L, Make_Integer_Literal (Loc, 0));
 948
 949       --  Raise_Hook component: null
 950
 951       Append_To (L, Make_Null (Loc));
 952
 953       Set_Expression (N, Make_Aggregate (Loc, Expressions => L));
 954       Analyze_And_Resolve (Expression (N), Etype (Id));
 955
 956       --  Register_Exception (except'Unchecked_Access);
 957
 958       if not Restriction_Active (No_Exception_Handlers)
 959         and then not Restriction_Active (No_Exception_Registration)
 960       then
 961          L := New_List (
 962                 Make_Procedure_Call_Statement (Loc,
 963                   Name => New_Occurrence_Of (RTE (RE_Register_Exception), Loc),
 964                   Parameter_Associations => New_List (
 965                     Unchecked_Convert_To (RTE (RE_Exception_Data_Ptr),
 966                       Make_Attribute_Reference (Loc,
 967                         Prefix         => New_Occurrence_Of (Id, Loc),
 968                         Attribute_Name => Name_Unrestricted_Access)))));
 969
 970          Set_Register_Exception_Call (Id, First (L));
 971
 972          if not Is_Library_Level_Entity (Id) then
 973             Flag_Id :=  Make_Defining_Identifier (Loc,
 974                           New_External_Name (Chars (Id), 'F'));
 975
 976             Insert_Action (N,
 977               Make_Object_Declaration (Loc,
 978                 Defining_Identifier => Flag_Id,
 979                 Object_Definition   =>
 980                   New_Occurrence_Of (Standard_Boolean, Loc),
 981                 Expression          =>
 982                   New_Occurrence_Of (Standard_True, Loc)));
 983
 984             Set_Is_Statically_Allocated (Flag_Id);
 985
 986             Append_To (L,
 987               Make_Assignment_Statement (Loc,
 988                 Name       => New_Occurrence_Of (Flag_Id, Loc),
 989                 Expression => New_Occurrence_Of (Standard_False, Loc)));
 990
 991             Insert_After_And_Analyze (N,
 992               Make_Implicit_If_Statement (N,
 993                 Condition       => New_Occurrence_Of (Flag_Id, Loc),
 994                 Then_Statements => L));
 995
 996          else
 997             Insert_List_After_And_Analyze (N, L);
 998          end if;
 999       end if;
1000
1001    end Expand_N_Exception_Declaration;
1002
1003    ---------------------------------------------
1004    -- Expand_N_Handled_Sequence_Of_Statements --
1005    ---------------------------------------------
1006
1007    procedure Expand_N_Handled_Sequence_Of_Statements (N : Node_Id) is
1008    begin
1009       if Present (Exception_Handlers (N))
1010         and then not Restriction_Active (No_Exception_Handlers)
1011       then
1012          Expand_Exception_Handlers (N);
1013       end if;
1014
1015       --  The following code needs comments ???
1016
1017       if Nkind (Parent (N)) /= N_Package_Body
1018         and then Nkind (Parent (N)) /= N_Accept_Statement
1019         and then not Delay_Cleanups (Current_Scope)
1020       then
1021          Expand_Cleanup_Actions (Parent (N));
1022       else
1023          Set_First_Real_Statement (N, First (Statements (N)));
1024       end if;
1025
1026    end Expand_N_Handled_Sequence_Of_Statements;
1027
1028    -------------------------------------
1029    -- Expand_N_Raise_Constraint_Error --
1030    -------------------------------------
1031
1032    --  The only processing required is to adjust the condition to deal
1033    --  with the C/Fortran boolean case. This may well not be necessary,
1034    --  as all such conditions are generated by the expander and probably
1035    --  are all standard boolean, but who knows what strange optimization
1036    --  in future may require this adjustment!
1037
1038    procedure Expand_N_Raise_Constraint_Error (N : Node_Id) is
1039    begin
1040       Adjust_Condition (Condition (N));
1041    end Expand_N_Raise_Constraint_Error;
1042
1043    ----------------------------------
1044    -- Expand_N_Raise_Program_Error --
1045    ----------------------------------
1046
1047    --  The only processing required is to adjust the condition to deal
1048    --  with the C/Fortran boolean case. This may well not be necessary,
1049    --  as all such conditions are generated by the expander and probably
1050    --  are all standard boolean, but who knows what strange optimization
1051    --  in future may require this adjustment!
1052
1053    procedure Expand_N_Raise_Program_Error (N : Node_Id) is
1054    begin
1055       Adjust_Condition (Condition (N));
1056    end Expand_N_Raise_Program_Error;
1057
1058    ------------------------------
1059    -- Expand_N_Raise_Statement --
1060    ------------------------------
1061
1062    procedure Expand_N_Raise_Statement (N : Node_Id) is
1063       Loc   : constant Source_Ptr := Sloc (N);
1064       Ehand : Node_Id;
1065       E     : Entity_Id;
1066       Str   : String_Id;
1067
1068    begin
1069       --  If a string expression is present, then the raise statement is
1070       --  converted to a call:
1071
1072       --     Raise_Exception (exception-name'Identity, string);
1073
1074       --  and there is nothing else to do
1075
1076       if Present (Expression (N)) then
1077          Rewrite (N,
1078            Make_Procedure_Call_Statement (Loc,
1079              Name => New_Occurrence_Of (RTE (RE_Raise_Exception), Loc),
1080              Parameter_Associations => New_List (
1081                Make_Attribute_Reference (Loc,
1082                  Prefix => Name (N),
1083                  Attribute_Name => Name_Identity),
1084                Expression (N))));
1085          Analyze (N);
1086          return;
1087       end if;
1088
1089       --  Remaining processing is for the case where no string expression
1090       --  is present.
1091
1092       --  There is no expansion needed for statement "raise <exception>;" when
1093       --  compiling for the JVM since the JVM has a built-in exception
1094       --  mechanism. However we need the keep the expansion for "raise;"
1095       --  statements. See 4jexcept.ads for details.
1096
1097       if Present (Name (N)) and then Hostparm.Java_VM then
1098          return;
1099       end if;
1100
1101       --  Don't expand a raise statement that does not come from source
1102       --  if we have already had configurable run-time violations, since
1103       --  most likely it will be junk cascaded nonsense.
1104
1105       if Configurable_Run_Time_Violations > 0
1106         and then not Comes_From_Source (N)
1107       then
1108          return;
1109       end if;
1110
1111       --  Convert explicit raise of Program_Error, Constraint_Error, and
1112       --  Storage_Error into the corresponding raise (in High_Integrity_Mode
1113       --  all other raises will get normal expansion and be disallowed,
1114       --  but this is also faster in all modes).
1115
1116       if Present (Name (N)) and then Nkind (Name (N)) = N_Identifier then
1117          if Entity (Name (N)) = Standard_Constraint_Error then
1118             Rewrite (N,
1119               Make_Raise_Constraint_Error (Loc,
1120                 Reason => CE_Explicit_Raise));
1121             Analyze (N);
1122             return;
1123
1124          elsif Entity (Name (N)) = Standard_Program_Error then
1125             Rewrite (N,
1126               Make_Raise_Program_Error (Loc,
1127                 Reason => PE_Explicit_Raise));
1128             Analyze (N);
1129             return;
1130
1131          elsif Entity (Name (N)) = Standard_Storage_Error then
1132             Rewrite (N,
1133               Make_Raise_Storage_Error (Loc,
1134                 Reason => SE_Explicit_Raise));
1135             Analyze (N);
1136             return;
1137          end if;
1138       end if;
1139
1140       --  Case of name present, in this case we expand raise name to
1141
1142       --    Raise_Exception (name'Identity, location_string);
1143
1144       --  where location_string identifies the file/line of the raise
1145
1146       if Present (Name (N)) then
1147          declare
1148             Id : Entity_Id := Entity (Name (N));
1149
1150          begin
1151             Build_Location_String (Loc);
1152
1153             --  If the exception is a renaming, use the exception that it
1154             --  renames (which might be a predefined exception, e.g.).
1155
1156             if Present (Renamed_Object (Id)) then
1157                Id := Renamed_Object (Id);
1158             end if;
1159
1160             --  Build a C-compatible string in case of no exception handlers,
1161             --  since this is what the last chance handler is expecting.
1162
1163             if Restriction_Active (No_Exception_Handlers) then
1164
1165                --  Generate an empty message if configuration pragma
1166                --  Suppress_Exception_Locations is set for this unit.
1167
1168                if Opt.Exception_Locations_Suppressed then
1169                   Name_Len := 1;
1170                else
1171                   Name_Len := Name_Len + 1;
1172                end if;
1173
1174                Name_Buffer (Name_Len) := ASCII.NUL;
1175             end if;
1176
1177             if Opt.Exception_Locations_Suppressed then
1178                Name_Len := 0;
1179             end if;
1180
1181             Str := String_From_Name_Buffer;
1182
1183             --  For VMS exceptions, convert the raise into a call to
1184             --  lib$stop so it will be handled by __gnat_error_handler.
1185
1186             if Is_VMS_Exception (Id) then
1187                declare
1188                   Excep_Image : String_Id;
1189                   Cond        : Node_Id;
1190
1191                begin
1192                   if Present (Interface_Name (Id)) then
1193                      Excep_Image := Strval (Interface_Name (Id));
1194                   else
1195                      Get_Name_String (Chars (Id));
1196                      Set_All_Upper_Case;
1197                      Excep_Image := String_From_Name_Buffer;
1198                   end if;
1199
1200                   if Exception_Code (Id) /= No_Uint then
1201                      Cond :=
1202                        Make_Integer_Literal (Loc, Exception_Code (Id));
1203                   else
1204                      Cond :=
1205                        Unchecked_Convert_To (Standard_Integer,
1206                          Make_Function_Call (Loc,
1207                            Name => New_Occurrence_Of
1208                              (RTE (RE_Import_Value), Loc),
1209                            Parameter_Associations => New_List
1210                              (Make_String_Literal (Loc,
1211                                Strval => Excep_Image))));
1212                   end if;
1213
1214                   Rewrite (N,
1215                     Make_Procedure_Call_Statement (Loc,
1216                       Name =>
1217                         New_Occurrence_Of (RTE (RE_Lib_Stop), Loc),
1218                       Parameter_Associations => New_List (Cond)));
1219                         Analyze_And_Resolve (Cond, Standard_Integer);
1220                end;
1221
1222             --  Not VMS exception case, convert raise to call to the
1223             --  Raise_Exception routine.
1224
1225             else
1226                Rewrite (N,
1227                  Make_Procedure_Call_Statement (Loc,
1228                     Name => New_Occurrence_Of (RTE (RE_Raise_Exception), Loc),
1229                     Parameter_Associations => New_List (
1230                       Make_Attribute_Reference (Loc,
1231                         Prefix => Name (N),
1232                         Attribute_Name => Name_Identity),
1233                       Make_String_Literal (Loc,
1234                         Strval => Str))));
1235             end if;
1236          end;
1237
1238       --  Case of no name present (reraise). We rewrite the raise to:
1239
1240       --    Reraise_Occurrence_Always (EO);
1241
1242       --  where EO is the current exception occurrence. If the current handler
1243       --  does not have a choice parameter specification, then we provide one.
1244
1245       else
1246          --  Find innermost enclosing exception handler (there must be one,
1247          --  since the semantics has already verified that this raise statement
1248          --  is valid, and a raise with no arguments is only permitted in the
1249          --  context of an exception handler.
1250
1251          Ehand := Parent (N);
1252          while Nkind (Ehand) /= N_Exception_Handler loop
1253             Ehand := Parent (Ehand);
1254          end loop;
1255
1256          --  Make exception choice parameter if none present. Note that we do
1257          --  not need to put the entity on the entity chain, since no one will
1258          --  be referencing this entity by normal visibility methods.
1259
1260          if No (Choice_Parameter (Ehand)) then
1261             E := Make_Defining_Identifier (Loc, New_Internal_Name ('E'));
1262             Set_Choice_Parameter (Ehand, E);
1263             Set_Ekind (E, E_Variable);
1264             Set_Etype (E, RTE (RE_Exception_Occurrence));
1265             Set_Scope (E, Current_Scope);
1266          end if;
1267
1268          --  Now rewrite the raise as a call to Reraise. A special case arises
1269          --  if this raise statement occurs in the context of a handler for
1270          --  all others (i.e. an at end handler). in this case we avoid
1271          --  the call to defer abort, cleanup routines are expected to be
1272          --  called in this case with aborts deferred.
1273
1274          declare
1275             Ech : constant Node_Id := First (Exception_Choices (Ehand));
1276             Ent : Entity_Id;
1277
1278          begin
1279             if Nkind (Ech) = N_Others_Choice
1280               and then All_Others (Ech)
1281             then
1282                Ent := RTE (RE_Reraise_Occurrence_No_Defer);
1283             else
1284                Ent := RTE (RE_Reraise_Occurrence_Always);
1285             end if;
1286
1287             Rewrite (N,
1288               Make_Procedure_Call_Statement (Loc,
1289                 Name => New_Occurrence_Of (Ent, Loc),
1290                 Parameter_Associations => New_List (
1291                   New_Occurrence_Of (Choice_Parameter (Ehand), Loc))));
1292          end;
1293       end if;
1294
1295       Analyze (N);
1296    end Expand_N_Raise_Statement;
1297
1298    ----------------------------------
1299    -- Expand_N_Raise_Storage_Error --
1300    ----------------------------------
1301
1302    --  The only processing required is to adjust the condition to deal
1303    --  with the C/Fortran boolean case. This may well not be necessary,
1304    --  as all such conditions are generated by the expander and probably
1305    --  are all standard boolean, but who knows what strange optimization
1306    --  in future may require this adjustment!
1307
1308    procedure Expand_N_Raise_Storage_Error (N : Node_Id) is
1309    begin
1310       Adjust_Condition (Condition (N));
1311    end Expand_N_Raise_Storage_Error;
1312
1313    ------------------------------
1314    -- Expand_N_Subprogram_Info --
1315    ------------------------------
1316
1317    procedure Expand_N_Subprogram_Info (N : Node_Id) is
1318       Loc : constant Source_Ptr := Sloc (N);
1319
1320    begin
1321       --  For now, we replace an Expand_N_Subprogram_Info node with an
1322       --  attribute reference that gives the address of the procedure.
1323       --  This is because gigi does not yet recognize this node, and
1324       --  for the initial targets, this is the right value anyway.
1325
1326       Rewrite (N,
1327         Make_Attribute_Reference (Loc,
1328           Prefix => Identifier (N),
1329           Attribute_Name => Name_Code_Address));
1330
1331       Analyze_And_Resolve (N, RTE (RE_Code_Loc));
1332    end Expand_N_Subprogram_Info;
1333
1334    ------------------------------------
1335    -- Generate_Subprogram_Descriptor --
1336    ------------------------------------
1337
1338    procedure Generate_Subprogram_Descriptor
1339      (N     : Node_Id;
1340       Loc   : Source_Ptr;
1341       Spec  : Entity_Id;
1342       Slist : List_Id)
1343    is
1344       Code  : Node_Id;
1345       Ent   : Entity_Id;
1346       Decl  : Node_Id;
1347       Dtyp  : Entity_Id;
1348       Numh  : Nat;
1349       Sdes  : Node_Id;
1350       Hrc   : List_Id;
1351
1352    begin
1353       if Exception_Mechanism /= Front_End_ZCX_Exceptions then
1354          return;
1355       end if;
1356
1357       if Restriction_Active (No_Exception_Handlers) then
1358          return;
1359       end if;
1360
1361       --  Suppress descriptor if we are not generating code. This happens
1362       --  in the case of a -gnatc -gnatt compilation where we force generics
1363       --  to be generated, but we still don't want exception tables.
1364
1365       if Operating_Mode /= Generate_Code then
1366          return;
1367       end if;
1368
1369       --  Suppress descriptor if we are in No_Exceptions restrictions mode,
1370       --  since we can never propagate exceptions in any case in this mode.
1371       --  The same consideration applies for No_Exception_Handlers (which
1372       --  is also set in High_Integrity_Mode).
1373
1374       if Restriction_Active (No_Exceptions)
1375         or Restriction_Active (No_Exception_Handlers)
1376       then
1377          return;
1378       end if;
1379
1380       --  Suppress descriptor if we are inside a generic. There are two
1381       --  ways that we can tell that, depending on what is going on. If
1382       --  we are actually inside the processing for a generic right now,
1383       --  then Expander_Active will be reset. If we are outside the
1384       --  generic, then we will see the generic entity.
1385
1386       if not Expander_Active then
1387          return;
1388       end if;
1389
1390       --  Suppress descriptor is subprogram is marked as eliminated, for
1391       --  example if this is a subprogram created to analyze a default
1392       --  expression with potential side effects. Ditto if it is nested
1393       --  within an eliminated subprogram, for example a cleanup action.
1394
1395       declare
1396          Scop : Entity_Id;
1397
1398       begin
1399          Scop := Spec;
1400          while Scop /= Standard_Standard loop
1401             if Is_Generic_Unit (Scop) or else Is_Eliminated (Scop) then
1402                return;
1403             end if;
1404
1405             Scop := Scope (Scop);
1406          end loop;
1407       end;
1408
1409       --  Suppress descriptor for original protected subprogram (we will
1410       --  be called again later to generate the descriptor for the actual
1411       --  protected body subprogram.) This does not apply to barrier
1412       --  functions which are there own protected subprogram.
1413
1414       if Is_Subprogram (Spec)
1415         and then Present (Protected_Body_Subprogram (Spec))
1416         and then Protected_Body_Subprogram (Spec) /= Spec
1417       then
1418          return;
1419       end if;
1420
1421       --  Suppress descriptors for packages unless they have at least one
1422       --  handler. The binder will generate the dummy (no handler) descriptors
1423       --  for elaboration procedures. We can't do it here, because we don't
1424       --  know if an elaboration routine does in fact exist.
1425
1426       --  If there is at least one handler for the package spec or body
1427       --  then most certainly an elaboration routine must exist, so we
1428       --  can safely reference it.
1429
1430       if (Nkind (N) = N_Package_Declaration
1431             or else
1432           Nkind (N) = N_Package_Body)
1433         and then No (Handler_Records (Spec))
1434       then
1435          return;
1436       end if;
1437
1438       --  Suppress all subprogram descriptors for the file System.Exceptions.
1439       --  We similarly suppress subprogram descriptors for Ada.Exceptions.
1440       --  These are all init procs for types which cannot raise exceptions.
1441       --  The reason this is done is that otherwise we get embarassing
1442       --  elaboration dependencies.
1443
1444       Get_Name_String (Unit_File_Name (Current_Sem_Unit));
1445
1446       if Name_Buffer (1 .. 12) = "s-except.ads"
1447            or else
1448          Name_Buffer (1 .. 12) = "a-except.ads"
1449       then
1450          return;
1451       end if;
1452
1453       --  Similarly, we need to suppress entries for System.Standard_Library,
1454       --  since otherwise we get elaboration circularities. Again, this would
1455       --  better be done with a Suppress_Initialization pragma :-)
1456
1457       if Name_Buffer (1 .. 11) = "s-stalib.ad" then
1458          return;
1459       end if;
1460
1461       --  For now, also suppress entries for s-stoele because we have
1462       --  some kind of unexplained error there ???
1463
1464       if Name_Buffer (1 .. 11) = "s-stoele.ad" then
1465          return;
1466       end if;
1467
1468       --  And also for g-htable, because it cannot raise exceptions,
1469       --  and generates some kind of elaboration order problem.
1470
1471       if Name_Buffer (1 .. 11) = "g-htable.ad" then
1472          return;
1473       end if;
1474
1475       --  Suppress subprogram descriptor if already generated. This happens
1476       --  in the case of late generation from Delay_Subprogram_Descriptors
1477       --  beging set (where there is more than one instantiation in the list)
1478
1479       if Has_Subprogram_Descriptor (Spec) then
1480          return;
1481       else
1482          Set_Has_Subprogram_Descriptor (Spec);
1483       end if;
1484
1485       --  Never generate descriptors for inlined bodies
1486
1487       if Analyzing_Inlined_Bodies then
1488          return;
1489       end if;
1490
1491       --  Here we definitely are going to generate a subprogram descriptor
1492
1493       declare
1494          Hnum : Nat := Homonym_Number (Spec);
1495
1496       begin
1497          if Hnum = 1 then
1498             Hnum := 0;
1499          end if;
1500
1501          Ent :=
1502            Make_Defining_Identifier (Loc,
1503              Chars => New_External_Name (Chars (Spec), "SD", Hnum));
1504       end;
1505
1506       if No (Handler_Records (Spec)) then
1507          Hrc  := Empty_List;
1508          Numh := 0;
1509       else
1510          Hrc  := Handler_Records (Spec);
1511          Numh := List_Length (Hrc);
1512       end if;
1513
1514       New_Scope (Spec);
1515
1516       --  We need a static subtype for the declaration of the subprogram
1517       --  descriptor. For the case of 0-3 handlers we can use one of the
1518       --  predefined subtypes in System.Exceptions. For more handlers,
1519       --  we build our own subtype here.
1520
1521       case Numh is
1522          when 0 =>
1523             Dtyp := RTE (RE_Subprogram_Descriptor_0);
1524
1525          when 1 =>
1526             Dtyp := RTE (RE_Subprogram_Descriptor_1);
1527
1528          when 2 =>
1529             Dtyp := RTE (RE_Subprogram_Descriptor_2);
1530
1531          when 3 =>
1532             Dtyp := RTE (RE_Subprogram_Descriptor_3);
1533
1534          when others =>
1535             Dtyp :=
1536               Make_Defining_Identifier (Loc,
1537                 Chars => New_Internal_Name ('T'));
1538
1539             --  Set the constructed type as global, since we will be
1540             --  referencing the object that is of this type globally
1541
1542             Set_Is_Statically_Allocated (Dtyp);
1543
1544             Decl :=
1545               Make_Subtype_Declaration (Loc,
1546                 Defining_Identifier => Dtyp,
1547                 Subtype_Indication =>
1548                   Make_Subtype_Indication (Loc,
1549                     Subtype_Mark =>
1550                       New_Occurrence_Of (RTE (RE_Subprogram_Descriptor), Loc),
1551                     Constraint =>
1552                       Make_Index_Or_Discriminant_Constraint (Loc,
1553                         Constraints => New_List (
1554                           Make_Integer_Literal (Loc, Numh)))));
1555
1556             Append (Decl, Slist);
1557
1558             --  We analyze the descriptor for the subprogram and package
1559             --  case, but not for the imported subprogram case (it will
1560             --  be analyzed when the freeze entity actions are analyzed.
1561
1562             if Present (N) then
1563                Analyze (Decl);
1564             end if;
1565
1566             Set_Exception_Junk (Decl);
1567       end case;
1568
1569       --  Prepare the code address entry for the table entry. For the normal
1570       --  case of being within a procedure, this is simply:
1571
1572       --    P'Code_Address
1573
1574       --  where P is the procedure, but for the package case, it is
1575
1576       --    P'Elab_Body'Code_Address
1577       --    P'Elab_Spec'Code_Address
1578
1579       --  for the body and spec respectively. Note that we do our own
1580       --  analysis of these attribute references, because we know in this
1581       --  case that the prefix of ELab_Body/Spec is a visible package,
1582       --  which can be referenced directly instead of using the general
1583       --  case expansion for these attributes.
1584
1585       if Ekind (Spec) = E_Package then
1586          Code :=
1587            Make_Attribute_Reference (Loc,
1588              Prefix         => New_Occurrence_Of (Spec, Loc),
1589              Attribute_Name => Name_Elab_Spec);
1590          Set_Etype (Code, Standard_Void_Type);
1591          Set_Analyzed (Code);
1592
1593       elsif Ekind (Spec) = E_Package_Body then
1594          Code :=
1595            Make_Attribute_Reference (Loc,
1596              Prefix         => New_Occurrence_Of (Spec_Entity (Spec), Loc),
1597              Attribute_Name => Name_Elab_Body);
1598          Set_Etype (Code, Standard_Void_Type);
1599          Set_Analyzed (Code);
1600
1601       else
1602          Code := New_Occurrence_Of (Spec, Loc);
1603       end if;
1604
1605       Code :=
1606         Make_Attribute_Reference (Loc,
1607           Prefix         => Code,
1608           Attribute_Name => Name_Code_Address);
1609
1610       Set_Etype (Code, RTE (RE_Address));
1611       Set_Analyzed (Code);
1612
1613       --  Now we can build the subprogram descriptor
1614
1615       Sdes :=
1616         Make_Object_Declaration (Loc,
1617           Defining_Identifier      => Ent,
1618           Constant_Present         => True,
1619           Aliased_Present          => True,
1620           Object_Definition        => New_Occurrence_Of (Dtyp, Loc),
1621
1622           Expression               =>
1623             Make_Aggregate (Loc,
1624               Expressions => New_List (
1625                 Make_Integer_Literal (Loc, Numh),          -- Num_Handlers
1626
1627                 Code,                                      -- Code
1628
1629 --  temp code ???
1630
1631 --                Make_Subprogram_Info (Loc,                 -- Subprogram_Info
1632 --                  Identifier =>
1633 --                    New_Occurrence_Of (Spec, Loc)),
1634
1635                 New_Copy_Tree (Code),
1636
1637                 Make_Aggregate (Loc,                       -- Handler_Records
1638                   Expressions => Hrc))));
1639
1640       Set_Exception_Junk (Sdes);
1641       Set_Is_Subprogram_Descriptor (Sdes);
1642
1643       Append (Sdes, Slist);
1644
1645       --  We analyze the descriptor for the subprogram and package case,
1646       --  but not for the imported subprogram case (it will be analyzed
1647       --  when the freeze entity actions are analyzed.
1648
1649       if Present (N) then
1650          Analyze (Sdes);
1651       end if;
1652
1653       --  We can now pop the scope used for analyzing the descriptor
1654
1655       Pop_Scope;
1656
1657       --  We need to set the descriptor as statically allocated, since
1658       --  it will be referenced from the unit exception table.
1659
1660       Set_Is_Statically_Allocated (Ent);
1661
1662       --  Append the resulting descriptor to the list. We do this only
1663       --  if we are in the main unit. You might think that we could
1664       --  simply skip generating the descriptors completely if we are
1665       --  not in the main unit, but in fact this is not the case, since
1666       --  we have problems with inconsistent serial numbers for internal
1667       --  names if we do this.
1668
1669       if In_Extended_Main_Code_Unit (Spec) then
1670          Append_To (SD_List,
1671            Make_Attribute_Reference (Loc,
1672              Prefix => New_Occurrence_Of (Ent, Loc),
1673              Attribute_Name => Name_Unrestricted_Access));
1674
1675          Unit_Exception_Table_Present := True;
1676       end if;
1677
1678    end Generate_Subprogram_Descriptor;
1679
1680    ------------------------------------------------------------
1681    -- Generate_Subprogram_Descriptor_For_Imported_Subprogram --
1682    ------------------------------------------------------------
1683
1684    procedure Generate_Subprogram_Descriptor_For_Imported_Subprogram
1685      (Spec  : Entity_Id;
1686       Slist : List_Id)
1687    is
1688    begin
1689       Generate_Subprogram_Descriptor (Empty, Sloc (Spec), Spec, Slist);
1690    end Generate_Subprogram_Descriptor_For_Imported_Subprogram;
1691
1692    ------------------------------------------------
1693    -- Generate_Subprogram_Descriptor_For_Package --
1694    ------------------------------------------------
1695
1696    procedure Generate_Subprogram_Descriptor_For_Package
1697      (N    : Node_Id;
1698       Spec : Entity_Id)
1699    is
1700       Adecl : Node_Id;
1701
1702    begin
1703       --  If N is empty with prior errors, ignore
1704
1705       if Total_Errors_Detected /= 0 and then No (N) then
1706          return;
1707       end if;
1708
1709       --  Do not generate if no exceptions
1710
1711       if Restriction_Active (No_Exception_Handlers) then
1712          return;
1713       end if;
1714
1715       --  Otherwise generate descriptor
1716
1717       Adecl := Aux_Decls_Node (Parent (N));
1718
1719       if No (Actions (Adecl)) then
1720          Set_Actions (Adecl, New_List);
1721       end if;
1722
1723       Generate_Subprogram_Descriptor (N, Sloc (N), Spec, Actions (Adecl));
1724    end Generate_Subprogram_Descriptor_For_Package;
1725
1726    ---------------------------------------------------
1727    -- Generate_Subprogram_Descriptor_For_Subprogram --
1728    ---------------------------------------------------
1729
1730    procedure Generate_Subprogram_Descriptor_For_Subprogram
1731      (N    : Node_Id;
1732       Spec : Entity_Id)
1733    is
1734    begin
1735       --  If we have no subprogram body and prior errors, ignore
1736
1737       if Total_Errors_Detected /= 0 and then No (N) then
1738          return;
1739       end if;
1740
1741       --  Do not generate if no exceptions
1742
1743       if Restriction_Active (No_Exception_Handlers) then
1744          return;
1745       end if;
1746
1747       --  Else generate descriptor
1748
1749       declare
1750          HSS : constant Node_Id := Handled_Statement_Sequence (N);
1751
1752       begin
1753          if No (Exception_Handlers (HSS)) then
1754             Generate_Subprogram_Descriptor
1755               (N, Sloc (N), Spec, Statements (HSS));
1756          else
1757             Generate_Subprogram_Descriptor
1758               (N, Sloc (N),
1759                Spec, Statements (Last (Exception_Handlers (HSS))));
1760          end if;
1761       end;
1762    end Generate_Subprogram_Descriptor_For_Subprogram;
1763
1764    -----------------------------------
1765    -- Generate_Unit_Exception_Table --
1766    -----------------------------------
1767
1768    --  The only remaining thing to generate here is to generate the
1769    --  reference to the subprogram descriptor chain. See Ada.Exceptions
1770    --  for details of required data structures.
1771
1772    procedure Generate_Unit_Exception_Table is
1773       Loc      : constant Source_Ptr := No_Location;
1774       Num      : Nat;
1775       Decl     : Node_Id;
1776       Ent      : Entity_Id;
1777       Next_Ent : Entity_Id;
1778       Stent    : Entity_Id;
1779
1780    begin
1781       --  Nothing to be done if zero length exceptions not active
1782
1783       if Exception_Mechanism /= Front_End_ZCX_Exceptions then
1784          return;
1785       end if;
1786
1787       --  Nothing to do if no exceptions
1788
1789       if Restriction_Active (No_Exception_Handlers) then
1790          return;
1791       end if;
1792
1793       --  Remove any entries from SD_List that correspond to eliminated
1794       --  subprograms.
1795
1796       Ent := First (SD_List);
1797       while Present (Ent) loop
1798          Next_Ent := Next (Ent);
1799          if Is_Eliminated (Scope (Entity (Prefix (Ent)))) then
1800             Remove (Ent); -- After this, there is no Next (Ent) anymore
1801          end if;
1802
1803          Ent := Next_Ent;
1804       end loop;
1805
1806       --  Nothing to do if no unit exception table present.
1807       --  An empty table can result from subprogram elimination,
1808       --  in such a case, eliminate the exception table itself.
1809
1810       if Is_Empty_List (SD_List) then
1811          Unit_Exception_Table_Present := False;
1812          return;
1813       end if;
1814
1815       --  Do not generate table in a generic
1816
1817       if Inside_A_Generic then
1818          return;
1819       end if;
1820
1821       --  Generate the unit exception table
1822
1823       --    subtype Tnn is Subprogram_Descriptors_Record (Num);
1824       --    __gnat_unitname__SDP : aliased constant Tnn :=
1825       --                             Num,
1826       --                             (sub1'unrestricted_access,
1827       --                              sub2'unrestricted_access,
1828       --                              ...
1829       --                              subNum'unrestricted_access));
1830
1831       Num := List_Length (SD_List);
1832
1833       Stent :=
1834         Make_Defining_Identifier (Loc,
1835           Chars => New_Internal_Name ('T'));
1836
1837       Insert_Library_Level_Action (
1838         Make_Subtype_Declaration (Loc,
1839           Defining_Identifier => Stent,
1840           Subtype_Indication =>
1841             Make_Subtype_Indication (Loc,
1842               Subtype_Mark =>
1843                 New_Occurrence_Of
1844                  (RTE (RE_Subprogram_Descriptors_Record), Loc),
1845               Constraint =>
1846                 Make_Index_Or_Discriminant_Constraint (Loc,
1847                   Constraints => New_List (
1848                     Make_Integer_Literal (Loc, Num))))));
1849
1850       Set_Is_Statically_Allocated (Stent);
1851
1852       Get_External_Unit_Name_String (Unit_Name (Main_Unit));
1853       Name_Buffer (1 + 7 .. Name_Len + 7) := Name_Buffer (1 .. Name_Len);
1854       Name_Buffer (1 .. 7) := "__gnat_";
1855       Name_Len := Name_Len + 7;
1856       Add_Str_To_Name_Buffer ("__SDP");
1857
1858       Ent :=
1859         Make_Defining_Identifier (Loc,
1860           Chars => Name_Find);
1861
1862       Get_Name_String (Chars (Ent));
1863       Set_Interface_Name (Ent,
1864         Make_String_Literal (Loc, Strval => String_From_Name_Buffer));
1865
1866       Decl :=
1867         Make_Object_Declaration (Loc,
1868              Defining_Identifier => Ent,
1869              Object_Definition   => New_Occurrence_Of (Stent, Loc),
1870           Constant_Present => True,
1871           Aliased_Present  => True,
1872           Expression =>
1873             Make_Aggregate (Loc,
1874               New_List (
1875                 Make_Integer_Literal (Loc, List_Length (SD_List)),
1876
1877               Make_Aggregate (Loc,
1878                 Expressions => SD_List))));
1879
1880       Insert_Library_Level_Action (Decl);
1881
1882       Set_Is_Exported             (Ent, True);
1883       Set_Is_Public               (Ent, True);
1884       Set_Is_Statically_Allocated (Ent, True);
1885
1886       Get_Name_String (Chars (Ent));
1887       Set_Interface_Name (Ent,
1888         Make_String_Literal (Loc,
1889           Strval => String_From_Name_Buffer));
1890
1891    end Generate_Unit_Exception_Table;
1892
1893    ----------------
1894    -- Initialize --
1895    ----------------
1896
1897    procedure Initialize is
1898    begin
1899       SD_List := Empty_List;
1900    end Initialize;
1901
1902    ----------------------
1903    -- Is_Non_Ada_Error --
1904    ----------------------
1905
1906    function Is_Non_Ada_Error (E : Entity_Id) return Boolean is
1907    begin
1908       if not OpenVMS_On_Target then
1909          return False;
1910       end if;
1911
1912       Get_Name_String (Chars (E));
1913
1914       --  Note: it is a little irregular for the body of exp_ch11 to know
1915       --  the details of the encoding scheme for names, but on the other
1916       --  hand, gigi knows them, and this is for gigi's benefit anyway!
1917
1918       if Name_Buffer (1 .. 30) /= "system__aux_dec__non_ada_error" then
1919          return False;
1920       end if;
1921
1922       return True;
1923    end Is_Non_Ada_Error;
1924
1925    ----------------------------
1926    -- Remove_Handler_Entries --
1927    ----------------------------
1928
1929    procedure Remove_Handler_Entries (N : Node_Id) is
1930       function Check_Handler_Entry (N : Node_Id) return Traverse_Result;
1931       --  This function checks one node for a possible reference to a
1932       --  handler entry that must be deleted. it always returns OK.
1933
1934       function Remove_All_Handler_Entries is new
1935         Traverse_Func (Check_Handler_Entry);
1936       --  This defines the traversal operation
1937
1938       Discard : Traverse_Result;
1939       pragma Warnings (Off, Discard);
1940
1941       function Check_Handler_Entry (N : Node_Id) return Traverse_Result is
1942       begin
1943          if Nkind (N) = N_Object_Declaration then
1944
1945             if Present (Handler_List_Entry (N)) then
1946                Remove (Handler_List_Entry (N));
1947                Delete_Tree (Handler_List_Entry (N));
1948                Set_Handler_List_Entry (N, Empty);
1949
1950             elsif Is_Subprogram_Descriptor (N) then
1951                declare
1952                   SDN : Node_Id;
1953
1954                begin
1955                   SDN := First (SD_List);
1956                   while Present (SDN) loop
1957                      if Defining_Identifier (N) = Entity (Prefix (SDN)) then
1958                         Remove (SDN);
1959                         Delete_Tree (SDN);
1960                         exit;
1961                      end if;
1962
1963                      Next (SDN);
1964                   end loop;
1965                end;
1966             end if;
1967          end if;
1968
1969          return OK;
1970       end Check_Handler_Entry;
1971
1972    --  Start of processing for Remove_Handler_Entries
1973
1974    begin
1975       if Exception_Mechanism = Front_End_ZCX_Exceptions then
1976          Discard := Remove_All_Handler_Entries (N);
1977       end if;
1978    end Remove_Handler_Entries;
1979
1980 end Exp_Ch11;