gcc/ada/a-tienio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . T E X T _ I O . E N U M E R A T I O N _ I O            --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-1999 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with Ada.Text_IO.Enumeration_Aux;
  36
  37 package body Ada.Text_IO.Enumeration_IO is
  38
  39    package Aux renames Ada.Text_IO.Enumeration_Aux;
  40
  41    ---------
  42    -- Get --
  43    ---------
  44
  45    procedure Get (File : in File_Type; Item : out Enum) is
  46       Buf    : String (1 .. Enum'Width);
  47       Buflen : Natural;
  48
  49    begin
  50       Aux.Get_Enum_Lit (File, Buf, Buflen);
  51
  52       declare
  53          Buf_Str : String renames Buf (1 .. Buflen);
  54          pragma Unsuppress (Range_Check);
  55       begin
  56          Item := Enum'Value (Buf_Str);
  57       end;
  58
  59    exception
  60       when Constraint_Error => raise Data_Error;
  61    end Get;
  62
  63    procedure Get (Item : out Enum) is
  64       pragma Unsuppress (Range_Check);
  65
  66    begin
  67       Get (Current_In, Item);
  68    end Get;
  69
  70    procedure Get
  71      (From : in String;
  72       Item : out Enum;
  73       Last : out Positive)
  74    is
  75       Start : Natural;
  76
  77    begin
  78       Aux.Scan_Enum_Lit (From, Start, Last);
  79
  80       declare
  81          From_Str : String renames From (Start .. Last);
  82          pragma Unsuppress (Range_Check);
  83       begin
  84          Item := Enum'Value (From_Str);
  85       end;
  86
  87    exception
  88       when Constraint_Error => raise Data_Error;
  89    end Get;
  90
  91    ---------
  92    -- Put --
  93    ---------
  94
  95    procedure Put
  96      (File  : in File_Type;
  97       Item  : in Enum;
  98       Width : in Field := Default_Width;
  99       Set   : in Type_Set := Default_Setting)
 100    is
 101       Image : constant String := Enum'Image (Item);
 102
 103    begin
 104       Aux.Put (File, Image, Width, Set);
 105    end Put;
 106
 107    procedure Put
 108      (Item  : in Enum;
 109       Width : in Field := Default_Width;
 110       Set   : in Type_Set := Default_Setting)
 111    is
 112    begin
 113       Put (Current_Out, Item, Width, Set);
 114    end Put;
 115
 116    procedure Put
 117      (To   : out String;
 118       Item : in Enum;
 119       Set  : in Type_Set := Default_Setting)
 120    is
 121       Image : constant String := Enum'Image (Item);
 122
 123    begin
 124       Aux.Puts (To, Image, Set);
 125    end Put;
 126
 127 end Ada.Text_IO.Enumeration_IO;