gcc/ada/5wmemory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --             Copyright (C) 2001 Free Software Foundation, Inc.            --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  25 -- MA 02111-1307, USA.                                                      --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- GNAT was originally developed  by the GNAT team at  New York University. --
  35 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  36 --                                                                          --
  37 ------------------------------------------------------------------------------
  38
  39 --  This version provides ways to limit the amount of used memory for systems
  40 --  that do not have OS support for that.
  41
  42 --  The amount of available memory available for dynamic allocation is limited
  43 --  by setting the environment variable GNAT_MEMORY_LIMIT to the number of
  44 --  kilobytes that can be used.
  45 --
  46 --  Windows is currently using this version.
  47
  48 with Ada.Exceptions;
  49 with System.Soft_Links;
  50
  51 package body System.Memory is
  52
  53    use Ada.Exceptions;
  54    use System.Soft_Links;
  55
  56    function c_malloc (Size : size_t) return System.Address;
  57    pragma Import (C, c_malloc, "malloc");
  58
  59    procedure c_free (Ptr : System.Address);
  60    pragma Import (C, c_free, "free");
  61
  62    function c_realloc
  63      (Ptr : System.Address; Size : size_t) return System.Address;
  64    pragma Import (C, c_realloc, "realloc");
  65
  66    function msize (Ptr : System.Address) return size_t;
  67    pragma Import (C, msize, "_msize");
  68
  69    function getenv (Str : String) return System.Address;
  70    pragma Import (C, getenv);
  71
  72    function atoi (Str : System.Address) return Integer;
  73    pragma Import (C, atoi);
  74
  75    Available_Memory : size_t := 0;
  76    --  Amount of memory that is available for heap allocations.
  77    --  A value of 0 means that the amount is not yet initialized.
  78
  79    Msize_Accuracy   : constant := 4096;
  80    --  Defines the amount of memory to add to requested allocation sizes,
  81    --  because malloc may return a bigger block than requested. As msize
  82    --  is used when by Free, it must be used on allocation as well. To
  83    --  prevent underflow of available_memory we need to use a reserve.
  84
  85    procedure Check_Available_Memory (Size : size_t);
  86    --  This routine must be called while holding the task lock. When the
  87    --  memory limit is not yet initialized, it will be set to the value of
  88    --  the GNAT_MEMORY_LIMIT environment variable or to unlimited if that
  89    --  does not exist. If the size is larger than the amount of available
  90    --  memory, the task lock will be freed and a storage_error exception
  91    --  will be raised.
  92
  93    -----------
  94    -- Alloc --
  95    -----------
  96
  97    function Alloc (Size : size_t) return System.Address is
  98       Result      : System.Address;
  99       Actual_Size : size_t := Size;
 100
 101    begin
 102       if Size = size_t'Last then
 103          Raise_Exception (Storage_Error'Identity, "object too large");
 104       end if;
 105
 106       --  Change size from zero to non-zero. We still want a proper pointer
 107       --  for the zero case because pointers to zero length objects have to
 108       --  be distinct, but we can't just go ahead and allocate zero bytes,
 109       --  since some malloc's return zero for a zero argument.
 110
 111       if Size = 0 then
 112          Actual_Size := 1;
 113       end if;
 114
 115       Lock_Task.all;
 116
 117       if Actual_Size + Msize_Accuracy >= Available_Memory then
 118          Check_Available_Memory (Size + Msize_Accuracy);
 119       end if;
 120
 121       Result := c_malloc (Actual_Size);
 122
 123       if Result /= System.Null_Address then
 124          Available_Memory := Available_Memory - msize (Result);
 125       end if;
 126
 127       Unlock_Task.all;
 128
 129       if Result = System.Null_Address then
 130          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 131       end if;
 132
 133       return Result;
 134    end Alloc;
 135
 136    ----------------------------
 137    -- Check_Available_Memory --
 138    ----------------------------
 139
 140    procedure Check_Available_Memory (Size : size_t) is
 141       Gnat_Memory_Limit : System.Address;
 142
 143    begin
 144       if Available_Memory = 0 then
 145
 146          --  The amount of available memory hasn't been initialized yet
 147
 148          Gnat_Memory_Limit := getenv ("GNAT_MEMORY_LIMIT" & ASCII.NUL);
 149
 150          if Gnat_Memory_Limit /= System.Null_Address then
 151             Available_Memory :=
 152               size_t (atoi (Gnat_Memory_Limit)) * 1024 + Msize_Accuracy;
 153          else
 154             Available_Memory := size_t'Last;
 155          end if;
 156       end if;
 157
 158       if Size >= Available_Memory then
 159
 160          --  There is a memory overflow
 161
 162          Unlock_Task.all;
 163          Raise_Exception
 164            (Storage_Error'Identity, "heap memory limit exceeded");
 165       end if;
 166    end Check_Available_Memory;
 167
 168    ----------
 169    -- Free --
 170    ----------
 171
 172    procedure Free (Ptr : System.Address) is
 173    begin
 174       Lock_Task.all;
 175
 176       if Ptr /= System.Null_Address then
 177          Available_Memory := Available_Memory + msize (Ptr);
 178       end if;
 179
 180       c_free (Ptr);
 181
 182       Unlock_Task.all;
 183    end Free;
 184
 185    -------------
 186    -- Realloc --
 187    -------------
 188
 189    function Realloc
 190      (Ptr  : System.Address;
 191       Size : size_t)
 192       return System.Address
 193    is
 194       Result      : System.Address;
 195       Actual_Size : size_t := Size;
 196       Old_Size    : size_t;
 197
 198    begin
 199       if Size = size_t'Last then
 200          Raise_Exception (Storage_Error'Identity, "object too large");
 201       end if;
 202
 203       Lock_Task.all;
 204
 205       Old_Size := msize (Ptr);
 206
 207       --  Conservative check - no need to try to be precise here
 208
 209       if Size + Msize_Accuracy >= Available_Memory then
 210          Check_Available_Memory (Size + Msize_Accuracy);
 211       end if;
 212
 213       Result := c_realloc (Ptr, Actual_Size);
 214
 215       if Result /= System.Null_Address then
 216          Available_Memory := Available_Memory + Old_Size - msize (Result);
 217       end if;
 218
 219       Unlock_Task.all;
 220
 221       if Result = System.Null_Address then
 222          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 223       end if;
 224
 225       return Result;
 226    end Realloc;
 227
 228 end System.Memory;