gcc/ada/elists.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               E L I S T S                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-1998 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This package provides facilities for manipulating lists of nodes (see
  36 --  package Atree for format and implementation of tree nodes). Separate list
  37 --  elements are allocated to represent elements of these lists, so it is
  38 --  possible for a given node to be on more than one element list at a time.
  39 --  See also package Nlists, which provides another form that is threaded
  40 --  through the nodes themselves (using the Link field), which is more time
  41 --  and space efficient, but a node can be only one such list.
  42
  43 with Types;  use Types;
  44 with System;
  45
  46 package Elists is
  47
  48    --  An element list is represented by a header that is allocated in the
  49    --  Elist header table. This header contains pointers to the first and
  50    --  last elements in the list, or to No_Elmt if the list is empty.
  51
  52    --  The elements in the list each contain a pointer to the next element
  53    --  and a pointer to the referenced node. Putting a node into an element
  54    --  list causes no change at all to the node itself, so a node may be
  55    --  included in multiple element lists, and the nodes thus included may
  56    --  or may not be elements of node lists (see package Nlists).
  57
  58    procedure Initialize;
  59    --  Initialize allocation of element list tables. Called at the start of
  60    --  compiling each new main source file. Note that Initialize must not be
  61    --  called if Tree_Read is used.
  62
  63    procedure Lock;
  64    --  Lock tables used for element lists before calling backend
  65
  66    procedure Tree_Read;
  67    --  Initializes internal tables from current tree file using Tree_Read.
  68    --  Note that Initialize should not be called if Tree_Read is used.
  69    --  Tree_Read includes all necessary initialization.
  70
  71    procedure Tree_Write;
  72    --  Writes out internal tables to current tree file using Tree_Write
  73
  74    function Last_Elist_Id return Elist_Id;
  75    --  Returns Id of last allocated element list header
  76
  77    function Elists_Address return System.Address;
  78    --  Return address of Elists table (used in Back_End for Gigi call)
  79
  80    function Num_Elists return Nat;
  81    --  Number of currently allocated element lists
  82
  83    function Last_Elmt_Id return Elmt_Id;
  84    --  Returns Id of last allocated list element
  85
  86    function Elmts_Address return System.Address;
  87    --  Return address of Elmts table (used in Back_End for Gigi call)
  88
  89    function Node (Elmt : Elmt_Id) return Node_Id;
  90    pragma Inline (Node);
  91    --  Returns the value of a given list element. Returns Empty if Elmt
  92    --  is set to No_Elmt.
  93
  94    function New_Elmt_List return Elist_Id;
  95    --  Creates a new empty element list. Typically this is used to initialize
  96    --  a field in some other node which points to an element list where the
  97    --  list is then subsequently filled in using Append calls.
  98
  99    function First_Elmt (List : Elist_Id) return Elmt_Id;
 100    pragma Inline (First_Elmt);
 101    --  Obtains the first element of the given element list or, if the
 102    --  list has no items, then No_Elmt is returned.
 103
 104    function Last_Elmt (List : Elist_Id) return Elmt_Id;
 105    pragma Inline (Last_Elmt);
 106    --  Obtains the last element of the given element list or, if the
 107    --  list has no items, then No_Elmt is returned.
 108
 109    function Next_Elmt (Elmt : Elmt_Id) return Elmt_Id;
 110    pragma Inline (Next_Elmt);
 111    --  This function returns the next element on an element list. The argument
 112    --  must be a list element other than No_Elmt. Returns No_Elmt if the given
 113    --  element is the last element of the list.
 114
 115    procedure Next_Elmt (Elmt : in out Elmt_Id);
 116    pragma Inline (Next_Elmt);
 117    --  Next_Elmt (Elmt) is equivalent to Elmt := Next_Elmt (Elmt)
 118
 119    function Is_Empty_Elmt_List (List : Elist_Id) return Boolean;
 120    pragma Inline (Is_Empty_Elmt_List);
 121    --  This function determines if a given tree id references an element list
 122    --  that contains no items.
 123
 124    procedure Append_Elmt (Node : Node_Id; To : Elist_Id);
 125    --  Appends Node at the end of To, allocating a new element.
 126
 127    procedure Prepend_Elmt (Node : Node_Id; To : Elist_Id);
 128    --  Appends Node at the beginning of To, allocating a new element.
 129
 130    procedure Insert_Elmt_After (Node : Node_Id; Elmt : Elmt_Id);
 131    --  Add a new element (Node) right after the pre-existing element Elmt
 132    --  It is invalid to call this subprogram with Elmt = No_Elmt.
 133
 134    procedure Replace_Elmt (Elmt : Elmt_Id; New_Node : Node_Id);
 135    pragma Inline (Replace_Elmt);
 136    --  Causes the given element of the list to refer to New_Node, the node
 137    --  which was previously referred to by Elmt is effectively removed from
 138    --  the list and replaced by New_Node.
 139
 140    procedure Remove_Elmt (List : Elist_Id; Elmt : Elmt_Id);
 141    --  Removes Elmt from the given list. The node itself is not affected,
 142    --  but the space used by the list element may be (but is not required
 143    --  to be) freed for reuse in a subsequent Append_Elmt call.
 144
 145    procedure Remove_Last_Elmt (List : Elist_Id);
 146    --  Removes the last element of the given list. The node itself is not
 147    --  affected, but the space used by the list element may be (but is not
 148    --  required to be) freed for reuse in a subsequent Append_Elmt call.
 149
 150    function No (List : Elist_Id) return Boolean;
 151    pragma Inline (No);
 152    --  Tests given Id for equality with No_Elist. This allows notations like
 153    --  "if No (Statements)" as opposed to "if Statements = No_Elist".
 154
 155    function Present (List : Elist_Id) return Boolean;
 156    pragma Inline (Present);
 157    --  Tests given Id for inequality with No_Elist. This allows notations like
 158    --  "if Present (Statements)" as opposed to "if Statements /= No_Elist".
 159
 160    function No (Elmt : Elmt_Id) return Boolean;
 161    pragma Inline (No);
 162    --  Tests given Id for equality with No_Elmt. This allows notations like
 163    --  "if No (Operation)" as opposed to "if Operation = No_Elmt".
 164
 165    function Present (Elmt : Elmt_Id) return Boolean;
 166    pragma Inline (Present);
 167    --  Tests given Id for inequality with No_Elmt. This allows notations like
 168    --  "if Present (Operation)" as opposed to "if Operation /= No_Elmt".
 169
 170 end Elists;