gcc/ada/a-calend.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         A D A . C A L E N D A R                          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Unchecked_Conversion;
  35
  36 with System.OS_Primitives;
  37
  38 package body Ada.Calendar is
  39
  40    --------------------------
  41    -- Implementation Notes --
  42    --------------------------
  43
  44    --  In complex algorithms, some variables of type Ada.Calendar.Time carry
  45    --  suffix _S or _N to denote units of seconds or nanoseconds.
  46    --
  47    --  Because time is measured in different units and from different origins
  48    --  on various targets, a system independent model is incorporated into
  49    --  Ada.Calendar. The idea behind the design is to encapsulate all target
  50    --  dependent machinery in a single package, thus providing a uniform
  51    --  interface to all existing and any potential children.
  52
  53    --     package Ada.Calendar
  54    --        procedure Split (5 parameters) -------+
  55    --                                              | Call from local routine
  56    --     private                                  |
  57    --        package Formatting_Operations         |
  58    --           procedure Split (11 parameters) <--+
  59    --        end Formatting_Operations             |
  60    --     end Ada.Calendar                         |
  61    --                                              |
  62    --     package Ada.Calendar.Formatting          | Call from child routine
  63    --        procedure Split (9 or 10 parameters) -+
  64    --     end Ada.Calendar.Formatting
  65
  66    --  The behaviour of the interfacing routines is controlled via various
  67    --  flags. All new Ada 2005 types from children of Ada.Calendar are
  68    --  emulated by a similar type. For instance, type Day_Number is replaced
  69    --  by Integer in various routines. One ramification of this model is that
  70    --  the caller site must perform validity checks on returned results.
  71    --  The end result of this model is the lack of target specific files per
  72    --  child of Ada.Calendar (a-calfor, a-calfor-vms, a-calfor-vxwors, etc).
  73
  74    -----------------------
  75    -- Local Subprograms --
  76    -----------------------
  77
  78    procedure Check_Within_Time_Bounds (T : Time_Rep);
  79    --  Ensure that a time representation value falls withing the bounds of Ada
  80    --  time. Leap seconds support is taken into account.
  81
  82    procedure Cumulative_Leap_Seconds
  83      (Start_Date    : Time_Rep;
  84       End_Date      : Time_Rep;
  85       Elapsed_Leaps : out Natural;
  86       Next_Leap     : out Time_Rep);
  87    --  Elapsed_Leaps is the sum of the leap seconds that have occurred on or
  88    --  after Start_Date and before (strictly before) End_Date. Next_Leap_Sec
  89    --  represents the next leap second occurrence on or after End_Date. If
  90    --  there are no leaps seconds after End_Date, End_Of_Time is returned.
  91    --  End_Of_Time can be used as End_Date to count all the leap seconds that
  92    --  have occurred on or after Start_Date.
  93    --
  94    --  Note: Any sub seconds of Start_Date and End_Date are discarded before
  95    --  the calculations are done. For instance: if 113 seconds is a leap
  96    --  second (it isn't) and 113.5 is input as an End_Date, the leap second
  97    --  at 113 will not be counted in Leaps_Between, but it will be returned
  98    --  as Next_Leap_Sec. Thus, if the caller wants to know if the End_Date is
  99    --  a leap second, the comparison should be:
 100    --
 101    --     End_Date >= Next_Leap_Sec;
 102    --
 103    --  After_Last_Leap is designed so that this comparison works without
 104    --  having to first check if Next_Leap_Sec is a valid leap second.
 105
 106    function Duration_To_Time_Rep is
 107      new Ada.Unchecked_Conversion (Duration, Time_Rep);
 108    --  Convert a duration value into a time representation value
 109
 110    function Time_Rep_To_Duration is
 111      new Ada.Unchecked_Conversion (Time_Rep, Duration);
 112    --  Convert a time representation value into a duration value
 113
 114    -----------------
 115    -- Local Types --
 116    -----------------
 117
 118    --  An integer time duration. The type is used whenever a positive elapsed
 119    --  duration is needed, for instance when splitting a time value. Here is
 120    --  how Time_Rep and Time_Dur are related:
 121
 122    --            'First  Ada_Low                  Ada_High  'Last
 123    --  Time_Rep: +-------+------------------------+---------+
 124    --  Time_Dur:         +------------------------+---------+
 125    --                    0                                  'Last
 126
 127    type Time_Dur is range 0 .. 2 ** 63 - 1;
 128
 129    --------------------------
 130    -- Leap seconds control --
 131    --------------------------
 132
 133    Flag : Integer;
 134    pragma Import (C, Flag, "__gl_leap_seconds_support");
 135    --  This imported value is used to determine whether the compilation had
 136    --  binder flag "-y" present which enables leap seconds. A value of zero
 137    --  signifies no leap seconds support while a value of one enables the
 138    --  support.
 139
 140    Leap_Support : constant Boolean := Flag = 1;
 141    --  The above flag controls the usage of leap seconds in all Ada.Calendar
 142    --  routines.
 143
 144    Leap_Seconds_Count : constant Natural := 23;
 145
 146    ---------------------
 147    -- Local Constants --
 148    ---------------------
 149
 150    Ada_Min_Year          : constant Year_Number := Year_Number'First;
 151    Secs_In_Four_Years    : constant := (3 * 365 + 366) * Secs_In_Day;
 152    Secs_In_Non_Leap_Year : constant := 365 * Secs_In_Day;
 153
 154    --  Lower and upper bound of Ada time. The zero (0) value of type Time is
 155    --  positioned at year 2150. Note that the lower and upper bound account
 156    --  for the non-leap centennial years.
 157
 158    Ada_Low  : constant Time_Rep := -(61 * 366 + 188 * 365) * Nanos_In_Day;
 159    Ada_High : constant Time_Rep :=  (60 * 366 + 190 * 365) * Nanos_In_Day;
 160
 161    --  Even though the upper bound of time is 2399-12-31 23:59:59.999999999
 162    --  UTC, it must be increased to include all leap seconds.
 163
 164    Ada_High_And_Leaps : constant Time_Rep :=
 165                           Ada_High + Time_Rep (Leap_Seconds_Count) * Nano;
 166
 167    --  Two constants used in the calculations of elapsed leap seconds.
 168    --  End_Of_Time is later than Ada_High in time zone -28. Start_Of_Time
 169    --  is earlier than Ada_Low in time zone +28.
 170
 171    End_Of_Time   : constant Time_Rep :=
 172                      Ada_High + Time_Rep (3) * Nanos_In_Day;
 173    Start_Of_Time : constant Time_Rep :=
 174                      Ada_Low - Time_Rep (3) * Nanos_In_Day;
 175
 176    --  The Unix lower time bound expressed as nanoseconds since the
 177    --  start of Ada time in UTC.
 178
 179    Unix_Min : constant Time_Rep :=
 180                 Ada_Low + Time_Rep (17 * 366 + 52 * 365) * Nanos_In_Day;
 181
 182    Cumulative_Days_Before_Month :
 183      constant array (Month_Number) of Natural :=
 184        (0, 31, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334);
 185
 186    --  The following table contains the hard time values of all existing leap
 187    --  seconds. The values are produced by the utility program xleaps.adb.
 188
 189    Leap_Second_Times : constant array (1 .. Leap_Seconds_Count) of Time_Rep :=
 190      (-5601484800000000000,
 191       -5585587199000000000,
 192       -5554051198000000000,
 193       -5522515197000000000,
 194       -5490979196000000000,
 195       -5459356795000000000,
 196       -5427820794000000000,
 197       -5396284793000000000,
 198       -5364748792000000000,
 199       -5317487991000000000,
 200       -5285951990000000000,
 201       -5254415989000000000,
 202       -5191257588000000000,
 203       -5112287987000000000,
 204       -5049129586000000000,
 205       -5017593585000000000,
 206       -4970332784000000000,
 207       -4938796783000000000,
 208       -4907260782000000000,
 209       -4859827181000000000,
 210       -4812566380000000000,
 211       -4765132779000000000,
 212       -4544207978000000000);
 213
 214    ---------
 215    -- "+" --
 216    ---------
 217
 218    function "+" (Left : Time; Right : Duration) return Time is
 219       pragma Unsuppress (Overflow_Check);
 220       Left_N : constant Time_Rep := Time_Rep (Left);
 221    begin
 222       return Time (Left_N + Duration_To_Time_Rep (Right));
 223    exception
 224       when Constraint_Error =>
 225          raise Time_Error;
 226    end "+";
 227
 228    function "+" (Left : Duration; Right : Time) return Time is
 229    begin
 230       return Right + Left;
 231    end "+";
 232
 233    ---------
 234    -- "-" --
 235    ---------
 236
 237    function "-" (Left : Time; Right : Duration) return Time is
 238       pragma Unsuppress (Overflow_Check);
 239       Left_N : constant Time_Rep := Time_Rep (Left);
 240    begin
 241       return Time (Left_N - Duration_To_Time_Rep (Right));
 242    exception
 243       when Constraint_Error =>
 244          raise Time_Error;
 245    end "-";
 246
 247    function "-" (Left : Time; Right : Time) return Duration is
 248       pragma Unsuppress (Overflow_Check);
 249
 250       --  The bounds of type Duration expressed as time representations
 251
 252       Dur_Low  : constant Time_Rep := Duration_To_Time_Rep (Duration'First);
 253       Dur_High : constant Time_Rep := Duration_To_Time_Rep (Duration'Last);
 254
 255       Res_N : Time_Rep;
 256
 257    begin
 258       Res_N := Time_Rep (Left) - Time_Rep (Right);
 259
 260       --  Due to the extended range of Ada time, "-" is capable of producing
 261       --  results which may exceed the range of Duration. In order to prevent
 262       --  the generation of bogus values by the Unchecked_Conversion, we apply
 263       --  the following check.
 264
 265       if Res_N < Dur_Low
 266         or else Res_N > Dur_High
 267       then
 268          raise Time_Error;
 269       end if;
 270
 271       return Time_Rep_To_Duration (Res_N);
 272    exception
 273       when Constraint_Error =>
 274          raise Time_Error;
 275    end "-";
 276
 277    ---------
 278    -- "<" --
 279    ---------
 280
 281    function "<" (Left, Right : Time) return Boolean is
 282    begin
 283       return Time_Rep (Left) < Time_Rep (Right);
 284    end "<";
 285
 286    ----------
 287    -- "<=" --
 288    ----------
 289
 290    function "<=" (Left, Right : Time) return Boolean is
 291    begin
 292       return Time_Rep (Left) <= Time_Rep (Right);
 293    end "<=";
 294
 295    ---------
 296    -- ">" --
 297    ---------
 298
 299    function ">" (Left, Right : Time) return Boolean is
 300    begin
 301       return Time_Rep (Left) > Time_Rep (Right);
 302    end ">";
 303
 304    ----------
 305    -- ">=" --
 306    ----------
 307
 308    function ">=" (Left, Right : Time) return Boolean is
 309    begin
 310       return Time_Rep (Left) >= Time_Rep (Right);
 311    end ">=";
 312
 313    ------------------------------
 314    -- Check_Within_Time_Bounds --
 315    ------------------------------
 316
 317    procedure Check_Within_Time_Bounds (T : Time_Rep) is
 318    begin
 319       if Leap_Support then
 320          if T < Ada_Low or else T > Ada_High_And_Leaps then
 321             raise Time_Error;
 322          end if;
 323       else
 324          if T < Ada_Low or else T > Ada_High then
 325             raise Time_Error;
 326          end if;
 327       end if;
 328    end Check_Within_Time_Bounds;
 329
 330    -----------
 331    -- Clock --
 332    -----------
 333
 334    function Clock return Time is
 335       Elapsed_Leaps : Natural;
 336       Next_Leap_N   : Time_Rep;
 337
 338       --  The system clock returns the time in UTC since the Unix Epoch of
 339       --  1970-01-01 00:00:00.0. We perform an origin shift to the Ada Epoch
 340       --  by adding the number of nanoseconds between the two origins.
 341
 342       Res_N : Time_Rep :=
 343                 Duration_To_Time_Rep (System.OS_Primitives.Clock) +
 344                   Unix_Min;
 345
 346    begin
 347       --  If the target supports leap seconds, determine the number of leap
 348       --  seconds elapsed until this moment.
 349
 350       if Leap_Support then
 351          Cumulative_Leap_Seconds
 352            (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
 353
 354          --  The system clock may fall exactly on a leap second
 355
 356          if Res_N >= Next_Leap_N then
 357             Elapsed_Leaps := Elapsed_Leaps + 1;
 358          end if;
 359
 360       --  The target does not support leap seconds
 361
 362       else
 363          Elapsed_Leaps := 0;
 364       end if;
 365
 366       Res_N := Res_N + Time_Rep (Elapsed_Leaps) * Nano;
 367
 368       return Time (Res_N);
 369    end Clock;
 370
 371    -----------------------------
 372    -- Cumulative_Leap_Seconds --
 373    -----------------------------
 374
 375    procedure Cumulative_Leap_Seconds
 376      (Start_Date    : Time_Rep;
 377       End_Date      : Time_Rep;
 378       Elapsed_Leaps : out Natural;
 379       Next_Leap     : out Time_Rep)
 380    is
 381       End_Index   : Positive;
 382       End_T       : Time_Rep := End_Date;
 383       Start_Index : Positive;
 384       Start_T     : Time_Rep := Start_Date;
 385
 386    begin
 387       --  Both input dates must be normalized to UTC
 388
 389       pragma Assert (Leap_Support and then End_Date >= Start_Date);
 390
 391       Next_Leap := End_Of_Time;
 392
 393       --  Make sure that the end date does not exceed the upper bound
 394       --  of Ada time.
 395
 396       if End_Date > Ada_High then
 397          End_T := Ada_High;
 398       end if;
 399
 400       --  Remove the sub seconds from both dates
 401
 402       Start_T := Start_T - (Start_T mod Nano);
 403       End_T   := End_T   - (End_T   mod Nano);
 404
 405       --  Some trivial cases:
 406       --                     Leap 1 . . . Leap N
 407       --  ---+========+------+############+-------+========+-----
 408       --     Start_T  End_T                       Start_T  End_T
 409
 410       if End_T < Leap_Second_Times (1) then
 411          Elapsed_Leaps := 0;
 412          Next_Leap     := Leap_Second_Times (1);
 413          return;
 414
 415       elsif Start_T > Leap_Second_Times (Leap_Seconds_Count) then
 416          Elapsed_Leaps := 0;
 417          Next_Leap     := End_Of_Time;
 418          return;
 419       end if;
 420
 421       --  Perform the calculations only if the start date is within the leap
 422       --  second occurrences table.
 423
 424       if Start_T <= Leap_Second_Times (Leap_Seconds_Count) then
 425
 426          --    1    2                  N - 1   N
 427          --  +----+----+--  . . .  --+-------+---+
 428          --  | T1 | T2 |             | N - 1 | N |
 429          --  +----+----+--  . . .  --+-------+---+
 430          --         ^                   ^
 431          --         | Start_Index       | End_Index
 432          --         +-------------------+
 433          --             Leaps_Between
 434
 435          --  The idea behind the algorithm is to iterate and find two
 436          --  closest dates which are after Start_T and End_T. Their
 437          --  corresponding index difference denotes the number of leap
 438          --  seconds elapsed.
 439
 440          Start_Index := 1;
 441          loop
 442             exit when Leap_Second_Times (Start_Index) >= Start_T;
 443             Start_Index := Start_Index + 1;
 444          end loop;
 445
 446          End_Index := Start_Index;
 447          loop
 448             exit when End_Index > Leap_Seconds_Count
 449               or else Leap_Second_Times (End_Index) >= End_T;
 450             End_Index := End_Index + 1;
 451          end loop;
 452
 453          if End_Index <= Leap_Seconds_Count then
 454             Next_Leap := Leap_Second_Times (End_Index);
 455          end if;
 456
 457          Elapsed_Leaps := End_Index - Start_Index;
 458
 459       else
 460          Elapsed_Leaps := 0;
 461       end if;
 462    end Cumulative_Leap_Seconds;
 463
 464    ---------
 465    -- Day --
 466    ---------
 467
 468    function Day (Date : Time) return Day_Number is
 469       D : Day_Number;
 470       Y : Year_Number;
 471       M : Month_Number;
 472       S : Day_Duration;
 473       pragma Unreferenced (Y, M, S);
 474    begin
 475       Split (Date, Y, M, D, S);
 476       return D;
 477    end Day;
 478
 479    -------------
 480    -- Is_Leap --
 481    -------------
 482
 483    function Is_Leap (Year : Year_Number) return Boolean is
 484    begin
 485       --  Leap centennial years
 486
 487       if Year mod 400 = 0 then
 488          return True;
 489
 490       --  Non-leap centennial years
 491
 492       elsif Year mod 100 = 0 then
 493          return False;
 494
 495       --  Regular years
 496
 497       else
 498          return Year mod 4 = 0;
 499       end if;
 500    end Is_Leap;
 501
 502    -----------
 503    -- Month --
 504    -----------
 505
 506    function Month (Date : Time) return Month_Number is
 507       Y : Year_Number;
 508       M : Month_Number;
 509       D : Day_Number;
 510       S : Day_Duration;
 511       pragma Unreferenced (Y, D, S);
 512    begin
 513       Split (Date, Y, M, D, S);
 514       return M;
 515    end Month;
 516
 517    -------------
 518    -- Seconds --
 519    -------------
 520
 521    function Seconds (Date : Time) return Day_Duration is
 522       Y : Year_Number;
 523       M : Month_Number;
 524       D : Day_Number;
 525       S : Day_Duration;
 526       pragma Unreferenced (Y, M, D);
 527    begin
 528       Split (Date, Y, M, D, S);
 529       return S;
 530    end Seconds;
 531
 532    -----------
 533    -- Split --
 534    -----------
 535
 536    procedure Split
 537      (Date    : Time;
 538       Year    : out Year_Number;
 539       Month   : out Month_Number;
 540       Day     : out Day_Number;
 541       Seconds : out Day_Duration)
 542    is
 543       H  : Integer;
 544       M  : Integer;
 545       Se : Integer;
 546       Ss : Duration;
 547       Le : Boolean;
 548
 549       pragma Unreferenced (H, M, Se, Ss, Le);
 550
 551    begin
 552       --  Even though the input time zone is UTC (0), the flag Is_Ada_05 will
 553       --  ensure that Split picks up the local time zone.
 554
 555       Formatting_Operations.Split
 556         (Date      => Date,
 557          Year      => Year,
 558          Month     => Month,
 559          Day       => Day,
 560          Day_Secs  => Seconds,
 561          Hour      => H,
 562          Minute    => M,
 563          Second    => Se,
 564          Sub_Sec   => Ss,
 565          Leap_Sec  => Le,
 566          Is_Ada_05 => False,
 567          Time_Zone => 0);
 568
 569       --  Validity checks
 570
 571       if not Year'Valid
 572         or else not Month'Valid
 573         or else not Day'Valid
 574         or else not Seconds'Valid
 575       then
 576          raise Time_Error;
 577       end if;
 578    end Split;
 579
 580    -------------
 581    -- Time_Of --
 582    -------------
 583
 584    function Time_Of
 585      (Year    : Year_Number;
 586       Month   : Month_Number;
 587       Day     : Day_Number;
 588       Seconds : Day_Duration := 0.0) return Time
 589    is
 590       --  The values in the following constants are irrelevant, they are just
 591       --  placeholders; the choice of constructing a Day_Duration value is
 592       --  controlled by the Use_Day_Secs flag.
 593
 594       H  : constant Integer := 1;
 595       M  : constant Integer := 1;
 596       Se : constant Integer := 1;
 597       Ss : constant Duration := 0.1;
 598
 599    begin
 600       --  Validity checks
 601
 602       if not Year'Valid
 603         or else not Month'Valid
 604         or else not Day'Valid
 605         or else not Seconds'Valid
 606       then
 607          raise Time_Error;
 608       end if;
 609
 610       --  Even though the input time zone is UTC (0), the flag Is_Ada_05 will
 611       --  ensure that Split picks up the local time zone.
 612
 613       return
 614         Formatting_Operations.Time_Of
 615           (Year         => Year,
 616            Month        => Month,
 617            Day          => Day,
 618            Day_Secs     => Seconds,
 619            Hour         => H,
 620            Minute       => M,
 621            Second       => Se,
 622            Sub_Sec      => Ss,
 623            Leap_Sec     => False,
 624            Use_Day_Secs => True,
 625            Is_Ada_05    => False,
 626            Time_Zone    => 0);
 627    end Time_Of;
 628
 629    ----------
 630    -- Year --
 631    ----------
 632
 633    function Year (Date : Time) return Year_Number is
 634       Y : Year_Number;
 635       M : Month_Number;
 636       D : Day_Number;
 637       S : Day_Duration;
 638       pragma Unreferenced (M, D, S);
 639    begin
 640       Split (Date, Y, M, D, S);
 641       return Y;
 642    end Year;
 643
 644    --  The following packages assume that Time is a signed 64 bit integer
 645    --  type, the units are nanoseconds and the origin is the start of Ada
 646    --  time (1901-01-01 00:00:00.0 UTC).
 647
 648    ---------------------------
 649    -- Arithmetic_Operations --
 650    ---------------------------
 651
 652    package body Arithmetic_Operations is
 653
 654       ---------
 655       -- Add --
 656       ---------
 657
 658       function Add (Date : Time; Days : Long_Integer) return Time is
 659          pragma Unsuppress (Overflow_Check);
 660          Date_N : constant Time_Rep := Time_Rep (Date);
 661       begin
 662          return Time (Date_N + Time_Rep (Days) * Nanos_In_Day);
 663       exception
 664          when Constraint_Error =>
 665             raise Time_Error;
 666       end Add;
 667
 668       ----------------
 669       -- Difference --
 670       ----------------
 671
 672       procedure Difference
 673         (Left         : Time;
 674          Right        : Time;
 675          Days         : out Long_Integer;
 676          Seconds      : out Duration;
 677          Leap_Seconds : out Integer)
 678       is
 679          Res_Dur       : Time_Dur;
 680          Earlier       : Time_Rep;
 681          Elapsed_Leaps : Natural;
 682          Later         : Time_Rep;
 683          Negate        : Boolean := False;
 684          Next_Leap_N   : Time_Rep;
 685          Sub_Secs      : Duration;
 686          Sub_Secs_Diff : Time_Rep;
 687
 688       begin
 689          --  Both input time values are assumed to be in UTC
 690
 691          if Left >= Right then
 692             Later   := Time_Rep (Left);
 693             Earlier := Time_Rep (Right);
 694          else
 695             Later   := Time_Rep (Right);
 696             Earlier := Time_Rep (Left);
 697             Negate  := True;
 698          end if;
 699
 700          --  If the target supports leap seconds, process them
 701
 702          if Leap_Support then
 703             Cumulative_Leap_Seconds
 704               (Earlier, Later, Elapsed_Leaps, Next_Leap_N);
 705
 706             if Later >= Next_Leap_N then
 707                Elapsed_Leaps := Elapsed_Leaps + 1;
 708             end if;
 709
 710          --  The target does not support leap seconds
 711
 712          else
 713             Elapsed_Leaps := 0;
 714          end if;
 715
 716          --  Sub seconds processing. We add the resulting difference to one
 717          --  of the input dates in order to account for any potential rounding
 718          --  of the difference in the next step.
 719
 720          Sub_Secs_Diff := Later mod Nano - Earlier mod Nano;
 721          Earlier       := Earlier + Sub_Secs_Diff;
 722          Sub_Secs      := Duration (Sub_Secs_Diff) / Nano_F;
 723
 724          --  Difference processing. This operation should be able to calculate
 725          --  the difference between opposite values which are close to the end
 726          --  and start of Ada time. To accommodate the large range, we convert
 727          --  to seconds. This action may potentially round the two values and
 728          --  either add or drop a second. We compensate for this issue in the
 729          --  previous step.
 730
 731          Res_Dur :=
 732            Time_Dur (Later / Nano - Earlier / Nano) - Time_Dur (Elapsed_Leaps);
 733
 734          Days         := Long_Integer (Res_Dur / Secs_In_Day);
 735          Seconds      := Duration (Res_Dur mod Secs_In_Day) + Sub_Secs;
 736          Leap_Seconds := Integer (Elapsed_Leaps);
 737
 738          if Negate then
 739             Days    := -Days;
 740             Seconds := -Seconds;
 741
 742             if Leap_Seconds /= 0 then
 743                Leap_Seconds := -Leap_Seconds;
 744             end if;
 745          end if;
 746       end Difference;
 747
 748       --------------
 749       -- Subtract --
 750       --------------
 751
 752       function Subtract (Date : Time; Days : Long_Integer) return Time is
 753          pragma Unsuppress (Overflow_Check);
 754          Date_N : constant Time_Rep := Time_Rep (Date);
 755       begin
 756          return Time (Date_N - Time_Rep (Days) * Nanos_In_Day);
 757       exception
 758          when Constraint_Error =>
 759             raise Time_Error;
 760       end Subtract;
 761    end Arithmetic_Operations;
 762
 763    ----------------------
 764    -- Delay_Operations --
 765    ----------------------
 766
 767    package body Delays_Operations is
 768
 769       -----------------
 770       -- To_Duration --
 771       -----------------
 772
 773       function To_Duration (Date : Time) return Duration is
 774          Elapsed_Leaps : Natural;
 775          Next_Leap_N   : Time_Rep;
 776          Res_N         : Time_Rep;
 777
 778       begin
 779          Res_N := Time_Rep (Date);
 780
 781          --  If the target supports leap seconds, remove any leap seconds
 782          --  elapsed up to the input date.
 783
 784          if Leap_Support then
 785             Cumulative_Leap_Seconds
 786               (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
 787
 788             --  The input time value may fall on a leap second occurrence
 789
 790             if Res_N >= Next_Leap_N then
 791                Elapsed_Leaps := Elapsed_Leaps + 1;
 792             end if;
 793
 794          --  The target does not support leap seconds
 795
 796          else
 797             Elapsed_Leaps := 0;
 798          end if;
 799
 800          Res_N := Res_N - Time_Rep (Elapsed_Leaps) * Nano;
 801
 802          --  Perform a shift in origins, note that enforcing type Time on
 803          --  both operands will invoke Ada.Calendar."-".
 804
 805          return Time (Res_N) - Time (Unix_Min);
 806       end To_Duration;
 807    end Delays_Operations;
 808
 809    ---------------------------
 810    -- Formatting_Operations --
 811    ---------------------------
 812
 813    package body Formatting_Operations is
 814
 815       -----------------
 816       -- Day_Of_Week --
 817       -----------------
 818
 819       function Day_Of_Week (Date : Time) return Integer is
 820          Y  : Year_Number;
 821          Mo : Month_Number;
 822          D  : Day_Number;
 823          Ds : Day_Duration;
 824          H  : Integer;
 825          Mi : Integer;
 826          Se : Integer;
 827          Su : Duration;
 828          Le : Boolean;
 829
 830          pragma Unreferenced (Ds, H, Mi, Se, Su, Le);
 831
 832          Day_Count : Long_Integer;
 833          Res_Dur   : Time_Dur;
 834          Res_N     : Time_Rep;
 835
 836       begin
 837          Formatting_Operations.Split
 838            (Date      => Date,
 839             Year      => Y,
 840             Month     => Mo,
 841             Day       => D,
 842             Day_Secs  => Ds,
 843             Hour      => H,
 844             Minute    => Mi,
 845             Second    => Se,
 846             Sub_Sec   => Su,
 847             Leap_Sec  => Le,
 848             Is_Ada_05 => True,
 849             Time_Zone => 0);
 850
 851          --  Build a time value in the middle of the same day
 852
 853          Res_N :=
 854            Time_Rep
 855              (Formatting_Operations.Time_Of
 856                (Year         => Y,
 857                 Month        => Mo,
 858                 Day          => D,
 859                 Day_Secs     => 0.0,
 860                 Hour         => 12,
 861                 Minute       => 0,
 862                 Second       => 0,
 863                 Sub_Sec      => 0.0,
 864                 Leap_Sec     => False,
 865                 Use_Day_Secs => False,
 866                 Is_Ada_05    => True,
 867                 Time_Zone    => 0));
 868
 869          --  Determine the elapsed seconds since the start of Ada time
 870
 871          Res_Dur := Time_Dur (Res_N / Nano - Ada_Low / Nano);
 872
 873          --  Count the number of days since the start of Ada time. 1901-1-1
 874          --  GMT was a Tuesday.
 875
 876          Day_Count := Long_Integer (Res_Dur / Secs_In_Day) + 1;
 877
 878          return Integer (Day_Count mod 7);
 879       end Day_Of_Week;
 880
 881       -----------
 882       -- Split --
 883       -----------
 884
 885       procedure Split
 886         (Date      : Time;
 887          Year      : out Year_Number;
 888          Month     : out Month_Number;
 889          Day       : out Day_Number;
 890          Day_Secs  : out Day_Duration;
 891          Hour      : out Integer;
 892          Minute    : out Integer;
 893          Second    : out Integer;
 894          Sub_Sec   : out Duration;
 895          Leap_Sec  : out Boolean;
 896          Is_Ada_05 : Boolean;
 897          Time_Zone : Long_Integer)
 898       is
 899          --  The following constants represent the number of nanoseconds
 900          --  elapsed since the start of Ada time to and including the non
 901          --  leap centennial years.
 902
 903          Year_2101 : constant Time_Rep := Ada_Low +
 904                        Time_Rep (49 * 366 + 151 * 365) * Nanos_In_Day;
 905          Year_2201 : constant Time_Rep := Ada_Low +
 906                        Time_Rep (73 * 366 + 227 * 365) * Nanos_In_Day;
 907          Year_2301 : constant Time_Rep := Ada_Low +
 908                        Time_Rep (97 * 366 + 303 * 365) * Nanos_In_Day;
 909
 910          Date_Dur       : Time_Dur;
 911          Date_N         : Time_Rep;
 912          Day_Seconds    : Natural;
 913          Elapsed_Leaps  : Natural;
 914          Four_Year_Segs : Natural;
 915          Hour_Seconds   : Natural;
 916          Is_Leap_Year   : Boolean;
 917          Next_Leap_N    : Time_Rep;
 918          Rem_Years      : Natural;
 919          Sub_Sec_N      : Time_Rep;
 920          Year_Day       : Natural;
 921
 922       begin
 923          Date_N := Time_Rep (Date);
 924
 925          --  Step 1: Leap seconds processing in UTC
 926
 927          if Leap_Support then
 928             Cumulative_Leap_Seconds
 929               (Start_Of_Time, Date_N, Elapsed_Leaps, Next_Leap_N);
 930
 931             Leap_Sec := Date_N >= Next_Leap_N;
 932
 933             if Leap_Sec then
 934                Elapsed_Leaps := Elapsed_Leaps + 1;
 935             end if;
 936
 937          --  The target does not support leap seconds
 938
 939          else
 940             Elapsed_Leaps := 0;
 941             Leap_Sec      := False;
 942          end if;
 943
 944          Date_N := Date_N - Time_Rep (Elapsed_Leaps) * Nano;
 945
 946          --  Step 2: Time zone processing. This action converts the input date
 947          --  from GMT to the requested time zone.
 948
 949          if Is_Ada_05 then
 950             if Time_Zone /= 0 then
 951                Date_N := Date_N + Time_Rep (Time_Zone) * 60 * Nano;
 952             end if;
 953
 954          --  Ada 83 and 95
 955
 956          else
 957             declare
 958                Off : constant Long_Integer :=
 959                        Time_Zones_Operations.UTC_Time_Offset (Time (Date_N));
 960             begin
 961                Date_N := Date_N + Time_Rep (Off) * Nano;
 962             end;
 963          end if;
 964
 965          --  Step 3: Non-leap centennial year adjustment in local time zone
 966
 967          --  In order for all divisions to work properly and to avoid more
 968          --  complicated arithmetic, we add fake February 29s to dates which
 969          --  occur after a non-leap centennial year.
 970
 971          if Date_N >= Year_2301 then
 972             Date_N := Date_N + Time_Rep (3) * Nanos_In_Day;
 973
 974          elsif Date_N >= Year_2201 then
 975             Date_N := Date_N + Time_Rep (2) * Nanos_In_Day;
 976
 977          elsif Date_N >= Year_2101 then
 978             Date_N := Date_N + Time_Rep (1) * Nanos_In_Day;
 979          end if;
 980
 981          --  Step 4: Sub second processing in local time zone
 982
 983          Sub_Sec_N := Date_N mod Nano;
 984          Sub_Sec   := Duration (Sub_Sec_N) / Nano_F;
 985          Date_N    := Date_N - Sub_Sec_N;
 986
 987          --  Convert Date_N into a time duration value, changing the units
 988          --  to seconds.
 989
 990          Date_Dur := Time_Dur (Date_N / Nano - Ada_Low / Nano);
 991
 992          --  Step 5: Year processing in local time zone. Determine the number
 993          --  of four year segments since the start of Ada time and the input
 994          --  date.
 995
 996          Four_Year_Segs := Natural (Date_Dur / Secs_In_Four_Years);
 997
 998          if Four_Year_Segs > 0 then
 999             Date_Dur := Date_Dur - Time_Dur (Four_Year_Segs) *
1000                                    Secs_In_Four_Years;
1001          end if;
1002
1003          --  Calculate the remaining non-leap years
1004
1005          Rem_Years := Natural (Date_Dur / Secs_In_Non_Leap_Year);
1006
1007          if Rem_Years > 3 then
1008             Rem_Years := 3;
1009          end if;
1010
1011          Date_Dur := Date_Dur - Time_Dur (Rem_Years) * Secs_In_Non_Leap_Year;
1012
1013          Year := Ada_Min_Year + Natural (4 * Four_Year_Segs + Rem_Years);
1014          Is_Leap_Year := Is_Leap (Year);
1015
1016          --  Step 6: Month and day processing in local time zone
1017
1018          Year_Day := Natural (Date_Dur / Secs_In_Day) + 1;
1019
1020          Month := 1;
1021
1022          --  Processing for months after January
1023
1024          if Year_Day > 31 then
1025             Month    := 2;
1026             Year_Day := Year_Day - 31;
1027
1028             --  Processing for a new month or a leap February
1029
1030             if Year_Day > 28
1031               and then (not Is_Leap_Year or else Year_Day > 29)
1032             then
1033                Month    := 3;
1034                Year_Day := Year_Day - 28;
1035
1036                if Is_Leap_Year then
1037                   Year_Day := Year_Day - 1;
1038                end if;
1039
1040                --  Remaining months
1041
1042                while Year_Day > Days_In_Month (Month) loop
1043                   Year_Day := Year_Day - Days_In_Month (Month);
1044                   Month    := Month + 1;
1045                end loop;
1046             end if;
1047          end if;
1048
1049          --  Step 7: Hour, minute, second and sub second processing in local
1050          --  time zone.
1051
1052          Day          := Day_Number (Year_Day);
1053          Day_Seconds  := Integer (Date_Dur mod Secs_In_Day);
1054          Day_Secs     := Duration (Day_Seconds) + Sub_Sec;
1055          Hour         := Day_Seconds / 3_600;
1056          Hour_Seconds := Day_Seconds mod 3_600;
1057          Minute       := Hour_Seconds / 60;
1058          Second       := Hour_Seconds mod 60;
1059       end Split;
1060
1061       -------------
1062       -- Time_Of --
1063       -------------
1064
1065       function Time_Of
1066         (Year         : Year_Number;
1067          Month        : Month_Number;
1068          Day          : Day_Number;
1069          Day_Secs     : Day_Duration;
1070          Hour         : Integer;
1071          Minute       : Integer;
1072          Second       : Integer;
1073          Sub_Sec      : Duration;
1074          Leap_Sec     : Boolean;
1075          Use_Day_Secs : Boolean;
1076          Is_Ada_05    : Boolean;
1077          Time_Zone    : Long_Integer) return Time
1078       is
1079          Count         : Integer;
1080          Elapsed_Leaps : Natural;
1081          Next_Leap_N   : Time_Rep;
1082          Res_N         : Time_Rep;
1083          Rounded_Res_N : Time_Rep;
1084
1085       begin
1086          --  Step 1: Check whether the day, month and year form a valid date
1087
1088          if Day > Days_In_Month (Month)
1089            and then (Day /= 29 or else Month /= 2 or else not Is_Leap (Year))
1090          then
1091             raise Time_Error;
1092          end if;
1093
1094          --  Start accumulating nanoseconds from the low bound of Ada time
1095
1096          Res_N := Ada_Low;
1097
1098          --  Step 2: Year processing and centennial year adjustment. Determine
1099          --  the number of four year segments since the start of Ada time and
1100          --  the input date.
1101
1102          Count := (Year - Year_Number'First) / 4;
1103          Res_N := Res_N + Time_Rep (Count) * Secs_In_Four_Years * Nano;
1104
1105          --  Note that non-leap centennial years are automatically considered
1106          --  leap in the operation above. An adjustment of several days is
1107          --  required to compensate for this.
1108
1109          if Year > 2300 then
1110             Res_N := Res_N - Time_Rep (3) * Nanos_In_Day;
1111
1112          elsif Year > 2200 then
1113             Res_N := Res_N - Time_Rep (2) * Nanos_In_Day;
1114
1115          elsif Year > 2100 then
1116             Res_N := Res_N - Time_Rep (1) * Nanos_In_Day;
1117          end if;
1118
1119          --  Add the remaining non-leap years
1120
1121          Count := (Year - Year_Number'First) mod 4;
1122          Res_N := Res_N + Time_Rep (Count) * Secs_In_Non_Leap_Year * Nano;
1123
1124          --  Step 3: Day of month processing. Determine the number of days
1125          --  since the start of the current year. Do not add the current
1126          --  day since it has not elapsed yet.
1127
1128          Count := Cumulative_Days_Before_Month (Month) + Day - 1;
1129
1130          --  The input year is leap and we have passed February
1131
1132          if Is_Leap (Year)
1133            and then Month > 2
1134          then
1135             Count := Count + 1;
1136          end if;
1137
1138          Res_N := Res_N + Time_Rep (Count) * Nanos_In_Day;
1139
1140          --  Step 4: Hour, minute, second and sub second processing
1141
1142          if Use_Day_Secs then
1143             Res_N := Res_N + Duration_To_Time_Rep (Day_Secs);
1144
1145          else
1146             Res_N := Res_N +
1147               Time_Rep (Hour * 3_600 + Minute * 60 + Second) * Nano;
1148
1149             if Sub_Sec = 1.0 then
1150                Res_N := Res_N + Time_Rep (1) * Nano;
1151             else
1152                Res_N := Res_N + Duration_To_Time_Rep (Sub_Sec);
1153             end if;
1154          end if;
1155
1156          --  At this point, the generated time value should be withing the
1157          --  bounds of Ada time.
1158
1159          Check_Within_Time_Bounds (Res_N);
1160
1161          --  Step 4: Time zone processing. At this point we have built an
1162          --  arbitrary time value which is not related to any time zone.
1163          --  For simplicity, the time value is normalized to GMT, producing
1164          --  a uniform representation which can be treated by arithmetic
1165          --  operations for instance without any additional corrections.
1166
1167          if Is_Ada_05 then
1168             if Time_Zone /= 0 then
1169                Res_N := Res_N - Time_Rep (Time_Zone) * 60 * Nano;
1170             end if;
1171
1172          --  Ada 83 and 95
1173
1174          else
1175             declare
1176                Current_Off   : constant Long_Integer :=
1177                                  Time_Zones_Operations.UTC_Time_Offset
1178                                    (Time (Res_N));
1179                Current_Res_N : constant Time_Rep :=
1180                                  Res_N - Time_Rep (Current_Off) * Nano;
1181                Off           : constant Long_Integer :=
1182                                  Time_Zones_Operations.UTC_Time_Offset
1183                                    (Time (Current_Res_N));
1184             begin
1185                Res_N := Res_N - Time_Rep (Off) * Nano;
1186             end;
1187          end if;
1188
1189          --  Step 5: Leap seconds processing in GMT
1190
1191          if Leap_Support then
1192             Cumulative_Leap_Seconds
1193               (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
1194
1195             Res_N := Res_N + Time_Rep (Elapsed_Leaps) * Nano;
1196
1197             --  An Ada 2005 caller requesting an explicit leap second or an
1198             --  Ada 95 caller accounting for an invisible leap second.
1199
1200             if Leap_Sec
1201               or else Res_N >= Next_Leap_N
1202             then
1203                Res_N := Res_N + Time_Rep (1) * Nano;
1204             end if;
1205
1206             --  Leap second validity check
1207
1208             Rounded_Res_N := Res_N - (Res_N mod Nano);
1209
1210             if Is_Ada_05
1211               and then Leap_Sec
1212               and then Rounded_Res_N /= Next_Leap_N
1213             then
1214                raise Time_Error;
1215             end if;
1216          end if;
1217
1218          return Time (Res_N);
1219       end Time_Of;
1220    end Formatting_Operations;
1221
1222    ---------------------------
1223    -- Time_Zones_Operations --
1224    ---------------------------
1225
1226    package body Time_Zones_Operations is
1227
1228       --  The Unix time bounds in nanoseconds: 1970/1/1 .. 2037/1/1
1229
1230       Unix_Min : constant Time_Rep := Ada_Low +
1231                    Time_Rep (17 * 366 +  52 * 365) * Nanos_In_Day;
1232
1233       Unix_Max : constant Time_Rep := Ada_Low +
1234                    Time_Rep (34 * 366 + 102 * 365) * Nanos_In_Day +
1235                    Time_Rep (Leap_Seconds_Count) * Nano;
1236
1237       --  The following constants denote February 28 during non-leap
1238       --  centennial years, the units are nanoseconds.
1239
1240       T_2100_2_28 : constant Time_Rep := Ada_Low +
1241                       (Time_Rep (49 * 366 + 150 * 365 + 59) * Secs_In_Day +
1242                        Time_Rep (Leap_Seconds_Count)) * Nano;
1243
1244       T_2200_2_28 : constant Time_Rep := Ada_Low +
1245                       (Time_Rep (73 * 366 + 226 * 365 + 59) * Secs_In_Day +
1246                        Time_Rep (Leap_Seconds_Count)) * Nano;
1247
1248       T_2300_2_28 : constant Time_Rep := Ada_Low +
1249                       (Time_Rep (97 * 366 + 302 * 365 + 59) * Secs_In_Day +
1250                        Time_Rep (Leap_Seconds_Count)) * Nano;
1251
1252       --  56 years (14 leap years + 42 non leap years) in nanoseconds:
1253
1254       Nanos_In_56_Years : constant := (14 * 366 + 42 * 365) * Nanos_In_Day;
1255
1256       --  Base C types. There is no point dragging in Interfaces.C just for
1257       --  these four types.
1258
1259       type char_Pointer is access Character;
1260       subtype int is Integer;
1261       subtype long is Long_Integer;
1262       type long_Pointer is access all long;
1263
1264       --  The Ada equivalent of struct tm and type time_t
1265
1266       type tm is record
1267          tm_sec    : int;           --  seconds after the minute (0 .. 60)
1268          tm_min    : int;           --  minutes after the hour (0 .. 59)
1269          tm_hour   : int;           --  hours since midnight (0 .. 24)
1270          tm_mday   : int;           --  day of the month (1 .. 31)
1271          tm_mon    : int;           --  months since January (0 .. 11)
1272          tm_year   : int;           --  years since 1900
1273          tm_wday   : int;           --  days since Sunday (0 .. 6)
1274          tm_yday   : int;           --  days since January 1 (0 .. 365)
1275          tm_isdst  : int;           --  Daylight Savings Time flag (-1 .. 1)
1276          tm_gmtoff : long;          --  offset from UTC in seconds
1277          tm_zone   : char_Pointer;  --  timezone abbreviation
1278       end record;
1279
1280       type tm_Pointer is access all tm;
1281
1282       subtype time_t is long;
1283       type time_t_Pointer is access all time_t;
1284
1285       procedure localtime_tzoff
1286        (C   : time_t_Pointer;
1287         res : tm_Pointer;
1288         off : long_Pointer);
1289       pragma Import (C, localtime_tzoff, "__gnat_localtime_tzoff");
1290       --  This is a lightweight wrapper around the system library function
1291       --  localtime_r. Parameter 'off' captures the UTC offset which is either
1292       --  retrieved from the tm struct or calculated from the 'timezone' extern
1293       --  and the tm_isdst flag in the tm struct.
1294
1295       ---------------------
1296       -- UTC_Time_Offset --
1297       ---------------------
1298
1299       function UTC_Time_Offset (Date : Time) return Long_Integer is
1300          Adj_Cent : Integer := 0;
1301          Date_N   : Time_Rep;
1302          Offset   : aliased long;
1303          Secs_T   : aliased time_t;
1304          Secs_TM  : aliased tm;
1305
1306       begin
1307          Date_N := Time_Rep (Date);
1308
1309          --  Dates which are 56 years apart fall on the same day, day light
1310          --  saving and so on. Non-leap centennial years violate this rule by
1311          --  one day and as a consequence, special adjustment is needed.
1312
1313          if Date_N > T_2100_2_28 then
1314             if Date_N > T_2200_2_28 then
1315                if Date_N > T_2300_2_28 then
1316                   Adj_Cent := 3;
1317                else
1318                   Adj_Cent := 2;
1319                end if;
1320
1321             else
1322                Adj_Cent := 1;
1323             end if;
1324          end if;
1325
1326          if Adj_Cent > 0 then
1327             Date_N := Date_N - Time_Rep (Adj_Cent) * Nanos_In_Day;
1328          end if;
1329
1330          --  Shift the date within bounds of Unix time
1331
1332          while Date_N < Unix_Min loop
1333             Date_N := Date_N + Nanos_In_56_Years;
1334          end loop;
1335
1336          while Date_N >= Unix_Max loop
1337             Date_N := Date_N - Nanos_In_56_Years;
1338          end loop;
1339
1340          --  Perform a shift in origins from Ada to Unix
1341
1342          Date_N := Date_N - Unix_Min;
1343
1344          --  Convert the date into seconds
1345
1346          Secs_T := time_t (Date_N / Nano);
1347
1348          localtime_tzoff
1349            (Secs_T'Unchecked_Access,
1350             Secs_TM'Unchecked_Access,
1351             Offset'Unchecked_Access);
1352
1353          return Offset;
1354       end UTC_Time_Offset;
1355    end Time_Zones_Operations;
1356
1357 --  Start of elaboration code for Ada.Calendar
1358
1359 begin
1360    System.OS_Primitives.Initialize;
1361 end Ada.Calendar;