gcc/ada/a-dirval-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                            (Windows Version)                             --
   9 --                                                                          --
  10 --          Copyright (C) 2004 Free Software Foundation, Inc.               --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the Windows version of this package
  36
  37 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
  38
  39 package body Ada.Directories.Validity is
  40
  41    Invalid_Character : constant array (Character) of Boolean :=
  42                          (NUL .. US | '\'       => True,
  43                           '/' | ':' | '*' | '?' => True,
  44                           '"' | '<' | '>' | '|' => True,
  45                           DEL .. NBSP           => True,
  46                           others                => False);
  47
  48    ------------------------
  49    -- Is_Valid_Path_Name --
  50    ------------------------
  51
  52    function Is_Valid_Path_Name (Name : String) return Boolean is
  53       Start : Positive := Name'First;
  54       Last  : Natural;
  55
  56    begin
  57       --  A path name cannot be empty, cannot contain more than 256 characters,
  58       --  cannot contain invalid characters and each directory/file name need
  59       --  to be valid.
  60
  61       if Name'Length = 0 or else Name'Length > 256 then
  62          return False;
  63
  64       else
  65          --  A drive letter may be specified at the beginning
  66
  67          if Name'Length >= 2
  68            and then  Name (Start + 1) = ':'
  69            and then
  70             (Name (Start) in 'A' .. 'Z' or else
  71              Name (Start) in 'a' .. 'z')
  72          then
  73             Start := Start + 2;
  74          end if;
  75
  76          loop
  77             --  Look for the start of the next directory or file name
  78
  79             while Start <= Name'Last and then
  80               (Name (Start) = '\' or Name (Start) = '/')
  81             loop
  82                Start := Start + 1;
  83             end loop;
  84
  85             --  If all directories/file names are OK, return True
  86
  87             exit when Start > Name'Last;
  88
  89             Last := Start;
  90
  91             --  Look for the end of the directory/file name
  92
  93             while Last < Name'Last loop
  94                exit when Name (Last + 1) = '\' or Name (Last + 1) = '/';
  95                Last := Last + 1;
  96             end loop;
  97
  98             --  Check if the directory/file name is valid
  99
 100             if not Is_Valid_Simple_Name (Name (Start .. Last)) then
 101                   return False;
 102             end if;
 103
 104             --  Move to the next name
 105
 106             Start := Last + 1;
 107          end loop;
 108       end if;
 109
 110       --  If Name follows the rules, it is valid
 111
 112       return True;
 113    end Is_Valid_Path_Name;
 114
 115    --------------------------
 116    -- Is_Valid_Simple_Name --
 117    --------------------------
 118
 119    function Is_Valid_Simple_Name (Name : String) return Boolean is
 120       Only_Spaces : Boolean;
 121
 122    begin
 123       --  A file name cannot be empty, cannot contain more than 256 characters,
 124       --  and cannot contain invalid characters.
 125
 126       if Name'Length = 0 or else Name'Length > 256 then
 127          return False;
 128
 129       --  Name length is OK
 130
 131       else
 132          Only_Spaces := True;
 133          for J in Name'Range loop
 134             if Invalid_Character (Name (J)) then
 135                return False;
 136             elsif Name (J) /= ' ' then
 137                Only_Spaces := False;
 138             end if;
 139          end loop;
 140
 141          --  If no invalid chars, and not all spaces, file name is valid.
 142
 143          return not Only_Spaces;
 144       end if;
 145    end Is_Valid_Simple_Name;
 146
 147 end Ada.Directories.Validity;
 148