gcc/ada/51osinte.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --                                                                          --
  10 --           Copyright (C) 1999-2001 Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University. It is --
  31 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  32 -- State University (http://www.gnat.com).                                  --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This is a UnixWare (Native) version of this package
  37
  38 pragma Polling (Off);
  39 --  Turn off polling, we do not want ATC polling to take place during
  40 --  tasking operations. It causes infinite loops and other problems.
  41
  42 with Interfaces.C;
  43
  44 package body System.OS_Interface is
  45
  46    use Interfaces.C;
  47
  48    -----------------
  49    -- To_Duration --
  50    -----------------
  51
  52    function To_Duration (TS : timespec) return Duration is
  53    begin
  54       return Duration (TS.tv_sec) + Duration (TS.tv_nsec) / 10#1#E9;
  55    end To_Duration;
  56
  57    function To_Duration (TV : struct_timeval) return Duration is
  58    begin
  59       return Duration (TV.tv_sec) + Duration (TV.tv_usec) / 10#1#E6;
  60    end To_Duration;
  61
  62    -----------------
  63    -- To_Timespec --
  64    -----------------
  65
  66    function To_Timespec (D : Duration) return timespec is
  67       S : time_t;
  68       F : Duration;
  69
  70    begin
  71       S := time_t (Long_Long_Integer (D));
  72       F := D - Duration (S);
  73
  74       --  If F has negative value due to a round-up, adjust for positive F
  75       --  value.
  76
  77       if F < 0.0 then
  78          S := S - 1;
  79          F := F + 1.0;
  80       end if;
  81
  82       return timespec' (tv_sec => S,
  83         tv_nsec => long (Long_Long_Integer (F * 10#1#E9)));
  84    end To_Timespec;
  85
  86    ----------------
  87    -- To_Timeval --
  88    ----------------
  89
  90    function To_Timeval (D : Duration) return struct_timeval is
  91       S : long;
  92       F : Duration;
  93
  94    begin
  95       S := long (Long_Long_Integer (D));
  96       F := D - Duration (S);
  97
  98       --  If F has negative value due to a round-up, adjust for positive F
  99       --  value.
 100
 101       if F < 0.0 then
 102          S := S - 1;
 103          F := F + 1.0;
 104       end if;
 105
 106       return struct_timeval' (tv_sec => S,
 107         tv_usec => long (Long_Long_Integer (F * 10#1#E6)));
 108    end To_Timeval;
 109
 110    -------------------
 111    -- clock_gettime --
 112    -------------------
 113
 114    function clock_gettime
 115      (clock_id : clockid_t;
 116       tp       : access timespec) return int
 117    is
 118       Result : int;
 119       tv     : aliased struct_timeval;
 120
 121       function gettimeofday
 122         (tv : access struct_timeval;
 123          tz : System.Address := System.Null_Address) return int;
 124       pragma Import (C, gettimeofday, "gettimeofday");
 125
 126    begin
 127       Result := gettimeofday (tv'Unchecked_Access);
 128       tp.all := To_Timespec (To_Duration (tv));
 129       return Result;
 130    end clock_gettime;
 131
 132    ---------------------------
 133    --  POSIX.1c  Section 3  --
 134    ---------------------------
 135
 136    function sigwait (set : access sigset_t; sig : access Signal) return int is
 137       Result : int;
 138
 139       function sigwait (set : access sigset_t) return int;
 140       pragma Import (C, sigwait, "sigwait");
 141
 142    begin
 143       Result := sigwait (set);
 144
 145       if Result < 0 then
 146          sig.all := 0;
 147          return errno;
 148       end if;
 149
 150       sig.all := Signal (Result);
 151       return 0;
 152    end sigwait;
 153
 154    function pthread_kill (thread : pthread_t; sig : Signal) return int is
 155       function pthread_kill_base
 156         (thread : access pthread_t; sig : access Signal) return int;
 157       pragma Import (C, pthread_kill_base, "pthread_kill");
 158
 159       thr   : aliased pthread_t := thread;
 160       signo : aliased Signal := sig;
 161
 162    begin
 163       return pthread_kill_base (thr'Unchecked_Access, signo'Unchecked_Access);
 164    end pthread_kill;
 165
 166    function Get_Stack_Base (thread : pthread_t) return Address is
 167    begin
 168       return Null_Address;
 169    end Get_Stack_Base;
 170
 171    procedure pthread_init is
 172    begin
 173       null;
 174    end pthread_init;
 175
 176 end System.OS_Interface;