gcc/ada/5lml-tgt.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                           (GNU/Linux Version)                            --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --              Copyright (C) 2001-2003, Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the GNU/Linux version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    use GNAT;
  44    use MLib;
  45
  46    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  47    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  48
  49    Wl_Init_String : aliased String         := "-Wl,-init";
  50    Wl_Init        : constant String_Access := Wl_Init_String'Access;
  51    Wl_Fini_String : aliased String         := "-Wl,-fini";
  52    Wl_Fini        : constant String_Access := Wl_Fini_String'Access;
  53
  54    Init_Fini_List :  constant Argument_List_Access :=
  55                        new Argument_List'(1 => Wl_Init,
  56                                           2 => null,
  57                                           3 => Wl_Fini,
  58                                           4 => null);
  59    --  Used to put switches for automatic elaboration/finalization
  60
  61    ---------------------
  62    -- Archive_Builder --
  63    ---------------------
  64
  65    function Archive_Builder return String is
  66    begin
  67       return "ar";
  68    end Archive_Builder;
  69
  70    -----------------------------
  71    -- Archive_Builder_Options --
  72    -----------------------------
  73
  74    function Archive_Builder_Options return String_List_Access is
  75    begin
  76       return new String_List'(1 => new String'("cr"));
  77    end Archive_Builder_Options;
  78
  79    -----------------
  80    -- Archive_Ext --
  81    -----------------
  82
  83    function Archive_Ext return  String is
  84    begin
  85       return "a";
  86    end Archive_Ext;
  87
  88    ---------------------
  89    -- Archive_Indexer --
  90    ---------------------
  91
  92    function Archive_Indexer return String is
  93    begin
  94       return "ranlib";
  95    end Archive_Indexer;
  96
  97    ---------------------------
  98    -- Build_Dynamic_Library --
  99    ---------------------------
 100
 101    procedure Build_Dynamic_Library
 102      (Ofiles       : Argument_List;
 103       Foreign      : Argument_List;
 104       Afiles       : Argument_List;
 105       Options      : Argument_List;
 106       Interfaces   : Argument_List;
 107       Lib_Filename : String;
 108       Lib_Dir      : String;
 109       Driver_Name  : Name_Id := No_Name;
 110       Lib_Address  : String  := "";
 111       Lib_Version  : String  := "";
 112       Relocatable  : Boolean := False;
 113       Auto_Init    : Boolean := False)
 114    is
 115       pragma Unreferenced (Foreign);
 116       pragma Unreferenced (Afiles);
 117       pragma Unreferenced (Interfaces);
 118       pragma Unreferenced (Lib_Address);
 119       pragma Unreferenced (Relocatable);
 120
 121       Lib_File : constant String :=
 122         Lib_Dir & Directory_Separator & "lib" &
 123         Fil.Ext_To (Lib_Filename, DLL_Ext);
 124
 125       Version_Arg          : String_Access;
 126       Symbolic_Link_Needed : Boolean := False;
 127
 128       Init_Fini : Argument_List_Access := Empty_Argument_List;
 129
 130    begin
 131       if Opt.Verbose_Mode then
 132          Write_Str ("building relocatable shared library ");
 133          Write_Line (Lib_File);
 134       end if;
 135
 136       --  If specified, add automatic elaboration/finalization
 137       if Auto_Init then
 138          Init_Fini := Init_Fini_List;
 139          Init_Fini (2) := new String'("-Wl," & Lib_Filename & "init");
 140          Init_Fini (4) := new String'("-Wl," & Lib_Filename & "final");
 141       end if;
 142
 143       if Lib_Version = "" then
 144          Utl.Gcc
 145            (Output_File => Lib_File,
 146             Objects     => Ofiles,
 147             Options     => Options & Init_Fini.all,
 148             Driver_Name => Driver_Name);
 149
 150       else
 151          Version_Arg := new String'("-Wl,-soname," & Lib_Version);
 152
 153          if Is_Absolute_Path (Lib_Version) then
 154             Utl.Gcc
 155               (Output_File => Lib_Version,
 156                Objects     => Ofiles,
 157                Options     => Options & Version_Arg & Init_Fini.all,
 158                Driver_Name => Driver_Name);
 159             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 160
 161          else
 162             Utl.Gcc
 163               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 164                Objects     => Ofiles,
 165                Options     => Options & Version_Arg & Init_Fini.all,
 166                Driver_Name => Driver_Name);
 167             Symbolic_Link_Needed :=
 168               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 169          end if;
 170
 171          if Symbolic_Link_Needed then
 172             declare
 173                Success : Boolean;
 174                Oldpath : String (1 .. Lib_Version'Length + 1);
 175                Newpath : String (1 .. Lib_File'Length + 1);
 176                Result  : Integer;
 177
 178                function Symlink
 179                  (Oldpath : System.Address;
 180                   Newpath : System.Address)
 181                   return    Integer;
 182                pragma Import (C, Symlink, "__gnat_symlink");
 183
 184             begin
 185                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 186                Oldpath (Oldpath'Last)            := ASCII.NUL;
 187                Newpath (1 .. Lib_File'Length)    := Lib_File;
 188                Newpath (Newpath'Last)            := ASCII.NUL;
 189
 190                Delete_File (Lib_File, Success);
 191
 192                Result := Symlink (Oldpath'Address, Newpath'Address);
 193             end;
 194          end if;
 195       end if;
 196    end Build_Dynamic_Library;
 197
 198    -------------------------
 199    -- Default_DLL_Address --
 200    -------------------------
 201
 202    function Default_DLL_Address return String is
 203    begin
 204       return "";
 205    end Default_DLL_Address;
 206
 207    -------------
 208    -- DLL_Ext --
 209    -------------
 210
 211    function DLL_Ext return String is
 212    begin
 213       return "so";
 214    end DLL_Ext;
 215
 216    --------------------
 217    -- Dynamic_Option --
 218    --------------------
 219
 220    function Dynamic_Option return String is
 221    begin
 222       return "-shared";
 223    end Dynamic_Option;
 224
 225    -------------------
 226    -- Is_Object_Ext --
 227    -------------------
 228
 229    function Is_Object_Ext (Ext : String) return Boolean is
 230    begin
 231       return Ext = ".o";
 232    end Is_Object_Ext;
 233
 234    --------------
 235    -- Is_C_Ext --
 236    --------------
 237
 238    function Is_C_Ext (Ext : String) return Boolean is
 239    begin
 240       return Ext = ".c";
 241    end Is_C_Ext;
 242
 243    --------------------
 244    -- Is_Archive_Ext --
 245    --------------------
 246
 247    function Is_Archive_Ext (Ext : String) return Boolean is
 248    begin
 249       return Ext = ".a" or else Ext = ".so";
 250    end Is_Archive_Ext;
 251
 252    -------------
 253    -- Libgnat --
 254    -------------
 255
 256    function Libgnat return String is
 257    begin
 258       return "libgnat.a";
 259    end Libgnat;
 260
 261    ------------------------
 262    -- Library_Exists_For --
 263    ------------------------
 264
 265    function Library_Exists_For (Project : Project_Id) return Boolean is
 266    begin
 267       if not Projects.Table (Project).Library then
 268          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 269                        "for non library project");
 270          return False;
 271
 272       else
 273          declare
 274             Lib_Dir : constant String :=
 275               Get_Name_String (Projects.Table (Project).Library_Dir);
 276             Lib_Name : constant String :=
 277               Get_Name_String (Projects.Table (Project).Library_Name);
 278
 279          begin
 280             if Projects.Table (Project).Library_Kind = Static then
 281                return Is_Regular_File
 282                  (Lib_Dir & Directory_Separator & "lib" &
 283                   Fil.Ext_To (Lib_Name, Archive_Ext));
 284
 285             else
 286                return Is_Regular_File
 287                  (Lib_Dir & Directory_Separator & "lib" &
 288                   Fil.Ext_To (Lib_Name, DLL_Ext));
 289             end if;
 290          end;
 291       end if;
 292    end Library_Exists_For;
 293
 294    ---------------------------
 295    -- Library_File_Name_For --
 296    ---------------------------
 297
 298    function Library_File_Name_For (Project : Project_Id) return Name_Id is
 299    begin
 300       if not Projects.Table (Project).Library then
 301          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 302                        "for non library project");
 303          return No_Name;
 304
 305       else
 306          declare
 307             Lib_Name : constant String :=
 308               Get_Name_String (Projects.Table (Project).Library_Name);
 309
 310          begin
 311             Name_Len := 3;
 312             Name_Buffer (1 .. Name_Len) := "lib";
 313
 314             if Projects.Table (Project).Library_Kind = Static then
 315                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 316
 317             else
 318                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 319             end if;
 320
 321             return Name_Find;
 322          end;
 323       end if;
 324    end Library_File_Name_For;
 325
 326    --------------------------------
 327    -- Linker_Library_Path_Option --
 328    --------------------------------
 329
 330    function Linker_Library_Path_Option return String_Access is
 331    begin
 332       return new String'("-Wl,-rpath,");
 333    end Linker_Library_Path_Option;
 334
 335    ----------------
 336    -- Object_Ext --
 337    ----------------
 338
 339    function Object_Ext return String is
 340    begin
 341       return "o";
 342    end Object_Ext;
 343
 344    ----------------
 345    -- PIC_Option --
 346    ----------------
 347
 348    function PIC_Option return String is
 349    begin
 350       return "-fPIC";
 351    end PIC_Option;
 352
 353    -----------------------------------------------
 354    -- Standalone_Library_Auto_Init_Is_Supported --
 355    -----------------------------------------------
 356
 357    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 358    begin
 359       return True;
 360    end Standalone_Library_Auto_Init_Is_Supported;
 361
 362    ---------------------------
 363    -- Support_For_Libraries --
 364    ---------------------------
 365
 366    function Support_For_Libraries return Library_Support is
 367    begin
 368       return Full;
 369    end Support_For_Libraries;
 370
 371 end MLib.Tgt;