fastjar/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(jartool.h)
   3 AM_INIT_AUTOMAKE(fastjar, 0.92-gcc)
   4 AM_CONFIG_HEADER(config.h)
   5
   6 dnl Checks for programs.
   7 AC_PROG_CC
   8 AC_PROG_INSTALL
   9 AC_PATH_PROG(RM, rm, /bin/rm, $PATH:/bin:/usr/bin:/usr/local/bin)
  10 AC_PATH_PROG(CP, cp, /bin/cp, $PATH:/bin:/usr/bin:/usr/local/bin)
  11 AC_PATH_PROG(STRIP, strip, /usr/bin/strip, $PATH:/bin:/usr/bin:/usr/local/bin)
  12 AC_PATH_PROG(CHMOD, chmod, /bin/chmod, $PATH:/bin:/usr/bin:/usr/local/bin)
  13 AC_EXEEXT
  14
  15 AM_MAINTAINER_MODE
  16
  17 dnl Add warning flags if we are using gcc.
  18 if test "$GCC" = yes; then
  19   fastjar_warn_cflags='-W -Wall -pedantic -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings'
  20 fi
  21 AC_SUBST(fastjar_warn_cflags)
  22
  23 dnl Checks for header files.
  24 AC_HEADER_DIRENT
  25 AC_HEADER_STDC
  26 AC_STRUCT_TM
  27 AC_CHECK_HEADERS(fcntl.h unistd.h sys/param.h stdlib.h limits.h)
  28
  29 dnl Checks for typedefs, structures, and compiler characteristics.
  30 AC_TYPE_OFF_T
  31 AC_STRUCT_TM
  32
  33 # mkdir takes a single argument on some systems.
  34 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
  35
  36 dnl Check for type-widths
  37 AC_COMPILE_CHECK_SIZEOF(char)
  38 AC_COMPILE_CHECK_SIZEOF(short)
  39 AC_COMPILE_CHECK_SIZEOF(int)
  40 AC_COMPILE_CHECK_SIZEOF(long)
  41 AC_COMPILE_CHECK_SIZEOF(long long)
  42
  43 dnl Check byte order
  44 AC_C_BIGENDIAN_CROSS
  45
  46 AC_ARG_WITH(system-zlib,
  47 [  --with-system-zlib      use installed libz])
  48
  49 ZLIBS=
  50 ZDEPS=
  51 ZINCS=
  52 use_zlib=maybe
  53 if test "$with_system_zlib" = yes; then
  54    AC_CHECK_LIB(z, deflate, ZLIBS=-lz, use_zlib=no)
  55 else
  56    use_zlib=no
  57 fi
  58
  59 if test "$use_zlib" = no; then
  60    # Brain dead way to find tree's zlib.
  61    ZDEPS='$(top_builddir)/../zlib/libz.a'
  62    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
  63    ZINCS='-I$(top_srcdir)/../zlib'
  64 fi
  65 AC_SUBST(ZLIBS)
  66 AC_SUBST(ZDEPS)
  67 AC_SUBST(ZINCS)
  68
  69 # Get the version trigger filename from the toplevel
  70 if test "${with_gcc_version_trigger+set}" = set; then
  71    gcc_version_trigger=$with_gcc_version_trigger
  72 else
  73    gcc_version_trigger=${srcdir}/version.c
  74 fi
  75 changequote(,)dnl
  76 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
  77 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
  78 changequote([,])dnl
  79 AC_SUBST(gcc_version)
  80
  81 AC_OUTPUT(Makefile install-defs.sh)