gcc/ada/a-cuprqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                 ADA.CONTAINERS.UNBOUNDED_PRIORITY_QUEUES                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2011, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35 with Ada.Containers.Synchronized_Queue_Interfaces;
  36 with Ada.Finalization;
  37
  38 generic
  39    with package Queue_Interfaces is
  40      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  41
  42    type Queue_Priority is private;
  43
  44    with function Get_Priority
  45      (Element : Queue_Interfaces.Element_Type) return Queue_Priority is <>;
  46
  47    with function Before
  48      (Left, Right : Queue_Priority) return Boolean is <>;
  49
  50    Default_Ceiling : System.Any_Priority := System.Priority'Last;
  51
  52 package Ada.Containers.Unbounded_Priority_Queues is
  53    pragma Preelaborate;
  54
  55    package Implementation is
  56
  57       --  All identifiers in this unit are implementation defined
  58
  59       pragma Implementation_Defined;
  60
  61       type List_Type is tagged limited private;
  62
  63       procedure Enqueue
  64         (List     : in out List_Type;
  65          New_Item : Queue_Interfaces.Element_Type);
  66
  67       procedure Dequeue
  68         (List    : in out List_Type;
  69          Element : out Queue_Interfaces.Element_Type);
  70
  71       procedure Dequeue
  72         (List     : in out List_Type;
  73          At_Least : Queue_Priority;
  74          Element  : in out Queue_Interfaces.Element_Type;
  75          Success  : out Boolean);
  76
  77       function Length (List : List_Type) return Count_Type;
  78
  79       function Max_Length (List : List_Type) return Count_Type;
  80
  81    private
  82
  83       type Node_Type;
  84       type Node_Access is access Node_Type;
  85
  86       type Node_Type is limited record
  87          Element : Queue_Interfaces.Element_Type;
  88          Next    : Node_Access;
  89       end record;
  90
  91       type List_Type is new Ada.Finalization.Limited_Controlled with record
  92          First, Last : Node_Access;
  93          Length      : Count_Type := 0;
  94          Max_Length  : Count_Type := 0;
  95       end record;
  96
  97       overriding
  98       procedure Finalize (List : in out List_Type);
  99
 100    end Implementation;
 101
 102    protected type Queue (Ceiling : System.Any_Priority := Default_Ceiling)
 103      with Priority => Ceiling is new Queue_Interfaces.Queue with
 104
 105       overriding
 106       entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 107
 108       overriding
 109       entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 110
 111       --  The priority queue operation Dequeue_Only_High_Priority had been a
 112       --  protected entry in early drafts of AI05-0159, but it was discovered
 113       --  that that operation as specified was not in fact implementable. The
 114       --  operation was changed from an entry to a protected procedure per the
 115       --  ARG meeting in Edinburgh (June 2011), with a different signature and
 116       --  semantics.
 117
 118       not overriding
 119       procedure Dequeue_Only_High_Priority
 120         (At_Least : Queue_Priority;
 121          Element  : in out Queue_Interfaces.Element_Type;
 122          Success  : out Boolean);
 123
 124       overriding
 125       function Current_Use return Count_Type;
 126
 127       overriding
 128       function Peak_Use return Count_Type;
 129
 130    private
 131
 132       List : Implementation.List_Type;
 133
 134    end Queue;
 135
 136 end Ada.Containers.Unbounded_Priority_Queues;