gcc/ada/a-colire.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --             A D A . C O M M A N D _ L I N E . R E M O V E                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --        Copyright (C) 1999 Free Software Foundation, Inc.                 --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 package body Ada.Command_Line.Remove is
  36
  37    -----------------------
  38    -- Local Subprograms --
  39    -----------------------
  40
  41    procedure Initialize;
  42    --  Initialize the Remove_Count and Remove_Args variables.
  43
  44    ----------------
  45    -- Initialize --
  46    ----------------
  47
  48    procedure Initialize is
  49    begin
  50       if Remove_Args = null then
  51          Remove_Count := Argument_Count;
  52          Remove_Args := new Arg_Nums (1 .. Argument_Count);
  53
  54          for J in Remove_Args'Range loop
  55             Remove_Args (J) := J;
  56          end loop;
  57       end if;
  58    end Initialize;
  59
  60    ---------------------
  61    -- Remove_Argument --
  62    ---------------------
  63
  64    procedure Remove_Argument (Number : in Positive) is
  65    begin
  66       Initialize;
  67
  68       if Number > Remove_Count then
  69          raise Constraint_Error;
  70       end if;
  71
  72       Remove_Count := Remove_Count - 1;
  73
  74       for J in Number .. Remove_Count loop
  75          Remove_Args (J) := Remove_Args (J + 1);
  76       end loop;
  77    end Remove_Argument;
  78
  79    procedure Remove_Argument (Argument : String) is
  80    begin
  81       for J in reverse 1 .. Argument_Count loop
  82          if Argument = Ada.Command_Line.Argument (J) then
  83             Remove_Argument (J);
  84          end if;
  85       end loop;
  86    end Remove_Argument;
  87
  88    ----------------------
  89    -- Remove_Arguments --
  90    ----------------------
  91
  92    procedure Remove_Arguments (From : Positive; To : Natural) is
  93    begin
  94       Initialize;
  95
  96       if From > Remove_Count
  97         or else To > Remove_Count
  98       then
  99          raise Constraint_Error;
 100       end if;
 101
 102       if To >= From then
 103          Remove_Count := Remove_Count - (To - From + 1);
 104
 105          for J in From .. Remove_Count loop
 106             Remove_Args (J) := Remove_Args (J + (To - From + 1));
 107          end loop;
 108       end if;
 109    end Remove_Arguments;
 110
 111    procedure Remove_Arguments (Argument_Prefix : String) is
 112    begin
 113       for J in reverse 1 .. Argument_Count loop
 114          declare
 115             Arg : constant String := Argument (J);
 116
 117          begin
 118             if Arg'Length >= Argument_Prefix'Length
 119               and then Arg (1 .. Argument_Prefix'Length) = Argument_Prefix
 120             then
 121                Remove_Argument (J);
 122             end if;
 123          end;
 124       end loop;
 125    end Remove_Arguments;
 126
 127 end Ada.Command_Line.Remove;