gcc/ada/a-taside.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                        GNAT RUN-TIME COMPONENTS                          --
   4 --                                                                          --
   5 --              A D A . T A S K _ I D E N T I F I C A T I O N               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Image;
  35 with System.Parameters;
  36 with System.Soft_Links;
  37 with System.Task_Primitives.Operations;
  38 with Ada.Unchecked_Conversion;
  39
  40 pragma Warnings (Off);
  41 --  Allow withing of non-Preelaborated units in Ada 2005 mode where this
  42 --  package will be categorized as Preelaborate. See AI-362 for details.
  43 --  It is safe in the context of the run-time to violate the rules!
  44
  45 with System.Tasking.Utilities;
  46
  47 pragma Warnings (On);
  48
  49 package body Ada.Task_Identification is
  50
  51    use System.Parameters;
  52
  53    package STPO renames System.Task_Primitives.Operations;
  54
  55    -----------------------
  56    -- Local Subprograms --
  57    -----------------------
  58
  59    function Convert_Ids (T : Task_Id) return System.Tasking.Task_Id;
  60    function Convert_Ids (T : System.Tasking.Task_Id) return Task_Id;
  61    pragma Inline (Convert_Ids);
  62    --  Conversion functions between different forms of Task_Id
  63
  64    ---------
  65    -- "=" --
  66    ---------
  67
  68    function "=" (Left, Right : Task_Id) return Boolean is
  69    begin
  70       return System.Tasking."=" (Convert_Ids (Left), Convert_Ids (Right));
  71    end "=";
  72
  73    -----------------
  74    -- Abort_Task --
  75    ----------------
  76
  77    procedure Abort_Task (T : Task_Id) is
  78    begin
  79       if T = Null_Task_Id then
  80          raise Program_Error;
  81       else
  82          System.Tasking.Utilities.Abort_Tasks
  83            (System.Tasking.Task_List'(1 => Convert_Ids (T)));
  84       end if;
  85    end Abort_Task;
  86
  87    -----------------
  88    -- Convert_Ids --
  89    -----------------
  90
  91    function Convert_Ids (T : Task_Id) return System.Tasking.Task_Id is
  92    begin
  93       return System.Tasking.Task_Id (T);
  94    end Convert_Ids;
  95
  96    function Convert_Ids (T : System.Tasking.Task_Id) return Task_Id is
  97    begin
  98       return Task_Id (T);
  99    end Convert_Ids;
 100
 101    ------------------
 102    -- Current_Task --
 103    ------------------
 104
 105    function Current_Task return Task_Id is
 106    begin
 107       return Convert_Ids (System.Task_Primitives.Operations.Self);
 108    end Current_Task;
 109
 110    -----------
 111    -- Image --
 112    -----------
 113
 114    function Image (T : Task_Id) return String is
 115       function To_Address is new
 116         Ada.Unchecked_Conversion (Task_Id, System.Address);
 117
 118    begin
 119       if T = Null_Task_Id then
 120          return "";
 121
 122       elsif T.Common.Task_Image_Len = 0 then
 123          return System.Address_Image (To_Address (T));
 124
 125       else
 126          return T.Common.Task_Image (1 .. T.Common.Task_Image_Len)
 127             & "_" &  System.Address_Image (To_Address (T));
 128       end if;
 129    end Image;
 130
 131    -----------------
 132    -- Is_Callable --
 133    -----------------
 134
 135    function Is_Callable (T : Task_Id) return Boolean is
 136       Result : Boolean;
 137       Id     : constant System.Tasking.Task_Id := Convert_Ids (T);
 138    begin
 139       if T = Null_Task_Id then
 140          raise Program_Error;
 141       else
 142          System.Soft_Links.Abort_Defer.all;
 143
 144          if Single_Lock then
 145             STPO.Lock_RTS;
 146          end if;
 147
 148          STPO.Write_Lock (Id);
 149          Result := Id.Callable;
 150          STPO.Unlock (Id);
 151
 152          if Single_Lock then
 153             STPO.Unlock_RTS;
 154          end if;
 155
 156          System.Soft_Links.Abort_Undefer.all;
 157          return Result;
 158       end if;
 159    end Is_Callable;
 160
 161    -------------------
 162    -- Is_Terminated --
 163    -------------------
 164
 165    function Is_Terminated (T : Task_Id) return Boolean is
 166       Result : Boolean;
 167       Id     : constant System.Tasking.Task_Id := Convert_Ids (T);
 168
 169       use System.Tasking;
 170
 171    begin
 172       if T = Null_Task_Id then
 173          raise Program_Error;
 174       else
 175          System.Soft_Links.Abort_Defer.all;
 176
 177          if Single_Lock then
 178             STPO.Lock_RTS;
 179          end if;
 180
 181          STPO.Write_Lock (Id);
 182          Result := Id.Common.State = Terminated;
 183          STPO.Unlock (Id);
 184
 185          if Single_Lock then
 186             STPO.Unlock_RTS;
 187          end if;
 188
 189          System.Soft_Links.Abort_Undefer.all;
 190          return Result;
 191       end if;
 192    end Is_Terminated;
 193
 194 end Ada.Task_Identification;