gcc/ada/a-taside.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                        GNAT RUN-TIME COMPONENTS                          --
   4 --                                                                          --
   5 --              A D A . T A S K _ I D E N T I F I C A T I O N               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Image;
  35 with System.Parameters;
  36 with System.Soft_Links;
  37 with System.Task_Primitives;
  38 with System.Task_Primitives.Operations;
  39 with Ada.Unchecked_Conversion;
  40
  41 pragma Warnings (Off);
  42 --  Allow withing of non-Preelaborated units in Ada 2005 mode where this
  43 --  package will be categorized as Preelaborate. See AI-362 for details.
  44 --  It is safe in the context of the run-time to violate the rules!
  45
  46 with System.Tasking.Utilities;
  47
  48 pragma Warnings (On);
  49
  50 package body Ada.Task_Identification is
  51
  52    use System.Parameters;
  53
  54    package STPO renames System.Task_Primitives.Operations;
  55
  56    -----------------------
  57    -- Local Subprograms --
  58    -----------------------
  59
  60    function Convert_Ids (T : Task_Id) return System.Tasking.Task_Id;
  61    function Convert_Ids (T : System.Tasking.Task_Id) return Task_Id;
  62    pragma Inline (Convert_Ids);
  63    --  Conversion functions between different forms of Task_Id
  64
  65    ---------
  66    -- "=" --
  67    ---------
  68
  69    function "=" (Left, Right : Task_Id) return Boolean is
  70    begin
  71       return System.Tasking."=" (Convert_Ids (Left), Convert_Ids (Right));
  72    end "=";
  73
  74    -----------------
  75    -- Abort_Task --
  76    ----------------
  77
  78    procedure Abort_Task (T : Task_Id) is
  79    begin
  80       if T = Null_Task_Id then
  81          raise Program_Error;
  82       else
  83          System.Tasking.Utilities.Abort_Tasks
  84            (System.Tasking.Task_List'(1 => Convert_Ids (T)));
  85       end if;
  86    end Abort_Task;
  87
  88    -----------------
  89    -- Convert_Ids --
  90    -----------------
  91
  92    function Convert_Ids (T : Task_Id) return System.Tasking.Task_Id is
  93    begin
  94       return System.Tasking.Task_Id (T);
  95    end Convert_Ids;
  96
  97    function Convert_Ids (T : System.Tasking.Task_Id) return Task_Id is
  98    begin
  99       return Task_Id (T);
 100    end Convert_Ids;
 101
 102    ------------------
 103    -- Current_Task --
 104    ------------------
 105
 106    function Current_Task return Task_Id is
 107    begin
 108       return Convert_Ids (System.Task_Primitives.Operations.Self);
 109    end Current_Task;
 110
 111    -----------
 112    -- Image --
 113    -----------
 114
 115    function Image (T : Task_Id) return String is
 116       function To_Address is new
 117         Ada.Unchecked_Conversion
 118           (Task_Id, System.Task_Primitives.Task_Address);
 119
 120    begin
 121       if T = Null_Task_Id then
 122          return "";
 123
 124       elsif T.Common.Task_Image_Len = 0 then
 125          return System.Address_Image (To_Address (T));
 126
 127       else
 128          return T.Common.Task_Image (1 .. T.Common.Task_Image_Len)
 129             & "_" &  System.Address_Image (To_Address (T));
 130       end if;
 131    end Image;
 132
 133    -----------------
 134    -- Is_Callable --
 135    -----------------
 136
 137    function Is_Callable (T : Task_Id) return Boolean is
 138       Result : Boolean;
 139       Id     : constant System.Tasking.Task_Id := Convert_Ids (T);
 140    begin
 141       if T = Null_Task_Id then
 142          raise Program_Error;
 143       else
 144          System.Soft_Links.Abort_Defer.all;
 145
 146          if Single_Lock then
 147             STPO.Lock_RTS;
 148          end if;
 149
 150          STPO.Write_Lock (Id);
 151          Result := Id.Callable;
 152          STPO.Unlock (Id);
 153
 154          if Single_Lock then
 155             STPO.Unlock_RTS;
 156          end if;
 157
 158          System.Soft_Links.Abort_Undefer.all;
 159          return Result;
 160       end if;
 161    end Is_Callable;
 162
 163    -------------------
 164    -- Is_Terminated --
 165    -------------------
 166
 167    function Is_Terminated (T : Task_Id) return Boolean is
 168       Result : Boolean;
 169       Id     : constant System.Tasking.Task_Id := Convert_Ids (T);
 170
 171       use System.Tasking;
 172
 173    begin
 174       if T = Null_Task_Id then
 175          raise Program_Error;
 176       else
 177          System.Soft_Links.Abort_Defer.all;
 178
 179          if Single_Lock then
 180             STPO.Lock_RTS;
 181          end if;
 182
 183          STPO.Write_Lock (Id);
 184          Result := Id.Common.State = Terminated;
 185          STPO.Unlock (Id);
 186
 187          if Single_Lock then
 188             STPO.Unlock_RTS;
 189          end if;
 190
 191          System.Soft_Links.Abort_Undefer.all;
 192          return Result;
 193       end if;
 194    end Is_Terminated;
 195
 196 end Ada.Task_Identification;