gcc/ada/a-ciorse.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --              I N D E F I N I T E _ O R D E R E D _ S E T S               --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Element_Type (<>) is private;
  43
  44    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  45    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  46
  47 package Ada.Containers.Indefinite_Ordered_Sets is
  48 pragma Preelaborate (Indefinite_Ordered_Sets);
  49
  50    type Set is tagged private;
  51
  52    type Cursor is private;
  53
  54    Empty_Set : constant Set;
  55
  56    No_Element : constant Cursor;
  57
  58    function "=" (Left, Right : Set) return Boolean;
  59
  60    function Equivalent_Sets (Left, Right : Set) return Boolean;
  61
  62    function Length (Container : Set) return Count_Type;
  63
  64    function Is_Empty (Container : Set) return Boolean;
  65
  66    procedure Clear (Container : in out Set);
  67
  68    function Element (Position : Cursor) return Element_Type;
  69
  70    procedure Query_Element
  71      (Position : Cursor;
  72       Process  : not null access procedure (Element : Element_Type));
  73
  74    procedure Replace_Element
  75      (Container : Set;   --  TODO: need ruling from ARG
  76       Position  : Cursor;
  77       By        : Element_Type);
  78
  79    procedure Move (Target : in out Set; Source : in out Set);
  80
  81    procedure Insert
  82      (Container : in out Set;
  83       New_Item  : Element_Type;
  84       Position  : out Cursor;
  85       Inserted  : out Boolean);
  86
  87    procedure Insert
  88      (Container : in out Set;
  89       New_Item  : Element_Type);
  90
  91    procedure Include
  92      (Container : in out Set;
  93       New_Item  : Element_Type);
  94
  95    procedure Replace
  96      (Container : in out Set;
  97       New_Item  : Element_Type);
  98
  99    procedure Delete
 100      (Container : in out Set;
 101       Item      : Element_Type);
 102
 103    procedure Delete
 104      (Container : in out Set;
 105       Position  : in out Cursor);
 106
 107    procedure Delete_First (Container : in out Set);
 108
 109    procedure Delete_Last (Container : in out Set);
 110
 111    procedure Exclude
 112      (Container : in out Set;
 113       Item      : Element_Type);
 114
 115    procedure Union (Target : in out Set; Source : Set);
 116
 117    function Union (Left, Right : Set) return Set;
 118
 119    function "or" (Left, Right : Set) return Set renames Union;
 120
 121    procedure Intersection (Target : in out Set; Source : Set);
 122
 123    function Intersection (Left, Right : Set) return Set;
 124
 125    function "and" (Left, Right : Set) return Set renames Intersection;
 126
 127    procedure Difference (Target : in out Set;
 128                          Source : Set);
 129
 130    function Difference (Left, Right : Set) return Set;
 131
 132    function "-" (Left, Right : Set) return Set renames Difference;
 133
 134    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 135
 136    function Symmetric_Difference (Left, Right : Set) return Set;
 137
 138    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 139
 140    function Overlap (Left, Right : Set) return Boolean;
 141
 142    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 143
 144    function Contains (Container : Set; Item : Element_Type) return Boolean;
 145
 146    function Find (Container : Set; Item : Element_Type) return Cursor;
 147
 148    function Floor (Container : Set; Item : Element_Type) return Cursor;
 149
 150    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 151
 152    function First (Container : Set) return Cursor;
 153
 154    function First_Element (Container : Set) return Element_Type;
 155
 156    function Last (Container : Set) return Cursor;
 157
 158    function Last_Element (Container : Set) return Element_Type;
 159
 160    function Next (Position : Cursor) return Cursor;
 161
 162    procedure Next (Position : in out Cursor);
 163
 164    function Previous (Position : Cursor) return Cursor;
 165
 166    procedure Previous (Position : in out Cursor);
 167
 168    function Has_Element (Position : Cursor) return Boolean;
 169
 170    function "<" (Left, Right : Cursor) return Boolean;
 171
 172    function ">" (Left, Right : Cursor) return Boolean;
 173
 174    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 175
 176    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 177
 178    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 179
 180    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 181
 182    procedure Iterate
 183      (Container : Set;
 184       Process   : not null access procedure (Position : Cursor));
 185
 186    procedure Reverse_Iterate
 187      (Container : Set;
 188       Process   : not null access procedure (Position : Cursor));
 189
 190    generic
 191       type Key_Type (<>) is limited private;
 192
 193       with function Key (Element : Element_Type) return Key_Type;
 194
 195       with function "<" (Left : Key_Type; Right : Element_Type)
 196           return Boolean is <>;
 197
 198       with function ">" (Left : Key_Type; Right : Element_Type)
 199           return Boolean is <>;
 200
 201    package Generic_Keys is
 202
 203       function Contains
 204         (Container : Set;
 205          Key       : Key_Type) return Boolean;
 206
 207       function Find
 208         (Container : Set;
 209          Key       : Key_Type) return Cursor;
 210
 211       function Floor
 212         (Container : Set;
 213          Key       : Key_Type) return Cursor;
 214
 215       function Ceiling
 216         (Container : Set;
 217          Key       : Key_Type) return Cursor;
 218
 219       function Key (Position : Cursor) return Key_Type;
 220
 221       function Element
 222         (Container : Set;
 223          Key       : Key_Type) return Element_Type;
 224
 225       procedure Replace
 226         (Container : in out Set;  --  TODO: need ruling from ARG
 227          Key       : Key_Type;
 228          New_Item  : Element_Type);
 229
 230       procedure Delete (Container : in out Set; Key : Key_Type);
 231
 232       procedure Exclude (Container : in out Set; Key : Key_Type);
 233
 234       function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 235
 236       function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 237
 238       function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 239
 240       function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 241
 242       procedure Update_Element_Preserving_Key
 243         (Container : in out Set;
 244          Position  : Cursor;
 245          Process   : not null access
 246                        procedure (Element : in out Element_Type));
 247
 248    end Generic_Keys;
 249
 250 private
 251
 252    type Node_Type;
 253    type Node_Access is access Node_Type;
 254
 255    type Element_Access is access Element_Type;
 256
 257    type Node_Type is limited record
 258       Parent  : Node_Access;
 259       Left    : Node_Access;
 260       Right   : Node_Access;
 261       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 262       Element : Element_Access;
 263    end record;
 264
 265    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 266      (Node_Type,
 267       Node_Access);
 268
 269    type Set is new Ada.Finalization.Controlled with record
 270       Tree : Tree_Types.Tree_Type;
 271    end record;
 272
 273    procedure Adjust (Container : in out Set);
 274
 275    procedure Finalize (Container : in out Set) renames Clear;
 276
 277    use Red_Black_Trees;
 278    use Tree_Types;
 279    use Ada.Finalization;
 280
 281    type Set_Access is access all Set;
 282    for Set_Access'Storage_Size use 0;
 283
 284    type Cursor is record
 285       Container : Set_Access;
 286       Node      : Node_Access;
 287    end record;
 288
 289    No_Element : constant Cursor := Cursor'(null, null);
 290
 291    use Ada.Streams;
 292
 293    procedure Write
 294      (Stream    : access Root_Stream_Type'Class;
 295       Container : Set);
 296
 297    for Set'Write use Write;
 298
 299    procedure Read
 300      (Stream    : access Root_Stream_Type'Class;
 301       Container : out Set);
 302
 303    for Set'Read use Read;
 304
 305    Empty_Set : constant Set :=
 306                  (Controlled with Tree => (First  => null,
 307                                            Last   => null,
 308                                            Root   => null,
 309                                            Length => 0,
 310                                            Busy   => 0,
 311                                            Lock   => 0));
 312
 313 end Ada.Containers.Indefinite_Ordered_Sets;