gcc/ada/a-cihase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                  ADA.CONTAINERS.INDEFINITE_HASHED_SETS                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --             Copyright (C) 2004 Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  24 -- MA 02111-1307, USA.                                                      --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Hash_Tables;
  37 with Ada.Streams;
  38
  39 generic
  40    type Element_Type (<>) is private;
  41
  42    with function Hash (Element : Element_Type) return Hash_Type;
  43
  44    --  TODO: get a ruling from ARG in Atlanta re the name and
  45    --  order of these declarations ???
  46
  47    with function Equivalent_Keys (Left, Right : Element_Type) return Boolean;
  48
  49    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  50
  51 package Ada.Containers.Indefinite_Hashed_Sets is
  52
  53    pragma Preelaborate (Indefinite_Hashed_Sets);
  54
  55    type Set is tagged private;
  56
  57    type Cursor is private;
  58
  59    Empty_Set : constant Set;
  60
  61    No_Element : constant Cursor;
  62
  63    function "=" (Left, Right : Set) return Boolean;
  64
  65    function Length (Container : Set) return Count_Type;
  66
  67    function Is_Empty (Container : Set) return Boolean;
  68
  69    procedure Clear (Container : in out Set);
  70
  71    function Element (Position : Cursor) return Element_Type;
  72
  73    procedure Query_Element
  74      (Position : Cursor;
  75       Process  : not null access procedure (Element : Element_Type));
  76
  77 --  TODO: resolve in atlanta ???
  78 --   procedure Replace_Element (Container : in out Set;
  79 --                              Position  : Cursor;
  80 --                              By        : Element_Type);
  81
  82    procedure Move
  83      (Target : in out Set;
  84       Source : in out Set);
  85
  86    procedure Insert
  87      (Container : in out Set;
  88       New_Item  : Element_Type;
  89       Position  : out Cursor;
  90       Inserted  : out Boolean);
  91
  92    procedure Insert  (Container : in out Set; New_Item : Element_Type);
  93
  94    procedure Include (Container : in out Set; New_Item : Element_Type);
  95
  96    procedure Replace (Container : in out Set; New_Item : Element_Type);
  97
  98    procedure Delete  (Container : in out Set; Item : Element_Type);
  99
 100    procedure Exclude (Container : in out Set; Item : Element_Type);
 101
 102    procedure Delete (Container : in out Set; Position  : in out Cursor);
 103
 104    procedure Union (Target : in out Set; Source : Set);
 105
 106    function Union (Left, Right : Set) return Set;
 107
 108    function "or" (Left, Right : Set) return Set renames Union;
 109
 110    procedure Intersection (Target : in out Set; Source : Set);
 111
 112    function Intersection (Left, Right : Set) return Set;
 113
 114    function "and" (Left, Right : Set) return Set renames Intersection;
 115
 116    procedure Difference (Target : in out Set; Source : Set);
 117
 118    function Difference (Left, Right : Set) return Set;
 119
 120    function "-" (Left, Right : Set) return Set renames Difference;
 121
 122    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 123
 124    function Symmetric_Difference (Left, Right : Set) return Set;
 125
 126    function "xor" (Left, Right : Set) return Set
 127      renames Symmetric_Difference;
 128
 129    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 130
 131    function Overlap (Left, Right : Set) return Boolean;
 132
 133    function Contains (Container : Set; Item : Element_Type) return Boolean;
 134
 135    function Find (Container : Set; Item : Element_Type) return Cursor;
 136
 137    function Capacity (Container : Set) return Count_Type;
 138
 139    procedure Reserve_Capacity
 140      (Container : in out Set;
 141       Capacity  : Count_Type);
 142
 143    function First (Container : Set) return Cursor;
 144
 145    function Next (Position : Cursor) return Cursor;
 146
 147    procedure Next (Position : in out Cursor);
 148
 149    function Has_Element (Position : Cursor) return Boolean;
 150
 151    function Equivalent_Keys (Left, Right : Cursor) return Boolean;
 152
 153    function Equivalent_Keys
 154      (Left  : Cursor;
 155       Right : Element_Type) return Boolean;
 156
 157    function Equivalent_Keys
 158      (Left  : Element_Type;
 159       Right : Cursor) return Boolean;
 160
 161    procedure Iterate
 162      (Container : Set;
 163       Process   : not null access procedure (Position : Cursor));
 164
 165    generic
 166       type Key_Type (<>) is limited private;
 167
 168       with function Key (Element : Element_Type) return Key_Type;
 169
 170       with function Hash (Key : Key_Type) return Hash_Type;
 171
 172       with function Equivalent_Keys
 173         (Key     : Key_Type;
 174          Element : Element_Type) return Boolean;
 175
 176    package Generic_Keys is
 177
 178       function Contains (Container : Set; Key : Key_Type) return Boolean;
 179
 180       function Find (Container : Set; Key : Key_Type) return Cursor;
 181
 182       function Key (Position : Cursor) return Key_Type;
 183
 184       function Element (Container : Set; Key : Key_Type) return Element_Type;
 185
 186 --  TODO: resolve in atlanta???
 187 --      procedure Replace (Container : in out Set;
 188 --                         Key       : Key_Type;
 189 --                         New_Item  : Element_Type);
 190
 191       procedure Delete (Container : in out Set; Key : Key_Type);
 192
 193       procedure Exclude (Container : in out Set; Key : Key_Type);
 194
 195       procedure Checked_Update_Element
 196         (Container : in out Set;
 197          Position  : Cursor;
 198          Process   : not null access
 199                        procedure (Element : in out Element_Type));
 200
 201       function Equivalent_Keys
 202         (Left  : Cursor;
 203          Right : Key_Type) return Boolean;
 204
 205       function Equivalent_Keys
 206         (Left  : Key_Type;
 207          Right : Cursor) return Boolean;
 208    end Generic_Keys;
 209
 210 private
 211    type Node_Type;
 212    type Node_Access is access Node_Type;
 213
 214    package HT_Types is
 215       new Hash_Tables.Generic_Hash_Table_Types (Node_Access);
 216
 217    use HT_Types;
 218
 219    type Set is new Hash_Table_Type with null record;
 220
 221    procedure Adjust (Container : in out Set);
 222
 223    procedure Finalize (Container : in out Set);
 224
 225    type Set_Access is access constant Set;
 226    for Set_Access'Storage_Size use 0;
 227
 228    type Cursor is
 229       record
 230          Container : Set_Access;
 231          Node      : Node_Access;
 232       end record;
 233
 234    No_Element : constant Cursor :=
 235                   (Container => null,
 236                    Node      => null);
 237
 238    use Ada.Streams;
 239
 240    procedure Write
 241      (Stream    : access Root_Stream_Type'Class;
 242       Container : Set);
 243
 244    for Set'Write use Write;
 245
 246    procedure Read
 247      (Stream    : access Root_Stream_Type'Class;
 248       Container : out Set);
 249
 250    for Set'Read use Read;
 251
 252    Empty_Set : constant Set := (Hash_Table_Type with null record);
 253
 254 end Ada.Containers.Indefinite_Hashed_Sets;
 255