gcc/ada/back_end.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            B A C K _ E N D                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;     use Atree;
  27 with Debug;     use Debug;
  28 with Elists;    use Elists;
  29 with Errout;    use Errout;
  30 with Lib;       use Lib;
  31 with Osint;     use Osint;
  32 with Opt;       use Opt;
  33 with Osint.C;   use Osint.C;
  34 with Namet;     use Namet;
  35 with Nlists;    use Nlists;
  36 with Stand;     use Stand;
  37 with Sinput;    use Sinput;
  38 with Stringt;   use Stringt;
  39 with Switch;    use Switch;
  40 with Switch.C;  use Switch.C;
  41 with System;    use System;
  42 with Types;     use Types;
  43
  44 with System.OS_Lib; use System.OS_Lib;
  45
  46 package body Back_End is
  47
  48    type Arg_Array is array (Nat) of Big_String_Ptr;
  49    type Arg_Array_Ptr is access Arg_Array;
  50    --  Types to access compiler arguments
  51
  52    flag_stack_check : Int;
  53    pragma Import (C, flag_stack_check);
  54    --  Indicates if stack checking is enabled, imported from decl.c
  55
  56    save_argc : Nat;
  57    pragma Import (C, save_argc);
  58    --  Saved value of argc (number of arguments), imported from misc.c
  59
  60    save_argv : Arg_Array_Ptr;
  61    pragma Import (C, save_argv);
  62    --  Saved value of argv (argument pointers), imported from misc.c
  63
  64    function Len_Arg (Arg : Pos) return Nat;
  65    --  Determine length of argument number Arg on original gnat1 command line
  66
  67    -------------------
  68    -- Call_Back_End --
  69    -------------------
  70
  71    procedure Call_Back_End (Mode : Back_End_Mode_Type) is
  72
  73       --  The Source_File_Record type has a lot of components that are
  74       --  meaningless to the back end, so a new record type is created
  75       --  here to contain the needed information for each file.
  76
  77       type File_Info_Type is record
  78          File_Name        : File_Name_Type;
  79          Num_Source_Lines : Nat;
  80       end record;
  81
  82       File_Info_Array : array (1 .. Last_Source_File) of File_Info_Type;
  83
  84       procedure gigi
  85         (gnat_root                     : Int;
  86          max_gnat_node                 : Int;
  87          number_name                   : Nat;
  88          nodes_ptr                     : Address;
  89
  90          next_node_ptr                 : Address;
  91          prev_node_ptr                 : Address;
  92          elists_ptr                    : Address;
  93          elmts_ptr                     : Address;
  94
  95          strings_ptr                   : Address;
  96          string_chars_ptr              : Address;
  97          list_headers_ptr              : Address;
  98          number_file                   : Nat;
  99
 100          file_info_ptr                 : Address;
 101          gigi_standard_boolean         : Entity_Id;
 102          gigi_standard_integer         : Entity_Id;
 103          gigi_standard_character       : Entity_Id;
 104          gigi_standard_long_long_float : Entity_Id;
 105          gigi_standard_exception_type  : Entity_Id;
 106          gigi_operating_mode           : Back_End_Mode_Type);
 107
 108       pragma Import (C, gigi);
 109
 110    begin
 111       --  Skip call if in -gnatdH mode
 112
 113       if Debug_Flag_HH then
 114          return;
 115       end if;
 116
 117       for J in 1 .. Last_Source_File loop
 118          File_Info_Array (J).File_Name        := Full_Debug_Name (J);
 119          File_Info_Array (J).Num_Source_Lines := Num_Source_Lines (J);
 120       end loop;
 121
 122       if Generate_SCIL then
 123          Error_Msg_N ("'S'C'I'L generation not available", Cunit (Main_Unit));
 124
 125          if CodePeer_Mode
 126            or else (Mode /= Generate_Object
 127                      and then not Back_Annotate_Rep_Info)
 128          then
 129             return;
 130          end if;
 131       end if;
 132
 133       gigi
 134         (gnat_root          => Int (Cunit (Main_Unit)),
 135          max_gnat_node      => Int (Last_Node_Id - First_Node_Id + 1),
 136          number_name        => Name_Entries_Count,
 137          nodes_ptr          => Nodes_Address,
 138
 139          next_node_ptr      => Next_Node_Address,
 140          prev_node_ptr      => Prev_Node_Address,
 141          elists_ptr         => Elists_Address,
 142          elmts_ptr          => Elmts_Address,
 143
 144          strings_ptr        => Strings_Address,
 145          string_chars_ptr   => String_Chars_Address,
 146          list_headers_ptr   => Lists_Address,
 147          number_file        => Num_Source_Files,
 148
 149          file_info_ptr                 => File_Info_Array'Address,
 150          gigi_standard_boolean         => Standard_Boolean,
 151          gigi_standard_integer         => Standard_Integer,
 152          gigi_standard_character       => Standard_Character,
 153          gigi_standard_long_long_float => Standard_Long_Long_Float,
 154          gigi_standard_exception_type  => Standard_Exception_Type,
 155          gigi_operating_mode           => Mode);
 156    end Call_Back_End;
 157
 158    -------------
 159    -- Len_Arg --
 160    -------------
 161
 162    function Len_Arg (Arg : Pos) return Nat is
 163    begin
 164       for J in 1 .. Nat'Last loop
 165          if save_argv (Arg).all (Natural (J)) = ASCII.NUL then
 166             return J - 1;
 167          end if;
 168       end loop;
 169
 170       raise Program_Error;
 171    end Len_Arg;
 172
 173    -----------------------------
 174    -- Scan_Compiler_Arguments --
 175    -----------------------------
 176
 177    procedure Scan_Compiler_Arguments is
 178
 179       Next_Arg : Positive;
 180       --  Next argument to be scanned
 181
 182       Output_File_Name_Seen : Boolean := False;
 183       --  Set to True after having scanned file_name for switch "-gnatO file"
 184
 185       procedure Scan_Back_End_Switches (Switch_Chars : String);
 186       --  Procedure to scan out switches stored in Switch_Chars. The first
 187       --  character is known to be a valid switch character, and there are no
 188       --  blanks or other switch terminator characters in the string, so the
 189       --  entire string should consist of valid switch characters, except that
 190       --  an optional terminating NUL character is allowed.
 191       --
 192       --  Back end switches have already been checked and processed by GCC in
 193       --  toplev.c, so no errors can occur and control will always return. The
 194       --  switches must still be scanned to skip "-o" or internal GCC switches
 195       --  with their argument.
 196
 197       ----------------------------
 198       -- Scan_Back_End_Switches --
 199       ----------------------------
 200
 201       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 202          First : constant Positive := Switch_Chars'First + 1;
 203          Last  : constant Natural  := Switch_Last (Switch_Chars);
 204
 205       begin
 206          --  Skip -o or internal GCC switches together with their argument
 207
 208          if Switch_Chars (First .. Last) = "o"
 209            or else Is_Internal_GCC_Switch (Switch_Chars)
 210          then
 211             Next_Arg := Next_Arg + 1;
 212
 213          --  Do not record -quiet switch
 214
 215          elsif Switch_Chars (First .. Last) = "quiet" then
 216             null;
 217
 218          --  Store any other GCC switches
 219
 220          else
 221             Store_Compilation_Switch (Switch_Chars);
 222
 223             --  Special check, the back end switch -fno-inline also sets the
 224             --  front end flag to entirely inhibit all inlining.
 225
 226             if Switch_Chars (First .. Last) = "fno-inline" then
 227                Opt.Suppress_All_Inlining := True;
 228
 229             --  Another special check, the switch -fpreserve-control-flow
 230             --  which is also a back end switch sets the front end flag
 231             --  that inhibits improper control flow transformations.
 232
 233             elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 234                Opt.Suppress_Control_Flow_Optimizations := True;
 235             end if;
 236          end if;
 237       end Scan_Back_End_Switches;
 238
 239       --  Local variables
 240
 241       Arg_Count : constant Natural := Natural (save_argc - 1);
 242       Args : Argument_List (1 .. Arg_Count);
 243
 244    --  Start of processing for Scan_Compiler_Arguments
 245
 246    begin
 247       --  Acquire stack checking mode directly from GCC
 248
 249       Opt.Stack_Checking_Enabled := (flag_stack_check /= 0);
 250
 251       --  Put the arguments in Args
 252
 253       for Arg in Pos range 1 .. save_argc - 1 loop
 254          declare
 255             Argv_Ptr : constant Big_String_Ptr := save_argv (Arg);
 256             Argv_Len : constant Nat            := Len_Arg (Arg);
 257             Argv     : constant String         :=
 258                          Argv_Ptr (1 .. Natural (Argv_Len));
 259          begin
 260             Args (Positive (Arg)) := new String'(Argv);
 261          end;
 262       end loop;
 263
 264       --  Loop through command line arguments, storing them for later access
 265
 266       Next_Arg := 1;
 267       while Next_Arg <= Args'Last loop
 268          Look_At_Arg : declare
 269             Argv     : constant String := Args (Next_Arg).all;
 270
 271          begin
 272             --  If the previous switch has set the Output_File_Name_Present
 273             --  flag (that is we have seen a -gnatO), then the next argument
 274             --  is the name of the output object file.
 275
 276             if Output_File_Name_Present
 277               and then not Output_File_Name_Seen
 278             then
 279                if Is_Switch (Argv) then
 280                   Fail ("Object file name missing after -gnatO");
 281
 282                else
 283                   Set_Output_Object_File_Name (Argv);
 284                   Output_File_Name_Seen := True;
 285                end if;
 286
 287             --  If the previous switch has set the Search_Directory_Present
 288             --  flag (that is if we have just seen -I), then the next argument
 289             --  is a search directory path.
 290
 291             elsif Search_Directory_Present then
 292                if Is_Switch (Argv) then
 293                   Fail ("search directory missing after -I");
 294                else
 295                   Add_Src_Search_Dir (Argv);
 296                   Search_Directory_Present := False;
 297                end if;
 298
 299             elsif not Is_Switch (Argv) then -- must be a file name
 300                Add_File (Argv);
 301
 302             --  We must recognize -nostdinc to suppress visibility on the
 303             --  standard GNAT RTL sources. This is also a gcc switch.
 304
 305             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 306                Opt.No_Stdinc := True;
 307                Scan_Back_End_Switches (Argv);
 308
 309             --  We must recognize -nostdlib to suppress visibility on the
 310             --  standard GNAT RTL objects.
 311
 312             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdlib" then
 313                Opt.No_Stdlib := True;
 314
 315             elsif Is_Front_End_Switch (Argv) then
 316                Scan_Front_End_Switches (Argv, Args, Next_Arg);
 317
 318             --  All non-front-end switches are back-end switches
 319
 320             else
 321                Scan_Back_End_Switches (Argv);
 322             end if;
 323          end Look_At_Arg;
 324
 325          Next_Arg := Next_Arg + 1;
 326       end loop;
 327    end Scan_Compiler_Arguments;
 328
 329    -----------------------------
 330    -- Register_Back_End_Types --
 331    -----------------------------
 332
 333    procedure Register_Back_End_Types (Call_Back : Register_Type_Proc) is
 334       procedure Enumerate_Modes (Call_Back : Register_Type_Proc);
 335       pragma Import (C, Enumerate_Modes, "enumerate_modes");
 336
 337    begin
 338       Enumerate_Modes (Call_Back);
 339    end Register_Back_End_Types;
 340
 341    -------------------------------
 342    -- Gen_Or_Update_Object_File --
 343    -------------------------------
 344
 345    procedure Gen_Or_Update_Object_File is
 346    begin
 347       null;
 348    end Gen_Or_Update_Object_File;
 349
 350 end Back_End;