gcc/ada/binde.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                B I N D E                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Binderr;  use Binderr;
  27 with Butil;    use Butil;
  28 with Debug;    use Debug;
  29 with Fname;    use Fname;
  30 with Namet;    use Namet;
  31 with Opt;      use Opt;
  32 with Osint;
  33 with Output;   use Output;
  34 with Targparm; use Targparm;
  35
  36 with System.Case_Util; use System.Case_Util;
  37
  38 package body Binde is
  39
  40    --  The following data structures are used to represent the graph that is
  41    --  used to determine the elaboration order (using a topological sort).
  42
  43    --  The following structures are used to record successors. If A is a
  44    --  successor of B in this table, it means that A must be elaborated
  45    --  before B is elaborated.
  46
  47    type Successor_Id is new Nat;
  48    --  Identification of single successor entry
  49
  50    No_Successor : constant Successor_Id := 0;
  51    --  Used to indicate end of list of successors
  52
  53    type Elab_All_Id is new Nat;
  54    --  Identification of Elab_All entry link
  55
  56    No_Elab_All_Link : constant Elab_All_Id := 0;
  57    --  Used to indicate end of list
  58
  59    --  Succ_Reason indicates the reason for a particular elaboration link
  60
  61    type Succ_Reason is
  62      (Withed,
  63       --  After directly with's Before, so the spec of Before must be
  64       --  elaborated before After is elaborated.
  65
  66       Elab,
  67       --  After directly mentions Before in a pragma Elaborate, so the
  68       --  body of Before must be elaborate before After is elaborated.
  69
  70       Elab_All,
  71       --  After either mentions Before directly in a pragma Elaborate_All,
  72       --  or mentions a third unit, X, which itself requires that Before be
  73       --  elaborated before unit X is elaborated. The Elab_All_Link list
  74       --  traces the dependencies in the latter case.
  75
  76       Elab_All_Desirable,
  77       --  This is just like Elab_All, except that the elaborate all was not
  78       --  explicitly present in the source, but rather was created by the
  79       --  front end, which decided that it was "desirable".
  80
  81       Elab_Desirable,
  82       --  This is just like Elab, except that the elaborate was not
  83       --  explicitly present in the source, but rather was created by the
  84       --  front end, which decided that it was "desirable".
  85
  86       Spec_First);
  87       --  After is a body, and Before is the corresponding spec
  88
  89    --  Successor_Link contains the information for one link
  90
  91    type Successor_Link is record
  92       Before : Unit_Id;
  93       --  Predecessor unit
  94
  95       After : Unit_Id;
  96       --  Successor unit
  97
  98       Next : Successor_Id;
  99       --  Next successor on this list
 100
 101       Reason : Succ_Reason;
 102       --  Reason for this link
 103
 104       Elab_Body : Boolean;
 105       --  Set True if this link is needed for the special Elaborate_Body
 106       --  processing described below.
 107
 108       Reason_Unit : Unit_Id;
 109       --  For Reason = Elab, or Elab_All or Elab_Desirable, records the unit
 110       --  containing the pragma leading to the link.
 111
 112       Elab_All_Link : Elab_All_Id;
 113       --  If Reason = Elab_All or Elab_Desirable, then this points to the
 114       --  first elment in a list of Elab_All entries that record the with
 115       --  chain leading resulting in this particular dependency.
 116
 117    end record;
 118
 119    --  Note on handling of Elaborate_Body. Basically, if we have a pragma
 120    --  Elaborate_Body in a unit, it means that the spec and body have to
 121    --  be handled as a single entity from the point of view of determining
 122    --  an elaboration order. What we do is to essentially remove the body
 123    --  from consideration completely, and transfer all its links (other
 124    --  than the spec link) to the spec. Then when then the spec gets chosen,
 125    --  we choose the body right afterwards. We mark the links that get moved
 126    --  from the body to the spec by setting their Elab_Body flag True, so
 127    --  that we can understand what is going on!
 128
 129    Succ_First : constant := 1;
 130
 131    package Succ is new Table.Table (
 132      Table_Component_Type => Successor_Link,
 133      Table_Index_Type     => Successor_Id,
 134      Table_Low_Bound      => Succ_First,
 135      Table_Initial        => 500,
 136      Table_Increment      => 200,
 137      Table_Name           => "Succ");
 138
 139    --  For the case of Elaborate_All, the following table is used to record
 140    --  chains of with relationships that lead to the Elab_All link. These
 141    --  are used solely for diagnostic purposes
 142
 143    type Elab_All_Entry is record
 144       Needed_By : Unit_Name_Type;
 145       --  Name of unit from which referencing unit was with'ed or otherwise
 146       --  needed as a result of Elaborate_All or Elaborate_Desirable.
 147
 148       Next_Elab : Elab_All_Id;
 149       --  Link to next entry on chain (No_Elab_All_Link marks end of list)
 150    end record;
 151
 152    package Elab_All_Entries is new Table.Table (
 153      Table_Component_Type => Elab_All_Entry,
 154      Table_Index_Type     => Elab_All_Id,
 155      Table_Low_Bound      => 1,
 156      Table_Initial        => 2000,
 157      Table_Increment      => 200,
 158      Table_Name           => "Elab_All_Entries");
 159
 160    --  A Unit_Node record is built for each active unit
 161
 162    type Unit_Node_Record is record
 163
 164       Successors : Successor_Id;
 165       --  Pointer to list of links for successor nodes
 166
 167       Num_Pred : Int;
 168       --  Number of predecessors for this unit. Normally non-negative, but
 169       --  can go negative in the case of units chosen by the diagnose error
 170       --  procedure (when cycles are being removed from the graph).
 171
 172       Nextnp : Unit_Id;
 173       --  Forward pointer for list of units with no predecessors
 174
 175       Elab_Order : Nat;
 176       --  Position in elaboration order (zero = not placed yet)
 177
 178       Visited : Boolean;
 179       --  Used in computing transitive closure for elaborate all and
 180       --  also in locating cycles and paths in the diagnose routines.
 181
 182       Elab_Position : Natural;
 183       --  Initialized to zero. Set non-zero when a unit is chosen and
 184       --  placed in the elaboration order. The value represents the
 185       --  ordinal position in the elaboration order.
 186
 187    end record;
 188
 189    package UNR is new Table.Table (
 190      Table_Component_Type => Unit_Node_Record,
 191      Table_Index_Type     => Unit_Id,
 192      Table_Low_Bound      => First_Unit_Entry,
 193      Table_Initial        => 500,
 194      Table_Increment      => 200,
 195      Table_Name           => "UNR");
 196
 197    No_Pred : Unit_Id;
 198    --  Head of list of items with no predecessors
 199
 200    Num_Left : Int;
 201    --  Number of entries not yet dealt with
 202
 203    Cur_Unit : Unit_Id;
 204    --  Current unit, set by Gather_Dependencies, and picked up in Build_Link
 205    --  to set the Reason_Unit field of the created dependency link.
 206
 207    Num_Chosen : Natural := 0;
 208    --  Number of units chosen in the elaboration order so far
 209
 210    -----------------------
 211    -- Local Subprograms --
 212    -----------------------
 213
 214    function Better_Choice (U1, U2 : Unit_Id) return Boolean;
 215    --  U1 and U2 are both permitted candidates for selection as the next unit
 216    --  to be elaborated. This function determines whether U1 is a better choice
 217    --  than U2, i.e. should be elaborated in preference to U2, based on a set
 218    --  of heuristics that establish a friendly and predictable order (see body
 219    --  for details). The result is True if U1 is a better choice than U2, and
 220    --  False if it is a worse choice, or there is no preference between them.
 221
 222    procedure Build_Link
 223      (Before : Unit_Id;
 224       After  : Unit_Id;
 225       R      : Succ_Reason;
 226       Ea_Id  : Elab_All_Id := No_Elab_All_Link);
 227    --  Establish a successor link, Before must be elaborated before After,
 228    --  and the reason for the link is R. Ea_Id is the contents to be placed
 229    --  in the Elab_All_Link of the entry.
 230
 231    procedure Choose (Chosen : Unit_Id);
 232    --  Chosen is the next entry chosen in the elaboration order. This
 233    --  procedure updates all data structures appropriately.
 234
 235    function Corresponding_Body (U : Unit_Id) return Unit_Id;
 236    pragma Inline (Corresponding_Body);
 237    --  Given a unit which is a spec for which there is a separate body,
 238    --  return the unit id of the body. It is an error to call this routine
 239    --  with a unit that is not a spec, or which does not have a separate body.
 240
 241    function Corresponding_Spec (U : Unit_Id) return Unit_Id;
 242    pragma Inline (Corresponding_Spec);
 243    --  Given a unit which is a body for which there is a separate spec,
 244    --  return the unit id of the spec. It is an error to call this routine
 245    --  with a unit that is not a body, or which does not have a separate spec.
 246
 247    procedure Diagnose_Elaboration_Problem;
 248    --  Called when no elaboration order can be found. Outputs an appropriate
 249    --  diagnosis of the problem, and then abandons the bind.
 250
 251    procedure Elab_All_Links
 252      (Before : Unit_Id;
 253       After  : Unit_Id;
 254       Reason : Succ_Reason;
 255       Link   : Elab_All_Id);
 256    --  Used to compute the transitive closure of elaboration links for an
 257    --  Elaborate_All pragma (Reason = Elab_All) or for an indication of
 258    --  Elaborate_All_Desirable (Reason = Elab_All_Desirable). Unit After has
 259    --  a pragma Elaborate_All or the front end has determined that a reference
 260    --  probably requires Elaborate_All is required, and unit Before must be
 261    --  previously elaborated. First a link is built making sure that unit
 262    --  Before is elaborated before After, then a recursive call ensures that
 263    --  we also build links for any units needed by Before (i.e. these units
 264    --  must/should also be elaborated before After). Link is used to build
 265    --  a chain of Elab_All_Entries to explain the reason for a link. The
 266    --  value passed is the chain so far.
 267
 268    procedure Elab_Error_Msg (S : Successor_Id);
 269    --  Given a successor link, outputs an error message of the form
 270    --  "$ must be elaborated before $ ..." where ... is the reason.
 271
 272    procedure Gather_Dependencies;
 273    --  Compute dependencies, building the Succ and UNR tables
 274
 275    function Is_Body_Unit (U : Unit_Id) return Boolean;
 276    pragma Inline (Is_Body_Unit);
 277    --  Determines if given unit is a body
 278
 279    function Is_Waiting_Body (U : Unit_Id) return Boolean;
 280    pragma Inline (Is_Waiting_Body);
 281    --  Determines if U is a waiting body, defined as a body which has
 282    --  not been elaborated, but whose spec has been elaborated.
 283
 284    function Make_Elab_Entry
 285      (Unam : Unit_Name_Type;
 286       Link : Elab_All_Id) return Elab_All_Id;
 287    --  Make an Elab_All_Entries table entry with the given Unam and Link
 288
 289    function Unit_Id_Of (Uname : Unit_Name_Type) return Unit_Id;
 290    --  This function uses the Info field set in the names table to obtain
 291    --  the unit Id of a unit, given its name id value.
 292
 293    function Worse_Choice (U1, U2 : Unit_Id) return Boolean;
 294    --  This is like Better_Choice, and has the same interface, but returns
 295    --  true if U1 is a worse choice than U2 in the sense of the -h (horrible
 296    --  elaboration order) switch. We still have to obey Ada rules, so it is
 297    --  not quite the direct inverse of Better_Choice.
 298
 299    procedure Write_Dependencies;
 300    --  Write out dependencies (called only if appropriate option is set)
 301
 302    procedure Write_Elab_All_Chain (S : Successor_Id);
 303    --  If the reason for the link S is Elaborate_All or Elaborate_Desirable,
 304    --  then this routine will output the "needed by" explanation chain.
 305
 306    -------------------
 307    -- Better_Choice --
 308    -------------------
 309
 310    function Better_Choice (U1, U2 : Unit_Id) return Boolean is
 311       UT1 : Unit_Record renames Units.Table (U1);
 312       UT2 : Unit_Record renames Units.Table (U2);
 313
 314    begin
 315       if Debug_Flag_B then
 316          Write_Str ("Better_Choice (");
 317          Write_Unit_Name (UT1.Uname);
 318          Write_Str (", ");
 319          Write_Unit_Name (UT2.Uname);
 320          Write_Line (")");
 321       end if;
 322
 323       --  Note: the checks here are applied in sequence, and the ordering is
 324       --  significant (i.e. the more important criteria are applied first).
 325
 326       --  Prefer a waiting body to any other case
 327
 328       if Is_Waiting_Body (U1) and not Is_Waiting_Body (U2) then
 329          if Debug_Flag_B then
 330             Write_Line ("  True: u1 is waiting body, u2 is not");
 331          end if;
 332
 333          return True;
 334
 335       elsif Is_Waiting_Body (U2) and not Is_Waiting_Body (U1) then
 336          if Debug_Flag_B then
 337             Write_Line ("  False: u2 is waiting body, u1 is not");
 338          end if;
 339
 340          return False;
 341
 342       --  Prefer a predefined unit to a non-predefined unit
 343
 344       elsif UT1.Predefined and not UT2.Predefined then
 345          if Debug_Flag_B then
 346             Write_Line ("  True: u1 is predefined, u2 is not");
 347          end if;
 348
 349          return True;
 350
 351       elsif UT2.Predefined and not UT1.Predefined then
 352          if Debug_Flag_B then
 353             Write_Line ("  False: u2 is predefined, u1 is not");
 354          end if;
 355
 356          return False;
 357
 358       --  Prefer an internal unit to a non-internal unit
 359
 360       elsif UT1.Internal and not UT2.Internal then
 361          if Debug_Flag_B then
 362             Write_Line ("  True: u1 is internal, u2 is not");
 363          end if;
 364          return True;
 365
 366       elsif UT2.Internal and not UT1.Internal then
 367          if Debug_Flag_B then
 368             Write_Line ("  False: u2 is internal, u1 is not");
 369          end if;
 370
 371          return False;
 372
 373       --  Prefer a body to a spec
 374
 375       elsif Is_Body_Unit (U1) and not Is_Body_Unit (U2) then
 376          if Debug_Flag_B then
 377             Write_Line ("  True: u1 is body, u2 is not");
 378          end if;
 379
 380          return True;
 381
 382       elsif Is_Body_Unit (U2) and not Is_Body_Unit (U1) then
 383          if Debug_Flag_B then
 384             Write_Line ("  False: u2 is body, u1 is not");
 385          end if;
 386
 387          return False;
 388
 389       --  If both are waiting bodies, then prefer the one whose spec is
 390       --  more recently elaborated. Consider the following:
 391
 392       --     spec of A
 393       --     spec of B
 394       --     body of A or B?
 395
 396       --  The normal waiting body preference would have placed the body of
 397       --  A before the spec of B if it could. Since it could not, there it
 398       --  must be the case that A depends on B. It is therefore a good idea
 399       --  to put the body of B first.
 400
 401       elsif Is_Waiting_Body (U1) and then Is_Waiting_Body (U2) then
 402          declare
 403             Result : constant Boolean :=
 404                        UNR.Table (Corresponding_Spec (U1)).Elab_Position >
 405                        UNR.Table (Corresponding_Spec (U2)).Elab_Position;
 406          begin
 407             if Debug_Flag_B then
 408                if Result then
 409                   Write_Line ("  True: based on waiting body elab positions");
 410                else
 411                   Write_Line ("  False: based on waiting body elab positions");
 412                end if;
 413             end if;
 414
 415             return Result;
 416          end;
 417       end if;
 418
 419       --  Remaining choice rules are disabled by Debug flag -do
 420
 421       if not Debug_Flag_O then
 422
 423          --  The following deal with the case of specs which have been marked
 424          --  as Elaborate_Body_Desirable. We generally want to delay these
 425          --  specs as long as possible, so that the bodies have a better chance
 426          --  of being elaborated closer to the specs.
 427
 428          --  If we have two units, one of which is a spec for which this flag
 429          --  is set, and the other is not, we prefer to delay the spec for
 430          --  which the flag is set.
 431
 432          if not UT1.Elaborate_Body_Desirable
 433            and then UT2.Elaborate_Body_Desirable
 434          then
 435             if Debug_Flag_B then
 436                Write_Line ("  True: u1 is elab body desirable, u2 is not");
 437             end if;
 438
 439             return True;
 440
 441          elsif not UT2.Elaborate_Body_Desirable
 442            and then UT1.Elaborate_Body_Desirable
 443          then
 444             if Debug_Flag_B then
 445                Write_Line ("  False: u1 is elab body desirable, u2 is not");
 446             end if;
 447
 448             return False;
 449
 450             --  If we have two specs that are both marked as Elaborate_Body
 451             --  desirable, we prefer the one whose body is nearer to being able
 452             --  to be elaborated, based on the Num_Pred count. This helps to
 453             --  ensure bodies are as close to specs as possible.
 454
 455          elsif UT1.Elaborate_Body_Desirable
 456            and then UT2.Elaborate_Body_Desirable
 457          then
 458             declare
 459                Result : constant Boolean :=
 460                           UNR.Table (Corresponding_Body (U1)).Num_Pred <
 461                           UNR.Table (Corresponding_Body (U2)).Num_Pred;
 462             begin
 463                if Debug_Flag_B then
 464                   if Result then
 465                      Write_Line ("  True based on Num_Pred compare");
 466                   else
 467                      Write_Line ("  False based on Num_Pred compare");
 468                   end if;
 469                end if;
 470
 471                return Result;
 472             end;
 473          end if;
 474       end if;
 475
 476       --  If we fall through, it means that no preference rule applies, so we
 477       --  use alphabetical order to at least give a deterministic result.
 478
 479       if Debug_Flag_B then
 480          Write_Line ("  choose on alpha order");
 481       end if;
 482
 483       return Uname_Less (UT1.Uname, UT2.Uname);
 484    end Better_Choice;
 485
 486    ----------------
 487    -- Build_Link --
 488    ----------------
 489
 490    procedure Build_Link
 491      (Before : Unit_Id;
 492       After  : Unit_Id;
 493       R      : Succ_Reason;
 494       Ea_Id  : Elab_All_Id := No_Elab_All_Link)
 495    is
 496       Cspec : Unit_Id;
 497
 498    begin
 499       Succ.Increment_Last;
 500       Succ.Table (Succ.Last).Before          := Before;
 501       Succ.Table (Succ.Last).Next            := UNR.Table (Before).Successors;
 502       UNR.Table (Before).Successors          := Succ.Last;
 503       Succ.Table (Succ.Last).Reason          := R;
 504       Succ.Table (Succ.Last).Reason_Unit     := Cur_Unit;
 505       Succ.Table (Succ.Last).Elab_All_Link   := Ea_Id;
 506
 507       --  Deal with special Elab_Body case. If the After of this link is
 508       --  a body whose spec has Elaborate_All set, and this is not the link
 509       --  directly from the body to the spec, then we make the After of the
 510       --  link reference its spec instead, marking the link appropriately.
 511
 512       if Units.Table (After).Utype = Is_Body then
 513          Cspec := Corresponding_Spec (After);
 514
 515          if Units.Table (Cspec).Elaborate_Body
 516            and then Cspec /= Before
 517          then
 518             Succ.Table (Succ.Last).After     := Cspec;
 519             Succ.Table (Succ.Last).Elab_Body := True;
 520             UNR.Table (Cspec).Num_Pred       := UNR.Table (Cspec).Num_Pred + 1;
 521             return;
 522          end if;
 523       end if;
 524
 525       --  Fall through on normal case
 526
 527       Succ.Table (Succ.Last).After           := After;
 528       Succ.Table (Succ.Last).Elab_Body       := False;
 529       UNR.Table (After).Num_Pred             := UNR.Table (After).Num_Pred + 1;
 530    end Build_Link;
 531
 532    ------------
 533    -- Choose --
 534    ------------
 535
 536    procedure Choose (Chosen : Unit_Id) is
 537       S : Successor_Id;
 538       U : Unit_Id;
 539
 540    begin
 541       if Debug_Flag_C then
 542          Write_Str ("Choosing Unit ");
 543          Write_Unit_Name (Units.Table (Chosen).Uname);
 544          Write_Eol;
 545       end if;
 546
 547       --  Add to elaboration order. Note that units having no elaboration
 548       --  code are not treated specially yet. The special casing of this
 549       --  is in Bindgen, where Gen_Elab_Calls skips over them. Meanwhile
 550       --  we need them here, because the object file list is also driven
 551       --  by the contents of the Elab_Order table.
 552
 553       Elab_Order.Increment_Last;
 554       Elab_Order.Table (Elab_Order.Last) := Chosen;
 555
 556       --  Remove from No_Pred list. This is a little inefficient and may
 557       --  be we should doubly link the list, but it will do for now!
 558
 559       if No_Pred = Chosen then
 560          No_Pred := UNR.Table (Chosen).Nextnp;
 561
 562       else
 563          --  Note that we just ignore the situation where it does not
 564          --  appear in the No_Pred list, this happens in calls from the
 565          --  Diagnose_Elaboration_Problem routine, where cycles are being
 566          --  removed arbitrarily from the graph.
 567
 568          U := No_Pred;
 569          while U /= No_Unit_Id loop
 570             if UNR.Table (U).Nextnp = Chosen then
 571                UNR.Table (U).Nextnp := UNR.Table (Chosen).Nextnp;
 572                exit;
 573             end if;
 574
 575             U := UNR.Table (U).Nextnp;
 576          end loop;
 577       end if;
 578
 579       --  For all successors, decrement the number of predecessors, and
 580       --  if it becomes zero, then add to no predecessor list.
 581
 582       S := UNR.Table (Chosen).Successors;
 583       while S /= No_Successor loop
 584          U := Succ.Table (S).After;
 585          UNR.Table (U).Num_Pred := UNR.Table (U).Num_Pred - 1;
 586
 587          if Debug_Flag_N then
 588             Write_Str ("  decrementing Num_Pred for unit ");
 589             Write_Unit_Name (Units.Table (U).Uname);
 590             Write_Str (" new value = ");
 591             Write_Int (Int (UNR.Table (U).Num_Pred));
 592             Write_Eol;
 593          end if;
 594
 595          if UNR.Table (U).Num_Pred = 0 then
 596             UNR.Table (U).Nextnp := No_Pred;
 597             No_Pred := U;
 598          end if;
 599
 600          S := Succ.Table (S).Next;
 601       end loop;
 602
 603       --  All done, adjust number of units left count and set elaboration pos
 604
 605       Num_Left := Num_Left - 1;
 606       Num_Chosen := Num_Chosen + 1;
 607       UNR.Table (Chosen).Elab_Position := Num_Chosen;
 608       Units.Table (Chosen).Elab_Position := Num_Chosen;
 609
 610       --  If we just chose a spec with Elaborate_Body set, then we
 611       --  must immediately elaborate the body, before any other units.
 612
 613       if Units.Table (Chosen).Elaborate_Body then
 614
 615          --  If the unit is a spec only, then there is no body. This is a bit
 616          --  odd given that Elaborate_Body is here, but it is valid in an
 617          --  RCI unit, where we only have the interface in the stub bind.
 618
 619          if Units.Table (Chosen).Utype = Is_Spec_Only
 620            and then Units.Table (Chosen).RCI
 621          then
 622             null;
 623          else
 624             Choose (Corresponding_Body (Chosen));
 625          end if;
 626       end if;
 627    end Choose;
 628
 629    ------------------------
 630    -- Corresponding_Body --
 631    ------------------------
 632
 633    --  Currently if the body and spec are separate, then they appear as
 634    --  two separate units in the same ALI file, with the body appearing
 635    --  first and the spec appearing second.
 636
 637    function Corresponding_Body (U : Unit_Id) return Unit_Id is
 638    begin
 639       pragma Assert (Units.Table (U).Utype = Is_Spec);
 640       return U - 1;
 641    end Corresponding_Body;
 642
 643    ------------------------
 644    -- Corresponding_Spec --
 645    ------------------------
 646
 647    --  Currently if the body and spec are separate, then they appear as
 648    --  two separate units in the same ALI file, with the body appearing
 649    --  first and the spec appearing second.
 650
 651    function Corresponding_Spec (U : Unit_Id) return Unit_Id is
 652    begin
 653       pragma Assert (Units.Table (U).Utype = Is_Body);
 654       return U + 1;
 655    end Corresponding_Spec;
 656
 657    ----------------------------------
 658    -- Diagnose_Elaboration_Problem --
 659    ----------------------------------
 660
 661    procedure Diagnose_Elaboration_Problem is
 662
 663       function Find_Path (Ufrom, Uto : Unit_Id; ML : Nat) return Boolean;
 664       --  Recursive routine used to find a path from node Ufrom to node Uto.
 665       --  If a path exists, returns True and outputs an appropriate set of
 666       --  error messages giving the path. Also calls Choose for each of the
 667       --  nodes so that they get removed from the remaining set. There are
 668       --  two cases of calls, either Ufrom = Uto for an attempt to find a
 669       --  cycle, or Ufrom is a spec and Uto the corresponding body for the
 670       --  case of an unsatisfiable Elaborate_Body pragma. ML is the minimum
 671       --  acceptable length for a path.
 672
 673       ---------------
 674       -- Find_Path --
 675       ---------------
 676
 677       function Find_Path (Ufrom, Uto : Unit_Id; ML : Nat) return Boolean is
 678
 679          function Find_Link (U : Unit_Id; PL : Nat) return Boolean;
 680          --  This is the inner recursive routine, it determines if a path
 681          --  exists from U to Uto, and if so returns True and outputs the
 682          --  appropriate set of error messages. PL is the path length
 683
 684          ---------------
 685          -- Find_Link --
 686          ---------------
 687
 688          function Find_Link (U : Unit_Id; PL : Nat) return Boolean is
 689             S : Successor_Id;
 690
 691          begin
 692             --  Recursion ends if we are at terminating node and the path
 693             --  is sufficiently long, generate error message and return True.
 694
 695             if U = Uto and then PL >= ML then
 696                Choose (U);
 697                return True;
 698
 699             --  All done if already visited, otherwise mark as visited
 700
 701             elsif UNR.Table (U).Visited then
 702                return False;
 703
 704             --  Otherwise mark as visited and look at all successors
 705
 706             else
 707                UNR.Table (U).Visited := True;
 708
 709                S := UNR.Table (U).Successors;
 710                while S /= No_Successor loop
 711                   if Find_Link (Succ.Table (S).After, PL + 1) then
 712                      Elab_Error_Msg (S);
 713                      Choose (U);
 714                      return True;
 715                   end if;
 716
 717                   S := Succ.Table (S).Next;
 718                end loop;
 719
 720                --  Falling through means this does not lead to a path
 721
 722                return False;
 723             end if;
 724          end Find_Link;
 725
 726       --  Start of processing for Find_Path
 727
 728       begin
 729          --  Initialize all non-chosen nodes to not visisted yet
 730
 731          for U in Units.First .. Units.Last loop
 732             UNR.Table (U).Visited := UNR.Table (U).Elab_Position /= 0;
 733          end loop;
 734
 735          --  Now try to find the path
 736
 737          return Find_Link (Ufrom, 0);
 738       end Find_Path;
 739
 740    --  Start of processing for Diagnose_Elaboration_Error
 741
 742    begin
 743       Set_Standard_Error;
 744
 745       --  Output state of things if debug flag N set
 746
 747       if Debug_Flag_N then
 748          declare
 749             NP : Int;
 750
 751          begin
 752             Write_Eol;
 753             Write_Eol;
 754             Write_Str ("Diagnose_Elaboration_Problem called");
 755             Write_Eol;
 756             Write_Str ("List of remaining unchosen units and predecessors");
 757             Write_Eol;
 758
 759             for U in Units.First .. Units.Last loop
 760                if UNR.Table (U).Elab_Position = 0 then
 761                   NP := UNR.Table (U).Num_Pred;
 762                   Write_Eol;
 763                   Write_Str ("  Unchosen unit: #");
 764                   Write_Int (Int (U));
 765                   Write_Str ("  ");
 766                   Write_Unit_Name (Units.Table (U).Uname);
 767                   Write_Str (" (Num_Pred = ");
 768                   Write_Int (NP);
 769                   Write_Char (')');
 770                   Write_Eol;
 771
 772                   if NP = 0 then
 773                      if Units.Table (U).Elaborate_Body then
 774                         Write_Str
 775                           ("    (not chosen because of Elaborate_Body)");
 776                         Write_Eol;
 777                      else
 778                         Write_Str ("  ****************** why not chosen?");
 779                         Write_Eol;
 780                      end if;
 781                   end if;
 782
 783                   --  Search links list to find unchosen predecessors
 784
 785                   for S in Succ.First .. Succ.Last loop
 786                      declare
 787                         SL : Successor_Link renames Succ.Table (S);
 788
 789                      begin
 790                         if SL.After = U
 791                           and then UNR.Table (SL.Before).Elab_Position = 0
 792                         then
 793                            Write_Str ("    unchosen predecessor: #");
 794                            Write_Int (Int (SL.Before));
 795                            Write_Str ("  ");
 796                            Write_Unit_Name (Units.Table (SL.Before).Uname);
 797                            Write_Eol;
 798                            NP := NP - 1;
 799                         end if;
 800                      end;
 801                   end loop;
 802
 803                   if NP /= 0 then
 804                      Write_Str ("  **************** Num_Pred value wrong!");
 805                      Write_Eol;
 806                   end if;
 807                end if;
 808             end loop;
 809          end;
 810       end if;
 811
 812       --  Output the header for the error, and manually increment the
 813       --  error count. We are using Error_Msg_Output rather than Error_Msg
 814       --  here for two reasons:
 815
 816       --    This is really only one error, not one for each line
 817       --    We want this output on standard output since it is voluminous
 818
 819       --  But we do need to deal with the error count manually in this case
 820
 821       Errors_Detected := Errors_Detected + 1;
 822       Error_Msg_Output ("elaboration circularity detected", Info => False);
 823
 824       --  Try to find cycles starting with any of the remaining nodes that have
 825       --  not yet been chosen. There must be at least one (there is some reason
 826       --  we are being called!)
 827
 828       for U in Units.First .. Units.Last loop
 829          if UNR.Table (U).Elab_Position = 0 then
 830             if Find_Path (U, U, 1) then
 831                raise Unrecoverable_Error;
 832             end if;
 833          end if;
 834       end loop;
 835
 836       --  We should never get here, since we were called for some reason,
 837       --  and we should have found and eliminated at least one bad path.
 838
 839       raise Program_Error;
 840    end Diagnose_Elaboration_Problem;
 841
 842    --------------------
 843    -- Elab_All_Links --
 844    --------------------
 845
 846    procedure Elab_All_Links
 847      (Before : Unit_Id;
 848       After  : Unit_Id;
 849       Reason : Succ_Reason;
 850       Link   : Elab_All_Id)
 851    is
 852    begin
 853       if UNR.Table (Before).Visited then
 854          return;
 855       end if;
 856
 857       --  Build the direct link for Before
 858
 859       UNR.Table (Before).Visited := True;
 860       Build_Link (Before, After, Reason, Link);
 861
 862       --  Process all units with'ed by Before recursively
 863
 864       for W in
 865         Units.Table (Before).First_With .. Units.Table (Before).Last_With
 866       loop
 867          --  Skip if this with is an interface to a stand-alone library.
 868          --  Skip also if no ALI file for this WITH, happens for language
 869          --  defined generics while bootstrapping the compiler (see body of
 870          --  Lib.Writ.Write_With_Lines).
 871
 872          if not Withs.Table (W).SAL_Interface
 873            and then Withs.Table (W).Afile /= No_File
 874          then
 875             declare
 876                Info : constant Int :=
 877                         Get_Name_Table_Info
 878                           (Withs.Table (W).Uname);
 879
 880             begin
 881                --  If the unit is unknown, for some unknown reason, fail
 882                --  graciously explaining that the unit is unknown. Without
 883                --  this check, gnatbind will crash in Unit_Id_Of.
 884
 885                if Info = 0 or else Unit_Id (Info) = No_Unit_Id then
 886                   declare
 887                      Withed       : String :=
 888                                       Get_Name_String (Withs.Table (W).Uname);
 889                      Last_Withed  : Natural := Withed'Last;
 890                      Withing      : String :=
 891                                       Get_Name_String
 892                                         (Units.Table (Before).Uname);
 893                      Last_Withing : Natural := Withing'Last;
 894                      Spec_Body    : String  := " (Spec)";
 895
 896                   begin
 897                      To_Mixed (Withed);
 898                      To_Mixed (Withing);
 899
 900                      if Last_Withed > 2 and then
 901                        Withed (Last_Withed - 1) = '%'
 902                      then
 903                         Last_Withed := Last_Withed - 2;
 904                      end if;
 905
 906                      if Last_Withing > 2 and then
 907                        Withing (Last_Withing - 1) = '%'
 908                      then
 909                         Last_Withing := Last_Withing - 2;
 910                      end if;
 911
 912                      if Units.Table (Before).Utype = Is_Body or else
 913                        Units.Table (Before).Utype = Is_Body_Only
 914                      then
 915                         Spec_Body := " (Body)";
 916                      end if;
 917
 918                      Osint.Fail
 919                        ("could not find unit ",
 920                         Withed (Withed'First .. Last_Withed) & " needed by " &
 921                         Withing (Withing'First .. Last_Withing) & Spec_Body);
 922                   end;
 923                end if;
 924
 925                Elab_All_Links
 926                  (Unit_Id_Of (Withs.Table (W).Uname),
 927                   After,
 928                   Reason,
 929                   Make_Elab_Entry (Withs.Table (W).Uname, Link));
 930             end;
 931          end if;
 932       end loop;
 933
 934       --  Process corresponding body, if there is one
 935
 936       if Units.Table (Before).Utype = Is_Spec then
 937          Elab_All_Links
 938            (Corresponding_Body (Before),
 939             After, Reason,
 940             Make_Elab_Entry
 941               (Units.Table (Corresponding_Body (Before)).Uname, Link));
 942       end if;
 943    end Elab_All_Links;
 944
 945    --------------------
 946    -- Elab_Error_Msg --
 947    --------------------
 948
 949    procedure Elab_Error_Msg (S : Successor_Id) is
 950       SL : Successor_Link renames Succ.Table (S);
 951
 952    begin
 953       --  Nothing to do if internal unit involved and no -da flag
 954
 955       if not Debug_Flag_A
 956         and then
 957           (Is_Internal_File_Name (Units.Table (SL.Before).Sfile)
 958             or else
 959            Is_Internal_File_Name (Units.Table (SL.After).Sfile))
 960       then
 961          return;
 962       end if;
 963
 964       --  Here we want to generate output
 965
 966       Error_Msg_Unit_1 := Units.Table (SL.Before).Uname;
 967
 968       if SL.Elab_Body then
 969          Error_Msg_Unit_2 := Units.Table (Corresponding_Body (SL.After)).Uname;
 970       else
 971          Error_Msg_Unit_2 := Units.Table (SL.After).Uname;
 972       end if;
 973
 974       Error_Msg_Output ("  $ must be elaborated before $", Info => True);
 975
 976       Error_Msg_Unit_1 := Units.Table (SL.Reason_Unit).Uname;
 977
 978       case SL.Reason is
 979          when Withed =>
 980             Error_Msg_Output
 981               ("     reason: with clause",
 982                Info => True);
 983
 984          when Elab =>
 985             Error_Msg_Output
 986               ("     reason: pragma Elaborate in unit $",
 987                Info => True);
 988
 989          when Elab_All =>
 990             Error_Msg_Output
 991               ("     reason: pragma Elaborate_All in unit $",
 992                Info => True);
 993
 994          when Elab_All_Desirable =>
 995             Error_Msg_Output
 996               ("     reason: implicit Elaborate_All in unit $",
 997                Info => True);
 998
 999             Error_Msg_Output
1000               ("     recompile $ with -gnatwl for full details",
1001                Info => True);
1002
1003          when Elab_Desirable =>
1004             Error_Msg_Output
1005               ("     reason: implicit Elaborate in unit $",
1006                Info => True);
1007
1008             Error_Msg_Output
1009               ("     recompile $ with -gnatwl for full details",
1010                Info => True);
1011
1012          when Spec_First =>
1013             Error_Msg_Output
1014               ("     reason: spec always elaborated before body",
1015                Info => True);
1016       end case;
1017
1018       Write_Elab_All_Chain (S);
1019
1020       if SL.Elab_Body then
1021          Error_Msg_Unit_1 := Units.Table (SL.Before).Uname;
1022          Error_Msg_Unit_2 := Units.Table (SL.After).Uname;
1023          Error_Msg_Output
1024            ("  $ must therefore be elaborated before $",
1025             True);
1026
1027          Error_Msg_Unit_1 := Units.Table (SL.After).Uname;
1028          Error_Msg_Output
1029            ("     (because $ has a pragma Elaborate_Body)",
1030             True);
1031       end if;
1032
1033       if not Zero_Formatting then
1034          Write_Eol;
1035       end if;
1036    end Elab_Error_Msg;
1037
1038    ---------------------
1039    -- Find_Elab_Order --
1040    ---------------------
1041
1042    procedure Find_Elab_Order is
1043       U           : Unit_Id;
1044       Best_So_Far : Unit_Id;
1045
1046    begin
1047       Succ.Init;
1048       Num_Left := Int (Units.Last - Units.First + 1);
1049
1050       --  Initialize unit table for elaboration control
1051
1052       for U in Units.First .. Units.Last loop
1053          UNR.Increment_Last;
1054          UNR.Table (UNR.Last).Successors    := No_Successor;
1055          UNR.Table (UNR.Last).Num_Pred      := 0;
1056          UNR.Table (UNR.Last).Nextnp        := No_Unit_Id;
1057          UNR.Table (UNR.Last).Elab_Order    := 0;
1058          UNR.Table (UNR.Last).Elab_Position := 0;
1059       end loop;
1060
1061       --  Output warning if -p used with no -gnatE units
1062
1063       if Pessimistic_Elab_Order
1064         and not Dynamic_Elaboration_Checks_Specified
1065       then
1066          if OpenVMS_On_Target then
1067             Error_Msg ("?use of /PESSIMISTIC_ELABORATION questionable");
1068          else
1069             Error_Msg ("?use of -p switch questionable");
1070          end if;
1071
1072          Error_Msg ("?since all units compiled with static elaboration model");
1073       end if;
1074
1075       --  Gather dependencies and output them if option set
1076
1077       Gather_Dependencies;
1078
1079       --  Output elaboration dependencies if option is set
1080
1081       if Elab_Dependency_Output or Debug_Flag_E then
1082          Write_Dependencies;
1083       end if;
1084
1085       --  Initialize the no predecessor list
1086
1087       No_Pred := No_Unit_Id;
1088
1089       for U in UNR.First .. UNR.Last loop
1090          if UNR.Table (U).Num_Pred = 0 then
1091             UNR.Table (U).Nextnp := No_Pred;
1092             No_Pred := U;
1093          end if;
1094       end loop;
1095
1096       --  OK, now we determine the elaboration order proper. All we do is to
1097       --  select the best choice from the no predecessor list until all the
1098       --  nodes have been chosen.
1099
1100       Outer : loop
1101
1102          --  If there are no nodes with predecessors, then either we are
1103          --  done, as indicated by Num_Left being set to zero, or we have
1104          --  a circularity. In the latter case, diagnose the circularity,
1105          --  removing it from the graph and continue
1106
1107          Get_No_Pred : while No_Pred = No_Unit_Id loop
1108             exit Outer when Num_Left < 1;
1109             Diagnose_Elaboration_Problem;
1110          end loop Get_No_Pred;
1111
1112          U := No_Pred;
1113          Best_So_Far := No_Unit_Id;
1114
1115          --  Loop to choose best entry in No_Pred list
1116
1117          No_Pred_Search : loop
1118             if Debug_Flag_N then
1119                Write_Str ("  considering choice of ");
1120                Write_Unit_Name (Units.Table (U).Uname);
1121                Write_Eol;
1122
1123                if Units.Table (U).Elaborate_Body then
1124                   Write_Str
1125                     ("    Elaborate_Body = True, Num_Pred for body = ");
1126                   Write_Int
1127                     (Int (UNR.Table (Corresponding_Body (U)).Num_Pred));
1128                else
1129                   Write_Str
1130                     ("    Elaborate_Body = False");
1131                end if;
1132
1133                Write_Eol;
1134             end if;
1135
1136             --  This is a candididate to be considered for choice
1137
1138             if Best_So_Far = No_Unit_Id
1139               or else ((not Pessimistic_Elab_Order)
1140                          and then Better_Choice (U, Best_So_Far))
1141               or else (Pessimistic_Elab_Order
1142                          and then Worse_Choice (U, Best_So_Far))
1143             then
1144                if Debug_Flag_N then
1145                   Write_Str ("    tentatively chosen (best so far)");
1146                   Write_Eol;
1147                end if;
1148
1149                Best_So_Far := U;
1150             end if;
1151
1152             U := UNR.Table (U).Nextnp;
1153             exit No_Pred_Search when U = No_Unit_Id;
1154          end loop No_Pred_Search;
1155
1156          --  If no candididate chosen, it means that no unit has No_Pred = 0,
1157          --  but there are units left, hence we have a circular dependency,
1158          --  which we will get Diagnose_Elaboration_Problem to diagnose it.
1159
1160          if Best_So_Far = No_Unit_Id then
1161             Diagnose_Elaboration_Problem;
1162
1163          --  Otherwise choose the best candidate found
1164
1165          else
1166             Choose (Best_So_Far);
1167          end if;
1168       end loop Outer;
1169    end Find_Elab_Order;
1170
1171    -------------------------
1172    -- Gather_Dependencies --
1173    -------------------------
1174
1175    procedure Gather_Dependencies is
1176       Withed_Unit : Unit_Id;
1177
1178    begin
1179       --  Loop through all units
1180
1181       for U in Units.First .. Units.Last loop
1182          Cur_Unit := U;
1183
1184          --  If this is not an interface to a stand-alone library and
1185          --  there is a body and a spec, then spec must be elaborated first
1186          --  Note that the corresponding spec immediately follows the body
1187
1188          if not Units.Table (U).SAL_Interface
1189            and then Units.Table (U).Utype = Is_Body
1190          then
1191             Build_Link (Corresponding_Spec (U), U, Spec_First);
1192          end if;
1193
1194          --  If this unit is not an interface to a stand-alone library,
1195          --  process WITH references for this unit ignoring generic units and
1196          --  interfaces to stand-alone libraries.
1197
1198          if not Units.Table (U).SAL_Interface then
1199             for
1200               W in Units.Table (U).First_With .. Units.Table (U).Last_With
1201             loop
1202                if Withs.Table (W).Sfile /= No_File
1203                  and then (not Withs.Table (W).SAL_Interface)
1204                then
1205                   --  Check for special case of withing a unit that does not
1206                   --  exist any more. If the unit was completely missing we
1207                   --  would already have detected this, but a nasty case arises
1208                   --  when we have a subprogram body with no spec, and some
1209                   --  obsolete unit with's a previous (now disappeared) spec.
1210
1211                   if Get_Name_Table_Info (Withs.Table (W).Uname) = 0 then
1212                      Error_Msg_File_1 := Units.Table (U).Sfile;
1213                      Error_Msg_Unit_1 := Withs.Table (W).Uname;
1214                      Error_Msg ("{ depends on $ which no longer exists");
1215                      goto Next_With;
1216                   end if;
1217
1218                   Withed_Unit :=
1219                     Unit_Id (Unit_Id_Of (Withs.Table (W).Uname));
1220
1221                   --  Pragma Elaborate_All case, for this we use the recursive
1222                   --  Elab_All_Links procedure to establish the links.
1223
1224                   if Withs.Table (W).Elaborate_All then
1225
1226                      --  Reset flags used to stop multiple visits to a given
1227                      --  node.
1228
1229                      for Uref in UNR.First .. UNR.Last loop
1230                         UNR.Table (Uref).Visited := False;
1231                      end loop;
1232
1233                      --  Now establish all the links we need
1234
1235                      Elab_All_Links
1236                        (Withed_Unit, U, Elab_All,
1237                         Make_Elab_Entry
1238                           (Withs.Table (W).Uname, No_Elab_All_Link));
1239
1240                      --  Elaborate_All_Desirable case, for this we establish
1241                      --  the same links as above, but with a different reason.
1242
1243                   elsif Withs.Table (W).Elab_All_Desirable then
1244
1245                      --  Reset flags used to stop multiple visits to a given
1246                      --  node.
1247
1248                      for Uref in UNR.First .. UNR.Last loop
1249                         UNR.Table (Uref).Visited := False;
1250                      end loop;
1251
1252                      --  Now establish all the links we need
1253
1254                      Elab_All_Links
1255                        (Withed_Unit, U, Elab_All_Desirable,
1256                         Make_Elab_Entry
1257                           (Withs.Table (W).Uname, No_Elab_All_Link));
1258
1259                      --  Pragma Elaborate case. We must build a link for the
1260                      --  withed unit itself, and also the corresponding body
1261                      --  if there is one.
1262
1263                      --  However, skip this processing if there is no ALI file
1264                      --  for the WITH entry, because this means it is a
1265                      --  generic (even when we fix the generics so that an ALI
1266                      --  file is present, we probably still will have no ALI
1267                      --  file for unchecked and other special cases).
1268
1269                   elsif Withs.Table (W).Elaborate
1270                     and then Withs.Table (W).Afile /= No_File
1271                   then
1272                      Build_Link (Withed_Unit, U, Withed);
1273
1274                      if Units.Table (Withed_Unit).Utype = Is_Spec then
1275                         Build_Link
1276                           (Corresponding_Body (Withed_Unit), U, Elab);
1277                      end if;
1278
1279                      --  Elaborate_Desirable case, for this we establish
1280                      --  the same links as above, but with a different reason.
1281
1282                   elsif Withs.Table (W).Elab_Desirable then
1283                      Build_Link (Withed_Unit, U, Withed);
1284
1285                      if Units.Table (Withed_Unit).Utype = Is_Spec then
1286                         Build_Link
1287                           (Corresponding_Body (Withed_Unit),
1288                            U, Elab_Desirable);
1289                      end if;
1290
1291                      --  Case of normal WITH with no elaboration pragmas, just
1292                      --  build the single link to the directly referenced unit
1293
1294                   else
1295                      Build_Link (Withed_Unit, U, Withed);
1296                   end if;
1297                end if;
1298
1299                <<Next_With>>
1300                null;
1301             end loop;
1302          end if;
1303       end loop;
1304    end Gather_Dependencies;
1305
1306    ------------------
1307    -- Is_Body_Unit --
1308    ------------------
1309
1310    function Is_Body_Unit (U : Unit_Id) return Boolean is
1311    begin
1312       return Units.Table (U).Utype = Is_Body
1313         or else Units.Table (U).Utype = Is_Body_Only;
1314    end Is_Body_Unit;
1315
1316    ---------------------
1317    -- Is_Waiting_Body --
1318    ---------------------
1319
1320    function Is_Waiting_Body (U : Unit_Id) return Boolean is
1321    begin
1322       return Units.Table (U).Utype = Is_Body
1323         and then UNR.Table (Corresponding_Spec (U)).Elab_Position /= 0;
1324    end Is_Waiting_Body;
1325
1326    ---------------------
1327    -- Make_Elab_Entry --
1328    ---------------------
1329
1330    function Make_Elab_Entry
1331      (Unam : Unit_Name_Type;
1332       Link : Elab_All_Id) return Elab_All_Id
1333    is
1334    begin
1335       Elab_All_Entries.Increment_Last;
1336       Elab_All_Entries.Table (Elab_All_Entries.Last).Needed_By := Unam;
1337       Elab_All_Entries.Table (Elab_All_Entries.Last).Next_Elab := Link;
1338       return Elab_All_Entries.Last;
1339    end Make_Elab_Entry;
1340
1341    ----------------
1342    -- Unit_Id_Of --
1343    ----------------
1344
1345    function Unit_Id_Of (Uname : Unit_Name_Type) return Unit_Id is
1346       Info : constant Int := Get_Name_Table_Info (Uname);
1347    begin
1348       pragma Assert (Info /= 0 and then Unit_Id (Info) /= No_Unit_Id);
1349       return Unit_Id (Info);
1350    end Unit_Id_Of;
1351
1352    ------------------
1353    -- Worse_Choice --
1354    ------------------
1355
1356    function Worse_Choice (U1, U2 : Unit_Id) return Boolean is
1357       UT1 : Unit_Record renames Units.Table (U1);
1358       UT2 : Unit_Record renames Units.Table (U2);
1359
1360    begin
1361       --  Note: the checks here are applied in sequence, and the ordering is
1362       --  significant (i.e. the more important criteria are applied first).
1363
1364       --  If either unit is internal, then use Better_Choice, since the
1365       --  language requires that predefined units not mess up in the choice
1366       --  of elaboration order, and for internal units, any problems are
1367       --  ours and not the programmers.
1368
1369       if UT1.Internal or else UT2.Internal then
1370          return Better_Choice (U1, U2);
1371
1372       --  Prefer anything else to a waiting body (!)
1373
1374       elsif Is_Waiting_Body (U1) and not Is_Waiting_Body (U2) then
1375          return False;
1376
1377       elsif Is_Waiting_Body (U2) and not Is_Waiting_Body (U1) then
1378          return True;
1379
1380       --  Prefer a spec to a body (!)
1381
1382       elsif Is_Body_Unit (U1) and not Is_Body_Unit (U2) then
1383          return False;
1384
1385       elsif Is_Body_Unit (U2) and not Is_Body_Unit (U1) then
1386          return True;
1387
1388       --  If both are waiting bodies, then prefer the one whose spec is
1389       --  less recently elaborated. Consider the following:
1390
1391       --     spec of A
1392       --     spec of B
1393       --     body of A or B?
1394
1395       --  The normal waiting body preference would have placed the body of
1396       --  A before the spec of B if it could. Since it could not, there it
1397       --  must be the case that A depends on B. It is therefore a good idea
1398       --  to put the body of B last so that if there is an elaboration order
1399       --  problem, we will find it (that's what horrible order is about)
1400
1401       elsif Is_Waiting_Body (U1) and then Is_Waiting_Body (U2) then
1402          return
1403            UNR.Table (Corresponding_Spec (U1)).Elab_Position <
1404            UNR.Table (Corresponding_Spec (U2)).Elab_Position;
1405       end if;
1406
1407       --  Remaining choice rules are disabled by Debug flag -do
1408
1409       if not Debug_Flag_O then
1410
1411          --  The following deal with the case of specs which have been marked
1412          --  as Elaborate_Body_Desirable. In the normal case, we generally want
1413          --  to delay the elaboration of these specs as long as possible, so
1414          --  that bodies have better chance of being elaborated closer to the
1415          --  specs. Worse_Choice as usual wants to do the opposite and
1416          --  elaborate such specs as early as possible.
1417
1418          --  If we have two units, one of which is a spec for which this flag
1419          --  is set, and the other is not, we normally prefer to delay the spec
1420          --  for which the flag is set, and so Worse_Choice does the opposite.
1421
1422          if not UT1.Elaborate_Body_Desirable
1423            and then UT2.Elaborate_Body_Desirable
1424          then
1425             return False;
1426
1427          elsif not UT2.Elaborate_Body_Desirable
1428            and then UT1.Elaborate_Body_Desirable
1429          then
1430             return True;
1431
1432             --  If we have two specs that are both marked as Elaborate_Body
1433             --  desirable, we normally prefer the one whose body is nearer to
1434             --  being able to be elaborated, based on the Num_Pred count. This
1435             --  helps to ensure bodies are as close to specs as possible. As
1436             --  usual, Worse_Choice does the opposite.
1437
1438          elsif UT1.Elaborate_Body_Desirable
1439            and then UT2.Elaborate_Body_Desirable
1440          then
1441             return UNR.Table (Corresponding_Body (U1)).Num_Pred >=
1442               UNR.Table (Corresponding_Body (U2)).Num_Pred;
1443          end if;
1444       end if;
1445
1446       --  If we fall through, it means that no preference rule applies, so we
1447       --  use alphabetical order to at least give a deterministic result. Since
1448       --  Worse_Choice is in the business of stirring up the order, we will
1449       --  use reverse alphabetical ordering.
1450
1451       return Uname_Less (UT2.Uname, UT1.Uname);
1452    end Worse_Choice;
1453
1454    ------------------------
1455    -- Write_Dependencies --
1456    ------------------------
1457
1458    procedure Write_Dependencies is
1459    begin
1460       if not Zero_Formatting then
1461          Write_Eol;
1462          Write_Str ("                 ELABORATION ORDER DEPENDENCIES");
1463          Write_Eol;
1464          Write_Eol;
1465       end if;
1466
1467       Info_Prefix_Suppress := True;
1468
1469       for S in Succ_First .. Succ.Last loop
1470          Elab_Error_Msg (S);
1471       end loop;
1472
1473       Info_Prefix_Suppress := False;
1474
1475       if not Zero_Formatting then
1476          Write_Eol;
1477       end if;
1478    end Write_Dependencies;
1479
1480    --------------------------
1481    -- Write_Elab_All_Chain --
1482    --------------------------
1483
1484    procedure Write_Elab_All_Chain (S : Successor_Id) is
1485       ST     : constant Successor_Link := Succ.Table (S);
1486       After  : constant Unit_Name_Type := Units.Table (ST.After).Uname;
1487
1488       L   : Elab_All_Id;
1489       Nam : Unit_Name_Type;
1490
1491       First_Name : Boolean := True;
1492
1493    begin
1494       if ST.Reason in Elab_All .. Elab_All_Desirable then
1495          L := ST.Elab_All_Link;
1496          while L /= No_Elab_All_Link loop
1497             Nam := Elab_All_Entries.Table (L).Needed_By;
1498             Error_Msg_Unit_1 := Nam;
1499             Error_Msg_Output ("        $", Info => True);
1500
1501             Get_Name_String (Nam);
1502
1503             if Name_Buffer (Name_Len) = 'b' then
1504                if First_Name then
1505                   Error_Msg_Output
1506                     ("           must be elaborated along with its spec:",
1507                      Info => True);
1508
1509                else
1510                   Error_Msg_Output
1511                     ("           which must be elaborated " &
1512                      "along with its spec:",
1513                      Info => True);
1514                end if;
1515
1516             else
1517                if First_Name then
1518                   Error_Msg_Output
1519                     ("           is withed by:",
1520                      Info => True);
1521
1522                else
1523                   Error_Msg_Output
1524                     ("           which is withed by:",
1525                      Info => True);
1526                end if;
1527             end if;
1528
1529             First_Name := False;
1530
1531             L := Elab_All_Entries.Table (L).Next_Elab;
1532          end loop;
1533
1534          Error_Msg_Unit_1 := After;
1535          Error_Msg_Output ("        $", Info => True);
1536       end if;
1537    end Write_Elab_All_Chain;
1538
1539 end Binde;