gcc/ada/a-stzunb.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --      A D A . S T R I N G S . W I D E _ W I D E _ U N B O U N D E D       --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Strings.Wide_Wide_Fixed;
  35 with Ada.Strings.Wide_Wide_Search;
  36 with Ada.Unchecked_Deallocation;
  37
  38 package body Ada.Strings.Wide_Wide_Unbounded is
  39
  40    use Ada.Finalization;
  41
  42    ---------
  43    -- "&" --
  44    ---------
  45
  46    function "&"
  47      (Left  : Unbounded_Wide_Wide_String;
  48       Right : Unbounded_Wide_Wide_String) return Unbounded_Wide_Wide_String
  49    is
  50       L_Length : constant Natural := Left.Last;
  51       R_Length : constant Natural := Right.Last;
  52       Result   : Unbounded_Wide_Wide_String;
  53
  54    begin
  55       Result.Last := L_Length + R_Length;
  56
  57       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
  58
  59       Result.Reference (1 .. L_Length) :=
  60         Left.Reference (1 .. Left.Last);
  61       Result.Reference (L_Length + 1 .. Result.Last) :=
  62         Right.Reference (1 .. Right.Last);
  63
  64       return Result;
  65    end "&";
  66
  67    function "&"
  68      (Left  : Unbounded_Wide_Wide_String;
  69       Right : Wide_Wide_String) return Unbounded_Wide_Wide_String
  70    is
  71       L_Length : constant Natural := Left.Last;
  72       Result   : Unbounded_Wide_Wide_String;
  73
  74    begin
  75       Result.Last := L_Length + Right'Length;
  76
  77       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
  78
  79       Result.Reference (1 .. L_Length) := Left.Reference (1 .. Left.Last);
  80       Result.Reference (L_Length + 1 .. Result.Last) := Right;
  81
  82       return Result;
  83    end "&";
  84
  85    function "&"
  86      (Left  : Wide_Wide_String;
  87       Right : Unbounded_Wide_Wide_String) return Unbounded_Wide_Wide_String
  88    is
  89       R_Length : constant Natural := Right.Last;
  90       Result   : Unbounded_Wide_Wide_String;
  91
  92    begin
  93       Result.Last := Left'Length + R_Length;
  94
  95       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
  96
  97       Result.Reference (1 .. Left'Length) := Left;
  98       Result.Reference (Left'Length + 1 .. Result.Last) :=
  99         Right.Reference (1 .. Right.Last);
 100
 101       return Result;
 102    end "&";
 103
 104    function "&"
 105      (Left  : Unbounded_Wide_Wide_String;
 106       Right : Wide_Wide_Character) return Unbounded_Wide_Wide_String
 107    is
 108       Result : Unbounded_Wide_Wide_String;
 109
 110    begin
 111       Result.Last := Left.Last + 1;
 112
 113       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
 114
 115       Result.Reference (1 .. Result.Last - 1) :=
 116         Left.Reference (1 .. Left.Last);
 117       Result.Reference (Result.Last) := Right;
 118
 119       return Result;
 120    end "&";
 121
 122    function "&"
 123      (Left  : Wide_Wide_Character;
 124       Right : Unbounded_Wide_Wide_String) return Unbounded_Wide_Wide_String
 125    is
 126       Result : Unbounded_Wide_Wide_String;
 127
 128    begin
 129       Result.Last := Right.Last + 1;
 130
 131       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
 132       Result.Reference (1) := Left;
 133       Result.Reference (2 .. Result.Last) :=
 134         Right.Reference (1 .. Right.Last);
 135       return Result;
 136    end "&";
 137
 138    ---------
 139    -- "*" --
 140    ---------
 141
 142    function "*"
 143      (Left  : Natural;
 144       Right : Wide_Wide_Character) return Unbounded_Wide_Wide_String
 145    is
 146       Result : Unbounded_Wide_Wide_String;
 147
 148    begin
 149       Result.Last   := Left;
 150
 151       Result.Reference := new Wide_Wide_String (1 .. Left);
 152       for J in Result.Reference'Range loop
 153          Result.Reference (J) := Right;
 154       end loop;
 155
 156       return Result;
 157    end "*";
 158
 159    function "*"
 160      (Left  : Natural;
 161       Right : Wide_Wide_String) return Unbounded_Wide_Wide_String
 162    is
 163       Len    : constant Natural := Right'Length;
 164       K      : Positive;
 165       Result : Unbounded_Wide_Wide_String;
 166
 167    begin
 168       Result.Last := Left * Len;
 169
 170       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
 171
 172       K := 1;
 173       for J in 1 .. Left loop
 174          Result.Reference (K .. K + Len - 1) := Right;
 175          K := K + Len;
 176       end loop;
 177
 178       return Result;
 179    end "*";
 180
 181    function "*"
 182      (Left  : Natural;
 183       Right : Unbounded_Wide_Wide_String) return Unbounded_Wide_Wide_String
 184    is
 185       Len    : constant Natural := Right.Last;
 186       K      : Positive;
 187       Result : Unbounded_Wide_Wide_String;
 188
 189    begin
 190       Result.Last := Left * Len;
 191
 192       Result.Reference := new Wide_Wide_String (1 .. Result.Last);
 193
 194       K := 1;
 195       for J in 1 .. Left loop
 196          Result.Reference (K .. K + Len - 1) :=
 197            Right.Reference (1 .. Right.Last);
 198          K := K + Len;
 199       end loop;
 200
 201       return Result;
 202    end "*";
 203
 204    ---------
 205    -- "<" --
 206    ---------
 207
 208    function "<"
 209      (Left  : Unbounded_Wide_Wide_String;
 210       Right : Unbounded_Wide_Wide_String) return Boolean
 211    is
 212    begin
 213       return
 214         Left.Reference (1 .. Left.Last) < Right.Reference (1 .. Right.Last);
 215    end "<";
 216
 217    function "<"
 218      (Left  : Unbounded_Wide_Wide_String;
 219       Right : Wide_Wide_String) return Boolean
 220    is
 221    begin
 222       return Left.Reference (1 .. Left.Last) < Right;
 223    end "<";
 224
 225    function "<"
 226      (Left  : Wide_Wide_String;
 227       Right : Unbounded_Wide_Wide_String) return Boolean
 228    is
 229    begin
 230       return Left < Right.Reference (1 .. Right.Last);
 231    end "<";
 232
 233    ----------
 234    -- "<=" --
 235    ----------
 236
 237    function "<="
 238      (Left  : Unbounded_Wide_Wide_String;
 239       Right : Unbounded_Wide_Wide_String) return Boolean
 240    is
 241    begin
 242       return
 243         Left.Reference (1 .. Left.Last) <= Right.Reference (1 .. Right.Last);
 244    end "<=";
 245
 246    function "<="
 247      (Left  : Unbounded_Wide_Wide_String;
 248       Right : Wide_Wide_String) return Boolean
 249    is
 250    begin
 251       return Left.Reference (1 .. Left.Last) <= Right;
 252    end "<=";
 253
 254    function "<="
 255      (Left  : Wide_Wide_String;
 256       Right : Unbounded_Wide_Wide_String) return Boolean
 257    is
 258    begin
 259       return Left <= Right.Reference (1 .. Right.Last);
 260    end "<=";
 261
 262    ---------
 263    -- "=" --
 264    ---------
 265
 266    function "="
 267      (Left  : Unbounded_Wide_Wide_String;
 268       Right : Unbounded_Wide_Wide_String) return Boolean
 269    is
 270    begin
 271       return
 272         Left.Reference (1 .. Left.Last) = Right.Reference (1 .. Right.Last);
 273    end "=";
 274
 275    function "="
 276      (Left  : Unbounded_Wide_Wide_String;
 277       Right : Wide_Wide_String) return Boolean
 278    is
 279    begin
 280       return Left.Reference (1 .. Left.Last) = Right;
 281    end "=";
 282
 283    function "="
 284      (Left  : Wide_Wide_String;
 285       Right : Unbounded_Wide_Wide_String) return Boolean
 286    is
 287    begin
 288       return Left = Right.Reference (1 .. Right.Last);
 289    end "=";
 290
 291    ---------
 292    -- ">" --
 293    ---------
 294
 295    function ">"
 296      (Left  : Unbounded_Wide_Wide_String;
 297       Right : Unbounded_Wide_Wide_String) return Boolean
 298    is
 299    begin
 300       return
 301         Left.Reference (1 .. Left.Last) > Right.Reference (1 .. Right.Last);
 302    end ">";
 303
 304    function ">"
 305      (Left  : Unbounded_Wide_Wide_String;
 306       Right : Wide_Wide_String) return Boolean
 307    is
 308    begin
 309       return Left.Reference (1 .. Left.Last) > Right;
 310    end ">";
 311
 312    function ">"
 313      (Left  : Wide_Wide_String;
 314       Right : Unbounded_Wide_Wide_String) return Boolean
 315    is
 316    begin
 317       return Left > Right.Reference (1 .. Right.Last);
 318    end ">";
 319
 320    ----------
 321    -- ">=" --
 322    ----------
 323
 324    function ">="
 325      (Left  : Unbounded_Wide_Wide_String;
 326       Right : Unbounded_Wide_Wide_String) return Boolean
 327    is
 328    begin
 329       return
 330         Left.Reference (1 .. Left.Last) >= Right.Reference (1 .. Right.Last);
 331    end ">=";
 332
 333    function ">="
 334      (Left  : Unbounded_Wide_Wide_String;
 335       Right : Wide_Wide_String) return Boolean
 336    is
 337    begin
 338       return Left.Reference (1 .. Left.Last) >= Right;
 339    end ">=";
 340
 341    function ">="
 342      (Left  : Wide_Wide_String;
 343       Right : Unbounded_Wide_Wide_String) return Boolean
 344    is
 345    begin
 346       return Left >= Right.Reference (1 .. Right.Last);
 347    end ">=";
 348
 349    ------------
 350    -- Adjust --
 351    ------------
 352
 353    procedure Adjust (Object : in out Unbounded_Wide_Wide_String) is
 354    begin
 355       --  Copy string, except we do not copy the statically allocated null
 356       --  string, since it can never be deallocated. Note that we do not copy
 357       --  extra string room here to avoid dragging unused allocated memory.
 358
 359       if Object.Reference /= Null_Wide_Wide_String'Access then
 360          Object.Reference :=
 361            new Wide_Wide_String'(Object.Reference (1 .. Object.Last));
 362       end if;
 363    end Adjust;
 364
 365    ------------
 366    -- Append --
 367    ------------
 368
 369    procedure Append
 370      (Source   : in out Unbounded_Wide_Wide_String;
 371       New_Item : Unbounded_Wide_Wide_String)
 372    is
 373    begin
 374       Realloc_For_Chunk (Source, New_Item.Last);
 375       Source.Reference (Source.Last + 1 .. Source.Last + New_Item.Last) :=
 376         New_Item.Reference (1 .. New_Item.Last);
 377       Source.Last := Source.Last + New_Item.Last;
 378    end Append;
 379
 380    procedure Append
 381      (Source   : in out Unbounded_Wide_Wide_String;
 382       New_Item : Wide_Wide_String)
 383    is
 384    begin
 385       Realloc_For_Chunk (Source, New_Item'Length);
 386       Source.Reference (Source.Last + 1 .. Source.Last + New_Item'Length) :=
 387         New_Item;
 388       Source.Last := Source.Last + New_Item'Length;
 389    end Append;
 390
 391    procedure Append
 392      (Source   : in out Unbounded_Wide_Wide_String;
 393       New_Item : Wide_Wide_Character)
 394    is
 395    begin
 396       Realloc_For_Chunk (Source, 1);
 397       Source.Reference (Source.Last + 1) := New_Item;
 398       Source.Last := Source.Last + 1;
 399    end Append;
 400
 401    -----------
 402    -- Count --
 403    -----------
 404
 405    function Count
 406      (Source  : Unbounded_Wide_Wide_String;
 407       Pattern : Wide_Wide_String;
 408       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping :=
 409                   Wide_Wide_Maps.Identity)
 410       return Natural
 411    is
 412    begin
 413       return
 414         Wide_Wide_Search.Count
 415           (Source.Reference (1 .. Source.Last), Pattern, Mapping);
 416    end Count;
 417
 418    function Count
 419      (Source  : Unbounded_Wide_Wide_String;
 420       Pattern : Wide_Wide_String;
 421       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping_Function)
 422       return Natural
 423    is
 424    begin
 425       return
 426         Wide_Wide_Search.Count
 427           (Source.Reference (1 .. Source.Last), Pattern, Mapping);
 428    end Count;
 429
 430    function Count
 431      (Source : Unbounded_Wide_Wide_String;
 432       Set    : Wide_Wide_Maps.Wide_Wide_Character_Set) return Natural
 433    is
 434    begin
 435       return
 436         Wide_Wide_Search.Count
 437         (Source.Reference (1 .. Source.Last), Set);
 438    end Count;
 439
 440    ------------
 441    -- Delete --
 442    ------------
 443
 444    function Delete
 445      (Source  : Unbounded_Wide_Wide_String;
 446       From    : Positive;
 447       Through : Natural) return Unbounded_Wide_Wide_String
 448    is
 449    begin
 450       return
 451         To_Unbounded_Wide_Wide_String
 452           (Wide_Wide_Fixed.Delete
 453              (Source.Reference (1 .. Source.Last), From, Through));
 454    end Delete;
 455
 456    procedure Delete
 457      (Source  : in out Unbounded_Wide_Wide_String;
 458       From    : Positive;
 459       Through : Natural)
 460    is
 461    begin
 462       if From > Through then
 463          null;
 464
 465       elsif From < Source.Reference'First or else Through > Source.Last then
 466          raise Index_Error;
 467
 468       else
 469          declare
 470             Len : constant Natural := Through - From + 1;
 471
 472          begin
 473             Source.Reference (From .. Source.Last - Len) :=
 474               Source.Reference (Through + 1 .. Source.Last);
 475             Source.Last := Source.Last - Len;
 476          end;
 477       end if;
 478    end Delete;
 479
 480    -------------
 481    -- Element --
 482    -------------
 483
 484    function Element
 485      (Source : Unbounded_Wide_Wide_String;
 486       Index  : Positive) return Wide_Wide_Character
 487    is
 488    begin
 489       if Index <= Source.Last then
 490          return Source.Reference (Index);
 491       else
 492          raise Strings.Index_Error;
 493       end if;
 494    end Element;
 495
 496    --------------
 497    -- Finalize --
 498    --------------
 499
 500    procedure Finalize (Object : in out Unbounded_Wide_Wide_String) is
 501       procedure Deallocate is
 502         new Ada.Unchecked_Deallocation
 503           (Wide_Wide_String, Wide_Wide_String_Access);
 504
 505    begin
 506       --  Note: Don't try to free statically allocated null string
 507
 508       if Object.Reference /= Null_Wide_Wide_String'Access then
 509          Deallocate (Object.Reference);
 510          Object.Reference := Null_Unbounded_Wide_Wide_String.Reference;
 511          Object.Last := 0;
 512       end if;
 513    end Finalize;
 514
 515    ----------------
 516    -- Find_Token --
 517    ----------------
 518
 519    procedure Find_Token
 520      (Source : Unbounded_Wide_Wide_String;
 521       Set    : Wide_Wide_Maps.Wide_Wide_Character_Set;
 522       Test   : Strings.Membership;
 523       First  : out Positive;
 524       Last   : out Natural)
 525    is
 526    begin
 527       Wide_Wide_Search.Find_Token
 528         (Source.Reference (1 .. Source.Last), Set, Test, First, Last);
 529    end Find_Token;
 530
 531    ----------
 532    -- Free --
 533    ----------
 534
 535    procedure Free (X : in out Wide_Wide_String_Access) is
 536       procedure Deallocate is
 537         new Ada.Unchecked_Deallocation
 538           (Wide_Wide_String, Wide_Wide_String_Access);
 539
 540    begin
 541       --  Note: Do not try to free statically allocated null string
 542
 543       if X /= Null_Unbounded_Wide_Wide_String.Reference then
 544          Deallocate (X);
 545       end if;
 546    end Free;
 547
 548    ----------
 549    -- Head --
 550    ----------
 551
 552    function Head
 553      (Source : Unbounded_Wide_Wide_String;
 554       Count  : Natural;
 555       Pad    : Wide_Wide_Character := Wide_Wide_Space)
 556       return Unbounded_Wide_Wide_String
 557    is
 558    begin
 559       return To_Unbounded_Wide_Wide_String
 560         (Wide_Wide_Fixed.Head
 561            (Source.Reference (1 .. Source.Last), Count, Pad));
 562    end Head;
 563
 564    procedure Head
 565      (Source : in out Unbounded_Wide_Wide_String;
 566       Count  : Natural;
 567       Pad    : Wide_Wide_Character := Wide_Wide_Space)
 568    is
 569       Old : Wide_Wide_String_Access := Source.Reference;
 570    begin
 571       Source.Reference :=
 572         new Wide_Wide_String'
 573           (Wide_Wide_Fixed.Head
 574              (Source.Reference (1 .. Source.Last), Count, Pad));
 575       Source.Last := Source.Reference'Length;
 576       Free (Old);
 577    end Head;
 578
 579    -----------
 580    -- Index --
 581    -----------
 582
 583    function Index
 584      (Source  : Unbounded_Wide_Wide_String;
 585       Pattern : Wide_Wide_String;
 586       Going   : Strings.Direction := Strings.Forward;
 587       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping :=
 588                   Wide_Wide_Maps.Identity)
 589       return Natural
 590    is
 591    begin
 592       return
 593         Wide_Wide_Search.Index
 594           (Source.Reference (1 .. Source.Last), Pattern, Going, Mapping);
 595    end Index;
 596
 597    function Index
 598      (Source  : Unbounded_Wide_Wide_String;
 599       Pattern : Wide_Wide_String;
 600       Going   : Direction := Forward;
 601       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping_Function)
 602       return Natural
 603    is
 604    begin
 605       return
 606         Wide_Wide_Search.Index
 607           (Source.Reference (1 .. Source.Last), Pattern, Going, Mapping);
 608    end Index;
 609
 610    function Index
 611      (Source : Unbounded_Wide_Wide_String;
 612       Set    : Wide_Wide_Maps.Wide_Wide_Character_Set;
 613       Test   : Strings.Membership := Strings.Inside;
 614       Going  : Strings.Direction  := Strings.Forward) return Natural
 615    is
 616    begin
 617       return Wide_Wide_Search.Index
 618         (Source.Reference (1 .. Source.Last), Set, Test, Going);
 619    end Index;
 620
 621    function Index
 622      (Source  : Unbounded_Wide_Wide_String;
 623       Pattern : Wide_Wide_String;
 624       From    : Positive;
 625       Going   : Direction := Forward;
 626       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping :=
 627                   Wide_Wide_Maps.Identity)
 628       return Natural
 629    is
 630    begin
 631       return
 632         Wide_Wide_Search.Index
 633           (Source.Reference (1 .. Source.Last), Pattern, From, Going, Mapping);
 634    end Index;
 635
 636    function Index
 637      (Source  : Unbounded_Wide_Wide_String;
 638       Pattern : Wide_Wide_String;
 639       From    : Positive;
 640       Going   : Direction := Forward;
 641       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping_Function)
 642       return Natural
 643    is
 644    begin
 645       return
 646         Wide_Wide_Search.Index
 647           (Source.Reference (1 .. Source.Last), Pattern, From, Going, Mapping);
 648    end Index;
 649
 650
 651    function Index
 652      (Source : Unbounded_Wide_Wide_String;
 653       Set    : Wide_Wide_Maps.Wide_Wide_Character_Set;
 654       From   : Positive;
 655       Test   : Membership := Inside;
 656       Going  : Direction := Forward) return Natural
 657    is
 658    begin
 659       return
 660         Wide_Wide_Search.Index
 661           (Source.Reference (1 .. Source.Last), Set, From, Test, Going);
 662    end Index;
 663
 664    function Index_Non_Blank
 665      (Source : Unbounded_Wide_Wide_String;
 666       Going  : Strings.Direction := Strings.Forward) return Natural
 667    is
 668    begin
 669       return
 670         Wide_Wide_Search.Index_Non_Blank
 671           (Source.Reference (1 .. Source.Last), Going);
 672    end Index_Non_Blank;
 673
 674    function Index_Non_Blank
 675      (Source : Unbounded_Wide_Wide_String;
 676       From   : Positive;
 677       Going  : Direction := Forward) return Natural
 678    is
 679    begin
 680       return
 681         Wide_Wide_Search.Index_Non_Blank
 682           (Source.Reference (1 .. Source.Last), From, Going);
 683    end Index_Non_Blank;
 684
 685    ----------------
 686    -- Initialize --
 687    ----------------
 688
 689    procedure Initialize (Object : in out Unbounded_Wide_Wide_String) is
 690    begin
 691       Object.Reference := Null_Unbounded_Wide_Wide_String.Reference;
 692       Object.Last      := 0;
 693    end Initialize;
 694
 695    ------------
 696    -- Insert --
 697    ------------
 698
 699    function Insert
 700      (Source   : Unbounded_Wide_Wide_String;
 701       Before   : Positive;
 702       New_Item : Wide_Wide_String) return Unbounded_Wide_Wide_String
 703    is
 704    begin
 705       return
 706         To_Unbounded_Wide_Wide_String
 707           (Wide_Wide_Fixed.Insert
 708              (Source.Reference (1 .. Source.Last), Before, New_Item));
 709    end Insert;
 710
 711    procedure Insert
 712      (Source   : in out Unbounded_Wide_Wide_String;
 713       Before   : Positive;
 714       New_Item : Wide_Wide_String)
 715    is
 716    begin
 717       if Before not in Source.Reference'First .. Source.Last + 1 then
 718          raise Index_Error;
 719       end if;
 720
 721       Realloc_For_Chunk (Source, New_Item'Size);
 722
 723       Source.Reference
 724         (Before +  New_Item'Length .. Source.Last + New_Item'Length) :=
 725            Source.Reference (Before .. Source.Last);
 726
 727       Source.Reference (Before .. Before + New_Item'Length - 1) := New_Item;
 728       Source.Last := Source.Last + New_Item'Length;
 729    end Insert;
 730
 731    ------------
 732    -- Length --
 733    ------------
 734
 735    function Length (Source : Unbounded_Wide_Wide_String) return Natural is
 736    begin
 737       return Source.Last;
 738    end Length;
 739
 740    ---------------
 741    -- Overwrite --
 742    ---------------
 743
 744    function Overwrite
 745      (Source   : Unbounded_Wide_Wide_String;
 746       Position : Positive;
 747       New_Item : Wide_Wide_String) return Unbounded_Wide_Wide_String
 748    is
 749    begin
 750       return
 751         To_Unbounded_Wide_Wide_String
 752           (Wide_Wide_Fixed.Overwrite
 753             (Source.Reference (1 .. Source.Last), Position, New_Item));
 754    end Overwrite;
 755
 756    procedure Overwrite
 757      (Source    : in out Unbounded_Wide_Wide_String;
 758       Position  : Positive;
 759       New_Item  : Wide_Wide_String)
 760    is
 761       NL : constant Natural := New_Item'Length;
 762    begin
 763       if Position <= Source.Last - NL + 1 then
 764          Source.Reference (Position .. Position + NL - 1) := New_Item;
 765       else
 766          declare
 767             Old : Wide_Wide_String_Access := Source.Reference;
 768          begin
 769             Source.Reference := new Wide_Wide_String'
 770               (Wide_Wide_Fixed.Overwrite
 771                 (Source.Reference (1 .. Source.Last), Position, New_Item));
 772             Source.Last := Source.Reference'Length;
 773             Free (Old);
 774          end;
 775       end if;
 776    end Overwrite;
 777
 778    -----------------------
 779    -- Realloc_For_Chunk --
 780    -----------------------
 781
 782    procedure Realloc_For_Chunk
 783      (Source     : in out Unbounded_Wide_Wide_String;
 784       Chunk_Size : Natural)
 785    is
 786       Growth_Factor : constant := 50;
 787       S_Length      : constant Natural := Source.Reference'Length;
 788
 789    begin
 790       if Chunk_Size > S_Length - Source.Last then
 791          declare
 792             Alloc_Chunk_Size : constant Positive :=
 793                                  Chunk_Size + (S_Length / Growth_Factor);
 794             Tmp : Wide_Wide_String_Access;
 795          begin
 796             Tmp := new Wide_Wide_String (1 .. S_Length + Alloc_Chunk_Size);
 797             Tmp (1 .. Source.Last) := Source.Reference (1 .. Source.Last);
 798             Free (Source.Reference);
 799             Source.Reference := Tmp;
 800          end;
 801       end if;
 802    end Realloc_For_Chunk;
 803
 804    ---------------------
 805    -- Replace_Element --
 806    ---------------------
 807
 808    procedure Replace_Element
 809      (Source : in out Unbounded_Wide_Wide_String;
 810       Index  : Positive;
 811       By     : Wide_Wide_Character)
 812    is
 813    begin
 814       if Index <= Source.Last then
 815          Source.Reference (Index) := By;
 816       else
 817          raise Strings.Index_Error;
 818       end if;
 819    end Replace_Element;
 820
 821    -------------------
 822    -- Replace_Slice --
 823    -------------------
 824
 825    function Replace_Slice
 826      (Source : Unbounded_Wide_Wide_String;
 827       Low    : Positive;
 828       High   : Natural;
 829       By     : Wide_Wide_String) return Unbounded_Wide_Wide_String
 830    is
 831    begin
 832       return To_Unbounded_Wide_Wide_String
 833         (Wide_Wide_Fixed.Replace_Slice
 834            (Source.Reference (1 .. Source.Last), Low, High, By));
 835    end Replace_Slice;
 836
 837    procedure Replace_Slice
 838      (Source : in out Unbounded_Wide_Wide_String;
 839       Low    : Positive;
 840       High   : Natural;
 841       By     : Wide_Wide_String)
 842    is
 843       Old : Wide_Wide_String_Access := Source.Reference;
 844    begin
 845       Source.Reference := new Wide_Wide_String'
 846         (Wide_Wide_Fixed.Replace_Slice
 847            (Source.Reference (1 .. Source.Last), Low, High, By));
 848       Source.Last := Source.Reference'Length;
 849       Free (Old);
 850    end Replace_Slice;
 851
 852    ------------------------------------
 853    -- Set_Unbounded_Wide_Wide_String --
 854    ------------------------------------
 855
 856    procedure Set_Unbounded_Wide_Wide_String
 857      (Target : out Unbounded_Wide_Wide_String;
 858       Source : Wide_Wide_String)
 859    is
 860    begin
 861       Target.Last          := Source'Length;
 862       Target.Reference     := new Wide_Wide_String (1 .. Source'Length);
 863       Target.Reference.all := Source;
 864    end Set_Unbounded_Wide_Wide_String;
 865
 866    -----------
 867    -- Slice --
 868    -----------
 869
 870    function Slice
 871      (Source : Unbounded_Wide_Wide_String;
 872       Low    : Positive;
 873       High   : Natural) return Wide_Wide_String
 874    is
 875    begin
 876       --  Note: test of High > Length is in accordance with AI95-00128
 877
 878       if Low > Source.Last + 1 or else High > Source.Last then
 879          raise Index_Error;
 880       else
 881          return Source.Reference (Low .. High);
 882       end if;
 883    end Slice;
 884
 885    ----------
 886    -- Tail --
 887    ----------
 888
 889    function Tail
 890      (Source : Unbounded_Wide_Wide_String;
 891       Count  : Natural;
 892       Pad    : Wide_Wide_Character := Wide_Wide_Space)
 893       return Unbounded_Wide_Wide_String is
 894    begin
 895       return To_Unbounded_Wide_Wide_String
 896         (Wide_Wide_Fixed.Tail
 897            (Source.Reference (1 .. Source.Last), Count, Pad));
 898    end Tail;
 899
 900    procedure Tail
 901      (Source : in out Unbounded_Wide_Wide_String;
 902       Count  : Natural;
 903       Pad    : Wide_Wide_Character := Wide_Wide_Space)
 904    is
 905       Old : Wide_Wide_String_Access := Source.Reference;
 906    begin
 907       Source.Reference := new Wide_Wide_String'
 908         (Wide_Wide_Fixed.Tail
 909            (Source.Reference (1 .. Source.Last), Count, Pad));
 910       Source.Last := Source.Reference'Length;
 911       Free (Old);
 912    end Tail;
 913
 914    ------------------------------
 915    -- To_Unbounded_Wide_Wide_String --
 916    ------------------------------
 917
 918    function To_Unbounded_Wide_Wide_String
 919      (Source : Wide_Wide_String) return Unbounded_Wide_Wide_String
 920    is
 921       Result : Unbounded_Wide_Wide_String;
 922    begin
 923       Result.Last          := Source'Length;
 924       Result.Reference     := new Wide_Wide_String (1 .. Source'Length);
 925       Result.Reference.all := Source;
 926       return Result;
 927    end To_Unbounded_Wide_Wide_String;
 928
 929    function To_Unbounded_Wide_Wide_String
 930      (Length : Natural) return Unbounded_Wide_Wide_String
 931    is
 932       Result : Unbounded_Wide_Wide_String;
 933    begin
 934       Result.Last      := Length;
 935       Result.Reference := new Wide_Wide_String (1 .. Length);
 936       return Result;
 937    end To_Unbounded_Wide_Wide_String;
 938
 939    -------------------
 940    -- To_Wide_Wide_String --
 941    --------------------
 942
 943    function To_Wide_Wide_String
 944      (Source : Unbounded_Wide_Wide_String) return Wide_Wide_String
 945    is
 946    begin
 947       return Source.Reference (1 .. Source.Last);
 948    end To_Wide_Wide_String;
 949
 950
 951    ---------------
 952    -- Translate --
 953    ---------------
 954
 955    function Translate
 956      (Source  : Unbounded_Wide_Wide_String;
 957       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping)
 958       return Unbounded_Wide_Wide_String
 959    is
 960    begin
 961       return
 962         To_Unbounded_Wide_Wide_String
 963           (Wide_Wide_Fixed.Translate
 964              (Source.Reference (1 .. Source.Last), Mapping));
 965    end Translate;
 966
 967    procedure Translate
 968      (Source  : in out Unbounded_Wide_Wide_String;
 969       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping)
 970    is
 971    begin
 972       Wide_Wide_Fixed.Translate (Source.Reference (1 .. Source.Last), Mapping);
 973    end Translate;
 974
 975    function Translate
 976      (Source  : Unbounded_Wide_Wide_String;
 977       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping_Function)
 978       return Unbounded_Wide_Wide_String
 979    is
 980    begin
 981       return
 982         To_Unbounded_Wide_Wide_String
 983           (Wide_Wide_Fixed.Translate
 984             (Source.Reference (1 .. Source.Last), Mapping));
 985    end Translate;
 986
 987    procedure Translate
 988      (Source  : in out Unbounded_Wide_Wide_String;
 989       Mapping : Wide_Wide_Maps.Wide_Wide_Character_Mapping_Function)
 990    is
 991    begin
 992       Wide_Wide_Fixed.Translate (Source.Reference (1 .. Source.Last), Mapping);
 993    end Translate;
 994
 995    ----------
 996    -- Trim --
 997    ----------
 998
 999    function Trim
1000      (Source : Unbounded_Wide_Wide_String;
1001       Side   : Trim_End) return Unbounded_Wide_Wide_String
1002    is
1003    begin
1004       return
1005         To_Unbounded_Wide_Wide_String
1006           (Wide_Wide_Fixed.Trim (Source.Reference (1 .. Source.Last), Side));
1007    end Trim;
1008
1009    procedure Trim
1010      (Source : in out Unbounded_Wide_Wide_String;
1011       Side   : Trim_End)
1012    is
1013       Old : Wide_Wide_String_Access := Source.Reference;
1014    begin
1015       Source.Reference :=
1016         new Wide_Wide_String'
1017           (Wide_Wide_Fixed.Trim (Source.Reference (1 .. Source.Last), Side));
1018       Source.Last      := Source.Reference'Length;
1019       Free (Old);
1020    end Trim;
1021
1022    function Trim
1023      (Source : Unbounded_Wide_Wide_String;
1024       Left   : Wide_Wide_Maps.Wide_Wide_Character_Set;
1025       Right  : Wide_Wide_Maps.Wide_Wide_Character_Set)
1026       return Unbounded_Wide_Wide_String
1027    is
1028    begin
1029       return
1030         To_Unbounded_Wide_Wide_String
1031           (Wide_Wide_Fixed.Trim
1032              (Source.Reference (1 .. Source.Last), Left, Right));
1033    end Trim;
1034
1035    procedure Trim
1036      (Source : in out Unbounded_Wide_Wide_String;
1037       Left   : Wide_Wide_Maps.Wide_Wide_Character_Set;
1038       Right  : Wide_Wide_Maps.Wide_Wide_Character_Set)
1039    is
1040       Old : Wide_Wide_String_Access := Source.Reference;
1041    begin
1042       Source.Reference :=
1043         new Wide_Wide_String'
1044           (Wide_Wide_Fixed.Trim
1045              (Source.Reference (1 .. Source.Last), Left, Right));
1046       Source.Last      := Source.Reference'Length;
1047       Free (Old);
1048    end Trim;
1049
1050    ---------------------
1051    -- Unbounded_Slice --
1052    ---------------------
1053
1054    function Unbounded_Slice
1055      (Source : Unbounded_Wide_Wide_String;
1056       Low    : Positive;
1057       High   : Natural) return Unbounded_Wide_Wide_String
1058    is
1059    begin
1060       if Low > Source.Last + 1 or else High > Source.Last then
1061          raise Index_Error;
1062       else
1063          return
1064            To_Unbounded_Wide_Wide_String (Source.Reference.all (Low .. High));
1065       end if;
1066    end Unbounded_Slice;
1067
1068    procedure Unbounded_Slice
1069      (Source : Unbounded_Wide_Wide_String;
1070       Target : out Unbounded_Wide_Wide_String;
1071       Low    : Positive;
1072       High   : Natural)
1073    is
1074    begin
1075       if Low > Source.Last + 1 or else High > Source.Last then
1076          raise Index_Error;
1077       else
1078          Target :=
1079            To_Unbounded_Wide_Wide_String (Source.Reference.all (Low .. High));
1080       end if;
1081    end Unbounded_Slice;
1082
1083 end Ada.Strings.Wide_Wide_Unbounded;