gcc/ada/a-cohase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . C O N T A I N E R S . H A S H E D _ S E T S            --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Hash_Tables;
  37 with Ada.Streams;
  38 with Ada.Finalization;
  39
  40 generic
  41    type Element_Type is private;
  42
  43    with function Hash (Element : Element_Type) return Hash_Type;
  44
  45    with function Equivalent_Elements (Left, Right : Element_Type)
  46                                      return Boolean;
  47
  48    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  49
  50 package Ada.Containers.Hashed_Sets is
  51    pragma Preelaborate;
  52    pragma Remote_Types;
  53
  54    type Set is tagged private;
  55    pragma Preelaborable_Initialization (Set);
  56
  57    type Cursor is private;
  58    pragma Preelaborable_Initialization (Cursor);
  59
  60    Empty_Set : constant Set;
  61
  62    No_Element : constant Cursor;
  63
  64    function "=" (Left, Right : Set) return Boolean;
  65
  66    function Equivalent_Sets (Left, Right : Set) return Boolean;
  67
  68    function To_Set (New_Item : Element_Type) return Set;
  69
  70    function Capacity (Container : Set) return Count_Type;
  71
  72    procedure Reserve_Capacity
  73      (Container : in out Set;
  74       Capacity  : Count_Type);
  75
  76    function Length (Container : Set) return Count_Type;
  77
  78    function Is_Empty (Container : Set) return Boolean;
  79
  80    procedure Clear (Container : in out Set);
  81
  82    function Element (Position : Cursor) return Element_Type;
  83
  84    procedure Replace_Element
  85      (Container : in out Set;
  86       Position  : Cursor;
  87       New_Item  : Element_Type);
  88
  89    procedure Query_Element
  90      (Position : Cursor;
  91       Process  : not null access procedure (Element : Element_Type));
  92
  93    procedure Move (Target : in out Set; Source : in out Set);
  94
  95    procedure Insert
  96      (Container : in out Set;
  97       New_Item  : Element_Type;
  98       Position  : out Cursor;
  99       Inserted  : out Boolean);
 100
 101    procedure Insert  (Container : in out Set; New_Item : Element_Type);
 102
 103    procedure Include (Container : in out Set; New_Item : Element_Type);
 104
 105    procedure Replace (Container : in out Set; New_Item : Element_Type);
 106
 107    procedure Exclude (Container : in out Set; Item     : Element_Type);
 108
 109    procedure Delete  (Container : in out Set; Item     : Element_Type);
 110
 111    procedure Delete (Container : in out Set; Position  : in out Cursor);
 112
 113    procedure Union (Target : in out Set; Source : Set);
 114
 115    function Union (Left, Right : Set) return Set;
 116
 117    function "or" (Left, Right : Set) return Set renames Union;
 118
 119    procedure Intersection (Target : in out Set; Source : Set);
 120
 121    function Intersection (Left, Right : Set) return Set;
 122
 123    function "and" (Left, Right : Set) return Set renames Intersection;
 124
 125    procedure Difference (Target : in out Set; Source : Set);
 126
 127    function Difference (Left, Right : Set) return Set;
 128
 129    function "-" (Left, Right : Set) return Set renames Difference;
 130
 131    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 132
 133    function Symmetric_Difference (Left, Right : Set) return Set;
 134
 135    function "xor" (Left, Right : Set) return Set
 136      renames Symmetric_Difference;
 137
 138    function Overlap (Left, Right : Set) return Boolean;
 139
 140    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 141
 142    function First (Container : Set) return Cursor;
 143
 144    function Next (Position : Cursor) return Cursor;
 145
 146    procedure Next (Position : in out Cursor);
 147
 148    function Find
 149      (Container : Set;
 150       Item      : Element_Type) return Cursor;
 151
 152    function Contains (Container : Set; Item : Element_Type) return Boolean;
 153
 154    function Has_Element (Position : Cursor) return Boolean;
 155
 156    function Equivalent_Elements (Left, Right : Cursor) return Boolean;
 157
 158    function Equivalent_Elements
 159      (Left  : Cursor;
 160       Right : Element_Type) return Boolean;
 161
 162    function Equivalent_Elements
 163      (Left  : Element_Type;
 164       Right : Cursor) return Boolean;
 165
 166    procedure Iterate
 167      (Container : Set;
 168       Process   : not null access procedure (Position : Cursor));
 169
 170    generic
 171       type Key_Type (<>) is private;
 172
 173       with function Key (Element : Element_Type) return Key_Type;
 174
 175       with function Hash (Key : Key_Type) return Hash_Type;
 176
 177       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 178
 179    package Generic_Keys is
 180
 181       function Key (Position : Cursor) return Key_Type;
 182
 183       function Element (Container : Set; Key : Key_Type) return Element_Type;
 184
 185       procedure Replace
 186         (Container : in out Set;
 187          Key       : Key_Type;
 188          New_Item  : Element_Type);
 189
 190       procedure Exclude (Container : in out Set; Key : Key_Type);
 191
 192       procedure Delete (Container : in out Set; Key : Key_Type);
 193
 194       function Find (Container : Set; Key : Key_Type) return Cursor;
 195
 196       function Contains (Container : Set; Key : Key_Type) return Boolean;
 197
 198       procedure Update_Element_Preserving_Key
 199         (Container : in out Set;
 200          Position  : Cursor;
 201          Process   : not null access
 202                        procedure (Element : in out Element_Type));
 203
 204    end Generic_Keys;
 205
 206 private
 207
 208    pragma Inline (Next);
 209
 210    type Node_Type;
 211    type Node_Access is access Node_Type;
 212
 213    type Node_Type is
 214       limited record
 215          Element : Element_Type;
 216          Next    : Node_Access;
 217       end record;
 218
 219    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 220      (Node_Type,
 221       Node_Access);
 222
 223    type Set is new Ada.Finalization.Controlled with record
 224       HT : HT_Types.Hash_Table_Type;
 225    end record;
 226
 227    procedure Adjust (Container : in out Set);
 228
 229    procedure Finalize (Container : in out Set);
 230
 231    use HT_Types;
 232    use Ada.Finalization;
 233    use Ada.Streams;
 234
 235    type Set_Access is access all Set;
 236    for Set_Access'Storage_Size use 0;
 237
 238    type Cursor is
 239       record
 240          Container : Set_Access;
 241          Node      : Node_Access;
 242       end record;
 243
 244    procedure Write
 245      (Stream : not null access Root_Stream_Type'Class;
 246       Item   : Cursor);
 247
 248    for Cursor'Write use Write;
 249
 250    procedure Read
 251      (Stream : not null access Root_Stream_Type'Class;
 252       Item   : out Cursor);
 253
 254    for Cursor'Read use Read;
 255
 256    No_Element : constant Cursor := (Container => null, Node => null);
 257
 258    procedure Write
 259      (Stream    : not null access Root_Stream_Type'Class;
 260       Container : Set);
 261
 262    for Set'Write use Write;
 263
 264    procedure Read
 265      (Stream    : not null access Root_Stream_Type'Class;
 266       Container : out Set);
 267
 268    for Set'Read use Read;
 269
 270    Empty_Set : constant Set := (Controlled with HT => (null, 0, 0, 0));
 271
 272 end Ada.Containers.Hashed_Sets;