gcc/ada/a-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  This version of Ada.Exceptions is a full Ada 95 version.
  39 --  It is used for building the compiler and the basic tools, since these
  40 --  builds may be done with bootstrap compilers that cannot handle these
  41 --  additions. The full version of Ada.Exceptions can be found in the files
  42 --  a-except-2005.ads/adb, and is used for all other builds where full Ada
  43 --  2005 functionality is required. in particular, it is used for building
  44 --  run times on all targets.
  45
  46 pragma Polling (Off);
  47 --  We must turn polling off for this unit, because otherwise we get
  48 --  elaboration circularities with ourself.
  49
  50 with System;
  51 with System.Parameters;
  52 with System.Standard_Library;
  53 with System.Traceback_Entries;
  54
  55 package Ada.Exceptions is
  56    pragma Warnings (Off);
  57    pragma Preelaborate_05;
  58    pragma Warnings (On);
  59    --  We make this preelaborable in Ada 2005 mode. If we did not do this, then
  60    --  run time units used by the compiler (e.g. s-soflin.ads) would run
  61    --  into trouble. Conformance is not an issue, since this version is used
  62    --  only by the compiler.
  63
  64    type Exception_Id is private;
  65
  66    Null_Id : constant Exception_Id;
  67
  68    type Exception_Occurrence is limited private;
  69
  70    type Exception_Occurrence_Access is access all Exception_Occurrence;
  71
  72    Null_Occurrence : constant Exception_Occurrence;
  73
  74    function Exception_Name (X : Exception_Occurrence) return String;
  75    --  Same as Exception_Name (Exception_Identity (X))
  76
  77    function Exception_Name (Id : Exception_Id) return String;
  78
  79    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  80    --  Note: it would be really nice to give a pragma No_Return for this
  81    --  procedure, but it would be wrong, since Raise_Exception does return if
  82    --  given the null exception in Ada 95 mode. However we do special case the
  83    --  name in the test in the compiler for issuing a warning for a missing
  84    --  return after this call. Program_Error seems reasonable enough in such a
  85    --  case. See also the routine Raise_Exception_Always in the private part.
  86
  87    function Exception_Message (X : Exception_Occurrence) return String;
  88
  89    procedure Reraise_Occurrence (X : Exception_Occurrence);
  90    --  Note: it would be really nice to give a pragma No_Return for this
  91    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  92    --  if the argument is the null exception occurrence. See also procedure
  93    --  Reraise_Occurrence_Always in the private part of this package.
  94
  95    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
  96
  97    function Exception_Information (X : Exception_Occurrence) return String;
  98    --  The format of the exception information is as follows:
  99    --
 100    --    exception name (as in Exception_Name)
 101    --    message (or a null line if no message)
 102    --    PID=nnnn
 103    --    0xyyyyyyyy 0xyyyyyyyy ...
 104    --
 105    --  The lines are separated by a ASCII.LF character
 106    --  The nnnn is the partition Id given as decimal digits.
 107    --  The 0x... line represents traceback program counter locations,
 108    --  in order with the first one being the exception location.
 109
 110    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 111    --  not the function from Rtsfind, so it is important that the procedure
 112    --  come first, since Rtsfind finds the first matching entity.
 113
 114    procedure Save_Occurrence
 115      (Target : out Exception_Occurrence;
 116       Source : Exception_Occurrence);
 117
 118    function Save_Occurrence
 119      (Source : Exception_Occurrence)
 120       return   Exception_Occurrence_Access;
 121
 122 private
 123    package SSL renames System.Standard_Library;
 124    package SP renames System.Parameters;
 125
 126    subtype EOA is Exception_Occurrence_Access;
 127
 128    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 129
 130    ------------------
 131    -- Exception_Id --
 132    ------------------
 133
 134    subtype Code_Loc is System.Address;
 135    --  Code location used in building exception tables and for call addresses
 136    --  when propagating an exception. Values of this type are created by using
 137    --  Label'Address or extracted from machine states using Get_Code_Loc.
 138
 139    Null_Loc : constant Code_Loc := System.Null_Address;
 140    --  Null code location, used to flag outer level frame
 141
 142    type Exception_Id is new SSL.Exception_Data_Ptr;
 143
 144    function EId_To_String (X : Exception_Id) return String;
 145    function String_To_EId (S : String) return Exception_Id;
 146    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 147    --  Functions for implementing Exception_Id stream attributes
 148
 149    Null_Id : constant Exception_Id := null;
 150
 151    -------------------------
 152    -- Private Subprograms --
 153    -------------------------
 154
 155    function Current_Target_Exception return Exception_Occurrence;
 156    pragma Export
 157      (Ada, Current_Target_Exception,
 158       "__gnat_current_target_exception");
 159    --  This routine should return the current raised exception on targets
 160    --  which have built-in exception handling such as the Java Virtual
 161    --  Machine. For other targets this routine is simply ignored. Currently,
 162    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 163    --  allows this routine to be accessed elsewhere in the run-time, even
 164    --  though it is in the private part of this package (it is not allowed
 165    --  to be in the visible part, since this is set by the reference manual).
 166
 167    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 168    --  Like Exception_Name, but returns the simple non-qualified name of the
 169    --  exception. This is used to implement the Exception_Name function in
 170    --  Current_Exceptions (the DEC compatible unit). It is called from the
 171    --  compiler generated code (using Rtsfind, which does not respect the
 172    --  private barrier, so we can place this function in the private part
 173    --  where the compiler can find it, but the spec is unchanged.)
 174
 175    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 176    pragma No_Return (Raise_Exception_Always);
 177    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 178    --  This differs from Raise_Exception only in that the caller has determined
 179    --  that for sure the parameter E is not null, and that therefore the call
 180    --  to this procedure cannot return. The expander converts Raise_Exception
 181    --  calls to Raise_Exception_Always if it can determine this is the case.
 182    --  The Export allows this routine to be accessed from Pure units.
 183
 184    procedure Raise_From_Signal_Handler
 185      (E : Exception_Id;
 186       M : System.Address);
 187    pragma Export
 188      (Ada, Raise_From_Signal_Handler,
 189            "ada__exceptions__raise_from_signal_handler");
 190    pragma No_Return (Raise_From_Signal_Handler);
 191    --  This routine is used to raise an exception from a signal handler. The
 192    --  signal handler has already stored the machine state (i.e. the state that
 193    --  corresponds to the location at which the signal was raised). E is the
 194    --  Exception_Id specifying what exception is being raised, and M is a
 195    --  pointer to a null-terminated string which is the message to be raised.
 196    --  Note that this routine never returns, so it is permissible to simply
 197    --  jump to this routine, rather than call it. This may be appropriate for
 198    --  systems where the right way to get out of signal handler is to alter the
 199    --  PC value in the machine state or in some other way ask the operating
 200    --  system to return here rather than to the original location.
 201
 202    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 203    pragma No_Return (Reraise_Occurrence_Always);
 204    --  This differs from Raise_Occurrence only in that the caller guarantees
 205    --  that for sure the parameter X is not the null occurrence, and that
 206    --  therefore this procedure cannot return. The expander uses this routine
 207    --  in the translation of a raise statement with no parameter (reraise).
 208
 209    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 210    pragma No_Return (Reraise_Occurrence_No_Defer);
 211    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 212    --  before the call and the parameter X is known not to be the null
 213    --  occurrence. This is used in generated code when it is known that
 214    --  abort is already deferred.
 215
 216    -----------------------
 217    -- Polling Interface --
 218    -----------------------
 219
 220    --  The GNAT compiler has an option to generate polling calls to the Poll
 221    --  routine in this package. Specifying the -gnatP option for a compilation
 222    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 223    --  entry and on every iteration of a loop, thus avoiding the possibility of
 224    --  a case of unbounded time between calls.
 225
 226    --  This polling interface may be used for instrumentation or debugging
 227    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 228
 229    --  In the GNAT technology itself, this interface is used to implement
 230    --  immediate aynschronous transfer of control and immediate abort on
 231    --  targets which do not provide for one thread interrupting another.
 232
 233    --  Note: this used to be in a separate unit called System.Poll, but that
 234    --  caused horrible circular elaboration problems between System.Poll and
 235    --  Ada.Exceptions. One way of solving such circularities is unification!
 236
 237    procedure Poll;
 238    --  Check for asynchronous abort. Note that we do not inline the body.
 239    --  This makes the interface more useful for debugging purposes.
 240
 241    --------------------------
 242    -- Exception_Occurrence --
 243    --------------------------
 244
 245    package TBE renames System.Traceback_Entries;
 246
 247    Max_Tracebacks : constant := 50;
 248    --  Maximum number of trace backs stored in exception occurrence
 249
 250    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 251    --  Traceback array stored in exception occurrence
 252
 253    type Exception_Occurrence is record
 254       Id : Exception_Id;
 255       --  Exception_Identity for this exception occurrence
 256       --  WARNING System.System.Finalization_Implementation.Finalize_List
 257       --  relies on the fact that this field is always first in the exception
 258       --  occurrence
 259
 260       Msg_Length : Natural := 0;
 261       --  Length of message (zero = no message)
 262
 263       Msg : String (1 .. Exception_Msg_Max_Length);
 264       --  Characters of message
 265
 266       Cleanup_Flag : Boolean := False;
 267       --  The cleanup flag is normally False, it is set True for an exception
 268       --  occurrence passed to a cleanup routine, and will still be set True
 269       --  when the cleanup routine does a Reraise_Occurrence call using this
 270       --  exception occurrence. This is used to avoid recording a bogus trace
 271       --  back entry from this reraise call.
 272
 273       Exception_Raised : Boolean := False;
 274       --  Set to true to indicate that this exception occurrence has actually
 275       --  been raised. When an exception occurrence is first created, this is
 276       --  set to False, then when it is processed by Raise_Current_Exception,
 277       --  it is set to True. If Raise_Current_Exception is used to raise an
 278       --  exception for which this flag is already True, then it knows that
 279       --  it is dealing with the reraise case (which is useful to distinguish
 280       --  for exception tracing purposes).
 281
 282       Pid : Natural := 0;
 283       --  Partition_Id for partition raising exception
 284
 285       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 286       --  Number of traceback entries stored
 287
 288       Tracebacks : Tracebacks_Array;
 289       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 290
 291       Private_Data : System.Address := System.Null_Address;
 292       --  Field used by low level exception mechanism to store specific data.
 293       --  Currently used by the GCC exception mechanism to store a pointer to
 294       --  a GNAT_GCC_Exception.
 295    end record;
 296
 297    function "=" (Left, Right : Exception_Occurrence) return Boolean
 298      is abstract;
 299    --  Don't allow comparison on exception occurrences, we should not need
 300    --  this, and it would not work right, because of the Msg and Tracebacks
 301    --  fields which have unused entries not copied by Save_Occurrence.
 302
 303    function EO_To_String (X : Exception_Occurrence) return String;
 304    function String_To_EO (S : String) return Exception_Occurrence;
 305    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 306    --  Functions for implementing Exception_Occurrence stream attributes
 307
 308    Null_Occurrence : constant Exception_Occurrence := (
 309      Id               => null,
 310      Msg_Length       => 0,
 311      Msg              => (others => ' '),
 312      Cleanup_Flag     => False,
 313      Exception_Raised => False,
 314      Pid              => 0,
 315      Num_Tracebacks   => 0,
 316      Tracebacks       => (others => TBE.Null_TB_Entry),
 317      Private_Data     => System.Null_Address);
 318
 319 end Ada.Exceptions;