gcc/ada/a-stwima.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                A D A . S T R I N G S . W I D E _ M A P S                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 with Ada.Finalization;
  39
  40 package Ada.Strings.Wide_Maps is
  41    pragma Preelaborate;
  42
  43    -------------------------------------
  44    -- Wide Character Set Declarations --
  45    -------------------------------------
  46
  47    type Wide_Character_Set is private;
  48    pragma Preelaborable_Initialization (Wide_Character_Set);
  49    --  Representation for a set of Wide_Character values:
  50
  51    Null_Set : constant Wide_Character_Set;
  52
  53    ------------------------------------------
  54    -- Constructors for Wide Character Sets --
  55    ------------------------------------------
  56
  57    type Wide_Character_Range is record
  58       Low  : Wide_Character;
  59       High : Wide_Character;
  60    end record;
  61    --  Represents Wide_Character range Low .. High
  62
  63    type Wide_Character_Ranges is
  64      array (Positive range <>) of Wide_Character_Range;
  65
  66    function To_Set
  67      (Ranges : Wide_Character_Ranges) return Wide_Character_Set;
  68
  69    function To_Set
  70      (Span : Wide_Character_Range) return Wide_Character_Set;
  71
  72    function To_Ranges
  73      (Set : Wide_Character_Set) return Wide_Character_Ranges;
  74
  75    ---------------------------------------
  76    -- Operations on Wide Character Sets --
  77    ---------------------------------------
  78
  79    function "=" (Left, Right : Wide_Character_Set) return Boolean;
  80
  81    function "not"
  82      (Right : Wide_Character_Set) return Wide_Character_Set;
  83
  84    function "and"
  85      (Left, Right : Wide_Character_Set) return Wide_Character_Set;
  86
  87    function "or"
  88      (Left, Right : Wide_Character_Set) return Wide_Character_Set;
  89
  90    function "xor"
  91      (Left, Right : Wide_Character_Set) return Wide_Character_Set;
  92
  93    function "-"
  94      (Left, Right : Wide_Character_Set) return Wide_Character_Set;
  95
  96    function Is_In
  97      (Element : Wide_Character;
  98       Set     : Wide_Character_Set) return Boolean;
  99
 100    function Is_Subset
 101      (Elements : Wide_Character_Set;
 102       Set      : Wide_Character_Set) return Boolean;
 103
 104    function "<="
 105      (Left  : Wide_Character_Set;
 106       Right : Wide_Character_Set) return Boolean
 107    renames Is_Subset;
 108
 109    subtype Wide_Character_Sequence is Wide_String;
 110    --  Alternative representation for a set of character values
 111
 112    function To_Set
 113      (Sequence : Wide_Character_Sequence) return Wide_Character_Set;
 114
 115    function To_Set
 116      (Singleton : Wide_Character) return Wide_Character_Set;
 117
 118    function To_Sequence
 119      (Set : Wide_Character_Set) return Wide_Character_Sequence;
 120
 121    -----------------------------------------
 122    -- Wide Character Mapping Declarations --
 123    -----------------------------------------
 124
 125    type Wide_Character_Mapping is private;
 126    pragma Preelaborable_Initialization (Wide_Character_Mapping);
 127    --  Representation for a wide character to wide character mapping:
 128
 129    function Value
 130      (Map     : Wide_Character_Mapping;
 131       Element : Wide_Character) return Wide_Character;
 132
 133    Identity : constant Wide_Character_Mapping;
 134
 135    ---------------------------------
 136    -- Operations on Wide Mappings --
 137    ---------------------------------
 138
 139    function To_Mapping
 140      (From, To : Wide_Character_Sequence) return Wide_Character_Mapping;
 141
 142    function To_Domain
 143      (Map : Wide_Character_Mapping) return Wide_Character_Sequence;
 144
 145    function To_Range
 146      (Map : Wide_Character_Mapping) return Wide_Character_Sequence;
 147
 148    type Wide_Character_Mapping_Function is
 149       access function (From : Wide_Character) return Wide_Character;
 150
 151 private
 152    package AF renames Ada.Finalization;
 153
 154    ------------------------------------------
 155    -- Representation of Wide_Character_Set --
 156    ------------------------------------------
 157
 158    --  A wide character set is represented as a sequence of wide character
 159    --  ranges (i.e. an object of type Wide_Character_Ranges) in which the
 160    --  following hold:
 161
 162    --    The lower bound is 1
 163    --    The ranges are in order by increasing Low values
 164    --    The ranges are non-overlapping and discontigous
 165
 166    --  A character value is in the set if it is contained in one of the
 167    --  ranges. The actual Wide_Character_Set value is a controlled pointer
 168    --  to this Wide_Character_Ranges value. The use of a controlled type
 169    --  is necessary to prevent storage leaks.
 170
 171    type Wide_Character_Ranges_Access is access all Wide_Character_Ranges;
 172
 173    type Wide_Character_Set is new AF.Controlled with record
 174       Set : Wide_Character_Ranges_Access;
 175    end record;
 176
 177    pragma Finalize_Storage_Only (Wide_Character_Set);
 178    --  This avoids useless finalizations, and, more importantly avoids
 179    --  incorrect attempts to finalize constants that are statically
 180    --  declared here and in Ada.Strings.Wide_Maps, which is incorrect.
 181
 182    procedure Initialize (Object : in out Wide_Character_Set);
 183    procedure Adjust     (Object : in out Wide_Character_Set);
 184    procedure Finalize   (Object : in out Wide_Character_Set);
 185
 186    Null_Range : aliased constant Wide_Character_Ranges :=
 187                   (1 .. 0 => (Low => ' ', High => ' '));
 188
 189    Null_Set : constant Wide_Character_Set :=
 190                 (AF.Controlled with
 191                  Set => Null_Range'Unrestricted_Access);
 192
 193    ----------------------------------------------
 194    -- Representation of Wide_Character_Mapping --
 195    ----------------------------------------------
 196
 197    --  A wide character mapping is represented as two strings of equal
 198    --  length, where any character appearing in Domain is mapped to the
 199    --  corresponding character in Rangev. A character not appearing in
 200    --  Domain is mapped to itself. The characters in Domain are sorted
 201    --  in ascending order.
 202
 203    --  The actual Wide_Character_Mapping value is a controlled record
 204    --  that contains a pointer to a discriminated record containing the
 205    --  range and domain values.
 206
 207    --  Note: this representation is canonical, and the values stored in
 208    --  Domain and Rangev are exactly the values that are returned by the
 209    --  functions To_Domain and To_Range. The use of a controlled type is
 210    --  necessary to prevent storage leaks.
 211
 212    type Wide_Character_Mapping_Values (Length : Natural) is record
 213       Domain : Wide_Character_Sequence (1 .. Length);
 214       Rangev : Wide_Character_Sequence (1 .. Length);
 215    end record;
 216
 217    type Wide_Character_Mapping_Values_Access is
 218      access all Wide_Character_Mapping_Values;
 219
 220    type Wide_Character_Mapping is new AF.Controlled with record
 221       Map : Wide_Character_Mapping_Values_Access;
 222    end record;
 223
 224    pragma Finalize_Storage_Only (Wide_Character_Mapping);
 225    --  This avoids useless finalizations, and, more importantly avoids
 226    --  incorrect attempts to finalize constants that are statically
 227    --  declared here and in Ada.Strings.Wide_Maps, which is incorrect.
 228
 229    procedure Initialize (Object : in out Wide_Character_Mapping);
 230    procedure Adjust     (Object : in out Wide_Character_Mapping);
 231    procedure Finalize   (Object : in out Wide_Character_Mapping);
 232
 233    Null_Map : aliased constant Wide_Character_Mapping_Values :=
 234                  (Length => 0,
 235                   Domain => "",
 236                   Rangev => "");
 237
 238    Identity : constant Wide_Character_Mapping :=
 239                 (AF.Controlled with
 240                  Map => Null_Map'Unrestricted_Access);
 241
 242 end Ada.Strings.Wide_Maps;