gcc/ada/a-ciorma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --             I N D E F I N I T E _ O R D E R E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43    type Element_Type (<>) is private;
  44
  45    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  46    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  47
  48 package Ada.Containers.Indefinite_Ordered_Maps is
  49    pragma Preelaborate;
  50
  51    function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  52
  53    type Map is tagged private;
  54
  55    type Cursor is private;
  56
  57    Empty_Map : constant Map;
  58
  59    No_Element : constant Cursor;
  60
  61    function "=" (Left, Right : Map) return Boolean;
  62
  63    function Length (Container : Map) return Count_Type;
  64
  65    function Is_Empty (Container : Map) return Boolean;
  66
  67    procedure Clear (Container : in out Map);
  68
  69    function Key (Position : Cursor) return Key_Type;
  70
  71    function Element (Position : Cursor) return Element_Type;
  72
  73    procedure Replace_Element
  74      (Container : in out Map;
  75       Position  : Cursor;
  76       New_Item  : Element_Type);
  77
  78    procedure Query_Element
  79      (Position : Cursor;
  80       Process  : not null access procedure (Key     : Key_Type;
  81                                             Element : Element_Type));
  82
  83    procedure Update_Element
  84      (Container : in out Map;
  85       Position  : Cursor;
  86       Process   : not null access procedure (Key     : Key_Type;
  87                                              Element : in out Element_Type));
  88
  89    procedure Move (Target : in out Map; Source : in out Map);
  90
  91    procedure Insert
  92      (Container : in out Map;
  93       Key       : Key_Type;
  94       New_Item  : Element_Type;
  95       Position  : out Cursor;
  96       Inserted  : out Boolean);
  97
  98    procedure Insert
  99      (Container : in out Map;
 100       Key       : Key_Type;
 101       New_Item  : Element_Type);
 102
 103    procedure Include
 104      (Container : in out Map;
 105       Key       : Key_Type;
 106       New_Item  : Element_Type);
 107
 108    procedure Replace
 109      (Container : in out Map;
 110       Key       : Key_Type;
 111       New_Item  : Element_Type);
 112
 113    procedure Exclude (Container : in out Map; Key : Key_Type);
 114
 115    procedure Delete (Container : in out Map; Key : Key_Type);
 116
 117    procedure Delete (Container : in out Map; Position : in out Cursor);
 118
 119    procedure Delete_First (Container : in out Map);
 120
 121    procedure Delete_Last (Container : in out Map);
 122
 123    function First (Container : Map) return Cursor;
 124
 125    function First_Element (Container : Map) return Element_Type;
 126
 127    function First_Key (Container : Map) return Key_Type;
 128
 129    function Last (Container : Map) return Cursor;
 130
 131    function Last_Element (Container : Map) return Element_Type;
 132
 133    function Last_Key (Container : Map) return Key_Type;
 134
 135    function Next (Position : Cursor) return Cursor;
 136
 137    procedure Next (Position : in out Cursor);
 138
 139    function Previous (Position : Cursor) return Cursor;
 140
 141    procedure Previous (Position : in out Cursor);
 142
 143    function Find (Container : Map; Key : Key_Type) return Cursor;
 144
 145    function Element (Container : Map; Key : Key_Type) return Element_Type;
 146
 147    function Floor (Container : Map; Key : Key_Type) return Cursor;
 148
 149    function Ceiling (Container : Map; Key : Key_Type) return Cursor;
 150
 151    function Contains (Container : Map; Key : Key_Type) return Boolean;
 152
 153    function Has_Element (Position : Cursor) return Boolean;
 154
 155    function "<" (Left, Right : Cursor) return Boolean;
 156
 157    function ">" (Left, Right : Cursor) return Boolean;
 158
 159    function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 160
 161    function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 162
 163    function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 164
 165    function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 166
 167    procedure Iterate
 168      (Container : Map;
 169       Process   : not null access procedure (Position : Cursor));
 170
 171    procedure Reverse_Iterate
 172      (Container : Map;
 173       Process   : not null access procedure (Position : Cursor));
 174
 175 private
 176
 177    type Node_Type;
 178    type Node_Access is access Node_Type;
 179
 180    type Key_Access is access Key_Type;
 181    type Element_Access is access Element_Type;
 182
 183    type Node_Type is limited record
 184       Parent  : Node_Access;
 185       Left    : Node_Access;
 186       Right   : Node_Access;
 187       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 188       Key     : Key_Access;
 189       Element : Element_Access;
 190    end record;
 191
 192    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 193      (Node_Type,
 194       Node_Access);
 195
 196    type Map is new Ada.Finalization.Controlled with record
 197       Tree : Tree_Types.Tree_Type;
 198    end record;
 199
 200    procedure Adjust (Container : in out Map);
 201
 202    procedure Finalize (Container : in out Map) renames Clear;
 203
 204    use Red_Black_Trees;
 205    use Tree_Types;
 206    use Ada.Finalization;
 207    use Ada.Streams;
 208
 209    type Map_Access is access all Map;
 210    for Map_Access'Storage_Size use 0;
 211
 212    type Cursor is record
 213       Container : Map_Access;
 214       Node      : Node_Access;
 215    end record;
 216
 217    procedure Write
 218      (Stream : not null access Root_Stream_Type'Class;
 219       Item   : Cursor);
 220
 221    for Cursor'Write use Write;
 222
 223    procedure Read
 224      (Stream : not null access Root_Stream_Type'Class;
 225       Item   : out Cursor);
 226
 227    for Cursor'Read use Read;
 228
 229    No_Element : constant Cursor := Cursor'(null, null);
 230
 231    procedure Write
 232      (Stream    : not null access Root_Stream_Type'Class;
 233       Container : Map);
 234
 235    for Map'Write use Write;
 236
 237    procedure Read
 238      (Stream    : not null access Root_Stream_Type'Class;
 239       Container : out Map);
 240
 241    for Map'Read use Read;
 242
 243    Empty_Map : constant Map :=
 244                  (Controlled with Tree => (First  => null,
 245                                            Last   => null,
 246                                            Root   => null,
 247                                            Length => 0,
 248                                            Busy   => 0,
 249                                            Lock   => 0));
 250
 251 end Ada.Containers.Indefinite_Ordered_Maps;