gcc/ada/4zsytaco.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --         A D A . S Y N C H R O N O U S _ T A S K _ C O N T R O L          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.1 $
  10 --                                                                          --
  11 --            Copyright (C) 1992-2001 Free Software Foundation, Inc.        --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 with Interfaces.C;
  37 package body Ada.Synchronous_Task_Control is
  38    use System.OS_Interface;
  39    use type Interfaces.C.int;
  40
  41    -------------------
  42    -- Current_State --
  43    -------------------
  44
  45    function Current_State (S : Suspension_Object) return Boolean is
  46       St     : STATUS;
  47       Result : Boolean := False;
  48
  49    begin
  50       --  Determine state by attempting to take the semaphore with
  51       --  a 0 timeout value.  Status = OK indicates the semaphore was
  52       --  full, so reset it to the full state.
  53
  54       St := semTake (S.Sema, NO_WAIT);
  55
  56       if St = OK then
  57          --  Took the semaphore. Reset semaphore state to FULL
  58          Result := True;
  59          St := semGive (S.Sema);
  60       end if;
  61
  62       return Result;
  63    end Current_State;
  64
  65    ---------------
  66    -- Set_False --
  67    ---------------
  68
  69    procedure Set_False (S : in out Suspension_Object) is
  70       St : STATUS;
  71    begin
  72       --  Need to get the semaphore into the "empty" state.
  73       --  On return, this task will have made the semaphore
  74       --  empty (St = OK) or have left it empty.
  75       St := semTake (S.Sema, NO_WAIT);
  76    end Set_False;
  77
  78    --------------
  79    -- Set_True --
  80    --------------
  81
  82    procedure Set_True (S : in out Suspension_Object) is
  83       St : STATUS;
  84    begin
  85       St := semGive (S.Sema);
  86    end Set_True;
  87
  88    ------------------------
  89    -- Suspend_Until_True --
  90    ------------------------
  91
  92    procedure Suspend_Until_True (S : in out Suspension_Object) is
  93       St : STATUS;
  94
  95       --  Declare local exception so the mutex can still be reset
  96       --  to full if Program_Error is raised
  97
  98       Task_Already_Pending : exception;
  99    begin
 100       --  Determine whether another task is pending on the suspension
 101       --  object. Should never be called from an ISR. Therefore semTake can
 102       --  be called on the mutex
 103       St := semTake (S.Mutex, NO_WAIT);
 104
 105       if St = OK then
 106          --  Wait for suspension object
 107
 108          St := semTake (S.Sema, WAIT_FOREVER);
 109          St := semGive (S.Mutex);
 110
 111       else
 112          --  Another task is pending on the suspension object
 113
 114          raise Task_Already_Pending;
 115       end if;
 116    exception
 117       when Task_Already_Pending =>
 118          raise Program_Error;
 119       when others =>
 120          St := semGive (S.Mutex);
 121          raise;
 122    end Suspend_Until_True;
 123
 124    procedure Initialize (S : in out Suspension_Object) is
 125    begin
 126       S.Sema := semBCreate (SEM_Q_FIFO, SEM_EMPTY);
 127
 128       --  Use simpler binary semaphore instead of VxWorks
 129       --  mutual exclusion semaphore, because we don't need
 130       --  the fancier semantics and their overhead.
 131
 132       S.Mutex := semBCreate (SEM_Q_FIFO, SEM_FULL);
 133    end Initialize;
 134
 135    procedure Finalize (S : in out Suspension_Object) is
 136       St : STATUS;
 137    begin
 138       St := semDelete (S.Sema);
 139       St := semDelete (S.Mutex);
 140    end Finalize;
 141
 142 end Ada.Synchronous_Task_Control;