gcc/ada/a-comlin.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                     A D A . C O M M A N D _ L I N E                      --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                            $Revision$
  10 --                                                                          --
  11 --          Copyright (C) 1992-2002 Free Software Foundation, Inc.          --
  12 --                                                                          --
  13 -- This specification is derived from the Ada Reference Manual for use with --
  14 -- GNAT. The copyright notice above, and the license provisions that follow --
  15 -- apply solely to the  contents of the part following the private keyword. --
  16 --                                                                          --
  17 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  18 -- terms of the  GNU General Public License as published  by the Free Soft- --
  19 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  20 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  21 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  22 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  23 -- for  more details.  You should have  received  a copy of the GNU General --
  24 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  25 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  26 -- MA 02111-1307, USA.                                                      --
  27 --                                                                          --
  28 -- As a special exception,  if other files  instantiate  generics from this --
  29 -- unit, or you link  this unit with other files  to produce an executable, --
  30 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  31 -- covered  by the  GNU  General  Public  License.  This exception does not --
  32 -- however invalidate  any other reasons why  the executable file  might be --
  33 -- covered by the  GNU Public License.                                      --
  34 --                                                                          --
  35 -- GNAT was originally developed  by the GNAT team at  New York University. --
  36 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  37 --                                                                          --
  38 ------------------------------------------------------------------------------
  39
  40 package Ada.Command_Line is
  41 pragma Preelaborate (Command_Line);
  42
  43    function Argument_Count return Natural;
  44    --  If the external execution environment supports passing arguments to a
  45    --  program, then Argument_Count returns the number of arguments passed to
  46    --  the program invoking the function. Otherwise it return 0.
  47    --
  48    --  In GNAT: Corresponds to (argc - 1) in C.
  49
  50    function Argument (Number : Positive) return String;
  51    --  If the external execution environment supports passing arguments to
  52    --  a program, then Argument returns an implementation-defined value
  53    --  corresponding to the argument at relative position Number. If Number
  54    --  is outside the range 1 .. Argument_Count, then Constraint_Error is
  55    --  propagated.
  56    --
  57    --  in GNAT: Corresponds to argv [n] (for n > 0) in C.
  58
  59    function Command_Name return String;
  60    --  If the external execution environment supports passing arguments to
  61    --  a program, then Command_Name returns an implementation-defined value
  62    --  corresponding to the name of the command invoking the program.
  63    --  Otherwise Command_Name returns the null string.
  64    --
  65    --  in GNAT: Corresponds to argv [0] in C.
  66
  67    type Exit_Status is new Integer;
  68
  69    Success : constant Exit_Status;
  70    Failure : constant Exit_Status;
  71
  72    procedure Set_Exit_Status (Code : Exit_Status);
  73
  74    ------------------------------------
  75    -- Note on Interface Requirements --
  76    ------------------------------------
  77
  78    --  If the main program is in Ada, this package works as specified without
  79    --  any other work than the normal steps of WITH'ing the package and then
  80    --  calling the desired routines.
  81
  82    --  If the main program is not in Ada, then the information must be made
  83    --  available for this package to work correctly. In particular, it is
  84    --  required that the global variable "gnat_argc" contain the number of
  85    --  arguments, and that the global variable "gnat_argv" points to an
  86    --  array of null-terminated strings, the first entry being the command
  87    --  name, and the remaining entries being the command arguments.
  88
  89    --  These correspond to the normal argc/argv variables passed to a C
  90    --  main program, and the following is an example of a complete C main
  91    --  program that stores the required information:
  92
  93    --    main(int argc, char **argv, char **envp)
  94    --    {
  95    --       extern int    gnat_argc;
  96    --       extern char **gnat_argv;
  97    --       extern char **gnat_envp;
  98    --       gnat_argc = argc;
  99    --       gnat_argv = argv;
 100    --       gnat_envp = envp;
 101
 102    --       adainit();
 103    --       adamain();
 104    --       adafinal();
 105    --    }
 106
 107    --  The assignment statements ensure that the necessary information is
 108    --  available for finding the command name and command line arguments.
 109
 110 private
 111    Success : constant Exit_Status := 0;
 112    Failure : constant Exit_Status := 1;
 113
 114    --  The following locations support the operation of the package
 115    --  Ada.Command_Line.Remove, whih provides facilities for logically
 116    --  removing arguments from the command line. If one of the remove
 117    --  procedures is called in this unit, then Remove_Args/Remove_Count
 118    --  are set to indicate which arguments are removed. If no such calls
 119    --  have been made, then Remove_Args is null.
 120
 121    Remove_Count : Natural;
 122    --  Number of arguments reflecting removals. Not defined unless
 123    --  Remove_Args is non-null.
 124
 125    type Arg_Nums is array (Positive range <>) of Positive;
 126    type Arg_Nums_Ptr is access Arg_Nums;
 127    --  An array that maps logical argument numbers (reflecting removal)
 128    --  to physical argument numbers (e.g. if the first argument has been
 129    --  removed, but not the second, then Arg_Nums (1) will be set to 2.
 130
 131    Remove_Args : Arg_Nums_Ptr := null;
 132    --  Left set to null if no remove calls have been made, otherwise set
 133    --  to point to an appropriate mapping array. Only the first Remove_Count
 134    --  elements are relevant.
 135
 136    pragma Import (C, Set_Exit_Status, "__gnat_set_exit_status");
 137
 138 end Ada.Command_Line;